git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  14
  15 dnl We use autoconf features new to 2.13.
  16 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  17 AC_PREREQ(2.13)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 ol_enable_syslog=no
  43 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  44 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  54
  55 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  56         auto, [auto k5 k4 afs yes no])
  57 OL_ARG_WITH(threads,[  --with-threads   use threads],
  58         auto, [auto posix mach lwp yes no manual] )
  59 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  60         auto, [auto yes no manual] )
  61 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  62         auto, [auto ssleay openssl yes no] )
  63
  64 dnl Server options
  65
  66 dnl LDAPD OPTIONS
  67 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  68 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  69
  70 dnl SLAPD OPTIONS
  71 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  72 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  73 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  74 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  75 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  76 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  77 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  78 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  79
  80 dnl SLAPD Backend options
  81 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  82 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  83 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  84         [auto db2 db gdbm ndbm manual])
  85 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  86         [auto btree hash])
  87
  88 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  89 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
  90 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  91 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
  92
  93 dnl SLURPD OPTIONS
  94 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  95 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  96
  97 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  98 AM_ENABLE_STATIC
  99 dnl AM_DISABLE_SHARED
 100 AM_ENABLE_SHARED
 101
 102 dnl General "enable" options
 103 # validate options
 104 if test $ol_enable_dns = yes ; then
 105         if test $ol_enable_referrals = no ; then
 106                 AC_MSG_ERROR([DNS requires --enable-referrals])
 107         fi
 108         if test $ol_enable_referrals = auto ; then
 109                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 110                 ol_enable_referrals=yes
 111         fi
 112 fi
 113
 114 if test $ol_enable_slapd = no ; then
 115         dnl SLAPD was specificallly disabled
 116         if test $ol_enable_bdb2 = yes ; then
 117                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 118         fi
 119         if test $ol_enable_ldbm = yes ; then
 120                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 121         fi
 122         if test $ol_enable_passwd = yes ; then
 123                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 124         fi
 125         if test $ol_enable_perl = yes ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 127         fi
 128         if test $ol_enable_shell = yes ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 130         fi
 131         if test $ol_enable_tcl = yes ; then
 132                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 133         fi
 134         if test $ol_enable_aclgroups = yes ; then
 135                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 136         fi
 137         if test $ol_enable_wrappers = yes ; then
 138                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 139         fi
 140         if test $ol_enable_phonetic = yes ; then
 141                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 142         fi
 143         if test $ol_enable_rlookups = yes ; then
 144                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 145         fi
 146         if test $ol_with_ldbm_api != auto ; then
 147                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 148         fi
 149         if test $ol_with_ldbm_type != auto ; then
 150                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 151         fi
 152         if test $ol_enable_slurpd = yes ; then
 153                 AC_MSG_ERROR([slurpd requires slapd])
 154         fi
 155
 156         # force settings to no
 157         ol_enable_bdb2=no
 158         ol_enable_ldbm=no
 159         ol_enable_passwd=no
 160         ol_enable_perl=no
 161         ol_enable_shell=no
 162         ol_enable_tcl=no
 163         ol_enable_aclgroups=no
 164         ol_enable_wrappers=no
 165         ol_enable_phonetic=no
 166         ol_enable_rlookups=no
 167         ol_with_ldbm_api=no
 168         ol_with_ldbm_type=no
 169         ol_enable_slurpd=no
 170
 171 elif test $ol_enable_ldbm = no ; then
 172         dnl SLAPD without LDBM
 173
 174         if test $ol_with_ldbm_api != auto ; then
 175                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 176         fi
 177
 178         if test $ol_with_ldbm_type != auto ; then
 179                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 180         fi
 181
 182         if test $ol_enable_bdb2 = yes ; then
 183                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 184         fi
 185
 186         if test $ol_enable_passwd = no -a \
 187                 $ol_enable_perl = no -a \
 188                 $ol_enable_shell = no -a \
 189                 $ol_enable_tcl = no ; then
 190                 AC_MSG_ERROR([slapd requires a backend])
 191         fi
 192
 193         ol_with_ldbm_api=no
 194         ol_with_ldbm_type=no
 195
 196 elif test $ol_enable_bdb2 = yes ; then
 197         dnl SLAPD with BDB2
 198
 199         if test $ol_with_ldbm_api != auto -a \
 200                 $ol_with_ldbm_api != db2 ; then
 201                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 202         fi
 203
 204         ol_with_ldbm_api=db2
 205
 206 else
 207         dnl SLAPD with LDBM
 208
 209         if test $ol_enable_bdb2 != no ; then
 210                 if test $ol_with_ldbm_api != auto -a \
 211                         $ol_with_ldbm_api != db2 ; then
 212                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 213                         ol_enable_bdb2=no
 214                 fi
 215         fi
 216
 217         if test $ol_with_ldbm_api = gdbm -a \
 218                 $ol_with_ldbm_type = btree ; then
 219                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 220         fi
 221         if test $ol_with_ldbm_api = ndbm -a \
 222                 $ol_with_ldbm_type = btree ; then
 223                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 224         fi
 225 fi
 226
 227 if test $ol_enable_slurpd = yes ; then
 228         dnl SLURPD was specifically enabled
 229         if test $ol_with_threads = no ; then
 230                 AC_MSG_ERROR([slurpd requires threads])
 231         fi
 232 fi
 233
 234 AC_MSG_RESULT(done)
 235
 236 AC_CANONICAL_HOST
 237
 238 ## Initialize vars
 239 LDAP_LIBS=
 240 LDBM_LIBS=
 241 LTHREAD_LIBS=
 242 LUTIL_LIBS=
 243
 244 LDAPD_LIBS=
 245 SLAPD_LIBS=
 246 SLURPD_LIBS=
 247
 248 BUILD_LDAPD=no
 249 BUILD_SLAPD=no
 250 BUILD_SLURPD=no
 251
 252 BUILD_BDB2=no
 253 BUILD_LDBM=no
 254 BUILD_PASSWD=no
 255 BUILD_PERL=no
 256 BUILD_SHELL=no
 257 BUILD_TCL=no
 258 BUILD_THREAD=no
 259
 260 SLAPD_PERL_LDFLAGS=
 261 SLAPD_PERL_CPPFLAGS=
 262
 263 KRB_LIBS=
 264 TERMCAP_LIBS=
 265 TLS_LIBS=
 266
 267 dnl ----------------------------------------------------------------
 268 dnl Checks for programs
 269
 270 AC_PROG_INSTALL
 271 AM_PROG_LIBTOOL
 272 dnl AC_PROG_MAKE_SET
 273
 274 AC_PROG_AWK
 275 AC_PROG_LN_S
 276
 277 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 278         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 279 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 280 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 281
 282 if test $ol_enable_perl = yes ; then
 283         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 284
 285         if test "no$PERLBIN" = "no" ; then
 286                 ol_enable_perl=no
 287         fi
 288
 289         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 290         SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e perl_inc`"
 291 fi
 292
 293 AC_PROG_CPP
 294
 295 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 296         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 297
 298 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 299         AC_MSG_WARN([programs compiled here do run here...])
 300         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 301
 302 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 303         AC_MSG_WARN([programs compiled here do not run here...])
 304         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 305 fi
 306
 307 dnl Checks for UNIX Variants
 308 AC_AIX
 309 AC_ISC_POSIX
 310 AC_MINIX
 311
 312 dnl Checks for system services
 313 AC_CYGWIN
 314 AC_MINGW32
 315 AC_EXEEXT
 316 AC_OBJEXT
 317
 318 dnl OpenLDAP requires STDC features
 319 AM_PROG_CC_STDC
 320 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 321         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 322 fi
 323
 324 dnl AM_C_PROTOTYPES
 325
 326 dnl Checks for libraries
 327
 328 dnl Find socket()
 329 dnl Likely combinations:
 330 dnl             -lsocket [ -lnsl_s | -lnsl ]
 331 dnl             -linet
 332
 333 AC_CHECK_FUNC(socket, [have_socket=yes], [
 334 dnl
 335 dnl hopefully we won't include too many libraries
 336 dnl
 337         AC_CHECK_LIB(socket, main)
 338         AC_CHECK_LIB(net, main)
 339         AC_CHECK_LIB(nsl_s, main)
 340         AC_CHECK_LIB(nsl, main)
 341         AC_CHECK_LIB(inet, socket)
 342         AC_CHECK_LIB(gen, main)
 343 ])
 344
 345 dnl Check for resolver routines
 346 AC_CHECK_FUNCS(res_search)
 347 if test $ac_cv_func_res_search = "no" ; then
 348         AC_CHECK_LIB(bind, res_search)
 349         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 350                 AC_DEFINE(HAVE_RES_SEARCH,1)
 351         else
 352                 AC_CHECK_LIB(resolv, res_search)
 353                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 354                         AC_DEFINE(HAVE_RES_SEARCH,1)
 355                 fi
 356         fi
 357 fi
 358
 359 dnl HP-UX requires -lV3
 360 AC_CHECK_LIB(V3, sigset)
 361
 362 # ISODE tests
 363 ol_link_isode=no
 364 if test $ol_enable_ldapd != no ; then
 365         dnl look for ISODE libraries
 366         AC_CHECK_LIB(xtpp, main, [
 367                 ol_link_isode=yes
 368                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 369                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 370                 ],:,[-lxtdsap -lxtisode -losi])
 371         AC_CHECK_LIB(dsap, main, [
 372                 ol_link_isode=yes
 373                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 374                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 375                 ],:,[-lisode])
 376         AC_CHECK_LIB(isode, main, [
 377                 ol_link_isode=yes
 378                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 379                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 380                 ],:)
 381 fi
 382
 383 if test $ol_link_isode != no; then
 384         AC_CHECK_LIB(pp, main, [
 385                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 386                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 387                 ],:)
 388
 389         AC_PATH_PROG(PEPSY, pepsy)
 390 fi
 391
 392 dnl
 393 dnl check for kerberos
 394 dnl
 395 ol_link_kerberos=no
 396
 397 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 398         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 399
 400         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 401                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 402                         [-lkrb5 -ldes425])
 403
 404                 if test $have_k5 = yes ; then
 405                         ol_with_kerberos=found
 406                         ol_link_kerberos=yes
 407
 408                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 409
 410                         LIBS="$KRB_LIBS $LIBS"
 411
 412                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 413                                 [ol_cv_var_des_debug], [
 414                                 dnl save the flags
 415                                 save_LIBS="$LIBS"
 416                                 LIBS="$KRB_LIBS $LIBS"
 417                                 AC_TRY_LINK([
 418 #include <kerberosIV/krb.h>
 419 #include <kerberosIV/des.h>
 420 extern int des_debug;
 421 ],[
 422 des_debug = 1;
 423 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 424                                 dnl restore the LIBS
 425                                 LIBS="$save_LIBS"
 426                         ])
 427
 428                         if test $ol_cv_var_des_debug= yes ; then
 429                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 430                                         [define if you have Kerberos des_debug])
 431                         fi
 432
 433                         LIBS="$save_LIBS"
 434                 fi
 435         fi
 436 fi
 437
 438 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 439         AC_CHECK_HEADERS(krb.h des.h)
 440
 441         if test $ac_cv_header_krb_h = yes ; then
 442                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 443
 444                 if test $have_k4 = yes ; then
 445                         ol_with_kerberos=found
 446                         ol_link_kerberos=yes
 447
 448                         KRB_LIBS="-lkrb -ldes"
 449                 fi
 450         fi
 451 fi
 452
 453 if test $ol_link_kerberos = yes ; then
 454         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 455 fi
 456
 457 dnl
 458 dnl Check for SSL/TLS
 459 dnl
 460 ol_link_tls=no
 461 if test $ol_with_tls != no ; then
 462
 463         AC_CHECK_HEADERS(ssl.h)
 464
 465         if test $ac_cv_header_ssl_h = yes ; then
 466                 AC_CHECK_LIB( ssl, SSLeay_add_ssl_algorithms,
 467                         [have_ssleay=yes], [have_ssleay=no], [-lcrypto])
 468
 469                 if test $have_ssleay = no ; then
 470                         AC_CHECK_LIB( ssl, ssl3_accept,
 471                                 [have_ssleay=yes], [have_ssleay=no], [-lcrypto -lRSAglue -lrsaref])
 472                 fi
 473
 474                 if test $have_ssleay = yes ; then
 475                         ol_with_tls=found
 476                         ol_link_tls=yes
 477
 478                         AC_DEFINE( HAVE_SSLEAY, 1,
 479                                 [define if you have SSLeay] )
 480
 481                         TLS_LIBS="-lssl -lcrypto"
 482                 fi
 483         fi
 484 fi
 485
 486 if test $ol_link_tls = yes ; then
 487         AC_DEFINE( HAVE_TLS, 1, [define if you have TLS] )
 488 fi
 489
 490 ol_link_threads=no
 491 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 492         -o $ol_with_threads = posix ; then
 493
 494         AC_CHECK_HEADERS(pthread.h sched.h)
 495
 496         if test $ac_cv_header_pthread_h = yes ; then
 497                 OL_POSIX_THREAD_VERSION
 498
 499                 if test $ol_cv_pthread_version = final ; then
 500                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 501                                 [define if pthreads API compatible with final spec])
 502                 elif test $ol_cv_pthread_version = draft4 ; then
 503                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 504                                 [define if pthreads API compatible with draft4 spec])
 505                 else
 506                         AC_MSG_ERROR([unknown pthread version])
 507                 fi
 508
 509                 # consider threads found
 510                 ol_with_threads=found
 511
 512                 OL_LINUX_THREADS
 513
 514                 if test $ol_cv_linux_threads = yes ; then
 515                         AC_DEFINE(HAVE_LINUX_THREADS,1,
 516                                 [define if you have LinuxThreads])
 517                 fi
 518
 519                 dnl Now the hard part, how to link?
 520                 dnl
 521                 dnl currently supported checks:
 522                 dnl
 523                 dnl Check for no flags
 524                 dnl     pthread_create() in $LIBS
 525                 dnl
 526                 dnl Check special pthread (final) flags
 527                 dnl     pthread_create() with -kthread (FreeBSD)
 528                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 529                 dnl     pthread_create() with -pthreads (?)
 530                 dnl     pthread_create() with -thread (?)
 531                 dnl     pthread_create() with -mt (Solaris)
 532                 dnl
 533                 dnl Check pthread (final) libraries
 534                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 535                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 536                 dnl     pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 537                 dnl     pthread_create() in -lpthread (many)
 538                 dnl     pthread_create() in -lc_r (FreeBSD)
 539                 dnl     pthread_create() in -lpthreads (many)
 540                 dnl     pthread_join() -Wl,-woff,85 -lpthreads (IRIX)
 541                 dnl
 542                 dnl Check pthread (draft4) flags (depreciated)
 543                 dnl     pthread_create() with -threads (OSF/1)
 544                 dnl
 545                 dnl Check pthread (final) libraries (depreciated)
 546                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 547                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 548                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 549                 dnl
 550
 551                 dnl pthread_create in $LIBS
 552                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 553
 554                 if test $ol_link_threads = no ; then
 555                         dnl try -kthread
 556                         AC_CACHE_CHECK([for pthread_create with -kthread],
 557                                 [ol_cv_kthread_flag], [
 558                                 dnl save the flags
 559                                 save_LIBS="$LIBS"
 560                                 LIBS="-kthread $LIBS"
 561                                 AC_TRY_LINK([#include <pthread.h>],
 562                                         [pthread_create(NULL,NULL,NULL,NULL);],
 563                                         [ol_cv_kthread_flag=yes], [ol_cv_kthread_flag=no])
 564                                 dnl restore the LIBS
 565                                 LIBS="$save_LIBS"
 566                         ])
 567
 568                         if test $ol_cv_kthread_flag = yes ; then
 569                                 LTHREAD_LIBS="$LTHREAD_LIBS -kthread"
 570                                 ol_link_threads=posix
 571                         fi
 572                 fi
 573
 574                 if test $ol_link_threads = no ; then
 575                         dnl try -pthread
 576                         AC_CACHE_CHECK([for pthread_create with -pthread],
 577                                 [ol_cv_pthread_flag], [
 578                                 dnl save the flags
 579                                 save_LIBS="$LIBS"
 580                                 LIBS="-pthread $LIBS"
 581                                 AC_TRY_LINK([#include <pthread.h>],
 582                                         [pthread_create(NULL,NULL,NULL,NULL);],
 583                                         [ol_cv_pthread_flag=yes], [ol_cv_pthread_flag=no])
 584                                 dnl restore the LIBS
 585                                 LIBS="$save_LIBS"
 586                         ])
 587
 588                         if test $ol_cv_pthread_flag = yes ; then
 589                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 590                                 ol_link_threads=posix
 591                         fi
 592                 fi
 593
 594                 if test $ol_link_threads = no ; then
 595                         dnl try -pthreads
 596                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 597                                 [ol_cv_pthreads_flag], [
 598                                 dnl save the flags
 599                                 save_LIBS="$LIBS"
 600                                 LIBS="-pthreads $LIBS"
 601                                 AC_TRY_LINK([#include <pthread.h>],
 602                                         [pthread_create(NULL,NULL,NULL,NULL);],
 603                                         [ol_cv_pthreads_flag=yes], [ol_cv_pthreads_flag=no])
 604                                 dnl restore the LIBS
 605                                 LIBS="$save_LIBS"
 606                         ])
 607
 608                         if test $ol_cv_pthreads_flag = yes ; then
 609                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 610                                 ol_link_threads=posix
 611                         fi
 612                 fi
 613
 614                 if test $ol_link_threads = no ; then
 615                         dnl try -thread
 616                         AC_CACHE_CHECK([for pthread_create with -thread],
 617                                 [ol_cv_thread_flag], [
 618                                 dnl save the flags
 619                                 save_LIBS="$LIBS"
 620                                 LIBS="-thread $LIBS"
 621                                 AC_TRY_LINK([char pthread_create();],
 622                                         [pthread_create();],
 623                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 624                                 dnl restore the LIBS
 625                                 LIBS="$save_LIBS"
 626                         ])
 627
 628                         if test $ol_cv_thread_flag = yes ; then
 629                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 630                                 ol_link_threads=posix
 631                         fi
 632                 fi
 633
 634                 if test $ol_link_threads = no ; then
 635                         dnl try -mt
 636                         AC_CACHE_CHECK([for pthread_create with -mt],
 637                                 [ol_cv_thread_flag], [
 638                                 dnl save the flags
 639                                 save_LIBS="$LIBS"
 640                                 LIBS="-mt $LIBS"
 641                                 AC_TRY_LINK([char pthread_create();],
 642                                         [pthread_create();],
 643                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 644                                 dnl restore the LIBS
 645                                 LIBS="$save_LIBS"
 646                         ])
 647
 648                         if test $ol_cv_thread_flag = yes ; then
 649                                 LTHREAD_LIBS="$LTHREAD_LIBS -mt"
 650                                 ol_link_threads=posix
 651                         fi
 652                 fi
 653
 654                 if test $ol_link_threads = no ; then
 655                         dnl try DEC Threads -lpthread -lmach -lexc -lc_r
 656                         save_LIBS="$LIBS"
 657                         AC_CHECK_LIB(pthread, pthread_mutex_unlock, [
 658                                 ol_link_threads=posix
 659                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc_r"
 660                                 if test $ol_with_yielding_select = auto ; then
 661                                         ol_with_yielding_select=yes
 662                                 fi
 663                                 ],:,[-lmach -lexc -lc_r])
 664                         LIBS="$save_LIBS"
 665                 fi
 666
 667                 if test $ol_link_threads = no ; then
 668                         dnl try DEC Threads -lpthread -lmach -lexc
 669                         save_LIBS="$LIBS"
 670                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 671                                 ol_link_threads=posix
 672                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc"
 673                                 if test $ol_with_yielding_select = auto ; then
 674                                         ol_with_yielding_select=yes
 675                                 fi
 676                                 ],:,[-lmach -lexc])
 677                         LIBS="$save_LIBS"
 678                 fi
 679
 680                 if test $ol_link_threads = no ; then
 681                         dnl try DEC Threads -lpthread -lexc
 682                         save_LIBS="$LIBS"
 683                         AC_CHECK_LIB(pthread, pthread_mutex_trylock, [
 684                                 ol_link_threads=posix
 685                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 686                                 if test $ol_with_yielding_select = auto ; then
 687                                         ol_with_yielding_select=yes
 688                                 fi
 689                                 ],:,[-lexc])
 690                         LIBS="$save_LIBS"
 691                 fi
 692
 693                 if test $ol_link_threads = no ; then
 694                         dnl try -lpthread
 695                         save_LIBS="$LIBS"
 696                         AC_CHECK_LIB(pthread, pthread_create, [
 697                                 ol_link_threads=posix
 698                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"],:)
 699                         LIBS="$save_LIBS"
 700                 fi
 701
 702                 if test $ol_link_threads = no ; then
 703                         dnl try -lc_r
 704                         save_LIBS="$LIBS"
 705                         AC_CHECK_LIB(c_r, pthread_create, [
 706                                 ol_link_threads=posix
 707                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"],:)
 708                         LIBS="$save_LIBS"
 709                 fi
 710
 711                 if test $ol_link_threads = no ; then
 712                         dnl try -lpthreads
 713                         save_LIBS="$LIBS"
 714                         AC_CHECK_LIB(pthreads, pthread_create, [
 715                                 ol_link_threads=posix
 716                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"],:)
 717                         LIBS="$save_LIBS"
 718                 fi
 719
 720                 dnl IRIX Pthread check
 721                 if test $ol_link_threads = no ; then
 722                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 723                         save_LIBS="$LIBS"
 724                         AC_CHECK_LIB(pthreads, pthread_join, [
 725                                 ol_link_threads=posix
 726                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 727                                 ],:,[-Wl,-woff,85])
 728                         LIBS="$save_LIBS"
 729                 fi
 730
 731                 if test $ol_link_threads = no ; then
 732                         dnl try -threads
 733                         AC_CACHE_CHECK([for pthread_create with -threads],
 734                                 [ol_cv_thread_flag], [
 735                                 dnl save the flags
 736                                 save_LIBS="$LIBS"
 737                                 LIBS="-threads $LIBS"
 738                                 AC_TRY_LINK([char pthread_create();],[
 739                                         pthread_create();
 740                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 741                                 dnl restore the LIBS
 742                                 LIBS="$save_LIBS"
 743                         ])
 744
 745                         if test $ol_cv_thread_flag = yes ; then
 746                                 LTHREAD_LIBS="$LTHREAD_LIBS -threads"
 747                                 ol_link_threads=posix
 748                         fi
 749                 fi
 750
 751                 if test $ol_link_threads = no ; then
 752                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 753                         save_LIBS="$LIBS"
 754                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 755                                 ol_link_threads=posix
 756                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 757                                 if test $ol_with_yielding_select = auto ; then
 758                                         ol_with_yielding_select=yes
 759                                 fi
 760                                 ],:,[-lmach -lexc -lc_r])
 761                         LIBS="$save_LIBS"
 762                 fi
 763
 764                 if test $ol_link_threads = no ; then
 765                         dnl try DEC Threads -lpthreads -lmach -lexc
 766                         save_LIBS="$LIBS"
 767                         AC_CHECK_LIB(pthreads, pthread_mutex_lock, [
 768                                 ol_link_threads=posix
 769                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc"
 770                                 if test $ol_with_yielding_select = auto ; then
 771                                         ol_with_yielding_select=yes
 772                                 fi
 773                                 ],:,[-lmach -lexc])
 774                         LIBS="$save_LIBS"
 775                 fi
 776
 777                 if test $ol_link_threads = no ; then
 778                         dnl try DEC Threads -lpthreads -lexc
 779                         save_LIBS="$LIBS"
 780                         AC_CHECK_LIB(pthreads, pthread_mutex_trylock, [
 781                                 ol_link_threads=posix
 782                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lexc"
 783                                 if test $ol_with_yielding_select = auto ; then
 784                                         ol_with_yielding_select=yes
 785                                 fi
 786                                 ],:,[-lexc])
 787                         LIBS="$save_LIBS"
 788                 fi
 789
 790                 if test $ol_link_threads != no ; then
 791                         AC_DEFINE(HAVE_PTHREADS,1,
 792                                 [define if you have POSIX Threads])
 793
 794                         dnl save flags
 795                         save_CPPFLAGS="$CPPFLAGS"
 796                         save_LIBS="$LIBS"
 797                         LIBS="$LTHREAD_LIBS $LIBS"
 798
 799                         dnl All POSIX Thread (final) implementations should have
 800                         dnl sched_yield instead of pthread yield.
 801                         dnl check for both
 802                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 803
 804                         if test $ac_cv_func_sched_yield = no -a \
 805                                 $ac_cv_func_pthread_yield = no ; then
 806                                 dnl Digital UNIX has sched_yield() in -lrt
 807                                 AC_CHECK_LIB(rt, sched_yield,
 808                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 809                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 810                                         ac_cv_func_sched_yield=yes],
 811                                         [ac_cv_func_sched_yield=no])
 812                         fi
 813                         if test $ac_cv_func_sched_yield = no -a \
 814                                 $ac_cv_func_pthread_yield = no ; then
 815                                 dnl Solaris has sched_yield() in -lposix4
 816                                 dnl but we'll use thr_yield instead.
 817                                 AC_CHECK_FUNCS(thr_yield)
 818                         fi
 819                         if test $ac_cv_func_sched_yield = no -a \
 820                                 $ac_cv_func_pthread_yield = no -a \
 821                                 "$ac_cv_func_thr_yield" = no ; then
 822                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 823                         fi
 824
 825                         dnl Check functions for compatibility
 826                         AC_CHECK_FUNCS(pthread_kill)
 827
 828                         dnl Check for pthread_detach with <pthread.h> inclusion
 829                         dnl as it's symbol may have been mangled.
 830                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 831                                 [ol_cv_func_pthread_detach], [
 832                                 dnl save the flags
 833                                 AC_TRY_LINK([#include <pthread.h>],
 834                                         [pthread_detach(NULL);],
 835                                         [ol_cv_func_pthread_detach=yes],
 836                                         [ol_cv_func_pthread_detach=no])
 837                         ])
 838
 839                         if test $ol_cv_func_pthread_detach = no ; then
 840                                 AC_MSG_ERROR([could not locate pthread_detach()])
 841                         fi
 842
 843                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 844                                 [define if you have pthread_detach function])
 845
 846                         dnl Check for setconcurreny functions
 847                         AC_CHECK_FUNCS( \
 848                                 pthread_setconcurrency \
 849                                 pthread_getconcurrency \
 850                                 thr_setconcurrency \
 851                                 thr_getconcurrency \
 852                         )
 853
 854                         AC_MSG_CHECKING([if pthread_create() works])
 855                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 856                         AC_TRY_RUN([
 857 #include <pthread.h>
 858 #ifndef NULL
 859 #define NULL (void*)0
 860 #endif
 861
 862 static void *task(p)
 863         void *p;
 864 {
 865         return (void *) (p == NULL);
 866 }
 867
 868 int main(argc, argv)
 869         int argc;
 870         char **argv;
 871 {
 872         pthread_t t;
 873         exit(pthread_create(&t, NULL, task, NULL));
 874 }
 875 ],
 876                                 [ol_cv_pthread_create_works=yes],
 877                                 [ol_cv_pthread_create_works=no],
 878                                 [dnl assume yes
 879                                 ol_cv_pthread_create_works=yes])])
 880                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 881
 882                         if test $ol_cv_pthread_create_works = no ; then
 883                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 884                         fi
 885
 886                         dnl Check if select causes an yield
 887                         if test $ol_with_yielding_select = auto ; then
 888                                 AC_MSG_CHECKING([if select yields when using pthreads])
 889                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 890                                 AC_TRY_RUN([
 891 #include <sys/types.h>
 892 #include <sys/time.h>
 893 #include <unistd.h>
 894 #include <pthread.h>
 895 #ifndef NULL
 896 #define NULL (void*) 0
 897 #endif
 898
 899 static int fildes[2];
 900
 901 static void *task(p)
 902         void *p;
 903 {
 904         int i;
 905         struct timeval tv;
 906
 907         fd_set rfds;
 908
 909         tv.tv_sec=10;
 910         tv.tv_usec=0;
 911
 912         FD_ZERO(&rfds);
 913         FD_SET(fildes[0], &rfds);
 914
 915         /* we're not interested in any fds */
 916         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 917
 918         if(i < 0) {
 919                 perror("select");
 920                 exit(10);
 921         }
 922
 923         exit(0); /* if we exit here, the select blocked the whole process */
 924 }
 925
 926 int main(argc, argv)
 927         int argc;
 928         char **argv;
 929 {
 930         pthread_t t;
 931
 932         /* create a pipe to select */
 933         if(pipe(&fildes[0])) {
 934                 perror("select");
 935                 exit(1);
 936         }
 937
 938 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 939         (void) pthread_setconcurrency(2);
 940 #else
 941 #ifdef HAVE_THR_SETCONCURRENCY
 942         /* Set Solaris LWP concurrency to 2 */
 943         thr_setconcurrency(2);
 944 #endif
 945 #endif
 946
 947         pthread_create(&t, NULL, task, NULL);
 948
 949 #if HAVE_SCHED_YIELD
 950         sched_yield();  /* make sure task runs first */
 951 #else
 952 #ifdef HAVE_PTHREAD_YIELD
 953         pthread_yield();        /* make sure task runs first */
 954 #endif
 955 #endif
 956
 957         exit(2);
 958 }],
 959                                 [ol_cv_pthread_select_yields=no],
 960                                 [ol_cv_pthread_select_yields=yes], [
 961                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 962                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 963
 964                                 if test $ol_cv_pthread_select_yields = yes ; then
 965                                         ol_with_yielding_select=yes
 966                                 fi
 967                         fi
 968
 969                         dnl restore flags
 970                         CPPFLAGS="$save_CPPFLAGS"
 971                         LIBS="$save_LIBS"
 972                 else
 973                         AC_MSG_ERROR([could not link with POSIX Threads])
 974                 fi
 975         fi
 976
 977         if test $ol_with_threads = posix ; then
 978                 AC_MSG_ERROR([could not locate POSIX Threads])
 979         fi
 980 fi
 981
 982 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 983         -o $ol_with_threads = mach ; then
 984
 985         dnl check for Mach CThreads
 986         AC_CHECK_HEADERS(mach/cthreads.h)
 987         if test $ac_cv_header_mach_cthreads_h = yes ; then
 988                 ol_with_threads=found
 989
 990                 dnl check for cthread support in current $LIBS
 991                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 992
 993                 if test $ol_link_threads = no ; then
 994                         dnl try -all_load
 995                         dnl this test needs work
 996                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 997                                 [ol_cv_cthread_all_load], [
 998                                 dnl save the flags
 999                                 save_LIBS="$LIBS"
1000                                 LIBS="-all_load $LIBS"
1001                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1002                                         cthread_fork((void *)0, (void *)0);
1003                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1004                                 dnl restore the LIBS
1005                                 LIBS="$save_LIBS"
1006                         ])
1007
1008                         if test $ol_cv_cthread_all_load = yes ; then
1009                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1010                                 ol_link_threads=mach
1011                         fi
1012                 fi
1013
1014                 if test $ol_link_threads != no ; then
1015                         : check for cthread specific functionality here
1016                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1017                                 [define if you have Mach Cthreads])
1018                 else
1019                         AC_MSG_ERROR([could not link with Mach CThreads])
1020                 fi
1021         fi
1022
1023         if test $ol_with_threads = mach ; then
1024                 AC_MSG_ERROR([could not locate Mach CThreads])
1025         fi
1026 fi
1027
1028 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1029         -o $ol_with_threads = lwp ; then
1030
1031         dnl check for SunOS5 LWP
1032         AC_CHECK_HEADERS(thread.h synch.h)
1033         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1034                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1035
1036                 if test $have_thr = yes ; then
1037                         AC_DEFINE(HAVE_THR,1,
1038                                 [if you have Solaris LWP (thr) package])
1039                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1040                         ol_link_threads=thr
1041
1042                         if test $ol_with_yielding_select = auto ; then
1043                                 ol_with_yielding_select=yes
1044                         fi
1045
1046                         dnl Check for setconcurreny functions
1047                         AC_CHECK_FUNCS( \
1048                                 thr_setconcurrency \
1049                                 thr_getconcurrency \
1050                         )
1051                 fi
1052         fi
1053
1054         dnl check for SunOS4 LWP
1055         AC_CHECK_HEADERS(lwp/lwp.h)
1056         if test $ac_cv_header_lwp_lwp_h = yes ; then
1057                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1058
1059                 if test $have_lwp = yes ; then
1060                         AC_DEFINE(HAVE_LWP,1,
1061                                 [if you have SunOS LWP package])
1062                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1063                         ol_link_threads=lwp
1064
1065                         if test $ol_with_yielding_select = auto ; then
1066                                 ol_with_yielding_select=no
1067                         fi
1068                 fi
1069         fi
1070 fi
1071
1072 if test $ol_with_yielding_select = yes ; then
1073         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1074                 [define if select implicitly yields])
1075 fi
1076
1077 if test $ol_with_threads = manual ; then
1078         dnl User thinks he can manually configure threads.
1079         ol_link_threads=yes
1080
1081         AC_MSG_WARN([thread defines and link options must be set manually])
1082
1083         AC_CHECK_HEADERS(pthread.h sched.h)
1084         AC_CHECK_FUNCS(sched_yield pthread_yield)
1085         OL_LINUX_THREADS
1086
1087         AC_CHECK_HEADERS(mach/cthreads.h)
1088         AC_CHECK_HEADERS(lwp/lwp.h)
1089         AC_CHECK_HEADERS(thread.h synch.h)
1090 fi
1091
1092 if test $ol_link_threads != no ; then
1093         dnl needed to get reentrant/threadsafe versions
1094         dnl
1095         AC_DEFINE(REENTRANT,1)
1096         AC_DEFINE(_REENTRANT,1)
1097         AC_DEFINE(THREAD_SAFE,1)
1098         AC_DEFINE(_THREAD_SAFE,1)
1099         AC_DEFINE(THREADSAFE,1)
1100         AC_DEFINE(_THREADSAFE,1)
1101
1102         dnl this might cause the errno symbol to be
1103         dnl replaced with a function to get a thread specific errno.
1104         dnl check to see if everything needs to be compiled
1105         dnl with the thread libraries
1106         AC_CACHE_CHECK([for thread specific errno],
1107                 [ol_cv_errno_thread_specific], [
1108                 AC_TRY_LINK([#include <errno.h>], [int x = errno;],
1109                         [ol_cv_errno_thread_specific=yes],
1110                         [ol_cv_errno_thread_specific=no])
1111         ])
1112
1113         if test $ol_cv_errno_thread_specific != yes ; then
1114                 LIBS="$LTHREAD_LIBS $LIBS"
1115                 LTHREAD_LIBS=""
1116         fi
1117
1118 dnl When in thread environment, use
1119 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1120 dnl                     || defined( HAVE_FUNC_R )
1121 dnl                     func_r(...);
1122 dnl             #else
1123 dnl             #       if defined( HAVE_THREADS )
1124 dnl                             /* lock */
1125 dnl             #       endif
1126 dnl                             func(...);
1127 dnl             #       if defined( HAVE_THREADS )
1128 dnl                             /* unlock */
1129 dnl             #       endif
1130 dnl             #endif
1131 dnl
1132 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1133 dnl             _POSIX_REENTRANT_FUNCTIONS
1134 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1135 dnl             _POSIX_THREADSAFE_FUNCTIONS
1136 dnl
1137 dnl             and is currently defined in lthread.h
1138 dnl
1139 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1140 dnl
1141 dnl libldap/*.c should only include <lthread.h> iff
1142 dnl LDAP_R_COMPILE is defined.  ie:
1143 dnl             #ifdef LDAP_R_COMPILE
1144 dnl             #       include LDAP_R_COMPILE
1145 dnl             #endif
1146 dnl
1147 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
1148 dnl specifically for compiling the threadsafe version of
1149 dnl     the ldap library (-lldap_r).
1150 dnl
1151 dnl     dnl check for reentrant/threadsafe functions
1152 dnl     dnl
1153 dnl     dnl note: these should only be used when linking
1154 dnl     dnl       with $LTHREAD_LIBS
1155 dnl     dnl
1156 dnl     save_CPPFLAGS="$CPPFLAGS"
1157 dnl     save_LIBS="$LIBS"
1158 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1159 dnl     AC_CHECK_FUNCS( \
1160 dnl             gmtime_r \
1161 dnl             gethostbyaddr_r gethostbyname_r \
1162 dnl             feof_unlocked unlocked_feof \
1163 dnl             putc_unlocked unlocked_putc \
1164 dnl             flockfile ftrylockfile \
1165 dnl     )
1166 dnl     CPPFLAGS="$save_CPPFLAGS"
1167 dnl     LIBS="$save_LIBS"
1168 fi
1169
1170 dnl ----------------------------------------------------------------
1171
1172 if test $ol_link_threads = no ; then
1173         if test $ol_with_threads = yes ; then
1174                 AC_MSG_ERROR([no suitable thread support])
1175         fi
1176
1177         if test $ol_with_threads = auto ; then
1178                 AC_MSG_WARN([no suitable thread support, disabling threads])
1179                 ol_with_threads=no
1180         fi
1181
1182         AC_DEFINE(NO_THREADS,1,
1183                 [define if you have (or want) no threads])
1184         LTHREAD_LIBS=""
1185 fi
1186
1187 ol_link_ldbm=no
1188 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1189         OL_BERKELEY_DB2
1190
1191         if test $ol_cv_berkeley_db2 = yes ; then
1192                 ol_link_ldbm=db2
1193                 ol_with_ldbm_api=db2
1194
1195                 if test $ol_with_ldbm_type = hash ; then
1196                         AC_DEFINE(LDBM_USE_DBHASH,1)
1197                 else
1198                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1199                 fi
1200
1201                 dnl $ol_cv_lib_db2 should be yes or -ldb
1202                 dnl (it could be no, but that would be an error
1203                 if test $ol_cv_lib_db2 != yes ; then
1204                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1205                 fi
1206         fi
1207 fi
1208
1209 ol_link_bdb2=no
1210 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1211         ol_link_bdb2=yes
1212 fi
1213
1214 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1215         OL_BERKELEY_DB
1216
1217         if test $ol_cv_berkeley_db = yes ; then
1218                 ol_link_ldbm=db
1219                 ol_with_ldbm_api=db
1220
1221                 if test $ol_with_ldbm_type = hash ; then
1222                         AC_DEFINE(LDBM_USE_DBHASH,1)
1223                 else
1224                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1225                 fi
1226
1227                 dnl $ol_cv_lib_db should be yes or -ldb
1228                 dnl (it could be no, but that would be an error
1229                 if test $ol_cv_lib_db != yes ; then
1230                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1231                 fi
1232         fi
1233 fi
1234
1235 if test $ol_with_ldbm_api = manual ; then
1236         dnl User thinks he can manually configure LDBM api.
1237         ol_link_ldbm=yes
1238
1239         AC_MSG_WARN([LDBM defines and link options must be set manually])
1240
1241         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1242 fi
1243
1244 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1245         AC_MSG_WARN(Could not find LDBM with BTREE support)
1246         ol_with_ldbm_api=none
1247 fi
1248
1249 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1250         OL_GDBM
1251
1252         if test $ol_cv_gdbm = yes ; then
1253                 ol_link_ldbm=gdbm
1254                 ol_with_ldbm_api=gdbm
1255
1256                 if test $ol_cv_lib_gdbm != yes ; then
1257                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1258                 fi
1259         fi
1260 fi
1261
1262 if test $ol_with_ldbm_api = auto ; then
1263         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1264 elif test $ol_with_ldbm_api = ndbm ; then
1265         OL_NDBM
1266
1267         if test $ol_cv_ndbm = yes ; then
1268                 ol_link_ldbm=ndbm
1269                 ol_with_ldbm_api=ndbm
1270
1271                 if test $ol_cv_lib_ndbm != yes ; then
1272                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1273                 fi
1274         fi
1275 fi
1276
1277 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1278         AC_MSG_WARN(could not find suitable LDBM backend)
1279         if test $ol_enable_ldbm = yes ; then
1280                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1281         fi
1282
1283         AC_MSG_WARN(disabling LDBM)
1284         ol_enable_ldbm=no
1285 fi
1286
1287 if test $ol_enable_wrappers != no ; then
1288         AC_CHECK_HEADERS(tcpd.h)
1289
1290         if test $ac_cv_header_tcpd_h != yes ; then
1291                 have_wrappers=no
1292         else
1293                 AC_CHECK_LIB(wrap, main,
1294                         [have_wrappers=yes], [have_wrappers=no])
1295         fi
1296
1297         if test $have_wrappers = yes ; then
1298                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1299                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1300         else
1301                 AC_MSG_WARN(could not find -lwrap)
1302                 if test $ol_enable_wrappers = yes ; then
1303                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1304                 fi
1305
1306                 AC_MSG_WARN(disabling wrappers support)
1307                 ol_enable_wrappers=no
1308         fi
1309 fi
1310
1311 if test $ol_enable_syslog != no ; then
1312         AC_CHECK_FUNC(openlog)
1313         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1314                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1315         fi
1316         ol_enable_syslog=$ac_cv_func_openlog
1317 fi
1318
1319 if test $ol_enable_dmalloc != no ; then
1320         AC_CHECK_HEADERS(dmalloc.h)
1321         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1322 fi
1323
1324 if test $ol_enable_tcl != no ; then
1325         AC_CHECK_HEADERS(tcl.h)
1326
1327         if test $ac_cv_header_tcl_h != yes ; then
1328                 have_tcl=no
1329         else
1330                 AC_CHECK_LIB(tcl,main,
1331                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1332                         [have_tcl=no])
1333
1334                 if test $have_tcl != yes; then
1335                         AC_CHECK_LIB(tcl7.6,main,
1336                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1337                                 [have_tcl=no])
1338                 fi
1339
1340                 if test $have_tcl != yes; then
1341                         AC_CHECK_LIB(tcl8.0,main,
1342                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1343                                 [have_tcl=no])
1344                 fi
1345         fi
1346
1347         if test $have_tcl != yes ; then
1348                 AC_MSG_WARN([could not find -ltcl])
1349                 if test $ol_enable_tcl = yes ; then
1350                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1351                 fi
1352
1353                 ol_enable_tcl=no
1354         fi
1355 fi
1356
1357 # ud needs termcap (should insert check here)
1358 ol_link_termcap=no
1359 AC_CHECK_HEADERS(termcap.h ncurses.h)
1360
1361 if test $ol_link_termcap = no ; then
1362         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1363         if test $have_termcap = yes ; then
1364                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1365                 ol_link_termcap=yes
1366                 TERMCAP_LIBS=-ltermcap
1367         fi
1368 fi
1369
1370 if test $ol_link_termcap = no ; then
1371         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1372         if test $have_ncurses = yes ; then
1373                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1374                 ol_link_termcap=yes
1375                 TERMCAP_LIBS=-lncurses
1376         fi
1377 fi
1378
1379 if test $ol_link_termcap = no ; then
1380         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1381         TERMCAP_LIBS=
1382 fi
1383
1384 # FreeBSD (and others) have crypt(3) in -lcrypt
1385 if test $ol_enable_crypt != no ; then
1386         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1387                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1388                         have_crypt=yes], [have_crypt=no])])
1389
1390         if test $have_crypt = yes ; then
1391                 AC_DEFINE(HAVE_CRYPT,1)
1392         else
1393                 AC_MSG_WARN(could not find crypt)
1394                 if test $ol_enable_crypt = yes ; then
1395                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1396                 fi
1397
1398                 AC_MSG_WARN(disabling crypt support)
1399                 ol_enable_crypt=no
1400         fi
1401 fi
1402
1403 # FreeBSD (and others) have setproctitle(3) in -lutil
1404 if test $ol_enable_proctitle != no ; then
1405         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1406                 AC_CHECK_LIB(util, setproctitle,
1407                         [have_setproctitle=yes
1408                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1409                         [have_setproctitle=no
1410                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1411
1412         if test $have_setproctitle = yes ; then
1413                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1414         fi
1415 fi
1416
1417 dnl ----------------------------------------------------------------
1418 dnl Checks for header files.
1419 AC_HEADER_STDC
1420
1421 if test $ac_cv_header_stdc != yes; then
1422         AC_MSG_WARN([could not Standard C compliant headers])
1423 fi
1424
1425 AC_HEADER_DIRENT
1426 AC_HEADER_SYS_WAIT
1427 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1428 if test $am_cv_sys_posix_termios = yes ; then
1429         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1430                 [define if you have POSIX termios])
1431 fi
1432
1433 AC_CHECK_HEADERS(       \
1434         arpa/nameser.h  \
1435         crypt.h                 \
1436         errno.h                 \
1437         fcntl.h                 \
1438         filio.h                 \
1439         getopt.h                \
1440         libutil.h               \
1441         limits.h                \
1442         locale.h                \
1443         malloc.h                \
1444         memory.h                \
1445         regex.h                 \
1446         psap.h                  \
1447         pwd.h                   \
1448         resolv.h                \
1449         sgtty.h                 \
1450         stdarg.h                \
1451         stddef.h                \
1452         string.h                \
1453         strings.h               \
1454         sysexits.h              \
1455         sys/file.h              \
1456         sys/filio.h             \
1457         sys/errno.h             \
1458         sys/ioctl.h             \
1459         sys/param.h             \
1460         sys/resource.h  \
1461         sys/socket.h    \
1462         sys/syslog.h    \
1463         sys/time.h              \
1464         sys/types.h             \
1465         syslog.h                \
1466         termios.h               \
1467         unistd.h                \
1468 )
1469
1470 dnl ----------------------------------------------------------------
1471 dnl Checks for typedefs, structures, and compiler characteristics.
1472 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1473 AC_TYPE_MODE_T
1474 AC_TYPE_OFF_T
1475 AC_TYPE_PID_T
1476 AM_TYPE_PTRDIFF_T
1477 AC_TYPE_SIGNAL
1478 OL_TYPE_SIG_ATOMIC_T
1479 AC_TYPE_SIZE_T
1480 AC_STRUCT_ST_BLKSIZE
1481 AC_HEADER_TIME
1482 AC_STRUCT_TM
1483
1484 OL_C_UPPER_LOWER
1485 AC_C_CONST
1486 OL_C_VOLATILE
1487
1488 if test $cross_compiling = yes ; then
1489         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1490 else
1491         AC_C_BIGENDIAN
1492         AC_CHECK_SIZEOF(short)
1493         AC_CHECK_SIZEOF(int)
1494         AC_CHECK_SIZEOF(long)
1495 fi
1496
1497 dnl ----------------------------------------------------------------
1498 dnl Checks for library functions.
1499 AC_FUNC_MEMCMP
1500 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1501 AC_FUNC_STRFTIME
1502 dnl AM_FUNC_STRTOD
1503 AC_FUNC_VPRINTF
1504
1505 if test $ac_cv_func_vprintf = yes ; then
1506         dnl check for vsnprintf
1507         AC_CHECK_FUNCS(vsnprintf vsprintf)
1508 fi
1509
1510 AC_CHECK_FUNCS(         \
1511         bcopy                   \
1512         flock                   \
1513         getdtablesize   \
1514         gethostname             \
1515         getpwuid                \
1516         gettimeofday    \
1517         lockf                   \
1518         memcpy                  \
1519         memmove                 \
1520         mkstemp                 \
1521         select                  \
1522         setpwfile               \
1523         setsid                  \
1524         signal                  \
1525         sigset                  \
1526         snprintf                \
1527         socket                  \
1528         strdup                  \
1529         strerror                \
1530         strpbrk                 \
1531         strrchr                 \
1532         strsep                  \
1533         strstr                  \
1534         strtol                  \
1535         strtoul                 \
1536         strspn                  \
1537         sysconf                 \
1538         waitpid                 \
1539 )
1540
1541 # these functions are required to build a thread_safe -lldap
1542 AC_CHECK_FUNCS(         \
1543         ctime_r                 \
1544         gethostbyaddr_r \
1545         gethostbyname_r \
1546 )
1547
1548 if test "$ac_cv_func_ctime_r" = yes ; then
1549         OL_FUNC_CTIME_R_NARGS
1550 else
1551         ol_cv_func_ctime_r=0
1552 fi
1553
1554 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1555         OL_FUNC_GETHOSTBYNAME_R_NARGS
1556 else
1557         ol_cv_func_gethostbyname_r=0
1558 fi
1559
1560 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1561         OL_FUNC_GETHOSTBYADDR_R_NARGS
1562 else
1563         ol_cv_func_gethostbyaddr_r=0
1564 fi
1565
1566 if test "$ac_cv_func_ctime_r" = yes \
1567         -a "$ol_cv_func_ctime_r_nargs" -ge 2 -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1568         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1569         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1570         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1571         -a "$ac_cv_func_gethostbyname_r" = yes \
1572         ; then
1573
1574         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT, 1)
1575 fi
1576
1577 if test $ol_link_threads != no ; then
1578         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE, 1)
1579 fi
1580
1581 dnl We actually may need to replace more than this.
1582 AC_REPLACE_FUNCS(getopt tempnam)
1583
1584 dnl ----------------------------------------------------------------
1585 # Check Configuration
1586 OL_SYS_ERRLIST
1587
1588 dnl ----------------------------------------------------------------
1589 dnl Sort out defines
1590
1591 if test "$ol_enable_debug" != no ; then
1592         AC_DEFINE(LDAP_DEBUG,1)
1593 fi
1594 if test "$ol_enable_syslog" = yes ; then
1595         AC_DEFINE(LDAP_SYSLOG,1)
1596 fi
1597 if test "$ol_enable_libui" = yes ; then
1598         AC_DEFINE(LDAP_LIBUI,1)
1599 fi
1600 if test "$ol_enable_cache" = no ; then
1601         AC_DEFINE(LDAP_NOCACHE,1)
1602 fi
1603 if test "$ol_enable_dns" != no ; then
1604         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1605 fi
1606 if test "$ol_enable_proctitle" != no ; then
1607         AC_DEFINE(LDAP_PROCTITLE,1)
1608 fi
1609 if test "$ol_enable_referrals" != no ; then
1610         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1611 fi
1612 if test "$ol_enable_cldap" != no ; then
1613         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1614 fi
1615
1616 if test "$ol_enable_aclgroups" != no ; then
1617         AC_DEFINE(SLAPD_ACLGROUPS,1)
1618 fi
1619 if test "$ol_enable_crypt" != no ; then
1620         AC_DEFINE(SLAPD_CRYPT,1)
1621 fi
1622 if test "$ol_enable_cleartext" != no ; then
1623         AC_DEFINE(SLAPD_CLEARTEXT,1)
1624 fi
1625 if test "$ol_enable_phonetic" != no ; then
1626         AC_DEFINE(SLAPD_PHONETIC,1)
1627 fi
1628 if test "$ol_enable_rlookups" != no ; then
1629         AC_DEFINE(SLAPD_RLOOKUPS,1)
1630 fi
1631
1632 if test "$ol_link_bdb2" != no ; then
1633         AC_DEFINE(SLAPD_BDB2,1)
1634         BUILD_SLAPD=yes
1635         BUILD_BDB2=yes
1636 fi
1637
1638 if test "$ol_link_ldbm" != no ; then
1639         AC_DEFINE(SLAPD_LDBM,1)
1640         BUILD_SLAPD=yes
1641         BUILD_LDBM=yes
1642 fi
1643
1644 if test "$ol_enable_passwd" != no ; then
1645         AC_DEFINE(SLAPD_PASSWD,1)
1646         BUILD_SLAPD=yes
1647         BUILD_PASSWD=yes
1648 fi
1649
1650 if test "$ol_enable_perl" != no ; then
1651         AC_DEFINE(SLAPD_PERL,1)
1652         BUILD_SLAPD=yes
1653         BUILD_PERL=yes
1654 fi
1655
1656 if test "$ol_enable_shell" != no ; then
1657         AC_DEFINE(SLAPD_SHELL,1)
1658         BUILD_SLAPD=yes
1659         BUILD_SHELL=yes
1660 fi
1661
1662 if test "$ol_enable_tcl" != no ; then
1663         AC_DEFINE(SLAPD_TCL,1)
1664         BUILD_SLAPD=yes
1665         BUILD_TCL=yes
1666 fi
1667
1668 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1669         $BUILD_SLAPD = yes ; then
1670         BUILD_SLURPD=yes
1671 fi
1672
1673 if test "$ol_link_isode" != no ; then
1674         BUILD_LDAPD=yes
1675 fi
1676
1677 dnl ----------------------------------------------------------------
1678
1679 AC_SUBST(BUILD_LDAPD)
1680 AC_SUBST(BUILD_SLAPD)
1681   AC_SUBST(BUILD_BDB2)
1682   AC_SUBST(BUILD_LDBM)
1683   AC_SUBST(BUILD_PASSWD)
1684   AC_SUBST(BUILD_PERL)
1685   AC_SUBST(BUILD_SHELL)
1686   AC_SUBST(BUILD_TCL)
1687 AC_SUBST(BUILD_SLURPD)
1688
1689 AC_SUBST(LDAP_LIBS)
1690 AC_SUBST(LDAPD_LIBS)
1691 AC_SUBST(SLAPD_LIBS)
1692 AC_SUBST(SLURPD_LIBS)
1693 AC_SUBST(LDBM_LIBS)
1694 AC_SUBST(LTHREAD_LIBS)
1695 AC_SUBST(LUTIL_LIBS)
1696
1697 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1698 AC_SUBST(SLAPD_PERL_LDFLAGS)
1699
1700 AC_SUBST(KRB_LIBS)
1701 AC_SUBST(TERMCAP_LIBS)
1702 AC_SUBST(TLS_LIBS)
1703
1704 dnl ----------------------------------------------------------------
1705 dnl final output
1706 dnl
1707
1708 AC_OUTPUT( \
1709 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1710 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1711 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1712 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1713 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1714 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1715 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1716 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1717 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1718 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1719 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1720 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1721 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1722 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1723 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1724 include/Makefile:build/top.mk:include/Makefile.in \
1725 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1726 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1727 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1728 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1729 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1730 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1731 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1732 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1733 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1734 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1735 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1736 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1737 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1738 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1739 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1740 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1741 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1742 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1743 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1744 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1745 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1746 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1747 ,[
1748 date > stamp-h
1749 echo Please \"make depend\" to build dependencies
1750 ])