git.sur5r.net Git - glabels/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.52)
   4
   5 AC_INIT(glabels, 2.3.pre0svn, http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116)
   6 AC_CONFIG_SRCDIR(src/glabels.c)
   7
   8 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   9
  10 AM_MAINTAINER_MODE
  11 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  12
  13 AC_CONFIG_HEADERS(config.h)
  14
  15 IT_PROG_INTLTOOL([0.21])
  16
  17 PKG_PROG_PKG_CONFIG
  18
  19 AC_PROG_LIBTOOL
  20
  21 GNOME_DOC_INIT
  22 GTK_DOC_CHECK(1.0)
  23
  24 AC_ISC_POSIX
  25 AC_PROG_CC
  26 AC_PROG_INSTALL
  27
  28 GNOME_COMPILE_WARNINGS
  29
  30 AC_PATH_PROG(GLIB_GENMARSHAL,    glib-genmarshal)
  31 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource)
  32
  33
  34 dnl ---------------------------------------------------------------------------
  35 dnl - LIBGLABELS API versioning
  36 dnl ---------------------------------------------------------------------------
  37 dnl From the libtool manual:
  38 dnl 1. Start with version information of `0:0:0' for each libtool library.
  39 dnl 2. Update the version information only immediately before a public release.
  40 dnl    More frequent updates are unnecessary, and only guarantee that the current
  41 dnl    interface number gets larger faster.
  42 dnl 3. If the library source code has changed at all since the last update, then increment
  43 dnl    revision (`c:r:a' becomes `c:r+1:a').
  44 dnl 4. If any interfaces have been added, removed, or changed since the last update,
  45 dnl    increment current, and set revision to 0.
  46 dnl 5. If any interfaces have been added since the last public release, then increment age.
  47 dnl 6. If any interfaces have been removed since the last public release, then set age
  48 dnl    to 0.
  49 LIBGLABELS_C=5
  50 LIBGLABELS_R=1
  51 LIBGLABELS_A=0
  52
  53 LIBGLABELS_VERSION_INFO=${LIBGLABELS_C}:${LIBGLABELS_R}:${LIBGLABELS_A}
  54 AC_SUBST(LIBGLABELS_VERSION_INFO)
  55
  56
  57 dnl ---------------------------------------------------------------------------
  58 dnl - Library dependencies
  59 dnl ---------------------------------------------------------------------------
  60 GLIB_REQUIRED=2.20.0
  61 GTK_REQUIRED=2.16.0
  62 LIBXML_REQUIRED=2.7.0
  63 LIBEBOOK_REQUIRED=2.26.0
  64
  65 dnl Make above strings available for packaging files (e.g. rpm spec files)
  66 AC_SUBST(GLIB_REQUIRED)
  67 AC_SUBST(GTK_REQUIRED)
  68 AC_SUBST(LIBXML_REQUIRED)
  69 AC_SUBST(LIBEBOOK_REQUIRED)
  70
  71
  72 dnl ---------------------------------------------------------------------------
  73 dnl - Check for evolution data server
  74 dnl ---------------------------------------------------------------------------
  75 AC_ARG_WITH(libebook,
  76             [AC_HELP_STRING([--without-libebook],
  77                             [build without Evolution Data Server support])])
  78 have_libebook=no
  79 if test "x$with_libebook" != xno; then
  80         PKG_CHECK_MODULES(LIBEBOOK, libebook-1.2 >= $LIBEBOOK_REQUIRED,
  81                           [have_libebook=yes], [have_libebook=no])
  82 fi
  83
  84 if test "x$have_libebook" = "xyes"; then
  85         AC_DEFINE(HAVE_LIBEBOOK,1,[Define to 1 for EDS support])
  86         OPTIONAL_MODULES="$OPTIONAL_MODULES libebook-1.2 >= $LIBEBOOK_REQUIRED"
  87 fi
  88
  89
  90 dnl ---------------------------------------------------------------------------
  91 dnl - GLABELS prerequisites
  92 dnl ---------------------------------------------------------------------------
  93 PKG_CHECK_MODULES(GLABELS, \
  94 glib-2.0 >= $GLIB_REQUIRED \
  95 gtk+-2.0 >= $GTK_REQUIRED \
  96 libxml-2.0 >= $LIBXML_REQUIRED \
  97 $OPTIONAL_MODULES \
  98 )
  99
 100 AC_SUBST(GLABELS_CFLAGS)
 101 AC_SUBST(GLABELS_LIBS)
 102
 103
 104 dnl ---------------------------------------------------------------------------
 105 dnl - LIBGLABELS more modest prerequisites
 106 dnl ---------------------------------------------------------------------------
 107 PKG_CHECK_MODULES(LIBGLABELS, \
 108 glib-2.0 >= $GLIB_REQUIRED \
 109 libxml-2.0 >= $LIBXML_REQUIRED \
 110 )
 111
 112 AC_SUBST(LIBGLABELS_CFLAGS)
 113 AC_SUBST(LIBGLABELS_LIBS)
 114
 115
 116 dnl ---------------------------------------------------------------------------
 117 dnl - Enable deprecation testing
 118 dnl ---------------------------------------------------------------------------
 119 AC_ARG_ENABLE(deprecations,
 120               [AC_HELP_STRING([--enable-deprecations],
 121                               [warn about deprecated usages [default=no]])],,
 122               [enable_deprecations=no])
 123
 124 if test "x$enable_deprecations" = "xyes"; then
 125    DISABLE_DEPRECATED_CFLAGS="\
 126 -DG_DISABLE_DEPRECATED \
 127 -DGDK_DISABLE_DEPRECATED \
 128 -DGTK_DISABLE_DEPRECATED \
 129 -DGDK_PIXBUF_DISABLE_DEPRECATED \
 130 "
 131    AC_SUBST(DISABLE_DEPRECATED_CFLAGS)
 132 fi
 133
 134
 135 dnl ---------------------------------------------------------------------------
 136 dnl - Is freedesktop mime dbase available?
 137 dnl ---------------------------------------------------------------------------
 138 AC_PATH_PROG(UPDATE_MIME_DATABASE, update-mime-database, no)
 139 AM_CONDITIONAL(HAVE_NEW_MIME, test x$UPDATE_MIME_DATABASE != xno)
 140
 141 AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, update-desktop-database, no)
 142 AM_CONDITIONAL(HAVE_NEWER_MIME, test x$UPDATE_DESKTOP_DATABASE != xno)
 143
 144 AC_ARG_ENABLE(update-mimedb, AC_HELP_STRING([--disable-update-mimedb],
 145               [disable the update-mime-database after install [default=no]]),,
 146               enable_update_mimedb=yes)
 147 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
 148
 149 AC_ARG_ENABLE(update-desktopdb, AC_HELP_STRING([--disable-update-desktopdb],
 150               [disable the update-desktop-database after install [default=no]]),,
 151               enable_update_desktopdb=yes)
 152 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)
 153
 154
 155 dnl ---------------------------------------------------------------------------
 156 dnl - Supported languages
 157 dnl ---------------------------------------------------------------------------
 158 GETTEXT_PACKAGE=glabels
 159 AC_SUBST(GETTEXT_PACKAGE)
 160 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
 161
 162 AM_GLIB_GNU_GETTEXT
 163
 164
 165 dnl ---------------------------------------------------------------------------
 166 dnl - Misc.
 167 dnl ---------------------------------------------------------------------------
 168
 169 dnl Setup for libqrencode compilation
 170 AC_DEFINE(__STATIC, static, [Static attribute, needed to compile libqrencode])
 171
 172
 173 dnl ---------------------------------------------------------------------------
 174 dnl - Makefiles, etc.
 175 dnl ---------------------------------------------------------------------------
 176 AC_OUTPUT([
 177 Makefile
 178 barcode-0.98/Makefile
 179 iec16022-0.2.1/Makefile
 180 qrencode-3.1.0/Makefile
 181 libglabels/Makefile
 182 libglabels/libglabels.pc
 183 src/Makefile
 184 src/pixmaps/Makefile
 185 src/stock-pixmaps/Makefile
 186 data/Makefile
 187 data/pixmaps/Makefile
 188 data/mime/Makefile
 189 data/builder/Makefile
 190 data/desktop/Makefile
 191 data/man/Makefile
 192 templates/Makefile
 193 po/Makefile.in
 194 help/Makefile
 195 docs/Makefile
 196 docs/libglabels/Makefile
 197 glabels.spec
 198 ])
 199
 200
 201 dnl ---------------------------------------------------------------------------
 202 dnl - Print configuration information
 203 dnl ---------------------------------------------------------------------------
 204 echo "
 205 Configuration:
 206
 207         Package:                        ${PACKAGE}-${VERSION}:
 208         Installation prefix             ${prefix}
 209         Source code location:           ${srcdir}
 210         Compiler:                       ${CC}
 211         Evolution Data Server support:  ${have_libebook}
 212
 213 "
 214
 215 cat ${srcdir}/MESSAGE-OF-DOOM
 216