git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Restrictions apply, see COPYRIGHT and LICENSE files."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35
  36 # set unset (borrowed from autoconf 2.14a)
  37 if (unset FOO) >/dev/null 2>&1; then
  38   ol_unset=unset
  39 else
  40   ol_unset=false
  41 fi
  42 # unset CDPATH
  43 $ol_unset CDPATH || test "${CDPATH+set}" != set || CDPATH=: && export CDPATH
  44
  45 AC_CONFIG_AUX_DIR(build)dnl
  46
  47 OL_VERSION=`cat $ac_aux_dir/version`
  48 if test -z "$OL_VERSION"; then
  49         AC_MSG_ERROR([could not determine version])
  50 fi
  51
  52 echo "Configuring OpenLDAP $OL_VERSION ..."
  53
  54 dnl Determine host platform
  55 dnl             we try not to use this for much
  56 AC_CANONICAL_SYSTEM
  57
  58 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  59 AC_SUBST(PACKAGE)
  60 AC_SUBST(VERSION)
  61 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  62 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  63
  64 dnl We use autoconf features new to 2.13.
  65 dnl aclocal.m4 should be built using aclocal from automake 1.4
  66 dnl libtool 1.3.3 should be installed.
  67 AC_PREREQ(2.13)dnl Required Autoconf version
  68
  69 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  70
  71 dnl ================================================================
  72 dnl Start Args
  73 AC_MSG_CHECKING(configure arguments)
  74 AC_PREFIX_DEFAULT(/usr/local)
  75
  76 top_builddir=`pwd`
  77 AC_SUBST(top_builddir)dnl
  78
  79 dnl ----------------------------------------------------------------
  80 dnl --with-subdir
  81 ldap_subdir="/openldap"
  82
  83 AC_ARG_WITH(subdir,
  84 [  --with-subdir=DIR change default subdirectory used for installs],
  85 [case "$withval" in
  86         no) ldap_subdir=""
  87                 ;;
  88         yes)
  89                 ;;
  90         /*|\\*)
  91                 ldap_subdir="$withval"
  92                 ;;
  93         *)
  94                 ldap_subdir="/$withval"
  95                 ;;
  96 esac
  97 ])dnl
  98
  99 AC_SUBST(ldap_subdir)dnl
 100
 101 dnl ----------------------------------------------------------------
 102 dnl General "enable" options
 103 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
 104 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
 105 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
 106 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
 107 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
 108 OL_ARG_ENABLE(kbind,[  --enable-kbind   enable V2 Kerberos IV bind], auto)dnl
 109 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
 110 OL_ARG_ENABLE(ipv6,[  --enable-ipv6     enable IPv6 support], auto)dnl
 111 OL_ARG_ENABLE(unix,[  --enable-unix             enable UNIX domain socket support], auto)dnl
 112 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
 113         no, [yes no])dnl
 114
 115 dnl ----------------------------------------------------------------
 116 dnl General "with" options
 117 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc   enable debug malloc support], no)dnl
 118
 119 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
 120         auto, [auto yes no] )
 121 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
 122         auto, [auto yes no] )
 123 OL_ARG_WITH(kerberos,[  --with-kerberos with support],
 124         auto, [auto k5 k5only k425 kth k4 afs yes no])
 125 OL_ARG_WITH(readline,[  --with-readline with readline support],
 126         auto, [auto yes no] )
 127 OL_ARG_WITH(threads,[  --with-threads   use threads],
 128         auto, [auto nt posix mach pth lwp yes no manual] )
 129 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
 130         auto, [auto ssleay openssl yes no] )
 131 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
 132         auto, [auto yes no manual] )
 133
 134 dnl ----------------------------------------------------------------
 135 dnl Server options
 136 dnl ----------------------------------------------------------------
 137
 138 dnl ----------------------------------------------------------------
 139 dnl SLAPD OPTIONS
 140 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 141 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 142 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 143 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 144 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd     enable kerberos password verification], no)dnl
 145 OL_ARG_ENABLE(spasswd,[    --enable-spasswd     enable (Cyrus) SASL password verification], no)dnl
 146 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 147 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 148 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 149 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 150 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 151 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 152 OL_ARG_ENABLE(dynamic,[    --enable-dynamic     enable linking built binaries with dynamic libs], no)dnl
 153
 154 dnl SLAPD Backend options
 155 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv       enable dnssrv backend], no)dnl
 156 OL_ARG_WITH(dnssrv_module,[      --with-dnssrv-module   module type], static,
 157         [static dynamic])
 158 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 159 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 160         [static dynamic])
 161 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 162 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 163         [auto berkeley bcompat mdbm gdbm])
 164 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 165         [static dynamic])
 166 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 167         [auto btree hash])
 168 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 169 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 170         [static dynamic])
 171 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 172 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 173         [static dynamic])
 174
 175 dnl ----------------------------------------------------------------
 176 dnl SLURPD OPTIONS
 177 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 178 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 179
 180 dnl ----------------------------------------------------------------
 181 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 182 AC_ENABLE_STATIC
 183 dnl AC_DISABLE_SHARED
 184 AC_ENABLE_SHARED
 185
 186 dnl ----------------------------------------------------------------
 187
 188 dnl General "enable" options
 189 # validate options
 190 if test $ol_enable_slapd = no ; then
 191         dnl SLAPD was specificallly disabled
 192         if test $ol_enable_dnssrv = yes ; then
 193                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 194         fi
 195         if test $ol_enable_ldap = yes ; then
 196                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 197         fi
 198         if test $ol_enable_ldbm = yes ; then
 199                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 200         fi
 201         if test $ol_enable_passwd = yes ; then
 202                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 203         fi
 204         if test $ol_enable_shell = yes ; then
 205                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 206         fi
 207         if test $ol_enable_modules = yes ; then
 208                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 209         fi
 210         if test $ol_enable_multimaster = yes ; then
 211                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 212         fi
 213         if test $ol_enable_wrappers = yes ; then
 214                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 215         fi
 216         if test $ol_enable_phonetic = yes ; then
 217                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 218         fi
 219         if test $ol_enable_rlookups = yes ; then
 220                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 221         fi
 222         if test $ol_enable_aci = yes ; then
 223                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 224         fi
 225         if test $ol_with_ldbm_api != auto ; then
 226                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 227         fi
 228         if test $ol_with_ldbm_type != auto ; then
 229                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 230         fi
 231         if test $ol_with_dnssrv_module != static ; then
 232                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 233         fi
 234         if test $ol_with_ldap_module != static ; then
 235                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 236         fi
 237         if test $ol_with_ldbm_module != static ; then
 238                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 239         fi
 240         if test $ol_with_passwd_module != static ; then
 241                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 242         fi
 243         if test $ol_with_shell_module != static ; then
 244                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 245         fi
 246         if test $ol_enable_slurpd = yes ; then
 247                 AC_MSG_ERROR([slurpd requires slapd])
 248         fi
 249
 250         # force settings to no
 251         ol_enable_dnssrv=no
 252         ol_enable_ldap=no
 253         ol_enable_ldbm=no
 254         ol_enable_passwd=no
 255         ol_enable_shell=no
 256
 257         ol_enable_modules=no
 258         ol_enable_multimaster=no
 259         ol_enable_phonetic=no
 260         ol_enable_rlookups=no
 261         ol_enable_aci=no
 262         ol_enable_wrappers=no
 263         ol_enable_dynamic=no
 264
 265         ol_with_ldbm_api=no
 266         ol_with_ldbm_type=no
 267
 268         ol_with_dnssrv_module=static
 269         ol_with_ldap_module=static
 270         ol_with_ldbm_module=static
 271         ol_with_passwd_module=static
 272         ol_with_shell_module=static
 273
 274         ol_enable_slurpd=no
 275
 276 elif test $ol_enable_ldbm = no ; then
 277         dnl SLAPD without LDBM
 278
 279         if test $ol_with_ldbm_api != auto ; then
 280                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 281         fi
 282
 283         if test $ol_with_ldbm_type != auto ; then
 284                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 285         fi
 286
 287         if test $ol_with_ldbm_module != static ; then
 288                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 289         fi
 290
 291         if test $ol_enable_modules != yes -a \
 292                 $ol_enable_dnssrv = no -a \
 293                 $ol_enable_ldap = no -a \
 294                 $ol_enable_passwd = no -a \
 295                 $ol_enable_shell = no ; then
 296                 AC_MSG_ERROR([slapd requires a backend])
 297         fi
 298
 299         ol_with_ldbm_api=no
 300         ol_with_ldbm_type=no
 301         ol_with_ldbm_module=static
 302
 303 else
 304         dnl SLAPD with LDBM
 305         if test $ol_with_ldbm_api = gdbm -a \
 306                 $ol_with_ldbm_type = btree ; then
 307                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 308         fi
 309         if test $ol_with_ldbm_api = mdbm -a \
 310                 $ol_with_ldbm_type = btree ; then
 311                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 312         fi
 313         if test $ol_with_ldbm_api = ndbm -a \
 314                 $ol_with_ldbm_type = btree ; then
 315                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 316         fi
 317 fi
 318
 319 if test $ol_enable_slurpd = yes ; then
 320         dnl SLURPD was specifically enabled
 321         if test $ol_with_threads = no ; then
 322                 AC_MSG_ERROR([slurpd requires threads])
 323         fi
 324 fi
 325
 326 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 327         if test $ol_with_kerberos = no ; then
 328                 AC_MSG_ERROR([options require --with-kerberos])
 329         fi
 330 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 331         if test $ol_with_kerberos != auto ; then
 332                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 333         else
 334                 ol_with_kerberos=no
 335         fi
 336 fi
 337
 338 if test $ol_enable_spasswd = yes ; then
 339         if test $ol_with_cyrus_sasl = no ; then
 340                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 341         fi
 342         ol_link_spasswd=yes
 343 fi
 344
 345 AC_MSG_RESULT(done)
 346
 347 dnl ----------------------------------------------------------------
 348 dnl Initialize vars
 349 LDAP_LIBS=
 350 LDIF_LIBS=
 351 LDBM_LIBS=
 352 LTHREAD_LIBS=
 353 LUTIL_LIBS=
 354
 355 SLAPD_LIBS=
 356 SLURPD_LIBS=
 357
 358 BUILD_SLAPD=no
 359 BUILD_SLURPD=no
 360
 361 BUILD_THREAD=no
 362
 363 BUILD_DNSSRV=no
 364 BUILD_LDAP=no
 365 BUILD_LDBM=no
 366 BUILD_PASSWD=no
 367 BUILD_SHELL=no
 368
 369 BUILD_DNSSRV_DYNAMIC=static
 370 BUILD_LDAP_DYNAMIC=static
 371 BUILD_LDBM_DYNAMIC=static
 372 BUILD_PASSWD_DYNAMIC=static
 373 BUILD_SHELL_DYNAMIC=static
 374
 375 SLAPD_MODULES_LDFLAGS=
 376 SLAPD_MODULES_CPPFLAGS=
 377 SLAPD_MODULES_LIST=
 378
 379 KRB4_LIBS=
 380 KRB5_LIBS=
 381 READLINE_LIBS=
 382 SASL_LIBS=
 383 TERMCAP_LIBS=
 384 TLS_LIBS=
 385 MODULES_LIBS=
 386 AUTH_LIBS=
 387
 388 dnl ================================================================
 389 dnl Checks for programs
 390
 391 dnl AC_PROG_INSTALL
 392
 393 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 394
 395 dnl ----------------------------------------------------------------
 396 dnl
 397 dnl Determine which C translator to use
 398 dnl
 399
 400 dnl AIX Thread requires we use cc_r or xlc_r.
 401 dnl But only do this IF AIX and CC is not set
 402 dnl and threads are auto|yes|posix.
 403 dnl
 404 dnl If we find cc_r|xlc_r, force pthreads and assume
 405 dnl             pthread_create is in $LIBS (ie: don't bring in
 406 dnl             any additional thread libraries)
 407 dnl If we do not find cc_r|xlc_r, disable threads
 408
 409 ol_aix_threads=no
 410 case "$target" in
 411 *-*-aix*) dnl all AIX is not a good idea.
 412         if test -z "$CC" ; then
 413                 case "$ol_with_threads" in
 414                 auto | yes |  posix) ol_aix_threads=yes ;;
 415                 esac
 416         fi
 417 ;;
 418 esac
 419
 420 if test $ol_aix_threads = yes ; then
 421         if test -z "${CC}" ; then
 422                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 423
 424                 if test "$CC" = cc ; then
 425                         dnl no CC! don't allow --with-threads
 426                         if test $ol_with_threads != auto ; then
 427                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 428                         else
 429                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 430                         fi
 431                         ol_with_threads=no
 432                 fi
 433         fi
 434
 435         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 436                 ol_with_threads=posix
 437                 ol_cv_pthread_create=yes
 438         fi
 439 fi
 440
 441 if test -z "${CC}"; then
 442         AC_CHECK_PROGS(CC,cc)
 443 fi
 444
 445 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 446 dnl (for now, let autoconf sort this out)
 447 dnl CFLAGS=${CFLAGS-""}
 448
 449 AC_LIBTOOL_WIN32_DLL
 450 AC_LIBTOOL_DLOPEN
 451 AC_PROG_LIBTOOL
 452
 453 AC_PROG_AWK
 454 OL_PROG_LN_H
 455 AC_PROG_LN_S
 456
 457 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 458         LN_S="$LN_H"
 459 fi
 460
 461 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 462         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 463 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 464 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 465
 466 AC_PROG_CPP
 467
 468 dnl ----------------------------------------------------------------
 469 dnl Cross compiling checks
 470 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 471         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 472
 473 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 474         AC_MSG_WARN([programs compiled here do run here...])
 475         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 476
 477 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 478         AC_MSG_WARN([programs compiled here do not run here...])
 479         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 480 fi
 481
 482 dnl ----------------------------------------------------------------
 483 dnl Checks for UNIX Variants
 484 AC_AIX
 485 AC_ISC_POSIX
 486 AC_MINIX
 487
 488 dnl ----------------------------------------------------------------
 489 dnl Checks for system services
 490 AC_CYGWIN
 491 AC_MINGW32
 492 AC_EXEEXT
 493 AC_OBJEXT
 494
 495 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 496
 497 dnl ----------------------------------------------------------------
 498 dnl BeOS requires -lbe -lroot -lnet
 499 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 500
 501 dnl ----------------------------------------------------------------
 502 dnl OpenLDAP requires STDC features
 503 AM_PROG_CC_STDC
 504 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 505         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 506 fi
 507
 508 dnl ----------------------------------------------------------------
 509 dnl Check cc depend flags
 510 OL_MKDEPEND
 511 if test "${ol_cv_mkdep}" = no ; then
 512         # this will soon become an error
 513         AC_MSG_WARN([do not know how to generate dependencies])
 514 fi
 515
 516 dnl ----------------------------------------------------------------
 517 dnl Check for AIX security library
 518 AC_CHECK_LIB(s, afopen, [
 519         AUTH_LIBS=-ls
 520         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 521 ])
 522
 523
 524 dnl ----------------------------------------------------------------
 525 dnl PF_INET6 support requires getaddrinfo
 526 dnl PF_UNIX may use getaddrinfo in available
 527 AC_CHECK_FUNCS( getaddrinfo )
 528
 529 if test $ac_cv_func_getaddrinfo = no ; then
 530         if test $ol_enable_ipv6 = yes ; then
 531                 AC_MSG_ERROR([IPv6 support requires getaddrinfo()])
 532         fi
 533         ol_enable_ipv6=no
 534 fi
 535
 536 if test $ol_enable_unix != no ; then
 537         AC_CHECK_HEADERS( sys/un.h )
 538
 539         if test $ol_enable_unix = auto ; then
 540                 ol_enable_unix=$ac_cv_header_sys_un_h
 541         elif test $ac_cv_header_sys_un_h = no ; then
 542                 AC_MSG_ERROR([UNIX domain support requires sys/un.h])
 543         fi
 544 fi
 545
 546 dnl ----------------------------------------------------------------
 547 dnl Check for module support
 548 ol_link_modules=no
 549 if test $ol_enable_modules != no ; then
 550         AC_CHECK_HEADERS(ltdl.h)
 551
 552         if test $ac_cv_header_ltdl_h = no ; then
 553                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 554         fi
 555
 556         AC_CHECK_LIB(ltdl, lt_dlinit, [
 557             MODULES_LIBS=-lltdl
 558             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 559         ])
 560
 561         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 562                 AC_MSG_ERROR([could not locate libtool -lltdl])
 563         fi
 564         ol_link_modules=yes
 565 else
 566         ol_with_dnssrv_module=static
 567         ol_with_ldap_module=static
 568         ol_with_ldbm_module=static
 569         ol_with_passwd_module=static
 570         ol_with_shell_module=static
 571 fi
 572
 573 dnl ----------------------------------------------------------------
 574 dnl Checks for header files.
 575 OL_HEADER_STDC
 576
 577 if test $ol_cv_header_stdc != yes; then
 578         AC_MSG_WARN([could not locate Standard C compliant headers])
 579 fi
 580
 581 AC_HEADER_DIRENT
 582 AC_HEADER_SYS_WAIT
 583 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 584 if test $am_cv_sys_posix_termios = yes ; then
 585         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 586                 [define if you have POSIX termios])
 587 fi
 588
 589 AC_CHECK_HEADERS(       \
 590         arpa/inet.h             \
 591         arpa/nameser.h  \
 592         assert.h                \
 593         conio.h                 \
 594         crypt.h                 \
 595         direct.h                \
 596         errno.h                 \
 597         fcntl.h                 \
 598         filio.h                 \
 599         getopt.h                \
 600         grp.h                   \
 601         io.h                    \
 602         libutil.h               \
 603         limits.h                \
 604         locale.h                \
 605         netinet/tcp.h   \
 606         malloc.h                \
 607         memory.h                \
 608         psap.h                  \
 609         pwd.h                   \
 610         process.h               \
 611         resolv.h                \
 612         sgtty.h                 \
 613         shadow.h                \
 614         stddef.h                \
 615         string.h                \
 616         strings.h               \
 617         sysexits.h              \
 618         sys/file.h              \
 619         sys/filio.h             \
 620         sys/errno.h             \
 621         sys/ioctl.h             \
 622         sys/param.h             \
 623         sys/resource.h  \
 624         sys/select.h    \
 625         sys/socket.h    \
 626         sys/syslog.h    \
 627         sys/time.h              \
 628         sys/types.h             \
 629         syslog.h                \
 630         termios.h               \
 631         unistd.h                \
 632         winsock.h               \
 633 )
 634
 635
 636 dnl ----------------------------------------------------------------
 637 dnl Checks for libraries
 638
 639 dnl HP-UX requires -lV3
 640 AC_CHECK_LIB(V3, sigset)
 641
 642 dnl Gotta check for winsock manually
 643 if test $ac_cv_header_winsock_h = yes; then
 644         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 645         AC_TRY_LINK([#include <winsock.h>],[
 646                         socket(0,0,0);
 647                         select(0,NULL,NULL,NULL,NULL);
 648                         closesocket(0);
 649                         gethostname(NULL,0);
 650         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 651
 652         if test $ol_cv_winsock = yes ; then
 653                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 654                 ac_cv_func_socket=yes
 655                 ac_cv_func_select=yes
 656                 ac_cv_func_closesocket=yes
 657                 ac_cv_func_gethostname=yes
 658         fi
 659 fi
 660
 661 dnl Find socket()
 662 dnl Likely combinations:
 663 dnl             -lsocket [ -lnsl_s | -lnsl ]
 664 dnl             -linet
 665
 666 AC_CHECK_FUNC(socket, :, [
 667 dnl hopefully we won't include too many libraries
 668         AC_CHECK_LIB(socket, main)
 669         AC_CHECK_LIB(net, main)
 670         AC_CHECK_LIB(nsl_s, main)
 671         AC_CHECK_LIB(nsl, main)
 672         AC_CHECK_LIB(inet, socket)
 673         AC_CHECK_LIB(gen, main)
 674 ])
 675
 676 dnl require select
 677 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 678
 679 if test "${ac_cv_header_winsock_h}" != yes; then
 680     dnl Select arg types
 681     dnl (if this detection becomes permenent, it and the select() detection
 682     dnl should be done before the yielding select test)
 683     AC_FUNC_SELECT_ARGTYPES
 684 fi
 685
 686 dnl check to see if system call automatically restart
 687 dnl AC_SYS_RESTARTABLE_SYSCALLS
 688
 689 dnl ----------------------------------------------------------------
 690 dnl require POSIX regex
 691 AC_CHECK_HEADERS( regex.h )
 692 if test "$ac_cv_header_regex_h" != yes ; then
 693         AC_MSG_ERROR([POSIX regex.h required.])
 694 fi
 695 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 696
 697 OL_POSIX_REGEX
 698 if test "$ol_cv_c_posix_regex" = no ; then
 699         AC_MSG_ERROR([broken POSIX regex!])
 700 fi
 701
 702 dnl ----------------------------------------------------------------
 703 dnl Check for resolver routines
 704 ol_link_dnssrv=no
 705 AC_CHECK_FUNC(res_query,:)
 706 if test $ac_cv_func_res_query = no ; then
 707         AC_CHECK_LIB(bind, res_query)
 708         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 709 fi
 710
 711 if test $ac_cv_func_res_query = no ; then
 712         AC_CHECK_LIB(bind, __res_query)
 713         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 714 fi
 715
 716 if test $ac_cv_func_res_query = no ; then
 717         AC_CHECK_LIB(resolv, res_query)
 718         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 719 fi
 720
 721 if test "$ac_cv_func_res_query" = yes ; then
 722         AC_DEFINE(HAVE_RES_QUERY,1,
 723                 [define if you have res_query()])
 724
 725         if test $ol_enable_dnssrv != no ; then
 726                 ol_link_dnssrv=yes
 727         fi
 728 fi
 729
 730 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 731         AC_MSG_ERROR([DNSSRV requires res_query()])
 732 fi
 733
 734 dnl ----------------------------------------------------------------
 735 dnl Kerberos
 736 ol_link_kbind=no
 737 ol_link_kpasswd=no
 738 ol_link_krb5=no
 739 ol_link_krb4=no
 740
 741 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 \
 742         -o $ol_with_kerberos = k5only -o $ol_with_kerberos = k425 ; then
 743
 744         AC_CHECK_HEADERS(krb5.h)
 745
 746         if test $ac_cv_header_krb5_h = yes ; then
 747                 dnl lazy check for Heimdal Kerberos
 748                 AC_CHECK_HEADERS(heim_err.h)
 749                 if test $ac_cv_header_heim_err_h = yes ; then
 750                         krb5_impl=heimdal
 751                 else
 752                         krb5_impl=mit
 753                 fi
 754
 755                 if test $krb5_impl = mit; then
 756                         AC_CHECK_LIB(krb5, main,
 757                                 [have_krb5=yes
 758                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 759                                 [have_krb5=no],
 760                                 [-lcrypto -lcom_err])
 761
 762                 elif test $krb5_impl = heimdal; then
 763                         AC_CHECK_LIB(krb5, main,
 764                                 [have_krb5=yes
 765                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 766                                 [have_krb5=no],
 767                                 [-ldes -lasn1 -lroken -lcom_err])
 768
 769                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 770                                 [define if you have HEIMDAL Kerberos])
 771                 else
 772                         have_krb5=no
 773                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 774                 fi
 775
 776                 if test $have_krb5 = yes ; then
 777                         ol_link_krb5=yes
 778
 779                         AC_DEFINE(HAVE_KRB5, 1,
 780                                 [define if you have Kerberos V])
 781
 782                         if test $ol_enable_kpasswd != no ; then
 783                                 ol_link_kpasswd=yes;
 784                         fi
 785
 786                         if test $ol_with_kerberos = k5only ; then
 787                                 ol_with_kerberos=found
 788                         fi
 789
 790                 elif test $ol_with_kerberos != auto ; then
 791                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 792                 fi
 793
 794         fi
 795 fi
 796
 797 if test $ol_link_krb5 = yes -a \
 798         \( $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 799
 800         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 801
 802         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 803                 if test $krb5_impl = mit; then
 804                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 805                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 806                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 807
 808                 elif test $krb5_impl = heimdal; then
 809                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 810                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 811                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 812
 813                 else
 814                         have_425=no
 815                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 816                 fi
 817
 818                 if test $have_k425 = yes ; then
 819                         ol_with_kerberos=found
 820                         ol_link_krb4=yes
 821
 822                         AC_DEFINE(HAVE_KRB425, 1,
 823                                 [define if you have Kerberos V with IV support])
 824                         AC_DEFINE(HAVE_KRB4, 1,
 825                                 [define if you have Kerberos IV])
 826
 827                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 828                                 [ol_cv_var_des_debug], [
 829                                 dnl save the flags
 830                                 save_LIBS="$LIBS"
 831                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 832                                 AC_TRY_LINK([
 833 #include <kerberosIV/krb.h>
 834 #include <kerberosIV/des.h>
 835 extern int des_debug;
 836 ],[
 837 des_debug = 1;
 838 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 839                                 dnl restore the LIBS
 840                                 LIBS="$save_LIBS"
 841                         ])
 842
 843                         if test $ol_cv_var_des_debug = yes ; then
 844                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 845                                         [define if you have Kerberos des_debug])
 846                         fi
 847
 848                         LIBS="$save_LIBS"
 849                 fi
 850         fi
 851 fi
 852
 853 if test $ol_link_krb5 = yes ; then
 854         ol_with_kerberos=found
 855 fi
 856
 857 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 \
 858         -o $ol_with_kerberos = kth ; then
 859
 860         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 861
 862         if test $ac_cv_header_krb_h = yes ; then
 863                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 864
 865                 if test $have_k4 = yes ; then
 866                         ol_with_kerberos=found
 867                         ol_link_krb4=yes
 868
 869                         AC_DEFINE(HAVE_KRB4, 1,
 870                                 [define if you have Kerberos IV])
 871
 872                         KRB4_LIBS="-lkrb -ldes"
 873
 874                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 875                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 876                                         [define if you have Kth Kerberos])
 877                         fi
 878                 fi
 879         fi
 880 fi
 881
 882 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 883         ol_link_kpasswd=yes;
 884 fi
 885
 886 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 887         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 888
 889 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 890         AC_MSG_ERROR([Kerberos detection failed.])
 891 fi
 892
 893 dnl ----------------------------------------------------------------
 894 dnl TLS/SSL
 895 ol_link_tls=no
 896 if test $ol_with_tls != no ; then
 897
 898         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 899
 900         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 901                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 902                         [have_ssleay=yes
 903                         need_rsaref=no],
 904                         [have_ssleay=no],
 905                         [-lcrypto])
 906
 907                 if test $have_ssleay = no ; then
 908                         AC_CHECK_LIB(ssl, SSL_library_init,
 909                                 [have_ssleay=yes
 910                                 need_rsaref=no], [have_ssleay=no],
 911                                 [-lcrypto])
 912                 fi
 913
 914                 if test $have_ssleay = no ; then
 915                         AC_CHECK_LIB(ssl, ssl3_accept,
 916                                 [have_ssleay=yes
 917                                 need_rsaref=yes], [have_ssleay=no],
 918                                 [-lcrypto -lRSAglue -lrsaref])
 919                 fi
 920
 921                 if test $have_ssleay = yes ; then
 922                         ol_with_tls=found
 923                         ol_link_tls=yes
 924
 925                         AC_DEFINE(HAVE_SSLEAY, 1,
 926                                 [define if you have SSLeay or OpenSSL])
 927
 928                         if test $need_rsaref = yes; then
 929                                 AC_DEFINE(HAVE_RSAREF, 1,
 930                                         [define if you have RSAref])
 931
 932                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 933                         else
 934                                 TLS_LIBS="-lssl -lcrypto"
 935                         fi
 936                 fi
 937         fi
 938 fi
 939
 940 if test $ol_link_tls = yes ; then
 941         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 942 fi
 943
 944 dnl ----------------------------------------------------------------
 945 dnl Tests for reentrant functions necessary to build a
 946 dnl thread_safe -lldap.
 947 AC_CHECK_FUNCS(         \
 948         ctime_r                 \
 949         gethostbyname_r gethostbyaddr_r \
 950 )
 951
 952 if test "$ac_cv_func_ctime_r" = no ; then
 953         ol_cv_func_ctime_r_nargs=0
 954 else
 955         OL_FUNC_CTIME_R_NARGS
 956 dnl     OL_FUNC_CTIME_R_TYPE
 957 fi
 958
 959 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 960         OL_FUNC_GETHOSTBYNAME_R_NARGS
 961 else
 962         ol_cv_func_gethostbyname_r_nargs=0
 963 fi
 964
 965 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 966         OL_FUNC_GETHOSTBYADDR_R_NARGS
 967 else
 968         ol_cv_func_gethostbyaddr_r_nargs=0
 969 fi
 970
 971 if test "$ac_cv_func_ctime_r" = yes \
 972         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 973         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 974         -a "$ac_cv_func_gethostbyname_r" = yes \
 975         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 976         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 977         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 978         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 979         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 980         ; then
 981
 982         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 983 fi
 984
 985 dnl ----------------------------------------------------------------
 986 dnl Threads?
 987 ol_link_threads=no
 988
 989 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 990         -o $ol_with_threads = nt ; then
 991
 992         OL_NT_THREADS
 993
 994         if test "$ol_cv_nt_threads" = yes ; then
 995         ol_link_threads=nt
 996         ol_with_threads=found
 997         ol_with_yielding_select=yes
 998
 999                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1000                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1001         fi
1002
1003         if test $ol_with_threads = nt ; then
1004                 AC_MSG_ERROR([could not locate NT Threads])
1005         fi
1006 fi
1007
1008 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1009         -o $ol_with_threads = posix ; then
1010
1011         AC_CHECK_HEADERS(pthread.h)
1012
1013         if test $ac_cv_header_pthread_h = yes ; then
1014                 OL_POSIX_THREAD_VERSION
1015
1016                 if test $ol_cv_pthread_version = final ; then
1017                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1018                                 [define if pthreads API compatible with final spec])
1019                 elif test $ol_cv_pthread_version = draft4 ; then
1020                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1021                                 [define if pthreads API compatible with draft4 spec])
1022                 else
1023                         AC_MSG_ERROR([unknown pthread version])
1024                 fi
1025
1026                 # consider threads found
1027                 ol_with_threads=found
1028
1029                 OL_HEADER_LINUX_THREADS
1030                 OL_HEADER_GNU_PTH_PTHREAD_H
1031
1032                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1033                         AC_CHECK_HEADERS(sched.h)
1034                 fi
1035
1036                 dnl Now the hard part, how to link?
1037                 dnl
1038                 dnl currently supported checks:
1039                 dnl
1040                 dnl Check for no flags
1041                 dnl     pthread_create() in $LIBS
1042                 dnl
1043                 dnl Check special pthread (final) flags
1044                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1045                 dnl     pthread_create() with -kthread (FreeBSD)
1046                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1047                 dnl     pthread_create() with -pthreads (?)
1048                 dnl     pthread_create() with -mthreads (AIX)
1049                 dnl     pthread_create() with -thread (?)
1050                 dnl
1051                 dnl Check pthread (final) libraries
1052                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1053                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1054                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1055                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1056                 dnl     pthread_create() in -lpthread (many)
1057                 dnl     pthread_create() in -lc_r (FreeBSD)
1058                 dnl
1059                 dnl Check pthread (draft4) flags (depreciated)
1060                 dnl     pthread_create() with -threads (OSF/1)
1061                 dnl
1062                 dnl Check pthread (draft4) libraries (depreciated)
1063                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1064                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1065                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1066                 dnl     pthread_create() in -lpthreads (many)
1067                 dnl
1068
1069                 dnl pthread_create in $LIBS
1070                 AC_CACHE_CHECK([for pthread_create in default libraries],
1071                         ol_cv_pthread_create,[
1072                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1073                         [ol_cv_pthread_create=yes],
1074                         [ol_cv_pthread_create=no],
1075                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1076                                 [ol_cv_pthread_create=yes],
1077                                 [ol_cv_pthread_create=no])])])
1078
1079                 if test $ol_cv_pthread_create != no ; then
1080                         ol_link_threads=posix
1081                         ol_link_pthreads=""
1082                 fi
1083
1084 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1085                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1086                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1087                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1088                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1089                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1090
1091                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1092                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1093                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1094                         [ol_cv_pthread_lpthread_lmach_lexc])
1095 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1096 dnl                     [ol_cv_pthread_lpthread_lexc])
1097
1098                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1099                         [ol_cv_pthread_lib_lpthread_woff])
1100
1101                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1102                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1103
1104                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1105
1106                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1107                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1108                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1109                         [ol_cv_pthread_lpthreads_lmach_lexc])
1110                 OL_PTHREAD_TRY([-lpthreads -lexc],
1111                         [ol_cv_pthread_lpthreads_lexc])
1112
1113                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1114
1115                 if test $ol_link_threads != no ; then
1116                         AC_DEFINE(HAVE_PTHREADS,1,
1117                                 [define if you have POSIX Threads])
1118
1119                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1120
1121                         dnl save flags
1122                         save_CPPFLAGS="$CPPFLAGS"
1123                         save_LIBS="$LIBS"
1124                         LIBS="$LTHREAD_LIBS $LIBS"
1125
1126                         dnl All POSIX Thread (final) implementations should have
1127                         dnl sched_yield instead of pthread yield.
1128                         dnl check for both
1129                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1130
1131                         if test $ac_cv_func_sched_yield = no -a \
1132                                 $ac_cv_func_pthread_yield = no ; then
1133                                 dnl Digital UNIX has sched_yield() in -lrt
1134                                 AC_CHECK_LIB(rt, sched_yield,
1135                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1136                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1137                                                 [Define if you have the sched_yield function.])
1138                                         ac_cv_func_sched_yield=yes],
1139                                         [ac_cv_func_sched_yield=no])
1140                         fi
1141                         if test $ac_cv_func_sched_yield = no -a \
1142                                 $ac_cv_func_pthread_yield = no ; then
1143                                 dnl Solaris has sched_yield() stub in -lposix4
1144                                 dnl but we'll use thr_yield instead.
1145                                 AC_CHECK_FUNCS(thr_yield)
1146                         fi
1147                         if test $ac_cv_func_sched_yield = no -a \
1148                                 $ac_cv_func_pthread_yield = no -a \
1149                                 "$ac_cv_func_thr_yield" = no ; then
1150                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1151                         fi
1152
1153                         dnl Check functions for compatibility
1154                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1155
1156                         dnl Check for pthread_detach with <pthread.h> inclusion
1157                         dnl as it's symbol may have been mangled.
1158                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1159                                 [ol_cv_func_pthread_detach], [
1160                                 dnl save the flags
1161                                 AC_TRY_LINK([
1162 #include <pthread.h>
1163 #ifndef NULL
1164 #define NULL (void*)0
1165 #endif
1166 ],
1167                                         [pthread_detach(NULL);],
1168                                         [ol_cv_func_pthread_detach=yes],
1169                                         [ol_cv_func_pthread_detach=no])
1170                         ])
1171
1172                         if test $ol_cv_func_pthread_detach = no ; then
1173                                 AC_MSG_ERROR([could not locate pthread_detach()])
1174                         fi
1175
1176                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1177                                 [define if you have pthread_detach function])
1178
1179                         dnl Check for setconcurreny functions
1180                         AC_CHECK_FUNCS( \
1181                                 pthread_setconcurrency \
1182                                 pthread_getconcurrency \
1183                                 thr_setconcurrency \
1184                                 thr_getconcurrency \
1185                         )
1186
1187                         OL_SYS_LINUX_THREADS
1188                         OL_LINUX_THREADS
1189
1190                         if test $ol_cv_linux_threads = error; then
1191                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1192                         fi
1193
1194                         AC_CACHE_CHECK([if pthread_create() works],
1195                                 ol_cv_pthread_create_works,[
1196                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1197                                 [ol_cv_pthread_create_works=yes],
1198                                 [ol_cv_pthread_create_works=no],
1199                                 [dnl assume yes
1200                                 ol_cv_pthread_create_works=yes])])
1201
1202                         if test $ol_cv_pthread_create_works = no ; then
1203                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1204                         fi
1205
1206                         dnl Check if select causes an yield
1207                         if test $ol_with_yielding_select = auto ; then
1208                                 AC_CACHE_CHECK([if select yields when using pthreads],
1209                                         ol_cv_pthread_select_yields,[
1210                                 AC_TRY_RUN([
1211 #include <sys/types.h>
1212 #include <sys/time.h>
1213 #include <unistd.h>
1214 #include <pthread.h>
1215 #ifndef NULL
1216 #define NULL (void*) 0
1217 #endif
1218
1219 static int fildes[2];
1220
1221 static void *task(p)
1222         void *p;
1223 {
1224         int i;
1225         struct timeval tv;
1226
1227         fd_set rfds;
1228
1229         tv.tv_sec=10;
1230         tv.tv_usec=0;
1231
1232         FD_ZERO(&rfds);
1233         FD_SET(fildes[0], &rfds);
1234
1235         /* we're not interested in any fds */
1236         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1237
1238         if(i < 0) {
1239                 perror("select");
1240                 exit(10);
1241         }
1242
1243         exit(0); /* if we exit here, the select blocked the whole process */
1244 }
1245
1246 int main(argc, argv)
1247         int argc;
1248         char **argv;
1249 {
1250         pthread_t t;
1251
1252         /* create a pipe to select */
1253         if(pipe(&fildes[0])) {
1254                 perror("select");
1255                 exit(1);
1256         }
1257
1258 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1259         (void) pthread_setconcurrency(2);
1260 #else
1261 #ifdef HAVE_THR_SETCONCURRENCY
1262         /* Set Solaris LWP concurrency to 2 */
1263         thr_setconcurrency(2);
1264 #endif
1265 #endif
1266
1267 #if HAVE_PTHREADS_D4
1268         pthread_create(&t, pthread_attr_default, task, NULL);
1269 #else
1270         pthread_create(&t, NULL, task, NULL);
1271 #endif
1272
1273 #if HAVE_SCHED_YIELD
1274         sched_yield();  /* make sure task runs first */
1275 #else
1276 #ifdef HAVE_PTHREAD_YIELD
1277         pthread_yield();        /* make sure task runs first */
1278 #endif
1279 #endif
1280
1281         exit(2);
1282 }],
1283                                 [ol_cv_pthread_select_yields=no],
1284                                 [ol_cv_pthread_select_yields=yes],
1285                                 [ol_cv_pthread_select_yields=cross])])
1286
1287                                 if test $ol_cv_pthread_select_yields = cross ; then
1288                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1289                                 fi
1290
1291                                 if test $ol_cv_pthread_select_yields = yes ; then
1292                                         ol_with_yielding_select=yes
1293                                 fi
1294                         fi
1295
1296                         dnl restore flags
1297                         CPPFLAGS="$save_CPPFLAGS"
1298                         LIBS="$save_LIBS"
1299                 else
1300                         AC_MSG_ERROR([could not link with POSIX Threads])
1301                 fi
1302         fi
1303
1304         if test $ol_with_threads = posix ; then
1305                 AC_MSG_ERROR([could not locate POSIX Threads])
1306         fi
1307 fi
1308
1309 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1310         -o $ol_with_threads = mach ; then
1311
1312         dnl check for Mach CThreads
1313         AC_CHECK_HEADERS(mach/cthreads.h)
1314         if test $ac_cv_header_mach_cthreads_h = yes ; then
1315                 ol_with_threads=found
1316
1317                 dnl check for cthread support in current $LIBS
1318                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1319
1320                 if test $ol_link_threads = no ; then
1321                         dnl try -all_load
1322                         dnl this test needs work
1323                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1324                                 [ol_cv_cthread_all_load], [
1325                                 dnl save the flags
1326                                 save_LIBS="$LIBS"
1327                                 LIBS="-all_load $LIBS"
1328                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1329                                         cthread_fork((void *)0, (void *)0);
1330                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1331                                 dnl restore the LIBS
1332                                 LIBS="$save_LIBS"
1333                         ])
1334
1335                         if test $ol_cv_cthread_all_load = yes ; then
1336                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1337                                 ol_link_threads=mach
1338                         fi
1339                 fi
1340
1341                 if test $ol_link_threads != no ; then
1342                         : check for cthread specific functionality here
1343                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1344                                 [define if you have Mach Cthreads])
1345                 else
1346                         AC_MSG_ERROR([could not link with Mach CThreads])
1347                 fi
1348         fi
1349
1350         if test $ol_with_threads = mach ; then
1351                 AC_MSG_ERROR([could not locate Mach CThreads])
1352         fi
1353 fi
1354
1355 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1356         -o $ol_with_threads = pth ; then
1357
1358         AC_CHECK_HEADERS(pth.h)
1359
1360         if test $ac_cv_header_pth_h = yes ; then
1361                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1362
1363                 if test $have_pth = yes ; then
1364                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1365                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1366                         ol_link_threads=pth
1367
1368                         if test $ol_with_yielding_select = auto ; then
1369                                 ol_with_yielding_select=yes
1370                         fi
1371                 fi
1372         fi
1373 fi
1374
1375 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1376         -o $ol_with_threads = lwp ; then
1377
1378         dnl check for SunOS5 LWP
1379         AC_CHECK_HEADERS(thread.h synch.h)
1380         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1381                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1382
1383                 if test $have_thr = yes ; then
1384                         AC_DEFINE(HAVE_THR,1,
1385                                 [if you have Solaris LWP (thr) package])
1386                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1387                         ol_link_threads=thr
1388
1389                         if test $ol_with_yielding_select = auto ; then
1390                                 ol_with_yielding_select=yes
1391                         fi
1392
1393                         dnl Check for setconcurreny functions
1394                         AC_CHECK_FUNCS( \
1395                                 thr_setconcurrency \
1396                                 thr_getconcurrency \
1397                         )
1398                 fi
1399         fi
1400
1401         dnl check for SunOS4 LWP
1402         AC_CHECK_HEADERS(lwp/lwp.h)
1403         if test $ac_cv_header_lwp_lwp_h = yes ; then
1404                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1405
1406                 if test $have_lwp = yes ; then
1407                         AC_DEFINE(HAVE_LWP,1,
1408                                 [if you have SunOS LWP package])
1409                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1410                         ol_link_threads=lwp
1411
1412                         if test $ol_with_yielding_select = auto ; then
1413                                 ol_with_yielding_select=no
1414                         fi
1415                 fi
1416         fi
1417 fi
1418
1419 if test $ol_with_yielding_select = yes ; then
1420         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1421                 [define if select implicitly yields])
1422 fi
1423
1424 if test $ol_with_threads = manual ; then
1425         dnl User thinks he can manually configure threads.
1426         ol_link_threads=yes
1427
1428         AC_MSG_WARN([thread defines and link options must be set manually])
1429
1430         AC_CHECK_HEADERS(pthread.h sched.h)
1431         AC_CHECK_FUNCS(sched_yield pthread_yield)
1432         OL_HEADER_LINUX_THREADS
1433
1434         AC_CHECK_HEADERS(mach/cthreads.h)
1435         AC_CHECK_HEADERS(lwp/lwp.h)
1436         AC_CHECK_HEADERS(thread.h synch.h)
1437 fi
1438
1439 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1440         dnl needed to get reentrant/threadsafe versions
1441         dnl
1442         AC_DEFINE(REENTRANT,1)
1443         AC_DEFINE(_REENTRANT,1)
1444         AC_DEFINE(THREAD_SAFE,1)
1445         AC_DEFINE(_THREAD_SAFE,1)
1446         AC_DEFINE(THREADSAFE,1)
1447         AC_DEFINE(_THREADSAFE,1)
1448         AC_DEFINE(_SGI_MP_SOURCE,1)
1449
1450         dnl The errno declaration may dependent upon _REENTRANT.
1451         dnl If it does, we must link with thread support.
1452         AC_CACHE_CHECK([for thread specific errno],
1453                 [ol_cv_errno_thread_specific], [
1454                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1455                         [ol_cv_errno_thread_specific=yes],
1456                         [ol_cv_errno_thread_specific=no])
1457         ])
1458
1459         dnl The h_errno declaration may dependent upon _REENTRANT.
1460         dnl If it does, we must link with thread support.
1461         AC_CACHE_CHECK([for thread specific h_errno],
1462                 [ol_cv_h_errno_thread_specific], [
1463                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1464                         [ol_cv_h_errno_thread_specific=yes],
1465                         [ol_cv_h_errno_thread_specific=no])
1466         ])
1467
1468         if test $ol_cv_errno_thread_specific != yes \
1469                 -o $ol_cv_h_errno_thread_specific != yes ; then
1470                 LIBS="$LTHREAD_LIBS $LIBS"
1471                 LTHREAD_LIBS=""
1472         fi
1473
1474 dnl When in thread environment, use
1475 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1476 dnl                     || defined( HAVE_FUNC_R )
1477 dnl                     func_r(...);
1478 dnl             #else
1479 dnl             #       if defined( HAVE_THREADS )
1480 dnl                             /* lock */
1481 dnl             #       endif
1482 dnl                             func(...);
1483 dnl             #       if defined( HAVE_THREADS )
1484 dnl                             /* unlock */
1485 dnl             #       endif
1486 dnl             #endif
1487 dnl
1488 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1489 dnl             _POSIX_REENTRANT_FUNCTIONS
1490 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1491 dnl             _POSIX_THREADSAFE_FUNCTIONS
1492 dnl
1493 dnl             and is currently defined in lthread.h
1494 dnl
1495 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1496 dnl
1497 dnl libldap/*.c should only include <lthread.h> iff
1498 dnl LDAP_R_COMPILE is defined.  ie:
1499 dnl             #ifdef LDAP_R_COMPILE
1500 dnl             #       include LDAP_R_COMPILE
1501 dnl             #endif
1502 dnl
1503 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1504 dnl specifically for compiling the threadsafe version of
1505 dnl     the ldap library (-lldap_r).
1506 dnl
1507 dnl     dnl check for reentrant/threadsafe functions
1508 dnl     dnl
1509 dnl     dnl note: these should only be used when linking
1510 dnl     dnl       with $LTHREAD_LIBS
1511 dnl     dnl
1512 dnl     save_CPPFLAGS="$CPPFLAGS"
1513 dnl     save_LIBS="$LIBS"
1514 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1515 dnl     AC_CHECK_FUNCS( \
1516 dnl             gmtime_r \
1517 dnl             gethostbyaddr_r gethostbyname_r \
1518 dnl             feof_unlocked unlocked_feof \
1519 dnl             putc_unlocked unlocked_putc \
1520 dnl             flockfile ftrylockfile \
1521 dnl     )
1522 dnl     CPPFLAGS="$save_CPPFLAGS"
1523 dnl     LIBS="$save_LIBS"
1524 fi
1525
1526 if test $ol_link_threads = no ; then
1527         if test $ol_with_threads = yes ; then
1528                 AC_MSG_ERROR([no suitable thread support])
1529         fi
1530
1531         if test $ol_with_threads = auto ; then
1532                 AC_MSG_WARN([no suitable thread support, disabling threads])
1533                 ol_with_threads=no
1534         fi
1535
1536         AC_DEFINE(NO_THREADS,1,
1537                 [define if you have (or want) no threads])
1538         LTHREAD_LIBS=""
1539 fi
1540
1541 if test $ol_link_threads != no ; then
1542         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1543 fi
1544
1545 dnl ----------------------------------------------------------------
1546 ol_link_ldbm=no
1547
1548 if test $ol_with_ldbm_api = auto \
1549         -o $ol_with_ldbm_api = berkeley \
1550         -o $ol_with_ldbm_api = bcompat ; then
1551
1552         if test $ol_with_ldbm_api = bcompat; then \
1553                 OL_BERKELEY_COMPAT_DB
1554         else
1555                 OL_BERKELEY_DB
1556         fi
1557
1558         if test $ol_cv_berkeley_db != no ; then
1559                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1560                         [define this if Berkeley DB is available])
1561
1562                 ol_link_ldbm=berkeley
1563                 ol_with_ldbm_api=db
1564
1565                 if test $ol_with_ldbm_type = hash ; then
1566                         AC_DEFINE(LDBM_USE_DBHASH,1,
1567                                 [define this to use DBHASH w/ LDBM backend])
1568                 else
1569                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1570                                 [define this to use DBBTREE w/ LDBM backend])
1571                 fi
1572
1573                 dnl $ol_cv_lib_db should be yes or -ldb
1574                 dnl (it could be no, but that would be an error
1575                 if test $ol_cv_lib_db != yes ; then
1576                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1577                 fi
1578         fi
1579 fi
1580
1581 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1582         AC_MSG_WARN(Could not find LDBM with BTREE support)
1583         ol_with_ldbm_api=none
1584 fi
1585
1586 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1587         OL_MDBM
1588
1589         if test $ol_cv_mdbm = yes ; then
1590                 ol_link_ldbm=mdbm
1591                 ol_with_ldbm_api=mdbm
1592                 if test $ol_cv_lib_mdbm != yes ; then
1593                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1594                 fi
1595         fi
1596 fi
1597
1598 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1599         OL_GDBM
1600
1601         if test $ol_cv_gdbm = yes ; then
1602                 ol_link_ldbm=gdbm
1603                 ol_with_ldbm_api=gdbm
1604
1605                 if test $ol_cv_lib_gdbm != yes ; then
1606                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1607                 fi
1608         fi
1609 fi
1610
1611 if test $ol_with_ldbm_api = ndbm ; then
1612         OL_NDBM
1613
1614         if test $ol_cv_ndbm = yes ; then
1615                 ol_link_ldbm=ndbm
1616                 ol_with_ldbm_api=ndbm
1617
1618                 if test $ol_cv_lib_ndbm != yes ; then
1619                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1620                 fi
1621         fi
1622 fi
1623
1624 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1625         AC_MSG_WARN(could not find suitable LDBM backend)
1626         if test $ol_enable_ldbm = yes ; then
1627                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1628         fi
1629
1630         AC_MSG_WARN(disabling LDBM)
1631         ol_enable_ldbm=no
1632 fi
1633
1634 dnl ----------------------------------------------------------------
1635 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1636         LINK_BINS_DYNAMIC="yes"
1637 else
1638         LINK_BINS_DYNAMIC="no"
1639 fi
1640
1641 dnl ----------------------------------------------------------------
1642 if test $ol_enable_wrappers != no ; then
1643         AC_CHECK_HEADERS(tcpd.h)
1644
1645         if test $ac_cv_header_tcpd_h != yes ; then
1646                 have_wrappers=no
1647         else
1648                 AC_TRY_COMPILE([
1649 int allow_severity = 0;
1650 int deny_severity  = 0;
1651                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1652         fi
1653
1654         if test $have_wrappers = yes ; then
1655                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1656                 WRAP_LIBS="-lwrap"
1657
1658                 dnl We add another check for -lnsl since some libwrap's
1659                 dnl need it, but it isn't always included from above
1660                 AC_CHECK_LIB(nsl, main)
1661         else
1662                 AC_MSG_WARN(could not find -lwrap)
1663                 if test $ol_enable_wrappers = yes ; then
1664                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1665                 fi
1666
1667                 AC_MSG_WARN(disabling wrappers support)
1668                 ol_enable_wrappers=no
1669                 WRAP_LIBS=""
1670         fi
1671 fi
1672
1673 dnl ----------------------------------------------------------------
1674 if test $ol_enable_syslog != no ; then
1675         AC_CHECK_FUNC(openlog)
1676         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1677                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1678         fi
1679         ol_enable_syslog=$ac_cv_func_openlog
1680 fi
1681
1682 dnl ----------------------------------------------------------------
1683 dnl ud needs termcap (should insert check here)
1684 ol_link_termcap=no
1685 AC_CHECK_HEADERS(termcap.h ncurses.h)
1686
1687 if test $ol_link_termcap = no ; then
1688         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1689         if test $have_termcap = yes ; then
1690                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1691                 ol_link_termcap=yes
1692                 TERMCAP_LIBS=-ltermcap
1693         fi
1694 fi
1695
1696 if test $ol_link_termcap = no ; then
1697         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1698         if test $have_ncurses = yes ; then
1699                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1700                 ol_link_termcap=yes
1701                 TERMCAP_LIBS=-lncurses
1702         fi
1703 fi
1704
1705 if test $ol_link_termcap = no ; then
1706         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1707         TERMCAP_LIBS=
1708 fi
1709
1710 dnl ----------------------------------------------------------------
1711 dnl
1712 dnl Check for Cyrus SASL
1713 dnl
1714 ol_link_sasl=no
1715 ol_link_spasswd=no
1716 if test $ol_with_cyrus_sasl != no ; then
1717         AC_CHECK_HEADER(sasl.h)
1718
1719         if test $ac_cv_header_sasl_h = yes ; then
1720                 AC_CHECK_LIB(sasl, sasl_client_init,
1721                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1722
1723                 if test $have_cyrus_sasl != no ; then
1724                         SASL_LIBS="-lsasl"
1725                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1726                         ol_link_sasl=yes
1727                 fi
1728         fi
1729
1730         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1731                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1732         fi
1733 fi
1734
1735 dnl ----------------------------------------------------------------
1736 dnl Check for entropy sources
1737 if test $cross_compiling != yes ; then
1738         dev=no
1739         if test -r /dev/urandom ; then
1740                 dev="/dev/urandom";
1741         elif test -r /idev/urandom ; then
1742                 dev="/idev/urandom";
1743         elif test -r /dev/srandom ; then
1744                 dev="/dev/srandom";
1745         elif test -r /dev/random ; then
1746                 dev="/dev/random";
1747         elif test -r /idev/random ; then
1748                 dev="/idev/random";
1749         fi
1750
1751         if test $dev != no ; then
1752                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1753         fi
1754 fi
1755
1756 dnl ----------------------------------------------------------------
1757 dnl
1758 dnl Check for fetch URL support
1759 dnl             should be extended to support other fetch URL APIs
1760 dnl
1761 ol_link_fetch=no
1762 if test $ol_with_fetch != no ; then
1763         OL_LIB_FETCH
1764
1765         if test $ol_cv_lib_fetch != no ; then
1766                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1767                 ol_link_fetch=freebsd
1768
1769         elif test $ol_with_fetch != auto ; then
1770                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1771         fi
1772 fi
1773
1774 dnl ----------------------------------------------------------------
1775 dnl
1776 dnl Check for GNU readline
1777 dnl
1778 ol_link_readline=no
1779 if test $ol_with_readline != no ; then
1780         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1781
1782         if test $ac_cv_header_readline_readline_h = yes ; then
1783                 save_LIBS="$LIBS"
1784                 LIBS="$TERMCAP_LIBS $LIBS"
1785                 AC_CHECK_LIB(readline, readline,
1786                         [have_readline=yes], [have_readline=no])
1787                 LIBS="$save_LIBS"
1788
1789                 if test $have_readline = yes ; then
1790                         ol_with_readline=found
1791                         ol_link_readline=yes
1792
1793                         READLINE_LIBS="-lreadline"
1794                 fi
1795         fi
1796 fi
1797
1798 if test $ol_link_readline = yes ; then
1799         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1800 fi
1801
1802
1803 dnl ----------------------------------------------------------------
1804 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1805 if test $ol_enable_crypt != no ; then
1806         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1807                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1808                         have_crypt=yes], [have_crypt=no])])
1809
1810         if test $have_crypt = yes ; then
1811                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1812         else
1813                 AC_MSG_WARN(could not find crypt)
1814                 if test $ol_enable_crypt = yes ; then
1815                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1816                 fi
1817
1818                 AC_MSG_WARN(disabling crypt support)
1819                 ol_enable_crypt=no
1820         fi
1821 fi
1822
1823 dnl ----------------------------------------------------------------
1824 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1825 if test $ol_enable_proctitle != no ; then
1826         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1827                 AC_CHECK_LIB(util, setproctitle,
1828                         [have_setproctitle=yes
1829                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1830                         [have_setproctitle=no
1831                         LIBOBJS="$LIBOBJS setproctitle.o"
1832                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1833
1834         if test $have_setproctitle = yes ; then
1835                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1836                         [define if setproctitle(3) is available])
1837         fi
1838 fi
1839
1840 dnl ----------------------------------------------------------------
1841 dnl Checks for typedefs, structures, and compiler characteristics.
1842 AC_TYPE_MODE_T
1843 AC_TYPE_OFF_T
1844 AC_TYPE_PID_T
1845 AM_TYPE_PTRDIFF_T
1846 AC_TYPE_SIGNAL
1847 AC_TYPE_SIZE_T
1848
1849 AC_CHECK_TYPE(ssize_t, [signed int])
1850 AC_CHECK_TYPE(caddr_t,  [char *])
1851
1852 OL_TYPE_SOCKLEN_T
1853 AC_STRUCT_ST_BLKSIZE
1854 AC_HEADER_TIME
1855 AC_STRUCT_TM
1856 AC_TYPE_UID_T
1857 OL_TYPE_SIG_ATOMIC_T
1858
1859 dnl AC_TYPE_GETGROUPS
1860
1861 OL_STRUCT_PASSWD_PW_GECOS
1862 OL_STRUCT_PASSWD_PW_PASSWD
1863
1864 OL_C_UPPER_LOWER
1865 AC_C_CONST
1866 OL_C_VOLATILE
1867
1868 if test $cross_compiling = yes ; then
1869         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1870 else
1871         AC_C_BIGENDIAN
1872 fi
1873
1874 AC_COMPILE_CHECK_SIZEOF(short)
1875 AC_COMPILE_CHECK_SIZEOF(int)
1876 AC_COMPILE_CHECK_SIZEOF(long)
1877
1878 if test "$ac_cv_sizeof_int" -lt 4 ; then
1879         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1880
1881         AC_DEFINE(LBER_INT_T,long)
1882 else
1883         AC_DEFINE(LBER_INT_T,int)
1884 fi
1885
1886 AC_DEFINE(LBER_LEN_T,long)
1887 AC_DEFINE(LBER_SOCKET_T,int)
1888 AC_DEFINE(LBER_TAG_T,long)
1889
1890 dnl ----------------------------------------------------------------
1891 dnl Checks for library functions.
1892 AC_FUNC_MEMCMP
1893 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1894 AC_FUNC_STRFTIME
1895 dnl AM_FUNC_STRTOD
1896
1897 OL_FUNC_INET_ATON
1898
1899 dnl Check for NT specific routines
1900 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
1901
1902 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
1903         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
1904 ])
1905
1906 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
1907         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
1908 ])
1909
1910 AC_FUNC_VPRINTF
1911
1912 if test $ac_cv_func_vprintf = yes ; then
1913         dnl check for vsnprintf
1914         AC_CHECK_FUNCS(vsnprintf vsprintf)
1915 fi
1916
1917 AC_CHECK_FUNCS(         \
1918         bcopy                   \
1919         closesocket             \
1920         chroot                  \
1921         endgrent                \
1922         endpwent                \
1923         flock                   \
1924         getdtablesize   \
1925         getgrgid                \
1926         gethostname             \
1927         getpass                 \
1928         getpassphrase   \
1929         getpwuid                \
1930         getpwnam                \
1931         getspnam                \
1932         gettimeofday    \
1933         initgroups              \
1934         lockf                   \
1935         memcpy                  \
1936         memmove                 \
1937         mkstemp                 \
1938         pipe                    \
1939         read                    \
1940         recv                    \
1941         recvfrom                \
1942         setpwfile               \
1943         setgid                  \
1944         setegid                 \
1945         setsid                  \
1946         setuid                  \
1947         seteuid                 \
1948         sigaction               \
1949         signal                  \
1950         sigset                  \
1951         snprintf                \
1952         strdup                  \
1953         strerror                \
1954         strpbrk                 \
1955         strrchr                 \
1956         strsep                  \
1957         strstr                  \
1958         strtol                  \
1959         strtoul                 \
1960         strspn                  \
1961         sysconf                 \
1962         waitpid                 \
1963         wait4                   \
1964         write                   \
1965         send                    \
1966         sendto                  \
1967 )
1968
1969 dnl We actually may need to replace more than this.
1970 AC_REPLACE_FUNCS(getopt tempnam)
1971
1972 if test "$ac_cv_func_getopt" != yes; then
1973     LIBSRCS="$LIBSRCS getopt.c"
1974 fi
1975
1976 if test "$ac_cv_func_tempnam" != yes; then
1977     LIBSRCS="$LIBSRCS tempnam.c"
1978 fi
1979
1980 dnl ----------------------------------------------------------------
1981 # Check Configuration
1982 OL_SYS_ERRLIST
1983
1984 dnl ----------------------------------------------------------------
1985 dnl Sort out defines
1986
1987 if test "$ol_enable_debug" != no ; then
1988         AC_DEFINE(LDAP_DEBUG,1,
1989                 [define this to add debugging code])
1990 fi
1991 if test "$ol_enable_syslog" = yes ; then
1992         AC_DEFINE(LDAP_SYSLOG,1,
1993                 [define this to add syslog code])
1994 fi
1995 if test "$ol_enable_libui" = yes ; then
1996         AC_DEFINE(LDAP_LIBUI,1,
1997                 [define this for LDAP User Interface support])
1998 fi
1999 if test "$ol_enable_cache" = no ; then
2000         AC_DEFINE(LDAP_NOCACHE,1,
2001                 [define this to remove -lldap cache support])
2002 fi
2003 if test "$ol_link_kbind" != no ; then
2004         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2005 fi
2006 if test "$ol_enable_proctitle" != no ; then
2007         AC_DEFINE(LDAP_PROCTITLE,1,
2008                 [define this for LDAP process title support])
2009 fi
2010 if test "$ol_enable_referrals" != no ; then
2011         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2012 fi
2013 if test "$ol_enable_cldap" != no ; then
2014         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
2015 fi
2016 if test "$ol_enable_unix" != no; then
2017         AC_DEFINE(LDAP_PF_UNIX,1,[define to support PF_UNIX])
2018 fi
2019 if test "$ol_enable_ipv6" != no; then
2020         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2021 fi
2022 if test "$ol_enable_cleartext" != no ; then
2023         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2024 fi
2025 if test "$ol_enable_crypt" != no ; then
2026         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2027 fi
2028 if test "$ol_link_kpasswd" != no ; then
2029         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2030 fi
2031 if test "$ol_link_spasswd" != no ; then
2032         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2033 fi
2034 if test "$ol_enable_multimaster" != no ; then
2035         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2036 fi
2037 if test "$ol_enable_phonetic" != no ; then
2038         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2039 fi
2040 if test "$ol_enable_rlookups" != no ; then
2041         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2042 fi
2043 if test "$ol_enable_aci" != no ; then
2044         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2045 fi
2046
2047 if test "$ol_link_modules" != no ; then
2048         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2049         BUILD_SLAPD=yes
2050         SLAPD_MODULES_LDFLAGS="-dlopen self"
2051 fi
2052
2053 if test "$ol_link_dnssrv" != no ; then
2054         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2055         BUILD_SLAPD=yes
2056         BUILD_DNSSRV=yes
2057         if test "$ol_with_dnssrv_module" != static ; then
2058                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2059                         [define to support dynamic DNS SRV backend])
2060                 BUILD_DNSSRV=mod
2061                 BUILD_DNSSRV_DYNAMIC=shared
2062                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2063         fi
2064 fi
2065
2066 if test "$ol_enable_ldap" != no ; then
2067         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2068         BUILD_SLAPD=yes
2069         BUILD_LDAP=yes
2070         if test "$ol_with_ldap_module" != static ; then
2071                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2072                         [define to support dynamic LDAP backend])
2073                 BUILD_LDAP=mod
2074                 BUILD_LDAP_DYNAMIC=shared
2075                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2076         fi
2077 fi
2078
2079 if test "$ol_link_ldbm" != no ; then
2080         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2081         BUILD_SLAPD=yes
2082         BUILD_LDBM=yes
2083         if test "$ol_with_ldbm_module" != static ; then
2084                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2085                         [define to support dynamic LDBM backend])
2086                 BUILD_LDBM=mod
2087                 BUILD_LDBM_DYNAMIC=shared
2088                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2089         fi
2090 fi
2091
2092 if test "$ol_enable_passwd" != no ; then
2093         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2094         BUILD_SLAPD=yes
2095         BUILD_PASSWD=yes
2096         if test "$ol_with_passwd_module" != static ; then
2097                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2098                         [define to support dynamic PASSWD backend])
2099                 BUILD_PASSWD=mod
2100                 BUILD_PASSWD_DYNAMIC=shared
2101                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2102         fi
2103 fi
2104
2105 if test "$ol_enable_shell" != no ; then
2106         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2107         BUILD_SLAPD=yes
2108         BUILD_SHELL=yes
2109         if test "$ol_with_shell_module" != static ; then
2110                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2111                         [define to support dynamic SHELL backend])
2112                 BUILD_SHELL=mod
2113                 BUILD_SHELL_DYNAMIC=shared
2114                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2115         fi
2116 fi
2117
2118 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2119         $BUILD_SLAPD = yes ; then
2120         BUILD_SLURPD=yes
2121 fi
2122
2123 dnl ----------------------------------------------------------------
2124
2125 if test "$LINK_BINS_DYNAMIC" = yes; then
2126     LIB_LINKAGE=DYN
2127     LT_LIB_LINKAGE=shared
2128 else
2129     LIB_LINKAGE=STAT
2130     LT_LIB_LINKAGE=static
2131 fi
2132
2133 if test "$ac_cv_mingw32" = yes ; then
2134     PLAT=NT
2135     DYN_EXT=dll
2136 else
2137     PLAT=UNIX
2138     DYN_EXT=so
2139 fi
2140
2141 AC_SUBST(LIBSRCS)
2142
2143 AC_SUBST(PLAT)
2144 AC_SUBST(LIB_LINKAGE)
2145 AC_SUBST(LT_LIB_LINKAGE)
2146 AC_SUBST(DYN_EXT)
2147
2148 AC_SUBST(BUILD_SLAPD)
2149   AC_SUBST(BUILD_DNSSRV)
2150   AC_SUBST(BUILD_LDAP)
2151   AC_SUBST(BUILD_LDBM)
2152   AC_SUBST(BUILD_PASSWD)
2153   AC_SUBST(BUILD_SHELL)
2154   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2155   AC_SUBST(BUILD_LDAP_DYNAMIC)
2156   AC_SUBST(BUILD_LDBM_DYNAMIC)
2157   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2158   AC_SUBST(BUILD_SHELL_DYNAMIC)
2159 AC_SUBST(BUILD_SLURPD)
2160
2161 AC_SUBST(LDAP_LIBS)
2162 AC_SUBST(LDIF_LIBS)
2163 AC_SUBST(SLAPD_LIBS)
2164 AC_SUBST(SLURPD_LIBS)
2165 AC_SUBST(LDBM_LIBS)
2166 AC_SUBST(LTHREAD_LIBS)
2167 AC_SUBST(LUTIL_LIBS)
2168 AC_SUBST(WRAP_LIBS)
2169 AC_SUBST(LINK_BINS_DYNAMIC)
2170
2171 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2172 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2173 AC_SUBST(SLAPD_MODULES_LIST)
2174
2175 AC_SUBST(KRB4_LIBS)
2176 AC_SUBST(KRB5_LIBS)
2177 AC_SUBST(READLINE_LIBS)
2178 AC_SUBST(SASL_LIBS)
2179 AC_SUBST(TERMCAP_LIBS)
2180 AC_SUBST(TLS_LIBS)
2181 AC_SUBST(MODULES_LIBS)
2182 AC_SUBST(AUTH_LIBS)
2183
2184 dnl ----------------------------------------------------------------
2185 dnl final output
2186 dnl
2187
2188 AC_OUTPUT( \
2189 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2190 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2191 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2192 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2193 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2194 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2195 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2196 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2197 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2198 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2199 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2200 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2201 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2202 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2203 clients/maildap/Makefile:build/top.mk:clients/maildap/Makefile.in:build/rules.mk \
2204 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2205 include/Makefile:build/top.mk:include/Makefile.in \
2206 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2207 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2208 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2209 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2210 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2211 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2212 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2213 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2214 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2215 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2216 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2217 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2218 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2219 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2220 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2221 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2222 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2223 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2224 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2225 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2226 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2227 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2228 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2229 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2230 ,[
2231 date > stamp-h
2232 echo Please \"make depend\" to build dependencies
2233 ])