git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  14
  15 dnl Do not use AutoConf 2.12; it produces a configuration script
  16 dnl that causes an "internal 2K buffer" error on HPUX when run
  17 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  18 AC_PREREQ(2.10)dnl Required Autoconf version
  19
  20 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  21
  22 dnl
  23 dnl Start Args
  24 AC_MSG_CHECKING(configure arguments)
  25 AC_PREFIX_DEFAULT(/usr/local)
  26
  27 top_builddir=`pwd`
  28 AC_SUBST(top_builddir)dnl
  29
  30 ldap_subdir="openldap"
  31
  32 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  33         if test "$withval" = "no"; then
  34                 ldap_subdir=""
  35         elif test "$withval" != "yes"; then
  36                 ldap_subdir="$withval"
  37         fi
  38 ])dnl
  39
  40 AC_SUBST(ldap_subdir)dnl
  41
  42 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  43 ol_enable_syslog=no
  44 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  45 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  46 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  47 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  48 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  49 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  50 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  51         no, [yes no])dnl
  52
  53
  54 dnl General "with" options
  55 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  56
  57 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  58         auto, [auto k5 k4 afs yes no])
  59 OL_ARG_WITH(threads,[  --with-threads   use threads],
  60         auto, [auto posix mach lwp yes no manual] )
  61 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  62         auto, [auto yes no manual] )
  63
  64 dnl Server options
  65
  66 dnl LDAPD OPTIONS
  67 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  68 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  69
  70 dnl SLAPD OPTIONS
  71 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  72 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  73 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  74 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  75 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  76 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  77 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  78 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  79
  80 dnl SLAPD Backend options
  81 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  82 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  83         [auto db2 db gdbm ndbm manual])
  84 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  85         [auto btree hash])
  86
  87 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  88 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  89
  90 dnl SLURPD OPTIONS
  91 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  92 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  93
  94 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  95 AM_ENABLE_STATIC
  96 dnl AM_DISABLE_SHARED
  97 AM_ENABLE_SHARED
  98
  99 dnl General "enable" options
 100 # validate options
 101 if test $ol_enable_referrals = no ; then
 102         if test $ol_enable_dns = yes ; then
 103                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
 104         fi
 105         ol_enable_dns=no
 106 fi
 107
 108 if test $ol_enable_slapd = no ; then
 109         dnl SLAPD was specificallly disabled
 110         if test $ol_enable_ldbm = yes ; then
 111                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 112         fi
 113         if test $ol_enable_passwd = yes ; then
 114                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 115         fi
 116         if test $ol_enable_shell = yes ; then
 117                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 118         fi
 119         if test $ol_enable_aclgroups = yes ; then
 120                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 121         fi
 122         if test $ol_enable_wrappers = yes ; then
 123                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 124         fi
 125         if test $ol_enable_phonetic = yes ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 127         fi
 128         if test $ol_enable_rlookups = yes ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 130         fi
 131         if test $ol_with_ldbm_api != auto ; then
 132                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 133         fi
 134         if test $ol_with_ldbm_type != auto ; then
 135                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 136         fi
 137         if test $ol_enable_slurpd = yes ; then
 138                 AC_MSG_ERROR([slurpd requires slapd])
 139         fi
 140
 141         # force settings to no
 142         ol_enable_ldbm=no
 143         ol_enable_shell=no
 144         ol_enable_passwd=no
 145         ol_enable_aclgroups=no
 146         ol_enable_wrappers=no
 147         ol_enable_phonetic=no
 148         ol_enable_rlookups=no
 149         ol_with_ldbm_api=no
 150         ol_with_ldbm_type=no
 151         ol_enable_slurpd=no
 152
 153 elif test $ol_enable_ldbm = no ; then
 154         dnl SLAPD without LDBM
 155
 156         if test $ol_with_ldbm_api != auto ; then
 157                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 158         fi
 159
 160         if test $ol_with_ldbm_type != auto ; then
 161                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 162         fi
 163
 164         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 165                 AC_MSG_ERROR([slapd requires a backend])
 166         fi
 167
 168         ol_with_ldbm_api=no
 169         ol_with_ldbm_type=no
 170
 171 else
 172         dnl SLAPD with LDBM
 173
 174         if test $ol_with_ldbm_api = gdbm -a \
 175                 $ol_with_ldbm_type = btree ; then
 176                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 177         fi
 178         if test $ol_with_ldbm_api = ndbm -a \
 179                 $ol_with_ldbm_type = btree ; then
 180                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 181         fi
 182 fi
 183
 184 if test $ol_enable_slurpd = yes ; then
 185         dnl SLURPD was specifically enabled
 186         if test $ol_with_threads = no ; then
 187                 AC_MSG_ERROR([slurpd requires threads])
 188         fi
 189 fi
 190
 191 AC_MSG_RESULT(done)
 192
 193 AC_CANONICAL_HOST
 194
 195 ## Initialize vars
 196 LDAP_LIBS=
 197 LDBM_LIBS=
 198 LTHREAD_LIBS=
 199 LUTIL_LIBS=
 200
 201 LDAPD_LIBS=
 202 SLAPD_LIBS=
 203 SLURPD_LIBS=
 204
 205 BUILD_LDAPD=no
 206 BUILD_SLAPD=no
 207 BUILD_SLURPD=no
 208
 209 BUILD_LDBM=no
 210 BUILD_PASSWD=no
 211 BUILD_SHELL=no
 212 BUILD_THREAD=no
 213
 214 KRB_LIBS=
 215 TERMCAP_LIBS=
 216
 217 dnl ----------------------------------------------------------------
 218 dnl Checks for programs
 219
 220 AC_PROG_INSTALL
 221 AM_PROG_LIBTOOL
 222 dnl AC_PROG_MAKE_SET
 223
 224 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 225         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 226 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 227 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 228
 229 dnl Checks the compiler and UNIX Variants
 230
 231 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 232         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 233
 234 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 235         AC_MSG_WARN([programs compiled here do run here...])
 236         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 237
 238 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 239         AC_MSG_WARN([programs compiled here do not run here...])
 240         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 241 fi
 242
 243 AC_PROG_CPP
 244
 245 AC_AIX
 246 AC_ISC_POSIX
 247 AC_MINIX
 248
 249 dnl OpenLDAP requires STDC features
 250 AM_PROG_CC_STDC
 251 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 252         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 253 fi
 254
 255 dnl AM_C_PROTOTYPES
 256
 257 dnl Checks for libraries
 258
 259 dnl Find socket()
 260 dnl Likely combinations:
 261 dnl             -lsocket [ -lnsl_s | -lnsl ]
 262 dnl             -linet
 263
 264 AC_CHECK_FUNC(socket, [have_socket=yes], [
 265 dnl
 266 dnl hopefully we won't include too many libraries
 267 dnl
 268         AC_CHECK_LIB(socket, main)
 269         AC_CHECK_LIB(net, main)
 270         AC_CHECK_LIB(nsl_s, main)
 271         AC_CHECK_LIB(nsl, main)
 272         AC_CHECK_LIB(inet, socket)
 273         AC_CHECK_LIB(gen, main)
 274 ])
 275
 276 dnl Check for resolver routines
 277 AC_CHECK_LIB(bind, res_search)
 278 AC_CHECK_LIB(resolv, res_search)
 279
 280 dnl HP-UX requires -lV3
 281 AC_CHECK_LIB(V3, sigset)
 282
 283 # ISODE tests
 284 ol_link_isode=no
 285 if test $ol_enable_ldapd != no ; then
 286         dnl look for ISODE libraries
 287         AC_CHECK_LIB(xtpp, main, [
 288                 ol_link_isode=yes
 289                 AC_DEFINE(HAVE_XTPP,1)
 290                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 291                 ],:,[-lxtdsap -lxtisode -losi])
 292         AC_CHECK_LIB(dsap, main, [
 293                 ol_link_isode=yes
 294                 AC_DEFINE(HAVE_DSAP,1)
 295                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 296                 ],:,[-lisode])
 297         AC_CHECK_LIB(isode, main, [
 298                 ol_link_isode=yes
 299                 AC_DEFINE(HAVE_ISODE,1)
 300                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 301                 ],:)
 302 fi
 303
 304 if test $ol_link_isode != no; then
 305         AC_CHECK_LIB(pp, main, [
 306                 AC_DEFINE(HAVE_PP,1)
 307                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 308                 ],:)
 309
 310         AC_PATH_PROG(PEPSY, pepsy)
 311 fi
 312
 313 dnl
 314 dnl check for kerberos
 315 dnl
 316 ol_link_kerberos=no
 317
 318 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 319         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 320
 321         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 322                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 323                         [-lkrb5 -ldes425])
 324
 325                 if test $have_k5 = yes ; then
 326                         ol_with_kerberos=found
 327                         ol_link_kerberos=yes
 328
 329                         AC_DEFINE(HAVE_KERBEROS)
 330                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 331                 fi
 332         fi
 333 fi
 334
 335 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 336         AC_CHECK_HEADERS(krb.h des.h)
 337
 338         if test $ac_cv_header_krb_h = yes ; then
 339                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 340
 341                 if test $have_k4 = yes ; then
 342                         ol_with_kerberos=found
 343                         ol_link_kerberos=yes
 344
 345                         AC_DEFINE(HAVE_KERBEROS)
 346                         KRB_LIBS="-lkrb -ldes"
 347                 fi
 348         fi
 349 fi
 350
 351 dnl     if test $ol_link_kerberos = yes ; then
 352 dnl             save_LIBS=$LIBS
 353 dnl             LIBS="$KRB_LIBS $LIBS"
 354 dnl             AC_CHECK_FUNCS(des_string_to_key)
 355 dnl             LIBS=$save_LIBS
 356 dnl fi
 357
 358 ol_link_threads=no
 359 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 360         -o $ol_with_threads = posix ; then
 361
 362         AC_CHECK_HEADERS(pthread.h sched.h)
 363
 364         if test $ac_cv_header_pthread_h = yes ; then
 365                 OL_POSIX_THREAD_VERSION
 366
 367                 if test $ol_cv_pthread_version = final ; then
 368                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 369                 elif test $ol_cv_pthread_version = draft4 ; then
 370                         AC_DEFINE(HAVE_PTHREADS_D4)
 371                 else
 372                         AC_MSG_ERROR([unknown pthread version])
 373                 fi
 374
 375                 # consider threads found
 376                 ol_with_threads=found
 377
 378                 OL_LINUX_THREADS
 379
 380                 if test $ol_cv_linux_threads = yes ; then
 381                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 382                 fi
 383
 384                 dnl Now the hard part, how to link
 385
 386                 dnl Check for pthread support in current $LIBS
 387                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 388
 389                 if test $ol_link_threads = no ; then
 390                         dnl try -pthread
 391                         AC_CACHE_CHECK([for pthread_create with -pthread],
 392                                 [ol_cv_pthread_flag], [
 393                                 dnl save the flags
 394                                 save_LIBS="$LIBS"
 395                                 LIBS="-pthread $LIBS"
 396                                 AC_TRY_LINK([char pthread();],[
 397                                         pthread_create();
 398                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 399                                 dnl restore the LIBS
 400                                 LIBS="$save_LIBS"
 401                         ])
 402
 403                         if test $ol_cv_pthread_flag = yes ; then
 404                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 405                                 ol_link_threads=posix
 406                         fi
 407                 fi
 408
 409                 if test $ol_link_threads = no ; then
 410                         dnl try -pthreads
 411                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 412                                 [ol_cv_pthreads_flag], [
 413                                 dnl save the flags
 414                                 save_LIBS="$LIBS"
 415                                 LIBS="-pthreads $LIBS"
 416                                 AC_TRY_LINK([char pthread();],[
 417                                         pthread_create();
 418                                         ], ol_cv_pthreads_flag=yes, ol_cv_pthreads_flag=no)
 419                                 dnl restore the LIBS
 420                                 LIBS="$save_LIBS"
 421                         ])
 422
 423                         if test $ol_cv_pthreads_flag = yes ; then
 424                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 425                                 ol_link_threads=posix
 426                         fi
 427                 fi
 428
 429                 if test $ol_link_threads = no ; then
 430                         dnl try -thread
 431                         AC_CACHE_CHECK([for pthread_create with -thread],
 432                                 [ol_cv_thread_flag], [
 433                                 dnl save the flags
 434                                 save_LIBS="$LIBS"
 435                                 LIBS="-thread $LIBS"
 436                                 AC_TRY_LINK([char pthread();],[
 437                                         pthread_create();
 438                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 439                                 dnl restore the LIBS
 440                                 LIBS="$save_LIBS"
 441                         ])
 442
 443                         if test $ol_cv_thread_flag = yes ; then
 444                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 445                                 ol_link_threads=posix
 446                         fi
 447                 fi
 448
 449                 if test $ol_link_threads = no ; then
 450                         dnl try DEC Threads -lpthread -lexc
 451                         save_LIBS="$LIBS"
 452                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 453                                 ol_link_threads=posix
 454                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 455                                 if test $ol_with_yielding_select = auto ; then
 456                                         ol_with_yielding_select=yes
 457                                 fi
 458                                 ],,[-lexc])
 459                         LIBS="$save_LIBS"
 460                 fi
 461
 462                 if test $ol_link_threads = no ; then
 463                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 464                         save_LIBS="$LIBS"
 465                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 466                                 ol_link_threads=posix
 467                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 468                                 if test $ol_with_yielding_select = auto ; then
 469                                         ol_with_yielding_select=yes
 470                                 fi
 471                                 ],,[-lmach -lexc -lc_r])
 472                         LIBS="$save_LIBS"
 473                 fi
 474
 475                 if test $ol_link_threads = no ; then
 476                         dnl try -lpthread
 477                         save_LIBS="$LIBS"
 478                         AC_CHECK_LIB(pthread, pthread_create, [
 479                                 ol_link_threads=posix
 480                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 481                         LIBS="$save_LIBS"
 482                 fi
 483
 484                 if test $ol_link_threads = no ; then
 485                         dnl try -lc_r
 486                         save_LIBS="$LIBS"
 487                         AC_CHECK_LIB(c_r, pthread_create, [
 488                                 ol_link_threads=posix
 489                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 490                         LIBS="$save_LIBS"
 491                 fi
 492
 493                 if test $ol_link_threads = no ; then
 494                         dnl try -lpthreads
 495                         save_LIBS="$LIBS"
 496                         AC_CHECK_LIB(pthreads, pthread_create, [
 497                                 ol_link_threads=posix
 498                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"])
 499                         LIBS="$save_LIBS"
 500                 fi
 501
 502                 dnl IRIX Pthread check
 503                 if test $ol_link_threads = no ; then
 504                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 505                         save_LIBS="$LIBS"
 506                         AC_CHECK_LIB(pthreads, pthread_join, [
 507                                 ol_link_threads=posix
 508                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 509                                 ],[-Wl,-woff,85])
 510                         LIBS="$save_LIBS"
 511                 fi
 512
 513                 dnl HP-UX 11 Pthread check
 514                 if test $ol_link_threads = no; then
 515                         save_LIBS="$LIBS"
 516                         LIBS="$LIBS -lpthread"
 517                         AC_MSG_CHECKING([for pthread_create() in HP-UX -lpthread])
 518                         ol_try_pthread_hpux_11=no
 519                         AC_CACHE_VAL(ol_cv_pthread_hpux_11,[
 520                                 AC_TRY_LINK([
 521 #include <pthread.h>
 522 #include <elf.h>
 523 #ifndef ELFABI_HPUX_REL11
 524         die horribly
 525 #endif
 526                                 ], [pthread_create(NULL, NULL, NULL, NULL);],
 527                                         ol_try_pthread_hpux_11=yes
 528                                         ol_cv_pthread_hpux_11=yes,
 529                                         ol_cv_pthread_hpux_11=no)])
 530                         AC_MSG_RESULT(yes)
 531                         LIBS="$save_LIBS"
 532
 533                         if test $ol_cv_pthread_hpux_11=yes ; then
 534                                 ol_link_threads=posix
 535                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"
 536                                 if test $ol_try_pthread_hpux_11=yes ; then
 537                                         dnl Some tests below may fail, cause we aint including
 538                                         dnl pthread.h. Force appropriate ones to yes
 539                                         ac_cv_func_pthread_attr_init=yes
 540                                 fi
 541                         fi
 542                 fi
 543
 544                 if test $ol_link_threads != no ; then
 545                         AC_DEFINE(HAVE_PTHREADS)
 546
 547                         dnl save flags
 548                         save_CPPFLAGS="$CPPFLAGS"
 549                         save_LIBS="$LIBS"
 550                         LIBS="$LTHREAD_LIBS $LIBS"
 551
 552                         dnl All POSIX Thread (final) implementations should have
 553                         dnl sched_yield instead of pthread yield.
 554                         dnl check for both
 555                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 556
 557                         if test $ac_cv_func_sched_yield = no -a \
 558                                 $ac_cv_func_pthread_yield = no ; then
 559                                 dnl Digital UNIX has sched_yield() in -lrt
 560                                 AC_CHECK_LIB(rt, sched_yield,
 561                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 562                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 563                                         ac_cv_func_sched_yield=yes],
 564                                         [ac_cv_func_sched_yield=no])
 565                         fi
 566                         if test $ac_cv_func_sched_yield = no -a \
 567                                 $ac_cv_func_pthread_yield = no ; then
 568                                 dnl Solaris has sched_yield() in -lposix4
 569                                 AC_CHECK_LIB(posix4, sched_yield,
 570                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 571                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 572                                         ac_cv_func_sched_yield=yes],
 573                                         [ac_cv_func_sched_yield=no])
 574                         fi
 575                         if test $ac_cv_func_sched_yield = no -a \
 576                                 $ac_cv_func_pthread_yield = no ; then
 577                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 578                         fi
 579
 580                         dnl Check functions for compatibility
 581                         AC_CHECK_FUNCS(pthread_kill)
 582                         AC_CHECK_FUNCS( \
 583                                 pthread_attr_create pthread_attr_init \
 584                                 pthread_attr_destroy pthread_attr_delete \
 585                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 586                         )
 587
 588                         dnl Check for setconcurreny functions
 589                         AC_CHECK_FUNCS( \
 590                                 pthread_setconcurrency \
 591                                 thr_setconcurrency \
 592                         )
 593
 594                         AC_MSG_CHECKING([if pthread_create() works])
 595                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 596                         AC_TRY_RUN([
 597 #include <pthread.h>
 598 #ifndef NULL
 599 #define NULL (void*)0
 600 #endif
 601
 602 static void *task(p)
 603         void *p;
 604 {
 605         return (void *) (p == NULL);
 606 }
 607
 608 int main(argc, argv)
 609         int argc;
 610         char **argv;
 611 {
 612         pthread_t t;
 613         exit(pthread_create(&t, NULL, task, NULL));
 614 }
 615 ],
 616                                 [ol_cv_pthread_create_works=yes],
 617                                 [ol_cv_pthread_create_works=no],
 618                                 [dnl assume yes
 619                                 ol_cv_pthread_create_works=yes])])
 620                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 621
 622                         if test $ol_cv_pthread_create_works = no ; then
 623                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 624                         fi
 625
 626                         dnl Check if select causes an yield
 627                         if test $ol_with_yielding_select = auto ; then
 628                                 AC_MSG_CHECKING([if select yields when using pthreads])
 629                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 630                                 AC_TRY_RUN([
 631 #include <sys/types.h>
 632 #include <sys/time.h>
 633 #include <unistd.h>
 634 #include <pthread.h>
 635 #ifndef NULL
 636 #define NULL (void*) 0
 637 #endif
 638
 639 static int fildes[2];
 640
 641 static void *task(p)
 642         void *p;
 643 {
 644         int i;
 645         struct timeval tv;
 646
 647         fd_set rfds;
 648
 649         tv.tv_sec=10;
 650         tv.tv_usec=0;
 651
 652         FD_ZERO(&rfds);
 653         FD_SET(fildes[0], &rfds);
 654
 655         /* we're not interested in any fds */
 656         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 657
 658         if(i < 0) {
 659                 perror("select");
 660                 exit(10);
 661         }
 662
 663         exit(0); /* if we exit here, the select blocked the whole process */
 664 }
 665
 666 int main(argc, argv)
 667         int argc;
 668         char **argv;
 669 {
 670         pthread_t t;
 671
 672         /* create a pipe to select */
 673         if(pipe(&fildes[0])) {
 674                 perror("select");
 675                 exit(1);
 676         }
 677
 678 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 679         (void) pthread_setconcurrency(2);
 680 #else
 681 #ifdef HAVE_THR_SETCONCURRENCY
 682         /* Set Solaris LWP concurrency to 2 */
 683         thr_setconcurrency(2);
 684 #endif
 685 #endif
 686
 687         pthread_create(&t, NULL, task, NULL);
 688
 689 #if HAVE_SCHED_YIELD
 690         sched_yield();  /* make sure task runs first */
 691 #else
 692 #ifdef HAVE_PTHREAD_YIELD
 693         pthread_yield();        /* make sure task runs first */
 694 #endif
 695 #endif
 696
 697         exit(2);
 698 }],
 699                                 [ol_cv_pthread_select_yields=no],
 700                                 [ol_cv_pthread_select_yields=yes], [
 701                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 702                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 703
 704                                 if test $ol_cv_pthread_select_yields = yes ; then
 705                                         ol_with_yielding_select=yes
 706                                 fi
 707                         fi
 708
 709                         dnl restore flags
 710                         CPPFLAGS="$save_CPPFLAGS"
 711                         LIBS="$save_LIBS"
 712                 else
 713                         AC_MSG_ERROR([could not link with POSIX Threads])
 714                 fi
 715         fi
 716
 717         if test $ol_with_threads = posix ; then
 718                 AC_MSG_ERROR([could not locate POSIX Threads])
 719         fi
 720 fi
 721
 722 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 723         -o $ol_with_threads = mach ; then
 724
 725         dnl check for Mach CThreads
 726         AC_CHECK_HEADERS(mach/cthreads.h)
 727         if test $ac_cv_header_mach_cthreads_h = yes ; then
 728                 ol_with_threads=found
 729
 730                 dnl check for cthread support in current $LIBS
 731                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 732
 733                 if test $ol_link_threads = no ; then
 734                         dnl try -all_load
 735                         dnl this test needs work
 736                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 737                                 [ol_cv_cthread_all_load], [
 738                                 dnl save the flags
 739                                 save_LIBS="$LIBS"
 740                                 LIBS="-all_load $LIBS"
 741                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 742                                         cthread_fork((void *)0, (void *)0);
 743                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 744                                 dnl restore the LIBS
 745                                 LIBS="$save_LIBS"
 746                         ])
 747
 748                         if test $ol_cv_cthread_all_load = yes ; then
 749                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 750                                 ol_link_threads=mach
 751                         fi
 752                 fi
 753
 754                 if test $ol_link_threads != no ; then
 755                         : check for cthread specific functionality here
 756                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 757                 else
 758                         AC_MSG_ERROR([could not link with Mach CThreads])
 759                 fi
 760         fi
 761
 762         if test $ol_with_threads = mach ; then
 763                 AC_MSG_ERROR([could not locate Mach CThreads])
 764         fi
 765 fi
 766
 767 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 768         -o $ol_with_threads = lwp ; then
 769
 770         dnl check for SunOS5 LWP
 771         AC_CHECK_HEADERS(thread.h synch.h)
 772         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 773                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 774
 775                 if test $have_thr = yes ; then
 776                         AC_DEFINE(HAVE_THR)
 777                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 778                         ol_link_threads=thr
 779
 780                         if test $ol_with_yielding_select = auto ; then
 781                                 ol_with_yielding_select=yes
 782                         fi
 783                 fi
 784         fi
 785
 786         dnl check for SunOS4 LWP
 787         AC_CHECK_HEADERS(lwp/lwp.h)
 788         if test $ac_cv_header_lwp_lwp_h = yes ; then
 789                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 790
 791                 if test $have_lwp = yes ; then
 792                         AC_DEFINE(HAVE_LWP)
 793                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 794                         ol_link_threads=lwp
 795
 796                         if test $ol_with_yielding_select = auto ; then
 797                                 ol_with_yielding_select=no
 798                         fi
 799                 fi
 800         fi
 801 fi
 802
 803 if test $ol_with_yielding_select = yes ; then
 804         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 805 fi
 806
 807 if test $ol_with_threads = manual ; then
 808         dnl User thinks he can manually configure threads.
 809         ol_link_threads=yes
 810
 811         AC_MSG_WARN([thread defines and link options must be set manually])
 812
 813         AC_CHECK_HEADERS(pthread.h sched.h)
 814         AC_CHECK_FUNCS(sched_yield pthread_yield)
 815         OL_LINUX_THREADS
 816
 817         AC_CHECK_HEADERS(mach/cthreads.h)
 818         AC_CHECK_HEADERS(lwp/lwp.h)
 819         AC_CHECK_HEADERS(thread.h synch.h)
 820 fi
 821
 822 if test $ol_link_threads != no ; then
 823         dnl needed to get reentrant/threadsafe versions
 824         dnl
 825         AC_DEFINE(REENTRANT,1)
 826         AC_DEFINE(_REENTRANT,1)
 827         AC_DEFINE(THREAD_SAFE,1)
 828         AC_DEFINE(_THREAD_SAFE,1)
 829         AC_DEFINE(THREADSAFE,1)
 830         AC_DEFINE(_THREADSAFE,1)
 831
 832         dnl this might cause the errno symbol to be
 833         dnl replaced with a function to get a thread specific errno.
 834         dnl check to see if everything needs to be compiled
 835         dnl with the thread libraries
 836         AC_CACHE_CHECK([for thread specific errno],
 837                 [ol_cv_errno_thread_specific], [
 838                 AC_TRY_LINK([
 839 #include <errno.h>
 840                         ], [
 841 int x = errno;
 842                         ],
 843                         [ol_cv_errno_thread_specific=yes],
 844                         [ol_cv_errno_thread_specific=no])
 845         ])
 846
 847         if test $ol_cv_errno_thread_specific != yes ; then
 848                 LIBS="$LTHREAD_LIBS $LIBS"
 849                 LTHREAD_LIBS=""
 850         fi
 851
 852 dnl When in thread environment, use
 853 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
 854 dnl                     || defined( HAVE_FUNC_R )
 855 dnl                     func_r(...);
 856 dnl             #else
 857 dnl             #       if defined( HAVE_THREADS )
 858 dnl                             /* lock */
 859 dnl             #       endif
 860 dnl                             func(...);
 861 dnl             #       if defined( HAVE_THREADS )
 862 dnl                             /* unlock */
 863 dnl             #       endif
 864 dnl             #endif
 865 dnl
 866 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
 867 dnl             _POSIX_REENTRANT_FUNCTIONS
 868 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
 869 dnl             _POSIX_THREADSAFE_FUNCTIONS
 870 dnl
 871 dnl             and is currently defined in lthread.h
 872 dnl
 873 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
 874 dnl
 875 dnl libldap/*.c should only include <lthread.h> iff
 876 dnl LDAP_R_COMPILE is defined.  ie:
 877 dnl             #ifdef LDAP_R_COMPILE
 878 dnl             #       include LDAP_R_COMPILE
 879 dnl             #endif
 880 dnl
 881 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
 882 dnl specifically for compiling the threadsafe version of
 883 dnl     the ldap library (-lldap_r).
 884 dnl
 885 dnl     dnl check for reentrant/threadsafe functions
 886 dnl     dnl
 887 dnl     dnl note: these should only be used when linking
 888 dnl     dnl       with $LTHREAD_LIBS
 889 dnl     dnl
 890 dnl     save_CPPFLAGS="$CPPFLAGS"
 891 dnl     save_LIBS="$LIBS"
 892 dnl     LIBS="$LTHREAD_LIBS $LIBS"
 893 dnl     AC_CHECK_FUNCS( \
 894 dnl             strtok_r \
 895 dnl             gmtime_r \
 896 dnl             gethostbyaddr_r gethostbyname_r \
 897 dnl             feof_unlocked unlocked_feof \
 898 dnl             putc_unlocked unlocked_putc \
 899 dnl             flockfile ftrylockfile \
 900 dnl     )
 901 dnl     CPPFLAGS="$save_CPPFLAGS"
 902 dnl     LIBS="$save_LIBS"
 903 fi
 904
 905 dnl ----------------------------------------------------------------
 906
 907 if test $ol_link_threads = no ; then
 908         if test $ol_with_threads = yes ; then
 909                 AC_MSG_ERROR([no suitable thread support])
 910         fi
 911
 912         if test $ol_with_threads = auto ; then
 913                 AC_MSG_WARN([no suitable thread support, disabling threads])
 914                 ol_with_threads=no
 915         fi
 916
 917         AC_DEFINE(NO_THREADS,1)
 918         LTHREAD_LIBS=""
 919 fi
 920
 921 ol_link_ldbm=no
 922 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 923         OL_BERKELEY_DB2
 924
 925         if test $ol_cv_berkeley_db2 = yes ; then
 926                 ol_link_ldbm=db2
 927                 ol_with_ldbm_api=db2
 928
 929                 if test $ol_with_ldbm_type = hash ; then
 930                         AC_DEFINE(LDBM_USE_DBHASH,1)
 931                 else
 932                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 933                 fi
 934
 935                 dnl $ol_cv_lib_db2 should be yes or -ldb
 936                 dnl (it could be no, but that would be an error
 937                 if test $ol_cv_lib_db2 != yes ; then
 938                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 939                 fi
 940         fi
 941 fi
 942
 943 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 944         OL_BERKELEY_DB
 945
 946         if test $ol_cv_berkeley_db = yes ; then
 947                 ol_link_ldbm=db
 948                 ol_with_ldbm_api=db
 949
 950                 if test $ol_with_ldbm_type = hash ; then
 951                         AC_DEFINE(LDBM_USE_DBHASH,1)
 952                 else
 953                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 954                 fi
 955
 956                 dnl $ol_cv_lib_db should be yes or -ldb
 957                 dnl (it could be no, but that would be an error
 958                 if test $ol_cv_lib_db != yes ; then
 959                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 960                 fi
 961         fi
 962 fi
 963
 964 if test $ol_with_ldbm_api = manual ; then
 965         dnl User thinks he can manually configure LDBM api.
 966         ol_link_ldbm=yes
 967
 968         AC_MSG_WARN([LDBM defines and link options must be set manually])
 969
 970         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 971 fi
 972
 973 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 974         AC_MSG_WARN(Could not find LDBM with BTREE support)
 975         ol_with_ldbm_api=none
 976 fi
 977
 978 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 979         OL_GDBM
 980
 981         if test $ol_cv_gdbm = yes ; then
 982                 ol_link_ldbm=gdbm
 983                 ol_with_ldbm_api=gdbm
 984
 985                 if test $ol_cv_lib_gdbm != yes ; then
 986                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 987                 fi
 988         fi
 989 fi
 990
 991 if test $ol_with_ldbm_api = auto ; then
 992         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
 993 elif test $ol_with_ldbm_api = ndbm ; then
 994         OL_NDBM
 995
 996         if test $ol_cv_ndbm = yes ; then
 997                 ol_link_ldbm=ndbm
 998                 ol_with_ldbm_api=ndbm
 999
1000                 if test $ol_cv_lib_ndbm != yes ; then
1001                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1002                 fi
1003         fi
1004 fi
1005
1006 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1007         AC_MSG_WARN(could not find suitable LDBM backend)
1008         if test $ol_enable_ldbm = yes ; then
1009                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1010         fi
1011
1012         AC_MSG_WARN(disabling LDBM)
1013         ol_enable_ldbm=no
1014 fi
1015
1016 if test $ol_enable_wrappers != no ; then
1017         AC_CHECK_LIB(wrap, main,
1018                 [have_wrappers=yes], [have_wrappers=no])
1019
1020         if test $have_wrappers = yes ; then
1021                 AC_DEFINE(HAVE_TCPD)
1022                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1023         else
1024                 AC_MSG_WARN(could not find -lwrap)
1025                 if test $ol_enable_wrappers = yes ; then
1026                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1027                 fi
1028
1029                 AC_MSG_WARN(disabling wrappers support)
1030                 ol_enable_wrappers=no
1031         fi
1032
1033 fi
1034
1035 if test $ol_enable_syslog != no ; then
1036         AC_CHECK_FUNC(openlog)
1037         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1038                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1039         fi
1040         ol_enable_syslog=$ac_cv_func_openlog
1041 fi
1042
1043 if test $ol_enable_dmalloc != no ; then
1044         AC_CHECK_HEADERS(dmalloc.h)
1045         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1046 fi
1047
1048 # ud needs termcap (should insert check here)
1049 ol_link_termcap=no
1050 AC_CHECK_HEADERS(termcap.h ncurses.h)
1051
1052 if test $ol_link_termcap = no ; then
1053         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1054         if test $have_termcap = yes ; then
1055                 AC_DEFINE(HAVE_TERMCAP)
1056                 ol_link_termcap=yes
1057                 TERMCAP_LIBS=-ltermcap
1058         fi
1059 fi
1060
1061 if test $ol_link_termcap = no ; then
1062         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1063         if test $have_ncurses = yes ; then
1064                 AC_DEFINE(HAVE_NCURSES)
1065                 ol_link_termcap=yes
1066                 TERMCAP_LIBS=-lncurses
1067         fi
1068 fi
1069
1070 if test $ol_link_termcap = no ; then
1071         AC_DEFINE(NO_TERMCAP,1)
1072         TERMCAP_LIBS=
1073 fi
1074
1075 # FreeBSD (and others) have crypt(3) in -lcrypt
1076 if test $ol_enable_crypt != no ; then
1077         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1078                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1079                         have_crypt=yes], [have_crypt=no])])
1080
1081         if test $have_crypt = yes ; then
1082                 AC_DEFINE(HAVE_CRYPT,1)
1083         else
1084                 AC_MSG_WARN(could not find crypt)
1085                 if test $ol_enable_crypt = yes ; then
1086                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1087                 fi
1088
1089                 AC_MSG_WARN(disabling crypt support)
1090                 ol_enable_crypt=no
1091         fi
1092 fi
1093
1094 # FreeBSD (and others) have setproctitle(3) in -lutil
1095 if test $ol_enable_proctitle != no ; then
1096         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1097                 AC_CHECK_LIB(util, setproctitle,
1098                         [have_setproctitle=yes
1099                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1100                         [have_setproctitle=no
1101                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1102
1103         if test $have_setproctitle = yes ; then
1104                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1105         fi
1106 fi
1107
1108 dnl ----------------------------------------------------------------
1109 dnl Checks for header files.
1110 AC_HEADER_STDC
1111
1112 if test $ac_cv_header_stdc != yes; then
1113         AC_MSG_WARN([could not Standard C compliant headers])
1114 fi
1115
1116 AC_HEADER_DIRENT
1117 AC_HEADER_SYS_WAIT
1118 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1119 if test $am_cv_sys_posix_termios = yes ; then
1120         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
1121 fi
1122
1123 AC_CHECK_HEADERS(       \
1124         crypt.h                 \
1125         errno.h                 \
1126         fcntl.h                 \
1127         filio.h                 \
1128         getopt.h                \
1129         libutil.h               \
1130         limits.h                \
1131         malloc.h                \
1132         memory.h                \
1133         regex.h                 \
1134         psap.h                  \
1135         pwd.h                   \
1136         sgtty.h                 \
1137         stdarg.h                \
1138         stddef.h                \
1139         string.h                \
1140         strings.h               \
1141         sys/file.h              \
1142         sys/filio.h             \
1143         sys/errno.h             \
1144         sys/ioctl.h             \
1145         sys/param.h             \
1146         sys/resource.h  \
1147         sys/socket.h    \
1148         sys/syslog.h    \
1149         sys/time.h              \
1150         sys/types.h             \
1151         syslog.h                \
1152         termios.h               \
1153         unistd.h                \
1154 )
1155
1156 dnl ----------------------------------------------------------------
1157 dnl Checks for typedefs, structures, and compiler characteristics.
1158 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1159 AC_TYPE_MODE_T
1160 AC_TYPE_OFF_T
1161 AC_TYPE_PID_T
1162 AM_TYPE_PTRDIFF_T
1163 AC_TYPE_SIGNAL
1164 OL_TYPE_SIG_ATOMIC_T
1165 AC_TYPE_SIZE_T
1166 AC_STRUCT_ST_BLKSIZE
1167 AC_HEADER_TIME
1168 AC_STRUCT_TM
1169
1170 OL_C_UPPER_LOWER
1171 AC_C_CONST
1172 OL_C_VOLATILE
1173
1174 if test $cross_compiling = yes ; then
1175         AC_DEFINE(CROSS_COMPILING, 1)
1176 else
1177         AC_C_BIGENDIAN
1178         AC_CHECK_SIZEOF(short)
1179         AC_CHECK_SIZEOF(int)
1180         AC_CHECK_SIZEOF(long)
1181 fi
1182
1183 dnl ----------------------------------------------------------------
1184 dnl Checks for library functions.
1185 AC_FUNC_MEMCMP
1186 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1187 AC_FUNC_STRFTIME
1188 dnl AM_FUNC_STRTOD
1189 AC_FUNC_VPRINTF
1190
1191 if test $ac_cv_func_vprintf = yes ; then
1192         dnl check for vsnprintf
1193         AC_CHECK_FUNCS(vsnprintf vsprintf)
1194 fi
1195
1196 AC_FUNC_WAIT3
1197
1198 AC_CHECK_FUNCS(         \
1199         bcopy                   \
1200         flock                   \
1201         getdtablesize   \
1202         gethostname             \
1203         getpwuid                \
1204         gettimeofday    \
1205         lockf                   \
1206         memcpy                  \
1207         memmove                 \
1208         mkstemp                 \
1209         res_search              \
1210         select                  \
1211         setpwfile               \
1212         setsid                  \
1213         signal                  \
1214         sigset                  \
1215         snprintf                \
1216         socket                  \
1217         strerror                \
1218         strpbrk                 \
1219         strrchr                 \
1220         strsep                  \
1221         strstr                  \
1222         strtok                  \
1223         strtol                  \
1224         strtoul                 \
1225         sysconf                 \
1226         waitpid                 \
1227 )
1228
1229 # these functions are required to build a thread_safe -lldap
1230 AC_CHECK_FUNCS(         \
1231         strtok_r                \
1232         ctime_r                 \
1233         gethostbyaddr_r \
1234         gethostbyname_r \
1235 )
1236
1237 OL_FUNC_CTIME_R_NARGS
1238
1239 if test $ac_cv_func_strtok_r = yes \
1240         -a $ac_cv_func_ctime_r = yes \
1241         -a $ol_cv_func_ctime_r_nargs -ge 2 -a $ol_cv_func_ctime_r_nargs -le 3 \
1242         -a $ac_cv_func_gethostbyaddr_r = yes \
1243         -a $ac_cv_func_gethostbyname_r = yes \
1244         ; then
1245
1246         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT, 1)
1247 fi
1248
1249 if test $ol_link_threads != no ; then
1250         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE, 1)
1251 fi
1252
1253 dnl We actually may need to replace more than this.
1254 AC_REPLACE_FUNCS(getopt strdup tempnam)
1255
1256 dnl ----------------------------------------------------------------
1257 # Check Configuration
1258 OL_SYS_ERRLIST
1259
1260 dnl ----------------------------------------------------------------
1261 dnl Sort out defines
1262
1263 if test "$ol_enable_debug" != no ; then
1264         AC_DEFINE(LDAP_DEBUG,1)
1265 fi
1266 if test "$ol_enable_syslog" = yes ; then
1267         AC_DEFINE(LDAP_SYSLOG,1)
1268 fi
1269 if test "$ol_enable_libui" = yes ; then
1270         AC_DEFINE(LDAP_LIBUI,1)
1271 fi
1272 if test "$ol_enable_cache" = no ; then
1273         AC_DEFINE(LDAP_NOCACHE,1)
1274 fi
1275 if test "$ol_enable_dns" != no ; then
1276         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION,1)
1277 fi
1278 if test "$ol_enable_proctitle" != no ; then
1279         AC_DEFINE(LDAP_PROCTITLE,1)
1280 fi
1281 if test "$ol_enable_referrals" != no ; then
1282         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION,1)
1283 fi
1284 if test "$ol_enable_cldap" != no ; then
1285         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1286 fi
1287
1288 if test "$ol_enable_aclgroups" != no ; then
1289         AC_DEFINE(SLAPD_ACLGROUPS,1)
1290 fi
1291 if test "$ol_enable_crypt" != no ; then
1292         AC_DEFINE(SLAPD_CRYPT,1)
1293 fi
1294 if test "$ol_enable_cleartext" != no ; then
1295         AC_DEFINE(SLAPD_CLEARTEXT,1)
1296 fi
1297 if test "$ol_enable_phonetic" != no ; then
1298         AC_DEFINE(SLAPD_PHONETIC,1)
1299 fi
1300 if test "$ol_enable_rlookups" != no ; then
1301         AC_DEFINE(SLAPD_RLOOKUPS,1)
1302 fi
1303
1304 if test "$ol_link_ldbm" != no ; then
1305         AC_DEFINE(SLAPD_LDBM,1)
1306         BUILD_SLAPD=yes
1307         BUILD_LDBM=yes
1308 fi
1309
1310 if test "$ol_enable_passwd" != no ; then
1311         AC_DEFINE(SLAPD_PASSWD,1)
1312         BUILD_SLAPD=yes
1313         BUILD_PASSWD=yes
1314 fi
1315
1316 if test "$ol_enable_shell" != no ; then
1317         AC_DEFINE(SLAPD_SHELL,1)
1318         BUILD_SLAPD=yes
1319         BUILD_SHELL=yes
1320 fi
1321
1322 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1323         $BUILD_SLAPD = yes ; then
1324         BUILD_SLURPD=yes
1325 fi
1326
1327 if test "$ol_link_isode" != no ; then
1328         BUILD_LDAPD=yes
1329 fi
1330
1331 dnl ----------------------------------------------------------------
1332
1333 AC_SUBST(BUILD_LDAPD)
1334 AC_SUBST(BUILD_SLAPD)
1335   AC_SUBST(BUILD_LDBM)
1336   AC_SUBST(BUILD_PASSWD)
1337   AC_SUBST(BUILD_SHELL)
1338 AC_SUBST(BUILD_SLURPD)
1339
1340 AC_SUBST(LDAP_LIBS)
1341 AC_SUBST(LDAPD_LIBS)
1342 AC_SUBST(SLAPD_LIBS)
1343 AC_SUBST(SLURPD_LIBS)
1344 AC_SUBST(LDBM_LIBS)
1345 AC_SUBST(LTHREAD_LIBS)
1346 AC_SUBST(LUTIL_LIBS)
1347
1348 AC_SUBST(KRB_LIBS)
1349 AC_SUBST(TERMCAP_LIBS)
1350
1351 dnl ----------------------------------------------------------------
1352 dnl final output
1353 dnl
1354
1355 AC_OUTPUT( \
1356 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1357 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1358 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1359 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1360 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1361 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1362 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1363 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1364 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1365 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1366 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1367 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1368 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1369 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1370 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1371 include/Makefile:build/top.mk:include/Makefile.in \
1372 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1373 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1374 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1375 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1376 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1377 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1378 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1379 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1380 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1381 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1382 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1383 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1384 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1385 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1386 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1387 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1388 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1389 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1390 tests/Makefile:build/top.mk:tests/Makefile.in \
1391 ,[
1392 date > stamp-h
1393 echo Please \"make depend\" to build dependencies
1394 ])