git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(openldap,[1.2], [no ac_define])dnl
  14
  15 dnl We use autoconf features new to 2.13.
  16 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  17 AC_PREREQ(2.13)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  43 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  44 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  45 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  46 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  47 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  48 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  49         no, [yes no])dnl
  50
  51 dnl General "with" options
  52 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  53
  54 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  55         auto, [auto k5 k4 afs yes no])
  56 OL_ARG_WITH(threads,[  --with-threads   use threads],
  57         auto, [auto posix mach lwp yes no manual] )
  58 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  59         auto, [auto yes no manual] )
  60
  61 dnl Server options
  62
  63 dnl LDAPD OPTIONS
  64 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  65 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  66
  67 dnl SLAPD OPTIONS
  68 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  69 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  70 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  71 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  72 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  73 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  74 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  75 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  76
  77 dnl SLAPD Backend options
  78 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  79 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  80         [auto db2 db gdbm ndbm manual])
  81 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  82         [auto btree hash])
  83
  84 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  85 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  86
  87 dnl SLURPD OPTIONS
  88 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  89 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  90
  91 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  92 AM_ENABLE_STATIC
  93 AM_DISABLE_SHARED
  94 dnl AM_ENABLE_SHARED
  95
  96 dnl General "enable" options
  97 # validate options
  98 if test $ol_enable_dns = yes ; then
  99         if test $ol_enable_referrals = no ; then
 100                 AC_MSG_ERROR([DNS requires --enable-referrals])
 101         fi
 102         if test $ol_enable_referrals = auto ; then
 103                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 104                 ol_enable_referrals=yes
 105         fi
 106 fi
 107
 108 if test $ol_enable_slapd = no ; then
 109         dnl SLAPD was specificallly disabled
 110         if test $ol_enable_ldbm = yes ; then
 111                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 112         fi
 113         if test $ol_enable_passwd = yes ; then
 114                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 115         fi
 116         if test $ol_enable_shell = yes ; then
 117                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 118         fi
 119         if test $ol_enable_aclgroups = yes ; then
 120                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 121         fi
 122         if test $ol_enable_wrappers = yes ; then
 123                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 124         fi
 125         if test $ol_enable_phonetic = yes ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 127         fi
 128         if test $ol_enable_rlookups = yes ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 130         fi
 131         if test $ol_with_ldbm_api != auto ; then
 132                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 133         fi
 134         if test $ol_with_ldbm_type != auto ; then
 135                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 136         fi
 137         if test $ol_enable_slurpd = yes ; then
 138                 AC_MSG_ERROR([slurpd requires slapd])
 139         fi
 140
 141         # force settings to no
 142         ol_enable_ldbm=no
 143         ol_enable_shell=no
 144         ol_enable_passwd=no
 145         ol_enable_aclgroups=no
 146         ol_enable_wrappers=no
 147         ol_enable_phonetic=no
 148         ol_enable_rlookups=no
 149         ol_with_ldbm_api=no
 150         ol_with_ldbm_type=no
 151         ol_enable_slurpd=no
 152
 153 elif test $ol_enable_ldbm = no ; then
 154         dnl SLAPD without LDBM
 155
 156         if test $ol_with_ldbm_api != auto ; then
 157                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 158         fi
 159
 160         if test $ol_with_ldbm_type != auto ; then
 161                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 162         fi
 163
 164         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 165                 AC_MSG_ERROR([slapd requires a backend])
 166         fi
 167
 168         ol_with_ldbm_api=no
 169         ol_with_ldbm_type=no
 170
 171 else
 172         dnl SLAPD with LDBM
 173
 174         if test $ol_with_ldbm_api = gdbm -a \
 175                 $ol_with_ldbm_type = btree ; then
 176                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 177         fi
 178         if test $ol_with_ldbm_api = ndbm -a \
 179                 $ol_with_ldbm_type = btree ; then
 180                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 181         fi
 182 fi
 183
 184 if test $ol_enable_slurpd = yes ; then
 185         dnl SLURPD was specifically enabled
 186         if test $ol_with_threads = no ; then
 187                 AC_MSG_ERROR([slurpd requires threads])
 188         fi
 189 fi
 190
 191 AC_MSG_RESULT(done)
 192
 193 AC_CANONICAL_HOST
 194
 195 ## Initialize vars
 196 LDAP_LIBS=
 197 LDBM_LIBS=
 198 LTHREAD_LIBS=
 199 LUTIL_LIBS=
 200
 201 LDAPD_LIBS=
 202 SLAPD_LIBS=
 203 SLURPD_LIBS=
 204
 205 BUILD_LDAPD=no
 206 BUILD_SLAPD=no
 207 BUILD_SLURPD=no
 208
 209 BUILD_LDBM=no
 210 BUILD_PASSWD=no
 211 BUILD_SHELL=no
 212 BUILD_THREAD=no
 213
 214 KRB_LIBS=
 215 TERMCAP_LIBS=
 216
 217 dnl ----------------------------------------------------------------
 218 dnl Checks for programs
 219
 220 AC_PROG_INSTALL
 221 AM_PROG_LIBTOOL
 222 dnl AC_PROG_MAKE_SET
 223
 224 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 225         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 226 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 227 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 228
 229 dnl Checks the compiler and UNIX Variants
 230
 231 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 232         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 233
 234 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 235         AC_MSG_WARN([programs compiled here do run here...])
 236         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 237
 238 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 239         AC_MSG_WARN([programs compiled here do not run here...])
 240         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 241 fi
 242
 243 AC_PROG_CPP
 244
 245 AC_AIX
 246 AC_ISC_POSIX
 247 AC_MINIX
 248
 249 dnl BeOS requires -lbe -lroot -lnet
 250 AC_CHECK_LIB(be, be_app,
 251         [LIBS="$LIBS -lbe -lroot -lnet"], :,
 252         [-lroot -lnet])
 253
 254 dnl OpenLDAP requires STDC features
 255 AM_PROG_CC_STDC
 256 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 257         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 258 fi
 259
 260 dnl AM_C_PROTOTYPES
 261
 262 dnl Checks for libraries
 263
 264 dnl Find socket()
 265 dnl Likely combinations:
 266 dnl             -lsocket [ -lnsl_s | -lnsl ]
 267 dnl             -linet
 268
 269 AC_CHECK_FUNC(socket, [have_socket=yes], [
 270 dnl
 271 dnl hopefully we won't include too many libraries
 272 dnl
 273         AC_CHECK_LIB(socket, main)
 274         AC_CHECK_LIB(net, main)
 275         AC_CHECK_LIB(nsl_s, main)
 276         AC_CHECK_LIB(nsl, main)
 277         AC_CHECK_LIB(inet, socket)
 278         AC_CHECK_LIB(gen, main)
 279 ])
 280
 281 dnl Check for resolver routines
 282 AC_CHECK_FUNCS(res_search)
 283 if test $ac_cv_func_res_search = "no" ; then
 284         AC_CHECK_LIB(bind, res_search)
 285         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 286                 AC_DEFINE(HAVE_RES_SEARCH,1)
 287         else
 288                 AC_CHECK_LIB(resolv, res_search)
 289                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 290                         AC_DEFINE(HAVE_RES_SEARCH,1)
 291                 fi
 292         fi
 293 fi
 294
 295 dnl HP-UX requires -lV3
 296 AC_CHECK_LIB(V3, sigset)
 297
 298 # ISODE tests
 299 ol_link_isode=no
 300 if test $ol_enable_ldapd != no ; then
 301         dnl look for ISODE libraries
 302         AC_CHECK_LIB(xtpp, main, [
 303                 ol_link_isode=yes
 304                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 305                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 306                 ],:,[-lxtdsap -lxtisode -losi])
 307         AC_CHECK_LIB(dsap, main, [
 308                 ol_link_isode=yes
 309                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 310                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 311                 ],:,[-lisode])
 312         AC_CHECK_LIB(isode, main, [
 313                 ol_link_isode=yes
 314                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 315                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 316                 ],:)
 317 fi
 318
 319 if test $ol_link_isode != no; then
 320         AC_CHECK_LIB(pp, main, [
 321                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 322                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 323                 ],:)
 324
 325         AC_PATH_PROG(PEPSY, pepsy)
 326 fi
 327
 328 dnl
 329 dnl check for kerberos
 330 dnl
 331 ol_link_kerberos=no
 332
 333 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 334         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 335
 336         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 337                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 338                         [-lkrb5 -ldes425])
 339
 340                 if test $have_k5 = yes ; then
 341                         ol_with_kerberos=found
 342                         ol_link_kerberos=yes
 343
 344                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 345
 346                         LIBS="$KRB_LIBS $LIBS"
 347
 348                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 349                                 [ol_cv_var_des_debug], [
 350                                 dnl save the flags
 351                                 save_LIBS="$LIBS"
 352                                 LIBS="$KRB_LIBS $LIBS"
 353                                 AC_TRY_LINK([
 354 #include <kerberosIV/krb.h>
 355 #include <kerberosIV/des.h>
 356 extern int des_debug;
 357 ],[
 358 des_debug = 1;
 359 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 360                                 dnl restore the LIBS
 361                                 LIBS="$save_LIBS"
 362                         ])
 363
 364                         if test $ol_cv_var_des_debug = yes ; then
 365                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 366                                         [define if you have Kerberos des_debug])
 367                         fi
 368
 369                         LIBS="$save_LIBS"
 370                 fi
 371         fi
 372 fi
 373
 374 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 375         AC_CHECK_HEADERS(krb.h des.h)
 376
 377         if test $ac_cv_header_krb_h = yes ; then
 378                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 379
 380                 if test $have_k4 = yes ; then
 381                         ol_with_kerberos=found
 382                         ol_link_kerberos=yes
 383
 384                         KRB_LIBS="-lkrb -ldes"
 385                 fi
 386         fi
 387 fi
 388
 389 if test $ol_link_kerberos = yes ; then
 390         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 391 fi
 392
 393 ol_link_threads=no
 394 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 395         -o $ol_with_threads = posix ; then
 396
 397         AC_CHECK_HEADERS(pthread.h sched.h)
 398
 399         if test $ac_cv_header_pthread_h = yes ; then
 400                 OL_POSIX_THREAD_VERSION
 401
 402                 if test $ol_cv_pthread_version = final ; then
 403                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 404                                 [define if pthreads API compatible with final spec])
 405                 elif test $ol_cv_pthread_version = draft4 ; then
 406                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 407                                 [define if pthreads API compatible with draft4 spec])
 408                 else
 409                         AC_MSG_ERROR([unknown pthread version])
 410                 fi
 411
 412                 # consider threads found
 413                 ol_with_threads=found
 414
 415                 OL_LINUX_THREADS
 416
 417                 if test $ol_cv_linux_threads = yes ; then
 418                         AC_DEFINE(HAVE_LINUX_THREADS,1,
 419                                 [define if you have LinuxThreads])
 420                 fi
 421
 422                 dnl Now the hard part, how to link?
 423                 dnl
 424                 dnl currently supported checks:
 425                 dnl
 426                 dnl Check for no flags
 427                 dnl     pthread_create() in $LIBS
 428                 dnl
 429                 dnl Check special pthread (final) flags
 430                 dnl     pthread_create() with -kthread (FreeBSD)
 431                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 432                 dnl     pthread_create() with -pthreads (?)
 433                 dnl     pthread_create() with -thread (?)
 434                 dnl     pthread_create() with -mt (Solaris)
 435                 dnl
 436                 dnl Check pthread (final) libraries
 437                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 438                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 439                 dnl     pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 440                 dnl     pthread_create() in -lpthread (many)
 441                 dnl     pthread_create() in -lc_r (FreeBSD)
 442                 dnl     pthread_create() in -lpthreads (many)
 443                 dnl     pthread_join() -Wl,-woff,85 -lpthreads (IRIX)
 444                 dnl     pthread_create() in HP-UX -lpthread (HP-UX 11)
 445                 dnl
 446                 dnl Check pthread (draft4) flags (to be depreciated)
 447                 dnl     pthread_create() with -threads (OSF/1)
 448                 dnl
 449                 dnl Check pthread (final) libraries (to be depreciated)
 450                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 451                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 452                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 453                 dnl
 454
 455                 dnl pthread_create in $LIBS
 456                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 457
 458                 if test $ol_link_threads = no ; then
 459                         dnl try -kthread
 460                         AC_CACHE_CHECK([for pthread_create with -kthread],
 461                                 [ol_cv_kthread_flag], [
 462                                 dnl save the flags
 463                                 save_LIBS="$LIBS"
 464                                 LIBS="-kthread $LIBS"
 465                                 AC_TRY_LINK([#include <pthread.h>],
 466                                         [pthread_create(NULL,NULL,NULL,NULL);],
 467                                         [ol_cv_kthread_flag=yes], [ol_cv_kthread_flag=no])
 468                                 dnl restore the LIBS
 469                                 LIBS="$save_LIBS"
 470                         ])
 471
 472                         if test $ol_cv_kthread_flag = yes ; then
 473                                 LTHREAD_LIBS="$LTHREAD_LIBS -kthread"
 474                                 ol_link_threads=posix
 475                         fi
 476                 fi
 477
 478                 if test $ol_link_threads = no ; then
 479                         dnl try -pthread
 480                         AC_CACHE_CHECK([for pthread_create with -pthread],
 481                                 [ol_cv_pthread_flag], [
 482                                 dnl save the flags
 483                                 save_LIBS="$LIBS"
 484                                 LIBS="-pthread $LIBS"
 485                                 AC_TRY_LINK([#include <pthread.h>],
 486                                         [pthread_create(NULL,NULL,NULL,NULL);],
 487                                         [ol_cv_pthread_flag=yes], [ol_cv_pthread_flag=no])
 488                                 dnl restore the LIBS
 489                                 LIBS="$save_LIBS"
 490                         ])
 491
 492                         if test $ol_cv_pthread_flag = yes ; then
 493                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 494                                 ol_link_threads=posix
 495                         fi
 496                 fi
 497
 498                 if test $ol_link_threads = no ; then
 499                         dnl try -pthreads
 500                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 501                                 [ol_cv_pthreads_flag], [
 502                                 dnl save the flags
 503                                 save_LIBS="$LIBS"
 504                                 LIBS="-pthreads $LIBS"
 505                                 AC_TRY_LINK([#include <pthread.h>],
 506                                         [pthread_create(NULL,NULL,NULL,NULL);],
 507                                         [ol_cv_pthreads_flag=yes], [ol_cv_pthreads_flag=no])
 508                                 dnl restore the LIBS
 509                                 LIBS="$save_LIBS"
 510                         ])
 511
 512                         if test $ol_cv_pthreads_flag = yes ; then
 513                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 514                                 ol_link_threads=posix
 515                         fi
 516                 fi
 517
 518                 if test $ol_link_threads = no ; then
 519                         dnl try -thread
 520                         AC_CACHE_CHECK([for pthread_create with -thread],
 521                                 [ol_cv_thread_flag], [
 522                                 dnl save the flags
 523                                 save_LIBS="$LIBS"
 524                                 LIBS="-thread $LIBS"
 525                                 AC_TRY_LINK([char pthread_create();],
 526                                         [pthread_create();],
 527                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 528                                 dnl restore the LIBS
 529                                 LIBS="$save_LIBS"
 530                         ])
 531
 532                         if test $ol_cv_thread_flag = yes ; then
 533                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 534                                 ol_link_threads=posix
 535                         fi
 536                 fi
 537
 538                 if test $ol_link_threads = no ; then
 539                         dnl try -mt
 540                         AC_CACHE_CHECK([for pthread_create with -mt],
 541                                 [ol_cv_thread_flag], [
 542                                 dnl save the flags
 543                                 save_LIBS="$LIBS"
 544                                 LIBS="-mt $LIBS"
 545                                 AC_TRY_LINK([char pthread_create();],
 546                                         [pthread_create();],
 547                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 548                                 dnl restore the LIBS
 549                                 LIBS="$save_LIBS"
 550                         ])
 551
 552                         if test $ol_cv_thread_flag = yes ; then
 553                                 LTHREAD_LIBS="$LTHREAD_LIBS -mt"
 554                                 ol_link_threads=posix
 555                         fi
 556                 fi
 557
 558                 if test $ol_link_threads = no ; then
 559                         dnl try DEC Threads -lpthread -lmach -lexc -lc_r
 560                         save_LIBS="$LIBS"
 561                         AC_CHECK_LIB(pthread, pthread_mutex_unlock, [
 562                                 ol_link_threads=posix
 563                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc_r"
 564                                 if test $ol_with_yielding_select = auto ; then
 565                                         ol_with_yielding_select=yes
 566                                 fi
 567                                 ],:,[-lmach -lexc -lc_r])
 568                         LIBS="$save_LIBS"
 569                 fi
 570
 571                 if test $ol_link_threads = no ; then
 572                         dnl try DEC Threads -lpthread -lmach -lexc
 573                         save_LIBS="$LIBS"
 574                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 575                                 ol_link_threads=posix
 576                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc"
 577                                 if test $ol_with_yielding_select = auto ; then
 578                                         ol_with_yielding_select=yes
 579                                 fi
 580                                 ],:,[-lmach -lexc])
 581                         LIBS="$save_LIBS"
 582                 fi
 583
 584                 if test $ol_link_threads = no ; then
 585                         dnl try DEC Threads -lpthread -lexc
 586                         save_LIBS="$LIBS"
 587                         AC_CHECK_LIB(pthread, pthread_mutex_trylock, [
 588                                 ol_link_threads=posix
 589                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 590                                 if test $ol_with_yielding_select = auto ; then
 591                                         ol_with_yielding_select=yes
 592                                 fi
 593                                 ],:,[-lexc])
 594                         LIBS="$save_LIBS"
 595                 fi
 596
 597                 if test $ol_link_threads = no ; then
 598                         dnl try -lpthread
 599                         save_LIBS="$LIBS"
 600                         AC_CHECK_LIB(pthread, pthread_create, [
 601                                 ol_link_threads=posix
 602                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"],:)
 603                         LIBS="$save_LIBS"
 604                 fi
 605
 606                 if test $ol_link_threads = no ; then
 607                         dnl try -lc_r
 608                         save_LIBS="$LIBS"
 609                         AC_CHECK_LIB(c_r, pthread_create, [
 610                                 ol_link_threads=posix
 611                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"],:)
 612                         LIBS="$save_LIBS"
 613                 fi
 614
 615                 if test $ol_link_threads = no ; then
 616                         dnl try -lpthreads
 617                         save_LIBS="$LIBS"
 618                         AC_CHECK_LIB(pthreads, pthread_create, [
 619                                 ol_link_threads=posix
 620                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"],:)
 621                         LIBS="$save_LIBS"
 622                 fi
 623
 624                 dnl IRIX Pthread check
 625                 if test $ol_link_threads = no ; then
 626                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 627                         save_LIBS="$LIBS"
 628                         AC_CHECK_LIB(pthreads, pthread_join, [
 629                                 ol_link_threads=posix
 630                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 631                                 ],:,[-Wl,-woff,85])
 632                         LIBS="$save_LIBS"
 633                 fi
 634
 635                 dnl HP-UX 11 Pthread check
 636                 if test $ol_link_threads = no; then
 637                         save_LIBS="$LIBS"
 638                         LIBS="$LIBS -lpthread"
 639                         AC_MSG_CHECKING([for pthread_create() in HP-UX -lpthread])
 640                         ol_try_pthread_hpux_11=no
 641                         AC_CACHE_VAL(ol_cv_pthread_hpux_11,[
 642                                 AC_TRY_LINK([
 643 #include <pthread.h>
 644 #include <elf.h>
 645 #ifndef ELFABI_HPUX_REL11
 646         die horribly
 647 #endif
 648                                 ], [pthread_create(NULL, NULL, NULL, NULL);],
 649                                         ol_try_pthread_hpux_11=yes
 650                                         ol_cv_pthread_hpux_11=yes,
 651                                         ol_cv_pthread_hpux_11=no)])
 652                         AC_MSG_RESULT(yes)
 653                         LIBS="$save_LIBS"
 654
 655                         if test $ol_cv_pthread_hpux_11=yes ; then
 656                                 ol_link_threads=posix
 657                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"
 658                                 if test $ol_try_pthread_hpux_11=yes ; then
 659                                         dnl Some tests below may fail, cause we aint including
 660                                         dnl pthread.h. Force appropriate ones to yes
 661                                         ac_cv_func_pthread_attr_init=yes
 662                                 fi
 663                         fi
 664                 fi
 665
 666                 if test $ol_link_threads = no ; then
 667                         dnl try -threads
 668                         AC_CACHE_CHECK([for pthread_create with -threads],
 669                                 [ol_cv_thread_flag], [
 670                                 dnl save the flags
 671                                 save_LIBS="$LIBS"
 672                                 LIBS="-threads $LIBS"
 673                                 AC_TRY_LINK([char pthread_create();],[
 674                                         pthread_create();
 675                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 676                                 dnl restore the LIBS
 677                                 LIBS="$save_LIBS"
 678                         ])
 679
 680                         if test $ol_cv_thread_flag = yes ; then
 681                                 LTHREAD_LIBS="$LTHREAD_LIBS -threads"
 682                                 ol_link_threads=posix
 683                         fi
 684                 fi
 685
 686                 if test $ol_link_threads = no ; then
 687                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 688                         save_LIBS="$LIBS"
 689                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 690                                 ol_link_threads=posix
 691                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 692                                 if test $ol_with_yielding_select = auto ; then
 693                                         ol_with_yielding_select=yes
 694                                 fi
 695                                 ],:,[-lmach -lexc -lc_r])
 696                         LIBS="$save_LIBS"
 697                 fi
 698
 699                 if test $ol_link_threads = no ; then
 700                         dnl try DEC Threads -lpthreads -lmach -lexc
 701                         save_LIBS="$LIBS"
 702                         AC_CHECK_LIB(pthreads, pthread_mutex_lock, [
 703                                 ol_link_threads=posix
 704                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc"
 705                                 if test $ol_with_yielding_select = auto ; then
 706                                         ol_with_yielding_select=yes
 707                                 fi
 708                                 ],:,[-lmach -lexc])
 709                         LIBS="$save_LIBS"
 710                 fi
 711
 712                 if test $ol_link_threads = no ; then
 713                         dnl try DEC Threads -lpthreads -lexc
 714                         save_LIBS="$LIBS"
 715                         AC_CHECK_LIB(pthreads, pthread_mutex_trylock, [
 716                                 ol_link_threads=posix
 717                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lexc"
 718                                 if test $ol_with_yielding_select = auto ; then
 719                                         ol_with_yielding_select=yes
 720                                 fi
 721                                 ],:,[-lexc])
 722                         LIBS="$save_LIBS"
 723                 fi
 724
 725                 if test $ol_link_threads != no ; then
 726                         AC_DEFINE(HAVE_PTHREADS,1,
 727                                 [define if you have POSIX Threads])
 728
 729                         dnl save flags
 730                         save_CPPFLAGS="$CPPFLAGS"
 731                         save_LIBS="$LIBS"
 732                         LIBS="$LTHREAD_LIBS $LIBS"
 733
 734                         dnl All POSIX Thread (final) implementations should have
 735                         dnl sched_yield instead of pthread yield.
 736                         dnl check for both
 737                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 738
 739                         if test $ac_cv_func_sched_yield = no -a \
 740                                 $ac_cv_func_pthread_yield = no ; then
 741                                 dnl Digital UNIX has sched_yield() in -lrt
 742                                 AC_CHECK_LIB(rt, sched_yield,
 743                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 744                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 745                                         ac_cv_func_sched_yield=yes],
 746                                         [ac_cv_func_sched_yield=no])
 747                         fi
 748                         if test $ac_cv_func_sched_yield = no -a \
 749                                 $ac_cv_func_pthread_yield = no ; then
 750                                 dnl Solaris has sched_yield() in -lposix4
 751                                 dnl but we'll use thr_yield instead.
 752                                 AC_CHECK_FUNCS(thr_yield)
 753                         fi
 754                         if test $ac_cv_func_sched_yield = no -a \
 755                                 $ac_cv_func_pthread_yield = no -a \
 756                                 "$ac_cv_func_thr_yield" = no ; then
 757                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 758                         fi
 759
 760                         dnl Check functions for compatibility
 761                         AC_CHECK_FUNCS(pthread_kill)
 762
 763                         dnl Check for pthread_detach with <pthread.h> inclusion
 764                         dnl as it's symbol may have been mangled.
 765                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 766                                 [ol_cv_func_pthread_detach], [
 767                                 dnl save the flags
 768                                 AC_TRY_LINK([#include <pthread.h>],
 769                                         [pthread_detach(NULL);],
 770                                         [ol_cv_func_pthread_detach=yes],
 771                                         [ol_cv_func_pthread_detach=no])
 772                         ])
 773
 774                         if test $ol_cv_func_pthread_detach = no ; then
 775                                 AC_MSG_ERROR([could not locate pthread_detach()])
 776                         fi
 777
 778                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 779                                 [define if you have pthread_detach function])
 780
 781                         dnl Check for setconcurreny functions
 782                         AC_CHECK_FUNCS( \
 783                                 pthread_setconcurrency \
 784                                 pthread_getconcurrency \
 785                                 thr_setconcurrency \
 786                                 thr_getconcurrency \
 787                         )
 788
 789                         AC_MSG_CHECKING([if pthread_create() works])
 790                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 791                         AC_TRY_RUN([
 792 #include <pthread.h>
 793 #ifndef NULL
 794 #define NULL (void*)0
 795 #endif
 796
 797 static void *task(p)
 798         void *p;
 799 {
 800         return (void *) (p == NULL);
 801 }
 802
 803 int main(argc, argv)
 804         int argc;
 805         char **argv;
 806 {
 807         pthread_t t;
 808         exit(pthread_create(&t, NULL, task, NULL));
 809 }
 810 ],
 811                                 [ol_cv_pthread_create_works=yes],
 812                                 [ol_cv_pthread_create_works=no],
 813                                 [dnl assume yes
 814                                 ol_cv_pthread_create_works=yes])])
 815                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 816
 817                         if test $ol_cv_pthread_create_works = no ; then
 818                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 819                         fi
 820
 821                         dnl Check if select causes an yield
 822                         if test $ol_with_yielding_select = auto ; then
 823                                 AC_MSG_CHECKING([if select yields when using pthreads])
 824                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 825                                 AC_TRY_RUN([
 826 #include <sys/types.h>
 827 #include <sys/time.h>
 828 #include <unistd.h>
 829 #include <pthread.h>
 830 #ifndef NULL
 831 #define NULL (void*) 0
 832 #endif
 833
 834 static int fildes[2];
 835
 836 static void *task(p)
 837         void *p;
 838 {
 839         int i;
 840         struct timeval tv;
 841
 842         fd_set rfds;
 843
 844         tv.tv_sec=10;
 845         tv.tv_usec=0;
 846
 847         FD_ZERO(&rfds);
 848         FD_SET(fildes[0], &rfds);
 849
 850         /* we're not interested in any fds */
 851         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 852
 853         if(i < 0) {
 854                 perror("select");
 855                 exit(10);
 856         }
 857
 858         exit(0); /* if we exit here, the select blocked the whole process */
 859 }
 860
 861 int main(argc, argv)
 862         int argc;
 863         char **argv;
 864 {
 865         pthread_t t;
 866
 867         /* create a pipe to select */
 868         if(pipe(&fildes[0])) {
 869                 perror("select");
 870                 exit(1);
 871         }
 872
 873 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 874         (void) pthread_setconcurrency(2);
 875 #else
 876 #ifdef HAVE_THR_SETCONCURRENCY
 877         /* Set Solaris LWP concurrency to 2 */
 878         thr_setconcurrency(2);
 879 #endif
 880 #endif
 881
 882         pthread_create(&t, NULL, task, NULL);
 883
 884 #if HAVE_SCHED_YIELD
 885         sched_yield();  /* make sure task runs first */
 886 #else
 887 #ifdef HAVE_PTHREAD_YIELD
 888         pthread_yield();        /* make sure task runs first */
 889 #endif
 890 #endif
 891
 892         exit(2);
 893 }],
 894                                 [ol_cv_pthread_select_yields=no],
 895                                 [ol_cv_pthread_select_yields=yes], [
 896                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 897                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 898
 899                                 if test $ol_cv_pthread_select_yields = yes ; then
 900                                         ol_with_yielding_select=yes
 901                                 fi
 902                         fi
 903
 904                         dnl restore flags
 905                         CPPFLAGS="$save_CPPFLAGS"
 906                         LIBS="$save_LIBS"
 907                 else
 908                         AC_MSG_ERROR([could not link with POSIX Threads])
 909                 fi
 910         fi
 911
 912         if test $ol_with_threads = posix ; then
 913                 AC_MSG_ERROR([could not locate POSIX Threads])
 914         fi
 915 fi
 916
 917 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 918         -o $ol_with_threads = mach ; then
 919
 920         dnl check for Mach CThreads
 921         AC_CHECK_HEADERS(mach/cthreads.h)
 922         if test $ac_cv_header_mach_cthreads_h = yes ; then
 923                 ol_with_threads=found
 924
 925                 dnl check for cthread support in current $LIBS
 926                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 927
 928                 if test $ol_link_threads = no ; then
 929                         dnl try -all_load
 930                         dnl this test needs work
 931                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 932                                 [ol_cv_cthread_all_load], [
 933                                 dnl save the flags
 934                                 save_LIBS="$LIBS"
 935                                 LIBS="-all_load $LIBS"
 936                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 937                                         cthread_fork((void *)0, (void *)0);
 938                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 939                                 dnl restore the LIBS
 940                                 LIBS="$save_LIBS"
 941                         ])
 942
 943                         if test $ol_cv_cthread_all_load = yes ; then
 944                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 945                                 ol_link_threads=mach
 946                         fi
 947                 fi
 948
 949                 if test $ol_link_threads != no ; then
 950                         : check for cthread specific functionality here
 951                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
 952                                 [define if you have Mach Cthreads])
 953                 else
 954                         AC_MSG_ERROR([could not link with Mach CThreads])
 955                 fi
 956         fi
 957
 958         if test $ol_with_threads = mach ; then
 959                 AC_MSG_ERROR([could not locate Mach CThreads])
 960         fi
 961 fi
 962
 963 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 964         -o $ol_with_threads = lwp ; then
 965
 966         dnl check for SunOS5 LWP
 967         AC_CHECK_HEADERS(thread.h synch.h)
 968         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 969                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 970
 971                 if test $have_thr = yes ; then
 972                         AC_DEFINE(HAVE_THR,1,
 973                                 [if you have Solaris LWP (thr) package])
 974                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 975                         ol_link_threads=thr
 976
 977                         if test $ol_with_yielding_select = auto ; then
 978                                 ol_with_yielding_select=yes
 979                         fi
 980
 981                         dnl Check for setconcurreny functions
 982                         AC_CHECK_FUNCS( \
 983                                 thr_setconcurrency \
 984                                 thr_getconcurrency \
 985                         )
 986                 fi
 987         fi
 988
 989         dnl check for SunOS4 LWP
 990         AC_CHECK_HEADERS(lwp/lwp.h)
 991         if test $ac_cv_header_lwp_lwp_h = yes ; then
 992                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 993
 994                 if test $have_lwp = yes ; then
 995                         AC_DEFINE(HAVE_LWP,1,
 996                                 [if you have SunOS LWP package])
 997                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 998                         ol_link_threads=lwp
 999
1000                         if test $ol_with_yielding_select = auto ; then
1001                                 ol_with_yielding_select=no
1002                         fi
1003                 fi
1004         fi
1005 fi
1006
1007 if test $ol_with_yielding_select = yes ; then
1008         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1009                 [define if select implicitly yields])
1010 fi
1011
1012 if test $ol_with_threads = manual ; then
1013         dnl User thinks he can manually configure threads.
1014         ol_link_threads=yes
1015
1016         AC_MSG_WARN([thread defines and link options must be set manually])
1017
1018         AC_CHECK_HEADERS(pthread.h sched.h)
1019         AC_CHECK_FUNCS(sched_yield pthread_yield)
1020         OL_LINUX_THREADS
1021
1022         AC_CHECK_HEADERS(mach/cthreads.h)
1023         AC_CHECK_HEADERS(lwp/lwp.h)
1024         AC_CHECK_HEADERS(thread.h synch.h)
1025 fi
1026
1027 if test $ol_link_threads != no ; then
1028         dnl needed to get reentrant/threadsafe versions
1029         dnl
1030         AC_DEFINE(REENTRANT,1)
1031         AC_DEFINE(_REENTRANT,1)
1032         AC_DEFINE(THREAD_SAFE,1)
1033         AC_DEFINE(_THREAD_SAFE,1)
1034         AC_DEFINE(THREADSAFE,1)
1035         AC_DEFINE(_THREADSAFE,1)
1036
1037         dnl this might cause the errno symbol to be
1038         dnl replaced with a function to get a thread specific errno.
1039         dnl check to see if everything needs to be compiled
1040         dnl with the thread libraries
1041         AC_CACHE_CHECK([for thread specific errno],
1042                 [ol_cv_errno_thread_specific], [
1043                 AC_TRY_LINK([#include <errno.h>], [int x = errno;],
1044                         [ol_cv_errno_thread_specific=yes],
1045                         [ol_cv_errno_thread_specific=no])
1046         ])
1047
1048         if test $ol_cv_errno_thread_specific != yes ; then
1049                 LIBS="$LTHREAD_LIBS $LIBS"
1050                 LTHREAD_LIBS=""
1051         fi
1052 fi
1053
1054 dnl ----------------------------------------------------------------
1055
1056 if test $ol_link_threads = no ; then
1057         if test $ol_with_threads = yes ; then
1058                 AC_MSG_ERROR([no suitable thread support])
1059         fi
1060
1061         if test $ol_with_threads = auto ; then
1062                 AC_MSG_WARN([no suitable thread support, disabling threads])
1063                 ol_with_threads=no
1064         fi
1065
1066         AC_DEFINE(NO_THREADS,1,
1067                 [define if you have (or want) no threads])
1068         LTHREAD_LIBS=""
1069 fi
1070
1071 ol_link_ldbm=no
1072 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1073         OL_BERKELEY_DB2
1074
1075         if test $ol_cv_berkeley_db2 = yes ; then
1076                 ol_link_ldbm=db2
1077                 ol_with_ldbm_api=db2
1078
1079                 if test $ol_with_ldbm_type = hash ; then
1080                         AC_DEFINE(LDBM_USE_DBHASH,1)
1081                 else
1082                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1083                 fi
1084
1085                 dnl $ol_cv_lib_db2 should be yes or -ldb
1086                 dnl (it could be no, but that would be an error
1087                 if test $ol_cv_lib_db2 != yes ; then
1088                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1089                 fi
1090         fi
1091 fi
1092
1093 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1094         OL_BERKELEY_DB
1095
1096         if test $ol_cv_berkeley_db = yes ; then
1097                 ol_link_ldbm=db
1098                 ol_with_ldbm_api=db
1099
1100                 if test $ol_with_ldbm_type = hash ; then
1101                         AC_DEFINE(LDBM_USE_DBHASH,1)
1102                 else
1103                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1104                 fi
1105
1106                 dnl $ol_cv_lib_db should be yes or -ldb
1107                 dnl (it could be no, but that would be an error
1108                 if test $ol_cv_lib_db != yes ; then
1109                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1110                 fi
1111         fi
1112 fi
1113
1114 if test $ol_with_ldbm_api = manual ; then
1115         dnl User thinks he can manually configure LDBM api.
1116         ol_link_ldbm=yes
1117
1118         AC_MSG_WARN([LDBM defines and link options must be set manually])
1119
1120         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1121 fi
1122
1123 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1124         AC_MSG_WARN(Could not find LDBM with BTREE support)
1125         ol_with_ldbm_api=none
1126 fi
1127
1128 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1129         OL_GDBM
1130
1131         if test $ol_cv_gdbm = yes ; then
1132                 ol_link_ldbm=gdbm
1133                 ol_with_ldbm_api=gdbm
1134
1135                 if test $ol_cv_lib_gdbm != yes ; then
1136                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1137                 fi
1138         fi
1139 fi
1140
1141 if test $ol_with_ldbm_api = auto ; then
1142         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1143 elif test $ol_with_ldbm_api = ndbm ; then
1144         OL_NDBM
1145
1146         if test $ol_cv_ndbm = yes ; then
1147                 ol_link_ldbm=ndbm
1148                 ol_with_ldbm_api=ndbm
1149
1150                 if test $ol_cv_lib_ndbm != yes ; then
1151                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1152                 fi
1153         fi
1154 fi
1155
1156 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1157         AC_MSG_WARN(could not find suitable LDBM backend)
1158         if test $ol_enable_ldbm = yes ; then
1159                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1160         fi
1161
1162         AC_MSG_WARN(disabling LDBM)
1163         ol_enable_ldbm=no
1164 fi
1165
1166 if test $ol_enable_wrappers != no ; then
1167         AC_CHECK_HEADERS(tcpd.h)
1168
1169         if test $ac_cv_header_tcpd_h != yes ; then
1170                 have_wrappers=no
1171         else
1172                 AC_CHECK_LIB(wrap, main,
1173                         [have_wrappers=yes], [have_wrappers=no])
1174         fi
1175
1176         if test $have_wrappers = yes ; then
1177                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1178                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1179         else
1180                 AC_MSG_WARN(could not find -lwrap)
1181                 if test $ol_enable_wrappers = yes ; then
1182                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1183                 fi
1184
1185                 AC_MSG_WARN(disabling wrappers support)
1186                 ol_enable_wrappers=no
1187         fi
1188 fi
1189
1190 if test $ol_enable_dmalloc != no ; then
1191         AC_CHECK_HEADERS(dmalloc.h)
1192         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1193 fi
1194
1195 # ud needs termcap (should insert check here)
1196 ol_link_termcap=no
1197 AC_CHECK_HEADERS(termcap.h ncurses.h)
1198
1199 if test $ol_link_termcap = no ; then
1200         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1201         if test $have_termcap = yes ; then
1202                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1203                 ol_link_termcap=yes
1204                 TERMCAP_LIBS=-ltermcap
1205         fi
1206 fi
1207
1208 if test $ol_link_termcap = no ; then
1209         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1210         if test $have_ncurses = yes ; then
1211                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1212                 ol_link_termcap=yes
1213                 TERMCAP_LIBS=-lncurses
1214         fi
1215 fi
1216
1217 if test $ol_link_termcap = no ; then
1218         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1219         TERMCAP_LIBS=
1220 fi
1221
1222 # FreeBSD (and others) have crypt(3) in -lcrypt
1223 if test $ol_enable_crypt != no ; then
1224         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1225                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1226                         have_crypt=yes], [have_crypt=no])])
1227
1228         if test $have_crypt = yes ; then
1229                 AC_DEFINE(HAVE_CRYPT,1)
1230         else
1231                 AC_MSG_WARN(could not find crypt)
1232                 if test $ol_enable_crypt = yes ; then
1233                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1234                 fi
1235
1236                 AC_MSG_WARN(disabling crypt support)
1237                 ol_enable_crypt=no
1238         fi
1239 fi
1240
1241 # FreeBSD (and others) have setproctitle(3) in -lutil
1242 if test $ol_enable_proctitle != no ; then
1243         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1244                 AC_CHECK_LIB(util, setproctitle,
1245                         [have_setproctitle=yes
1246                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1247                         [have_setproctitle=no
1248                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1249
1250         if test $have_setproctitle = yes ; then
1251                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1252         fi
1253 fi
1254
1255 dnl ----------------------------------------------------------------
1256 dnl Checks for header files.
1257 AC_HEADER_STDC
1258
1259 if test $ac_cv_header_stdc != yes; then
1260         AC_MSG_WARN([could not Standard C compliant headers])
1261 fi
1262
1263 AC_HEADER_DIRENT
1264 AC_HEADER_SYS_WAIT
1265 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1266 if test $am_cv_sys_posix_termios = yes ; then
1267         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1268                 [define if you have POSIX termios])
1269 fi
1270
1271 AC_CHECK_HEADERS(       \
1272         arpa/nameser.h  \
1273         crypt.h                 \
1274         errno.h                 \
1275         fcntl.h                 \
1276         filio.h                 \
1277         getopt.h                \
1278         libutil.h               \
1279         limits.h                \
1280         malloc.h                \
1281         memory.h                \
1282         regex.h                 \
1283         psap.h                  \
1284         pwd.h                   \
1285         resolv.h                \
1286         sgtty.h                 \
1287         stdarg.h                \
1288         stddef.h                \
1289         string.h                \
1290         strings.h               \
1291         sys/file.h              \
1292         sys/filio.h             \
1293         sys/errno.h             \
1294         sys/ioctl.h             \
1295         sys/param.h             \
1296         sys/resource.h  \
1297         sys/socket.h    \
1298         sys/syslog.h    \
1299         sys/time.h              \
1300         sys/types.h             \
1301         syslog.h                \
1302         termios.h               \
1303         unistd.h                \
1304 )
1305
1306 dnl ----------------------------------------------------------------
1307 dnl Checks for typedefs, structures, and compiler characteristics.
1308 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1309 AC_TYPE_MODE_T
1310 AC_TYPE_OFF_T
1311 AC_TYPE_PID_T
1312 AM_TYPE_PTRDIFF_T
1313 AC_TYPE_SIGNAL
1314 AC_TYPE_SIZE_T
1315 AC_STRUCT_ST_BLKSIZE
1316 AC_HEADER_TIME
1317 AC_STRUCT_TM
1318
1319 OL_C_UPPER_LOWER
1320 AC_C_CONST
1321
1322 if test $cross_compiling = yes ; then
1323         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1324 else
1325         AC_C_BIGENDIAN
1326         AC_CHECK_SIZEOF(short)
1327         AC_CHECK_SIZEOF(int)
1328         AC_CHECK_SIZEOF(long)
1329 fi
1330
1331 dnl ----------------------------------------------------------------
1332 dnl Checks for library functions.
1333 AC_FUNC_MEMCMP
1334 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1335 AC_FUNC_STRFTIME
1336 dnl AM_FUNC_STRTOD
1337 AC_FUNC_VPRINTF
1338
1339 if test $ac_cv_func_vprintf = yes ; then
1340         dnl check for vsnprintf
1341         AC_CHECK_FUNCS(vsnprintf vsprintf)
1342 fi
1343
1344 AC_CHECK_FUNCS(         \
1345         bcopy                   \
1346         flock                   \
1347         getdtablesize   \
1348         gethostname             \
1349         getpwuid                \
1350         gettimeofday    \
1351         lockf                   \
1352         memcpy                  \
1353         memmove                 \
1354         mkstemp                 \
1355         select                  \
1356         setpwfile               \
1357         setsid                  \
1358         signal                  \
1359         sigset                  \
1360         snprintf                \
1361         socket                  \
1362         strerror                \
1363         strpbrk                 \
1364         strrchr                 \
1365         strsep                  \
1366         strstr                  \
1367         strtok                  \
1368         strtol                  \
1369         strtoul                 \
1370         sysconf                 \
1371         waitpid                 \
1372 )
1373
1374 dnl We actually may need to replace more than this.
1375 AC_REPLACE_FUNCS(getopt strdup tempnam)
1376
1377 dnl ----------------------------------------------------------------
1378 # Check Configuration
1379 OL_SYS_ERRLIST
1380
1381 dnl ----------------------------------------------------------------
1382 dnl Sort out defines
1383
1384 if test "$ol_enable_debug" != no ; then
1385         AC_DEFINE(LDAP_DEBUG,1)
1386 fi
1387 if test "$ol_enable_libui" = yes ; then
1388         AC_DEFINE(LDAP_LIBUI,1)
1389 fi
1390 if test "$ol_enable_cache" = no ; then
1391         AC_DEFINE(LDAP_NOCACHE,1)
1392 fi
1393 if test "$ol_enable_dns" != no ; then
1394         AC_DEFINE(LDAP_DNS,1)
1395 fi
1396 if test "$ol_enable_proctitle" != no ; then
1397         AC_DEFINE(LDAP_PROCTITLE,1)
1398 fi
1399 if test "$ol_enable_referrals" != no ; then
1400         AC_DEFINE(LDAP_REFERRALS,1)
1401 fi
1402 if test "$ol_enable_cldap" != no ; then
1403         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1404 fi
1405
1406 if test "$ol_enable_aclgroups" != no ; then
1407         AC_DEFINE(SLAPD_ACLGROUPS,1)
1408 fi
1409 if test "$ol_enable_crypt" != no ; then
1410         AC_DEFINE(SLAPD_CRYPT,1)
1411 fi
1412 if test "$ol_enable_cleartext" != no ; then
1413         AC_DEFINE(SLAPD_CLEARTEXT,1)
1414 fi
1415 if test "$ol_enable_phonetic" != no ; then
1416         AC_DEFINE(SLAPD_PHONETIC,1)
1417 fi
1418 if test "$ol_enable_rlookups" != no ; then
1419         AC_DEFINE(SLAPD_RLOOKUPS,1)
1420 fi
1421
1422 if test "$ol_link_ldbm" != no ; then
1423         AC_DEFINE(SLAPD_LDBM,1)
1424         BUILD_SLAPD=yes
1425         BUILD_LDBM=yes
1426 fi
1427
1428 if test "$ol_enable_passwd" != no ; then
1429         AC_DEFINE(SLAPD_PASSWD,1)
1430         BUILD_SLAPD=yes
1431         BUILD_PASSWD=yes
1432 fi
1433
1434 if test "$ol_enable_shell" != no ; then
1435         AC_DEFINE(SLAPD_SHELL,1)
1436         BUILD_SLAPD=yes
1437         BUILD_SHELL=yes
1438 fi
1439
1440 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1441         $BUILD_SLAPD = yes ; then
1442         BUILD_SLURPD=yes
1443 fi
1444
1445 if test "$ol_link_isode" != no ; then
1446         BUILD_LDAPD=yes
1447 fi
1448
1449 dnl ----------------------------------------------------------------
1450
1451 AC_SUBST(BUILD_LDAPD)
1452 AC_SUBST(BUILD_SLAPD)
1453   AC_SUBST(BUILD_LDBM)
1454   AC_SUBST(BUILD_PASSWD)
1455   AC_SUBST(BUILD_SHELL)
1456 AC_SUBST(BUILD_SLURPD)
1457
1458 AC_SUBST(LDAP_LIBS)
1459 AC_SUBST(LDAPD_LIBS)
1460 AC_SUBST(SLAPD_LIBS)
1461 AC_SUBST(SLURPD_LIBS)
1462 AC_SUBST(LDBM_LIBS)
1463 AC_SUBST(LTHREAD_LIBS)
1464 AC_SUBST(LUTIL_LIBS)
1465
1466 AC_SUBST(KRB_LIBS)
1467 AC_SUBST(TERMCAP_LIBS)
1468
1469 dnl ----------------------------------------------------------------
1470 dnl final output
1471 dnl
1472
1473 AC_OUTPUT( \
1474 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1475 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1476 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1477 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1478 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1479 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1480 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1481 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1482 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1483 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1484 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1485 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1486 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1487 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1488 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1489 include/Makefile:build/top.mk:include/Makefile.in \
1490 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1491 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1492 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1493 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1494 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1495 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1496 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1497 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1498 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1499 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1500 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1501 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1502 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1503 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1504 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1505 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1506 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1507 tests/Makefile:build/top.mk:tests/Makefile.in \
1508 ,[
1509 date > stamp-h
1510 echo Please \"make depend\" to build dependencies
1511 ])