git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  28 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  29 OL_ARG_ENABLE(dns,[  --enable-dns       enable dns support], no)dnl
  30 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  31 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  32
  33 dnl General "with" options
  34 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  35         auto, [auto k5 k4 afs yes no])
  36 OL_ARG_WITH(threads,[  --with-threads   use threads],
  37         auto, [auto posix mach lwp yes no manual] )
  38 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  39         auto, [auto yes no manual] )
  40
  41 dnl Server options
  42
  43 dnl LDAPD OPTIONS
  44 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  45
  46 dnl SLAPD OPTIONS
  47 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  48 OL_ARG_ENABLE(aclgroup,[    --enable-aclgroup   enable ACL group support], auto)dnl
  49 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  50 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  51 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  52 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  53 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  54 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  55
  56 dnl SLAPD Backend options
  57 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  58 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  59         [auto db2 db gdbm ndbm manual])
  60 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  61         [auto btree hash])
  62
  63 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  64 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  65
  66 dnl SLURPD OPTIONS
  67 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  68
  69 if test $ol_enable_slapd = no ; then
  70         dnl SLAPD was specificallly disabled
  71         if test $ol_enable_ldbm = yes ; then
  72                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument]);
  73         fi
  74         if test $ol_enable_passwd = yes ; then
  75                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument]);
  76         fi
  77         if test $ol_enable_shell = yes ; then
  78                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument]);
  79         fi
  80         if test $ol_enable_aclgroup = yes ; then
  81                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroup argument]);
  82         fi
  83         if test $ol_enable_crypt = yes ; then
  84                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument]);
  85         fi
  86         if test $ol_enable_md5 = yes ; then
  87                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument]);
  88         fi
  89         if test $ol_enable_sha1 = yes ; then
  90                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument]);
  91         fi
  92         if test $ol_enable_wrappers = yes ; then
  93                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument]);
  94         fi
  95         if test $ol_enable_phonetic = yes ; then
  96                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument]);
  97         fi
  98         if test $ol_enable_rlookups = yes ; then
  99                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument]);
 100         fi
 101         if test $ol_with_ldbm_api != auto ; then
 102                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument]);
 103         fi
 104         if test $ol_with_ldbm_type != auto ; then
 105                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument]);
 106         fi
 107         if test $ol_enable_slurpd = yes ; then
 108                 AC_MSG_ERROR([slurpd requires slapd]);
 109         fi
 110
 111         # force settings to no
 112         ol_enable_ldbm=no
 113         ol_enable_shell=no
 114         ol_enable_passwd=no
 115         ol_enable_aclgroup=no
 116         ol_enable_crypt=no
 117         ol_enable_md5=no
 118         ol_enable_sha1=no
 119         ol_enable_wrappers=no
 120         ol_enable_phonetic=no
 121         ol_enable_rlookups=no
 122         ol_with_ldbm_api=no
 123         ol_with_ldbm_type=no
 124         ol_enable_slurpd=no
 125
 126 elif test $ol_enable_ldbm = no ; then
 127         dnl SLAPD without LDBM
 128
 129         if test $ol_with_ldbm_api != auto ; then
 130                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument]);
 131         fi
 132
 133         if test $ol_with_ldbm_type != auto ; then
 134                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument]);
 135         fi
 136
 137         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 138                 AC_MSG_ERROR([slapd requires a backend]);
 139         fi
 140
 141         ol_with_ldbm_api=no
 142         ol_with_ldbm_type=no
 143
 144 else
 145         dnl SLAPD with LDBM
 146
 147         if test $ol_with_ldbm_api = gdbm -a \
 148                 $ol_with_ldbm_type = btree ; then
 149                 AC_MSG_ERROR([GDBM only supports LDBM type hash]);
 150         fi
 151         if test $ol_with_ldbm_api = ndbm -a \
 152                 $ol_with_ldbm_type = btree ; then
 153                 AC_MSG_ERROR([NDBM only supports LDBM type hash]);
 154         fi
 155 fi
 156
 157 if test $ol_enable_slurpd = yes ; then
 158         dnl SLURPD was specifically enabled
 159         if test $ol_with_threads = no ; then
 160                 AC_MSG_ERROR([slurpd requires threads]);
 161         fi
 162 fi
 163
 164 AC_MSG_RESULT(done)
 165
 166 ## Initialize vars
 167 LDAP_LIBS=
 168 LDBM_LIBS=
 169 LTHREAD_LIBS=
 170 LUTIL_LIBS=
 171
 172 LDAPD_LIBS=
 173 SLAPD_LIBS=
 174 SLURPD_LIBS=
 175
 176 BUILD_LDAPD=no
 177 BUILD_SLAPD=no
 178 BUILD_SLURPD=no
 179
 180 BUILD_LDBM=no
 181 BUILD_PASSWD=no
 182 BUILD_SHELL=no
 183
 184 KRB_LIBS=
 185 TERMCAP_LIBS=
 186
 187 dnl ----------------------------------------------------------------
 188 dnl Checks for programs
 189
 190 AC_PROG_LN_S
 191 AC_PROG_INSTALL
 192 AC_PROG_RANLIB
 193 AC_PROG_MAKE_SET
 194
 195 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 196         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 197 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 198 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 199
 200 dnl Checks the compiler and UNIX Variants
 201 AC_PROG_CC
 202 AC_PROG_GCC_TRADITIONAL
 203
 204 AC_AIX
 205 AC_ISC_POSIX
 206 AC_MINIX
 207
 208 dnl ----------------------------------------------------------------
 209 dnl Checks for libraries
 210
 211 dnl Find socket()
 212 dnl Likely combinations:
 213 dnl             -lsocket [ -lnsl_s | -lnsl ]
 214 dnl             -linet
 215
 216 AC_CHECK_FUNC(socket, :, [
 217 dnl
 218 dnl hopefully we won't include too many libraries
 219 dnl
 220         AC_CHECK_LIB(socket, main)
 221         AC_CHECK_LIB(net, main)
 222         AC_CHECK_LIB(nsl_s, main)
 223         AC_CHECK_LIB(nsl, main)
 224         AC_CHECK_LIB(inet, socket)
 225         AC_CHECK_LIB(gen, main)
 226 ])
 227
 228 dnl HP-UX requires -lV3
 229 AC_CHECK_LIB(V3, sigset)
 230
 231 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 232         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 233
 234         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 235                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 236                         [-lkrb5 -ldes425])
 237
 238                 if test $have_k5 = yes ; then
 239                         ol_with_kerberos=found
 240                         ol_link_kerberos=yes
 241
 242                         AC_DEFINE(HAVE_KERBEROS)
 243
 244                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 245                 fi
 246         fi
 247 fi
 248 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 249         AC_CHECK_HEADERS(krb.h des.h)
 250
 251         if test $ac_cv_header_krb_h = yes ; then
 252                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 253
 254                 if test $have_k4 = yes ; then
 255                         ol_with_kerberos=found
 256                         ol_link_kerberos=yes
 257
 258                         AC_DEFINE(HAVE_KERBEROS)
 259
 260                         KRB_LIBS="-lkrb -ldes"
 261                 fi
 262         fi
 263 fi
 264
 265
 266 ol_link_threads=no
 267 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 268         AC_CHECK_HEADERS(pthread.h sched.h)
 269
 270         if test $ac_cv_header_pthread_h = yes ; then
 271                 OL_POSIX_THREAD_VERSION
 272
 273                 if test $ol_cv_pthread_version = final ; then
 274                         dnl AC_DEFINE(HAVE_PTHREADS_FINAL)
 275                 elif test $ol_cv_pthread_version = draft4 ; then
 276                         AC_DEFINE(HAVE_PTHREADS_D4)
 277                 else
 278                         AC_MSG_ERROR([unknown pthread version])
 279                 fi
 280
 281                 # consider threads found
 282                 ol_with_threads=found
 283
 284                 OL_LINUX_THREADS
 285
 286                 if test $ol_cv_linux_threads = yes ; then
 287                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 288                 fi
 289
 290                 dnl Now the hard part, how to link
 291
 292                 dnl A few platforms have pthread support in standard libraries
 293                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 294
 295                 if test $ol_link_threads = no ; then
 296                         dnl try -pthread
 297                         AC_CACHE_CHECK([for pthread_create with -pthread],
 298                                 [ol_cv_pthread_flag], [
 299                                 dnl save the CPPFLAGS
 300                                 save_LIBS="$LIBS"
 301                                 LIBS="-pthread $LIBS"
 302                                 AC_TRY_LINK([#include <pthread.h>],[
 303                                         pthread_create((pthread_t*) 0,
 304                                                 (pthread_attr_t*) 0, 0, 0);
 305                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 306                                 dnl restore the LIBS
 307                                 LIBS="$save_LIBS"
 308                         ])
 309
 310                         if test $ol_cv_pthread_flag = yes ; then
 311                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 312                                 ol_link_threads=posix
 313                         fi
 314                 fi
 315
 316                 if test $ol_link_threads = no ; then
 317                         dnl try -lpthread
 318                         save_LIBS="$LIBS"
 319                         AC_CHECK_LIB(pthread, pthread_create, [
 320                                 ol_link_threads=posix
 321                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 322                         LIBS="$save_LIBS"
 323                 fi
 324
 325                 if test $ol_link_threads = no ; then
 326                         dnl try -lc_r
 327                         save_LIBS="$LIBS"
 328                         AC_CHECK_LIB(c_r, pthread_create, [
 329                                 ol_link_threads=posix
 330                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 331                         LIBS="$save_LIBS"
 332                 fi
 333
 334                 if test $ol_link_threads = no ; then
 335                         dnl try DEC Threads
 336                         save_LIBS="$LIBS"
 337                         AC_CHECK_LIB(pthread, pthread_create, [
 338                                 AC_DEFINE(HAVE_DCE)
 339                                 ol_link_threads=posix
 340                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc"],,
 341                                 if test $ol_with_preemptive = auto ; then
 342                                         ol_with_preemptive=yes
 343                                 fi
 344                                 [-lmach -lexc -lc])
 345                         LIBS="$save_LIBS"
 346                 fi
 347
 348                 if test $ol_link_threads != no ; then
 349                         AC_DEFINE(HAVE_PTHREADS)
 350
 351                         dnl save DEFS/LIBS
 352                         save_CPPFLAGS="$CPPFLAGS"
 353                         save_LIBS="$LIBS"
 354                         LIBS="$LTHREAD_LIBS $LIBS"
 355
 356                         dnl All POSIX Thread (final) implementations should have
 357                         dnl sched_yield instead of pthread yield.
 358                         dnl check for both
 359                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 360
 361                         if test $ac_cv_func_sched_yield = no -a \
 362                                 $ac_cv_func_pthread_yield = no ; then
 363
 364                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 365                                 AC_MSG_ERROR([POSIX Threads are not usable])
 366                         fi
 367
 368                         dnl Check functions for compatibility
 369                         AC_CHECK_FUNCS(pthread_kill)
 370 dnl                     AC_CHECK_FUNCS(
 371 dnl                             pthread_attr_create pthread_attr_init \
 372 dnl                             pthread_attr_destroy pthread_attr_delete \
 373 dnl                             pthread_attr_setdetachstate pthread_attr_setdetach_np \
 374 dnl                     )
 375
 376                         dnl Check PREEMPTIVE Implementation
 377                         if test $ol_with_preemptive = auto ; then
 378                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 379                                 AC_TRY_RUN([
 380 #include <sys/types.h>
 381 #include <sys/time.h>
 382 #include <unistd.h>
 383 #include <pthread.h>
 384 #ifndef NULL
 385 #define NULL 0
 386 #endif
 387
 388 int task(arg)
 389         int *arg;
 390 {
 391         struct timeval tv;
 392
 393         tv.tv_sec=4;
 394         tv.tv_usec=0;
 395         select(0, NULL, NULL, NULL, &tv);
 396
 397         tv.tv_sec=6;
 398         tv.tv_usec=0;
 399         select(0, NULL, NULL, NULL, &tv);
 400
 401         exit(1); /* if we exit here, the select blocked the whole process */
 402 }
 403
 404 main(argc, argv)
 405 int argc; char **argv;
 406 {
 407         pthread_t t;
 408         pthread_create(&t, NULL, (void *) task, NULL);
 409
 410 #if HAVE_SCHED_YIELD
 411         sched_yield();  /* make sure task runs first */
 412 #else
 413 #if defined(HAVE_PTHREAD_YIELD)
 414         pthread_yield();        /* make sure task runs first */
 415 #endif
 416 #endif
 417         exit(0);
 418 }
 419                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 420                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 421                                 AC_MSG_RESULT($ol_pthread_preemptive)
 422
 423                                 if test $ol_pthread_preemptive = yes ; then
 424                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 425                                         ol_with_preemptive=yes
 426                                 fi
 427                         fi
 428
 429                         dnl restore DEFS/LIBS
 430                         CPPFLAGS="$save_CPPFLAGS"
 431                         LIBS="$save_LIBS"
 432                 else
 433                         AC_MSG_ERROR([could not link with POSIX Threads])
 434                 fi
 435         fi
 436
 437         if test $ol_with_threads = posix ; then
 438                 AC_MSG_ERROR([could not locate POSIX Threads])
 439         fi
 440 fi
 441
 442 if test $ol_with_threads = auto -o $ol_with_threads = cthreads ; then
 443         dnl check for Mach CThreads
 444         AC_CHECK_HEADERS(mach/cthreads.h)
 445         if test $ac_cv_header_lwp_lwp_h = yes ; then
 446                 AC_CHECK_LIB(lwp, cthread_fork, [have_cthreads=yes], [have_cthreads=no])
 447
 448                 if test $have_cthreads = yes ; then
 449                         AC_DEFINE(HAVE_MACH_CTHREADS)
 450                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 451                 fi
 452         fi
 453 fi
 454
 455 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 456         dnl check for SunOS5 LWP
 457         AC_CHECK_HEADERS(thread.h synch.h)
 458         if test $ac_cv_header_lwp_lwp_h = yes ; then
 459                 AC_CHECK_LIB(thread, thr_create, [have_lwp=yes], [have_lwp=no])
 460
 461                 if test $have_lwp = yes ; then
 462                         AC_DEFINE(HAVE_THR)
 463                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 464
 465                         if test $ol_with_preemptive = auto ; then
 466                                 ol_with_preemptive=yes
 467                         fi
 468                 fi
 469         fi
 470
 471         dnl check for SunOS4 LWP
 472         AC_CHECK_HEADERS(lwp/lwp.h)
 473         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 474                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 475
 476                 if test $have_lwp = yes ; then
 477                         AC_DEFINE(HAVE_LWP)
 478                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 479
 480                         if test $ol_with_preemptive = auto ; then
 481                                 ol_with_preemptive=no
 482                         fi
 483                 fi
 484         fi
 485 fi
 486
 487 if test $ol_with_preemptive = yes ; then
 488         AC_DEFINE(PREEMPTIVE_THREADS,1)
 489 fi
 490
 491 if test $ol_with_threads = manual ; then
 492         dnl User thinks he can manually configure threads.
 493         $ol_link_threads=yes
 494
 495         AC_MSG_WARN([thread defines and link options must be set manually])
 496
 497         AC_CHECK_HEADERS(pthread.h sched.h)
 498         AC_CHECK_FUNCS(sched_yield pthread_yield)
 499         OL_LINUX_THREADS
 500
 501         AC_CHECK_HEADERS(mach/cthreads.h)
 502         AC_CHECK_HEADERS(lwp/lwp.h)
 503         AC_CHECK_HEADERS(thread.h synch.h)
 504 fi
 505
 506 if test $ol_link_threads = no ; then
 507         if test $ol_with_threads = yes ; then
 508                 AC_MSG_ERROR([no suitable thread support])
 509         fi
 510
 511         if test $ol_with_threads = auto ; then
 512                 AC_MSG_WARN([no suitable thread support, disabling threads])
 513                 $ol_with_threads = no
 514         fi
 515
 516         AC_DEFINE(NO_THREADS,1)
 517         AC_DEFINE(PREEMPTIVE_THREADS,1)
 518         LTHREAD_LIBS=""
 519 fi
 520
 521 ol_link_ldbm=no
 522 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 523         OL_BERKELEY_DB2
 524
 525         if test $ol_cv_berkeley_db2 = yes ; then
 526                 ol_link_ldbm=db2
 527                 ol_with_ldbm_api=db2
 528
 529                 if test $ol_with_ldbm_type = hash ; then
 530                         AC_DEFINE(LDBM_USE_DBHASH,1)
 531                 else
 532                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 533                 fi
 534
 535                 dnl $ol_cv_lib_db2 should be yes or -ldb
 536                 dnl (it could be no, but that would be an error
 537                 if test $ol_cv_lib_db2 != yes ; then
 538                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 539                 fi
 540         fi
 541 fi
 542
 543 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 544         OL_BERKELEY_DB
 545
 546         if test $ol_cv_berkeley_db = yes ; then
 547                 ol_link_ldbm=db
 548                 ol_with_ldbm_api=db
 549
 550                 if test $ol_with_ldbm_type = hash ; then
 551                         AC_DEFINE(LDBM_USE_DBHASH,1)
 552                 else
 553                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 554                 fi
 555
 556                 dnl $ol_cv_lib_db should be yes or -ldb
 557                 dnl (it could be no, but that would be an error
 558                 if test $ol_cv_lib_db != yes ; then
 559                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 560                 fi
 561         fi
 562 fi
 563
 564 if test $ol_with_ldbm_api = manual ; then
 565         dnl User thinks he can manually configure LDBM api.
 566         $ol_link_ldbm=yes
 567
 568         AC_MSG_WARN([LDBM defines and link options must be set manually])
 569
 570         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 571 fi
 572
 573 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 574         AC_MSG_WARN(Could not find LDBM with BTREE support);
 575         $ol_with_ldbm_api=none
 576 fi
 577
 578 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 579         OL_GDBM
 580
 581         if test $ol_cv_gdbm = yes ; then
 582                 ol_link_ldbm=gdbm
 583                 ol_with_ldbm_api=gdbm
 584
 585                 if test $ol_cv_lib_gdbm != yes ; then
 586                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 587                 fi
 588         fi
 589 fi
 590
 591 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 592         OL_NDBM
 593
 594         if test $ol_cv_ndbm = yes ; then
 595                 ol_link_ldbm=ndbm
 596                 ol_with_ldbm_api=ndbm
 597
 598                 if test $ol_with_ldbm_api = ndbm ; then
 599                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 600                 fi
 601
 602                 if test $ol_cv_lib_ndbm != yes ; then
 603                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 604                 fi
 605         fi
 606 fi
 607
 608 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 609         AC_MSG_WARN(could not find suitable LDBM backend)
 610         if test $ol_enable_ldbm = yes ; then
 611                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 612         fi
 613
 614         AC_MSG_WARN(disabling LDBM)
 615         $ol_enable_ldbm=no
 616 fi
 617
 618 if test $ol_enable_wrappers = yes ; then
 619         AC_CHECK_LIB(wrap, hosts_access,
 620                 [have_wrappers=yes], [have_wrappers=no])
 621
 622         if test $have_wrappers = yes ; then
 623                 AC_DEFINE(HAVE_TCPD)
 624                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 625         else
 626                 AC_MSG_WARN(could not find -lwrap)
 627                 if test $ol_enable_wrappers = yes ; then
 628                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 629                 fi
 630
 631                 AC_MSG_WARN(disabling wrappers support)
 632                 ol_enable_wrappers=no
 633         fi
 634
 635 fi
 636
 637 # ud needs termcap (should insert check here)
 638 ol_link_termcap=no
 639 AC_CHECK_HEADERS(termcap.h ncurses.h)
 640
 641 if test $ol_link_termcap = no ; then
 642         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 643         if test $have_termcap = yes ; then
 644                 AC_DEFINE(HAVE_TERMCAP)
 645                 ol_link_termcap=yes
 646                 TERMCAP_LIBS=-ltermcap
 647         fi
 648 fi
 649
 650 if test $ol_link_termcap = no ; then
 651         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 652         if test $have_ncurses = yes ; then
 653                 AC_DEFINE(HAVE_NCURSES)
 654                 ol_link_termcap=yes
 655                 TERMCAP_LIBS=-lncurses
 656         fi
 657 fi
 658
 659 if test $ol_link_termcap = no ; then
 660         AC_DEFINE(NO_TERMCAP,1)
 661         TERMCAP_LIBS=
 662 fi
 663
 664 # FreeBSD (and others) have crypt(3) in -lcrypt
 665 if test $ol_enable_crypt != no ; then
 666         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 667                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 668                         have_crypt=yes], [have_crypt=no])])
 669
 670         if test $have_crypt = yes ; then
 671                 AC_DEFINE(HAVE_CRYPT)
 672         else
 673                 AC_MSG_WARN(could not find crypt)
 674                 if test $ol_enable_crypt = yes ; then
 675                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 676                 fi
 677
 678                 AC_MSG_WARN(disabling crypt support)
 679                 ol_enable_crypt=no
 680         fi
 681 fi
 682
 683 dnl ----------------------------------------------------------------
 684 dnl Checks for header files.
 685 AC_HEADER_STDC
 686 AC_HEADER_DIRENT
 687 AC_HEADER_SYS_WAIT
 688 AC_CHECK_HEADERS( \
 689         stddef.h        \
 690         errno.h         \
 691         fcntl.h         \
 692         filio.h         \
 693         getopt.h        \
 694         limits.h        \
 695         malloc.h        \
 696         regex.h         \
 697         sgtty.h         \
 698         sys/file.h      \
 699         sys/errno.h \
 700         sys/ioctl.h     \
 701         sys/param.h     \
 702         sys/socket.h\
 703         sys/time.h      \
 704         sys/types.h     \
 705         syslog.h        \
 706         termios.h       \
 707         unistd.h        \
 708 )
 709
 710 dnl ----------------------------------------------------------------
 711 dnl Checks for typedefs, structures, and compiler characteristics.
 712 AC_TYPE_GETGROUPS
 713 AC_TYPE_MODE_T
 714 AC_TYPE_OFF_T
 715 AC_TYPE_PID_T
 716 AC_TYPE_SIGNAL
 717 AC_TYPE_SIZE_T
 718 AC_TYPE_UID_T
 719 AC_STRUCT_ST_BLKSIZE
 720 AC_HEADER_TIME
 721 AC_STRUCT_TM
 722
 723 OL_C_UPPER_LOWER
 724 AC_C_CONST
 725
 726 dnl AC_CHECK_SIZEOF(short)
 727 dnl AC_CHECK_SIZEOF(int)
 728 dnl AC_CHECK_SIZEOF(long)
 729
 730 dnl ----------------------------------------------------------------
 731 dnl Checks for library functions.
 732 AC_FUNC_MEMCMP
 733 AC_FUNC_STRFTIME
 734 AC_FUNC_VPRINTF
 735 AC_FUNC_WAIT3
 736
 737 AC_CHECK_FUNCS(         \
 738         bcopy                   \
 739         getopt                  \
 740         flock                   \
 741         gethostname             \
 742         gettimeofday    \
 743         getdtablesize   \
 744         lockf                   \
 745         memcpy                  \
 746         memmove                 \
 747         mkstemp                 \
 748         mktime                  \
 749         select                  \
 750         setpwfile               \
 751         setsid                  \
 752         signal                  \
 753         sigset                  \
 754         socket                  \
 755         strerror                \
 756         strstr                  \
 757         strrchr                 \
 758         strsep                  \
 759         strtod                  \
 760         strtol                  \
 761         strtoul                 \
 762         sysconf                 \
 763         tempnam                 \
 764         waitpid                 \
 765 )
 766
 767 AC_REPLACE_FUNCS(getopt strdup tempnam)
 768
 769 dnl ----------------------------------------------------------------
 770 # Check Configuration
 771 OL_SYS_ERRLIST
 772
 773 dnl ----------------------------------------------------------------
 774 dnl Sort out defines
 775
 776 if test $ol_enable_debug != no ; then
 777         AC_DEFINE(LDAP_DEBUG,1)
 778 fi
 779 dnl     if test $ol_enable_syslog != no ; then
 780 dnl             AC_DEFINE(LDAP_SYSLOG,1)
 781 dnl     fi
 782 if test $ol_enable_libui = yes ; then
 783         AC_DEFINE(LDAP_LIBUI,1)
 784 fi
 785 if test $ol_enable_cache = no ; then
 786         AC_DEFINE(LDAP_NOCACHE,1)
 787 fi
 788 if test $ol_enable_dns != no ; then
 789         AC_DEFINE(LDAP_DNS,1)
 790 fi
 791 if test $ol_enable_referrals != no ; then
 792         AC_DEFINE(LDAP_REFERRALS,1)
 793 fi
 794 if test $ol_enable_cldap != no ; then
 795         AC_DEFINE(LDAP_CONNECTIONLESS,1)
 796 fi
 797
 798 if test $ol_enable_aclgroup != no ; then
 799         AC_DEFINE(SLAPD_ACLGROUP,1)
 800 fi
 801
 802 if test $ol_enable_crypt != no ; then
 803         AC_DEFINE(SLAPD_CRYPT,1)
 804 fi
 805
 806 if test $ol_enable_md5 != no ; then
 807         AC_DEFINE(SLAPD_MD5,1)
 808 fi
 809
 810 if test $ol_enable_sha1 != no ; then
 811         AC_DEFINE(SLAPD_SHA1,1)
 812 fi
 813
 814 if test $ol_enable_phonetic != no ; then
 815         AC_DEFINE(SLAPD_PHONETIC,1)
 816 fi
 817
 818 if test $ol_enable_rlookups != no ; then
 819         AC_DEFINE(SLAPD_RLOOKUPS,1)
 820 fi
 821
 822 if test $ol_link_ldbm != no ; then
 823         AC_DEFINE(SLAPD_LDBM,1)
 824         BUILD_SLAPD=yes
 825         BUILD_LDBM=yes
 826 fi
 827
 828 if test $ol_enable_passwd != no ; then
 829         AC_DEFINE(SLAPD_PASSWD,1)
 830         BUILD_SLAPD=yes
 831         BUILD_PASSWD=yes
 832 fi
 833
 834 if test $ol_enable_shell != no ; then
 835         AC_DEFINE(SLAPD_SHELL,1)
 836         BUILD_SLAPD=yes
 837         BUILD_SHELL=yes
 838 fi
 839
 840 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
 841         $BUILD_SLAPD = yes ; then
 842         BUILD_SLURPD=yes
 843 fi
 844
 845 dnl ----------------------------------------------------------------
 846
 847 AC_SUBST(BUILD_LDAPD)
 848 AC_SUBST(BUILD_SLAPD)
 849   AC_SUBST(BUILD_LDBM)
 850   AC_SUBST(BUILD_PASSWD)
 851   AC_SUBST(BUILD_SHELL)
 852 AC_SUBST(BUILD_SLURPD)
 853
 854
 855 AC_SUBST(LDAP_LIBS)
 856 AC_SUBST(LDAPD_LIBS)
 857 AC_SUBST(SLAPD_LIBS)
 858 AC_SUBST(SLURPD_LIBS)
 859 AC_SUBST(LDBM_LIBS)
 860 AC_SUBST(LTHREAD_LIBS)
 861 AC_SUBST(LUTIL_LIBS)
 862
 863 AC_SUBST(KRB_LIBS)
 864 AC_SUBST(TERMCAP_LIBS)
 865
 866 dnl ----------------------------------------------------------------
 867 dnl final output
 868 dnl
 869
 870 dnl AC_OUTPUT( \
 871 dnl contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
 872 dnl contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
 873 dnl contrib/whois++/Makefile:build/top.mk:contrib/whois++/Makefile.in:build/rules.mk \
 874 dnl [date > stamp-h])
 875
 876 AC_OUTPUT( \
 877 Makefile:build/top.mk:Makefile.in:build/dir.mk \
 878 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
 879 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
 880 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
 881 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
 882 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
 883 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
 884 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
 885 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
 886 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
 887 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
 888 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
 889 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
 890 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
 891 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
 892 include/Makefile:build/top.mk:include/Makefile.in \
 893 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
 894 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
 895 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
 896 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
 897 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
 898 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
 899 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
 900 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
 901 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
 902 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
 903 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
 904 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
 905 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
 906 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
 907 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
 908 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
 909 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
 910 tests/Makefile:build/top.mk:tests/Makefile.in \
 911 ,[date > stamp-h])