git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(build/version)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17
  18 OL_VERSION=`cat $ac_aux_dir/version`
  19 if test -z "$OL_VERSION"; then
  20         AC_MSG_ERROR([could not determine version])
  21 fi
  22
  23 dnl ----------------------------------------------------------------
  24 dnl Determine host platform
  25 dnl             we try not to use this for much
  26 AC_CANONICAL_SYSTEM
  27
  28 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  29 AC_SUBST(PACKAGE)
  30 AC_SUBST(VERSION)
  31 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  32 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  33
  34 dnl We use autoconf features new to 2.13.
  35 dnl aclocal.m4 should be built using aclocal from automake 1.4
  36 dnl libtool 1.3.3 should be installed.
  37 AC_PREREQ(2.13)dnl Required Autoconf version
  38
  39 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  40
  41 dnl ----------------------------------------------------------------
  42 dnl Start Args
  43 AC_MSG_CHECKING(configure arguments)
  44 AC_PREFIX_DEFAULT(/usr/local)
  45
  46 top_builddir=`pwd`
  47 AC_SUBST(top_builddir)dnl
  48
  49 ldap_subdir="openldap"
  50
  51 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  52         if test "$withval" = "no"; then
  53                 ldap_subdir=""
  54         elif test "$withval" != "yes"; then
  55                 ldap_subdir="$withval"
  56         fi
  57 ])dnl
  58
  59 AC_SUBST(ldap_subdir)dnl
  60
  61 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  62 dnl ol_enable_syslog=no
  63 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  64 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  65 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  66 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  67 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  68 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  69 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  70         no, [yes no])dnl
  71
  72 dnl General "with" options
  73 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  74
  75 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl  with Cyrus SASL support],
  76         auto, [auto yes no] )
  77 OL_ARG_WITH(fetch,[  --with-fetch  with fetch URL support],
  78         auto, [auto yes no] )
  79 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  80         auto, [auto k5 k4 afs yes no])
  81 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  82         auto, [auto yes no] )
  83 OL_ARG_WITH(threads,[  --with-threads   use threads],
  84         auto, [auto posix mach lwp yes no manual] )
  85 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  86         auto, [auto ssleay openssl yes no] )
  87 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  88         auto, [auto yes no manual] )
  89
  90 dnl Server options
  91
  92 dnl LDAPD OPTIONS
  93 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  94 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  95
  96 dnl SLAPD OPTIONS
  97 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  98 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  99 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 100 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 101 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 102 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 103 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 104 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 105
 106 dnl SLAPD Backend options
 107 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 108 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 109         [static dynamic])
 110 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 111 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 112         [static dynamic])
 113 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 114 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 115         [static dynamic])
 116 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 117         [auto db2 db mdbm gdbm ndbm manual])
 118 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 119         [auto btree hash])
 120
 121 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 122 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 123         [static dynamic])
 124 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 125 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 126         [static dynamic])
 127 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 128 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 129         [static dynamic])
 130 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 131 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 132         [static dynamic])
 133
 134 dnl SLURPD OPTIONS
 135 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 136 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 137
 138 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 139 AC_ENABLE_STATIC
 140 dnl AC_DISABLE_SHARED
 141 AC_ENABLE_SHARED
 142
 143 dnl General "enable" options
 144 # validate options
 145 if test $ol_enable_dns = yes ; then
 146         if test $ol_enable_referrals = no ; then
 147                 AC_MSG_ERROR([DNS requires --enable-referrals])
 148         fi
 149         if test $ol_enable_referrals = auto ; then
 150                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 151                 ol_enable_referrals=yes
 152         fi
 153 fi
 154
 155 if test $ol_enable_slapd = no ; then
 156         dnl SLAPD was specificallly disabled
 157         if test $ol_enable_bdb2 = yes ; then
 158                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 159         fi
 160         if test $ol_enable_ldap = yes ; then
 161                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 162         fi
 163         if test $ol_enable_ldbm = yes ; then
 164                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 165         fi
 166         if test $ol_enable_passwd = yes ; then
 167                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 168         fi
 169         if test $ol_enable_perl = yes ; then
 170                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 171         fi
 172         if test $ol_enable_shell = yes ; then
 173                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 174         fi
 175         if test $ol_enable_tcl = yes ; then
 176                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 177         fi
 178         if test $ol_enable_modules = yes ; then
 179                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 180         fi
 181         if test $ol_enable_wrappers = yes ; then
 182                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 183         fi
 184         if test $ol_enable_phonetic = yes ; then
 185                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 186         fi
 187         if test $ol_enable_rlookups = yes ; then
 188                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 189         fi
 190         if test $ol_with_ldbm_api != auto ; then
 191                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 192         fi
 193         if test $ol_with_ldbm_type != auto ; then
 194                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 195         fi
 196         if test $ol_with_bdb2_module != static ; then
 197                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 198         fi
 199         if test $ol_with_ldap_module != static ; then
 200                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 201         fi
 202         if test $ol_with_ldbm_module != static ; then
 203                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 204         fi
 205         if test $ol_with_passwd_module != static ; then
 206                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 207         fi
 208         if test $ol_with_perl_module != static ; then
 209                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 210         fi
 211         if test $ol_with_shell_module != static ; then
 212                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 213         fi
 214         if test $ol_with_tcl_module != static ; then
 215                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 216         fi
 217         if test $ol_enable_slurpd = yes ; then
 218                 AC_MSG_ERROR([slurpd requires slapd])
 219         fi
 220
 221         # force settings to no
 222         ol_enable_bdb2=no
 223         ol_enable_ldap=no
 224         ol_enable_ldbm=no
 225         ol_enable_passwd=no
 226         ol_enable_perl=no
 227         ol_enable_shell=no
 228         ol_enable_tcl=no
 229
 230         ol_enable_modules=no
 231         ol_enable_phonetic=no
 232         ol_enable_rlookups=no
 233         ol_enable_wrappers=no
 234
 235         ol_with_ldbm_api=no
 236         ol_with_ldbm_type=no
 237
 238         ol_with_bdb2_module=static
 239         ol_with_ldap_module=static
 240         ol_with_ldbm_module=static
 241         ol_with_passwd_module=static
 242         ol_with_perl_module=static
 243         ol_with_shell_module=static
 244         ol_with_tcl_module=static
 245
 246         ol_enable_slurpd=no
 247
 248 elif test $ol_enable_ldbm = no ; then
 249         dnl SLAPD without LDBM
 250
 251         if test $ol_with_ldbm_api != auto ; then
 252                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 253         fi
 254
 255         if test $ol_with_ldbm_type != auto ; then
 256                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 257         fi
 258
 259         if test $ol_with_ldbm_module != static ; then
 260                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 261         fi
 262
 263         if test $ol_enable_bdb2 = yes ; then
 264                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 265         fi
 266
 267         if test $ol_enable_modules != yes -a \
 268                 $ol_enable_ldap = no -a \
 269                 $ol_enable_passwd = no -a \
 270                 $ol_enable_perl = no -a \
 271                 $ol_enable_shell = no -a \
 272                 $ol_enable_tcl = no ; then
 273                 AC_MSG_ERROR([slapd requires a backend])
 274         fi
 275
 276         ol_with_ldbm_api=no
 277         ol_with_ldbm_type=no
 278         ol_with_ldbm_module=static
 279
 280 elif test $ol_enable_bdb2 = yes ; then
 281         dnl SLAPD with BDB2
 282
 283         if test $ol_with_ldbm_api != auto -a \
 284                 $ol_with_ldbm_api != db2 ; then
 285                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 286         fi
 287
 288         ol_with_ldbm_api=db2
 289
 290 else
 291         dnl SLAPD with LDBM
 292
 293         if test $ol_enable_bdb2 != no ; then
 294                 if test $ol_with_ldbm_api != auto -a \
 295                         $ol_with_ldbm_api != db2 ; then
 296                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 297                         ol_enable_bdb2=no
 298                 fi
 299         fi
 300
 301         if test $ol_with_ldbm_api = gdbm -a \
 302                 $ol_with_ldbm_type = btree ; then
 303                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 304         fi
 305         if test $ol_with_ldbm_api = mdbm -a \
 306                 $ol_with_ldbm_type = btree ; then
 307                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 308         fi
 309         if test $ol_with_ldbm_api = ndbm -a \
 310                 $ol_with_ldbm_type = btree ; then
 311                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 312         fi
 313 fi
 314
 315 if test $ol_enable_slurpd = yes ; then
 316         dnl SLURPD was specifically enabled
 317         if test $ol_with_threads = no ; then
 318                 AC_MSG_ERROR([slurpd requires threads])
 319         fi
 320 fi
 321
 322 AC_MSG_RESULT(done)
 323
 324 ## Initialize vars
 325 LDAP_LIBS=
 326 LDIF_LIBS=
 327 LDBM_LIBS=
 328 LTHREAD_LIBS=
 329 LUTIL_LIBS=
 330
 331 LDAPD_LIBS=
 332 SLAPD_LIBS=
 333 SLURPD_LIBS=
 334
 335 BUILD_LDAPD=no
 336 BUILD_SLAPD=no
 337 BUILD_SLURPD=no
 338
 339 BUILD_BDB2=no
 340 BUILD_LDAP=no
 341 BUILD_LDBM=no
 342 BUILD_PASSWD=no
 343 BUILD_PERL=no
 344 BUILD_SHELL=no
 345 BUILD_TCL=no
 346 BUILD_THREAD=no
 347
 348 BUILD_BDB2_DYNAMIC=no
 349 BUILD_LDAP_DYNAMIC=no
 350 BUILD_LDBM_DYNAMIC=no
 351 BUILD_PASSWD_DYNAMIC=no
 352 BUILD_PERL_DYNAMIC=no
 353 BUILD_SHELL_DYNAMIC=no
 354 BUILD_TCL_DYNAMIC=no
 355
 356 SLAPD_MODULES_LDFLAGS=
 357 SLAPD_MODULES_CPPFLAGS=
 358
 359 SLAPD_PERL_LDFLAGS=
 360 SLAPD_PERL_CPPFLAGS=
 361
 362 KRB_LIBS=
 363 READLINE_LIBS=
 364 TERMCAP_LIBS=
 365 TLS_LIBS=
 366
 367 dnl ----------------------------------------------------------------
 368 dnl Checks for programs
 369
 370 dnl AC_PROG_INSTALL
 371
 372 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 373
 374
 375 dnl
 376 dnl Determine which C translator to use
 377 dnl
 378
 379 dnl AIX Thread requires we use cc_r or xlc_r.
 380 dnl But only do this IF AIX and CC is not set
 381 dnl and threads are auto|yes|posix.
 382 dnl
 383 dnl If we find cc_r|xlc_r, force pthreads and assume
 384 dnl             pthread_create is in $LIBS (ie: don't bring in
 385 dnl             any additional thread libraries)
 386 dnl If we do not find cc_r|xlc_r, disable threads
 387
 388 ol_aix_threads=no
 389 case "$target" in
 390 *-*-aix*) dnl all AIX is not a good idea.
 391         if test -z "$CC" ; then
 392                 case "$ol_with_threads" in
 393                 auto | yes |  posix) ol_aix_threads=yes ;;
 394                 esac
 395         fi
 396 ;;
 397 esac
 398
 399 if test $ol_aix_threads = yes ; then
 400         if test -z "${CC}" ; then
 401                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 402
 403                 if test "$CC" = cc ; then
 404                         dnl no CC! don't allow --with-threads
 405                         if test $ol_with_threads != auto ; then
 406                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 407                         else
 408                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 409                         fi
 410                         ol_with_threads=no
 411                 fi
 412         fi
 413
 414         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 415                 ol_with_threads=posix
 416                 ol_cv_pthread_create=yes
 417         fi
 418 fi
 419
 420 if test -z "${CC}"; then
 421         AC_CHECK_PROGS(CC,cc)
 422 fi
 423
 424 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 425 dnl (for now, let autoconf sort this out)
 426 dnl CFLAGS=${CFLAGS-""}
 427
 428 AC_PROG_LIBTOOL
 429 dnl AC_PROG_MAKE_SET
 430
 431 AC_PROG_AWK
 432 OL_PROG_LN_H
 433 AC_PROG_LN_S
 434
 435 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 436         LN_S="$LN_H"
 437 fi
 438
 439 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 440         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 441 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 442 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 443
 444 ol_link_perl=no
 445 if test $ol_enable_perl != no ; then
 446         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 447
 448         if test "no$PERLBIN" = "no" ; then
 449                 if test $ol_enable_perl = yes ; then
 450                         AC_MSG_ERROR([could not locate perl])
 451                 fi
 452
 453         else
 454                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 455                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 456
 457                 dnl should check perl version
 458                 ol_link_perl=yes
 459         fi
 460 fi
 461
 462 AC_PROG_CPP
 463
 464 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 465         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 466
 467 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 468         AC_MSG_WARN([programs compiled here do run here...])
 469         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 470
 471 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 472         AC_MSG_WARN([programs compiled here do not run here...])
 473         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 474 fi
 475
 476 dnl Checks for UNIX Variants
 477 AC_AIX
 478 AC_ISC_POSIX
 479 AC_MINIX
 480
 481 dnl Checks for system services
 482 AC_CYGWIN
 483 AC_MINGW32
 484 AC_EXEEXT
 485 AC_OBJEXT
 486
 487 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 488
 489 dnl BeOS requires -lbe -lroot -lnet
 490 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 491
 492 dnl OpenLDAP requires STDC features
 493 AM_PROG_CC_STDC
 494 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 495         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 496 fi
 497
 498 dnl Check cc depend flags
 499 OL_MKDEPEND
 500 if test "${ol_cv_mkdep}" = no ; then
 501         # this will soon become an error
 502         AC_MSG_WARN([do not know how to generate dependencies])
 503 fi
 504
 505 dnl
 506 dnl Check for module support
 507 dnl
 508 ol_link_modules=no
 509 if test $ol_enable_modules != no ; then
 510         AC_PATH_PROG(GLIBCONFIG, glib-config)
 511
 512         if test "no$GLIBCONFIG" = "no" ; then
 513                 if test $ol_enable_modules = yes ; then
 514                         AC_MSG_ERROR([could not locate glib-config])
 515                 fi
 516
 517         else
 518                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 519                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 520                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 521
 522                 dnl should check glib version
 523                 ol_link_modules=yes
 524         fi
 525 else
 526         ol_with_bdb2_module=static
 527         ol_with_ldap_module=static
 528         ol_with_ldbm_module=static
 529         ol_with_passwd_module=static
 530         ol_with_perl_module=static
 531         ol_with_shell_module=static
 532         ol_with_tcl_module=static
 533 fi
 534
 535 dnl ----------------------------------------------------------------
 536 dnl Checks for header files.
 537 OL_HEADER_STDC
 538
 539 if test $ol_cv_header_stdc != yes; then
 540         AC_MSG_WARN([could not locate Standard C compliant headers])
 541 fi
 542
 543 AC_HEADER_DIRENT
 544 AC_HEADER_SYS_WAIT
 545 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 546 if test $am_cv_sys_posix_termios = yes ; then
 547         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 548                 [define if you have POSIX termios])
 549 fi
 550
 551 AC_CHECK_HEADERS(       \
 552         arpa/inet.h             \
 553         arpa/nameser.h  \
 554         assert.h                \
 555         crypt.h                 \
 556         errno.h                 \
 557         fcntl.h                 \
 558         filio.h                 \
 559         getopt.h                \
 560         grp.h                   \
 561         libutil.h               \
 562         limits.h                \
 563         locale.h                \
 564         netinet/tcp.h   \
 565         malloc.h                \
 566         memory.h                \
 567         psap.h                  \
 568         pwd.h                   \
 569         resolv.h                \
 570         sgtty.h                 \
 571         shadow.h                \
 572         stdarg.h                \
 573         stddef.h                \
 574         string.h                \
 575         strings.h               \
 576         sysexits.h              \
 577         sys/file.h              \
 578         sys/filio.h             \
 579         sys/errno.h             \
 580         sys/ioctl.h             \
 581         sys/param.h             \
 582         sys/resource.h  \
 583         sys/select.h    \
 584         sys/socket.h    \
 585         sys/syslog.h    \
 586         sys/time.h              \
 587         sys/types.h             \
 588         syslog.h                \
 589         termios.h               \
 590         unistd.h                \
 591 )
 592
 593 dnl ----------------------------------------------------------------
 594 dnl Checks for libraries
 595
 596 dnl Find socket()
 597 dnl Likely combinations:
 598 dnl             -lsocket [ -lnsl_s | -lnsl ]
 599 dnl             -linet
 600
 601 AC_CHECK_FUNC(socket, :, [
 602 dnl
 603 dnl hopefully we won't include too many libraries
 604 dnl
 605         AC_CHECK_LIB(socket, main)
 606         AC_CHECK_LIB(net, main)
 607         AC_CHECK_LIB(net, socket)
 608         AC_CHECK_LIB(nsl_s, main)
 609         AC_CHECK_LIB(nsl, main)
 610         AC_CHECK_LIB(inet, socket)
 611         AC_CHECK_LIB(gen, main)
 612 ])
 613
 614 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 615
 616 dnl Select arg types
 617 dnl (if this detection becomes permenent, it and the select() detection
 618 dnl should be done before the yielding select test)
 619 AC_FUNC_SELECT_ARGTYPES
 620
 621
 622 AC_CHECK_HEADERS( regex.h )
 623 if test "$ac_cv_header_regex_h" != yes ; then
 624         AC_MSG_ERROR([POSIX regex.h required.])
 625 fi
 626 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 627
 628 OL_POSIX_REGEX
 629 if test "$ol_cv_c_posix_regex" = no ; then
 630         AC_MSG_ERROR([broken POSIX regex!])
 631 fi
 632
 633
 634 dnl HP-UX requires -lV3
 635 AC_CHECK_LIB(V3, sigset)
 636
 637
 638 # find res_search
 639 if test $ol_enable_dns != no ; then
 640         dnl Check for resolver routines
 641         AC_CHECK_FUNC(res_search,:)
 642         if test $ac_cv_func_res_search = no ; then
 643                 AC_CHECK_LIB(bind, res_search)
 644                 ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 645         fi
 646         if test $ac_cv_func_res_search = no ; then
 647                 AC_CHECK_LIB(resolv, res_search)
 648                 ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 649         fi
 650
 651         if test "$ac_cv_func_res_search" = yes ; then
 652                 AC_DEFINE(HAVE_RES_SEARCH,1,
 653                         [define if you have res_search()])
 654         elif test $ol_enable_dns = yes ; then
 655                 AC_MSG_ERROR([--enable-dns requires res_search])
 656         else
 657                 AC_MSG_WARN([no res_search, disabling DNS support])
 658         fi
 659 fi
 660
 661
 662 # ISODE tests
 663 ol_link_isode=no
 664 if test $ol_enable_ldapd != no ; then
 665         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 666
 667         dnl look for ISODE libraries
 668         AC_CHECK_LIB(xtpp, main, [
 669                 ol_link_isode=yes
 670                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 671                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 672                 ],:,[-lxtdsap -lxtisode -losi])
 673         AC_CHECK_LIB(dsap, main, [
 674                 ol_link_isode=yes
 675                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 676                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 677                 ],:,[-lisode])
 678         AC_CHECK_LIB(isode, main, [
 679                 ol_link_isode=yes
 680                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 681                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 682                 ],:)
 683 fi
 684
 685 if test $ol_link_isode != no; then
 686         AC_CHECK_LIB(pp, main, [
 687                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 688                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 689                 ],:)
 690
 691         AC_PATH_PROG(PEPSY, pepsy)
 692 fi
 693
 694 dnl
 695 dnl check for kerberos
 696 dnl
 697 ol_link_kerberos=no
 698
 699 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 700         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 701
 702         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 703                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 704                         [-lkrb5 -ldes425])
 705
 706                 if test $have_k5 = yes ; then
 707                         ol_with_kerberos=found
 708                         ol_link_kerberos=yes
 709
 710                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 711
 712                         LIBS="$KRB_LIBS $LIBS"
 713
 714                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 715                                 [ol_cv_var_des_debug], [
 716                                 dnl save the flags
 717                                 save_LIBS="$LIBS"
 718                                 LIBS="$KRB_LIBS $LIBS"
 719                                 AC_TRY_LINK([
 720 #include <kerberosIV/krb.h>
 721 #include <kerberosIV/des.h>
 722 extern int des_debug;
 723 ],[
 724 des_debug = 1;
 725 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 726                                 dnl restore the LIBS
 727                                 LIBS="$save_LIBS"
 728                         ])
 729
 730                         if test $ol_cv_var_des_debug = yes ; then
 731                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 732                                         [define if you have Kerberos des_debug])
 733                         fi
 734
 735                         LIBS="$save_LIBS"
 736                 fi
 737         fi
 738 fi
 739
 740 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 741         AC_CHECK_HEADERS(krb.h des.h)
 742
 743         if test $ac_cv_header_krb_h = yes ; then
 744                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 745
 746                 if test $have_k4 = yes ; then
 747                         ol_with_kerberos=found
 748                         ol_link_kerberos=yes
 749
 750                         KRB_LIBS="-lkrb -ldes"
 751                 fi
 752         fi
 753 fi
 754
 755 if test $ol_link_kerberos = yes ; then
 756         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 757 fi
 758
 759 dnl
 760 dnl Check for SSL/TLS
 761 dnl
 762 ol_link_tls=no
 763 if test $ol_with_tls != no ; then
 764
 765         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 766
 767         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 768                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 769                         [have_ssleay=yes
 770                         need_rsaref=no],
 771                         [have_ssleay=no],
 772                         [-lcrypto])
 773
 774                 if test $have_ssleay = no ; then
 775                         AC_CHECK_LIB(ssl, SSL_library_init,
 776                                 [have_ssleay=yes
 777                                 need_rsaref=no], [have_ssleay=no],
 778                                 [-lcrypto])
 779                 fi
 780
 781                 if test $have_ssleay = no ; then
 782                         AC_CHECK_LIB(ssl, ssl3_accept,
 783                                 [have_ssleay=yes
 784                                 need_rsaref=yes], [have_ssleay=no],
 785                                 [-lcrypto -lRSAglue -lrsaref])
 786                 fi
 787
 788                 if test $have_ssleay = yes ; then
 789                         ol_with_tls=found
 790                         ol_link_tls=yes
 791
 792                         AC_DEFINE(HAVE_SSLEAY, 1,
 793                                 [define if you have SSLeay or OpenSSL])
 794
 795                         if test $need_rsaref = yes; then
 796                                 AC_DEFINE(HAVE_RSAREF, 1,
 797                                         [define if you have RSAref])
 798
 799                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 800                         else
 801                                 TLS_LIBS="-lssl -lcrypto"
 802                         fi
 803                 fi
 804         fi
 805 fi
 806
 807 if test $ol_link_tls = yes ; then
 808         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 809 fi
 810
 811 dnl Tests for reentrant functions necessary to build a
 812 dnl thread_safe -lldap.
 813 AC_CHECK_FUNCS(         \
 814         ctime_r                 \
 815         gethostbyname_r gethostbyaddr_r \
 816 )
 817
 818 if test "$ac_cv_func_ctime_r" = no ; then
 819         ol_cv_func_ctime_r_nargs=0
 820 else
 821         OL_FUNC_CTIME_R_NARGS
 822 dnl     OL_FUNC_CTIME_R_TYPE
 823 fi
 824
 825 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 826         OL_FUNC_GETHOSTBYNAME_R_NARGS
 827 else
 828         ol_cv_func_gethostbyname_r_nargs=0
 829 fi
 830
 831 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 832         OL_FUNC_GETHOSTBYADDR_R_NARGS
 833 else
 834         ol_cv_func_gethostbyaddr_r_nargs=0
 835 fi
 836
 837 if test "$ac_cv_func_ctime_r" = yes \
 838         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 839         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 840         -a "$ac_cv_func_gethostbyname_r" = yes \
 841         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 842         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 843         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 844         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 845         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 846         ; then
 847
 848         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 849 fi
 850
 851 ol_link_threads=no
 852 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 853         -o $ol_with_threads = posix ; then
 854
 855         AC_CHECK_HEADERS(pthread.h sched.h)
 856
 857         if test $ac_cv_header_pthread_h = yes ; then
 858                 OL_POSIX_THREAD_VERSION
 859
 860                 if test $ol_cv_pthread_version = final ; then
 861                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 862                                 [define if pthreads API compatible with final spec])
 863                 elif test $ol_cv_pthread_version = draft4 ; then
 864                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 865                                 [define if pthreads API compatible with draft4 spec])
 866                 else
 867                         AC_MSG_ERROR([unknown pthread version])
 868                 fi
 869
 870                 # consider threads found
 871                 ol_with_threads=found
 872
 873                 OL_HEADER_LINUX_THREADS
 874
 875                 dnl Now the hard part, how to link?
 876                 dnl
 877                 dnl currently supported checks:
 878                 dnl
 879                 dnl Check for no flags
 880                 dnl     pthread_create() in $LIBS
 881                 dnl
 882                 dnl Check special pthread (final) flags
 883                 dnl     pthread_create() with -mt (Solaris)
 884                 dnl     pthread_create() with -kthread (FreeBSD)
 885                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 886                 dnl     pthread_create() with -pthreads (?)
 887                 dnl     pthread_create() with -mthreads (AIX)
 888                 dnl     pthread_create() with -thread (?)
 889                 dnl
 890                 dnl Check pthread (final) libraries
 891                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 892                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 893                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 894                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 895                 dnl     pthread_create() in -lpthread (many)
 896                 dnl     pthread_create() in -lc_r (FreeBSD)
 897                 dnl
 898                 dnl Check pthread (draft4) flags (depreciated)
 899                 dnl     pthread_create() with -threads (OSF/1)
 900                 dnl
 901                 dnl Check pthread (draft4) libraries (depreciated)
 902                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 903                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 904                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 905                 dnl     pthread_create() in -lpthreads (many)
 906                 dnl
 907
 908                 dnl pthread_create in $LIBS
 909                 AC_CACHE_CHECK([for pthread_create in default libraries],
 910                         ol_cv_pthread_create,[
 911                 AC_TRY_RUN([
 912 #include <pthread.h>
 913 #ifndef NULL
 914 #define NULL (void*)0
 915 #endif
 916
 917 static void *task(p)
 918         void *p;
 919 {
 920         return (void *) (p == NULL);
 921 }
 922
 923 int main(argc, argv)
 924         int argc;
 925         char **argv;
 926 {
 927         pthread_t t;
 928         int status;
 929
 930         /* make sure pthread_create() isn't just a stub */
 931 #if HAVE_PTHREADS_D4
 932         status = pthread_create(&t, pthread_attr_default, task, NULL);
 933 #else
 934         status = pthread_create(&t, NULL, task, NULL);
 935 #endif
 936
 937         if( status ) return status;
 938
 939         /* make sure pthread_detach() isn't just a stub */
 940 #if HAVE_PTHREADS_D4
 941         status = pthread_detach( &t );
 942 #else
 943         status = pthread_detach( t );
 944 #endif
 945
 946         return status;
 947 }
 948 ],
 949                         [ol_cv_pthread_create=yes],
 950                         [ol_cv_pthread_create=no],
 951                         [dnl assume yes
 952                         ol_cv_pthread_create=yes])])
 953
 954                 if test $ol_cv_pthread_create != no ; then
 955                         ol_link_threads=posix
 956                         ol_link_pthreads=""
 957                 fi
 958
 959                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 960                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 961                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 962                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 963                 OL_PTHREAD_TRY_LINK([-mthreads],[ol_cv_pthread_mthreads])
 964                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 965
 966                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 967                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 968                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 969                         [ol_cv_pthread_lpthread_lmach_lexc])
 970 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 971 dnl                     [ol_cv_pthread_lpthread_lexc])
 972
 973                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 974                         [ol_cv_pthread_lib_lpthread_woff])
 975
 976                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 977                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 978
 979                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 980
 981                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 982                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 983                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 984                         [ol_cv_pthread_lpthreads_lmach_lexc])
 985                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 986                         [ol_cv_pthread_lpthreads_lexc])
 987
 988                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 989
 990                 if test $ol_link_threads != no ; then
 991                         AC_DEFINE(HAVE_PTHREADS,1,
 992                                 [define if you have POSIX Threads])
 993
 994                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 995
 996                         dnl save flags
 997                         save_CPPFLAGS="$CPPFLAGS"
 998                         save_LIBS="$LIBS"
 999                         LIBS="$LTHREAD_LIBS $LIBS"
1000
1001                         dnl All POSIX Thread (final) implementations should have
1002                         dnl sched_yield instead of pthread yield.
1003                         dnl check for both
1004                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1005
1006                         if test $ac_cv_func_sched_yield = no -a \
1007                                 $ac_cv_func_pthread_yield = no ; then
1008                                 dnl Digital UNIX has sched_yield() in -lrt
1009                                 AC_CHECK_LIB(rt, sched_yield,
1010                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1011                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1012                                                 [Define if you have the sched_yield function.])
1013                                         ac_cv_func_sched_yield=yes],
1014                                         [ac_cv_func_sched_yield=no])
1015                         fi
1016                         if test $ac_cv_func_sched_yield = no -a \
1017                                 $ac_cv_func_pthread_yield = no ; then
1018                                 dnl Solaris has sched_yield() stub in -lposix4
1019                                 dnl but we'll use thr_yield instead.
1020                                 AC_CHECK_FUNCS(thr_yield)
1021                         fi
1022                         if test $ac_cv_func_sched_yield = no -a \
1023                                 $ac_cv_func_pthread_yield = no -a \
1024                                 "$ac_cv_func_thr_yield" = no ; then
1025                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1026                         fi
1027
1028                         dnl Check functions for compatibility
1029                         AC_CHECK_FUNCS(pthread_kill)
1030
1031                         dnl Check for pthread_detach with <pthread.h> inclusion
1032                         dnl as it's symbol may have been mangled.
1033                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1034                                 [ol_cv_func_pthread_detach], [
1035                                 dnl save the flags
1036                                 AC_TRY_LINK([
1037 #include <pthread.h>
1038 #ifndef NULL
1039 #define NULL (void*)0
1040 #endif
1041 ],
1042                                         [pthread_detach(NULL);],
1043                                         [ol_cv_func_pthread_detach=yes],
1044                                         [ol_cv_func_pthread_detach=no])
1045                         ])
1046
1047                         if test $ol_cv_func_pthread_detach = no ; then
1048                                 AC_MSG_ERROR([could not locate pthread_detach()])
1049                         fi
1050
1051                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1052                                 [define if you have pthread_detach function])
1053
1054                         dnl Check for setconcurreny functions
1055                         AC_CHECK_FUNCS( \
1056                                 pthread_setconcurrency \
1057                                 pthread_getconcurrency \
1058                                 thr_setconcurrency \
1059                                 thr_getconcurrency \
1060                         )
1061
1062                         OL_SYS_LINUX_THREADS
1063                         OL_LINUX_THREADS
1064
1065                         if test $ol_cv_linux_threads = error; then
1066                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1067                         fi
1068
1069                         AC_CACHE_CHECK([if pthread_create() works],
1070                                 ol_cv_pthread_create_works,[
1071                         AC_TRY_RUN([
1072 #include <pthread.h>
1073 #ifndef NULL
1074 #define NULL (void*)0
1075 #endif
1076
1077 static void *task(p)
1078         void *p;
1079 {
1080         return (void *) (p == NULL);
1081 }
1082
1083 int main(argc, argv)
1084         int argc;
1085         char **argv;
1086 {
1087         pthread_t t;
1088 #if HAVE_PTHREADS_D4
1089         exit(pthread_create(&t, pthread_attr_default, task, NULL));
1090 #else
1091         exit(pthread_create(&t, NULL, task, NULL));
1092 #endif
1093 }
1094 ],
1095                                 [ol_cv_pthread_create_works=yes],
1096                                 [ol_cv_pthread_create_works=no],
1097                                 [dnl assume yes
1098                                 ol_cv_pthread_create_works=yes])])
1099
1100                         if test $ol_cv_pthread_create_works = no ; then
1101                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1102                         fi
1103
1104                         dnl Check if select causes an yield
1105                         if test $ol_with_yielding_select = auto ; then
1106                                 AC_CACHE_CHECK([if select yields when using pthreads],
1107                                         ol_cv_pthread_select_yields,[
1108                                 AC_TRY_RUN([
1109 #include <sys/types.h>
1110 #include <sys/time.h>
1111 #include <unistd.h>
1112 #include <pthread.h>
1113 #ifndef NULL
1114 #define NULL (void*) 0
1115 #endif
1116
1117 static int fildes[2];
1118
1119 static void *task(p)
1120         void *p;
1121 {
1122         int i;
1123         struct timeval tv;
1124
1125         fd_set rfds;
1126
1127         tv.tv_sec=10;
1128         tv.tv_usec=0;
1129
1130         FD_ZERO(&rfds);
1131         FD_SET(fildes[0], &rfds);
1132
1133         /* we're not interested in any fds */
1134         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1135
1136         if(i < 0) {
1137                 perror("select");
1138                 exit(10);
1139         }
1140
1141         exit(0); /* if we exit here, the select blocked the whole process */
1142 }
1143
1144 int main(argc, argv)
1145         int argc;
1146         char **argv;
1147 {
1148         pthread_t t;
1149
1150         /* create a pipe to select */
1151         if(pipe(&fildes[0])) {
1152                 perror("select");
1153                 exit(1);
1154         }
1155
1156 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1157         (void) pthread_setconcurrency(2);
1158 #else
1159 #ifdef HAVE_THR_SETCONCURRENCY
1160         /* Set Solaris LWP concurrency to 2 */
1161         thr_setconcurrency(2);
1162 #endif
1163 #endif
1164
1165 #if HAVE_PTHREADS_D4
1166         pthread_create(&t, pthread_attr_default, task, NULL);
1167 #else
1168         pthread_create(&t, NULL, task, NULL);
1169 #endif
1170
1171 #if HAVE_SCHED_YIELD
1172         sched_yield();  /* make sure task runs first */
1173 #else
1174 #ifdef HAVE_PTHREAD_YIELD
1175         pthread_yield();        /* make sure task runs first */
1176 #endif
1177 #endif
1178
1179         exit(2);
1180 }],
1181                                 [ol_cv_pthread_select_yields=no],
1182                                 [ol_cv_pthread_select_yields=yes],
1183                                 [ol_cv_pthread_select_yields=cross])])
1184
1185                                 if test $ol_cv_pthread_select_yields = cross ; then
1186                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1187                                 fi
1188
1189                                 if test $ol_cv_pthread_select_yields = yes ; then
1190                                         ol_with_yielding_select=yes
1191                                 fi
1192                         fi
1193
1194                         dnl restore flags
1195                         CPPFLAGS="$save_CPPFLAGS"
1196                         LIBS="$save_LIBS"
1197                 else
1198                         AC_MSG_ERROR([could not link with POSIX Threads])
1199                 fi
1200         fi
1201
1202         if test $ol_with_threads = posix ; then
1203                 AC_MSG_ERROR([could not locate POSIX Threads])
1204         fi
1205 fi
1206
1207 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1208         -o $ol_with_threads = mach ; then
1209
1210         dnl check for Mach CThreads
1211         AC_CHECK_HEADERS(mach/cthreads.h)
1212         if test $ac_cv_header_mach_cthreads_h = yes ; then
1213                 ol_with_threads=found
1214
1215                 dnl check for cthread support in current $LIBS
1216                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1217
1218                 if test $ol_link_threads = no ; then
1219                         dnl try -all_load
1220                         dnl this test needs work
1221                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1222                                 [ol_cv_cthread_all_load], [
1223                                 dnl save the flags
1224                                 save_LIBS="$LIBS"
1225                                 LIBS="-all_load $LIBS"
1226                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1227                                         cthread_fork((void *)0, (void *)0);
1228                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1229                                 dnl restore the LIBS
1230                                 LIBS="$save_LIBS"
1231                         ])
1232
1233                         if test $ol_cv_cthread_all_load = yes ; then
1234                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1235                                 ol_link_threads=mach
1236                         fi
1237                 fi
1238
1239                 if test $ol_link_threads != no ; then
1240                         : check for cthread specific functionality here
1241                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1242                                 [define if you have Mach Cthreads])
1243                 else
1244                         AC_MSG_ERROR([could not link with Mach CThreads])
1245                 fi
1246         fi
1247
1248         if test $ol_with_threads = mach ; then
1249                 AC_MSG_ERROR([could not locate Mach CThreads])
1250         fi
1251 fi
1252
1253 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1254         -o $ol_with_threads = lwp ; then
1255
1256         dnl check for SunOS5 LWP
1257         AC_CHECK_HEADERS(thread.h synch.h)
1258         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1259                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1260
1261                 if test $have_thr = yes ; then
1262                         AC_DEFINE(HAVE_THR,1,
1263                                 [if you have Solaris LWP (thr) package])
1264                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1265                         ol_link_threads=thr
1266
1267                         if test $ol_with_yielding_select = auto ; then
1268                                 ol_with_yielding_select=yes
1269                         fi
1270
1271                         dnl Check for setconcurreny functions
1272                         AC_CHECK_FUNCS( \
1273                                 thr_setconcurrency \
1274                                 thr_getconcurrency \
1275                         )
1276                 fi
1277         fi
1278
1279         dnl check for SunOS4 LWP
1280         AC_CHECK_HEADERS(lwp/lwp.h)
1281         if test $ac_cv_header_lwp_lwp_h = yes ; then
1282                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1283
1284                 if test $have_lwp = yes ; then
1285                         AC_DEFINE(HAVE_LWP,1,
1286                                 [if you have SunOS LWP package])
1287                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1288                         ol_link_threads=lwp
1289
1290                         if test $ol_with_yielding_select = auto ; then
1291                                 ol_with_yielding_select=no
1292                         fi
1293                 fi
1294         fi
1295 fi
1296
1297 if test $ol_with_yielding_select = yes ; then
1298         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1299                 [define if select implicitly yields])
1300 fi
1301
1302 if test $ol_with_threads = manual ; then
1303         dnl User thinks he can manually configure threads.
1304         ol_link_threads=yes
1305
1306         AC_MSG_WARN([thread defines and link options must be set manually])
1307
1308         AC_CHECK_HEADERS(pthread.h sched.h)
1309         AC_CHECK_FUNCS(sched_yield pthread_yield)
1310         OL_HEADER_LINUX_THREADS
1311
1312         AC_CHECK_HEADERS(mach/cthreads.h)
1313         AC_CHECK_HEADERS(lwp/lwp.h)
1314         AC_CHECK_HEADERS(thread.h synch.h)
1315 fi
1316
1317 if test $ol_link_threads != no ; then
1318         dnl needed to get reentrant/threadsafe versions
1319         dnl
1320         AC_DEFINE(REENTRANT,1)
1321         AC_DEFINE(_REENTRANT,1)
1322         AC_DEFINE(THREAD_SAFE,1)
1323         AC_DEFINE(_THREAD_SAFE,1)
1324         AC_DEFINE(THREADSAFE,1)
1325         AC_DEFINE(_THREADSAFE,1)
1326         AC_DEFINE(_SGI_MP_SOURCE,1)
1327
1328         dnl The errno declaration may dependent upon _REENTRANT.
1329         dnl If it does, we must link with thread support.
1330         AC_CACHE_CHECK([for thread specific errno],
1331                 [ol_cv_errno_thread_specific], [
1332                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1333                         [ol_cv_errno_thread_specific=yes],
1334                         [ol_cv_errno_thread_specific=no])
1335         ])
1336
1337         dnl The h_errno declaration may dependent upon _REENTRANT.
1338         dnl If it does, we must link with thread support.
1339         AC_CACHE_CHECK([for thread specific h_errno],
1340                 [ol_cv_h_errno_thread_specific], [
1341                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1342                         [ol_cv_h_errno_thread_specific=yes],
1343                         [ol_cv_h_errno_thread_specific=no])
1344         ])
1345
1346         if test $ol_cv_errno_thread_specific != yes \
1347                 -o $ol_cv_h_errno_thread_specific != yes ; then
1348                 LIBS="$LTHREAD_LIBS $LIBS"
1349                 LTHREAD_LIBS=""
1350         fi
1351
1352 dnl When in thread environment, use
1353 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1354 dnl                     || defined( HAVE_FUNC_R )
1355 dnl                     func_r(...);
1356 dnl             #else
1357 dnl             #       if defined( HAVE_THREADS )
1358 dnl                             /* lock */
1359 dnl             #       endif
1360 dnl                             func(...);
1361 dnl             #       if defined( HAVE_THREADS )
1362 dnl                             /* unlock */
1363 dnl             #       endif
1364 dnl             #endif
1365 dnl
1366 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1367 dnl             _POSIX_REENTRANT_FUNCTIONS
1368 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1369 dnl             _POSIX_THREADSAFE_FUNCTIONS
1370 dnl
1371 dnl             and is currently defined in lthread.h
1372 dnl
1373 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1374 dnl
1375 dnl libldap/*.c should only include <lthread.h> iff
1376 dnl LDAP_R_COMPILE is defined.  ie:
1377 dnl             #ifdef LDAP_R_COMPILE
1378 dnl             #       include LDAP_R_COMPILE
1379 dnl             #endif
1380 dnl
1381 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1382 dnl specifically for compiling the threadsafe version of
1383 dnl     the ldap library (-lldap_r).
1384 dnl
1385 dnl     dnl check for reentrant/threadsafe functions
1386 dnl     dnl
1387 dnl     dnl note: these should only be used when linking
1388 dnl     dnl       with $LTHREAD_LIBS
1389 dnl     dnl
1390 dnl     save_CPPFLAGS="$CPPFLAGS"
1391 dnl     save_LIBS="$LIBS"
1392 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1393 dnl     AC_CHECK_FUNCS( \
1394 dnl             gmtime_r \
1395 dnl             gethostbyaddr_r gethostbyname_r \
1396 dnl             feof_unlocked unlocked_feof \
1397 dnl             putc_unlocked unlocked_putc \
1398 dnl             flockfile ftrylockfile \
1399 dnl     )
1400 dnl     CPPFLAGS="$save_CPPFLAGS"
1401 dnl     LIBS="$save_LIBS"
1402 fi
1403
1404 if test $ol_link_threads = no ; then
1405         if test $ol_with_threads = yes ; then
1406                 AC_MSG_ERROR([no suitable thread support])
1407         fi
1408
1409         if test $ol_with_threads = auto ; then
1410                 AC_MSG_WARN([no suitable thread support, disabling threads])
1411                 ol_with_threads=no
1412         fi
1413
1414         AC_DEFINE(NO_THREADS,1,
1415                 [define if you have (or want) no threads])
1416         LTHREAD_LIBS=""
1417 fi
1418
1419 if test $ol_link_threads != no ; then
1420         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1421 fi
1422
1423 dnl ----------------------------------------------------------------
1424
1425 ol_link_ldbm=no
1426 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1427         OL_BERKELEY_DB2
1428
1429         if test $ol_cv_berkeley_db2 = yes ; then
1430                 ol_link_ldbm=db2
1431                 ol_with_ldbm_api=db2
1432
1433                 if test $ol_with_ldbm_type = hash ; then
1434                         AC_DEFINE(LDBM_USE_DBHASH,1,
1435                                 [define this to use DBHASH w/ LDBM backend])
1436                 else
1437                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1438                                 [define this to use DBBTREE w/ LDBM backend])
1439                 fi
1440
1441                 dnl $ol_cv_lib_db2 should be yes or -ldb
1442                 dnl (it could be no, but that would be an error
1443                 if test $ol_cv_lib_db2 != yes ; then
1444                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1445                 fi
1446         fi
1447 fi
1448
1449 ol_link_bdb2=no
1450 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1451         ol_link_bdb2=yes
1452 fi
1453
1454 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1455         OL_BERKELEY_DB
1456
1457         if test $ol_cv_berkeley_db = yes ; then
1458                 ol_link_ldbm=db
1459                 ol_with_ldbm_api=db
1460
1461                 if test $ol_with_ldbm_type = hash ; then
1462                         AC_DEFINE(LDBM_USE_DBHASH,1,
1463                                 [define this to use DBHASH w/ LDBM backend])
1464                 else
1465                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1466                                 [define this to use DBBTREE w/ LDBM backend])
1467                 fi
1468
1469                 dnl $ol_cv_lib_db should be yes or -ldb
1470                 dnl (it could be no, but that would be an error
1471                 if test $ol_cv_lib_db != yes ; then
1472                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1473                 fi
1474         fi
1475 fi
1476
1477 if test $ol_with_ldbm_api = manual ; then
1478         dnl User thinks he can manually configure LDBM api.
1479         ol_link_ldbm=yes
1480
1481         AC_MSG_WARN([LDBM defines and link options must be set manually])
1482
1483         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1484 fi
1485
1486 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1487         AC_MSG_WARN(Could not find LDBM with BTREE support)
1488         ol_with_ldbm_api=none
1489 fi
1490
1491 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1492         OL_MDBM
1493
1494         if test $ol_cv_mdbm = yes ; then
1495                 ol_link_ldbm=mdbm
1496                 ol_with_ldbm_api=mdbm
1497                 if test $ol_cv_lib_mdbm != yes ; then
1498                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1499                 fi
1500         fi
1501 fi
1502
1503 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1504         OL_GDBM
1505
1506         if test $ol_cv_gdbm = yes ; then
1507                 ol_link_ldbm=gdbm
1508                 ol_with_ldbm_api=gdbm
1509
1510                 if test $ol_cv_lib_gdbm != yes ; then
1511                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1512                 fi
1513         fi
1514 fi
1515
1516 if test $ol_with_ldbm_api = auto ; then
1517         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1518 elif test $ol_with_ldbm_api = ndbm ; then
1519         OL_NDBM
1520
1521         if test $ol_cv_ndbm = yes ; then
1522                 ol_link_ldbm=ndbm
1523                 ol_with_ldbm_api=ndbm
1524
1525                 if test $ol_cv_lib_ndbm != yes ; then
1526                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1527                 fi
1528         fi
1529 fi
1530
1531 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1532         AC_MSG_WARN(could not find suitable LDBM backend)
1533         if test $ol_enable_ldbm = yes ; then
1534                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1535         fi
1536
1537         AC_MSG_WARN(disabling LDBM)
1538         ol_enable_ldbm=no
1539 fi
1540
1541 if test $ol_enable_wrappers != no ; then
1542         AC_CHECK_HEADERS(tcpd.h)
1543
1544         if test $ac_cv_header_tcpd_h != yes ; then
1545                 have_wrappers=no
1546         else
1547                 AC_CHECK_LIB(wrap, main,
1548                         [have_wrappers=yes], [have_wrappers=no])
1549         fi
1550
1551         if test $have_wrappers = yes ; then
1552                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1553                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1554
1555                 dnl We add another check for -lnsl since some libwrap's
1556                 dnl need it, but it isn't always included from above
1557                 AC_CHECK_LIB(nsl, main)
1558         else
1559                 AC_MSG_WARN(could not find -lwrap)
1560                 if test $ol_enable_wrappers = yes ; then
1561                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1562                 fi
1563
1564                 AC_MSG_WARN(disabling wrappers support)
1565                 ol_enable_wrappers=no
1566         fi
1567 fi
1568
1569 if test $ol_enable_syslog != no ; then
1570         AC_CHECK_FUNC(openlog)
1571         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1572                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1573         fi
1574         ol_enable_syslog=$ac_cv_func_openlog
1575 fi
1576
1577 if test $ol_enable_dmalloc != no ; then
1578         AC_CHECK_HEADERS(dmalloc.h)
1579         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1580 fi
1581
1582 if test $ol_enable_tcl != no ; then
1583         AC_CHECK_HEADERS(tcl.h)
1584
1585         if test $ac_cv_header_tcl_h != yes ; then
1586                 have_tcl=no
1587         else
1588                 AC_CHECK_LIB(tcl,main,
1589                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1590                         [have_tcl=no])
1591
1592                 if test $have_tcl != yes; then
1593                         AC_CHECK_LIB(tcl7.6,main,
1594                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1595                                 [have_tcl=no])
1596                 fi
1597
1598                 if test $have_tcl != yes; then
1599                         AC_CHECK_LIB(tcl8.0,main,
1600                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1601                                 [have_tcl=no])
1602                 fi
1603         fi
1604
1605         if test $have_tcl != yes ; then
1606                 AC_MSG_WARN([could not find -ltcl])
1607                 if test $ol_enable_tcl = yes ; then
1608                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1609                 fi
1610
1611                 ol_enable_tcl=no
1612         fi
1613 fi
1614
1615 # ud needs termcap (should insert check here)
1616 ol_link_termcap=no
1617 AC_CHECK_HEADERS(termcap.h ncurses.h)
1618
1619 if test $ol_link_termcap = no ; then
1620         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1621         if test $have_termcap = yes ; then
1622                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1623                 ol_link_termcap=yes
1624                 TERMCAP_LIBS=-ltermcap
1625         fi
1626 fi
1627
1628 if test $ol_link_termcap = no ; then
1629         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1630         if test $have_ncurses = yes ; then
1631                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1632                 ol_link_termcap=yes
1633                 TERMCAP_LIBS=-lncurses
1634         fi
1635 fi
1636
1637 if test $ol_link_termcap = no ; then
1638         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1639         TERMCAP_LIBS=
1640 fi
1641
1642 dnl
1643 dnl Check for fetch URL support
1644 dnl             should be extended to support other fetch URL APIs
1645 dnl
1646 ol_link_sasl=no
1647 if test $ol_with_cyrus_sasl != no ; then
1648         AC_CHECK_HEADER(sasl.h)
1649
1650         if test $ac_cv_header_sasl_h = yes ; then
1651                 AC_CHECK_LIB(sasl, sasl_client_init,
1652                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1653
1654                 if test $have_cyrus_sasl != no ; then
1655                         LUTIL_LIBS="$LUTIL_LIBS -lsasl"
1656                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1657                         ol_link_sasl=yes
1658                 fi
1659         fi
1660
1661         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1662                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1663         fi
1664 fi
1665
1666 dnl
1667 dnl Check for fetch URL support
1668 dnl             should be extended to support other fetch URL APIs
1669 dnl
1670 ol_link_fetch=no
1671 if test $ol_with_fetch != no ; then
1672         OL_LIB_FETCH
1673
1674         if test $ol_cv_lib_fetch != no ; then
1675                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1676                 ol_link_fetch=freebsd
1677
1678         elif test $ol_with_fetch != auto ; then
1679                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1680         fi
1681 fi
1682
1683 dnl
1684 dnl Check for GNU readline
1685 dnl
1686 ol_link_readline=no
1687 if test $ol_with_readline != no ; then
1688         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1689
1690         if test $ac_cv_header_readline_readline_h = yes ; then
1691                 save_LIBS="$LIBS"
1692                 LIBS="$TERMCAP_LIBS $LIBS"
1693                 AC_CHECK_LIB(readline, readline,
1694                         [have_readline=yes], [have_readline=no])
1695                 LIBS="$save_LIBS"
1696
1697                 if test $have_readline = yes ; then
1698                         ol_with_readline=found
1699                         ol_link_readline=yes
1700
1701                         READLINE_LIBS="-lreadline"
1702                 fi
1703         fi
1704 fi
1705
1706 if test $ol_link_readline = yes ; then
1707         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1708 fi
1709
1710
1711 # FreeBSD (and others) have crypt(3) in -lcrypt
1712 if test $ol_enable_crypt != no ; then
1713         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1714                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1715                         have_crypt=yes], [have_crypt=no])])
1716
1717         if test $have_crypt = yes ; then
1718                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1719         else
1720                 AC_MSG_WARN(could not find crypt)
1721                 if test $ol_enable_crypt = yes ; then
1722                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1723                 fi
1724
1725                 AC_MSG_WARN(disabling crypt support)
1726                 ol_enable_crypt=no
1727         fi
1728 fi
1729
1730 # FreeBSD (and others) have setproctitle(3) in -lutil
1731 if test $ol_enable_proctitle != no ; then
1732         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1733                 AC_CHECK_LIB(util, setproctitle,
1734                         [have_setproctitle=yes
1735                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1736                         [have_setproctitle=no
1737                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1738
1739         if test $have_setproctitle = yes ; then
1740                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1741                         [define if setproctitle(3) is available])
1742         fi
1743 fi
1744
1745 dnl ----------------------------------------------------------------
1746 dnl Checks for typedefs, structures, and compiler characteristics.
1747 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1748 AC_TYPE_MODE_T
1749 AC_TYPE_OFF_T
1750 AC_TYPE_PID_T
1751 AM_TYPE_PTRDIFF_T
1752 AC_TYPE_SIGNAL
1753 OL_TYPE_SIG_ATOMIC_T
1754 AC_TYPE_SIZE_T
1755 OL_TYPE_SOCKLEN_T
1756 AC_STRUCT_ST_BLKSIZE
1757 AC_HEADER_TIME
1758 AC_STRUCT_TM
1759 OL_STRUCT_PASSWD_PW_GECOS
1760 OL_STRUCT_PASSWD_PW_PASSWD
1761
1762 OL_C_UPPER_LOWER
1763 AC_C_CONST
1764 OL_C_VOLATILE
1765
1766 if test $cross_compiling = yes ; then
1767         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1768
1769         AC_DEFINE(LBER_INT_T,long)
1770         AC_DEFINE(LBER_TAG_T,long)
1771         AC_DEFINE(LBER_SOCKET_T,int)
1772
1773 else
1774         AC_C_BIGENDIAN
1775         AC_CHECK_SIZEOF(short)
1776         AC_CHECK_SIZEOF(int)
1777         AC_CHECK_SIZEOF(long)
1778
1779         if test "$ac_cv_sizeof_int" -lt 4 ; then
1780                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1781
1782                 AC_DEFINE(LBER_INT_T,long)
1783                 AC_DEFINE(LBER_TAG_T,long)
1784                 AC_DEFINE(LBER_SOCKET_T,int)
1785         else
1786                 AC_DEFINE(LBER_INT_T,int)
1787                 AC_DEFINE(LBER_TAG_T,long)
1788                 AC_DEFINE(LBER_SOCKET_T,int)
1789         fi
1790 fi
1791
1792 AC_DEFINE(LBER_LEN_T,long)
1793
1794 dnl ----------------------------------------------------------------
1795 dnl Checks for library functions.
1796 AC_FUNC_MEMCMP
1797 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1798 AC_FUNC_STRFTIME
1799 dnl AM_FUNC_STRTOD
1800
1801 OL_FUNC_INET_ATON
1802
1803 dnl we should use vfork instead of fork in a number of places...
1804 dnl AC_FUNC_VFORK
1805 AC_FUNC_VPRINTF
1806
1807 if test $ac_cv_func_vprintf = yes ; then
1808         dnl check for vsnprintf
1809         AC_CHECK_FUNCS(vsnprintf vsprintf)
1810 fi
1811
1812 AC_CHECK_FUNCS(         \
1813         bcopy                   \
1814         closesocket             \
1815         endgrent                \
1816         endpwent                \
1817         flock                   \
1818         getdtablesize   \
1819         getgrgid                \
1820         gethostname             \
1821         getpass                 \
1822         getpwuid                \
1823         getpwnam                \
1824         getspnam                \
1825         gettimeofday    \
1826         initgroups              \
1827         lockf                   \
1828         memcpy                  \
1829         memmove                 \
1830         mkstemp                 \
1831         read                    \
1832         recv                    \
1833         recvfrom                \
1834         setpwfile               \
1835         setgid                  \
1836         setegid                 \
1837         setsid                  \
1838         setuid                  \
1839         seteuid                 \
1840         signal                  \
1841         sigset                  \
1842         snprintf                \
1843         strdup                  \
1844         strerror                \
1845         strpbrk                 \
1846         strrchr                 \
1847         strsep                  \
1848         strstr                  \
1849         strtol                  \
1850         strtoul                 \
1851         strspn                  \
1852         sysconf                 \
1853         waitpid                 \
1854         wait4                   \
1855         write                   \
1856         send                    \
1857         sendto                  \
1858 )
1859
1860 dnl We actually may need to replace more than this.
1861 AC_REPLACE_FUNCS(getopt tempnam)
1862
1863 dnl ----------------------------------------------------------------
1864 # Check Configuration
1865 OL_SYS_ERRLIST
1866
1867 dnl ----------------------------------------------------------------
1868 dnl Sort out defines
1869
1870 if test "$ol_enable_debug" != no ; then
1871         AC_DEFINE(LDAP_DEBUG,1,
1872                 [define this to add debugging code])
1873 fi
1874 if test "$ol_enable_syslog" = yes ; then
1875         AC_DEFINE(LDAP_SYSLOG,1,
1876                 [define this to add syslog code])
1877 fi
1878 if test "$ol_enable_libui" = yes ; then
1879         AC_DEFINE(LDAP_LIBUI,1,
1880                 [define this for LDAP User Interface support])
1881 fi
1882 if test "$ol_enable_cache" = no ; then
1883         AC_DEFINE(LDAP_NOCACHE,1,
1884                 [define this to remove -lldap cache support])
1885 fi
1886 if test "$ol_enable_dns" != no ; then
1887         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1888 fi
1889 if test "$ol_enable_proctitle" != no ; then
1890         AC_DEFINE(LDAP_PROCTITLE,1,
1891                 [define this for LDAP process title support])
1892 fi
1893 if test "$ol_enable_referrals" != no ; then
1894         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1895 fi
1896 if test "$ol_enable_cldap" != no ; then
1897         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
1898 fi
1899
1900 if test "$ol_enable_crypt" != no ; then
1901         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
1902 fi
1903 if test "$ol_enable_cleartext" != no ; then
1904         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
1905 fi
1906 if test "$ol_enable_phonetic" != no ; then
1907         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
1908 fi
1909 if test "$ol_enable_rlookups" != no ; then
1910         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
1911 fi
1912
1913 if test "$ol_link_modules" != no ; then
1914         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
1915         BUILD_SLAPD=yes
1916 fi
1917
1918 if test "$ol_link_bdb2" != no ; then
1919         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
1920         BUILD_SLAPD=yes
1921         BUILD_BDB2=yes
1922         if test "$ol_with_bdb2_module" != static ; then
1923                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
1924                         [define to support dynamic BDB2 backend])
1925                 BUILD_BDB2_DYNAMIC=yes
1926         fi
1927 fi
1928
1929 if test "$ol_enable_ldap" != no ; then
1930         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
1931         BUILD_SLAPD=yes
1932         BUILD_LDAP=yes
1933         if test "$ol_with_ldap_module" != static ; then
1934                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
1935                         [define to support dynamic LDAP backend])
1936                 BUILD_LDAP_DYNAMIC=yes
1937         fi
1938 fi
1939
1940 if test "$ol_link_ldbm" != no ; then
1941         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
1942         BUILD_SLAPD=yes
1943         BUILD_LDBM=yes
1944         if test "$ol_with_ldbm_module" != static ; then
1945                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
1946                         [define to support dynamic LDBM backend])
1947                 BUILD_LDBM_DYNAMIC=yes
1948         fi
1949 fi
1950
1951 if test "$ol_enable_passwd" != no ; then
1952         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
1953         BUILD_SLAPD=yes
1954         BUILD_PASSWD=yes
1955         if test "$ol_with_passwd_module" != static ; then
1956                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
1957                         [define to support dynamic PASSWD backend])
1958                 BUILD_PASSWD_DYNAMIC=yes
1959         fi
1960 fi
1961
1962 if test "$ol_link_perl" != no ; then
1963         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
1964         BUILD_SLAPD=yes
1965         BUILD_PERL=yes
1966         if test "$ol_with_perl_module" != static ; then
1967                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
1968                         [define to support dynamic PERL backend])
1969                 BUILD_PERL_DYNAMIC=yes
1970         fi
1971 fi
1972
1973 if test "$ol_enable_shell" != no ; then
1974         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
1975         BUILD_SLAPD=yes
1976         BUILD_SHELL=yes
1977         if test "$ol_with_shell_module" != static ; then
1978                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
1979                         [define to support dynamic SHELL backend])
1980                 BUILD_SHELL_DYNAMIC=yes
1981         fi
1982 fi
1983
1984 if test "$ol_enable_tcl" != no ; then
1985         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
1986         BUILD_SLAPD=yes
1987         BUILD_TCL=yes
1988         if test "$ol_with_tcl_module" != static; then
1989                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
1990                         [define to support dynamic TCL backend])
1991                 BUILD_TCL_DYNAMIC=yes
1992         fi
1993 fi
1994
1995 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1996         $BUILD_SLAPD = yes ; then
1997         BUILD_SLURPD=yes
1998 fi
1999
2000 if test "$ol_link_isode" != no ; then
2001         BUILD_LDAPD=yes
2002 fi
2003
2004 dnl ----------------------------------------------------------------
2005
2006 AC_SUBST(BUILD_LDAPD)
2007 AC_SUBST(BUILD_SLAPD)
2008   AC_SUBST(BUILD_BDB2)
2009   AC_SUBST(BUILD_LDAP)
2010   AC_SUBST(BUILD_LDBM)
2011   AC_SUBST(BUILD_PASSWD)
2012   AC_SUBST(BUILD_PERL)
2013   AC_SUBST(BUILD_SHELL)
2014   AC_SUBST(BUILD_TCL)
2015   AC_SUBST(BUILD_BDB2_DYNAMIC)
2016   AC_SUBST(BUILD_LDAP_DYNAMIC)
2017   AC_SUBST(BUILD_LDBM_DYNAMIC)
2018   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2019   AC_SUBST(BUILD_PERL_DYNAMIC)
2020   AC_SUBST(BUILD_SHELL_DYNAMIC)
2021   AC_SUBST(BUILD_TCL_DYNAMIC)
2022 AC_SUBST(BUILD_SLURPD)
2023
2024 AC_SUBST(LDAP_LIBS)
2025 AC_SUBST(LDAPD_LIBS)
2026 AC_SUBST(LDIF_LIBS)
2027 AC_SUBST(SLAPD_LIBS)
2028 AC_SUBST(SLURPD_LIBS)
2029 AC_SUBST(LDBM_LIBS)
2030 AC_SUBST(LTHREAD_LIBS)
2031 AC_SUBST(LUTIL_LIBS)
2032
2033 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2034 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2035
2036 AC_SUBST(SLAPD_PERL_CPPFLAGS)
2037 AC_SUBST(SLAPD_PERL_LDFLAGS)
2038
2039 AC_SUBST(KRB_LIBS)
2040 AC_SUBST(READLINE_LIBS)
2041 AC_SUBST(TERMCAP_LIBS)
2042 AC_SUBST(TLS_LIBS)
2043
2044 dnl ----------------------------------------------------------------
2045 dnl final output
2046 dnl
2047
2048 AC_OUTPUT( \
2049 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2050 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2051 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2052 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2053 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2054 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2055 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2056 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2057 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2058 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2059 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2060 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2061 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2062 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2063 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2064 include/Makefile:build/top.mk:include/Makefile.in \
2065 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2066 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2067 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2068 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2069 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2070 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2071 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2072 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2073 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2074 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2075 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2076 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
2077 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/srv.mk \
2078 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
2079 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
2080 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
2081 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
2082 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
2083 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2084 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2085 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2086 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2087 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2088 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2089 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2090 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2091 ,[
2092 date > stamp-h
2093 echo Please \"make depend\" to build dependencies
2094 ])