git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8
   9 dnl Configure.in for OpenLDAP
  10 AC_INIT(include/ldap.h)dnl
  11 AC_CONFIG_AUX_DIR(build)dnl
  12 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  13
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_PREREQ(2.10)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  43 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  44 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  54         auto, [auto k5 k4 afs yes no])
  55 OL_ARG_WITH(threads,[  --with-threads   use threads],
  56         auto, [auto posix mach lwp yes no manual] )
  57 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  58         auto, [auto yes no manual] )
  59
  60 dnl Server options
  61
  62 dnl LDAPD OPTIONS
  63 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  64 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  65
  66 dnl SLAPD OPTIONS
  67 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  68 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  69 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  70 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  71 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  72 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  73 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  74 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  75
  76 dnl SLAPD Backend options
  77 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  78 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  79         [auto db2 db gdbm ndbm manual])
  80 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  81         [auto btree hash])
  82
  83 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  84 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  85
  86 dnl SLURPD OPTIONS
  87 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  88 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  89
  90 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  91 AM_ENABLE_STATIC
  92 dnl AM_DISABLE_SHARED
  93 AM_ENABLE_SHARED
  94
  95 dnl General "enable" options
  96 # validate options
  97 if test $ol_enable_referrals = no ; then
  98         if test $ol_enable_dns = yes ; then
  99                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
 100         fi
 101         ol_enable_dns=no
 102 fi
 103
 104 if test $ol_enable_slapd = no ; then
 105         dnl SLAPD was specificallly disabled
 106         if test $ol_enable_ldbm = yes ; then
 107                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 108         fi
 109         if test $ol_enable_passwd = yes ; then
 110                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 111         fi
 112         if test $ol_enable_shell = yes ; then
 113                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 114         fi
 115         if test $ol_enable_aclgroups = yes ; then
 116                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 117         fi
 118         if test $ol_enable_wrappers = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 120         fi
 121         if test $ol_enable_phonetic = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 123         fi
 124         if test $ol_enable_rlookups = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 126         fi
 127         if test $ol_with_ldbm_api != auto ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 129         fi
 130         if test $ol_with_ldbm_type != auto ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 132         fi
 133         if test $ol_enable_slurpd = yes ; then
 134                 AC_MSG_ERROR([slurpd requires slapd])
 135         fi
 136
 137         # force settings to no
 138         ol_enable_ldbm=no
 139         ol_enable_shell=no
 140         ol_enable_passwd=no
 141         ol_enable_aclgroups=no
 142         ol_enable_wrappers=no
 143         ol_enable_phonetic=no
 144         ol_enable_rlookups=no
 145         ol_with_ldbm_api=no
 146         ol_with_ldbm_type=no
 147         ol_enable_slurpd=no
 148
 149 elif test $ol_enable_ldbm = no ; then
 150         dnl SLAPD without LDBM
 151
 152         if test $ol_with_ldbm_api != auto ; then
 153                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 154         fi
 155
 156         if test $ol_with_ldbm_type != auto ; then
 157                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 158         fi
 159
 160         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 161                 AC_MSG_ERROR([slapd requires a backend])
 162         fi
 163
 164         ol_with_ldbm_api=no
 165         ol_with_ldbm_type=no
 166
 167 else
 168         dnl SLAPD with LDBM
 169
 170         if test $ol_with_ldbm_api = gdbm -a \
 171                 $ol_with_ldbm_type = btree ; then
 172                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 173         fi
 174         if test $ol_with_ldbm_api = ndbm -a \
 175                 $ol_with_ldbm_type = btree ; then
 176                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 177         fi
 178 fi
 179
 180 if test $ol_enable_slurpd = yes ; then
 181         dnl SLURPD was specifically enabled
 182         if test $ol_with_threads = no ; then
 183                 AC_MSG_ERROR([slurpd requires threads])
 184         fi
 185 fi
 186
 187 AC_MSG_RESULT(done)
 188
 189 AC_CANONICAL_HOST
 190
 191 ## Initialize vars
 192 LDAP_LIBS=
 193 LDBM_LIBS=
 194 LTHREAD_LIBS=
 195 LUTIL_LIBS=
 196
 197 LDAPD_LIBS=
 198 SLAPD_LIBS=
 199 SLURPD_LIBS=
 200
 201 BUILD_LDAPD=no
 202 BUILD_SLAPD=no
 203 BUILD_SLURPD=no
 204
 205 BUILD_LDBM=no
 206 BUILD_PASSWD=no
 207 BUILD_SHELL=no
 208 BUILD_THREAD=no
 209
 210 KRB_LIBS=
 211 TERMCAP_LIBS=
 212
 213 dnl ----------------------------------------------------------------
 214 dnl Checks for programs
 215
 216 AC_PROG_INSTALL
 217 AM_PROG_LIBTOOL
 218 dnl AC_PROG_MAKE_SET
 219
 220 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 221         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 222 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 223 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 224
 225 dnl Checks the compiler and UNIX Variants
 226
 227 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 228         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 229
 230 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 231         AC_MSG_WARN([programs compiled here do run here...])
 232         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 233
 234 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 235         AC_MSG_WARN([programs compiled here do not run here...])
 236         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 237 fi
 238
 239 AC_PROG_CPP
 240
 241 AC_AIX
 242 AC_ISC_POSIX
 243 AC_MINIX
 244
 245 dnl OpenLDAP requires STDC features
 246 AM_PROG_CC_STDC
 247 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 248         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 249 fi
 250
 251 dnl AM_C_PROTOTYPES
 252
 253 dnl Checks for libraries
 254
 255 dnl Find socket()
 256 dnl Likely combinations:
 257 dnl             -lsocket [ -lnsl_s | -lnsl ]
 258 dnl             -linet
 259
 260 AC_CHECK_FUNC(socket, [have_socket=yes], [
 261 dnl
 262 dnl hopefully we won't include too many libraries
 263 dnl
 264         AC_CHECK_LIB(socket, main)
 265         AC_CHECK_LIB(net, main)
 266         AC_CHECK_LIB(nsl_s, main)
 267         AC_CHECK_LIB(nsl, main)
 268         AC_CHECK_LIB(inet, socket)
 269         AC_CHECK_LIB(gen, main)
 270 ])
 271
 272 dnl Check for resolv
 273 AC_CHECK_LIB(resolv, res_search)
 274
 275 dnl HP-UX requires -lV3
 276 AC_CHECK_LIB(V3, sigset)
 277
 278 # ISODE tests
 279 ol_link_isode=no
 280 if test $ol_enable_ldapd != no ; then
 281         dnl look for ISODE libraries
 282         AC_CHECK_LIB(xtpp, main, [
 283                 ol_link_isode=yes
 284                 AC_DEFINE(HAVE_XTPP,1)
 285                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 286                 ],:,[-lxtdsap -lxtisode -losi])
 287         AC_CHECK_LIB(dsap, main, [
 288                 ol_link_isode=yes
 289                 AC_DEFINE(HAVE_DSAP,1)
 290                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 291                 ],:,[-lisode])
 292         AC_CHECK_LIB(isode, main, [
 293                 ol_link_isode=yes
 294                 AC_DEFINE(HAVE_ISODE,1)
 295                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 296                 ],:)
 297 fi
 298
 299 if test $ol_link_isode != no; then
 300         AC_CHECK_LIB(pp, main, [
 301                 AC_DEFINE(HAVE_PP,1)
 302                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 303                 ],:)
 304
 305         AC_PATH_PROG(PEPSY, pepsy)
 306 fi
 307
 308 dnl
 309 dnl check for kerberos
 310 dnl
 311 ol_link_kerberos=no
 312
 313 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 314         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 315
 316         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 317                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 318                         [-lkrb5 -ldes425])
 319
 320                 if test $have_k5 = yes ; then
 321                         ol_with_kerberos=found
 322                         ol_link_kerberos=yes
 323
 324                         AC_DEFINE(HAVE_KERBEROS)
 325                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 326                 fi
 327         fi
 328 fi
 329
 330 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 331         AC_CHECK_HEADERS(krb.h des.h)
 332
 333         if test $ac_cv_header_krb_h = yes ; then
 334                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 335
 336                 if test $have_k4 = yes ; then
 337                         ol_with_kerberos=found
 338                         ol_link_kerberos=yes
 339
 340                         AC_DEFINE(HAVE_KERBEROS)
 341                         KRB_LIBS="-lkrb -ldes"
 342                 fi
 343         fi
 344 fi
 345
 346 if test $ol_link_kerberos = yes ; then
 347         save_LIBS=$LIBS
 348         $LIBS="$KRB_LIBS $LIBS"
 349         AC_CHECK_FUNCS(des_string_to_key)
 350         LIBS=$save_LIBS
 351 fi
 352
 353 ol_link_threads=no
 354 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 355         -o $ol_with_threads = posix ; then
 356
 357         AC_CHECK_HEADERS(pthread.h sched.h)
 358
 359         if test $ac_cv_header_pthread_h = yes ; then
 360                 OL_POSIX_THREAD_VERSION
 361
 362                 if test $ol_cv_pthread_version = final ; then
 363                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 364                 elif test $ol_cv_pthread_version = draft4 ; then
 365                         AC_DEFINE(HAVE_PTHREADS_D4)
 366                 else
 367                         AC_MSG_ERROR([unknown pthread version])
 368                 fi
 369
 370                 # consider threads found
 371                 ol_with_threads=found
 372
 373                 OL_LINUX_THREADS
 374
 375                 if test $ol_cv_linux_threads = yes ; then
 376                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 377                 fi
 378
 379                 dnl Now the hard part, how to link
 380
 381                 dnl Check for pthread support in current $LIBS
 382                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 383
 384                 if test $ol_link_threads = no ; then
 385                         dnl try -pthread
 386                         AC_CACHE_CHECK([for pthread_create with -pthread],
 387                                 [ol_cv_pthread_flag], [
 388                                 dnl save the flags
 389                                 save_LIBS="$LIBS"
 390                                 LIBS="-pthread $LIBS"
 391                                 AC_TRY_LINK([char pthread();],[
 392                                         pthread_create();
 393                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 394                                 dnl restore the LIBS
 395                                 LIBS="$save_LIBS"
 396                         ])
 397
 398                         if test $ol_cv_pthread_flag = yes ; then
 399                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 400                                 ol_link_threads=posix
 401                         fi
 402                 fi
 403
 404                 if test $ol_link_threads = no ; then
 405                         dnl try -pthreads
 406                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 407                                 [ol_cv_pthreads_flag], [
 408                                 dnl save the flags
 409                                 save_LIBS="$LIBS"
 410                                 LIBS="-pthreads $LIBS"
 411                                 AC_TRY_LINK([char pthread();],[
 412                                         pthread_create();
 413                                         ], ol_cv_pthreads_flag=yes, ol_cv_pthreads_flag=no)
 414                                 dnl restore the LIBS
 415                                 LIBS="$save_LIBS"
 416                         ])
 417
 418                         if test $ol_cv_pthreads_flag = yes ; then
 419                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 420                                 ol_link_threads=posix
 421                         fi
 422                 fi
 423
 424                 if test $ol_link_threads = no ; then
 425                         dnl try -thread
 426                         AC_CACHE_CHECK([for pthread_create with -thread],
 427                                 [ol_cv_thread_flag], [
 428                                 dnl save the flags
 429                                 save_LIBS="$LIBS"
 430                                 LIBS="-thread $LIBS"
 431                                 AC_TRY_LINK([char pthread();],[
 432                                         pthread_create();
 433                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 434                                 dnl restore the LIBS
 435                                 LIBS="$save_LIBS"
 436                         ])
 437
 438                         if test $ol_cv_thread_flag = yes ; then
 439                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 440                                 ol_link_threads=posix
 441                         fi
 442                 fi
 443
 444                 if test $ol_link_threads = no ; then
 445                         dnl try DEC Threads -lpthread -lexc
 446                         save_LIBS="$LIBS"
 447                         AC_CHECK_LIB(pthread, pthread_join, [
 448                                 ol_link_threads=posix
 449                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 450                                 if test $ol_with_yielding_select = auto ; then
 451                                         ol_with_yielding_select=yes
 452                                 fi
 453                                 ],,[-lexc])
 454                         LIBS="$save_LIBS"
 455                 fi
 456
 457                 if test $ol_link_threads = no ; then
 458                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 459                         save_LIBS="$LIBS"
 460                         AC_CHECK_LIB(pthreads, pthread_join, [
 461                                 ol_link_threads=posix
 462                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 463                                 if test $ol_with_yielding_select = auto ; then
 464                                         ol_with_yielding_select=yes
 465                                 fi
 466                                 ],,[-lmach -lexc -lc_r])
 467                         LIBS="$save_LIBS"
 468                 fi
 469
 470                 if test $ol_link_threads = no ; then
 471                         dnl try -lpthread
 472                         save_LIBS="$LIBS"
 473                         AC_CHECK_LIB(pthread, pthread_create, [
 474                                 ol_link_threads=posix
 475                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 476                         LIBS="$save_LIBS"
 477                 fi
 478
 479                 if test $ol_link_threads = no ; then
 480                         dnl try -lc_r
 481                         save_LIBS="$LIBS"
 482                         AC_CHECK_LIB(c_r, pthread_create, [
 483                                 ol_link_threads=posix
 484                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 485                         LIBS="$save_LIBS"
 486                 fi
 487
 488                 if test $ol_link_threads != no ; then
 489                         AC_DEFINE(HAVE_PTHREADS)
 490
 491                         dnl save flags
 492                         save_CPPFLAGS="$CPPFLAGS"
 493                         save_LIBS="$LIBS"
 494                         LIBS="$LTHREAD_LIBS $LIBS"
 495
 496                         dnl All POSIX Thread (final) implementations should have
 497                         dnl sched_yield instead of pthread yield.
 498                         dnl check for both
 499                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 500
 501                         if test $ac_cv_func_sched_yield = no -a \
 502                                 $ac_cv_func_pthread_yield = no ; then
 503                                 dnl Digital UNIX has sched_yield() in -lrt
 504                                 AC_CHECK_LIB(rt, sched_yield,
 505                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 506                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 507                                         ac_cv_func_sched_yield=yes],
 508                                         [ac_cv_func_sched_yield=no])
 509                         fi
 510                         if test $ac_cv_func_sched_yield = no -a \
 511                                 $ac_cv_func_pthread_yield = no ; then
 512                                 dnl Solaris has sched_yield() in -lposix4
 513                                 AC_CHECK_LIB(posix4, sched_yield,
 514                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 515                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 516                                         ac_cv_func_sched_yield=yes],
 517                                         [ac_cv_func_sched_yield=no])
 518                         fi
 519                         if test $ac_cv_func_sched_yield = no -a \
 520                                 $ac_cv_func_pthread_yield = no ; then
 521                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 522                                 AC_MSG_ERROR([POSIX Threads are not usable])
 523                         fi
 524
 525                         dnl Check functions for compatibility
 526                         AC_CHECK_FUNCS(pthread_kill)
 527                         AC_CHECK_FUNCS( \
 528                                 pthread_attr_create pthread_attr_init \
 529                                 pthread_attr_destroy pthread_attr_delete \
 530                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 531                         )
 532
 533                         dnl Check for setconcurreny functions
 534                         AC_CHECK_FUNCS( \
 535                                 pthread_setconcurrency \
 536                                 thr_setconcurrency \
 537                         )
 538
 539                         AC_MSG_CHECKING([if pthread_create() works])
 540                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 541                         AC_TRY_RUN([
 542 #include <pthread.h>
 543 #ifndef NULL
 544 #define NULL (void*)0
 545 #endif
 546
 547 static void *task(p)
 548         void *p;
 549 {
 550         return (void *) (p == NULL);
 551 }
 552
 553 int main(argc, argv)
 554         int argc;
 555         char **argv;
 556 {
 557         pthread_t t;
 558         exit(pthread_create(&t, NULL, task, NULL));
 559 }
 560 ],
 561                                 [ol_cv_pthread_create_works=yes],
 562                                 [ol_cv_pthread_create_works=no],
 563                                 [dnl assume yes
 564                                 ol_cv_pthread_create_works=yes])])
 565                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 566
 567                         if test $ol_cv_pthread_create_works = no ; then
 568                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 569                         fi
 570
 571                         dnl Check if select causes an yield
 572                         if test $ol_with_yielding_select = auto ; then
 573                                 AC_MSG_CHECKING([if select yields when using pthreads])
 574                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 575                                 AC_TRY_RUN([
 576 #include <sys/types.h>
 577 #include <sys/time.h>
 578 #include <unistd.h>
 579 #include <pthread.h>
 580 #ifndef NULL
 581 #define NULL (void*) 0
 582 #endif
 583
 584 static int fildes[2];
 585
 586 static void *task(p)
 587         void *p;
 588 {
 589         int i;
 590         struct timeval tv;
 591
 592         fd_set rfds;
 593
 594         tv.tv_sec=10;
 595         tv.tv_usec=0;
 596
 597         FD_ZERO(&rfds);
 598         FD_SET(fildes[0], &rfds);
 599
 600         /* we're not interested in any fds */
 601         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 602
 603         if(i < 0) {
 604                 perror("select");
 605                 exit(0);
 606         }
 607
 608         exit(1); /* if we exit here, the select blocked the whole process */
 609 }
 610
 611 int main(argc, argv)
 612         int argc;
 613         char **argv;
 614 {
 615         pthread_t t;
 616
 617         /* create a pipe to select */
 618         if(pipe(&fildes[0])) {
 619                 perror("select");
 620                 exit(0);
 621         }
 622
 623 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 624         (void) pthread_setconcurrency(2);
 625 #else
 626 #ifdef HAVE_THR_SETCONCURRENCY
 627         /* Set Solaris LWP concurrency to 2 */
 628         thr_setconcurrency(2);
 629 #endif
 630 #endif
 631
 632         pthread_create(&t, NULL, task, NULL);
 633
 634 #if HAVE_SCHED_YIELD
 635         sched_yield();  /* make sure task runs first */
 636 #else
 637 #ifdef HAVE_PTHREAD_YIELD
 638         pthread_yield();        /* make sure task runs first */
 639 #endif
 640 #endif
 641         exit(0);
 642 }],
 643                                 [ol_cv_pthread_select_yields=yes],
 644                                 [ol_cv_pthread_select_yields=no], [
 645                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 646                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 647
 648                                 if test $ol_cv_pthread_select_yields = yes ; then
 649                                         ol_with_yielding_select=yes
 650                                 fi
 651                         fi
 652
 653                         dnl check for reentrant/threadsafe functions
 654                         dnl
 655                         dnl note: these should only be used when linking
 656                         dnl       with $LTHREAD_LIBS
 657                         dnl
 658                         AC_CHECK_FUNCS( \
 659                                 strtok_r \
 660                                 gmtime_r \
 661                                 gethostbyaddr_r gethostbyname_r \
 662                                 feof_unlocked unlocked_feof \
 663                                 putc_unlocked unlocked_putc \
 664                                 flockfile ftrylockfile \
 665                         )
 666
 667                         dnl restore flags
 668                         CPPFLAGS="$save_CPPFLAGS"
 669                         LIBS="$save_LIBS"
 670                 else
 671                         AC_MSG_ERROR([could not link with POSIX Threads])
 672                 fi
 673         fi
 674
 675         if test $ol_with_threads = posix ; then
 676                 AC_MSG_ERROR([could not locate POSIX Threads])
 677         fi
 678 fi
 679
 680 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 681         -o $ol_with_threads = mach ; then
 682
 683         dnl check for Mach CThreads
 684         AC_CHECK_HEADERS(mach/cthreads.h)
 685         if test $ac_cv_header_mach_cthreads_h = yes ; then
 686                 ol_with_threads=found
 687
 688                 dnl check for cthread support in current $LIBS
 689                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 690
 691                 if test $ol_link_threads = no ; then
 692                         dnl try -all_load
 693                         dnl this test needs work
 694                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 695                                 [ol_cv_cthread_all_load], [
 696                                 dnl save the flags
 697                                 save_LIBS="$LIBS"
 698                                 LIBS="-all_load $LIBS"
 699                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 700                                         cthread_fork((void *)0, (void *)0);
 701                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 702                                 dnl restore the LIBS
 703                                 LIBS="$save_LIBS"
 704                         ])
 705
 706                         if test $ol_cv_cthread_all_load = yes ; then
 707                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 708                                 ol_link_threads=mach
 709                         fi
 710                 fi
 711
 712                 if test $ol_link_threads != no ; then
 713                         : check for cthread specific functionality here
 714                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 715                 else
 716                         AC_MSG_ERROR([could not link with Mach CThreads])
 717                 fi
 718         fi
 719
 720         if test $ol_with_threads = mach ; then
 721                 AC_MSG_ERROR([could not locate Mach CThreads])
 722         fi
 723 fi
 724
 725 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 726         -o $ol_with_threads = lwp ; then
 727
 728         dnl check for SunOS5 LWP
 729         AC_CHECK_HEADERS(thread.h synch.h)
 730         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 731                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 732
 733                 if test $have_thr = yes ; then
 734                         AC_DEFINE(HAVE_THR)
 735                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 736                         ol_link_threads=thr
 737
 738                         if test $ol_with_yielding_select = auto ; then
 739                                 ol_with_yielding_select=yes
 740                         fi
 741                 fi
 742         fi
 743
 744         dnl check for SunOS4 LWP
 745         AC_CHECK_HEADERS(lwp/lwp.h)
 746         if test $ac_cv_header_lwp_lwp_h = yes ; then
 747                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 748
 749                 if test $have_lwp = yes ; then
 750                         AC_DEFINE(HAVE_LWP)
 751                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 752                         ol_link_threads=lwp
 753
 754                         if test $ol_with_yielding_select = auto ; then
 755                                 ol_with_yielding_select=no
 756                         fi
 757                 fi
 758         fi
 759 fi
 760
 761 if test $ol_with_yielding_select = yes ; then
 762         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 763 fi
 764
 765 if test $ol_with_threads = manual ; then
 766         dnl User thinks he can manually configure threads.
 767         ol_link_threads=yes
 768
 769         AC_MSG_WARN([thread defines and link options must be set manually])
 770
 771         AC_CHECK_HEADERS(pthread.h sched.h)
 772         AC_CHECK_FUNCS(sched_yield pthread_yield)
 773         OL_LINUX_THREADS
 774
 775         AC_CHECK_HEADERS(mach/cthreads.h)
 776         AC_CHECK_HEADERS(lwp/lwp.h)
 777         AC_CHECK_HEADERS(thread.h synch.h)
 778 fi
 779
 780 if test $ol_link_threads != no ; then
 781         dnl needed to get reentrant/threadsafe versions
 782         dnl
 783         AC_DEFINE(REENTRANT,1)
 784         AC_DEFINE(_REENTRANT,1)
 785         AC_DEFINE(THREAD_SAFE,1)
 786         AC_DEFINE(_THREAD_SAFE,1)
 787         AC_DEFINE(THREADSAFE,1)
 788         AC_DEFINE(_THREADSAFE,1)
 789
 790         dnl this might cause the errno symbol to be
 791         dnl replaced with a function to get a thread specific errno.
 792         dnl check to see if everything needs to be compiled
 793         dnl with the thread libraries
 794         AC_CACHE_CHECK([for thread specific errno],
 795                 [ol_cv_errno_thread_specific], [
 796                 AC_TRY_LINK([
 797 #include <errno.h>
 798                         ], [
 799 int x = errno;
 800                         ],
 801                         [ol_cv_errno_thread_specific=yes],
 802                         [ol_cv_errno_thread_specific=no])
 803         ])
 804
 805         if test $ol_cv_errno_thread_specific != yes ; then
 806                 LIBS="$LTHREAD_LIBS $LIBS"
 807                 LTHREAD_LIBS=""
 808         fi
 809 fi
 810
 811 dnl ----------------------------------------------------------------
 812
 813 if test $ol_link_threads = no ; then
 814         if test $ol_with_threads = yes ; then
 815                 AC_MSG_ERROR([no suitable thread support])
 816         fi
 817
 818         if test $ol_with_threads = auto ; then
 819                 AC_MSG_WARN([no suitable thread support, disabling threads])
 820                 ol_with_threads=no
 821         fi
 822
 823         AC_DEFINE(NO_THREADS,1)
 824         LTHREAD_LIBS=""
 825 fi
 826
 827 ol_link_ldbm=no
 828 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 829         OL_BERKELEY_DB2
 830
 831         if test $ol_cv_berkeley_db2 = yes ; then
 832                 ol_link_ldbm=db2
 833                 ol_with_ldbm_api=db2
 834
 835                 if test $ol_with_ldbm_type = hash ; then
 836                         AC_DEFINE(LDBM_USE_DBHASH,1)
 837                 else
 838                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 839                 fi
 840
 841                 dnl $ol_cv_lib_db2 should be yes or -ldb
 842                 dnl (it could be no, but that would be an error
 843                 if test $ol_cv_lib_db2 != yes ; then
 844                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 845                 fi
 846         fi
 847 fi
 848
 849 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 850         OL_BERKELEY_DB
 851
 852         if test $ol_cv_berkeley_db = yes ; then
 853                 ol_link_ldbm=db
 854                 ol_with_ldbm_api=db
 855
 856                 if test $ol_with_ldbm_type = hash ; then
 857                         AC_DEFINE(LDBM_USE_DBHASH,1)
 858                 else
 859                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 860                 fi
 861
 862                 dnl $ol_cv_lib_db should be yes or -ldb
 863                 dnl (it could be no, but that would be an error
 864                 if test $ol_cv_lib_db != yes ; then
 865                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 866                 fi
 867         fi
 868 fi
 869
 870 if test $ol_with_ldbm_api = manual ; then
 871         dnl User thinks he can manually configure LDBM api.
 872         ol_link_ldbm=yes
 873
 874         AC_MSG_WARN([LDBM defines and link options must be set manually])
 875
 876         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 877 fi
 878
 879 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 880         AC_MSG_WARN(Could not find LDBM with BTREE support)
 881         ol_with_ldbm_api=none
 882 fi
 883
 884 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 885         OL_GDBM
 886
 887         if test $ol_cv_gdbm = yes ; then
 888                 ol_link_ldbm=gdbm
 889                 ol_with_ldbm_api=gdbm
 890
 891                 if test $ol_cv_lib_gdbm != yes ; then
 892                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 893                 fi
 894         fi
 895 fi
 896
 897 if test $ol_with_ldbm_api = auto ; then
 898         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
 899 elif test $ol_with_ldbm_api = ndbm ; then
 900         OL_NDBM
 901
 902         if test $ol_cv_ndbm = yes ; then
 903                 ol_link_ldbm=ndbm
 904                 ol_with_ldbm_api=ndbm
 905
 906                 if test $ol_cv_lib_ndbm != yes ; then
 907                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 908                 fi
 909         fi
 910 fi
 911
 912 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 913         AC_MSG_WARN(could not find suitable LDBM backend)
 914         if test $ol_enable_ldbm = yes ; then
 915                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 916         fi
 917
 918         AC_MSG_WARN(disabling LDBM)
 919         ol_enable_ldbm=no
 920 fi
 921
 922 if test $ol_enable_wrappers = yes ; then
 923         AC_CHECK_LIB(wrap, hosts_access,
 924                 [have_wrappers=yes], [have_wrappers=no])
 925
 926         if test $have_wrappers = yes ; then
 927                 AC_DEFINE(HAVE_TCPD)
 928                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 929         else
 930                 AC_MSG_WARN(could not find -lwrap)
 931                 if test $ol_enable_wrappers = yes ; then
 932                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 933                 fi
 934
 935                 AC_MSG_WARN(disabling wrappers support)
 936                 ol_enable_wrappers=no
 937         fi
 938
 939 fi
 940
 941 # ud needs termcap (should insert check here)
 942 ol_link_termcap=no
 943 AC_CHECK_HEADERS(termcap.h ncurses.h)
 944
 945 if test $ol_link_termcap = no ; then
 946         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 947         if test $have_termcap = yes ; then
 948                 AC_DEFINE(HAVE_TERMCAP)
 949                 ol_link_termcap=yes
 950                 TERMCAP_LIBS=-ltermcap
 951         fi
 952 fi
 953
 954 if test $ol_link_termcap = no ; then
 955         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 956         if test $have_ncurses = yes ; then
 957                 AC_DEFINE(HAVE_NCURSES)
 958                 ol_link_termcap=yes
 959                 TERMCAP_LIBS=-lncurses
 960         fi
 961 fi
 962
 963 if test $ol_link_termcap = no ; then
 964         AC_DEFINE(NO_TERMCAP,1)
 965         TERMCAP_LIBS=
 966 fi
 967
 968 # FreeBSD (and others) have crypt(3) in -lcrypt
 969 if test $ol_enable_crypt != no ; then
 970         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 971                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 972                         have_crypt=yes], [have_crypt=no])])
 973
 974         if test $have_crypt = yes ; then
 975                 AC_DEFINE(HAVE_CRYPT,1)
 976         else
 977                 AC_MSG_WARN(could not find crypt)
 978                 if test $ol_enable_crypt = yes ; then
 979                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 980                 fi
 981
 982                 AC_MSG_WARN(disabling crypt support)
 983                 ol_enable_crypt=no
 984         fi
 985 fi
 986
 987 # FreeBSD (and others) have setproctitle(3) in -lutil
 988 if test $ol_enable_proctitle != no ; then
 989         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 990                 AC_CHECK_LIB(util, setproctitle,
 991                         [have_setproctitle=yes
 992                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 993                         [have_setproctitle=no
 994                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 995
 996         if test $have_setproctitle = yes ; then
 997                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 998         fi
 999 fi
1000
1001 dnl ----------------------------------------------------------------
1002 dnl Checks for header files.
1003 AC_HEADER_STDC
1004
1005 if test $ac_cv_header_stdc != yes; then
1006         AC_MSG_WARN([could not Standard C compliant headers])
1007 fi
1008
1009 AC_HEADER_DIRENT
1010 AC_HEADER_SYS_WAIT
1011 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1012 if test $am_cv_sys_posix_termios = yes ; then
1013         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
1014 fi
1015
1016 AC_CHECK_HEADERS(       \
1017         crypt.h                 \
1018         errno.h                 \
1019         fcntl.h                 \
1020         filio.h                 \
1021         getopt.h                \
1022         libutil.h               \
1023         limits.h                \
1024         malloc.h                \
1025         memory.h                \
1026         regex.h                 \
1027         psap.h                  \
1028         pwd.h                   \
1029         sgtty.h                 \
1030         stdarg.h                \
1031         stddef.h                \
1032         string.h                \
1033         strings.h               \
1034         sys/file.h              \
1035         sys/filio.h             \
1036         sys/errno.h             \
1037         sys/ioctl.h             \
1038         sys/param.h             \
1039         sys/resource.h  \
1040         sys/socket.h    \
1041         sys/syslog.h    \
1042         sys/time.h              \
1043         sys/types.h             \
1044         syslog.h                \
1045         termios.h               \
1046         unistd.h                \
1047 )
1048
1049 dnl ----------------------------------------------------------------
1050 dnl Checks for typedefs, structures, and compiler characteristics.
1051 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1052 AC_TYPE_MODE_T
1053 AC_TYPE_OFF_T
1054 AC_TYPE_PID_T
1055 AM_TYPE_PTRDIFF_T
1056 AC_TYPE_SIGNAL
1057 AC_TYPE_SIZE_T
1058 AC_STRUCT_ST_BLKSIZE
1059 AC_HEADER_TIME
1060 AC_STRUCT_TM
1061
1062 OL_C_UPPER_LOWER
1063 AC_C_CONST
1064
1065 if test $cross_compiling = yes ; then
1066         AC_DEFINE(CROSS_COMPILING, 1)
1067 else
1068         AC_C_BIGENDIAN
1069         AC_CHECK_SIZEOF(short)
1070         AC_CHECK_SIZEOF(int)
1071         AC_CHECK_SIZEOF(long)
1072 fi
1073
1074 dnl ----------------------------------------------------------------
1075 dnl Checks for library functions.
1076 AC_FUNC_MEMCMP
1077 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1078 AC_FUNC_STRFTIME
1079 dnl AM_FUNC_STRTOD
1080 AC_FUNC_VPRINTF
1081
1082 if test $ac_cv_func_vprintf = yes ; then
1083         dnl check for vsnprintf
1084         AC_CHECK_FUNCS(vsnprintf)
1085 fi
1086
1087 AC_FUNC_WAIT3
1088
1089 AC_CHECK_FUNCS(         \
1090         bcopy                   \
1091         flock                   \
1092         getdtablesize   \
1093         gethostname             \
1094         getpwuid                \
1095         gettimeofday    \
1096         lockf                   \
1097         memcpy                  \
1098         memmove                 \
1099         mkstemp                 \
1100         res_search              \
1101         select                  \
1102         setpwfile               \
1103         setsid                  \
1104         signal                  \
1105         sigset                  \
1106         snprintf                \
1107         socket                  \
1108         strerror                \
1109         strpbrk                 \
1110         strrchr                 \
1111         strsep                  \
1112         strstr                  \
1113         strtok                  \
1114         strtol                  \
1115         strtoul                 \
1116         sysconf                 \
1117         waitpid                 \
1118 )
1119
1120 dnl We actually may need to replace more than this.
1121 AC_REPLACE_FUNCS(getopt strdup tempnam)
1122
1123 dnl ----------------------------------------------------------------
1124 # Check Configuration
1125 OL_SYS_ERRLIST
1126
1127 dnl ----------------------------------------------------------------
1128 dnl Sort out defines
1129
1130 if test $ol_enable_debug != no ; then
1131         AC_DEFINE(LDAP_DEBUG,1)
1132 fi
1133 dnl     if test $ol_enable_syslog != no ; then
1134 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1135 dnl     fi
1136 if test $ol_enable_libui = yes ; then
1137         AC_DEFINE(LDAP_LIBUI,1)
1138 fi
1139 if test $ol_enable_cache = no ; then
1140         AC_DEFINE(LDAP_NOCACHE,1)
1141 fi
1142 if test $ol_enable_dns != no ; then
1143         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION,1)
1144 fi
1145 if test $ol_enable_proctitle != no ; then
1146         AC_DEFINE(LDAP_PROCTITLE,1)
1147 fi
1148 if test $ol_enable_referrals != no ; then
1149         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION,1)
1150 fi
1151 if test $ol_enable_cldap != no ; then
1152         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1153 fi
1154
1155 if test $ol_enable_aclgroups != no ; then
1156         AC_DEFINE(SLAPD_ACLGROUPS,1)
1157 fi
1158 if test $ol_enable_crypt != no ; then
1159         AC_DEFINE(SLAPD_CRYPT,1)
1160 fi
1161 if test $ol_enable_cleartext != no ; then
1162         AC_DEFINE(SLAPD_CLEARTEXT,1)
1163 fi
1164 if test $ol_enable_phonetic != no ; then
1165         AC_DEFINE(SLAPD_PHONETIC,1)
1166 fi
1167 if test $ol_enable_rlookups != no ; then
1168         AC_DEFINE(SLAPD_RLOOKUPS,1)
1169 fi
1170
1171 if test $ol_link_ldbm != no ; then
1172         AC_DEFINE(SLAPD_LDBM,1)
1173         BUILD_SLAPD=yes
1174         BUILD_LDBM=yes
1175 fi
1176
1177 if test $ol_enable_passwd != no ; then
1178         AC_DEFINE(SLAPD_PASSWD,1)
1179         BUILD_SLAPD=yes
1180         BUILD_PASSWD=yes
1181 fi
1182
1183 if test $ol_enable_shell != no ; then
1184         AC_DEFINE(SLAPD_SHELL,1)
1185         BUILD_SLAPD=yes
1186         BUILD_SHELL=yes
1187 fi
1188
1189 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1190         $BUILD_SLAPD = yes ; then
1191         BUILD_SLURPD=yes
1192 fi
1193
1194 if test $ol_link_isode != no ; then
1195         BUILD_LDAPD=yes
1196 fi
1197
1198 dnl ----------------------------------------------------------------
1199
1200 AC_SUBST(BUILD_LDAPD)
1201 AC_SUBST(BUILD_SLAPD)
1202   AC_SUBST(BUILD_LDBM)
1203   AC_SUBST(BUILD_PASSWD)
1204   AC_SUBST(BUILD_SHELL)
1205 AC_SUBST(BUILD_SLURPD)
1206
1207
1208 AC_SUBST(LDAP_LIBS)
1209 AC_SUBST(LDAPD_LIBS)
1210 AC_SUBST(SLAPD_LIBS)
1211 AC_SUBST(SLURPD_LIBS)
1212 AC_SUBST(LDBM_LIBS)
1213 AC_SUBST(LTHREAD_LIBS)
1214 AC_SUBST(LUTIL_LIBS)
1215
1216 AC_SUBST(KRB_LIBS)
1217 AC_SUBST(TERMCAP_LIBS)
1218
1219 dnl ----------------------------------------------------------------
1220 dnl final output
1221 dnl
1222
1223 AC_OUTPUT( \
1224 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1225 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1226 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1227 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1228 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1229 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1230 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1231 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1232 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1233 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1234 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1235 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1236 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1237 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1238 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1239 include/Makefile:build/top.mk:include/Makefile.in \
1240 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1241 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1242 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1243 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1244 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1245 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1246 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1247 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1248 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1249 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1250 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1251 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1252 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1253 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1254 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1255 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1256 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1257 tests/Makefile:build/top.mk:tests/Makefile.in \
1258 ,[
1259 date > stamp-h
1260 echo Please \"make depend\" to build dependencies
1261 ])