git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 #OL_ARG_ENABLE(syslog,[  --enable-syslog        enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  28 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  29 OL_ARG_ENABLE(dns,[  --enable-dns       enable dns support], auto)dnl
  30 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  31 OL_ARG_ENABLE(cldap,[  --enable-clapd   enable connectionless ldap], no)dnl
  32
  33 dnl General "with" options
  34 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  35         auto, [auto k5 k4 afs yes no])
  36 OL_ARG_WITH(threads,[  --with-threads   use threads],
  37         auto, [auto posix dce mach yes no] )
  38
  39 dnl Server options
  40
  41 dnl LDAPD OPTIONS
  42 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  43
  44 dnl SLAPD OPTIONS
  45 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  46 OL_ARG_ENABLE(aclgroup,[    --enable-aclgroup   enable ACL group support], auto)dnl
  47 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  48 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  49 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  50 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  51 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  52 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  53
  54 dnl SLAPD Backend options
  55 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  56 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  57         [auto db2 db gdbm ndbm])
  58 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  59         [auto btree hash])
  60
  61 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  62 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  63
  64 dnl SLURPD OPTIONS
  65 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  66
  67 if test $ol_enable_slapd = no ; then
  68         dnl SLAPD was specificallly disabled
  69         if test $ol_enable_ldbm = yes ; then
  70                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument]);
  71         fi
  72         if test $ol_enable_passwd = yes ; then
  73                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument]);
  74         fi
  75         if test $ol_enable_shell = yes ; then
  76                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument]);
  77         fi
  78         if test $ol_enable_aclgroup = yes ; then
  79                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroup argument]);
  80         fi
  81         if test $ol_enable_crypt = yes ; then
  82                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument]);
  83         fi
  84         if test $ol_enable_md5 = yes ; then
  85                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument]);
  86         fi
  87         if test $ol_enable_sha1 = yes ; then
  88                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument]);
  89         fi
  90         if test $ol_enable_wrappers = yes ; then
  91                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument]);
  92         fi
  93         if test $ol_enable_phonetic = yes ; then
  94                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument]);
  95         fi
  96         if test $ol_enable_rlookups = yes ; then
  97                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument]);
  98         fi
  99         if test $ol_with_ldbm_api != auto ; then
 100                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument]);
 101         fi
 102         if test $ol_with_ldbm_type != auto ; then
 103                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument]);
 104         fi
 105         if test $ol_enable_slurpd = yes ; then
 106                 AC_MSG_ERROR([slurpd requires slapd]);
 107         fi
 108
 109         # force settings to no
 110         ol_enable_ldbm=no
 111         ol_enable_shell=no
 112         ol_enable_passwd=no
 113         ol_enable_aclgroup=no
 114         ol_enable_crypt=no
 115         ol_enable_md5=no
 116         ol_enable_sha1=no
 117         ol_enable_wrappers=no
 118         ol_enable_phonetic=no
 119         ol_enable_rlookups=no
 120         ol_with_ldbm_api=no
 121         ol_with_ldbm_type=no
 122         ol_enable_slurpd=no
 123
 124 elif test $ol_enable_ldbm = no ; then
 125         dnl SLAPD without LDBM
 126
 127         if test $ol_with_ldbm_api != auto ; then
 128                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument]);
 129         fi
 130
 131         if test $ol_with_ldbm_type != auto ; then
 132                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument]);
 133         fi
 134
 135         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 136                 AC_MSG_ERROR([slapd requires a backend]);
 137         fi
 138
 139         ol_with_ldbm_api=no
 140         ol_with_ldbm_type=no
 141
 142 else
 143         dnl SLAPD with LDBM
 144
 145         if test $ol_with_ldbm_api = gdbm -a \
 146                 $ol_with_ldbm_type = btree ; then
 147                 AC_MSG_ERROR([GDBM only supports LDBM type hash]);
 148         fi
 149         if test $ol_with_ldbm_api = ndbm -a \
 150                 $ol_with_ldbm_type = btree ; then
 151                 AC_MSG_ERROR([NDBM only supports LDBM type hash]);
 152         fi
 153 fi
 154
 155 if test $ol_enable_slurpd = yes ; then
 156         dnl SLURPD was specifically enabled
 157         if test $ol_with_threads = no ; then
 158                 AC_MSG_ERROR([slurpd requires threads]);
 159         fi
 160 fi
 161
 162 AC_MSG_RESULT(done)
 163
 164 ## Initialize vars
 165 LDAP_DEFS=
 166 LDAP_LIBS=
 167 LDBM_DEFS=
 168 LDBM_LIBS=
 169 LTHREAD_DEFS=
 170 LTHREAD_LIBS=
 171 LUTIL_DEFS=
 172 LUTIL_LIBS=
 173
 174 LDAPD_DEFS=
 175 LDAPD_LIBS=
 176 SLAPD_DEFS=
 177 SLAPD_LIBS=
 178 SLURPD_DEFS=
 179 SLURPD_LIBS=
 180
 181 BUILD_LDAPD=no
 182 BUILD_SLAPD=no
 183 BUILD_SLURPD=no
 184
 185 BUILD_LDBM=no
 186 BUILD_PASSWD=no
 187 BUILD_SHELL=no
 188
 189 dnl ----------------------------------------------------------------
 190 dnl Checks for programs
 191
 192 AC_PROG_CC
 193 AC_PROG_GCC_TRADITIONAL
 194
 195 AC_PROG_LN_S
 196 AC_PROG_INSTALL
 197 AC_PROG_RANLIB
 198 AC_PROG_MAKE_SET
 199
 200 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 201         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 202 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 203 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 204
 205 dnl ----------------------------------------------------------------
 206 dnl Checks for libraries
 207
 208 ol_link_threads=no
 209 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 210         AC_CHECK_HEADERS(pthread.h sched.h)
 211
 212         if test "$ac_cv_header_pthread_h" = yes ; then
 213                 OL_POSIX_THREAD_VERSION
 214
 215                 if test $ol_cv_pthread_version = final ; then
 216                         LTHREAD_DEFS="$LTHREAD_DEFS -DPOSIX_THREADS"
 217                 elif test $ol_cv_pthread_version = draft4 ; then
 218                         LTHREAD_DEFS="$LTHREAD_DEFS -DTHREAD_MIT_PTHREADS"
 219                 else
 220                         AC_MSG_ERROR([unknown pthread version])
 221                 fi
 222
 223                 # consider threads found
 224                 ol_with_threads="posix"
 225
 226                 OL_LINUX_THREADS
 227
 228                 if test $ol_cv_linux_threads = yes ; then
 229 dnl                     AC_DEFINE(HAVE_LINUX_THREADS,1)
 230                         LTHREAD_DEFS="$LTHREAD_DEFS -DHAVE_LINUX_THREADS"
 231                 fi
 232
 233                 dnl Now the hard part, how to link
 234
 235                 dnl A few platforms have pthread support in standard libraries
 236                 AC_CHECK_FUNC(pthread_create,ol_link_threads=yes)
 237
 238                 if test $ol_link_threads = no ; then
 239                         dnl try -pthread
 240                         AC_CACHE_CHECK([for pthread_create with -pthread],
 241                                 [ol_cv_pthread_flag], [
 242                                 dnl save the CPPFLAGS
 243                                 save_LIBS="$LIBS"
 244                                 LIBS="-pthread $LIBS"
 245                                 AC_TRY_LINK([#include <pthread.h>],[
 246                                         pthread_create((pthread_t*) 0,
 247                                                 (pthread_attr_t*) 0, 0, 0);
 248                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 249                                 dnl restore the LIBS
 250                                 LIBS="$save_LIBS"
 251                         ])
 252
 253                         if test $ol_cv_pthread_flag = yes ; then
 254                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 255                                 ol_link_threads=yes
 256                         fi
 257                 fi
 258
 259                 if test $ol_link_threads = no ; then
 260                         dnl try -lpthread
 261                         save_LIBS="$LIBS"
 262                         AC_CHECK_LIB(pthread, pthread_create, [
 263                                 ol_link_threads=yes
 264                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 265                         LIBS="$save_LIBS"
 266                 fi
 267
 268                 if test $ol_link_threads = no ; then
 269                         dnl try -lc_r
 270                         save_LIBS="$LIBS"
 271                         AC_CHECK_LIB(c_r, pthread_create, [
 272                                 ol_link_threads=yes
 273                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 274                         LIBS="$save_LIBS"
 275                 fi
 276
 277                 if test $ol_link_threads = no ; then
 278                         dnl try DEC Threads
 279                         save_LIBS="$LIBS"
 280                         AC_CHECK_LIB(pthread, pthread_create, [
 281                                 ol_link_threads=yes
 282                                 LTHREAD_DEFS="$LTHREAD_DEFS -DDEC_THREADS"
 283                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc"],,
 284                                 [-lmach -lexc -lc])
 285                         LIBS="$save_LIBS"
 286                 fi
 287
 288                 if test $ol_link_threads = no ; then
 289                         AC_MSG_ERROR([could not link with POSIX Threads])
 290                 fi
 291         elif test $ol_with_threads = posix ; then
 292                 AC_MSG_ERROR([could not locate POSIX Threads])
 293         fi
 294 fi
 295
 296 if test $ol_link_threads = no ; then
 297         if test $ol_with_threads = yes ; then
 298                 AC_MSG_ERROR([no suitable thread support])
 299         fi
 300
 301         if test $ol_with_threads = auto ; then
 302                 AC_MSG_WARN([no suitable thread support, disabling threads])
 303                 $ol_with_threads = no
 304         fi
 305
 306         LTHREAD_DEFS="-DNO_THREADS"
 307         LTHREAD_LIBS=""
 308 fi
 309
 310 dnl     # check for strtok_r (and presumely other reentrant functions)
 311 dnl     save_LIBS="$LIBS"
 312 dnl     LIBS="$save_LIBS $LTHREAD_LIBS"
 313 dnl     AC_CHECK_LIB(pthread,strtok_r)
 314 dnl
 315 dnl     if test $ac_cv_lib_pthread_strtok_r = no ; then
 316 dnl     LIBS="$save_LIBS $LTHREAD_LIBS"
 317 dnl     AC_CHECK_LIB(c_r,strtok_r)
 318 dnl     AC_CHECK_FUNCS(strtok_r sched_yield)
 319 dnl     if test $ac_cv_lib_c_r_strtok_r = yes ; then
 320 dnl             LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"
 321 dnl     fi
 322 dnl     else
 323 dnl     AC_CHECK_FUNCS(strtok_r sched_yield)
 324 dnl     fi
 325 dnl
 326 dnl     LIBS="$save_LIBS"
 327
 328
 329 ol_link_ldbm=no
 330 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 331         OL_BERKELEY_DB2
 332
 333         if test $ol_cv_berkeley_db2 = yes ; then
 334                 ol_link_ldbm=db2
 335                 ol_with_ldbm_api=db2
 336
 337                 LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_DB2"
 338
 339                 if test $ol_with_ldbm_type = hash ; then
 340                         LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_DBHASH"
 341                 else
 342                         LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_DBBTREE"
 343                 fi
 344
 345                 if test $ol_cv_lib_db2 != yes ; then
 346                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 347                 fi
 348         fi
 349 fi
 350
 351 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 352         OL_BERKELEY_DB
 353
 354         if test $ol_cv_berkeley_db = yes ; then
 355                 ol_link_ldbm=db
 356                 ol_with_ldbm_api=db
 357
 358                 if test $ac_cv_header_db_185_h = yes ; then
 359                         LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_DB2_COMPAT185"
 360                 fi
 361
 362                 if test $ol_with_ldbm_type = hash ; then
 363                         LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_DBHASH"
 364                 else
 365                         LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_DBBTREE"
 366                 fi
 367
 368                 if test $ol_cv_lib_db != yes ; then
 369                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 370                 fi
 371         fi
 372 fi
 373
 374 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 375         AC_MSG_WARN(Could not find LDBM with BTREE support);
 376         $ol_with_ldbm_api=none
 377 fi
 378
 379 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 380         OL_GDBM
 381
 382         if test $ol_cv_gdbm = yes ; then
 383                 ol_link_ldbm=gdbm
 384                 ol_with_ldbm_api=gdbm
 385
 386                 LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_GDBM"
 387
 388                 if test $ol_cv_lib_db != yes ; then
 389                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 390                 fi
 391         fi
 392 fi
 393
 394 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 395         OL_NDBM
 396
 397         if test $ol_cv_ndbm = yes ; then
 398                 ol_link_ldbm=ndbm
 399                 ol_with_ldbm_api=ndbm
 400
 401                 if test $ol_with_ldbm_api = ndbm ; then
 402                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 403                 fi
 404
 405                 LDBM_DEFS="$LDBM_DEFS -DLDBM_USE_NDBM"
 406
 407                 if test $ol_cv_lib_db != yes ; then
 408                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 409                 fi
 410         fi
 411 fi
 412
 413 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 414         AC_MSG_WARN(could not find suitable LDBM backend)
 415         if test $ol_enable_ldbm = yes ; then
 416                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 417         fi
 418
 419         AC_MSG_WARN(disabling LDBM)
 420         $ol_enable_ldbm=no
 421 fi
 422
 423 if test $ol_enable_wrappers = yes ; then
 424         AC_CHECK_LIB(wrap, hosts_access,
 425                 [have_wrappers=yes], [have_wrappers=no])
 426
 427         if test $have_wrappers = yes ; then
 428 dnl             LIBTCPD="-lwrap"
 429 dnl             AC_DEFINE(HAVE_TCPD)
 430                 SLAPD_DEFS="$SLAPD_DEFS -DTCP_WRAPPERS"
 431                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 432         else
 433                 AC_MSG_WARN(could not find -lwrap)
 434                 if test $ol_enable_wrappers = yes ; then
 435                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 436                 fi
 437
 438                 AC_MSG_WARN(disabling wrappers support)
 439                 ol_enable_wrappers=no
 440         fi
 441
 442 fi
 443
 444 # ud needs termcap (should insert check here)
 445 LIBTERMCAP="-ltermcap"
 446 AC_SUBST(LIBTERMCAP)
 447
 448 # FreeBSD (and others) have crypt(3) in -lcrypt
 449 if test $ol_enable_crypt != no ; then
 450         AC_CHECK_FUNC(crypt, have_crypt=yes, [
 451                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 452                         have_crypt=yes], [have_crypt=no])])
 453
 454         if test $have_crypt = yes ; then
 455 dnl             AC_DEFINE(SLAPD_CRYPT,1)
 456                 LUTIL_DEFS="$LUTIL_DEFS -DLDAP_CRYPT"
 457         else
 458                 AC_MSG_WARN(could not find crypt)
 459                 if test $ol_enable_crypt = yes ; then
 460                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 461                 fi
 462
 463                 AC_MSG_WARN(disabling crypt support)
 464                 ol_enable_crypt=no
 465         fi
 466 fi
 467
 468 dnl ----------------------------------------------------------------
 469 dnl Checks for header files.
 470 AC_HEADER_DIRENT
 471 AC_HEADER_STDC
 472 AC_HEADER_SYS_WAIT
 473 AC_CHECK_HEADERS( \
 474         stddef.h        \
 475         fcntl.h         \
 476         limits.h        \
 477         malloc.h        \
 478         sgtty.h         \
 479         sys/file.h      \
 480         sys/ioctl.h     \
 481         sys/time.h      \
 482         syslog.h        \
 483         termio.h        \
 484         unistd.h        \
 485 )
 486
 487 dnl ----------------------------------------------------------------
 488 dnl Checks for typedefs, structures, and compiler characteristics.
 489 AC_TYPE_GETGROUPS
 490 AC_TYPE_MODE_T
 491 AC_TYPE_OFF_T
 492 AC_TYPE_PID_T
 493 AC_TYPE_SIGNAL
 494 AC_TYPE_SIZE_T
 495 AC_TYPE_UID_T
 496 AC_STRUCT_ST_BLKSIZE
 497 AC_HEADER_TIME
 498 AC_STRUCT_TM
 499
 500 dnl AC_C_BIGENDIAN
 501 AC_C_CONST
 502
 503 dnl ----------------------------------------------------------------
 504 dnl Checks for library functions.
 505 AC_FUNC_MEMCMP
 506 AC_TYPE_SIGNAL
 507 AC_FUNC_STRFTIME
 508 AC_FUNC_VPRINTF
 509 AC_FUNC_WAIT3
 510
 511 AC_CHECK_FUNCS(         \
 512         gethostname             \
 513         gettimeofday    \
 514         mktime                  \
 515         select                  \
 516         socket                  \
 517         strdup                  \
 518         strerror                \
 519         strstr                  \
 520         strrchr                 \
 521         strtod                  \
 522         strtol                  \
 523         strtoul                 \
 524         strsep                  \
 525         memcpy                  \
 526 )
 527
 528 AC_REPLACE_FUNCS(strdup)
 529
 530 dnl ----------------------------------------------------------------
 531 # Check Configuration
 532 OL_SYS_ERRLIST
 533
 534 dnl ----------------------------------------------------------------
 535 dnl Sort out defines
 536
 537 if test $ol_enable_debug != no ; then
 538         LDAP_DEFS="$LDAP_DEFS -DLDAP_DEBUG"
 539 fi
 540 #if test $ol_enable_syslog != no ; then
 541 #       LDAP_DEFS="$LDAP_DEFS -DLDAP_SYSLOG"
 542 #fi
 543 if test $ol_enable_libui = no ; then
 544         LDAP_DEFS="$LDAP_DEFS -DNO_USERINTERFACE"
 545 fi
 546 if test $ol_enable_cache = no ; then
 547         LDAP_DEFS="$LDAP_DEFS -DNO_CACHE"
 548 fi
 549 if test $ol_enable_dns != no ; then
 550         LDAP_DEFS="$LDAP_DEFS -DLDAP_DNS"
 551 fi
 552 if test $ol_enable_referrals != no ; then
 553         LDAP_DEFS="$LDAP_DEFS -DLDAP_REFERRALS"
 554 fi
 555 if test $ol_enable_cldap != no ; then
 556         LDAP_DEFS="$LDAP_DEFS -DCLDAP"
 557 fi
 558
 559 if test $ol_enable_aclgroup != no ; then
 560         AC_DEFINE(SLAPD_ACLGROUP,1)
 561         SLAPD_DEFS="$SLAPD_DEFS -DACLGROUP"
 562 fi
 563
 564 if test $ol_enable_md5 != no ; then
 565 dnl     AC_DEFINE(SLAPD_MD5,1)
 566         LUTIL_DEFS="$LUTIL_DEFS -DLDAP_MD5"
 567 fi
 568
 569 if test $ol_enable_sha1 != no ; then
 570 dnl     AC_DEFINE(SLAPD_SHA1,1)
 571         LUTIL_DEFS="$LUTIL_DEFS -DLDAP_SHA1"
 572 fi
 573
 574 if test $ol_enable_phonetic != no ; then
 575         AC_DEFINE(SLAPD_PHONETIC,1)
 576         SLAPD_DEFS="$SLAPD_DEFS -DSOUNDEX"
 577 fi
 578
 579 if test $ol_enable_rlookups != no ; then
 580         AC_DEFINE(SLAPD_RLOOKUPS,1)
 581         SLAPD_DEFS="$SLAPD_DEFS -DREVERSE_LOOKUPS"
 582 fi
 583
 584 if test $ol_link_ldbm != no ; then
 585 dnl     AC_DEFINE(SLAPD_LDBM,1)
 586         BUILD_SLAPD=yes
 587         BUILD_LDBM=yes
 588         LDBM_DEFS="-DLDAP_LDBM $LDBM_DEFS"
 589 fi
 590
 591 if test $ol_enable_passwd != no ; then
 592 dnl     AC_DEFINE(SLAPD_PASSWD,1)
 593         BUILD_SLAPD=yes
 594         BUILD_PASSWD=yes
 595         SLAPD_DEFS="-DLDAP_PASSWD $SLAPD_DEFS"
 596 fi
 597
 598 if test $ol_enable_shell != no ; then
 599 dnl     AC_DEFINE(SLAPD_SHELL,1)
 600         BUILD_SLAPD=yes
 601         BUILD_SHELL=yes
 602         SLAPD_DEFS="-DLDAP_SHELL $SLAPD_DEFS"
 603 fi
 604
 605 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
 606         $BUILD_SLAPD = yes ; then
 607         BUILD_SLURPD=yes
 608 fi
 609
 610 dnl ----------------------------------------------------------------
 611
 612 AC_SUBST(BUILD_LDAPD)
 613 AC_SUBST(BUILD_SLAPD)
 614   AC_SUBST(BUILD_LDBM)
 615   AC_SUBST(BUILD_PASSWD)
 616   AC_SUBST(BUILD_SHELL)
 617 AC_SUBST(BUILD_SLURPD)
 618
 619
 620 AC_SUBST(LDAP_DEFS)
 621 AC_SUBST(LDAP_LIBS)
 622 AC_SUBST(LDAPD_DEFS)
 623 AC_SUBST(LDAPD_LIBS)
 624 AC_SUBST(SLAPD_DEFS)
 625 AC_SUBST(SLAPD_LIBS)
 626 AC_SUBST(SLURPD_DEFS)
 627 AC_SUBST(SLURPD_LIBS)
 628 AC_SUBST(LDBM_DEFS)
 629 AC_SUBST(LDBM_LIBS)
 630 AC_SUBST(LTHREAD_DEFS)
 631 AC_SUBST(LTHREAD_LIBS)
 632 AC_SUBST(LUTIL_DEFS)
 633 AC_SUBST(LUTIL_LIBS)
 634
 635 dnl ----------------------------------------------------------------
 636 dnl final output
 637 dnl
 638
 639 dnl AC_OUTPUT( \
 640 dnl contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
 641 dnl contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
 642 dnl contrib/whois++/Makefile:build/top.mk:contrib/whois++/Makefile.in:build/rules.mk \
 643 dnl [date > stamp-h])
 644
 645 AC_OUTPUT( \
 646 Makefile:build/top.mk:Makefile.in:build/dir.mk \
 647 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
 648 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
 649 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
 650 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
 651 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
 652 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
 653 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
 654 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
 655 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
 656 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
 657 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
 658 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
 659 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
 660 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
 661 include/Makefile:build/top.mk:include/Makefile.in \
 662 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
 663 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
 664 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
 665 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
 666 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
 667 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
 668 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
 669 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
 670 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
 671 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
 672 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
 673 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
 674 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
 675 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
 676 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
 677 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
 678 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
 679 tests/Makefile:build/top.mk:tests/Makefile.in \
 680 ,[date > stamp-h])