git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Copying restrictions apply, see COPYRIGHT file."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35 AC_CONFIG_AUX_DIR(build)dnl
  36
  37 OL_VERSION=`cat $ac_aux_dir/version`
  38 if test -z "$OL_VERSION"; then
  39         AC_MSG_ERROR([could not determine version])
  40 fi
  41
  42 echo "Configuring OpenLDAP $OL_VERSION ..."
  43
  44 dnl Determine host platform
  45 dnl             we try not to use this for much
  46 AC_CANONICAL_SYSTEM
  47
  48 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  49 AC_SUBST(PACKAGE)
  50 AC_SUBST(VERSION)
  51 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  52 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  53
  54 dnl We use autoconf features new to 2.13.
  55 dnl aclocal.m4 should be built using aclocal from automake 1.4
  56 dnl libtool 1.3.3 should be installed.
  57 AC_PREREQ(2.13)dnl Required Autoconf version
  58
  59 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  60
  61 dnl ================================================================
  62 dnl Start Args
  63 AC_MSG_CHECKING(configure arguments)
  64 AC_PREFIX_DEFAULT(/usr/local)
  65
  66 top_builddir=`pwd`
  67 AC_SUBST(top_builddir)dnl
  68
  69 dnl ----------------------------------------------------------------
  70 dnl --with-subdir
  71 ldap_subdir="/openldap"
  72
  73 AC_ARG_WITH(subdir,
  74 [  --with-subdir=DIR change default subdirectory used for installs],
  75 [case "$withval" in
  76         no) ldap_subdir=""
  77                 ;;
  78         yes)
  79                 ;;
  80         /*|\\*)
  81                 ldap_subdir="$withval"
  82                 ;;
  83         *)
  84                 ldap_subdir="/$withval"
  85                 ;;
  86 esac
  87 ])dnl
  88
  89 AC_SUBST(ldap_subdir)dnl
  90
  91 dnl ----------------------------------------------------------------
  92 dnl General "enable" options
  93 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  94 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  95 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  96 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  97 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  98 OL_ARG_ENABLE(kbind,[  --enable-kbind   enable V2 Kerberos IV bind], auto)dnl
  99 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
 100 OL_ARG_ENABLE(ldapi,[  --enable-ldapi   enable domain socket (PF_LOCAL) ldap], no)dnl
 101 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
 102         no, [yes no])dnl
 103
 104 dnl ----------------------------------------------------------------
 105 dnl General "with" options
 106 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc   enable debug malloc support], no)dnl
 107
 108 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
 109         auto, [auto yes no] )
 110 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
 111         auto, [auto yes no] )
 112 OL_ARG_WITH(kerberos,[  --with-kerberos with support],
 113         auto, [auto k5 k5only k425 kth k4 afs yes no])
 114 OL_ARG_WITH(readline,[  --with-readline with readline support],
 115         auto, [auto yes no] )
 116 OL_ARG_WITH(threads,[  --with-threads   use threads],
 117         auto, [auto nt posix mach pth lwp yes no manual] )
 118 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
 119         auto, [auto ssleay openssl yes no] )
 120 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
 121         auto, [auto yes no manual] )
 122
 123 dnl ----------------------------------------------------------------
 124 dnl Server options
 125 dnl ----------------------------------------------------------------
 126
 127 dnl ----------------------------------------------------------------
 128 dnl SLAPD OPTIONS
 129 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 130 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 131 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 132 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 133 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd     enable kerberos password verification], no)dnl
 134 OL_ARG_ENABLE(spasswd,[    --enable-spasswd     enable (Cyrus) SASL password verification], no)dnl
 135 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 136 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 137 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 138 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 139 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 140 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 141 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 142 OL_ARG_ENABLE(dynamic,[    --enable-dynamic     enable linking built binaries with dynamic libs], no)dnl
 143
 144 dnl SLAPD Backend options
 145 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 146 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 147         [static dynamic])
 148 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv       enable bdb2 backend], no)dnl
 149 OL_ARG_WITH(dnssrv_module,[      --with-dnssrv-module   module type], static,
 150         [static dynamic])
 151 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 152 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 153         [static dynamic])
 154 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 155 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 156         [auto berkeley bcompat mdbm gdbm])
 157 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 158         [static dynamic])
 159 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 160         [auto btree hash])
 161 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 162 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 163         [static dynamic])
 164 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 165 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 166         [static dynamic])
 167 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 168 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 169         [static dynamic])
 170 OL_ARG_ENABLE(sql,[    --enable-sql     enable sql backend], no)dnl
 171 OL_ARG_WITH(sql_module,[      --with-sql-module module type], static,
 172         [static dynamic])
 173 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 174 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 175         [static dynamic])
 176
 177 dnl ----------------------------------------------------------------
 178 dnl SLURPD OPTIONS
 179 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 180 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 181
 182 dnl ----------------------------------------------------------------
 183 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 184 AC_ENABLE_STATIC
 185 dnl AC_DISABLE_SHARED
 186 AC_ENABLE_SHARED
 187
 188 dnl ----------------------------------------------------------------
 189
 190 dnl General "enable" options
 191 # validate options
 192 if test $ol_enable_slapd = no ; then
 193         dnl SLAPD was specificallly disabled
 194         if test $ol_enable_bdb2 = yes ; then
 195                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 196         fi
 197         if test $ol_enable_dnssrv = yes ; then
 198                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 199         fi
 200         if test $ol_enable_ldap = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 202         fi
 203         if test $ol_enable_ldbm = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 205         fi
 206         if test $ol_enable_passwd = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 208         fi
 209         if test $ol_enable_perl = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 211         fi
 212         if test $ol_enable_shell = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 214         fi
 215         if test $ol_enable_tcl = yes ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 217         fi
 218         if test $ol_enable_sql = yes ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 220         fi
 221         if test $ol_enable_modules = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 223         fi
 224         if test $ol_enable_multimaster = yes ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 226         fi
 227         if test $ol_enable_wrappers = yes ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 229         fi
 230         if test $ol_enable_phonetic = yes ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 232         fi
 233         if test $ol_enable_quipu = yes ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 235         fi
 236         if test $ol_enable_rlookups = yes ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 238         fi
 239         if test $ol_enable_aci = yes ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 241         fi
 242         if test $ol_with_ldbm_api != auto ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 244         fi
 245         if test $ol_with_ldbm_type != auto ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 247         fi
 248         if test $ol_with_bdb2_module != static ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 250         fi
 251         if test $ol_with_dnssrv_module != static ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 253         fi
 254         if test $ol_with_ldap_module != static ; then
 255                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 256         fi
 257         if test $ol_with_ldbm_module != static ; then
 258                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 259         fi
 260         if test $ol_with_passwd_module != static ; then
 261                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 262         fi
 263         if test $ol_with_perl_module != static ; then
 264                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 265         fi
 266         if test $ol_with_shell_module != static ; then
 267                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 268         fi
 269         if test $ol_with_tcl_module != static ; then
 270                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 271         fi
 272         if test $ol_with_sql_module != static ; then
 273                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 274         fi
 275         if test $ol_enable_slurpd = yes ; then
 276                 AC_MSG_ERROR([slurpd requires slapd])
 277         fi
 278
 279         # force settings to no
 280         ol_enable_bdb2=no
 281         ol_enable_dnssrv=no
 282         ol_enable_ldap=no
 283         ol_enable_ldbm=no
 284         ol_enable_passwd=no
 285         ol_enable_perl=no
 286         ol_enable_shell=no
 287         ol_enable_tcl=no
 288         ol_enable_sql=no
 289
 290         ol_enable_modules=no
 291         ol_enable_multimaster=no
 292         ol_enable_phonetic=no
 293         ol_enable_quipu=no
 294         ol_enable_rlookups=no
 295         ol_enable_aci=no
 296         ol_enable_wrappers=no
 297         ol_enable_dynamic=no
 298
 299         ol_with_ldbm_api=no
 300         ol_with_ldbm_type=no
 301
 302         ol_with_bdb2_module=static
 303         ol_with_dnssrv_module=static
 304         ol_with_ldap_module=static
 305         ol_with_ldbm_module=static
 306         ol_with_passwd_module=static
 307         ol_with_perl_module=static
 308         ol_with_shell_module=static
 309         ol_with_tcl_module=static
 310         ol_with_sql_module=static
 311
 312         ol_enable_slurpd=no
 313
 314 elif test $ol_enable_ldbm = no ; then
 315         dnl SLAPD without LDBM
 316
 317         if test $ol_with_ldbm_api != auto ; then
 318                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 319         fi
 320
 321         if test $ol_with_ldbm_type != auto ; then
 322                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 323         fi
 324
 325         if test $ol_with_ldbm_module != static ; then
 326                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 327         fi
 328
 329         if test $ol_enable_bdb2 = yes ; then
 330                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 331         fi
 332
 333         if test $ol_enable_modules != yes -a \
 334                 $ol_enable_dnssrv = no -a \
 335                 $ol_enable_ldap = no -a \
 336                 $ol_enable_passwd = no -a \
 337                 $ol_enable_perl = no -a \
 338                 $ol_enable_shell = no -a \
 339                 $ol_enable_sql = no -a \
 340                 $ol_enable_tcl = no ; then
 341                 AC_MSG_ERROR([slapd requires a backend])
 342         fi
 343
 344         ol_with_ldbm_api=no
 345         ol_with_ldbm_type=no
 346         ol_with_ldbm_module=static
 347
 348 elif test $ol_enable_bdb2 = yes ; then
 349         dnl SLAPD with BDB2
 350
 351         if test $ol_with_ldbm_api != auto -a \
 352                 $ol_with_ldbm_api != berkeley ; then
 353                 AC_MSG_ERROR([BDB2 requires LDBM API berkeley or auto])
 354         fi
 355
 356         ol_with_ldbm_api=db2
 357
 358 else
 359         dnl SLAPD with LDBM
 360
 361         if test $ol_enable_bdb2 != no ; then
 362                 if test $ol_with_ldbm_api != auto -a \
 363                         $ol_with_ldbm_api != berkeley ; then
 364                         AC_MSG_WARN([BDB2 requires LDBM api berkeley or auto])
 365                         ol_enable_bdb2=no
 366                 fi
 367         fi
 368
 369         if test $ol_with_ldbm_api = gdbm -a \
 370                 $ol_with_ldbm_type = btree ; then
 371                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 372         fi
 373         if test $ol_with_ldbm_api = mdbm -a \
 374                 $ol_with_ldbm_type = btree ; then
 375                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 376         fi
 377         if test $ol_with_ldbm_api = ndbm -a \
 378                 $ol_with_ldbm_type = btree ; then
 379                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 380         fi
 381 fi
 382
 383 if test $ol_enable_slurpd = yes ; then
 384         dnl SLURPD was specifically enabled
 385         if test $ol_with_threads = no ; then
 386                 AC_MSG_ERROR([slurpd requires threads])
 387         fi
 388 fi
 389
 390 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 391         if test $ol_with_kerberos = no ; then
 392                 AC_MSG_ERROR([options require --with-kerberos])
 393         fi
 394 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 395         if test $ol_with_kerberos != auto ; then
 396                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 397         else
 398                 ol_with_kerberos=no
 399         fi
 400 fi
 401
 402 if test $ol_enable_spasswd = yes ; then
 403         if test $ol_with_cyrus_sasl = no ; then
 404                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 405         fi
 406         ol_link_spasswd=yes
 407 fi
 408
 409 AC_MSG_RESULT(done)
 410
 411 dnl ----------------------------------------------------------------
 412 dnl Initialize vars
 413 LDAP_LIBS=
 414 LDIF_LIBS=
 415 LDBM_LIBS=
 416 LTHREAD_LIBS=
 417 LUTIL_LIBS=
 418
 419 QUIPU_LIBS=
 420 SLAPD_LIBS=
 421 SLURPD_LIBS=
 422
 423 BUILD_SLAPD=no
 424 BUILD_SLURPD=no
 425
 426 BUILD_QUIPU=no
 427 BUILD_THREAD=no
 428
 429 BUILD_BDB2=no
 430 BUILD_DNSSRV=no
 431 BUILD_LDAP=no
 432 BUILD_LDBM=no
 433 BUILD_PASSWD=no
 434 BUILD_PERL=no
 435 BUILD_SHELL=no
 436 BUILD_SQL=no
 437 BUILD_TCL=no
 438
 439 BUILD_BDB2_DYNAMIC=static
 440 BUILD_DNSSRV_DYNAMIC=static
 441 BUILD_LDAP_DYNAMIC=static
 442 BUILD_LDBM_DYNAMIC=static
 443 BUILD_PASSWD_DYNAMIC=static
 444 BUILD_PERL_DYNAMIC=static
 445 BUILD_SHELL_DYNAMIC=static
 446 BUILD_TCL_DYNAMIC=static
 447 BUILD_SQL_DYNAMIC=static
 448
 449 SLAPD_MODULES_LDFLAGS=
 450 SLAPD_MODULES_CPPFLAGS=
 451 SLAPD_MODULES_LIST=
 452
 453 SLAPD_PERL_LDFLAGS=
 454 MOD_PERL_LDFLAGS=
 455 PERL_CPPFLAGS=
 456
 457 SLAPD_SQL_LDFLAGS=
 458 SLAPD_SQL_LIBS=
 459 SLAPD_SQL_INCLUDES=
 460
 461 MOD_TCL_LIB=
 462 KRB4_LIBS=
 463 KRB5_LIBS=
 464 READLINE_LIBS=
 465 SASL_LIBS=
 466 TERMCAP_LIBS=
 467 TLS_LIBS=
 468 MODULES_LIBS=
 469 AUTH_LIBS=
 470
 471 dnl ================================================================
 472 dnl Checks for programs
 473
 474 dnl AC_PROG_INSTALL
 475
 476 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 477
 478 dnl ----------------------------------------------------------------
 479 dnl
 480 dnl Determine which C translator to use
 481 dnl
 482
 483 dnl AIX Thread requires we use cc_r or xlc_r.
 484 dnl But only do this IF AIX and CC is not set
 485 dnl and threads are auto|yes|posix.
 486 dnl
 487 dnl If we find cc_r|xlc_r, force pthreads and assume
 488 dnl             pthread_create is in $LIBS (ie: don't bring in
 489 dnl             any additional thread libraries)
 490 dnl If we do not find cc_r|xlc_r, disable threads
 491
 492 ol_aix_threads=no
 493 case "$target" in
 494 *-*-aix*) dnl all AIX is not a good idea.
 495         if test -z "$CC" ; then
 496                 case "$ol_with_threads" in
 497                 auto | yes |  posix) ol_aix_threads=yes ;;
 498                 esac
 499         fi
 500 ;;
 501 esac
 502
 503 if test $ol_aix_threads = yes ; then
 504         if test -z "${CC}" ; then
 505                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 506
 507                 if test "$CC" = cc ; then
 508                         dnl no CC! don't allow --with-threads
 509                         if test $ol_with_threads != auto ; then
 510                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 511                         else
 512                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 513                         fi
 514                         ol_with_threads=no
 515                 fi
 516         fi
 517
 518         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 519                 ol_with_threads=posix
 520                 ol_cv_pthread_create=yes
 521         fi
 522 fi
 523
 524 if test -z "${CC}"; then
 525         AC_CHECK_PROGS(CC,cc)
 526 fi
 527
 528 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 529 dnl (for now, let autoconf sort this out)
 530 dnl CFLAGS=${CFLAGS-""}
 531
 532 AC_LIBTOOL_WIN32_DLL
 533 AC_LIBTOOL_DLOPEN
 534 AC_PROG_LIBTOOL
 535
 536 AC_PROG_AWK
 537 OL_PROG_LN_H
 538 AC_PROG_LN_S
 539
 540 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 541         LN_S="$LN_H"
 542 fi
 543
 544 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 545         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 546 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 547 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 548
 549 dnl ----------------------------------------------------------------
 550 dnl Perl
 551 ol_link_perl=no
 552 if test $ol_enable_perl != no ; then
 553         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 554
 555         if test "no$PERLBIN" = "no" ; then
 556                 if test $ol_enable_perl = yes ; then
 557                         AC_MSG_ERROR([could not locate perl])
 558                 fi
 559
 560         else
 561                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 562                 if test x"$ol_with_perl_module" = "xstatic" ; then
 563                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 564                 else
 565                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 566                 fi
 567                 dnl should check perl version
 568                 ol_link_perl=yes
 569         fi
 570 fi
 571
 572 AC_PROG_CPP
 573
 574 dnl ----------------------------------------------------------------
 575 dnl Cross compiling checks
 576 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 577         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 578
 579 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 580         AC_MSG_WARN([programs compiled here do run here...])
 581         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 582
 583 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 584         AC_MSG_WARN([programs compiled here do not run here...])
 585         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 586 fi
 587
 588 dnl ----------------------------------------------------------------
 589 dnl Checks for UNIX Variants
 590 AC_AIX
 591 AC_ISC_POSIX
 592 AC_MINIX
 593
 594 dnl ----------------------------------------------------------------
 595 dnl Checks for system services
 596 AC_CYGWIN
 597 AC_MINGW32
 598 AC_EXEEXT
 599 AC_OBJEXT
 600
 601 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 602
 603 dnl ----------------------------------------------------------------
 604 dnl BeOS requires -lbe -lroot -lnet
 605 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 606
 607 dnl ----------------------------------------------------------------
 608 dnl OpenLDAP requires STDC features
 609 AM_PROG_CC_STDC
 610 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 611         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 612 fi
 613
 614 dnl ----------------------------------------------------------------
 615 dnl Check cc depend flags
 616 OL_MKDEPEND
 617 if test "${ol_cv_mkdep}" = no ; then
 618         # this will soon become an error
 619         AC_MSG_WARN([do not know how to generate dependencies])
 620 fi
 621
 622 dnl ----------------------------------------------------------------
 623 dnl Check for AIX security library
 624 AC_CHECK_LIB(s, afopen, [
 625         AUTH_LIBS=-ls
 626         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 627 ])
 628
 629 dnl ----------------------------------------------------------------
 630 dnl Check for module support
 631 ol_link_modules=no
 632 if test $ol_enable_modules != no ; then
 633         AC_CHECK_HEADERS(ltdl.h)
 634
 635         if test $ac_cv_header_ltdl_h = no ; then
 636                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 637         fi
 638
 639         AC_CHECK_LIB(ltdl, lt_dlinit, [
 640             MODULES_LIBS=-lltdl
 641             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 642         ])
 643
 644         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 645                 AC_MSG_ERROR([could not locate libtool -lltdl])
 646         fi
 647         ol_link_modules=yes
 648 else
 649         ol_with_bdb2_module=static
 650         ol_with_dnssrv_module=static
 651         ol_with_ldap_module=static
 652         ol_with_ldbm_module=static
 653         ol_with_passwd_module=static
 654         ol_with_perl_module=static
 655         ol_with_shell_module=static
 656         ol_with_tcl_module=static
 657         ol_with_sql_module=static
 658 fi
 659
 660 dnl ----------------------------------------------------------------
 661 dnl Checks for header files.
 662 OL_HEADER_STDC
 663
 664 if test $ol_cv_header_stdc != yes; then
 665         AC_MSG_WARN([could not locate Standard C compliant headers])
 666 fi
 667
 668 AC_HEADER_DIRENT
 669 AC_HEADER_SYS_WAIT
 670 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 671 if test $am_cv_sys_posix_termios = yes ; then
 672         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 673                 [define if you have POSIX termios])
 674 fi
 675
 676 AC_CHECK_HEADERS(       \
 677         arpa/inet.h             \
 678         arpa/nameser.h  \
 679         assert.h                \
 680         conio.h                 \
 681         crypt.h                 \
 682         direct.h                \
 683         errno.h                 \
 684         fcntl.h                 \
 685         filio.h                 \
 686         getopt.h                \
 687         grp.h                   \
 688         io.h                    \
 689         libutil.h               \
 690         limits.h                \
 691         locale.h                \
 692         netinet/tcp.h   \
 693         malloc.h                \
 694         memory.h                \
 695         psap.h                  \
 696         pwd.h                   \
 697         process.h               \
 698         resolv.h                \
 699         sgtty.h                 \
 700         shadow.h                \
 701         stddef.h                \
 702         string.h                \
 703         strings.h               \
 704         sysexits.h              \
 705         sys/file.h              \
 706         sys/filio.h             \
 707         sys/errno.h             \
 708         sys/ioctl.h             \
 709         sys/param.h             \
 710         sys/resource.h  \
 711         sys/select.h    \
 712         sys/socket.h    \
 713         sys/syslog.h    \
 714         sys/time.h              \
 715         sys/types.h             \
 716         syslog.h                \
 717         termios.h               \
 718         unistd.h                \
 719         winsock.h               \
 720 )
 721
 722
 723 dnl ----------------------------------------------------------------
 724 dnl Checks for libraries
 725
 726 dnl HP-UX requires -lV3
 727 AC_CHECK_LIB(V3, sigset)
 728
 729 dnl Gotta check for winsock manually
 730 if test $ac_cv_header_winsock_h = yes; then
 731         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 732         AC_TRY_LINK([#include <winsock.h>],[
 733                         socket(0,0,0);
 734                         select(0,NULL,NULL,NULL,NULL);
 735                         closesocket(0);
 736                         gethostname(NULL,0);
 737         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 738
 739         if test $ol_cv_winsock = yes ; then
 740                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 741                 ac_cv_func_socket=yes
 742                 ac_cv_func_select=yes
 743                 ac_cv_func_closesocket=yes
 744                 ac_cv_func_gethostname=yes
 745         fi
 746 fi
 747
 748 dnl Find socket()
 749 dnl Likely combinations:
 750 dnl             -lsocket [ -lnsl_s | -lnsl ]
 751 dnl             -linet
 752
 753 AC_CHECK_FUNC(socket, :, [
 754 dnl hopefully we won't include too many libraries
 755         AC_CHECK_LIB(socket, main)
 756         AC_CHECK_LIB(net, main)
 757         AC_CHECK_LIB(nsl_s, main)
 758         AC_CHECK_LIB(nsl, main)
 759         AC_CHECK_LIB(inet, socket)
 760         AC_CHECK_LIB(gen, main)
 761 ])
 762
 763 dnl require select
 764 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 765
 766 if test "${ac_cv_header_winsock_h}" != yes; then
 767     dnl Select arg types
 768     dnl (if this detection becomes permenent, it and the select() detection
 769     dnl should be done before the yielding select test)
 770     AC_FUNC_SELECT_ARGTYPES
 771 fi
 772
 773 dnl check to see if system call automatically restart
 774 dnl AC_SYS_RESTARTABLE_SYSCALLS
 775
 776 dnl ----------------------------------------------------------------
 777 dnl require POSIX regex
 778 AC_CHECK_HEADERS( regex.h )
 779 if test "$ac_cv_header_regex_h" != yes ; then
 780         AC_MSG_ERROR([POSIX regex.h required.])
 781 fi
 782 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 783
 784 OL_POSIX_REGEX
 785 if test "$ol_cv_c_posix_regex" = no ; then
 786         AC_MSG_ERROR([broken POSIX regex!])
 787 fi
 788
 789 dnl ----------------------------------------------------------------
 790 dnl Check for resolver routines
 791 ol_link_dnssrv=no
 792 AC_CHECK_FUNC(res_query,:)
 793 if test $ac_cv_func_res_query = no ; then
 794         AC_CHECK_LIB(bind, res_query)
 795         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 796 fi
 797
 798 if test $ac_cv_func_res_query = no ; then
 799         AC_CHECK_LIB(bind, __res_query)
 800         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 801 fi
 802
 803 if test $ac_cv_func_res_query = no ; then
 804         AC_CHECK_LIB(resolv, res_query)
 805         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 806 fi
 807
 808 if test "$ac_cv_func_res_query" = yes ; then
 809         AC_DEFINE(HAVE_RES_QUERY,1,
 810                 [define if you have res_query()])
 811
 812         if test $ol_enable_dnssrv != no ; then
 813                 ol_link_dnssrv=yes
 814         fi
 815 fi
 816
 817 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 818         AC_MSG_ERROR([DNSSRV requires res_query()])
 819 fi
 820
 821 dnl ----------------------------------------------------------------
 822 dnl QUIPU
 823 if test $ol_enable_quipu != no ; then
 824         AC_CHECK_HEADERS(quipu/commonarg.h)
 825
 826         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 827                 BUILD_QUIPU=yes
 828         elif test $ol_enable_quipu = auto ; then
 829                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 830         else
 831                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 832         fi
 833 fi
 834
 835 dnl ----------------------------------------------------------------
 836 dnl Kerberos
 837 ol_link_kbind=no
 838 ol_link_kpasswd=no
 839 ol_link_krb5=no
 840 ol_link_krb4=no
 841
 842 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 \
 843         -o $ol_with_kerberos = k5only -o $ol_with_kerberos = k425 ; then
 844
 845         AC_CHECK_HEADERS(krb5.h)
 846
 847         if test $ac_cv_header_krb5_h = yes ; then
 848                 dnl lazy check for Heimdal Kerberos
 849                 AC_CHECK_HEADERS(heim_err.h)
 850                 if test $ac_cv_header_heim_err_h = yes ; then
 851                         krb5_impl=heimdal
 852                 else
 853                         krb5_impl=mit
 854                 fi
 855
 856                 if test $krb5_impl = mit; then
 857                         AC_CHECK_LIB(krb5, main,
 858                                 [have_krb5=yes
 859                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 860                                 [have_krb5=no],
 861                                 [-lcrypto -lcom_err])
 862
 863                 elif test $krb5_impl = heimdal; then
 864                         AC_CHECK_LIB(krb5, main,
 865                                 [have_krb5=yes
 866                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 867                                 [have_krb5=no],
 868                                 [-ldes -lasn1 -lroken -lcom_err])
 869
 870                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 871                                 [define if you have HEIMDAL Kerberos])
 872                 else
 873                         have_krb5=no
 874                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 875                 fi
 876
 877                 if test $have_krb5 = yes ; then
 878                         ol_link_krb5=yes
 879
 880                         AC_DEFINE(HAVE_KRB5, 1,
 881                                 [define if you have Kerberos V])
 882
 883                         if test $ol_enable_kpasswd != no ; then
 884                                 ol_link_kpasswd=yes;
 885                         fi
 886
 887                         if test $ol_with_kerberos = k5only ; then
 888                                 ol_with_kerberos=found
 889                         fi
 890
 891                 elif test $ol_with_kerberos != auto ; then
 892                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 893                 fi
 894
 895         fi
 896 fi
 897
 898 if test $ol_link_krb5 = yes -a \
 899         \( $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 900
 901         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 902
 903         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 904                 if test $krb5_impl = mit; then
 905                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 906                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 907                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 908
 909                 elif test $krb5_impl = heimdal; then
 910                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 911                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 912                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 913
 914                 else
 915                         have_425=no
 916                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 917                 fi
 918
 919                 if test $have_k425 = yes ; then
 920                         ol_with_kerberos=found
 921                         ol_link_krb4=yes
 922
 923                         AC_DEFINE(HAVE_KRB425, 1,
 924                                 [define if you have Kerberos V with IV support])
 925                         AC_DEFINE(HAVE_KRB4, 1,
 926                                 [define if you have Kerberos IV])
 927
 928                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 929                                 [ol_cv_var_des_debug], [
 930                                 dnl save the flags
 931                                 save_LIBS="$LIBS"
 932                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 933                                 AC_TRY_LINK([
 934 #include <kerberosIV/krb.h>
 935 #include <kerberosIV/des.h>
 936 extern int des_debug;
 937 ],[
 938 des_debug = 1;
 939 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 940                                 dnl restore the LIBS
 941                                 LIBS="$save_LIBS"
 942                         ])
 943
 944                         if test $ol_cv_var_des_debug = yes ; then
 945                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 946                                         [define if you have Kerberos des_debug])
 947                         fi
 948
 949                         LIBS="$save_LIBS"
 950                 fi
 951         fi
 952 fi
 953
 954 if test $ol_link_krb5 = yes ; then
 955         ol_with_kerberos=found
 956 fi
 957
 958 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 \
 959         -o $ol_with_kerberos = kth ; then
 960
 961         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 962
 963         if test $ac_cv_header_krb_h = yes ; then
 964                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 965
 966                 if test $have_k4 = yes ; then
 967                         ol_with_kerberos=found
 968                         ol_link_krb4=yes
 969
 970                         AC_DEFINE(HAVE_KRB4, 1,
 971                                 [define if you have Kerberos IV])
 972
 973                         KRB4_LIBS="-lkrb -ldes"
 974
 975                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 976                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 977                                         [define if you have Kth Kerberos])
 978                         fi
 979                 fi
 980         fi
 981 fi
 982
 983 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 984         ol_link_kpasswd=yes;
 985 fi
 986
 987 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 988         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 989
 990 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 991         AC_MSG_ERROR([Kerberos detection failed.])
 992 fi
 993
 994 dnl ----------------------------------------------------------------
 995 dnl TLS/SSL
 996 ol_link_tls=no
 997 if test $ol_with_tls != no ; then
 998
 999         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
1000
1001         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
1002                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
1003                         [have_ssleay=yes
1004                         need_rsaref=no],
1005                         [have_ssleay=no],
1006                         [-lcrypto])
1007
1008                 if test $have_ssleay = no ; then
1009                         AC_CHECK_LIB(ssl, SSL_library_init,
1010                                 [have_ssleay=yes
1011                                 need_rsaref=no], [have_ssleay=no],
1012                                 [-lcrypto])
1013                 fi
1014
1015                 if test $have_ssleay = no ; then
1016                         AC_CHECK_LIB(ssl, ssl3_accept,
1017                                 [have_ssleay=yes
1018                                 need_rsaref=yes], [have_ssleay=no],
1019                                 [-lcrypto -lRSAglue -lrsaref])
1020                 fi
1021
1022                 if test $have_ssleay = yes ; then
1023                         ol_with_tls=found
1024                         ol_link_tls=yes
1025
1026                         AC_DEFINE(HAVE_SSLEAY, 1,
1027                                 [define if you have SSLeay or OpenSSL])
1028
1029                         if test $need_rsaref = yes; then
1030                                 AC_DEFINE(HAVE_RSAREF, 1,
1031                                         [define if you have RSAref])
1032
1033                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1034                         else
1035                                 TLS_LIBS="-lssl -lcrypto"
1036                         fi
1037                 fi
1038         fi
1039 fi
1040
1041 if test $ol_link_tls = yes ; then
1042         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1043 fi
1044
1045 dnl ----------------------------------------------------------------
1046 dnl Tests for reentrant functions necessary to build a
1047 dnl thread_safe -lldap.
1048 AC_CHECK_FUNCS(         \
1049         ctime_r                 \
1050         gethostbyname_r gethostbyaddr_r \
1051 )
1052
1053 if test "$ac_cv_func_ctime_r" = no ; then
1054         ol_cv_func_ctime_r_nargs=0
1055 else
1056         OL_FUNC_CTIME_R_NARGS
1057 dnl     OL_FUNC_CTIME_R_TYPE
1058 fi
1059
1060 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1061         OL_FUNC_GETHOSTBYNAME_R_NARGS
1062 else
1063         ol_cv_func_gethostbyname_r_nargs=0
1064 fi
1065
1066 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1067         OL_FUNC_GETHOSTBYADDR_R_NARGS
1068 else
1069         ol_cv_func_gethostbyaddr_r_nargs=0
1070 fi
1071
1072 if test "$ac_cv_func_ctime_r" = yes \
1073         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1074         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1075         -a "$ac_cv_func_gethostbyname_r" = yes \
1076         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1077         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1078         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1079         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1080         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1081         ; then
1082
1083         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1084 fi
1085
1086 dnl ----------------------------------------------------------------
1087 dnl Threads?
1088 ol_link_threads=no
1089
1090 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1091         -o $ol_with_threads = nt ; then
1092
1093         OL_NT_THREADS
1094
1095         if test "$ol_cv_nt_threads" = yes ; then
1096         ol_link_threads=nt
1097         ol_with_threads=found
1098         ol_with_yielding_select=yes
1099
1100                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1101                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1102         fi
1103
1104         if test $ol_with_threads = nt ; then
1105                 AC_MSG_ERROR([could not locate NT Threads])
1106         fi
1107 fi
1108
1109 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1110         -o $ol_with_threads = posix ; then
1111
1112         AC_CHECK_HEADERS(pthread.h)
1113
1114         if test $ac_cv_header_pthread_h = yes ; then
1115                 OL_POSIX_THREAD_VERSION
1116
1117                 if test $ol_cv_pthread_version = final ; then
1118                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1119                                 [define if pthreads API compatible with final spec])
1120                 elif test $ol_cv_pthread_version = draft4 ; then
1121                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1122                                 [define if pthreads API compatible with draft4 spec])
1123                 else
1124                         AC_MSG_ERROR([unknown pthread version])
1125                 fi
1126
1127                 # consider threads found
1128                 ol_with_threads=found
1129
1130                 OL_HEADER_LINUX_THREADS
1131                 OL_HEADER_GNU_PTH_PTHREAD_H
1132
1133                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1134                         AC_CHECK_HEADERS(sched.h)
1135                 fi
1136
1137                 dnl Now the hard part, how to link?
1138                 dnl
1139                 dnl currently supported checks:
1140                 dnl
1141                 dnl Check for no flags
1142                 dnl     pthread_create() in $LIBS
1143                 dnl
1144                 dnl Check special pthread (final) flags
1145                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1146                 dnl     pthread_create() with -kthread (FreeBSD)
1147                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1148                 dnl     pthread_create() with -pthreads (?)
1149                 dnl     pthread_create() with -mthreads (AIX)
1150                 dnl     pthread_create() with -thread (?)
1151                 dnl
1152                 dnl Check pthread (final) libraries
1153                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1154                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1155                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1156                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1157                 dnl     pthread_create() in -lpthread (many)
1158                 dnl     pthread_create() in -lc_r (FreeBSD)
1159                 dnl
1160                 dnl Check pthread (draft4) flags (depreciated)
1161                 dnl     pthread_create() with -threads (OSF/1)
1162                 dnl
1163                 dnl Check pthread (draft4) libraries (depreciated)
1164                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1165                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1166                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1167                 dnl     pthread_create() in -lpthreads (many)
1168                 dnl
1169
1170                 dnl pthread_create in $LIBS
1171                 AC_CACHE_CHECK([for pthread_create in default libraries],
1172                         ol_cv_pthread_create,[
1173                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1174                         [ol_cv_pthread_create=yes],
1175                         [ol_cv_pthread_create=no],
1176                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1177                                 [ol_cv_pthread_create=yes],
1178                                 [ol_cv_pthread_create=no])])])
1179
1180                 if test $ol_cv_pthread_create != no ; then
1181                         ol_link_threads=posix
1182                         ol_link_pthreads=""
1183                 fi
1184
1185 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1186                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1187                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1188                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1189                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1190                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1191
1192                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1193                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1194                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1195                         [ol_cv_pthread_lpthread_lmach_lexc])
1196 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1197 dnl                     [ol_cv_pthread_lpthread_lexc])
1198
1199                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1200                         [ol_cv_pthread_lib_lpthread_woff])
1201
1202                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1203                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1204
1205                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1206
1207                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1208                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1209                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1210                         [ol_cv_pthread_lpthreads_lmach_lexc])
1211                 OL_PTHREAD_TRY([-lpthreads -lexc],
1212                         [ol_cv_pthread_lpthreads_lexc])
1213
1214                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1215
1216                 if test $ol_link_threads != no ; then
1217                         AC_DEFINE(HAVE_PTHREADS,1,
1218                                 [define if you have POSIX Threads])
1219
1220                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1221
1222                         dnl save flags
1223                         save_CPPFLAGS="$CPPFLAGS"
1224                         save_LIBS="$LIBS"
1225                         LIBS="$LTHREAD_LIBS $LIBS"
1226
1227                         dnl All POSIX Thread (final) implementations should have
1228                         dnl sched_yield instead of pthread yield.
1229                         dnl check for both
1230                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1231
1232                         if test $ac_cv_func_sched_yield = no -a \
1233                                 $ac_cv_func_pthread_yield = no ; then
1234                                 dnl Digital UNIX has sched_yield() in -lrt
1235                                 AC_CHECK_LIB(rt, sched_yield,
1236                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1237                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1238                                                 [Define if you have the sched_yield function.])
1239                                         ac_cv_func_sched_yield=yes],
1240                                         [ac_cv_func_sched_yield=no])
1241                         fi
1242                         if test $ac_cv_func_sched_yield = no -a \
1243                                 $ac_cv_func_pthread_yield = no ; then
1244                                 dnl Solaris has sched_yield() stub in -lposix4
1245                                 dnl but we'll use thr_yield instead.
1246                                 AC_CHECK_FUNCS(thr_yield)
1247                         fi
1248                         if test $ac_cv_func_sched_yield = no -a \
1249                                 $ac_cv_func_pthread_yield = no -a \
1250                                 "$ac_cv_func_thr_yield" = no ; then
1251                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1252                         fi
1253
1254                         dnl Check functions for compatibility
1255                         AC_CHECK_FUNCS(pthread_kill)
1256
1257                         dnl Check for pthread_detach with <pthread.h> inclusion
1258                         dnl as it's symbol may have been mangled.
1259                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1260                                 [ol_cv_func_pthread_detach], [
1261                                 dnl save the flags
1262                                 AC_TRY_LINK([
1263 #include <pthread.h>
1264 #ifndef NULL
1265 #define NULL (void*)0
1266 #endif
1267 ],
1268                                         [pthread_detach(NULL);],
1269                                         [ol_cv_func_pthread_detach=yes],
1270                                         [ol_cv_func_pthread_detach=no])
1271                         ])
1272
1273                         if test $ol_cv_func_pthread_detach = no ; then
1274                                 AC_MSG_ERROR([could not locate pthread_detach()])
1275                         fi
1276
1277                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1278                                 [define if you have pthread_detach function])
1279
1280                         dnl Check for setconcurreny functions
1281                         AC_CHECK_FUNCS( \
1282                                 pthread_setconcurrency \
1283                                 pthread_getconcurrency \
1284                                 thr_setconcurrency \
1285                                 thr_getconcurrency \
1286                         )
1287
1288                         OL_SYS_LINUX_THREADS
1289                         OL_LINUX_THREADS
1290
1291                         if test $ol_cv_linux_threads = error; then
1292                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1293                         fi
1294
1295                         AC_CACHE_CHECK([if pthread_create() works],
1296                                 ol_cv_pthread_create_works,[
1297                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1298                                 [ol_cv_pthread_create_works=yes],
1299                                 [ol_cv_pthread_create_works=no],
1300                                 [dnl assume yes
1301                                 ol_cv_pthread_create_works=yes])])
1302
1303                         if test $ol_cv_pthread_create_works = no ; then
1304                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1305                         fi
1306
1307                         dnl Check if select causes an yield
1308                         if test $ol_with_yielding_select = auto ; then
1309                                 AC_CACHE_CHECK([if select yields when using pthreads],
1310                                         ol_cv_pthread_select_yields,[
1311                                 AC_TRY_RUN([
1312 #include <sys/types.h>
1313 #include <sys/time.h>
1314 #include <unistd.h>
1315 #include <pthread.h>
1316 #ifndef NULL
1317 #define NULL (void*) 0
1318 #endif
1319
1320 static int fildes[2];
1321
1322 static void *task(p)
1323         void *p;
1324 {
1325         int i;
1326         struct timeval tv;
1327
1328         fd_set rfds;
1329
1330         tv.tv_sec=10;
1331         tv.tv_usec=0;
1332
1333         FD_ZERO(&rfds);
1334         FD_SET(fildes[0], &rfds);
1335
1336         /* we're not interested in any fds */
1337         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1338
1339         if(i < 0) {
1340                 perror("select");
1341                 exit(10);
1342         }
1343
1344         exit(0); /* if we exit here, the select blocked the whole process */
1345 }
1346
1347 int main(argc, argv)
1348         int argc;
1349         char **argv;
1350 {
1351         pthread_t t;
1352
1353         /* create a pipe to select */
1354         if(pipe(&fildes[0])) {
1355                 perror("select");
1356                 exit(1);
1357         }
1358
1359 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1360         (void) pthread_setconcurrency(2);
1361 #else
1362 #ifdef HAVE_THR_SETCONCURRENCY
1363         /* Set Solaris LWP concurrency to 2 */
1364         thr_setconcurrency(2);
1365 #endif
1366 #endif
1367
1368 #if HAVE_PTHREADS_D4
1369         pthread_create(&t, pthread_attr_default, task, NULL);
1370 #else
1371         pthread_create(&t, NULL, task, NULL);
1372 #endif
1373
1374 #if HAVE_SCHED_YIELD
1375         sched_yield();  /* make sure task runs first */
1376 #else
1377 #ifdef HAVE_PTHREAD_YIELD
1378         pthread_yield();        /* make sure task runs first */
1379 #endif
1380 #endif
1381
1382         exit(2);
1383 }],
1384                                 [ol_cv_pthread_select_yields=no],
1385                                 [ol_cv_pthread_select_yields=yes],
1386                                 [ol_cv_pthread_select_yields=cross])])
1387
1388                                 if test $ol_cv_pthread_select_yields = cross ; then
1389                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1390                                 fi
1391
1392                                 if test $ol_cv_pthread_select_yields = yes ; then
1393                                         ol_with_yielding_select=yes
1394                                 fi
1395                         fi
1396
1397                         dnl restore flags
1398                         CPPFLAGS="$save_CPPFLAGS"
1399                         LIBS="$save_LIBS"
1400                 else
1401                         AC_MSG_ERROR([could not link with POSIX Threads])
1402                 fi
1403         fi
1404
1405         if test $ol_with_threads = posix ; then
1406                 AC_MSG_ERROR([could not locate POSIX Threads])
1407         fi
1408 fi
1409
1410 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1411         -o $ol_with_threads = mach ; then
1412
1413         dnl check for Mach CThreads
1414         AC_CHECK_HEADERS(mach/cthreads.h)
1415         if test $ac_cv_header_mach_cthreads_h = yes ; then
1416                 ol_with_threads=found
1417
1418                 dnl check for cthread support in current $LIBS
1419                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1420
1421                 if test $ol_link_threads = no ; then
1422                         dnl try -all_load
1423                         dnl this test needs work
1424                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1425                                 [ol_cv_cthread_all_load], [
1426                                 dnl save the flags
1427                                 save_LIBS="$LIBS"
1428                                 LIBS="-all_load $LIBS"
1429                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1430                                         cthread_fork((void *)0, (void *)0);
1431                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1432                                 dnl restore the LIBS
1433                                 LIBS="$save_LIBS"
1434                         ])
1435
1436                         if test $ol_cv_cthread_all_load = yes ; then
1437                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1438                                 ol_link_threads=mach
1439                         fi
1440                 fi
1441
1442                 if test $ol_link_threads != no ; then
1443                         : check for cthread specific functionality here
1444                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1445                                 [define if you have Mach Cthreads])
1446                 else
1447                         AC_MSG_ERROR([could not link with Mach CThreads])
1448                 fi
1449         fi
1450
1451         if test $ol_with_threads = mach ; then
1452                 AC_MSG_ERROR([could not locate Mach CThreads])
1453         fi
1454 fi
1455
1456 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1457         -o $ol_with_threads = pth ; then
1458
1459         AC_CHECK_HEADERS(pth.h)
1460
1461         if test $ac_cv_header_pth_h = yes ; then
1462                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1463
1464                 if test $have_pth = yes ; then
1465                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1466                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1467                         ol_link_threads=pth
1468
1469                         if test $ol_with_yielding_select = auto ; then
1470                                 ol_with_yielding_select=yes
1471                         fi
1472                 fi
1473         fi
1474 fi
1475
1476 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1477         -o $ol_with_threads = lwp ; then
1478
1479         dnl check for SunOS5 LWP
1480         AC_CHECK_HEADERS(thread.h synch.h)
1481         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1482                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1483
1484                 if test $have_thr = yes ; then
1485                         AC_DEFINE(HAVE_THR,1,
1486                                 [if you have Solaris LWP (thr) package])
1487                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1488                         ol_link_threads=thr
1489
1490                         if test $ol_with_yielding_select = auto ; then
1491                                 ol_with_yielding_select=yes
1492                         fi
1493
1494                         dnl Check for setconcurreny functions
1495                         AC_CHECK_FUNCS( \
1496                                 thr_setconcurrency \
1497                                 thr_getconcurrency \
1498                         )
1499                 fi
1500         fi
1501
1502         dnl check for SunOS4 LWP
1503         AC_CHECK_HEADERS(lwp/lwp.h)
1504         if test $ac_cv_header_lwp_lwp_h = yes ; then
1505                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1506
1507                 if test $have_lwp = yes ; then
1508                         AC_DEFINE(HAVE_LWP,1,
1509                                 [if you have SunOS LWP package])
1510                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1511                         ol_link_threads=lwp
1512
1513                         if test $ol_with_yielding_select = auto ; then
1514                                 ol_with_yielding_select=no
1515                         fi
1516                 fi
1517         fi
1518 fi
1519
1520 if test $ol_with_yielding_select = yes ; then
1521         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1522                 [define if select implicitly yields])
1523 fi
1524
1525 if test $ol_with_threads = manual ; then
1526         dnl User thinks he can manually configure threads.
1527         ol_link_threads=yes
1528
1529         AC_MSG_WARN([thread defines and link options must be set manually])
1530
1531         AC_CHECK_HEADERS(pthread.h sched.h)
1532         AC_CHECK_FUNCS(sched_yield pthread_yield)
1533         OL_HEADER_LINUX_THREADS
1534
1535         AC_CHECK_HEADERS(mach/cthreads.h)
1536         AC_CHECK_HEADERS(lwp/lwp.h)
1537         AC_CHECK_HEADERS(thread.h synch.h)
1538 fi
1539
1540 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1541         dnl needed to get reentrant/threadsafe versions
1542         dnl
1543         AC_DEFINE(REENTRANT,1)
1544         AC_DEFINE(_REENTRANT,1)
1545         AC_DEFINE(THREAD_SAFE,1)
1546         AC_DEFINE(_THREAD_SAFE,1)
1547         AC_DEFINE(THREADSAFE,1)
1548         AC_DEFINE(_THREADSAFE,1)
1549         AC_DEFINE(_SGI_MP_SOURCE,1)
1550
1551         dnl The errno declaration may dependent upon _REENTRANT.
1552         dnl If it does, we must link with thread support.
1553         AC_CACHE_CHECK([for thread specific errno],
1554                 [ol_cv_errno_thread_specific], [
1555                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1556                         [ol_cv_errno_thread_specific=yes],
1557                         [ol_cv_errno_thread_specific=no])
1558         ])
1559
1560         dnl The h_errno declaration may dependent upon _REENTRANT.
1561         dnl If it does, we must link with thread support.
1562         AC_CACHE_CHECK([for thread specific h_errno],
1563                 [ol_cv_h_errno_thread_specific], [
1564                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1565                         [ol_cv_h_errno_thread_specific=yes],
1566                         [ol_cv_h_errno_thread_specific=no])
1567         ])
1568
1569         if test $ol_cv_errno_thread_specific != yes \
1570                 -o $ol_cv_h_errno_thread_specific != yes ; then
1571                 LIBS="$LTHREAD_LIBS $LIBS"
1572                 LTHREAD_LIBS=""
1573         fi
1574
1575 dnl When in thread environment, use
1576 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1577 dnl                     || defined( HAVE_FUNC_R )
1578 dnl                     func_r(...);
1579 dnl             #else
1580 dnl             #       if defined( HAVE_THREADS )
1581 dnl                             /* lock */
1582 dnl             #       endif
1583 dnl                             func(...);
1584 dnl             #       if defined( HAVE_THREADS )
1585 dnl                             /* unlock */
1586 dnl             #       endif
1587 dnl             #endif
1588 dnl
1589 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1590 dnl             _POSIX_REENTRANT_FUNCTIONS
1591 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1592 dnl             _POSIX_THREADSAFE_FUNCTIONS
1593 dnl
1594 dnl             and is currently defined in lthread.h
1595 dnl
1596 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1597 dnl
1598 dnl libldap/*.c should only include <lthread.h> iff
1599 dnl LDAP_R_COMPILE is defined.  ie:
1600 dnl             #ifdef LDAP_R_COMPILE
1601 dnl             #       include LDAP_R_COMPILE
1602 dnl             #endif
1603 dnl
1604 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1605 dnl specifically for compiling the threadsafe version of
1606 dnl     the ldap library (-lldap_r).
1607 dnl
1608 dnl     dnl check for reentrant/threadsafe functions
1609 dnl     dnl
1610 dnl     dnl note: these should only be used when linking
1611 dnl     dnl       with $LTHREAD_LIBS
1612 dnl     dnl
1613 dnl     save_CPPFLAGS="$CPPFLAGS"
1614 dnl     save_LIBS="$LIBS"
1615 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1616 dnl     AC_CHECK_FUNCS( \
1617 dnl             gmtime_r \
1618 dnl             gethostbyaddr_r gethostbyname_r \
1619 dnl             feof_unlocked unlocked_feof \
1620 dnl             putc_unlocked unlocked_putc \
1621 dnl             flockfile ftrylockfile \
1622 dnl     )
1623 dnl     CPPFLAGS="$save_CPPFLAGS"
1624 dnl     LIBS="$save_LIBS"
1625 fi
1626
1627 if test $ol_link_threads = no ; then
1628         if test $ol_with_threads = yes ; then
1629                 AC_MSG_ERROR([no suitable thread support])
1630         fi
1631
1632         if test $ol_with_threads = auto ; then
1633                 AC_MSG_WARN([no suitable thread support, disabling threads])
1634                 ol_with_threads=no
1635         fi
1636
1637         AC_DEFINE(NO_THREADS,1,
1638                 [define if you have (or want) no threads])
1639         LTHREAD_LIBS=""
1640 fi
1641
1642 if test $ol_link_threads != no ; then
1643         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1644 fi
1645
1646 dnl ----------------------------------------------------------------
1647 ol_link_ldbm=no
1648
1649 if test $ol_with_ldbm_api = auto \
1650         -o $ol_with_ldbm_api = berkeley \
1651         -o $ol_with_ldbm_api = bcompat ; then
1652
1653         if test $ol_with_ldbm_api = bcompat; then \
1654                 OL_BERKELEY_COMPAT_DB
1655         else
1656                 OL_BERKELEY_DB
1657         fi
1658
1659         if test $ol_cv_berkeley_db != no ; then
1660                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1661                         [define this if Berkeley DB is available])
1662
1663                 ol_link_ldbm=berkeley
1664                 ol_with_ldbm_api=db
1665
1666                 if test $ol_with_ldbm_type = hash ; then
1667                         AC_DEFINE(LDBM_USE_DBHASH,1,
1668                                 [define this to use DBHASH w/ LDBM backend])
1669                 else
1670                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1671                                 [define this to use DBBTREE w/ LDBM backend])
1672                 fi
1673
1674                 dnl $ol_cv_lib_db should be yes or -ldb
1675                 dnl (it could be no, but that would be an error
1676                 if test $ol_cv_lib_db != yes ; then
1677                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1678                 fi
1679         fi
1680 fi
1681
1682 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1683         AC_MSG_WARN(Could not find LDBM with BTREE support)
1684         ol_with_ldbm_api=none
1685 fi
1686
1687 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1688         OL_MDBM
1689
1690         if test $ol_cv_mdbm = yes ; then
1691                 ol_link_ldbm=mdbm
1692                 ol_with_ldbm_api=mdbm
1693                 if test $ol_cv_lib_mdbm != yes ; then
1694                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1695                 fi
1696         fi
1697 fi
1698
1699 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1700         OL_GDBM
1701
1702         if test $ol_cv_gdbm = yes ; then
1703                 ol_link_ldbm=gdbm
1704                 ol_with_ldbm_api=gdbm
1705
1706                 if test $ol_cv_lib_gdbm != yes ; then
1707                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1708                 fi
1709         fi
1710 fi
1711
1712 if test $ol_with_ldbm_api = ndbm ; then
1713         OL_NDBM
1714
1715         if test $ol_cv_ndbm = yes ; then
1716                 ol_link_ldbm=ndbm
1717                 ol_with_ldbm_api=ndbm
1718
1719                 if test $ol_cv_lib_ndbm != yes ; then
1720                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1721                 fi
1722         fi
1723 fi
1724
1725 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1726         AC_MSG_WARN(could not find suitable LDBM backend)
1727         if test $ol_enable_ldbm = yes ; then
1728                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1729         fi
1730
1731         AC_MSG_WARN(disabling LDBM)
1732         ol_enable_ldbm=no
1733 fi
1734
1735 dnl ----------------------------------------------------------------
1736 ol_link_bdb2=no
1737 if test $ol_enable_bdb2 != no ; then
1738         if test $ol_enable_bdb2 = yes -a $ol_link_ldbm != berkeley ; then
1739                 AC_MSG_ERROR(BDB2 requires LDBM BerkeleyDB 2)
1740         elif test $ol_link_ldbm = berkeley ; then
1741                 ol_link_bdb2=$ol_link_ldbm
1742         fi
1743 fi
1744
1745 dnl ----------------------------------------------------------------
1746 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1747         LINK_BINS_DYNAMIC="yes"
1748 else
1749         LINK_BINS_DYNAMIC="no"
1750 fi
1751
1752 dnl ----------------------------------------------------------------
1753 if test $ol_enable_wrappers != no ; then
1754         AC_CHECK_HEADERS(tcpd.h)
1755
1756         if test $ac_cv_header_tcpd_h != yes ; then
1757                 have_wrappers=no
1758         else
1759                 AC_TRY_COMPILE([
1760 int allow_severity = 0;
1761 int deny_severity  = 0;
1762                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1763         fi
1764
1765         if test $have_wrappers = yes ; then
1766                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1767                 WRAP_LIBS="-lwrap"
1768
1769                 dnl We add another check for -lnsl since some libwrap's
1770                 dnl need it, but it isn't always included from above
1771                 AC_CHECK_LIB(nsl, main)
1772         else
1773                 AC_MSG_WARN(could not find -lwrap)
1774                 if test $ol_enable_wrappers = yes ; then
1775                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1776                 fi
1777
1778                 AC_MSG_WARN(disabling wrappers support)
1779                 ol_enable_wrappers=no
1780                 WRAP_LIBS=""
1781         fi
1782 fi
1783
1784 dnl ----------------------------------------------------------------
1785 if test $ol_enable_syslog != no ; then
1786         AC_CHECK_FUNC(openlog)
1787         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1788                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1789         fi
1790         ol_enable_syslog=$ac_cv_func_openlog
1791 fi
1792
1793 dnl ----------------------------------------------------------------
1794 dnl dmalloc support (deprecated in favor of -DCSRIMALLOC support)
1795 dnl if test $ol_enable_dmalloc != no ; then
1796 dnl     AC_CHECK_HEADERS(dmalloc.h)
1797 dnl     AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1798 dnl fi
1799 dnl ----------------------------------------------------------------
1800 dnl TCL
1801 if test $ol_enable_tcl != no ; then
1802         AC_CHECK_HEADERS(tcl.h)
1803
1804         if test $ac_cv_header_tcl_h != yes ; then
1805                 have_tcl=no
1806         else
1807                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1808                         AC_CHECK_LIB($lib,main,
1809                           [have_tcl=yes
1810                            if test x"$ol_with_tcl_module" = "xstatic" ; then
1811                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1812                            else
1813                                MOD_TCL_LIB="-l${lib}"
1814                            fi;break],[have_tcl=no])
1815                 done
1816         fi
1817
1818         if test $have_tcl != yes ; then
1819                 AC_MSG_WARN([could not find -ltcl])
1820                 if test $ol_enable_tcl = yes ; then
1821                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1822                 fi
1823
1824                 ol_enable_tcl=no
1825         fi
1826 fi
1827
1828 dnl ----------------------------------------------------------------
1829 dnl ud needs termcap (should insert check here)
1830 ol_link_termcap=no
1831 AC_CHECK_HEADERS(termcap.h ncurses.h)
1832
1833 if test $ol_link_termcap = no ; then
1834         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1835         if test $have_termcap = yes ; then
1836                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1837                 ol_link_termcap=yes
1838                 TERMCAP_LIBS=-ltermcap
1839         fi
1840 fi
1841
1842 if test $ol_link_termcap = no ; then
1843         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1844         if test $have_ncurses = yes ; then
1845                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1846                 ol_link_termcap=yes
1847                 TERMCAP_LIBS=-lncurses
1848         fi
1849 fi
1850
1851 if test $ol_link_termcap = no ; then
1852         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1853         TERMCAP_LIBS=
1854 fi
1855
1856 dnl ----------------------------------------------------------------
1857 dnl
1858 dnl Check for Cyrus SASL
1859 dnl
1860 ol_link_sasl=no
1861 ol_link_spasswd=no
1862 if test $ol_with_cyrus_sasl != no ; then
1863         AC_CHECK_HEADER(sasl.h)
1864
1865         if test $ac_cv_header_sasl_h = yes ; then
1866                 AC_CHECK_LIB(sasl, sasl_client_init,
1867                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1868
1869                 if test $have_cyrus_sasl != no ; then
1870                         SASL_LIBS="-lsasl"
1871                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1872                         ol_link_sasl=yes
1873                 fi
1874         fi
1875
1876         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1877                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1878         fi
1879 fi
1880
1881 dnl ----------------------------------------------------------------
1882 dnl Check for entropy sources
1883 if test $cross_compiling != yes ; then
1884         dev=no
1885         if test -r /dev/urandom ; then
1886                 dev="/dev/urandom";
1887         elif test -r /idev/urandom ; then
1888                 dev="/idev/urandom";
1889         elif test -r /dev/srandom ; then
1890                 dev="/dev/srandom";
1891         elif test -r /dev/random ; then
1892                 dev="/dev/random";
1893         elif test -r /idev/random ; then
1894                 dev="/idev/random";
1895         fi
1896
1897         if test $dev != no ; then
1898                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1899         fi
1900 fi
1901
1902 dnl ----------------------------------------------------------------
1903 dnl
1904 dnl Check for fetch URL support
1905 dnl             should be extended to support other fetch URL APIs
1906 dnl
1907 ol_link_fetch=no
1908 if test $ol_with_fetch != no ; then
1909         OL_LIB_FETCH
1910
1911         if test $ol_cv_lib_fetch != no ; then
1912                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1913                 ol_link_fetch=freebsd
1914
1915         elif test $ol_with_fetch != auto ; then
1916                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1917         fi
1918 fi
1919
1920 dnl ----------------------------------------------------------------
1921 dnl
1922 dnl Check for GNU readline
1923 dnl
1924 ol_link_readline=no
1925 if test $ol_with_readline != no ; then
1926         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1927
1928         if test $ac_cv_header_readline_readline_h = yes ; then
1929                 save_LIBS="$LIBS"
1930                 LIBS="$TERMCAP_LIBS $LIBS"
1931                 AC_CHECK_LIB(readline, readline,
1932                         [have_readline=yes], [have_readline=no])
1933                 LIBS="$save_LIBS"
1934
1935                 if test $have_readline = yes ; then
1936                         ol_with_readline=found
1937                         ol_link_readline=yes
1938
1939                         READLINE_LIBS="-lreadline"
1940                 fi
1941         fi
1942 fi
1943
1944 if test $ol_link_readline = yes ; then
1945         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1946 fi
1947
1948
1949 dnl ----------------------------------------------------------------
1950 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1951 if test $ol_enable_crypt != no ; then
1952         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1953                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1954                         have_crypt=yes], [have_crypt=no])])
1955
1956         if test $have_crypt = yes ; then
1957                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1958         else
1959                 AC_MSG_WARN(could not find crypt)
1960                 if test $ol_enable_crypt = yes ; then
1961                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1962                 fi
1963
1964                 AC_MSG_WARN(disabling crypt support)
1965                 ol_enable_crypt=no
1966         fi
1967 fi
1968
1969 dnl ----------------------------------------------------------------
1970 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1971 if test $ol_enable_proctitle != no ; then
1972         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1973                 AC_CHECK_LIB(util, setproctitle,
1974                         [have_setproctitle=yes
1975                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1976                         [have_setproctitle=no
1977                         LIBOBJS="$LIBOBJS setproctitle.o"
1978                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1979
1980         if test $have_setproctitle = yes ; then
1981                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1982                         [define if setproctitle(3) is available])
1983         fi
1984 fi
1985
1986 dnl ----------------------------------------------------------------
1987 dnl Checks for typedefs, structures, and compiler characteristics.
1988 AC_TYPE_MODE_T
1989 AC_TYPE_OFF_T
1990 AC_TYPE_PID_T
1991 AM_TYPE_PTRDIFF_T
1992 AC_TYPE_SIGNAL
1993 AC_TYPE_SIZE_T
1994
1995 AC_CHECK_TYPE(ssize_t, [signed int])
1996 AC_CHECK_TYPE(caddr_t,  [char *])
1997
1998 OL_TYPE_SOCKLEN_T
1999 AC_STRUCT_ST_BLKSIZE
2000 AC_HEADER_TIME
2001 AC_STRUCT_TM
2002 AC_TYPE_UID_T
2003 OL_TYPE_SIG_ATOMIC_T
2004
2005 dnl AC_TYPE_GETGROUPS
2006
2007 OL_STRUCT_PASSWD_PW_GECOS
2008 OL_STRUCT_PASSWD_PW_PASSWD
2009
2010 OL_C_UPPER_LOWER
2011 AC_C_CONST
2012 OL_C_VOLATILE
2013
2014 if test $cross_compiling = yes ; then
2015         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2016 else
2017         AC_C_BIGENDIAN
2018 fi
2019
2020 AC_COMPILE_CHECK_SIZEOF(short)
2021 AC_COMPILE_CHECK_SIZEOF(int)
2022 AC_COMPILE_CHECK_SIZEOF(long)
2023
2024 if test "$ac_cv_sizeof_int" -lt 4 ; then
2025         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2026
2027         AC_DEFINE(LBER_INT_T,long)
2028 else
2029         AC_DEFINE(LBER_INT_T,int)
2030 fi
2031
2032 AC_DEFINE(LBER_LEN_T,long)
2033 AC_DEFINE(LBER_SOCKET_T,int)
2034 AC_DEFINE(LBER_TAG_T,long)
2035
2036 dnl ----------------------------------------------------------------
2037 dnl Checks for library functions.
2038 AC_FUNC_MEMCMP
2039 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
2040 AC_FUNC_STRFTIME
2041 dnl AM_FUNC_STRTOD
2042
2043 OL_FUNC_INET_ATON
2044
2045 dnl Check for NT specific routines
2046 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2047
2048 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2049         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2050 ])
2051
2052 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2053         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2054 ])
2055
2056 AC_FUNC_VPRINTF
2057
2058 if test $ac_cv_func_vprintf = yes ; then
2059         dnl check for vsnprintf
2060         AC_CHECK_FUNCS(vsnprintf vsprintf)
2061 fi
2062
2063 AC_CHECK_FUNCS(         \
2064         bcopy                   \
2065         closesocket             \
2066         chroot                  \
2067         endgrent                \
2068         endpwent                \
2069         flock                   \
2070         getdtablesize   \
2071         getgrgid                \
2072         gethostname             \
2073         getpass                 \
2074         getpassphrase   \
2075         getpwuid                \
2076         getpwnam                \
2077         getspnam                \
2078         gettimeofday    \
2079         initgroups              \
2080         lockf                   \
2081         memcpy                  \
2082         memmove                 \
2083         mkstemp                 \
2084         pipe                    \
2085         read                    \
2086         recv                    \
2087         recvfrom                \
2088         setpwfile               \
2089         setgid                  \
2090         setegid                 \
2091         setsid                  \
2092         setuid                  \
2093         seteuid                 \
2094         sigaction               \
2095         signal                  \
2096         sigset                  \
2097         snprintf                \
2098         strdup                  \
2099         strerror                \
2100         strpbrk                 \
2101         strrchr                 \
2102         strsep                  \
2103         strstr                  \
2104         strtol                  \
2105         strtoul                 \
2106         strspn                  \
2107         sysconf                 \
2108         waitpid                 \
2109         wait4                   \
2110         write                   \
2111         send                    \
2112         sendto                  \
2113 )
2114
2115 dnl We actually may need to replace more than this.
2116 AC_REPLACE_FUNCS(getopt tempnam)
2117
2118 if test "$ac_cv_func_getopt" != yes; then
2119     LIBSRCS="$LIBSRCS getopt.c"
2120 fi
2121
2122 if test "$ac_cv_func_tempnam" != yes; then
2123     LIBSRCS="$LIBSRCS tempnam.c"
2124 fi
2125
2126 dnl ----------------------------------------------------------------
2127 # Check Configuration
2128 OL_SYS_ERRLIST
2129
2130 dnl ----------------------------------------------------------------
2131 dnl Sort out defines
2132
2133 if test "$ol_enable_debug" != no ; then
2134         AC_DEFINE(LDAP_DEBUG,1,
2135                 [define this to add debugging code])
2136 fi
2137 if test "$ol_enable_syslog" = yes ; then
2138         AC_DEFINE(LDAP_SYSLOG,1,
2139                 [define this to add syslog code])
2140 fi
2141 if test "$ol_enable_libui" = yes ; then
2142         AC_DEFINE(LDAP_LIBUI,1,
2143                 [define this for LDAP User Interface support])
2144 fi
2145 if test "$ol_enable_cache" = no ; then
2146         AC_DEFINE(LDAP_NOCACHE,1,
2147                 [define this to remove -lldap cache support])
2148 fi
2149 if test "$ol_link_kbind" != no ; then
2150         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2151 fi
2152 if test "$ol_enable_proctitle" != no ; then
2153         AC_DEFINE(LDAP_PROCTITLE,1,
2154                 [define this for LDAP process title support])
2155 fi
2156 if test "$ol_enable_referrals" != no ; then
2157         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2158 fi
2159 if test "$ol_enable_cldap" != no ; then
2160         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
2161 fi
2162 if test "$ol_enable_ldapi" != no; then
2163         AC_DEFINE(USE_PF_LOCAL,1,[define to support PF_LOCAL transport])
2164 fi
2165
2166 if test "$ol_enable_cleartext" != no ; then
2167         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2168 fi
2169 if test "$ol_enable_crypt" != no ; then
2170         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2171 fi
2172 if test "$ol_link_kpasswd" != no ; then
2173         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2174 fi
2175 if test "$ol_link_spasswd" != no ; then
2176         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2177 fi
2178 if test "$ol_enable_multimaster" != no ; then
2179         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2180 fi
2181 if test "$ol_enable_phonetic" != no ; then
2182         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2183 fi
2184 if test "$ol_enable_rlookups" != no ; then
2185         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2186 fi
2187 if test "$ol_enable_aci" != no ; then
2188         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2189 fi
2190
2191 if test "$ol_link_modules" != no ; then
2192         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2193         BUILD_SLAPD=yes
2194         SLAPD_MODULES_LDFLAGS="-dlopen self"
2195 fi
2196
2197 if test "$ol_link_bdb2" != no ; then
2198         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
2199         BUILD_SLAPD=yes
2200         BUILD_BDB2=yes
2201         if test "$ol_with_bdb2_module" != static ; then
2202                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
2203                         [define to support dynamic BDB2 backend])
2204                 BUILD_BDB2=mod
2205                 BUILD_BDB2_DYNAMIC=shared
2206                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
2207         fi
2208 fi
2209
2210 if test "$ol_link_dnssrv" != no ; then
2211         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2212         BUILD_SLAPD=yes
2213         BUILD_DNSSRV=yes
2214         if test "$ol_with_dnssrv_module" != static ; then
2215                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2216                         [define to support dynamic DNS SRV backend])
2217                 BUILD_DNSSRV=mod
2218                 BUILD_DNSSRV_DYNAMIC=shared
2219                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2220         fi
2221 fi
2222
2223 if test "$ol_enable_ldap" != no ; then
2224         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2225         BUILD_SLAPD=yes
2226         BUILD_LDAP=yes
2227         if test "$ol_with_ldap_module" != static ; then
2228                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2229                         [define to support dynamic LDAP backend])
2230                 BUILD_LDAP=mod
2231                 BUILD_LDAP_DYNAMIC=shared
2232                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2233         fi
2234 fi
2235
2236 if test "$ol_link_ldbm" != no ; then
2237         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2238         BUILD_SLAPD=yes
2239         BUILD_LDBM=yes
2240         if test "$ol_with_ldbm_module" != static ; then
2241                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2242                         [define to support dynamic LDBM backend])
2243                 BUILD_LDBM=mod
2244                 BUILD_LDBM_DYNAMIC=shared
2245                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2246         fi
2247 fi
2248
2249 if test "$ol_enable_passwd" != no ; then
2250         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2251         BUILD_SLAPD=yes
2252         BUILD_PASSWD=yes
2253         if test "$ol_with_passwd_module" != static ; then
2254                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2255                         [define to support dynamic PASSWD backend])
2256                 BUILD_PASSWD=mod
2257                 BUILD_PASSWD_DYNAMIC=shared
2258                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2259         fi
2260 fi
2261
2262 if test "$ol_link_perl" != no ; then
2263         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2264         BUILD_SLAPD=yes
2265         BUILD_PERL=yes
2266         if test "$ol_with_perl_module" != static ; then
2267                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2268                         [define to support dynamic PERL backend])
2269                 BUILD_PERL=mod
2270                 BUILD_PERL_DYNAMIC=shared
2271                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2272         fi
2273 fi
2274
2275 if test "$ol_enable_shell" != no ; then
2276         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2277         BUILD_SLAPD=yes
2278         BUILD_SHELL=yes
2279         if test "$ol_with_shell_module" != static ; then
2280                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2281                         [define to support dynamic SHELL backend])
2282                 BUILD_SHELL=mod
2283                 BUILD_SHELL_DYNAMIC=shared
2284                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2285         fi
2286 fi
2287
2288 if test "$ol_enable_tcl" != no ; then
2289         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2290         BUILD_SLAPD=yes
2291         BUILD_TCL=yes
2292         if test "$ol_with_tcl_module" != static; then
2293                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2294                         [define to support dynamic TCL backend])
2295                 BUILD_TCL=mod
2296                 BUILD_TCL_DYNAMIC=shared
2297                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2298         fi
2299 fi
2300
2301 if test "$ol_enable_sql" != no ; then
2302         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2303         BUILD_SLAPD=yes
2304         BUILD_SQL=yes
2305         SLAPD_SQL_LIBS=-liodbc
2306         if test "$ol_with_sql_module" != static; then
2307                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2308                         [define to support dynamic SQL backend])
2309                 BUILD_SQL=mod
2310                 BUILD_SQL_DYNAMIC=shared
2311                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2312         fi
2313 fi
2314
2315 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2316         $BUILD_SLAPD = yes ; then
2317         BUILD_SLURPD=yes
2318 fi
2319
2320 dnl ----------------------------------------------------------------
2321
2322 if test "$LINK_BINS_DYNAMIC" = yes; then
2323     LIB_LINKAGE=DYN
2324     LT_LIB_LINKAGE=shared
2325 else
2326     LIB_LINKAGE=STAT
2327     LT_LIB_LINKAGE=static
2328 fi
2329
2330 if test "$ac_cv_mingw32" = yes ; then
2331     PLAT=NT
2332     DYN_EXT=dll
2333 else
2334     PLAT=UNIX
2335     DYN_EXT=so
2336 fi
2337
2338 AC_SUBST(LIBSRCS)
2339
2340 AC_SUBST(PLAT)
2341 AC_SUBST(LIB_LINKAGE)
2342 AC_SUBST(LT_LIB_LINKAGE)
2343 AC_SUBST(DYN_EXT)
2344
2345 AC_SUBST(BUILD_SLAPD)
2346   AC_SUBST(BUILD_BDB2)
2347   AC_SUBST(BUILD_DNSSRV)
2348   AC_SUBST(BUILD_LDAP)
2349   AC_SUBST(BUILD_LDBM)
2350   AC_SUBST(BUILD_PASSWD)
2351   AC_SUBST(BUILD_PERL)
2352   AC_SUBST(BUILD_QUIPU)
2353   AC_SUBST(BUILD_SHELL)
2354   AC_SUBST(BUILD_SQL)
2355   AC_SUBST(BUILD_TCL)
2356   AC_SUBST(BUILD_BDB2_DYNAMIC)
2357   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2358   AC_SUBST(BUILD_LDAP_DYNAMIC)
2359   AC_SUBST(BUILD_LDBM_DYNAMIC)
2360   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2361   AC_SUBST(BUILD_PERL_DYNAMIC)
2362   AC_SUBST(BUILD_SHELL_DYNAMIC)
2363   AC_SUBST(BUILD_SQL_DYNAMIC)
2364   AC_SUBST(BUILD_TCL_DYNAMIC)
2365 AC_SUBST(BUILD_SLURPD)
2366
2367 AC_SUBST(LDAP_LIBS)
2368 AC_SUBST(LDIF_LIBS)
2369 AC_SUBST(SLAPD_LIBS)
2370 AC_SUBST(QUIPU_LIBS)
2371 AC_SUBST(SLURPD_LIBS)
2372 AC_SUBST(LDBM_LIBS)
2373 AC_SUBST(LTHREAD_LIBS)
2374 AC_SUBST(LUTIL_LIBS)
2375 AC_SUBST(WRAP_LIBS)
2376 AC_SUBST(MOD_TCL_LIB)
2377 AC_SUBST(LINK_BINS_DYNAMIC)
2378
2379 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2380 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2381 AC_SUBST(SLAPD_MODULES_LIST)
2382
2383 AC_SUBST(PERL_CPPFLAGS)
2384 AC_SUBST(SLAPD_PERL_LDFLAGS)
2385 AC_SUBST(MOD_PERL_LDFLAGS)
2386
2387 AC_SUBST(KRB4_LIBS)
2388 AC_SUBST(KRB5_LIBS)
2389 AC_SUBST(READLINE_LIBS)
2390 AC_SUBST(SASL_LIBS)
2391 AC_SUBST(TERMCAP_LIBS)
2392 AC_SUBST(TLS_LIBS)
2393 AC_SUBST(MODULES_LIBS)
2394 AC_SUBST(AUTH_LIBS)
2395
2396 AC_SUBST(SLAPD_SQL_LDFLAGS)
2397 AC_SUBST(SLAPD_SQL_LIBS)
2398 AC_SUBST(SLAPD_SQL_INCLUDES)
2399
2400 dnl ----------------------------------------------------------------
2401 dnl final output
2402 dnl
2403
2404 AC_OUTPUT( \
2405 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2406 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2407 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2408 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2409 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2410 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2411 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2412 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2413 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2414 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2415 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2416 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2417 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2418 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2419 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2420 include/Makefile:build/top.mk:include/Makefile.in \
2421 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2422 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2423 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2424 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2425 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2426 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2427 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2428 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2429 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2430 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2431 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2432 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2433 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2434 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2435 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2436 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2437 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2438 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2439 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2440 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2441 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2442 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2443 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2444 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2445 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2446 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2447 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2448 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2449 ,[
2450 date > stamp-h
2451 echo Please \"make depend\" to build dependencies
2452 ])