git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  14
  15 dnl We use autoconf features new to 2.13.
  16 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  17 AC_PREREQ(2.13)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 ol_enable_syslog=no
  43 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  44 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  54
  55 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  56         auto, [auto k5 k4 afs yes no])
  57 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  58         auto, [auto yes no] )
  59 OL_ARG_WITH(threads,[  --with-threads   use threads],
  60         auto, [auto posix mach lwp yes no manual] )
  61 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  62         auto, [auto ssleay openssl yes no] )
  63 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  64         auto, [auto yes no manual] )
  65
  66 dnl Server options
  67
  68 dnl LDAPD OPTIONS
  69 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  70 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  71
  72 dnl SLAPD OPTIONS
  73 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  74 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  75 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  76 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  77 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  78 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  79 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  80 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  81
  82 dnl SLAPD Backend options
  83 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  84 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  85 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  86         [auto db2 db gdbm ndbm manual])
  87 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  88         [auto btree hash])
  89
  90 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  91 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
  92 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  93 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
  94
  95 dnl SLURPD OPTIONS
  96 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  97 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  98
  99 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 100 AM_ENABLE_STATIC
 101 dnl AM_DISABLE_SHARED
 102 AM_ENABLE_SHARED
 103
 104 dnl General "enable" options
 105 # validate options
 106 if test $ol_enable_dns = yes ; then
 107         if test $ol_enable_referrals = no ; then
 108                 AC_MSG_ERROR([DNS requires --enable-referrals])
 109         fi
 110         if test $ol_enable_referrals = auto ; then
 111                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 112                 ol_enable_referrals=yes
 113         fi
 114 fi
 115
 116 if test $ol_enable_slapd = no ; then
 117         dnl SLAPD was specificallly disabled
 118         if test $ol_enable_bdb2 = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 120         fi
 121         if test $ol_enable_ldbm = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 123         fi
 124         if test $ol_enable_passwd = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 126         fi
 127         if test $ol_enable_perl = yes ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 129         fi
 130         if test $ol_enable_shell = yes ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 132         fi
 133         if test $ol_enable_tcl = yes ; then
 134                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 135         fi
 136         if test $ol_enable_aclgroups = yes ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 138         fi
 139         if test $ol_enable_wrappers = yes ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 141         fi
 142         if test $ol_enable_phonetic = yes ; then
 143                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 144         fi
 145         if test $ol_enable_rlookups = yes ; then
 146                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 147         fi
 148         if test $ol_with_ldbm_api != auto ; then
 149                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 150         fi
 151         if test $ol_with_ldbm_type != auto ; then
 152                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 153         fi
 154         if test $ol_enable_slurpd = yes ; then
 155                 AC_MSG_ERROR([slurpd requires slapd])
 156         fi
 157
 158         # force settings to no
 159         ol_enable_bdb2=no
 160         ol_enable_ldbm=no
 161         ol_enable_passwd=no
 162         ol_enable_perl=no
 163         ol_enable_shell=no
 164         ol_enable_tcl=no
 165         ol_enable_aclgroups=no
 166         ol_enable_wrappers=no
 167         ol_enable_phonetic=no
 168         ol_enable_rlookups=no
 169         ol_with_ldbm_api=no
 170         ol_with_ldbm_type=no
 171         ol_enable_slurpd=no
 172
 173 elif test $ol_enable_ldbm = no ; then
 174         dnl SLAPD without LDBM
 175
 176         if test $ol_with_ldbm_api != auto ; then
 177                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 178         fi
 179
 180         if test $ol_with_ldbm_type != auto ; then
 181                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 182         fi
 183
 184         if test $ol_enable_bdb2 = yes ; then
 185                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 186         fi
 187
 188         if test $ol_enable_passwd = no -a \
 189                 $ol_enable_perl = no -a \
 190                 $ol_enable_shell = no -a \
 191                 $ol_enable_tcl = no ; then
 192                 AC_MSG_ERROR([slapd requires a backend])
 193         fi
 194
 195         ol_with_ldbm_api=no
 196         ol_with_ldbm_type=no
 197
 198 elif test $ol_enable_bdb2 = yes ; then
 199         dnl SLAPD with BDB2
 200
 201         if test $ol_with_ldbm_api != auto -a \
 202                 $ol_with_ldbm_api != db2 ; then
 203                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 204         fi
 205
 206         ol_with_ldbm_api=db2
 207
 208 else
 209         dnl SLAPD with LDBM
 210
 211         if test $ol_enable_bdb2 != no ; then
 212                 if test $ol_with_ldbm_api != auto -a \
 213                         $ol_with_ldbm_api != db2 ; then
 214                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 215                         ol_enable_bdb2=no
 216                 fi
 217         fi
 218
 219         if test $ol_with_ldbm_api = gdbm -a \
 220                 $ol_with_ldbm_type = btree ; then
 221                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 222         fi
 223         if test $ol_with_ldbm_api = ndbm -a \
 224                 $ol_with_ldbm_type = btree ; then
 225                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 226         fi
 227 fi
 228
 229 if test $ol_enable_slurpd = yes ; then
 230         dnl SLURPD was specifically enabled
 231         if test $ol_with_threads = no ; then
 232                 AC_MSG_ERROR([slurpd requires threads])
 233         fi
 234 fi
 235
 236 AC_MSG_RESULT(done)
 237
 238 AC_CANONICAL_HOST
 239
 240 ## Initialize vars
 241 LDAP_LIBS=
 242 LDBM_LIBS=
 243 LTHREAD_LIBS=
 244 LUTIL_LIBS=
 245
 246 LDAPD_LIBS=
 247 SLAPD_LIBS=
 248 SLURPD_LIBS=
 249
 250 BUILD_LDAPD=no
 251 BUILD_SLAPD=no
 252 BUILD_SLURPD=no
 253
 254 BUILD_BDB2=no
 255 BUILD_LDBM=no
 256 BUILD_PASSWD=no
 257 BUILD_PERL=no
 258 BUILD_SHELL=no
 259 BUILD_TCL=no
 260 BUILD_THREAD=no
 261
 262 SLAPD_PERL_LDFLAGS=
 263 SLAPD_PERL_CPPFLAGS=
 264
 265 KRB_LIBS=
 266 READLINE_LIBS=
 267 TERMCAP_LIBS=
 268 TLS_LIBS=
 269
 270 dnl ----------------------------------------------------------------
 271 dnl Checks for programs
 272
 273 AC_PROG_INSTALL
 274
 275 dnl The default compiler is cc (NOT gcc)
 276 CC=${CC-"cc"}
 277 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 278 CFLAGS=${CFLAGS-""}
 279
 280 AM_PROG_LIBTOOL
 281 dnl AC_PROG_MAKE_SET
 282
 283 AC_PROG_AWK
 284 AC_PROG_LN_S
 285
 286 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 287         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 288 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 289 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 290
 291 if test $ol_enable_perl = yes ; then
 292         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 293
 294         if test "no$PERLBIN" = "no" ; then
 295                 ol_enable_perl=no
 296         fi
 297
 298         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 299         SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e perl_inc`"
 300 fi
 301
 302 AC_PROG_CPP
 303
 304 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 305         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 306
 307 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 308         AC_MSG_WARN([programs compiled here do run here...])
 309         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 310
 311 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 312         AC_MSG_WARN([programs compiled here do not run here...])
 313         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 314 fi
 315
 316 dnl Checks for UNIX Variants
 317 AC_AIX
 318 AC_ISC_POSIX
 319 AC_MINIX
 320
 321 dnl Checks for system services
 322 AC_CYGWIN
 323 AC_MINGW32
 324 AC_EXEEXT
 325 AC_OBJEXT
 326
 327 dnl OpenLDAP requires STDC features
 328 AM_PROG_CC_STDC
 329 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 330         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 331 fi
 332
 333 dnl AM_C_PROTOTYPES
 334
 335 dnl Checks for libraries
 336
 337 dnl Find socket()
 338 dnl Likely combinations:
 339 dnl             -lsocket [ -lnsl_s | -lnsl ]
 340 dnl             -linet
 341
 342 AC_CHECK_FUNC(socket, [have_socket=yes], [
 343 dnl
 344 dnl hopefully we won't include too many libraries
 345 dnl
 346         AC_CHECK_LIB(socket, main)
 347         AC_CHECK_LIB(net, main)
 348         AC_CHECK_LIB(nsl_s, main)
 349         AC_CHECK_LIB(nsl, main)
 350         AC_CHECK_LIB(inet, socket)
 351         AC_CHECK_LIB(gen, main)
 352 ])
 353
 354 dnl Check for resolver routines
 355 AC_CHECK_FUNCS(res_search)
 356 if test $ac_cv_func_res_search = "no" ; then
 357         AC_CHECK_LIB(bind, res_search)
 358         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 359                 AC_DEFINE(HAVE_RES_SEARCH,1)
 360         else
 361                 AC_CHECK_LIB(resolv, res_search)
 362                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 363                         AC_DEFINE(HAVE_RES_SEARCH,1)
 364                 fi
 365         fi
 366 fi
 367
 368 dnl HP-UX requires -lV3
 369 AC_CHECK_LIB(V3, sigset)
 370
 371 # ISODE tests
 372 ol_link_isode=no
 373 if test $ol_enable_ldapd != no ; then
 374         dnl look for ISODE libraries
 375         AC_CHECK_LIB(xtpp, main, [
 376                 ol_link_isode=yes
 377                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 378                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 379                 ],:,[-lxtdsap -lxtisode -losi])
 380         AC_CHECK_LIB(dsap, main, [
 381                 ol_link_isode=yes
 382                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 383                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 384                 ],:,[-lisode])
 385         AC_CHECK_LIB(isode, main, [
 386                 ol_link_isode=yes
 387                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 388                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 389                 ],:)
 390 fi
 391
 392 if test $ol_link_isode != no; then
 393         AC_CHECK_LIB(pp, main, [
 394                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 395                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 396                 ],:)
 397
 398         AC_PATH_PROG(PEPSY, pepsy)
 399 fi
 400
 401 dnl
 402 dnl check for kerberos
 403 dnl
 404 ol_link_kerberos=no
 405
 406 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 407         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 408
 409         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 410                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 411                         [-lkrb5 -ldes425])
 412
 413                 if test $have_k5 = yes ; then
 414                         ol_with_kerberos=found
 415                         ol_link_kerberos=yes
 416
 417                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 418
 419                         LIBS="$KRB_LIBS $LIBS"
 420
 421                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 422                                 [ol_cv_var_des_debug], [
 423                                 dnl save the flags
 424                                 save_LIBS="$LIBS"
 425                                 LIBS="$KRB_LIBS $LIBS"
 426                                 AC_TRY_LINK([
 427 #include <kerberosIV/krb.h>
 428 #include <kerberosIV/des.h>
 429 extern int des_debug;
 430 ],[
 431 des_debug = 1;
 432 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 433                                 dnl restore the LIBS
 434                                 LIBS="$save_LIBS"
 435                         ])
 436
 437                         if test $ol_cv_var_des_debug= yes ; then
 438                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 439                                         [define if you have Kerberos des_debug])
 440                         fi
 441
 442                         LIBS="$save_LIBS"
 443                 fi
 444         fi
 445 fi
 446
 447 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 448         AC_CHECK_HEADERS(krb.h des.h)
 449
 450         if test $ac_cv_header_krb_h = yes ; then
 451                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 452
 453                 if test $have_k4 = yes ; then
 454                         ol_with_kerberos=found
 455                         ol_link_kerberos=yes
 456
 457                         KRB_LIBS="-lkrb -ldes"
 458                 fi
 459         fi
 460 fi
 461
 462 if test $ol_link_kerberos = yes ; then
 463         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 464 fi
 465
 466 dnl
 467 dnl Check for GNU readline
 468 dnl
 469 ol_link_readline=no
 470 if test $ol_with_readline != no ; then
 471         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
 472
 473         if test $ac_cv_header_readline_readline_h = yes ; then
 474                 AC_CHECK_LIB(readline, readline,
 475                         [have_readline=yes], [have_readline=no])
 476
 477                 if test $have_readline = yes ; then
 478                         ol_with_readline=found
 479                         ol_link_readline=yes
 480
 481                         READLINE_LIBS="-lreadline"
 482                 fi
 483         fi
 484 fi
 485
 486 if test $ol_link_readline = yes ; then
 487         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
 488 fi
 489
 490 dnl
 491 dnl Check for SSL/TLS
 492 dnl
 493 ol_link_tls=no
 494 if test $ol_with_tls != no ; then
 495
 496         AC_CHECK_HEADERS(ssl.h)
 497
 498         if test $ac_cv_header_ssl_h = yes ; then
 499                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 500                         [have_ssleay=yes
 501                         need_rsaref=no],
 502                         [have_ssleay=no],
 503                         [-lcrypto])
 504
 505                 if test $have_ssleay = no ; then
 506                         AC_CHECK_LIB(ssl, ssl3_accept,
 507                                 [have_ssleay=yes
 508                                 need_rsaref=yes], [have_ssleay=no],
 509                                 [-lcrypto -lRSAglue -lrsaref])
 510                 fi
 511
 512                 if test $have_ssleay = yes ; then
 513                         ol_with_tls=found
 514                         ol_link_tls=yes
 515
 516                         AC_DEFINE(HAVE_SSLEAY, 1,
 517                                 [define if you have SSLeay or OpenSSL])
 518
 519                         if test $need_rsaref = yes; then
 520                                 AC_DEFINE(HAVE_RSAREF, 1,
 521                                         [define if you have RSAref])
 522
 523                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 524                         else
 525                                 TLS_LIBS="-lssl -lcrypto"
 526                         fi
 527                 fi
 528         fi
 529 fi
 530
 531 if test $ol_link_tls = yes ; then
 532         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 533 fi
 534
 535 dnl Tests for reentrant functions necessary to build a
 536 dnl thread_safe -lldap.
 537 AC_CHECK_FUNCS(         \
 538         ctime_r                 \
 539         gethostbyname_r gethostbyaddr_r \
 540 )
 541
 542 if test "$ac_cv_func_ctime_r" = no ; then
 543         ol_cv_func_ctime_r_nargs=0
 544 else
 545         OL_FUNC_CTIME_R_NARGS
 546 dnl     OL_FUNC_CTIME_R_TYPE
 547 fi
 548
 549 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 550         OL_FUNC_GETHOSTBYNAME_R_NARGS
 551 else
 552         ol_cv_func_gethostbyname_r_nargs=0
 553 fi
 554
 555 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 556         OL_FUNC_GETHOSTBYADDR_R_NARGS
 557 else
 558         ol_cv_func_gethostbyaddr_r_nargs=0
 559 fi
 560
 561 if test "$ac_cv_func_ctime_r" = yes \
 562         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 563         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 564         -a "$ac_cv_func_gethostbyname_r" = yes \
 565         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 566         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 567         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 568         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 569         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 570         ; then
 571
 572         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 573 fi
 574
 575 ol_link_threads=no
 576 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 577         -o $ol_with_threads = posix ; then
 578
 579         AC_CHECK_HEADERS(pthread.h sched.h)
 580
 581         if test $ac_cv_header_pthread_h = yes ; then
 582                 OL_POSIX_THREAD_VERSION
 583
 584                 if test $ol_cv_pthread_version = final ; then
 585                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 586                                 [define if pthreads API compatible with final spec])
 587                 elif test $ol_cv_pthread_version = draft4 ; then
 588                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 589                                 [define if pthreads API compatible with draft4 spec])
 590                 else
 591                         AC_MSG_ERROR([unknown pthread version])
 592                 fi
 593
 594                 # consider threads found
 595                 ol_with_threads=found
 596
 597                 OL_LINUX_THREADS
 598
 599                 if test $ol_cv_linux_threads = yes ; then
 600                         AC_DEFINE(HAVE_LINUX_THREADS,1,
 601                                 [define if you have LinuxThreads])
 602                 fi
 603
 604                 dnl Now the hard part, how to link?
 605                 dnl
 606                 dnl currently supported checks:
 607                 dnl
 608                 dnl Check for no flags
 609                 dnl     pthread_create() in $LIBS
 610                 dnl
 611                 dnl Check special pthread (final) flags
 612                 dnl     pthread_create() with -kthread (FreeBSD)
 613                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 614                 dnl     pthread_create() with -pthreads (?)
 615                 dnl     pthread_create() with -thread (?)
 616                 dnl     pthread_create() with -mt (Solaris)
 617                 dnl
 618                 dnl Check pthread (final) libraries
 619                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 620                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 621                 dnl     pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 622                 dnl     pthread_create() in -lpthread (many)
 623                 dnl     pthread_create() in -lc_r (FreeBSD)
 624                 dnl     pthread_create() in -lpthreads (many)
 625                 dnl     pthread_join() -Wl,-woff,85 -lpthreads (IRIX)
 626                 dnl
 627                 dnl Check pthread (draft4) flags (depreciated)
 628                 dnl     pthread_create() with -threads (OSF/1)
 629                 dnl
 630                 dnl Check pthread (final) libraries (depreciated)
 631                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 632                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 633                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 634                 dnl
 635
 636                 dnl pthread_create in $LIBS
 637                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 638
 639                 if test $ol_link_threads = no ; then
 640                         dnl try -kthread
 641                         AC_CACHE_CHECK([for pthread_create with -kthread],
 642                                 [ol_cv_kthread_flag], [
 643                                 dnl save the flags
 644                                 save_LIBS="$LIBS"
 645                                 LIBS="-kthread $LIBS"
 646                                 AC_TRY_LINK([#include <pthread.h>],[
 647 #if HAVE_PTHREADS_D4
 648         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 649 #else
 650         pthread_create(NULL,NULL,NULL,NULL);
 651 #endif
 652 ],
 653                                         [ol_cv_kthread_flag=yes], [ol_cv_kthread_flag=no])
 654                                 dnl restore the LIBS
 655                                 LIBS="$save_LIBS"
 656                         ])
 657
 658                         if test $ol_cv_kthread_flag = yes ; then
 659                                 LTHREAD_LIBS="$LTHREAD_LIBS -kthread"
 660                                 ol_link_threads=posix
 661                         fi
 662                 fi
 663
 664                 if test $ol_link_threads = no ; then
 665                         dnl try -pthread
 666                         AC_CACHE_CHECK([for pthread_create with -pthread],
 667                                 [ol_cv_pthread_flag], [
 668                                 dnl save the flags
 669                                 save_LIBS="$LIBS"
 670                                 LIBS="-pthread $LIBS"
 671                                 AC_TRY_LINK([#include <pthread.h>],[
 672 #if HAVE_PTHREADS_D4
 673         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 674 #else
 675         pthread_create(NULL,NULL,NULL,NULL);
 676 #endif
 677 ],
 678                                         [ol_cv_pthread_flag=yes], [ol_cv_pthread_flag=no])
 679                                 dnl restore the LIBS
 680                                 LIBS="$save_LIBS"
 681                         ])
 682
 683                         if test $ol_cv_pthread_flag = yes ; then
 684                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 685                                 ol_link_threads=posix
 686                         fi
 687                 fi
 688
 689                 if test $ol_link_threads = no ; then
 690                         dnl try -pthreads
 691                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 692                                 [ol_cv_pthreads_flag], [
 693                                 dnl save the flags
 694                                 save_LIBS="$LIBS"
 695                                 LIBS="-pthreads $LIBS"
 696                                 AC_TRY_LINK([#include <pthread.h>],[
 697 #if HAVE_PTHREADS_D4
 698         pthread_create(NULL,pthread_attr_default,NULL,NULL);
 699 #else
 700         pthread_create(NULL,NULL,NULL,NULL);
 701 #endif
 702 ],
 703                                         [ol_cv_pthreads_flag=yes], [ol_cv_pthreads_flag=no])
 704                                 dnl restore the LIBS
 705                                 LIBS="$save_LIBS"
 706                         ])
 707
 708                         if test $ol_cv_pthreads_flag = yes ; then
 709                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 710                                 ol_link_threads=posix
 711                         fi
 712                 fi
 713
 714                 if test $ol_link_threads = no ; then
 715                         dnl try -thread
 716                         AC_CACHE_CHECK([for pthread_create with -thread],
 717                                 [ol_cv_thread_flag], [
 718                                 dnl save the flags
 719                                 save_LIBS="$LIBS"
 720                                 LIBS="-thread $LIBS"
 721                                 AC_TRY_LINK([char pthread_create();],
 722                                         [pthread_create();],
 723                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 724                                 dnl restore the LIBS
 725                                 LIBS="$save_LIBS"
 726                         ])
 727
 728                         if test $ol_cv_thread_flag = yes ; then
 729                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 730                                 ol_link_threads=posix
 731                         fi
 732                 fi
 733
 734                 if test $ol_link_threads = no ; then
 735                         dnl try -mt
 736                         AC_CACHE_CHECK([for pthread_create with -mt],
 737                                 [ol_cv_thread_flag], [
 738                                 dnl save the flags
 739                                 save_LIBS="$LIBS"
 740                                 LIBS="-mt $LIBS"
 741                                 AC_TRY_LINK([char pthread_create();],
 742                                         [pthread_create();],
 743                                         [ol_cv_thread_flag=yes], [ol_cv_thread_flag=no])
 744                                 dnl restore the LIBS
 745                                 LIBS="$save_LIBS"
 746                         ])
 747
 748                         if test $ol_cv_thread_flag = yes ; then
 749                                 LTHREAD_LIBS="$LTHREAD_LIBS -mt"
 750                                 ol_link_threads=posix
 751                         fi
 752                 fi
 753
 754                 if test $ol_link_threads = no ; then
 755                         dnl try DEC Threads -lpthread -lmach -lexc -lc_r
 756                         save_LIBS="$LIBS"
 757                         AC_CHECK_LIB(pthread, pthread_mutex_unlock, [
 758                                 ol_link_threads=posix
 759                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc_r"
 760                                 if test $ol_with_yielding_select = auto ; then
 761                                         ol_with_yielding_select=yes
 762                                 fi
 763                                 ],:,[-lmach -lexc -lc_r])
 764                         LIBS="$save_LIBS"
 765                 fi
 766
 767                 if test $ol_link_threads = no ; then
 768                         dnl try DEC Threads -lpthread -lmach -lexc
 769                         save_LIBS="$LIBS"
 770                         AC_CHECK_LIB(pthread, pthread_mutex_lock, [
 771                                 ol_link_threads=posix
 772                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc"
 773                                 if test $ol_with_yielding_select = auto ; then
 774                                         ol_with_yielding_select=yes
 775                                 fi
 776                                 ],:,[-lmach -lexc])
 777                         LIBS="$save_LIBS"
 778                 fi
 779
 780                 if test $ol_link_threads = no ; then
 781                         dnl try DEC Threads -lpthread -lexc
 782                         save_LIBS="$LIBS"
 783                         AC_CHECK_LIB(pthread, pthread_mutex_trylock, [
 784                                 ol_link_threads=posix
 785                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 786                                 if test $ol_with_yielding_select = auto ; then
 787                                         ol_with_yielding_select=yes
 788                                 fi
 789                                 ],:,[-lexc])
 790                         LIBS="$save_LIBS"
 791                 fi
 792
 793                 if test $ol_link_threads = no ; then
 794                         dnl try -lpthread
 795                         save_LIBS="$LIBS"
 796                         AC_CHECK_LIB(pthread, pthread_create, [
 797                                 ol_link_threads=posix
 798                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"],:)
 799                         LIBS="$save_LIBS"
 800                 fi
 801
 802                 if test $ol_link_threads = no ; then
 803                         dnl try -lc_r
 804                         save_LIBS="$LIBS"
 805                         AC_CHECK_LIB(c_r, pthread_create, [
 806                                 ol_link_threads=posix
 807                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"],:)
 808                         LIBS="$save_LIBS"
 809                 fi
 810
 811                 if test $ol_link_threads = no ; then
 812                         dnl try -lpthreads
 813                         save_LIBS="$LIBS"
 814                         AC_CHECK_LIB(pthreads, pthread_create, [
 815                                 ol_link_threads=posix
 816                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"],:)
 817                         LIBS="$save_LIBS"
 818                 fi
 819
 820                 dnl IRIX Pthread check
 821                 if test $ol_link_threads = no ; then
 822                         dnl try IRIX Pthreads -Wl,-woff,85 -lpthreads
 823                         save_LIBS="$LIBS"
 824                         AC_CHECK_LIB(pthreads, pthread_join, [
 825                                 ol_link_threads=posix
 826                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads"
 827                                 ],:,[-Wl,-woff,85])
 828                         LIBS="$save_LIBS"
 829                 fi
 830
 831                 if test $ol_link_threads = no ; then
 832                         dnl try -threads
 833                         AC_CACHE_CHECK([for pthread_create with -threads],
 834                                 [ol_cv_thread_flag], [
 835                                 dnl save the flags
 836                                 save_LIBS="$LIBS"
 837                                 LIBS="-threads $LIBS"
 838                                 AC_TRY_LINK([char pthread_create();],[
 839                                         pthread_create();
 840                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 841                                 dnl restore the LIBS
 842                                 LIBS="$save_LIBS"
 843                         ])
 844
 845                         if test $ol_cv_thread_flag = yes ; then
 846                                 LTHREAD_LIBS="$LTHREAD_LIBS -threads"
 847                                 ol_link_threads=posix
 848                         fi
 849                 fi
 850
 851                 if test $ol_link_threads = no ; then
 852                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 853                         save_LIBS="$LIBS"
 854                         AC_CHECK_LIB(pthreads, pthread_mutex_unlock, [
 855                                 ol_link_threads=posix
 856                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 857                                 if test $ol_with_yielding_select = auto ; then
 858                                         ol_with_yielding_select=yes
 859                                 fi
 860                                 ],:,[-lmach -lexc -lc_r])
 861                         LIBS="$save_LIBS"
 862                 fi
 863
 864                 if test $ol_link_threads = no ; then
 865                         dnl try DEC Threads -lpthreads -lmach -lexc
 866                         save_LIBS="$LIBS"
 867                         AC_CHECK_LIB(pthreads, pthread_mutex_lock, [
 868                                 ol_link_threads=posix
 869                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc"
 870                                 if test $ol_with_yielding_select = auto ; then
 871                                         ol_with_yielding_select=yes
 872                                 fi
 873                                 ],:,[-lmach -lexc])
 874                         LIBS="$save_LIBS"
 875                 fi
 876
 877                 if test $ol_link_threads = no ; then
 878                         dnl try DEC Threads -lpthreads -lexc
 879                         save_LIBS="$LIBS"
 880                         AC_CHECK_LIB(pthreads, pthread_mutex_trylock, [
 881                                 ol_link_threads=posix
 882                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lexc"
 883                                 if test $ol_with_yielding_select = auto ; then
 884                                         ol_with_yielding_select=yes
 885                                 fi
 886                                 ],:,[-lexc])
 887                         LIBS="$save_LIBS"
 888                 fi
 889
 890                 if test $ol_link_threads != no ; then
 891                         AC_DEFINE(HAVE_PTHREADS,1,
 892                                 [define if you have POSIX Threads])
 893
 894                         dnl save flags
 895                         save_CPPFLAGS="$CPPFLAGS"
 896                         save_LIBS="$LIBS"
 897                         LIBS="$LTHREAD_LIBS $LIBS"
 898
 899                         dnl All POSIX Thread (final) implementations should have
 900                         dnl sched_yield instead of pthread yield.
 901                         dnl check for both
 902                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 903
 904                         if test $ac_cv_func_sched_yield = no -a \
 905                                 $ac_cv_func_pthread_yield = no ; then
 906                                 dnl Digital UNIX has sched_yield() in -lrt
 907                                 AC_CHECK_LIB(rt, sched_yield,
 908                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 909                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 910                                         ac_cv_func_sched_yield=yes],
 911                                         [ac_cv_func_sched_yield=no])
 912                         fi
 913                         if test $ac_cv_func_sched_yield = no -a \
 914                                 $ac_cv_func_pthread_yield = no ; then
 915                                 dnl Solaris has sched_yield() in -lposix4
 916                                 dnl but we'll use thr_yield instead.
 917                                 AC_CHECK_FUNCS(thr_yield)
 918                         fi
 919                         if test $ac_cv_func_sched_yield = no -a \
 920                                 $ac_cv_func_pthread_yield = no -a \
 921                                 "$ac_cv_func_thr_yield" = no ; then
 922                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 923                         fi
 924
 925                         dnl Check functions for compatibility
 926                         AC_CHECK_FUNCS(pthread_kill)
 927
 928                         dnl Check for pthread_detach with <pthread.h> inclusion
 929                         dnl as it's symbol may have been mangled.
 930                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 931                                 [ol_cv_func_pthread_detach], [
 932                                 dnl save the flags
 933                                 AC_TRY_LINK([#include <pthread.h>],
 934                                         [pthread_detach(NULL);],
 935                                         [ol_cv_func_pthread_detach=yes],
 936                                         [ol_cv_func_pthread_detach=no])
 937                         ])
 938
 939                         if test $ol_cv_func_pthread_detach = no ; then
 940                                 AC_MSG_ERROR([could not locate pthread_detach()])
 941                         fi
 942
 943                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 944                                 [define if you have pthread_detach function])
 945
 946                         dnl Check for setconcurreny functions
 947                         AC_CHECK_FUNCS( \
 948                                 pthread_setconcurrency \
 949                                 pthread_getconcurrency \
 950                                 thr_setconcurrency \
 951                                 thr_getconcurrency \
 952                         )
 953
 954                         AC_MSG_CHECKING([if pthread_create() works])
 955                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 956                         AC_TRY_RUN([
 957 #include <pthread.h>
 958 #ifndef NULL
 959 #define NULL (void*)0
 960 #endif
 961
 962 static void *task(p)
 963         void *p;
 964 {
 965         return (void *) (p == NULL);
 966 }
 967
 968 int main(argc, argv)
 969         int argc;
 970         char **argv;
 971 {
 972         pthread_t t;
 973 #if HAVE_PTHREADS_D4
 974         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 975 #else
 976         exit(pthread_create(&t, NULL, task, NULL));
 977 #endif
 978 }
 979 ],
 980                                 [ol_cv_pthread_create_works=yes],
 981                                 [ol_cv_pthread_create_works=no],
 982                                 [dnl assume yes
 983                                 ol_cv_pthread_create_works=yes])])
 984                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 985
 986                         if test $ol_cv_pthread_create_works = no ; then
 987                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 988                         fi
 989
 990                         dnl Check if select causes an yield
 991                         if test $ol_with_yielding_select = auto ; then
 992                                 AC_MSG_CHECKING([if select yields when using pthreads])
 993                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 994                                 AC_TRY_RUN([
 995 #include <sys/types.h>
 996 #include <sys/time.h>
 997 #include <unistd.h>
 998 #include <pthread.h>
 999 #ifndef NULL
1000 #define NULL (void*) 0
1001 #endif
1002
1003 static int fildes[2];
1004
1005 static void *task(p)
1006         void *p;
1007 {
1008         int i;
1009         struct timeval tv;
1010
1011         fd_set rfds;
1012
1013         tv.tv_sec=10;
1014         tv.tv_usec=0;
1015
1016         FD_ZERO(&rfds);
1017         FD_SET(fildes[0], &rfds);
1018
1019         /* we're not interested in any fds */
1020         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1021
1022         if(i < 0) {
1023                 perror("select");
1024                 exit(10);
1025         }
1026
1027         exit(0); /* if we exit here, the select blocked the whole process */
1028 }
1029
1030 int main(argc, argv)
1031         int argc;
1032         char **argv;
1033 {
1034         pthread_t t;
1035
1036         /* create a pipe to select */
1037         if(pipe(&fildes[0])) {
1038                 perror("select");
1039                 exit(1);
1040         }
1041
1042 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1043         (void) pthread_setconcurrency(2);
1044 #else
1045 #ifdef HAVE_THR_SETCONCURRENCY
1046         /* Set Solaris LWP concurrency to 2 */
1047         thr_setconcurrency(2);
1048 #endif
1049 #endif
1050
1051 #if HAVE_PTHREADS_D4
1052         pthread_create(&t, pthread_attr_default, task, NULL);
1053 #else
1054         pthread_create(&t, NULL, task, NULL);
1055 #endif
1056
1057 #if HAVE_SCHED_YIELD
1058         sched_yield();  /* make sure task runs first */
1059 #else
1060 #ifdef HAVE_PTHREAD_YIELD
1061         pthread_yield();        /* make sure task runs first */
1062 #endif
1063 #endif
1064
1065         exit(2);
1066 }],
1067                                 [ol_cv_pthread_select_yields=no],
1068                                 [ol_cv_pthread_select_yields=yes], [
1069                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
1070                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
1071
1072                                 if test $ol_cv_pthread_select_yields = yes ; then
1073                                         ol_with_yielding_select=yes
1074                                 fi
1075                         fi
1076
1077                         dnl restore flags
1078                         CPPFLAGS="$save_CPPFLAGS"
1079                         LIBS="$save_LIBS"
1080                 else
1081                         AC_MSG_ERROR([could not link with POSIX Threads])
1082                 fi
1083         fi
1084
1085         if test $ol_with_threads = posix ; then
1086                 AC_MSG_ERROR([could not locate POSIX Threads])
1087         fi
1088 fi
1089
1090 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1091         -o $ol_with_threads = mach ; then
1092
1093         dnl check for Mach CThreads
1094         AC_CHECK_HEADERS(mach/cthreads.h)
1095         if test $ac_cv_header_mach_cthreads_h = yes ; then
1096                 ol_with_threads=found
1097
1098                 dnl check for cthread support in current $LIBS
1099                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1100
1101                 if test $ol_link_threads = no ; then
1102                         dnl try -all_load
1103                         dnl this test needs work
1104                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1105                                 [ol_cv_cthread_all_load], [
1106                                 dnl save the flags
1107                                 save_LIBS="$LIBS"
1108                                 LIBS="-all_load $LIBS"
1109                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1110                                         cthread_fork((void *)0, (void *)0);
1111                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1112                                 dnl restore the LIBS
1113                                 LIBS="$save_LIBS"
1114                         ])
1115
1116                         if test $ol_cv_cthread_all_load = yes ; then
1117                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1118                                 ol_link_threads=mach
1119                         fi
1120                 fi
1121
1122                 if test $ol_link_threads != no ; then
1123                         : check for cthread specific functionality here
1124                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1125                                 [define if you have Mach Cthreads])
1126                 else
1127                         AC_MSG_ERROR([could not link with Mach CThreads])
1128                 fi
1129         fi
1130
1131         if test $ol_with_threads = mach ; then
1132                 AC_MSG_ERROR([could not locate Mach CThreads])
1133         fi
1134 fi
1135
1136 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1137         -o $ol_with_threads = lwp ; then
1138
1139         dnl check for SunOS5 LWP
1140         AC_CHECK_HEADERS(thread.h synch.h)
1141         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1142                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1143
1144                 if test $have_thr = yes ; then
1145                         AC_DEFINE(HAVE_THR,1,
1146                                 [if you have Solaris LWP (thr) package])
1147                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1148                         ol_link_threads=thr
1149
1150                         if test $ol_with_yielding_select = auto ; then
1151                                 ol_with_yielding_select=yes
1152                         fi
1153
1154                         dnl Check for setconcurreny functions
1155                         AC_CHECK_FUNCS( \
1156                                 thr_setconcurrency \
1157                                 thr_getconcurrency \
1158                         )
1159                 fi
1160         fi
1161
1162         dnl check for SunOS4 LWP
1163         AC_CHECK_HEADERS(lwp/lwp.h)
1164         if test $ac_cv_header_lwp_lwp_h = yes ; then
1165                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1166
1167                 if test $have_lwp = yes ; then
1168                         AC_DEFINE(HAVE_LWP,1,
1169                                 [if you have SunOS LWP package])
1170                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1171                         ol_link_threads=lwp
1172
1173                         if test $ol_with_yielding_select = auto ; then
1174                                 ol_with_yielding_select=no
1175                         fi
1176                 fi
1177         fi
1178 fi
1179
1180 if test $ol_with_yielding_select = yes ; then
1181         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1182                 [define if select implicitly yields])
1183 fi
1184
1185 if test $ol_with_threads = manual ; then
1186         dnl User thinks he can manually configure threads.
1187         ol_link_threads=yes
1188
1189         AC_MSG_WARN([thread defines and link options must be set manually])
1190
1191         AC_CHECK_HEADERS(pthread.h sched.h)
1192         AC_CHECK_FUNCS(sched_yield pthread_yield)
1193         OL_LINUX_THREADS
1194
1195         AC_CHECK_HEADERS(mach/cthreads.h)
1196         AC_CHECK_HEADERS(lwp/lwp.h)
1197         AC_CHECK_HEADERS(thread.h synch.h)
1198 fi
1199
1200 if test $ol_link_threads != no ; then
1201         dnl needed to get reentrant/threadsafe versions
1202         dnl
1203         AC_DEFINE(REENTRANT,1)
1204         AC_DEFINE(_REENTRANT,1)
1205         AC_DEFINE(THREAD_SAFE,1)
1206         AC_DEFINE(_THREAD_SAFE,1)
1207         AC_DEFINE(THREADSAFE,1)
1208         AC_DEFINE(_THREADSAFE,1)
1209
1210         dnl this might cause the errno symbol to be
1211         dnl replaced with a function to get a thread specific errno.
1212         dnl check to see if everything needs to be compiled
1213         dnl with the thread libraries
1214         AC_CACHE_CHECK([for thread specific errno],
1215                 [ol_cv_errno_thread_specific], [
1216                 AC_TRY_LINK([#include <errno.h>], [int x = errno;],
1217                         [ol_cv_errno_thread_specific=yes],
1218                         [ol_cv_errno_thread_specific=no])
1219         ])
1220
1221         if test $ol_cv_errno_thread_specific != yes ; then
1222                 LIBS="$LTHREAD_LIBS $LIBS"
1223                 LTHREAD_LIBS=""
1224         fi
1225
1226 dnl When in thread environment, use
1227 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1228 dnl                     || defined( HAVE_FUNC_R )
1229 dnl                     func_r(...);
1230 dnl             #else
1231 dnl             #       if defined( HAVE_THREADS )
1232 dnl                             /* lock */
1233 dnl             #       endif
1234 dnl                             func(...);
1235 dnl             #       if defined( HAVE_THREADS )
1236 dnl                             /* unlock */
1237 dnl             #       endif
1238 dnl             #endif
1239 dnl
1240 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1241 dnl             _POSIX_REENTRANT_FUNCTIONS
1242 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1243 dnl             _POSIX_THREADSAFE_FUNCTIONS
1244 dnl
1245 dnl             and is currently defined in lthread.h
1246 dnl
1247 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1248 dnl
1249 dnl libldap/*.c should only include <lthread.h> iff
1250 dnl LDAP_R_COMPILE is defined.  ie:
1251 dnl             #ifdef LDAP_R_COMPILE
1252 dnl             #       include LDAP_R_COMPILE
1253 dnl             #endif
1254 dnl
1255 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
1256 dnl specifically for compiling the threadsafe version of
1257 dnl     the ldap library (-lldap_r).
1258 dnl
1259 dnl     dnl check for reentrant/threadsafe functions
1260 dnl     dnl
1261 dnl     dnl note: these should only be used when linking
1262 dnl     dnl       with $LTHREAD_LIBS
1263 dnl     dnl
1264 dnl     save_CPPFLAGS="$CPPFLAGS"
1265 dnl     save_LIBS="$LIBS"
1266 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1267 dnl     AC_CHECK_FUNCS( \
1268 dnl             gmtime_r \
1269 dnl             gethostbyaddr_r gethostbyname_r \
1270 dnl             feof_unlocked unlocked_feof \
1271 dnl             putc_unlocked unlocked_putc \
1272 dnl             flockfile ftrylockfile \
1273 dnl     )
1274 dnl     CPPFLAGS="$save_CPPFLAGS"
1275 dnl     LIBS="$save_LIBS"
1276 fi
1277
1278 if test $ol_link_threads = no ; then
1279         if test $ol_with_threads = yes ; then
1280                 AC_MSG_ERROR([no suitable thread support])
1281         fi
1282
1283         if test $ol_with_threads = auto ; then
1284                 AC_MSG_WARN([no suitable thread support, disabling threads])
1285                 ol_with_threads=no
1286         fi
1287
1288         AC_DEFINE(NO_THREADS,1,
1289                 [define if you have (or want) no threads])
1290         LTHREAD_LIBS=""
1291 fi
1292
1293 if test $ol_link_threads != no ; then
1294         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1295 fi
1296
1297 dnl ----------------------------------------------------------------
1298
1299 ol_link_ldbm=no
1300 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1301         OL_BERKELEY_DB2
1302
1303         if test $ol_cv_berkeley_db2 = yes ; then
1304                 ol_link_ldbm=db2
1305                 ol_with_ldbm_api=db2
1306
1307                 if test $ol_with_ldbm_type = hash ; then
1308                         AC_DEFINE(LDBM_USE_DBHASH,1)
1309                 else
1310                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1311                 fi
1312
1313                 dnl $ol_cv_lib_db2 should be yes or -ldb
1314                 dnl (it could be no, but that would be an error
1315                 if test $ol_cv_lib_db2 != yes ; then
1316                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1317                 fi
1318         fi
1319 fi
1320
1321 ol_link_bdb2=no
1322 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1323         ol_link_bdb2=yes
1324 fi
1325
1326 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1327         OL_BERKELEY_DB
1328
1329         if test $ol_cv_berkeley_db = yes ; then
1330                 ol_link_ldbm=db
1331                 ol_with_ldbm_api=db
1332
1333                 if test $ol_with_ldbm_type = hash ; then
1334                         AC_DEFINE(LDBM_USE_DBHASH,1)
1335                 else
1336                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1337                 fi
1338
1339                 dnl $ol_cv_lib_db should be yes or -ldb
1340                 dnl (it could be no, but that would be an error
1341                 if test $ol_cv_lib_db != yes ; then
1342                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1343                 fi
1344         fi
1345 fi
1346
1347 if test $ol_with_ldbm_api = manual ; then
1348         dnl User thinks he can manually configure LDBM api.
1349         ol_link_ldbm=yes
1350
1351         AC_MSG_WARN([LDBM defines and link options must be set manually])
1352
1353         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1354 fi
1355
1356 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1357         AC_MSG_WARN(Could not find LDBM with BTREE support)
1358         ol_with_ldbm_api=none
1359 fi
1360
1361 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1362         OL_GDBM
1363
1364         if test $ol_cv_gdbm = yes ; then
1365                 ol_link_ldbm=gdbm
1366                 ol_with_ldbm_api=gdbm
1367
1368                 if test $ol_cv_lib_gdbm != yes ; then
1369                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1370                 fi
1371         fi
1372 fi
1373
1374 if test $ol_with_ldbm_api = auto ; then
1375         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1376 elif test $ol_with_ldbm_api = ndbm ; then
1377         OL_NDBM
1378
1379         if test $ol_cv_ndbm = yes ; then
1380                 ol_link_ldbm=ndbm
1381                 ol_with_ldbm_api=ndbm
1382
1383                 if test $ol_cv_lib_ndbm != yes ; then
1384                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1385                 fi
1386         fi
1387 fi
1388
1389 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1390         AC_MSG_WARN(could not find suitable LDBM backend)
1391         if test $ol_enable_ldbm = yes ; then
1392                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1393         fi
1394
1395         AC_MSG_WARN(disabling LDBM)
1396         ol_enable_ldbm=no
1397 fi
1398
1399 if test $ol_enable_wrappers != no ; then
1400         AC_CHECK_HEADERS(tcpd.h)
1401
1402         if test $ac_cv_header_tcpd_h != yes ; then
1403                 have_wrappers=no
1404         else
1405                 AC_CHECK_LIB(wrap, main,
1406                         [have_wrappers=yes], [have_wrappers=no])
1407         fi
1408
1409         if test $have_wrappers = yes ; then
1410                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1411                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1412         else
1413                 AC_MSG_WARN(could not find -lwrap)
1414                 if test $ol_enable_wrappers = yes ; then
1415                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1416                 fi
1417
1418                 AC_MSG_WARN(disabling wrappers support)
1419                 ol_enable_wrappers=no
1420         fi
1421 fi
1422
1423 if test $ol_enable_syslog != no ; then
1424         AC_CHECK_FUNC(openlog)
1425         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1426                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1427         fi
1428         ol_enable_syslog=$ac_cv_func_openlog
1429 fi
1430
1431 if test $ol_enable_dmalloc != no ; then
1432         AC_CHECK_HEADERS(dmalloc.h)
1433         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1434 fi
1435
1436 if test $ol_enable_tcl != no ; then
1437         AC_CHECK_HEADERS(tcl.h)
1438
1439         if test $ac_cv_header_tcl_h != yes ; then
1440                 have_tcl=no
1441         else
1442                 AC_CHECK_LIB(tcl,main,
1443                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1444                         [have_tcl=no])
1445
1446                 if test $have_tcl != yes; then
1447                         AC_CHECK_LIB(tcl7.6,main,
1448                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1449                                 [have_tcl=no])
1450                 fi
1451
1452                 if test $have_tcl != yes; then
1453                         AC_CHECK_LIB(tcl8.0,main,
1454                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1455                                 [have_tcl=no])
1456                 fi
1457         fi
1458
1459         if test $have_tcl != yes ; then
1460                 AC_MSG_WARN([could not find -ltcl])
1461                 if test $ol_enable_tcl = yes ; then
1462                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1463                 fi
1464
1465                 ol_enable_tcl=no
1466         fi
1467 fi
1468
1469 # ud needs termcap (should insert check here)
1470 ol_link_termcap=no
1471 AC_CHECK_HEADERS(termcap.h ncurses.h)
1472
1473 if test $ol_link_termcap = no ; then
1474         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1475         if test $have_termcap = yes ; then
1476                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1477                 ol_link_termcap=yes
1478                 TERMCAP_LIBS=-ltermcap
1479         fi
1480 fi
1481
1482 if test $ol_link_termcap = no ; then
1483         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1484         if test $have_ncurses = yes ; then
1485                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1486                 ol_link_termcap=yes
1487                 TERMCAP_LIBS=-lncurses
1488         fi
1489 fi
1490
1491 if test $ol_link_termcap = no ; then
1492         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1493         TERMCAP_LIBS=
1494 fi
1495
1496 # FreeBSD (and others) have crypt(3) in -lcrypt
1497 if test $ol_enable_crypt != no ; then
1498         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1499                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1500                         have_crypt=yes], [have_crypt=no])])
1501
1502         if test $have_crypt = yes ; then
1503                 AC_DEFINE(HAVE_CRYPT,1)
1504         else
1505                 AC_MSG_WARN(could not find crypt)
1506                 if test $ol_enable_crypt = yes ; then
1507                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1508                 fi
1509
1510                 AC_MSG_WARN(disabling crypt support)
1511                 ol_enable_crypt=no
1512         fi
1513 fi
1514
1515 # FreeBSD (and others) have setproctitle(3) in -lutil
1516 if test $ol_enable_proctitle != no ; then
1517         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1518                 AC_CHECK_LIB(util, setproctitle,
1519                         [have_setproctitle=yes
1520                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1521                         [have_setproctitle=no
1522                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1523
1524         if test $have_setproctitle = yes ; then
1525                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1526         fi
1527 fi
1528
1529 dnl ----------------------------------------------------------------
1530 dnl Checks for header files.
1531 AC_HEADER_STDC
1532
1533 if test $ac_cv_header_stdc != yes; then
1534         AC_MSG_WARN([could not Standard C compliant headers])
1535 fi
1536
1537 AC_HEADER_DIRENT
1538 AC_HEADER_SYS_WAIT
1539 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1540 if test $am_cv_sys_posix_termios = yes ; then
1541         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1542                 [define if you have POSIX termios])
1543 fi
1544
1545 AC_CHECK_HEADERS(       \
1546         arpa/nameser.h  \
1547         crypt.h                 \
1548         errno.h                 \
1549         fcntl.h                 \
1550         filio.h                 \
1551         getopt.h                \
1552         libutil.h               \
1553         limits.h                \
1554         locale.h                \
1555         malloc.h                \
1556         memory.h                \
1557         regex.h                 \
1558         psap.h                  \
1559         pwd.h                   \
1560         resolv.h                \
1561         sgtty.h                 \
1562         stdarg.h                \
1563         stddef.h                \
1564         string.h                \
1565         strings.h               \
1566         sysexits.h              \
1567         sys/file.h              \
1568         sys/filio.h             \
1569         sys/errno.h             \
1570         sys/ioctl.h             \
1571         sys/param.h             \
1572         sys/resource.h  \
1573         sys/socket.h    \
1574         sys/syslog.h    \
1575         sys/time.h              \
1576         sys/types.h             \
1577         syslog.h                \
1578         termios.h               \
1579         unistd.h                \
1580 )
1581
1582 dnl ----------------------------------------------------------------
1583 dnl Checks for typedefs, structures, and compiler characteristics.
1584 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1585 AC_TYPE_MODE_T
1586 AC_TYPE_OFF_T
1587 AC_TYPE_PID_T
1588 AM_TYPE_PTRDIFF_T
1589 AC_TYPE_SIGNAL
1590 OL_TYPE_SIG_ATOMIC_T
1591 AC_TYPE_SIZE_T
1592 AC_STRUCT_ST_BLKSIZE
1593 AC_HEADER_TIME
1594 AC_STRUCT_TM
1595
1596 OL_C_UPPER_LOWER
1597 AC_C_CONST
1598 OL_C_VOLATILE
1599
1600 if test $cross_compiling = yes ; then
1601         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1602 else
1603         AC_C_BIGENDIAN
1604         AC_CHECK_SIZEOF(short)
1605         AC_CHECK_SIZEOF(int)
1606         AC_CHECK_SIZEOF(long)
1607 fi
1608
1609 dnl ----------------------------------------------------------------
1610 dnl Checks for library functions.
1611 AC_FUNC_MEMCMP
1612 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1613 AC_FUNC_STRFTIME
1614 dnl AM_FUNC_STRTOD
1615 AC_FUNC_VPRINTF
1616
1617 if test $ac_cv_func_vprintf = yes ; then
1618         dnl check for vsnprintf
1619         AC_CHECK_FUNCS(vsnprintf vsprintf)
1620 fi
1621
1622 AC_CHECK_FUNCS(         \
1623         bcopy                   \
1624         flock                   \
1625         getdtablesize   \
1626         gethostname             \
1627         getpwuid                \
1628         gettimeofday    \
1629         lockf                   \
1630         memcpy                  \
1631         memmove                 \
1632         mkstemp                 \
1633         select                  \
1634         setpwfile               \
1635         setsid                  \
1636         signal                  \
1637         sigset                  \
1638         snprintf                \
1639         socket                  \
1640         strdup                  \
1641         strerror                \
1642         strpbrk                 \
1643         strrchr                 \
1644         strsep                  \
1645         strstr                  \
1646         strtol                  \
1647         strtoul                 \
1648         strspn                  \
1649         sysconf                 \
1650         waitpid                 \
1651 )
1652
1653 dnl We actually may need to replace more than this.
1654 AC_REPLACE_FUNCS(getopt tempnam)
1655
1656 dnl ----------------------------------------------------------------
1657 # Check Configuration
1658 OL_SYS_ERRLIST
1659
1660 dnl ----------------------------------------------------------------
1661 dnl Sort out defines
1662
1663 if test "$ol_enable_debug" != no ; then
1664         AC_DEFINE(LDAP_DEBUG,1)
1665 fi
1666 if test "$ol_enable_syslog" = yes ; then
1667         AC_DEFINE(LDAP_SYSLOG,1)
1668 fi
1669 if test "$ol_enable_libui" = yes ; then
1670         AC_DEFINE(LDAP_LIBUI,1)
1671 fi
1672 if test "$ol_enable_cache" = no ; then
1673         AC_DEFINE(LDAP_NOCACHE,1)
1674 fi
1675 if test "$ol_enable_dns" != no ; then
1676         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1677 fi
1678 if test "$ol_enable_proctitle" != no ; then
1679         AC_DEFINE(LDAP_PROCTITLE,1)
1680 fi
1681 if test "$ol_enable_referrals" != no ; then
1682         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1683 fi
1684 if test "$ol_enable_cldap" != no ; then
1685         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1686 fi
1687
1688 if test "$ol_enable_aclgroups" != no ; then
1689         AC_DEFINE(SLAPD_ACLGROUPS,1)
1690 fi
1691 if test "$ol_enable_crypt" != no ; then
1692         AC_DEFINE(SLAPD_CRYPT,1)
1693 fi
1694 if test "$ol_enable_cleartext" != no ; then
1695         AC_DEFINE(SLAPD_CLEARTEXT,1)
1696 fi
1697 if test "$ol_enable_phonetic" != no ; then
1698         AC_DEFINE(SLAPD_PHONETIC,1)
1699 fi
1700 if test "$ol_enable_rlookups" != no ; then
1701         AC_DEFINE(SLAPD_RLOOKUPS,1)
1702 fi
1703
1704 if test "$ol_link_bdb2" != no ; then
1705         AC_DEFINE(SLAPD_BDB2,1)
1706         BUILD_SLAPD=yes
1707         BUILD_BDB2=yes
1708 fi
1709
1710 if test "$ol_link_ldbm" != no ; then
1711         AC_DEFINE(SLAPD_LDBM,1)
1712         BUILD_SLAPD=yes
1713         BUILD_LDBM=yes
1714 fi
1715
1716 if test "$ol_enable_passwd" != no ; then
1717         AC_DEFINE(SLAPD_PASSWD,1)
1718         BUILD_SLAPD=yes
1719         BUILD_PASSWD=yes
1720 fi
1721
1722 if test "$ol_enable_perl" != no ; then
1723         AC_DEFINE(SLAPD_PERL,1)
1724         BUILD_SLAPD=yes
1725         BUILD_PERL=yes
1726 fi
1727
1728 if test "$ol_enable_shell" != no ; then
1729         AC_DEFINE(SLAPD_SHELL,1)
1730         BUILD_SLAPD=yes
1731         BUILD_SHELL=yes
1732 fi
1733
1734 if test "$ol_enable_tcl" != no ; then
1735         AC_DEFINE(SLAPD_TCL,1)
1736         BUILD_SLAPD=yes
1737         BUILD_TCL=yes
1738 fi
1739
1740 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1741         $BUILD_SLAPD = yes ; then
1742         BUILD_SLURPD=yes
1743 fi
1744
1745 if test "$ol_link_isode" != no ; then
1746         BUILD_LDAPD=yes
1747 fi
1748
1749 dnl ----------------------------------------------------------------
1750
1751 AC_SUBST(BUILD_LDAPD)
1752 AC_SUBST(BUILD_SLAPD)
1753   AC_SUBST(BUILD_BDB2)
1754   AC_SUBST(BUILD_LDBM)
1755   AC_SUBST(BUILD_PASSWD)
1756   AC_SUBST(BUILD_PERL)
1757   AC_SUBST(BUILD_SHELL)
1758   AC_SUBST(BUILD_TCL)
1759 AC_SUBST(BUILD_SLURPD)
1760
1761 AC_SUBST(LDAP_LIBS)
1762 AC_SUBST(LDAPD_LIBS)
1763 AC_SUBST(SLAPD_LIBS)
1764 AC_SUBST(SLURPD_LIBS)
1765 AC_SUBST(LDBM_LIBS)
1766 AC_SUBST(LTHREAD_LIBS)
1767 AC_SUBST(LUTIL_LIBS)
1768
1769 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1770 AC_SUBST(SLAPD_PERL_LDFLAGS)
1771
1772 AC_SUBST(KRB_LIBS)
1773 AC_SUBST(READLINE_LIBS)
1774 AC_SUBST(TERMCAP_LIBS)
1775 AC_SUBST(TLS_LIBS)
1776
1777 dnl ----------------------------------------------------------------
1778 dnl final output
1779 dnl
1780
1781 AC_OUTPUT( \
1782 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1783 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1784 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1785 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1786 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1787 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1788 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1789 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1790 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1791 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1792 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1793 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1794 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1795 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1796 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1797 include/Makefile:build/top.mk:include/Makefile.in \
1798 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1799 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1800 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1801 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1802 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1803 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1804 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1805 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1806 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1807 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1808 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1809 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1810 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1811 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1812 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1813 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1814 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1815 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1816 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1817 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1818 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1819 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1820 ,[
1821 date > stamp-h
1822 echo Please \"make depend\" to build dependencies
1823 ])