git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  28 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  29 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  30 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  31 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  32 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  33 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  34         no, [yes no])dnl
  35
  36 dnl General "with" options
  37 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  38         auto, [auto k5 k4 afs yes no])
  39 OL_ARG_WITH(threads,[  --with-threads   use threads],
  40         auto, [auto posix mach lwp yes no manual] )
  41 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  42         auto, [auto yes no manual] )
  43
  44 dnl Server options
  45
  46 dnl LDAPD OPTIONS
  47 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  48
  49 dnl SLAPD OPTIONS
  50 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  51 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  52 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  53 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  54 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  55 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  56 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  57 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  58
  59 dnl SLAPD Backend options
  60 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  61 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  62         [auto db2 db gdbm ndbm manual])
  63 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  64         [auto btree hash])
  65
  66 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  67 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  68
  69 dnl SLURPD OPTIONS
  70 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  71
  72 # validate options
  73 if test $ol_enable_referrals = no ; then
  74         if test $ol_enable_dns = yes ; then
  75                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
  76         fi
  77         ol_enable_dns=no
  78 fi
  79
  80 if test $ol_enable_slapd = no ; then
  81         dnl SLAPD was specificallly disabled
  82         if test $ol_enable_ldbm = yes ; then
  83                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  84         fi
  85         if test $ol_enable_passwd = yes ; then
  86                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
  87         fi
  88         if test $ol_enable_shell = yes ; then
  89                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
  90         fi
  91         if test $ol_enable_aclgroups = yes ; then
  92                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
  93         fi
  94         if test $ol_enable_crypt = yes ; then
  95                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
  96         fi
  97         if test $ol_enable_md5 = yes ; then
  98                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
  99         fi
 100         if test $ol_enable_sha1 = yes ; then
 101                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 102         fi
 103         if test $ol_enable_wrappers = yes ; then
 104                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 105         fi
 106         if test $ol_enable_phonetic = yes ; then
 107                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 108         fi
 109         if test $ol_enable_rlookups = yes ; then
 110                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 111         fi
 112         if test $ol_with_ldbm_api != auto ; then
 113                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 114         fi
 115         if test $ol_with_ldbm_type != auto ; then
 116                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 117         fi
 118         if test $ol_enable_slurpd = yes ; then
 119                 AC_MSG_ERROR([slurpd requires slapd])
 120         fi
 121
 122         # force settings to no
 123         ol_enable_ldbm=no
 124         ol_enable_shell=no
 125         ol_enable_passwd=no
 126         ol_enable_aclgroups=no
 127         ol_enable_crypt=no
 128         ol_enable_md5=no
 129         ol_enable_sha1=no
 130         ol_enable_wrappers=no
 131         ol_enable_phonetic=no
 132         ol_enable_rlookups=no
 133         ol_with_ldbm_api=no
 134         ol_with_ldbm_type=no
 135         ol_enable_slurpd=no
 136
 137 elif test $ol_enable_ldbm = no ; then
 138         dnl SLAPD without LDBM
 139
 140         if test $ol_with_ldbm_api != auto ; then
 141                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 142         fi
 143
 144         if test $ol_with_ldbm_type != auto ; then
 145                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 146         fi
 147
 148         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 149                 AC_MSG_ERROR([slapd requires a backend])
 150         fi
 151
 152         ol_with_ldbm_api=no
 153         ol_with_ldbm_type=no
 154
 155 else
 156         dnl SLAPD with LDBM
 157
 158         if test $ol_with_ldbm_api = gdbm -a \
 159                 $ol_with_ldbm_type = btree ; then
 160                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 161         fi
 162         if test $ol_with_ldbm_api = ndbm -a \
 163                 $ol_with_ldbm_type = btree ; then
 164                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 165         fi
 166 fi
 167
 168 if test $ol_enable_slurpd = yes ; then
 169         dnl SLURPD was specifically enabled
 170         if test $ol_with_threads = no ; then
 171                 AC_MSG_ERROR([slurpd requires threads])
 172         fi
 173 fi
 174
 175 AC_MSG_RESULT(done)
 176
 177 ## Initialize vars
 178 LDAP_LIBS=
 179 LDBM_LIBS=
 180 LTHREAD_LIBS=
 181 LUTIL_LIBS=
 182
 183 LDAPD_LIBS=
 184 SLAPD_LIBS=
 185 SLURPD_LIBS=
 186
 187 BUILD_LDAPD=no
 188 BUILD_SLAPD=no
 189 BUILD_SLURPD=no
 190
 191 BUILD_LDBM=no
 192 BUILD_PASSWD=no
 193 BUILD_SHELL=no
 194 BUILD_THREAD=no
 195
 196 KRB_LIBS=
 197 TERMCAP_LIBS=
 198
 199 dnl ----------------------------------------------------------------
 200 dnl Checks for programs
 201
 202 AC_PROG_LN_S
 203 AC_PROG_INSTALL
 204 AC_PROG_RANLIB
 205 AC_PROG_MAKE_SET
 206
 207 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 208         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 209 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 210 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 211
 212 dnl Checks the compiler and UNIX Variants
 213 AC_PROG_CC
 214
 215 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 216         AC_WARN([cross compiling....  go for it])
 217
 218 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 219         AC_WARN([programs compiled here do run here...])
 220         AC_ERROR([  if not cross compiling, use --disable-x-compile.])
 221
 222 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 223         AC_WARN([programs compiled here do not run here...])
 224         AC_ERROR([  if cross compiling,  add --enable-x-compile.])
 225 fi
 226
 227 dnl OpenLDAP requires STDC features
 228 dnl AC_PROG_GCC_TRADITIONAL
 229 AC_PROG_CPP
 230
 231
 232 AC_AIX
 233 AC_ISC_POSIX
 234 AC_MINIX
 235
 236 dnl Checks for libraries
 237
 238 dnl Find socket()
 239 dnl Likely combinations:
 240 dnl             -lsocket [ -lnsl_s | -lnsl ]
 241 dnl             -linet
 242
 243 AC_CHECK_FUNC(socket, :, [
 244 dnl
 245 dnl hopefully we won't include too many libraries
 246 dnl
 247         AC_CHECK_LIB(socket, main)
 248         AC_CHECK_LIB(net, main)
 249         AC_CHECK_LIB(nsl_s, main)
 250         AC_CHECK_LIB(nsl, main)
 251         AC_CHECK_LIB(inet, socket)
 252         AC_CHECK_LIB(gen, main)
 253 ])
 254
 255 dnl Check for resolv
 256 AC_CHECK_LIB(resolv, res_search)
 257
 258 dnl HP-UX requires -lV3
 259 AC_CHECK_LIB(V3, sigset)
 260
 261 # ISODE tests
 262 ol_link_isode=no
 263 if test $ol_enable_ldapd != no ; then
 264         dnl look for ISODE libraries
 265         AC_CHECK_LIB(xtpp, main, [
 266                 ol_link_isode=yes
 267                 AC_DEFINE(HAVE_XTPP,1)
 268                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 269                 ],:,[-lxtdsap -lxtisode -losi])
 270         AC_CHECK_LIB(dsap, main, [
 271                 ol_link_isode=yes
 272                 AC_DEFINE(HAVE_DSAP,1)
 273                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 274                 ],:,[-lisode])
 275         AC_CHECK_LIB(isode, main, [
 276                 ol_link_isode=yes
 277                 AC_DEFINE(HAVE_ISODE,1)
 278                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 279                 ],:)
 280 fi
 281
 282 if test $ol_link_isode != no; then
 283         AC_CHECK_LIB(pp, main, [
 284                 AC_DEFINE(HAVE_PP,1)
 285                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 286                 ],:)
 287
 288         AC_PATH_PROG(PEPSY, pepsy)
 289 fi
 290
 291 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 292         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 293
 294         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 295                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 296                         [-lkrb5 -ldes425])
 297
 298                 if test $have_k5 = yes ; then
 299                         ol_with_kerberos=found
 300                         ol_link_kerberos=yes
 301
 302                         AC_DEFINE(HAVE_KERBEROS)
 303
 304                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 305                 fi
 306         fi
 307 fi
 308 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 309         AC_CHECK_HEADERS(krb.h des.h)
 310
 311         if test $ac_cv_header_krb_h = yes ; then
 312                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 313
 314                 if test $have_k4 = yes ; then
 315                         ol_with_kerberos=found
 316                         ol_link_kerberos=yes
 317
 318                         AC_DEFINE(HAVE_KERBEROS)
 319
 320                         KRB_LIBS="-lkrb -ldes"
 321                 fi
 322         fi
 323 fi
 324
 325 ol_link_threads=no
 326 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 327         AC_CHECK_HEADERS(pthread.h sched.h)
 328
 329         if test $ac_cv_header_pthread_h = yes ; then
 330                 OL_POSIX_THREAD_VERSION
 331
 332                 if test $ol_cv_pthread_version = final ; then
 333                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 334                 elif test $ol_cv_pthread_version = draft4 ; then
 335                         AC_DEFINE(HAVE_PTHREADS_D4)
 336                 else
 337                         AC_MSG_ERROR([unknown pthread version])
 338                 fi
 339
 340                 # consider threads found
 341                 ol_with_threads=found
 342
 343                 OL_LINUX_THREADS
 344
 345                 if test $ol_cv_linux_threads = yes ; then
 346                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 347                 fi
 348
 349                 dnl Now the hard part, how to link
 350
 351                 dnl A few platforms have pthread support in standard libraries
 352                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 353
 354                 if test $ol_link_threads = no ; then
 355                         dnl try -pthread
 356                         AC_CACHE_CHECK([for pthread_create with -pthread],
 357                                 [ol_cv_pthread_flag], [
 358                                 dnl save the flags
 359                                 save_LIBS="$LIBS"
 360                                 LIBS="-pthread $LIBS"
 361                                 AC_TRY_LINK([char pthread();],[
 362                                         pthread_create();
 363                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 364                                 dnl restore the LIBS
 365                                 LIBS="$save_LIBS"
 366                         ])
 367
 368                         if test $ol_cv_pthread_flag = yes ; then
 369                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 370                                 ol_link_threads=posix
 371                         fi
 372                 fi
 373
 374                 if test $ol_link_threads = no ; then
 375                         dnl try -thread
 376                         AC_CACHE_CHECK([for pthread_create with -thread],
 377                                 [ol_cv_thread_flag], [
 378                                 dnl save the flags
 379                                 save_LIBS="$LIBS"
 380                                 LIBS="-thread $LIBS"
 381                                 AC_TRY_LINK([char pthread();],[
 382                                         pthread_create();
 383                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 384                                 dnl restore the LIBS
 385                                 LIBS="$save_LIBS"
 386                         ])
 387
 388                         if test $ol_cv_thread_flag = yes ; then
 389                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 390                                 ol_link_threads=posix
 391                         fi
 392                 fi
 393
 394                 if test $ol_link_threads = no ; then
 395                         dnl try DEC Threads -lpthread -lexc
 396                         save_LIBS="$LIBS"
 397                         AC_CHECK_LIB(pthread, pthread_create, [
 398                                 ol_link_threads=posix
 399                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 400                                 if test $ol_with_preemptive = auto ; then
 401                                         ol_with_preemptive=yes
 402                                 fi
 403                                 ],,[-lexc])
 404                         LIBS="$save_LIBS"
 405                 fi
 406
 407                 if test $ol_link_threads = no ; then
 408                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 409                         save_LIBS="$LIBS"
 410                         AC_CHECK_LIB(pthreads, pthread_create, [
 411                                 ol_link_threads=posix
 412                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 413                                 if test $ol_with_preemptive = auto ; then
 414                                         ol_with_preemptive=yes
 415                                 fi
 416                                 ],,[-lmach -lexc -lc_r])
 417                         LIBS="$save_LIBS"
 418                 fi
 419
 420                 if test $ol_link_threads = no ; then
 421                         dnl try -lpthread
 422                         save_LIBS="$LIBS"
 423                         AC_CHECK_LIB(pthread, pthread_create, [
 424                                 ol_link_threads=posix
 425                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 426                         LIBS="$save_LIBS"
 427                 fi
 428
 429                 if test $ol_link_threads = no ; then
 430                         dnl try -lc_r
 431                         save_LIBS="$LIBS"
 432                         AC_CHECK_LIB(c_r, pthread_create, [
 433                                 ol_link_threads=posix
 434                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 435                         LIBS="$save_LIBS"
 436                 fi
 437
 438                 if test $ol_link_threads != no ; then
 439                         AC_DEFINE(HAVE_PTHREADS)
 440
 441                         dnl save flags
 442                         save_CPPFLAGS="$CPPFLAGS"
 443                         save_LIBS="$LIBS"
 444                         LIBS="$LTHREAD_LIBS $LIBS"
 445
 446                         dnl All POSIX Thread (final) implementations should have
 447                         dnl sched_yield instead of pthread yield.
 448                         dnl check for both
 449                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 450
 451                         if test $ac_cv_func_sched_yield = no -a \
 452                                 $ac_cv_func_pthread_yield = no ; then
 453                                 dnl Digital UNIX has sched_yield() in -lrt
 454                                 AC_CHECK_LIB(rt, sched_yield,
 455                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 456                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 457                                         ac_cv_func_sched_yield=yes],
 458                                         [ac_cv_func_sched_yield=no])
 459                         fi
 460                         if test $ac_cv_func_sched_yield = no -a \
 461                                 $ac_cv_func_pthread_yield = no ; then
 462                                 dnl Solaris has sched_yield() in -lposix4
 463                                 AC_CHECK_LIB(posix4, sched_yield,
 464                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 465                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 466                                         ac_cv_func_sched_yield=yes],
 467                                         [ac_cv_func_sched_yield=no])
 468                         fi
 469                         if test $ac_cv_func_sched_yield = no -a \
 470                                 $ac_cv_func_pthread_yield = no ; then
 471                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 472                                 AC_MSG_ERROR([POSIX Threads are not usable])
 473                         fi
 474
 475                         dnl Check functions for compatibility
 476                         AC_CHECK_FUNCS(pthread_kill)
 477                         AC_CHECK_FUNCS( \
 478                                 pthread_attr_create pthread_attr_init \
 479                                 pthread_attr_destroy pthread_attr_delete \
 480                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 481                         )
 482
 483                         dnl Check for setconcurreny functions
 484                         AC_CHECK_FUNCS( \
 485                                 pthread_setconcurrency \
 486                                 thr_setconcurrency \
 487                         )
 488
 489                         dnl Check PREEMPTIVE Implementation
 490                         if test $ol_with_preemptive = auto ; then
 491                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 492                                 AC_TRY_RUN([
 493 #include <sys/types.h>
 494 #include <sys/time.h>
 495 #include <unistd.h>
 496 #include <pthread.h>
 497 #ifndef NULL
 498 #define NULL 0
 499 #endif
 500
 501 int task(arg)
 502         int *arg;
 503 {
 504         struct timeval tv;
 505
 506         tv.tv_sec=4;
 507         tv.tv_usec=0;
 508         select(0, NULL, NULL, NULL, &tv);
 509
 510         tv.tv_sec=6;
 511         tv.tv_usec=0;
 512         select(0, NULL, NULL, NULL, &tv);
 513
 514         exit(1); /* if we exit here, the select blocked the whole process */
 515 }
 516
 517 main(argc, argv)
 518 int argc; char **argv;
 519 {
 520         pthread_t t;
 521
 522 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 523         (void) pthread_setconcurrency(2);
 524 #else
 525 #ifdef HAVE_THR_SETCONCURRENCY
 526         /* Set Solaris LWP concurrency to 2 */
 527         thr_setconcurrency(2);
 528 #endif
 529 #endif
 530
 531         pthread_create(&t, NULL, (void *) task, NULL);
 532
 533 #if HAVE_SCHED_YIELD
 534         sched_yield();  /* make sure task runs first */
 535 #else
 536 #ifdef HAVE_PTHREAD_YIELD
 537         pthread_yield();        /* make sure task runs first */
 538 #endif
 539 #endif
 540         exit(0);
 541 }
 542                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 543                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 544                                 AC_MSG_RESULT($ol_pthread_preemptive)
 545
 546                                 if test $ol_pthread_preemptive = yes ; then
 547                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 548                                         ol_with_preemptive=yes
 549                                 fi
 550                         fi
 551
 552 dnl                     dnl check for reentrant/threadsafe functions
 553 dnl                     AC_CHECK_FUNCS( \
 554 dnl                             feof_unlocked \
 555 dnl                             unlocked_feof \
 556 dnl                             ftrylockfile \
 557 dnl                             flockfile \
 558 dnl                             putc_unlocked \
 559 dnl                             gmtime_r \
 560 dnl                             strtok_r \
 561 dnl                     )
 562
 563                         dnl restore flags
 564                         CPPFLAGS="$save_CPPFLAGS"
 565                         LIBS="$save_LIBS"
 566                 else
 567                         AC_MSG_ERROR([could not link with POSIX Threads])
 568                 fi
 569         fi
 570
 571         if test $ol_with_threads = posix ; then
 572                 AC_MSG_ERROR([could not locate POSIX Threads])
 573         fi
 574 fi
 575
 576 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 577         dnl check for Mach CThreads
 578         AC_CHECK_HEADERS(mach/cthreads.h)
 579         if test $ac_cv_header_mach_cthreads_h = yes ; then
 580                 ol_with_threads=found
 581
 582                 dnl A few platforms have cthread support in standard libraries
 583                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 584
 585                 if test $ol_link_threads = no ; then
 586                         dnl try -all_load
 587                         dnl this test needs work
 588                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 589                                 [ol_cv_cthread_all_load], [
 590                                 dnl save the flags
 591                                 save_LIBS="$LIBS"
 592                                 LIBS="-all_load $LIBS"
 593                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 594                                         cthread_fork((void *)0, (void *)0);
 595                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 596                                 dnl restore the LIBS
 597                                 LIBS="$save_LIBS"
 598                         ])
 599
 600                         if test $ol_cv_cthread_all_load = yes ; then
 601                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 602                                 ol_link_threads=mach
 603                         fi
 604                 fi
 605
 606                 if test $ol_link_threads != no ; then
 607                         : check for cthread specific functionality here
 608                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 609                 else
 610                         AC_MSG_ERROR([could not link with Mach CThreads])
 611                 fi
 612         fi
 613
 614         if test $ol_with_threads = mach ; then
 615                 AC_MSG_ERROR([could not locate Mach CThreads])
 616         fi
 617 fi
 618
 619 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 620         dnl check for SunOS5 LWP
 621         AC_CHECK_HEADERS(thread.h synch.h)
 622         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 623                 AC_CHECK_LIB(thread, thr_create, [have_lwp=yes], [have_lwp=no])
 624
 625                 if test $have_lwp = yes ; then
 626                         AC_DEFINE(HAVE_THR)
 627                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 628
 629                         if test $ol_with_preemptive = auto ; then
 630                                 ol_with_preemptive=yes
 631                         fi
 632                 fi
 633         fi
 634
 635         dnl check for SunOS4 LWP
 636         AC_CHECK_HEADERS(lwp/lwp.h)
 637         if test $ac_cv_header_lwp_lwp_h = yes ; then
 638                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 639
 640                 if test $have_lwp = yes ; then
 641                         AC_DEFINE(HAVE_LWP)
 642                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 643
 644                         if test $ol_with_preemptive = auto ; then
 645                                 ol_with_preemptive=no
 646                         fi
 647                 fi
 648         fi
 649 fi
 650
 651 if test $ol_with_preemptive = yes ; then
 652         AC_DEFINE(PREEMPTIVE_THREADS,1)
 653 fi
 654
 655 if test $ol_with_threads = manual ; then
 656         dnl User thinks he can manually configure threads.
 657         ol_link_threads=yes
 658
 659         AC_MSG_WARN([thread defines and link options must be set manually])
 660
 661         AC_CHECK_HEADERS(pthread.h sched.h)
 662         AC_CHECK_FUNCS(sched_yield pthread_yield)
 663         OL_LINUX_THREADS
 664
 665         AC_CHECK_HEADERS(mach/cthreads.h)
 666         AC_CHECK_HEADERS(lwp/lwp.h)
 667         AC_CHECK_HEADERS(thread.h synch.h)
 668 fi
 669
 670 if test $ol_with_threads != no ; then
 671         dnl needed to get reentrant/threadsafe versions
 672         dnl
 673         dnl hopefully this will not cause problems with
 674         dnl non-threaded apps
 675         dnl
 676         AC_DEFINE(_REENTRANT,1)
 677         AC_DEFINE(_THREAD_SAFE,1)
 678         AC_DEFINE(_THREADSAFE,1)
 679 fi
 680
 681 dnl ----------------------------------------------------------------
 682
 683 if test $ol_link_threads = no ; then
 684         if test $ol_with_threads = yes ; then
 685                 AC_MSG_ERROR([no suitable thread support])
 686         fi
 687
 688         if test $ol_with_threads = auto ; then
 689                 AC_MSG_WARN([no suitable thread support, disabling threads])
 690                 ol_with_threads=no
 691         fi
 692
 693         AC_DEFINE(NO_THREADS,1)
 694         AC_DEFINE(PREEMPTIVE_THREADS,1)
 695         LTHREAD_LIBS=""
 696 fi
 697
 698 ol_link_ldbm=no
 699 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 700         OL_BERKELEY_DB2
 701
 702         if test $ol_cv_berkeley_db2 = yes ; then
 703                 ol_link_ldbm=db2
 704                 ol_with_ldbm_api=db2
 705
 706                 if test $ol_with_ldbm_type = hash ; then
 707                         AC_DEFINE(LDBM_USE_DBHASH,1)
 708                 else
 709                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 710                 fi
 711
 712                 dnl $ol_cv_lib_db2 should be yes or -ldb
 713                 dnl (it could be no, but that would be an error
 714                 if test $ol_cv_lib_db2 != yes ; then
 715                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 716                 fi
 717         fi
 718 fi
 719
 720 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 721         OL_BERKELEY_DB
 722
 723         if test $ol_cv_berkeley_db = yes ; then
 724                 ol_link_ldbm=db
 725                 ol_with_ldbm_api=db
 726
 727                 if test $ol_with_ldbm_type = hash ; then
 728                         AC_DEFINE(LDBM_USE_DBHASH,1)
 729                 else
 730                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 731                 fi
 732
 733                 dnl $ol_cv_lib_db should be yes or -ldb
 734                 dnl (it could be no, but that would be an error
 735                 if test $ol_cv_lib_db != yes ; then
 736                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 737                 fi
 738         fi
 739 fi
 740
 741 if test $ol_with_ldbm_api = manual ; then
 742         dnl User thinks he can manually configure LDBM api.
 743         ol_link_ldbm=yes
 744
 745         AC_MSG_WARN([LDBM defines and link options must be set manually])
 746
 747         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 748 fi
 749
 750 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 751         AC_MSG_WARN(Could not find LDBM with BTREE support)
 752         ol_with_ldbm_api=none
 753 fi
 754
 755 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 756         OL_GDBM
 757
 758         if test $ol_cv_gdbm = yes ; then
 759                 ol_link_ldbm=gdbm
 760                 ol_with_ldbm_api=gdbm
 761
 762                 if test $ol_cv_lib_gdbm != yes ; then
 763                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 764                 fi
 765         fi
 766 fi
 767
 768 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 769         OL_NDBM
 770
 771         if test $ol_cv_ndbm = yes ; then
 772                 ol_link_ldbm=ndbm
 773                 ol_with_ldbm_api=ndbm
 774
 775                 if test $ol_with_ldbm_api = ndbm ; then
 776                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 777                 fi
 778
 779                 if test $ol_cv_lib_ndbm != yes ; then
 780                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 781                 fi
 782         fi
 783 fi
 784
 785 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 786         AC_MSG_WARN(could not find suitable LDBM backend)
 787         if test $ol_enable_ldbm = yes ; then
 788                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 789         fi
 790
 791         AC_MSG_WARN(disabling LDBM)
 792         ol_enable_ldbm=no
 793 fi
 794
 795 if test $ol_enable_wrappers = yes ; then
 796         AC_CHECK_LIB(wrap, hosts_access,
 797                 [have_wrappers=yes], [have_wrappers=no])
 798
 799         if test $have_wrappers = yes ; then
 800                 AC_DEFINE(HAVE_TCPD)
 801                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 802         else
 803                 AC_MSG_WARN(could not find -lwrap)
 804                 if test $ol_enable_wrappers = yes ; then
 805                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 806                 fi
 807
 808                 AC_MSG_WARN(disabling wrappers support)
 809                 ol_enable_wrappers=no
 810         fi
 811
 812 fi
 813
 814 # ud needs termcap (should insert check here)
 815 ol_link_termcap=no
 816 AC_CHECK_HEADERS(termcap.h ncurses.h)
 817
 818 if test $ol_link_termcap = no ; then
 819         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 820         if test $have_termcap = yes ; then
 821                 AC_DEFINE(HAVE_TERMCAP)
 822                 ol_link_termcap=yes
 823                 TERMCAP_LIBS=-ltermcap
 824         fi
 825 fi
 826
 827 if test $ol_link_termcap = no ; then
 828         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 829         if test $have_ncurses = yes ; then
 830                 AC_DEFINE(HAVE_NCURSES)
 831                 ol_link_termcap=yes
 832                 TERMCAP_LIBS=-lncurses
 833         fi
 834 fi
 835
 836 if test $ol_link_termcap = no ; then
 837         AC_DEFINE(NO_TERMCAP,1)
 838         TERMCAP_LIBS=
 839 fi
 840
 841 # FreeBSD (and others) have crypt(3) in -lcrypt
 842 if test $ol_enable_crypt != no ; then
 843         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 844                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 845                         have_crypt=yes], [have_crypt=no])])
 846
 847         if test $have_crypt = yes ; then
 848                 AC_DEFINE(HAVE_CRYPT,1)
 849         else
 850                 AC_MSG_WARN(could not find crypt)
 851                 if test $ol_enable_crypt = yes ; then
 852                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 853                 fi
 854
 855                 AC_MSG_WARN(disabling crypt support)
 856                 ol_enable_crypt=no
 857         fi
 858 fi
 859
 860 # FreeBSD (and others) have setproctitle(3) in -lutil
 861 if test $ol_enable_proctitle != no ; then
 862         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 863                 AC_CHECK_LIB(util, setproctitle,
 864                         [have_setproctitle=yes
 865                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 866                         [have_setproctitle=no
 867                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 868
 869         if test $have_setproctitle = yes ; then
 870                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 871         fi
 872 fi
 873
 874 dnl ----------------------------------------------------------------
 875 dnl Checks for header files.
 876 AC_HEADER_STDC
 877
 878 if test $ac_cv_header_stdc != yes; then
 879         AC_MSG_WARN([could not locate Standard C headers])
 880 fi
 881
 882 AC_HEADER_DIRENT
 883 AC_HEADER_SYS_WAIT
 884 AC_CHECK_HEADERS(       \
 885         stdarg.h                \
 886         stddef.h                \
 887         errno.h                 \
 888         fcntl.h                 \
 889         filio.h                 \
 890         getopt.h                \
 891         libutil.h               \
 892         limits.h                \
 893         malloc.h                \
 894         regex.h                 \
 895         sgtty.h                 \
 896         sys/file.h              \
 897         sys/filio.h             \
 898         sys/errno.h             \
 899         sys/ioctl.h             \
 900         sys/param.h             \
 901         sys/socket.h    \
 902         sys/syslog.h    \
 903         sys/time.h              \
 904         sys/types.h             \
 905         syslog.h                \
 906         termios.h               \
 907         unistd.h                \
 908 )
 909
 910 dnl ----------------------------------------------------------------
 911 dnl Checks for typedefs, structures, and compiler characteristics.
 912 AC_TYPE_GETGROUPS
 913 AC_TYPE_MODE_T
 914 AC_TYPE_OFF_T
 915 AC_TYPE_PID_T
 916 AC_TYPE_SIGNAL
 917 AC_TYPE_SIZE_T
 918 AC_TYPE_UID_T
 919 AC_STRUCT_ST_BLKSIZE
 920 AC_HEADER_TIME
 921 AC_STRUCT_TM
 922
 923 OL_C_UPPER_LOWER
 924 AC_C_CONST
 925
 926 dnl AC_CHECK_SIZEOF(short)
 927 dnl AC_CHECK_SIZEOF(int)
 928 dnl AC_CHECK_SIZEOF(long)
 929
 930 dnl ----------------------------------------------------------------
 931 dnl Checks for library functions.
 932 AC_FUNC_MEMCMP
 933 AC_FUNC_STRFTIME
 934 AC_FUNC_VPRINTF
 935
 936 if test $ac_cv_func_vprintf = yes ; then
 937         dnl check for vsnprintf
 938         AC_CHECK_FUNCS(vsnprintf)
 939 fi
 940
 941 AC_FUNC_WAIT3
 942
 943 AC_CHECK_FUNCS(         \
 944         bcopy                   \
 945         getopt                  \
 946         flock                   \
 947         gethostname             \
 948         gettimeofday    \
 949         getdtablesize   \
 950         lockf                   \
 951         memcpy                  \
 952         memmove                 \
 953         mkstemp                 \
 954         mktime                  \
 955         res_search              \
 956         select                  \
 957         setpwfile               \
 958         setsid                  \
 959         signal                  \
 960         sigset                  \
 961         snprintf                \
 962         socket                  \
 963         strerror                \
 964         strstr                  \
 965         strrchr                 \
 966         strsep                  \
 967         strtod                  \
 968         strtol                  \
 969         strtoul                 \
 970         sysconf                 \
 971         tempnam                 \
 972         waitpid                 \
 973 )
 974
 975 AC_REPLACE_FUNCS(getopt strdup tempnam)
 976
 977 dnl ----------------------------------------------------------------
 978 # Check Configuration
 979 OL_SYS_ERRLIST
 980
 981 dnl ----------------------------------------------------------------
 982 dnl Sort out defines
 983
 984 if test $ol_enable_debug != no ; then
 985         AC_DEFINE(LDAP_DEBUG,1)
 986 fi
 987 dnl     if test $ol_enable_syslog != no ; then
 988 dnl             AC_DEFINE(LDAP_SYSLOG,1)
 989 dnl     fi
 990 if test $ol_enable_libui = yes ; then
 991         AC_DEFINE(LDAP_LIBUI,1)
 992 fi
 993 if test $ol_enable_cache = no ; then
 994         AC_DEFINE(LDAP_NOCACHE,1)
 995 fi
 996 if test $ol_enable_dns != no ; then
 997         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION)
 998 fi
 999 if test $ol_enable_proctitle != no ; then
1000         AC_DEFINE(LDAP_PROCTITLE,1)
1001 fi
1002 if test $ol_enable_referrals != no ; then
1003         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION)
1004 fi
1005 if test $ol_enable_cldap != no ; then
1006         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1007 fi
1008
1009 if test $ol_enable_aclgroups != no ; then
1010         AC_DEFINE(SLAPD_ACLGROUPS,1)
1011 fi
1012 if test $ol_enable_crypt != no ; then
1013         AC_DEFINE(SLAPD_CRYPT,1)
1014 fi
1015 if test $ol_enable_md5 != no ; then
1016         AC_DEFINE(SLAPD_MD5,1)
1017 fi
1018 if test $ol_enable_sha1 != no ; then
1019         AC_DEFINE(SLAPD_SHA1,1)
1020 fi
1021 if test $ol_enable_phonetic != no ; then
1022         AC_DEFINE(SLAPD_PHONETIC,1)
1023 fi
1024 if test $ol_enable_rlookups != no ; then
1025         AC_DEFINE(SLAPD_RLOOKUPS,1)
1026 fi
1027
1028 if test $ol_link_ldbm != no ; then
1029         AC_DEFINE(SLAPD_LDBM,1)
1030         BUILD_SLAPD=yes
1031         BUILD_LDBM=yes
1032 fi
1033
1034 if test $ol_enable_passwd != no ; then
1035         AC_DEFINE(SLAPD_PASSWD,1)
1036         BUILD_SLAPD=yes
1037         BUILD_PASSWD=yes
1038 fi
1039
1040 if test $ol_enable_shell != no ; then
1041         AC_DEFINE(SLAPD_SHELL,1)
1042         BUILD_SLAPD=yes
1043         BUILD_SHELL=yes
1044 fi
1045
1046 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1047         $BUILD_SLAPD = yes ; then
1048         BUILD_SLURPD=yes
1049 fi
1050
1051 if test $ol_link_isode != no ; then
1052         BUILD_LDAPD=yes
1053 fi
1054
1055 dnl ----------------------------------------------------------------
1056
1057 AC_SUBST(BUILD_LDAPD)
1058 AC_SUBST(BUILD_SLAPD)
1059   AC_SUBST(BUILD_LDBM)
1060   AC_SUBST(BUILD_PASSWD)
1061   AC_SUBST(BUILD_SHELL)
1062 AC_SUBST(BUILD_SLURPD)
1063
1064
1065 AC_SUBST(LDAP_LIBS)
1066 AC_SUBST(LDAPD_LIBS)
1067 AC_SUBST(SLAPD_LIBS)
1068 AC_SUBST(SLURPD_LIBS)
1069 AC_SUBST(LDBM_LIBS)
1070 AC_SUBST(LTHREAD_LIBS)
1071 AC_SUBST(LUTIL_LIBS)
1072
1073 AC_SUBST(KRB_LIBS)
1074 AC_SUBST(TERMCAP_LIBS)
1075
1076 dnl ----------------------------------------------------------------
1077 dnl final output
1078 dnl
1079
1080 AC_OUTPUT( \
1081 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1082 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1083 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1084 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1085 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1086 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1087 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1088 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1089 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1090 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1091 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1092 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1093 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1094 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1095 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1096 include/Makefile:build/top.mk:include/Makefile.in \
1097 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1098 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
1099 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
1100 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
1101 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
1102 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
1103 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
1104 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
1105 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1106 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1107 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1108 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1109 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1110 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1111 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1112 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1113 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1114 tests/Makefile:build/top.mk:tests/Makefile.in \
1115 ,[
1116 date > stamp-h
1117 echo Please \"make depend\" to build dependencies
1118 ])