git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  28 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  29 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  30 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  31 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  32 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  33 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  34         no, [yes no])dnl
  35
  36 dnl General "with" options
  37 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  38         auto, [auto k5 k4 afs yes no])
  39 OL_ARG_WITH(threads,[  --with-threads   use threads],
  40         auto, [auto posix mach lwp yes no manual] )
  41 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  42         auto, [auto yes no manual] )
  43
  44 dnl Server options
  45
  46 dnl LDAPD OPTIONS
  47 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  48
  49 dnl SLAPD OPTIONS
  50 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  51 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  52 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  53 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  54 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  55 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  56 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  57 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  58
  59 dnl SLAPD Backend options
  60 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  61 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  62         [auto db2 db gdbm ndbm manual])
  63 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  64         [auto btree hash])
  65
  66 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  67 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  68
  69 dnl SLURPD OPTIONS
  70 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  71
  72 if test $ol_enable_slapd = no ; then
  73         dnl SLAPD was specificallly disabled
  74         if test $ol_enable_ldbm = yes ; then
  75                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  76         fi
  77         if test $ol_enable_passwd = yes ; then
  78                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
  79         fi
  80         if test $ol_enable_shell = yes ; then
  81                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
  82         fi
  83         if test $ol_enable_aclgroups = yes ; then
  84                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
  85         fi
  86         if test $ol_enable_crypt = yes ; then
  87                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
  88         fi
  89         if test $ol_enable_md5 = yes ; then
  90                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
  91         fi
  92         if test $ol_enable_sha1 = yes ; then
  93                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
  94         fi
  95         if test $ol_enable_wrappers = yes ; then
  96                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
  97         fi
  98         if test $ol_enable_phonetic = yes ; then
  99                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 100         fi
 101         if test $ol_enable_rlookups = yes ; then
 102                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 103         fi
 104         if test $ol_with_ldbm_api != auto ; then
 105                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 106         fi
 107         if test $ol_with_ldbm_type != auto ; then
 108                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 109         fi
 110         if test $ol_enable_slurpd = yes ; then
 111                 AC_MSG_ERROR([slurpd requires slapd])
 112         fi
 113
 114         # force settings to no
 115         ol_enable_ldbm=no
 116         ol_enable_shell=no
 117         ol_enable_passwd=no
 118         ol_enable_aclgroups=no
 119         ol_enable_crypt=no
 120         ol_enable_md5=no
 121         ol_enable_sha1=no
 122         ol_enable_wrappers=no
 123         ol_enable_phonetic=no
 124         ol_enable_rlookups=no
 125         ol_with_ldbm_api=no
 126         ol_with_ldbm_type=no
 127         ol_enable_slurpd=no
 128
 129 elif test $ol_enable_ldbm = no ; then
 130         dnl SLAPD without LDBM
 131
 132         if test $ol_with_ldbm_api != auto ; then
 133                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 134         fi
 135
 136         if test $ol_with_ldbm_type != auto ; then
 137                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 138         fi
 139
 140         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 141                 AC_MSG_ERROR([slapd requires a backend])
 142         fi
 143
 144         ol_with_ldbm_api=no
 145         ol_with_ldbm_type=no
 146
 147 else
 148         dnl SLAPD with LDBM
 149
 150         if test $ol_with_ldbm_api = gdbm -a \
 151                 $ol_with_ldbm_type = btree ; then
 152                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 153         fi
 154         if test $ol_with_ldbm_api = ndbm -a \
 155                 $ol_with_ldbm_type = btree ; then
 156                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 157         fi
 158 fi
 159
 160 if test $ol_enable_slurpd = yes ; then
 161         dnl SLURPD was specifically enabled
 162         if test $ol_with_threads = no ; then
 163                 AC_MSG_ERROR([slurpd requires threads])
 164         fi
 165 fi
 166
 167 AC_MSG_RESULT(done)
 168
 169 ## Initialize vars
 170 LDAP_LIBS=
 171 LDBM_LIBS=
 172 LTHREAD_LIBS=
 173 LUTIL_LIBS=
 174
 175 LDAPD_LIBS=
 176 SLAPD_LIBS=
 177 SLURPD_LIBS=
 178
 179 BUILD_LDAPD=no
 180 BUILD_SLAPD=no
 181 BUILD_SLURPD=no
 182
 183 BUILD_LDBM=no
 184 BUILD_PASSWD=no
 185 BUILD_SHELL=no
 186
 187 KRB_LIBS=
 188 TERMCAP_LIBS=
 189
 190 dnl ----------------------------------------------------------------
 191 dnl Checks for programs
 192
 193 AC_PROG_LN_S
 194 AC_PROG_INSTALL
 195 AC_PROG_RANLIB
 196 AC_PROG_MAKE_SET
 197
 198 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 199         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 200 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 201 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 202
 203 dnl Checks the compiler and UNIX Variants
 204 AC_PROG_CC
 205
 206 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 207         AC_WARN([cross compiling....  go for it])
 208
 209 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 210         AC_WARN([programs compiled here do run here...])
 211         AC_ERROR([  if not cross compiling, use --disable-x-compile.])
 212
 213 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 214         AC_WARN([programs compiled here do not run here...])
 215         AC_ERROR([  if cross compiling,  add --enable-x-compile.])
 216 fi
 217
 218 dnl OpenLDAP requires STDC features
 219 dnl AC_PROG_GCC_TRADITIONAL
 220 AC_PROG_CPP
 221
 222
 223 AC_AIX
 224 AC_ISC_POSIX
 225 AC_MINIX
 226
 227 dnl Checks for libraries
 228
 229 dnl Find socket()
 230 dnl Likely combinations:
 231 dnl             -lsocket [ -lnsl_s | -lnsl ]
 232 dnl             -linet
 233
 234 AC_CHECK_FUNC(socket, :, [
 235 dnl
 236 dnl hopefully we won't include too many libraries
 237 dnl
 238         AC_CHECK_LIB(socket, main)
 239         AC_CHECK_LIB(net, main)
 240         AC_CHECK_LIB(nsl_s, main)
 241         AC_CHECK_LIB(nsl, main)
 242         AC_CHECK_LIB(inet, socket)
 243         AC_CHECK_LIB(gen, main)
 244 ])
 245
 246 # LDAPD tests
 247 if test $ol_enable_ldapd != no ; then
 248         dnl look for ISODE libraries
 249         AC_CHECK_LIB(dsap, main, [
 250                 AC_DEFINE(HAVE_DSAP,1)
 251                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 252                 ],:)
 253         AC_CHECK_LIB(isode, main, [
 254                 AC_DEFINE(HAVE_ISODE,1)
 255                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 256                 ],:)
 257         AC_CHECK_LIB(xtpp, main, [
 258                 AC_DEFINE(HAVE_XTPP,1)
 259                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp"
 260                 ],:)
 261 fi
 262
 263 dnl HP-UX requires -lV3
 264 AC_CHECK_LIB(V3, sigset)
 265
 266 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 267         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 268
 269         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 270                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 271                         [-lkrb5 -ldes425])
 272
 273                 if test $have_k5 = yes ; then
 274                         ol_with_kerberos=found
 275                         ol_link_kerberos=yes
 276
 277                         AC_DEFINE(HAVE_KERBEROS)
 278
 279                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 280                 fi
 281         fi
 282 fi
 283 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 284         AC_CHECK_HEADERS(krb.h des.h)
 285
 286         if test $ac_cv_header_krb_h = yes ; then
 287                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 288
 289                 if test $have_k4 = yes ; then
 290                         ol_with_kerberos=found
 291                         ol_link_kerberos=yes
 292
 293                         AC_DEFINE(HAVE_KERBEROS)
 294
 295                         KRB_LIBS="-lkrb -ldes"
 296                 fi
 297         fi
 298 fi
 299
 300
 301 ol_link_threads=no
 302 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 303         AC_CHECK_HEADERS(pthread.h sched.h)
 304
 305         if test $ac_cv_header_pthread_h = yes ; then
 306                 OL_POSIX_THREAD_VERSION
 307
 308                 if test $ol_cv_pthread_version = final ; then
 309                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 310                 elif test $ol_cv_pthread_version = draft4 ; then
 311                         AC_DEFINE(HAVE_PTHREADS_D4)
 312                 else
 313                         AC_MSG_ERROR([unknown pthread version])
 314                 fi
 315
 316                 # consider threads found
 317                 ol_with_threads=found
 318
 319                 OL_LINUX_THREADS
 320
 321                 if test $ol_cv_linux_threads = yes ; then
 322                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 323                 fi
 324
 325                 dnl Now the hard part, how to link
 326
 327                 dnl A few platforms have pthread support in standard libraries
 328                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 329
 330                 if test $ol_link_threads = no ; then
 331                         dnl try -pthread
 332                         AC_CACHE_CHECK([for pthread_create with -pthread],
 333                                 [ol_cv_pthread_flag], [
 334                                 dnl save the CPPFLAGS
 335                                 save_LIBS="$LIBS"
 336                                 LIBS="-pthread $LIBS"
 337                                 AC_TRY_LINK([#include <pthread.h>],[
 338                                         pthread_create((pthread_t*) 0,
 339                                                 (pthread_attr_t*) 0, 0, 0);
 340                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 341                                 dnl restore the LIBS
 342                                 LIBS="$save_LIBS"
 343                         ])
 344
 345                         if test $ol_cv_pthread_flag = yes ; then
 346                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 347                                 ol_link_threads=posix
 348                         fi
 349                 fi
 350
 351                 if test $ol_link_threads = no ; then
 352                         dnl try -lpthread
 353                         save_LIBS="$LIBS"
 354                         AC_CHECK_LIB(pthread, pthread_create, [
 355                                 ol_link_threads=posix
 356                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 357                         LIBS="$save_LIBS"
 358                 fi
 359
 360                 if test $ol_link_threads = no ; then
 361                         dnl try -lc_r
 362                         save_LIBS="$LIBS"
 363                         AC_CHECK_LIB(c_r, pthread_create, [
 364                                 ol_link_threads=posix
 365                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 366                         LIBS="$save_LIBS"
 367                 fi
 368
 369                 if test $ol_link_threads = no ; then
 370                         dnl try DEC Threads
 371                         save_LIBS="$LIBS"
 372                         AC_CHECK_LIB(pthread, pthread_create, [
 373                                 AC_DEFINE(HAVE_DCE)
 374                                 ol_link_threads=posix
 375                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc"
 376                                 if test $ol_with_preemptive = auto ; then
 377                                         ol_with_preemptive=yes
 378                                 fi
 379                                 ],,[-lmach -lexc -lc])
 380                         LIBS="$save_LIBS"
 381                 fi
 382
 383                 if test $ol_link_threads != no ; then
 384                         AC_DEFINE(HAVE_PTHREADS)
 385
 386                         dnl save DEFS/LIBS
 387                         save_CPPFLAGS="$CPPFLAGS"
 388                         save_LIBS="$LIBS"
 389                         LIBS="$LTHREAD_LIBS $LIBS"
 390
 391                         dnl All POSIX Thread (final) implementations should have
 392                         dnl sched_yield instead of pthread yield.
 393                         dnl check for both
 394                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 395
 396                         if test $ac_cv_func_sched_yield = no -a \
 397                                 $ac_cv_func_pthread_yield = no ; then
 398                                 dnl Digital UNIX has sched_yield() in -lrt
 399                                 AC_CHECK_LIB(rt, sched_yield,
 400                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 401                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 402                                         ac_cv_func_sched_yield=yes],
 403                                         [ac_cv_func_sched_yield=no])
 404                         fi
 405                         if test $ac_cv_func_sched_yield = no -a \
 406                                 $ac_cv_func_pthread_yield = no ; then
 407                                 dnl Solaris has sched_yield() in -lposix4
 408                                 AC_CHECK_LIB(posix4, sched_yield,
 409                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 410                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 411                                         ac_cv_func_sched_yield=yes],
 412                                         [ac_cv_func_sched_yield=no])
 413                         fi
 414                         if test $ac_cv_func_sched_yield = no -a \
 415                                 $ac_cv_func_pthread_yield = no ; then
 416                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 417                                 AC_MSG_ERROR([POSIX Threads are not usable])
 418                         fi
 419
 420                         dnl Check functions for compatibility
 421                         AC_CHECK_FUNCS(pthread_kill)
 422 dnl                     AC_CHECK_FUNCS( \
 423 dnl                             pthread_attr_create pthread_attr_init \
 424 dnl                             pthread_attr_destroy pthread_attr_delete \
 425 dnl                             pthread_attr_setdetachstate pthread_attr_setdetach_np \
 426 dnl                     )
 427
 428                         dnl Check for setconcurreny functions
 429                         AC_CHECK_FUNCS( \
 430                                 pthread_setconcurrency \
 431                                 thr_setconcurrency \
 432                         )
 433
 434                         dnl Check PREEMPTIVE Implementation
 435                         if test $ol_with_preemptive = auto ; then
 436                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 437                                 AC_TRY_RUN([
 438 #include <sys/types.h>
 439 #include <sys/time.h>
 440 #include <unistd.h>
 441 #include <pthread.h>
 442 #ifndef NULL
 443 #define NULL 0
 444 #endif
 445
 446 int task(arg)
 447         int *arg;
 448 {
 449         struct timeval tv;
 450
 451         tv.tv_sec=4;
 452         tv.tv_usec=0;
 453         select(0, NULL, NULL, NULL, &tv);
 454
 455         tv.tv_sec=6;
 456         tv.tv_usec=0;
 457         select(0, NULL, NULL, NULL, &tv);
 458
 459         exit(1); /* if we exit here, the select blocked the whole process */
 460 }
 461
 462 main(argc, argv)
 463 int argc; char **argv;
 464 {
 465         pthread_t t;
 466
 467 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 468         (void) pthread_setconcurrency(2);
 469 #elif HAVE_THR_SETCONCURRENCY
 470         /* Set Solaris LWP concurrency to 2 */
 471         thr_setconcurrency(2);
 472 #endif
 473
 474         pthread_create(&t, NULL, (void *) task, NULL);
 475
 476 #if HAVE_SCHED_YIELD
 477         sched_yield();  /* make sure task runs first */
 478 #else
 479 #if defined(HAVE_PTHREAD_YIELD)
 480         pthread_yield();        /* make sure task runs first */
 481 #endif
 482 #endif
 483         exit(0);
 484 }
 485                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 486                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 487                                 AC_MSG_RESULT($ol_pthread_preemptive)
 488
 489                                 if test $ol_pthread_preemptive = yes ; then
 490                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 491                                         ol_with_preemptive=yes
 492                                 fi
 493                         fi
 494
 495 dnl                     dnl check for reentrant/threadsafe functions
 496 dnl                     AC_CHECK_FUNCS( \
 497 dnl                             feof_unlocked \
 498 dnl                             unlocked_feof \
 499 dnl                             ftrylockfile \
 500 dnl                             flockfile \
 501 dnl                             putc_unlocked \
 502 dnl                             gmtime_r \
 503 dnl                             strtok_r \
 504 dnl                     )
 505
 506                         dnl restore DEFS/LIBS
 507                         CPPFLAGS="$save_CPPFLAGS"
 508                         LIBS="$save_LIBS"
 509                 else
 510                         AC_MSG_ERROR([could not link with POSIX Threads])
 511                 fi
 512         fi
 513
 514         if test $ol_with_threads = posix ; then
 515                 AC_MSG_ERROR([could not locate POSIX Threads])
 516         fi
 517 fi
 518
 519 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 520         dnl check for Mach CThreads
 521         AC_CHECK_HEADERS(mach/cthreads.h)
 522         if test $ac_cv_header_mach_cthreads_h = yes ; then
 523                 ol_with_threads=found
 524
 525                 dnl A few platforms have cthread support in standard libraries
 526                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 527
 528                 if test $ol_link_threads = no ; then
 529                         dnl try -all_load
 530                         dnl this test needs work
 531                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 532                                 [ol_cv_cthread_all_load], [
 533                                 dnl save the CPPFLAGS
 534                                 save_LIBS="$LIBS"
 535                                 LIBS="-all_load $LIBS"
 536                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 537                                         cthread_fork((void *)0, (void *)0);
 538                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 539                                 dnl restore the LIBS
 540                                 LIBS="$save_LIBS"
 541                         ])
 542
 543                         if test $ol_cv_cthread_all_load = yes ; then
 544                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 545                                 ol_link_threads=mach
 546                         fi
 547                 fi
 548
 549                 if test $ol_link_threads != no ; then
 550                         : check for cthread specific functionality here
 551                 else
 552                         AC_MSG_ERROR([could not link with Mach CThreads])
 553                 fi
 554         fi
 555
 556         if test $ol_with_threads = mach ; then
 557                 AC_MSG_ERROR([could not locate Mach CThreads])
 558         fi
 559 fi
 560
 561 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 562         dnl check for SunOS5 LWP
 563         AC_CHECK_HEADERS(thread.h synch.h)
 564         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 565                 AC_CHECK_LIB(thread, thr_create, [have_lwp=yes], [have_lwp=no])
 566
 567                 if test $have_lwp = yes ; then
 568                         AC_DEFINE(HAVE_THR)
 569                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 570
 571                         if test $ol_with_preemptive = auto ; then
 572                                 ol_with_preemptive=yes
 573                         fi
 574                 fi
 575         fi
 576
 577         dnl check for SunOS4 LWP
 578         AC_CHECK_HEADERS(lwp/lwp.h)
 579         if test $ac_cv_header_lwp_lwp_h = yes ; then
 580                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 581
 582                 if test $have_lwp = yes ; then
 583                         AC_DEFINE(HAVE_LWP)
 584                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 585
 586                         if test $ol_with_preemptive = auto ; then
 587                                 ol_with_preemptive=no
 588                         fi
 589                 fi
 590         fi
 591 fi
 592
 593 if test $ol_with_preemptive = yes ; then
 594         AC_DEFINE(PREEMPTIVE_THREADS,1)
 595 fi
 596
 597 if test $ol_with_threads = manual ; then
 598         dnl User thinks he can manually configure threads.
 599         ol_link_threads=yes
 600
 601         AC_MSG_WARN([thread defines and link options must be set manually])
 602
 603         AC_CHECK_HEADERS(pthread.h sched.h)
 604         AC_CHECK_FUNCS(sched_yield pthread_yield)
 605         OL_LINUX_THREADS
 606
 607         AC_CHECK_HEADERS(mach/cthreads.h)
 608         AC_CHECK_HEADERS(lwp/lwp.h)
 609         AC_CHECK_HEADERS(thread.h synch.h)
 610 fi
 611
 612 if test $ol_with_threads = yes ; then
 613         dnl needed to get reentrant/threadsafe versions
 614         dnl
 615         dnl hopefully this will not cause problems with
 616         dnl non-threaded apps
 617         dnl
 618         AC_DEFINE(_REENTRANT,1)
 619         AC_DEFINE(_THREAD_SAFE,1)
 620 fi
 621
 622 dnl ----------------------------------------------------------------
 623
 624 if test $ol_link_threads = no ; then
 625         if test $ol_with_threads = yes ; then
 626                 AC_MSG_ERROR([no suitable thread support])
 627         fi
 628
 629         if test $ol_with_threads = auto ; then
 630                 AC_MSG_WARN([no suitable thread support, disabling threads])
 631                 ol_with_threads=no
 632         fi
 633
 634         AC_DEFINE(NO_THREADS,1)
 635         AC_DEFINE(PREEMPTIVE_THREADS,1)
 636         LTHREAD_LIBS=""
 637 fi
 638
 639 ol_link_ldbm=no
 640 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 641         OL_BERKELEY_DB2
 642
 643         if test $ol_cv_berkeley_db2 = yes ; then
 644                 ol_link_ldbm=db2
 645                 ol_with_ldbm_api=db2
 646
 647                 if test $ol_with_ldbm_type = hash ; then
 648                         AC_DEFINE(LDBM_USE_DBHASH,1)
 649                 else
 650                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 651                 fi
 652
 653                 dnl $ol_cv_lib_db2 should be yes or -ldb
 654                 dnl (it could be no, but that would be an error
 655                 if test $ol_cv_lib_db2 != yes ; then
 656                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 657                 fi
 658         fi
 659 fi
 660
 661 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 662         OL_BERKELEY_DB
 663
 664         if test $ol_cv_berkeley_db = yes ; then
 665                 ol_link_ldbm=db
 666                 ol_with_ldbm_api=db
 667
 668                 if test $ol_with_ldbm_type = hash ; then
 669                         AC_DEFINE(LDBM_USE_DBHASH,1)
 670                 else
 671                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 672                 fi
 673
 674                 dnl $ol_cv_lib_db should be yes or -ldb
 675                 dnl (it could be no, but that would be an error
 676                 if test $ol_cv_lib_db != yes ; then
 677                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 678                 fi
 679         fi
 680 fi
 681
 682 if test $ol_with_ldbm_api = manual ; then
 683         dnl User thinks he can manually configure LDBM api.
 684         ol_link_ldbm=yes
 685
 686         AC_MSG_WARN([LDBM defines and link options must be set manually])
 687
 688         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 689 fi
 690
 691 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 692         AC_MSG_WARN(Could not find LDBM with BTREE support)
 693         ol_with_ldbm_api=none
 694 fi
 695
 696 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 697         OL_GDBM
 698
 699         if test $ol_cv_gdbm = yes ; then
 700                 ol_link_ldbm=gdbm
 701                 ol_with_ldbm_api=gdbm
 702
 703                 if test $ol_cv_lib_gdbm != yes ; then
 704                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 705                 fi
 706         fi
 707 fi
 708
 709 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 710         OL_NDBM
 711
 712         if test $ol_cv_ndbm = yes ; then
 713                 ol_link_ldbm=ndbm
 714                 ol_with_ldbm_api=ndbm
 715
 716                 if test $ol_with_ldbm_api = ndbm ; then
 717                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 718                 fi
 719
 720                 if test $ol_cv_lib_ndbm != yes ; then
 721                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 722                 fi
 723         fi
 724 fi
 725
 726 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 727         AC_MSG_WARN(could not find suitable LDBM backend)
 728         if test $ol_enable_ldbm = yes ; then
 729                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 730         fi
 731
 732         AC_MSG_WARN(disabling LDBM)
 733         ol_enable_ldbm=no
 734 fi
 735
 736 if test $ol_enable_wrappers = yes ; then
 737         AC_CHECK_LIB(wrap, hosts_access,
 738                 [have_wrappers=yes], [have_wrappers=no])
 739
 740         if test $have_wrappers = yes ; then
 741                 AC_DEFINE(HAVE_TCPD)
 742                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 743         else
 744                 AC_MSG_WARN(could not find -lwrap)
 745                 if test $ol_enable_wrappers = yes ; then
 746                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 747                 fi
 748
 749                 AC_MSG_WARN(disabling wrappers support)
 750                 ol_enable_wrappers=no
 751         fi
 752
 753 fi
 754
 755 # ud needs termcap (should insert check here)
 756 ol_link_termcap=no
 757 AC_CHECK_HEADERS(termcap.h ncurses.h)
 758
 759 if test $ol_link_termcap = no ; then
 760         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 761         if test $have_termcap = yes ; then
 762                 AC_DEFINE(HAVE_TERMCAP)
 763                 ol_link_termcap=yes
 764                 TERMCAP_LIBS=-ltermcap
 765         fi
 766 fi
 767
 768 if test $ol_link_termcap = no ; then
 769         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 770         if test $have_ncurses = yes ; then
 771                 AC_DEFINE(HAVE_NCURSES)
 772                 ol_link_termcap=yes
 773                 TERMCAP_LIBS=-lncurses
 774         fi
 775 fi
 776
 777 if test $ol_link_termcap = no ; then
 778         AC_DEFINE(NO_TERMCAP,1)
 779         TERMCAP_LIBS=
 780 fi
 781
 782 # FreeBSD (and others) have crypt(3) in -lcrypt
 783 if test $ol_enable_crypt != no ; then
 784         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 785                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 786                         have_crypt=yes], [have_crypt=no])])
 787
 788         if test $have_crypt = yes ; then
 789                 AC_DEFINE(HAVE_CRYPT,1)
 790         else
 791                 AC_MSG_WARN(could not find crypt)
 792                 if test $ol_enable_crypt = yes ; then
 793                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 794                 fi
 795
 796                 AC_MSG_WARN(disabling crypt support)
 797                 ol_enable_crypt=no
 798         fi
 799 fi
 800
 801 # FreeBSD (and others) have setproctitle(3) in -lutil
 802 if test $ol_enable_proctitle != no ; then
 803         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 804                 AC_CHECK_LIB(util, setproctitle,
 805                         [have_setproctitle=yes
 806                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 807                         [have_setproctitle=no
 808                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 809
 810         if test $have_setproctitle = yes ; then
 811                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 812         fi
 813 fi
 814
 815 dnl ----------------------------------------------------------------
 816 dnl Checks for header files.
 817 AC_HEADER_STDC
 818
 819 if test $ac_cv_header_stdc != yes; then
 820         AC_MSG_WARN([could not locate Standard C headers])
 821 fi
 822
 823 AC_HEADER_DIRENT
 824 AC_HEADER_SYS_WAIT
 825 AC_CHECK_HEADERS(       \
 826         stdarg.h                \
 827         stddef.h                \
 828         errno.h                 \
 829         fcntl.h                 \
 830         filio.h                 \
 831         getopt.h                \
 832         libutil.h               \
 833         limits.h                \
 834         malloc.h                \
 835         regex.h                 \
 836         sgtty.h                 \
 837         sys/file.h              \
 838         sys/filio.h             \
 839         sys/errno.h             \
 840         sys/ioctl.h             \
 841         sys/param.h             \
 842         sys/socket.h    \
 843         sys/syslog.h    \
 844         sys/time.h              \
 845         sys/types.h             \
 846         syslog.h                \
 847         termios.h               \
 848         unistd.h                \
 849 )
 850
 851 dnl ----------------------------------------------------------------
 852 dnl Checks for typedefs, structures, and compiler characteristics.
 853 AC_TYPE_GETGROUPS
 854 AC_TYPE_MODE_T
 855 AC_TYPE_OFF_T
 856 AC_TYPE_PID_T
 857 AC_TYPE_SIGNAL
 858 AC_TYPE_SIZE_T
 859 AC_TYPE_UID_T
 860 AC_STRUCT_ST_BLKSIZE
 861 AC_HEADER_TIME
 862 AC_STRUCT_TM
 863
 864 OL_C_UPPER_LOWER
 865 AC_C_CONST
 866
 867 dnl AC_CHECK_SIZEOF(short)
 868 dnl AC_CHECK_SIZEOF(int)
 869 dnl AC_CHECK_SIZEOF(long)
 870
 871 dnl ----------------------------------------------------------------
 872 dnl Checks for library functions.
 873 AC_FUNC_MEMCMP
 874 AC_FUNC_STRFTIME
 875 AC_FUNC_VPRINTF
 876
 877 if test $ac_cv_func_vprintf = yes ; then
 878         dnl check for vsnprintf
 879         AC_CHECK_FUNCS(vsnprintf)
 880 fi
 881
 882 AC_FUNC_WAIT3
 883
 884 AC_CHECK_FUNCS(         \
 885         bcopy                   \
 886         getopt                  \
 887         flock                   \
 888         gethostname             \
 889         gettimeofday    \
 890         getdtablesize   \
 891         lockf                   \
 892         memcpy                  \
 893         memmove                 \
 894         mkstemp                 \
 895         mktime                  \
 896         select                  \
 897         setpwfile               \
 898         setsid                  \
 899         signal                  \
 900         sigset                  \
 901         snprintf                \
 902         socket                  \
 903         strerror                \
 904         strstr                  \
 905         strrchr                 \
 906         strsep                  \
 907         strtod                  \
 908         strtol                  \
 909         strtoul                 \
 910         sysconf                 \
 911         tempnam                 \
 912         waitpid                 \
 913 )
 914
 915 AC_REPLACE_FUNCS(getopt strdup tempnam)
 916
 917 dnl ----------------------------------------------------------------
 918 # Check Configuration
 919 OL_SYS_ERRLIST
 920
 921 dnl ----------------------------------------------------------------
 922 dnl Sort out defines
 923
 924 if test $ol_enable_debug != no ; then
 925         AC_DEFINE(LDAP_DEBUG,1)
 926 fi
 927 dnl     if test $ol_enable_syslog != no ; then
 928 dnl             AC_DEFINE(LDAP_SYSLOG,1)
 929 dnl     fi
 930 if test $ol_enable_libui = yes ; then
 931         AC_DEFINE(LDAP_LIBUI,1)
 932 fi
 933 if test $ol_enable_cache = no ; then
 934         AC_DEFINE(LDAP_NOCACHE,1)
 935 fi
 936 if test $ol_enable_dns != no ; then
 937         AC_DEFINE(LDAP_DNS,1)
 938 fi
 939 if test $ol_enable_proctitle != no ; then
 940         AC_DEFINE(LDAP_PROCTITLE,1)
 941 fi
 942 if test $ol_enable_referrals != no ; then
 943         AC_DEFINE(LDAP_REFERRALS,1)
 944 fi
 945 if test $ol_enable_cldap != no ; then
 946         AC_DEFINE(LDAP_CONNECTIONLESS,1)
 947 fi
 948
 949 if test $ol_enable_aclgroups != no ; then
 950         AC_DEFINE(SLAPD_ACLGROUPS,1)
 951 fi
 952 if test $ol_enable_crypt != no ; then
 953         AC_DEFINE(SLAPD_CRYPT,1)
 954 fi
 955 if test $ol_enable_md5 != no ; then
 956         AC_DEFINE(SLAPD_MD5,1)
 957 fi
 958 if test $ol_enable_sha1 != no ; then
 959         AC_DEFINE(SLAPD_SHA1,1)
 960 fi
 961 if test $ol_enable_phonetic != no ; then
 962         AC_DEFINE(SLAPD_PHONETIC,1)
 963 fi
 964 if test $ol_enable_rlookups != no ; then
 965         AC_DEFINE(SLAPD_RLOOKUPS,1)
 966 fi
 967
 968 if test $ol_link_ldbm != no ; then
 969         AC_DEFINE(SLAPD_LDBM,1)
 970         BUILD_SLAPD=yes
 971         BUILD_LDBM=yes
 972 fi
 973
 974 if test $ol_enable_passwd != no ; then
 975         AC_DEFINE(SLAPD_PASSWD,1)
 976         BUILD_SLAPD=yes
 977         BUILD_PASSWD=yes
 978 fi
 979
 980 if test $ol_enable_shell != no ; then
 981         AC_DEFINE(SLAPD_SHELL,1)
 982         BUILD_SLAPD=yes
 983         BUILD_SHELL=yes
 984 fi
 985
 986 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
 987         $BUILD_SLAPD = yes ; then
 988         BUILD_SLURPD=yes
 989 fi
 990
 991 if test $ol_enable_ldapd != no ; then
 992         BUILD_LDAPD=yes
 993 fi
 994
 995 dnl ----------------------------------------------------------------
 996
 997 AC_SUBST(BUILD_LDAPD)
 998 AC_SUBST(BUILD_SLAPD)
 999   AC_SUBST(BUILD_LDBM)
1000   AC_SUBST(BUILD_PASSWD)
1001   AC_SUBST(BUILD_SHELL)
1002 AC_SUBST(BUILD_SLURPD)
1003
1004
1005 AC_SUBST(LDAP_LIBS)
1006 AC_SUBST(LDAPD_LIBS)
1007 AC_SUBST(SLAPD_LIBS)
1008 AC_SUBST(SLURPD_LIBS)
1009 AC_SUBST(LDBM_LIBS)
1010 AC_SUBST(LTHREAD_LIBS)
1011 AC_SUBST(LUTIL_LIBS)
1012
1013 AC_SUBST(KRB_LIBS)
1014 AC_SUBST(TERMCAP_LIBS)
1015
1016 dnl ----------------------------------------------------------------
1017 dnl final output
1018 dnl
1019
1020 dnl AC_OUTPUT( \
1021 dnl contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1022 dnl contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1023 dnl contrib/whois++/Makefile:build/top.mk:contrib/whois++/Makefile.in:build/rules.mk \
1024 dnl [date > stamp-h])
1025
1026 AC_OUTPUT( \
1027 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1028 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1029 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1030 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1031 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1032 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1033 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1034 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1035 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1036 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1037 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1038 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1039 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1040 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1041 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1042 include/Makefile:build/top.mk:include/Makefile.in \
1043 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1044 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
1045 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
1046 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
1047 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
1048 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
1049 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
1050 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
1051 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1052 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1053 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1054 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1055 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1056 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1057 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1058 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1059 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1060 tests/Makefile:build/top.mk:tests/Makefile.in \
1061 ,[
1062 date > stamp-h
1063 echo Please \"make depend\" to build dependencies
1064 ])