git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(build/version)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17
  18 OL_VERSION=`cat $ac_aux_dir/version`
  19 if test -z "$OL_VERSION"; then
  20         AC_MSG_ERROR([could not determine version])
  21 fi
  22
  23 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  24 AC_SUBST(PACKAGE)
  25 AC_SUBST(VERSION)
  26 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  27 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  28
  29 dnl We use autoconf features new to 2.13.
  30 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  31 AC_PREREQ(2.13)dnl Required Autoconf version
  32
  33 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  34
  35 dnl
  36 dnl Start Args
  37 AC_MSG_CHECKING(configure arguments)
  38 AC_PREFIX_DEFAULT(/usr/local)
  39
  40 top_builddir=`pwd`
  41 AC_SUBST(top_builddir)dnl
  42
  43 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
  44
  45 ldap_subdir="openldap"
  46
  47 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  48         if test "$withval" = "no"; then
  49                 ldap_subdir=""
  50         elif test "$withval" != "yes"; then
  51                 ldap_subdir="$withval"
  52         fi
  53 ])dnl
  54
  55 AC_SUBST(ldap_subdir)dnl
  56
  57 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  58 dnl ol_enable_syslog=no
  59 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  60 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  61 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  62 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  63 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  64 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  65 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  66         no, [yes no])dnl
  67
  68 dnl General "with" options
  69 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  70
  71 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  72         auto, [auto k5 k4 afs yes no])
  73 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  74         auto, [auto yes no] )
  75 OL_ARG_WITH(threads,[  --with-threads   use threads],
  76         auto, [auto posix mach lwp yes no manual] )
  77 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  78         auto, [auto ssleay openssl yes no] )
  79 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  80         auto, [auto yes no manual] )
  81
  82 dnl Server options
  83
  84 dnl LDAPD OPTIONS
  85 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  86 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  87
  88 dnl SLAPD OPTIONS
  89 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  90 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  91 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  92 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  93 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  94 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
  95 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  96 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  97 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  98
  99 dnl SLAPD Backend options
 100 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 101 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 102 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 103 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 104         [auto db2 db mdbm gdbm ndbm manual])
 105 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 106         [auto btree hash])
 107
 108 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 109 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 110 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 111 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 112
 113 dnl SLURPD OPTIONS
 114 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 115 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 116
 117 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 118 AM_ENABLE_STATIC
 119 dnl AM_DISABLE_SHARED
 120 AM_ENABLE_SHARED
 121
 122 dnl General "enable" options
 123 # validate options
 124 if test $ol_enable_dns = yes ; then
 125         if test $ol_enable_referrals = no ; then
 126                 AC_MSG_ERROR([DNS requires --enable-referrals])
 127         fi
 128         if test $ol_enable_referrals = auto ; then
 129                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 130                 ol_enable_referrals=yes
 131         fi
 132 fi
 133
 134 if test $ol_enable_slapd = no ; then
 135         dnl SLAPD was specificallly disabled
 136         if test $ol_enable_bdb2 = yes ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 138         fi
 139         if test $ol_enable_ldap = yes ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 141         fi
 142         if test $ol_enable_ldbm = yes ; then
 143                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 144         fi
 145         if test $ol_enable_passwd = yes ; then
 146                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 147         fi
 148         if test $ol_enable_perl = yes ; then
 149                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 150         fi
 151         if test $ol_enable_shell = yes ; then
 152                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 153         fi
 154         if test $ol_enable_tcl = yes ; then
 155                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 156         fi
 157         if test $ol_enable_aclgroups = yes ; then
 158                 AC_MSG_WARN([slapd disabled, ignoring --enable-aclgroups argument])
 159         fi
 160         if test $ol_enable_modules = yes ; then
 161                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 162         fi
 163         if test $ol_enable_wrappers = yes ; then
 164                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 165         fi
 166         if test $ol_enable_phonetic = yes ; then
 167                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 168         fi
 169         if test $ol_enable_rlookups = yes ; then
 170                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 171         fi
 172         if test $ol_with_ldbm_api != auto ; then
 173                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 174         fi
 175         if test $ol_with_ldbm_type != auto ; then
 176                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 177         fi
 178         if test $ol_enable_slurpd = yes ; then
 179                 AC_MSG_ERROR([slurpd requires slapd])
 180         fi
 181
 182         # force settings to no
 183         ol_enable_bdb2=no
 184         ol_enable_ldap=no
 185         ol_enable_ldbm=no
 186         ol_enable_passwd=no
 187         ol_enable_perl=no
 188         ol_enable_shell=no
 189         ol_enable_tcl=no
 190
 191         ol_enable_aclgroups=no
 192         ol_enable_modules=no
 193         ol_enable_phonetic=no
 194         ol_enable_rlookups=no
 195         ol_enable_wrappers=no
 196
 197         ol_with_ldbm_api=no
 198         ol_with_ldbm_type=no
 199
 200         ol_enable_slurpd=no
 201
 202 elif test $ol_enable_ldbm = no ; then
 203         dnl SLAPD without LDBM
 204
 205         if test $ol_with_ldbm_api != auto ; then
 206                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 207         fi
 208
 209         if test $ol_with_ldbm_type != auto ; then
 210                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 211         fi
 212
 213         if test $ol_enable_bdb2 = yes ; then
 214                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 215         fi
 216
 217         if test $ol_enable_modules != yes -a \
 218                 $ol_enable_ldap = no -a \
 219                 $ol_enable_passwd = no -a \
 220                 $ol_enable_perl = no -a \
 221                 $ol_enable_shell = no -a \
 222                 $ol_enable_tcl = no ; then
 223                 AC_MSG_ERROR([slapd requires a backend])
 224         fi
 225
 226         ol_with_ldbm_api=no
 227         ol_with_ldbm_type=no
 228
 229 elif test $ol_enable_bdb2 = yes ; then
 230         dnl SLAPD with BDB2
 231
 232         if test $ol_with_ldbm_api != auto -a \
 233                 $ol_with_ldbm_api != db2 ; then
 234                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 235         fi
 236
 237         ol_with_ldbm_api=db2
 238
 239 else
 240         dnl SLAPD with LDBM
 241
 242         if test $ol_enable_bdb2 != no ; then
 243                 if test $ol_with_ldbm_api != auto -a \
 244                         $ol_with_ldbm_api != db2 ; then
 245                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 246                         ol_enable_bdb2=no
 247                 fi
 248         fi
 249
 250         if test $ol_with_ldbm_api = gdbm -a \
 251                 $ol_with_ldbm_type = btree ; then
 252                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 253         fi
 254         if test $ol_with_ldbm_api = mdbm -a \
 255                 $ol_with_ldbm_type = btree ; then
 256                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 257         fi
 258         if test $ol_with_ldbm_api = ndbm -a \
 259                 $ol_with_ldbm_type = btree ; then
 260                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 261         fi
 262 fi
 263
 264 if test $ol_enable_slurpd = yes ; then
 265         dnl SLURPD was specifically enabled
 266         if test $ol_with_threads = no ; then
 267                 AC_MSG_ERROR([slurpd requires threads])
 268         fi
 269 fi
 270
 271 AC_MSG_RESULT(done)
 272
 273 ## Initialize vars
 274 LDAP_LIBS=
 275 LDBM_LIBS=
 276 LTHREAD_LIBS=
 277 LUTIL_LIBS=
 278
 279 LDAPD_LIBS=
 280 SLAPD_LIBS=
 281 SLURPD_LIBS=
 282
 283 BUILD_LDAPD=no
 284 BUILD_SLAPD=no
 285 BUILD_SLURPD=no
 286
 287 BUILD_BDB2=no
 288 BUILD_LDAP=no
 289 BUILD_LDBM=no
 290 BUILD_PASSWD=no
 291 BUILD_PERL=no
 292 BUILD_SHELL=no
 293 BUILD_TCL=no
 294 BUILD_THREAD=no
 295
 296 SLAPD_MODULES_LDFLAGS=
 297 SLAPD_MODULES_CPPFLAGS=
 298
 299 SLAPD_PERL_LDFLAGS=
 300 SLAPD_PERL_CPPFLAGS=
 301
 302 KRB_LIBS=
 303 READLINE_LIBS=
 304 TERMCAP_LIBS=
 305 TLS_LIBS=
 306
 307 dnl ----------------------------------------------------------------
 308 dnl Checks for programs
 309
 310 dnl AC_PROG_INSTALL
 311
 312 dnl The default compiler is cc (NOT gcc)
 313 dnl     (should check to see if 'cc' exists)
 314 save_CC="$CC"
 315 if test -z "${CC}"; then
 316         AC_CHECK_PROGS(CC,cc)
 317 fi
 318
 319 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 320 dnl CFLAGS=${CFLAGS-""}
 321
 322 dnl
 323 dnl AIX Thread requires we use cc_r or xlc_r.
 324 dnl But only do this IF AIX and CC is zero (initially),
 325 dnl and cc exists and threads are auto|yes|posix.
 326 dnl
 327 dnl If we find cc_r|xlc_r, force pthreads and assume
 328 dnl             pthread_create is in $LIBS (ie: don't bring in
 329 dnl             any additional thread libraries)
 330 dnl If we do not find cc_r|xlc_r, disable threads
 331 dnl
 332 AC_CANONICAL_HOST
 333
 334 case "$host" in
 335         *-*-aix*) ol_host_os=aix ;;
 336 esac
 337
 338 ol_aix_threads=no
 339 if test -z "$save_CC" -a "$CC" = cc -a "$ol_host_os" = aix ; then
 340         case "$ol_with_threads" in
 341                 auto | yes |  posix) ol_aix_threads=yes ;;
 342         esac
 343 fi
 344
 345 if test ol_aix_threads = yes ; then
 346         CC=
 347         AC_CHECK_PROGS(CC,cc_r xlc_r)
 348
 349         if test "$CC" ; then
 350                 if test $ol_with_threads != auto ; then
 351                         AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 352                 else
 353                         AC_MSG_WARN([disabling threads, no cc_r on AIX])
 354                 fi
 355                 ol_with_threads=no
 356         else
 357                 ol_with_threads=posix
 358                 ol_cv_pthread_create=yes
 359         fi
 360 fi
 361
 362 AM_PROG_LIBTOOL
 363 dnl AC_PROG_MAKE_SET
 364
 365 AC_PROG_AWK
 366 OL_PROG_LN_H
 367 AC_PROG_LN_S
 368
 369 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 370         LN_S="$LN_H"
 371 fi
 372
 373 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 374         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 375 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 376 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 377
 378 ol_link_modules=no
 379 if test $ol_enable_modules != no ; then
 380         AC_PATH_PROG(GLIBCONFIG, glib-config)
 381
 382         if test "no$GLIBCONFIG" = "no" ; then
 383                 if test $ol_enable_modules = yes ; then
 384                         AC_MSG_ERROR([could not locate glib-config])
 385                 fi
 386
 387         else
 388                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 389                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 390                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 391
 392                 dnl should check glib version
 393                 ol_link_modules=yes
 394         fi
 395 fi
 396
 397 ol_link_perl=no
 398 if test $ol_enable_perl != no ; then
 399         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 400
 401         if test "no$PERLBIN" = "no" ; then
 402                 if test $ol_enable_perl = yes ; then
 403                         AC_MSG_ERROR([could not locate perl])
 404                 fi
 405
 406         else
 407                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 408                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 409
 410                 dnl should check perl version
 411                 ol_link_perl=yes
 412         fi
 413 fi
 414
 415 AC_PROG_CPP
 416
 417 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 418         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 419
 420 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 421         AC_MSG_WARN([programs compiled here do run here...])
 422         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 423
 424 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 425         AC_MSG_WARN([programs compiled here do not run here...])
 426         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 427 fi
 428
 429 dnl Checks for UNIX Variants
 430 AC_AIX
 431 AC_ISC_POSIX
 432 AC_MINIX
 433
 434 dnl BeOS requires -lbe -lroot -lnet
 435 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 436
 437 dnl Checks for system services
 438 AC_CYGWIN
 439 AC_MINGW32
 440 AC_EXEEXT
 441 AC_OBJEXT
 442
 443 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 444
 445 dnl OpenLDAP requires STDC features
 446 AM_PROG_CC_STDC
 447 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 448         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 449 fi
 450
 451 dnl AM_C_PROTOTYPES
 452
 453 dnl Check cc depend flags
 454 OL_MKDEPEND
 455 if test "${ol_cv_mkdep}" = no ; then
 456         # this will soon become an error
 457         AC_MSG_WARN([do not know how to generate dependencies])
 458 fi
 459
 460 dnl Checks for libraries
 461
 462 dnl Find socket()
 463 dnl Likely combinations:
 464 dnl             -lsocket [ -lnsl_s | -lnsl ]
 465 dnl             -linet
 466
 467 AC_CHECK_FUNC(socket, :, [
 468 dnl
 469 dnl hopefully we won't include too many libraries
 470 dnl
 471         AC_CHECK_LIB(socket, main)
 472         AC_CHECK_LIB(net, main)
 473         AC_CHECK_LIB(net, socket)
 474         AC_CHECK_LIB(nsl_s, main)
 475         AC_CHECK_LIB(nsl, main)
 476         AC_CHECK_LIB(inet, socket)
 477         AC_CHECK_LIB(gen, main)
 478 ])
 479
 480 dnl Check for resolver routines
 481 AC_CHECK_FUNCS(res_search)
 482 if test $ac_cv_func_res_search = "no" ; then
 483         AC_CHECK_LIB(bind, res_search)
 484         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 485                 AC_DEFINE(HAVE_RES_SEARCH,1)
 486         else
 487                 AC_CHECK_LIB(resolv, res_search)
 488                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 489                         AC_DEFINE(HAVE_RES_SEARCH,1)
 490                 fi
 491         fi
 492 fi
 493
 494 dnl HP-UX requires -lV3
 495 AC_CHECK_LIB(V3, sigset)
 496
 497 AC_CHECK_HEADERS( regex.h )
 498 if test "$ac_cv_header_regex_h" != yes ; then
 499         AC_MSG_ERROR([POSIX regex.h required.])
 500 fi
 501 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 502
 503 OL_POSIX_REGEX
 504 if test "$ol_cv_c_posix_regex" = no ; then
 505         AC_MSG_ERROR([broken POSIX regex!])
 506 fi
 507
 508 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 509
 510 dnl Select arg types
 511 dnl (if this detection becomes permenent, it and the select() detection
 512 dnl should be done before the yielding select test)
 513 AC_FUNC_SELECT_ARGTYPES
 514
 515 # ISODE tests
 516 ol_link_isode=no
 517 if test $ol_enable_ldapd != no ; then
 518         AC_MSG_WARN([ldapd support deprecated.  Manual intervention required.])
 519
 520         dnl look for ISODE libraries
 521         AC_CHECK_LIB(xtpp, main, [
 522                 ol_link_isode=yes
 523                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 524                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 525                 ],:,[-lxtdsap -lxtisode -losi])
 526         AC_CHECK_LIB(dsap, main, [
 527                 ol_link_isode=yes
 528                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 529                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 530                 ],:,[-lisode])
 531         AC_CHECK_LIB(isode, main, [
 532                 ol_link_isode=yes
 533                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 534                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 535                 ],:)
 536 fi
 537
 538 if test $ol_link_isode != no; then
 539         AC_CHECK_LIB(pp, main, [
 540                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 541                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 542                 ],:)
 543
 544         AC_PATH_PROG(PEPSY, pepsy)
 545 fi
 546
 547 dnl
 548 dnl check for kerberos
 549 dnl
 550 ol_link_kerberos=no
 551
 552 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 553         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 554
 555         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 556                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 557                         [-lkrb5 -ldes425])
 558
 559                 if test $have_k5 = yes ; then
 560                         ol_with_kerberos=found
 561                         ol_link_kerberos=yes
 562
 563                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 564
 565                         LIBS="$KRB_LIBS $LIBS"
 566
 567                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 568                                 [ol_cv_var_des_debug], [
 569                                 dnl save the flags
 570                                 save_LIBS="$LIBS"
 571                                 LIBS="$KRB_LIBS $LIBS"
 572                                 AC_TRY_LINK([
 573 #include <kerberosIV/krb.h>
 574 #include <kerberosIV/des.h>
 575 extern int des_debug;
 576 ],[
 577 des_debug = 1;
 578 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 579                                 dnl restore the LIBS
 580                                 LIBS="$save_LIBS"
 581                         ])
 582
 583                         if test $ol_cv_var_des_debug = yes ; then
 584                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 585                                         [define if you have Kerberos des_debug])
 586                         fi
 587
 588                         LIBS="$save_LIBS"
 589                 fi
 590         fi
 591 fi
 592
 593 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 594         AC_CHECK_HEADERS(krb.h des.h)
 595
 596         if test $ac_cv_header_krb_h = yes ; then
 597                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 598
 599                 if test $have_k4 = yes ; then
 600                         ol_with_kerberos=found
 601                         ol_link_kerberos=yes
 602
 603                         KRB_LIBS="-lkrb -ldes"
 604                 fi
 605         fi
 606 fi
 607
 608 if test $ol_link_kerberos = yes ; then
 609         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 610 fi
 611
 612 dnl
 613 dnl Check for SSL/TLS
 614 dnl
 615 ol_link_tls=no
 616 if test $ol_with_tls != no ; then
 617
 618         AC_CHECK_HEADERS(ssl.h)
 619
 620         if test $ac_cv_header_ssl_h = yes ; then
 621                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 622                         [have_ssleay=yes
 623                         need_rsaref=no],
 624                         [have_ssleay=no],
 625                         [-lcrypto])
 626
 627                 if test $have_ssleay = no ; then
 628                         AC_CHECK_LIB(ssl, ssl3_accept,
 629                                 [have_ssleay=yes
 630                                 need_rsaref=yes], [have_ssleay=no],
 631                                 [-lcrypto -lRSAglue -lrsaref])
 632                 fi
 633
 634                 if test $have_ssleay = yes ; then
 635                         ol_with_tls=found
 636                         ol_link_tls=yes
 637
 638                         AC_DEFINE(HAVE_SSLEAY, 1,
 639                                 [define if you have SSLeay or OpenSSL])
 640
 641                         if test $need_rsaref = yes; then
 642                                 AC_DEFINE(HAVE_RSAREF, 1,
 643                                         [define if you have RSAref])
 644
 645                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 646                         else
 647                                 TLS_LIBS="-lssl -lcrypto"
 648                         fi
 649                 fi
 650         fi
 651 fi
 652
 653 if test $ol_link_tls = yes ; then
 654         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 655 fi
 656
 657 dnl Tests for reentrant functions necessary to build a
 658 dnl thread_safe -lldap.
 659 AC_CHECK_FUNCS(         \
 660         ctime_r                 \
 661         gethostbyname_r gethostbyaddr_r \
 662 )
 663
 664 if test "$ac_cv_func_ctime_r" = no ; then
 665         ol_cv_func_ctime_r_nargs=0
 666 else
 667         OL_FUNC_CTIME_R_NARGS
 668 dnl     OL_FUNC_CTIME_R_TYPE
 669 fi
 670
 671 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 672         OL_FUNC_GETHOSTBYNAME_R_NARGS
 673 else
 674         ol_cv_func_gethostbyname_r_nargs=0
 675 fi
 676
 677 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 678         OL_FUNC_GETHOSTBYADDR_R_NARGS
 679 else
 680         ol_cv_func_gethostbyaddr_r_nargs=0
 681 fi
 682
 683 if test "$ac_cv_func_ctime_r" = yes \
 684         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 685         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 686         -a "$ac_cv_func_gethostbyname_r" = yes \
 687         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 688         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 689         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 690         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 691         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 692         ; then
 693
 694         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 695 fi
 696
 697 ol_link_threads=no
 698 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 699         -o $ol_with_threads = posix ; then
 700
 701         AC_CHECK_HEADERS(pthread.h sched.h)
 702
 703         if test $ac_cv_header_pthread_h = yes ; then
 704                 OL_POSIX_THREAD_VERSION
 705
 706                 if test $ol_cv_pthread_version = final ; then
 707                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 708                                 [define if pthreads API compatible with final spec])
 709                 elif test $ol_cv_pthread_version = draft4 ; then
 710                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 711                                 [define if pthreads API compatible with draft4 spec])
 712                 else
 713                         AC_MSG_ERROR([unknown pthread version])
 714                 fi
 715
 716                 # consider threads found
 717                 ol_with_threads=found
 718
 719                 OL_HEADER_LINUX_THREADS
 720
 721                 dnl Now the hard part, how to link?
 722                 dnl
 723                 dnl currently supported checks:
 724                 dnl
 725                 dnl Check for no flags
 726                 dnl     pthread_create() in $LIBS
 727                 dnl
 728                 dnl Check special pthread (final) flags
 729                 dnl     pthread_create() with -mt (Solaris)
 730                 dnl     pthread_create() with -kthread (FreeBSD)
 731                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 732                 dnl     pthread_create() with -pthreads (?)
 733                 dnl     pthread_create() with -thread (?)
 734                 dnl
 735                 dnl Check pthread (final) libraries
 736                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 737                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 738                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 739                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 740                 dnl     pthread_create() in -lpthread (many)
 741                 dnl     pthread_create() in -lc_r (FreeBSD)
 742                 dnl
 743                 dnl Check pthread (draft4) flags (depreciated)
 744                 dnl     pthread_create() with -threads (OSF/1)
 745                 dnl
 746                 dnl Check pthread (draft4) libraries (depreciated)
 747                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 748                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 749                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 750                 dnl     pthread_create() in -lpthreads (many)
 751                 dnl
 752
 753                 dnl pthread_create in $LIBS
 754                 AC_MSG_CHECKING([for pthread_create in default libraries])
 755                 AC_CACHE_VAL(ol_cv_pthread_create,[
 756                 AC_TRY_RUN([
 757 #include <pthread.h>
 758 #ifndef NULL
 759 #define NULL (void*)0
 760 #endif
 761
 762 static void *task(p)
 763         void *p;
 764 {
 765         return (void *) (p == NULL);
 766 }
 767
 768 int main(argc, argv)
 769         int argc;
 770         char **argv;
 771 {
 772         pthread_t t;
 773         int status;
 774
 775         /* make sure pthread_create() isn't just a stub */
 776 #if HAVE_PTHREADS_D4
 777         status = pthread_create(&t, pthread_attr_default, task, NULL);
 778 #else
 779         status = pthread_create(&t, NULL, task, NULL);
 780 #endif
 781
 782         if( status ) return status;
 783
 784         /* make sure pthread_detach() isn't just a stub */
 785 #if HAVE_PTHREADS_D4
 786         status = pthread_detach( &t );
 787 #else
 788         status = pthread_detach( t );
 789 #endif
 790
 791         if( status ) return status;
 792
 793         return status;
 794 }
 795 ],
 796                         [ol_cv_pthread_create=yes],
 797                         [ol_cv_pthread_create=no],
 798                         [dnl assume yes
 799                         ol_cv_pthread_create=yes])])
 800                 AC_MSG_RESULT($ol_cv_pthread_create)
 801
 802                 if test $ol_cv_pthread_create != no ; then
 803                         ol_link_threads=posix
 804                         ol_link_pthreads=""
 805                 fi
 806
 807                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 808                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 809                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 810                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 811                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 812
 813                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 814                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 815                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 816                         [ol_cv_pthread_lpthread_lmach_lexc])
 817 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 818 dnl                     [ol_cv_pthread_lpthread_lexc])
 819
 820                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 821                         [ol_cv_pthread_lib_lpthread_woff])
 822
 823                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 824                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 825
 826                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 827
 828                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 829                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 830                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 831                         [ol_cv_pthread_lpthreads_lmach_lexc])
 832                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 833                         [ol_cv_pthread_lpthreads_lexc])
 834
 835                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 836
 837                 if test $ol_link_threads != no ; then
 838                         AC_DEFINE(HAVE_PTHREADS,1,
 839                                 [define if you have POSIX Threads])
 840
 841                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 842
 843                         dnl save flags
 844                         save_CPPFLAGS="$CPPFLAGS"
 845                         save_LIBS="$LIBS"
 846                         LIBS="$LTHREAD_LIBS $LIBS"
 847
 848                         dnl All POSIX Thread (final) implementations should have
 849                         dnl sched_yield instead of pthread yield.
 850                         dnl check for both
 851                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 852
 853                         if test $ac_cv_func_sched_yield = no -a \
 854                                 $ac_cv_func_pthread_yield = no ; then
 855                                 dnl Digital UNIX has sched_yield() in -lrt
 856                                 AC_CHECK_LIB(rt, sched_yield,
 857                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 858                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 859                                         ac_cv_func_sched_yield=yes],
 860                                         [ac_cv_func_sched_yield=no])
 861                         fi
 862                         if test $ac_cv_func_sched_yield = no -a \
 863                                 $ac_cv_func_pthread_yield = no ; then
 864                                 dnl Solaris has sched_yield() stub in -lposix4
 865                                 dnl but we'll use thr_yield instead.
 866                                 AC_CHECK_FUNCS(thr_yield)
 867                         fi
 868                         if test $ac_cv_func_sched_yield = no -a \
 869                                 $ac_cv_func_pthread_yield = no -a \
 870                                 "$ac_cv_func_thr_yield" = no ; then
 871                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 872                         fi
 873
 874                         dnl Check functions for compatibility
 875                         AC_CHECK_FUNCS(pthread_kill)
 876
 877                         dnl Check for pthread_detach with <pthread.h> inclusion
 878                         dnl as it's symbol may have been mangled.
 879                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 880                                 [ol_cv_func_pthread_detach], [
 881                                 dnl save the flags
 882                                 AC_TRY_LINK([
 883 #include <pthread.h>
 884 #ifndef NULL
 885 #define NULL (void*)0
 886 #endif
 887 ],
 888                                         [pthread_detach(NULL);],
 889                                         [ol_cv_func_pthread_detach=yes],
 890                                         [ol_cv_func_pthread_detach=no])
 891                         ])
 892
 893                         if test $ol_cv_func_pthread_detach = no ; then
 894                                 AC_MSG_ERROR([could not locate pthread_detach()])
 895                         fi
 896
 897                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 898                                 [define if you have pthread_detach function])
 899
 900                         dnl Check for setconcurreny functions
 901                         AC_CHECK_FUNCS( \
 902                                 pthread_setconcurrency \
 903                                 pthread_getconcurrency \
 904                                 thr_setconcurrency \
 905                                 thr_getconcurrency \
 906                         )
 907
 908                         OL_SYS_LINUX_THREADS
 909                         OL_LINUX_THREADS
 910
 911                         if test $ol_cv_linux_threads = error; then
 912                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 913                         fi
 914
 915                         AC_MSG_CHECKING([if pthread_create() works])
 916                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 917                         AC_TRY_RUN([
 918 #include <pthread.h>
 919 #ifndef NULL
 920 #define NULL (void*)0
 921 #endif
 922
 923 static void *task(p)
 924         void *p;
 925 {
 926         return (void *) (p == NULL);
 927 }
 928
 929 int main(argc, argv)
 930         int argc;
 931         char **argv;
 932 {
 933         pthread_t t;
 934 #if HAVE_PTHREADS_D4
 935         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 936 #else
 937         exit(pthread_create(&t, NULL, task, NULL));
 938 #endif
 939 }
 940 ],
 941                                 [ol_cv_pthread_create_works=yes],
 942                                 [ol_cv_pthread_create_works=no],
 943                                 [dnl assume yes
 944                                 ol_cv_pthread_create_works=yes])])
 945                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 946
 947                         if test $ol_cv_pthread_create_works = no ; then
 948                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 949                         fi
 950
 951                         dnl Check if select causes an yield
 952                         if test $ol_with_yielding_select = auto ; then
 953                                 AC_MSG_CHECKING([if select yields when using pthreads])
 954                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 955                                 AC_TRY_RUN([
 956 #include <sys/types.h>
 957 #include <sys/time.h>
 958 #include <unistd.h>
 959 #include <pthread.h>
 960 #ifndef NULL
 961 #define NULL (void*) 0
 962 #endif
 963
 964 static int fildes[2];
 965
 966 static void *task(p)
 967         void *p;
 968 {
 969         int i;
 970         struct timeval tv;
 971
 972         fd_set rfds;
 973
 974         tv.tv_sec=10;
 975         tv.tv_usec=0;
 976
 977         FD_ZERO(&rfds);
 978         FD_SET(fildes[0], &rfds);
 979
 980         /* we're not interested in any fds */
 981         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 982
 983         if(i < 0) {
 984                 perror("select");
 985                 exit(10);
 986         }
 987
 988         exit(0); /* if we exit here, the select blocked the whole process */
 989 }
 990
 991 int main(argc, argv)
 992         int argc;
 993         char **argv;
 994 {
 995         pthread_t t;
 996
 997         /* create a pipe to select */
 998         if(pipe(&fildes[0])) {
 999                 perror("select");
1000                 exit(1);
1001         }
1002
1003 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1004         (void) pthread_setconcurrency(2);
1005 #else
1006 #ifdef HAVE_THR_SETCONCURRENCY
1007         /* Set Solaris LWP concurrency to 2 */
1008         thr_setconcurrency(2);
1009 #endif
1010 #endif
1011
1012 #if HAVE_PTHREADS_D4
1013         pthread_create(&t, pthread_attr_default, task, NULL);
1014 #else
1015         pthread_create(&t, NULL, task, NULL);
1016 #endif
1017
1018 #if HAVE_SCHED_YIELD
1019         sched_yield();  /* make sure task runs first */
1020 #else
1021 #ifdef HAVE_PTHREAD_YIELD
1022         pthread_yield();        /* make sure task runs first */
1023 #endif
1024 #endif
1025
1026         exit(2);
1027 }],
1028                                 [ol_cv_pthread_select_yields=no],
1029                                 [ol_cv_pthread_select_yields=yes], [
1030                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
1031                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
1032
1033                                 if test $ol_cv_pthread_select_yields = yes ; then
1034                                         ol_with_yielding_select=yes
1035                                 fi
1036                         fi
1037
1038                         dnl restore flags
1039                         CPPFLAGS="$save_CPPFLAGS"
1040                         LIBS="$save_LIBS"
1041                 else
1042                         AC_MSG_ERROR([could not link with POSIX Threads])
1043                 fi
1044         fi
1045
1046         if test $ol_with_threads = posix ; then
1047                 AC_MSG_ERROR([could not locate POSIX Threads])
1048         fi
1049 fi
1050
1051 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1052         -o $ol_with_threads = mach ; then
1053
1054         dnl check for Mach CThreads
1055         AC_CHECK_HEADERS(mach/cthreads.h)
1056         if test $ac_cv_header_mach_cthreads_h = yes ; then
1057                 ol_with_threads=found
1058
1059                 dnl check for cthread support in current $LIBS
1060                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1061
1062                 if test $ol_link_threads = no ; then
1063                         dnl try -all_load
1064                         dnl this test needs work
1065                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1066                                 [ol_cv_cthread_all_load], [
1067                                 dnl save the flags
1068                                 save_LIBS="$LIBS"
1069                                 LIBS="-all_load $LIBS"
1070                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1071                                         cthread_fork((void *)0, (void *)0);
1072                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1073                                 dnl restore the LIBS
1074                                 LIBS="$save_LIBS"
1075                         ])
1076
1077                         if test $ol_cv_cthread_all_load = yes ; then
1078                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1079                                 ol_link_threads=mach
1080                         fi
1081                 fi
1082
1083                 if test $ol_link_threads != no ; then
1084                         : check for cthread specific functionality here
1085                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1086                                 [define if you have Mach Cthreads])
1087                 else
1088                         AC_MSG_ERROR([could not link with Mach CThreads])
1089                 fi
1090         fi
1091
1092         if test $ol_with_threads = mach ; then
1093                 AC_MSG_ERROR([could not locate Mach CThreads])
1094         fi
1095 fi
1096
1097 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1098         -o $ol_with_threads = lwp ; then
1099
1100         dnl check for SunOS5 LWP
1101         AC_CHECK_HEADERS(thread.h synch.h)
1102         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1103                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1104
1105                 if test $have_thr = yes ; then
1106                         AC_DEFINE(HAVE_THR,1,
1107                                 [if you have Solaris LWP (thr) package])
1108                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1109                         ol_link_threads=thr
1110
1111                         if test $ol_with_yielding_select = auto ; then
1112                                 ol_with_yielding_select=yes
1113                         fi
1114
1115                         dnl Check for setconcurreny functions
1116                         AC_CHECK_FUNCS( \
1117                                 thr_setconcurrency \
1118                                 thr_getconcurrency \
1119                         )
1120                 fi
1121         fi
1122
1123         dnl check for SunOS4 LWP
1124         AC_CHECK_HEADERS(lwp/lwp.h)
1125         if test $ac_cv_header_lwp_lwp_h = yes ; then
1126                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1127
1128                 if test $have_lwp = yes ; then
1129                         AC_DEFINE(HAVE_LWP,1,
1130                                 [if you have SunOS LWP package])
1131                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1132                         ol_link_threads=lwp
1133
1134                         if test $ol_with_yielding_select = auto ; then
1135                                 ol_with_yielding_select=no
1136                         fi
1137                 fi
1138         fi
1139 fi
1140
1141 if test $ol_with_yielding_select = yes ; then
1142         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1143                 [define if select implicitly yields])
1144 fi
1145
1146 if test $ol_with_threads = manual ; then
1147         dnl User thinks he can manually configure threads.
1148         ol_link_threads=yes
1149
1150         AC_MSG_WARN([thread defines and link options must be set manually])
1151
1152         AC_CHECK_HEADERS(pthread.h sched.h)
1153         AC_CHECK_FUNCS(sched_yield pthread_yield)
1154         OL_HEADER_LINUX_THREADS
1155
1156         AC_CHECK_HEADERS(mach/cthreads.h)
1157         AC_CHECK_HEADERS(lwp/lwp.h)
1158         AC_CHECK_HEADERS(thread.h synch.h)
1159 fi
1160
1161 if test $ol_link_threads != no ; then
1162         dnl needed to get reentrant/threadsafe versions
1163         dnl
1164         AC_DEFINE(REENTRANT,1)
1165         AC_DEFINE(_REENTRANT,1)
1166         AC_DEFINE(THREAD_SAFE,1)
1167         AC_DEFINE(_THREAD_SAFE,1)
1168         AC_DEFINE(THREADSAFE,1)
1169         AC_DEFINE(_THREADSAFE,1)
1170
1171         dnl The errno declaration may dependent upon _REENTRANT.
1172         dnl If it does, we must link with thread support.
1173         AC_CACHE_CHECK([for thread specific errno],
1174                 [ol_cv_errno_thread_specific], [
1175                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1176                         [ol_cv_errno_thread_specific=yes],
1177                         [ol_cv_errno_thread_specific=no])
1178         ])
1179
1180         dnl The h_errno declaration may dependent upon _REENTRANT.
1181         dnl If it does, we must link with thread support.
1182         AC_CACHE_CHECK([for thread specific h_errno],
1183                 [ol_cv_h_errno_thread_specific], [
1184                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1185                         [ol_cv_h_errno_thread_specific=yes],
1186                         [ol_cv_h_errno_thread_specific=no])
1187         ])
1188
1189         if test $ol_cv_errno_thread_specific != yes \
1190                 -o $ol_cv_h_errno_thread_specific != yes ; then
1191                 LIBS="$LTHREAD_LIBS $LIBS"
1192                 LTHREAD_LIBS=""
1193         fi
1194
1195 dnl When in thread environment, use
1196 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1197 dnl                     || defined( HAVE_FUNC_R )
1198 dnl                     func_r(...);
1199 dnl             #else
1200 dnl             #       if defined( HAVE_THREADS )
1201 dnl                             /* lock */
1202 dnl             #       endif
1203 dnl                             func(...);
1204 dnl             #       if defined( HAVE_THREADS )
1205 dnl                             /* unlock */
1206 dnl             #       endif
1207 dnl             #endif
1208 dnl
1209 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1210 dnl             _POSIX_REENTRANT_FUNCTIONS
1211 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1212 dnl             _POSIX_THREADSAFE_FUNCTIONS
1213 dnl
1214 dnl             and is currently defined in lthread.h
1215 dnl
1216 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1217 dnl
1218 dnl libldap/*.c should only include <lthread.h> iff
1219 dnl LDAP_R_COMPILE is defined.  ie:
1220 dnl             #ifdef LDAP_R_COMPILE
1221 dnl             #       include LDAP_R_COMPILE
1222 dnl             #endif
1223 dnl
1224 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1225 dnl specifically for compiling the threadsafe version of
1226 dnl     the ldap library (-lldap_r).
1227 dnl
1228 dnl     dnl check for reentrant/threadsafe functions
1229 dnl     dnl
1230 dnl     dnl note: these should only be used when linking
1231 dnl     dnl       with $LTHREAD_LIBS
1232 dnl     dnl
1233 dnl     save_CPPFLAGS="$CPPFLAGS"
1234 dnl     save_LIBS="$LIBS"
1235 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1236 dnl     AC_CHECK_FUNCS( \
1237 dnl             gmtime_r \
1238 dnl             gethostbyaddr_r gethostbyname_r \
1239 dnl             feof_unlocked unlocked_feof \
1240 dnl             putc_unlocked unlocked_putc \
1241 dnl             flockfile ftrylockfile \
1242 dnl     )
1243 dnl     CPPFLAGS="$save_CPPFLAGS"
1244 dnl     LIBS="$save_LIBS"
1245 fi
1246
1247 if test $ol_link_threads = no ; then
1248         if test $ol_with_threads = yes ; then
1249                 AC_MSG_ERROR([no suitable thread support])
1250         fi
1251
1252         if test $ol_with_threads = auto ; then
1253                 AC_MSG_WARN([no suitable thread support, disabling threads])
1254                 ol_with_threads=no
1255         fi
1256
1257         AC_DEFINE(NO_THREADS,1,
1258                 [define if you have (or want) no threads])
1259         LTHREAD_LIBS=""
1260 fi
1261
1262 if test $ol_link_threads != no ; then
1263         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1264 fi
1265
1266 dnl ----------------------------------------------------------------
1267
1268 ol_link_ldbm=no
1269 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1270         OL_BERKELEY_DB2
1271
1272         if test $ol_cv_berkeley_db2 = yes ; then
1273                 ol_link_ldbm=db2
1274                 ol_with_ldbm_api=db2
1275
1276                 if test $ol_with_ldbm_type = hash ; then
1277                         AC_DEFINE(LDBM_USE_DBHASH,1)
1278                 else
1279                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1280                 fi
1281
1282                 dnl $ol_cv_lib_db2 should be yes or -ldb
1283                 dnl (it could be no, but that would be an error
1284                 if test $ol_cv_lib_db2 != yes ; then
1285                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1286                 fi
1287         fi
1288 fi
1289
1290 ol_link_bdb2=no
1291 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1292         ol_link_bdb2=yes
1293 fi
1294
1295 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1296         OL_BERKELEY_DB
1297
1298         if test $ol_cv_berkeley_db = yes ; then
1299                 ol_link_ldbm=db
1300                 ol_with_ldbm_api=db
1301
1302                 if test $ol_with_ldbm_type = hash ; then
1303                         AC_DEFINE(LDBM_USE_DBHASH,1)
1304                 else
1305                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1306                 fi
1307
1308                 dnl $ol_cv_lib_db should be yes or -ldb
1309                 dnl (it could be no, but that would be an error
1310                 if test $ol_cv_lib_db != yes ; then
1311                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1312                 fi
1313         fi
1314 fi
1315
1316 if test $ol_with_ldbm_api = manual ; then
1317         dnl User thinks he can manually configure LDBM api.
1318         ol_link_ldbm=yes
1319
1320         AC_MSG_WARN([LDBM defines and link options must be set manually])
1321
1322         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1323 fi
1324
1325 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1326         AC_MSG_WARN(Could not find LDBM with BTREE support)
1327         ol_with_ldbm_api=none
1328 fi
1329
1330 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1331         OL_MDBM
1332
1333         if test $ol_cv_mdbm = yes ; then
1334                 ol_link_ldbm=mdbm
1335                 ol_with_ldbm_api=mdbm
1336                 if test $ol_cv_lib_mdbm != yes ; then
1337                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1338                 fi
1339         fi
1340 fi
1341
1342 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1343         OL_GDBM
1344
1345         if test $ol_cv_gdbm = yes ; then
1346                 ol_link_ldbm=gdbm
1347                 ol_with_ldbm_api=gdbm
1348
1349                 if test $ol_cv_lib_gdbm != yes ; then
1350                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1351                 fi
1352         fi
1353 fi
1354
1355 if test $ol_with_ldbm_api = auto ; then
1356         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1357 elif test $ol_with_ldbm_api = ndbm ; then
1358         OL_NDBM
1359
1360         if test $ol_cv_ndbm = yes ; then
1361                 ol_link_ldbm=ndbm
1362                 ol_with_ldbm_api=ndbm
1363
1364                 if test $ol_cv_lib_ndbm != yes ; then
1365                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1366                 fi
1367         fi
1368 fi
1369
1370 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1371         AC_MSG_WARN(could not find suitable LDBM backend)
1372         if test $ol_enable_ldbm = yes ; then
1373                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1374         fi
1375
1376         AC_MSG_WARN(disabling LDBM)
1377         ol_enable_ldbm=no
1378 fi
1379
1380 if test $ol_enable_wrappers != no ; then
1381         AC_CHECK_HEADERS(tcpd.h)
1382
1383         if test $ac_cv_header_tcpd_h != yes ; then
1384                 have_wrappers=no
1385         else
1386                 AC_CHECK_LIB(wrap, main,
1387                         [have_wrappers=yes], [have_wrappers=no])
1388         fi
1389
1390         if test $have_wrappers = yes ; then
1391                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1392                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1393
1394                 dnl We add another check for -lnsl since some libwrap's
1395                 dnl need it, but it isn't always included from above
1396                 AC_CHECK_LIB(nsl, main)
1397         else
1398                 AC_MSG_WARN(could not find -lwrap)
1399                 if test $ol_enable_wrappers = yes ; then
1400                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1401                 fi
1402
1403                 AC_MSG_WARN(disabling wrappers support)
1404                 ol_enable_wrappers=no
1405         fi
1406 fi
1407
1408 if test $ol_enable_syslog != no ; then
1409         AC_CHECK_FUNC(openlog)
1410         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1411                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1412         fi
1413         ol_enable_syslog=$ac_cv_func_openlog
1414 fi
1415
1416 if test $ol_enable_dmalloc != no ; then
1417         AC_CHECK_HEADERS(dmalloc.h)
1418         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1419 fi
1420
1421 if test $ol_enable_tcl != no ; then
1422         AC_CHECK_HEADERS(tcl.h)
1423
1424         if test $ac_cv_header_tcl_h != yes ; then
1425                 have_tcl=no
1426         else
1427                 AC_CHECK_LIB(tcl,main,
1428                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1429                         [have_tcl=no])
1430
1431                 if test $have_tcl != yes; then
1432                         AC_CHECK_LIB(tcl7.6,main,
1433                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1434                                 [have_tcl=no])
1435                 fi
1436
1437                 if test $have_tcl != yes; then
1438                         AC_CHECK_LIB(tcl8.0,main,
1439                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1440                                 [have_tcl=no])
1441                 fi
1442         fi
1443
1444         if test $have_tcl != yes ; then
1445                 AC_MSG_WARN([could not find -ltcl])
1446                 if test $ol_enable_tcl = yes ; then
1447                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1448                 fi
1449
1450                 ol_enable_tcl=no
1451         fi
1452 fi
1453
1454 # ud needs termcap (should insert check here)
1455 ol_link_termcap=no
1456 AC_CHECK_HEADERS(termcap.h ncurses.h)
1457
1458 if test $ol_link_termcap = no ; then
1459         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1460         if test $have_termcap = yes ; then
1461                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1462                 ol_link_termcap=yes
1463                 TERMCAP_LIBS=-ltermcap
1464         fi
1465 fi
1466
1467 if test $ol_link_termcap = no ; then
1468         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1469         if test $have_ncurses = yes ; then
1470                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1471                 ol_link_termcap=yes
1472                 TERMCAP_LIBS=-lncurses
1473         fi
1474 fi
1475
1476 if test $ol_link_termcap = no ; then
1477         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1478         TERMCAP_LIBS=
1479 fi
1480
1481 dnl
1482 dnl Check for GNU readline
1483 dnl
1484 ol_link_readline=no
1485 if test $ol_with_readline != no ; then
1486         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1487
1488         if test $ac_cv_header_readline_readline_h = yes ; then
1489                 save_LIBS="$LIBS"
1490                 LIBS="$TERMCAP_LIBS $LIBS"
1491                 AC_CHECK_LIB(readline, readline,
1492                         [have_readline=yes], [have_readline=no])
1493                 LIBS="$save_LIBS"
1494
1495                 if test $have_readline = yes ; then
1496                         ol_with_readline=found
1497                         ol_link_readline=yes
1498
1499                         READLINE_LIBS="-lreadline"
1500                 fi
1501         fi
1502 fi
1503
1504 if test $ol_link_readline = yes ; then
1505         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1506 fi
1507
1508
1509 # FreeBSD (and others) have crypt(3) in -lcrypt
1510 if test $ol_enable_crypt != no ; then
1511         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1512                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1513                         have_crypt=yes], [have_crypt=no])])
1514
1515         if test $have_crypt = yes ; then
1516                 AC_DEFINE(HAVE_CRYPT,1)
1517         else
1518                 AC_MSG_WARN(could not find crypt)
1519                 if test $ol_enable_crypt = yes ; then
1520                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1521                 fi
1522
1523                 AC_MSG_WARN(disabling crypt support)
1524                 ol_enable_crypt=no
1525         fi
1526 fi
1527
1528 # FreeBSD (and others) have setproctitle(3) in -lutil
1529 if test $ol_enable_proctitle != no ; then
1530         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1531                 AC_CHECK_LIB(util, setproctitle,
1532                         [have_setproctitle=yes
1533                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1534                         [have_setproctitle=no
1535                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1536
1537         if test $have_setproctitle = yes ; then
1538                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1539         fi
1540 fi
1541
1542 dnl ----------------------------------------------------------------
1543 dnl Checks for header files.
1544 OL_HEADER_STDC
1545
1546 if test $ol_cv_header_stdc != yes; then
1547         AC_MSG_WARN([could not locate Standard C compliant headers])
1548 fi
1549
1550 AC_HEADER_DIRENT
1551 AC_HEADER_SYS_WAIT
1552 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1553 if test $am_cv_sys_posix_termios = yes ; then
1554         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1555                 [define if you have POSIX termios])
1556 fi
1557
1558 AC_CHECK_HEADERS(       \
1559         arpa/inet.h             \
1560         arpa/nameser.h  \
1561         assert.h                \
1562         crypt.h                 \
1563         errno.h                 \
1564         fcntl.h                 \
1565         filio.h                 \
1566         getopt.h                \
1567         grp.h                   \
1568         libutil.h               \
1569         limits.h                \
1570         locale.h                \
1571         malloc.h                \
1572         memory.h                \
1573         psap.h                  \
1574         pwd.h                   \
1575         resolv.h                \
1576         sgtty.h                 \
1577         stdarg.h                \
1578         stddef.h                \
1579         string.h                \
1580         strings.h               \
1581         sysexits.h              \
1582         sys/file.h              \
1583         sys/filio.h             \
1584         sys/errno.h             \
1585         sys/ioctl.h             \
1586         sys/param.h             \
1587         sys/resource.h  \
1588         sys/select.h    \
1589         sys/socket.h    \
1590         sys/syslog.h    \
1591         sys/time.h              \
1592         sys/types.h             \
1593         syslog.h                \
1594         termios.h               \
1595         unistd.h                \
1596 )
1597
1598 dnl ----------------------------------------------------------------
1599 dnl Checks for typedefs, structures, and compiler characteristics.
1600 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1601 AC_TYPE_MODE_T
1602 AC_TYPE_OFF_T
1603 AC_TYPE_PID_T
1604 AM_TYPE_PTRDIFF_T
1605 AC_TYPE_SIGNAL
1606 OL_TYPE_SIG_ATOMIC_T
1607 AC_TYPE_SIZE_T
1608 AC_STRUCT_ST_BLKSIZE
1609 AC_HEADER_TIME
1610 AC_STRUCT_TM
1611 OL_STRUCT_PASSWD_PW_GECOS
1612
1613 OL_C_UPPER_LOWER
1614 AC_C_CONST
1615 OL_C_VOLATILE
1616
1617 if test $cross_compiling = yes ; then
1618         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1619 else
1620         AC_C_BIGENDIAN
1621         AC_CHECK_SIZEOF(short)
1622         AC_CHECK_SIZEOF(int)
1623         AC_CHECK_SIZEOF(long)
1624
1625         if test "$ac_cv_sizeof_int" -lt 4 ; then
1626                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1627         fi
1628 fi
1629
1630 dnl ----------------------------------------------------------------
1631 dnl Checks for library functions.
1632 AC_FUNC_MEMCMP
1633 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1634 AC_FUNC_STRFTIME
1635 dnl AM_FUNC_STRTOD
1636
1637 dnl we should use vfork instead of fork in a number of places...
1638 dnl AC_FUNC_VFORK
1639 AC_FUNC_VPRINTF
1640
1641 if test $ac_cv_func_vprintf = yes ; then
1642         dnl check for vsnprintf
1643         AC_CHECK_FUNCS(vsnprintf vsprintf)
1644 fi
1645
1646 AC_CHECK_FUNCS(         \
1647         bcopy                   \
1648         closesocket             \
1649         endgrent                \
1650         endpwent                \
1651         flock                   \
1652         getdtablesize   \
1653         getgrgid                \
1654         gethostname             \
1655         getpass                 \
1656         getpwuid                \
1657         gettimeofday    \
1658         initgroups              \
1659         lockf                   \
1660         memcpy                  \
1661         memmove                 \
1662         mkstemp                 \
1663         recv                    \
1664         recvfrom                \
1665         setpwfile               \
1666         setgid                  \
1667         setegid                 \
1668         setsid                  \
1669         setuid                  \
1670         seteuid                 \
1671         signal                  \
1672         sigset                  \
1673         snprintf                \
1674         strdup                  \
1675         strerror                \
1676         strpbrk                 \
1677         strrchr                 \
1678         strsep                  \
1679         strstr                  \
1680         strtol                  \
1681         strtoul                 \
1682         strspn                  \
1683         sysconf                 \
1684         waitpid                 \
1685         wait4                   \
1686 )
1687
1688 dnl We actually may need to replace more than this.
1689 AC_REPLACE_FUNCS(getopt tempnam)
1690
1691 dnl ----------------------------------------------------------------
1692 # Check Configuration
1693 OL_SYS_ERRLIST
1694
1695 dnl ----------------------------------------------------------------
1696 dnl Sort out defines
1697
1698 if test "$ol_enable_debug" != no ; then
1699         AC_DEFINE(LDAP_DEBUG,1)
1700 fi
1701 if test "$ol_enable_syslog" = yes ; then
1702         AC_DEFINE(LDAP_SYSLOG,1)
1703 fi
1704 if test "$ol_enable_libui" = yes ; then
1705         AC_DEFINE(LDAP_LIBUI,1)
1706 fi
1707 if test "$ol_enable_cache" = no ; then
1708         AC_DEFINE(LDAP_NOCACHE,1)
1709 fi
1710 if test "$ol_enable_dns" != no ; then
1711         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1712 fi
1713 if test "$ol_enable_proctitle" != no ; then
1714         AC_DEFINE(LDAP_PROCTITLE,1)
1715 fi
1716 if test "$ol_enable_referrals" != no ; then
1717         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1718 fi
1719 if test "$ol_enable_cldap" != no ; then
1720         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1721 fi
1722
1723 if test "$ol_enable_aclgroups" != no ; then
1724         AC_DEFINE(SLAPD_ACLGROUPS,1)
1725 fi
1726 if test "$ol_enable_crypt" != no ; then
1727         AC_DEFINE(SLAPD_CRYPT,1)
1728 fi
1729 if test "$ol_enable_cleartext" != no ; then
1730         AC_DEFINE(SLAPD_CLEARTEXT,1)
1731 fi
1732 if test "$ol_enable_phonetic" != no ; then
1733         AC_DEFINE(SLAPD_PHONETIC,1)
1734 fi
1735 if test "$ol_enable_rlookups" != no ; then
1736         AC_DEFINE(SLAPD_RLOOKUPS,1)
1737 fi
1738
1739 if test "$ol_link_modules" != no ; then
1740         AC_DEFINE(SLAPD_MODULES,1)
1741         BUILD_SLAPD=yes
1742 fi
1743
1744 if test "$ol_link_bdb2" != no ; then
1745         AC_DEFINE(SLAPD_BDB2,1)
1746         BUILD_SLAPD=yes
1747         BUILD_BDB2=yes
1748 fi
1749
1750 if test "$ol_enable_ldap" != no ; then
1751         AC_DEFINE(SLAPD_LDAP,1)
1752         BUILD_SLAPD=yes
1753         BUILD_LDAP=yes
1754 fi
1755
1756 if test "$ol_link_ldbm" != no ; then
1757         AC_DEFINE(SLAPD_LDBM,1)
1758         BUILD_SLAPD=yes
1759         BUILD_LDBM=yes
1760 fi
1761
1762 if test "$ol_enable_passwd" != no ; then
1763         AC_DEFINE(SLAPD_PASSWD,1)
1764         BUILD_SLAPD=yes
1765         BUILD_PASSWD=yes
1766 fi
1767
1768 if test "$ol_link_perl" != no ; then
1769         AC_DEFINE(SLAPD_PERL,1)
1770         BUILD_SLAPD=yes
1771         BUILD_PERL=yes
1772 fi
1773
1774 if test "$ol_enable_shell" != no ; then
1775         AC_DEFINE(SLAPD_SHELL,1)
1776         BUILD_SLAPD=yes
1777         BUILD_SHELL=yes
1778 fi
1779
1780 if test "$ol_enable_tcl" != no ; then
1781         AC_DEFINE(SLAPD_TCL,1)
1782         BUILD_SLAPD=yes
1783         BUILD_TCL=yes
1784 fi
1785
1786 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1787         $BUILD_SLAPD = yes ; then
1788         BUILD_SLURPD=yes
1789 fi
1790
1791 if test "$ol_link_isode" != no ; then
1792         BUILD_LDAPD=yes
1793 fi
1794
1795 dnl ----------------------------------------------------------------
1796
1797 AC_SUBST(BUILD_LDAPD)
1798 AC_SUBST(BUILD_SLAPD)
1799   AC_SUBST(BUILD_BDB2)
1800   AC_SUBST(BUILD_LDAP)
1801   AC_SUBST(BUILD_LDBM)
1802   AC_SUBST(BUILD_PASSWD)
1803   AC_SUBST(BUILD_PERL)
1804   AC_SUBST(BUILD_SHELL)
1805   AC_SUBST(BUILD_TCL)
1806 AC_SUBST(BUILD_SLURPD)
1807
1808 AC_SUBST(LDAP_LIBS)
1809 AC_SUBST(LDAPD_LIBS)
1810 AC_SUBST(SLAPD_LIBS)
1811 AC_SUBST(SLURPD_LIBS)
1812 AC_SUBST(LDBM_LIBS)
1813 AC_SUBST(LTHREAD_LIBS)
1814 AC_SUBST(LUTIL_LIBS)
1815
1816 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1817 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1818
1819 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1820 AC_SUBST(SLAPD_PERL_LDFLAGS)
1821
1822 AC_SUBST(KRB_LIBS)
1823 AC_SUBST(READLINE_LIBS)
1824 AC_SUBST(TERMCAP_LIBS)
1825 AC_SUBST(TLS_LIBS)
1826
1827 dnl ----------------------------------------------------------------
1828 dnl final output
1829 dnl
1830
1831 AC_OUTPUT( \
1832 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1833 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1834 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1835 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1836 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1837 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1838 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1839 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1840 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1841 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1842 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1843 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1844 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1845 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1846 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1847 include/Makefile:build/top.mk:include/Makefile.in \
1848 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1849 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1850 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1851 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1852 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1853 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1854 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1855 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1856 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1857 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1858 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1859 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1860 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/srv.mk \
1861 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1862 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1863 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1864 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1865 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1866 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1867 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1868 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1869 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1870 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1871 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1872 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1873 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1874 ,[
1875 date > stamp-h
1876 echo Please \"make depend\" to build dependencies
1877 ])