git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(build/version)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17
  18 OL_VERSION=`cat $ac_aux_dir/version`
  19 if test -z "$OL_VERSION"; then
  20         AC_MSG_ERROR([could not determine version])
  21 fi
  22
  23 dnl ----------------------------------------------------------------
  24 dnl Determine host platform
  25 dnl             we try not to use this for much
  26 AC_CANONICAL_SYSTEM
  27
  28 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  29 AC_SUBST(PACKAGE)
  30 AC_SUBST(VERSION)
  31 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  32 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  33
  34 dnl We use autoconf features new to 2.13.
  35 dnl aclocal.m4 should be built using aclocal from automake 1.4
  36 dnl libtool 1.3.3 should be installed.
  37 AC_PREREQ(2.13)dnl Required Autoconf version
  38
  39 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  40
  41 dnl ----------------------------------------------------------------
  42 dnl Start Args
  43 AC_MSG_CHECKING(configure arguments)
  44 AC_PREFIX_DEFAULT(/usr/local)
  45
  46 top_builddir=`pwd`
  47 AC_SUBST(top_builddir)dnl
  48
  49 ldap_subdir="openldap"
  50
  51 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  52         if test "$withval" = "no"; then
  53                 ldap_subdir=""
  54         elif test "$withval" != "yes"; then
  55                 ldap_subdir="$withval"
  56         fi
  57 ])dnl
  58
  59 AC_SUBST(ldap_subdir)dnl
  60
  61 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  62 dnl ol_enable_syslog=no
  63 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  64 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  65 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  66 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  67 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  68 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  69 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  70         no, [yes no])dnl
  71
  72 dnl General "with" options
  73 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  74
  75 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl  with Cyrus SASL support],
  76         auto, [auto yes no] )
  77 OL_ARG_WITH(fetch,[  --with-fetch  with fetch URL support],
  78         auto, [auto yes no] )
  79 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  80         auto, [auto k5 k4 afs yes no])
  81 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  82         auto, [auto yes no] )
  83 OL_ARG_WITH(threads,[  --with-threads   use threads],
  84         auto, [auto posix mach lwp yes no manual] )
  85 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  86         auto, [auto ssleay openssl yes no] )
  87 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  88         auto, [auto yes no manual] )
  89
  90 dnl Server options
  91
  92 dnl LDAPD OPTIONS
  93 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  94 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  95
  96 dnl SLAPD OPTIONS
  97 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  98 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  99 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 100 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 101 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 102 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 103 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 104 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 105 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 106 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 107
 108 dnl SLAPD Backend options
 109 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 110 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 111         [static dynamic])
 112 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 113 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 114         [static dynamic])
 115 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 116 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 117         [static dynamic])
 118 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 119         [auto db2 db mdbm gdbm ndbm manual])
 120 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 121         [auto btree hash])
 122
 123 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 124 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 125         [static dynamic])
 126 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 127 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 128         [static dynamic])
 129 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 130 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 131         [static dynamic])
 132 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 133 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 134         [static dynamic])
 135
 136 dnl SLURPD OPTIONS
 137 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 138 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 139
 140 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 141 AC_ENABLE_STATIC
 142 dnl AC_DISABLE_SHARED
 143 AC_ENABLE_SHARED
 144
 145 dnl General "enable" options
 146 # validate options
 147 if test $ol_enable_dns = yes ; then
 148         if test $ol_enable_referrals = no ; then
 149                 AC_MSG_ERROR([DNS requires --enable-referrals])
 150         fi
 151         if test $ol_enable_referrals = auto ; then
 152                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 153                 ol_enable_referrals=yes
 154         fi
 155 fi
 156
 157 if test $ol_enable_slapd = no ; then
 158         dnl SLAPD was specificallly disabled
 159         if test $ol_enable_bdb2 = yes ; then
 160                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 161         fi
 162         if test $ol_enable_ldap = yes ; then
 163                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 164         fi
 165         if test $ol_enable_ldbm = yes ; then
 166                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 167         fi
 168         if test $ol_enable_passwd = yes ; then
 169                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 170         fi
 171         if test $ol_enable_perl = yes ; then
 172                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 173         fi
 174         if test $ol_enable_shell = yes ; then
 175                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 176         fi
 177         if test $ol_enable_tcl = yes ; then
 178                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 179         fi
 180         if test $ol_enable_modules = yes ; then
 181                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 182         fi
 183         if test $ol_enable_multimaster = yes ; then
 184                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 185         fi
 186         if test $ol_enable_wrappers = yes ; then
 187                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 188         fi
 189         if test $ol_enable_phonetic = yes ; then
 190                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 191         fi
 192         if test $ol_enable_quipu = yes ; then
 193                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 194         fi
 195         if test $ol_enable_rlookups = yes ; then
 196                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 197         fi
 198         if test $ol_with_ldbm_api != auto ; then
 199                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 200         fi
 201         if test $ol_with_ldbm_type != auto ; then
 202                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 203         fi
 204         if test $ol_with_bdb2_module != static ; then
 205                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 206         fi
 207         if test $ol_with_ldap_module != static ; then
 208                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 209         fi
 210         if test $ol_with_ldbm_module != static ; then
 211                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 212         fi
 213         if test $ol_with_passwd_module != static ; then
 214                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 215         fi
 216         if test $ol_with_perl_module != static ; then
 217                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 218         fi
 219         if test $ol_with_shell_module != static ; then
 220                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 221         fi
 222         if test $ol_with_tcl_module != static ; then
 223                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 224         fi
 225         if test $ol_enable_slurpd = yes ; then
 226                 AC_MSG_ERROR([slurpd requires slapd])
 227         fi
 228
 229         # force settings to no
 230         ol_enable_bdb2=no
 231         ol_enable_ldap=no
 232         ol_enable_ldbm=no
 233         ol_enable_passwd=no
 234         ol_enable_perl=no
 235         ol_enable_shell=no
 236         ol_enable_tcl=no
 237
 238         ol_enable_modules=no
 239         ol_enable_multimaster=no
 240         ol_enable_phonetic=no
 241         ol_enable_quipu=no
 242         ol_enable_rlookups=no
 243         ol_enable_wrappers=no
 244
 245         ol_with_ldbm_api=no
 246         ol_with_ldbm_type=no
 247
 248         ol_with_bdb2_module=static
 249         ol_with_ldap_module=static
 250         ol_with_ldbm_module=static
 251         ol_with_passwd_module=static
 252         ol_with_perl_module=static
 253         ol_with_shell_module=static
 254         ol_with_tcl_module=static
 255
 256         ol_enable_slurpd=no
 257
 258 elif test $ol_enable_ldbm = no ; then
 259         dnl SLAPD without LDBM
 260
 261         if test $ol_with_ldbm_api != auto ; then
 262                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 263         fi
 264
 265         if test $ol_with_ldbm_type != auto ; then
 266                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 267         fi
 268
 269         if test $ol_with_ldbm_module != static ; then
 270                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 271         fi
 272
 273         if test $ol_enable_bdb2 = yes ; then
 274                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 275         fi
 276
 277         if test $ol_enable_modules != yes -a \
 278                 $ol_enable_ldap = no -a \
 279                 $ol_enable_passwd = no -a \
 280                 $ol_enable_perl = no -a \
 281                 $ol_enable_shell = no -a \
 282                 $ol_enable_tcl = no ; then
 283                 AC_MSG_ERROR([slapd requires a backend])
 284         fi
 285
 286         ol_with_ldbm_api=no
 287         ol_with_ldbm_type=no
 288         ol_with_ldbm_module=static
 289
 290 elif test $ol_enable_bdb2 = yes ; then
 291         dnl SLAPD with BDB2
 292
 293         if test $ol_with_ldbm_api != auto -a \
 294                 $ol_with_ldbm_api != db2 ; then
 295                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 296         fi
 297
 298         ol_with_ldbm_api=db2
 299
 300 else
 301         dnl SLAPD with LDBM
 302
 303         if test $ol_enable_bdb2 != no ; then
 304                 if test $ol_with_ldbm_api != auto -a \
 305                         $ol_with_ldbm_api != db2 ; then
 306                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 307                         ol_enable_bdb2=no
 308                 fi
 309         fi
 310
 311         if test $ol_with_ldbm_api = gdbm -a \
 312                 $ol_with_ldbm_type = btree ; then
 313                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 314         fi
 315         if test $ol_with_ldbm_api = mdbm -a \
 316                 $ol_with_ldbm_type = btree ; then
 317                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 318         fi
 319         if test $ol_with_ldbm_api = ndbm -a \
 320                 $ol_with_ldbm_type = btree ; then
 321                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 322         fi
 323 fi
 324
 325 if test $ol_enable_slurpd = yes ; then
 326         dnl SLURPD was specifically enabled
 327         if test $ol_with_threads = no ; then
 328                 AC_MSG_ERROR([slurpd requires threads])
 329         fi
 330 fi
 331
 332 AC_MSG_RESULT(done)
 333
 334 ## Initialize vars
 335 LDAP_LIBS=
 336 LDIF_LIBS=
 337 LDBM_LIBS=
 338 LTHREAD_LIBS=
 339 LUTIL_LIBS=
 340
 341 LDAPD_LIBS=
 342 SLAPD_LIBS=
 343 SLURPD_LIBS=
 344
 345 BUILD_LDAPD=no
 346 BUILD_SLAPD=no
 347 BUILD_SLURPD=no
 348
 349 BUILD_BDB2=no
 350 BUILD_LDAP=no
 351 BUILD_LDBM=no
 352 BUILD_PASSWD=no
 353 BUILD_PERL=no
 354 BUILD_QUIPU=no
 355 BUILD_SHELL=no
 356 BUILD_TCL=no
 357 BUILD_THREAD=no
 358
 359 BUILD_BDB2_DYNAMIC=static
 360 BUILD_LDAP_DYNAMIC=static
 361 BUILD_LDBM_DYNAMIC=static
 362 BUILD_PASSWD_DYNAMIC=static
 363 BUILD_PERL_DYNAMIC=static
 364 BUILD_SHELL_DYNAMIC=static
 365 BUILD_TCL_DYNAMIC=static
 366
 367 SLAPD_MODULES_LDFLAGS=
 368 SLAPD_MODULES_CPPFLAGS=
 369 SLAPD_MODULES_LIST=
 370
 371 SLAPD_PERL_LDFLAGS=
 372 SLAPD_PERL_CPPFLAGS=
 373
 374 KRB_LIBS=
 375 READLINE_LIBS=
 376 SASL_LIBS=
 377 TERMCAP_LIBS=
 378 TLS_LIBS=
 379 MODULES_LIBS=
 380
 381 dnl ----------------------------------------------------------------
 382 dnl Checks for programs
 383
 384 dnl AC_PROG_INSTALL
 385
 386 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 387
 388
 389 dnl
 390 dnl Determine which C translator to use
 391 dnl
 392
 393 dnl AIX Thread requires we use cc_r or xlc_r.
 394 dnl But only do this IF AIX and CC is not set
 395 dnl and threads are auto|yes|posix.
 396 dnl
 397 dnl If we find cc_r|xlc_r, force pthreads and assume
 398 dnl             pthread_create is in $LIBS (ie: don't bring in
 399 dnl             any additional thread libraries)
 400 dnl If we do not find cc_r|xlc_r, disable threads
 401
 402 ol_aix_threads=no
 403 case "$target" in
 404 *-*-aix*) dnl all AIX is not a good idea.
 405         if test -z "$CC" ; then
 406                 case "$ol_with_threads" in
 407                 auto | yes |  posix) ol_aix_threads=yes ;;
 408                 esac
 409         fi
 410 ;;
 411 esac
 412
 413 if test $ol_aix_threads = yes ; then
 414         if test -z "${CC}" ; then
 415                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 416
 417                 if test "$CC" = cc ; then
 418                         dnl no CC! don't allow --with-threads
 419                         if test $ol_with_threads != auto ; then
 420                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 421                         else
 422                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 423                         fi
 424                         ol_with_threads=no
 425                 fi
 426         fi
 427
 428         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 429                 ol_with_threads=posix
 430                 ol_cv_pthread_create=yes
 431         fi
 432 fi
 433
 434 if test -z "${CC}"; then
 435         AC_CHECK_PROGS(CC,cc)
 436 fi
 437
 438 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 439 dnl (for now, let autoconf sort this out)
 440 dnl CFLAGS=${CFLAGS-""}
 441
 442 AC_LIBTOOL_DLOPEN
 443 AC_PROG_LIBTOOL
 444 dnl AC_PROG_MAKE_SET
 445
 446 AC_PROG_AWK
 447 OL_PROG_LN_H
 448 AC_PROG_LN_S
 449
 450 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 451         LN_S="$LN_H"
 452 fi
 453
 454 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 455         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 456 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 457 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 458
 459 ol_link_perl=no
 460 if test $ol_enable_perl != no ; then
 461         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 462
 463         if test "no$PERLBIN" = "no" ; then
 464                 if test $ol_enable_perl = yes ; then
 465                         AC_MSG_ERROR([could not locate perl])
 466                 fi
 467
 468         else
 469                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 470                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 471
 472                 dnl should check perl version
 473                 ol_link_perl=yes
 474         fi
 475 fi
 476
 477 AC_PROG_CPP
 478
 479 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 480         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 481
 482 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 483         AC_MSG_WARN([programs compiled here do run here...])
 484         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 485
 486 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 487         AC_MSG_WARN([programs compiled here do not run here...])
 488         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 489 fi
 490
 491 dnl Checks for UNIX Variants
 492 AC_AIX
 493 AC_ISC_POSIX
 494 AC_MINIX
 495
 496 dnl Checks for system services
 497 AC_CYGWIN
 498 AC_MINGW32
 499 AC_EXEEXT
 500 AC_OBJEXT
 501
 502 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 503
 504 dnl BeOS requires -lbe -lroot -lnet
 505 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 506
 507 dnl OpenLDAP requires STDC features
 508 AM_PROG_CC_STDC
 509 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 510         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 511 fi
 512
 513 dnl Check cc depend flags
 514 OL_MKDEPEND
 515 if test "${ol_cv_mkdep}" = no ; then
 516         # this will soon become an error
 517         AC_MSG_WARN([do not know how to generate dependencies])
 518 fi
 519
 520 dnl ----------------------------------------------------------------
 521 dnl Checks for header files.
 522 OL_HEADER_STDC
 523
 524 if test $ol_cv_header_stdc != yes; then
 525         AC_MSG_WARN([could not locate Standard C compliant headers])
 526 fi
 527
 528 AC_HEADER_DIRENT
 529 AC_HEADER_SYS_WAIT
 530 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 531 if test $am_cv_sys_posix_termios = yes ; then
 532         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 533                 [define if you have POSIX termios])
 534 fi
 535
 536 AC_CHECK_HEADERS(       \
 537         arpa/inet.h             \
 538         arpa/nameser.h  \
 539         assert.h                \
 540         crypt.h                 \
 541         errno.h                 \
 542         fcntl.h                 \
 543         filio.h                 \
 544         getopt.h                \
 545         grp.h                   \
 546         libutil.h               \
 547         limits.h                \
 548         locale.h                \
 549         netinet/tcp.h   \
 550         malloc.h                \
 551         memory.h                \
 552         psap.h                  \
 553         pwd.h                   \
 554         resolv.h                \
 555         sgtty.h                 \
 556         shadow.h                \
 557         stdarg.h                \
 558         stddef.h                \
 559         string.h                \
 560         strings.h               \
 561         sysexits.h              \
 562         sys/file.h              \
 563         sys/filio.h             \
 564         sys/errno.h             \
 565         sys/ioctl.h             \
 566         sys/param.h             \
 567         sys/resource.h  \
 568         sys/select.h    \
 569         sys/socket.h    \
 570         sys/syslog.h    \
 571         sys/time.h              \
 572         sys/types.h             \
 573         syslog.h                \
 574         termios.h               \
 575         unistd.h                \
 576 )
 577
 578 dnl ----------------------------------------------------------------
 579 dnl Checks for libraries
 580
 581 dnl Find socket()
 582 dnl Likely combinations:
 583 dnl             -lsocket [ -lnsl_s | -lnsl ]
 584 dnl             -linet
 585
 586 AC_CHECK_FUNC(socket, :, [
 587 dnl
 588 dnl hopefully we won't include too many libraries
 589 dnl
 590         AC_CHECK_LIB(socket, main)
 591         AC_CHECK_LIB(net, main)
 592         AC_CHECK_LIB(net, socket)
 593         AC_CHECK_LIB(nsl_s, main)
 594         AC_CHECK_LIB(nsl, main)
 595         AC_CHECK_LIB(inet, socket)
 596         AC_CHECK_LIB(gen, main)
 597 ])
 598
 599 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 600
 601 dnl Select arg types
 602 dnl (if this detection becomes permenent, it and the select() detection
 603 dnl should be done before the yielding select test)
 604 AC_FUNC_SELECT_ARGTYPES
 605
 606
 607 AC_CHECK_HEADERS( regex.h )
 608 if test "$ac_cv_header_regex_h" != yes ; then
 609         AC_MSG_ERROR([POSIX regex.h required.])
 610 fi
 611 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 612
 613 OL_POSIX_REGEX
 614 if test "$ol_cv_c_posix_regex" = no ; then
 615         AC_MSG_ERROR([broken POSIX regex!])
 616 fi
 617
 618
 619 dnl HP-UX requires -lV3
 620 AC_CHECK_LIB(V3, sigset)
 621
 622
 623 # find res_search
 624 if test $ol_enable_dns != no ; then
 625         dnl Check for resolver routines
 626         AC_CHECK_FUNC(res_search,:)
 627         if test $ac_cv_func_res_search = no ; then
 628                 AC_CHECK_LIB(bind, res_search)
 629                 ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 630         fi
 631         if test $ac_cv_func_res_search = no ; then
 632                 AC_CHECK_LIB(bind, __res_search)
 633                 ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 634         fi
 635         if test $ac_cv_func_res_search = no ; then
 636                 AC_CHECK_LIB(resolv, res_search)
 637                 ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 638         fi
 639
 640         if test "$ac_cv_func_res_search" = yes ; then
 641                 AC_DEFINE(HAVE_RES_SEARCH,1,
 642                         [define if you have res_search()])
 643         elif test $ol_enable_dns = yes ; then
 644                 AC_MSG_ERROR([--enable-dns requires res_search])
 645         else
 646                 AC_MSG_WARN([no res_search, disabling DNS support])
 647         fi
 648 fi
 649
 650
 651 # ISODE tests
 652 ol_link_isode=no
 653 if test $ol_enable_ldapd != no ; then
 654         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 655
 656         dnl look for ISODE libraries
 657         AC_CHECK_LIB(xtpp, main, [
 658                 ol_link_isode=yes
 659                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 660                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 661                 ],:,[-lxtdsap -lxtisode -losi])
 662         AC_CHECK_LIB(dsap, main, [
 663                 ol_link_isode=yes
 664                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 665                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 666                 ],:,[-lisode])
 667         AC_CHECK_LIB(isode, main, [
 668                 ol_link_isode=yes
 669                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 670                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 671                 ],:)
 672 fi
 673
 674 if test $ol_link_isode != no; then
 675         AC_CHECK_LIB(pp, main, [
 676                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 677                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 678                 ],:)
 679
 680         AC_PATH_PROG(PEPSY, pepsy)
 681 fi
 682
 683 if test $ol_enable_quipu != no ; then
 684         AC_CHECK_HEADERS(quipu/commonarg.h)
 685
 686         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 687                 BUILD_QUIPU=yes
 688         elif test $ol_enable_quipu = auto ; then
 689                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 690         else
 691                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 692         fi
 693 fi
 694
 695 dnl
 696 dnl check for kerberos
 697 dnl
 698 ol_link_kerberos=no
 699
 700 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 701         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 702
 703         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 704                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 705                         [-lkrb5 -ldes425])
 706
 707                 if test $have_k5 = yes ; then
 708                         ol_with_kerberos=found
 709                         ol_link_kerberos=yes
 710
 711                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 712
 713                         LIBS="$KRB_LIBS $LIBS"
 714
 715                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 716                                 [ol_cv_var_des_debug], [
 717                                 dnl save the flags
 718                                 save_LIBS="$LIBS"
 719                                 LIBS="$KRB_LIBS $LIBS"
 720                                 AC_TRY_LINK([
 721 #include <kerberosIV/krb.h>
 722 #include <kerberosIV/des.h>
 723 extern int des_debug;
 724 ],[
 725 des_debug = 1;
 726 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 727                                 dnl restore the LIBS
 728                                 LIBS="$save_LIBS"
 729                         ])
 730
 731                         if test $ol_cv_var_des_debug = yes ; then
 732                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 733                                         [define if you have Kerberos des_debug])
 734                         fi
 735
 736                         LIBS="$save_LIBS"
 737                 fi
 738         fi
 739 fi
 740
 741 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 742         AC_CHECK_HEADERS(krb.h des.h)
 743
 744         if test $ac_cv_header_krb_h = yes ; then
 745                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 746
 747                 if test $have_k4 = yes ; then
 748                         ol_with_kerberos=found
 749                         ol_link_kerberos=yes
 750
 751                         KRB_LIBS="-lkrb -ldes"
 752                 fi
 753         fi
 754 fi
 755
 756 if test $ol_link_kerberos = yes ; then
 757         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 758 fi
 759
 760 dnl
 761 dnl Check for SSL/TLS
 762 dnl
 763 ol_link_tls=no
 764 if test $ol_with_tls != no ; then
 765
 766         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 767
 768         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 769                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 770                         [have_ssleay=yes
 771                         need_rsaref=no],
 772                         [have_ssleay=no],
 773                         [-lcrypto])
 774
 775                 if test $have_ssleay = no ; then
 776                         AC_CHECK_LIB(ssl, SSL_library_init,
 777                                 [have_ssleay=yes
 778                                 need_rsaref=no], [have_ssleay=no],
 779                                 [-lcrypto])
 780                 fi
 781
 782                 if test $have_ssleay = no ; then
 783                         AC_CHECK_LIB(ssl, ssl3_accept,
 784                                 [have_ssleay=yes
 785                                 need_rsaref=yes], [have_ssleay=no],
 786                                 [-lcrypto -lRSAglue -lrsaref])
 787                 fi
 788
 789                 if test $have_ssleay = yes ; then
 790                         ol_with_tls=found
 791                         ol_link_tls=yes
 792
 793                         AC_DEFINE(HAVE_SSLEAY, 1,
 794                                 [define if you have SSLeay or OpenSSL])
 795
 796                         if test $need_rsaref = yes; then
 797                                 AC_DEFINE(HAVE_RSAREF, 1,
 798                                         [define if you have RSAref])
 799
 800                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 801                         else
 802                                 TLS_LIBS="-lssl -lcrypto"
 803                         fi
 804                 fi
 805         fi
 806 fi
 807
 808 if test $ol_link_tls = yes ; then
 809         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 810 fi
 811
 812 dnl Tests for reentrant functions necessary to build a
 813 dnl thread_safe -lldap.
 814 AC_CHECK_FUNCS(         \
 815         ctime_r                 \
 816         gethostbyname_r gethostbyaddr_r \
 817 )
 818
 819 if test "$ac_cv_func_ctime_r" = no ; then
 820         ol_cv_func_ctime_r_nargs=0
 821 else
 822         OL_FUNC_CTIME_R_NARGS
 823 dnl     OL_FUNC_CTIME_R_TYPE
 824 fi
 825
 826 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 827         OL_FUNC_GETHOSTBYNAME_R_NARGS
 828 else
 829         ol_cv_func_gethostbyname_r_nargs=0
 830 fi
 831
 832 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 833         OL_FUNC_GETHOSTBYADDR_R_NARGS
 834 else
 835         ol_cv_func_gethostbyaddr_r_nargs=0
 836 fi
 837
 838 if test "$ac_cv_func_ctime_r" = yes \
 839         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 840         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 841         -a "$ac_cv_func_gethostbyname_r" = yes \
 842         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 843         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 844         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 845         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 846         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 847         ; then
 848
 849         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 850 fi
 851
 852 ol_link_threads=no
 853 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 854         -o $ol_with_threads = posix ; then
 855
 856         AC_CHECK_HEADERS(pthread.h sched.h)
 857
 858         if test $ac_cv_header_pthread_h = yes ; then
 859                 OL_POSIX_THREAD_VERSION
 860
 861                 if test $ol_cv_pthread_version = final ; then
 862                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 863                                 [define if pthreads API compatible with final spec])
 864                 elif test $ol_cv_pthread_version = draft4 ; then
 865                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 866                                 [define if pthreads API compatible with draft4 spec])
 867                 else
 868                         AC_MSG_ERROR([unknown pthread version])
 869                 fi
 870
 871                 # consider threads found
 872                 ol_with_threads=found
 873
 874                 OL_HEADER_LINUX_THREADS
 875
 876                 dnl Now the hard part, how to link?
 877                 dnl
 878                 dnl currently supported checks:
 879                 dnl
 880                 dnl Check for no flags
 881                 dnl     pthread_create() in $LIBS
 882                 dnl
 883                 dnl Check special pthread (final) flags
 884                 dnl     pthread_create() with -mt (Solaris)
 885                 dnl     pthread_create() with -kthread (FreeBSD)
 886                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 887                 dnl     pthread_create() with -pthreads (?)
 888                 dnl     pthread_create() with -mthreads (AIX)
 889                 dnl     pthread_create() with -thread (?)
 890                 dnl
 891                 dnl Check pthread (final) libraries
 892                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 893                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 894                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 895                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 896                 dnl     pthread_create() in -lpthread (many)
 897                 dnl     pthread_create() in -lc_r (FreeBSD)
 898                 dnl
 899                 dnl Check pthread (draft4) flags (depreciated)
 900                 dnl     pthread_create() with -threads (OSF/1)
 901                 dnl
 902                 dnl Check pthread (draft4) libraries (depreciated)
 903                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 904                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 905                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 906                 dnl     pthread_create() in -lpthreads (many)
 907                 dnl
 908
 909                 dnl pthread_create in $LIBS
 910                 AC_CACHE_CHECK([for pthread_create in default libraries],
 911                         ol_cv_pthread_create,[
 912                 AC_TRY_RUN([
 913 #include <pthread.h>
 914 #ifndef NULL
 915 #define NULL (void*)0
 916 #endif
 917
 918 static void *task(p)
 919         void *p;
 920 {
 921         return (void *) (p == NULL);
 922 }
 923
 924 int main(argc, argv)
 925         int argc;
 926         char **argv;
 927 {
 928         pthread_t t;
 929         int status;
 930
 931         /* make sure pthread_create() isn't just a stub */
 932 #if HAVE_PTHREADS_D4
 933         status = pthread_create(&t, pthread_attr_default, task, NULL);
 934 #else
 935         status = pthread_create(&t, NULL, task, NULL);
 936 #endif
 937
 938         if( status ) return status;
 939
 940         /* make sure pthread_detach() isn't just a stub */
 941 #if HAVE_PTHREADS_D4
 942         status = pthread_detach( &t );
 943 #else
 944         status = pthread_detach( t );
 945 #endif
 946
 947         return status;
 948 }
 949 ],
 950                         [ol_cv_pthread_create=yes],
 951                         [ol_cv_pthread_create=no],
 952                         [dnl assume yes
 953                         ol_cv_pthread_create=yes])])
 954
 955                 if test $ol_cv_pthread_create != no ; then
 956                         ol_link_threads=posix
 957                         ol_link_pthreads=""
 958                 fi
 959
 960                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 961                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 962                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 963                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 964                 OL_PTHREAD_TRY_LINK([-mthreads],[ol_cv_pthread_mthreads])
 965                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 966
 967                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 968                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 969                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 970                         [ol_cv_pthread_lpthread_lmach_lexc])
 971 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 972 dnl                     [ol_cv_pthread_lpthread_lexc])
 973
 974                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 975                         [ol_cv_pthread_lib_lpthread_woff])
 976
 977                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 978                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 979
 980                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 981
 982                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 983                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 984                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 985                         [ol_cv_pthread_lpthreads_lmach_lexc])
 986                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 987                         [ol_cv_pthread_lpthreads_lexc])
 988
 989                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 990
 991                 if test $ol_link_threads != no ; then
 992                         AC_DEFINE(HAVE_PTHREADS,1,
 993                                 [define if you have POSIX Threads])
 994
 995                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 996
 997                         dnl save flags
 998                         save_CPPFLAGS="$CPPFLAGS"
 999                         save_LIBS="$LIBS"
1000                         LIBS="$LTHREAD_LIBS $LIBS"
1001
1002                         dnl All POSIX Thread (final) implementations should have
1003                         dnl sched_yield instead of pthread yield.
1004                         dnl check for both
1005                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1006
1007                         if test $ac_cv_func_sched_yield = no -a \
1008                                 $ac_cv_func_pthread_yield = no ; then
1009                                 dnl Digital UNIX has sched_yield() in -lrt
1010                                 AC_CHECK_LIB(rt, sched_yield,
1011                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1012                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1013                                                 [Define if you have the sched_yield function.])
1014                                         ac_cv_func_sched_yield=yes],
1015                                         [ac_cv_func_sched_yield=no])
1016                         fi
1017                         if test $ac_cv_func_sched_yield = no -a \
1018                                 $ac_cv_func_pthread_yield = no ; then
1019                                 dnl Solaris has sched_yield() stub in -lposix4
1020                                 dnl but we'll use thr_yield instead.
1021                                 AC_CHECK_FUNCS(thr_yield)
1022                         fi
1023                         if test $ac_cv_func_sched_yield = no -a \
1024                                 $ac_cv_func_pthread_yield = no -a \
1025                                 "$ac_cv_func_thr_yield" = no ; then
1026                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1027                         fi
1028
1029                         dnl Check functions for compatibility
1030                         AC_CHECK_FUNCS(pthread_kill)
1031
1032                         dnl Check for pthread_detach with <pthread.h> inclusion
1033                         dnl as it's symbol may have been mangled.
1034                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1035                                 [ol_cv_func_pthread_detach], [
1036                                 dnl save the flags
1037                                 AC_TRY_LINK([
1038 #include <pthread.h>
1039 #ifndef NULL
1040 #define NULL (void*)0
1041 #endif
1042 ],
1043                                         [pthread_detach(NULL);],
1044                                         [ol_cv_func_pthread_detach=yes],
1045                                         [ol_cv_func_pthread_detach=no])
1046                         ])
1047
1048                         if test $ol_cv_func_pthread_detach = no ; then
1049                                 AC_MSG_ERROR([could not locate pthread_detach()])
1050                         fi
1051
1052                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1053                                 [define if you have pthread_detach function])
1054
1055                         dnl Check for setconcurreny functions
1056                         AC_CHECK_FUNCS( \
1057                                 pthread_setconcurrency \
1058                                 pthread_getconcurrency \
1059                                 thr_setconcurrency \
1060                                 thr_getconcurrency \
1061                         )
1062
1063                         OL_SYS_LINUX_THREADS
1064                         OL_LINUX_THREADS
1065
1066                         if test $ol_cv_linux_threads = error; then
1067                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1068                         fi
1069
1070                         AC_CACHE_CHECK([if pthread_create() works],
1071                                 ol_cv_pthread_create_works,[
1072                         AC_TRY_RUN([
1073 #include <pthread.h>
1074 #ifndef NULL
1075 #define NULL (void*)0
1076 #endif
1077
1078 static void *task(p)
1079         void *p;
1080 {
1081         return (void *) (p == NULL);
1082 }
1083
1084 int main(argc, argv)
1085         int argc;
1086         char **argv;
1087 {
1088         pthread_t t;
1089 #if HAVE_PTHREADS_D4
1090         exit(pthread_create(&t, pthread_attr_default, task, NULL));
1091 #else
1092         exit(pthread_create(&t, NULL, task, NULL));
1093 #endif
1094 }
1095 ],
1096                                 [ol_cv_pthread_create_works=yes],
1097                                 [ol_cv_pthread_create_works=no],
1098                                 [dnl assume yes
1099                                 ol_cv_pthread_create_works=yes])])
1100
1101                         if test $ol_cv_pthread_create_works = no ; then
1102                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1103                         fi
1104
1105                         dnl Check if select causes an yield
1106                         if test $ol_with_yielding_select = auto ; then
1107                                 AC_CACHE_CHECK([if select yields when using pthreads],
1108                                         ol_cv_pthread_select_yields,[
1109                                 AC_TRY_RUN([
1110 #include <sys/types.h>
1111 #include <sys/time.h>
1112 #include <unistd.h>
1113 #include <pthread.h>
1114 #ifndef NULL
1115 #define NULL (void*) 0
1116 #endif
1117
1118 static int fildes[2];
1119
1120 static void *task(p)
1121         void *p;
1122 {
1123         int i;
1124         struct timeval tv;
1125
1126         fd_set rfds;
1127
1128         tv.tv_sec=10;
1129         tv.tv_usec=0;
1130
1131         FD_ZERO(&rfds);
1132         FD_SET(fildes[0], &rfds);
1133
1134         /* we're not interested in any fds */
1135         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1136
1137         if(i < 0) {
1138                 perror("select");
1139                 exit(10);
1140         }
1141
1142         exit(0); /* if we exit here, the select blocked the whole process */
1143 }
1144
1145 int main(argc, argv)
1146         int argc;
1147         char **argv;
1148 {
1149         pthread_t t;
1150
1151         /* create a pipe to select */
1152         if(pipe(&fildes[0])) {
1153                 perror("select");
1154                 exit(1);
1155         }
1156
1157 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1158         (void) pthread_setconcurrency(2);
1159 #else
1160 #ifdef HAVE_THR_SETCONCURRENCY
1161         /* Set Solaris LWP concurrency to 2 */
1162         thr_setconcurrency(2);
1163 #endif
1164 #endif
1165
1166 #if HAVE_PTHREADS_D4
1167         pthread_create(&t, pthread_attr_default, task, NULL);
1168 #else
1169         pthread_create(&t, NULL, task, NULL);
1170 #endif
1171
1172 #if HAVE_SCHED_YIELD
1173         sched_yield();  /* make sure task runs first */
1174 #else
1175 #ifdef HAVE_PTHREAD_YIELD
1176         pthread_yield();        /* make sure task runs first */
1177 #endif
1178 #endif
1179
1180         exit(2);
1181 }],
1182                                 [ol_cv_pthread_select_yields=no],
1183                                 [ol_cv_pthread_select_yields=yes],
1184                                 [ol_cv_pthread_select_yields=cross])])
1185
1186                                 if test $ol_cv_pthread_select_yields = cross ; then
1187                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1188                                 fi
1189
1190                                 if test $ol_cv_pthread_select_yields = yes ; then
1191                                         ol_with_yielding_select=yes
1192                                 fi
1193                         fi
1194
1195                         dnl restore flags
1196                         CPPFLAGS="$save_CPPFLAGS"
1197                         LIBS="$save_LIBS"
1198                 else
1199                         AC_MSG_ERROR([could not link with POSIX Threads])
1200                 fi
1201         fi
1202
1203         if test $ol_with_threads = posix ; then
1204                 AC_MSG_ERROR([could not locate POSIX Threads])
1205         fi
1206 fi
1207
1208 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1209         -o $ol_with_threads = mach ; then
1210
1211         dnl check for Mach CThreads
1212         AC_CHECK_HEADERS(mach/cthreads.h)
1213         if test $ac_cv_header_mach_cthreads_h = yes ; then
1214                 ol_with_threads=found
1215
1216                 dnl check for cthread support in current $LIBS
1217                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1218
1219                 if test $ol_link_threads = no ; then
1220                         dnl try -all_load
1221                         dnl this test needs work
1222                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1223                                 [ol_cv_cthread_all_load], [
1224                                 dnl save the flags
1225                                 save_LIBS="$LIBS"
1226                                 LIBS="-all_load $LIBS"
1227                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1228                                         cthread_fork((void *)0, (void *)0);
1229                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1230                                 dnl restore the LIBS
1231                                 LIBS="$save_LIBS"
1232                         ])
1233
1234                         if test $ol_cv_cthread_all_load = yes ; then
1235                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1236                                 ol_link_threads=mach
1237                         fi
1238                 fi
1239
1240                 if test $ol_link_threads != no ; then
1241                         : check for cthread specific functionality here
1242                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1243                                 [define if you have Mach Cthreads])
1244                 else
1245                         AC_MSG_ERROR([could not link with Mach CThreads])
1246                 fi
1247         fi
1248
1249         if test $ol_with_threads = mach ; then
1250                 AC_MSG_ERROR([could not locate Mach CThreads])
1251         fi
1252 fi
1253
1254 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1255         -o $ol_with_threads = lwp ; then
1256
1257         dnl check for SunOS5 LWP
1258         AC_CHECK_HEADERS(thread.h synch.h)
1259         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1260                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1261
1262                 if test $have_thr = yes ; then
1263                         AC_DEFINE(HAVE_THR,1,
1264                                 [if you have Solaris LWP (thr) package])
1265                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1266                         ol_link_threads=thr
1267
1268                         if test $ol_with_yielding_select = auto ; then
1269                                 ol_with_yielding_select=yes
1270                         fi
1271
1272                         dnl Check for setconcurreny functions
1273                         AC_CHECK_FUNCS( \
1274                                 thr_setconcurrency \
1275                                 thr_getconcurrency \
1276                         )
1277                 fi
1278         fi
1279
1280         dnl check for SunOS4 LWP
1281         AC_CHECK_HEADERS(lwp/lwp.h)
1282         if test $ac_cv_header_lwp_lwp_h = yes ; then
1283                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1284
1285                 if test $have_lwp = yes ; then
1286                         AC_DEFINE(HAVE_LWP,1,
1287                                 [if you have SunOS LWP package])
1288                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1289                         ol_link_threads=lwp
1290
1291                         if test $ol_with_yielding_select = auto ; then
1292                                 ol_with_yielding_select=no
1293                         fi
1294                 fi
1295         fi
1296 fi
1297
1298 if test $ol_with_yielding_select = yes ; then
1299         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1300                 [define if select implicitly yields])
1301 fi
1302
1303 if test $ol_with_threads = manual ; then
1304         dnl User thinks he can manually configure threads.
1305         ol_link_threads=yes
1306
1307         AC_MSG_WARN([thread defines and link options must be set manually])
1308
1309         AC_CHECK_HEADERS(pthread.h sched.h)
1310         AC_CHECK_FUNCS(sched_yield pthread_yield)
1311         OL_HEADER_LINUX_THREADS
1312
1313         AC_CHECK_HEADERS(mach/cthreads.h)
1314         AC_CHECK_HEADERS(lwp/lwp.h)
1315         AC_CHECK_HEADERS(thread.h synch.h)
1316 fi
1317
1318 if test $ol_link_threads != no ; then
1319         dnl needed to get reentrant/threadsafe versions
1320         dnl
1321         AC_DEFINE(REENTRANT,1)
1322         AC_DEFINE(_REENTRANT,1)
1323         AC_DEFINE(THREAD_SAFE,1)
1324         AC_DEFINE(_THREAD_SAFE,1)
1325         AC_DEFINE(THREADSAFE,1)
1326         AC_DEFINE(_THREADSAFE,1)
1327         AC_DEFINE(_SGI_MP_SOURCE,1)
1328
1329         dnl The errno declaration may dependent upon _REENTRANT.
1330         dnl If it does, we must link with thread support.
1331         AC_CACHE_CHECK([for thread specific errno],
1332                 [ol_cv_errno_thread_specific], [
1333                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1334                         [ol_cv_errno_thread_specific=yes],
1335                         [ol_cv_errno_thread_specific=no])
1336         ])
1337
1338         dnl The h_errno declaration may dependent upon _REENTRANT.
1339         dnl If it does, we must link with thread support.
1340         AC_CACHE_CHECK([for thread specific h_errno],
1341                 [ol_cv_h_errno_thread_specific], [
1342                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1343                         [ol_cv_h_errno_thread_specific=yes],
1344                         [ol_cv_h_errno_thread_specific=no])
1345         ])
1346
1347         if test $ol_cv_errno_thread_specific != yes \
1348                 -o $ol_cv_h_errno_thread_specific != yes ; then
1349                 LIBS="$LTHREAD_LIBS $LIBS"
1350                 LTHREAD_LIBS=""
1351         fi
1352
1353 dnl When in thread environment, use
1354 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1355 dnl                     || defined( HAVE_FUNC_R )
1356 dnl                     func_r(...);
1357 dnl             #else
1358 dnl             #       if defined( HAVE_THREADS )
1359 dnl                             /* lock */
1360 dnl             #       endif
1361 dnl                             func(...);
1362 dnl             #       if defined( HAVE_THREADS )
1363 dnl                             /* unlock */
1364 dnl             #       endif
1365 dnl             #endif
1366 dnl
1367 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1368 dnl             _POSIX_REENTRANT_FUNCTIONS
1369 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1370 dnl             _POSIX_THREADSAFE_FUNCTIONS
1371 dnl
1372 dnl             and is currently defined in lthread.h
1373 dnl
1374 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1375 dnl
1376 dnl libldap/*.c should only include <lthread.h> iff
1377 dnl LDAP_R_COMPILE is defined.  ie:
1378 dnl             #ifdef LDAP_R_COMPILE
1379 dnl             #       include LDAP_R_COMPILE
1380 dnl             #endif
1381 dnl
1382 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1383 dnl specifically for compiling the threadsafe version of
1384 dnl     the ldap library (-lldap_r).
1385 dnl
1386 dnl     dnl check for reentrant/threadsafe functions
1387 dnl     dnl
1388 dnl     dnl note: these should only be used when linking
1389 dnl     dnl       with $LTHREAD_LIBS
1390 dnl     dnl
1391 dnl     save_CPPFLAGS="$CPPFLAGS"
1392 dnl     save_LIBS="$LIBS"
1393 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1394 dnl     AC_CHECK_FUNCS( \
1395 dnl             gmtime_r \
1396 dnl             gethostbyaddr_r gethostbyname_r \
1397 dnl             feof_unlocked unlocked_feof \
1398 dnl             putc_unlocked unlocked_putc \
1399 dnl             flockfile ftrylockfile \
1400 dnl     )
1401 dnl     CPPFLAGS="$save_CPPFLAGS"
1402 dnl     LIBS="$save_LIBS"
1403 fi
1404
1405 if test $ol_link_threads = no ; then
1406         if test $ol_with_threads = yes ; then
1407                 AC_MSG_ERROR([no suitable thread support])
1408         fi
1409
1410         if test $ol_with_threads = auto ; then
1411                 AC_MSG_WARN([no suitable thread support, disabling threads])
1412                 ol_with_threads=no
1413         fi
1414
1415         AC_DEFINE(NO_THREADS,1,
1416                 [define if you have (or want) no threads])
1417         LTHREAD_LIBS=""
1418 fi
1419
1420 if test $ol_link_threads != no ; then
1421         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1422 fi
1423
1424 dnl ----------------------------------------------------------------
1425
1426 ol_link_ldbm=no
1427 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1428         OL_BERKELEY_DB2
1429
1430         if test $ol_cv_berkeley_db2 = yes ; then
1431                 ol_link_ldbm=db2
1432                 ol_with_ldbm_api=db2
1433
1434                 if test $ol_with_ldbm_type = hash ; then
1435                         AC_DEFINE(LDBM_USE_DBHASH,1,
1436                                 [define this to use DBHASH w/ LDBM backend])
1437                 else
1438                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1439                                 [define this to use DBBTREE w/ LDBM backend])
1440                 fi
1441
1442                 dnl $ol_cv_lib_db2 should be yes or -ldb
1443                 dnl (it could be no, but that would be an error
1444                 if test $ol_cv_lib_db2 != yes ; then
1445                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1446                 fi
1447         fi
1448 fi
1449
1450 ol_link_bdb2=no
1451 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1452         ol_link_bdb2=yes
1453 fi
1454
1455 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1456         OL_BERKELEY_DB
1457
1458         if test $ol_cv_berkeley_db = yes ; then
1459                 ol_link_ldbm=db
1460                 ol_with_ldbm_api=db
1461
1462                 if test $ol_with_ldbm_type = hash ; then
1463                         AC_DEFINE(LDBM_USE_DBHASH,1,
1464                                 [define this to use DBHASH w/ LDBM backend])
1465                 else
1466                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1467                                 [define this to use DBBTREE w/ LDBM backend])
1468                 fi
1469
1470                 dnl $ol_cv_lib_db should be yes or -ldb
1471                 dnl (it could be no, but that would be an error
1472                 if test $ol_cv_lib_db != yes ; then
1473                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1474                 fi
1475         fi
1476 fi
1477
1478 if test $ol_with_ldbm_api = manual ; then
1479         dnl User thinks he can manually configure LDBM api.
1480         ol_link_ldbm=yes
1481
1482         AC_MSG_WARN([LDBM defines and link options must be set manually])
1483
1484         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1485 fi
1486
1487 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1488         AC_MSG_WARN(Could not find LDBM with BTREE support)
1489         ol_with_ldbm_api=none
1490 fi
1491
1492 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1493         OL_MDBM
1494
1495         if test $ol_cv_mdbm = yes ; then
1496                 ol_link_ldbm=mdbm
1497                 ol_with_ldbm_api=mdbm
1498                 if test $ol_cv_lib_mdbm != yes ; then
1499                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1500                 fi
1501         fi
1502 fi
1503
1504 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1505         OL_GDBM
1506
1507         if test $ol_cv_gdbm = yes ; then
1508                 ol_link_ldbm=gdbm
1509                 ol_with_ldbm_api=gdbm
1510
1511                 if test $ol_cv_lib_gdbm != yes ; then
1512                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1513                 fi
1514         fi
1515 fi
1516
1517 if test $ol_with_ldbm_api = auto ; then
1518         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1519 elif test $ol_with_ldbm_api = ndbm ; then
1520         OL_NDBM
1521
1522         if test $ol_cv_ndbm = yes ; then
1523                 ol_link_ldbm=ndbm
1524                 ol_with_ldbm_api=ndbm
1525
1526                 if test $ol_cv_lib_ndbm != yes ; then
1527                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1528                 fi
1529         fi
1530 fi
1531
1532 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1533         AC_MSG_WARN(could not find suitable LDBM backend)
1534         if test $ol_enable_ldbm = yes ; then
1535                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1536         fi
1537
1538         AC_MSG_WARN(disabling LDBM)
1539         ol_enable_ldbm=no
1540 fi
1541
1542 if test $ol_enable_wrappers != no ; then
1543         AC_CHECK_HEADERS(tcpd.h)
1544
1545         if test $ac_cv_header_tcpd_h != yes ; then
1546                 have_wrappers=no
1547         else
1548                 AC_CHECK_LIB(wrap, main,
1549                         [have_wrappers=yes], [have_wrappers=no])
1550         fi
1551
1552         if test $have_wrappers = yes ; then
1553                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1554                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1555
1556                 dnl We add another check for -lnsl since some libwrap's
1557                 dnl need it, but it isn't always included from above
1558                 AC_CHECK_LIB(nsl, main)
1559         else
1560                 AC_MSG_WARN(could not find -lwrap)
1561                 if test $ol_enable_wrappers = yes ; then
1562                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1563                 fi
1564
1565                 AC_MSG_WARN(disabling wrappers support)
1566                 ol_enable_wrappers=no
1567         fi
1568 fi
1569
1570 if test $ol_enable_syslog != no ; then
1571         AC_CHECK_FUNC(openlog)
1572         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1573                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1574         fi
1575         ol_enable_syslog=$ac_cv_func_openlog
1576 fi
1577
1578 if test $ol_enable_dmalloc != no ; then
1579         AC_CHECK_HEADERS(dmalloc.h)
1580         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1581 fi
1582
1583 if test $ol_enable_tcl != no ; then
1584         AC_CHECK_HEADERS(tcl.h)
1585
1586         if test $ac_cv_header_tcl_h != yes ; then
1587                 have_tcl=no
1588         else
1589                 AC_CHECK_LIB(tcl,main,
1590                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1591                         [have_tcl=no])
1592
1593                 if test $have_tcl != yes; then
1594                         AC_CHECK_LIB(tcl7.6,main,
1595                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1596                                 [have_tcl=no])
1597                 fi
1598
1599                 if test $have_tcl != yes; then
1600                         AC_CHECK_LIB(tcl8.0,main,
1601                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1602                                 [have_tcl=no])
1603                 fi
1604         fi
1605
1606         if test $have_tcl != yes ; then
1607                 AC_MSG_WARN([could not find -ltcl])
1608                 if test $ol_enable_tcl = yes ; then
1609                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1610                 fi
1611
1612                 ol_enable_tcl=no
1613         fi
1614 fi
1615
1616 # ud needs termcap (should insert check here)
1617 ol_link_termcap=no
1618 AC_CHECK_HEADERS(termcap.h ncurses.h)
1619
1620 if test $ol_link_termcap = no ; then
1621         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1622         if test $have_termcap = yes ; then
1623                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1624                 ol_link_termcap=yes
1625                 TERMCAP_LIBS=-ltermcap
1626         fi
1627 fi
1628
1629 if test $ol_link_termcap = no ; then
1630         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1631         if test $have_ncurses = yes ; then
1632                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1633                 ol_link_termcap=yes
1634                 TERMCAP_LIBS=-lncurses
1635         fi
1636 fi
1637
1638 if test $ol_link_termcap = no ; then
1639         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1640         TERMCAP_LIBS=
1641 fi
1642
1643 dnl
1644 dnl Check for fetch URL support
1645 dnl             should be extended to support other fetch URL APIs
1646 dnl
1647 ol_link_sasl=no
1648 if test $ol_with_cyrus_sasl != no ; then
1649         AC_CHECK_HEADER(sasl.h)
1650
1651         if test $ac_cv_header_sasl_h = yes ; then
1652                 AC_CHECK_LIB(sasl, sasl_client_init,
1653                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1654
1655                 if test $have_cyrus_sasl != no ; then
1656                         SASL_LIBS="-lsasl"
1657                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1658                         ol_link_sasl=yes
1659                 fi
1660         fi
1661
1662         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1663                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1664         fi
1665 fi
1666
1667 dnl
1668 dnl Check for fetch URL support
1669 dnl             should be extended to support other fetch URL APIs
1670 dnl
1671 ol_link_fetch=no
1672 if test $ol_with_fetch != no ; then
1673         OL_LIB_FETCH
1674
1675         if test $ol_cv_lib_fetch != no ; then
1676                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1677                 ol_link_fetch=freebsd
1678
1679         elif test $ol_with_fetch != auto ; then
1680                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1681         fi
1682 fi
1683
1684 dnl
1685 dnl Check for GNU readline
1686 dnl
1687 ol_link_readline=no
1688 if test $ol_with_readline != no ; then
1689         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1690
1691         if test $ac_cv_header_readline_readline_h = yes ; then
1692                 save_LIBS="$LIBS"
1693                 LIBS="$TERMCAP_LIBS $LIBS"
1694                 AC_CHECK_LIB(readline, readline,
1695                         [have_readline=yes], [have_readline=no])
1696                 LIBS="$save_LIBS"
1697
1698                 if test $have_readline = yes ; then
1699                         ol_with_readline=found
1700                         ol_link_readline=yes
1701
1702                         READLINE_LIBS="-lreadline"
1703                 fi
1704         fi
1705 fi
1706
1707 if test $ol_link_readline = yes ; then
1708         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1709 fi
1710
1711
1712 # FreeBSD (and others) have crypt(3) in -lcrypt
1713 if test $ol_enable_crypt != no ; then
1714         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1715                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1716                         have_crypt=yes], [have_crypt=no])])
1717
1718         if test $have_crypt = yes ; then
1719                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1720         else
1721                 AC_MSG_WARN(could not find crypt)
1722                 if test $ol_enable_crypt = yes ; then
1723                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1724                 fi
1725
1726                 AC_MSG_WARN(disabling crypt support)
1727                 ol_enable_crypt=no
1728         fi
1729 fi
1730
1731 # FreeBSD (and others) have setproctitle(3) in -lutil
1732 if test $ol_enable_proctitle != no ; then
1733         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1734                 AC_CHECK_LIB(util, setproctitle,
1735                         [have_setproctitle=yes
1736                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1737                         [have_setproctitle=no
1738                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1739
1740         if test $have_setproctitle = yes ; then
1741                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1742                         [define if setproctitle(3) is available])
1743         fi
1744 fi
1745
1746 dnl ----------------------------------------------------------------
1747 dnl Checks for typedefs, structures, and compiler characteristics.
1748 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1749 AC_TYPE_MODE_T
1750 AC_TYPE_OFF_T
1751 AC_TYPE_PID_T
1752 AM_TYPE_PTRDIFF_T
1753 AC_TYPE_SIGNAL
1754 OL_TYPE_SIG_ATOMIC_T
1755 AC_TYPE_SIZE_T
1756 OL_TYPE_SOCKLEN_T
1757 AC_STRUCT_ST_BLKSIZE
1758 AC_HEADER_TIME
1759 AC_STRUCT_TM
1760 OL_STRUCT_PASSWD_PW_GECOS
1761 OL_STRUCT_PASSWD_PW_PASSWD
1762
1763 OL_C_UPPER_LOWER
1764 AC_C_CONST
1765 OL_C_VOLATILE
1766
1767 if test $cross_compiling = yes ; then
1768         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1769
1770         AC_DEFINE(LBER_INT_T,long)
1771         AC_DEFINE(LBER_TAG_T,long)
1772         AC_DEFINE(LBER_SOCKET_T,int)
1773
1774 else
1775         AC_C_BIGENDIAN
1776         AC_CHECK_SIZEOF(short)
1777         AC_CHECK_SIZEOF(int)
1778         AC_CHECK_SIZEOF(long)
1779
1780         if test "$ac_cv_sizeof_int" -lt 4 ; then
1781                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1782
1783                 AC_DEFINE(LBER_INT_T,long)
1784                 AC_DEFINE(LBER_TAG_T,long)
1785                 AC_DEFINE(LBER_SOCKET_T,int)
1786         else
1787                 AC_DEFINE(LBER_INT_T,int)
1788                 AC_DEFINE(LBER_TAG_T,long)
1789                 AC_DEFINE(LBER_SOCKET_T,int)
1790         fi
1791 fi
1792
1793 AC_DEFINE(LBER_LEN_T,long)
1794
1795 dnl ----------------------------------------------------------------
1796 dnl Checks for library functions.
1797 AC_FUNC_MEMCMP
1798 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1799 AC_FUNC_STRFTIME
1800 dnl AM_FUNC_STRTOD
1801
1802 OL_FUNC_INET_ATON
1803
1804 dnl we should use vfork instead of fork in a number of places...
1805 dnl AC_FUNC_VFORK
1806 AC_FUNC_VPRINTF
1807
1808 if test $ac_cv_func_vprintf = yes ; then
1809         dnl check for vsnprintf
1810         AC_CHECK_FUNCS(vsnprintf vsprintf)
1811 fi
1812
1813 AC_CHECK_FUNCS(         \
1814         bcopy                   \
1815         closesocket             \
1816         endgrent                \
1817         endpwent                \
1818         flock                   \
1819         getdtablesize   \
1820         getgrgid                \
1821         gethostname             \
1822         getpass                 \
1823         getpwuid                \
1824         getpwnam                \
1825         getspnam                \
1826         gettimeofday    \
1827         initgroups              \
1828         lockf                   \
1829         memcpy                  \
1830         memmove                 \
1831         mkstemp                 \
1832         read                    \
1833         recv                    \
1834         recvfrom                \
1835         setpwfile               \
1836         setgid                  \
1837         setegid                 \
1838         setsid                  \
1839         setuid                  \
1840         seteuid                 \
1841         signal                  \
1842         sigset                  \
1843         snprintf                \
1844         strdup                  \
1845         strerror                \
1846         strpbrk                 \
1847         strrchr                 \
1848         strsep                  \
1849         strstr                  \
1850         strtol                  \
1851         strtoul                 \
1852         strspn                  \
1853         sysconf                 \
1854         waitpid                 \
1855         wait4                   \
1856         write                   \
1857         send                    \
1858         sendto                  \
1859 )
1860
1861 dnl We actually may need to replace more than this.
1862 AC_REPLACE_FUNCS(getopt tempnam)
1863
1864 dnl ----------------------------------------------------------------
1865 # Check Configuration
1866 OL_SYS_ERRLIST
1867
1868 dnl ----------------------------------------------------------------
1869 dnl Sort out defines
1870
1871 if test "$ol_enable_debug" != no ; then
1872         AC_DEFINE(LDAP_DEBUG,1,
1873                 [define this to add debugging code])
1874 fi
1875 if test "$ol_enable_syslog" = yes ; then
1876         AC_DEFINE(LDAP_SYSLOG,1,
1877                 [define this to add syslog code])
1878 fi
1879 if test "$ol_enable_libui" = yes ; then
1880         AC_DEFINE(LDAP_LIBUI,1,
1881                 [define this for LDAP User Interface support])
1882 fi
1883 if test "$ol_enable_cache" = no ; then
1884         AC_DEFINE(LDAP_NOCACHE,1,
1885                 [define this to remove -lldap cache support])
1886 fi
1887 if test "$ol_enable_dns" != no ; then
1888         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1889 fi
1890 if test "$ol_enable_proctitle" != no ; then
1891         AC_DEFINE(LDAP_PROCTITLE,1,
1892                 [define this for LDAP process title support])
1893 fi
1894 if test "$ol_enable_referrals" != no ; then
1895         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1896 fi
1897 if test "$ol_enable_cldap" != no ; then
1898         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
1899 fi
1900
1901 if test "$ol_enable_crypt" != no ; then
1902         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
1903 fi
1904 if test "$ol_enable_cleartext" != no ; then
1905         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
1906 fi
1907 if test "$ol_enable_multimaster" != no ; then
1908         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
1909 fi
1910 if test "$ol_enable_phonetic" != no ; then
1911         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
1912 fi
1913 if test "$ol_enable_rlookups" != no ; then
1914         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
1915 fi
1916
1917 if test "$ol_enable_modules" != no ; then
1918         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
1919         BUILD_SLAPD=yes
1920         MODULES_LIBS=-lltdl
1921         SLAPD_MODULES_LDFLAGS="-dlopen self"
1922 fi
1923
1924 if test "$ol_link_bdb2" != no ; then
1925         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
1926         BUILD_SLAPD=yes
1927         BUILD_BDB2=yes
1928         if test "$ol_with_bdb2_module" != static ; then
1929                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
1930                         [define to support dynamic BDB2 backend])
1931                 BUILD_BDB2=mod
1932                 BUILD_BDB2_DYNAMIC=shared
1933                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
1934         fi
1935 fi
1936
1937 if test "$ol_enable_ldap" != no ; then
1938         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
1939         BUILD_SLAPD=yes
1940         BUILD_LDAP=yes
1941         if test "$ol_with_ldap_module" != static ; then
1942                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
1943                         [define to support dynamic LDAP backend])
1944                 BUILD_LDAP=mod
1945                 BUILD_LDAP_DYNAMIC=shared
1946                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
1947         fi
1948 fi
1949
1950 if test "$ol_link_ldbm" != no ; then
1951         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
1952         BUILD_SLAPD=yes
1953         BUILD_LDBM=yes
1954         if test "$ol_with_ldbm_module" != static ; then
1955                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
1956                         [define to support dynamic LDBM backend])
1957                 BUILD_LDBM=mod
1958                 BUILD_LDBM_DYNAMIC=shared
1959                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
1960         fi
1961 fi
1962
1963 if test "$ol_enable_passwd" != no ; then
1964         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
1965         BUILD_SLAPD=yes
1966         BUILD_PASSWD=yes
1967         if test "$ol_with_passwd_module" != static ; then
1968                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
1969                         [define to support dynamic PASSWD backend])
1970                 BUILD_PASSWD=mod
1971                 BUILD_PASSWD_DYNAMIC=shared
1972                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
1973         fi
1974 fi
1975
1976 if test "$ol_link_perl" != no ; then
1977         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
1978         BUILD_SLAPD=yes
1979         BUILD_PERL=yes
1980         if test "$ol_with_perl_module" != static ; then
1981                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
1982                         [define to support dynamic PERL backend])
1983                 BUILD_PERL=mod
1984                 BUILD_PERL_DYNAMIC=shared
1985                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
1986         fi
1987 fi
1988
1989 if test "$ol_enable_shell" != no ; then
1990         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
1991         BUILD_SLAPD=yes
1992         BUILD_SHELL=yes
1993         if test "$ol_with_shell_module" != static ; then
1994                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
1995                         [define to support dynamic SHELL backend])
1996                 BUILD_SHELL=mod
1997                 BUILD_SHELL_DYNAMIC=shared
1998                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
1999         fi
2000 fi
2001
2002 if test "$ol_enable_tcl" != no ; then
2003         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2004         BUILD_SLAPD=yes
2005         BUILD_TCL=yes
2006         if test "$ol_with_tcl_module" != static; then
2007                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2008                         [define to support dynamic TCL backend])
2009                 BUILD_TCL=mod
2010                 BUILD_TCL_DYNAMIC=shared
2011                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2012         fi
2013 fi
2014
2015 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2016         $BUILD_SLAPD = yes ; then
2017         BUILD_SLURPD=yes
2018 fi
2019
2020 if test "$ol_link_isode" != no ; then
2021         BUILD_LDAPD=yes
2022 fi
2023
2024 dnl ----------------------------------------------------------------
2025
2026 AC_SUBST(BUILD_LDAPD)
2027 AC_SUBST(BUILD_SLAPD)
2028   AC_SUBST(BUILD_BDB2)
2029   AC_SUBST(BUILD_LDAP)
2030   AC_SUBST(BUILD_LDBM)
2031   AC_SUBST(BUILD_PASSWD)
2032   AC_SUBST(BUILD_PERL)
2033   AC_SUBST(BUILD_QUIPU)
2034   AC_SUBST(BUILD_SHELL)
2035   AC_SUBST(BUILD_TCL)
2036   AC_SUBST(BUILD_BDB2_DYNAMIC)
2037   AC_SUBST(BUILD_LDAP_DYNAMIC)
2038   AC_SUBST(BUILD_LDBM_DYNAMIC)
2039   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2040   AC_SUBST(BUILD_PERL_DYNAMIC)
2041   AC_SUBST(BUILD_SHELL_DYNAMIC)
2042   AC_SUBST(BUILD_TCL_DYNAMIC)
2043 AC_SUBST(BUILD_SLURPD)
2044
2045 AC_SUBST(LDAP_LIBS)
2046 AC_SUBST(LDAPD_LIBS)
2047 AC_SUBST(LDIF_LIBS)
2048 AC_SUBST(SLAPD_LIBS)
2049 AC_SUBST(SLURPD_LIBS)
2050 AC_SUBST(LDBM_LIBS)
2051 AC_SUBST(LTHREAD_LIBS)
2052 AC_SUBST(LUTIL_LIBS)
2053
2054 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2055 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2056 AC_SUBST(SLAPD_MODULES_LIST)
2057
2058 AC_SUBST(SLAPD_PERL_CPPFLAGS)
2059 AC_SUBST(SLAPD_PERL_LDFLAGS)
2060
2061 AC_SUBST(KRB_LIBS)
2062 AC_SUBST(READLINE_LIBS)
2063 AC_SUBST(SASL_LIBS)
2064 AC_SUBST(TERMCAP_LIBS)
2065 AC_SUBST(TLS_LIBS)
2066 AC_SUBST(MODULES_LIBS)
2067
2068 dnl ----------------------------------------------------------------
2069 dnl final output
2070 dnl
2071
2072 AC_OUTPUT( \
2073 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2074 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2075 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2076 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2077 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2078 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2079 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2080 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2081 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2082 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2083 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2084 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2085 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2086 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2087 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2088 include/Makefile:build/top.mk:include/Makefile.in \
2089 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2090 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2091 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2092 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2093 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2094 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2095 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2096 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2097 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2098 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2099 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2100 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2101 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2102 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2103 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2104 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2105 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2106 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2107 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2108 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2109 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2110 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2111 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2112 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2113 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2114 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2115 ,[
2116 date > stamp-h
2117 echo Please \"make depend\" to build dependencies
2118 ])