git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8
   9 dnl Configure.in for OpenLDAP
  10 AC_INIT(include/ldap.h)dnl
  11 AC_CONFIG_AUX_DIR(build)dnl
  12 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  13
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_PREREQ(2.10)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30 AC_SUBST(ldap_subdir)dnl
  31
  32 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  33         if test "$withval" = "no"; then
  34                 ldap_subdir=""
  35         elif test "$withval" != "yes"; then
  36                 ldap_subdir="$withval"
  37         fi
  38 ])dnl
  39
  40 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  41 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  42 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  43 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  44 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  45 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  46 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  47 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  48 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  49         no, [yes no])dnl
  50
  51 dnl General "with" options
  52 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  53         auto, [auto k5 k4 afs yes no])
  54 OL_ARG_WITH(threads,[  --with-threads   use threads],
  55         auto, [auto posix mach lwp yes no manual] )
  56 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  57         auto, [auto yes no manual] )
  58
  59 dnl Server options
  60
  61 dnl LDAPD OPTIONS
  62 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  63 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  64
  65 dnl SLAPD OPTIONS
  66 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  67 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  68 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  69 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  70 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  71 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  72 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  73 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  74 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  75
  76 dnl SLAPD Backend options
  77 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  78 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  79         [auto db2 db gdbm ndbm manual])
  80 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  81         [auto btree hash])
  82
  83 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  84 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  85
  86 dnl SLURPD OPTIONS
  87 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  88 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  89
  90 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  91 AM_ENABLE_STATIC
  92 dnl AM_DISABLE_SHARED
  93 AM_ENABLE_SHARED
  94
  95 dnl General "enable" options
  96 # validate options
  97 if test $ol_enable_referrals = no ; then
  98         if test $ol_enable_dns = yes ; then
  99                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
 100         fi
 101         ol_enable_dns=no
 102 fi
 103
 104 if test $ol_enable_slapd = no ; then
 105         dnl SLAPD was specificallly disabled
 106         if test $ol_enable_ldbm = yes ; then
 107                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 108         fi
 109         if test $ol_enable_passwd = yes ; then
 110                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 111         fi
 112         if test $ol_enable_shell = yes ; then
 113                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 114         fi
 115         if test $ol_enable_aclgroups = yes ; then
 116                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 117         fi
 118         if test $ol_enable_crypt = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
 120         fi
 121         if test $ol_enable_md5 = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
 123         fi
 124         if test $ol_enable_sha1 = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 126         fi
 127         if test $ol_enable_wrappers = yes ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 129         fi
 130         if test $ol_enable_phonetic = yes ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 132         fi
 133         if test $ol_enable_rlookups = yes ; then
 134                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 135         fi
 136         if test $ol_with_ldbm_api != auto ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 138         fi
 139         if test $ol_with_ldbm_type != auto ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 141         fi
 142         if test $ol_enable_slurpd = yes ; then
 143                 AC_MSG_ERROR([slurpd requires slapd])
 144         fi
 145
 146         # force settings to no
 147         ol_enable_ldbm=no
 148         ol_enable_shell=no
 149         ol_enable_passwd=no
 150         ol_enable_aclgroups=no
 151         ol_enable_crypt=no
 152         ol_enable_md5=no
 153         ol_enable_sha1=no
 154         ol_enable_wrappers=no
 155         ol_enable_phonetic=no
 156         ol_enable_rlookups=no
 157         ol_with_ldbm_api=no
 158         ol_with_ldbm_type=no
 159         ol_enable_slurpd=no
 160
 161 elif test $ol_enable_ldbm = no ; then
 162         dnl SLAPD without LDBM
 163
 164         if test $ol_with_ldbm_api != auto ; then
 165                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 166         fi
 167
 168         if test $ol_with_ldbm_type != auto ; then
 169                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 170         fi
 171
 172         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 173                 AC_MSG_ERROR([slapd requires a backend])
 174         fi
 175
 176         ol_with_ldbm_api=no
 177         ol_with_ldbm_type=no
 178
 179 else
 180         dnl SLAPD with LDBM
 181
 182         if test $ol_with_ldbm_api = gdbm -a \
 183                 $ol_with_ldbm_type = btree ; then
 184                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 185         fi
 186         if test $ol_with_ldbm_api = ndbm -a \
 187                 $ol_with_ldbm_type = btree ; then
 188                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 189         fi
 190 fi
 191
 192 if test $ol_enable_slurpd = yes ; then
 193         dnl SLURPD was specifically enabled
 194         if test $ol_with_threads = no ; then
 195                 AC_MSG_ERROR([slurpd requires threads])
 196         fi
 197 fi
 198
 199 AC_MSG_RESULT(done)
 200
 201 AC_CANONICAL_HOST
 202
 203 ## Initialize vars
 204 LDAP_LIBS=
 205 LDBM_LIBS=
 206 LTHREAD_LIBS=
 207 LUTIL_LIBS=
 208
 209 LDAPD_LIBS=
 210 SLAPD_LIBS=
 211 SLURPD_LIBS=
 212
 213 BUILD_LDAPD=no
 214 BUILD_SLAPD=no
 215 BUILD_SLURPD=no
 216
 217 BUILD_LDBM=no
 218 BUILD_PASSWD=no
 219 BUILD_SHELL=no
 220 BUILD_THREAD=no
 221
 222 KRB_LIBS=
 223 TERMCAP_LIBS=
 224
 225 dnl ----------------------------------------------------------------
 226 dnl Checks for programs
 227
 228 AC_PROG_INSTALL
 229 AM_PROG_LIBTOOL
 230 dnl AC_PROG_MAKE_SET
 231
 232 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 233         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 234 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 235 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 236
 237 dnl Checks the compiler and UNIX Variants
 238
 239 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 240         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 241
 242 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 243         AC_MSG_WARN([programs compiled here do run here...])
 244         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 245
 246 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 247         AC_MSG_WARN([programs compiled here do not run here...])
 248         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 249 fi
 250
 251 AC_PROG_CPP
 252
 253 AC_AIX
 254 AC_ISC_POSIX
 255 AC_MINIX
 256
 257 dnl OpenLDAP requires STDC features
 258 AM_PROG_CC_STDC
 259 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 260         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 261 fi
 262
 263 dnl AM_C_PROTOTYPES
 264
 265 dnl Checks for libraries
 266
 267 dnl Find socket()
 268 dnl Likely combinations:
 269 dnl             -lsocket [ -lnsl_s | -lnsl ]
 270 dnl             -linet
 271
 272 AC_CHECK_FUNC(socket, [have_socket=yes], [
 273 dnl
 274 dnl hopefully we won't include too many libraries
 275 dnl
 276         AC_CHECK_LIB(socket, main)
 277         AC_CHECK_LIB(net, main)
 278         AC_CHECK_LIB(nsl_s, main)
 279         AC_CHECK_LIB(nsl, main)
 280         AC_CHECK_LIB(inet, socket)
 281         AC_CHECK_LIB(gen, main)
 282 ])
 283
 284 dnl Check for resolv
 285 AC_CHECK_LIB(resolv, res_search)
 286
 287 dnl HP-UX requires -lV3
 288 AC_CHECK_LIB(V3, sigset)
 289
 290 # ISODE tests
 291 ol_link_isode=no
 292 if test $ol_enable_ldapd != no ; then
 293         dnl look for ISODE libraries
 294         AC_CHECK_LIB(xtpp, main, [
 295                 ol_link_isode=yes
 296                 AC_DEFINE(HAVE_XTPP,1)
 297                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 298                 ],:,[-lxtdsap -lxtisode -losi])
 299         AC_CHECK_LIB(dsap, main, [
 300                 ol_link_isode=yes
 301                 AC_DEFINE(HAVE_DSAP,1)
 302                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 303                 ],:,[-lisode])
 304         AC_CHECK_LIB(isode, main, [
 305                 ol_link_isode=yes
 306                 AC_DEFINE(HAVE_ISODE,1)
 307                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 308                 ],:)
 309 fi
 310
 311 if test $ol_link_isode != no; then
 312         AC_CHECK_LIB(pp, main, [
 313                 AC_DEFINE(HAVE_PP,1)
 314                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 315                 ],:)
 316
 317         AC_PATH_PROG(PEPSY, pepsy)
 318 fi
 319
 320 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 321         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 322
 323         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 324                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 325                         [-lkrb5 -ldes425])
 326
 327                 if test $have_k5 = yes ; then
 328                         ol_with_kerberos=found
 329                         ol_link_kerberos=yes
 330
 331                         AC_DEFINE(HAVE_KERBEROS)
 332
 333                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 334                 fi
 335         fi
 336 fi
 337 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 338         AC_CHECK_HEADERS(krb.h des.h)
 339
 340         if test $ac_cv_header_krb_h = yes ; then
 341                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 342
 343                 if test $have_k4 = yes ; then
 344                         ol_with_kerberos=found
 345                         ol_link_kerberos=yes
 346
 347                         AC_DEFINE(HAVE_KERBEROS)
 348                         KRB_LIBS="-lkrb -ldes"
 349
 350                         AC_CHECK_FUNCS(des_string_to_key)
 351                 fi
 352         fi
 353 fi
 354
 355 ol_link_threads=no
 356 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 357         AC_CHECK_HEADERS(pthread.h sched.h)
 358
 359         if test $ac_cv_header_pthread_h = yes ; then
 360                 OL_POSIX_THREAD_VERSION
 361
 362                 if test $ol_cv_pthread_version = final ; then
 363                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 364                 elif test $ol_cv_pthread_version = draft4 ; then
 365                         AC_DEFINE(HAVE_PTHREADS_D4)
 366                 else
 367                         AC_MSG_ERROR([unknown pthread version])
 368                 fi
 369
 370                 # consider threads found
 371                 ol_with_threads=found
 372
 373                 OL_LINUX_THREADS
 374
 375                 if test $ol_cv_linux_threads = yes ; then
 376                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 377                 fi
 378
 379                 dnl Now the hard part, how to link
 380
 381                 dnl Check for pthread support in current $LIBS
 382                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 383
 384                 if test $ol_link_threads = no ; then
 385                         dnl try -pthread
 386                         AC_CACHE_CHECK([for pthread_create with -pthread],
 387                                 [ol_cv_pthread_flag], [
 388                                 dnl save the flags
 389                                 save_LIBS="$LIBS"
 390                                 LIBS="-pthread $LIBS"
 391                                 AC_TRY_LINK([char pthread();],[
 392                                         pthread_create();
 393                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 394                                 dnl restore the LIBS
 395                                 LIBS="$save_LIBS"
 396                         ])
 397
 398                         if test $ol_cv_pthread_flag = yes ; then
 399                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 400                                 ol_link_threads=posix
 401                         fi
 402                 fi
 403
 404                 if test $ol_link_threads = no ; then
 405                         dnl try -thread
 406                         AC_CACHE_CHECK([for pthread_create with -thread],
 407                                 [ol_cv_thread_flag], [
 408                                 dnl save the flags
 409                                 save_LIBS="$LIBS"
 410                                 LIBS="-thread $LIBS"
 411                                 AC_TRY_LINK([char pthread();],[
 412                                         pthread_create();
 413                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 414                                 dnl restore the LIBS
 415                                 LIBS="$save_LIBS"
 416                         ])
 417
 418                         if test $ol_cv_thread_flag = yes ; then
 419                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 420                                 ol_link_threads=posix
 421                         fi
 422                 fi
 423
 424                 if test $ol_link_threads = no ; then
 425                         dnl try DEC Threads -lpthread -lexc
 426                         save_LIBS="$LIBS"
 427                         AC_CHECK_LIB(pthread, pthread_join, [
 428                                 ol_link_threads=posix
 429                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 430                                 if test $ol_with_yielding_select = auto ; then
 431                                         ol_with_yielding_select=yes
 432                                 fi
 433                                 ],,[-lexc])
 434                         LIBS="$save_LIBS"
 435                 fi
 436
 437                 if test $ol_link_threads = no ; then
 438                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 439                         save_LIBS="$LIBS"
 440                         AC_CHECK_LIB(pthreads, pthread_join, [
 441                                 ol_link_threads=posix
 442                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 443                                 if test $ol_with_yielding_select = auto ; then
 444                                         ol_with_yielding_select=yes
 445                                 fi
 446                                 ],,[-lmach -lexc -lc_r])
 447                         LIBS="$save_LIBS"
 448                 fi
 449
 450                 if test $ol_link_threads = no ; then
 451                         dnl try -lpthread
 452                         save_LIBS="$LIBS"
 453                         AC_CHECK_LIB(pthread, pthread_create, [
 454                                 ol_link_threads=posix
 455                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 456                         LIBS="$save_LIBS"
 457                 fi
 458
 459                 if test $ol_link_threads = no ; then
 460                         dnl try -lc_r
 461                         save_LIBS="$LIBS"
 462                         AC_CHECK_LIB(c_r, pthread_create, [
 463                                 ol_link_threads=posix
 464                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 465                         LIBS="$save_LIBS"
 466                 fi
 467
 468                 if test $ol_link_threads != no ; then
 469                         AC_DEFINE(HAVE_PTHREADS)
 470
 471                         dnl save flags
 472                         save_CPPFLAGS="$CPPFLAGS"
 473                         save_LIBS="$LIBS"
 474                         LIBS="$LTHREAD_LIBS $LIBS"
 475
 476                         dnl All POSIX Thread (final) implementations should have
 477                         dnl sched_yield instead of pthread yield.
 478                         dnl check for both
 479                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 480
 481                         if test $ac_cv_func_sched_yield = no -a \
 482                                 $ac_cv_func_pthread_yield = no ; then
 483                                 dnl Digital UNIX has sched_yield() in -lrt
 484                                 AC_CHECK_LIB(rt, sched_yield,
 485                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 486                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 487                                         ac_cv_func_sched_yield=yes],
 488                                         [ac_cv_func_sched_yield=no])
 489                         fi
 490                         if test $ac_cv_func_sched_yield = no -a \
 491                                 $ac_cv_func_pthread_yield = no ; then
 492                                 dnl Solaris has sched_yield() in -lposix4
 493                                 AC_CHECK_LIB(posix4, sched_yield,
 494                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 495                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 496                                         ac_cv_func_sched_yield=yes],
 497                                         [ac_cv_func_sched_yield=no])
 498                         fi
 499                         if test $ac_cv_func_sched_yield = no -a \
 500                                 $ac_cv_func_pthread_yield = no ; then
 501                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 502                                 AC_MSG_ERROR([POSIX Threads are not usable])
 503                         fi
 504
 505                         dnl Check functions for compatibility
 506                         AC_CHECK_FUNCS(pthread_kill)
 507                         AC_CHECK_FUNCS( \
 508                                 pthread_attr_create pthread_attr_init \
 509                                 pthread_attr_destroy pthread_attr_delete \
 510                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 511                         )
 512
 513                         dnl Check for setconcurreny functions
 514                         AC_CHECK_FUNCS( \
 515                                 pthread_setconcurrency \
 516                                 thr_setconcurrency \
 517                         )
 518
 519                         dnl Check if select causes an yield
 520                         if test $ol_with_yielding_select = auto ; then
 521                                 AC_MSG_CHECKING([if select yields])
 522                                 AC_TRY_RUN([
 523 #include <sys/types.h>
 524 #include <sys/time.h>
 525 #include <unistd.h>
 526 #include <pthread.h>
 527 #ifndef NULL
 528 #define NULL 0
 529 #endif
 530
 531 int fildes[2];
 532
 533 int task(arg)
 534         int *arg;
 535 {
 536         int i;
 537         struct timeval tv;
 538
 539         fd_set rfds;
 540
 541         tv.tv_sec=10;
 542         tv.tv_usec=0;
 543
 544         FD_ZERO(&rfds);
 545         FD_SET(fildes[0], &rfds);
 546
 547         /* we're not interested in any fds */
 548         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 549
 550         if(i < 0) {
 551                 perror("select");
 552                 exit(0);
 553         }
 554
 555         exit(1); /* if we exit here, the select blocked the whole process */
 556 }
 557
 558 int main(argc, argv)
 559         int argc;
 560         char **argv;
 561 {
 562         pthread_t t;
 563
 564         /* create a pipe to select */
 565         if(pipe(&fildes[0])) {
 566                 perror("select");
 567                 exit(0);
 568         }
 569
 570 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 571         (void) pthread_setconcurrency(2);
 572 #else
 573 #ifdef HAVE_THR_SETCONCURRENCY
 574         /* Set Solaris LWP concurrency to 2 */
 575         thr_setconcurrency(2);
 576 #endif
 577 #endif
 578
 579         pthread_create(&t, NULL, (void *) task, NULL);
 580
 581 #if HAVE_SCHED_YIELD
 582         sched_yield();  /* make sure task runs first */
 583 #else
 584 #ifdef HAVE_PTHREAD_YIELD
 585         pthread_yield();        /* make sure task runs first */
 586 #endif
 587 #endif
 588         exit(0);
 589 }
 590                                 ], [ol_pthread_select_yields=yes], [ol_pthread_select_yields=no], [
 591                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])
 592                                 AC_MSG_RESULT($ol_pthread_select_yields)
 593
 594                                 if test $ol_pthread_select_yields = yes ; then
 595                                         ol_with_yielding_select=yes
 596                                 fi
 597                         fi
 598
 599 dnl                     dnl check for reentrant/threadsafe functions
 600 dnl                     AC_CHECK_FUNCS( \
 601 dnl                             feof_unlocked \
 602 dnl                             unlocked_feof \
 603 dnl                             ftrylockfile \
 604 dnl                             flockfile \
 605 dnl                             putc_unlocked \
 606 dnl                             gmtime_r \
 607 dnl                             strtok_r \
 608 dnl                     )
 609
 610                         dnl restore flags
 611                         CPPFLAGS="$save_CPPFLAGS"
 612                         LIBS="$save_LIBS"
 613                 else
 614                         AC_MSG_ERROR([could not link with POSIX Threads])
 615                 fi
 616         fi
 617
 618         if test $ol_with_threads = posix ; then
 619                 AC_MSG_ERROR([could not locate POSIX Threads])
 620         fi
 621 fi
 622
 623 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 624         dnl check for Mach CThreads
 625         AC_CHECK_HEADERS(mach/cthreads.h)
 626         if test $ac_cv_header_mach_cthreads_h = yes ; then
 627                 ol_with_threads=found
 628
 629                 dnl check for cthread support in current $LIBS
 630                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 631
 632                 if test $ol_link_threads = no ; then
 633                         dnl try -all_load
 634                         dnl this test needs work
 635                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 636                                 [ol_cv_cthread_all_load], [
 637                                 dnl save the flags
 638                                 save_LIBS="$LIBS"
 639                                 LIBS="-all_load $LIBS"
 640                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 641                                         cthread_fork((void *)0, (void *)0);
 642                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 643                                 dnl restore the LIBS
 644                                 LIBS="$save_LIBS"
 645                         ])
 646
 647                         if test $ol_cv_cthread_all_load = yes ; then
 648                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 649                                 ol_link_threads=mach
 650                         fi
 651                 fi
 652
 653                 if test $ol_link_threads != no ; then
 654                         : check for cthread specific functionality here
 655                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 656                 else
 657                         AC_MSG_ERROR([could not link with Mach CThreads])
 658                 fi
 659         fi
 660
 661         if test $ol_with_threads = mach ; then
 662                 AC_MSG_ERROR([could not locate Mach CThreads])
 663         fi
 664 fi
 665
 666 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 667         dnl check for SunOS5 LWP
 668         AC_CHECK_HEADERS(thread.h synch.h)
 669         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 670                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 671
 672                 if test $have_thr = yes ; then
 673                         AC_DEFINE(HAVE_THR)
 674                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 675                         ol_link_threads=thr
 676
 677                         if test $ol_with_yielding_select = auto ; then
 678                                 ol_with_yielding_select=yes
 679                         fi
 680                 fi
 681         fi
 682
 683         dnl check for SunOS4 LWP
 684         AC_CHECK_HEADERS(lwp/lwp.h)
 685         if test $ac_cv_header_lwp_lwp_h = yes ; then
 686                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 687
 688                 if test $have_lwp = yes ; then
 689                         AC_DEFINE(HAVE_LWP)
 690                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 691                         ol_link_threads=lwp
 692
 693                         if test $ol_with_yielding_select = auto ; then
 694                                 ol_with_yielding_select=no
 695                         fi
 696                 fi
 697         fi
 698 fi
 699
 700 if test $ol_with_yielding_select = yes ; then
 701         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 702 fi
 703
 704 if test $ol_with_threads = manual ; then
 705         dnl User thinks he can manually configure threads.
 706         ol_link_threads=yes
 707
 708         AC_MSG_WARN([thread defines and link options must be set manually])
 709
 710         AC_CHECK_HEADERS(pthread.h sched.h)
 711         AC_CHECK_FUNCS(sched_yield pthread_yield)
 712         OL_LINUX_THREADS
 713
 714         AC_CHECK_HEADERS(mach/cthreads.h)
 715         AC_CHECK_HEADERS(lwp/lwp.h)
 716         AC_CHECK_HEADERS(thread.h synch.h)
 717 fi
 718
 719 if test $ol_with_threads != no ; then
 720         dnl needed to get reentrant/threadsafe versions
 721         dnl
 722         AC_DEFINE(_REENTRANT,1)
 723         AC_DEFINE(_THREAD_SAFE,1)
 724         AC_DEFINE(_THREADSAFE,1)
 725
 726         dnl this might cause the errno symbol to be
 727         dnl replaced with a function to get a thread specific errno.
 728         dnl check to see if everything needs to be compiled
 729         dnl with the thread libraries
 730         AC_CACHE_CHECK([for thread specific errno],
 731                 [ol_cv_errno_thread_specific], [
 732                 AC_TRY_LINK([
 733 #include <errno.h>
 734                         ], [
 735 int x = errno;
 736                         ],
 737                         [ol_cv_errno_thread_specific=yes],
 738                         [ol_cv_errno_thread_specific=no])
 739         ])
 740
 741         if test $ol_cv_errno_thread_specific != yes ; then
 742                 LIBS="$LTHREAD_LIBS $LIBS"
 743                 LTHREAD_LIBS=""
 744         fi
 745 fi
 746
 747 dnl ----------------------------------------------------------------
 748
 749 if test $ol_link_threads = no ; then
 750         if test $ol_with_threads = yes ; then
 751                 AC_MSG_ERROR([no suitable thread support])
 752         fi
 753
 754         if test $ol_with_threads = auto ; then
 755                 AC_MSG_WARN([no suitable thread support, disabling threads])
 756                 ol_with_threads=no
 757         fi
 758
 759         AC_DEFINE(NO_THREADS,1)
 760         LTHREAD_LIBS=""
 761 fi
 762
 763 ol_link_ldbm=no
 764 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 765         OL_BERKELEY_DB2
 766
 767         if test $ol_cv_berkeley_db2 = yes ; then
 768                 ol_link_ldbm=db2
 769                 ol_with_ldbm_api=db2
 770
 771                 if test $ol_with_ldbm_type = hash ; then
 772                         AC_DEFINE(LDBM_USE_DBHASH,1)
 773                 else
 774                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 775                 fi
 776
 777                 dnl $ol_cv_lib_db2 should be yes or -ldb
 778                 dnl (it could be no, but that would be an error
 779                 if test $ol_cv_lib_db2 != yes ; then
 780                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 781                 fi
 782         fi
 783 fi
 784
 785 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 786         OL_BERKELEY_DB
 787
 788         if test $ol_cv_berkeley_db = yes ; then
 789                 ol_link_ldbm=db
 790                 ol_with_ldbm_api=db
 791
 792                 if test $ol_with_ldbm_type = hash ; then
 793                         AC_DEFINE(LDBM_USE_DBHASH,1)
 794                 else
 795                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 796                 fi
 797
 798                 dnl $ol_cv_lib_db should be yes or -ldb
 799                 dnl (it could be no, but that would be an error
 800                 if test $ol_cv_lib_db != yes ; then
 801                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 802                 fi
 803         fi
 804 fi
 805
 806 if test $ol_with_ldbm_api = manual ; then
 807         dnl User thinks he can manually configure LDBM api.
 808         ol_link_ldbm=yes
 809
 810         AC_MSG_WARN([LDBM defines and link options must be set manually])
 811
 812         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 813 fi
 814
 815 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 816         AC_MSG_WARN(Could not find LDBM with BTREE support)
 817         ol_with_ldbm_api=none
 818 fi
 819
 820 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 821         OL_GDBM
 822
 823         if test $ol_cv_gdbm = yes ; then
 824                 ol_link_ldbm=gdbm
 825                 ol_with_ldbm_api=gdbm
 826
 827                 if test $ol_cv_lib_gdbm != yes ; then
 828                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 829                 fi
 830         fi
 831 fi
 832
 833 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 834         OL_NDBM
 835
 836         if test $ol_cv_ndbm = yes ; then
 837                 if test $ol_with_ldbm_api = auto ; then
 838                         AC_MSG_WARN([Attempting to use NDBM.  Functionality will be limited.])
 839                 fi
 840
 841                 ol_link_ldbm=ndbm
 842                 ol_with_ldbm_api=ndbm
 843
 844                 if test $ol_cv_lib_ndbm != yes ; then
 845                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 846                 fi
 847         fi
 848 fi
 849
 850 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 851         AC_MSG_WARN(could not find suitable LDBM backend)
 852         if test $ol_enable_ldbm = yes ; then
 853                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 854         fi
 855
 856         AC_MSG_WARN(disabling LDBM)
 857         ol_enable_ldbm=no
 858 fi
 859
 860 if test $ol_enable_wrappers = yes ; then
 861         AC_CHECK_LIB(wrap, hosts_access,
 862                 [have_wrappers=yes], [have_wrappers=no])
 863
 864         if test $have_wrappers = yes ; then
 865                 AC_DEFINE(HAVE_TCPD)
 866                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 867         else
 868                 AC_MSG_WARN(could not find -lwrap)
 869                 if test $ol_enable_wrappers = yes ; then
 870                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 871                 fi
 872
 873                 AC_MSG_WARN(disabling wrappers support)
 874                 ol_enable_wrappers=no
 875         fi
 876
 877 fi
 878
 879 # ud needs termcap (should insert check here)
 880 ol_link_termcap=no
 881 AC_CHECK_HEADERS(termcap.h ncurses.h)
 882
 883 if test $ol_link_termcap = no ; then
 884         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 885         if test $have_termcap = yes ; then
 886                 AC_DEFINE(HAVE_TERMCAP)
 887                 ol_link_termcap=yes
 888                 TERMCAP_LIBS=-ltermcap
 889         fi
 890 fi
 891
 892 if test $ol_link_termcap = no ; then
 893         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 894         if test $have_ncurses = yes ; then
 895                 AC_DEFINE(HAVE_NCURSES)
 896                 ol_link_termcap=yes
 897                 TERMCAP_LIBS=-lncurses
 898         fi
 899 fi
 900
 901 if test $ol_link_termcap = no ; then
 902         AC_DEFINE(NO_TERMCAP,1)
 903         TERMCAP_LIBS=
 904 fi
 905
 906 # FreeBSD (and others) have crypt(3) in -lcrypt
 907 if test $ol_enable_crypt != no ; then
 908         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 909                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 910                         have_crypt=yes], [have_crypt=no])])
 911
 912         if test $have_crypt = yes ; then
 913                 AC_DEFINE(HAVE_CRYPT,1)
 914         else
 915                 AC_MSG_WARN(could not find crypt)
 916                 if test $ol_enable_crypt = yes ; then
 917                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 918                 fi
 919
 920                 AC_MSG_WARN(disabling crypt support)
 921                 ol_enable_crypt=no
 922         fi
 923 fi
 924
 925 # FreeBSD (and others) have setproctitle(3) in -lutil
 926 if test $ol_enable_proctitle != no ; then
 927         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 928                 AC_CHECK_LIB(util, setproctitle,
 929                         [have_setproctitle=yes
 930                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 931                         [have_setproctitle=no
 932                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 933
 934         if test $have_setproctitle = yes ; then
 935                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 936         fi
 937 fi
 938
 939 dnl ----------------------------------------------------------------
 940 dnl Checks for header files.
 941 AC_HEADER_STDC
 942
 943 if test $ac_cv_header_stdc != yes; then
 944         AC_MSG_WARN([could not Standard C compliant headers])
 945 fi
 946
 947 AC_HEADER_DIRENT
 948 AC_HEADER_SYS_WAIT
 949 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 950 if test $am_cv_sys_posix_termios = yes ; then
 951         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
 952 fi
 953
 954 AC_CHECK_HEADERS(       \
 955         crypt.h                 \
 956         errno.h                 \
 957         fcntl.h                 \
 958         filio.h                 \
 959         getopt.h                \
 960         libutil.h               \
 961         limits.h                \
 962         malloc.h                \
 963         memory.h                \
 964         regex.h                 \
 965         psap.h                  \
 966         pwd.h                   \
 967         sgtty.h                 \
 968         stdarg.h                \
 969         stddef.h                \
 970         string.h                \
 971         strings.h               \
 972         sys/file.h              \
 973         sys/filio.h             \
 974         sys/errno.h             \
 975         sys/ioctl.h             \
 976         sys/param.h             \
 977         sys/resource.h  \
 978         sys/socket.h    \
 979         sys/syslog.h    \
 980         sys/time.h              \
 981         sys/types.h             \
 982         syslog.h                \
 983         termios.h               \
 984         unistd.h                \
 985 )
 986
 987 dnl ----------------------------------------------------------------
 988 dnl Checks for typedefs, structures, and compiler characteristics.
 989 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
 990 AC_TYPE_MODE_T
 991 AC_TYPE_OFF_T
 992 AC_TYPE_PID_T
 993 AM_TYPE_PTRDIFF_T
 994 AC_TYPE_SIGNAL
 995 AC_TYPE_SIZE_T
 996 AC_STRUCT_ST_BLKSIZE
 997 AC_HEADER_TIME
 998 AC_STRUCT_TM
 999
1000 OL_C_UPPER_LOWER
1001 AC_C_CONST
1002
1003 if test $cross_compiling = yes ; then
1004         AC_DEFINE(CROSS_COMPILING, 1)
1005 else
1006         AC_C_BIGENDIAN
1007         AC_CHECK_SIZEOF(short)
1008         AC_CHECK_SIZEOF(int)
1009         AC_CHECK_SIZEOF(long)
1010 fi
1011
1012 dnl ----------------------------------------------------------------
1013 dnl Checks for library functions.
1014 AC_FUNC_MEMCMP
1015 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1016 AC_FUNC_STRFTIME
1017 dnl AM_FUNC_STRTOD
1018 AC_FUNC_VPRINTF
1019
1020 if test $ac_cv_func_vprintf = yes ; then
1021         dnl check for vsnprintf
1022         AC_CHECK_FUNCS(vsnprintf)
1023 fi
1024
1025 AC_FUNC_WAIT3
1026
1027 AC_CHECK_FUNCS(         \
1028         bcopy                   \
1029         flock                   \
1030         getdtablesize   \
1031         gethostname             \
1032         getpwuid                \
1033         gettimeofday    \
1034         lockf                   \
1035         memcpy                  \
1036         memmove                 \
1037         mkstemp                 \
1038         res_search              \
1039         select                  \
1040         setpwfile               \
1041         setsid                  \
1042         signal                  \
1043         sigset                  \
1044         snprintf                \
1045         socket                  \
1046         strerror                \
1047         strpbrk                 \
1048         strrchr                 \
1049         strsep                  \
1050         strstr                  \
1051         strtok                  \
1052         strtol                  \
1053         strtoul                 \
1054         sysconf                 \
1055         waitpid                 \
1056 )
1057
1058 dnl We actually may need to replace more than this.
1059 AC_REPLACE_FUNCS(getopt strdup tempnam)
1060
1061 dnl ----------------------------------------------------------------
1062 # Check Configuration
1063 OL_SYS_ERRLIST
1064
1065 dnl ----------------------------------------------------------------
1066 dnl Sort out defines
1067
1068 if test $ol_enable_debug != no ; then
1069         AC_DEFINE(LDAP_DEBUG,1)
1070 fi
1071 dnl     if test $ol_enable_syslog != no ; then
1072 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1073 dnl     fi
1074 if test $ol_enable_libui = yes ; then
1075         AC_DEFINE(LDAP_LIBUI,1)
1076 fi
1077 if test $ol_enable_cache = no ; then
1078         AC_DEFINE(LDAP_NOCACHE,1)
1079 fi
1080 if test $ol_enable_dns != no ; then
1081         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION,1)
1082 fi
1083 if test $ol_enable_proctitle != no ; then
1084         AC_DEFINE(LDAP_PROCTITLE,1)
1085 fi
1086 if test $ol_enable_referrals != no ; then
1087         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION,1)
1088 fi
1089 if test $ol_enable_cldap != no ; then
1090         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1091 fi
1092
1093 if test $ol_enable_aclgroups != no ; then
1094         AC_DEFINE(SLAPD_ACLGROUPS,1)
1095 fi
1096 if test $ol_enable_crypt != no ; then
1097         AC_DEFINE(SLAPD_CRYPT,1)
1098 fi
1099 if test $ol_enable_md5 != no ; then
1100         AC_DEFINE(SLAPD_MD5,1)
1101 fi
1102 if test $ol_enable_sha1 != no ; then
1103         AC_DEFINE(SLAPD_SHA1,1)
1104 fi
1105 if test $ol_enable_phonetic != no ; then
1106         AC_DEFINE(SLAPD_PHONETIC,1)
1107 fi
1108 if test $ol_enable_rlookups != no ; then
1109         AC_DEFINE(SLAPD_RLOOKUPS,1)
1110 fi
1111
1112 if test $ol_link_ldbm != no ; then
1113         AC_DEFINE(SLAPD_LDBM,1)
1114         BUILD_SLAPD=yes
1115         BUILD_LDBM=yes
1116 fi
1117
1118 if test $ol_enable_passwd != no ; then
1119         AC_DEFINE(SLAPD_PASSWD,1)
1120         BUILD_SLAPD=yes
1121         BUILD_PASSWD=yes
1122 fi
1123
1124 if test $ol_enable_shell != no ; then
1125         AC_DEFINE(SLAPD_SHELL,1)
1126         BUILD_SLAPD=yes
1127         BUILD_SHELL=yes
1128 fi
1129
1130 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1131         $BUILD_SLAPD = yes ; then
1132         BUILD_SLURPD=yes
1133 fi
1134
1135 if test $ol_link_isode != no ; then
1136         BUILD_LDAPD=yes
1137 fi
1138
1139 dnl ----------------------------------------------------------------
1140
1141 AC_SUBST(BUILD_LDAPD)
1142 AC_SUBST(BUILD_SLAPD)
1143   AC_SUBST(BUILD_LDBM)
1144   AC_SUBST(BUILD_PASSWD)
1145   AC_SUBST(BUILD_SHELL)
1146 AC_SUBST(BUILD_SLURPD)
1147
1148
1149 AC_SUBST(LDAP_LIBS)
1150 AC_SUBST(LDAPD_LIBS)
1151 AC_SUBST(SLAPD_LIBS)
1152 AC_SUBST(SLURPD_LIBS)
1153 AC_SUBST(LDBM_LIBS)
1154 AC_SUBST(LTHREAD_LIBS)
1155 AC_SUBST(LUTIL_LIBS)
1156
1157 AC_SUBST(KRB_LIBS)
1158 AC_SUBST(TERMCAP_LIBS)
1159
1160 dnl ----------------------------------------------------------------
1161 dnl final output
1162 dnl
1163
1164 AC_OUTPUT( \
1165 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1166 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1167 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1168 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1169 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1170 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1171 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1172 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1173 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1174 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1175 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1176 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1177 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1178 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1179 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1180 include/Makefile:build/top.mk:include/Makefile.in \
1181 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1182 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1183 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1184 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1185 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1186 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1187 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1188 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1189 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1190 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1191 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1192 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1193 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1194 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1195 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1196 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1197 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1198 tests/Makefile:build/top.mk:tests/Makefile.in \
1199 ,[
1200 date > stamp-h
1201 echo Please \"make depend\" to build dependencies
1202 ])