git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2003 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms, with or without
   6 dnl modification, are permitted only as authorized by the OpenLDAP
   7 dnl Public License.  A copy of this license is available at
   8 dnl http://www.OpenLDAP.org/license.html or in file LICENSE in the
   9 dnl top-level directory of the distribution.
  10 dnl
  11 dnl ----------------------------------------------------------------
  12 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  13 dnl at top of generated configure script.  Prints simple copyright.
  14 define([AC_INIT_BINSH],
  15 [[#! /bin/sh
  16 # $]OpenLDAP[$
  17 # from] translit([$OpenLDAP$], $")] [
  18
  19 # Copyright 1998-2003 The OpenLDAP Foundation.  All Rights Reserved.
  20 #
  21 # Redistribution and use in source and binary forms, with or without
  22 # modification, are permitted only as authorized by the OpenLDAP
  23 # Public License.  A copy of this license is available at
  24 # http://www.OpenLDAP.org/license.html or in file LICENSE in the
  25 # top-level directory of the distribution.
  26
  27 echo "Copyright 1998-2003 The OpenLDAP Foundation,  All Rights Reserved."
  28 echo "  Restrictions apply, see COPYRIGHT and LICENSE files."
  29 ])dnl
  30 dnl ----------------------------------------------------------------
  31 dnl Disable config.cache!
  32 define([AC_CACHE_LOAD], )dnl
  33 define([AC_CACHE_SAVE], )dnl
  34 dnl ================================================================
  35 dnl Configure.in for OpenLDAP
  36 AC_INIT(build/version.sh)dnl
  37
  38 # set unset (borrowed from autoconf 2.49c)
  39 if (OL_FOO=OL_FOO; unset OL_FOO) >/dev/null 2>&1; then
  40   ol_unset=unset
  41 else
  42   ol_unset=false
  43 fi
  44 # unset CDPATH
  45 $ol_unset CDPATH || test "${CDPATH+set}" != set || { CDPATH=:; export CDPATH; }
  46
  47 AC_CONFIG_AUX_DIR(build)dnl
  48
  49 eval `$ac_aux_dir/version.sh`
  50 if test -z "$OL_STRING"; then
  51         AC_MSG_ERROR([could not determine version])
  52 fi
  53
  54 if test -f "$ac_aux_dir/shtool" -a ! -d $ac_aux_dir/shtool; then
  55         ac_cv_shtool="$ac_aux_dir/shtool"
  56 else
  57         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  58 fi
  59
  60 SHTOOL="$ac_cv_shtool"
  61 dnl AC_SUBST(SHTOOL)dnl
  62
  63 TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  64 TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  65
  66 OPENLDAP_CVS=""
  67 if test -d $ac_aux_dir/CVS; then
  68         OPENLDAP_CVS="(from CVS sources) "
  69 fi
  70
  71 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_CVS}..."
  72
  73 dnl Determine host platform
  74 dnl             we try not to use this for much
  75 AC_CANONICAL_SYSTEM
  76
  77 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  78 AC_SUBST(PACKAGE)dnl
  79 AC_SUBST(VERSION)dnl
  80 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  81 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  82
  83 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  84 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  85 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  86 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  87
  88 OPENLDAP_LIBVERSION=$OL_API_LIB
  89 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  90
  91 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  92 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  93
  94 dnl We use autoconf features new to 2.13.
  95 dnl aclocal.m4 should be built using aclocal from automake 1.4
  96 dnl libtool 1.4.2 should be installed.
  97 AC_PREREQ(2.13)dnl Required Autoconf version
  98
  99 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
 100
 101 dnl ================================================================
 102 dnl Start Args
 103 AC_MSG_CHECKING(configure arguments)
 104 AC_PREFIX_DEFAULT(/usr/local)
 105
 106 top_builddir=`pwd`
 107 AC_SUBST(top_builddir)dnl
 108
 109 dnl ----------------------------------------------------------------
 110 dnl --with-subdir
 111 ldap_subdir="/openldap"
 112
 113 AC_ARG_WITH(subdir,
 114 [  --with-subdir=DIR       change default subdirectory used for installs],
 115 [case "$withval" in
 116         no) ldap_subdir=""
 117                 ;;
 118         yes)
 119                 ;;
 120         /*|\\*)
 121                 ldap_subdir="$withval"
 122                 ;;
 123         *)
 124                 ldap_subdir="/$withval"
 125                 ;;
 126 esac
 127 ])dnl
 128
 129 AC_SUBST(ldap_subdir)dnl
 130
 131 dnl ----------------------------------------------------------------
 132 dnl General "enable" options
 133 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes)dnl
 134 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 135 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 136 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 137 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 138 ol_enable_referrals=${ol_enable_referrals-no}
 139 dnl OL_ARG_ENABLE(kbind,[  --enable-kbind         enable LDAPv2+ Kerberos IV bind (deprecated)], no)dnl
 140 ol_enable_kbind=${ol_enable_kbind-no}
 141 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 142 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 143 OL_ARG_ENABLE(x_compile,[  --enable-x-compile     enable cross compiling],
 144         no, [yes no])dnl
 145
 146 dnl ----------------------------------------------------------------
 147 dnl General "with" options
 148 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc     enable debug malloc support], no)dnl
 149
 150 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 151         auto, [auto yes no] )
 152 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 153         auto, [auto yes no] )
 154 dnl OL_ARG_WITH(kerberos,[  --with-kerberos       with Kerberos support],
 155 dnl     auto, [auto k5 k5only k425 kth k4 afs yes no])
 156 ol_with_kerberos=${ol_with_kerberos-auto}
 157 OL_ARG_WITH(readline,[  --with-readline   with readline support],
 158         auto, [auto yes no] )
 159 OL_ARG_WITH(threads,[  --with-threads     with threads],
 160         auto, [auto nt posix mach pth lwp yes no manual] )
 161 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 162         auto, [auto ssleay openssl yes no] )
 163 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 164         auto, [auto yes no manual] )
 165
 166 dnl ----------------------------------------------------------------
 167 dnl Server options
 168 dnl ----------------------------------------------------------------
 169
 170 dnl ----------------------------------------------------------------
 171 dnl SLAPD OPTIONS
 172 AC_ARG_WITH(xxslapdoptions,[
 173 SLAPD (Standalone LDAP Daemon) Options:])
 174 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 175 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no)dnl
 176 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 177 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 178 dnl OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd   enable Kerberos password verification], no)dnl
 179 ol_enable_kpasswd=${ol_enable_kpasswd-no}
 180 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 181 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 182 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 183 dnl OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 184 ol_enable_multimaster=${ol_enable_multimaster-no}
 185 OL_ARG_ENABLE(phonetic,[    --enable-phonetic     enable phonetic/soundex], no)dnl
 186 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and back-meta], no)dnl
 187 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 188 OL_ARG_ENABLE(slp, [    --enable-slp          enable SLPv2 support], no)dnl
 189 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 190
 191 dnl SLAPD Backend options
 192 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend], yes)dnl
 193 OL_ARG_WITH(bdb_module,[    --with-bdb-module     module type static|dynamic], static,
 194         [static dynamic])
 195 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend], no)dnl
 196 OL_ARG_WITH(dnssrv_module,[    --with-dnssrv-module  module type static|dynamic], static,
 197         [static dynamic])
 198 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend], no)dnl
 199 OL_ARG_WITH(ldap_module,[    --with-ldap-module   module type static|dynamic], static,
 200         [static dynamic])
 201 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend], no)dnl
 202 OL_ARG_WITH(ldbm_api,[    --with-ldbm-api       with LDBM API auto|berkeley|bcompat|mdbm|gdbm], auto,
 203         [auto berkeley bcompat mdbm gdbm])
 204 OL_ARG_WITH(ldbm_module,[    --with-ldbm-module   module type static|dynamic], static,
 205         [static dynamic])
 206 OL_ARG_WITH(ldbm_type,[    --with-ldbm-type       use LDBM type auto|btree|hash], auto,
 207         [auto btree hash])
 208 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend], no)dnl
 209 OL_ARG_WITH(meta_module,[    --with-meta-module   module type static|dynamic], static,
 210         [static dynamic])
 211 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend], no)dnl
 212 OL_ARG_WITH(monitor_module,[    --with-monitor-module module type static|dynamic], static,
 213         [static dynamic])
 214 OL_ARG_ENABLE(null,[    --enable-null     enable null backend], no)dnl
 215 OL_ARG_WITH(null_module,[    --with-null-module   module type static|dynamic], static,
 216         [static dynamic])
 217 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend], no)dnl
 218 OL_ARG_WITH(passwd_module,[    --with-passwd-module  module type static|dynamic], static,
 219         [static dynamic])
 220 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend], no)dnl
 221 OL_ARG_WITH(perl_module,[    --with-perl-module   module type static|dynamic], static,
 222         [static dynamic])
 223 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend], no)dnl
 224 OL_ARG_WITH(shell_module,[    --with-shell-module         module type static|dynamic], static,
 225         [static dynamic])
 226 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend], no)dnl
 227 OL_ARG_WITH(sql_module,[    --with-sql-module     module type static|dynamic], static,
 228         [static dynamic])
 229
 230 dnl ----------------------------------------------------------------
 231 dnl SLURPD OPTIONS
 232 AC_ARG_WITH(xxslurpdoptions,[
 233 SLURPD (Replication Daemon) Options:])
 234 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 235
 236 dnl ----------------------------------------------------------------
 237 AC_ARG_WITH(xxliboptions,[
 238 Library Generation & Linking Options])
 239 AC_ENABLE_STATIC
 240 AC_ENABLE_SHARED
 241
 242 dnl ----------------------------------------------------------------
 243
 244 dnl General "enable" options
 245 # validate options
 246 if test $ol_enable_slapd = no ; then
 247         dnl SLAPD was specificallly disabled
 248         if test $ol_enable_bdb = yes ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb argument])
 250         fi
 251         if test $ol_enable_dnssrv = yes ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 253         fi
 254         if test $ol_enable_ldap = yes ; then
 255                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 256         fi
 257         if test $ol_enable_ldbm = yes ; then
 258                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 259         fi
 260         if test $ol_enable_meta = yes ; then
 261                 AC_MSG_WARN([slapd disabled, ignoring --enable-meta argument])
 262         fi
 263         if test $ol_enable_monitor = yes ; then
 264                 AC_MSG_WARN([slapd disabled, ignoring --enable-monitor argument])
 265         fi
 266         if test $ol_enable_null = yes ; then
 267                 AC_MSG_WARN([slapd disabled, ignoring --enable-null argument])
 268         fi
 269         if test $ol_enable_passwd = yes ; then
 270                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 271         fi
 272         if test $ol_enable_perl = yes ; then
 273                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 274         fi
 275         if test $ol_enable_shell = yes ; then
 276                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 277         fi
 278         if test $ol_enable_sql = yes ; then
 279                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 280         fi
 281         if test $ol_enable_modules = yes ; then
 282                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 283         fi
 284         if test $ol_enable_multimaster = yes ; then
 285                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 286         fi
 287         if test $ol_enable_wrappers = yes ; then
 288                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 289         fi
 290         if test $ol_enable_phonetic = yes ; then
 291                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 292         fi
 293         if test $ol_enable_rlookups = yes ; then
 294                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 295         fi
 296         if test $ol_enable_aci = yes ; then
 297                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 298         fi
 299         if test $ol_with_ldbm_api != auto ; then
 300                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 301         fi
 302         if test $ol_with_ldbm_type != auto ; then
 303                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 304         fi
 305         if test $ol_with_bdb_module != static ; then
 306                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb-module argument])
 307         fi
 308         if test $ol_with_dnssrv_module != static ; then
 309                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 310         fi
 311         if test $ol_with_ldap_module != static ; then
 312                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 313         fi
 314         if test $ol_with_ldbm_module != static ; then
 315                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 316         fi
 317         if test $ol_with_meta_module != static ; then
 318                 AC_MSG_WARN([slapd disabled, ignoring --with-meta-module argument])
 319         fi
 320         if test $ol_with_monitor_module != static ; then
 321                 AC_MSG_WARN([slapd disabled, ignoring --with-monitor-module argument])
 322         fi
 323         if test $ol_with_null_module != static ; then
 324                 AC_MSG_WARN([slapd disabled, ignoring --with-null-module argument])
 325         fi
 326         if test $ol_with_passwd_module != static ; then
 327                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 328         fi
 329         if test $ol_with_perl_module != static ; then
 330                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 331         fi
 332         if test $ol_with_shell_module != static ; then
 333                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 334         fi
 335         if test $ol_with_sql_module != static ; then
 336                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 337         fi
 338         if test $ol_enable_slurpd = yes ; then
 339                 AC_MSG_ERROR([slurpd requires slapd])
 340         fi
 341         if test $ol_enable_rewrite = yes ; then
 342                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 343         fi
 344
 345         # force settings to no
 346         ol_enable_bdb=no
 347         ol_enable_dnssrv=no
 348         ol_enable_ldap=no
 349         ol_enable_ldbm=no
 350         ol_enable_meta=no
 351         ol_enable_monitor=no
 352         ol_enable_null=no
 353         ol_enable_passwd=no
 354         ol_enable_perl=no
 355         ol_enable_shell=no
 356         ol_enable_sql=no
 357
 358         ol_enable_modules=no
 359         ol_enable_multimaster=no
 360         ol_enable_phonetic=no
 361         ol_enable_rlookups=no
 362         ol_enable_aci=no
 363         ol_enable_wrappers=no
 364         ol_enable_dynamic=no
 365
 366         ol_with_ldbm_api=no
 367         ol_with_ldbm_type=no
 368
 369         ol_with_bdb_module=static
 370         ol_with_dnssrv_module=static
 371         ol_with_ldap_module=static
 372         ol_with_ldbm_module=static
 373         ol_with_meta_module=static
 374         ol_with_monitor_module=static
 375         ol_with_null_module=static
 376         ol_with_passwd_module=static
 377         ol_with_perl_module=static
 378         ol_with_shell_module=static
 379         ol_with_sql_module=static
 380
 381         ol_enable_slurpd=no
 382
 383         ol_enable_rewrite=no
 384
 385 elif test $ol_enable_ldbm = no ; then
 386         dnl SLAPD without LDBM
 387
 388         if test $ol_with_ldbm_api != auto ; then
 389                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 390         fi
 391
 392         if test $ol_with_ldbm_type != auto ; then
 393                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 394         fi
 395
 396         if test $ol_with_ldbm_module != static ; then
 397                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 398         fi
 399
 400         if test $ol_enable_modules != yes -a \
 401                 $ol_enable_bdb = no -a \
 402                 $ol_enable_dnssrv = no -a \
 403                 $ol_enable_ldap = no -a \
 404                 $ol_enable_meta = no -a \
 405                 $ol_enable_monitor = no -a \
 406                 $ol_enable_null = no -a \
 407                 $ol_enable_passwd = no -a \
 408                 $ol_enable_perl = no -a \
 409                 $ol_enable_shell = no -a \
 410                 $ol_enable_sql = no ; then
 411
 412                 if test $ol_enable_slapd = yes ; then
 413                         AC_MSG_ERROR([slapd requires a backend])
 414                 else
 415                         AC_MSG_WARN([skipping slapd, no backend specified])
 416                         ol_enable_slapd=no
 417                 fi
 418         fi
 419
 420         ol_with_ldbm_api=no
 421         ol_with_ldbm_type=no
 422         ol_with_ldbm_module=static
 423
 424         if test $ol_enable_bdb != no ; then
 425                 ol_with_ldbm_api=berkeley
 426         fi
 427
 428 else
 429         dnl SLAPD with LDBM
 430         if test $ol_with_ldbm_api = gdbm -a \
 431                 $ol_with_ldbm_type = btree ; then
 432                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 433         fi
 434         if test $ol_with_ldbm_api = mdbm -a \
 435                 $ol_with_ldbm_type = btree ; then
 436                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 437         fi
 438         if test $ol_with_ldbm_api = ndbm -a \
 439                 $ol_with_ldbm_type = btree ; then
 440                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 441         fi
 442
 443         if test $ol_enable_bdb = yes ; then
 444                 if test $ol_with_ldbm_api = auto ; then
 445                         ol_with_ldbm_api=berkeley
 446                 elif test $ol_with_ldbm_api != berkeley ; then
 447                         AC_MSG_ERROR([LDBM API not compatible with BDB])
 448                 fi
 449
 450         elif test $ol_enable_bdb = auto ; then
 451                 if test $ol_with_ldbm_api != berkeley \
 452                         -o $ol_with_ldbm_api != auto ; then
 453                         AC_MSG_WARN([LDBM API not compatible with BDB, disabling BDB])
 454                         ol_enable_bdb=no
 455                 fi
 456         fi
 457 fi
 458
 459 if test $ol_enable_slurpd = yes ; then
 460         dnl SLURPD was specifically enabled
 461         if test $ol_with_threads = no ; then
 462                 AC_MSG_ERROR([slurpd requires threads])
 463         fi
 464 fi
 465
 466 if test $ol_enable_lmpasswd = yes ; then
 467         if test $ol_with_tls = no ; then
 468                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 469         fi
 470 fi
 471
 472 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 473         if test $ol_with_kerberos = no ; then
 474                 AC_MSG_ERROR([options require --with-kerberos])
 475         elif test $ol_with_kerberos = auto ; then
 476                 ol_with_kerberos=yes
 477         fi
 478
 479 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 480         if test $ol_with_kerberos = auto ; then
 481                 ol_with_kerberos=no
 482         elif test $ol_with_kerberos != no ; then
 483                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 484                 ol_with_kerberos=no
 485         fi
 486 fi
 487
 488 if test $ol_enable_spasswd = yes ; then
 489         if test $ol_with_cyrus_sasl = no ; then
 490                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 491         fi
 492         ol_with_cyrus_sasl=yes
 493 fi
 494
 495 AC_MSG_RESULT(done)
 496
 497 dnl ----------------------------------------------------------------
 498 dnl Initialize vars
 499 LDAP_LIBS=
 500 LDIF_LIBS=
 501 LDBM_LIBS=
 502 LTHREAD_LIBS=
 503 LUTIL_LIBS=
 504
 505 SLAPD_LIBS=
 506 SLURPD_LIBS=
 507
 508 BUILD_SLAPD=no
 509 BUILD_SLURPD=no
 510
 511 BUILD_THREAD=no
 512
 513 BUILD_BDB=no
 514 BUILD_DNSSRV=no
 515 BUILD_LDAP=no
 516 BUILD_LDBM=no
 517 BUILD_META=no
 518 BUILD_MONITOR=no
 519 BUILD_NULL=no
 520 BUILD_PASSWD=no
 521 BUILD_PERL=no
 522 BUILD_SHELL=no
 523 BUILD_SQL=no
 524
 525 BUILD_BDB_DYNAMIC=static
 526 BUILD_DNSSRV_DYNAMIC=static
 527 BUILD_LDAP_DYNAMIC=static
 528 BUILD_LDBM_DYNAMIC=static
 529 BUILD_META_DYNAMIC=static
 530 BUILD_MONITOR_DYNAMIC=static
 531 BUILD_NULL_DYNAMIC=static
 532 BUILD_PASSWD_DYNAMIC=static
 533 BUILD_PERL_DYNAMIC=static
 534 BUILD_SHELL_DYNAMIC=static
 535 BUILD_SQL_DYNAMIC=static
 536
 537 SLAPD_MODULES_LDFLAGS=
 538 SLAPD_MODULES_CPPFLAGS=
 539
 540 SLAPD_STATIC_BACKENDS=
 541 SLAPD_DYNAMIC_BACKENDS=
 542
 543 SLAPD_PERL_LDFLAGS=
 544 MOD_PERL_LDFLAGS=
 545 PERL_CPPFLAGS=
 546
 547 SLAPD_SQL_LDFLAGS=
 548 SLAPD_SQL_LIBS=
 549 SLAPD_SQL_INCLUDES=
 550
 551 KRB4_LIBS=
 552 KRB5_LIBS=
 553 READLINE_LIBS=
 554 SASL_LIBS=
 555 TERMCAP_LIBS=
 556 TLS_LIBS=
 557 MODULES_LIBS=
 558 AUTH_LIBS=
 559
 560 SLAPD_SLP_LIBS=
 561
 562 dnl ================================================================
 563 dnl Checks for programs
 564
 565 AC_PROG_INSTALL
 566
 567 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 568
 569 dnl ----------------------------------------------------------------
 570 dnl
 571 dnl Determine which C translator to use
 572 dnl
 573
 574 dnl AIX Thread requires we use cc_r or xlc_r.
 575 dnl But only do this IF AIX and CC is not set
 576 dnl and threads are auto|yes|posix.
 577 dnl
 578 dnl If we find cc_r|xlc_r, force pthreads and assume
 579 dnl             pthread_create is in $LIBS (ie: don't bring in
 580 dnl             any additional thread libraries)
 581 dnl If we do not find cc_r|xlc_r, disable threads
 582
 583 ol_aix_threads=no
 584 case "$target" in
 585 *-*-aix*) dnl all AIX is not a good idea.
 586         if test -z "$CC" ; then
 587                 case "$ol_with_threads" in
 588                 auto | yes |  posix) ol_aix_threads=yes ;;
 589                 esac
 590         fi
 591 ;;
 592 esac
 593
 594 if test $ol_aix_threads = yes ; then
 595         if test -z "${CC}" ; then
 596                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 597
 598                 if test "$CC" = cc ; then
 599                         dnl no CC! don't allow --with-threads
 600                         if test $ol_with_threads != auto ; then
 601                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 602                         else
 603                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 604                         fi
 605                         ol_with_threads=no
 606                 fi
 607         fi
 608
 609         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 610                 ol_with_threads=posix
 611                 ol_cv_pthread_create=yes
 612         fi
 613 fi
 614
 615 if test -z "${CC}"; then
 616         AC_CHECK_PROGS(CC,cc gcc,missing)
 617
 618         if test "${CC}" = "missing" ; then
 619                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 620         fi
 621 fi
 622
 623 if test -z "${AR}"; then
 624         AC_CHECK_PROGS(AR,ar gar,missing)
 625
 626         if test "${AR}" = "missing" ; then
 627                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 628         fi
 629 fi
 630
 631 AC_LIBTOOL_WIN32_DLL
 632 AC_LIBTOOL_DLOPEN
 633 AC_PROG_LIBTOOL
 634
 635 OL_PROG_LN_H
 636 AC_PROG_LN_S
 637
 638 dnl ----------------------------------------------------------------
 639 dnl Perl
 640 ol_link_perl=no
 641 if test $ol_enable_perl != no ; then
 642         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 643
 644         if test "no$PERLBIN" = "no" ; then
 645                 if test $ol_enable_perl = yes ; then
 646                         AC_MSG_ERROR([could not locate perl])
 647                 fi
 648
 649         else
 650                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 651                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 652                 if test x"$ol_with_perl_module" = "xstatic" ; then
 653                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 654                 else
 655                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 656                 fi
 657                 dnl should check perl version
 658                 ol_link_perl=yes
 659         fi
 660 fi
 661
 662 AC_PROG_CPP
 663
 664 dnl ----------------------------------------------------------------
 665 dnl Cross compiling checks
 666 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 667         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 668
 669 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 670         AC_MSG_WARN([programs compiled here do run here...])
 671         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 672
 673 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 674         AC_MSG_WARN([programs compiled here do not run here...])
 675         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 676 fi
 677
 678 dnl ----------------------------------------------------------------
 679 dnl Checks for UNIX Variants
 680 dnl AC_AIX
 681 dnl AC_ISC_POSIX
 682 dnl AC_MINIX
 683
 684 dnl ----------------------------------------------------------------
 685 dnl Checks for system services
 686 AC_CYGWIN
 687 AC_MINGW32
 688 AC_EXEEXT
 689 AC_OBJEXT
 690
 691 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 692
 693 dnl ----------------------------------------------------------------
 694 dnl BeOS requires -lbe -lroot -lnet
 695 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 696
 697 dnl ----------------------------------------------------------------
 698 dnl OpenLDAP requires STDC features
 699 AM_PROG_CC_STDC
 700 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 701         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 702 fi
 703
 704 dnl ----------------------------------------------------------------
 705 dnl Check cc depend flags
 706 OL_MKDEPEND
 707 if test "${ol_cv_mkdep}" = no ; then
 708         # this will soon become an error
 709         AC_MSG_WARN([do not know how to generate dependencies])
 710 fi
 711
 712 dnl ----------------------------------------------------------------
 713 dnl Check for AIX security library
 714 AC_CHECK_LIB(s, afopen, [
 715         AUTH_LIBS=-ls
 716         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 717 ])
 718
 719 dnl ----------------------------------------------------------------
 720 dnl Check for IBM OS/390
 721 case "$target" in
 722 *-ibm-openedition)
 723         ac_cv_func_getopt=no
 724         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 725         ;;
 726 esac
 727
 728 dnl ----------------------------------------------------------------
 729 dnl Check for module support
 730 ol_link_modules=no
 731 if test $ol_enable_modules != no ; then
 732         AC_CHECK_HEADERS(ltdl.h)
 733
 734         if test $ac_cv_header_ltdl_h = no ; then
 735                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 736         fi
 737
 738         AC_CHECK_LIB(ltdl, lt_dlinit, [
 739                 MODULES_LIBS=-lltdl
 740                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 741         ])
 742
 743         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 744                 AC_MSG_ERROR([could not locate libtool -lltdl])
 745         fi
 746         ol_link_modules=yes
 747 else
 748         ol_with_bdb_module=static
 749         ol_with_dnssrv_module=static
 750         ol_with_ldap_module=static
 751         ol_with_ldbm_module=static
 752         ol_with_meta_module=static
 753         ol_with_monitor_module=static
 754         ol_with_null_module=static
 755         ol_with_passwd_module=static
 756         ol_with_perl_module=static
 757         ol_with_shell_module=static
 758         ol_with_sql_module=static
 759 fi
 760
 761 dnl ----------------------------------------------------------------
 762 dnl Checks for header files.
 763 OL_HEADER_STDC
 764
 765 if test $ol_cv_header_stdc != yes; then
 766         AC_MSG_WARN([could not locate Standard C compliant headers])
 767 fi
 768
 769 AC_HEADER_DIRENT
 770 AC_HEADER_SYS_WAIT
 771 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 772 if test $am_cv_sys_posix_termios = yes ; then
 773         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 774                 [define if you have POSIX termios])
 775 fi
 776
 777 AC_CHECK_HEADERS(       \
 778         arpa/inet.h             \
 779         arpa/nameser.h  \
 780         assert.h                \
 781         conio.h                 \
 782         crypt.h                 \
 783         direct.h                \
 784         errno.h                 \
 785         fcntl.h                 \
 786         filio.h                 \
 787         getopt.h                \
 788         grp.h                   \
 789         io.h                    \
 790         libutil.h               \
 791         limits.h                \
 792         locale.h                \
 793         netinet/tcp.h   \
 794         malloc.h                \
 795         memory.h                \
 796         psap.h                  \
 797         pwd.h                   \
 798         process.h               \
 799         resolv.h                \
 800         sgtty.h                 \
 801         shadow.h                \
 802         stddef.h                \
 803         string.h                \
 804         strings.h               \
 805         sysexits.h              \
 806         sys/file.h              \
 807         sys/filio.h             \
 808         sys/errno.h             \
 809         sys/ioctl.h             \
 810         sys/param.h             \
 811         sys/resource.h  \
 812         sys/select.h    \
 813         sys/socket.h    \
 814         sys/stat.h              \
 815         sys/syslog.h    \
 816         sys/time.h              \
 817         sys/types.h             \
 818         sys/ucred.h             \
 819         sys/uio.h               \
 820         syslog.h                \
 821         termios.h               \
 822         unistd.h                \
 823         winsock.h               \
 824         winsock2.h              \
 825 )
 826
 827
 828 dnl ----------------------------------------------------------------
 829 dnl Checks for libraries
 830
 831 AC_CHECK_FUNC(dlopen, :, [AC_CHECK_LIB(dl, dlopen)])
 832
 833 dnl HP-UX requires -lV3
 834 dnl this is not needed on newer versions of HP-UX
 835 AC_CHECK_LIB(V3, sigset)
 836
 837 dnl The following is INTENTIONALLY scripted out because shell does not
 838 dnl support variable names with the '@' character, which is what
 839 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 840 AC_MSG_CHECKING(for winsock)
 841 save_LIBS="$LIBS"
 842 for curlib in ws2_32 wsock32; do
 843         LIBS="$LIBS -l$curlib"
 844         AC_TRY_LINK([
 845                         char socket@12();
 846                         char select@20();
 847                         char closesocket@4();
 848                         char gethostname@8();
 849                         ],
 850                         [
 851                         socket@12();
 852                         select@20();
 853                         closesocket@4();
 854                         gethostname@8();
 855                         ],
 856                         have_winsock=yes, have_winsock=no)
 857
 858         if test $have_winsock = yes; then
 859                 AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 860                 ac_cv_func_socket=yes
 861                 ac_cv_func_select=yes
 862                 ac_cv_func_closesocket=yes
 863                 ac_cv_func_gethostname=yes
 864                 if test $curlib = ws2_32; then
 865                         have_winsock=winsock2
 866                         AC_DEFINE(HAVE_WINSOCK2, 1,
 867                                   [define if you have winsock2])
 868                 fi
 869                 break
 870         fi
 871         LIBS="$save_LIBS"
 872 done
 873 AC_MSG_RESULT($have_winsock)
 874
 875 dnl Find socket()
 876 dnl Likely combinations:
 877 dnl             -lsocket [ -lnsl_s | -lnsl ]
 878 dnl             -linet
 879
 880 AC_CHECK_FUNC(socket, :, [
 881 dnl hopefully we won't include too many libraries
 882         AC_CHECK_LIB(socket, main)
 883         AC_CHECK_LIB(net, main)
 884         AC_CHECK_LIB(nsl_s, main)
 885         AC_CHECK_LIB(nsl, main)
 886         AC_CHECK_LIB(inet, socket)
 887         AC_CHECK_LIB(gen, main)
 888 ])
 889
 890 dnl require select
 891 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 892
 893 if test "${ac_cv_header_winsock_h}" != yes; then
 894         dnl Select arg types
 895         dnl (if this detection becomes permenent, it and the select() detection
 896         dnl should be done before the yielding select test)
 897         AC_FUNC_SELECT_ARGTYPES
 898 fi
 899
 900 dnl check to see if system call automatically restart
 901 dnl AC_SYS_RESTARTABLE_SYSCALLS
 902
 903 dnl ----------------------------------------------------------------
 904 dnl require POSIX regex
 905 AC_CHECK_HEADERS( regex.h )
 906 if test "$ac_cv_header_regex_h" != yes ; then
 907         AC_MSG_ERROR([POSIX regex.h required.])
 908 fi
 909 AC_SEARCH_LIBS(regfree, [regex gnuregex],
 910         :, AC_MSG_ERROR([POSIX regex required.]))
 911
 912 OL_POSIX_REGEX
 913 if test "$ol_cv_c_posix_regex" = no ; then
 914         AC_MSG_ERROR([broken POSIX regex!])
 915 fi
 916
 917 dnl ----------------------------------------------------------------
 918 dnl UUID Support
 919
 920 have_uuid=no
 921 AC_CHECK_HEADERS(sys/uuid.h)
 922 if test $ac_cv_header_sys_uuid_h = yes ; then
 923         save_LIBS="$LIBS"
 924         AC_SEARCH_LIBS(uuid_to_str, uuid, [have_uuid=yes], :)
 925         LIBS="$save_LIBS"
 926
 927         if test have_uuid = yes ; then
 928                 AC_DEFINE(HAVE_UUID_TO_STR,1,
 929                         [define if you have uuid_to_str()])
 930
 931                 test "$ac_cv_search_uuid_to_str" = "none required" || \
 932                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
 933         fi
 934 fi
 935
 936 dnl For windows, check for the need of RPCRT for UUID function support
 937 if test $have_uuid = no ; then
 938         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
 939         save_LIBS="$LIBS"
 940         LIBS="$LIBS -lrpcrt4"
 941         AC_TRY_LINK([
 942                 char UuidCreate@4();
 943                 char UuidToStringA@8();
 944                 ],
 945                 [
 946                 UuidCreate@4();
 947                 UuidToStringA@8();
 948                 ],
 949                 need_rpcrt=yes, need_rpcrt=no)
 950         if test $need_rpcrt = yes; then
 951                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
 952         fi
 953         LIBS="$save_LIBS"
 954         AC_MSG_RESULT($need_rpcrt)
 955 fi
 956
 957 dnl ----------------------------------------------------------------
 958 dnl Check for resolver routines
 959 dnl       need to check for both res_query and __res_query
 960 dnl   need to check -lc, -lbind, and -lresolv
 961 ol_link_dnssrv=no
 962 AC_CHECK_FUNC(res_query,:)
 963 if test $ac_cv_func_res_query = no ; then
 964         AC_CHECK_FUNC(__res_query,:)
 965         ac_cv_func_res_query=$ac_cv_func___res_query
 966 fi
 967
 968 if test $ac_cv_func_res_query = no ; then
 969         AC_CHECK_LIB(bind, res_query)
 970         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 971 fi
 972
 973 if test $ac_cv_func_res_query = no ; then
 974         AC_CHECK_LIB(bind, __res_query)
 975         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 976 fi
 977
 978 if test $ac_cv_func_res_query = no ; then
 979         AC_CHECK_LIB(resolv, res_query)
 980         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 981 fi
 982
 983 if test $ac_cv_func_res_query = no ; then
 984         AC_CHECK_LIB(resolv, __res_query)
 985         ac_cv_func_res_query=$ac_cv_lib_resolv___res_query
 986 fi
 987
 988 if test "$ac_cv_func_res_query" = yes ; then
 989         AC_DEFINE(HAVE_RES_QUERY,1,
 990                 [define if you have res_query()])
 991
 992         if test $ol_enable_dnssrv != no ; then
 993                 ol_link_dnssrv=yes
 994         fi
 995 fi
 996
 997 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 998         AC_MSG_ERROR([DNSSRV requires res_query()])
 999 fi
1000
1001 dnl ----------------------------------------------------------------
1002 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1003 dnl PF_LOCAL may use getaddrinfo in available
1004 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1005
1006 ol_link_ipv6=no
1007 if test $ac_cv_func_getaddrinfo = no -o $ac_cv_func_inet_ntop = no ; then
1008         if test $ol_enable_ipv6 = yes ; then
1009                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1010         fi
1011 elif test $ol_enable_ipv6 != no ; then
1012         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1013                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1014 #                       include <netinet/in.h>
1015 #                       ifdef INET6_ADDRSTRLEN
1016                                 __has_inet6_addrstrlen__;
1017 #                       endif
1018                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1019
1020
1021         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1022                 AC_TRY_COMPILE([
1023 #include <sys/types.h>
1024 #include <sys/socket.h>
1025 ],[
1026                         struct sockaddr_storage ss;
1027 ],                      [ol_cv_struct_sockaddr_storage=yes],
1028                         [ol_cv_struct_sockaddr_storage=no])])
1029
1030         if test $ol_cv_inet6_addrstrlen = yes \
1031                 -a $ol_cv_struct_sockaddr_storage = yes ; then
1032                 ol_link_ipv6=yes
1033         elif test $ol_enable_ipv6 = yes \
1034                         -a $ol_cv_inet6_addrstrlen = no ; then
1035                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1036         elif test $ol_enable_ipv6 = yes \
1037                         -a $ol_cv_struct_sockaddr_storage = no ; then
1038                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1039         fi
1040 fi
1041
1042 if test $ol_enable_local != no ; then
1043         AC_CHECK_HEADERS( sys/un.h )
1044
1045         if test $ol_enable_local = auto ; then
1046                 ol_enable_local=$ac_cv_header_sys_un_h
1047         elif test $ac_cv_header_sys_un_h = no ; then
1048                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1049         fi
1050 fi
1051
1052 dnl ----------------------------------------------------------------
1053 dnl Kerberos
1054 ol_link_kbind=no
1055 ol_link_kpasswd=no
1056 ol_link_krb5=no
1057 ol_link_krb4=no
1058
1059 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
1060         -o $ol_with_kerberos = k5 -o $ol_with_kerberos = k5only \
1061         -o $ol_with_kerberos = k425 ; then
1062
1063         AC_CHECK_HEADERS(krb5.h)
1064
1065         if test $ac_cv_header_krb5_h = yes ; then
1066                 dnl lazy check for Heimdal Kerberos
1067                 AC_CHECK_HEADERS(heim_err.h)
1068                 if test $ac_cv_header_heim_err_h = yes ; then
1069                         krb5_impl=heimdal
1070                 else
1071                         krb5_impl=mit
1072                 fi
1073
1074                 if test $krb5_impl = mit; then
1075                         AC_CHECK_LIB(k5crypto, main,
1076                                 [krb5crypto=k5crypto],
1077                                 [krb5crypto=crypto])
1078
1079                         AC_CHECK_LIB(krb5, main,
1080                                 [have_krb5=yes
1081                                 KRB5_LIBS="-lkrb5 -l$krb5crypto -lcom_err"],
1082                                 [have_krb5=no],
1083                                 [-l$krb5crypto -lcom_err])
1084
1085                 elif test $krb5_impl = heimdal; then
1086                         AC_CHECK_LIB(des, main,
1087                                 [krb5crypto=des],
1088                                 [krb5crypto=crypto])
1089
1090                         AC_CHECK_LIB(krb5, main,
1091                                 [have_krb5=yes
1092                                 KRB5_LIBS="-lkrb5 -l$krb5crypto -lasn1 -lroken -lcom_err"],
1093                                 [have_krb5=no],
1094                                 [-l$krb5crypto -lasn1 -lroken -lcom_err])
1095
1096                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
1097                                 [define if you have HEIMDAL Kerberos])
1098
1099                 else
1100                         have_krb5=no
1101                         AC_MSG_WARN([Unrecognized Kerberos5 Implementation])
1102                 fi
1103
1104                 if test $have_krb5 = yes ; then
1105                         ol_link_krb5=yes
1106
1107                         AC_DEFINE(HAVE_KRB5, 1,
1108                                 [define if you have Kerberos V])
1109
1110                         if test $ol_enable_kpasswd != no ; then
1111                                 ol_link_kpasswd=yes;
1112                         fi
1113
1114                         if test $ol_with_kerberos = k5only ; then
1115                                 ol_with_kerberos=found
1116                         fi
1117
1118                 elif test $ol_with_kerberos != auto ; then
1119                         AC_MSG_ERROR([Required Kerberos 5 support not available])
1120                 fi
1121
1122         fi
1123 fi
1124
1125 if test $ol_link_krb5 = yes -a \( $ol_with_kerberos = yes -o \
1126         $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
1127
1128         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
1129
1130         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
1131                 if test $krb5_impl = mit; then
1132                         AC_CHECK_LIB(krb4, main, [have_k425=yes
1133                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
1134                                 [-ldes425 -lkrb5 -l$krb5crypto -lcom_err])
1135
1136                 elif test $krb5_impl = heimdal; then
1137                         AC_CHECK_LIB(krb4, main, [have_k425=yes
1138                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
1139                                 [-lkrb5 -l$krb5crypto -lasn1 -lroken -lcom_err])
1140
1141                 else
1142                         have_425=no
1143                         AC_MSG_WARN([Unrecongized Kerberos V Implementation])
1144                 fi
1145
1146                 if test $have_k425 = yes ; then
1147                         ol_with_kerberos=found
1148                         ol_link_krb4=yes
1149
1150                         AC_DEFINE(HAVE_KRB425, 1,
1151                                 [define if you have Kerberos V with IV support])
1152                         AC_DEFINE(HAVE_KRB4, 1,
1153                                 [define if you have Kerberos IV])
1154
1155                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
1156                                 [ol_cv_var_des_debug], [
1157                                 dnl save the flags
1158                                 save_LIBS="$LIBS"
1159                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
1160                                 AC_TRY_LINK([
1161 #include <kerberosIV/krb.h>
1162 #include <kerberosIV/des.h>
1163 extern int des_debug;
1164 ],[
1165 des_debug = 1;
1166 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
1167                                 dnl restore the LIBS
1168                                 LIBS="$save_LIBS"
1169                         ])
1170
1171                         if test $ol_cv_var_des_debug = yes ; then
1172                                 AC_DEFINE(HAVE_DES_DEBUG,1,
1173                                         [define if you have Kerberos des_debug])
1174                         fi
1175
1176                         LIBS="$save_LIBS"
1177                 fi
1178         fi
1179 fi
1180
1181 if test $ol_link_krb5 = yes ; then
1182         ol_with_kerberos=found
1183 fi
1184
1185 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
1186         -o $ol_with_kerberos = k4 -o $ol_with_kerberos = kth ; then
1187
1188         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
1189
1190         if test $ac_cv_header_krb_h = yes ; then
1191                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
1192
1193                 if test $have_k4 = yes ; then
1194                         ol_with_kerberos=found
1195                         ol_link_krb4=yes
1196
1197                         AC_DEFINE(HAVE_KRB4, 1,
1198                                 [define if you have Kerberos IV])
1199
1200                         KRB4_LIBS="-lkrb -ldes"
1201
1202                         if test $ac_cv_header_krb_archaeology_h = yes ; then
1203                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
1204                                         [define if you have Kth Kerberos])
1205                         fi
1206                 fi
1207         fi
1208 fi
1209
1210 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
1211         ol_link_kpasswd=yes
1212 fi
1213
1214 if test $ol_link_krb4 = yes -a $ol_enable_kbind != no ; then
1215         ol_link_kbind=yes
1216
1217 elif test $ol_enable_kbind = yes ; then
1218         AC_MSG_ERROR([Kerberos IV detection failed])
1219 fi
1220
1221 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
1222         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
1223
1224 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
1225         AC_MSG_ERROR([Kerberos detection failed])
1226 fi
1227
1228 dnl ----------------------------------------------------------------
1229 dnl TLS/SSL
1230 ol_link_tls=no
1231 if test $ol_with_tls != no ; then
1232         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
1233
1234         if test $ac_cv_header_openssl_ssl_h = yes \
1235                 -o $ac_cv_header_ssl_h = yes ; then
1236                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
1237                         [have_ssleay=yes
1238                         need_rsaref=no],
1239                         [have_ssleay=no],
1240                         [-lcrypto])
1241
1242                 if test $have_ssleay = no ; then
1243                         AC_CHECK_LIB(ssl, SSL_library_init,
1244                                 [have_ssleay=yes
1245                                 need_rsaref=no], [have_ssleay=no],
1246                                 [-lcrypto])
1247                 fi
1248
1249                 if test $have_ssleay = no ; then
1250                         AC_CHECK_LIB(ssl, ssl3_accept,
1251                                 [have_ssleay=yes
1252                                 need_rsaref=yes], [have_ssleay=no],
1253                                 [-lcrypto -lRSAglue -lrsaref])
1254                 fi
1255
1256                 if test $have_ssleay = yes ; then
1257                         ol_with_tls=found
1258                         ol_link_tls=yes
1259
1260                         AC_DEFINE(HAVE_SSLEAY, 1,
1261                                 [define if you have SSLeay or OpenSSL])
1262
1263                         if test $need_rsaref = yes; then
1264                                 AC_DEFINE(HAVE_RSAREF, 1,
1265                                         [define if you have RSAref])
1266
1267                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1268                         else
1269                                 TLS_LIBS="-lssl -lcrypto"
1270                         fi
1271                 fi
1272         fi
1273
1274 else
1275         AC_WARN([TLS data protection not supported!])
1276 fi
1277
1278 if test $ol_link_tls = yes ; then
1279         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1280
1281 elif test $ol_with_tls = auto ; then
1282         AC_WARN([Could not locate TLS/SSL package])
1283         AC_WARN([TLS data protection not supported!])
1284
1285 elif test $ol_with_tls != no ; then
1286         AC_ERROR([Could not locate TLS/SSL package])
1287 fi
1288
1289 dnl ----------------------------------------------------------------
1290 dnl LAN Manger password checking requires DES from OpenSSL
1291 if test $ol_enable_lmpasswd != no; then
1292         if test $ol_link_tls != yes ; then
1293                 AC_ERROR([LAN Manager passwords require OpenSSL])
1294         fi
1295
1296         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1297 fi
1298
1299 dnl ----------------------------------------------------------------
1300 dnl Threads?
1301 ol_link_threads=no
1302
1303 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1304         -o $ol_with_threads = nt ; then
1305
1306         OL_NT_THREADS
1307
1308         if test "$ol_cv_nt_threads" = yes ; then
1309                 ol_link_threads=nt
1310                 ol_with_threads=found
1311                 ol_with_yielding_select=yes
1312
1313                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1314                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1315         fi
1316
1317         if test $ol_with_threads = nt ; then
1318                 AC_MSG_ERROR([could not locate NT Threads])
1319         fi
1320 fi
1321
1322 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1323         -o $ol_with_threads = posix ; then
1324
1325         AC_CHECK_HEADERS(pthread.h)
1326
1327         if test $ac_cv_header_pthread_h = yes ; then
1328                 OL_POSIX_THREAD_VERSION
1329
1330                 if test $ol_cv_pthread_version != 0 ; then
1331                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1332                                 [define to pthreads API spec revision])
1333                 else
1334                         AC_MSG_ERROR([unknown pthread version])
1335                 fi
1336
1337                 # consider threads found
1338                 ol_with_threads=found
1339
1340                 OL_HEADER_LINUX_THREADS
1341                 OL_HEADER_GNU_PTH_PTHREAD_H
1342
1343                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1344                         AC_CHECK_HEADERS(sched.h)
1345                 fi
1346
1347                 dnl Now the hard part, how to link?
1348                 dnl
1349                 dnl currently supported checks:
1350                 dnl
1351                 dnl Check for no flags
1352                 dnl     pthread_create() in $LIBS
1353                 dnl
1354                 dnl Check special pthread (final) flags
1355                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1356                 dnl     pthread_create() with -kthread (FreeBSD)
1357                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1358                 dnl     pthread_create() with -pthreads (?)
1359                 dnl     pthread_create() with -mthreads (AIX)
1360                 dnl     pthread_create() with -thread (?)
1361                 dnl
1362                 dnl Check pthread (final) libraries
1363                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1364                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1365                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1366                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1367                 dnl     pthread_create() in -lpthread (many)
1368                 dnl     pthread_create() in -lc_r (FreeBSD)
1369                 dnl
1370                 dnl Check pthread (draft4) flags (depreciated)
1371                 dnl     pthread_create() with -threads (OSF/1)
1372                 dnl
1373                 dnl Check pthread (draft4) libraries (depreciated)
1374                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1375                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1376                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1377                 dnl     pthread_create() in -lpthreads (many)
1378                 dnl
1379
1380                 dnl pthread_create in $LIBS
1381                 AC_CACHE_CHECK([for pthread_create in default libraries],
1382                         ol_cv_pthread_create,[
1383                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1384                         [ol_cv_pthread_create=yes],
1385                         [ol_cv_pthread_create=no],
1386                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1387                                 [ol_cv_pthread_create=yes],
1388                                 [ol_cv_pthread_create=no])])])
1389
1390                 if test $ol_cv_pthread_create != no ; then
1391                         ol_link_threads=posix
1392                         ol_link_pthreads=""
1393                 fi
1394
1395 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1396                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1397                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1398                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1399                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1400                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1401
1402                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1403                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1404                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1405                         [ol_cv_pthread_lpthread_lmach_lexc])
1406 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1407 dnl                     [ol_cv_pthread_lpthread_lexc])
1408
1409                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1410                         [ol_cv_pthread_lib_lpthread_woff])
1411
1412                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1413                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1414
1415                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1416
1417                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1418                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1419                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1420                         [ol_cv_pthread_lpthreads_lmach_lexc])
1421                 OL_PTHREAD_TRY([-lpthreads -lexc],
1422                         [ol_cv_pthread_lpthreads_lexc])
1423
1424                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1425
1426                 if test $ol_link_threads != no ; then
1427                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1428
1429                         dnl save flags
1430                         save_CPPFLAGS="$CPPFLAGS"
1431                         save_LIBS="$LIBS"
1432                         LIBS="$LTHREAD_LIBS $LIBS"
1433
1434                         dnl All POSIX Thread (final) implementations should have
1435                         dnl sched_yield instead of pthread yield.
1436                         dnl check for both, and thr_yield for Solaris
1437                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1438
1439                         if test $ac_cv_func_sched_yield = no -a \
1440                                 $ac_cv_func_pthread_yield = no -a \
1441                                 $ac_cv_func_thr_yield = no ; then
1442                                 dnl Digital UNIX has sched_yield() in -lrt
1443                                 AC_CHECK_LIB(rt, sched_yield,
1444                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1445                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1446                                                 [Define if you have the sched_yield function.])
1447                                         ac_cv_func_sched_yield=yes],
1448                                         [ac_cv_func_sched_yield=no])
1449                         fi
1450                         if test $ac_cv_func_sched_yield = no -a \
1451                                 $ac_cv_func_pthread_yield = no -a \
1452                                 "$ac_cv_func_thr_yield" = no ; then
1453                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1454                         fi
1455
1456                         dnl Check functions for compatibility
1457                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1458
1459                         dnl Check for pthread_detach with <pthread.h> inclusion
1460                         dnl as it's symbol may have been mangled.
1461                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1462                                 [ol_cv_func_pthread_detach], [
1463                                 dnl save the flags
1464                                 AC_TRY_LINK([
1465 #include <pthread.h>
1466 #ifndef NULL
1467 #define NULL (void*)0
1468 #endif
1469 ],
1470                                         [pthread_detach(NULL);],
1471                                         [ol_cv_func_pthread_detach=yes],
1472                                         [ol_cv_func_pthread_detach=no])
1473                         ])
1474
1475                         if test $ol_cv_func_pthread_detach = no ; then
1476                                 AC_MSG_ERROR([could not locate pthread_detach()])
1477                         fi
1478
1479                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1480                                 [define if you have pthread_detach function])
1481
1482                         dnl Check for setconcurreny functions
1483                         AC_CHECK_FUNCS( \
1484                                 pthread_setconcurrency \
1485                                 pthread_getconcurrency \
1486                                 thr_setconcurrency \
1487                                 thr_getconcurrency \
1488                         )
1489
1490                         OL_SYS_LINUX_THREADS
1491                         OL_LINUX_THREADS
1492
1493                         if test $ol_cv_linux_threads = error; then
1494                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1495                         fi
1496
1497                         AC_CACHE_CHECK([if pthread_create() works],
1498                                 ol_cv_pthread_create_works,[
1499                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1500                                 [ol_cv_pthread_create_works=yes],
1501                                 [ol_cv_pthread_create_works=no],
1502                                 [dnl assume yes
1503                                 ol_cv_pthread_create_works=yes])])
1504
1505                         if test $ol_cv_pthread_create_works = no ; then
1506                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1507                         fi
1508
1509                         dnl Check if select causes an yield
1510                         if test $ol_with_yielding_select = auto ; then
1511                                 AC_CACHE_CHECK([if select yields when using pthreads],
1512                                         ol_cv_pthread_select_yields,[
1513                                 AC_TRY_RUN([
1514 #include <sys/types.h>
1515 #include <sys/time.h>
1516 #include <unistd.h>
1517 #include <pthread.h>
1518 #ifndef NULL
1519 #define NULL (void*) 0
1520 #endif
1521
1522 static int fildes[2];
1523
1524 static void *task(p)
1525         void *p;
1526 {
1527         int i;
1528         struct timeval tv;
1529
1530         fd_set rfds;
1531
1532         tv.tv_sec=10;
1533         tv.tv_usec=0;
1534
1535         FD_ZERO(&rfds);
1536         FD_SET(fildes[0], &rfds);
1537
1538         /* we're not interested in any fds */
1539         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1540
1541         if(i < 0) {
1542                 perror("select");
1543                 exit(10);
1544         }
1545
1546         exit(0); /* if we exit here, the select blocked the whole process */
1547 }
1548
1549 int main(argc, argv)
1550         int argc;
1551         char **argv;
1552 {
1553         pthread_t t;
1554
1555         /* create a pipe to select */
1556         if(pipe(&fildes[0])) {
1557                 perror("select");
1558                 exit(1);
1559         }
1560
1561 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1562         (void) pthread_setconcurrency(2);
1563 #else
1564 #ifdef HAVE_THR_SETCONCURRENCY
1565         /* Set Solaris LWP concurrency to 2 */
1566         thr_setconcurrency(2);
1567 #endif
1568 #endif
1569
1570 #if HAVE_PTHREADS < 6
1571         pthread_create(&t, pthread_attr_default, task, NULL);
1572 #else
1573         pthread_create(&t, NULL, task, NULL);
1574 #endif
1575
1576         /* make sure task runs first */
1577 #if HAVE_THR_YIELD
1578         thr_yield();
1579 #elif defined( HAVE_SCHED_YIELD )
1580         sched_yield();
1581 #elif defined( HAVE_PTHREAD_YIELD )
1582         pthread_yield();
1583 #endif
1584
1585         exit(2);
1586 }],
1587                                 [ol_cv_pthread_select_yields=no],
1588                                 [ol_cv_pthread_select_yields=yes],
1589                                 [ol_cv_pthread_select_yields=cross])])
1590
1591                                 if test $ol_cv_pthread_select_yields = cross ; then
1592                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1593                                 fi
1594
1595                                 if test $ol_cv_pthread_select_yields = yes ; then
1596                                         ol_with_yielding_select=yes
1597                                 fi
1598                         fi
1599
1600                         dnl restore flags
1601                         CPPFLAGS="$save_CPPFLAGS"
1602                         LIBS="$save_LIBS"
1603                 else
1604                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1605                 fi
1606         fi
1607
1608         if test $ol_with_threads = posix ; then
1609                 AC_MSG_ERROR([could not locate POSIX Threads])
1610         fi
1611 fi
1612
1613 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1614         -o $ol_with_threads = mach ; then
1615
1616         dnl check for Mach CThreads
1617         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1618         if test $ac_cv_header_mach_cthreads_h = yes ; then
1619                 ol_with_threads=found
1620
1621                 dnl check for cthreads support in current $LIBS
1622                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1623
1624                 if test $ol_link_threads = no ; then
1625                         dnl try -all_load
1626                         dnl this test needs work
1627                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1628                                 [ol_cv_cthread_all_load], [
1629                                 dnl save the flags
1630                                 save_LIBS="$LIBS"
1631                                 LIBS="-all_load $LIBS"
1632                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1633                                         cthread_fork((void *)0, (void *)0);
1634                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1635                                 dnl restore the LIBS
1636                                 LIBS="$save_LIBS"
1637                         ])
1638
1639                         if test $ol_cv_cthread_all_load = yes ; then
1640                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1641                                 ol_link_threads=mach
1642                                 ol_with_threads=found
1643                         fi
1644                 fi
1645
1646         elif test $ac_cv_header_cthreads_h = yes ; then
1647                 dnl Hurd variant of Mach Cthreads
1648                 dnl uses <cthreads.h> and -lthreads
1649
1650                 ol_with_threads=found
1651
1652                 dnl save the flags
1653                 save_LIBS="$LIBS"
1654                 LIBS="$LIBS -lthreads"
1655                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1656                 LIBS="$save_LIBS"
1657
1658                 if test $ol_link_threads = yes ; then
1659                         LTHREAD_LIBS="-lthreads"
1660                         ol_link_threads=mach
1661                         ol_with_threads=found
1662                 else
1663                         AC_MSG_ERROR([could not link with Mach CThreads])
1664                 fi
1665
1666         elif test $ol_with_threads = mach ; then
1667                 AC_MSG_ERROR([could not locate Mach CThreads])
1668         fi
1669
1670         if test $ol_link_threads = mach ; then
1671                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1672                         [define if you have Mach Cthreads])
1673         elif test $ol_with_threads = found ; then
1674                 AC_MSG_ERROR([could not link with Mach CThreads])
1675         fi
1676 fi
1677
1678 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1679         -o $ol_with_threads = pth ; then
1680
1681         AC_CHECK_HEADERS(pth.h)
1682
1683         if test $ac_cv_header_pth_h = yes ; then
1684                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1685
1686                 if test $have_pth = yes ; then
1687                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1688                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1689                         ol_link_threads=pth
1690                         ol_with_threads=found
1691
1692                         if test $ol_with_yielding_select = auto ; then
1693                                 ol_with_yielding_select=yes
1694                         fi
1695                 fi
1696         fi
1697 fi
1698
1699 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1700         -o $ol_with_threads = lwp ; then
1701
1702         dnl check for SunOS5 LWP
1703         AC_CHECK_HEADERS(thread.h synch.h)
1704         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1705                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1706
1707                 if test $have_thr = yes ; then
1708                         AC_DEFINE(HAVE_THR,1,
1709                                 [if you have Solaris LWP (thr) package])
1710                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1711                         ol_link_threads=thr
1712
1713                         if test $ol_with_yielding_select = auto ; then
1714                                 ol_with_yielding_select=yes
1715                         fi
1716
1717                         dnl Check for setconcurreny functions
1718                         AC_CHECK_FUNCS( \
1719                                 thr_setconcurrency \
1720                                 thr_getconcurrency \
1721                         )
1722                 fi
1723         fi
1724
1725         dnl check for SunOS4 LWP
1726         AC_CHECK_HEADERS(lwp/lwp.h)
1727         if test $ac_cv_header_lwp_lwp_h = yes ; then
1728                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1729
1730                 if test $have_lwp = yes ; then
1731                         AC_DEFINE(HAVE_LWP,1,
1732                                 [if you have SunOS LWP package])
1733                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1734                         ol_link_threads=lwp
1735
1736                         if test $ol_with_yielding_select = auto ; then
1737                                 ol_with_yielding_select=no
1738                         fi
1739                 fi
1740         fi
1741 fi
1742
1743 if test $ol_with_yielding_select = yes ; then
1744         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1745                 [define if select implicitly yields])
1746 fi
1747
1748 if test $ol_with_threads = manual ; then
1749         dnl User thinks he can manually configure threads.
1750         ol_link_threads=yes
1751
1752         AC_MSG_WARN([thread defines and link options must be set manually])
1753
1754         AC_CHECK_HEADERS(pthread.h sched.h)
1755         AC_CHECK_FUNCS(sched_yield pthread_yield)
1756         OL_HEADER_LINUX_THREADS
1757
1758         AC_CHECK_HEADERS(mach/cthreads.h)
1759         AC_CHECK_HEADERS(lwp/lwp.h)
1760         AC_CHECK_HEADERS(thread.h synch.h)
1761 fi
1762
1763 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1764         dnl needed to get reentrant/threadsafe versions
1765         dnl
1766         AC_DEFINE(REENTRANT,1)
1767         AC_DEFINE(_REENTRANT,1)
1768         AC_DEFINE(THREAD_SAFE,1)
1769         AC_DEFINE(_THREAD_SAFE,1)
1770         AC_DEFINE(THREADSAFE,1)
1771         AC_DEFINE(_THREADSAFE,1)
1772         AC_DEFINE(_SGI_MP_SOURCE,1)
1773
1774         dnl The errno declaration may dependent upon _REENTRANT.
1775         dnl If it does, we must link with thread support.
1776         AC_CACHE_CHECK([for thread specific errno],
1777                 [ol_cv_errno_thread_specific], [
1778                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1779                         [ol_cv_errno_thread_specific=yes],
1780                         [ol_cv_errno_thread_specific=no])
1781         ])
1782
1783         dnl The h_errno declaration may dependent upon _REENTRANT.
1784         dnl If it does, we must link with thread support.
1785         AC_CACHE_CHECK([for thread specific h_errno],
1786                 [ol_cv_h_errno_thread_specific], [
1787                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1788                         [ol_cv_h_errno_thread_specific=yes],
1789                         [ol_cv_h_errno_thread_specific=no])
1790         ])
1791
1792         if test $ol_cv_errno_thread_specific != yes \
1793                 -o $ol_cv_h_errno_thread_specific != yes ; then
1794                 LIBS="$LTHREAD_LIBS $LIBS"
1795                 LTHREAD_LIBS=""
1796         fi
1797
1798 dnl When in thread environment, use
1799 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1800 dnl                     func_r(...);
1801 dnl             #else
1802 dnl             #       if defined( HAVE_THREADS )
1803 dnl                             /* lock */
1804 dnl             #       endif
1805 dnl                             func(...);
1806 dnl             #       if defined( HAVE_THREADS )
1807 dnl                             /* unlock */
1808 dnl             #       endif
1809 dnl             #endif
1810 dnl
1811 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1812 dnl             _POSIX_REENTRANT_FUNCTIONS
1813 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1814 dnl             _POSIX_THREADSAFE_FUNCTIONS
1815 dnl
1816 dnl             and is currently defined in <ldap_pvt_thread.h>
1817 dnl
1818 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1819 dnl
1820 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1821 dnl LDAP_R_COMPILE is defined.  ie:
1822 dnl             #ifdef LDAP_R_COMPILE
1823 dnl             #       include <ldap_pvt_thread.h>
1824 dnl             #endif
1825 dnl
1826 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1827 dnl specifically for compiling the threadsafe version of
1828 dnl     the ldap library (-lldap_r).
1829 dnl
1830 dnl     dnl check for reentrant/threadsafe functions
1831 dnl     dnl
1832 dnl     dnl note: these should only be used when linking
1833 dnl     dnl             with $LTHREAD_LIBS
1834 dnl     dnl
1835 dnl     save_CPPFLAGS="$CPPFLAGS"
1836 dnl     save_LIBS="$LIBS"
1837 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1838 dnl     AC_CHECK_FUNCS( \
1839 dnl             gmtime_r \
1840 dnl             gethostbyaddr_r gethostbyname_r \
1841 dnl             feof_unlocked unlocked_feof \
1842 dnl             putc_unlocked unlocked_putc \
1843 dnl             flockfile ftrylockfile \
1844 dnl     )
1845 dnl     CPPFLAGS="$save_CPPFLAGS"
1846 dnl     LIBS="$save_LIBS"
1847 fi
1848
1849 if test $ol_link_threads = no ; then
1850         if test $ol_with_threads = yes ; then
1851                 AC_MSG_ERROR([no suitable thread support])
1852         fi
1853
1854         if test $ol_with_threads = auto ; then
1855                 AC_MSG_WARN([no suitable thread support, disabling threads])
1856                 ol_with_threads=no
1857         fi
1858
1859         AC_DEFINE(NO_THREADS,1,
1860                 [define if you have (or want) no threads])
1861         LTHREAD_LIBS=""
1862 fi
1863
1864 if test $ol_link_threads != no ; then
1865         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1866 fi
1867
1868 dnl ----------------------------------------------------------------
1869 dnl Tests for reentrant functions necessary to build -lldap_r
1870 AC_CHECK_FUNCS(         \
1871         ctime_r                 \
1872         gethostbyname_r gethostbyaddr_r \
1873 )
1874
1875 if test "$ac_cv_func_ctime_r" = no ; then
1876         ol_cv_func_ctime_r_nargs=0
1877 else
1878         OL_FUNC_CTIME_R_NARGS
1879 dnl     OL_FUNC_CTIME_R_TYPE
1880 fi
1881
1882 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1883         OL_FUNC_GETHOSTBYNAME_R_NARGS
1884 else
1885         ol_cv_func_gethostbyname_r_nargs=0
1886 fi
1887
1888 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1889         OL_FUNC_GETHOSTBYADDR_R_NARGS
1890 else
1891         ol_cv_func_gethostbyaddr_r_nargs=0
1892 fi
1893
1894 dnl ----------------------------------------------------------------
1895 ol_link_ldbm=no
1896
1897 if test $ol_with_ldbm_api = auto \
1898         -o $ol_with_ldbm_api = berkeley \
1899         -o $ol_with_ldbm_api = bcompat ; then
1900
1901         if test $ol_with_ldbm_api = bcompat; then \
1902                 OL_BERKELEY_COMPAT_DB
1903         else
1904                 OL_BERKELEY_DB
1905         fi
1906
1907         if test $ol_cv_berkeley_db != no ; then
1908                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1909                         [define this if Berkeley DB is available])
1910
1911                 ol_link_ldbm=berkeley
1912                 ol_with_ldbm_api=berkeley
1913
1914                 if test $ol_with_ldbm_type = hash ; then
1915                         AC_DEFINE(LDBM_USE_DBHASH,1,
1916                                 [define this to use DBHASH w/ LDBM backend])
1917                 else
1918                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1919                                 [define this to use DBBTREE w/ LDBM backend])
1920                 fi
1921
1922                 dnl $ol_cv_lib_db should be yes or -ldb
1923                 dnl (it could be no, but that would be an error
1924                 if test $ol_cv_lib_db != yes ; then
1925                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1926                 fi
1927         fi
1928 fi
1929
1930 if test $ol_enable_bdb = yes -a $ol_link_ldbm != berkeley ; then
1931         AC_MSG_ERROR(BDB: BerkeleyDB not available)
1932 elif test $ol_enable_bdb != no -a $ol_link_ldbm = berkeley ; then
1933         OL_BDB_COMPAT
1934
1935         if test $ol_cv_bdb_compat = yes ; then
1936                 ol_enable_bdb=yes
1937         elif test $ol_enable_bdb = yes ; then
1938                 AC_MSG_ERROR(BDB: BerkeleyDB version incompatible)
1939         else
1940                 ol_enable_bdb=no
1941         fi
1942 fi
1943
1944 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1945         AC_MSG_WARN(Could not find LDBM with BTREE support)
1946         ol_with_ldbm_api=none
1947 fi
1948
1949 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1950         OL_MDBM
1951
1952         if test $ol_cv_mdbm = yes ; then
1953                 ol_link_ldbm=mdbm
1954                 ol_with_ldbm_api=mdbm
1955                 if test $ol_cv_lib_mdbm != yes ; then
1956                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1957                 fi
1958         fi
1959 fi
1960
1961 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1962         OL_GDBM
1963
1964         if test $ol_cv_gdbm = yes ; then
1965                 ol_link_ldbm=gdbm
1966                 ol_with_ldbm_api=gdbm
1967
1968                 if test $ol_cv_lib_gdbm != yes ; then
1969                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1970                 fi
1971         fi
1972 fi
1973
1974 if test $ol_with_ldbm_api = ndbm ; then
1975         OL_NDBM
1976
1977         if test $ol_cv_ndbm = yes ; then
1978                 ol_link_ldbm=ndbm
1979                 ol_with_ldbm_api=ndbm
1980
1981                 if test $ol_cv_lib_ndbm != yes ; then
1982                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1983                 fi
1984         fi
1985 fi
1986
1987 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1988         AC_MSG_WARN(could not find suitable LDBM backend)
1989         if test $ol_enable_ldbm = yes ; then
1990                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1991         fi
1992
1993         AC_MSG_WARN(disabling LDBM)
1994         ol_enable_ldbm=no
1995 fi
1996
1997 dnl ----------------------------------------------------------------
1998
1999 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
2000         BUILD_LIBS_DYNAMIC=shared
2001         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
2002         LTSTATIC=""
2003 else
2004         BUILD_LIBS_DYNAMIC=static
2005         LTSTATIC="-static"
2006 fi
2007 AC_SUBST(LTSTATIC)dnl
2008
2009 dnl ----------------------------------------------------------------
2010 if test $ol_enable_wrappers != no ; then
2011         AC_CHECK_HEADERS(tcpd.h,[
2012                 AC_MSG_CHECKING([for TCP wrappers library])
2013                 save_LIBS="$LIBS"
2014                 LIBS="$LIBS -lwrap"
2015                 AC_TRY_LINK([
2016 #include <tcpd.h>
2017 int allow_severity = 0;
2018 int deny_severity  = 0;
2019
2020 struct request_info *req;
2021                 ],[
2022 hosts_access(req)
2023                 ],[AC_MSG_RESULT([-lwrap])
2024                 have_wrappers=yes
2025                 LIBS="$save_LIBS"],[
2026                 dnl try with -lnsl
2027                 LIBS="$LIBS -lnsl"
2028                 AC_TRY_LINK([
2029 #include <tcpd.h>
2030 int allow_severity = 0;
2031 int deny_severity  = 0;
2032
2033 struct request_info *req;
2034                 ],[
2035 hosts_access(req)
2036                 ],[AC_MSG_RESULT([-lwrap -lnsl])
2037                 have_wrappers=yes
2038                 LIBS="$save_LIBS -lnsl"],[
2039                 AC_MSG_RESULT(no)
2040                 have_wrappers=no
2041                 LIBS=$save_LIBS])],[
2042                 have_wrappers=no])],[have_wrappers=no])
2043
2044         if test $have_wrappers = yes ; then
2045                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
2046                 WRAP_LIBS="-lwrap"
2047         elif test $ol_enable_wrappers = yes ; then
2048                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options ore disable])
2049         else
2050                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
2051                 WRAP_LIBS=""
2052         fi
2053 fi
2054
2055 dnl ----------------------------------------------------------------
2056 if test $ol_enable_syslog != no ; then
2057         AC_CHECK_FUNC(openlog)
2058         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
2059                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
2060         fi
2061         ol_enable_syslog=$ac_cv_func_openlog
2062 fi
2063
2064 dnl ----------------------------------------------------------------
2065 dnl dmalloc support (deprecated in favor of -DCSRIMALLOC support)
2066 dnl if test $ol_enable_dmalloc != no ; then
2067 dnl     AC_CHECK_HEADERS(dmalloc.h)
2068 dnl     AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
2069 dnl fi
2070
2071 dnl ----------------------------------------------------------------
2072 dnl SQL
2073 ol_link_sql=no
2074 if test $ol_enable_sql != no ; then
2075         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
2076                 AC_MSG_ERROR([could not locate SQL headers])
2077         ])
2078
2079         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
2080         if test $have_iodbc = yes ; then
2081                 ol_link_sql="-liodbc"
2082         else
2083                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
2084                 if test $have_odbc = yes ; then
2085                         ol_link_sql="-lodbc"
2086                 fi
2087         fi
2088
2089         if test $ol_link_sql != no ; then
2090                 SLAPD_SQL_LIBS="$ol_link_sql"
2091
2092         elif test $ol_enable_sql != auto ; then
2093                 AC_MSG_ERROR([could not locate suitable ODBC library])
2094         fi
2095 fi
2096
2097 dnl ----------------------------------------------------------------
2098 dnl ud needs termcap (should insert check here)
2099 ol_link_termcap=no
2100 AC_CHECK_HEADERS(termcap.h ncurses.h)
2101
2102 if test $ol_link_termcap = no ; then
2103         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
2104         if test $have_termcap = yes ; then
2105                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
2106                 ol_link_termcap=yes
2107                 TERMCAP_LIBS=-ltermcap
2108         fi
2109 fi
2110
2111 if test $ol_link_termcap = no ; then
2112         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
2113         if test $have_ncurses = yes ; then
2114                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
2115                 ol_link_termcap=yes
2116                 TERMCAP_LIBS=-lncurses
2117         fi
2118 fi
2119
2120 if test $ol_link_termcap = no ; then
2121         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
2122         TERMCAP_LIBS=
2123 fi
2124
2125 dnl ----------------------------------------------------------------
2126 dnl
2127 dnl Check for Cyrus SASL
2128 dnl
2129 ol_link_sasl=no
2130 ol_link_spasswd=no
2131 if test $ol_with_cyrus_sasl != no ; then
2132         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
2133
2134         if test $ac_cv_header_sasl_sasl_h = yes -o $ac_cv_header_sasl_h = yes; then
2135                 AC_CHECK_LIB(sasl2, sasl_client_init,
2136                         [ol_link_sasl="-lsasl2"],
2137                         [AC_CHECK_LIB(sasl, sasl_client_init,
2138                                 [ol_link_sasl="-lsasl"])])
2139         fi
2140
2141         if test $ol_link_sasl = no ; then
2142                 if test $ol_with_cyrus_sasl != auto ; then
2143                         AC_MSG_ERROR([Could not locate Cyrus SASL])
2144                 else
2145                         AC_MSG_WARN([Could not locate Cyrus SASL])
2146                         AC_MSG_WARN([SASL authentication not supported!])
2147                         if test $ol_link_tls = no ; then
2148                                 AC_MSG_WARN([Strong authentication not supported!])
2149                         fi
2150                 fi
2151         else
2152                 OL_SASL_COMPAT
2153                 if test $ol_cv_sasl_compat = no ; then
2154                         ol_link_sasl=no
2155                         AC_MSG_ERROR([Cyrus SASL library located but incompatible])
2156                 fi
2157
2158                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
2159                 SASL_LIBS="$ol_link_sasl"
2160                 if test $ol_enable_spasswd != no ; then
2161                         ol_link_spasswd=yes
2162                 fi
2163
2164                 ac_save_LIBS="$LIBS"
2165                 LIBS="$LIBS $ol_link_sasl"
2166                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
2167                         [define if your SASL library has sasl_version()])])
2168                 LIBS="$ac_save_LIBS"
2169         fi
2170
2171 else
2172         AC_MSG_WARN([SASL authentication not supported!])
2173         if test $ol_link_tls = no ; then
2174                 AC_MSG_WARN([Strong authentication not supported!])
2175         fi
2176 fi
2177
2178 dnl ----------------------------------------------------------------
2179 dnl Check for entropy sources
2180 if test $cross_compiling != yes -a "$ac_cv_mingw32" != yes ; then
2181         dev=no
2182         if test -r /dev/urandom ; then
2183                 dev="/dev/urandom";
2184         elif test -r /idev/urandom ; then
2185                 dev="/idev/urandom";
2186         elif test -r /dev/srandom ; then
2187                 dev="/dev/srandom";
2188         elif test -r /dev/random ; then
2189                 dev="/dev/random";
2190         elif test -r /idev/random ; then
2191                 dev="/idev/random";
2192         fi
2193
2194         if test $dev != no ; then
2195                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2196         fi
2197 fi
2198
2199 dnl ----------------------------------------------------------------
2200 dnl
2201 dnl Check for fetch URL support
2202 dnl             should be extended to support other fetch URL APIs
2203 dnl
2204 ol_link_fetch=no
2205 if test $ol_with_fetch != no ; then
2206         OL_LIB_FETCH
2207
2208         if test $ol_cv_lib_fetch != no ; then
2209                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
2210                 ol_link_fetch=freebsd
2211
2212         elif test $ol_with_fetch != auto ; then
2213                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2214         fi
2215 fi
2216
2217 dnl ----------------------------------------------------------------
2218 dnl
2219 dnl Check for GNU readline
2220 dnl
2221 ol_link_readline=no
2222 if test $ol_with_readline != no ; then
2223         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
2224
2225         if test $ac_cv_header_readline_readline_h = yes ; then
2226                 save_LIBS="$LIBS"
2227                 LIBS="$TERMCAP_LIBS $LIBS"
2228                 AC_CHECK_LIB(readline, readline,
2229                         [have_readline=yes], [have_readline=no])
2230                 LIBS="$save_LIBS"
2231
2232                 if test $have_readline = yes ; then
2233                         ol_with_readline=found
2234                         ol_link_readline=yes
2235
2236                         READLINE_LIBS="-lreadline"
2237                 fi
2238         fi
2239 fi
2240
2241 if test $ol_link_readline = yes ; then
2242         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
2243 fi
2244
2245
2246 dnl ----------------------------------------------------------------
2247 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2248 if test $ol_enable_crypt != no ; then
2249         save_LIBS="$LIBS"
2250         LIBS="$TLS_LIBS $LIBS"
2251
2252         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2253                 LIBS="$save_LIBS"
2254                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2255                         have_crypt=yes], [have_crypt=no])])
2256
2257         LIBS="$save_LIBS"
2258
2259         if test $have_crypt = yes ; then
2260                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2261         else
2262                 AC_MSG_WARN(could not find crypt)
2263                 if test $ol_enable_crypt = yes ; then
2264                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
2265                 fi
2266
2267                 AC_MSG_WARN(disabling crypt support)
2268                 ol_enable_crypt=no
2269         fi
2270 fi
2271
2272 dnl ----------------------------------------------------------------
2273 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2274 if test $ol_enable_proctitle != no ; then
2275         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2276                 AC_CHECK_LIB(util, setproctitle,
2277                         [have_setproctitle=yes
2278                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2279                         [have_setproctitle=no
2280                         LIBOBJS="$LIBOBJS setproctitle.o"
2281                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2282
2283         if test $have_setproctitle = yes ; then
2284                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2285                         [define if setproctitle(3) is available])
2286         fi
2287 fi
2288
2289 dnl ----------------------------------------------------------------
2290 dnl Check for SLPv2 Compliant API Library
2291 if test $ol_enable_slp != no ; then
2292         AC_CHECK_HEADERS( slp.h )
2293
2294         if test $ac_cv_header_slp_h = yes ; then
2295                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2296                 if test $have_slp = yes ; then
2297                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2298                         SLAPD_SLP_LIBS=-lslp
2299                 fi
2300
2301         elif test $ol_enable_slp = yes ; then
2302                 AC_MSG_ERROR([SLP not found])
2303         fi
2304 fi
2305
2306 dnl ----------------------------------------------------------------
2307 dnl Checks for typedefs, structures, and compiler characteristics.
2308 AC_TYPE_MODE_T
2309 AC_TYPE_OFF_T
2310 AC_TYPE_PID_T
2311 AM_TYPE_PTRDIFF_T
2312 AC_TYPE_SIGNAL
2313 AC_TYPE_SIZE_T
2314
2315 AC_CHECK_TYPE(ssize_t, [signed int])
2316 AC_CHECK_TYPE(caddr_t,  [char *])
2317
2318 OL_TYPE_SOCKLEN_T
2319 AC_STRUCT_ST_BLKSIZE
2320 AC_HEADER_TIME
2321 AC_STRUCT_TM
2322 AC_TYPE_UID_T
2323 OL_TYPE_SIG_ATOMIC_T
2324
2325 dnl AC_TYPE_GETGROUPS
2326
2327 OL_STRUCT_PASSWD_PW_GECOS
2328 OL_STRUCT_PASSWD_PW_PASSWD
2329
2330 OL_C_UPPER_LOWER
2331 AC_C_CONST
2332 OL_C_VOLATILE
2333
2334 if test $cross_compiling = yes ; then
2335         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2336 else
2337         AC_C_BIGENDIAN
2338 fi
2339
2340 AC_COMPILE_CHECK_SIZEOF(short)
2341 AC_COMPILE_CHECK_SIZEOF(int)
2342 AC_COMPILE_CHECK_SIZEOF(long)
2343
2344 if test "$ac_cv_sizeof_int" -lt 4 ; then
2345         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2346
2347         AC_DEFINE(LBER_INT_T,long)
2348 else
2349         AC_DEFINE(LBER_INT_T,int)
2350 fi
2351
2352 AC_DEFINE(LBER_LEN_T,long)
2353 AC_DEFINE(LBER_SOCKET_T,int)
2354 AC_DEFINE(LBER_TAG_T,long)
2355
2356 dnl ----------------------------------------------------------------
2357 dnl Checks for library functions.
2358 AC_FUNC_MEMCMP
2359 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
2360 AC_FUNC_STRFTIME
2361 dnl AM_FUNC_STRTOD
2362
2363 OL_FUNC_INET_ATON
2364
2365 dnl Check for NT specific routines
2366 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2367
2368 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2369         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2370 ])
2371
2372 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2373         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2374 ])
2375
2376 AC_FUNC_VPRINTF
2377
2378 if test $ac_cv_func_vprintf = yes ; then
2379         dnl check for vsnprintf
2380         AC_CHECK_FUNCS(snprintf vsnprintf)
2381 fi
2382
2383 AC_CHECK_FUNCS(         \
2384         bcopy                   \
2385         closesocket             \
2386         chroot                  \
2387         endgrent                \
2388         endpwent                \
2389         fcntl                   \
2390         flock                   \
2391         fstat                   \
2392         getdtablesize   \
2393         getgrgid                \
2394         gethostname             \
2395         getpass                 \
2396         getpassphrase   \
2397         getpwuid                \
2398         getpwnam                \
2399         getspnam                \
2400         gettimeofday    \
2401         initgroups              \
2402         lockf                   \
2403         memcpy                  \
2404         memmove                 \
2405         mkstemp                 \
2406         mktemp                  \
2407         pipe                    \
2408         read                    \
2409         recv                    \
2410         recvfrom                \
2411         setpwfile               \
2412         setgid                  \
2413         setegid                 \
2414         setsid                  \
2415         setuid                  \
2416         seteuid                 \
2417         sigaction               \
2418         signal                  \
2419         sigset                  \
2420         strdup                  \
2421         strerror                \
2422         strpbrk                 \
2423         strrchr                 \
2424         strsep                  \
2425         strstr                  \
2426         strtol                  \
2427         strtoul                 \
2428         strspn                  \
2429         sysconf                 \
2430         usleep                  \
2431         waitpid                 \
2432         wait4                   \
2433         write                   \
2434         send                    \
2435         sendmsg                 \
2436         sendto                  \
2437 )
2438
2439 dnl We actually may need to replace more than this.
2440 AC_REPLACE_FUNCS(getopt getpeereid)
2441
2442 if test "$ac_cv_func_getopt" != yes; then
2443         LIBSRCS="$LIBSRCS getopt.c"
2444 fi
2445 if test "$ac_cv_func_getpeereid" != yes; then
2446         OL_MSGHDR_MSG_ACCRIGHTS
2447         LIBSRCS="$LIBSRCS getpeereid.c"
2448 fi
2449 if test "$ac_cv_func_snprintf" != yes -o "$ac_cv_func_vsnprintf" != yes; then
2450         if test "$ac_cv_func_snprintf" != yes; then
2451                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2452         fi
2453         if test "$ac_cv_func_vsnprintf" != yes; then
2454                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2455         fi
2456 fi
2457
2458 dnl ----------------------------------------------------------------
2459 # Check Configuration
2460 OL_SYS_ERRLIST
2461
2462 dnl ----------------------------------------------------------------
2463 dnl Sort out defines
2464
2465 if test "$ol_enable_debug" != no ; then
2466         AC_DEFINE(LDAP_DEBUG,1,
2467                 [define this to add debugging code])
2468 fi
2469 if test "$ol_enable_syslog" = yes ; then
2470         AC_DEFINE(LDAP_SYSLOG,1,
2471                 [define this to add syslog code])
2472 fi
2473 if test "$ol_link_kbind" != no ; then
2474         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2475 fi
2476 if test "$ol_enable_proctitle" != no ; then
2477         AC_DEFINE(LDAP_PROCTITLE,1,
2478                 [define this for LDAP process title support])
2479 fi
2480 if test "$ol_enable_referrals" != no ; then
2481         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2482 fi
2483 if test "$ol_enable_local" != no; then
2484         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2485 fi
2486 if test "$ol_link_ipv6" != no; then
2487         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2488 fi
2489 if test "$ol_enable_cleartext" != no ; then
2490         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2491 fi
2492 if test "$ol_enable_crypt" != no ; then
2493         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2494 fi
2495 if test "$ol_link_kpasswd" != no ; then
2496         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2497 fi
2498 if test "$ol_link_spasswd" != no ; then
2499         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2500 fi
2501 if test "$ol_enable_multimaster" != no ; then
2502         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2503 fi
2504 if test "$ol_enable_phonetic" != no ; then
2505         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2506 fi
2507 if test "$ol_enable_rlookups" != no ; then
2508         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2509 fi
2510 if test "$ol_enable_aci" != no ; then
2511         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2512 fi
2513
2514 if test "$ol_link_modules" != no ; then
2515         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2516         BUILD_SLAPD=yes
2517         SLAPD_MODULES_LDFLAGS="-dlopen self"
2518 fi
2519
2520 if test "$ol_enable_bdb" != no ; then
2521         AC_DEFINE(SLAPD_BDB,1,[define to support BDB backend])
2522         BUILD_SLAPD=yes
2523         BUILD_BDB=yes
2524         if test "$ol_with_bdb_module" != static ; then
2525                 AC_DEFINE(SLAPD_BDB_DYNAMIC,1,
2526                         [define to support dynamic BDB backend])
2527                 BUILD_BDB=mod
2528                 BUILD_BDB_DYNAMIC=shared
2529                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2530         else
2531                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2532         fi
2533 fi
2534
2535 if test "$ol_link_dnssrv" != no ; then
2536         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2537         BUILD_SLAPD=yes
2538         BUILD_DNSSRV=yes
2539         if test "$ol_with_dnssrv_module" != static ; then
2540                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2541                         [define to support dynamic DNS SRV backend])
2542                 BUILD_DNSSRV=mod
2543                 BUILD_DNSSRV_DYNAMIC=shared
2544                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2545         else
2546                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2547         fi
2548 fi
2549
2550 if test "$ol_enable_ldap" != no ; then
2551         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2552         BUILD_SLAPD=yes
2553         BUILD_LDAP=yes
2554         if test "$ol_with_ldap_module" != static ; then
2555                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2556                         [define to support dynamic LDAP backend])
2557                 BUILD_LDAP=mod
2558                 BUILD_LDAP_DYNAMIC=shared
2559                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2560         else
2561                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2562         fi
2563 fi
2564
2565 if test "$ol_link_ldbm" != no -a $ol_enable_ldbm != no; then
2566         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2567         BUILD_SLAPD=yes
2568         BUILD_LDBM=yes
2569         if test "$ol_with_ldbm_module" != static ; then
2570                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2571                         [define to support dynamic LDBM backend])
2572                 BUILD_LDBM=mod
2573                 BUILD_LDBM_DYNAMIC=shared
2574                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldbm"
2575         else
2576                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldbm"
2577         fi
2578 fi
2579
2580 if test "$ol_enable_meta" != no ; then
2581         if test "$ol_enable_ldap" = no ; then
2582                 AC_MSG_ERROR([need --enable-ldap to use --enable-meta])
2583         fi
2584         if test "$ol_enable_rewrite" = no ; then
2585                 AC_MSG_ERROR([need --enable-rewrite to use --enable-meta])
2586         fi
2587         AC_DEFINE(SLAPD_META,1,[define to support LDAP Metadirectory backend])
2588         BUILD_SLAPD=yes
2589         BUILD_META=yes
2590         BUILD_REWRITE=yes
2591         if test "$ol_with_meta_module" != static ; then
2592                 AC_DEFINE(SLAPD_META_DYNAMIC,1,
2593                         [define to support dynamic LDAP Metadirectory backend])
2594                 BUILD_META=mod
2595                 BUILD_META_DYNAMIC=shared
2596                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2597         else
2598                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2599         fi
2600 fi
2601
2602 if test "$ol_enable_monitor" != no ; then
2603         AC_DEFINE(SLAPD_MONITOR,1,[define to support cn=Monitor backend])
2604         BUILD_SLAPD=yes
2605         BUILD_MONITOR=yes
2606         if test "$ol_with_monitor_module" != static ; then
2607                 AC_DEFINE(SLAPD_MONITOR_DYNAMIC,1,
2608                         [define to support dynamic cn=Monitor backend])
2609                 BUILD_MONITOR=mod
2610                 BUILD_MONITOR_DYNAMIC=shared
2611                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2612         else
2613                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2614         fi
2615 fi
2616
2617 if test "$ol_enable_null" != no ; then
2618         AC_DEFINE(SLAPD_NULL,1,[define to support NULL backend])
2619         BUILD_SLAPD=yes
2620         BUILD_NULL=yes
2621         if test "$ol_with_null_module" != static ; then
2622                 AC_DEFINE(SLAPD_NULL_DYNAMIC,1,
2623                         [define to support dynamic NULL backend])
2624                 BUILD_NULL=mod
2625                 BUILD_NULL_DYNAMIC=shared
2626                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2627         else
2628                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2629         fi
2630 fi
2631
2632 if test "$ol_enable_passwd" != no ; then
2633         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2634         BUILD_SLAPD=yes
2635         BUILD_PASSWD=yes
2636         if test "$ol_with_passwd_module" != static ; then
2637                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2638                         [define to support dynamic PASSWD backend])
2639                 BUILD_PASSWD=mod
2640                 BUILD_PASSWD_DYNAMIC=shared
2641                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2642         else
2643                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2644         fi
2645 fi
2646
2647 if test "$ol_link_perl" != no ; then
2648         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2649         BUILD_SLAPD=yes
2650         BUILD_PERL=yes
2651         if test "$ol_with_perl_module" != static ; then
2652                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2653                         [define to support dynamic PERL backend])
2654                 BUILD_PERL=mod
2655                 BUILD_PERL_DYNAMIC=shared
2656                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2657         else
2658                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2659         fi
2660 fi
2661
2662 if test "$ol_enable_shell" != no ; then
2663         if test "$ol_link_thread" != no ; then
2664                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2665         fi
2666         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2667         BUILD_SLAPD=yes
2668         BUILD_SHELL=yes
2669         if test "$ol_with_shell_module" != static ; then
2670                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2671                         [define to support dynamic SHELL backend])
2672                 BUILD_SHELL=mod
2673                 BUILD_SHELL_DYNAMIC=shared
2674                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2675         else
2676                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2677         fi
2678 fi
2679
2680 if test "$ol_link_sql" != no ; then
2681         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2682         BUILD_SLAPD=yes
2683         BUILD_SQL=yes
2684         if test "$ol_with_sql_module" != static; then
2685                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2686                         [define to support dynamic SQL backend])
2687                 BUILD_SQL=mod
2688                 BUILD_SQL_DYNAMIC=shared
2689                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2690         else
2691                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2692         fi
2693 fi
2694
2695 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2696         $BUILD_SLAPD = yes ; then
2697         BUILD_SLURPD=yes
2698 fi
2699
2700 if test "$ol_enable_rewrite" != no ; then
2701         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
2702         BUILD_REWRITE=yes
2703 fi
2704
2705 dnl ----------------------------------------------------------------
2706
2707 dnl
2708 dnl For Windows build, we don't want to include -dlopen flags.
2709 dnl They hurt more than they help.
2710 dnl
2711
2712 if test "$ac_cv_mingw32" = yes ; then
2713         PLAT=NT
2714         SLAPD_MODULES_LDFLAGS=
2715 else
2716         PLAT=UNIX
2717 fi
2718
2719 if test -z "$SLAPD_STATIC_BACKENDS"; then
2720         SLAPD_NO_STATIC='#'
2721 else
2722         SLAPD_NO_STATIC=
2723 fi
2724
2725 AC_SUBST(LIBSRCS)
2726 AC_SUBST(PLAT)
2727 AC_SUBST(BUILD_LIBS_DYNAMIC)
2728
2729 AC_SUBST(BUILD_SLAPD)
2730   AC_SUBST(BUILD_BDB)
2731   AC_SUBST(BUILD_DNSSRV)
2732   AC_SUBST(BUILD_LDAP)
2733   AC_SUBST(BUILD_LDBM)
2734   AC_SUBST(BUILD_META)
2735   AC_SUBST(BUILD_MONITOR)
2736   AC_SUBST(BUILD_NULL)
2737   AC_SUBST(BUILD_PASSWD)
2738   AC_SUBST(BUILD_PERL)
2739   AC_SUBST(BUILD_SHELL)
2740   AC_SUBST(BUILD_SQL)
2741   AC_SUBST(BUILD_BDB_DYNAMIC)
2742   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2743   AC_SUBST(BUILD_LDAP_DYNAMIC)
2744   AC_SUBST(BUILD_LDBM_DYNAMIC)
2745   AC_SUBST(BUILD_META_DYNAMIC)
2746   AC_SUBST(BUILD_MONITOR_DYNAMIC)
2747   AC_SUBST(BUILD_NULL_DYNAMIC)
2748   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2749   AC_SUBST(BUILD_PERL_DYNAMIC)
2750   AC_SUBST(BUILD_SHELL_DYNAMIC)
2751   AC_SUBST(BUILD_SQL_DYNAMIC)
2752 AC_SUBST(BUILD_SLURPD)
2753
2754 AC_SUBST(LDAP_LIBS)
2755 AC_SUBST(LDIF_LIBS)
2756 AC_SUBST(SLAPD_LIBS)
2757 AC_SUBST(SLURPD_LIBS)
2758 AC_SUBST(LDBM_LIBS)
2759 AC_SUBST(LTHREAD_LIBS)
2760 AC_SUBST(LUTIL_LIBS)
2761 AC_SUBST(WRAP_LIBS)
2762
2763 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2764 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2765
2766 AC_SUBST(SLAPD_NO_STATIC)
2767 AC_SUBST(SLAPD_STATIC_BACKENDS)
2768 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
2769
2770 AC_SUBST(PERL_CPPFLAGS)
2771 AC_SUBST(SLAPD_PERL_LDFLAGS)
2772 AC_SUBST(MOD_PERL_LDFLAGS)
2773
2774 AC_SUBST(KRB4_LIBS)
2775 AC_SUBST(KRB5_LIBS)
2776 AC_SUBST(READLINE_LIBS)
2777 AC_SUBST(SASL_LIBS)
2778 AC_SUBST(TERMCAP_LIBS)
2779 AC_SUBST(TLS_LIBS)
2780 AC_SUBST(MODULES_LIBS)
2781 AC_SUBST(AUTH_LIBS)
2782
2783 AC_SUBST(SLAPD_SLP_LIBS)
2784
2785 AC_SUBST(SLAPD_SQL_LDFLAGS)
2786 AC_SUBST(SLAPD_SQL_LIBS)
2787 AC_SUBST(SLAPD_SQL_INCLUDES)
2788
2789 dnl ----------------------------------------------------------------
2790 dnl final help output
2791 AC_ARG_WITH(xxinstall,[
2792 See INSTALL file for further details.])
2793
2794 dnl ----------------------------------------------------------------
2795 dnl final output
2796 dnl
2797
2798 AC_OUTPUT( \
2799 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2800 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2801 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2802 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2803 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2804 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2805 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2806 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2807 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2808 include/Makefile:build/top.mk:include/Makefile.in \
2809 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2810 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2811 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2812 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2813 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2814 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2815 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2816 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2817 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2818 libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-static.mk \
2819 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2820 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2821 servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk \
2822 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2823 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2824 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2825 servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk \
2826 servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk \
2827 servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk \
2828 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2829 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2830 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2831 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2832 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2833 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2834 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2835 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2836 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2837 ,[
2838 date > stamp-h
2839 echo Please run \"make depend\" to build dependencies
2840 ])