git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl This work is part of OpenLDAP Software <http://www.openldap.org/>.
   3 dnl
   4 dnl Copyright 1998-2007 The OpenLDAP Foundation.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted only as authorized by the OpenLDAP
   9 dnl Public License.
  10 dnl
  11 dnl A copy of this license is available in the file LICENSE in the
  12 dnl top-level directory of the distribution or, alternatively, at
  13 dnl <http://www.OpenLDAP.org/license.html>.
  14 dnl
  15 dnl ----------------------------------------------------------------
  16 dnl Disable config.cache!
  17 define([AC_CACHE_LOAD], )dnl
  18 define([AC_CACHE_SAVE], )dnl
  19 dnl ----------------------------------------------------------------
  20 dnl Disable libtool 1.5 support for languages we don't use
  21 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  22 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  23 define([AC_LIBTOOL_LANG_GCJ_CONFIG], [:])dnl
  24 dnl ================================================================
  25 dnl Configure.in for OpenLDAP
  26 AC_COPYRIGHT([[Copyright 1998-2007 The OpenLDAP Foundation. All rights reserved.
  27 Restrictions apply, see COPYRIGHT and LICENSE files.]])
  28 AC_REVISION([$OpenLDAP$])
  29 AC_INIT([OpenLDAP],,[http://www.openldap.org/its/])
  30 m4_define([AC_PACKAGE_BUGREPORT],[<http://www.openldap.org/its/>])
  31 AC_CONFIG_SRCDIR(build/version.sh)dnl
  32 dnl ----------------------------------------------------------------
  33 dnl OpenLDAP Autoconf Macros
  34 builtin(include, build/openldap.m4)dnl
  35 dnl ================================================================
  36
  37 AC_CONFIG_AUX_DIR(build)dnl
  38
  39 eval `$ac_aux_dir/version.sh`
  40 if test -z "$OL_STRING"; then
  41         AC_MSG_ERROR([could not determine version])
  42 fi
  43
  44 if test -f "$ac_aux_dir/shtool" && test ! -d $ac_aux_dir/shtool; then
  45         ac_cv_shtool="$ac_aux_dir/shtool"
  46 else
  47         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  48 fi
  49
  50 SHTOOL="$ac_cv_shtool"
  51 dnl AC_SUBST(SHTOOL)dnl
  52
  53 TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  54 TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  55
  56 OPENLDAP_CVS=""
  57 if test -d $ac_aux_dir/CVS; then
  58         OPENLDAP_CVS="(from CVS sources) "
  59 fi
  60
  61 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_CVS}..."
  62
  63 dnl Determine host platform
  64 dnl             we try not to use this for much
  65 AC_CANONICAL_TARGET([])
  66
  67 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  68 AC_SUBST(PACKAGE)dnl
  69 AC_SUBST(VERSION)dnl
  70 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  71 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  72
  73 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  74 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  75 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  76 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  77
  78 OPENLDAP_LIBRELEASE=$OL_API_LIB_RELEASE
  79 AC_SUBST(OPENLDAP_LIBRELEASE)dnl
  80
  81 OPENLDAP_LIBVERSION=$OL_API_LIB_VERSION
  82 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  83
  84 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  85 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  86
  87 dnl We use autoconf features new to 2.59.  Later versions like won't work.
  88 dnl aclocal.m4 should be built using aclocal from automake 1.5
  89 dnl libtool 1.5 should be installed.
  90 AC_PREREQ(2.59)dnl Required Autoconf version
  91
  92 AH_TOP([
  93 /* begin of portable.h.pre */
  94 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
  95  *
  96  * Copyright 1998-2007 The OpenLDAP Foundation
  97  * All rights reserved.
  98  *
  99  * Redistribution and use in source and binary forms, with or without
 100  * modification, are permitted only as authorized by the OpenLDAP
 101  * Public License.
 102  *
 103  * A copy of this license is available in the file LICENSE in the
 104  * top-level directory of the distribution or, alternatively, at
 105  * <http://www.OpenLDAP.org/license.html>.
 106  */
 107
 108 #ifndef _LDAP_PORTABLE_H
 109 #define _LDAP_PORTABLE_H
 110
 111 /* define this if needed to get reentrant functions */
 112 #ifndef REENTRANT
 113 #undef REENTRANT
 114 #endif
 115 #ifndef _REENTRANT
 116 #undef _REENTRANT
 117 #endif
 118
 119 /* define this if needed to get threadsafe functions */
 120 #ifndef THREADSAFE
 121 #undef THREADSAFE
 122 #endif
 123 #ifndef _THREADSAFE
 124 #undef _THREADSAFE
 125 #endif
 126 #ifndef THREAD_SAFE
 127 #undef THREAD_SAFE
 128 #endif
 129 #ifndef _THREAD_SAFE
 130 #undef _THREAD_SAFE
 131 #endif
 132
 133 #ifndef _SGI_MP_SOURCE
 134 #undef _SGI_MP_SOURCE
 135 #endif
 136
 137 /* end of portable.h.pre */
 138 ])
 139 AH_BOTTOM([
 140 /* begin of portable.h.post */
 141
 142 #ifdef _WIN32
 143         /* don't suck in all of the win32 api */
 144 #       define WIN32_LEAN_AND_MEAN 1
 145 #endif
 146
 147 #ifndef LDAP_NEEDS_PROTOTYPES
 148 /* force LDAP_P to always include prototypes */
 149 #define LDAP_NEEDS_PROTOTYPES 1
 150 #endif
 151
 152 #ifndef LDAP_REL_ENG
 153 #if (LDAP_VENDOR_VERSION == 000000) && !defined(LDAP_DEVEL)
 154 #define LDAP_DEVEL
 155 #endif
 156 #if defined(LDAP_DEVEL) && !defined(LDAP_TEST)
 157 #define LDAP_TEST
 158 #endif
 159 #endif
 160
 161 #ifdef HAVE_STDDEF_H
 162 #       include <stddef.h>
 163 #endif
 164
 165 #ifdef HAVE_EBCDIC
 166 /* ASCII/EBCDIC converting replacements for stdio funcs
 167  * vsnprintf and snprintf are used too, but they are already
 168  * checked by the configure script
 169  */
 170 #define fputs ber_pvt_fputs
 171 #define fgets ber_pvt_fgets
 172 #define printf ber_pvt_printf
 173 #define fprintf ber_pvt_fprintf
 174 #define vfprintf ber_pvt_vfprintf
 175 #define vsprintf ber_pvt_vsprintf
 176 #endif
 177
 178 #include "ac/fdset.h"
 179
 180 #include "ldap_cdefs.h"
 181 #include "ldap_features.h"
 182
 183 #include "ac/assert.h"
 184 #include "ac/localize.h"
 185
 186 #endif /* _LDAP_PORTABLE_H */
 187 /* end of portable.h.post */
 188 ])
 189
 190 AC_CONFIG_HEADERS([include/portable.h:include/portable.hin])
 191 AC_CONFIG_HEADERS([include/ldap_features.h:include/ldap_features.hin])
 192 AC_CONFIG_HEADERS([include/lber_types.h:include/lber_types.hin])
 193
 194 dnl ================================================================
 195 dnl Start Args
 196 AC_MSG_CHECKING(configure arguments)
 197 AC_PREFIX_DEFAULT(/usr/local)
 198
 199 top_builddir=`pwd`
 200 AC_SUBST(top_builddir)dnl
 201
 202 dnl ----------------------------------------------------------------
 203 dnl --with-subdir
 204 ldap_subdir="/openldap"
 205
 206 AC_ARG_WITH(subdir,
 207 [  --with-subdir=DIR       change default subdirectory used for installs],
 208 [case "$withval" in
 209         no) ldap_subdir=""
 210                 ;;
 211         yes)
 212                 ;;
 213         /*|\\*)
 214                 ldap_subdir="$withval"
 215                 ;;
 216         *)
 217                 ldap_subdir="/$withval"
 218                 ;;
 219 esac
 220 ])dnl
 221
 222 AC_SUBST(ldap_subdir)dnl
 223
 224 dnl ----------------------------------------------------------------
 225 dnl General "enable" options
 226 dnl set default to traditional to enable the original debug style
 227 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes, [no yes traditional])dnl
 228 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 229 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 230 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 231 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 232 ol_enable_referrals=${ol_enable_referrals-no}
 233 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 234 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 235
 236 dnl ----------------------------------------------------------------
 237 dnl General "with" options
 238 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 239         auto, [auto yes no] )
 240 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 241         auto, [auto yes no] )
 242 OL_ARG_WITH(threads,[  --with-threads     with threads],
 243         auto, [auto nt posix mach pth lwp yes no manual] )
 244 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 245         auto, [auto openssl yes no] )
 246 OL_ARG_WITH(yielding_select,
 247         [  --with-yielding-select  with implicitly yielding select],
 248         auto, [auto yes no manual] )
 249 OL_ARG_WITH(mp,
 250         [  --with-mp               with multiple precision statistics auto|longlong|long|bignum|gmp],
 251         auto, [auto longlong long bignum gmp yes no])
 252 OL_ARG_WITH(odbc,
 253         [  --with-odbc             with specific ODBC support iodbc|unixodbc|auto],
 254         auto, [auto iodbc unixodbc] )
 255
 256 dnl ----------------------------------------------------------------
 257 dnl Server options
 258 dnl ----------------------------------------------------------------
 259
 260 dnl ----------------------------------------------------------------
 261 dnl SLAPD OPTIONS
 262 AC_ARG_ENABLE(xxslapdoptions,[
 263 SLAPD (Standalone LDAP Daemon) Options:])
 264 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 265 OL_ARG_ENABLE(dynacl,[    --enable-dynacl         enable run-time loadable ACL support (experimental)], no)dnl
 266 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no, [no yes mod])dnl
 267 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 268 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 269 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 270 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 271 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 272 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and rwm overlay], auto)dnl
 273 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 274 OL_ARG_ENABLE(slapi,[    --enable-slapi        enable SLAPI support (experimental)], no)dnl
 275 OL_ARG_ENABLE(slp,[    --enable-slp          enable SLPv2 support], no)dnl
 276 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 277
 278 dnl ----------------------------------------------------------------
 279 dnl SLAPD Backend Options
 280 Backends="bdb \
 281         dnssrv \
 282         hdb \
 283         ldap \
 284         meta \
 285         monitor \
 286         null \
 287         passwd \
 288         perl \
 289         relay \
 290         shell \
 291         sql"
 292
 293 AC_ARG_ENABLE(xxslapbackends,[
 294 SLAPD Backend Options:])
 295
 296 OL_ARG_ENABLE(backends,[    --enable-backends     enable all available backends],
 297         --, [no yes mod])dnl
 298 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend],
 299         yes, [no yes mod], ol_enable_backends)dnl
 300 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend],
 301         no, [no yes mod], ol_enable_backends)dnl
 302 OL_ARG_ENABLE(hdb,[    --enable-hdb       enable Hierarchical DB backend],
 303         yes, [no yes mod], ol_enable_backends)dnl
 304 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend],
 305         no, [no yes mod], ol_enable_backends)dnl
 306 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend],
 307         no, [no yes mod], ol_enable_backends)dnl
 308 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend],
 309         yes, [no yes mod], ol_enable_backends)dnl
 310 OL_ARG_ENABLE(null,[    --enable-null     enable null backend],
 311         no, [no yes mod], ol_enable_backends)dnl
 312 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend],
 313         no, [no yes mod], ol_enable_backends)dnl
 314 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend],
 315         no, [no yes mod], ol_enable_backends)dnl
 316 OL_ARG_ENABLE(relay,[    --enable-relay           enable relay backend],
 317         yes, [no yes mod], ol_enable_backends)dnl
 318 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend],
 319         no, [no yes mod], ol_enable_backends)dnl
 320 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend],
 321         no, [no yes mod], ol_enable_backends)dnl
 322
 323 dnl ----------------------------------------------------------------
 324 dnl SLAPD Overlay Options
 325 Overlays="accesslog \
 326         auditlog \
 327         constraint \
 328         dds \
 329         dyngroup \
 330         dynlist \
 331         ppolicy \
 332         proxycache \
 333         refint \
 334         retcode \
 335         rwm \
 336         seqmod \
 337         syncprov \
 338         translucent \
 339         unique \
 340         valsort"
 341
 342 AC_ARG_ENABLE(xxslapoverlays,[
 343 SLAPD Overlay Options:])
 344
 345 OL_ARG_ENABLE(overlays,[    --enable-overlays     enable all available overlays],
 346         --, [no yes mod])dnl
 347 OL_ARG_ENABLE(accesslog,[    --enable-accesslog   In-Directory Access Logging overlay],
 348         no, [no yes mod], ol_enable_overlays)
 349 OL_ARG_ENABLE(auditlog,[    --enable-auditlog     Audit Logging overlay],
 350         no, [no yes mod], ol_enable_overlays)
 351 OL_ARG_ENABLE(constraint,[    --enable-constraint         Attribute Constraint overlay],
 352         no, [no yes mod], ol_enable_overlays)
 353 OL_ARG_ENABLE(dds,[    --enable-dds       Dynamic Directory Services overlay],
 354         no, [no yes mod], ol_enable_overlays)
 355 OL_ARG_ENABLE(dyngroup,[    --enable-dyngroup     Dynamic Group overlay],
 356         no, [no yes mod], ol_enable_overlays)
 357 OL_ARG_ENABLE(dynlist,[    --enable-dynlist       Dynamic List overlay],
 358         no, [no yes mod], ol_enable_overlays)
 359 OL_ARG_ENABLE(ppolicy,[    --enable-ppolicy       Password Policy overlay],
 360         no, [no yes mod], ol_enable_overlays)
 361 OL_ARG_ENABLE(proxycache,[    --enable-proxycache         Proxy Cache overlay],
 362         no, [no yes mod], ol_enable_overlays)
 363 OL_ARG_ENABLE(refint,[    --enable-refint         Referential Integrity overlay],
 364         no, [no yes mod], ol_enable_overlays)
 365 OL_ARG_ENABLE(retcode,[    --enable-retcode       Return Code testing overlay],
 366         no, [no yes mod], ol_enable_overlays)
 367 OL_ARG_ENABLE(rwm,[    --enable-rwm               Rewrite/Remap overlay],
 368         no, [no yes mod], ol_enable_overlays)
 369 OL_ARG_ENABLE(seqmod,[    --enable-seqmod         Sequential Modify overlay],
 370         yes, [no yes mod], ol_enable_overlays)
 371 OL_ARG_ENABLE(syncprov,[    --enable-syncprov     Syncrepl Provider overlay],
 372         yes, [no yes mod], ol_enable_overlays)
 373 OL_ARG_ENABLE(translucent,[    --enable-translucent  Translucent Proxy overlay],
 374         no, [no yes mod], ol_enable_overlays)
 375 OL_ARG_ENABLE(unique,[    --enable-unique       Attribute Uniqueness overlay],
 376         no, [no yes mod], ol_enable_overlays)
 377 OL_ARG_ENABLE(valsort,[    --enable-valsort      Value Sorting overlay],
 378         no, [no yes mod], ol_enable_overlays)
 379
 380 dnl ----------------------------------------------------------------
 381 dnl SLURPD OPTIONS
 382 AC_ARG_ENABLE(xxslurpdoptions,[
 383 SLURPD (Replication Daemon) Options:])
 384 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 385
 386 dnl ----------------------------------------------------------------
 387 AC_ARG_ENABLE(xxliboptions,[
 388 Library Generation & Linking Options])
 389 AC_ENABLE_STATIC
 390 AC_ENABLE_SHARED
 391
 392 dnl ----------------------------------------------------------------
 393
 394 # validate options
 395 if test $ol_enable_slapd = no ; then
 396         dnl SLAPD was specificallly disabled
 397         if test $ol_enable_slapi = yes ; then
 398                 AC_MSG_WARN([slapd disabled, ignoring --enable-slapi argument])
 399         fi
 400         case "$ol_enable_backends" in yes | mod)
 401                 AC_MSG_WARN([slapd disabled, ignoring --enable-backends argument])
 402         esac
 403         for i in $Backends; do
 404                 eval "ol_tmp=\$ol_enable_$i"
 405                 if test $ol_tmp != no ; then
 406                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 407                         eval "ol_enable_$i=no"
 408                 fi
 409         done
 410         if test $ol_enable_modules = yes ; then
 411                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 412         fi
 413         if test $ol_enable_wrappers = yes ; then
 414                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 415         fi
 416         if test $ol_enable_rlookups = yes ; then
 417                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 418         fi
 419         if test $ol_enable_dynacl = yes ; then
 420                 AC_MSG_WARN([slapd disabled, ignoring --enable-dynacl argument])
 421         fi
 422         if test $ol_enable_aci != no ; then
 423                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 424         fi
 425         if test $ol_enable_slurpd = yes ; then
 426                 AC_MSG_ERROR([slurpd requires slapd])
 427         fi
 428         if test $ol_enable_rewrite = yes ; then
 429                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 430         fi
 431         dnl overlays
 432         case "$ol_enable_overlays" in yes | mod)
 433                 AC_MSG_WARN([slapd disabled, ignoring --enable-overlays argument])
 434         esac
 435         for i in $Overlays; do
 436                 eval "ol_tmp=\$ol_enable_$i"
 437                 if test $ol_tmp != no ; then
 438                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 439                         eval "ol_enable_$i=no"
 440                 fi
 441         done
 442
 443         # force settings to no
 444         ol_enable_slapi=no
 445
 446         ol_enable_backends=
 447         ol_enable_overlays=
 448         ol_enable_modules=no
 449         ol_enable_rlookups=no
 450         ol_enable_dynacl=no
 451         ol_enable_aci=no
 452         ol_enable_wrappers=no
 453
 454         ol_enable_slurpd=no
 455
 456         ol_enable_rewrite=no
 457
 458 elif test $ol_enable_modules != yes &&
 459         test $ol_enable_bdb = no &&
 460         test $ol_enable_dnssrv = no &&
 461         test $ol_enable_hdb = no &&
 462         test $ol_enable_ldap = no &&
 463         test $ol_enable_meta = no &&
 464         test $ol_enable_monitor = no &&
 465         test $ol_enable_null = no &&
 466         test $ol_enable_passwd = no &&
 467         test $ol_enable_perl = no &&
 468         test $ol_enable_relay = no &&
 469         test $ol_enable_shell = no &&
 470         test $ol_enable_sql = no ; then
 471         dnl no slapd backend
 472
 473         if test $ol_enable_slapd = yes ; then
 474                 AC_MSG_ERROR([slapd requires a backend])
 475         else
 476                 AC_MSG_WARN([skipping slapd, no backend specified])
 477                 ol_enable_slapd=no
 478         fi
 479 fi
 480
 481 if test $ol_enable_meta/$ol_enable_ldap = yes/no ; then
 482         AC_MSG_ERROR([--enable-meta requires --enable-ldap])
 483 fi
 484
 485 if test $ol_enable_slurpd = yes ; then
 486         dnl SLURPD was specifically enabled
 487         if test $ol_with_threads = no ; then
 488                 AC_MSG_ERROR([slurpd requires threads])
 489         fi
 490 fi
 491
 492 if test $ol_enable_lmpasswd = yes ; then
 493         if test $ol_with_tls = no ; then
 494                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 495         fi
 496 fi
 497
 498 if test $ol_enable_spasswd = yes ; then
 499         if test $ol_with_cyrus_sasl = no ; then
 500                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 501         fi
 502         ol_with_cyrus_sasl=yes
 503 fi
 504
 505 AC_MSG_RESULT(done)
 506
 507 dnl ----------------------------------------------------------------
 508 dnl Initialize vars
 509 LDAP_LIBS=
 510 BDB_LIBS=
 511 LTHREAD_LIBS=
 512 LUTIL_LIBS=
 513
 514 SLAPD_LIBS=
 515 SLURPD_LIBS=
 516
 517 BUILD_SLAPD=no
 518 BUILD_SLURPD=no
 519
 520 BUILD_THREAD=no
 521
 522 BUILD_SLAPI=no
 523 SLAPD_SLAPI_DEPEND=
 524
 525 BUILD_BDB=no
 526 BUILD_DNSSRV=no
 527 BUILD_HDB=no
 528 BUILD_LDAP=no
 529 BUILD_META=no
 530 BUILD_MONITOR=no
 531 BUILD_NULL=no
 532 BUILD_PASSWD=no
 533 BUILD_PERL=no
 534 BUILD_RELAY=no
 535 BUILD_SHELL=no
 536 BUILD_SQL=no
 537
 538 BUILD_ACCESSLOG=no
 539 BUILD_AUDITLOG=no
 540 BUILD_CONSTRAINT=no
 541 BUILD_DDS=no
 542 BUILD_DENYOP=no
 543 BUILD_DYNGROUP=no
 544 BUILD_DYNLIST=no
 545 BUILD_LASTMOD=no
 546 BUILD_PPOLICY=no
 547 BUILD_PROXYCACHE=no
 548 BUILD_REFINT=no
 549 BUILD_RETCODE=no
 550 BUILD_RWM=no
 551 BUILD_SEQMOD=no
 552 BUILD_SYNCPROV=no
 553 BUILD_TRANSLUCENT=no
 554 BUILD_UNIQUE=no
 555 BUILD_VALSORT=no
 556
 557 SLAPD_STATIC_OVERLAYS=
 558 SLAPD_DYNAMIC_OVERLAYS=
 559
 560 SLAPD_MODULES_LDFLAGS=
 561 SLAPD_MODULES_CPPFLAGS=
 562
 563 SLAPD_STATIC_BACKENDS=back-ldif
 564 SLAPD_DYNAMIC_BACKENDS=
 565
 566 SLAPD_PERL_LDFLAGS=
 567 MOD_PERL_LDFLAGS=
 568 PERL_CPPFLAGS=
 569
 570 SLAPD_SQL_LDFLAGS=
 571 SLAPD_SQL_LIBS=
 572 SLAPD_SQL_INCLUDES=
 573
 574 KRB4_LIBS=
 575 KRB5_LIBS=
 576 SASL_LIBS=
 577 TLS_LIBS=
 578 MODULES_LIBS=
 579 SLAPI_LIBS=
 580 LIBSLAPI=
 581 LIBSLAPITOOLS=
 582 AUTH_LIBS=
 583 ICU_LIBS=
 584
 585 SLAPD_SLP_LIBS=
 586 SLAPD_GMP_LIBS=
 587
 588 dnl ================================================================
 589 dnl Checks for programs
 590
 591 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 592
 593 dnl ----------------------------------------------------------------
 594 dnl
 595 dnl Determine which C translator to use
 596 dnl
 597
 598 dnl AIX Thread requires we use cc_r or xlc_r.
 599 dnl But only do this IF AIX and CC is not set
 600 dnl and threads are auto|yes|posix.
 601 dnl
 602 dnl If we find cc_r|xlc_r, force pthreads and assume
 603 dnl             pthread_create is in $LIBS (ie: don't bring in
 604 dnl             any additional thread libraries)
 605 dnl If we do not find cc_r|xlc_r, disable threads
 606
 607 ol_aix_threads=no
 608 case "$target" in
 609 *-*-aix*) dnl all AIX is not a good idea.
 610         if test -z "$CC" ; then
 611                 case "$ol_with_threads" in
 612                 auto | yes |  posix) ol_aix_threads=yes ;;
 613                 esac
 614         fi
 615 ;;
 616 esac
 617
 618 if test $ol_aix_threads = yes ; then
 619         if test -z "${CC}" ; then
 620                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 621
 622                 if test "$CC" = cc ; then
 623                         dnl no CC! don't allow --with-threads
 624                         if test $ol_with_threads != auto ; then
 625                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 626                         else
 627                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 628                         fi
 629                         ol_with_threads=no
 630                 fi
 631         fi
 632
 633         case ${CC} in cc_r | xlc_r)
 634                 ol_with_threads=posix
 635                 ol_cv_pthread_create=yes
 636                 ;;
 637         esac
 638 fi
 639
 640 if test -z "${CC}"; then
 641         AC_CHECK_PROGS(CC,cc gcc,missing)
 642
 643         if test "${CC}" = "missing" ; then
 644                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 645         fi
 646 fi
 647
 648 if test -z "${AR}"; then
 649         AC_CHECK_PROGS(AR,ar gar,missing)
 650
 651         if test "${AR}" = "missing" ; then
 652                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 653         fi
 654 fi
 655
 656 AC_LIBTOOL_WIN32_DLL
 657 AC_LIBTOOL_DLOPEN
 658 AC_PROG_LIBTOOL
 659
 660 dnl ----------------------------------------------------------------
 661 dnl Perl
 662 ol_link_perl=no
 663 if test $ol_enable_perl != no ; then
 664         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 665
 666         if test "no$PERLBIN" = "no" ; then
 667                 if test $ol_enable_perl = yes ; then
 668                         AC_MSG_ERROR([could not locate perl])
 669                 fi
 670
 671         else
 672                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 673                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 674
 675                 if test x"$ol_enable_perl" = "xyes" ; then
 676                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 677                 else
 678                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 679                 fi
 680                 dnl should check perl version
 681                 ol_link_perl=yes
 682         fi
 683 fi
 684
 685 AC_PROG_CPP
 686
 687 dnl ----------------------------------------------------------------
 688 dnl Checks for Windows NT
 689 case $host_os in
 690   *mingw32* ) ac_cv_mingw32=yes ;;
 691   *cygwin* ) ac_cv_cygwin=yes ;;
 692 esac
 693
 694 dnl ----------------------------------------------------------------
 695 dnl Checks for file extensions
 696 AC_EXEEXT
 697 AC_OBJEXT
 698 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 699
 700 dnl ----------------------------------------------------------------
 701 dnl BeOS requires -lbe -lroot -lnet
 702 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 703
 704 dnl ----------------------------------------------------------------
 705 dnl OpenLDAP requires STDC features
 706 AC_PROG_CC
 707 if test "X${ac_cv_prog_cc_stdc}" = "Xno" ; then
 708         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 709 fi
 710
 711 dnl ----------------------------------------------------------------
 712 dnl Check cc depend flags
 713 OL_MKDEPEND
 714 if test "${ol_cv_mkdep}" = no ; then
 715         # this will soon become an error
 716         AC_MSG_WARN([do not know how to generate dependencies])
 717 fi
 718
 719 dnl ----------------------------------------------------------------
 720 dnl Check for AIX security library
 721 AC_CHECK_LIB(s, afopen, [
 722         AUTH_LIBS=-ls
 723         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 724 ])
 725
 726 dnl ----------------------------------------------------------------
 727 dnl Check for IBM OS/390
 728 case "$target" in
 729 *-ibm-openedition)
 730         ac_cv_func_getopt=no
 731         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 732         ;;
 733 esac
 734
 735 dnl ----------------------------------------------------------------
 736 dnl Check for module support
 737 ol_link_modules=no
 738 WITH_MODULES_ENABLED=no
 739 if test $ol_enable_modules != no ; then
 740         AC_CHECK_HEADERS(ltdl.h)
 741
 742         if test $ac_cv_header_ltdl_h = no ; then
 743                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 744         fi
 745
 746         AC_CHECK_LIB(ltdl, lt_dlinit, [
 747                 MODULES_LIBS=-lltdl
 748                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 749         ])
 750
 751         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 752                 AC_MSG_ERROR([could not locate libtool -lltdl])
 753         fi
 754         ol_link_modules=yes
 755         WITH_MODULES_ENABLED=yes
 756
 757 else
 758         for i in $Backends; do
 759                 eval "ol_tmp=\$ol_enable_$i"
 760                 if test $ol_tmp = mod ; then
 761                         AC_MSG_WARN([building static $i backend])
 762                         eval "ol_enable_$i=yes"
 763                 fi
 764         done
 765         for i in $Overlays; do
 766                 eval "ol_tmp=\$ol_enable_$i"
 767                 if test $ol_tmp = mod ; then
 768                         AC_MSG_WARN([building static $i overlay])
 769                         eval "ol_enable_$i=yes"
 770                 fi
 771         done
 772 fi
 773
 774 dnl ----------------------------------------------------------------
 775 dnl Checks for header files.
 776 OL_HEADER_STDC
 777
 778 if test $ol_cv_header_stdc != yes; then
 779         AC_MSG_WARN([could not locate Standard C compliant headers])
 780 fi
 781
 782 AC_HEADER_DIRENT
 783 AC_HEADER_SYS_WAIT
 784 AC_HEADER_TIOCGWINSZ
 785
 786 AC_CHECK_HEADERS(       \
 787         arpa/inet.h             \
 788         arpa/nameser.h  \
 789         assert.h                \
 790         bits/types.h    \
 791         conio.h                 \
 792         crypt.h                 \
 793         direct.h                \
 794         errno.h                 \
 795         fcntl.h                 \
 796         filio.h                 \
 797         getopt.h                \
 798         grp.h                   \
 799         io.h                    \
 800         libutil.h               \
 801         limits.h                \
 802         locale.h                \
 803         malloc.h                \
 804         memory.h                \
 805         psap.h                  \
 806         pwd.h                   \
 807         process.h               \
 808         sgtty.h                 \
 809         shadow.h                \
 810         stddef.h                \
 811         string.h                \
 812         strings.h               \
 813         sysexits.h              \
 814         sys/file.h              \
 815         sys/filio.h             \
 816         sys/errno.h             \
 817         sys/ioctl.h             \
 818         sys/param.h             \
 819         sys/resource.h  \
 820         sys/select.h    \
 821         sys/socket.h    \
 822         sys/stat.h              \
 823         sys/syslog.h    \
 824         sys/time.h              \
 825         sys/types.h             \
 826         sys/uio.h               \
 827         syslog.h                \
 828         termios.h               \
 829         unistd.h                \
 830         utime.h                 \
 831 )
 832
 833 dnl Only check Winsock on MinGW
 834 if test "$ac_cv_mingw32" = yes ; then
 835         AC_CHECK_HEADERS( winsock.h winsock2.h )
 836 fi
 837
 838 AC_CHECK_HEADERS( resolv.h, [], [],
 839 [$ac_includes_default
 840 #include <netinet/in.h>
 841 ])
 842
 843 AC_CHECK_HEADERS( netinet/tcp.h, [], [],
 844 [$ac_includes_default
 845 #include <netinet/in.h>
 846 ])
 847
 848 AC_CHECK_HEADERS( sys/ucred.h, [], [],
 849 [$ac_includes_default
 850 #ifdef HAVE_SYS_PARAM_H
 851 #include <sys/param.h>
 852 #endif
 853 ])
 854
 855 dnl ----------------------------------------------------------------
 856 dnl Checks for libraries
 857
 858 AC_CHECK_FUNCS( sigaction sigset )
 859
 860 dnl HP-UX requires -lV3
 861 dnl this is not needed on newer versions of HP-UX
 862 if test $ac_cv_func_sigaction = no && test $ac_cv_func_sigaction = no ; then
 863         AC_CHECK_LIB(V3, sigset)
 864 fi
 865
 866 dnl The following is INTENTIONALLY scripted out because shell does not
 867 dnl support variable names with the '@' character, which is what
 868 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 869 if test "$ac_cv_header_winsock_h" = yes; then
 870 AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 871 save_LIBS="$LIBS"
 872 for curlib in ws2_32 wsock32; do
 873         LIBS="$LIBS -l$curlib"
 874         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <winsock.h>
 875                         ]], [[
 876                         socket(0,0,0);
 877                         select(0,NULL,NULL,NULL,NULL);
 878                         closesocket(0);
 879                         gethostname(NULL,0);
 880                         ]])],[ol_cv_winsock=yes],[ol_cv_winsock=no])
 881
 882         if test $ol_cv_winsock = yes; then
 883                 AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 884                 ac_cv_func_socket=yes
 885                 ac_cv_func_select=yes
 886                 ac_cv_func_closesocket=yes
 887                 ac_cv_func_gethostname=yes
 888                 if test $curlib = ws2_32; then
 889                         ol_cv_winsock=winsock2
 890                         AC_DEFINE(HAVE_WINSOCK2, 1,
 891                                   [define if you have winsock2])
 892                 fi
 893                 break
 894         fi
 895         LIBS="$save_LIBS"
 896 done)
 897 fi
 898
 899 dnl Find socket()
 900 dnl Likely combinations:
 901 dnl             -lsocket [ -lnsl_s | -lnsl ]
 902 dnl             -linet
 903
 904 AC_CHECK_FUNC(socket, :, [
 905 dnl hopefully we won't include too many libraries
 906         AC_CHECK_LIB(socket, main)
 907         AC_CHECK_LIB(net, main)
 908         AC_CHECK_LIB(nsl_s, main)
 909         AC_CHECK_LIB(nsl, main)
 910         AC_CHECK_LIB(inet, socket)
 911         AC_CHECK_LIB(gen, main)
 912 ])
 913
 914 dnl require select
 915 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 916
 917 if test "${ac_cv_header_winsock_h}" != yes; then
 918         dnl Select arg types
 919         dnl (if this detection becomes permenent, it and the select() detection
 920         dnl should be done before the yielding select test)
 921         AC_FUNC_SELECT_ARGTYPES
 922 fi
 923
 924 dnl check to see if system call automatically restart
 925 dnl AC_SYS_RESTARTABLE_SYSCALLS
 926
 927 dnl ----------------------------------------------------------------
 928 AC_CHECK_FUNCS( poll )
 929 if test $ac_cv_func_poll = yes; then
 930 AC_CHECK_HEADERS( poll.h sys/poll.h )
 931 fi
 932
 933 dnl ----------------------------------------------------------------
 934 AC_CHECK_HEADERS( sys/epoll.h )
 935 if test "${ac_cv_header_sys_epoll_h}" = yes; then
 936         AC_MSG_CHECKING(for epoll system call)
 937         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 938 {
 939         int epfd = epoll_create(256);
 940         exit (epfd == -1 ? 1 : 0);
 941 }]])],[AC_MSG_RESULT(yes)
 942         AC_DEFINE(HAVE_EPOLL,1, [define if your system supports epoll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 943 fi
 944
 945 dnl ----------------------------------------------------------------
 946 AC_CHECK_HEADERS( sys/devpoll.h )
 947 dnl "/dev/poll" needs <sys/poll.h> as well...
 948 if test "${ac_cv_header_sys_devpoll_h}" = yes \
 949                 -a "${ac_cv_header_poll_h}" = yes ; \
 950 then
 951         AC_MSG_CHECKING(for /dev/poll)
 952         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 953 {
 954         int devpollfd = open("/dev/poll", /* O_RDWR */ 2);
 955         exit (devpollfd == -1 ? 1 : 0);
 956 }]])],[AC_MSG_RESULT(yes)
 957         AC_DEFINE(HAVE_DEVPOLL,1, [define if your system supports /dev/poll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 958 fi
 959
 960 dnl ----------------------------------------------------------------
 961 # strerror checks
 962 OL_STRERROR
 963
 964 dnl ----------------------------------------------------------------
 965 dnl require POSIX regex
 966 AC_CHECK_HEADERS( regex.h, [], [],
 967 [$ac_includes_default
 968 #ifdef HAVE_SYS_TYPES_H
 969 #include <sys/types.h>
 970 #endif
 971 ])
 972
 973 if test "$ac_cv_header_regex_h" != yes ; then
 974         AC_MSG_ERROR([POSIX regex.h required.])
 975 fi
 976 AC_SEARCH_LIBS(regfree, [regex gnuregex],
 977         :, AC_MSG_ERROR([POSIX regex required.]))
 978
 979 OL_POSIX_REGEX
 980 if test "$ol_cv_c_posix_regex" = no ; then
 981         AC_MSG_ERROR([broken POSIX regex!])
 982 fi
 983
 984 dnl ----------------------------------------------------------------
 985 dnl UUID Support
 986
 987 have_uuid=no
 988 AC_CHECK_HEADERS(sys/uuid.h)
 989 if test $ac_cv_header_sys_uuid_h = yes ; then
 990         save_LIBS="$LIBS"
 991         AC_SEARCH_LIBS(uuid_to_str, uuid, [have_uuid=yes], :)
 992         LIBS="$save_LIBS"
 993
 994         if test have_uuid = yes ; then
 995                 AC_DEFINE(HAVE_UUID_TO_STR,1,
 996                         [define if you have uuid_to_str()])
 997
 998                 test "$ac_cv_search_uuid_to_str" = "none required" || \
 999                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
1000         fi
1001 fi
1002
1003 dnl For windows, check for the need of RPCRT for UUID function support
1004 if test $have_uuid = no ; then
1005         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
1006         save_LIBS="$LIBS"
1007         LIBS="$LIBS -lrpcrt4"
1008         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1009                 int __stdcall UuidCreate(void *);
1010                 int __stdcall UuidToStringA(void *,void **);
1011                 ]], [[
1012                 UuidCreate(0);
1013                 UuidToStringA(0,0);
1014                 ]])],[need_rpcrt=yes],[need_rpcrt=no])
1015         if test $need_rpcrt = yes; then
1016                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
1017         fi
1018         LIBS="$save_LIBS"
1019         AC_MSG_RESULT($need_rpcrt)
1020 fi
1021
1022 dnl ----------------------------------------------------------------
1023 dnl Check for resolver routines
1024 OL_RESOLVER_LINK
1025
1026 ol_link_dnssrv=no
1027 if test "$ol_cv_lib_resolver" != no ; then
1028         AC_DEFINE(HAVE_RES_QUERY,1,
1029                 [define if you have res_query()])
1030
1031         if test "$ol_enable_dnssrv" != no ; then
1032                 ol_link_dnssrv=yes
1033         fi
1034
1035         if test "$ol_cv_lib_resolver" != yes ; then
1036                 LIBS="$ol_cv_lib_resolver $LIBS"
1037         fi
1038 fi
1039
1040 if test "$ol_enable_dnssrv" = yes || test "$ol_enable_dnssrv" = mod ; then
1041         if test "$ol_link_dnssrv" = no ; then
1042                 AC_MSG_ERROR([DNSSRV requires res_query()])
1043         fi
1044 else
1045         ol_enable_dnssrv=no
1046 fi
1047
1048 AC_CHECK_FUNCS( hstrerror )
1049
1050 dnl ----------------------------------------------------------------
1051 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1052 dnl PF_LOCAL may use getaddrinfo in available
1053 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1054
1055 ol_link_ipv6=no
1056 if test $ac_cv_func_getaddrinfo = no || test $ac_cv_func_inet_ntop = no ; then
1057         if test $ol_enable_ipv6 = yes ; then
1058                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1059         fi
1060 elif test $ol_enable_ipv6 != no ; then
1061         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1062                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1063 #                       include <netinet/in.h>
1064 #                       ifdef INET6_ADDRSTRLEN
1065                                 __has_inet6_addrstrlen__;
1066 #                       endif
1067                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1068
1069
1070         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1071                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1072 #include <sys/types.h>
1073 #include <sys/socket.h>
1074 ]], [[
1075                         struct sockaddr_storage ss;
1076 ]])],[ol_cv_struct_sockaddr_storage=yes],[ol_cv_struct_sockaddr_storage=no])])
1077
1078         if test $ol_cv_inet6_addrstrlen = yes &&
1079            test $ol_cv_struct_sockaddr_storage = yes ; then
1080                 ol_link_ipv6=yes
1081         elif test $ol_enable_ipv6 = yes &&
1082              test $ol_cv_inet6_addrstrlen = no ; then
1083                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1084         elif test $ol_enable_ipv6 = yes &&
1085              test $ol_cv_struct_sockaddr_storage = no ; then
1086                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1087         fi
1088 fi
1089
1090 if test $ol_enable_local != no ; then
1091         AC_CHECK_HEADERS( sys/un.h )
1092
1093         if test $ol_enable_local = auto ; then
1094                 ol_enable_local=$ac_cv_header_sys_un_h
1095         elif test $ac_cv_header_sys_un_h = no ; then
1096                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1097         fi
1098 fi
1099
1100 dnl ----------------------------------------------------------------
1101 dnl TLS/SSL
1102
1103 if test $ol_with_tls = yes ; then
1104         ol_with_tls=auto
1105 fi
1106
1107 ol_link_tls=no
1108 if test $ol_with_tls = openssl || test $ol_with_tls = auto ; then
1109         AC_CHECK_HEADERS(openssl/ssl.h)
1110
1111         if test $ac_cv_header_openssl_ssl_h = yes ; then
1112                 AC_CHECK_LIB(ssl, SSL_library_init,
1113                         [have_openssl=yes
1114                         need_rsaref=no], [have_openssl=no],
1115                         [-lcrypto])
1116
1117                 if test $have_openssl = no ; then
1118                         AC_CHECK_LIB(ssl, ssl3_accept,
1119                                 [have_openssl=yes
1120                                 need_rsaref=yes], [have_openssl=no],
1121                                 [-lcrypto -lRSAglue -lrsaref])
1122                 fi
1123
1124                 if test $have_openssl = yes ; then
1125                         ol_with_tls=openssl
1126                         ol_link_tls=yes
1127
1128                         AC_DEFINE(HAVE_OPENSSL, 1,
1129                                 [define if you have OpenSSL])
1130
1131                         if test $need_rsaref = yes; then
1132                                 AC_DEFINE(HAVE_RSAREF, 1,
1133                                         [define if OpenSSL needs RSAref])
1134
1135                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1136                         else
1137                                 TLS_LIBS="-lssl -lcrypto"
1138                         fi
1139
1140                         OL_SSL_COMPAT
1141                         if test $ol_cv_ssl_crl_compat = yes ; then
1142                                 AC_DEFINE(HAVE_OPENSSL_CRL, 1,
1143                                         [define if you have OpenSSL with CRL checking capability])
1144                         fi
1145                 fi
1146         fi
1147 fi
1148
1149 WITH_TLS=no
1150 if test $ol_link_tls = yes ; then
1151         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1152         WITH_TLS=yes
1153 elif test $ol_with_tls = auto ; then
1154         AC_MSG_WARN([Could not locate TLS/SSL package])
1155         AC_MSG_WARN([TLS data protection not supported!])
1156 elif test $ol_with_tls != no ; then
1157         AC_MSG_ERROR([Could not locate TLS/SSL package])
1158 else
1159         AC_MSG_WARN([TLS data protection not supported!])
1160 fi
1161
1162 dnl ----------------------------------------------------------------
1163 dnl LAN Manger password checking requires DES from OpenSSL
1164 if test $ol_enable_lmpasswd != no; then
1165         if test $ol_link_tls != yes ; then
1166                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
1167         fi
1168
1169         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1170 fi
1171
1172 dnl ----------------------------------------------------------------
1173 dnl Threads?
1174 ol_link_threads=no
1175
1176 case $ol_with_threads in auto | yes | nt)
1177
1178         OL_NT_THREADS
1179
1180         if test "$ol_cv_nt_threads" = yes ; then
1181                 ol_link_threads=nt
1182                 ol_with_threads=found
1183                 ol_with_yielding_select=yes
1184
1185                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1186                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1187         fi
1188
1189         if test $ol_with_threads = nt ; then
1190                 AC_MSG_ERROR([could not locate NT Threads])
1191         fi
1192         ;;
1193 esac
1194
1195 case $ol_with_threads in auto | yes | posix)
1196
1197         AC_CHECK_HEADERS(pthread.h)
1198
1199         if test $ac_cv_header_pthread_h = yes ; then
1200                 OL_POSIX_THREAD_VERSION
1201
1202                 if test $ol_cv_pthread_version != 0 ; then
1203                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1204                                 [define to pthreads API spec revision])
1205                 else
1206                         AC_MSG_ERROR([unknown pthread version])
1207                 fi
1208
1209                 # consider threads found
1210                 ol_with_threads=found
1211
1212                 OL_HEADER_LINUX_THREADS
1213                 OL_HEADER_GNU_PTH_PTHREAD_H
1214
1215                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1216                         AC_CHECK_HEADERS(sched.h)
1217                 fi
1218
1219                 dnl Now the hard part, how to link?
1220                 dnl
1221                 dnl currently supported checks:
1222                 dnl
1223                 dnl Check for no flags
1224                 dnl     pthread_create() in $LIBS
1225                 dnl
1226                 dnl Check special pthread (final) flags
1227                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1228                 dnl     pthread_create() with -kthread (FreeBSD)
1229                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1230                 dnl     pthread_create() with -pthreads (?)
1231                 dnl     pthread_create() with -mthreads (AIX)
1232                 dnl     pthread_create() with -thread (?)
1233                 dnl
1234                 dnl Check pthread (final) libraries
1235                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1236                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1237                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1238                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1239                 dnl     pthread_create() in -lpthread (many)
1240                 dnl     pthread_create() in -lc_r (FreeBSD)
1241                 dnl
1242                 dnl Check pthread (draft4) flags (depreciated)
1243                 dnl     pthread_create() with -threads (OSF/1)
1244                 dnl
1245                 dnl Check pthread (draft4) libraries (depreciated)
1246                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1247                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1248                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1249                 dnl     pthread_create() in -lpthreads (many)
1250                 dnl
1251
1252                 dnl pthread_create in $LIBS
1253                 AC_CACHE_CHECK([for pthread_create in default libraries],
1254                         ol_cv_pthread_create,[
1255                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1256                                 [ol_cv_pthread_create=yes],
1257                                 [ol_cv_pthread_create=no],
1258                                 [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1259                                         [ol_cv_pthread_create=yes],
1260                                         [ol_cv_pthread_create=no])])])
1261
1262                 if test $ol_cv_pthread_create != no ; then
1263                         ol_link_threads=posix
1264                         ol_link_pthreads=""
1265                 fi
1266
1267 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1268                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1269                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1270                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1271                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1272                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1273
1274                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1275                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1276                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1277                         [ol_cv_pthread_lpthread_lmach_lexc])
1278 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1279 dnl                     [ol_cv_pthread_lpthread_lexc])
1280
1281                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1282                         [ol_cv_pthread_lib_lpthread_woff])
1283
1284                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1285                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1286
1287                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1288
1289                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1290                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1291                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1292                         [ol_cv_pthread_lpthreads_lmach_lexc])
1293                 OL_PTHREAD_TRY([-lpthreads -lexc],
1294                         [ol_cv_pthread_lpthreads_lexc])
1295
1296                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1297
1298                 if test $ol_link_threads != no ; then
1299                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1300
1301                         dnl save flags
1302                         save_CPPFLAGS="$CPPFLAGS"
1303                         save_LIBS="$LIBS"
1304                         LIBS="$LTHREAD_LIBS $LIBS"
1305
1306                         dnl All POSIX Thread (final) implementations should have
1307                         dnl sched_yield instead of pthread yield.
1308                         dnl check for both, and thr_yield for Solaris
1309                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1310
1311                         if test $ac_cv_func_sched_yield = no &&
1312                            test $ac_cv_func_pthread_yield = no &&
1313                            test $ac_cv_func_thr_yield = no ; then
1314                                 dnl Digital UNIX has sched_yield() in -lrt
1315                                 AC_CHECK_LIB(rt, sched_yield,
1316                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1317                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1318                                                 [Define if you have the sched_yield function.])
1319                                         ac_cv_func_sched_yield=yes],
1320                                         [ac_cv_func_sched_yield=no])
1321                         fi
1322                         if test $ac_cv_func_sched_yield = no &&
1323                            test $ac_cv_func_pthread_yield = no &&
1324                            test "$ac_cv_func_thr_yield" = no ; then
1325                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1326                         fi
1327
1328                         dnl Check functions for compatibility
1329                         AC_CHECK_FUNCS(pthread_kill)
1330
1331                         dnl Check for pthread_rwlock_destroy with <pthread.h>
1332                         dnl as pthread_rwlock_t may not be defined.
1333                         AC_CACHE_CHECK([for pthread_rwlock_destroy with <pthread.h>],
1334                                 [ol_cv_func_pthread_rwlock_destroy], [
1335                                 dnl save the flags
1336                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1337 #include <pthread.h>
1338 pthread_rwlock_t rwlock;
1339 ]], [[pthread_rwlock_destroy(&rwlock);]])],[ol_cv_func_pthread_rwlock_destroy=yes],[ol_cv_func_pthread_rwlock_destroy=no])
1340                         ])
1341                         if test $ol_cv_func_pthread_rwlock_destroy = yes ; then
1342                                 AC_DEFINE(HAVE_PTHREAD_RWLOCK_DESTROY,1,
1343                                         [define if you have pthread_rwlock_destroy function])
1344                         fi
1345
1346                         dnl Check for pthread_detach with <pthread.h> inclusion
1347                         dnl as it's symbol may have been mangled.
1348                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1349                                 [ol_cv_func_pthread_detach], [
1350                                 dnl save the flags
1351                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1352 #include <pthread.h>
1353 #ifndef NULL
1354 #define NULL (void*)0
1355 #endif
1356 ]], [[pthread_detach(NULL);]])],[ol_cv_func_pthread_detach=yes],[ol_cv_func_pthread_detach=no])
1357                         ])
1358
1359                         if test $ol_cv_func_pthread_detach = no ; then
1360                                 AC_MSG_ERROR([could not locate pthread_detach()])
1361                         fi
1362
1363                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1364                                 [define if you have pthread_detach function])
1365
1366                         dnl Check for setconcurreny functions
1367                         AC_CHECK_FUNCS( \
1368                                 pthread_setconcurrency \
1369                                 pthread_getconcurrency \
1370                                 thr_setconcurrency \
1371                                 thr_getconcurrency \
1372                         )
1373
1374                         OL_SYS_LINUX_THREADS
1375                         OL_LINUX_THREADS
1376
1377                         if test $ol_cv_linux_threads = error; then
1378                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1379                         fi
1380
1381                         AC_CACHE_CHECK([if pthread_create() works],
1382                                 ol_cv_pthread_create_works,[
1383                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1384                                 [ol_cv_pthread_create_works=yes],
1385                                 [ol_cv_pthread_create_works=no],
1386                                 [dnl assume yes
1387                                 ol_cv_pthread_create_works=yes])])
1388
1389                         if test $ol_cv_pthread_create_works = no ; then
1390                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1391                         fi
1392
1393                         ol_replace_broken_yield=no
1394 dnl                     case "$target" in
1395 dnl                     *-*-linux*)
1396 dnl                             AC_CHECK_FUNCS(nanosleep)
1397 dnl                             ol_replace_broken_yield=yes
1398 dnl                     ;;
1399 dnl                     esac
1400
1401                         if test $ol_replace_broken_yield = yes ; then
1402                                 AC_DEFINE([REPLACE_BROKEN_YIELD],1,
1403                                         [define if sched_yield yields the entire process])
1404                         fi
1405
1406                         dnl Check if select causes an yield
1407                         if test $ol_with_yielding_select = auto ; then
1408                                 AC_CACHE_CHECK([if select yields when using pthreads],
1409                                         ol_cv_pthread_select_yields,[
1410                                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1411 #include <sys/types.h>
1412 #include <sys/time.h>
1413 #include <unistd.h>
1414 #include <pthread.h>
1415 #ifndef NULL
1416 #define NULL (void*) 0
1417 #endif
1418
1419 static int fildes[2];
1420
1421 static void *task(p)
1422         void *p;
1423 {
1424         int i;
1425         struct timeval tv;
1426
1427         fd_set rfds;
1428
1429         tv.tv_sec=10;
1430         tv.tv_usec=0;
1431
1432         FD_ZERO(&rfds);
1433         FD_SET(fildes[0], &rfds);
1434
1435         /* we're not interested in any fds */
1436         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1437
1438         if(i < 0) {
1439                 perror("select");
1440                 exit(10);
1441         }
1442
1443         exit(0); /* if we exit here, the select blocked the whole process */
1444 }
1445
1446 int main(argc, argv)
1447         int argc;
1448         char **argv;
1449 {
1450         pthread_t t;
1451
1452         /* create a pipe to select */
1453         if(pipe(&fildes[0])) {
1454                 perror("select");
1455                 exit(1);
1456         }
1457
1458 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1459         (void) pthread_setconcurrency(2);
1460 #else
1461 #ifdef HAVE_THR_SETCONCURRENCY
1462         /* Set Solaris LWP concurrency to 2 */
1463         thr_setconcurrency(2);
1464 #endif
1465 #endif
1466
1467 #if HAVE_PTHREADS < 6
1468         pthread_create(&t, pthread_attr_default, task, NULL);
1469 #else
1470         pthread_create(&t, NULL, task, NULL);
1471 #endif
1472
1473         /* make sure task runs first */
1474 #if HAVE_THR_YIELD
1475         thr_yield();
1476 #elif defined( HAVE_SCHED_YIELD )
1477         sched_yield();
1478 #elif defined( HAVE_PTHREAD_YIELD )
1479         pthread_yield();
1480 #endif
1481
1482         exit(2);
1483 }]])],[ol_cv_pthread_select_yields=no],[ol_cv_pthread_select_yields=yes],[ol_cv_pthread_select_yields=cross])])
1484
1485                                 if test $ol_cv_pthread_select_yields = cross ; then
1486                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1487                                 fi
1488
1489                                 if test $ol_cv_pthread_select_yields = yes ; then
1490                                         ol_with_yielding_select=yes
1491                                 fi
1492                         fi
1493
1494                         dnl restore flags
1495                         CPPFLAGS="$save_CPPFLAGS"
1496                         LIBS="$save_LIBS"
1497                 else
1498                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1499                 fi
1500         fi
1501
1502         if test $ol_with_threads = posix ; then
1503                 AC_MSG_ERROR([could not locate POSIX Threads])
1504         fi
1505         ;;
1506 esac
1507
1508 case $ol_with_threads in auto | yes | mach)
1509
1510         dnl check for Mach CThreads
1511         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1512         if test $ac_cv_header_mach_cthreads_h = yes ; then
1513                 ol_with_threads=found
1514
1515                 dnl check for cthreads support in current $LIBS
1516                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1517
1518                 if test $ol_link_threads = no ; then
1519                         dnl try -all_load
1520                         dnl this test needs work
1521                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1522                                 [ol_cv_cthread_all_load], [
1523                                 dnl save the flags
1524                                 save_LIBS="$LIBS"
1525                                 LIBS="-all_load $LIBS"
1526                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <mach/cthreads.h>]], [[
1527                                         cthread_fork((void *)0, (void *)0);
1528                                         ]])],[ol_cv_cthread_all_load=yes],[ol_cv_cthread_all_load=no])
1529                                 dnl restore the LIBS
1530                                 LIBS="$save_LIBS"
1531                         ])
1532
1533                         if test $ol_cv_cthread_all_load = yes ; then
1534                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1535                                 ol_link_threads=mach
1536                                 ol_with_threads=found
1537                         fi
1538                 fi
1539
1540         elif test $ac_cv_header_cthreads_h = yes ; then
1541                 dnl Hurd variant of Mach Cthreads
1542                 dnl uses <cthreads.h> and -lthreads
1543
1544                 ol_with_threads=found
1545
1546                 dnl save the flags
1547                 save_LIBS="$LIBS"
1548                 LIBS="$LIBS -lthreads"
1549                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1550                 LIBS="$save_LIBS"
1551
1552                 if test $ol_link_threads = yes ; then
1553                         LTHREAD_LIBS="-lthreads"
1554                         ol_link_threads=mach
1555                         ol_with_threads=found
1556                 else
1557                         AC_MSG_ERROR([could not link with Mach CThreads])
1558                 fi
1559
1560         elif test $ol_with_threads = mach ; then
1561                 AC_MSG_ERROR([could not locate Mach CThreads])
1562         fi
1563
1564         if test $ol_link_threads = mach ; then
1565                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1566                         [define if you have Mach Cthreads])
1567         elif test $ol_with_threads = found ; then
1568                 AC_MSG_ERROR([could not link with Mach CThreads])
1569         fi
1570         ;;
1571 esac
1572
1573 case $ol_with_threads in auto | yes | pth)
1574
1575         AC_CHECK_HEADERS(pth.h)
1576
1577         if test $ac_cv_header_pth_h = yes ; then
1578                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1579
1580                 if test $have_pth = yes ; then
1581                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1582                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1583                         ol_link_threads=pth
1584                         ol_with_threads=found
1585
1586                         if test $ol_with_yielding_select = auto ; then
1587                                 ol_with_yielding_select=yes
1588                         fi
1589                 fi
1590         fi
1591         ;;
1592 esac
1593
1594 case $ol_with_threads in auto | yes | lwp)
1595
1596         dnl check for SunOS5 LWP
1597         AC_CHECK_HEADERS(thread.h synch.h)
1598         if test $ac_cv_header_thread_h = yes &&
1599            test $ac_cv_header_synch_h = yes ; then
1600                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1601
1602                 if test $have_thr = yes ; then
1603                         AC_DEFINE(HAVE_THR,1,
1604                                 [if you have Solaris LWP (thr) package])
1605                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1606                         ol_link_threads=thr
1607
1608                         if test $ol_with_yielding_select = auto ; then
1609                                 ol_with_yielding_select=yes
1610                         fi
1611
1612                         dnl Check for setconcurreny functions
1613                         AC_CHECK_FUNCS( \
1614                                 thr_setconcurrency \
1615                                 thr_getconcurrency \
1616                         )
1617                 fi
1618         fi
1619
1620         dnl check for SunOS4 LWP
1621         AC_CHECK_HEADERS(lwp/lwp.h)
1622         if test $ac_cv_header_lwp_lwp_h = yes ; then
1623                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1624
1625                 if test $have_lwp = yes ; then
1626                         AC_DEFINE(HAVE_LWP,1,
1627                                 [if you have SunOS LWP package])
1628                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1629                         ol_link_threads=lwp
1630
1631                         if test $ol_with_yielding_select = auto ; then
1632                                 ol_with_yielding_select=no
1633                         fi
1634                 fi
1635         fi
1636         ;;
1637 esac
1638
1639 if test $ol_with_yielding_select = yes ; then
1640         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1641                 [define if select implicitly yields])
1642 fi
1643
1644 if test $ol_with_threads = manual ; then
1645         dnl User thinks he can manually configure threads.
1646         ol_link_threads=yes
1647
1648         AC_MSG_WARN([thread defines and link options must be set manually])
1649
1650         AC_CHECK_HEADERS(pthread.h sched.h)
1651         AC_CHECK_FUNCS(sched_yield pthread_yield)
1652         OL_HEADER_LINUX_THREADS
1653
1654         AC_CHECK_HEADERS(mach/cthreads.h)
1655         AC_CHECK_HEADERS(lwp/lwp.h)
1656         AC_CHECK_HEADERS(thread.h synch.h)
1657 fi
1658
1659 if test $ol_link_threads != no && test $ol_link_threads != nt ; then
1660         dnl needed to get reentrant/threadsafe versions
1661         dnl
1662         AC_DEFINE(REENTRANT,1)
1663         AC_DEFINE(_REENTRANT,1)
1664         AC_DEFINE(THREAD_SAFE,1)
1665         AC_DEFINE(_THREAD_SAFE,1)
1666         AC_DEFINE(THREADSAFE,1)
1667         AC_DEFINE(_THREADSAFE,1)
1668         AC_DEFINE(_SGI_MP_SOURCE,1)
1669
1670         dnl The errno declaration may dependent upon _REENTRANT.
1671         dnl If it does, we must link with thread support.
1672         AC_CACHE_CHECK([for thread specific errno],
1673                 [ol_cv_errno_thread_specific], [
1674                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[errno = 0;]])],[ol_cv_errno_thread_specific=yes],[ol_cv_errno_thread_specific=no])
1675         ])
1676
1677         dnl The h_errno declaration may dependent upon _REENTRANT.
1678         dnl If it does, we must link with thread support.
1679         AC_CACHE_CHECK([for thread specific h_errno],
1680                 [ol_cv_h_errno_thread_specific], [
1681                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[h_errno = 0;]])],[ol_cv_h_errno_thread_specific=yes],[ol_cv_h_errno_thread_specific=no])
1682         ])
1683
1684         if test $ol_cv_errno_thread_specific != yes ||
1685            test $ol_cv_h_errno_thread_specific != yes ; then
1686                 LIBS="$LTHREAD_LIBS $LIBS"
1687                 LTHREAD_LIBS=""
1688         fi
1689
1690 dnl When in thread environment, use
1691 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1692 dnl                     func_r(...);
1693 dnl             #else
1694 dnl             #       if defined( HAVE_THREADS )
1695 dnl                             /* lock */
1696 dnl             #       endif
1697 dnl                             func(...);
1698 dnl             #       if defined( HAVE_THREADS )
1699 dnl                             /* unlock */
1700 dnl             #       endif
1701 dnl             #endif
1702 dnl
1703 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1704 dnl             _POSIX_REENTRANT_FUNCTIONS
1705 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1706 dnl             _POSIX_THREADSAFE_FUNCTIONS
1707 dnl
1708 dnl             and is currently defined in <ldap_pvt_thread.h>
1709 dnl
1710 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1711 dnl
1712 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1713 dnl LDAP_R_COMPILE is defined.  ie:
1714 dnl             #ifdef LDAP_R_COMPILE
1715 dnl             #       include <ldap_pvt_thread.h>
1716 dnl             #endif
1717 dnl
1718 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1719 dnl specifically for compiling the threadsafe version of
1720 dnl     the ldap library (-lldap_r).
1721 dnl
1722 dnl     dnl check for reentrant/threadsafe functions
1723 dnl     dnl
1724 dnl     dnl note: these should only be used when linking
1725 dnl     dnl             with $LTHREAD_LIBS
1726 dnl     dnl
1727 dnl     save_CPPFLAGS="$CPPFLAGS"
1728 dnl     save_LIBS="$LIBS"
1729 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1730 dnl     AC_CHECK_FUNCS( \
1731 dnl             gmtime_r \
1732 dnl             gethostbyaddr_r gethostbyname_r \
1733 dnl             feof_unlocked unlocked_feof \
1734 dnl             putc_unlocked unlocked_putc \
1735 dnl             flockfile ftrylockfile \
1736 dnl     )
1737 dnl     CPPFLAGS="$save_CPPFLAGS"
1738 dnl     LIBS="$save_LIBS"
1739 fi
1740
1741 if test $ol_link_threads = no ; then
1742         if test $ol_with_threads = yes ; then
1743                 AC_MSG_ERROR([no suitable thread support])
1744         fi
1745
1746         if test $ol_with_threads = auto ; then
1747                 AC_MSG_WARN([no suitable thread support, disabling threads])
1748                 ol_with_threads=no
1749         fi
1750
1751         AC_DEFINE(NO_THREADS,1,
1752                 [define if you have (or want) no threads])
1753         LTHREAD_LIBS=""
1754         BUILD_THREAD=no
1755 else
1756         BUILD_THREAD=yes
1757 fi
1758
1759 if test $ol_link_threads != no ; then
1760         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1,
1761                 [define to 1 if library is thread safe])
1762 fi
1763
1764 dnl ----------------------------------------------------------------
1765 dnl Tests for reentrant functions necessary to build -lldap_r
1766 AC_CHECK_FUNCS(         \
1767         ctime_r                 \
1768         gethostbyname_r gethostbyaddr_r \
1769 )
1770
1771 if test "$ac_cv_func_ctime_r" = no ; then
1772         ol_cv_func_ctime_r_nargs=0
1773 else
1774         OL_FUNC_CTIME_R_NARGS
1775 dnl     OL_FUNC_CTIME_R_TYPE
1776 fi
1777
1778 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1779         OL_FUNC_GETHOSTBYNAME_R_NARGS
1780 else
1781         ol_cv_func_gethostbyname_r_nargs=0
1782 fi
1783
1784 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1785         OL_FUNC_GETHOSTBYADDR_R_NARGS
1786 else
1787         ol_cv_func_gethostbyaddr_r_nargs=0
1788 fi
1789
1790 dnl ----------------------------------------------------------------
1791 ol_link_bdb=no
1792
1793 if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
1794         OL_BERKELEY_DB
1795
1796         if test $ol_cv_berkeley_db = no ; then
1797                 AC_MSG_ERROR(BDB/HDB: BerkeleyDB not available)
1798         fi
1799
1800         AC_DEFINE(HAVE_BERKELEY_DB,1,
1801                 [define this if Berkeley DB is available])
1802
1803         dnl $ol_cv_lib_db should be yes or -ldb
1804         dnl (it could be no, but that would be an error
1805         if test $ol_cv_lib_db != yes ; then
1806                 BDB_LIBS="$BDB_LIBS $ol_cv_lib_db"
1807         fi
1808
1809         OL_BDB_COMPAT
1810
1811         if test $ol_cv_bdb_compat != yes ; then
1812                 AC_MSG_ERROR([BDB/HDB: BerkeleyDB version incompatible])
1813         fi
1814
1815         SLAPD_LIBS="$SLAPD_LIBS \$(BDB_LIBS)"
1816
1817         ol_link_bdb=yes
1818 fi
1819
1820 dnl ----------------------------------------------------------------
1821
1822 if test $ol_enable_dynamic = yes && test $enable_shared = yes ; then
1823         BUILD_LIBS_DYNAMIC=shared
1824         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
1825         LTSTATIC=""
1826 else
1827         BUILD_LIBS_DYNAMIC=static
1828         LTSTATIC="-static"
1829 fi
1830 AC_SUBST(LTSTATIC)dnl
1831
1832 dnl ----------------------------------------------------------------
1833 if test $ol_enable_wrappers != no ; then
1834         AC_CHECK_HEADERS(tcpd.h,[
1835                 AC_MSG_CHECKING([for TCP wrappers library])
1836                 save_LIBS="$LIBS"
1837                 LIBS="$LIBS -lwrap"
1838                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1839 #include <tcpd.h>
1840 int allow_severity = 0;
1841 int deny_severity  = 0;
1842
1843 struct request_info *req;
1844                 ]], [[
1845 hosts_access(req)
1846                 ]])],[AC_MSG_RESULT([-lwrap])
1847                 have_wrappers=yes
1848                 LIBS="$save_LIBS"],[
1849                 dnl try with -lnsl
1850                 LIBS="$LIBS -lnsl"
1851                 AC_TRY_LINK([
1852 #include <tcpd.h>
1853 int allow_severity = 0;
1854 int deny_severity  = 0;
1855
1856 struct request_info *req;
1857                 ],[
1858 hosts_access(req)
1859                 ],[AC_MSG_RESULT([-lwrap -lnsl])
1860                 have_wrappers=yes
1861                 LIBS="$save_LIBS -lnsl"],[
1862                 AC_MSG_RESULT(no)
1863                 have_wrappers=no
1864                 LIBS=$save_LIBS])])],[have_wrappers=no])
1865
1866         if test $have_wrappers = yes ; then
1867                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1868                 WRAP_LIBS="-lwrap"
1869         elif test $ol_enable_wrappers = yes ; then
1870                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options or disable])
1871         else
1872                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
1873                 WRAP_LIBS=""
1874         fi
1875 fi
1876
1877 dnl ----------------------------------------------------------------
1878 if test $ol_enable_syslog != no ; then
1879         AC_CHECK_FUNC(openlog)
1880         if test $ac_cv_func_openlog = no && test $ol_enable_syslog = yes; then
1881                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1882         fi
1883         ol_enable_syslog=$ac_cv_func_openlog
1884 fi
1885
1886 dnl ----------------------------------------------------------------
1887 dnl SQL
1888 ol_link_sql=no
1889 if test $ol_enable_sql != no ; then
1890         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
1891                 AC_MSG_ERROR([could not locate SQL headers])
1892         ])
1893
1894         sql_LIBS="$LIBS"
1895         LIBS="$LTHREAD_LIBS"
1896
1897         if test $ol_with_odbc = auto ; then
1898                 ol_with_odbc="iodbc unixodbc"
1899         fi
1900
1901         for odbc in $ol_with_odbc ; do
1902                 if test $ol_link_sql = no ; then
1903                         case $odbc in
1904                         iodbc)
1905                                 AC_CHECK_LIB(iodbc, SQLDriverConnect, [have_iodbc=yes], [have_iodbc=no])
1906                                 if test $have_iodbc = yes ; then
1907                                         ol_link_sql="-liodbc"
1908                                 fi
1909                                 ;;
1910
1911                         unixodbc)
1912                                 AC_CHECK_LIB(odbc, SQLDriverConnect, [have_odbc=yes], [have_odbc=no])
1913                                 if test $have_odbc = yes ; then
1914                                         ol_link_sql="-lodbc"
1915                                 fi
1916                                 ;;
1917
1918                         *)
1919                                 AC_MSG_ERROR([unknown ODBC library])
1920                                 ;;
1921                         esac
1922                 fi
1923         done
1924
1925         LIBS="$sql_LIBS"
1926
1927         if test $ol_link_sql != no ; then
1928                 SLAPD_SQL_LIBS="$ol_link_sql"
1929
1930         elif test $ol_enable_sql != auto ; then
1931                 AC_MSG_ERROR([could not locate suitable ODBC library])
1932         fi
1933 fi
1934
1935 dnl ----------------------------------------------------------------
1936 dnl International Components for Unicode
1937 OL_ICU
1938 if test "$ol_icu" = no ; then
1939         AC_MSG_WARN([ICU not available])
1940 else
1941         ICU_LIBS="$ol_icu"
1942 fi
1943 dnl ----------------------------------------------------------------
1944 dnl
1945 dnl Check for Cyrus SASL
1946 dnl
1947 WITH_SASL=no
1948 ol_link_sasl=no
1949 ol_link_spasswd=no
1950 if test $ol_with_cyrus_sasl != no ; then
1951         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
1952
1953         if test $ac_cv_header_sasl_sasl_h = yes ||
1954            test $ac_cv_header_sasl_h = yes; then
1955                 AC_CHECK_LIB(sasl2, sasl_client_init,
1956                         [ol_link_sasl="-lsasl2"],
1957                         [AC_CHECK_LIB(sasl, sasl_client_init,
1958                                 [ol_link_sasl="-lsasl"])])
1959         fi
1960
1961         if test $ol_link_sasl = no ; then
1962                 if test $ol_with_cyrus_sasl != auto ; then
1963                         AC_MSG_ERROR([Could not locate Cyrus SASL])
1964                 else
1965                         AC_MSG_WARN([Could not locate Cyrus SASL])
1966                         AC_MSG_WARN([SASL authentication not supported!])
1967                         if test $ol_link_tls = no ; then
1968                                 AC_MSG_WARN([Strong authentication not supported!])
1969                         fi
1970                 fi
1971         else
1972                 OL_SASL_COMPAT
1973                 if test $ol_cv_sasl_compat = no ; then
1974                         ol_link_sasl=no
1975                         AC_MSG_ERROR([Cyrus SASL library located but is incompatible])
1976                 fi
1977
1978                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1979                 SASL_LIBS="$ol_link_sasl"
1980                 if test $ol_enable_spasswd != no ; then
1981                         ol_link_spasswd=yes
1982                 fi
1983
1984                 ac_save_LIBS="$LIBS"
1985                 LIBS="$LIBS $ol_link_sasl"
1986                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
1987                         [define if your SASL library has sasl_version()])])
1988                 LIBS="$ac_save_LIBS"
1989
1990                 WITH_SASL=yes
1991         fi
1992
1993 else
1994         AC_MSG_WARN([SASL authentication not supported!])
1995         if test $ol_link_tls = no ; then
1996                 AC_MSG_WARN([Strong authentication not supported!])
1997         fi
1998 fi
1999
2000 dnl ----------------------------------------------------------------
2001 dnl Check for entropy sources
2002 if test $cross_compiling != yes && test "$ac_cv_mingw32" != yes ; then
2003         dev=no
2004         if test -r /dev/urandom ; then
2005                 dev="/dev/urandom";
2006         elif test -r /idev/urandom ; then
2007                 dev="/idev/urandom";
2008         elif test -r /dev/srandom ; then
2009                 dev="/dev/srandom";
2010         elif test -r /dev/random ; then
2011                 dev="/dev/random";
2012         elif test -r /idev/random ; then
2013                 dev="/idev/random";
2014         fi
2015
2016         if test $dev != no ; then
2017                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2018         fi
2019 fi
2020
2021 dnl ----------------------------------------------------------------
2022 dnl
2023 dnl Check for fetch URL support
2024 dnl             should be extended to support other fetch URL APIs
2025 dnl
2026 ol_link_fetch=no
2027 if test $ol_with_fetch != no ; then
2028         OL_LIB_FETCH
2029
2030         if test $ol_cv_lib_fetch != no ; then
2031                 LUTIL_LIBS="$LUTIL_LIBS $ol_link_fetch"
2032                 ol_link_fetch=freebsd
2033
2034         elif test $ol_with_fetch != auto ; then
2035                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2036         fi
2037 fi
2038
2039 dnl ----------------------------------------------------------------
2040 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2041 if test $ol_enable_crypt != no ; then
2042         save_LIBS="$LIBS"
2043         LIBS="$TLS_LIBS $LIBS"
2044
2045         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2046                 LIBS="$save_LIBS"
2047                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2048                         have_crypt=yes], [have_crypt=no])])
2049
2050         LIBS="$save_LIBS"
2051
2052         if test $have_crypt = yes ; then
2053                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2054         else
2055                 AC_MSG_WARN([could not find crypt])
2056                 if test $ol_enable_crypt = yes ; then
2057                         AC_MSG_ERROR([could not find crypt, select appropriate options or disable])
2058                 fi
2059
2060                 AC_MSG_WARN([disabling crypt support])
2061                 ol_enable_crypt=no
2062         fi
2063 fi
2064
2065 dnl ----------------------------------------------------------------
2066 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2067 if test $ol_enable_proctitle != no ; then
2068         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2069                 AC_CHECK_LIB(util, setproctitle,
2070                         [have_setproctitle=yes
2071                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2072                         [have_setproctitle=no
2073                         AC_LIBOBJ(setproctitle)
2074                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2075
2076         if test $have_setproctitle = yes ; then
2077                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2078                         [define if setproctitle(3) is available])
2079         fi
2080 fi
2081
2082 dnl ----------------------------------------------------------------
2083 if test $ol_enable_slp != no ; then
2084         AC_CHECK_HEADERS( slp.h )
2085
2086         if test $ac_cv_header_slp_h = yes ; then
2087                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2088                 if test $have_slp = yes ; then
2089                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2090                         SLAPD_SLP_LIBS=-lslp
2091                 fi
2092
2093         elif test $ol_enable_slp = yes ; then
2094                 AC_MSG_ERROR([SLP not found])
2095         fi
2096 fi
2097
2098 dnl ----------------------------------------------------------------
2099 dnl Checks for typedefs, structures, and compiler characteristics.
2100
2101 AC_CHECK_TYPE(mode_t, int)
2102 AC_CHECK_TYPE(off_t, long)
2103 AC_CHECK_TYPE(pid_t, int)
2104 AC_CHECK_TYPE(ssize_t, [signed int])
2105 AC_CHECK_TYPE(caddr_t,  [char *])
2106 AC_CHECK_TYPE(size_t, unsigned)
2107
2108 AC_CHECK_TYPES([long long])
2109 AC_CHECK_TYPES([ptrdiff_t])
2110
2111 AC_CHECK_TYPE([socklen_t],,
2112         [AC_DEFINE_UNQUOTED([socklen_t], [int],
2113                 [Define to `int' if <sys/socket.h> does not define.])],
2114         [$ac_includes_default
2115 #ifdef HAVE_SYS_SOCKET_H
2116 #include <sys/socket.h>
2117 #endif
2118         ])
2119
2120 AC_TYPE_SIGNAL
2121
2122 AC_CHECK_TYPE([sig_atomic_t],,
2123         [AC_DEFINE_UNQUOTED([sig_atomic_t], [int],
2124                 [Define to `int' if <signal.h> does not define.])],
2125         [$ac_includes_default
2126 #include <signal.h>
2127         ])
2128
2129 AC_TYPE_UID_T
2130
2131 AC_HEADER_TIME
2132 AC_STRUCT_TM
2133 AC_CHECK_MEMBERS([struct stat.st_blksize])
2134 AC_CHECK_MEMBERS([struct passwd.pw_gecos],,,[$ac_includes_default
2135 #include <pwd.h>])
2136 AC_CHECK_MEMBERS([struct passwd.pw_passwd],,,[$ac_includes_default
2137 #include <pwd.h>])
2138
2139 OL_C_UPPER_LOWER
2140 AC_C_CONST
2141 OL_C_VOLATILE
2142
2143 if test $cross_compiling = yes ; then
2144         AC_MSG_WARN([Crossing compiling... all bets are off!])
2145         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2146 else
2147         AC_C_BIGENDIAN
2148 fi
2149
2150 AC_CHECK_SIZEOF(short)
2151 AC_CHECK_SIZEOF(int)
2152 AC_CHECK_SIZEOF(long)
2153 AC_CHECK_SIZEOF(long long)
2154 AC_CHECK_SIZEOF(wchar_t)
2155
2156 if test "$ac_cv_sizeof_int" -lt 4 ; then
2157         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2158
2159         AC_DEFINE(LBER_INT_T,long,[define to 32-bit or greater integer type])
2160 else
2161         AC_DEFINE(LBER_INT_T,int,[define to 32-bit or greater integer type])
2162 fi
2163
2164 AC_DEFINE(LBER_LEN_T,long,[define to large integer type])
2165 AC_DEFINE(LBER_SOCKET_T,int,[define to socket descriptor type])
2166 AC_DEFINE(LBER_TAG_T,long,[define to large integer type])
2167
2168 dnl ----------------------------------------------------------------
2169 dnl Check for multiple precision support
2170 if test $ol_with_mp = longlong || test $ol_with_mp = auto ; then
2171         if test $ac_cv_sizeof_long_long -gt 4 ; then
2172                 ol_with_mp=longlong
2173                 AC_DEFINE(USE_MP_LONG_LONG,1,[define to use 'long long' for MP])
2174         elif test $ol_with_mp = longlong ; then
2175                 AC_MSG_ERROR([long long unusable for multiple precision])
2176         fi
2177 fi
2178 if test $ol_with_mp = long || test $ol_with_mp = auto ; then
2179         if test $ac_cv_sizeof_long -gt 4 ; then
2180                 ol_with_mp=long
2181                 AC_DEFINE(USE_MP_LONG,1,[define to use 'long' for MP])
2182         elif test $ol_with_mp = long ; then
2183                 AC_MSG_ERROR([long unusable for multiple precision])
2184         fi
2185 fi
2186 if test $ol_with_mp = bignum || test $ol_with_mp = auto ; then
2187         AC_CHECK_HEADERS(openssl/bn.h)
2188         AC_CHECK_HEADERS(openssl/crypto.h)
2189         if test "$ac_cv_header_openssl_bn_h" = "yes" &&
2190                 test "$ac_cv_header_openssl_crypto_h" = "yes" &&
2191                 test "$ol_with_tls" = "found" ; then
2192                 ol_with_mp=bignum
2193                 AC_DEFINE(USE_MP_BIGNUM,1,[define to use OpenSSL BIGNUM for MP])
2194         elif test $ol_with_mp = bignum ; then
2195                 AC_MSG_ERROR([bignum not available])
2196         fi
2197 fi
2198 if test $ol_with_mp = gmp || test $ol_with_mp = auto ; then
2199         AC_CHECK_HEADERS(gmp.h)
2200         AC_CHECK_LIB(gmp, __gmpz_add_ui)
2201         if test $ac_cv_header_gmp_h = yes && test $ac_cv_lib_gmp___gmpz_add_ui = yes ; then
2202                 AC_DEFINE(USE_MP_GMP,1,[define to use GMP for MP])
2203                 ol_with_mp=gmp
2204         elif test $ol_with_mp = gmp ; then
2205                 AC_MSG_ERROR([gmp not available])
2206         fi
2207 fi
2208 if test $ol_with_mp = auto ; then
2209         ol_with_mp=no
2210 fi
2211
2212 dnl ----------------------------------------------------------------
2213 dnl Checks for library functions.
2214 AC_FUNC_MEMCMP
2215
2216 if test $ac_cv_func_memcmp_working = no ; then
2217         AC_DEFINE(NEED_MEMCMP_REPLACEMENT,1,
2218                 [define if memcmp is not 8-bit clean or is otherwise broken])
2219 fi
2220
2221 AC_FUNC_STRFTIME
2222
2223 OL_FUNC_INET_ATON
2224
2225 dnl Check for NT specific routines
2226 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2227
2228 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2229         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2230 ])
2231
2232 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2233         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2234 ])
2235
2236 AC_FUNC_VPRINTF
2237
2238 if test $ac_cv_func_vprintf = yes ; then
2239         dnl check for vsnprintf
2240         AC_CHECK_FUNCS(snprintf vsnprintf)
2241 fi
2242
2243 AC_CHECK_FUNCS(                 \
2244         bcopy                   \
2245         closesocket             \
2246         chroot                  \
2247         endgrent                \
2248         endpwent                \
2249         fcntl                   \
2250         flock                   \
2251         fstat                   \
2252         getdtablesize           \
2253         getgrgid                \
2254         gethostname             \
2255         getpass                 \
2256         getpassphrase           \
2257         getpwuid                \
2258         getpwnam                \
2259         getspnam                \
2260         gettimeofday            \
2261         initgroups              \
2262         inet_ntoa_b             \
2263         ioctl                   \
2264         lockf                   \
2265         memcpy                  \
2266         memmove                 \
2267         memrchr                 \
2268         mkstemp                 \
2269         mktemp                  \
2270         pipe                    \
2271         read                    \
2272         recv                    \
2273         recvfrom                \
2274         setpwfile               \
2275         setgid                  \
2276         setegid                 \
2277         setsid                  \
2278         setuid                  \
2279         seteuid                 \
2280         signal                  \
2281         strdup                  \
2282         strpbrk                 \
2283         strrchr                 \
2284         strsep                  \
2285         strstr                  \
2286         strtol                  \
2287         strtoul                 \
2288         strtoq                  \
2289         strtouq                 \
2290         strtoll                 \
2291         strspn                  \
2292         sysconf                 \
2293         waitpid                 \
2294         wait4                   \
2295         write                   \
2296         send                    \
2297         sendmsg                 \
2298         sendto                  \
2299 )
2300
2301 dnl We actually may need to replace more than this.
2302 AC_REPLACE_FUNCS(getopt getpeereid)
2303
2304 if test "$ac_cv_func_getopt" != yes; then
2305         LIBSRCS="$LIBSRCS getopt.c"
2306 fi
2307
2308 if test "$ac_cv_func_getpeereid" != yes; then
2309         AC_CHECK_FUNCS( getpeerucred )
2310         if test "$ac_cv_func_getpeerucred" != yes ; then
2311                 AC_CHECK_MEMBERS([struct msghdr.msg_accrightslen],,,
2312                         [$ac_includes_default
2313 #ifdef HAVE_SYS_SOCKET_H
2314 #include <sys/socket.h>
2315 #endif])
2316                 if test "$ac_cv_member_struct_msghdr_msg_accrightslen" != yes; then
2317                         AC_CHECK_MEMBERS([struct msghdr.msg_control],,,
2318                                 [$ac_includes_default
2319 #ifdef HAVE_SYS_SOCKET_H
2320 #include <sys/socket.h>
2321 #endif])
2322                 fi
2323         fi
2324         LIBSRCS="$LIBSRCS getpeereid.c"
2325 fi
2326
2327 if test "$ac_cv_func_snprintf" != yes ||
2328    test "$ac_cv_func_vsnprintf" != yes; then
2329         if test "$ac_cv_func_snprintf" != yes; then
2330                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2331         fi
2332         if test "$ac_cv_func_vsnprintf" != yes; then
2333                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2334         fi
2335 fi
2336
2337 dnl ----------------------------------------------------------------
2338 dnl Sort out defines
2339
2340 if test "$ol_enable_slapi" != no ; then
2341         dnl This check is done also if --enable-modules is used;
2342         dnl it is duplicated here, 'cause it'd be cached anyway
2343         AC_CHECK_HEADERS(ltdl.h)
2344
2345         if test $ac_cv_header_ltdl_h != yes ; then
2346                 AC_MSG_ERROR([could not locate <ltdl.h>])
2347         fi
2348         AC_CHECK_LIB(ltdl, lt_dlinit, [
2349                 SLAPI_LIBS=-lltdl
2350                 LIBSLAPI=libslapi.a
2351                 LIBSLAPITOOLS=../libslapi.a
2352                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
2353         ],[AC_MSG_ERROR([could not locate libtool -lltdl])])
2354
2355         AC_DEFINE(LDAP_SLAPI,1, [define this to add SLAPI code])
2356 fi
2357
2358 if test "$ol_enable_debug" != no ; then
2359         if test "$ol_enable_debug" = traditional; then
2360                 AC_DEFINE(OLD_DEBUG,1,
2361                         [define to use the original debug style])
2362         fi
2363         AC_DEFINE(LDAP_DEBUG,1,
2364                 [define this to add debugging code])
2365 fi
2366 if test "$ol_enable_syslog" = yes ; then
2367         AC_DEFINE(LDAP_SYSLOG,1,
2368                 [define this to add syslog code])
2369 fi
2370 if test "$ol_enable_proctitle" != no ; then
2371         AC_DEFINE(LDAP_PROCTITLE,1,
2372                 [define this for LDAP process title support])
2373 fi
2374 if test "$ol_enable_referrals" != no ; then
2375         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION,
2376                 [define to LDAP VENDOR VERSION])
2377 fi
2378 if test "$ol_enable_local" != no; then
2379         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2380 fi
2381 if test "$ol_link_ipv6" != no; then
2382         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2383 fi
2384 if test "$ol_enable_cleartext" != no ; then
2385         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2386 fi
2387 if test "$ol_enable_crypt" != no ; then
2388         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2389 fi
2390 if test "$ol_link_spasswd" != no ; then
2391         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2392 fi
2393 if test "$ol_enable_rlookups" != no ; then
2394         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2395 fi
2396 if test "$ol_enable_aci" != no ; then
2397         if test $ol_enable_dynacl = no ; then
2398                 ol_enable_dynacl=yes
2399                 AC_MSG_WARN([ACIs need dynacl])
2400         fi
2401         if test "$ol_enable_aci" = mod ; then
2402                 MFLAG=SLAPD_MOD_DYNAMIC
2403                 dnl remove this after moving servers/slapd/aci.c in contrib/slapd-modules/acl
2404                 AC_MSG_ERROR([ACI build as dynamic module not supported (yet)])
2405         else
2406                 MFLAG=SLAPD_MOD_STATIC
2407         fi
2408         WITH_ACI_ENABLED=$ol_enable_aci
2409         AC_DEFINE_UNQUOTED(SLAPD_ACI_ENABLED,$MFLAG,[define to support per-object ACIs])
2410 else
2411         WITH_ACI_ENABLED=no
2412 fi
2413 if test "$ol_enable_dynacl" != no ; then
2414         AC_DEFINE(SLAP_DYNACL,1,[define to support run-time loadable ACL])
2415 fi
2416
2417 if test "$ol_link_modules" != no ; then
2418         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2419         BUILD_SLAPD=yes
2420         SLAPD_MODULES_LDFLAGS="-dlopen self"
2421 fi
2422
2423 AC_DEFINE(SLAPD_MOD_STATIC,1,[statically linked module])
2424 AC_DEFINE(SLAPD_MOD_DYNAMIC,2,[dynamically linked module])
2425
2426 dnl back-monitor goes first (well, after back-config)
2427 if test "$ol_enable_monitor" != no ; then
2428         BUILD_SLAPD=yes
2429         BUILD_MONITOR=$ol_enable_monitor
2430         if test "$ol_enable_monitor" = mod ; then
2431                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2432                 MFLAG=SLAPD_MOD_DYNAMIC
2433         else
2434                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2435                 MFLAG=SLAPD_MOD_STATIC
2436         fi
2437         AC_DEFINE_UNQUOTED(SLAPD_MONITOR,$MFLAG,[define to support cn=Monitor backend])
2438 fi
2439
2440 if test "$ol_enable_bdb" != no ; then
2441         BUILD_SLAPD=yes
2442         BUILD_BDB=$ol_enable_bdb
2443         if test "$ol_enable_bdb" = mod ; then
2444                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2445                 MFLAG=SLAPD_MOD_DYNAMIC
2446         else
2447                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2448                 MFLAG=SLAPD_MOD_STATIC
2449         fi
2450         AC_DEFINE_UNQUOTED(SLAPD_BDB,$MFLAG,[define to support BDB backend])
2451 fi
2452
2453 if test "$ol_enable_dnssrv" != no ; then
2454         BUILD_SLAPD=yes
2455         BUILD_DNSSRV=$ol_enable_dnssrv
2456         if test "$ol_enable_dnssrv" = mod ; then
2457                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2458                 MFLAG=SLAPD_MOD_DYNAMIC
2459         else
2460                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2461                 MFLAG=SLAPD_MOD_STATIC
2462         fi
2463         AC_DEFINE_UNQUOTED(SLAPD_DNSSRV,$MFLAG,[define to support DNS SRV backend])
2464 fi
2465
2466 if test "$ol_enable_hdb" != no ; then
2467         BUILD_SLAPD=yes
2468         BUILD_HDB=$ol_enable_hdb
2469         if test "$ol_enable_hdb" = mod ; then
2470                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-hdb"
2471                 MFLAG=SLAPD_MOD_DYNAMIC
2472         else
2473                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-hdb"
2474                 MFLAG=SLAPD_MOD_STATIC
2475         fi
2476         AC_DEFINE_UNQUOTED(SLAPD_HDB,$MFLAG,[define to support HDB backend])
2477 fi
2478
2479 if test "$ol_enable_ldap" != no ; then
2480         BUILD_SLAPD=yes
2481         BUILD_LDAP=$ol_enable_ldap
2482         if test "$ol_enable_ldap" = mod ; then
2483                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2484                 MFLAG=SLAPD_MOD_DYNAMIC
2485         else
2486                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2487                 MFLAG=SLAPD_MOD_STATIC
2488         fi
2489         AC_DEFINE_UNQUOTED(SLAPD_LDAP,$MFLAG,[define to support LDAP backend])
2490 fi
2491
2492 if test "$ol_enable_meta" != no ; then
2493         BUILD_SLAPD=yes
2494         BUILD_META=$ol_enable_meta
2495         BUILD_REWRITE=yes
2496         if test "$ol_enable_meta" = mod ; then
2497                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2498                 MFLAG=SLAPD_MOD_DYNAMIC
2499         else
2500                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2501                 MFLAG=SLAPD_MOD_STATIC
2502         fi
2503         AC_DEFINE_UNQUOTED(SLAPD_META,$MFLAG,[define to support LDAP Metadirectory backend])
2504 fi
2505
2506 if test "$ol_enable_null" != no ; then
2507         BUILD_SLAPD=yes
2508         BUILD_NULL=$ol_enable_null
2509         if test "$ol_enable_null" = mod ; then
2510                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2511                 MFLAG=SLAPD_MOD_DYNAMIC
2512         else
2513                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2514                 MFLAG=SLAPD_MOD_STATIC
2515         fi
2516         AC_DEFINE_UNQUOTED(SLAPD_NULL,$MFLAG,[define to support NULL backend])
2517 fi
2518
2519 if test "$ol_enable_passwd" != no ; then
2520         BUILD_SLAPD=yes
2521         BUILD_PASSWD=$ol_enable_passwd
2522         if test "$ol_enable_passwd" = mod ; then
2523                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2524                 MFLAG=SLAPD_MOD_DYNAMIC
2525         else
2526                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2527                 MFLAG=SLAPD_MOD_STATIC
2528         fi
2529         AC_DEFINE_UNQUOTED(SLAPD_PASSWD,$MFLAG,[define to support PASSWD backend])
2530 fi
2531
2532 if test "$ol_link_perl" != no ; then
2533         BUILD_SLAPD=yes
2534         BUILD_PERL=$ol_enable_perl
2535         if test "$ol_enable_perl" = mod ; then
2536                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2537                 MFLAG=SLAPD_MOD_DYNAMIC
2538         else
2539                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2540                 MFLAG=SLAPD_MOD_STATIC
2541         fi
2542         AC_DEFINE_UNQUOTED(SLAPD_PERL,$MFLAG,[define to support PERL backend])
2543 fi
2544
2545 if test "$ol_enable_relay" != no ; then
2546         BUILD_SLAPD=yes
2547         BUILD_RELAY=$ol_enable_relay
2548         if test "$ol_enable_relay" = mod ; then
2549                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-relay"
2550                 MFLAG=SLAPD_MOD_DYNAMIC
2551         else
2552                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-relay"
2553                 MFLAG=SLAPD_MOD_STATIC
2554         fi
2555         AC_DEFINE_UNQUOTED(SLAPD_RELAY,$MFLAG,[define to support relay backend])
2556 fi
2557
2558 if test "$ol_enable_shell" != no ; then
2559         if test "$ol_link_threads" != no ; then
2560                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2561         fi
2562         BUILD_SLAPD=yes
2563         BUILD_SHELL=$ol_enable_shell
2564         if test "$ol_enable_shell" = mod ; then
2565                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2566                 MFLAG=SLAPD_MOD_DYNAMIC
2567         else
2568                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2569                 MFLAG=SLAPD_MOD_STATIC
2570         fi
2571         AC_DEFINE_UNQUOTED(SLAPD_SHELL,$MFLAG,[define to support SHELL backend])
2572 fi
2573
2574 if test "$ol_link_sql" != no ; then
2575         BUILD_SLAPD=yes
2576         BUILD_SQL=$ol_enable_sql
2577         if test "$ol_enable_sql" = mod; then
2578                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2579                 MFLAG=SLAPD_MOD_DYNAMIC
2580         else
2581                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2582                 MFLAG=SLAPD_MOD_STATIC
2583         fi
2584         AC_DEFINE_UNQUOTED(SLAPD_SQL,$MFLAG,[define to support SQL backend])
2585 fi
2586
2587 if test "$ol_enable_accesslog" != no ; then
2588         BUILD_ACCESSLOG=$ol_enable_accesslog
2589         if test "$ol_enable_accesslog" = mod ; then
2590                 MFLAG=SLAPD_MOD_DYNAMIC
2591                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS accesslog.la"
2592         else
2593                 MFLAG=SLAPD_MOD_STATIC
2594                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS accesslog.o"
2595         fi
2596         AC_DEFINE_UNQUOTED(SLAPD_OVER_ACCESSLOG,$MFLAG,[define for In-Directory Access Logging overlay])
2597 fi
2598
2599 if test "$ol_enable_auditlog" != no ; then
2600         BUILD_AUDITLOG=$ol_enable_auditlog
2601         if test "$ol_enable_auditlog" = mod ; then
2602                 MFLAG=SLAPD_MOD_DYNAMIC
2603                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS auditlog.la"
2604         else
2605                 MFLAG=SLAPD_MOD_STATIC
2606                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS auditlog.o"
2607         fi
2608         AC_DEFINE_UNQUOTED(SLAPD_OVER_AUDITLOG,$MFLAG,[define for Audit Logging overlay])
2609 fi
2610
2611 if test "$ol_enable_constraint" != no ; then
2612         BUILD_CONSTRAINT=$ol_enable_constraint
2613         if test "$ol_enable_constraint" = mod ; then
2614                 MFLAG=SLAPD_MOD_DYNAMIC
2615                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS constraint.la"
2616         else
2617                 MFLAG=SLAPD_MOD_STATIC
2618                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS constraint.o"
2619         fi
2620         AC_DEFINE_UNQUOTED(SLAPD_OVER_CONSTRAINT,$MFLAG,[define for Attribute Constraint overlay])
2621 fi
2622
2623 if test "$ol_enable_dds" != no ; then
2624         BUILD_DDS=$ol_enable_dds
2625         if test "$ol_enable_dds" = mod ; then
2626                 MFLAG=SLAPD_MOD_DYNAMIC
2627                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dds.la"
2628         else
2629                 MFLAG=SLAPD_MOD_STATIC
2630                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dds.o"
2631         fi
2632         AC_DEFINE_UNQUOTED(SLAPD_OVER_DDS,$MFLAG,[define for Dynamic Directory Services overlay])
2633 fi
2634
2635 if test "$ol_enable_dyngroup" != no ; then
2636         BUILD_DYNGROUP=$ol_enable_dyngroup
2637         if test "$ol_enable_dyngroup" = mod ; then
2638                 MFLAG=SLAPD_MOD_DYNAMIC
2639                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dyngroup.la"
2640         else
2641                 MFLAG=SLAPD_MOD_STATIC
2642                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dyngroup.o"
2643         fi
2644         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNGROUP,$MFLAG,[define for Dynamic Group overlay])
2645 fi
2646
2647 if test "$ol_enable_dynlist" != no ; then
2648         BUILD_DYNLIST=$ol_enable_dynlist
2649         if test "$ol_enable_dynlist" = mod ; then
2650                 MFLAG=SLAPD_MOD_DYNAMIC
2651                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dynlist.la"
2652         else
2653                 MFLAG=SLAPD_MOD_STATIC
2654                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dynlist.o"
2655         fi
2656         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNLIST,$MFLAG,[define for Dynamic List overlay])
2657 fi
2658
2659 if test "$ol_enable_ppolicy" != no ; then
2660         BUILD_PPOLICY=$ol_enable_ppolicy
2661         if test "$ol_enable_ppolicy" = mod ; then
2662                 MFLAG=SLAPD_MOD_DYNAMIC
2663                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS ppolicy.la"
2664         else
2665                 MFLAG=SLAPD_MOD_STATIC
2666                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS ppolicy.o"
2667         fi
2668         AC_DEFINE_UNQUOTED(SLAPD_OVER_PPOLICY,$MFLAG,[define for Password Policy overlay])
2669 fi
2670
2671 if test "$ol_enable_proxycache" != no ; then
2672         BUILD_PROXYCACHE=$ol_enable_proxycache
2673         if test "$ol_enable_proxycache" = mod ; then
2674                 MFLAG=SLAPD_MOD_DYNAMIC
2675                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS pcache.la"
2676         else
2677                 MFLAG=SLAPD_MOD_STATIC
2678                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS pcache.o"
2679         fi
2680         AC_DEFINE_UNQUOTED(SLAPD_OVER_PROXYCACHE,$MFLAG,[define for Proxy Cache overlay])
2681 fi
2682
2683 if test "$ol_enable_refint" != no ; then
2684         BUILD_REFINT=$ol_enable_refint
2685         if test "$ol_enable_refint" = mod ; then
2686                 MFLAG=SLAPD_MOD_DYNAMIC
2687                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS refint.la"
2688         else
2689                 MFLAG=SLAPD_MOD_STATIC
2690                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS refint.o"
2691         fi
2692         AC_DEFINE_UNQUOTED(SLAPD_OVER_REFINT,$MFLAG,[define for Referential Integrity overlay])
2693 fi
2694
2695 if test "$ol_enable_retcode" != no ; then
2696         BUILD_RETCODE=$ol_enable_retcode
2697         if test "$ol_enable_retcode" = mod ; then
2698                 MFLAG=SLAPD_MOD_DYNAMIC
2699                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS retcode.la"
2700         else
2701                 MFLAG=SLAPD_MOD_STATIC
2702                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS retcode.o"
2703         fi
2704         AC_DEFINE_UNQUOTED(SLAPD_OVER_RETCODE,$MFLAG,[define for Referential Integrity overlay])
2705 fi
2706
2707 if test "$ol_enable_rwm" != no ; then
2708         BUILD_REWRITE=yes
2709         BUILD_RWM=$ol_enable_rwm
2710         if test "$ol_enable_rwm" = mod ; then
2711                 MFLAG=SLAPD_MOD_DYNAMIC
2712                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS rwm.la"
2713         else
2714                 MFLAG=SLAPD_MOD_STATIC
2715                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS rwm_x.o"
2716         fi
2717         AC_DEFINE_UNQUOTED(SLAPD_OVER_RWM,$MFLAG,[define for Rewrite/Remap overlay])
2718 fi
2719
2720 if test "$ol_enable_seqmod" != no ; then
2721         BUILD_SEQMOD=$ol_enable_seqmod
2722         if test "$ol_enable_seqmod" = mod ; then
2723                 MFLAG=SLAPD_MOD_DYNAMIC
2724                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS seqmod.la"
2725         else
2726                 MFLAG=SLAPD_MOD_STATIC
2727                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS seqmod.o"
2728         fi
2729         AC_DEFINE_UNQUOTED(SLAPD_OVER_SEQMOD,$MFLAG,[define for Sequential Modify overlay])
2730 fi
2731
2732 if test "$ol_enable_syncprov" != no ; then
2733         BUILD_SYNCPROV=$ol_enable_syncprov
2734         if test "$ol_enable_syncprov" = mod ; then
2735                 MFLAG=SLAPD_MOD_DYNAMIC
2736                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS syncprov.la"
2737         else
2738                 MFLAG=SLAPD_MOD_STATIC
2739                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS syncprov.o"
2740         fi
2741         AC_DEFINE_UNQUOTED(SLAPD_OVER_SYNCPROV,$MFLAG,[define for Syncrepl Provider overlay])
2742 fi
2743
2744 if test "$ol_enable_translucent" != no ; then
2745         BUILD_TRANSLUCENT=$ol_enable_translucent
2746         if test "$ol_enable_translucent" = mod ; then
2747                 MFLAG=SLAPD_MOD_DYNAMIC
2748                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS translucent.la"
2749         else
2750                 MFLAG=SLAPD_MOD_STATIC
2751                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS translucent.o"
2752         fi
2753         AC_DEFINE_UNQUOTED(SLAPD_OVER_TRANSLUCENT,$MFLAG,[define for Translucent Proxy overlay])
2754 fi
2755
2756 if test "$ol_enable_unique" != no ; then
2757         BUILD_UNIQUE=$ol_enable_unique
2758         if test "$ol_enable_unique" = mod ; then
2759                 MFLAG=SLAPD_MOD_DYNAMIC
2760                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS unique.la"
2761         else
2762                 MFLAG=SLAPD_MOD_STATIC
2763                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS unique.o"
2764         fi
2765         AC_DEFINE_UNQUOTED(SLAPD_OVER_UNIQUE,$MFLAG,[define for Attribute Uniqueness overlay])
2766 fi
2767
2768 if test "$ol_enable_valsort" != no ; then
2769         BUILD_VALSORT=$ol_enable_valsort
2770         if test "$ol_enable_valsort" = mod ; then
2771                 MFLAG=SLAPD_MOD_DYNAMIC
2772                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS valsort.la"
2773         else
2774                 MFLAG=SLAPD_MOD_STATIC
2775                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS valsort.o"
2776         fi
2777         AC_DEFINE_UNQUOTED(SLAPD_OVER_VALSORT,$MFLAG,[define for Value Sorting overlay])
2778 fi
2779
2780 if test "$ol_enable_slurpd" != no &&
2781    test "$ol_link_threads" != no &&
2782    test $BUILD_SLAPD = yes ; then
2783         BUILD_SLURPD=yes
2784 fi
2785
2786 if test "$ol_enable_rewrite" != no ; then
2787         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
2788         BUILD_REWRITE=yes
2789 fi
2790
2791 if test "$ol_enable_slapi" != no ; then
2792         AC_DEFINE(ENABLE_SLAPI,1,[define to enable slapi library])
2793         BUILD_SLAPI=yes
2794         SLAPD_SLAPI_DEPEND=libslapi.a
2795 fi
2796
2797 dnl ----------------------------------------------------------------
2798
2799 dnl
2800 dnl For Windows build, we don't want to include -dlopen flags.
2801 dnl They hurt more than they help.
2802 dnl
2803
2804 if test "$ac_cv_mingw32" = yes ; then
2805         PLAT=NT
2806         SLAPD_MODULES_LDFLAGS=
2807 else
2808         PLAT=UNIX
2809 fi
2810
2811 AC_SUBST(LIBSRCS)
2812 AC_SUBST(PLAT)
2813 AC_SUBST(WITH_SASL)
2814 AC_SUBST(WITH_TLS)
2815 AC_SUBST(WITH_MODULES_ENABLED)
2816 AC_SUBST(WITH_ACI_ENABLED)
2817 AC_SUBST(BUILD_THREAD)
2818 AC_SUBST(BUILD_LIBS_DYNAMIC)
2819
2820 AC_SUBST(BUILD_SLAPD)
2821 dnl slapi
2822   AC_SUBST(BUILD_SLAPI)
2823   AC_SUBST(SLAPD_SLAPI_DEPEND)
2824 dnl backends
2825   AC_SUBST(BUILD_BDB)
2826   AC_SUBST(BUILD_DNSSRV)
2827   AC_SUBST(BUILD_HDB)
2828   AC_SUBST(BUILD_LDAP)
2829   AC_SUBST(BUILD_META)
2830   AC_SUBST(BUILD_MONITOR)
2831   AC_SUBST(BUILD_NULL)
2832   AC_SUBST(BUILD_PASSWD)
2833   AC_SUBST(BUILD_RELAY)
2834   AC_SUBST(BUILD_PERL)
2835   AC_SUBST(BUILD_SHELL)
2836   AC_SUBST(BUILD_SQL)
2837 dnl overlays
2838   AC_SUBST(BUILD_ACCESSLOG)
2839   AC_SUBST(BUILD_AUDITLOG)
2840   AC_SUBST(BUILD_CONSTRAINT)
2841   AC_SUBST(BUILD_DDS)
2842   AC_SUBST(BUILD_DENYOP)
2843   AC_SUBST(BUILD_DYNGROUP)
2844   AC_SUBST(BUILD_DYNLIST)
2845   AC_SUBST(BUILD_LASTMOD)
2846   AC_SUBST(BUILD_PPOLICY)
2847   AC_SUBST(BUILD_PROXYCACHE)
2848   AC_SUBST(BUILD_REFINT)
2849   AC_SUBST(BUILD_RETCODE)
2850   AC_SUBST(BUILD_RWM)
2851   AC_SUBST(BUILD_SEQMOD)
2852   AC_SUBST(BUILD_SYNCPROV)
2853   AC_SUBST(BUILD_TRANSLUCENT)
2854   AC_SUBST(BUILD_UNIQUE)
2855   AC_SUBST(BUILD_VALSORT)
2856 AC_SUBST(BUILD_SLURPD)
2857
2858 AC_SUBST(LDAP_LIBS)
2859 AC_SUBST(SLAPD_LIBS)
2860 AC_SUBST(SLURPD_LIBS)
2861 AC_SUBST(BDB_LIBS)
2862 AC_SUBST(LTHREAD_LIBS)
2863 AC_SUBST(LUTIL_LIBS)
2864 AC_SUBST(WRAP_LIBS)
2865
2866 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2867 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2868
2869 AC_SUBST(SLAPD_NO_STATIC)
2870 AC_SUBST(SLAPD_STATIC_BACKENDS)
2871 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
2872 AC_SUBST(SLAPD_STATIC_OVERLAYS)
2873 AC_SUBST(SLAPD_DYNAMIC_OVERLAYS)
2874
2875 AC_SUBST(PERL_CPPFLAGS)
2876 AC_SUBST(SLAPD_PERL_LDFLAGS)
2877 AC_SUBST(MOD_PERL_LDFLAGS)
2878
2879 AC_SUBST(KRB4_LIBS)
2880 AC_SUBST(KRB5_LIBS)
2881 AC_SUBST(SASL_LIBS)
2882 AC_SUBST(TLS_LIBS)
2883 AC_SUBST(MODULES_LIBS)
2884 AC_SUBST(SLAPI_LIBS)
2885 AC_SUBST(LIBSLAPI)
2886 AC_SUBST(LIBSLAPITOOLS)
2887 AC_SUBST(AUTH_LIBS)
2888 AC_SUBST(ICU_LIBS)
2889
2890 AC_SUBST(SLAPD_SLP_LIBS)
2891 AC_SUBST(SLAPD_GMP_LIBS)
2892
2893 AC_SUBST(SLAPD_SQL_LDFLAGS)
2894 AC_SUBST(SLAPD_SQL_LIBS)
2895 AC_SUBST(SLAPD_SQL_INCLUDES)
2896
2897 dnl ----------------------------------------------------------------
2898 dnl final help output
2899 AC_ARG_WITH(xxinstall,[
2900 See INSTALL file for further details.])
2901
2902 dnl ----------------------------------------------------------------
2903 dnl final output
2904 dnl
2905
2906 AC_CONFIG_FILES([Makefile:build/top.mk:Makefile.in:build/dir.mk]
2907 [doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk]
2908 [doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk]
2909 [doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk]
2910 [doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk]
2911 [doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk]
2912 [doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk]
2913 [clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk]
2914 [clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk]
2915 [include/Makefile:build/top.mk:include/Makefile.in]
2916 [libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk]
2917 [libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk]
2918 [libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk]
2919 [libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk]
2920 [libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk]
2921 [libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk]
2922 [libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-static.mk]
2923 [servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk]
2924 [servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk]
2925 [servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk]
2926 [servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk]
2927 [servers/slapd/back-hdb/Makefile:build/top.mk:servers/slapd/back-hdb/Makefile.in:build/mod.mk]
2928 [servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk]
2929 [servers/slapd/back-ldif/Makefile:build/top.mk:servers/slapd/back-ldif/Makefile.in:build/mod.mk]
2930 [servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk]
2931 [servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk]
2932 [servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk]
2933 [servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk]
2934 [servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk]
2935 [servers/slapd/back-relay/Makefile:build/top.mk:servers/slapd/back-relay/Makefile.in:build/mod.mk]
2936 [servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk]
2937 [servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk]
2938 [servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk]
2939 [servers/slapd/slapi/Makefile:build/top.mk:servers/slapd/slapi/Makefile.in:build/lib.mk:build/lib-shared.mk]
2940 [servers/slapd/overlays/Makefile:build/top.mk:servers/slapd/overlays/Makefile.in:build/lib.mk]
2941 [servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk]
2942 [tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk]
2943 [tests/run]
2944 [tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk])
2945
2946 AC_CONFIG_COMMANDS([default],[[
2947 chmod +x tests/run
2948 date > stamp-h
2949 BACKENDSC="servers/slapd/backends.c"
2950 echo "Making $BACKENDSC"
2951 rm -f $BACKENDSC
2952 cat > $BACKENDSC << ENDX
2953 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
2954  *
2955  * Copyright 1998-2007 The OpenLDAP Foundation.
2956  * All rights reserved.
2957  *
2958  * Redistribution and use in source and binary forms, with or without
2959  * modification, are permitted only as authorized by the OpenLDAP
2960  * Public License.
2961  *
2962  * A copy of this license is available in the file LICENSE in the
2963  * top-level directory of the distribution or, alternatively, at
2964  * <http://www.OpenLDAP.org/license.html>.
2965  */
2966 /* This file is automatically generated by configure; please do not edit. */
2967
2968 #include "portable.h"
2969 #include "slap.h"
2970
2971 ENDX
2972 if test "${STATIC_BACKENDS}"; then
2973         for b in config ${STATIC_BACKENDS}; do
2974                 bb=`echo "${b}" | sed -e 's/back-//'`
2975                 cat >> $BACKENDSC << ENDX
2976 extern BI_init ${bb}_back_initialize;
2977 ENDX
2978         done
2979
2980         cat >> $BACKENDSC << ENDX
2981
2982 BackendInfo slap_binfo[] = {
2983 ENDX
2984
2985         for b in config ${STATIC_BACKENDS}; do
2986                 bb=`echo "${b}" | sed -e 's/back-//'`
2987                 echo "    Add ${bb} ..."
2988                 cat >> $BACKENDSC << ENDX
2989         { "${bb}", ${bb}_back_initialize },
2990 ENDX
2991         done
2992
2993         cat >> $BACKENDSC << ENDX
2994         { NULL, NULL },
2995 };
2996
2997 /* end of generated file */
2998 ENDX
2999 fi
3000 OVERLAYSC="servers/slapd/overlays/statover.c"
3001 echo "Making $OVERLAYSC"
3002 rm -f $OVERLAYSC
3003 cat > $OVERLAYSC << ENDX
3004 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3005  *
3006  * Copyright 1998-2007 The OpenLDAP Foundation.
3007  * All rights reserved.
3008  *
3009  * Redistribution and use in source and binary forms, with or without
3010  * modification, are permitted only as authorized by the OpenLDAP
3011  * Public License.
3012  *
3013  * A copy of this license is available in the file LICENSE in the
3014  * top-level directory of the distribution or, alternatively, at
3015  * <http://www.OpenLDAP.org/license.html>.
3016  */
3017 /* This file is automatically generated by configure; please do not edit. */
3018
3019 #include "portable.h"
3020 #include "slap.h"
3021
3022 ENDX
3023 if test "${STATIC_OVERLAYS}"; then
3024         for o in ${STATIC_OVERLAYS}; do
3025                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3026                 cat >> $OVERLAYSC << ENDX
3027 extern OV_init ${oo}_initialize;
3028 ENDX
3029         done
3030 fi
3031
3032 cat >> $OVERLAYSC << ENDX
3033
3034 OverlayInit slap_oinfo[] = {
3035 ENDX
3036
3037 if test "${STATIC_OVERLAYS}"; then
3038         for o in ${STATIC_OVERLAYS}; do
3039                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3040                 echo "    Add ${oo} ..."
3041                 cat >> $OVERLAYSC << ENDX
3042         { "${oo}", ${oo}_initialize },
3043 ENDX
3044         done
3045 fi
3046
3047         cat >> $OVERLAYSC << ENDX
3048         { NULL, NULL },
3049 };
3050
3051 /* end of generated file */
3052 ENDX
3053
3054 echo Please run \"make depend\" to build dependencies
3055 ]],[[
3056 STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS"
3057 STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS"
3058 ]])
3059 AC_OUTPUT