git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl This work is part of OpenLDAP Software <http://www.openldap.org/>.
   3 dnl
   4 dnl Copyright 1998-2008 The OpenLDAP Foundation.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted only as authorized by the OpenLDAP
   9 dnl Public License.
  10 dnl
  11 dnl A copy of this license is available in the file LICENSE in the
  12 dnl top-level directory of the distribution or, alternatively, at
  13 dnl <http://www.OpenLDAP.org/license.html>.
  14 dnl
  15 dnl ----------------------------------------------------------------
  16 dnl Disable config.cache!
  17 define([AC_CACHE_LOAD], )dnl
  18 define([AC_CACHE_SAVE], )dnl
  19 dnl ----------------------------------------------------------------
  20 dnl Disable libtool 1.5 support for languages we don't use
  21 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  22 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  23 define([AC_LIBTOOL_LANG_GCJ_CONFIG], [:])dnl
  24 dnl ================================================================
  25 dnl Configure.in for OpenLDAP
  26 AC_COPYRIGHT([[Copyright 1998-2008 The OpenLDAP Foundation. All rights reserved.
  27 Restrictions apply, see COPYRIGHT and LICENSE files.]])
  28 AC_REVISION([$OpenLDAP$])
  29 AC_INIT([OpenLDAP],,[http://www.openldap.org/its/])
  30 m4_define([AC_PACKAGE_BUGREPORT],[<http://www.openldap.org/its/>])
  31 AC_CONFIG_SRCDIR(build/version.sh)dnl
  32 dnl ----------------------------------------------------------------
  33 dnl OpenLDAP Autoconf Macros
  34 builtin(include, build/openldap.m4)dnl
  35 dnl ================================================================
  36
  37 AC_CONFIG_AUX_DIR(build)dnl
  38
  39 eval `$ac_aux_dir/version.sh`
  40 if test -z "$OL_STRING"; then
  41         AC_MSG_ERROR([could not determine version])
  42 fi
  43
  44 if test -f "$ac_aux_dir/shtool" && test ! -d $ac_aux_dir/shtool; then
  45         ac_cv_shtool="$ac_aux_dir/shtool"
  46 else
  47         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  48 fi
  49
  50 SHTOOL="$ac_cv_shtool"
  51 dnl AC_SUBST(SHTOOL)dnl
  52
  53 TB="" TN=""
  54 if test -t 1; then
  55         TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  56         TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  57 fi
  58
  59 OPENLDAP_CVS=""
  60 if test -d $ac_aux_dir/CVS; then
  61         OPENLDAP_CVS="(from CVS sources) "
  62 fi
  63
  64 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_CVS}..."
  65
  66 dnl Determine host platform
  67 dnl             we try not to use this for much
  68 AC_CANONICAL_TARGET([])
  69
  70 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  71 AC_SUBST(PACKAGE)dnl
  72 AC_SUBST(VERSION)dnl
  73 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  74 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  75
  76 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  77 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  78 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  79 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  80
  81 OPENLDAP_LIBRELEASE=$OL_API_LIB_RELEASE
  82 AC_SUBST(OPENLDAP_LIBRELEASE)dnl
  83
  84 OPENLDAP_LIBVERSION=$OL_API_LIB_VERSION
  85 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  86
  87 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  88 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  89
  90 dnl We use autoconf features new to 2.59.  Later versions like won't work.
  91 dnl aclocal.m4 should be built using aclocal from automake 1.5
  92 dnl libtool 1.5 should be installed.
  93 AC_PREREQ(2.59)dnl Required Autoconf version
  94
  95 AH_TOP([
  96 /* begin of portable.h.pre */
  97 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
  98  *
  99  * Copyright 1998-2008 The OpenLDAP Foundation
 100  * All rights reserved.
 101  *
 102  * Redistribution and use in source and binary forms, with or without
 103  * modification, are permitted only as authorized by the OpenLDAP
 104  * Public License.
 105  *
 106  * A copy of this license is available in the file LICENSE in the
 107  * top-level directory of the distribution or, alternatively, at
 108  * <http://www.OpenLDAP.org/license.html>.
 109  */
 110
 111 #ifndef _LDAP_PORTABLE_H
 112 #define _LDAP_PORTABLE_H
 113
 114 /* define this if needed to get reentrant functions */
 115 #ifndef REENTRANT
 116 #undef REENTRANT
 117 #endif
 118 #ifndef _REENTRANT
 119 #undef _REENTRANT
 120 #endif
 121
 122 /* define this if needed to get threadsafe functions */
 123 #ifndef THREADSAFE
 124 #undef THREADSAFE
 125 #endif
 126 #ifndef _THREADSAFE
 127 #undef _THREADSAFE
 128 #endif
 129 #ifndef THREAD_SAFE
 130 #undef THREAD_SAFE
 131 #endif
 132 #ifndef _THREAD_SAFE
 133 #undef _THREAD_SAFE
 134 #endif
 135
 136 #ifndef _SGI_MP_SOURCE
 137 #undef _SGI_MP_SOURCE
 138 #endif
 139
 140 /* end of portable.h.pre */
 141 ])
 142 AH_BOTTOM([
 143 /* begin of portable.h.post */
 144
 145 #ifdef _WIN32
 146         /* don't suck in all of the win32 api */
 147 #       define WIN32_LEAN_AND_MEAN 1
 148 #endif
 149
 150 #ifndef LDAP_NEEDS_PROTOTYPES
 151 /* force LDAP_P to always include prototypes */
 152 #define LDAP_NEEDS_PROTOTYPES 1
 153 #endif
 154
 155 #ifndef LDAP_REL_ENG
 156 #if (LDAP_VENDOR_VERSION == 000000) && !defined(LDAP_DEVEL)
 157 #define LDAP_DEVEL
 158 #endif
 159 #if defined(LDAP_DEVEL) && !defined(LDAP_TEST)
 160 #define LDAP_TEST
 161 #endif
 162 #endif
 163
 164 #ifdef HAVE_STDDEF_H
 165 #       include <stddef.h>
 166 #endif
 167
 168 #ifdef HAVE_EBCDIC
 169 /* ASCII/EBCDIC converting replacements for stdio funcs
 170  * vsnprintf and snprintf are used too, but they are already
 171  * checked by the configure script
 172  */
 173 #define fputs ber_pvt_fputs
 174 #define fgets ber_pvt_fgets
 175 #define printf ber_pvt_printf
 176 #define fprintf ber_pvt_fprintf
 177 #define vfprintf ber_pvt_vfprintf
 178 #define vsprintf ber_pvt_vsprintf
 179 #endif
 180
 181 #include "ac/fdset.h"
 182
 183 #include "ldap_cdefs.h"
 184 #include "ldap_features.h"
 185
 186 #include "ac/assert.h"
 187 #include "ac/localize.h"
 188
 189 #endif /* _LDAP_PORTABLE_H */
 190 /* end of portable.h.post */
 191 ])
 192
 193 AC_CONFIG_HEADERS([include/portable.h:include/portable.hin])
 194 AC_CONFIG_HEADERS([include/ldap_features.h:include/ldap_features.hin])
 195 AC_CONFIG_HEADERS([include/lber_types.h:include/lber_types.hin])
 196
 197 dnl ================================================================
 198 dnl Start Args
 199 AC_MSG_CHECKING(configure arguments)
 200 AC_PREFIX_DEFAULT(/usr/local)
 201
 202 top_builddir=`pwd`
 203 AC_SUBST(top_builddir)dnl
 204
 205 dnl ----------------------------------------------------------------
 206 dnl --with-subdir
 207 ldap_subdir="/openldap"
 208
 209 AC_ARG_WITH(subdir,
 210 [  --with-subdir=DIR       change default subdirectory used for installs],
 211 [case "$withval" in
 212         no) ldap_subdir=""
 213                 ;;
 214         yes)
 215                 ;;
 216         /*|\\*)
 217                 ldap_subdir="$withval"
 218                 ;;
 219         *)
 220                 ldap_subdir="/$withval"
 221                 ;;
 222 esac
 223 ])dnl
 224
 225 AC_SUBST(ldap_subdir)dnl
 226
 227 dnl ----------------------------------------------------------------
 228 dnl General "enable" options
 229 dnl set default to traditional to enable the original debug style
 230 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes, [no yes traditional])dnl
 231 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 232 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 233 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 234 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 235 ol_enable_referrals=${ol_enable_referrals-no}
 236 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 237 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 238
 239 dnl ----------------------------------------------------------------
 240 dnl General "with" options
 241 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 242         auto, [auto yes no] )
 243 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 244         auto, [auto yes no] )
 245 OL_ARG_WITH(threads,[  --with-threads     with threads],
 246         auto, [auto nt posix mach pth lwp yes no manual] )
 247 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support auto|openssl|gnutls],
 248         auto, [auto openssl gnutls yes no] )
 249 OL_ARG_WITH(yielding_select,
 250         [  --with-yielding-select  with implicitly yielding select],
 251         auto, [auto yes no manual] )
 252 OL_ARG_WITH(mp,
 253         [  --with-mp               with multiple precision statistics auto|longlong|long|bignum|gmp],
 254         auto, [auto longlong long bignum gmp yes no])
 255 OL_ARG_WITH(odbc,
 256         [  --with-odbc             with specific ODBC support iodbc|unixodbc|odbc32|auto],
 257         auto, [auto iodbc unixodbc odbc32] )
 258
 259 dnl ----------------------------------------------------------------
 260 dnl Server options
 261 dnl ----------------------------------------------------------------
 262
 263 dnl ----------------------------------------------------------------
 264 dnl SLAPD OPTIONS
 265 AC_ARG_ENABLE(xxslapdoptions,[
 266 SLAPD (Standalone LDAP Daemon) Options:])
 267 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 268 OL_ARG_ENABLE(dynacl,[    --enable-dynacl         enable run-time loadable ACL support (experimental)], no)dnl
 269 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no, [no yes mod])dnl
 270 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 271 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 272 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 273 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 274 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 275 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and rwm overlay], auto)dnl
 276 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 277 OL_ARG_ENABLE(slapi,[    --enable-slapi        enable SLAPI support (experimental)], no)dnl
 278 OL_ARG_ENABLE(slp,[    --enable-slp          enable SLPv2 support], no)dnl
 279 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 280
 281 dnl ----------------------------------------------------------------
 282 dnl SLAPD Backend Options
 283 Backends="bdb \
 284         dnssrv \
 285         hdb \
 286         ldap \
 287         meta \
 288         monitor \
 289         null \
 290         passwd \
 291         perl \
 292         relay \
 293         shell \
 294         sock \
 295         sql"
 296
 297 AC_ARG_ENABLE(xxslapbackends,[
 298 SLAPD Backend Options:])
 299
 300 OL_ARG_ENABLE(backends,[    --enable-backends     enable all available backends],
 301         --, [no yes mod])dnl
 302 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend],
 303         yes, [no yes mod], ol_enable_backends)dnl
 304 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend],
 305         no, [no yes mod], ol_enable_backends)dnl
 306 OL_ARG_ENABLE(hdb,[    --enable-hdb       enable Hierarchical DB backend],
 307         yes, [no yes mod], ol_enable_backends)dnl
 308 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend],
 309         no, [no yes mod], ol_enable_backends)dnl
 310 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend],
 311         no, [no yes mod], ol_enable_backends)dnl
 312 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend],
 313         yes, [no yes mod], ol_enable_backends)dnl
 314 OL_ARG_ENABLE(null,[    --enable-null     enable null backend],
 315         no, [no yes mod], ol_enable_backends)dnl
 316 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend],
 317         no, [no yes mod], ol_enable_backends)dnl
 318 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend],
 319         no, [no yes mod], ol_enable_backends)dnl
 320 OL_ARG_ENABLE(relay,[    --enable-relay           enable relay backend],
 321         yes, [no yes mod], ol_enable_backends)dnl
 322 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend],
 323         no, [no yes mod], ol_enable_backends)dnl
 324 OL_ARG_ENABLE(sock,[    --enable-sock     enable sock backend],
 325         no, [no yes mod], ol_enable_backends)dnl
 326 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend],
 327         no, [no yes mod], ol_enable_backends)dnl
 328
 329 dnl ----------------------------------------------------------------
 330 dnl SLAPD Overlay Options
 331 Overlays="accesslog \
 332         auditlog \
 333         constraint \
 334         dds \
 335         dyngroup \
 336         dynlist \
 337         memberof \
 338         ppolicy \
 339         proxycache \
 340         refint \
 341         retcode \
 342         rwm \
 343         seqmod \
 344         syncprov \
 345         translucent \
 346         unique \
 347         valsort"
 348
 349 AC_ARG_ENABLE(xxslapoverlays,[
 350 SLAPD Overlay Options:])
 351
 352 OL_ARG_ENABLE(overlays,[    --enable-overlays     enable all available overlays],
 353         --, [no yes mod])dnl
 354 OL_ARG_ENABLE(accesslog,[    --enable-accesslog   In-Directory Access Logging overlay],
 355         no, [no yes mod], ol_enable_overlays)
 356 OL_ARG_ENABLE(auditlog,[    --enable-auditlog     Audit Logging overlay],
 357         no, [no yes mod], ol_enable_overlays)
 358 OL_ARG_ENABLE(constraint,[    --enable-constraint         Attribute Constraint overlay],
 359         no, [no yes mod], ol_enable_overlays)
 360 OL_ARG_ENABLE(dds,[    --enable-dds       Dynamic Directory Services overlay],
 361         no, [no yes mod], ol_enable_overlays)
 362 OL_ARG_ENABLE(dyngroup,[    --enable-dyngroup     Dynamic Group overlay],
 363         no, [no yes mod], ol_enable_overlays)
 364 OL_ARG_ENABLE(dynlist,[    --enable-dynlist       Dynamic List overlay],
 365         no, [no yes mod], ol_enable_overlays)
 366 OL_ARG_ENABLE(memberof,[    --enable-memberof     Reverse Group Membership overlay],
 367         no, [no yes mod], ol_enable_overlays)
 368 OL_ARG_ENABLE(ppolicy,[    --enable-ppolicy       Password Policy overlay],
 369         no, [no yes mod], ol_enable_overlays)
 370 OL_ARG_ENABLE(proxycache,[    --enable-proxycache         Proxy Cache overlay],
 371         no, [no yes mod], ol_enable_overlays)
 372 OL_ARG_ENABLE(refint,[    --enable-refint         Referential Integrity overlay],
 373         no, [no yes mod], ol_enable_overlays)
 374 OL_ARG_ENABLE(retcode,[    --enable-retcode       Return Code testing overlay],
 375         no, [no yes mod], ol_enable_overlays)
 376 OL_ARG_ENABLE(rwm,[    --enable-rwm               Rewrite/Remap overlay],
 377         no, [no yes mod], ol_enable_overlays)
 378 OL_ARG_ENABLE(seqmod,[    --enable-seqmod         Sequential Modify overlay],
 379         yes, [no yes mod], ol_enable_overlays)
 380 OL_ARG_ENABLE(syncprov,[    --enable-syncprov     Syncrepl Provider overlay],
 381         yes, [no yes mod], ol_enable_overlays)
 382 OL_ARG_ENABLE(translucent,[    --enable-translucent  Translucent Proxy overlay],
 383         no, [no yes mod], ol_enable_overlays)
 384 OL_ARG_ENABLE(unique,[    --enable-unique       Attribute Uniqueness overlay],
 385         no, [no yes mod], ol_enable_overlays)
 386 OL_ARG_ENABLE(valsort,[    --enable-valsort      Value Sorting overlay],
 387         no, [no yes mod], ol_enable_overlays)
 388
 389 dnl ----------------------------------------------------------------
 390 AC_ARG_ENABLE(xxliboptions,[
 391 Library Generation & Linking Options])
 392 AC_ENABLE_STATIC
 393 AC_ENABLE_SHARED
 394
 395 dnl ----------------------------------------------------------------
 396
 397 # validate options
 398 if test $ol_enable_slapd = no ; then
 399         dnl SLAPD was specificallly disabled
 400         if test $ol_enable_slapi = yes ; then
 401                 AC_MSG_WARN([slapd disabled, ignoring --enable-slapi argument])
 402         fi
 403         case "$ol_enable_backends" in yes | mod)
 404                 AC_MSG_WARN([slapd disabled, ignoring --enable-backends argument])
 405         esac
 406         for i in $Backends; do
 407                 eval "ol_tmp=\$ol_enable_$i"
 408                 if test $ol_tmp != no ; then
 409                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 410                         eval "ol_enable_$i=no"
 411                 fi
 412         done
 413         if test $ol_enable_modules = yes ; then
 414                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 415         fi
 416         if test $ol_enable_wrappers = yes ; then
 417                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 418         fi
 419         if test $ol_enable_rlookups = yes ; then
 420                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 421         fi
 422         if test $ol_enable_dynacl = yes ; then
 423                 AC_MSG_WARN([slapd disabled, ignoring --enable-dynacl argument])
 424         fi
 425         if test $ol_enable_aci != no ; then
 426                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 427         fi
 428         if test $ol_enable_rewrite = yes ; then
 429                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 430         fi
 431         dnl overlays
 432         case "$ol_enable_overlays" in yes | mod)
 433                 AC_MSG_WARN([slapd disabled, ignoring --enable-overlays argument])
 434         esac
 435         for i in $Overlays; do
 436                 eval "ol_tmp=\$ol_enable_$i"
 437                 if test $ol_tmp != no ; then
 438                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 439                         eval "ol_enable_$i=no"
 440                 fi
 441         done
 442
 443         # force settings to no
 444         ol_enable_slapi=no
 445
 446         ol_enable_backends=
 447         ol_enable_overlays=
 448         ol_enable_modules=no
 449         ol_enable_rlookups=no
 450         ol_enable_dynacl=no
 451         ol_enable_aci=no
 452         ol_enable_wrappers=no
 453
 454         ol_enable_rewrite=no
 455
 456 elif test $ol_enable_modules != yes &&
 457         test $ol_enable_bdb = no &&
 458         test $ol_enable_dnssrv = no &&
 459         test $ol_enable_hdb = no &&
 460         test $ol_enable_ldap = no &&
 461         test $ol_enable_meta = no &&
 462         test $ol_enable_monitor = no &&
 463         test $ol_enable_null = no &&
 464         test $ol_enable_passwd = no &&
 465         test $ol_enable_perl = no &&
 466         test $ol_enable_relay = no &&
 467         test $ol_enable_shell = no &&
 468         test $ol_enable_sock = no &&
 469         test $ol_enable_sql = no ; then
 470         dnl no slapd backend
 471
 472         if test $ol_enable_slapd = yes ; then
 473                 AC_MSG_ERROR([slapd requires a backend])
 474         else
 475                 AC_MSG_WARN([skipping slapd, no backend specified])
 476                 ol_enable_slapd=no
 477         fi
 478 fi
 479
 480 if test $ol_enable_meta/$ol_enable_ldap = yes/no ; then
 481         AC_MSG_ERROR([--enable-meta requires --enable-ldap])
 482 fi
 483
 484 if test $ol_enable_lmpasswd = yes ; then
 485         if test $ol_with_tls = no ; then
 486                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 487         fi
 488 fi
 489
 490 if test $ol_enable_spasswd = yes ; then
 491         if test $ol_with_cyrus_sasl = no ; then
 492                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 493         fi
 494         ol_with_cyrus_sasl=yes
 495 fi
 496
 497 AC_MSG_RESULT(done)
 498
 499 dnl ----------------------------------------------------------------
 500 dnl Initialize vars
 501 LDAP_LIBS=
 502 BDB_LIBS=
 503 LTHREAD_LIBS=
 504 LUTIL_LIBS=
 505
 506 SLAPD_LIBS=
 507
 508 BUILD_SLAPD=no
 509
 510 BUILD_THREAD=no
 511
 512 BUILD_SLAPI=no
 513 SLAPD_SLAPI_DEPEND=
 514
 515 BUILD_BDB=no
 516 BUILD_DNSSRV=no
 517 BUILD_HDB=no
 518 BUILD_LDAP=no
 519 BUILD_META=no
 520 BUILD_MONITOR=no
 521 BUILD_NULL=no
 522 BUILD_PASSWD=no
 523 BUILD_PERL=no
 524 BUILD_RELAY=no
 525 BUILD_SHELL=no
 526 BUILD_SOCK=no
 527 BUILD_SQL=no
 528
 529 BUILD_ACCESSLOG=no
 530 BUILD_AUDITLOG=no
 531 BUILD_CONSTRAINT=no
 532 BUILD_DDS=no
 533 BUILD_DENYOP=no
 534 BUILD_DYNGROUP=no
 535 BUILD_DYNLIST=no
 536 BUILD_LASTMOD=no
 537 BUILD_MEMBEROF=no
 538 BUILD_PPOLICY=no
 539 BUILD_PROXYCACHE=no
 540 BUILD_REFINT=no
 541 BUILD_RETCODE=no
 542 BUILD_RWM=no
 543 BUILD_SEQMOD=no
 544 BUILD_SYNCPROV=no
 545 BUILD_TRANSLUCENT=no
 546 BUILD_UNIQUE=no
 547 BUILD_VALSORT=no
 548
 549 SLAPD_STATIC_OVERLAYS=
 550 SLAPD_DYNAMIC_OVERLAYS=
 551
 552 SLAPD_MODULES_LDFLAGS=
 553 SLAPD_MODULES_CPPFLAGS=
 554
 555 SLAPD_STATIC_BACKENDS=back-ldif
 556 SLAPD_DYNAMIC_BACKENDS=
 557
 558 SLAPD_PERL_LDFLAGS=
 559 MOD_PERL_LDFLAGS=
 560 PERL_CPPFLAGS=
 561
 562 SLAPD_SQL_LDFLAGS=
 563 SLAPD_SQL_LIBS=
 564 SLAPD_SQL_INCLUDES=
 565
 566 KRB4_LIBS=
 567 KRB5_LIBS=
 568 SASL_LIBS=
 569 TLS_LIBS=
 570 MODULES_LIBS=
 571 SLAPI_LIBS=
 572 LIBSLAPI=
 573 LIBSLAPITOOLS=
 574 AUTH_LIBS=
 575 ICU_LIBS=
 576
 577 SLAPD_SLP_LIBS=
 578 SLAPD_GMP_LIBS=
 579
 580 dnl ================================================================
 581 dnl Checks for programs
 582
 583 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 584
 585 dnl ----------------------------------------------------------------
 586 dnl
 587 dnl Determine which C translator to use
 588 dnl
 589
 590 dnl AIX Thread requires we use cc_r or xlc_r.
 591 dnl But only do this IF AIX and CC is not set
 592 dnl and threads are auto|yes|posix.
 593 dnl
 594 dnl If we find cc_r|xlc_r, force pthreads and assume
 595 dnl             pthread_create is in $LIBS (ie: don't bring in
 596 dnl             any additional thread libraries)
 597 dnl If we do not find cc_r|xlc_r, disable threads
 598
 599 ol_aix_threads=no
 600 case "$target" in
 601 *-*-aix*) dnl all AIX is not a good idea.
 602         if test -z "$CC" ; then
 603                 case "$ol_with_threads" in
 604                 auto | yes |  posix) ol_aix_threads=yes ;;
 605                 esac
 606         fi
 607 ;;
 608 esac
 609
 610 if test $ol_aix_threads = yes ; then
 611         if test -z "${CC}" ; then
 612                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 613
 614                 if test "$CC" = cc ; then
 615                         dnl no CC! don't allow --with-threads
 616                         if test $ol_with_threads != auto ; then
 617                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 618                         else
 619                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 620                         fi
 621                         ol_with_threads=no
 622                 fi
 623         fi
 624
 625         case ${CC} in cc_r | xlc_r)
 626                 ol_with_threads=posix
 627                 ol_cv_pthread_create=yes
 628                 ;;
 629         esac
 630 fi
 631
 632 if test -z "${CC}"; then
 633         AC_CHECK_PROGS(CC,cc gcc,missing)
 634
 635         if test "${CC}" = "missing" ; then
 636                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 637         fi
 638 fi
 639
 640 if test -z "${AR}"; then
 641         AC_CHECK_PROGS(AR,ar gar,missing)
 642
 643         if test "${AR}" = "missing" ; then
 644                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 645         fi
 646 fi
 647
 648 AC_LIBTOOL_WIN32_DLL
 649 AC_LIBTOOL_DLOPEN
 650 AC_PROG_LIBTOOL
 651
 652 dnl ----------------------------------------------------------------
 653 dnl Perl
 654 ol_link_perl=no
 655 if test $ol_enable_perl != no ; then
 656         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 657
 658         if test "no$PERLBIN" = "no" ; then
 659                 if test $ol_enable_perl = yes ; then
 660                         AC_MSG_ERROR([could not locate perl])
 661                 fi
 662
 663         else
 664                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 665                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 666
 667                 if test x"$ol_enable_perl" = "xyes" ; then
 668                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 669                 else
 670                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 671                 fi
 672                 dnl should check perl version
 673                 ol_link_perl=yes
 674         fi
 675 fi
 676
 677 AC_PROG_CPP
 678
 679 dnl ----------------------------------------------------------------
 680 dnl Checks for Windows NT
 681 case $host_os in
 682   *mingw32* ) ac_cv_mingw32=yes ;;
 683   *cygwin* ) ac_cv_cygwin=yes ;;
 684 esac
 685
 686 dnl ----------------------------------------------------------------
 687 dnl Checks for file extensions
 688 AC_EXEEXT
 689 AC_OBJEXT
 690 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 691
 692 dnl ----------------------------------------------------------------
 693 dnl BeOS requires -lbe -lroot -lnet
 694 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 695
 696 dnl ----------------------------------------------------------------
 697 dnl OpenLDAP requires STDC features
 698 AC_PROG_CC
 699 if test "X${ac_cv_prog_cc_stdc}" = "Xno" ; then
 700         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 701 fi
 702
 703 dnl ----------------------------------------------------------------
 704 dnl Check cc depend flags
 705 OL_MKDEPEND
 706 if test "${ol_cv_mkdep}" = no ; then
 707         # this will soon become an error
 708         AC_MSG_WARN([do not know how to generate dependencies])
 709 fi
 710
 711 dnl ----------------------------------------------------------------
 712 dnl Check for AIX security library
 713 AC_CHECK_LIB(s, afopen, [
 714         AUTH_LIBS=-ls
 715         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 716 ])
 717
 718 dnl ----------------------------------------------------------------
 719 dnl Check for IBM OS/390
 720 case "$target" in
 721 *-ibm-openedition)
 722         ac_cv_func_getopt=no
 723         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 724         ;;
 725 esac
 726
 727 dnl ----------------------------------------------------------------
 728 dnl Check for module support
 729 ol_link_modules=no
 730 WITH_MODULES_ENABLED=no
 731 if test $ol_enable_modules != no ; then
 732         AC_CHECK_HEADERS(ltdl.h)
 733
 734         if test $ac_cv_header_ltdl_h = no ; then
 735                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 736         fi
 737
 738         AC_CHECK_LIB(ltdl, lt_dlinit, [
 739                 MODULES_LIBS=-lltdl
 740                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 741         ])
 742
 743         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 744                 AC_MSG_ERROR([could not locate libtool -lltdl])
 745         fi
 746         ol_link_modules=yes
 747         WITH_MODULES_ENABLED=yes
 748
 749 else
 750         for i in $Backends; do
 751                 eval "ol_tmp=\$ol_enable_$i"
 752                 if test $ol_tmp = mod ; then
 753                         AC_MSG_WARN([building static $i backend])
 754                         eval "ol_enable_$i=yes"
 755                 fi
 756         done
 757         for i in $Overlays; do
 758                 eval "ol_tmp=\$ol_enable_$i"
 759                 if test $ol_tmp = mod ; then
 760                         AC_MSG_WARN([building static $i overlay])
 761                         eval "ol_enable_$i=yes"
 762                 fi
 763         done
 764 fi
 765
 766 dnl ----------------------------------------------------------------
 767 dnl Checks for header files.
 768 OL_HEADER_STDC
 769
 770 if test $ol_cv_header_stdc != yes; then
 771         AC_MSG_WARN([could not locate Standard C compliant headers])
 772 fi
 773
 774 AC_HEADER_DIRENT
 775 AC_HEADER_SYS_WAIT
 776 AC_HEADER_TIOCGWINSZ
 777
 778 AC_CHECK_HEADERS(       \
 779         arpa/inet.h             \
 780         arpa/nameser.h  \
 781         assert.h                \
 782         bits/types.h    \
 783         conio.h                 \
 784         crypt.h                 \
 785         direct.h                \
 786         errno.h                 \
 787         fcntl.h                 \
 788         filio.h                 \
 789         getopt.h                \
 790         grp.h                   \
 791         io.h                    \
 792         libutil.h               \
 793         limits.h                \
 794         locale.h                \
 795         malloc.h                \
 796         memory.h                \
 797         psap.h                  \
 798         pwd.h                   \
 799         process.h               \
 800         sgtty.h                 \
 801         shadow.h                \
 802         stddef.h                \
 803         string.h                \
 804         strings.h               \
 805         sysexits.h              \
 806         sys/file.h              \
 807         sys/filio.h             \
 808         sys/fstyp.h             \
 809         sys/errno.h             \
 810         sys/ioctl.h             \
 811         sys/param.h             \
 812         sys/privgrp.h   \
 813         sys/resource.h  \
 814         sys/select.h    \
 815         sys/socket.h    \
 816         sys/stat.h              \
 817         sys/syslog.h    \
 818         sys/time.h              \
 819         sys/types.h             \
 820         sys/uio.h               \
 821         sys/vmount.h    \
 822         syslog.h                \
 823         termios.h               \
 824         unistd.h                \
 825         utime.h                 \
 826 )
 827
 828 dnl Only check Winsock on MinGW
 829 if test "$ac_cv_mingw32" = yes ; then
 830         AC_CHECK_HEADERS( winsock.h winsock2.h )
 831 fi
 832
 833 AC_CHECK_HEADERS( resolv.h, [], [],
 834 [$ac_includes_default
 835 #include <netinet/in.h>
 836 ])
 837
 838 AC_CHECK_HEADERS( netinet/tcp.h, [], [],
 839 [$ac_includes_default
 840 #include <netinet/in.h>
 841 ])
 842
 843 AC_CHECK_HEADERS( sys/ucred.h, [], [],
 844 [$ac_includes_default
 845 #ifdef HAVE_SYS_PARAM_H
 846 #include <sys/param.h>
 847 #endif
 848 ])
 849
 850 dnl ----------------------------------------------------------------
 851 dnl Checks for libraries
 852
 853 AC_CHECK_FUNCS( sigaction sigset )
 854
 855 dnl HP-UX requires -lV3
 856 dnl this is not needed on newer versions of HP-UX
 857 if test $ac_cv_func_sigaction = no && test $ac_cv_func_sigaction = no ; then
 858         AC_CHECK_LIB(V3, sigset)
 859 fi
 860
 861 dnl The following is INTENTIONALLY scripted out because shell does not
 862 dnl support variable names with the '@' character, which is what
 863 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 864 if test "$ac_cv_header_winsock_h" = yes; then
 865 AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 866 save_LIBS="$LIBS"
 867 for curlib in ws2_32 wsock32; do
 868         LIBS="$LIBS -l$curlib"
 869         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <winsock.h>
 870                         ]], [[
 871                         socket(0,0,0);
 872                         select(0,NULL,NULL,NULL,NULL);
 873                         closesocket(0);
 874                         gethostname(NULL,0);
 875                         ]])],[ol_cv_winsock=yes],[ol_cv_winsock=no])
 876
 877         if test $ol_cv_winsock = yes; then
 878                 AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 879                 ac_cv_func_socket=yes
 880                 ac_cv_func_select=yes
 881                 ac_cv_func_closesocket=yes
 882                 ac_cv_func_gethostname=yes
 883                 if test $curlib = ws2_32; then
 884                         ol_cv_winsock=winsock2
 885                         AC_DEFINE(HAVE_WINSOCK2, 1,
 886                                   [define if you have winsock2])
 887                 fi
 888                 break
 889         fi
 890         LIBS="$save_LIBS"
 891 done)
 892 fi
 893
 894 dnl Find socket()
 895 dnl Likely combinations:
 896 dnl             -lsocket [ -lnsl_s | -lnsl ]
 897 dnl             -linet
 898
 899 AC_CHECK_FUNC(socket, :, [
 900 dnl hopefully we won't include too many libraries
 901         AC_CHECK_LIB(socket, main)
 902         AC_CHECK_LIB(net, main)
 903         AC_CHECK_LIB(nsl_s, main)
 904         AC_CHECK_LIB(nsl, main)
 905         AC_CHECK_LIB(inet, socket)
 906         AC_CHECK_LIB(gen, main)
 907 ])
 908
 909 dnl require select
 910 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 911
 912 if test "${ac_cv_header_winsock_h}" != yes; then
 913         dnl Select arg types
 914         dnl (if this detection becomes permenent, it and the select() detection
 915         dnl should be done before the yielding select test)
 916         AC_FUNC_SELECT_ARGTYPES
 917 fi
 918
 919 dnl check to see if system call automatically restart
 920 dnl AC_SYS_RESTARTABLE_SYSCALLS
 921
 922 dnl ----------------------------------------------------------------
 923 AC_CHECK_FUNCS( poll )
 924 if test $ac_cv_func_poll = yes; then
 925 AC_CHECK_HEADERS( poll.h sys/poll.h )
 926 fi
 927
 928 dnl ----------------------------------------------------------------
 929 AC_CHECK_HEADERS( sys/epoll.h )
 930 if test "${ac_cv_header_sys_epoll_h}" = yes; then
 931         AC_MSG_CHECKING(for epoll system call)
 932         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 933 {
 934         int epfd = epoll_create(256);
 935         exit (epfd == -1 ? 1 : 0);
 936 }]])],[AC_MSG_RESULT(yes)
 937         AC_DEFINE(HAVE_EPOLL,1, [define if your system supports epoll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 938 fi
 939
 940 dnl ----------------------------------------------------------------
 941 AC_CHECK_HEADERS( sys/devpoll.h )
 942 dnl "/dev/poll" needs <sys/poll.h> as well...
 943 if test "${ac_cv_header_sys_devpoll_h}" = yes \
 944                 -a "${ac_cv_header_poll_h}" = yes ; \
 945 then
 946         AC_MSG_CHECKING(for /dev/poll)
 947         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 948 {
 949         int devpollfd = open("/dev/poll", /* O_RDWR */ 2);
 950         exit (devpollfd == -1 ? 1 : 0);
 951 }]])],[AC_MSG_RESULT(yes)
 952         AC_DEFINE(HAVE_DEVPOLL,1, [define if your system supports /dev/poll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 953 fi
 954
 955 dnl ----------------------------------------------------------------
 956 # strerror checks
 957 OL_STRERROR
 958
 959 dnl ----------------------------------------------------------------
 960 dnl require POSIX regex
 961 AC_CHECK_HEADERS( regex.h, [], [],
 962 [$ac_includes_default
 963 #ifdef HAVE_SYS_TYPES_H
 964 #include <sys/types.h>
 965 #endif
 966 ])
 967
 968 if test "$ac_cv_header_regex_h" != yes ; then
 969         AC_MSG_ERROR([POSIX regex.h required.])
 970 fi
 971 AC_SEARCH_LIBS(regfree, [regex gnuregex],
 972         :, AC_MSG_ERROR([POSIX regex required.]))
 973
 974 OL_POSIX_REGEX
 975 if test "$ol_cv_c_posix_regex" = no ; then
 976         AC_MSG_ERROR([broken POSIX regex!])
 977 fi
 978
 979 dnl ----------------------------------------------------------------
 980 dnl UUID Support
 981
 982 have_uuid=no
 983 AC_CHECK_HEADERS(sys/uuid.h)
 984 if test $ac_cv_header_sys_uuid_h = yes ; then
 985         save_LIBS="$LIBS"
 986         AC_SEARCH_LIBS([uuid_to_str], [uuid], [have_uuid=yes], :)
 987         LIBS="$save_LIBS"
 988
 989         if test have_uuid = yes ; then
 990                 AC_DEFINE(HAVE_UUID_TO_STR,1,
 991                         [define if you have uuid_to_str()])
 992
 993                 test "$ac_cv_search_uuid_to_str" = "none required" || \
 994                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
 995         fi
 996 fi
 997
 998 dnl Look for uuid_generate
 999 if test $have_uuid = no ; then
1000         AC_CHECK_HEADERS(uuid/uuid.h)
1001         if test $ac_cv_header_uuid_uuid_h = yes ; then
1002                 save_LIBS="$LIBS"
1003                 AC_SEARCH_LIBS([uuid_generate], [uuid], [have_uuid=yes], :)
1004                 LIBS="$save_LIBS"
1005
1006                 if test have_uuid = yes ; then
1007                         AC_DEFINE(HAVE_UUID_GENERATE,1,
1008                                 [define if you have uuid_generate()])
1009
1010                         test "$ac_cv_search_uuid_generate" = "none required" || \
1011                                 SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_generate"
1012                 fi
1013         fi
1014 fi
1015
1016 dnl For windows, check for the need of RPCRT for UUID function support
1017 if test $have_uuid = no ; then
1018         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
1019         save_LIBS="$LIBS"
1020         LIBS="$LIBS -lrpcrt4"
1021         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1022                 int __stdcall UuidCreate(void *);
1023                 int __stdcall UuidToStringA(void *,void **);
1024                 ]], [[
1025                 UuidCreate(0);
1026                 UuidToStringA(0,0);
1027                 ]])],[need_rpcrt=yes],[need_rpcrt=no])
1028         if test $need_rpcrt = yes; then
1029                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
1030         fi
1031         LIBS="$save_LIBS"
1032         AC_MSG_RESULT($need_rpcrt)
1033 fi
1034
1035 dnl ----------------------------------------------------------------
1036 dnl Check for resolver routines
1037 OL_RESOLVER_LINK
1038
1039 ol_link_dnssrv=no
1040 if test "$ol_cv_lib_resolver" != no ; then
1041         AC_DEFINE(HAVE_RES_QUERY,1,
1042                 [define if you have res_query()])
1043
1044         if test "$ol_enable_dnssrv" != no ; then
1045                 ol_link_dnssrv=yes
1046         fi
1047
1048         if test "$ol_cv_lib_resolver" != yes ; then
1049                 LIBS="$ol_cv_lib_resolver $LIBS"
1050         fi
1051 fi
1052
1053 if test "$ol_enable_dnssrv" = yes || test "$ol_enable_dnssrv" = mod ; then
1054         if test "$ol_link_dnssrv" = no ; then
1055                 AC_MSG_ERROR([DNSSRV requires res_query()])
1056         fi
1057 else
1058         ol_enable_dnssrv=no
1059 fi
1060
1061 AC_CHECK_FUNCS( hstrerror )
1062
1063 dnl ----------------------------------------------------------------
1064 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1065 dnl PF_LOCAL may use getaddrinfo in available
1066 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1067
1068 ol_link_ipv6=no
1069 if test $ac_cv_func_getaddrinfo = no || test $ac_cv_func_inet_ntop = no ; then
1070         if test $ol_enable_ipv6 = yes ; then
1071                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1072         fi
1073 elif test $ol_enable_ipv6 != no ; then
1074         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1075                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1076 #                       include <netinet/in.h>
1077 #                       ifdef INET6_ADDRSTRLEN
1078                                 __has_inet6_addrstrlen__;
1079 #                       endif
1080                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1081
1082
1083         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1084                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1085 #include <sys/types.h>
1086 #include <sys/socket.h>
1087 ]], [[
1088                         struct sockaddr_storage ss;
1089 ]])],[ol_cv_struct_sockaddr_storage=yes],[ol_cv_struct_sockaddr_storage=no])])
1090
1091         if test $ol_cv_inet6_addrstrlen = yes &&
1092            test $ol_cv_struct_sockaddr_storage = yes ; then
1093                 ol_link_ipv6=yes
1094         elif test $ol_enable_ipv6 = yes &&
1095              test $ol_cv_inet6_addrstrlen = no ; then
1096                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1097         elif test $ol_enable_ipv6 = yes &&
1098              test $ol_cv_struct_sockaddr_storage = no ; then
1099                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1100         fi
1101 fi
1102
1103 if test $ol_enable_local != no ; then
1104         AC_CHECK_HEADERS( sys/un.h )
1105
1106         if test $ol_enable_local = auto ; then
1107                 ol_enable_local=$ac_cv_header_sys_un_h
1108         elif test $ac_cv_header_sys_un_h = no ; then
1109                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1110         fi
1111 fi
1112
1113 dnl ----------------------------------------------------------------
1114 dnl TLS/SSL
1115
1116 if test $ol_with_tls = yes ; then
1117         ol_with_tls=auto
1118 fi
1119
1120 ol_link_tls=no
1121 if test $ol_with_tls = openssl || test $ol_with_tls = auto ; then
1122         AC_CHECK_HEADERS(openssl/ssl.h)
1123
1124         if test $ac_cv_header_openssl_ssl_h = yes ; then
1125                 AC_CHECK_LIB(ssl, SSL_library_init,
1126                         [have_openssl=yes
1127                         need_rsaref=no], [have_openssl=no],
1128                         [-lcrypto])
1129
1130                 if test $have_openssl = no ; then
1131                         AC_CHECK_LIB(ssl, ssl3_accept,
1132                                 [have_openssl=yes
1133                                 need_rsaref=yes], [have_openssl=no],
1134                                 [-lcrypto -lRSAglue -lrsaref])
1135                 fi
1136
1137                 if test $have_openssl = yes ; then
1138                         ol_with_tls=openssl
1139                         ol_link_tls=yes
1140
1141                         AC_DEFINE(HAVE_OPENSSL, 1,
1142                                 [define if you have OpenSSL])
1143
1144                         if test $need_rsaref = yes; then
1145                                 AC_DEFINE(HAVE_RSAREF, 1,
1146                                         [define if OpenSSL needs RSAref])
1147
1148                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1149                         else
1150                                 TLS_LIBS="-lssl -lcrypto"
1151                         fi
1152
1153                         OL_SSL_COMPAT
1154                         if test $ol_cv_ssl_crl_compat = yes ; then
1155                                 AC_DEFINE(HAVE_OPENSSL_CRL, 1,
1156                                         [define if you have OpenSSL with CRL checking capability])
1157                         fi
1158                 fi
1159         fi
1160 fi
1161
1162 if test $ol_link_tls = no ; then
1163         if test $ol_with_tls = gnutls || test $ol_with_tls = auto ; then
1164                 AC_CHECK_HEADERS(gnutls/gnutls.h)
1165
1166                 if test $ac_cv_header_gnutls_gnutls_h = yes ; then
1167                         AC_CHECK_LIB(gnutls, gnutls_init,
1168                                 [have_gnutls=yes], [have_gnutls=no])
1169
1170                         if test $have_gnutls = yes ; then
1171                                 ol_with_tls=gnutls
1172                                 ol_link_tls=yes
1173
1174                                 TLS_LIBS="-lgnutls"
1175
1176                                 AC_DEFINE(HAVE_GNUTLS, 1,
1177                                         [define if you have GNUtls])
1178                         fi
1179                 fi
1180         fi
1181 fi
1182
1183 WITH_TLS=no
1184 if test $ol_link_tls = yes ; then
1185         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1186         WITH_TLS=yes
1187 elif test $ol_with_tls = auto ; then
1188         AC_MSG_WARN([Could not locate TLS/SSL package])
1189         AC_MSG_WARN([TLS data protection not supported!])
1190 elif test $ol_with_tls != no ; then
1191         AC_MSG_ERROR([Could not locate TLS/SSL package])
1192 else
1193         AC_MSG_WARN([TLS data protection not supported!])
1194 fi
1195
1196 dnl ----------------------------------------------------------------
1197 dnl LAN Manger password checking requires DES from OpenSSL
1198 if test $ol_enable_lmpasswd != no; then
1199         if test $ol_link_tls != yes ; then
1200                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
1201         fi
1202
1203         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1204 fi
1205
1206 dnl ----------------------------------------------------------------
1207 dnl Threads?
1208 ol_link_threads=no
1209
1210 case $ol_with_threads in auto | yes | nt)
1211
1212         OL_NT_THREADS
1213
1214         if test "$ol_cv_nt_threads" = yes ; then
1215                 ol_link_threads=nt
1216                 ol_with_threads=found
1217                 ol_with_yielding_select=yes
1218
1219                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1220                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1221         fi
1222
1223         if test $ol_with_threads = nt ; then
1224                 AC_MSG_ERROR([could not locate NT Threads])
1225         fi
1226         ;;
1227 esac
1228
1229 case $ol_with_threads in auto | yes | posix)
1230
1231         AC_CHECK_HEADERS(pthread.h)
1232
1233         if test $ac_cv_header_pthread_h = yes ; then
1234                 OL_POSIX_THREAD_VERSION
1235
1236                 if test $ol_cv_pthread_version != 0 ; then
1237                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1238                                 [define to pthreads API spec revision])
1239                 else
1240                         AC_MSG_ERROR([unknown pthread version])
1241                 fi
1242
1243                 # consider threads found
1244                 ol_with_threads=found
1245
1246                 OL_HEADER_LINUX_THREADS
1247                 OL_HEADER_GNU_PTH_PTHREAD_H
1248
1249                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1250                         AC_CHECK_HEADERS(sched.h)
1251                 fi
1252
1253                 dnl Now the hard part, how to link?
1254                 dnl
1255                 dnl currently supported checks:
1256                 dnl
1257                 dnl Check for no flags
1258                 dnl     pthread_create() in $LIBS
1259                 dnl
1260                 dnl Check special pthread (final) flags
1261                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1262                 dnl     pthread_create() with -kthread (FreeBSD)
1263                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1264                 dnl     pthread_create() with -pthreads (?)
1265                 dnl     pthread_create() with -mthreads (AIX)
1266                 dnl     pthread_create() with -thread (?)
1267                 dnl
1268                 dnl Check pthread (final) libraries
1269                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1270                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1271                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1272                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1273                 dnl     pthread_create() in -lpthread (many)
1274                 dnl     pthread_create() in -lc_r (FreeBSD)
1275                 dnl
1276                 dnl Check pthread (draft4) flags (depreciated)
1277                 dnl     pthread_create() with -threads (OSF/1)
1278                 dnl
1279                 dnl Check pthread (draft4) libraries (depreciated)
1280                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1281                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1282                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1283                 dnl     pthread_create() in -lpthreads (many)
1284                 dnl
1285
1286                 dnl pthread_create in $LIBS
1287                 AC_CACHE_CHECK([for pthread_create in default libraries],
1288                         ol_cv_pthread_create,[
1289                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1290                                 [ol_cv_pthread_create=yes],
1291                                 [ol_cv_pthread_create=no],
1292                                 [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1293                                         [ol_cv_pthread_create=yes],
1294                                         [ol_cv_pthread_create=no])])])
1295
1296                 if test $ol_cv_pthread_create != no ; then
1297                         ol_link_threads=posix
1298                         ol_link_pthreads=""
1299                 fi
1300
1301 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1302                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1303                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1304                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1305                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1306                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1307
1308                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1309                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1310                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1311                         [ol_cv_pthread_lpthread_lmach_lexc])
1312 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1313 dnl                     [ol_cv_pthread_lpthread_lexc])
1314
1315                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1316                         [ol_cv_pthread_lib_lpthread_woff])
1317
1318                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1319                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1320
1321                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1322
1323                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1324                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1325                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1326                         [ol_cv_pthread_lpthreads_lmach_lexc])
1327                 OL_PTHREAD_TRY([-lpthreads -lexc],
1328                         [ol_cv_pthread_lpthreads_lexc])
1329
1330                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1331
1332                 if test $ol_link_threads != no ; then
1333                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1334
1335                         dnl save flags
1336                         save_CPPFLAGS="$CPPFLAGS"
1337                         save_LIBS="$LIBS"
1338                         LIBS="$LTHREAD_LIBS $LIBS"
1339
1340                         dnl All POSIX Thread (final) implementations should have
1341                         dnl sched_yield instead of pthread yield.
1342                         dnl check for both, and thr_yield for Solaris
1343                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1344
1345                         if test $ac_cv_func_sched_yield = no &&
1346                            test $ac_cv_func_pthread_yield = no &&
1347                            test $ac_cv_func_thr_yield = no ; then
1348                                 dnl Digital UNIX has sched_yield() in -lrt
1349                                 AC_CHECK_LIB(rt, sched_yield,
1350                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1351                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1352                                                 [Define if you have the sched_yield function.])
1353                                         ac_cv_func_sched_yield=yes],
1354                                         [ac_cv_func_sched_yield=no])
1355                         fi
1356                         if test $ac_cv_func_sched_yield = no &&
1357                            test $ac_cv_func_pthread_yield = no &&
1358                            test "$ac_cv_func_thr_yield" = no ; then
1359                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1360                         fi
1361
1362                         dnl Check functions for compatibility
1363                         AC_CHECK_FUNCS(pthread_kill)
1364
1365                         dnl Check for pthread_rwlock_destroy with <pthread.h>
1366                         dnl as pthread_rwlock_t may not be defined.
1367                         AC_CACHE_CHECK([for pthread_rwlock_destroy with <pthread.h>],
1368                                 [ol_cv_func_pthread_rwlock_destroy], [
1369                                 dnl save the flags
1370                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1371 #include <pthread.h>
1372 pthread_rwlock_t rwlock;
1373 ]], [[pthread_rwlock_destroy(&rwlock);]])],[ol_cv_func_pthread_rwlock_destroy=yes],[ol_cv_func_pthread_rwlock_destroy=no])
1374                         ])
1375                         if test $ol_cv_func_pthread_rwlock_destroy = yes ; then
1376                                 AC_DEFINE(HAVE_PTHREAD_RWLOCK_DESTROY,1,
1377                                         [define if you have pthread_rwlock_destroy function])
1378                         fi
1379
1380                         dnl Check for pthread_detach with <pthread.h> inclusion
1381                         dnl as it's symbol may have been mangled.
1382                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1383                                 [ol_cv_func_pthread_detach], [
1384                                 dnl save the flags
1385                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1386 #include <pthread.h>
1387 #ifndef NULL
1388 #define NULL (void*)0
1389 #endif
1390 ]], [[pthread_detach(NULL);]])],[ol_cv_func_pthread_detach=yes],[ol_cv_func_pthread_detach=no])
1391                         ])
1392
1393                         if test $ol_cv_func_pthread_detach = no ; then
1394                                 AC_MSG_ERROR([could not locate pthread_detach()])
1395                         fi
1396
1397                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1398                                 [define if you have pthread_detach function])
1399
1400                         dnl Check for setconcurreny functions
1401                         AC_CHECK_FUNCS( \
1402                                 pthread_setconcurrency \
1403                                 pthread_getconcurrency \
1404                                 thr_setconcurrency \
1405                                 thr_getconcurrency \
1406                         )
1407
1408                         OL_SYS_LINUX_THREADS
1409                         OL_LINUX_THREADS
1410
1411                         if test $ol_cv_linux_threads = error; then
1412                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1413                         fi
1414
1415                         AC_CACHE_CHECK([if pthread_create() works],
1416                                 ol_cv_pthread_create_works,[
1417                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1418                                 [ol_cv_pthread_create_works=yes],
1419                                 [ol_cv_pthread_create_works=no],
1420                                 [dnl assume yes
1421                                 ol_cv_pthread_create_works=yes])])
1422
1423                         if test $ol_cv_pthread_create_works = no ; then
1424                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1425                         fi
1426
1427                         ol_replace_broken_yield=no
1428 dnl                     case "$target" in
1429 dnl                     *-*-linux*)
1430 dnl                             AC_CHECK_FUNCS(nanosleep)
1431 dnl                             ol_replace_broken_yield=yes
1432 dnl                     ;;
1433 dnl                     esac
1434
1435                         if test $ol_replace_broken_yield = yes ; then
1436                                 AC_DEFINE([REPLACE_BROKEN_YIELD],1,
1437                                         [define if sched_yield yields the entire process])
1438                         fi
1439
1440                         dnl Check if select causes an yield
1441                         if test $ol_with_yielding_select = auto ; then
1442                                 AC_CACHE_CHECK([if select yields when using pthreads],
1443                                         ol_cv_pthread_select_yields,[
1444                                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1445 #include <sys/types.h>
1446 #include <sys/time.h>
1447 #include <unistd.h>
1448 #include <pthread.h>
1449 #ifndef NULL
1450 #define NULL (void*) 0
1451 #endif
1452
1453 static int fildes[2];
1454
1455 static void *task(p)
1456         void *p;
1457 {
1458         int i;
1459         struct timeval tv;
1460
1461         fd_set rfds;
1462
1463         tv.tv_sec=10;
1464         tv.tv_usec=0;
1465
1466         FD_ZERO(&rfds);
1467         FD_SET(fildes[0], &rfds);
1468
1469         /* we're not interested in any fds */
1470         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1471
1472         if(i < 0) {
1473                 perror("select");
1474                 exit(10);
1475         }
1476
1477         exit(0); /* if we exit here, the select blocked the whole process */
1478 }
1479
1480 int main(argc, argv)
1481         int argc;
1482         char **argv;
1483 {
1484         pthread_t t;
1485
1486         /* create a pipe to select */
1487         if(pipe(&fildes[0])) {
1488                 perror("select");
1489                 exit(1);
1490         }
1491
1492 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1493         (void) pthread_setconcurrency(2);
1494 #else
1495 #ifdef HAVE_THR_SETCONCURRENCY
1496         /* Set Solaris LWP concurrency to 2 */
1497         thr_setconcurrency(2);
1498 #endif
1499 #endif
1500
1501 #if HAVE_PTHREADS < 6
1502         pthread_create(&t, pthread_attr_default, task, NULL);
1503 #else
1504         pthread_create(&t, NULL, task, NULL);
1505 #endif
1506
1507         /* make sure task runs first */
1508 #ifdef HAVE_THR_YIELD
1509         thr_yield();
1510 #elif defined( HAVE_SCHED_YIELD )
1511         sched_yield();
1512 #elif defined( HAVE_PTHREAD_YIELD )
1513         pthread_yield();
1514 #endif
1515
1516         exit(2);
1517 }]])],[ol_cv_pthread_select_yields=no],[ol_cv_pthread_select_yields=yes],[ol_cv_pthread_select_yields=cross])])
1518
1519                                 if test $ol_cv_pthread_select_yields = cross ; then
1520                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1521                                 fi
1522
1523                                 if test $ol_cv_pthread_select_yields = yes ; then
1524                                         ol_with_yielding_select=yes
1525                                 fi
1526                         fi
1527
1528                         dnl restore flags
1529                         CPPFLAGS="$save_CPPFLAGS"
1530                         LIBS="$save_LIBS"
1531                 else
1532                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1533                 fi
1534         fi
1535
1536         if test $ol_with_threads = posix ; then
1537                 AC_MSG_ERROR([could not locate POSIX Threads])
1538         fi
1539         ;;
1540 esac
1541
1542 case $ol_with_threads in auto | yes | mach)
1543
1544         dnl check for Mach CThreads
1545         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1546         if test $ac_cv_header_mach_cthreads_h = yes ; then
1547                 ol_with_threads=found
1548
1549                 dnl check for cthreads support in current $LIBS
1550                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1551
1552                 if test $ol_link_threads = no ; then
1553                         dnl try -all_load
1554                         dnl this test needs work
1555                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1556                                 [ol_cv_cthread_all_load], [
1557                                 dnl save the flags
1558                                 save_LIBS="$LIBS"
1559                                 LIBS="-all_load $LIBS"
1560                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <mach/cthreads.h>]], [[
1561                                         cthread_fork((void *)0, (void *)0);
1562                                         ]])],[ol_cv_cthread_all_load=yes],[ol_cv_cthread_all_load=no])
1563                                 dnl restore the LIBS
1564                                 LIBS="$save_LIBS"
1565                         ])
1566
1567                         if test $ol_cv_cthread_all_load = yes ; then
1568                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1569                                 ol_link_threads=mach
1570                                 ol_with_threads=found
1571                         fi
1572                 fi
1573
1574         elif test $ac_cv_header_cthreads_h = yes ; then
1575                 dnl Hurd variant of Mach Cthreads
1576                 dnl uses <cthreads.h> and -lthreads
1577
1578                 ol_with_threads=found
1579
1580                 dnl save the flags
1581                 save_LIBS="$LIBS"
1582                 LIBS="$LIBS -lthreads"
1583                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1584                 LIBS="$save_LIBS"
1585
1586                 if test $ol_link_threads = yes ; then
1587                         LTHREAD_LIBS="-lthreads"
1588                         ol_link_threads=mach
1589                         ol_with_threads=found
1590                 else
1591                         AC_MSG_ERROR([could not link with Mach CThreads])
1592                 fi
1593
1594         elif test $ol_with_threads = mach ; then
1595                 AC_MSG_ERROR([could not locate Mach CThreads])
1596         fi
1597
1598         if test $ol_link_threads = mach ; then
1599                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1600                         [define if you have Mach Cthreads])
1601         elif test $ol_with_threads = found ; then
1602                 AC_MSG_ERROR([could not link with Mach CThreads])
1603         fi
1604         ;;
1605 esac
1606
1607 case $ol_with_threads in auto | yes | pth)
1608
1609         AC_CHECK_HEADERS(pth.h)
1610
1611         if test $ac_cv_header_pth_h = yes ; then
1612                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1613
1614                 if test $have_pth = yes ; then
1615                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1616                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1617                         ol_link_threads=pth
1618                         ol_with_threads=found
1619
1620                         if test $ol_with_yielding_select = auto ; then
1621                                 ol_with_yielding_select=yes
1622                         fi
1623                 fi
1624         fi
1625         ;;
1626 esac
1627
1628 case $ol_with_threads in auto | yes | lwp)
1629
1630         dnl check for SunOS5 LWP
1631         AC_CHECK_HEADERS(thread.h synch.h)
1632         if test $ac_cv_header_thread_h = yes &&
1633            test $ac_cv_header_synch_h = yes ; then
1634                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1635
1636                 if test $have_thr = yes ; then
1637                         AC_DEFINE(HAVE_THR,1,
1638                                 [if you have Solaris LWP (thr) package])
1639                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1640                         ol_link_threads=thr
1641
1642                         if test $ol_with_yielding_select = auto ; then
1643                                 ol_with_yielding_select=yes
1644                         fi
1645
1646                         dnl Check for setconcurreny functions
1647                         AC_CHECK_FUNCS( \
1648                                 thr_setconcurrency \
1649                                 thr_getconcurrency \
1650                         )
1651                 fi
1652         fi
1653
1654         dnl check for SunOS4 LWP
1655         AC_CHECK_HEADERS(lwp/lwp.h)
1656         if test $ac_cv_header_lwp_lwp_h = yes ; then
1657                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1658
1659                 if test $have_lwp = yes ; then
1660                         AC_DEFINE(HAVE_LWP,1,
1661                                 [if you have SunOS LWP package])
1662                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1663                         ol_link_threads=lwp
1664
1665                         if test $ol_with_yielding_select = auto ; then
1666                                 ol_with_yielding_select=no
1667                         fi
1668                 fi
1669         fi
1670         ;;
1671 esac
1672
1673 if test $ol_with_yielding_select = yes ; then
1674         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1675                 [define if select implicitly yields])
1676 fi
1677
1678 if test $ol_with_threads = manual ; then
1679         dnl User thinks he can manually configure threads.
1680         ol_link_threads=yes
1681
1682         AC_MSG_WARN([thread defines and link options must be set manually])
1683
1684         AC_CHECK_HEADERS(pthread.h sched.h)
1685         AC_CHECK_FUNCS(sched_yield pthread_yield)
1686         OL_HEADER_LINUX_THREADS
1687
1688         AC_CHECK_HEADERS(mach/cthreads.h)
1689         AC_CHECK_HEADERS(lwp/lwp.h)
1690         AC_CHECK_HEADERS(thread.h synch.h)
1691 fi
1692
1693 if test $ol_link_threads != no && test $ol_link_threads != nt ; then
1694         dnl needed to get reentrant/threadsafe versions
1695         dnl
1696         AC_DEFINE(REENTRANT,1)
1697         AC_DEFINE(_REENTRANT,1)
1698         AC_DEFINE(THREAD_SAFE,1)
1699         AC_DEFINE(_THREAD_SAFE,1)
1700         AC_DEFINE(THREADSAFE,1)
1701         AC_DEFINE(_THREADSAFE,1)
1702         AC_DEFINE(_SGI_MP_SOURCE,1)
1703
1704         dnl The errno declaration may dependent upon _REENTRANT.
1705         dnl If it does, we must link with thread support.
1706         AC_CACHE_CHECK([for thread specific errno],
1707                 [ol_cv_errno_thread_specific], [
1708                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[errno = 0;]])],[ol_cv_errno_thread_specific=yes],[ol_cv_errno_thread_specific=no])
1709         ])
1710
1711         dnl The h_errno declaration may dependent upon _REENTRANT.
1712         dnl If it does, we must link with thread support.
1713         AC_CACHE_CHECK([for thread specific h_errno],
1714                 [ol_cv_h_errno_thread_specific], [
1715                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[h_errno = 0;]])],[ol_cv_h_errno_thread_specific=yes],[ol_cv_h_errno_thread_specific=no])
1716         ])
1717
1718         if test $ol_cv_errno_thread_specific != yes ||
1719            test $ol_cv_h_errno_thread_specific != yes ; then
1720                 LIBS="$LTHREAD_LIBS $LIBS"
1721                 LTHREAD_LIBS=""
1722         fi
1723
1724 dnl When in thread environment, use
1725 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1726 dnl                     func_r(...);
1727 dnl             #else
1728 dnl             #       if defined( HAVE_THREADS )
1729 dnl                             /* lock */
1730 dnl             #       endif
1731 dnl                             func(...);
1732 dnl             #       if defined( HAVE_THREADS )
1733 dnl                             /* unlock */
1734 dnl             #       endif
1735 dnl             #endif
1736 dnl
1737 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1738 dnl             _POSIX_REENTRANT_FUNCTIONS
1739 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1740 dnl             _POSIX_THREADSAFE_FUNCTIONS
1741 dnl
1742 dnl             and is currently defined in <ldap_pvt_thread.h>
1743 dnl
1744 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1745 dnl
1746 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1747 dnl LDAP_R_COMPILE is defined.  ie:
1748 dnl             #ifdef LDAP_R_COMPILE
1749 dnl             #       include <ldap_pvt_thread.h>
1750 dnl             #endif
1751 dnl
1752 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1753 dnl specifically for compiling the threadsafe version of
1754 dnl     the ldap library (-lldap_r).
1755 dnl
1756 dnl     dnl check for reentrant/threadsafe functions
1757 dnl     dnl
1758 dnl     dnl note: these should only be used when linking
1759 dnl     dnl             with $LTHREAD_LIBS
1760 dnl     dnl
1761 dnl     save_CPPFLAGS="$CPPFLAGS"
1762 dnl     save_LIBS="$LIBS"
1763 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1764 dnl     AC_CHECK_FUNCS( \
1765 dnl             gmtime_r \
1766 dnl             gethostbyaddr_r gethostbyname_r \
1767 dnl             feof_unlocked unlocked_feof \
1768 dnl             putc_unlocked unlocked_putc \
1769 dnl             flockfile ftrylockfile \
1770 dnl     )
1771 dnl     CPPFLAGS="$save_CPPFLAGS"
1772 dnl     LIBS="$save_LIBS"
1773 fi
1774
1775 if test $ol_link_threads = no ; then
1776         if test $ol_with_threads = yes ; then
1777                 AC_MSG_ERROR([no suitable thread support])
1778         fi
1779
1780         if test $ol_with_threads = auto ; then
1781                 AC_MSG_WARN([no suitable thread support, disabling threads])
1782                 ol_with_threads=no
1783         fi
1784
1785         AC_DEFINE(NO_THREADS,1,
1786                 [define if you have (or want) no threads])
1787         LTHREAD_LIBS=""
1788         BUILD_THREAD=no
1789 else
1790         BUILD_THREAD=yes
1791 fi
1792
1793 if test $ol_link_threads != no ; then
1794         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1,
1795                 [define to 1 if library is thread safe])
1796 fi
1797
1798 dnl ----------------------------------------------------------------
1799 dnl Tests for reentrant functions necessary to build -lldap_r
1800 AC_CHECK_FUNCS(         \
1801         ctime_r                 \
1802         gethostbyname_r gethostbyaddr_r \
1803 )
1804
1805 if test "$ac_cv_func_ctime_r" = no ; then
1806         ol_cv_func_ctime_r_nargs=0
1807 else
1808         OL_FUNC_CTIME_R_NARGS
1809 dnl     OL_FUNC_CTIME_R_TYPE
1810 fi
1811
1812 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1813         OL_FUNC_GETHOSTBYNAME_R_NARGS
1814 else
1815         ol_cv_func_gethostbyname_r_nargs=0
1816 fi
1817
1818 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1819         OL_FUNC_GETHOSTBYADDR_R_NARGS
1820 else
1821         ol_cv_func_gethostbyaddr_r_nargs=0
1822 fi
1823
1824 dnl ----------------------------------------------------------------
1825 ol_link_bdb=no
1826
1827 if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
1828         OL_BERKELEY_DB
1829
1830         if test $ol_cv_berkeley_db = no ; then
1831                 AC_MSG_ERROR(BDB/HDB: BerkeleyDB not available)
1832         fi
1833
1834         AC_DEFINE(HAVE_BERKELEY_DB,1,
1835                 [define this if Berkeley DB is available])
1836
1837         dnl $ol_cv_lib_db should be yes or -ldb
1838         dnl (it could be no, but that would be an error
1839         if test $ol_cv_lib_db != yes ; then
1840                 BDB_LIBS="$BDB_LIBS $ol_cv_lib_db"
1841         fi
1842
1843         OL_BDB_COMPAT
1844
1845         if test $ol_cv_bdb_compat != yes ; then
1846                 AC_MSG_ERROR([BDB/HDB: BerkeleyDB version incompatible])
1847         fi
1848
1849         SLAPD_LIBS="$SLAPD_LIBS \$(BDB_LIBS)"
1850
1851         ol_link_bdb=yes
1852 fi
1853
1854 dnl ----------------------------------------------------------------
1855
1856 if test $ol_enable_dynamic = yes && test $enable_shared = yes ; then
1857         BUILD_LIBS_DYNAMIC=shared
1858         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
1859         LTSTATIC=""
1860 else
1861         BUILD_LIBS_DYNAMIC=static
1862         LTSTATIC="-static"
1863 fi
1864 AC_SUBST(LTSTATIC)dnl
1865
1866 dnl ----------------------------------------------------------------
1867 if test $ol_enable_wrappers != no ; then
1868         AC_CHECK_HEADERS(tcpd.h,[
1869                 AC_MSG_CHECKING([for TCP wrappers library])
1870                 save_LIBS="$LIBS"
1871                 LIBS="$LIBS -lwrap"
1872                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1873 #include <tcpd.h>
1874 int allow_severity = 0;
1875 int deny_severity  = 0;
1876
1877 struct request_info *req;
1878                 ]], [[
1879 hosts_access(req)
1880                 ]])],[AC_MSG_RESULT([-lwrap])
1881                 have_wrappers=yes
1882                 LIBS="$save_LIBS"],[
1883                 dnl try with -lnsl
1884                 LIBS="$LIBS -lnsl"
1885                 AC_TRY_LINK([
1886 #include <tcpd.h>
1887 int allow_severity = 0;
1888 int deny_severity  = 0;
1889
1890 struct request_info *req;
1891                 ],[
1892 hosts_access(req)
1893                 ],[AC_MSG_RESULT([-lwrap -lnsl])
1894                 have_wrappers=yes
1895                 LIBS="$save_LIBS -lnsl"],[
1896                 AC_MSG_RESULT(no)
1897                 have_wrappers=no
1898                 LIBS=$save_LIBS])])],[have_wrappers=no])
1899
1900         if test $have_wrappers = yes ; then
1901                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1902                 WRAP_LIBS="-lwrap"
1903         elif test $ol_enable_wrappers = yes ; then
1904                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options or disable])
1905         else
1906                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
1907                 WRAP_LIBS=""
1908         fi
1909 fi
1910
1911 dnl ----------------------------------------------------------------
1912 if test $ol_enable_syslog != no ; then
1913         AC_CHECK_FUNC(openlog)
1914         if test $ac_cv_func_openlog = no && test $ol_enable_syslog = yes; then
1915                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1916         fi
1917         ol_enable_syslog=$ac_cv_func_openlog
1918 fi
1919
1920 dnl ----------------------------------------------------------------
1921 dnl SQL
1922 ol_link_sql=no
1923 if test $ol_enable_sql != no ; then
1924         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
1925                 AC_MSG_ERROR([could not locate SQL headers])
1926         ])
1927
1928         sql_LIBS="$LIBS"
1929         LIBS="$LTHREAD_LIBS"
1930
1931         if test $ol_with_odbc = auto ; then
1932                 ol_with_odbc="iodbc unixodbc odbc32"
1933         fi
1934
1935         for odbc in $ol_with_odbc ; do
1936                 if test $ol_link_sql = no ; then
1937                         case $odbc in
1938                         iodbc)
1939                                 AC_CHECK_LIB(iodbc, SQLDriverConnect, [have_iodbc=yes], [have_iodbc=no])
1940                                 if test $have_iodbc = yes ; then
1941                                         ol_link_sql="-liodbc"
1942                                 fi
1943                                 ;;
1944
1945                         unixodbc)
1946                                 AC_CHECK_LIB(odbc, SQLDriverConnect, [have_odbc=yes], [have_odbc=no])
1947                                 if test $have_odbc = yes ; then
1948                                         ol_link_sql="-lodbc"
1949                                 fi
1950                                 ;;
1951
1952                         odbc32)
1953                                 AC_CHECK_LIB(odbc32, SQLDriverConnect, [have_odbc32=yes], [have_odbc32=no])
1954                                 if test $have_odbc32 = yes ; then
1955                                         ol_link_sql="-lodbc32"
1956                                 fi
1957                                 ;;
1958
1959                         *)
1960                                 AC_MSG_ERROR([unknown ODBC library])
1961                                 ;;
1962                         esac
1963                 fi
1964         done
1965
1966         LIBS="$sql_LIBS"
1967
1968         if test $ol_link_sql != no ; then
1969                 SLAPD_SQL_LIBS="$ol_link_sql"
1970
1971         elif test $ol_enable_sql != auto ; then
1972                 AC_MSG_ERROR([could not locate suitable ODBC library])
1973         fi
1974 fi
1975
1976 dnl ----------------------------------------------------------------
1977 dnl International Components for Unicode
1978 OL_ICU
1979 if test "$ol_icu" = no ; then
1980         AC_MSG_WARN([ICU not available])
1981 else
1982         ICU_LIBS="$ol_icu"
1983 fi
1984 dnl ----------------------------------------------------------------
1985 dnl
1986 dnl Check for Cyrus SASL
1987 dnl
1988 WITH_SASL=no
1989 ol_link_sasl=no
1990 ol_link_spasswd=no
1991 if test $ol_with_cyrus_sasl != no ; then
1992         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
1993
1994         if test $ac_cv_header_sasl_sasl_h = yes ||
1995            test $ac_cv_header_sasl_h = yes; then
1996                 AC_CHECK_LIB(sasl2, sasl_client_init,
1997                         [ol_link_sasl="-lsasl2"],
1998                         [AC_CHECK_LIB(sasl, sasl_client_init,
1999                                 [ol_link_sasl="-lsasl"])])
2000         fi
2001
2002         if test $ol_link_sasl = no ; then
2003                 if test $ol_with_cyrus_sasl != auto ; then
2004                         AC_MSG_ERROR([Could not locate Cyrus SASL])
2005                 else
2006                         AC_MSG_WARN([Could not locate Cyrus SASL])
2007                         AC_MSG_WARN([SASL authentication not supported!])
2008                         if test $ol_link_tls = no ; then
2009                                 AC_MSG_WARN([Strong authentication not supported!])
2010                         fi
2011                 fi
2012         else
2013                 OL_SASL_COMPAT
2014                 if test $ol_cv_sasl_compat = no ; then
2015                         ol_link_sasl=no
2016                         AC_MSG_ERROR([Cyrus SASL library located but is incompatible])
2017                 fi
2018
2019                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
2020                 SASL_LIBS="$ol_link_sasl"
2021                 if test $ol_enable_spasswd != no ; then
2022                         ol_link_spasswd=yes
2023                 fi
2024
2025                 ac_save_LIBS="$LIBS"
2026                 LIBS="$LIBS $ol_link_sasl"
2027                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
2028                         [define if your SASL library has sasl_version()])])
2029                 LIBS="$ac_save_LIBS"
2030
2031                 WITH_SASL=yes
2032         fi
2033
2034 else
2035         AC_MSG_WARN([SASL authentication not supported!])
2036         if test $ol_link_tls = no ; then
2037                 AC_MSG_WARN([Strong authentication not supported!])
2038         fi
2039 fi
2040
2041 dnl ----------------------------------------------------------------
2042 dnl Check for entropy sources
2043 if test $cross_compiling != yes && test "$ac_cv_mingw32" != yes ; then
2044         dev=no
2045         if test -r /dev/urandom ; then
2046                 dev="/dev/urandom";
2047         elif test -r /idev/urandom ; then
2048                 dev="/idev/urandom";
2049         elif test -r /dev/srandom ; then
2050                 dev="/dev/srandom";
2051         elif test -r /dev/random ; then
2052                 dev="/dev/random";
2053         elif test -r /idev/random ; then
2054                 dev="/idev/random";
2055         fi
2056
2057         if test $dev != no ; then
2058                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2059         fi
2060 fi
2061
2062 dnl ----------------------------------------------------------------
2063 dnl
2064 dnl Check for fetch URL support
2065 dnl             should be extended to support other fetch URL APIs
2066 dnl
2067 ol_link_fetch=no
2068 if test $ol_with_fetch != no ; then
2069         OL_LIB_FETCH
2070
2071         if test $ol_cv_lib_fetch != no ; then
2072                 LUTIL_LIBS="$LUTIL_LIBS $ol_link_fetch"
2073                 ol_link_fetch=freebsd
2074
2075         elif test $ol_with_fetch != auto ; then
2076                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2077         fi
2078 fi
2079
2080 dnl ----------------------------------------------------------------
2081 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2082 if test $ol_enable_crypt != no ; then
2083         save_LIBS="$LIBS"
2084         LIBS="$TLS_LIBS $LIBS"
2085
2086         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2087                 LIBS="$save_LIBS"
2088                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2089                         have_crypt=yes], [have_crypt=no])])
2090
2091         LIBS="$save_LIBS"
2092
2093         if test $have_crypt = yes ; then
2094                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2095         else
2096                 AC_MSG_WARN([could not find crypt])
2097                 if test $ol_enable_crypt = yes ; then
2098                         AC_MSG_ERROR([could not find crypt, select appropriate options or disable])
2099                 fi
2100
2101                 AC_MSG_WARN([disabling crypt support])
2102                 ol_enable_crypt=no
2103         fi
2104 fi
2105
2106 dnl ----------------------------------------------------------------
2107 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2108 if test $ol_enable_proctitle != no ; then
2109         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2110                 AC_CHECK_LIB(util, setproctitle,
2111                         [have_setproctitle=yes
2112                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2113                         [have_setproctitle=no
2114                         AC_LIBOBJ(setproctitle)
2115                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2116
2117         if test $have_setproctitle = yes ; then
2118                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2119                         [define if setproctitle(3) is available])
2120         fi
2121 fi
2122
2123 dnl ----------------------------------------------------------------
2124 if test $ol_enable_slp != no ; then
2125         AC_CHECK_HEADERS( slp.h )
2126
2127         if test $ac_cv_header_slp_h = yes ; then
2128                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2129                 if test $have_slp = yes ; then
2130                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2131                         SLAPD_SLP_LIBS=-lslp
2132                 fi
2133
2134         elif test $ol_enable_slp = yes ; then
2135                 AC_MSG_ERROR([SLP not found])
2136         fi
2137 fi
2138
2139 dnl ----------------------------------------------------------------
2140 dnl Checks for typedefs, structures, and compiler characteristics.
2141
2142 AC_CHECK_TYPE(mode_t, int)
2143 AC_CHECK_TYPE(off_t, long)
2144 AC_CHECK_TYPE(pid_t, int)
2145 AC_CHECK_TYPE(ssize_t, [signed int])
2146 AC_CHECK_TYPE(caddr_t,  [char *])
2147 AC_CHECK_TYPE(size_t, unsigned)
2148
2149 AC_CHECK_TYPES([long long])
2150 AC_CHECK_TYPES([ptrdiff_t])
2151
2152
2153 AC_CHECK_TYPE([socklen_t],,, [$ac_includes_default
2154 #ifdef HAVE_SYS_SOCKET_H
2155 #include <sys/socket.h>
2156 #endif])
2157
2158 dnl socklen_t-like type in accept(), default socklen_t or int:
2159 dnl - The OS might define socklen_t without using it.  POSIX moved from
2160 dnl   int to size_t to socklen_t, hoping to stay at a 32-bit type, and
2161 dnl   HP-UX now has selectors for what to use.
2162 dnl - On Solaris 2.8 the prototype has void *len, but the default is OK.
2163 AC_MSG_CHECKING([the type of arg 3 to accept()])
2164 AC_CACHE_VAL(ol_cv_type_ber_socklen_t, [
2165         set socklen_t int unsigned "unsigned long" long size_t
2166         test "$ac_cv_type_socklen_t" = yes || shift
2167         ol_cv_type_ber_socklen_t=$1 guessing="guessing "
2168         for lentype in "$@" ; do for addrtype in "struct sockaddr" void ; do
2169                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([$ac_includes_default
2170 #ifdef HAVE_SYS_SOCKET_H
2171 #include <sys/socket.h>
2172 #endif
2173 extern int accept(int s, $addrtype *ap, $lentype *lp);
2174 ], [
2175 accept(0, (struct sockaddr *) 0, ($lentype *) 0);
2176 ])], [ol_cv_type_ber_socklen_t=$lentype guessing= ; break 2])
2177         done ; done])
2178 AC_MSG_RESULT([$guessing$ol_cv_type_ber_socklen_t *])
2179 AC_DEFINE_UNQUOTED(ber_socklen_t, $ol_cv_type_ber_socklen_t,
2180         [Define to the type of arg 3 for `accept'.])
2181
2182 dnl Modules should use ber_socklen_t, not socklen_t.  Define socklen_t
2183 dnl for the time being anyway, for backwards compatibility.
2184 if test "$ac_cv_type_socklen_t" != yes; then
2185         AC_DEFINE_UNQUOTED([socklen_t], [$ol_cv_type_ber_socklen_t],
2186                 [Define like ber_socklen_t if <sys/socket.h> does not define.])
2187 fi
2188
2189
2190 AC_TYPE_SIGNAL
2191
2192 AC_CHECK_TYPE([sig_atomic_t],,
2193         [AC_DEFINE_UNQUOTED([sig_atomic_t], [int],
2194                 [Define to `int' if <signal.h> does not define.])],
2195         [$ac_includes_default
2196 #include <signal.h>
2197         ])
2198
2199 AC_TYPE_UID_T
2200
2201 AC_HEADER_TIME
2202 AC_STRUCT_TM
2203 AC_CHECK_MEMBERS([struct stat.st_blksize])
2204 AC_CHECK_MEMBERS([struct passwd.pw_gecos],,,[$ac_includes_default
2205 #include <pwd.h>])
2206 AC_CHECK_MEMBERS([struct passwd.pw_passwd],,,[$ac_includes_default
2207 #include <pwd.h>])
2208
2209 OL_C_UPPER_LOWER
2210 AC_C_CONST
2211 OL_C_VOLATILE
2212
2213 if test $cross_compiling = yes ; then
2214         AC_MSG_WARN([Crossing compiling... all bets are off!])
2215         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2216 else
2217         AC_C_BIGENDIAN
2218 fi
2219
2220 AC_CHECK_SIZEOF(short)
2221 AC_CHECK_SIZEOF(int)
2222 AC_CHECK_SIZEOF(long)
2223 AC_CHECK_SIZEOF(long long)
2224 AC_CHECK_SIZEOF(wchar_t)
2225
2226 if test "$ac_cv_sizeof_int" -lt 4 ; then
2227         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2228
2229         AC_DEFINE(LBER_INT_T,long,[define to 32-bit or greater integer type])
2230 else
2231         AC_DEFINE(LBER_INT_T,int,[define to 32-bit or greater integer type])
2232 fi
2233
2234 AC_DEFINE(LBER_LEN_T,long,[define to large integer type])
2235 AC_DEFINE(LBER_SOCKET_T,int,[define to socket descriptor type])
2236 AC_DEFINE(LBER_TAG_T,long,[define to large integer type])
2237
2238 dnl ----------------------------------------------------------------
2239 dnl Check for multiple precision support
2240 if test $ol_with_mp = longlong || test $ol_with_mp = auto ; then
2241         if test $ac_cv_sizeof_long_long -gt 4 ; then
2242                 ol_with_mp=longlong
2243                 AC_DEFINE(USE_MP_LONG_LONG,1,[define to use 'long long' for MP])
2244         elif test $ol_with_mp = longlong ; then
2245                 AC_MSG_ERROR([long long unusable for multiple precision])
2246         fi
2247 fi
2248 if test $ol_with_mp = long || test $ol_with_mp = auto ; then
2249         if test $ac_cv_sizeof_long -gt 4 ; then
2250                 ol_with_mp=long
2251                 AC_DEFINE(USE_MP_LONG,1,[define to use 'long' for MP])
2252         elif test $ol_with_mp = long ; then
2253                 AC_MSG_ERROR([long unusable for multiple precision])
2254         fi
2255 fi
2256 if test $ol_with_mp = bignum || test $ol_with_mp = auto ; then
2257         AC_CHECK_HEADERS(openssl/bn.h)
2258         AC_CHECK_HEADERS(openssl/crypto.h)
2259         if test "$ac_cv_header_openssl_bn_h" = "yes" &&
2260                 test "$ac_cv_header_openssl_crypto_h" = "yes" &&
2261                 test "$ol_with_tls" = "found" ; then
2262                 ol_with_mp=bignum
2263                 AC_DEFINE(USE_MP_BIGNUM,1,[define to use OpenSSL BIGNUM for MP])
2264         elif test $ol_with_mp = bignum ; then
2265                 AC_MSG_ERROR([bignum not available])
2266         fi
2267 fi
2268 if test $ol_with_mp = gmp || test $ol_with_mp = auto ; then
2269         AC_CHECK_HEADERS(gmp.h)
2270         AC_CHECK_LIB(gmp, __gmpz_add_ui)
2271         if test $ac_cv_header_gmp_h = yes && test $ac_cv_lib_gmp___gmpz_add_ui = yes ; then
2272                 AC_DEFINE(USE_MP_GMP,1,[define to use GMP for MP])
2273                 ol_with_mp=gmp
2274         elif test $ol_with_mp = gmp ; then
2275                 AC_MSG_ERROR([gmp not available])
2276         fi
2277 fi
2278 if test $ol_with_mp = auto ; then
2279         ol_with_mp=no
2280 fi
2281
2282 dnl ----------------------------------------------------------------
2283 dnl Checks for library functions.
2284 AC_FUNC_MEMCMP
2285
2286 if test $ac_cv_func_memcmp_working = no ; then
2287         AC_DEFINE(NEED_MEMCMP_REPLACEMENT,1,
2288                 [define if memcmp is not 8-bit clean or is otherwise broken])
2289 fi
2290
2291 AC_FUNC_STRFTIME
2292
2293 OL_FUNC_INET_ATON
2294
2295 dnl Check for NT specific routines
2296 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2297
2298 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2299         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2300 ])
2301
2302 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2303         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2304 ])
2305
2306 AC_FUNC_VPRINTF
2307
2308 if test $ac_cv_func_vprintf = yes ; then
2309         dnl check for vsnprintf
2310         AC_CHECK_FUNCS(snprintf vsnprintf)
2311 fi
2312
2313 AC_CHECK_FUNCS(                 \
2314         bcopy                   \
2315         closesocket             \
2316         chroot                  \
2317         endgrent                \
2318         endpwent                \
2319         fcntl                   \
2320         flock                   \
2321         fstat                   \
2322         getdtablesize           \
2323         getgrgid                \
2324         gethostname             \
2325         getpass                 \
2326         getpassphrase           \
2327         getpwuid                \
2328         getpwnam                \
2329         getspnam                \
2330         gettimeofday            \
2331         initgroups              \
2332         inet_ntoa_b             \
2333         ioctl                   \
2334         lockf                   \
2335         memcpy                  \
2336         memmove                 \
2337         memrchr                 \
2338         mkstemp                 \
2339         mktemp                  \
2340         pipe                    \
2341         read                    \
2342         recv                    \
2343         recvfrom                \
2344         setpwfile               \
2345         setgid                  \
2346         setegid                 \
2347         setsid                  \
2348         setuid                  \
2349         seteuid                 \
2350         signal                  \
2351         strdup                  \
2352         strpbrk                 \
2353         strrchr                 \
2354         strsep                  \
2355         strstr                  \
2356         strtol                  \
2357         strtoul                 \
2358         strtoq                  \
2359         strtouq                 \
2360         strtoll                 \
2361         strspn                  \
2362         sysconf                 \
2363         waitpid                 \
2364         wait4                   \
2365         write                   \
2366         send                    \
2367         sendmsg                 \
2368         sendto                  \
2369 )
2370
2371 dnl We actually may need to replace more than this.
2372 AC_REPLACE_FUNCS(getopt getpeereid)
2373
2374 if test "$ac_cv_func_getopt" != yes; then
2375         LIBSRCS="$LIBSRCS getopt.c"
2376 fi
2377
2378 if test "$ac_cv_func_getpeereid" != yes; then
2379         AC_CHECK_FUNCS( getpeerucred )
2380         if test "$ac_cv_func_getpeerucred" != yes ; then
2381                 AC_CHECK_MEMBERS([struct msghdr.msg_accrightslen],,,
2382                         [$ac_includes_default
2383 #ifdef HAVE_SYS_SOCKET_H
2384 #include <sys/socket.h>
2385 #endif])
2386                 if test "$ac_cv_member_struct_msghdr_msg_accrightslen" != yes; then
2387                         AC_CHECK_MEMBERS([struct msghdr.msg_control],,,
2388                                 [$ac_includes_default
2389 #ifdef HAVE_SYS_SOCKET_H
2390 #include <sys/socket.h>
2391 #endif])
2392                 fi
2393                 AC_CHECK_MEMBERS([struct stat.st_fstype, struct stat.st_vfstype])
2394                 if test "$ac_cv_member_struct_stat_st_fstype" = yes; then
2395                         AC_COMPILE_IFELSE([struct stat st; char *ptr=st.st_fstype;],
2396                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_CHAR],1,[define to 1 if st_fstype is char *]),
2397                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_INT],1,[define to 1 if st_fstype is int]))
2398                 fi
2399         fi
2400         LIBSRCS="$LIBSRCS getpeereid.c"
2401 fi
2402
2403 if test "$ac_cv_func_snprintf" != yes ||
2404    test "$ac_cv_func_vsnprintf" != yes; then
2405         if test "$ac_cv_func_snprintf" != yes; then
2406                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2407         fi
2408         if test "$ac_cv_func_vsnprintf" != yes; then
2409                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2410         fi
2411 fi
2412
2413 dnl ----------------------------------------------------------------
2414 dnl Sort out defines
2415
2416 if test "$ol_enable_slapi" != no ; then
2417         dnl This check is done also if --enable-modules is used;
2418         dnl it is duplicated here, 'cause it'd be cached anyway
2419         AC_CHECK_HEADERS(ltdl.h)
2420
2421         if test $ac_cv_header_ltdl_h != yes ; then
2422                 AC_MSG_ERROR([could not locate <ltdl.h>])
2423         fi
2424         AC_CHECK_LIB(ltdl, lt_dlinit, [
2425                 SLAPI_LIBS=-lltdl
2426                 LIBSLAPI=libslapi.a
2427                 LIBSLAPITOOLS=../libslapi.a
2428                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
2429         ],[AC_MSG_ERROR([could not locate libtool -lltdl])])
2430
2431         AC_DEFINE(LDAP_SLAPI,1, [define this to add SLAPI code])
2432 fi
2433
2434 if test "$ol_enable_debug" != no ; then
2435         if test "$ol_enable_debug" = traditional; then
2436                 AC_DEFINE(OLD_DEBUG,1,
2437                         [define to use the original debug style])
2438         fi
2439         AC_DEFINE(LDAP_DEBUG,1,
2440                 [define this to add debugging code])
2441 fi
2442 if test "$ol_enable_syslog" = yes ; then
2443         AC_DEFINE(LDAP_SYSLOG,1,
2444                 [define this to add syslog code])
2445 fi
2446 if test "$ol_enable_proctitle" != no ; then
2447         AC_DEFINE(LDAP_PROCTITLE,1,
2448                 [define this for LDAP process title support])
2449 fi
2450 if test "$ol_enable_referrals" != no ; then
2451         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION,
2452                 [define to LDAP VENDOR VERSION])
2453 fi
2454 if test "$ol_enable_local" != no; then
2455         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2456 fi
2457 if test "$ol_link_ipv6" != no; then
2458         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2459 fi
2460 if test "$ol_enable_cleartext" != no ; then
2461         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2462 fi
2463 if test "$ol_enable_crypt" != no ; then
2464         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2465 fi
2466 if test "$ol_link_spasswd" != no ; then
2467         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2468 fi
2469 if test "$ol_enable_rlookups" != no ; then
2470         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2471 fi
2472 if test "$ol_enable_aci" != no ; then
2473         if test $ol_enable_dynacl = no ; then
2474                 ol_enable_dynacl=yes
2475                 AC_MSG_WARN([ACIs need dynacl])
2476         fi
2477         if test "$ol_enable_aci" = mod ; then
2478                 MFLAG=SLAPD_MOD_DYNAMIC
2479                 dnl remove this after moving servers/slapd/aci.c in contrib/slapd-modules/acl
2480                 AC_MSG_ERROR([ACI build as dynamic module not supported (yet)])
2481         else
2482                 MFLAG=SLAPD_MOD_STATIC
2483         fi
2484         WITH_ACI_ENABLED=$ol_enable_aci
2485         AC_DEFINE_UNQUOTED(SLAPD_ACI_ENABLED,$MFLAG,[define to support per-object ACIs])
2486 else
2487         WITH_ACI_ENABLED=no
2488 fi
2489 if test "$ol_enable_dynacl" != no ; then
2490         AC_DEFINE(SLAP_DYNACL,1,[define to support run-time loadable ACL])
2491 fi
2492
2493 if test "$ol_link_modules" != no ; then
2494         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2495         BUILD_SLAPD=yes
2496         SLAPD_MODULES_LDFLAGS="-dlopen self"
2497 fi
2498
2499 AC_DEFINE(SLAPD_MOD_STATIC,1,[statically linked module])
2500 AC_DEFINE(SLAPD_MOD_DYNAMIC,2,[dynamically linked module])
2501
2502 dnl back-monitor goes first (well, after back-config)
2503 if test "$ol_enable_monitor" != no ; then
2504         BUILD_SLAPD=yes
2505         BUILD_MONITOR=$ol_enable_monitor
2506         if test "$ol_enable_monitor" = mod ; then
2507                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2508                 MFLAG=SLAPD_MOD_DYNAMIC
2509         else
2510                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2511                 MFLAG=SLAPD_MOD_STATIC
2512         fi
2513         AC_DEFINE_UNQUOTED(SLAPD_MONITOR,$MFLAG,[define to support cn=Monitor backend])
2514 fi
2515
2516 if test "$ol_enable_bdb" != no ; then
2517         BUILD_SLAPD=yes
2518         BUILD_BDB=$ol_enable_bdb
2519         if test "$ol_enable_bdb" = mod ; then
2520                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2521                 MFLAG=SLAPD_MOD_DYNAMIC
2522         else
2523                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2524                 MFLAG=SLAPD_MOD_STATIC
2525         fi
2526         AC_DEFINE_UNQUOTED(SLAPD_BDB,$MFLAG,[define to support BDB backend])
2527 fi
2528
2529 if test "$ol_enable_dnssrv" != no ; then
2530         BUILD_SLAPD=yes
2531         BUILD_DNSSRV=$ol_enable_dnssrv
2532         if test "$ol_enable_dnssrv" = mod ; then
2533                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2534                 MFLAG=SLAPD_MOD_DYNAMIC
2535         else
2536                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2537                 MFLAG=SLAPD_MOD_STATIC
2538         fi
2539         AC_DEFINE_UNQUOTED(SLAPD_DNSSRV,$MFLAG,[define to support DNS SRV backend])
2540 fi
2541
2542 if test "$ol_enable_hdb" != no ; then
2543         BUILD_SLAPD=yes
2544         BUILD_HDB=$ol_enable_hdb
2545         if test "$ol_enable_hdb" = mod ; then
2546                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-hdb"
2547                 MFLAG=SLAPD_MOD_DYNAMIC
2548         else
2549                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-hdb"
2550                 MFLAG=SLAPD_MOD_STATIC
2551         fi
2552         AC_DEFINE_UNQUOTED(SLAPD_HDB,$MFLAG,[define to support HDB backend])
2553 fi
2554
2555 if test "$ol_enable_ldap" != no ; then
2556         BUILD_SLAPD=yes
2557         BUILD_LDAP=$ol_enable_ldap
2558         if test "$ol_enable_ldap" = mod ; then
2559                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2560                 MFLAG=SLAPD_MOD_DYNAMIC
2561         else
2562                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2563                 MFLAG=SLAPD_MOD_STATIC
2564         fi
2565         AC_DEFINE_UNQUOTED(SLAPD_LDAP,$MFLAG,[define to support LDAP backend])
2566 fi
2567
2568 if test "$ol_enable_meta" != no ; then
2569         BUILD_SLAPD=yes
2570         BUILD_META=$ol_enable_meta
2571         BUILD_REWRITE=yes
2572         if test "$ol_enable_meta" = mod ; then
2573                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2574                 MFLAG=SLAPD_MOD_DYNAMIC
2575         else
2576                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2577                 MFLAG=SLAPD_MOD_STATIC
2578         fi
2579         AC_DEFINE_UNQUOTED(SLAPD_META,$MFLAG,[define to support LDAP Metadirectory backend])
2580 fi
2581
2582 if test "$ol_enable_null" != no ; then
2583         BUILD_SLAPD=yes
2584         BUILD_NULL=$ol_enable_null
2585         if test "$ol_enable_null" = mod ; then
2586                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2587                 MFLAG=SLAPD_MOD_DYNAMIC
2588         else
2589                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2590                 MFLAG=SLAPD_MOD_STATIC
2591         fi
2592         AC_DEFINE_UNQUOTED(SLAPD_NULL,$MFLAG,[define to support NULL backend])
2593 fi
2594
2595 if test "$ol_enable_passwd" != no ; then
2596         BUILD_SLAPD=yes
2597         BUILD_PASSWD=$ol_enable_passwd
2598         if test "$ol_enable_passwd" = mod ; then
2599                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2600                 MFLAG=SLAPD_MOD_DYNAMIC
2601         else
2602                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2603                 MFLAG=SLAPD_MOD_STATIC
2604         fi
2605         AC_DEFINE_UNQUOTED(SLAPD_PASSWD,$MFLAG,[define to support PASSWD backend])
2606 fi
2607
2608 if test "$ol_link_perl" != no ; then
2609         BUILD_SLAPD=yes
2610         BUILD_PERL=$ol_enable_perl
2611         if test "$ol_enable_perl" = mod ; then
2612                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2613                 MFLAG=SLAPD_MOD_DYNAMIC
2614         else
2615                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2616                 MFLAG=SLAPD_MOD_STATIC
2617         fi
2618         AC_DEFINE_UNQUOTED(SLAPD_PERL,$MFLAG,[define to support PERL backend])
2619 fi
2620
2621 if test "$ol_enable_relay" != no ; then
2622         BUILD_SLAPD=yes
2623         BUILD_RELAY=$ol_enable_relay
2624         if test "$ol_enable_relay" = mod ; then
2625                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-relay"
2626                 MFLAG=SLAPD_MOD_DYNAMIC
2627         else
2628                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-relay"
2629                 MFLAG=SLAPD_MOD_STATIC
2630         fi
2631         AC_DEFINE_UNQUOTED(SLAPD_RELAY,$MFLAG,[define to support relay backend])
2632 fi
2633
2634 if test "$ol_enable_shell" != no ; then
2635         if test "$ol_link_threads" != no ; then
2636                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2637         fi
2638         BUILD_SLAPD=yes
2639         BUILD_SHELL=$ol_enable_shell
2640         if test "$ol_enable_shell" = mod ; then
2641                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2642                 MFLAG=SLAPD_MOD_DYNAMIC
2643         else
2644                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2645                 MFLAG=SLAPD_MOD_STATIC
2646         fi
2647         AC_DEFINE_UNQUOTED(SLAPD_SHELL,$MFLAG,[define to support SHELL backend])
2648 fi
2649
2650 if test "$ol_enable_sock" != no ; then
2651         BUILD_SLAPD=yes
2652         BUILD_SOCK=$ol_enable_sock
2653         if test "$ol_enable_sock" = mod ; then
2654                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sock"
2655                 MFLAG=SLAPD_MOD_DYNAMIC
2656         else
2657                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sock"
2658                 MFLAG=SLAPD_MOD_STATIC
2659         fi
2660         AC_DEFINE_UNQUOTED(SLAPD_SOCK,$MFLAG,[define to support SOCK backend])
2661 fi
2662
2663 if test "$ol_link_sql" != no ; then
2664         BUILD_SLAPD=yes
2665         BUILD_SQL=$ol_enable_sql
2666         if test "$ol_enable_sql" = mod; then
2667                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2668                 MFLAG=SLAPD_MOD_DYNAMIC
2669         else
2670                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2671                 MFLAG=SLAPD_MOD_STATIC
2672         fi
2673         AC_DEFINE_UNQUOTED(SLAPD_SQL,$MFLAG,[define to support SQL backend])
2674 fi
2675
2676 if test "$ol_enable_accesslog" != no ; then
2677         BUILD_ACCESSLOG=$ol_enable_accesslog
2678         if test "$ol_enable_accesslog" = mod ; then
2679                 MFLAG=SLAPD_MOD_DYNAMIC
2680                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS accesslog.la"
2681         else
2682                 MFLAG=SLAPD_MOD_STATIC
2683                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS accesslog.o"
2684         fi
2685         AC_DEFINE_UNQUOTED(SLAPD_OVER_ACCESSLOG,$MFLAG,[define for In-Directory Access Logging overlay])
2686 fi
2687
2688 if test "$ol_enable_auditlog" != no ; then
2689         BUILD_AUDITLOG=$ol_enable_auditlog
2690         if test "$ol_enable_auditlog" = mod ; then
2691                 MFLAG=SLAPD_MOD_DYNAMIC
2692                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS auditlog.la"
2693         else
2694                 MFLAG=SLAPD_MOD_STATIC
2695                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS auditlog.o"
2696         fi
2697         AC_DEFINE_UNQUOTED(SLAPD_OVER_AUDITLOG,$MFLAG,[define for Audit Logging overlay])
2698 fi
2699
2700 if test "$ol_enable_constraint" != no ; then
2701         BUILD_CONSTRAINT=$ol_enable_constraint
2702         if test "$ol_enable_constraint" = mod ; then
2703                 MFLAG=SLAPD_MOD_DYNAMIC
2704                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS constraint.la"
2705         else
2706                 MFLAG=SLAPD_MOD_STATIC
2707                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS constraint.o"
2708         fi
2709         AC_DEFINE_UNQUOTED(SLAPD_OVER_CONSTRAINT,$MFLAG,[define for Attribute Constraint overlay])
2710 fi
2711
2712 if test "$ol_enable_dds" != no ; then
2713         BUILD_DDS=$ol_enable_dds
2714         if test "$ol_enable_dds" = mod ; then
2715                 MFLAG=SLAPD_MOD_DYNAMIC
2716                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dds.la"
2717         else
2718                 MFLAG=SLAPD_MOD_STATIC
2719                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dds.o"
2720         fi
2721         AC_DEFINE_UNQUOTED(SLAPD_OVER_DDS,$MFLAG,[define for Dynamic Directory Services overlay])
2722 fi
2723
2724 if test "$ol_enable_dyngroup" != no ; then
2725         BUILD_DYNGROUP=$ol_enable_dyngroup
2726         if test "$ol_enable_dyngroup" = mod ; then
2727                 MFLAG=SLAPD_MOD_DYNAMIC
2728                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dyngroup.la"
2729         else
2730                 MFLAG=SLAPD_MOD_STATIC
2731                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dyngroup.o"
2732         fi
2733         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNGROUP,$MFLAG,[define for Dynamic Group overlay])
2734 fi
2735
2736 if test "$ol_enable_dynlist" != no ; then
2737         BUILD_DYNLIST=$ol_enable_dynlist
2738         if test "$ol_enable_dynlist" = mod ; then
2739                 MFLAG=SLAPD_MOD_DYNAMIC
2740                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dynlist.la"
2741         else
2742                 MFLAG=SLAPD_MOD_STATIC
2743                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dynlist.o"
2744         fi
2745         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNLIST,$MFLAG,[define for Dynamic List overlay])
2746 fi
2747
2748 if test "$ol_enable_memberof" != no ; then
2749         BUILD_MEMBEROF=$ol_enable_memberof
2750         if test "$ol_enable_memberof" = mod ; then
2751                 MFLAG=SLAPD_MOD_DYNAMIC
2752                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS memberof.la"
2753         else
2754                 MFLAG=SLAPD_MOD_STATIC
2755                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS memberof.o"
2756         fi
2757         AC_DEFINE_UNQUOTED(SLAPD_OVER_MEMBEROF,$MFLAG,[define for Reverse Group Membership overlay])
2758 fi
2759
2760 if test "$ol_enable_ppolicy" != no ; then
2761         BUILD_PPOLICY=$ol_enable_ppolicy
2762         if test "$ol_enable_ppolicy" = mod ; then
2763                 MFLAG=SLAPD_MOD_DYNAMIC
2764                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS ppolicy.la"
2765         else
2766                 MFLAG=SLAPD_MOD_STATIC
2767                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS ppolicy.o"
2768         fi
2769         AC_DEFINE_UNQUOTED(SLAPD_OVER_PPOLICY,$MFLAG,[define for Password Policy overlay])
2770 fi
2771
2772 if test "$ol_enable_proxycache" != no ; then
2773         BUILD_PROXYCACHE=$ol_enable_proxycache
2774         if test "$ol_enable_proxycache" = mod ; then
2775                 MFLAG=SLAPD_MOD_DYNAMIC
2776                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS pcache.la"
2777         else
2778                 MFLAG=SLAPD_MOD_STATIC
2779                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS pcache.o"
2780         fi
2781         AC_DEFINE_UNQUOTED(SLAPD_OVER_PROXYCACHE,$MFLAG,[define for Proxy Cache overlay])
2782 fi
2783
2784 if test "$ol_enable_refint" != no ; then
2785         BUILD_REFINT=$ol_enable_refint
2786         if test "$ol_enable_refint" = mod ; then
2787                 MFLAG=SLAPD_MOD_DYNAMIC
2788                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS refint.la"
2789         else
2790                 MFLAG=SLAPD_MOD_STATIC
2791                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS refint.o"
2792         fi
2793         AC_DEFINE_UNQUOTED(SLAPD_OVER_REFINT,$MFLAG,[define for Referential Integrity overlay])
2794 fi
2795
2796 if test "$ol_enable_retcode" != no ; then
2797         BUILD_RETCODE=$ol_enable_retcode
2798         if test "$ol_enable_retcode" = mod ; then
2799                 MFLAG=SLAPD_MOD_DYNAMIC
2800                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS retcode.la"
2801         else
2802                 MFLAG=SLAPD_MOD_STATIC
2803                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS retcode.o"
2804         fi
2805         AC_DEFINE_UNQUOTED(SLAPD_OVER_RETCODE,$MFLAG,[define for Referential Integrity overlay])
2806 fi
2807
2808 if test "$ol_enable_rwm" != no ; then
2809         BUILD_REWRITE=yes
2810         BUILD_RWM=$ol_enable_rwm
2811         if test "$ol_enable_rwm" = mod ; then
2812                 MFLAG=SLAPD_MOD_DYNAMIC
2813                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS rwm.la"
2814         else
2815                 MFLAG=SLAPD_MOD_STATIC
2816                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS rwm_x.o"
2817         fi
2818         AC_DEFINE_UNQUOTED(SLAPD_OVER_RWM,$MFLAG,[define for Rewrite/Remap overlay])
2819 fi
2820
2821 if test "$ol_enable_seqmod" != no ; then
2822         BUILD_SEQMOD=$ol_enable_seqmod
2823         if test "$ol_enable_seqmod" = mod ; then
2824                 MFLAG=SLAPD_MOD_DYNAMIC
2825                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS seqmod.la"
2826         else
2827                 MFLAG=SLAPD_MOD_STATIC
2828                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS seqmod.o"
2829         fi
2830         AC_DEFINE_UNQUOTED(SLAPD_OVER_SEQMOD,$MFLAG,[define for Sequential Modify overlay])
2831 fi
2832
2833 if test "$ol_enable_syncprov" != no ; then
2834         BUILD_SYNCPROV=$ol_enable_syncprov
2835         if test "$ol_enable_syncprov" = mod ; then
2836                 MFLAG=SLAPD_MOD_DYNAMIC
2837                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS syncprov.la"
2838         else
2839                 MFLAG=SLAPD_MOD_STATIC
2840                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS syncprov.o"
2841         fi
2842         AC_DEFINE_UNQUOTED(SLAPD_OVER_SYNCPROV,$MFLAG,[define for Syncrepl Provider overlay])
2843 fi
2844
2845 if test "$ol_enable_translucent" != no ; then
2846         BUILD_TRANSLUCENT=$ol_enable_translucent
2847         if test "$ol_enable_translucent" = mod ; then
2848                 MFLAG=SLAPD_MOD_DYNAMIC
2849                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS translucent.la"
2850         else
2851                 MFLAG=SLAPD_MOD_STATIC
2852                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS translucent.o"
2853         fi
2854         AC_DEFINE_UNQUOTED(SLAPD_OVER_TRANSLUCENT,$MFLAG,[define for Translucent Proxy overlay])
2855 fi
2856
2857 if test "$ol_enable_unique" != no ; then
2858         BUILD_UNIQUE=$ol_enable_unique
2859         if test "$ol_enable_unique" = mod ; then
2860                 MFLAG=SLAPD_MOD_DYNAMIC
2861                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS unique.la"
2862         else
2863                 MFLAG=SLAPD_MOD_STATIC
2864                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS unique.o"
2865         fi
2866         AC_DEFINE_UNQUOTED(SLAPD_OVER_UNIQUE,$MFLAG,[define for Attribute Uniqueness overlay])
2867 fi
2868
2869 if test "$ol_enable_valsort" != no ; then
2870         BUILD_VALSORT=$ol_enable_valsort
2871         if test "$ol_enable_valsort" = mod ; then
2872                 MFLAG=SLAPD_MOD_DYNAMIC
2873                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS valsort.la"
2874         else
2875                 MFLAG=SLAPD_MOD_STATIC
2876                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS valsort.o"
2877         fi
2878         AC_DEFINE_UNQUOTED(SLAPD_OVER_VALSORT,$MFLAG,[define for Value Sorting overlay])
2879 fi
2880
2881 if test "$ol_enable_rewrite" != no ; then
2882         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
2883         BUILD_REWRITE=yes
2884 fi
2885
2886 if test "$ol_enable_slapi" != no ; then
2887         AC_DEFINE(ENABLE_SLAPI,1,[define to enable slapi library])
2888         BUILD_SLAPI=yes
2889         SLAPD_SLAPI_DEPEND=libslapi.a
2890 fi
2891
2892 dnl ----------------------------------------------------------------
2893
2894 dnl
2895 dnl For Windows build, we don't want to include -dlopen flags.
2896 dnl They hurt more than they help.
2897 dnl
2898
2899 if test "$ac_cv_mingw32" = yes ; then
2900         PLAT=NT
2901         SLAPD_MODULES_LDFLAGS=
2902 else
2903         PLAT=UNIX
2904 fi
2905
2906 AC_SUBST(LIBSRCS)
2907 AC_SUBST(PLAT)
2908 AC_SUBST(WITH_SASL)
2909 AC_SUBST(WITH_TLS)
2910 AC_SUBST(WITH_MODULES_ENABLED)
2911 AC_SUBST(WITH_ACI_ENABLED)
2912 AC_SUBST(BUILD_THREAD)
2913 AC_SUBST(BUILD_LIBS_DYNAMIC)
2914
2915 AC_SUBST(BUILD_SLAPD)
2916 dnl slapi
2917   AC_SUBST(BUILD_SLAPI)
2918   AC_SUBST(SLAPD_SLAPI_DEPEND)
2919 dnl backends
2920   AC_SUBST(BUILD_BDB)
2921   AC_SUBST(BUILD_DNSSRV)
2922   AC_SUBST(BUILD_HDB)
2923   AC_SUBST(BUILD_LDAP)
2924   AC_SUBST(BUILD_META)
2925   AC_SUBST(BUILD_MONITOR)
2926   AC_SUBST(BUILD_NULL)
2927   AC_SUBST(BUILD_PASSWD)
2928   AC_SUBST(BUILD_RELAY)
2929   AC_SUBST(BUILD_PERL)
2930   AC_SUBST(BUILD_SHELL)
2931   AC_SUBST(BUILD_SOCK)
2932   AC_SUBST(BUILD_SQL)
2933 dnl overlays
2934   AC_SUBST(BUILD_ACCESSLOG)
2935   AC_SUBST(BUILD_AUDITLOG)
2936   AC_SUBST(BUILD_CONSTRAINT)
2937   AC_SUBST(BUILD_DDS)
2938   AC_SUBST(BUILD_DENYOP)
2939   AC_SUBST(BUILD_DYNGROUP)
2940   AC_SUBST(BUILD_DYNLIST)
2941   AC_SUBST(BUILD_LASTMOD)
2942   AC_SUBST(BUILD_MEMBEROF)
2943   AC_SUBST(BUILD_PPOLICY)
2944   AC_SUBST(BUILD_PROXYCACHE)
2945   AC_SUBST(BUILD_REFINT)
2946   AC_SUBST(BUILD_RETCODE)
2947   AC_SUBST(BUILD_RWM)
2948   AC_SUBST(BUILD_SEQMOD)
2949   AC_SUBST(BUILD_SYNCPROV)
2950   AC_SUBST(BUILD_TRANSLUCENT)
2951   AC_SUBST(BUILD_UNIQUE)
2952   AC_SUBST(BUILD_VALSORT)
2953
2954 AC_SUBST(LDAP_LIBS)
2955 AC_SUBST(SLAPD_LIBS)
2956 AC_SUBST(BDB_LIBS)
2957 AC_SUBST(LTHREAD_LIBS)
2958 AC_SUBST(LUTIL_LIBS)
2959 AC_SUBST(WRAP_LIBS)
2960
2961 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2962 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2963
2964 AC_SUBST(SLAPD_NO_STATIC)
2965 AC_SUBST(SLAPD_STATIC_BACKENDS)
2966 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
2967 AC_SUBST(SLAPD_STATIC_OVERLAYS)
2968 AC_SUBST(SLAPD_DYNAMIC_OVERLAYS)
2969
2970 AC_SUBST(PERL_CPPFLAGS)
2971 AC_SUBST(SLAPD_PERL_LDFLAGS)
2972 AC_SUBST(MOD_PERL_LDFLAGS)
2973
2974 AC_SUBST(KRB4_LIBS)
2975 AC_SUBST(KRB5_LIBS)
2976 AC_SUBST(SASL_LIBS)
2977 AC_SUBST(TLS_LIBS)
2978 AC_SUBST(MODULES_LIBS)
2979 AC_SUBST(SLAPI_LIBS)
2980 AC_SUBST(LIBSLAPI)
2981 AC_SUBST(LIBSLAPITOOLS)
2982 AC_SUBST(AUTH_LIBS)
2983 AC_SUBST(ICU_LIBS)
2984
2985 AC_SUBST(SLAPD_SLP_LIBS)
2986 AC_SUBST(SLAPD_GMP_LIBS)
2987
2988 AC_SUBST(SLAPD_SQL_LDFLAGS)
2989 AC_SUBST(SLAPD_SQL_LIBS)
2990 AC_SUBST(SLAPD_SQL_INCLUDES)
2991
2992 dnl ----------------------------------------------------------------
2993 dnl final help output
2994 AC_ARG_WITH(xxinstall,[
2995 See INSTALL file for further details.])
2996
2997 dnl ----------------------------------------------------------------
2998 dnl final output
2999 dnl
3000
3001 AC_CONFIG_FILES([Makefile:build/top.mk:Makefile.in:build/dir.mk]
3002 [doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk]
3003 [doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk]
3004 [doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk]
3005 [doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk]
3006 [doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk]
3007 [doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk]
3008 [clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk]
3009 [clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk]
3010 [include/Makefile:build/top.mk:include/Makefile.in]
3011 [libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk]
3012 [libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk]
3013 [libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk]
3014 [libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk]
3015 [libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk]
3016 [libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk]
3017 [libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-static.mk]
3018 [servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk]
3019 [servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk]
3020 [servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk]
3021 [servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk]
3022 [servers/slapd/back-hdb/Makefile:build/top.mk:servers/slapd/back-hdb/Makefile.in:build/mod.mk]
3023 [servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk]
3024 [servers/slapd/back-ldif/Makefile:build/top.mk:servers/slapd/back-ldif/Makefile.in:build/mod.mk]
3025 [servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk]
3026 [servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk]
3027 [servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk]
3028 [servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk]
3029 [servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk]
3030 [servers/slapd/back-relay/Makefile:build/top.mk:servers/slapd/back-relay/Makefile.in:build/mod.mk]
3031 [servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk]
3032 [servers/slapd/back-sock/Makefile:build/top.mk:servers/slapd/back-sock/Makefile.in:build/mod.mk]
3033 [servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk]
3034 [servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk]
3035 [servers/slapd/slapi/Makefile:build/top.mk:servers/slapd/slapi/Makefile.in:build/lib.mk:build/lib-shared.mk]
3036 [servers/slapd/overlays/Makefile:build/top.mk:servers/slapd/overlays/Makefile.in:build/lib.mk]
3037 [tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk]
3038 [tests/run]
3039 [tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk])
3040
3041 AC_CONFIG_COMMANDS([default],[[
3042 chmod +x tests/run
3043 date > stamp-h
3044 BACKENDSC="servers/slapd/backends.c"
3045 echo "Making $BACKENDSC"
3046 rm -f $BACKENDSC
3047 cat > $BACKENDSC << ENDX
3048 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3049  *
3050  * Copyright 1998-2008 The OpenLDAP Foundation.
3051  * All rights reserved.
3052  *
3053  * Redistribution and use in source and binary forms, with or without
3054  * modification, are permitted only as authorized by the OpenLDAP
3055  * Public License.
3056  *
3057  * A copy of this license is available in the file LICENSE in the
3058  * top-level directory of the distribution or, alternatively, at
3059  * <http://www.OpenLDAP.org/license.html>.
3060  */
3061 /* This file is automatically generated by configure; please do not edit. */
3062
3063 #include "portable.h"
3064 #include "slap.h"
3065
3066 ENDX
3067 if test "${STATIC_BACKENDS}"; then
3068         for b in config ${STATIC_BACKENDS}; do
3069                 bb=`echo "${b}" | sed -e 's/back-//'`
3070                 cat >> $BACKENDSC << ENDX
3071 extern BI_init ${bb}_back_initialize;
3072 ENDX
3073         done
3074
3075         cat >> $BACKENDSC << ENDX
3076
3077 BackendInfo slap_binfo[] = {
3078 ENDX
3079
3080         for b in config ${STATIC_BACKENDS}; do
3081                 bb=`echo "${b}" | sed -e 's/back-//'`
3082                 echo "    Add ${bb} ..."
3083                 cat >> $BACKENDSC << ENDX
3084         { "${bb}", ${bb}_back_initialize },
3085 ENDX
3086         done
3087
3088         cat >> $BACKENDSC << ENDX
3089         { NULL, NULL },
3090 };
3091
3092 /* end of generated file */
3093 ENDX
3094 fi
3095 OVERLAYSC="servers/slapd/overlays/statover.c"
3096 echo "Making $OVERLAYSC"
3097 rm -f $OVERLAYSC
3098 cat > $OVERLAYSC << ENDX
3099 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3100  *
3101  * Copyright 1998-2008 The OpenLDAP Foundation.
3102  * All rights reserved.
3103  *
3104  * Redistribution and use in source and binary forms, with or without
3105  * modification, are permitted only as authorized by the OpenLDAP
3106  * Public License.
3107  *
3108  * A copy of this license is available in the file LICENSE in the
3109  * top-level directory of the distribution or, alternatively, at
3110  * <http://www.OpenLDAP.org/license.html>.
3111  */
3112 /* This file is automatically generated by configure; please do not edit. */
3113
3114 #include "portable.h"
3115 #include "slap.h"
3116
3117 ENDX
3118 if test "${STATIC_OVERLAYS}"; then
3119         for o in ${STATIC_OVERLAYS}; do
3120                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3121                 cat >> $OVERLAYSC << ENDX
3122 extern OV_init ${oo}_initialize;
3123 ENDX
3124         done
3125 fi
3126
3127 cat >> $OVERLAYSC << ENDX
3128
3129 OverlayInit slap_oinfo[] = {
3130 ENDX
3131
3132 if test "${STATIC_OVERLAYS}"; then
3133         for o in ${STATIC_OVERLAYS}; do
3134                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3135                 echo "    Add ${oo} ..."
3136                 cat >> $OVERLAYSC << ENDX
3137         { "${oo}", ${oo}_initialize },
3138 ENDX
3139         done
3140 fi
3141
3142         cat >> $OVERLAYSC << ENDX
3143         { NULL, NULL },
3144 };
3145
3146 /* end of generated file */
3147 ENDX
3148
3149 if test "${ol_cv_mkdep}" = no; then
3150         echo '(Do not "make depend"; we do not know how to build dependencies)'
3151 else
3152         echo 'Please run "make depend" to build dependencies'
3153 fi
3154 ]],[[
3155 STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS"
3156 STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS"
3157 ]])
3158 AC_OUTPUT