git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  28 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  29 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  30 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  31 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  32 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  33 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  34         no, [yes no])dnl
  35
  36 dnl General "with" options
  37 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  38         auto, [auto k5 k4 afs yes no])
  39 OL_ARG_WITH(threads,[  --with-threads   use threads],
  40         auto, [auto posix mach lwp yes no manual] )
  41 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  42         auto, [auto yes no manual] )
  43
  44 dnl Server options
  45
  46 dnl LDAPD OPTIONS
  47 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  48
  49 dnl SLAPD OPTIONS
  50 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  51 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  52 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  53 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  54 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  55 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  56 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  57 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  58
  59 dnl SLAPD Backend options
  60 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  61 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  62         [auto db2 db gdbm ndbm manual])
  63 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  64         [auto btree hash])
  65
  66 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  67 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  68
  69 dnl SLURPD OPTIONS
  70 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  71
  72 # validate options
  73 if test $ol_enable_referrals = no ; then
  74         if test $ol_enable_dns = yes ; then
  75                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
  76         fi
  77         ol_enable_dns=no
  78 fi
  79
  80 if test $ol_enable_slapd = no ; then
  81         dnl SLAPD was specificallly disabled
  82         if test $ol_enable_ldbm = yes ; then
  83                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  84         fi
  85         if test $ol_enable_passwd = yes ; then
  86                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
  87         fi
  88         if test $ol_enable_shell = yes ; then
  89                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
  90         fi
  91         if test $ol_enable_aclgroups = yes ; then
  92                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
  93         fi
  94         if test $ol_enable_crypt = yes ; then
  95                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
  96         fi
  97         if test $ol_enable_md5 = yes ; then
  98                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
  99         fi
 100         if test $ol_enable_sha1 = yes ; then
 101                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 102         fi
 103         if test $ol_enable_wrappers = yes ; then
 104                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 105         fi
 106         if test $ol_enable_phonetic = yes ; then
 107                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 108         fi
 109         if test $ol_enable_rlookups = yes ; then
 110                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 111         fi
 112         if test $ol_with_ldbm_api != auto ; then
 113                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 114         fi
 115         if test $ol_with_ldbm_type != auto ; then
 116                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 117         fi
 118         if test $ol_enable_slurpd = yes ; then
 119                 AC_MSG_ERROR([slurpd requires slapd])
 120         fi
 121
 122         # force settings to no
 123         ol_enable_ldbm=no
 124         ol_enable_shell=no
 125         ol_enable_passwd=no
 126         ol_enable_aclgroups=no
 127         ol_enable_crypt=no
 128         ol_enable_md5=no
 129         ol_enable_sha1=no
 130         ol_enable_wrappers=no
 131         ol_enable_phonetic=no
 132         ol_enable_rlookups=no
 133         ol_with_ldbm_api=no
 134         ol_with_ldbm_type=no
 135         ol_enable_slurpd=no
 136
 137 elif test $ol_enable_ldbm = no ; then
 138         dnl SLAPD without LDBM
 139
 140         if test $ol_with_ldbm_api != auto ; then
 141                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 142         fi
 143
 144         if test $ol_with_ldbm_type != auto ; then
 145                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 146         fi
 147
 148         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 149                 AC_MSG_ERROR([slapd requires a backend])
 150         fi
 151
 152         ol_with_ldbm_api=no
 153         ol_with_ldbm_type=no
 154
 155 else
 156         dnl SLAPD with LDBM
 157
 158         if test $ol_with_ldbm_api = gdbm -a \
 159                 $ol_with_ldbm_type = btree ; then
 160                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 161         fi
 162         if test $ol_with_ldbm_api = ndbm -a \
 163                 $ol_with_ldbm_type = btree ; then
 164                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 165         fi
 166 fi
 167
 168 if test $ol_enable_slurpd = yes ; then
 169         dnl SLURPD was specifically enabled
 170         if test $ol_with_threads = no ; then
 171                 AC_MSG_ERROR([slurpd requires threads])
 172         fi
 173 fi
 174
 175 AC_MSG_RESULT(done)
 176
 177 ## Initialize vars
 178 LDAP_LIBS=
 179 LDBM_LIBS=
 180 LTHREAD_LIBS=
 181 LUTIL_LIBS=
 182
 183 LDAPD_LIBS=
 184 SLAPD_LIBS=
 185 SLURPD_LIBS=
 186
 187 BUILD_LDAPD=no
 188 BUILD_SLAPD=no
 189 BUILD_SLURPD=no
 190
 191 BUILD_LDBM=no
 192 BUILD_PASSWD=no
 193 BUILD_SHELL=no
 194 BUILD_THREAD=no
 195
 196 KRB_LIBS=
 197 TERMCAP_LIBS=
 198
 199 dnl ----------------------------------------------------------------
 200 dnl Checks for programs
 201
 202 AC_PROG_LN_S
 203 AC_PROG_INSTALL
 204 AC_PROG_RANLIB
 205 AC_PROG_MAKE_SET
 206
 207 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 208         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 209 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 210 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 211
 212 dnl Checks the compiler and UNIX Variants
 213 AC_PROG_CC
 214
 215 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 216         AC_WARN([cross compiling....  go for it])
 217
 218 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 219         AC_WARN([programs compiled here do run here...])
 220         AC_ERROR([  if not cross compiling, use --disable-x-compile.])
 221
 222 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 223         AC_WARN([programs compiled here do not run here...])
 224         AC_ERROR([  if cross compiling,  add --enable-x-compile.])
 225 fi
 226
 227 dnl OpenLDAP requires STDC features
 228 dnl AC_PROG_GCC_TRADITIONAL
 229 AC_PROG_CPP
 230
 231
 232 AC_AIX
 233 AC_ISC_POSIX
 234 AC_MINIX
 235
 236 dnl Checks for libraries
 237
 238 dnl Find socket()
 239 dnl Likely combinations:
 240 dnl             -lsocket [ -lnsl_s | -lnsl ]
 241 dnl             -linet
 242
 243 AC_CHECK_FUNC(socket, :, [
 244 dnl
 245 dnl hopefully we won't include too many libraries
 246 dnl
 247         AC_CHECK_LIB(socket, main)
 248         AC_CHECK_LIB(net, main)
 249         AC_CHECK_LIB(nsl_s, main)
 250         AC_CHECK_LIB(nsl, main)
 251         AC_CHECK_LIB(inet, socket)
 252         AC_CHECK_LIB(gen, main)
 253 ])
 254
 255 dnl Check for resolv
 256 AC_CHECK_LIB(resolv, res_search)
 257
 258 dnl HP-UX requires -lV3
 259 AC_CHECK_LIB(V3, sigset)
 260
 261 # ISODE tests
 262 ol_link_isode=no
 263 if test $ol_enable_ldapd != no ; then
 264         dnl look for ISODE libraries
 265         AC_CHECK_LIB(xtpp, main, [
 266                 ol_link_isode=yes
 267                 AC_DEFINE(HAVE_XTPP,1)
 268                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 269                 ],:,[-lxtdsap -lxtisode -losi])
 270         AC_CHECK_LIB(dsap, main, [
 271                 ol_link_isode=yes
 272                 AC_DEFINE(HAVE_DSAP,1)
 273                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 274                 ],:,[-lisode])
 275         AC_CHECK_LIB(isode, main, [
 276                 ol_link_isode=yes
 277                 AC_DEFINE(HAVE_ISODE,1)
 278                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 279                 ],:)
 280 fi
 281
 282 if test $ol_link_isode != no; then
 283         AC_CHECK_LIB(pp, main, [
 284                 AC_DEFINE(HAVE_PP,1)
 285                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 286                 ],:)
 287
 288         AC_PATH_PROG(PEPSY, pepsy)
 289 fi
 290
 291 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 292         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 293
 294         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 295                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 296                         [-lkrb5 -ldes425])
 297
 298                 if test $have_k5 = yes ; then
 299                         ol_with_kerberos=found
 300                         ol_link_kerberos=yes
 301
 302                         AC_DEFINE(HAVE_KERBEROS)
 303
 304                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 305                 fi
 306         fi
 307 fi
 308 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 309         AC_CHECK_HEADERS(krb.h des.h)
 310
 311         if test $ac_cv_header_krb_h = yes ; then
 312                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 313
 314                 if test $have_k4 = yes ; then
 315                         ol_with_kerberos=found
 316                         ol_link_kerberos=yes
 317
 318                         AC_DEFINE(HAVE_KERBEROS)
 319
 320                         KRB_LIBS="-lkrb -ldes"
 321                 fi
 322         fi
 323 fi
 324
 325
 326 ol_link_threads=no
 327 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 328         AC_CHECK_HEADERS(pthread.h sched.h)
 329
 330         if test $ac_cv_header_pthread_h = yes ; then
 331                 OL_POSIX_THREAD_VERSION
 332
 333                 if test $ol_cv_pthread_version = final ; then
 334                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 335                 elif test $ol_cv_pthread_version = draft4 ; then
 336                         AC_DEFINE(HAVE_PTHREADS_D4)
 337                 else
 338                         AC_MSG_ERROR([unknown pthread version])
 339                 fi
 340
 341                 # consider threads found
 342                 ol_with_threads=found
 343
 344                 OL_LINUX_THREADS
 345
 346                 if test $ol_cv_linux_threads = yes ; then
 347                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 348                 fi
 349
 350                 dnl Now the hard part, how to link
 351
 352                 dnl A few platforms have pthread support in standard libraries
 353                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 354
 355                 if test $ol_link_threads = no ; then
 356                         dnl try -pthread
 357                         AC_CACHE_CHECK([for pthread_create with -pthread],
 358                                 [ol_cv_pthread_flag], [
 359                                 dnl save the flags
 360                                 save_LIBS="$LIBS"
 361                                 LIBS="-pthread $LIBS"
 362                                 AC_TRY_LINK([char pthread();],[
 363                                         pthread_create();
 364                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 365                                 dnl restore the LIBS
 366                                 LIBS="$save_LIBS"
 367                         ])
 368
 369                         if test $ol_cv_pthread_flag = yes ; then
 370                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 371                                 ol_link_threads=posix
 372                         fi
 373                 fi
 374
 375                 if test $ol_link_threads = no ; then
 376                         dnl try -thread
 377                         AC_CACHE_CHECK([for pthread_create with -thread],
 378                                 [ol_cv_thread_flag], [
 379                                 dnl save the flags
 380                                 save_LIBS="$LIBS"
 381                                 LIBS="-thread $LIBS"
 382                                 AC_TRY_LINK([char pthread();],[
 383                                         pthread_create();
 384                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 385                                 dnl restore the LIBS
 386                                 LIBS="$save_LIBS"
 387                         ])
 388
 389                         if test $ol_cv_thread_flag = yes ; then
 390                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 391                                 ol_link_threads=posix
 392                         fi
 393                 fi
 394
 395                 if test $ol_link_threads = no ; then
 396                         dnl try DEC Threads
 397                         save_LIBS="$LIBS"
 398                         AC_CHECK_LIB(pthread, pthread_create, [
 399                                 AC_DEFINE(HAVE_DCE)
 400                                 ol_link_threads=posix
 401                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc_r"
 402                                 if test $ol_with_preemptive = auto ; then
 403                                         ol_with_preemptive=yes
 404                                 fi
 405                                 ],,[-lmach -lexc -lc_r])
 406                         LIBS="$save_LIBS"
 407                 fi
 408
 409                 if test $ol_link_threads = no ; then
 410                         dnl try -lpthread
 411                         save_LIBS="$LIBS"
 412                         AC_CHECK_LIB(pthread, pthread_create, [
 413                                 ol_link_threads=posix
 414                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 415                         LIBS="$save_LIBS"
 416                 fi
 417
 418                 if test $ol_link_threads = no ; then
 419                         dnl try -lc_r
 420                         save_LIBS="$LIBS"
 421                         AC_CHECK_LIB(c_r, pthread_create, [
 422                                 ol_link_threads=posix
 423                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 424                         LIBS="$save_LIBS"
 425                 fi
 426
 427                 if test $ol_link_threads != no ; then
 428                         AC_DEFINE(HAVE_PTHREADS)
 429
 430                         dnl save flags
 431                         save_CPPFLAGS="$CPPFLAGS"
 432                         save_LIBS="$LIBS"
 433                         LIBS="$LTHREAD_LIBS $LIBS"
 434
 435                         dnl All POSIX Thread (final) implementations should have
 436                         dnl sched_yield instead of pthread yield.
 437                         dnl check for both
 438                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 439
 440                         if test $ac_cv_func_sched_yield = no -a \
 441                                 $ac_cv_func_pthread_yield = no ; then
 442                                 dnl Digital UNIX has sched_yield() in -lrt
 443                                 AC_CHECK_LIB(rt, sched_yield,
 444                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 445                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 446                                         ac_cv_func_sched_yield=yes],
 447                                         [ac_cv_func_sched_yield=no])
 448                         fi
 449                         if test $ac_cv_func_sched_yield = no -a \
 450                                 $ac_cv_func_pthread_yield = no ; then
 451                                 dnl Solaris has sched_yield() in -lposix4
 452                                 AC_CHECK_LIB(posix4, sched_yield,
 453                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 454                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 455                                         ac_cv_func_sched_yield=yes],
 456                                         [ac_cv_func_sched_yield=no])
 457                         fi
 458                         if test $ac_cv_func_sched_yield = no -a \
 459                                 $ac_cv_func_pthread_yield = no ; then
 460                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 461                                 AC_MSG_ERROR([POSIX Threads are not usable])
 462                         fi
 463
 464                         dnl Check functions for compatibility
 465                         AC_CHECK_FUNCS(pthread_kill)
 466                         AC_CHECK_FUNCS( \
 467                                 pthread_attr_create pthread_attr_init \
 468                                 pthread_attr_destroy pthread_attr_delete \
 469                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 470                         )
 471
 472                         dnl Check for setconcurreny functions
 473                         AC_CHECK_FUNCS( \
 474                                 pthread_setconcurrency \
 475                                 thr_setconcurrency \
 476                         )
 477
 478                         dnl Check PREEMPTIVE Implementation
 479                         if test $ol_with_preemptive = auto ; then
 480                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 481                                 AC_TRY_RUN([
 482 #include <sys/types.h>
 483 #include <sys/time.h>
 484 #include <unistd.h>
 485 #include <pthread.h>
 486 #ifndef NULL
 487 #define NULL 0
 488 #endif
 489
 490 int task(arg)
 491         int *arg;
 492 {
 493         struct timeval tv;
 494
 495         tv.tv_sec=4;
 496         tv.tv_usec=0;
 497         select(0, NULL, NULL, NULL, &tv);
 498
 499         tv.tv_sec=6;
 500         tv.tv_usec=0;
 501         select(0, NULL, NULL, NULL, &tv);
 502
 503         exit(1); /* if we exit here, the select blocked the whole process */
 504 }
 505
 506 main(argc, argv)
 507 int argc; char **argv;
 508 {
 509         pthread_t t;
 510
 511 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 512         (void) pthread_setconcurrency(2);
 513 #else
 514 #ifdef HAVE_THR_SETCONCURRENCY
 515         /* Set Solaris LWP concurrency to 2 */
 516         thr_setconcurrency(2);
 517 #endif
 518 #endif
 519
 520         pthread_create(&t, NULL, (void *) task, NULL);
 521
 522 #if HAVE_SCHED_YIELD
 523         sched_yield();  /* make sure task runs first */
 524 #else
 525 #ifdef HAVE_PTHREAD_YIELD
 526         pthread_yield();        /* make sure task runs first */
 527 #endif
 528 #endif
 529         exit(0);
 530 }
 531                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 532                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 533                                 AC_MSG_RESULT($ol_pthread_preemptive)
 534
 535                                 if test $ol_pthread_preemptive = yes ; then
 536                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 537                                         ol_with_preemptive=yes
 538                                 fi
 539                         fi
 540
 541 dnl                     dnl check for reentrant/threadsafe functions
 542 dnl                     AC_CHECK_FUNCS( \
 543 dnl                             feof_unlocked \
 544 dnl                             unlocked_feof \
 545 dnl                             ftrylockfile \
 546 dnl                             flockfile \
 547 dnl                             putc_unlocked \
 548 dnl                             gmtime_r \
 549 dnl                             strtok_r \
 550 dnl                     )
 551
 552                         dnl restore flags
 553                         CPPFLAGS="$save_CPPFLAGS"
 554                         LIBS="$save_LIBS"
 555                 else
 556                         AC_MSG_ERROR([could not link with POSIX Threads])
 557                 fi
 558         fi
 559
 560         if test $ol_with_threads = posix ; then
 561                 AC_MSG_ERROR([could not locate POSIX Threads])
 562         fi
 563 fi
 564
 565 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 566         dnl check for Mach CThreads
 567         AC_CHECK_HEADERS(mach/cthreads.h)
 568         if test $ac_cv_header_mach_cthreads_h = yes ; then
 569                 ol_with_threads=found
 570
 571                 dnl A few platforms have cthread support in standard libraries
 572                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 573
 574                 if test $ol_link_threads = no ; then
 575                         dnl try -all_load
 576                         dnl this test needs work
 577                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 578                                 [ol_cv_cthread_all_load], [
 579                                 dnl save the flags
 580                                 save_LIBS="$LIBS"
 581                                 LIBS="-all_load $LIBS"
 582                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 583                                         cthread_fork((void *)0, (void *)0);
 584                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 585                                 dnl restore the LIBS
 586                                 LIBS="$save_LIBS"
 587                         ])
 588
 589                         if test $ol_cv_cthread_all_load = yes ; then
 590                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 591                                 ol_link_threads=mach
 592                         fi
 593                 fi
 594
 595                 if test $ol_link_threads != no ; then
 596                         : check for cthread specific functionality here
 597                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 598                 else
 599                         AC_MSG_ERROR([could not link with Mach CThreads])
 600                 fi
 601         fi
 602
 603         if test $ol_with_threads = mach ; then
 604                 AC_MSG_ERROR([could not locate Mach CThreads])
 605         fi
 606 fi
 607
 608 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 609         dnl check for SunOS5 LWP
 610         AC_CHECK_HEADERS(thread.h synch.h)
 611         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 612                 AC_CHECK_LIB(thread, thr_create, [have_lwp=yes], [have_lwp=no])
 613
 614                 if test $have_lwp = yes ; then
 615                         AC_DEFINE(HAVE_THR)
 616                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 617
 618                         if test $ol_with_preemptive = auto ; then
 619                                 ol_with_preemptive=yes
 620                         fi
 621                 fi
 622         fi
 623
 624         dnl check for SunOS4 LWP
 625         AC_CHECK_HEADERS(lwp/lwp.h)
 626         if test $ac_cv_header_lwp_lwp_h = yes ; then
 627                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 628
 629                 if test $have_lwp = yes ; then
 630                         AC_DEFINE(HAVE_LWP)
 631                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 632
 633                         if test $ol_with_preemptive = auto ; then
 634                                 ol_with_preemptive=no
 635                         fi
 636                 fi
 637         fi
 638 fi
 639
 640 if test $ol_with_preemptive = yes ; then
 641         AC_DEFINE(PREEMPTIVE_THREADS,1)
 642 fi
 643
 644 if test $ol_with_threads = manual ; then
 645         dnl User thinks he can manually configure threads.
 646         ol_link_threads=yes
 647
 648         AC_MSG_WARN([thread defines and link options must be set manually])
 649
 650         AC_CHECK_HEADERS(pthread.h sched.h)
 651         AC_CHECK_FUNCS(sched_yield pthread_yield)
 652         OL_LINUX_THREADS
 653
 654         AC_CHECK_HEADERS(mach/cthreads.h)
 655         AC_CHECK_HEADERS(lwp/lwp.h)
 656         AC_CHECK_HEADERS(thread.h synch.h)
 657 fi
 658
 659 if test $ol_with_threads != no ; then
 660         dnl needed to get reentrant/threadsafe versions
 661         dnl
 662         dnl hopefully this will not cause problems with
 663         dnl non-threaded apps
 664         dnl
 665         AC_DEFINE(_REENTRANT,1)
 666         AC_DEFINE(_THREAD_SAFE,1)
 667 fi
 668
 669 dnl ----------------------------------------------------------------
 670
 671 if test $ol_link_threads = no ; then
 672         if test $ol_with_threads = yes ; then
 673                 AC_MSG_ERROR([no suitable thread support])
 674         fi
 675
 676         if test $ol_with_threads = auto ; then
 677                 AC_MSG_WARN([no suitable thread support, disabling threads])
 678                 ol_with_threads=no
 679         fi
 680
 681         AC_DEFINE(NO_THREADS,1)
 682         AC_DEFINE(PREEMPTIVE_THREADS,1)
 683         LTHREAD_LIBS=""
 684 fi
 685
 686 ol_link_ldbm=no
 687 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 688         OL_BERKELEY_DB2
 689
 690         if test $ol_cv_berkeley_db2 = yes ; then
 691                 ol_link_ldbm=db2
 692                 ol_with_ldbm_api=db2
 693
 694                 if test $ol_with_ldbm_type = hash ; then
 695                         AC_DEFINE(LDBM_USE_DBHASH,1)
 696                 else
 697                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 698                 fi
 699
 700                 dnl $ol_cv_lib_db2 should be yes or -ldb
 701                 dnl (it could be no, but that would be an error
 702                 if test $ol_cv_lib_db2 != yes ; then
 703                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 704                 fi
 705         fi
 706 fi
 707
 708 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 709         OL_BERKELEY_DB
 710
 711         if test $ol_cv_berkeley_db = yes ; then
 712                 ol_link_ldbm=db
 713                 ol_with_ldbm_api=db
 714
 715                 if test $ol_with_ldbm_type = hash ; then
 716                         AC_DEFINE(LDBM_USE_DBHASH,1)
 717                 else
 718                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 719                 fi
 720
 721                 dnl $ol_cv_lib_db should be yes or -ldb
 722                 dnl (it could be no, but that would be an error
 723                 if test $ol_cv_lib_db != yes ; then
 724                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 725                 fi
 726         fi
 727 fi
 728
 729 if test $ol_with_ldbm_api = manual ; then
 730         dnl User thinks he can manually configure LDBM api.
 731         ol_link_ldbm=yes
 732
 733         AC_MSG_WARN([LDBM defines and link options must be set manually])
 734
 735         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 736 fi
 737
 738 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 739         AC_MSG_WARN(Could not find LDBM with BTREE support)
 740         ol_with_ldbm_api=none
 741 fi
 742
 743 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 744         OL_GDBM
 745
 746         if test $ol_cv_gdbm = yes ; then
 747                 ol_link_ldbm=gdbm
 748                 ol_with_ldbm_api=gdbm
 749
 750                 if test $ol_cv_lib_gdbm != yes ; then
 751                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 752                 fi
 753         fi
 754 fi
 755
 756 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 757         OL_NDBM
 758
 759         if test $ol_cv_ndbm = yes ; then
 760                 ol_link_ldbm=ndbm
 761                 ol_with_ldbm_api=ndbm
 762
 763                 if test $ol_with_ldbm_api = ndbm ; then
 764                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 765                 fi
 766
 767                 if test $ol_cv_lib_ndbm != yes ; then
 768                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 769                 fi
 770         fi
 771 fi
 772
 773 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 774         AC_MSG_WARN(could not find suitable LDBM backend)
 775         if test $ol_enable_ldbm = yes ; then
 776                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 777         fi
 778
 779         AC_MSG_WARN(disabling LDBM)
 780         ol_enable_ldbm=no
 781 fi
 782
 783 if test $ol_enable_wrappers = yes ; then
 784         AC_CHECK_LIB(wrap, hosts_access,
 785                 [have_wrappers=yes], [have_wrappers=no])
 786
 787         if test $have_wrappers = yes ; then
 788                 AC_DEFINE(HAVE_TCPD)
 789                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 790         else
 791                 AC_MSG_WARN(could not find -lwrap)
 792                 if test $ol_enable_wrappers = yes ; then
 793                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 794                 fi
 795
 796                 AC_MSG_WARN(disabling wrappers support)
 797                 ol_enable_wrappers=no
 798         fi
 799
 800 fi
 801
 802 # ud needs termcap (should insert check here)
 803 ol_link_termcap=no
 804 AC_CHECK_HEADERS(termcap.h ncurses.h)
 805
 806 if test $ol_link_termcap = no ; then
 807         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 808         if test $have_termcap = yes ; then
 809                 AC_DEFINE(HAVE_TERMCAP)
 810                 ol_link_termcap=yes
 811                 TERMCAP_LIBS=-ltermcap
 812         fi
 813 fi
 814
 815 if test $ol_link_termcap = no ; then
 816         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 817         if test $have_ncurses = yes ; then
 818                 AC_DEFINE(HAVE_NCURSES)
 819                 ol_link_termcap=yes
 820                 TERMCAP_LIBS=-lncurses
 821         fi
 822 fi
 823
 824 if test $ol_link_termcap = no ; then
 825         AC_DEFINE(NO_TERMCAP,1)
 826         TERMCAP_LIBS=
 827 fi
 828
 829 # FreeBSD (and others) have crypt(3) in -lcrypt
 830 if test $ol_enable_crypt != no ; then
 831         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 832                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 833                         have_crypt=yes], [have_crypt=no])])
 834
 835         if test $have_crypt = yes ; then
 836                 AC_DEFINE(HAVE_CRYPT,1)
 837         else
 838                 AC_MSG_WARN(could not find crypt)
 839                 if test $ol_enable_crypt = yes ; then
 840                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 841                 fi
 842
 843                 AC_MSG_WARN(disabling crypt support)
 844                 ol_enable_crypt=no
 845         fi
 846 fi
 847
 848 # FreeBSD (and others) have setproctitle(3) in -lutil
 849 if test $ol_enable_proctitle != no ; then
 850         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 851                 AC_CHECK_LIB(util, setproctitle,
 852                         [have_setproctitle=yes
 853                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 854                         [have_setproctitle=no
 855                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 856
 857         if test $have_setproctitle = yes ; then
 858                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 859         fi
 860 fi
 861
 862 dnl ----------------------------------------------------------------
 863 dnl Checks for header files.
 864 AC_HEADER_STDC
 865
 866 if test $ac_cv_header_stdc != yes; then
 867         AC_MSG_WARN([could not locate Standard C headers])
 868 fi
 869
 870 AC_HEADER_DIRENT
 871 AC_HEADER_SYS_WAIT
 872 AC_CHECK_HEADERS(       \
 873         stdarg.h                \
 874         stddef.h                \
 875         errno.h                 \
 876         fcntl.h                 \
 877         filio.h                 \
 878         getopt.h                \
 879         libutil.h               \
 880         limits.h                \
 881         malloc.h                \
 882         regex.h                 \
 883         sgtty.h                 \
 884         sys/file.h              \
 885         sys/filio.h             \
 886         sys/errno.h             \
 887         sys/ioctl.h             \
 888         sys/param.h             \
 889         sys/socket.h    \
 890         sys/syslog.h    \
 891         sys/time.h              \
 892         sys/types.h             \
 893         syslog.h                \
 894         termios.h               \
 895         unistd.h                \
 896 )
 897
 898 dnl ----------------------------------------------------------------
 899 dnl Checks for typedefs, structures, and compiler characteristics.
 900 AC_TYPE_GETGROUPS
 901 AC_TYPE_MODE_T
 902 AC_TYPE_OFF_T
 903 AC_TYPE_PID_T
 904 AC_TYPE_SIGNAL
 905 AC_TYPE_SIZE_T
 906 AC_TYPE_UID_T
 907 AC_STRUCT_ST_BLKSIZE
 908 AC_HEADER_TIME
 909 AC_STRUCT_TM
 910
 911 OL_C_UPPER_LOWER
 912 AC_C_CONST
 913
 914 dnl AC_CHECK_SIZEOF(short)
 915 dnl AC_CHECK_SIZEOF(int)
 916 dnl AC_CHECK_SIZEOF(long)
 917
 918 dnl ----------------------------------------------------------------
 919 dnl Checks for library functions.
 920 AC_FUNC_MEMCMP
 921 AC_FUNC_STRFTIME
 922 AC_FUNC_VPRINTF
 923
 924 if test $ac_cv_func_vprintf = yes ; then
 925         dnl check for vsnprintf
 926         AC_CHECK_FUNCS(vsnprintf)
 927 fi
 928
 929 AC_FUNC_WAIT3
 930
 931 AC_CHECK_FUNCS(         \
 932         bcopy                   \
 933         getopt                  \
 934         flock                   \
 935         gethostname             \
 936         gettimeofday    \
 937         getdtablesize   \
 938         lockf                   \
 939         memcpy                  \
 940         memmove                 \
 941         mkstemp                 \
 942         mktime                  \
 943         res_search              \
 944         select                  \
 945         setpwfile               \
 946         setsid                  \
 947         signal                  \
 948         sigset                  \
 949         snprintf                \
 950         socket                  \
 951         strerror                \
 952         strstr                  \
 953         strrchr                 \
 954         strsep                  \
 955         strtod                  \
 956         strtol                  \
 957         strtoul                 \
 958         sysconf                 \
 959         tempnam                 \
 960         waitpid                 \
 961 )
 962
 963 AC_REPLACE_FUNCS(getopt strdup tempnam)
 964
 965 dnl ----------------------------------------------------------------
 966 # Check Configuration
 967 OL_SYS_ERRLIST
 968
 969 dnl ----------------------------------------------------------------
 970 dnl Sort out defines
 971
 972 if test $ol_enable_debug != no ; then
 973         AC_DEFINE(LDAP_DEBUG,1)
 974 fi
 975 dnl     if test $ol_enable_syslog != no ; then
 976 dnl             AC_DEFINE(LDAP_SYSLOG,1)
 977 dnl     fi
 978 if test $ol_enable_libui = yes ; then
 979         AC_DEFINE(LDAP_LIBUI,1)
 980 fi
 981 if test $ol_enable_cache = no ; then
 982         AC_DEFINE(LDAP_NOCACHE,1)
 983 fi
 984 if test $ol_enable_dns != no ; then
 985         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION)
 986 fi
 987 if test $ol_enable_proctitle != no ; then
 988         AC_DEFINE(LDAP_PROCTITLE,1)
 989 fi
 990 if test $ol_enable_referrals != no ; then
 991         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION)
 992 fi
 993 if test $ol_enable_cldap != no ; then
 994         AC_DEFINE(LDAP_CONNECTIONLESS,1)
 995 fi
 996
 997 if test $ol_enable_aclgroups != no ; then
 998         AC_DEFINE(SLAPD_ACLGROUPS,1)
 999 fi
1000 if test $ol_enable_crypt != no ; then
1001         AC_DEFINE(SLAPD_CRYPT,1)
1002 fi
1003 if test $ol_enable_md5 != no ; then
1004         AC_DEFINE(SLAPD_MD5,1)
1005 fi
1006 if test $ol_enable_sha1 != no ; then
1007         AC_DEFINE(SLAPD_SHA1,1)
1008 fi
1009 if test $ol_enable_phonetic != no ; then
1010         AC_DEFINE(SLAPD_PHONETIC,1)
1011 fi
1012 if test $ol_enable_rlookups != no ; then
1013         AC_DEFINE(SLAPD_RLOOKUPS,1)
1014 fi
1015
1016 if test $ol_link_ldbm != no ; then
1017         AC_DEFINE(SLAPD_LDBM,1)
1018         BUILD_SLAPD=yes
1019         BUILD_LDBM=yes
1020 fi
1021
1022 if test $ol_enable_passwd != no ; then
1023         AC_DEFINE(SLAPD_PASSWD,1)
1024         BUILD_SLAPD=yes
1025         BUILD_PASSWD=yes
1026 fi
1027
1028 if test $ol_enable_shell != no ; then
1029         AC_DEFINE(SLAPD_SHELL,1)
1030         BUILD_SLAPD=yes
1031         BUILD_SHELL=yes
1032 fi
1033
1034 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1035         $BUILD_SLAPD = yes ; then
1036         BUILD_SLURPD=yes
1037 fi
1038
1039 if test $ol_link_isode != no ; then
1040         BUILD_LDAPD=yes
1041 fi
1042
1043 dnl ----------------------------------------------------------------
1044
1045 AC_SUBST(BUILD_LDAPD)
1046 AC_SUBST(BUILD_SLAPD)
1047   AC_SUBST(BUILD_LDBM)
1048   AC_SUBST(BUILD_PASSWD)
1049   AC_SUBST(BUILD_SHELL)
1050 AC_SUBST(BUILD_SLURPD)
1051
1052
1053 AC_SUBST(LDAP_LIBS)
1054 AC_SUBST(LDAPD_LIBS)
1055 AC_SUBST(SLAPD_LIBS)
1056 AC_SUBST(SLURPD_LIBS)
1057 AC_SUBST(LDBM_LIBS)
1058 AC_SUBST(LTHREAD_LIBS)
1059 AC_SUBST(LUTIL_LIBS)
1060
1061 AC_SUBST(KRB_LIBS)
1062 AC_SUBST(TERMCAP_LIBS)
1063
1064 dnl ----------------------------------------------------------------
1065 dnl final output
1066 dnl
1067
1068 AC_OUTPUT( \
1069 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1070 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1071 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1072 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1073 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1074 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1075 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1076 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1077 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1078 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1079 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1080 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1081 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1082 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1083 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1084 include/Makefile:build/top.mk:include/Makefile.in \
1085 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1086 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
1087 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
1088 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
1089 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
1090 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
1091 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
1092 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
1093 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1094 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1095 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1096 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1097 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1098 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1099 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1100 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1101 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1102 tests/Makefile:build/top.mk:tests/Makefile.in \
1103 ,[
1104 date > stamp-h
1105 echo Please \"make depend\" to build dependencies
1106 ])