git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Copying restrictions apply, see COPYRIGHT file."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35 AC_CONFIG_AUX_DIR(build)dnl
  36
  37 OL_VERSION=`cat $ac_aux_dir/version`
  38 if test -z "$OL_VERSION"; then
  39         AC_MSG_ERROR([could not determine version])
  40 fi
  41
  42 echo "Configuring OpenLDAP $OL_VERSION ..."
  43
  44 dnl Determine host platform
  45 dnl             we try not to use this for much
  46 AC_CANONICAL_SYSTEM
  47
  48 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  49 AC_SUBST(PACKAGE)
  50 AC_SUBST(VERSION)
  51 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  52 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  53
  54 dnl We use autoconf features new to 2.13.
  55 dnl aclocal.m4 should be built using aclocal from automake 1.4
  56 dnl libtool 1.3.3 should be installed.
  57 AC_PREREQ(2.13)dnl Required Autoconf version
  58
  59 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  60
  61 dnl ================================================================
  62 dnl Start Args
  63 AC_MSG_CHECKING(configure arguments)
  64 AC_PREFIX_DEFAULT(/usr/local)
  65
  66 top_builddir=`pwd`
  67 AC_SUBST(top_builddir)dnl
  68
  69 dnl ----------------------------------------------------------------
  70 dnl --with-subdir
  71 ldap_subdir="/openldap"
  72
  73 AC_ARG_WITH(subdir,
  74 [  --with-subdir=DIR change default subdirectory used for installs],
  75 [case "$withval" in
  76         no) ldap_subdir=""
  77                 ;;
  78         yes)
  79                 ;;
  80         /*|\\*)
  81                 ldap_subdir="$withval"
  82                 ;;
  83         *)
  84                 ldap_subdir="/$withval"
  85                 ;;
  86 esac
  87 ])dnl
  88
  89 AC_SUBST(ldap_subdir)dnl
  90
  91 dnl ----------------------------------------------------------------
  92 dnl General "enable" options
  93 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  94 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  95 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  96 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  97 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  98 OL_ARG_ENABLE(kbind,[  --enable-kbind   enable V2 Kerberos IV bind], auto)dnl
  99 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
 100 OL_ARG_ENABLE(ldapi,[  --enable-ldapi   enable domain socket (PF_LOCAL) ldap], no)dnl
 101 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
 102         no, [yes no])dnl
 103
 104 dnl ----------------------------------------------------------------
 105 dnl General "with" options
 106 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc   enable debug malloc support], no)dnl
 107
 108 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
 109         auto, [auto yes no] )
 110 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
 111         auto, [auto yes no] )
 112 OL_ARG_WITH(kerberos,[  --with-kerberos with support],
 113         auto, [auto k5 k5only k425 kth k4 afs yes no])
 114 OL_ARG_WITH(readline,[  --with-readline with readline support],
 115         auto, [auto yes no] )
 116 OL_ARG_WITH(threads,[  --with-threads   use threads],
 117         auto, [auto nt posix mach pth lwp yes no manual] )
 118 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
 119         auto, [auto ssleay openssl yes no] )
 120 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
 121         auto, [auto yes no manual] )
 122
 123 dnl ----------------------------------------------------------------
 124 dnl Server options
 125 dnl ----------------------------------------------------------------
 126
 127 dnl ----------------------------------------------------------------
 128 dnl SLAPD OPTIONS
 129 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 130 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 131 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 132 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 133 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd     enable kerberos password verification], no)dnl
 134 OL_ARG_ENABLE(spasswd,[    --enable-spasswd     enable (Cyrus) SASL password verification], no)dnl
 135 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 136 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 137 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 138 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 139 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 140 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 141 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 142 OL_ARG_ENABLE(dynamic,[    --enable-dynamic     enable linking built binaries with dynamic libs], no)dnl
 143
 144 dnl SLAPD Backend options
 145 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 146 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 147         [static dynamic])
 148 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv       enable bdb2 backend], no)dnl
 149 OL_ARG_WITH(dnssrv_module,[      --with-dnssrv-module   module type], static,
 150         [static dynamic])
 151 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 152 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 153         [static dynamic])
 154 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 155 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 156         [auto berkeley bcompat mdbm gdbm])
 157 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 158         [static dynamic])
 159 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 160         [auto btree hash])
 161 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 162 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 163         [static dynamic])
 164 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 165 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 166         [static dynamic])
 167 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 168 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 169         [static dynamic])
 170 OL_ARG_ENABLE(sql,[    --enable-sql     enable sql backend], no)dnl
 171 OL_ARG_WITH(sql_module,[      --with-sql-module module type], static,
 172         [static dynamic])
 173 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 174 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 175         [static dynamic])
 176
 177 dnl ----------------------------------------------------------------
 178 dnl SLURPD OPTIONS
 179 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 180 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 181
 182 dnl ----------------------------------------------------------------
 183 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 184 AC_ENABLE_STATIC
 185 dnl AC_DISABLE_SHARED
 186 AC_ENABLE_SHARED
 187
 188 dnl ----------------------------------------------------------------
 189
 190 dnl General "enable" options
 191 # validate options
 192 if test $ol_enable_slapd = no ; then
 193         dnl SLAPD was specificallly disabled
 194         if test $ol_enable_bdb2 = yes ; then
 195                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 196         fi
 197         if test $ol_enable_dnssrv = yes ; then
 198                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 199         fi
 200         if test $ol_enable_ldap = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 202         fi
 203         if test $ol_enable_ldbm = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 205         fi
 206         if test $ol_enable_passwd = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 208         fi
 209         if test $ol_enable_perl = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 211         fi
 212         if test $ol_enable_shell = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 214         fi
 215         if test $ol_enable_tcl = yes ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 217         fi
 218         if test $ol_enable_sql = yes ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 220         fi
 221         if test $ol_enable_modules = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 223         fi
 224         if test $ol_enable_multimaster = yes ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 226         fi
 227         if test $ol_enable_wrappers = yes ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 229         fi
 230         if test $ol_enable_phonetic = yes ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 232         fi
 233         if test $ol_enable_quipu = yes ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 235         fi
 236         if test $ol_enable_rlookups = yes ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 238         fi
 239         if test $ol_enable_aci = yes ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 241         fi
 242         if test $ol_with_ldbm_api != auto ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 244         fi
 245         if test $ol_with_ldbm_type != auto ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 247         fi
 248         if test $ol_with_bdb2_module != static ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 250         fi
 251         if test $ol_with_dnssrv_module != static ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 253         fi
 254         if test $ol_with_ldap_module != static ; then
 255                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 256         fi
 257         if test $ol_with_ldbm_module != static ; then
 258                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 259         fi
 260         if test $ol_with_passwd_module != static ; then
 261                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 262         fi
 263         if test $ol_with_perl_module != static ; then
 264                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 265         fi
 266         if test $ol_with_shell_module != static ; then
 267                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 268         fi
 269         if test $ol_with_tcl_module != static ; then
 270                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 271         fi
 272         if test $ol_with_sql_module != static ; then
 273                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 274         fi
 275         if test $ol_enable_slurpd = yes ; then
 276                 AC_MSG_ERROR([slurpd requires slapd])
 277         fi
 278
 279         # force settings to no
 280         ol_enable_bdb2=no
 281         ol_enable_dnssrv=no
 282         ol_enable_ldap=no
 283         ol_enable_ldbm=no
 284         ol_enable_passwd=no
 285         ol_enable_perl=no
 286         ol_enable_shell=no
 287         ol_enable_tcl=no
 288         ol_enable_sql=no
 289
 290         ol_enable_modules=no
 291         ol_enable_multimaster=no
 292         ol_enable_phonetic=no
 293         ol_enable_quipu=no
 294         ol_enable_rlookups=no
 295         ol_enable_aci=no
 296         ol_enable_wrappers=no
 297         ol_enable_dynamic=no
 298
 299         ol_with_ldbm_api=no
 300         ol_with_ldbm_type=no
 301
 302         ol_with_bdb2_module=static
 303         ol_with_dnssrv_module=static
 304         ol_with_ldap_module=static
 305         ol_with_ldbm_module=static
 306         ol_with_passwd_module=static
 307         ol_with_perl_module=static
 308         ol_with_shell_module=static
 309         ol_with_tcl_module=static
 310         ol_with_sql_module=static
 311
 312         ol_enable_slurpd=no
 313
 314 elif test $ol_enable_ldbm = no ; then
 315         dnl SLAPD without LDBM
 316
 317         if test $ol_with_ldbm_api != auto ; then
 318                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 319         fi
 320
 321         if test $ol_with_ldbm_type != auto ; then
 322                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 323         fi
 324
 325         if test $ol_with_ldbm_module != static ; then
 326                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 327         fi
 328
 329         if test $ol_enable_bdb2 = yes ; then
 330                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 331         fi
 332
 333         if test $ol_enable_modules != yes -a \
 334                 $ol_enable_dnssrv = no -a \
 335                 $ol_enable_ldap = no -a \
 336                 $ol_enable_passwd = no -a \
 337                 $ol_enable_perl = no -a \
 338                 $ol_enable_shell = no -a \
 339                 $ol_enable_sql = no -a \
 340                 $ol_enable_tcl = no ; then
 341                 AC_MSG_ERROR([slapd requires a backend])
 342         fi
 343
 344         ol_with_ldbm_api=no
 345         ol_with_ldbm_type=no
 346         ol_with_ldbm_module=static
 347
 348 elif test $ol_enable_bdb2 = yes ; then
 349         dnl SLAPD with BDB2
 350
 351         if test $ol_with_ldbm_api != auto -a \
 352                 $ol_with_ldbm_api != berkeley ; then
 353                 AC_MSG_ERROR([BDB2 requires LDBM API berkeley or auto])
 354         fi
 355
 356         ol_with_ldbm_api=db2
 357
 358 else
 359         dnl SLAPD with LDBM
 360
 361         if test $ol_enable_bdb2 != no ; then
 362                 if test $ol_with_ldbm_api != auto -a \
 363                         $ol_with_ldbm_api != berkeley ; then
 364                         AC_MSG_WARN([BDB2 requires LDBM api berkeley or auto])
 365                         ol_enable_bdb2=no
 366                 fi
 367         fi
 368
 369         if test $ol_with_ldbm_api = gdbm -a \
 370                 $ol_with_ldbm_type = btree ; then
 371                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 372         fi
 373         if test $ol_with_ldbm_api = mdbm -a \
 374                 $ol_with_ldbm_type = btree ; then
 375                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 376         fi
 377         if test $ol_with_ldbm_api = ndbm -a \
 378                 $ol_with_ldbm_type = btree ; then
 379                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 380         fi
 381 fi
 382
 383 if test $ol_enable_slurpd = yes ; then
 384         dnl SLURPD was specifically enabled
 385         if test $ol_with_threads = no ; then
 386                 AC_MSG_ERROR([slurpd requires threads])
 387         fi
 388 fi
 389
 390 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 391         if test $ol_with_kerberos = no ; then
 392                 AC_MSG_ERROR([options require --with-kerberos])
 393         fi
 394 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 395         if test $ol_with_kerberos != auto ; then
 396                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 397         else
 398                 ol_with_kerberos=no
 399         fi
 400 fi
 401
 402 if test $ol_enable_spasswd = yes ; then
 403         if test $ol_with_cyrus_sasl = no ; then
 404                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 405         fi
 406         ol_link_spasswd=yes
 407 fi
 408
 409 AC_MSG_RESULT(done)
 410
 411 dnl ----------------------------------------------------------------
 412 dnl Initialize vars
 413 LDAP_LIBS=
 414 LDIF_LIBS=
 415 LDBM_LIBS=
 416 LTHREAD_LIBS=
 417 LUTIL_LIBS=
 418
 419 QUIPU_LIBS=
 420 SLAPD_LIBS=
 421 SLURPD_LIBS=
 422
 423 BUILD_SLAPD=no
 424 BUILD_SLURPD=no
 425
 426 BUILD_QUIPU=no
 427 BUILD_THREAD=no
 428
 429 BUILD_BDB2=no
 430 BUILD_DNSSRV=no
 431 BUILD_LDAP=no
 432 BUILD_LDBM=no
 433 BUILD_PASSWD=no
 434 BUILD_PERL=no
 435 BUILD_SHELL=no
 436 BUILD_SQL=no
 437 BUILD_TCL=no
 438
 439 BUILD_BDB2_DYNAMIC=static
 440 BUILD_DNSSRV_DYNAMIC=static
 441 BUILD_LDAP_DYNAMIC=static
 442 BUILD_LDBM_DYNAMIC=static
 443 BUILD_PASSWD_DYNAMIC=static
 444 BUILD_PERL_DYNAMIC=static
 445 BUILD_SHELL_DYNAMIC=static
 446 BUILD_TCL_DYNAMIC=static
 447 BUILD_SQL_DYNAMIC=static
 448
 449 SLAPD_MODULES_LDFLAGS=
 450 SLAPD_MODULES_CPPFLAGS=
 451 SLAPD_MODULES_LIST=
 452
 453 SLAPD_PERL_LDFLAGS=
 454 MOD_PERL_LDFLAGS=
 455 PERL_CPPFLAGS=
 456
 457 SLAPD_SQL_LDFLAGS=
 458 SLAPD_SQL_LIBS=
 459 SLAPD_SQL_INCLUDES=
 460
 461 MOD_TCL_LIB=
 462 KRB4_LIBS=
 463 KRB5_LIBS=
 464 READLINE_LIBS=
 465 SASL_LIBS=
 466 TERMCAP_LIBS=
 467 TLS_LIBS=
 468 MODULES_LIBS=
 469 AUTH_LIBS=
 470
 471 dnl ================================================================
 472 dnl Checks for programs
 473
 474 dnl AC_PROG_INSTALL
 475
 476 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 477
 478 dnl ----------------------------------------------------------------
 479 dnl
 480 dnl Determine which C translator to use
 481 dnl
 482
 483 dnl AIX Thread requires we use cc_r or xlc_r.
 484 dnl But only do this IF AIX and CC is not set
 485 dnl and threads are auto|yes|posix.
 486 dnl
 487 dnl If we find cc_r|xlc_r, force pthreads and assume
 488 dnl             pthread_create is in $LIBS (ie: don't bring in
 489 dnl             any additional thread libraries)
 490 dnl If we do not find cc_r|xlc_r, disable threads
 491
 492 ol_aix_threads=no
 493 case "$target" in
 494 *-*-aix*) dnl all AIX is not a good idea.
 495         if test -z "$CC" ; then
 496                 case "$ol_with_threads" in
 497                 auto | yes |  posix) ol_aix_threads=yes ;;
 498                 esac
 499         fi
 500 ;;
 501 esac
 502
 503 if test $ol_aix_threads = yes ; then
 504         if test -z "${CC}" ; then
 505                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 506
 507                 if test "$CC" = cc ; then
 508                         dnl no CC! don't allow --with-threads
 509                         if test $ol_with_threads != auto ; then
 510                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 511                         else
 512                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 513                         fi
 514                         ol_with_threads=no
 515                 fi
 516         fi
 517
 518         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 519                 ol_with_threads=posix
 520                 ol_cv_pthread_create=yes
 521         fi
 522 fi
 523
 524 if test -z "${CC}"; then
 525         AC_CHECK_PROGS(CC,cc)
 526 fi
 527
 528 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 529 dnl (for now, let autoconf sort this out)
 530 dnl CFLAGS=${CFLAGS-""}
 531
 532 AC_LIBTOOL_WIN32_DLL
 533 AC_LIBTOOL_DLOPEN
 534 AC_PROG_LIBTOOL
 535
 536 AC_PROG_AWK
 537 OL_PROG_LN_H
 538 AC_PROG_LN_S
 539
 540 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 541         LN_S="$LN_H"
 542 fi
 543
 544 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 545         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 546 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 547 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 548
 549 dnl ----------------------------------------------------------------
 550 dnl Perl
 551 ol_link_perl=no
 552 if test $ol_enable_perl != no ; then
 553         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 554
 555         if test "no$PERLBIN" = "no" ; then
 556                 if test $ol_enable_perl = yes ; then
 557                         AC_MSG_ERROR([could not locate perl])
 558                 fi
 559
 560         else
 561                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 562                 if test x"$ol_with_perl_module" = "xstatic" ; then
 563                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 564                 else
 565                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 566                 fi
 567                 dnl should check perl version
 568                 ol_link_perl=yes
 569         fi
 570 fi
 571
 572 AC_PROG_CPP
 573
 574 dnl ----------------------------------------------------------------
 575 dnl Cross compiling checks
 576 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 577         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 578
 579 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 580         AC_MSG_WARN([programs compiled here do run here...])
 581         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 582
 583 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 584         AC_MSG_WARN([programs compiled here do not run here...])
 585         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 586 fi
 587
 588 dnl ----------------------------------------------------------------
 589 dnl Checks for UNIX Variants
 590 AC_AIX
 591 AC_ISC_POSIX
 592 AC_MINIX
 593
 594 dnl ----------------------------------------------------------------
 595 dnl Checks for system services
 596 AC_CYGWIN
 597 AC_MINGW32
 598 AC_EXEEXT
 599 AC_OBJEXT
 600
 601 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 602
 603 dnl ----------------------------------------------------------------
 604 dnl BeOS requires -lbe -lroot -lnet
 605 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 606
 607 dnl ----------------------------------------------------------------
 608 dnl OpenLDAP requires STDC features
 609 AM_PROG_CC_STDC
 610 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 611         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 612 fi
 613
 614 dnl ----------------------------------------------------------------
 615 dnl Check cc depend flags
 616 OL_MKDEPEND
 617 if test "${ol_cv_mkdep}" = no ; then
 618         # this will soon become an error
 619         AC_MSG_WARN([do not know how to generate dependencies])
 620 fi
 621
 622 dnl ----------------------------------------------------------------
 623 dnl Check for AIX security library
 624 AC_CHECK_LIB(s, afopen, [
 625         AUTH_LIBS=-ls
 626         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 627 ])
 628
 629 dnl ----------------------------------------------------------------
 630 dnl Check for module support
 631 ol_link_modules=no
 632 if test $ol_enable_modules != no ; then
 633         AC_CHECK_HEADERS(ltdl.h)
 634
 635         if test $ac_cv_header_ltdl_h = no ; then
 636                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 637         fi
 638
 639         AC_CHECK_LIB(ltdl, lt_dlinit, [
 640             MODULES_LIBS=-lltdl
 641             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 642         ])
 643
 644         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 645                 AC_MSG_ERROR([could not locate libtool -lltdl])
 646         fi
 647         ol_link_modules=yes
 648 else
 649         ol_with_bdb2_module=static
 650         ol_with_dnssrv_module=static
 651         ol_with_ldap_module=static
 652         ol_with_ldbm_module=static
 653         ol_with_passwd_module=static
 654         ol_with_perl_module=static
 655         ol_with_shell_module=static
 656         ol_with_tcl_module=static
 657         ol_with_sql_module=static
 658 fi
 659
 660 dnl ----------------------------------------------------------------
 661 dnl Checks for header files.
 662 OL_HEADER_STDC
 663
 664 if test $ol_cv_header_stdc != yes; then
 665         AC_MSG_WARN([could not locate Standard C compliant headers])
 666 fi
 667
 668 AC_HEADER_DIRENT
 669 AC_HEADER_SYS_WAIT
 670 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 671 if test $am_cv_sys_posix_termios = yes ; then
 672         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 673                 [define if you have POSIX termios])
 674 fi
 675
 676 AC_CHECK_HEADERS(       \
 677         arpa/inet.h             \
 678         arpa/nameser.h  \
 679         assert.h                \
 680         conio.h                 \
 681         crypt.h                 \
 682         direct.h                \
 683         errno.h                 \
 684         fcntl.h                 \
 685         filio.h                 \
 686         getopt.h                \
 687         grp.h                   \
 688         io.h                    \
 689         libutil.h               \
 690         limits.h                \
 691         locale.h                \
 692         netinet/tcp.h   \
 693         malloc.h                \
 694         memory.h                \
 695         psap.h                  \
 696         pwd.h                   \
 697         process.h               \
 698         resolv.h                \
 699         sgtty.h                 \
 700         shadow.h                \
 701         stddef.h                \
 702         string.h                \
 703         strings.h               \
 704         sysexits.h              \
 705         sys/file.h              \
 706         sys/filio.h             \
 707         sys/errno.h             \
 708         sys/ioctl.h             \
 709         sys/param.h             \
 710         sys/resource.h  \
 711         sys/select.h    \
 712         sys/socket.h    \
 713         sys/syslog.h    \
 714         sys/time.h              \
 715         sys/types.h             \
 716         syslog.h                \
 717         termios.h               \
 718         unistd.h                \
 719         winsock.h               \
 720 )
 721
 722
 723 dnl ----------------------------------------------------------------
 724 dnl Checks for libraries
 725
 726 dnl HP-UX requires -lV3
 727 AC_CHECK_LIB(V3, sigset)
 728
 729 dnl Gotta check for winsock manually
 730 if test $ac_cv_header_winsock_h = yes; then
 731         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 732         AC_TRY_LINK([#include <winsock.h>],[
 733                         socket(0,0,0);
 734                         select(0,NULL,NULL,NULL,NULL);
 735                         closesocket(0);
 736                         gethostname(NULL,0);
 737         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 738
 739         if test $ol_cv_winsock = yes ; then
 740                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 741                 ac_cv_func_socket=yes
 742                 ac_cv_func_select=yes
 743                 ac_cv_func_closesocket=yes
 744                 ac_cv_func_gethostname=yes
 745         fi
 746 fi
 747
 748 dnl Find socket()
 749 dnl Likely combinations:
 750 dnl             -lsocket [ -lnsl_s | -lnsl ]
 751 dnl             -linet
 752
 753 AC_CHECK_FUNC(socket, :, [
 754 dnl hopefully we won't include too many libraries
 755         AC_CHECK_LIB(socket, main)
 756         AC_CHECK_LIB(net, main)
 757         AC_CHECK_LIB(nsl_s, main)
 758         AC_CHECK_LIB(nsl, main)
 759         AC_CHECK_LIB(inet, socket)
 760         AC_CHECK_LIB(gen, main)
 761 ])
 762
 763 dnl require select
 764 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 765
 766 if test "${ac_cv_header_winsock_h}" != yes; then
 767     dnl Select arg types
 768     dnl (if this detection becomes permenent, it and the select() detection
 769     dnl should be done before the yielding select test)
 770     AC_FUNC_SELECT_ARGTYPES
 771 fi
 772
 773 dnl check to see if system call automatically restart
 774 dnl AC_SYS_RESTARTABLE_SYSCALLS
 775
 776 dnl ----------------------------------------------------------------
 777 dnl require POSIX regex
 778 AC_CHECK_HEADERS( regex.h )
 779 if test "$ac_cv_header_regex_h" != yes ; then
 780         AC_MSG_ERROR([POSIX regex.h required.])
 781 fi
 782 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 783
 784 OL_POSIX_REGEX
 785 if test "$ol_cv_c_posix_regex" = no ; then
 786         AC_MSG_ERROR([broken POSIX regex!])
 787 fi
 788
 789 dnl ----------------------------------------------------------------
 790 dnl Check for resolver routines
 791 AC_CHECK_FUNC(res_search,:)
 792 if test $ac_cv_func_res_search = no ; then
 793         AC_CHECK_LIB(bind, res_search)
 794         ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 795 fi
 796
 797 if test $ac_cv_func_res_search = no ; then
 798         AC_CHECK_LIB(bind, __res_search)
 799         ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 800 fi
 801
 802 if test $ac_cv_func_res_search = no ; then
 803         AC_CHECK_LIB(resolv, res_search)
 804         ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 805 fi
 806
 807 if test "$ac_cv_func_res_search" = yes ; then
 808         AC_DEFINE(HAVE_RES_SEARCH,1,
 809                 [define if you have res_search()])
 810 fi
 811
 812
 813 dnl ----------------------------------------------------------------
 814 dnl QUIPU
 815 if test $ol_enable_quipu != no ; then
 816         AC_CHECK_HEADERS(quipu/commonarg.h)
 817
 818         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 819                 BUILD_QUIPU=yes
 820         elif test $ol_enable_quipu = auto ; then
 821                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 822         else
 823                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 824         fi
 825 fi
 826
 827 dnl ----------------------------------------------------------------
 828 dnl Kerberos
 829 ol_link_kbind=no
 830 ol_link_kpasswd=no
 831 ol_link_krb5=no
 832 ol_link_krb4=no
 833
 834 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 \
 835         -o $ol_with_kerberos = k5only -o $ol_with_kerberos = k425 ; then
 836
 837         AC_CHECK_HEADERS(krb5.h)
 838
 839         if test $ac_cv_header_krb5_h = yes ; then
 840                 dnl lazy check for Heimdal Kerberos
 841                 AC_CHECK_HEADERS(heim_err.h)
 842                 if test $ac_cv_header_heim_err_h = yes ; then
 843                         krb5_impl=heimdal
 844                 else
 845                         krb5_impl=mit
 846                 fi
 847
 848                 if test $krb5_impl = mit; then
 849                         AC_CHECK_LIB(krb5, main,
 850                                 [have_krb5=yes
 851                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 852                                 [have_krb5=no],
 853                                 [-lcrypto -lcom_err])
 854
 855                 elif test $krb5_impl = heimdal; then
 856                         AC_CHECK_LIB(krb5, main,
 857                                 [have_krb5=yes
 858                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 859                                 [have_krb5=no],
 860                                 [-ldes -lasn1 -lroken -lcom_err])
 861
 862                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 863                                 [define if you have HEIMDAL Kerberos])
 864                 else
 865                         have_krb5=no
 866                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 867                 fi
 868
 869                 if test $have_krb5 = yes ; then
 870                         ol_link_krb5=yes
 871
 872                         AC_DEFINE(HAVE_KRB5, 1,
 873                                 [define if you have Kerberos V])
 874
 875                         if test $ol_enable_kpasswd != no ; then
 876                                 ol_link_kpasswd=yes;
 877                         fi
 878
 879                         if test $ol_with_kerberos = k5only ; then
 880                                 ol_with_kerberos=found
 881                         fi
 882
 883                 elif test $ol_with_kerberos != auto ; then
 884                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 885                 fi
 886
 887         fi
 888 fi
 889
 890 if test $ol_link_krb5 = yes -a \
 891         \( $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 892
 893         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 894
 895         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 896                 if test $krb5_impl = mit; then
 897                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 898                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 899                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 900
 901                 elif test $krb5_impl = heimdal; then
 902                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 903                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 904                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 905
 906                 else
 907                         have_425=no
 908                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 909                 fi
 910
 911                 if test $have_k425 = yes ; then
 912                         ol_with_kerberos=found
 913                         ol_link_krb4=yes
 914
 915                         AC_DEFINE(HAVE_KRB425, 1,
 916                                 [define if you have Kerberos V with IV support])
 917                         AC_DEFINE(HAVE_KRB4, 1,
 918                                 [define if you have Kerberos IV])
 919
 920                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 921                                 [ol_cv_var_des_debug], [
 922                                 dnl save the flags
 923                                 save_LIBS="$LIBS"
 924                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 925                                 AC_TRY_LINK([
 926 #include <kerberosIV/krb.h>
 927 #include <kerberosIV/des.h>
 928 extern int des_debug;
 929 ],[
 930 des_debug = 1;
 931 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 932                                 dnl restore the LIBS
 933                                 LIBS="$save_LIBS"
 934                         ])
 935
 936                         if test $ol_cv_var_des_debug = yes ; then
 937                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 938                                         [define if you have Kerberos des_debug])
 939                         fi
 940
 941                         LIBS="$save_LIBS"
 942                 fi
 943         fi
 944 fi
 945
 946 if test $ol_link_krb5 = yes ; then
 947         ol_with_kerberos=found
 948 fi
 949
 950 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 \
 951         -o $ol_with_kerberos = kth ; then
 952
 953         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 954
 955         if test $ac_cv_header_krb_h = yes ; then
 956                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 957
 958                 if test $have_k4 = yes ; then
 959                         ol_with_kerberos=found
 960                         ol_link_krb4=yes
 961
 962                         AC_DEFINE(HAVE_KRB4, 1,
 963                                 [define if you have Kerberos IV])
 964
 965                         KRB4_LIBS="-lkrb -ldes"
 966
 967                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 968                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 969                                         [define if you have Kth Kerberos])
 970                         fi
 971                 fi
 972         fi
 973 fi
 974
 975 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 976         ol_link_kpasswd=yes;
 977 fi
 978
 979 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 980         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 981
 982 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 983         AC_MSG_ERROR([Kerberos detection failed.])
 984 fi
 985
 986 dnl ----------------------------------------------------------------
 987 dnl TLS/SSL
 988 ol_link_tls=no
 989 if test $ol_with_tls != no ; then
 990
 991         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 992
 993         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 994                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 995                         [have_ssleay=yes
 996                         need_rsaref=no],
 997                         [have_ssleay=no],
 998                         [-lcrypto])
 999
1000                 if test $have_ssleay = no ; then
1001                         AC_CHECK_LIB(ssl, SSL_library_init,
1002                                 [have_ssleay=yes
1003                                 need_rsaref=no], [have_ssleay=no],
1004                                 [-lcrypto])
1005                 fi
1006
1007                 if test $have_ssleay = no ; then
1008                         AC_CHECK_LIB(ssl, ssl3_accept,
1009                                 [have_ssleay=yes
1010                                 need_rsaref=yes], [have_ssleay=no],
1011                                 [-lcrypto -lRSAglue -lrsaref])
1012                 fi
1013
1014                 if test $have_ssleay = yes ; then
1015                         ol_with_tls=found
1016                         ol_link_tls=yes
1017
1018                         AC_DEFINE(HAVE_SSLEAY, 1,
1019                                 [define if you have SSLeay or OpenSSL])
1020
1021                         if test $need_rsaref = yes; then
1022                                 AC_DEFINE(HAVE_RSAREF, 1,
1023                                         [define if you have RSAref])
1024
1025                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1026                         else
1027                                 TLS_LIBS="-lssl -lcrypto"
1028                         fi
1029                 fi
1030         fi
1031 fi
1032
1033 if test $ol_link_tls = yes ; then
1034         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1035 fi
1036
1037 dnl ----------------------------------------------------------------
1038 dnl Tests for reentrant functions necessary to build a
1039 dnl thread_safe -lldap.
1040 AC_CHECK_FUNCS(         \
1041         ctime_r                 \
1042         gethostbyname_r gethostbyaddr_r \
1043 )
1044
1045 if test "$ac_cv_func_ctime_r" = no ; then
1046         ol_cv_func_ctime_r_nargs=0
1047 else
1048         OL_FUNC_CTIME_R_NARGS
1049 dnl     OL_FUNC_CTIME_R_TYPE
1050 fi
1051
1052 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1053         OL_FUNC_GETHOSTBYNAME_R_NARGS
1054 else
1055         ol_cv_func_gethostbyname_r_nargs=0
1056 fi
1057
1058 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1059         OL_FUNC_GETHOSTBYADDR_R_NARGS
1060 else
1061         ol_cv_func_gethostbyaddr_r_nargs=0
1062 fi
1063
1064 if test "$ac_cv_func_ctime_r" = yes \
1065         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1066         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1067         -a "$ac_cv_func_gethostbyname_r" = yes \
1068         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1069         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1070         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1071         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1072         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1073         ; then
1074
1075         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1076 fi
1077
1078 dnl ----------------------------------------------------------------
1079 dnl Threads?
1080 ol_link_threads=no
1081
1082 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1083         -o $ol_with_threads = nt ; then
1084
1085         OL_NT_THREADS
1086
1087         if test "$ol_cv_nt_threads" = yes ; then
1088         ol_link_threads=nt
1089         ol_with_threads=found
1090         ol_with_yielding_select=yes
1091
1092                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1093                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1094         fi
1095
1096         if test $ol_with_threads = nt ; then
1097                 AC_MSG_ERROR([could not locate NT Threads])
1098         fi
1099 fi
1100
1101 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1102         -o $ol_with_threads = posix ; then
1103
1104         AC_CHECK_HEADERS(pthread.h)
1105
1106         if test $ac_cv_header_pthread_h = yes ; then
1107                 OL_POSIX_THREAD_VERSION
1108
1109                 if test $ol_cv_pthread_version = final ; then
1110                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1111                                 [define if pthreads API compatible with final spec])
1112                 elif test $ol_cv_pthread_version = draft4 ; then
1113                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1114                                 [define if pthreads API compatible with draft4 spec])
1115                 else
1116                         AC_MSG_ERROR([unknown pthread version])
1117                 fi
1118
1119                 # consider threads found
1120                 ol_with_threads=found
1121
1122                 OL_HEADER_LINUX_THREADS
1123                 OL_HEADER_GNU_PTH_PTHREAD_H
1124
1125                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1126                         AC_CHECK_HEADERS(sched.h)
1127                 fi
1128
1129                 dnl Now the hard part, how to link?
1130                 dnl
1131                 dnl currently supported checks:
1132                 dnl
1133                 dnl Check for no flags
1134                 dnl     pthread_create() in $LIBS
1135                 dnl
1136                 dnl Check special pthread (final) flags
1137                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1138                 dnl     pthread_create() with -kthread (FreeBSD)
1139                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1140                 dnl     pthread_create() with -pthreads (?)
1141                 dnl     pthread_create() with -mthreads (AIX)
1142                 dnl     pthread_create() with -thread (?)
1143                 dnl
1144                 dnl Check pthread (final) libraries
1145                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1146                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1147                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1148                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1149                 dnl     pthread_create() in -lpthread (many)
1150                 dnl     pthread_create() in -lc_r (FreeBSD)
1151                 dnl
1152                 dnl Check pthread (draft4) flags (depreciated)
1153                 dnl     pthread_create() with -threads (OSF/1)
1154                 dnl
1155                 dnl Check pthread (draft4) libraries (depreciated)
1156                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1157                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1158                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1159                 dnl     pthread_create() in -lpthreads (many)
1160                 dnl
1161
1162                 dnl pthread_create in $LIBS
1163                 AC_CACHE_CHECK([for pthread_create in default libraries],
1164                         ol_cv_pthread_create,[
1165                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1166                         [ol_cv_pthread_create=yes],
1167                         [ol_cv_pthread_create=no],
1168                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1169                                 [ol_cv_pthread_create=yes],
1170                                 [ol_cv_pthread_create=no])])])
1171
1172                 if test $ol_cv_pthread_create != no ; then
1173                         ol_link_threads=posix
1174                         ol_link_pthreads=""
1175                 fi
1176
1177 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1178                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1179                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1180                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1181                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1182                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1183
1184                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1185                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1186                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1187                         [ol_cv_pthread_lpthread_lmach_lexc])
1188 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1189 dnl                     [ol_cv_pthread_lpthread_lexc])
1190
1191                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1192                         [ol_cv_pthread_lib_lpthread_woff])
1193
1194                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1195                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1196
1197                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1198
1199                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1200                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1201                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1202                         [ol_cv_pthread_lpthreads_lmach_lexc])
1203                 OL_PTHREAD_TRY([-lpthreads -lexc],
1204                         [ol_cv_pthread_lpthreads_lexc])
1205
1206                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1207
1208                 if test $ol_link_threads != no ; then
1209                         AC_DEFINE(HAVE_PTHREADS,1,
1210                                 [define if you have POSIX Threads])
1211
1212                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1213
1214                         dnl save flags
1215                         save_CPPFLAGS="$CPPFLAGS"
1216                         save_LIBS="$LIBS"
1217                         LIBS="$LTHREAD_LIBS $LIBS"
1218
1219                         dnl All POSIX Thread (final) implementations should have
1220                         dnl sched_yield instead of pthread yield.
1221                         dnl check for both
1222                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1223
1224                         if test $ac_cv_func_sched_yield = no -a \
1225                                 $ac_cv_func_pthread_yield = no ; then
1226                                 dnl Digital UNIX has sched_yield() in -lrt
1227                                 AC_CHECK_LIB(rt, sched_yield,
1228                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1229                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1230                                                 [Define if you have the sched_yield function.])
1231                                         ac_cv_func_sched_yield=yes],
1232                                         [ac_cv_func_sched_yield=no])
1233                         fi
1234                         if test $ac_cv_func_sched_yield = no -a \
1235                                 $ac_cv_func_pthread_yield = no ; then
1236                                 dnl Solaris has sched_yield() stub in -lposix4
1237                                 dnl but we'll use thr_yield instead.
1238                                 AC_CHECK_FUNCS(thr_yield)
1239                         fi
1240                         if test $ac_cv_func_sched_yield = no -a \
1241                                 $ac_cv_func_pthread_yield = no -a \
1242                                 "$ac_cv_func_thr_yield" = no ; then
1243                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1244                         fi
1245
1246                         dnl Check functions for compatibility
1247                         AC_CHECK_FUNCS(pthread_kill)
1248
1249                         dnl Check for pthread_detach with <pthread.h> inclusion
1250                         dnl as it's symbol may have been mangled.
1251                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1252                                 [ol_cv_func_pthread_detach], [
1253                                 dnl save the flags
1254                                 AC_TRY_LINK([
1255 #include <pthread.h>
1256 #ifndef NULL
1257 #define NULL (void*)0
1258 #endif
1259 ],
1260                                         [pthread_detach(NULL);],
1261                                         [ol_cv_func_pthread_detach=yes],
1262                                         [ol_cv_func_pthread_detach=no])
1263                         ])
1264
1265                         if test $ol_cv_func_pthread_detach = no ; then
1266                                 AC_MSG_ERROR([could not locate pthread_detach()])
1267                         fi
1268
1269                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1270                                 [define if you have pthread_detach function])
1271
1272                         dnl Check for setconcurreny functions
1273                         AC_CHECK_FUNCS( \
1274                                 pthread_setconcurrency \
1275                                 pthread_getconcurrency \
1276                                 thr_setconcurrency \
1277                                 thr_getconcurrency \
1278                         )
1279
1280                         OL_SYS_LINUX_THREADS
1281                         OL_LINUX_THREADS
1282
1283                         if test $ol_cv_linux_threads = error; then
1284                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1285                         fi
1286
1287                         AC_CACHE_CHECK([if pthread_create() works],
1288                                 ol_cv_pthread_create_works,[
1289                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1290                                 [ol_cv_pthread_create_works=yes],
1291                                 [ol_cv_pthread_create_works=no],
1292                                 [dnl assume yes
1293                                 ol_cv_pthread_create_works=yes])])
1294
1295                         if test $ol_cv_pthread_create_works = no ; then
1296                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1297                         fi
1298
1299                         dnl Check if select causes an yield
1300                         if test $ol_with_yielding_select = auto ; then
1301                                 AC_CACHE_CHECK([if select yields when using pthreads],
1302                                         ol_cv_pthread_select_yields,[
1303                                 AC_TRY_RUN([
1304 #include <sys/types.h>
1305 #include <sys/time.h>
1306 #include <unistd.h>
1307 #include <pthread.h>
1308 #ifndef NULL
1309 #define NULL (void*) 0
1310 #endif
1311
1312 static int fildes[2];
1313
1314 static void *task(p)
1315         void *p;
1316 {
1317         int i;
1318         struct timeval tv;
1319
1320         fd_set rfds;
1321
1322         tv.tv_sec=10;
1323         tv.tv_usec=0;
1324
1325         FD_ZERO(&rfds);
1326         FD_SET(fildes[0], &rfds);
1327
1328         /* we're not interested in any fds */
1329         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1330
1331         if(i < 0) {
1332                 perror("select");
1333                 exit(10);
1334         }
1335
1336         exit(0); /* if we exit here, the select blocked the whole process */
1337 }
1338
1339 int main(argc, argv)
1340         int argc;
1341         char **argv;
1342 {
1343         pthread_t t;
1344
1345         /* create a pipe to select */
1346         if(pipe(&fildes[0])) {
1347                 perror("select");
1348                 exit(1);
1349         }
1350
1351 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1352         (void) pthread_setconcurrency(2);
1353 #else
1354 #ifdef HAVE_THR_SETCONCURRENCY
1355         /* Set Solaris LWP concurrency to 2 */
1356         thr_setconcurrency(2);
1357 #endif
1358 #endif
1359
1360 #if HAVE_PTHREADS_D4
1361         pthread_create(&t, pthread_attr_default, task, NULL);
1362 #else
1363         pthread_create(&t, NULL, task, NULL);
1364 #endif
1365
1366 #if HAVE_SCHED_YIELD
1367         sched_yield();  /* make sure task runs first */
1368 #else
1369 #ifdef HAVE_PTHREAD_YIELD
1370         pthread_yield();        /* make sure task runs first */
1371 #endif
1372 #endif
1373
1374         exit(2);
1375 }],
1376                                 [ol_cv_pthread_select_yields=no],
1377                                 [ol_cv_pthread_select_yields=yes],
1378                                 [ol_cv_pthread_select_yields=cross])])
1379
1380                                 if test $ol_cv_pthread_select_yields = cross ; then
1381                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1382                                 fi
1383
1384                                 if test $ol_cv_pthread_select_yields = yes ; then
1385                                         ol_with_yielding_select=yes
1386                                 fi
1387                         fi
1388
1389                         dnl restore flags
1390                         CPPFLAGS="$save_CPPFLAGS"
1391                         LIBS="$save_LIBS"
1392                 else
1393                         AC_MSG_ERROR([could not link with POSIX Threads])
1394                 fi
1395         fi
1396
1397         if test $ol_with_threads = posix ; then
1398                 AC_MSG_ERROR([could not locate POSIX Threads])
1399         fi
1400 fi
1401
1402 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1403         -o $ol_with_threads = mach ; then
1404
1405         dnl check for Mach CThreads
1406         AC_CHECK_HEADERS(mach/cthreads.h)
1407         if test $ac_cv_header_mach_cthreads_h = yes ; then
1408                 ol_with_threads=found
1409
1410                 dnl check for cthread support in current $LIBS
1411                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1412
1413                 if test $ol_link_threads = no ; then
1414                         dnl try -all_load
1415                         dnl this test needs work
1416                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1417                                 [ol_cv_cthread_all_load], [
1418                                 dnl save the flags
1419                                 save_LIBS="$LIBS"
1420                                 LIBS="-all_load $LIBS"
1421                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1422                                         cthread_fork((void *)0, (void *)0);
1423                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1424                                 dnl restore the LIBS
1425                                 LIBS="$save_LIBS"
1426                         ])
1427
1428                         if test $ol_cv_cthread_all_load = yes ; then
1429                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1430                                 ol_link_threads=mach
1431                         fi
1432                 fi
1433
1434                 if test $ol_link_threads != no ; then
1435                         : check for cthread specific functionality here
1436                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1437                                 [define if you have Mach Cthreads])
1438                 else
1439                         AC_MSG_ERROR([could not link with Mach CThreads])
1440                 fi
1441         fi
1442
1443         if test $ol_with_threads = mach ; then
1444                 AC_MSG_ERROR([could not locate Mach CThreads])
1445         fi
1446 fi
1447
1448 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1449         -o $ol_with_threads = pth ; then
1450
1451         AC_CHECK_HEADERS(pth.h)
1452
1453         if test $ac_cv_header_pth_h = yes ; then
1454                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1455
1456                 if test $have_pth = yes ; then
1457                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1458                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1459                         ol_link_threads=pth
1460
1461                         if test $ol_with_yielding_select = auto ; then
1462                                 ol_with_yielding_select=yes
1463                         fi
1464                 fi
1465         fi
1466 fi
1467
1468 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1469         -o $ol_with_threads = lwp ; then
1470
1471         dnl check for SunOS5 LWP
1472         AC_CHECK_HEADERS(thread.h synch.h)
1473         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1474                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1475
1476                 if test $have_thr = yes ; then
1477                         AC_DEFINE(HAVE_THR,1,
1478                                 [if you have Solaris LWP (thr) package])
1479                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1480                         ol_link_threads=thr
1481
1482                         if test $ol_with_yielding_select = auto ; then
1483                                 ol_with_yielding_select=yes
1484                         fi
1485
1486                         dnl Check for setconcurreny functions
1487                         AC_CHECK_FUNCS( \
1488                                 thr_setconcurrency \
1489                                 thr_getconcurrency \
1490                         )
1491                 fi
1492         fi
1493
1494         dnl check for SunOS4 LWP
1495         AC_CHECK_HEADERS(lwp/lwp.h)
1496         if test $ac_cv_header_lwp_lwp_h = yes ; then
1497                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1498
1499                 if test $have_lwp = yes ; then
1500                         AC_DEFINE(HAVE_LWP,1,
1501                                 [if you have SunOS LWP package])
1502                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1503                         ol_link_threads=lwp
1504
1505                         if test $ol_with_yielding_select = auto ; then
1506                                 ol_with_yielding_select=no
1507                         fi
1508                 fi
1509         fi
1510 fi
1511
1512 if test $ol_with_yielding_select = yes ; then
1513         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1514                 [define if select implicitly yields])
1515 fi
1516
1517 if test $ol_with_threads = manual ; then
1518         dnl User thinks he can manually configure threads.
1519         ol_link_threads=yes
1520
1521         AC_MSG_WARN([thread defines and link options must be set manually])
1522
1523         AC_CHECK_HEADERS(pthread.h sched.h)
1524         AC_CHECK_FUNCS(sched_yield pthread_yield)
1525         OL_HEADER_LINUX_THREADS
1526
1527         AC_CHECK_HEADERS(mach/cthreads.h)
1528         AC_CHECK_HEADERS(lwp/lwp.h)
1529         AC_CHECK_HEADERS(thread.h synch.h)
1530 fi
1531
1532 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1533         dnl needed to get reentrant/threadsafe versions
1534         dnl
1535         AC_DEFINE(REENTRANT,1)
1536         AC_DEFINE(_REENTRANT,1)
1537         AC_DEFINE(THREAD_SAFE,1)
1538         AC_DEFINE(_THREAD_SAFE,1)
1539         AC_DEFINE(THREADSAFE,1)
1540         AC_DEFINE(_THREADSAFE,1)
1541         AC_DEFINE(_SGI_MP_SOURCE,1)
1542
1543         dnl The errno declaration may dependent upon _REENTRANT.
1544         dnl If it does, we must link with thread support.
1545         AC_CACHE_CHECK([for thread specific errno],
1546                 [ol_cv_errno_thread_specific], [
1547                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1548                         [ol_cv_errno_thread_specific=yes],
1549                         [ol_cv_errno_thread_specific=no])
1550         ])
1551
1552         dnl The h_errno declaration may dependent upon _REENTRANT.
1553         dnl If it does, we must link with thread support.
1554         AC_CACHE_CHECK([for thread specific h_errno],
1555                 [ol_cv_h_errno_thread_specific], [
1556                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1557                         [ol_cv_h_errno_thread_specific=yes],
1558                         [ol_cv_h_errno_thread_specific=no])
1559         ])
1560
1561         if test $ol_cv_errno_thread_specific != yes \
1562                 -o $ol_cv_h_errno_thread_specific != yes ; then
1563                 LIBS="$LTHREAD_LIBS $LIBS"
1564                 LTHREAD_LIBS=""
1565         fi
1566
1567 dnl When in thread environment, use
1568 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1569 dnl                     || defined( HAVE_FUNC_R )
1570 dnl                     func_r(...);
1571 dnl             #else
1572 dnl             #       if defined( HAVE_THREADS )
1573 dnl                             /* lock */
1574 dnl             #       endif
1575 dnl                             func(...);
1576 dnl             #       if defined( HAVE_THREADS )
1577 dnl                             /* unlock */
1578 dnl             #       endif
1579 dnl             #endif
1580 dnl
1581 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1582 dnl             _POSIX_REENTRANT_FUNCTIONS
1583 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1584 dnl             _POSIX_THREADSAFE_FUNCTIONS
1585 dnl
1586 dnl             and is currently defined in lthread.h
1587 dnl
1588 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1589 dnl
1590 dnl libldap/*.c should only include <lthread.h> iff
1591 dnl LDAP_R_COMPILE is defined.  ie:
1592 dnl             #ifdef LDAP_R_COMPILE
1593 dnl             #       include LDAP_R_COMPILE
1594 dnl             #endif
1595 dnl
1596 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1597 dnl specifically for compiling the threadsafe version of
1598 dnl     the ldap library (-lldap_r).
1599 dnl
1600 dnl     dnl check for reentrant/threadsafe functions
1601 dnl     dnl
1602 dnl     dnl note: these should only be used when linking
1603 dnl     dnl       with $LTHREAD_LIBS
1604 dnl     dnl
1605 dnl     save_CPPFLAGS="$CPPFLAGS"
1606 dnl     save_LIBS="$LIBS"
1607 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1608 dnl     AC_CHECK_FUNCS( \
1609 dnl             gmtime_r \
1610 dnl             gethostbyaddr_r gethostbyname_r \
1611 dnl             feof_unlocked unlocked_feof \
1612 dnl             putc_unlocked unlocked_putc \
1613 dnl             flockfile ftrylockfile \
1614 dnl     )
1615 dnl     CPPFLAGS="$save_CPPFLAGS"
1616 dnl     LIBS="$save_LIBS"
1617 fi
1618
1619 if test $ol_link_threads = no ; then
1620         if test $ol_with_threads = yes ; then
1621                 AC_MSG_ERROR([no suitable thread support])
1622         fi
1623
1624         if test $ol_with_threads = auto ; then
1625                 AC_MSG_WARN([no suitable thread support, disabling threads])
1626                 ol_with_threads=no
1627         fi
1628
1629         AC_DEFINE(NO_THREADS,1,
1630                 [define if you have (or want) no threads])
1631         LTHREAD_LIBS=""
1632 fi
1633
1634 if test $ol_link_threads != no ; then
1635         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1636 fi
1637
1638 dnl ----------------------------------------------------------------
1639 ol_link_ldbm=no
1640
1641 if test $ol_with_ldbm_api = auto \
1642         -o $ol_with_ldbm_api = berkeley \
1643         -o $ol_with_ldbm_api = bcompat ; then
1644
1645         if test $ol_with_ldbm_api = bcompat; then \
1646                 OL_BERKELEY_COMPAT_DB
1647         else
1648                 OL_BERKELEY_DB
1649         fi
1650
1651         if test $ol_cv_berkeley_db != no ; then
1652                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1653                         [define this if Berkeley DB is available])
1654
1655                 ol_link_ldbm=berkeley
1656                 ol_with_ldbm_api=db
1657
1658                 if test $ol_with_ldbm_type = hash ; then
1659                         AC_DEFINE(LDBM_USE_DBHASH,1,
1660                                 [define this to use DBHASH w/ LDBM backend])
1661                 else
1662                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1663                                 [define this to use DBBTREE w/ LDBM backend])
1664                 fi
1665
1666                 dnl $ol_cv_lib_db should be yes or -ldb
1667                 dnl (it could be no, but that would be an error
1668                 if test $ol_cv_lib_db != yes ; then
1669                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1670                 fi
1671         fi
1672 fi
1673
1674 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1675         AC_MSG_WARN(Could not find LDBM with BTREE support)
1676         ol_with_ldbm_api=none
1677 fi
1678
1679 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1680         OL_MDBM
1681
1682         if test $ol_cv_mdbm = yes ; then
1683                 ol_link_ldbm=mdbm
1684                 ol_with_ldbm_api=mdbm
1685                 if test $ol_cv_lib_mdbm != yes ; then
1686                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1687                 fi
1688         fi
1689 fi
1690
1691 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1692         OL_GDBM
1693
1694         if test $ol_cv_gdbm = yes ; then
1695                 ol_link_ldbm=gdbm
1696                 ol_with_ldbm_api=gdbm
1697
1698                 if test $ol_cv_lib_gdbm != yes ; then
1699                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1700                 fi
1701         fi
1702 fi
1703
1704 if test $ol_with_ldbm_api = ndbm ; then
1705         OL_NDBM
1706
1707         if test $ol_cv_ndbm = yes ; then
1708                 ol_link_ldbm=ndbm
1709                 ol_with_ldbm_api=ndbm
1710
1711                 if test $ol_cv_lib_ndbm != yes ; then
1712                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1713                 fi
1714         fi
1715 fi
1716
1717 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1718         AC_MSG_WARN(could not find suitable LDBM backend)
1719         if test $ol_enable_ldbm = yes ; then
1720                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1721         fi
1722
1723         AC_MSG_WARN(disabling LDBM)
1724         ol_enable_ldbm=no
1725 fi
1726
1727 dnl ----------------------------------------------------------------
1728 ol_link_bdb2=no
1729 if test $ol_enable_bdb2 != no ; then
1730         if test $ol_enable_bdb2 = yes -a $ol_link_ldbm != berkeley ; then
1731                 AC_MSG_ERROR(BDB2 requires LDBM BerkeleyDB 2)
1732         elif test $ol_link_ldbm = berkeley ; then
1733                 ol_link_bdb2=$ol_link_ldbm
1734         fi
1735 fi
1736
1737 dnl ----------------------------------------------------------------
1738 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1739         LINK_BINS_DYNAMIC="yes"
1740 else
1741         LINK_BINS_DYNAMIC="no"
1742 fi
1743
1744 dnl ----------------------------------------------------------------
1745 if test $ol_enable_wrappers != no ; then
1746         AC_CHECK_HEADERS(tcpd.h)
1747
1748         if test $ac_cv_header_tcpd_h != yes ; then
1749                 have_wrappers=no
1750         else
1751                 AC_TRY_COMPILE([
1752 int allow_severity = 0;
1753 int deny_severity  = 0;
1754                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1755         fi
1756
1757         if test $have_wrappers = yes ; then
1758                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1759                 WRAP_LIBS="-lwrap"
1760
1761                 dnl We add another check for -lnsl since some libwrap's
1762                 dnl need it, but it isn't always included from above
1763                 AC_CHECK_LIB(nsl, main)
1764         else
1765                 AC_MSG_WARN(could not find -lwrap)
1766                 if test $ol_enable_wrappers = yes ; then
1767                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1768                 fi
1769
1770                 AC_MSG_WARN(disabling wrappers support)
1771                 ol_enable_wrappers=no
1772                 WRAP_LIBS=""
1773         fi
1774 fi
1775
1776 dnl ----------------------------------------------------------------
1777 if test $ol_enable_syslog != no ; then
1778         AC_CHECK_FUNC(openlog)
1779         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1780                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1781         fi
1782         ol_enable_syslog=$ac_cv_func_openlog
1783 fi
1784
1785 dnl ----------------------------------------------------------------
1786 dnl dmalloc support (deprecated in favor of -DCSRIMALLOC support)
1787 dnl if test $ol_enable_dmalloc != no ; then
1788 dnl     AC_CHECK_HEADERS(dmalloc.h)
1789 dnl     AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1790 dnl fi
1791 dnl ----------------------------------------------------------------
1792 dnl TCL
1793 if test $ol_enable_tcl != no ; then
1794         AC_CHECK_HEADERS(tcl.h)
1795
1796         if test $ac_cv_header_tcl_h != yes ; then
1797                 have_tcl=no
1798         else
1799                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1800                         AC_CHECK_LIB($lib,main,
1801                           [have_tcl=yes
1802                            if test x"$ol_with_tcl_module" = "xstatic" ; then
1803                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1804                            else
1805                                MOD_TCL_LIB="-l${lib}"
1806                            fi;break],[have_tcl=no])
1807                 done
1808         fi
1809
1810         if test $have_tcl != yes ; then
1811                 AC_MSG_WARN([could not find -ltcl])
1812                 if test $ol_enable_tcl = yes ; then
1813                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1814                 fi
1815
1816                 ol_enable_tcl=no
1817         fi
1818 fi
1819
1820 dnl ----------------------------------------------------------------
1821 dnl ud needs termcap (should insert check here)
1822 ol_link_termcap=no
1823 AC_CHECK_HEADERS(termcap.h ncurses.h)
1824
1825 if test $ol_link_termcap = no ; then
1826         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1827         if test $have_termcap = yes ; then
1828                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1829                 ol_link_termcap=yes
1830                 TERMCAP_LIBS=-ltermcap
1831         fi
1832 fi
1833
1834 if test $ol_link_termcap = no ; then
1835         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1836         if test $have_ncurses = yes ; then
1837                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1838                 ol_link_termcap=yes
1839                 TERMCAP_LIBS=-lncurses
1840         fi
1841 fi
1842
1843 if test $ol_link_termcap = no ; then
1844         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1845         TERMCAP_LIBS=
1846 fi
1847
1848 dnl ----------------------------------------------------------------
1849 dnl
1850 dnl Check for Cyrus SASL
1851 dnl
1852 ol_link_sasl=no
1853 ol_link_spasswd=no
1854 if test $ol_with_cyrus_sasl != no ; then
1855         AC_CHECK_HEADER(sasl.h)
1856
1857         if test $ac_cv_header_sasl_h = yes ; then
1858                 AC_CHECK_LIB(sasl, sasl_client_init,
1859                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1860
1861                 if test $have_cyrus_sasl != no ; then
1862                         SASL_LIBS="-lsasl"
1863                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1864                         ol_link_sasl=yes
1865                 fi
1866         fi
1867
1868         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1869                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1870         fi
1871 fi
1872
1873 dnl ----------------------------------------------------------------
1874 dnl Check for entropy sources
1875 if test $cross_compiling != yes ; then
1876         dev=no
1877         if test -r /dev/urandom ; then
1878                 dev="/dev/urandom";
1879         elif test -r /idev/urandom ; then
1880                 dev="/idev/urandom";
1881         elif test -r /dev/srandom ; then
1882                 dev="/dev/srandom";
1883         elif test -r /dev/random ; then
1884                 dev="/dev/random";
1885         elif test -r /idev/random ; then
1886                 dev="/idev/random";
1887         fi
1888
1889         if test $dev != no ; then
1890                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1891         fi
1892 fi
1893
1894 dnl ----------------------------------------------------------------
1895 dnl
1896 dnl Check for fetch URL support
1897 dnl             should be extended to support other fetch URL APIs
1898 dnl
1899 ol_link_fetch=no
1900 if test $ol_with_fetch != no ; then
1901         OL_LIB_FETCH
1902
1903         if test $ol_cv_lib_fetch != no ; then
1904                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1905                 ol_link_fetch=freebsd
1906
1907         elif test $ol_with_fetch != auto ; then
1908                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1909         fi
1910 fi
1911
1912 dnl ----------------------------------------------------------------
1913 dnl
1914 dnl Check for GNU readline
1915 dnl
1916 ol_link_readline=no
1917 if test $ol_with_readline != no ; then
1918         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1919
1920         if test $ac_cv_header_readline_readline_h = yes ; then
1921                 save_LIBS="$LIBS"
1922                 LIBS="$TERMCAP_LIBS $LIBS"
1923                 AC_CHECK_LIB(readline, readline,
1924                         [have_readline=yes], [have_readline=no])
1925                 LIBS="$save_LIBS"
1926
1927                 if test $have_readline = yes ; then
1928                         ol_with_readline=found
1929                         ol_link_readline=yes
1930
1931                         READLINE_LIBS="-lreadline"
1932                 fi
1933         fi
1934 fi
1935
1936 if test $ol_link_readline = yes ; then
1937         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1938 fi
1939
1940
1941 dnl ----------------------------------------------------------------
1942 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1943 if test $ol_enable_crypt != no ; then
1944         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1945                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1946                         have_crypt=yes], [have_crypt=no])])
1947
1948         if test $have_crypt = yes ; then
1949                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1950         else
1951                 AC_MSG_WARN(could not find crypt)
1952                 if test $ol_enable_crypt = yes ; then
1953                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1954                 fi
1955
1956                 AC_MSG_WARN(disabling crypt support)
1957                 ol_enable_crypt=no
1958         fi
1959 fi
1960
1961 dnl ----------------------------------------------------------------
1962 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1963 if test $ol_enable_proctitle != no ; then
1964         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1965                 AC_CHECK_LIB(util, setproctitle,
1966                         [have_setproctitle=yes
1967                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1968                         [have_setproctitle=no
1969                         LIBOBJS="$LIBOBJS setproctitle.o"
1970                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1971
1972         if test $have_setproctitle = yes ; then
1973                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1974                         [define if setproctitle(3) is available])
1975         fi
1976 fi
1977
1978 dnl ----------------------------------------------------------------
1979 dnl Checks for typedefs, structures, and compiler characteristics.
1980 AC_TYPE_MODE_T
1981 AC_TYPE_OFF_T
1982 AC_TYPE_PID_T
1983 AM_TYPE_PTRDIFF_T
1984 AC_TYPE_SIGNAL
1985 AC_TYPE_SIZE_T
1986
1987 AC_CHECK_TYPE(ssize_t, [signed int])
1988 AC_CHECK_TYPE(caddr_t,  [char *])
1989
1990 OL_TYPE_SOCKLEN_T
1991 AC_STRUCT_ST_BLKSIZE
1992 AC_HEADER_TIME
1993 AC_STRUCT_TM
1994 AC_TYPE_UID_T
1995 OL_TYPE_SIG_ATOMIC_T
1996
1997 dnl AC_TYPE_GETGROUPS
1998
1999 OL_STRUCT_PASSWD_PW_GECOS
2000 OL_STRUCT_PASSWD_PW_PASSWD
2001
2002 OL_C_UPPER_LOWER
2003 AC_C_CONST
2004 OL_C_VOLATILE
2005
2006 if test $cross_compiling = yes ; then
2007         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2008 else
2009         AC_C_BIGENDIAN
2010 fi
2011
2012 AC_COMPILE_CHECK_SIZEOF(short)
2013 AC_COMPILE_CHECK_SIZEOF(int)
2014 AC_COMPILE_CHECK_SIZEOF(long)
2015
2016 if test "$ac_cv_sizeof_int" -lt 4 ; then
2017         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2018
2019         AC_DEFINE(LBER_INT_T,long)
2020 else
2021         AC_DEFINE(LBER_INT_T,int)
2022 fi
2023
2024 AC_DEFINE(LBER_LEN_T,long)
2025 AC_DEFINE(LBER_SOCKET_T,int)
2026 AC_DEFINE(LBER_TAG_T,long)
2027
2028 dnl ----------------------------------------------------------------
2029 dnl Checks for library functions.
2030 AC_FUNC_MEMCMP
2031 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
2032 AC_FUNC_STRFTIME
2033 dnl AM_FUNC_STRTOD
2034
2035 OL_FUNC_INET_ATON
2036
2037 dnl Check for NT specific routines
2038 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2039
2040 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2041         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2042 ])
2043
2044 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2045         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2046 ])
2047
2048 AC_FUNC_VPRINTF
2049
2050 if test $ac_cv_func_vprintf = yes ; then
2051         dnl check for vsnprintf
2052         AC_CHECK_FUNCS(vsnprintf vsprintf)
2053 fi
2054
2055 AC_CHECK_FUNCS(         \
2056         bcopy                   \
2057         closesocket             \
2058         chroot                  \
2059         endgrent                \
2060         endpwent                \
2061         flock                   \
2062         getdtablesize   \
2063         getgrgid                \
2064         gethostname             \
2065         getpass                 \
2066         getpassphrase   \
2067         getpwuid                \
2068         getpwnam                \
2069         getspnam                \
2070         gettimeofday    \
2071         initgroups              \
2072         lockf                   \
2073         memcpy                  \
2074         memmove                 \
2075         mkstemp                 \
2076         pipe                    \
2077         read                    \
2078         recv                    \
2079         recvfrom                \
2080         setpwfile               \
2081         setgid                  \
2082         setegid                 \
2083         setsid                  \
2084         setuid                  \
2085         seteuid                 \
2086         sigaction               \
2087         signal                  \
2088         sigset                  \
2089         snprintf                \
2090         strdup                  \
2091         strerror                \
2092         strpbrk                 \
2093         strrchr                 \
2094         strsep                  \
2095         strstr                  \
2096         strtol                  \
2097         strtoul                 \
2098         strspn                  \
2099         sysconf                 \
2100         waitpid                 \
2101         wait4                   \
2102         write                   \
2103         send                    \
2104         sendto                  \
2105 )
2106
2107 dnl We actually may need to replace more than this.
2108 AC_REPLACE_FUNCS(getopt tempnam)
2109
2110 if test "$ac_cv_func_getopt" != yes; then
2111     LIBSRCS="$LIBSRCS getopt.c"
2112 fi
2113
2114 if test "$ac_cv_func_tempnam" != yes; then
2115     LIBSRCS="$LIBSRCS tempnam.c"
2116 fi
2117
2118 dnl ----------------------------------------------------------------
2119 # Check Configuration
2120 OL_SYS_ERRLIST
2121
2122 dnl ----------------------------------------------------------------
2123 dnl Sort out defines
2124
2125 if test "$ol_enable_debug" != no ; then
2126         AC_DEFINE(LDAP_DEBUG,1,
2127                 [define this to add debugging code])
2128 fi
2129 if test "$ol_enable_syslog" = yes ; then
2130         AC_DEFINE(LDAP_SYSLOG,1,
2131                 [define this to add syslog code])
2132 fi
2133 if test "$ol_enable_libui" = yes ; then
2134         AC_DEFINE(LDAP_LIBUI,1,
2135                 [define this for LDAP User Interface support])
2136 fi
2137 if test "$ol_enable_cache" = no ; then
2138         AC_DEFINE(LDAP_NOCACHE,1,
2139                 [define this to remove -lldap cache support])
2140 fi
2141 if test "$ol_link_kbind" != no ; then
2142         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2143 fi
2144 if test "$ol_enable_proctitle" != no ; then
2145         AC_DEFINE(LDAP_PROCTITLE,1,
2146                 [define this for LDAP process title support])
2147 fi
2148 if test "$ol_enable_referrals" != no ; then
2149         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2150 fi
2151 if test "$ol_enable_cldap" != no ; then
2152         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
2153 fi
2154 if test "$ol_enable_ldapi" != no; then
2155         AC_DEFINE(USE_PF_LOCAL,1,[define to support PF_LOCAL transport])
2156 fi
2157
2158 if test "$ol_enable_cleartext" != no ; then
2159         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2160 fi
2161 if test "$ol_enable_crypt" != no ; then
2162         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2163 fi
2164 if test "$ol_link_kpasswd" != no ; then
2165         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2166 fi
2167 if test "$ol_link_spasswd" != no ; then
2168         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2169 fi
2170 if test "$ol_enable_multimaster" != no ; then
2171         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2172 fi
2173 if test "$ol_enable_phonetic" != no ; then
2174         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2175 fi
2176 if test "$ol_enable_rlookups" != no ; then
2177         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2178 fi
2179 if test "$ol_enable_aci" != no ; then
2180         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2181 fi
2182
2183 if test "$ol_link_modules" != no ; then
2184         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2185         BUILD_SLAPD=yes
2186         SLAPD_MODULES_LDFLAGS="-dlopen self"
2187 fi
2188
2189 if test "$ol_link_bdb2" != no ; then
2190         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
2191         BUILD_SLAPD=yes
2192         BUILD_BDB2=yes
2193         if test "$ol_with_bdb2_module" != static ; then
2194                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
2195                         [define to support dynamic BDB2 backend])
2196                 BUILD_BDB2=mod
2197                 BUILD_BDB2_DYNAMIC=shared
2198                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
2199         fi
2200 fi
2201
2202 if test "$ol_enable_dnssrv" != no ; then
2203         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2204         BUILD_SLAPD=yes
2205         BUILD_DNSSRV=yes
2206         if test "$ol_with_dnssrv_module" != static ; then
2207                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2208                         [define to support dynamic DNS SRV backend])
2209                 BUILD_DNSSRV=mod
2210                 BUILD_DNSSRV_DYNAMIC=shared
2211                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2212         fi
2213 fi
2214
2215 if test "$ol_enable_ldap" != no ; then
2216         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2217         BUILD_SLAPD=yes
2218         BUILD_LDAP=yes
2219         if test "$ol_with_ldap_module" != static ; then
2220                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2221                         [define to support dynamic LDAP backend])
2222                 BUILD_LDAP=mod
2223                 BUILD_LDAP_DYNAMIC=shared
2224                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2225         fi
2226 fi
2227
2228 if test "$ol_link_ldbm" != no ; then
2229         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2230         BUILD_SLAPD=yes
2231         BUILD_LDBM=yes
2232         if test "$ol_with_ldbm_module" != static ; then
2233                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2234                         [define to support dynamic LDBM backend])
2235                 BUILD_LDBM=mod
2236                 BUILD_LDBM_DYNAMIC=shared
2237                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2238         fi
2239 fi
2240
2241 if test "$ol_enable_passwd" != no ; then
2242         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2243         BUILD_SLAPD=yes
2244         BUILD_PASSWD=yes
2245         if test "$ol_with_passwd_module" != static ; then
2246                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2247                         [define to support dynamic PASSWD backend])
2248                 BUILD_PASSWD=mod
2249                 BUILD_PASSWD_DYNAMIC=shared
2250                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2251         fi
2252 fi
2253
2254 if test "$ol_link_perl" != no ; then
2255         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2256         BUILD_SLAPD=yes
2257         BUILD_PERL=yes
2258         if test "$ol_with_perl_module" != static ; then
2259                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2260                         [define to support dynamic PERL backend])
2261                 BUILD_PERL=mod
2262                 BUILD_PERL_DYNAMIC=shared
2263                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2264         fi
2265 fi
2266
2267 if test "$ol_enable_shell" != no ; then
2268         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2269         BUILD_SLAPD=yes
2270         BUILD_SHELL=yes
2271         if test "$ol_with_shell_module" != static ; then
2272                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2273                         [define to support dynamic SHELL backend])
2274                 BUILD_SHELL=mod
2275                 BUILD_SHELL_DYNAMIC=shared
2276                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2277         fi
2278 fi
2279
2280 if test "$ol_enable_tcl" != no ; then
2281         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2282         BUILD_SLAPD=yes
2283         BUILD_TCL=yes
2284         if test "$ol_with_tcl_module" != static; then
2285                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2286                         [define to support dynamic TCL backend])
2287                 BUILD_TCL=mod
2288                 BUILD_TCL_DYNAMIC=shared
2289                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2290         fi
2291 fi
2292
2293 if test "$ol_enable_sql" != no ; then
2294         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2295         BUILD_SLAPD=yes
2296         BUILD_SQL=yes
2297         SLAPD_SQL_LIBS=-liodbc
2298         if test "$ol_with_sql_module" != static; then
2299                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2300                         [define to support dynamic SQL backend])
2301                 BUILD_SQL=mod
2302                 BUILD_SQL_DYNAMIC=shared
2303                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2304         fi
2305 fi
2306
2307 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2308         $BUILD_SLAPD = yes ; then
2309         BUILD_SLURPD=yes
2310 fi
2311
2312 dnl ----------------------------------------------------------------
2313
2314 if test "$LINK_BINS_DYNAMIC" = yes; then
2315     LIB_LINKAGE=DYN
2316     LT_LIB_LINKAGE=shared
2317 else
2318     LIB_LINKAGE=STAT
2319     LT_LIB_LINKAGE=static
2320 fi
2321
2322 if test "$ac_cv_mingw32" = yes ; then
2323     PLAT=NT
2324     DYN_EXT=dll
2325 else
2326     PLAT=UNIX
2327     DYN_EXT=so
2328 fi
2329
2330 AC_SUBST(LIBSRCS)
2331
2332 AC_SUBST(PLAT)
2333 AC_SUBST(LIB_LINKAGE)
2334 AC_SUBST(LT_LIB_LINKAGE)
2335 AC_SUBST(DYN_EXT)
2336
2337 AC_SUBST(BUILD_SLAPD)
2338   AC_SUBST(BUILD_BDB2)
2339   AC_SUBST(BUILD_DNSSRV)
2340   AC_SUBST(BUILD_LDAP)
2341   AC_SUBST(BUILD_LDBM)
2342   AC_SUBST(BUILD_PASSWD)
2343   AC_SUBST(BUILD_PERL)
2344   AC_SUBST(BUILD_QUIPU)
2345   AC_SUBST(BUILD_SHELL)
2346   AC_SUBST(BUILD_SQL)
2347   AC_SUBST(BUILD_TCL)
2348   AC_SUBST(BUILD_BDB2_DYNAMIC)
2349   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2350   AC_SUBST(BUILD_LDAP_DYNAMIC)
2351   AC_SUBST(BUILD_LDBM_DYNAMIC)
2352   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2353   AC_SUBST(BUILD_PERL_DYNAMIC)
2354   AC_SUBST(BUILD_SHELL_DYNAMIC)
2355   AC_SUBST(BUILD_SQL_DYNAMIC)
2356   AC_SUBST(BUILD_TCL_DYNAMIC)
2357 AC_SUBST(BUILD_SLURPD)
2358
2359 AC_SUBST(LDAP_LIBS)
2360 AC_SUBST(LDIF_LIBS)
2361 AC_SUBST(SLAPD_LIBS)
2362 AC_SUBST(QUIPU_LIBS)
2363 AC_SUBST(SLURPD_LIBS)
2364 AC_SUBST(LDBM_LIBS)
2365 AC_SUBST(LTHREAD_LIBS)
2366 AC_SUBST(LUTIL_LIBS)
2367 AC_SUBST(WRAP_LIBS)
2368 AC_SUBST(MOD_TCL_LIB)
2369 AC_SUBST(LINK_BINS_DYNAMIC)
2370
2371 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2372 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2373 AC_SUBST(SLAPD_MODULES_LIST)
2374
2375 AC_SUBST(PERL_CPPFLAGS)
2376 AC_SUBST(SLAPD_PERL_LDFLAGS)
2377 AC_SUBST(MOD_PERL_LDFLAGS)
2378
2379 AC_SUBST(KRB4_LIBS)
2380 AC_SUBST(KRB5_LIBS)
2381 AC_SUBST(READLINE_LIBS)
2382 AC_SUBST(SASL_LIBS)
2383 AC_SUBST(TERMCAP_LIBS)
2384 AC_SUBST(TLS_LIBS)
2385 AC_SUBST(MODULES_LIBS)
2386 AC_SUBST(AUTH_LIBS)
2387
2388 AC_SUBST(SLAPD_SQL_LDFLAGS)
2389 AC_SUBST(SLAPD_SQL_LIBS)
2390 AC_SUBST(SLAPD_SQL_INCLUDES)
2391
2392 dnl ----------------------------------------------------------------
2393 dnl final output
2394 dnl
2395
2396 AC_OUTPUT( \
2397 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2398 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2399 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2400 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2401 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2402 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2403 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2404 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2405 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2406 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2407 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2408 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2409 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2410 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2411 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2412 include/Makefile:build/top.mk:include/Makefile.in \
2413 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2414 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2415 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2416 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2417 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2418 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2419 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2420 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2421 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2422 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2423 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2424 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2425 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2426 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2427 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2428 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2429 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2430 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2431 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2432 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2433 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2434 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2435 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2436 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2437 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2438 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2439 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2440 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2441 ,[
2442 date > stamp-h
2443 echo Please \"make depend\" to build dependencies
2444 ])