git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl This work is part of OpenLDAP Software <http://www.openldap.org/>.
   3 dnl
   4 dnl Copyright 1998-2006 The OpenLDAP Foundation.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted only as authorized by the OpenLDAP
   9 dnl Public License.
  10 dnl
  11 dnl A copy of this license is available in the file LICENSE in the
  12 dnl top-level directory of the distribution or, alternatively, at
  13 dnl <http://www.OpenLDAP.org/license.html>.
  14 dnl
  15 dnl ----------------------------------------------------------------
  16 dnl Disable config.cache!
  17 define([AC_CACHE_LOAD], )dnl
  18 define([AC_CACHE_SAVE], )dnl
  19 dnl ----------------------------------------------------------------
  20 dnl Disable libtool 1.5 support for languages we don't use
  21 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  22 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  23 define([AC_LIBTOOL_LANG_GCJ_CONFIG], [:])dnl
  24 dnl ================================================================
  25 dnl Configure.in for OpenLDAP
  26 AC_COPYRIGHT([[Copyright 1998-2006 The OpenLDAP Foundation. All rights reserved.
  27 Restrictions apply, see COPYRIGHT and LICENSE files.]])
  28 AC_REVISION([$OpenLDAP$])
  29 AC_INIT([OpenLDAP],,[http://www.openldap.org/its/])
  30 AC_CONFIG_SRCDIR(build/version.sh)dnl
  31 dnl ----------------------------------------------------------------
  32 dnl OpenLDAP Autoconf Macros
  33 builtin(include, build/openldap.m4)dnl
  34 dnl ================================================================
  35
  36 AC_CONFIG_AUX_DIR(build)dnl
  37
  38 eval `$ac_aux_dir/version.sh`
  39 if test -z "$OL_STRING"; then
  40         AC_MSG_ERROR([could not determine version])
  41 fi
  42
  43 if test -f "$ac_aux_dir/shtool" && test ! -d $ac_aux_dir/shtool; then
  44         ac_cv_shtool="$ac_aux_dir/shtool"
  45 else
  46         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  47 fi
  48
  49 SHTOOL="$ac_cv_shtool"
  50 dnl AC_SUBST(SHTOOL)dnl
  51
  52 TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  53 TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  54
  55 OPENLDAP_CVS=""
  56 if test -d $ac_aux_dir/CVS; then
  57         OPENLDAP_CVS="(from CVS sources) "
  58 fi
  59
  60 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_CVS}..."
  61
  62 dnl Determine host platform
  63 dnl             we try not to use this for much
  64 AC_CANONICAL_TARGET([])
  65
  66 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  67 AC_SUBST(PACKAGE)dnl
  68 AC_SUBST(VERSION)dnl
  69 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  70 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  71
  72 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  73 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  74 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  75 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  76
  77 OPENLDAP_LIBRELEASE=$OL_API_LIB_RELEASE
  78 AC_SUBST(OPENLDAP_LIBRELEASE)dnl
  79
  80 OPENLDAP_LIBVERSION=$OL_API_LIB_VERSION
  81 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  82
  83 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  84 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  85
  86 dnl We use autoconf features new to 2.59.  Later versions like won't work.
  87 dnl aclocal.m4 should be built using aclocal from automake 1.5
  88 dnl libtool 1.5 should be installed.
  89 AC_PREREQ(2.59)dnl Required Autoconf version
  90
  91 AH_TOP([
  92 /* begin of portable.h.pre */
  93 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
  94  *
  95  * Copyright 1998-2006 The OpenLDAP Foundation
  96  * All rights reserved.
  97  *
  98  * Redistribution and use in source and binary forms, with or without
  99  * modification, are permitted only as authorized by the OpenLDAP
 100  * Public License.
 101  *
 102  * A copy of this license is available in the file LICENSE in the
 103  * top-level directory of the distribution or, alternatively, at
 104  * <http://www.OpenLDAP.org/license.html>.
 105  */
 106
 107 #ifndef _LDAP_PORTABLE_H
 108 #define _LDAP_PORTABLE_H
 109
 110 /* define this if needed to get reentrant functions */
 111 #ifndef REENTRANT
 112 #undef REENTRANT
 113 #endif
 114 #ifndef _REENTRANT
 115 #undef _REENTRANT
 116 #endif
 117
 118 /* define this if needed to get threadsafe functions */
 119 #ifndef THREADSAFE
 120 #undef THREADSAFE
 121 #endif
 122 #ifndef _THREADSAFE
 123 #undef _THREADSAFE
 124 #endif
 125 #ifndef THREAD_SAFE
 126 #undef THREAD_SAFE
 127 #endif
 128 #ifndef _THREAD_SAFE
 129 #undef _THREAD_SAFE
 130 #endif
 131
 132 #ifndef _SGI_MP_SOURCE
 133 #undef _SGI_MP_SOURCE
 134 #endif
 135
 136 /* end of portable.h.pre */
 137 ])
 138 AH_BOTTOM([
 139 /* begin of portable.h.post */
 140
 141 #ifdef _WIN32
 142         /* don't suck in all of the win32 api */
 143 #       define WIN32_LEAN_AND_MEAN 1
 144 #endif
 145
 146 #ifndef LDAP_NEEDS_PROTOTYPES
 147 /* force LDAP_P to always include prototypes */
 148 #define LDAP_NEEDS_PROTOTYPES 1
 149 #endif
 150
 151 #ifndef LDAP_REL_ENG
 152 #if (LDAP_VENDOR_VERSION == 000000) && !defined(LDAP_DEVEL)
 153 #define LDAP_DEVEL
 154 #endif
 155 #if defined(LDAP_DEVEL) && !defined(LDAP_TEST)
 156 #define LDAP_TEST
 157 #endif
 158 #endif
 159
 160 #ifdef HAVE_STDDEF_H
 161 #       include <stddef.h>
 162 #endif
 163
 164 #ifdef HAVE_EBCDIC
 165 /* ASCII/EBCDIC converting replacements for stdio funcs
 166  * vsnprintf and snprintf are used too, but they are already
 167  * checked by the configure script
 168  */
 169 #define fputs ber_pvt_fputs
 170 #define fgets ber_pvt_fgets
 171 #define printf ber_pvt_printf
 172 #define fprintf ber_pvt_fprintf
 173 #define vfprintf ber_pvt_vfprintf
 174 #define vsprintf ber_pvt_vsprintf
 175 #endif
 176
 177 #include "ac/fdset.h"
 178
 179 #include "ldap_cdefs.h"
 180 #include "ldap_features.h"
 181
 182 #include "ac/assert.h"
 183 #include "ac/localize.h"
 184
 185 #endif /* _LDAP_PORTABLE_H */
 186 /* end of portable.h.post */
 187 ])
 188
 189 AC_CONFIG_HEADERS([include/portable.h:include/portable.hin])
 190 AC_CONFIG_HEADERS([include/ldap_features.h:include/ldap_features.hin])
 191 AC_CONFIG_HEADERS([include/lber_types.h:include/lber_types.hin])
 192
 193 dnl ================================================================
 194 dnl Start Args
 195 AC_MSG_CHECKING(configure arguments)
 196 AC_PREFIX_DEFAULT(/usr/local)
 197
 198 top_builddir=`pwd`
 199 AC_SUBST(top_builddir)dnl
 200
 201 dnl ----------------------------------------------------------------
 202 dnl --with-subdir
 203 ldap_subdir="/openldap"
 204
 205 AC_ARG_WITH(subdir,
 206 [  --with-subdir=DIR       change default subdirectory used for installs],
 207 [case "$withval" in
 208         no) ldap_subdir=""
 209                 ;;
 210         yes)
 211                 ;;
 212         /*|\\*)
 213                 ldap_subdir="$withval"
 214                 ;;
 215         *)
 216                 ldap_subdir="/$withval"
 217                 ;;
 218 esac
 219 ])dnl
 220
 221 AC_SUBST(ldap_subdir)dnl
 222
 223 dnl ----------------------------------------------------------------
 224 dnl General "enable" options
 225 dnl set default to traditional to enable the original debug style
 226 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes, [no yes traditional])dnl
 227 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 228 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 229 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 230 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 231 ol_enable_referrals=${ol_enable_referrals-no}
 232 dnl OL_ARG_ENABLE(kbind,[  --enable-kbind         enable LDAPv2+ Kerberos IV bind (deprecated)], no)dnl
 233 ol_enable_kbind=${ol_enable_kbind-no}
 234 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 235 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 236
 237 dnl ----------------------------------------------------------------
 238 dnl General "with" options
 239 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 240         auto, [auto yes no] )
 241 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 242         auto, [auto yes no] )
 243 dnl     OL_ARG_WITH(kerberos,[  --with-kerberos   with Kerberos support],
 244 dnl             auto, [auto k5 k5only k425 kth k4 afs yes no])
 245 ol_with_kerberos=${ol_with_kerberos-auto}
 246 OL_ARG_WITH(threads,[  --with-threads     with threads],
 247         auto, [auto nt posix mach pth lwp yes no manual] )
 248 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 249         auto, [auto openssl yes no] )
 250 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 251         auto, [auto yes no manual] )
 252 OL_ARG_WITH(multiple_precision,[  --with-multiple-precision
 253                           multiple precision support for statistics
 254                           auto|bignum|gmp],
 255         auto, [auto bignum gmp yes no] )
 256
 257 dnl ----------------------------------------------------------------
 258 dnl Server options
 259 dnl ----------------------------------------------------------------
 260
 261 dnl ----------------------------------------------------------------
 262 dnl SLAPD OPTIONS
 263 AC_ARG_ENABLE(xxslapdoptions,[
 264 SLAPD (Standalone LDAP Daemon) Options:])
 265 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 266 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no)dnl
 267 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 268 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 269 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 270 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 271 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 272 dnl OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 273 ol_enable_multimaster=${ol_enable_multimaster-no}
 274 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and rwm overlay], auto)dnl
 275 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 276 OL_ARG_ENABLE(slapi,[    --enable-slapi        enable SLAPI support (experimental)], no)dnl
 277 OL_ARG_ENABLE(slp,[    --enable-slp          enable SLPv2 support], no)dnl
 278 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 279
 280 dnl ----------------------------------------------------------------
 281 dnl SLAPD Backend Options
 282 Backends="bdb \
 283         dnssrv \
 284         hdb \
 285         ldap \
 286         ldbm \
 287         meta \
 288         monitor \
 289         null \
 290         passwd \
 291         perl \
 292         relay \
 293         shell \
 294         sql"
 295
 296 AC_ARG_ENABLE(xxslapbackends,[
 297 SLAPD Backend Options:])
 298
 299 OL_ARG_ENABLE(backends,[    --enable-backends     enable all available backends],
 300         --, [no yes mod])dnl
 301 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend],
 302         yes, [no yes mod], ol_enable_backends)dnl
 303 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend],
 304         no, [no yes mod], ol_enable_backends)dnl
 305 OL_ARG_ENABLE(hdb,[    --enable-hdb       enable Hierarchical DB backend],
 306         yes, [no yes mod], ol_enable_backends)dnl
 307 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend],
 308         no, [no yes mod], ol_enable_backends)dnl
 309 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend],
 310         no, [no yes mod], ol_enable_backends)dnl
 311 AC_ARG_WITH(ldbm_api,,[
 312         AC_MSG_WARN([Please use --enable-ldbm-api instead of --with-ldbm-api])
 313         enable_ldbm_api="$with_ldbm_api"])
 314 OL_ARG_ENABLE(ldbm_api,[      --enable-ldbm-api   use LDBM API],
 315         auto, [auto berkeley bcompat mdbm gdbm])
 316 AC_ARG_WITH(ldbm_type,,[
 317         AC_MSG_WARN([Please use --enable-ldbm-type instead of --with-ldbm-type])
 318         enable_ldbm_type="$with_ldbm_type"])
 319 OL_ARG_ENABLE(ldbm_type,[      --enable-ldbm-type  use LDBM type],
 320         auto, [auto btree hash])
 321 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend],
 322         no, [no yes mod], ol_enable_backends)dnl
 323 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend],
 324         yes, [no yes mod], ol_enable_backends)dnl
 325 OL_ARG_ENABLE(null,[    --enable-null     enable null backend],
 326         no, [no yes mod], ol_enable_backends)dnl
 327 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend],
 328         no, [no yes mod], ol_enable_backends)dnl
 329 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend],
 330         no, [no yes mod], ol_enable_backends)dnl
 331 OL_ARG_ENABLE(relay,[    --enable-relay           enable relay backend],
 332         yes, [no yes mod], ol_enable_backends)dnl
 333 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend],
 334         no, [no yes mod], ol_enable_backends)dnl
 335 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend],
 336         no, [no yes mod], ol_enable_backends)dnl
 337
 338 dnl ----------------------------------------------------------------
 339 dnl SLAPD Overlay Options
 340 Overlays="accesslog \
 341         denyop \
 342         dyngroup \
 343         dynlist \
 344         lastmod \
 345         ppolicy \
 346         proxycache \
 347         refint \
 348         retcode \
 349         rwm \
 350         syncprov \
 351         translucent \
 352         unique \
 353         valsort"
 354
 355 AC_ARG_ENABLE(xxslapoverlays,[
 356 SLAPD Overlay Options:])
 357
 358 OL_ARG_ENABLE(overlays,[    --enable-overlays     enable all available overlays],
 359         --, [no yes mod])dnl
 360 OL_ARG_ENABLE(accesslog,[    --enable-accesslog   In-Directory Access Logging overlay],
 361         no, [no yes mod], ol_enable_overlays)
 362 OL_ARG_ENABLE(denyop,[    --enable-denyop         Deny Operation overlay],
 363         no, [no yes mod], ol_enable_overlays)
 364 OL_ARG_ENABLE(dyngroup,[    --enable-dyngroup     Dynamic Group overlay],
 365         no, [no yes mod], ol_enable_overlays)
 366 OL_ARG_ENABLE(dynlist,[    --enable-dynlist       Dynamic List overlay],
 367         no, [no yes mod], ol_enable_overlays)
 368 OL_ARG_ENABLE(lastmod,[    --enable-lastmod       Last Modification overlay],
 369         no, [no yes mod], ol_enable_overlays)
 370 OL_ARG_ENABLE(ppolicy,[    --enable-ppolicy       Password Policy overlay],
 371         no, [no yes mod], ol_enable_overlays)
 372 OL_ARG_ENABLE(proxycache,[    --enable-proxycache         Proxy Cache overlay],
 373         no, [no yes mod], ol_enable_overlays)
 374 OL_ARG_ENABLE(refint,[    --enable-refint         Referential Integrity overlay],
 375         no, [no yes mod], ol_enable_overlays)
 376 OL_ARG_ENABLE(retcode,[    --enable-retcode       Return Code testing overlay],
 377         no, [no yes mod], ol_enable_overlays)
 378 OL_ARG_ENABLE(rwm,[    --enable-rwm               Rewrite/Remap overlay],
 379         no, [no yes mod], ol_enable_overlays)
 380 OL_ARG_ENABLE(syncprov,[    --enable-syncprov     Syncrepl Provider overlay],
 381         yes, [no yes mod], ol_enable_overlays)
 382 OL_ARG_ENABLE(translucent,[    --enable-translucent  Translucent Proxy overlay],
 383         no, [no yes mod], ol_enable_overlays)
 384 OL_ARG_ENABLE(unique,[    --enable-unique       Attribute Uniqueness overlay],
 385         no, [no yes mod], ol_enable_overlays)
 386 OL_ARG_ENABLE(valsort,[    --enable-valsort      Value Sorting overlay],
 387         no, [no yes mod], ol_enable_overlays)
 388
 389 dnl ----------------------------------------------------------------
 390 dnl SLURPD OPTIONS
 391 AC_ARG_ENABLE(xxslurpdoptions,[
 392 SLURPD (Replication Daemon) Options:])
 393 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 394
 395 dnl ----------------------------------------------------------------
 396 AC_ARG_ENABLE(xxliboptions,[
 397 Library Generation & Linking Options])
 398 AC_ENABLE_STATIC
 399 AC_ENABLE_SHARED
 400
 401 dnl ----------------------------------------------------------------
 402
 403 # validate options
 404 if test $ol_enable_slapd = no ; then
 405         dnl SLAPD was specificallly disabled
 406         if test $ol_enable_slapi = yes ; then
 407                 AC_MSG_WARN([slapd disabled, ignoring --enable-slapi argument])
 408         fi
 409         case "$ol_enable_backends" in yes | mod)
 410                 AC_MSG_WARN([slapd disabled, ignoring --enable-backends argument])
 411         esac
 412         for i in $Backends; do
 413                 eval "ol_tmp=\$ol_enable_$i"
 414                 if test $ol_tmp != no ; then
 415                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 416                         eval "ol_enable_$i=no"
 417                 fi
 418         done
 419         if test $ol_enable_modules = yes ; then
 420                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 421         fi
 422         if test $ol_enable_multimaster = yes ; then
 423                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 424         fi
 425         if test $ol_enable_wrappers = yes ; then
 426                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 427         fi
 428         if test $ol_enable_rlookups = yes ; then
 429                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 430         fi
 431         if test $ol_enable_aci = yes ; then
 432                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 433         fi
 434         if test $ol_enable_ldbm_api != auto ; then
 435                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm-api argument])
 436         fi
 437         if test $ol_enable_ldbm_type != auto ; then
 438                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm-type argument])
 439         fi
 440         if test $ol_enable_slurpd = yes ; then
 441                 AC_MSG_ERROR([slurpd requires slapd])
 442         fi
 443         if test $ol_enable_rewrite = yes ; then
 444                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 445         fi
 446         dnl overlays
 447         case "$ol_enable_overlays" in yes | mod)
 448                 AC_MSG_WARN([slapd disabled, ignoring --enable-overlays argument])
 449         esac
 450         for i in $Overlays; do
 451                 eval "ol_tmp=\$ol_enable_$i"
 452                 if test $ol_tmp != no ; then
 453                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 454                         eval "ol_enable_$i=no"
 455                 fi
 456         done
 457
 458         # force settings to no
 459         ol_enable_slapi=no
 460
 461         ol_enable_backends=
 462         ol_enable_overlays=
 463         ol_enable_modules=no
 464         ol_enable_multimaster=no
 465         ol_enable_rlookups=no
 466         ol_enable_aci=no
 467         ol_enable_wrappers=no
 468
 469         ol_enable_ldbm_api=no
 470         ol_enable_ldbm_type=no
 471
 472         ol_enable_slurpd=no
 473
 474         ol_enable_rewrite=no
 475
 476 elif test $ol_enable_ldbm = no ; then
 477         dnl SLAPD without LDBM
 478
 479         if test $ol_enable_ldbm_api != auto ; then
 480                 AC_MSG_WARN([LDBM disabled, ignoring --enable-ldbm-api argument])
 481         fi
 482
 483         if test $ol_enable_ldbm_type != auto ; then
 484                 AC_MSG_WARN([LDBM disabled, ignoring --enable-ldbm-type argument])
 485         fi
 486
 487         if test $ol_enable_modules != yes &&
 488            test $ol_enable_bdb = no &&
 489            test $ol_enable_dnssrv = no &&
 490            test $ol_enable_hdb = no &&
 491            test $ol_enable_ldap = no &&
 492            test $ol_enable_meta = no &&
 493            test $ol_enable_monitor = no &&
 494            test $ol_enable_null = no &&
 495            test $ol_enable_passwd = no &&
 496            test $ol_enable_perl = no &&
 497            test $ol_enable_relay = no &&
 498            test $ol_enable_shell = no &&
 499            test $ol_enable_sql = no ; then
 500
 501                 if test $ol_enable_slapd = yes ; then
 502                         AC_MSG_ERROR([slapd requires a backend])
 503                 else
 504                         AC_MSG_WARN([skipping slapd, no backend specified])
 505                         ol_enable_slapd=no
 506                 fi
 507         fi
 508
 509         ol_enable_ldbm_api=no
 510         ol_enable_ldbm_type=no
 511
 512         if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
 513                 ol_enable_ldbm_api=berkeley
 514         fi
 515
 516 else
 517         dnl SLAPD with LDBM
 518         if test $ol_enable_ldbm_api = gdbm &&
 519            test $ol_enable_ldbm_type = btree ; then
 520                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 521         fi
 522         if test $ol_enable_ldbm_api = mdbm &&
 523            test $ol_enable_ldbm_type = btree ; then
 524                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 525         fi
 526         if test $ol_enable_ldbm_api = ndbm &&
 527            test $ol_enable_ldbm_type = btree ; then
 528                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 529         fi
 530
 531         if test $ol_enable_bdb/$ol_enable_hdb != no/no ; then
 532                 if test $ol_enable_ldbm_api = auto ; then
 533                         ol_enable_ldbm_api=berkeley
 534                 elif test $ol_enable_ldbm_api != berkeley ; then
 535                         AC_MSG_ERROR([LDBM API not compatible with BDB/HDB])
 536                 fi
 537         fi
 538 fi
 539
 540 if test $ol_enable_meta/$ol_enable_ldap = yes/no ; then
 541         AC_MSG_ERROR([--enable-meta requires --enable-ldap])
 542 fi
 543
 544 if test $ol_enable_slurpd = yes ; then
 545         dnl SLURPD was specifically enabled
 546         if test $ol_with_threads = no ; then
 547                 AC_MSG_ERROR([slurpd requires threads])
 548         fi
 549 fi
 550
 551 if test $ol_enable_lmpasswd = yes ; then
 552         if test $ol_with_tls = no ; then
 553                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 554         fi
 555 fi
 556
 557 if test $ol_enable_kbind = yes ; then
 558         if test $ol_with_kerberos = no ; then
 559                 AC_MSG_ERROR([options require --with-kerberos])
 560         elif test $ol_with_kerberos = auto ; then
 561                 ol_with_kerberos=yes
 562         fi
 563
 564 elif test $ol_enable_kbind = no ; then
 565         if test $ol_with_kerberos = auto ; then
 566                 ol_with_kerberos=no
 567         elif test $ol_with_kerberos != no ; then
 568                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 569                 ol_with_kerberos=no
 570         fi
 571 fi
 572
 573 if test $ol_enable_spasswd = yes ; then
 574         if test $ol_with_cyrus_sasl = no ; then
 575                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 576         fi
 577         ol_with_cyrus_sasl=yes
 578 fi
 579
 580 AC_MSG_RESULT(done)
 581
 582 dnl ----------------------------------------------------------------
 583 dnl Initialize vars
 584 LDAP_LIBS=
 585 LDBM_LIBS=
 586 LTHREAD_LIBS=
 587 LUTIL_LIBS=
 588
 589 SLAPD_LIBS=
 590 SLURPD_LIBS=
 591
 592 BUILD_SLAPD=no
 593 BUILD_SLURPD=no
 594
 595 BUILD_THREAD=no
 596
 597 BUILD_SLAPI=no
 598 SLAPD_SLAPI_DEPEND=
 599
 600 BUILD_BDB=no
 601 BUILD_DNSSRV=no
 602 BUILD_HDB=no
 603 BUILD_LDAP=no
 604 BUILD_LDBM=no
 605 BUILD_META=no
 606 BUILD_MONITOR=no
 607 BUILD_NULL=no
 608 BUILD_PASSWD=no
 609 BUILD_PERL=no
 610 BUILD_RELAY=no
 611 BUILD_SHELL=no
 612 BUILD_SQL=no
 613
 614 BUILD_ACCESSLOG=no
 615 BUILD_DENYOP=no
 616 BUILD_DYNGROUP=no
 617 BUILD_DYNLIST=no
 618 BUILD_LASTMOD=no
 619 BUILD_PPOLICY=no
 620 BUILD_PROXYCACHE=no
 621 BUILD_REFINT=no
 622 BUILD_RETCODE=no
 623 BUILD_RWM=no
 624 BUILD_SYNCPROV=no
 625 BUILD_TRANSLUCENT=no
 626 BUILD_UNIQUE=no
 627 BUILD_VALSORT=no
 628
 629 SLAPD_STATIC_OVERLAYS=
 630 SLAPD_DYNAMIC_OVERLAYS=
 631
 632 SLAPD_MODULES_LDFLAGS=
 633 SLAPD_MODULES_CPPFLAGS=
 634
 635 SLAPD_STATIC_BACKENDS=back-ldif
 636 SLAPD_DYNAMIC_BACKENDS=
 637
 638 SLAPD_PERL_LDFLAGS=
 639 MOD_PERL_LDFLAGS=
 640 PERL_CPPFLAGS=
 641
 642 SLAPD_SQL_LDFLAGS=
 643 SLAPD_SQL_LIBS=
 644 SLAPD_SQL_INCLUDES=
 645
 646 KRB4_LIBS=
 647 KRB5_LIBS=
 648 SASL_LIBS=
 649 TLS_LIBS=
 650 MODULES_LIBS=
 651 SLAPI_LIBS=
 652 LIBSLAPI=
 653 LIBSLAPITOOLS=
 654 AUTH_LIBS=
 655 ICU_LIBS=
 656
 657 SLAPD_SLP_LIBS=
 658 SLAPD_GMP_LIBS=
 659
 660 dnl ================================================================
 661 dnl Checks for programs
 662
 663 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 664
 665 dnl ----------------------------------------------------------------
 666 dnl
 667 dnl Determine which C translator to use
 668 dnl
 669
 670 dnl AIX Thread requires we use cc_r or xlc_r.
 671 dnl But only do this IF AIX and CC is not set
 672 dnl and threads are auto|yes|posix.
 673 dnl
 674 dnl If we find cc_r|xlc_r, force pthreads and assume
 675 dnl             pthread_create is in $LIBS (ie: don't bring in
 676 dnl             any additional thread libraries)
 677 dnl If we do not find cc_r|xlc_r, disable threads
 678
 679 ol_aix_threads=no
 680 case "$target" in
 681 *-*-aix*) dnl all AIX is not a good idea.
 682         if test -z "$CC" ; then
 683                 case "$ol_with_threads" in
 684                 auto | yes |  posix) ol_aix_threads=yes ;;
 685                 esac
 686         fi
 687 ;;
 688 esac
 689
 690 if test $ol_aix_threads = yes ; then
 691         if test -z "${CC}" ; then
 692                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 693
 694                 if test "$CC" = cc ; then
 695                         dnl no CC! don't allow --with-threads
 696                         if test $ol_with_threads != auto ; then
 697                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 698                         else
 699                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 700                         fi
 701                         ol_with_threads=no
 702                 fi
 703         fi
 704
 705         case ${CC} in cc_r | xlc_r)
 706                 ol_with_threads=posix
 707                 ol_cv_pthread_create=yes
 708                 ;;
 709         esac
 710 fi
 711
 712 if test -z "${CC}"; then
 713         AC_CHECK_PROGS(CC,cc gcc,missing)
 714
 715         if test "${CC}" = "missing" ; then
 716                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 717         fi
 718 fi
 719
 720 if test -z "${AR}"; then
 721         AC_CHECK_PROGS(AR,ar gar,missing)
 722
 723         if test "${AR}" = "missing" ; then
 724                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 725         fi
 726 fi
 727
 728 AC_LIBTOOL_WIN32_DLL
 729 AC_LIBTOOL_DLOPEN
 730 AC_PROG_LIBTOOL
 731
 732 dnl ----------------------------------------------------------------
 733 dnl Perl
 734 ol_link_perl=no
 735 if test $ol_enable_perl != no ; then
 736         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 737
 738         if test "no$PERLBIN" = "no" ; then
 739                 if test $ol_enable_perl = yes ; then
 740                         AC_MSG_ERROR([could not locate perl])
 741                 fi
 742
 743         else
 744                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 745                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 746
 747                 if test x"$ol_enable_perl" = "xyes" ; then
 748                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 749                 else
 750                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 751                 fi
 752                 dnl should check perl version
 753                 ol_link_perl=yes
 754         fi
 755 fi
 756
 757 AC_PROG_CPP
 758
 759 dnl ----------------------------------------------------------------
 760 dnl Checks for Windows NT
 761 case $host_os in
 762   *mingw32* ) ac_cv_mingw32=yes ;;
 763   *cygwin* ) ac_cv_cygwin=yes ;;
 764 esac
 765
 766 dnl ----------------------------------------------------------------
 767 dnl Checks for file extensions
 768 AC_EXEEXT
 769 AC_OBJEXT
 770 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 771
 772 dnl ----------------------------------------------------------------
 773 dnl BeOS requires -lbe -lroot -lnet
 774 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 775
 776 dnl ----------------------------------------------------------------
 777 dnl OpenLDAP requires STDC features
 778 AC_PROG_CC
 779 if test "X${ac_cv_prog_cc_stdc}" = "Xno" ; then
 780         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 781 fi
 782
 783 dnl ----------------------------------------------------------------
 784 dnl Check cc depend flags
 785 OL_MKDEPEND
 786 if test "${ol_cv_mkdep}" = no ; then
 787         # this will soon become an error
 788         AC_MSG_WARN([do not know how to generate dependencies])
 789 fi
 790
 791 dnl ----------------------------------------------------------------
 792 dnl Check for AIX security library
 793 AC_CHECK_LIB(s, afopen, [
 794         AUTH_LIBS=-ls
 795         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 796 ])
 797
 798 dnl ----------------------------------------------------------------
 799 dnl Check for IBM OS/390
 800 case "$target" in
 801 *-ibm-openedition)
 802         ac_cv_func_getopt=no
 803         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 804         ;;
 805 esac
 806
 807 dnl ----------------------------------------------------------------
 808 dnl Check for module support
 809 ol_link_modules=no
 810 WITH_MODULES_ENABLED=no
 811 if test $ol_enable_modules != no ; then
 812         AC_CHECK_HEADERS(ltdl.h)
 813
 814         if test $ac_cv_header_ltdl_h = no ; then
 815                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 816         fi
 817
 818         AC_CHECK_LIB(ltdl, lt_dlinit, [
 819                 MODULES_LIBS=-lltdl
 820                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 821         ])
 822
 823         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 824                 AC_MSG_ERROR([could not locate libtool -lltdl])
 825         fi
 826         ol_link_modules=yes
 827         WITH_MODULES_ENABLED=yes
 828
 829 else
 830         for i in $Backends; do
 831                 eval "ol_tmp=\$ol_enable_$i"
 832                 if test $ol_tmp = mod ; then
 833                         AC_MSG_WARN([building static $i backend])
 834                         eval "ol_enable_$i=yes"
 835                 fi
 836         done
 837         for i in $Overlays; do
 838                 eval "ol_tmp=\$ol_enable_$i"
 839                 if test $ol_tmp = mod ; then
 840                         AC_MSG_WARN([building static $i overlay])
 841                         eval "ol_enable_$i=yes"
 842                 fi
 843         done
 844 fi
 845
 846 dnl ----------------------------------------------------------------
 847 dnl Checks for header files.
 848 OL_HEADER_STDC
 849
 850 if test $ol_cv_header_stdc != yes; then
 851         AC_MSG_WARN([could not locate Standard C compliant headers])
 852 fi
 853
 854 AC_HEADER_DIRENT
 855 AC_HEADER_SYS_WAIT
 856 AC_HEADER_TIOCGWINSZ
 857
 858 AC_CHECK_HEADERS(               \
 859         arpa/inet.h             \
 860         arpa/nameser.h          \
 861         assert.h                \
 862         bits/types.h            \
 863         conio.h                 \
 864         crypt.h                 \
 865         direct.h                \
 866         errno.h                 \
 867         fcntl.h                 \
 868         filio.h                 \
 869         getopt.h                \
 870         grp.h                   \
 871         io.h                    \
 872         libutil.h               \
 873         limits.h                \
 874         locale.h                \
 875         netinet/tcp.h           \
 876         malloc.h                \
 877         memory.h                \
 878         psap.h                  \
 879         pwd.h                   \
 880         process.h               \
 881         sgtty.h                 \
 882         shadow.h                \
 883         stddef.h                \
 884         string.h                \
 885         strings.h               \
 886         sysexits.h              \
 887         sys/file.h              \
 888         sys/filio.h             \
 889         sys/errno.h             \
 890         sys/ioctl.h             \
 891         sys/param.h             \
 892         sys/resource.h          \
 893         sys/select.h            \
 894         sys/socket.h            \
 895         sys/stat.h              \
 896         sys/syslog.h            \
 897         sys/time.h              \
 898         sys/types.h             \
 899         sys/uio.h               \
 900         syslog.h                \
 901         termios.h               \
 902         unistd.h                \
 903         utime.h                 \
 904         winsock.h               \
 905         winsock2.h              \
 906 )
 907
 908 AC_CHECK_HEADERS( resolv.h, [], [],
 909 [$ac_includes_default]
 910 #include <netinet/in.h>
 911 )
 912
 913 AC_CHECK_HEADERS(sys/ucred.h, [], [],
 914 [$ac_includes_default
 915 #ifdef HAVE_SYS_PARAM_H
 916 #include <sys/param.h>
 917 #endif
 918 ])
 919
 920 dnl ----------------------------------------------------------------
 921 dnl Checks for libraries
 922
 923 AC_CHECK_FUNCS( sigaction sigset )
 924
 925 dnl HP-UX requires -lV3
 926 dnl this is not needed on newer versions of HP-UX
 927 if test $ac_cv_func_sigaction = no && test $ac_cv_func_sigaction = no ; then
 928         AC_CHECK_LIB(V3, sigset)
 929 fi
 930
 931 dnl The following is INTENTIONALLY scripted out because shell does not
 932 dnl support variable names with the '@' character, which is what
 933 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 934 dnl
 935 dnl Skip Winsock tests on Cygwin
 936 if test "$ac_cv_cygwin" != yes && test "$ac_cv_header_winsock_h" = yes; then
 937 AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 938 save_LIBS="$LIBS"
 939 for curlib in ws2_32 wsock32; do
 940         LIBS="$LIBS -l$curlib"
 941         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <winsock.h>
 942                         ]], [[
 943                         socket(0,0,0);
 944                         select(0,NULL,NULL,NULL,NULL);
 945                         closesocket(0);
 946                         gethostname(NULL,0);
 947                         ]])],[ol_cv_winsock=yes],[ol_cv_winsock=no])
 948
 949         if test $ol_cv_winsock = yes; then
 950                 AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 951                 ac_cv_func_socket=yes
 952                 ac_cv_func_select=yes
 953                 ac_cv_func_closesocket=yes
 954                 ac_cv_func_gethostname=yes
 955                 if test $curlib = ws2_32; then
 956                         ol_cv_winsock=winsock2
 957                         AC_DEFINE(HAVE_WINSOCK2, 1,
 958                                   [define if you have winsock2])
 959                 fi
 960                 break
 961         fi
 962         LIBS="$save_LIBS"
 963 done)
 964 fi
 965
 966 dnl Find socket()
 967 dnl Likely combinations:
 968 dnl             -lsocket [ -lnsl_s | -lnsl ]
 969 dnl             -linet
 970
 971 AC_CHECK_FUNC(socket, :, [
 972 dnl hopefully we won't include too many libraries
 973         AC_CHECK_LIB(socket, main)
 974         AC_CHECK_LIB(net, main)
 975         AC_CHECK_LIB(nsl_s, main)
 976         AC_CHECK_LIB(nsl, main)
 977         AC_CHECK_LIB(inet, socket)
 978         AC_CHECK_LIB(gen, main)
 979 ])
 980
 981 dnl require select
 982 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 983
 984 if test "${ac_cv_header_winsock_h}" != yes; then
 985         dnl Select arg types
 986         dnl (if this detection becomes permenent, it and the select() detection
 987         dnl should be done before the yielding select test)
 988         AC_FUNC_SELECT_ARGTYPES
 989 fi
 990
 991 dnl check to see if system call automatically restart
 992 dnl AC_SYS_RESTARTABLE_SYSCALLS
 993
 994 dnl ----------------------------------------------------------------
 995 AC_CHECK_FUNCS( poll )
 996 AC_CHECK_HEADERS( poll.h )
 997
 998 dnl ----------------------------------------------------------------
 999 AC_CHECK_HEADERS( sys/epoll.h )
1000 if test "${ac_cv_header_sys_epoll_h}" = yes; then
1001 AC_MSG_CHECKING(for epoll system call)
1002 AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char *argv)
1003 {
1004         int epfd = epoll_create(256);
1005         exit (epfd == -1 ? 1 : 0);
1006 }]])],[AC_MSG_RESULT(yes)
1007 AC_DEFINE(HAVE_EPOLL,1, [define if your system supports epoll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1008 fi
1009
1010 dnl ----------------------------------------------------------------
1011 # strerror checks
1012 OL_STRERROR
1013
1014 dnl ----------------------------------------------------------------
1015 dnl require POSIX regex
1016 AC_CHECK_HEADERS( regex.h )
1017 if test "$ac_cv_header_regex_h" != yes ; then
1018         AC_MSG_ERROR([POSIX regex.h required.])
1019 fi
1020 AC_SEARCH_LIBS(regfree, [regex gnuregex],
1021         :, AC_MSG_ERROR([POSIX regex required.]))
1022
1023 OL_POSIX_REGEX
1024 if test "$ol_cv_c_posix_regex" = no ; then
1025         AC_MSG_ERROR([broken POSIX regex!])
1026 fi
1027
1028 dnl ----------------------------------------------------------------
1029 dnl UUID Support
1030
1031 have_uuid=no
1032 AC_CHECK_HEADERS(sys/uuid.h)
1033 if test $ac_cv_header_sys_uuid_h = yes ; then
1034         save_LIBS="$LIBS"
1035         AC_SEARCH_LIBS(uuid_to_str, uuid, [have_uuid=yes], :)
1036         LIBS="$save_LIBS"
1037
1038         if test have_uuid = yes ; then
1039                 AC_DEFINE(HAVE_UUID_TO_STR,1,
1040                         [define if you have uuid_to_str()])
1041
1042                 test "$ac_cv_search_uuid_to_str" = "none required" || \
1043                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
1044         fi
1045 fi
1046
1047 dnl For windows, check for the need of RPCRT for UUID function support
1048 if test $have_uuid = no ; then
1049         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
1050         save_LIBS="$LIBS"
1051         LIBS="$LIBS -lrpcrt4"
1052         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1053                 int __stdcall UuidCreate(void *);
1054                 int __stdcall UuidToStringA(void *,void **);
1055                 ]], [[
1056                 UuidCreate(0);
1057                 UuidToStringA(0,0);
1058                 ]])],[need_rpcrt=yes],[need_rpcrt=no])
1059         if test $need_rpcrt = yes; then
1060                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
1061         fi
1062         LIBS="$save_LIBS"
1063         AC_MSG_RESULT($need_rpcrt)
1064 fi
1065
1066 dnl ----------------------------------------------------------------
1067 dnl Check for resolver routines
1068 OL_RESOLVER_LINK
1069
1070 ol_link_dnssrv=no
1071 if test "$ol_cv_lib_resolver" != no ; then
1072         AC_DEFINE(HAVE_RES_QUERY,1,
1073                 [define if you have res_query()])
1074
1075         if test "$ol_enable_dnssrv" != no ; then
1076                 ol_link_dnssrv=yes
1077         fi
1078
1079         if test "$ol_cv_lib_resolver" != yes ; then
1080                 LIBS="$ol_cv_lib_resolver $LIBS"
1081         fi
1082 fi
1083
1084 if test "$ol_enable_dnssrv" = yes || test "$ol_enable_dnssrv" = mod ; then
1085         if test "$ol_link_dnssrv" = no ; then
1086                 AC_MSG_ERROR([DNSSRV requires res_query()])
1087         fi
1088 else
1089         ol_enable_dnssrv=no
1090 fi
1091
1092 AC_CHECK_FUNCS( hstrerror )
1093
1094 dnl ----------------------------------------------------------------
1095 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1096 dnl PF_LOCAL may use getaddrinfo in available
1097 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1098
1099 ol_link_ipv6=no
1100 if test $ac_cv_func_getaddrinfo = no || test $ac_cv_func_inet_ntop = no ; then
1101         if test $ol_enable_ipv6 = yes ; then
1102                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1103         fi
1104 elif test $ol_enable_ipv6 != no ; then
1105         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1106                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1107 #                       include <netinet/in.h>
1108 #                       ifdef INET6_ADDRSTRLEN
1109                                 __has_inet6_addrstrlen__;
1110 #                       endif
1111                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1112
1113
1114         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1115                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1116 #include <sys/types.h>
1117 #include <sys/socket.h>
1118 ]], [[
1119                         struct sockaddr_storage ss;
1120 ]])],[ol_cv_struct_sockaddr_storage=yes],[ol_cv_struct_sockaddr_storage=no])])
1121
1122         if test $ol_cv_inet6_addrstrlen = yes &&
1123            test $ol_cv_struct_sockaddr_storage = yes ; then
1124                 ol_link_ipv6=yes
1125         elif test $ol_enable_ipv6 = yes &&
1126              test $ol_cv_inet6_addrstrlen = no ; then
1127                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1128         elif test $ol_enable_ipv6 = yes &&
1129              test $ol_cv_struct_sockaddr_storage = no ; then
1130                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1131         fi
1132 fi
1133
1134 if test $ol_enable_local != no ; then
1135         AC_CHECK_HEADERS( sys/un.h )
1136
1137         if test $ol_enable_local = auto ; then
1138                 ol_enable_local=$ac_cv_header_sys_un_h
1139         elif test $ac_cv_header_sys_un_h = no ; then
1140                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1141         fi
1142 fi
1143
1144 dnl ----------------------------------------------------------------
1145 dnl Kerberos
1146 ol_link_kbind=no
1147 ol_link_krb5=no
1148 ol_link_krb4=no
1149
1150 case $ol_with_kerberos in yes | auto | k5 | k5only | k425)
1151
1152         AC_CHECK_HEADERS(krb5.h)
1153
1154         if test $ac_cv_header_krb5_h = yes ; then
1155                 dnl lazy check for Heimdal Kerberos
1156                 AC_CHECK_HEADERS(heim_err.h)
1157                 if test $ac_cv_header_heim_err_h = yes ; then
1158                         krb5_impl=heimdal
1159                 else
1160                         krb5_impl=mit
1161                 fi
1162
1163                 if test $krb5_impl = mit; then
1164                         AC_CHECK_LIB(k5crypto, main,
1165                                 [krb5crypto=k5crypto],
1166                                 [krb5crypto=crypto])
1167
1168                         AC_CHECK_LIB(krb5, main,
1169                                 [have_krb5=yes
1170                                 KRB5_LIBS="-lkrb5 -l$krb5crypto -lcom_err"],
1171                                 [have_krb5=no],
1172                                 [-l$krb5crypto -lcom_err])
1173
1174                 elif test $krb5_impl = heimdal; then
1175                         AC_CHECK_LIB(des, main,
1176                                 [krb5crypto=des],
1177                                 [krb5crypto=crypto])
1178
1179                         AC_CHECK_LIB(krb5, main,
1180                                 [have_krb5=yes
1181                                 KRB5_LIBS="-lkrb5 -l$krb5crypto -lasn1 -lroken -lcom_err"],
1182                                 [have_krb5=no],
1183                                 [-l$krb5crypto -lasn1 -lroken -lcom_err])
1184
1185                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
1186                                 [define if you have HEIMDAL Kerberos])
1187
1188                 else
1189                         have_krb5=no
1190                         AC_MSG_WARN([Unrecognized Kerberos5 Implementation])
1191                 fi
1192
1193                 if test $have_krb5 = yes ; then
1194                         ol_link_krb5=yes
1195
1196                         AC_DEFINE(HAVE_KRB5, 1,
1197                                 [define if you have Kerberos V])
1198
1199                         if test $ol_with_kerberos = k5only ; then
1200                                 ol_with_kerberos=found
1201                         fi
1202
1203                 elif test $ol_with_kerberos != auto ; then
1204                         AC_MSG_ERROR([Required Kerberos 5 support not available])
1205                 fi
1206
1207         fi
1208         ;;
1209 esac
1210
1211 if test $ol_link_krb5 = yes &&
1212    { test $ol_with_kerberos = yes ||
1213      test $ol_with_kerberos = auto ||
1214      test $ol_with_kerberos = k425; }; then
1215
1216         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
1217
1218         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
1219                 if test $krb5_impl = mit; then
1220                         AC_CHECK_LIB(krb4, main, [have_k425=yes
1221                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
1222                                 [-ldes425 -lkrb5 -l$krb5crypto -lcom_err])
1223
1224                 elif test $krb5_impl = heimdal; then
1225                         AC_CHECK_LIB(krb4, main, [have_k425=yes
1226                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
1227                                 [-lkrb5 -l$krb5crypto -lasn1 -lroken -lcom_err])
1228
1229                 else
1230                         have_425=no
1231                         AC_MSG_WARN([Unrecongized Kerberos V Implementation])
1232                 fi
1233
1234                 if test $have_k425 = yes ; then
1235                         ol_with_kerberos=found
1236                         ol_link_krb4=yes
1237
1238                         AC_DEFINE(HAVE_KRB425, 1,
1239                                 [define if you have Kerberos V with IV support])
1240                         AC_DEFINE(HAVE_KRB4, 1,
1241                                 [define if you have Kerberos IV])
1242
1243                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
1244                                 [ol_cv_var_des_debug], [
1245                                 dnl save the flags
1246                                 save_LIBS="$LIBS"
1247                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
1248                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1249 #include <kerberosIV/krb.h>
1250 #include <kerberosIV/des.h>
1251 extern int des_debug;
1252 ]], [[
1253 des_debug = 1;
1254 ]])],[ol_cv_var_des_debug=yes],[ol_cv_var_des_debug=no])
1255                                 dnl restore the LIBS
1256                                 LIBS="$save_LIBS"
1257                         ])
1258
1259                         if test $ol_cv_var_des_debug = yes ; then
1260                                 AC_DEFINE(HAVE_DES_DEBUG,1,
1261                                         [define if you have Kerberos des_debug])
1262                         fi
1263
1264                         LIBS="$save_LIBS"
1265                 fi
1266         fi
1267 fi
1268
1269 if test $ol_link_krb5 = yes ; then
1270         ol_with_kerberos=found
1271 fi
1272
1273 case $ol_with_kerberos in yes | auto | k4 | kth)
1274
1275         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
1276
1277         if test $ac_cv_header_krb_h = yes ; then
1278                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
1279
1280                 if test $have_k4 = yes ; then
1281                         ol_with_kerberos=found
1282                         ol_link_krb4=yes
1283
1284                         AC_DEFINE(HAVE_KRB4, 1,
1285                                 [define if you have Kerberos IV])
1286
1287                         KRB4_LIBS="-lkrb -ldes"
1288
1289                         if test $ac_cv_header_krb_archaeology_h = yes ; then
1290                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
1291                                         [define if you have Kth Kerberos])
1292                         fi
1293                 fi
1294         fi
1295         ;;
1296 esac
1297
1298 if test $ol_link_krb4 = yes && test $ol_enable_kbind != no ; then
1299         ol_link_kbind=yes
1300
1301 elif test $ol_enable_kbind = yes ; then
1302         AC_MSG_ERROR([Kerberos IV detection failed])
1303 fi
1304
1305 if test $ol_link_krb4 = yes || test $ol_link_krb5 = yes ; then
1306         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
1307
1308 elif test $ol_with_kerberos != auto && test $ol_with_kerberos != no ; then
1309         AC_MSG_ERROR([Kerberos detection failed])
1310 fi
1311
1312 dnl ----------------------------------------------------------------
1313 dnl TLS/SSL
1314
1315 ol_link_tls=no
1316 if test $ol_with_tls != no ; then
1317         AC_CHECK_HEADERS(openssl/ssl.h)
1318
1319         if test $ac_cv_header_openssl_ssl_h = yes ; then
1320                 AC_CHECK_LIB(ssl, SSL_library_init,
1321                         [have_openssl=yes
1322                         need_rsaref=no], [have_openssl=no],
1323                         [-lcrypto])
1324
1325                 if test $have_openssl = no ; then
1326                         AC_CHECK_LIB(ssl, ssl3_accept,
1327                                 [have_openssl=yes
1328                                 need_rsaref=yes], [have_openssl=no],
1329                                 [-lcrypto -lRSAglue -lrsaref])
1330                 fi
1331
1332                 if test $have_openssl = yes ; then
1333                         ol_with_tls=found
1334                         ol_link_tls=yes
1335
1336                         AC_DEFINE(HAVE_OPENSSL, 1,
1337                                 [define if you have OpenSSL])
1338
1339                         if test $need_rsaref = yes; then
1340                                 AC_DEFINE(HAVE_RSAREF, 1,
1341                                         [define if OpenSSL needs RSAref])
1342
1343                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1344                         else
1345                                 TLS_LIBS="-lssl -lcrypto"
1346                         fi
1347                 fi
1348                 OL_SSL_COMPAT
1349                 if test $ol_cv_ssl_crl_compat = no ; then
1350                         ol_link_ssl=no
1351                 else
1352                         AC_DEFINE(HAVE_OPENSSL_CRL, 1,
1353                                 [define if you have OpenSSL with CRL checking capability])
1354                 fi
1355         fi
1356
1357 else
1358         AC_MSG_WARN([TLS data protection not supported!])
1359 fi
1360
1361 WITH_TLS=no
1362 if test $ol_link_tls = yes ; then
1363         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1364         WITH_TLS=yes
1365
1366 elif test $ol_with_tls = auto ; then
1367         AC_MSG_WARN([Could not locate TLS/SSL package])
1368         AC_MSG_WARN([TLS data protection not supported!])
1369
1370 elif test $ol_with_tls != no ; then
1371         AC_MSG_ERROR([Could not locate TLS/SSL package])
1372 fi
1373
1374 dnl ----------------------------------------------------------------
1375 dnl LAN Manger password checking requires DES from OpenSSL
1376 if test $ol_enable_lmpasswd != no; then
1377         if test $ol_link_tls != yes ; then
1378                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
1379         fi
1380
1381         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1382 fi
1383
1384 dnl ----------------------------------------------------------------
1385 dnl Threads?
1386 ol_link_threads=no
1387
1388 case $ol_with_threads in auto | yes | nt)
1389
1390         OL_NT_THREADS
1391
1392         if test "$ol_cv_nt_threads" = yes ; then
1393                 ol_link_threads=nt
1394                 ol_with_threads=found
1395                 ol_with_yielding_select=yes
1396
1397                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1398                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1399         fi
1400
1401         if test $ol_with_threads = nt ; then
1402                 AC_MSG_ERROR([could not locate NT Threads])
1403         fi
1404         ;;
1405 esac
1406
1407 case $ol_with_threads in auto | yes | posix)
1408
1409         AC_CHECK_HEADERS(pthread.h)
1410
1411         if test $ac_cv_header_pthread_h = yes ; then
1412                 OL_POSIX_THREAD_VERSION
1413
1414                 if test $ol_cv_pthread_version != 0 ; then
1415                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1416                                 [define to pthreads API spec revision])
1417                 else
1418                         AC_MSG_ERROR([unknown pthread version])
1419                 fi
1420
1421                 # consider threads found
1422                 ol_with_threads=found
1423
1424                 OL_HEADER_LINUX_THREADS
1425                 OL_HEADER_GNU_PTH_PTHREAD_H
1426
1427                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1428                         AC_CHECK_HEADERS(sched.h)
1429                 fi
1430
1431                 dnl Now the hard part, how to link?
1432                 dnl
1433                 dnl currently supported checks:
1434                 dnl
1435                 dnl Check for no flags
1436                 dnl     pthread_create() in $LIBS
1437                 dnl
1438                 dnl Check special pthread (final) flags
1439                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1440                 dnl     pthread_create() with -kthread (FreeBSD)
1441                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1442                 dnl     pthread_create() with -pthreads (?)
1443                 dnl     pthread_create() with -mthreads (AIX)
1444                 dnl     pthread_create() with -thread (?)
1445                 dnl
1446                 dnl Check pthread (final) libraries
1447                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1448                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1449                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1450                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1451                 dnl     pthread_create() in -lpthread (many)
1452                 dnl     pthread_create() in -lc_r (FreeBSD)
1453                 dnl
1454                 dnl Check pthread (draft4) flags (depreciated)
1455                 dnl     pthread_create() with -threads (OSF/1)
1456                 dnl
1457                 dnl Check pthread (draft4) libraries (depreciated)
1458                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1459                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1460                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1461                 dnl     pthread_create() in -lpthreads (many)
1462                 dnl
1463
1464                 dnl pthread_create in $LIBS
1465                 AC_CACHE_CHECK([for pthread_create in default libraries],
1466                         ol_cv_pthread_create,[
1467                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1468                                 [ol_cv_pthread_create=yes],
1469                                 [ol_cv_pthread_create=no],
1470                                 [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1471                                         [ol_cv_pthread_create=yes],
1472                                         [ol_cv_pthread_create=no])])])
1473
1474                 if test $ol_cv_pthread_create != no ; then
1475                         ol_link_threads=posix
1476                         ol_link_pthreads=""
1477                 fi
1478
1479 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1480                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1481                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1482                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1483                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1484                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1485
1486                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1487                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1488                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1489                         [ol_cv_pthread_lpthread_lmach_lexc])
1490 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1491 dnl                     [ol_cv_pthread_lpthread_lexc])
1492
1493                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1494                         [ol_cv_pthread_lib_lpthread_woff])
1495
1496                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1497                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1498
1499                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1500
1501                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1502                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1503                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1504                         [ol_cv_pthread_lpthreads_lmach_lexc])
1505                 OL_PTHREAD_TRY([-lpthreads -lexc],
1506                         [ol_cv_pthread_lpthreads_lexc])
1507
1508                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1509
1510                 if test $ol_link_threads != no ; then
1511                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1512
1513                         dnl save flags
1514                         save_CPPFLAGS="$CPPFLAGS"
1515                         save_LIBS="$LIBS"
1516                         LIBS="$LTHREAD_LIBS $LIBS"
1517
1518                         dnl All POSIX Thread (final) implementations should have
1519                         dnl sched_yield instead of pthread yield.
1520                         dnl check for both, and thr_yield for Solaris
1521                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1522
1523                         if test $ac_cv_func_sched_yield = no &&
1524                            test $ac_cv_func_pthread_yield = no &&
1525                            test $ac_cv_func_thr_yield = no ; then
1526                                 dnl Digital UNIX has sched_yield() in -lrt
1527                                 AC_CHECK_LIB(rt, sched_yield,
1528                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1529                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1530                                                 [Define if you have the sched_yield function.])
1531                                         ac_cv_func_sched_yield=yes],
1532                                         [ac_cv_func_sched_yield=no])
1533                         fi
1534                         if test $ac_cv_func_sched_yield = no &&
1535                            test $ac_cv_func_pthread_yield = no &&
1536                            test "$ac_cv_func_thr_yield" = no ; then
1537                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1538                         fi
1539
1540                         dnl Check functions for compatibility
1541                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1542
1543                         dnl Check for pthread_detach with <pthread.h> inclusion
1544                         dnl as it's symbol may have been mangled.
1545                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1546                                 [ol_cv_func_pthread_detach], [
1547                                 dnl save the flags
1548                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1549 #include <pthread.h>
1550 #ifndef NULL
1551 #define NULL (void*)0
1552 #endif
1553 ]], [[pthread_detach(NULL);]])],[ol_cv_func_pthread_detach=yes],[ol_cv_func_pthread_detach=no])
1554                         ])
1555
1556                         if test $ol_cv_func_pthread_detach = no ; then
1557                                 AC_MSG_ERROR([could not locate pthread_detach()])
1558                         fi
1559
1560                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1561                                 [define if you have pthread_detach function])
1562
1563                         dnl Check for setconcurreny functions
1564                         AC_CHECK_FUNCS( \
1565                                 pthread_setconcurrency \
1566                                 pthread_getconcurrency \
1567                                 thr_setconcurrency \
1568                                 thr_getconcurrency \
1569                         )
1570
1571                         OL_SYS_LINUX_THREADS
1572                         OL_LINUX_THREADS
1573
1574                         if test $ol_cv_linux_threads = error; then
1575                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1576                         fi
1577
1578                         AC_CACHE_CHECK([if pthread_create() works],
1579                                 ol_cv_pthread_create_works,[
1580                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1581                                 [ol_cv_pthread_create_works=yes],
1582                                 [ol_cv_pthread_create_works=no],
1583                                 [dnl assume yes
1584                                 ol_cv_pthread_create_works=yes])])
1585
1586                         if test $ol_cv_pthread_create_works = no ; then
1587                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1588                         fi
1589
1590                         dnl Check if select causes an yield
1591                         if test $ol_with_yielding_select = auto ; then
1592                                 AC_CACHE_CHECK([if select yields when using pthreads],
1593                                         ol_cv_pthread_select_yields,[
1594                                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1595 #include <sys/types.h>
1596 #include <sys/time.h>
1597 #include <unistd.h>
1598 #include <pthread.h>
1599 #ifndef NULL
1600 #define NULL (void*) 0
1601 #endif
1602
1603 static int fildes[2];
1604
1605 static void *task(p)
1606         void *p;
1607 {
1608         int i;
1609         struct timeval tv;
1610
1611         fd_set rfds;
1612
1613         tv.tv_sec=10;
1614         tv.tv_usec=0;
1615
1616         FD_ZERO(&rfds);
1617         FD_SET(fildes[0], &rfds);
1618
1619         /* we're not interested in any fds */
1620         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1621
1622         if(i < 0) {
1623                 perror("select");
1624                 exit(10);
1625         }
1626
1627         exit(0); /* if we exit here, the select blocked the whole process */
1628 }
1629
1630 int main(argc, argv)
1631         int argc;
1632         char **argv;
1633 {
1634         pthread_t t;
1635
1636         /* create a pipe to select */
1637         if(pipe(&fildes[0])) {
1638                 perror("select");
1639                 exit(1);
1640         }
1641
1642 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1643         (void) pthread_setconcurrency(2);
1644 #else
1645 #ifdef HAVE_THR_SETCONCURRENCY
1646         /* Set Solaris LWP concurrency to 2 */
1647         thr_setconcurrency(2);
1648 #endif
1649 #endif
1650
1651 #if HAVE_PTHREADS < 6
1652         pthread_create(&t, pthread_attr_default, task, NULL);
1653 #else
1654         pthread_create(&t, NULL, task, NULL);
1655 #endif
1656
1657         /* make sure task runs first */
1658 #if HAVE_THR_YIELD
1659         thr_yield();
1660 #elif defined( HAVE_SCHED_YIELD )
1661         sched_yield();
1662 #elif defined( HAVE_PTHREAD_YIELD )
1663         pthread_yield();
1664 #endif
1665
1666         exit(2);
1667 }]])],[ol_cv_pthread_select_yields=no],[ol_cv_pthread_select_yields=yes],[ol_cv_pthread_select_yields=cross])])
1668
1669                                 if test $ol_cv_pthread_select_yields = cross ; then
1670                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1671                                 fi
1672
1673                                 if test $ol_cv_pthread_select_yields = yes ; then
1674                                         ol_with_yielding_select=yes
1675                                 fi
1676                         fi
1677
1678                         dnl restore flags
1679                         CPPFLAGS="$save_CPPFLAGS"
1680                         LIBS="$save_LIBS"
1681                 else
1682                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1683                 fi
1684         fi
1685
1686         if test $ol_with_threads = posix ; then
1687                 AC_MSG_ERROR([could not locate POSIX Threads])
1688         fi
1689         ;;
1690 esac
1691
1692 case $ol_with_threads in auto | yes | mach)
1693
1694         dnl check for Mach CThreads
1695         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1696         if test $ac_cv_header_mach_cthreads_h = yes ; then
1697                 ol_with_threads=found
1698
1699                 dnl check for cthreads support in current $LIBS
1700                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1701
1702                 if test $ol_link_threads = no ; then
1703                         dnl try -all_load
1704                         dnl this test needs work
1705                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1706                                 [ol_cv_cthread_all_load], [
1707                                 dnl save the flags
1708                                 save_LIBS="$LIBS"
1709                                 LIBS="-all_load $LIBS"
1710                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <mach/cthreads.h>]], [[
1711                                         cthread_fork((void *)0, (void *)0);
1712                                         ]])],[ol_cv_cthread_all_load=yes],[ol_cv_cthread_all_load=no])
1713                                 dnl restore the LIBS
1714                                 LIBS="$save_LIBS"
1715                         ])
1716
1717                         if test $ol_cv_cthread_all_load = yes ; then
1718                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1719                                 ol_link_threads=mach
1720                                 ol_with_threads=found
1721                         fi
1722                 fi
1723
1724         elif test $ac_cv_header_cthreads_h = yes ; then
1725                 dnl Hurd variant of Mach Cthreads
1726                 dnl uses <cthreads.h> and -lthreads
1727
1728                 ol_with_threads=found
1729
1730                 dnl save the flags
1731                 save_LIBS="$LIBS"
1732                 LIBS="$LIBS -lthreads"
1733                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1734                 LIBS="$save_LIBS"
1735
1736                 if test $ol_link_threads = yes ; then
1737                         LTHREAD_LIBS="-lthreads"
1738                         ol_link_threads=mach
1739                         ol_with_threads=found
1740                 else
1741                         AC_MSG_ERROR([could not link with Mach CThreads])
1742                 fi
1743
1744         elif test $ol_with_threads = mach ; then
1745                 AC_MSG_ERROR([could not locate Mach CThreads])
1746         fi
1747
1748         if test $ol_link_threads = mach ; then
1749                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1750                         [define if you have Mach Cthreads])
1751         elif test $ol_with_threads = found ; then
1752                 AC_MSG_ERROR([could not link with Mach CThreads])
1753         fi
1754         ;;
1755 esac
1756
1757 case $ol_with_threads in auto | yes | pth)
1758
1759         AC_CHECK_HEADERS(pth.h)
1760
1761         if test $ac_cv_header_pth_h = yes ; then
1762                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1763
1764                 if test $have_pth = yes ; then
1765                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1766                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1767                         ol_link_threads=pth
1768                         ol_with_threads=found
1769
1770                         if test $ol_with_yielding_select = auto ; then
1771                                 ol_with_yielding_select=yes
1772                         fi
1773                 fi
1774         fi
1775         ;;
1776 esac
1777
1778 case $ol_with_threads in auto | yes | lwp)
1779
1780         dnl check for SunOS5 LWP
1781         AC_CHECK_HEADERS(thread.h synch.h)
1782         if test $ac_cv_header_thread_h = yes &&
1783            test $ac_cv_header_synch_h = yes ; then
1784                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1785
1786                 if test $have_thr = yes ; then
1787                         AC_DEFINE(HAVE_THR,1,
1788                                 [if you have Solaris LWP (thr) package])
1789                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1790                         ol_link_threads=thr
1791
1792                         if test $ol_with_yielding_select = auto ; then
1793                                 ol_with_yielding_select=yes
1794                         fi
1795
1796                         dnl Check for setconcurreny functions
1797                         AC_CHECK_FUNCS( \
1798                                 thr_setconcurrency \
1799                                 thr_getconcurrency \
1800                         )
1801                 fi
1802         fi
1803
1804         dnl check for SunOS4 LWP
1805         AC_CHECK_HEADERS(lwp/lwp.h)
1806         if test $ac_cv_header_lwp_lwp_h = yes ; then
1807                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1808
1809                 if test $have_lwp = yes ; then
1810                         AC_DEFINE(HAVE_LWP,1,
1811                                 [if you have SunOS LWP package])
1812                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1813                         ol_link_threads=lwp
1814
1815                         if test $ol_with_yielding_select = auto ; then
1816                                 ol_with_yielding_select=no
1817                         fi
1818                 fi
1819         fi
1820         ;;
1821 esac
1822
1823 if test $ol_with_yielding_select = yes ; then
1824         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1825                 [define if select implicitly yields])
1826 fi
1827
1828 if test $ol_with_threads = manual ; then
1829         dnl User thinks he can manually configure threads.
1830         ol_link_threads=yes
1831
1832         AC_MSG_WARN([thread defines and link options must be set manually])
1833
1834         AC_CHECK_HEADERS(pthread.h sched.h)
1835         AC_CHECK_FUNCS(sched_yield pthread_yield)
1836         OL_HEADER_LINUX_THREADS
1837
1838         AC_CHECK_HEADERS(mach/cthreads.h)
1839         AC_CHECK_HEADERS(lwp/lwp.h)
1840         AC_CHECK_HEADERS(thread.h synch.h)
1841 fi
1842
1843 if test $ol_link_threads != no && test $ol_link_threads != nt ; then
1844         dnl needed to get reentrant/threadsafe versions
1845         dnl
1846         AC_DEFINE(REENTRANT,1)
1847         AC_DEFINE(_REENTRANT,1)
1848         AC_DEFINE(THREAD_SAFE,1)
1849         AC_DEFINE(_THREAD_SAFE,1)
1850         AC_DEFINE(THREADSAFE,1)
1851         AC_DEFINE(_THREADSAFE,1)
1852         AC_DEFINE(_SGI_MP_SOURCE,1)
1853
1854         dnl The errno declaration may dependent upon _REENTRANT.
1855         dnl If it does, we must link with thread support.
1856         AC_CACHE_CHECK([for thread specific errno],
1857                 [ol_cv_errno_thread_specific], [
1858                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[errno = 0;]])],[ol_cv_errno_thread_specific=yes],[ol_cv_errno_thread_specific=no])
1859         ])
1860
1861         dnl The h_errno declaration may dependent upon _REENTRANT.
1862         dnl If it does, we must link with thread support.
1863         AC_CACHE_CHECK([for thread specific h_errno],
1864                 [ol_cv_h_errno_thread_specific], [
1865                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[h_errno = 0;]])],[ol_cv_h_errno_thread_specific=yes],[ol_cv_h_errno_thread_specific=no])
1866         ])
1867
1868         if test $ol_cv_errno_thread_specific != yes ||
1869            test $ol_cv_h_errno_thread_specific != yes ; then
1870                 LIBS="$LTHREAD_LIBS $LIBS"
1871                 LTHREAD_LIBS=""
1872         fi
1873
1874 dnl When in thread environment, use
1875 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1876 dnl                     func_r(...);
1877 dnl             #else
1878 dnl             #       if defined( HAVE_THREADS )
1879 dnl                             /* lock */
1880 dnl             #       endif
1881 dnl                             func(...);
1882 dnl             #       if defined( HAVE_THREADS )
1883 dnl                             /* unlock */
1884 dnl             #       endif
1885 dnl             #endif
1886 dnl
1887 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1888 dnl             _POSIX_REENTRANT_FUNCTIONS
1889 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1890 dnl             _POSIX_THREADSAFE_FUNCTIONS
1891 dnl
1892 dnl             and is currently defined in <ldap_pvt_thread.h>
1893 dnl
1894 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1895 dnl
1896 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1897 dnl LDAP_R_COMPILE is defined.  ie:
1898 dnl             #ifdef LDAP_R_COMPILE
1899 dnl             #       include <ldap_pvt_thread.h>
1900 dnl             #endif
1901 dnl
1902 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1903 dnl specifically for compiling the threadsafe version of
1904 dnl     the ldap library (-lldap_r).
1905 dnl
1906 dnl     dnl check for reentrant/threadsafe functions
1907 dnl     dnl
1908 dnl     dnl note: these should only be used when linking
1909 dnl     dnl             with $LTHREAD_LIBS
1910 dnl     dnl
1911 dnl     save_CPPFLAGS="$CPPFLAGS"
1912 dnl     save_LIBS="$LIBS"
1913 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1914 dnl     AC_CHECK_FUNCS( \
1915 dnl             gmtime_r \
1916 dnl             gethostbyaddr_r gethostbyname_r \
1917 dnl             feof_unlocked unlocked_feof \
1918 dnl             putc_unlocked unlocked_putc \
1919 dnl             flockfile ftrylockfile \
1920 dnl     )
1921 dnl     CPPFLAGS="$save_CPPFLAGS"
1922 dnl     LIBS="$save_LIBS"
1923 fi
1924
1925 if test $ol_link_threads = no ; then
1926         if test $ol_with_threads = yes ; then
1927                 AC_MSG_ERROR([no suitable thread support])
1928         fi
1929
1930         if test $ol_with_threads = auto ; then
1931                 AC_MSG_WARN([no suitable thread support, disabling threads])
1932                 ol_with_threads=no
1933         fi
1934
1935         AC_DEFINE(NO_THREADS,1,
1936                 [define if you have (or want) no threads])
1937         LTHREAD_LIBS=""
1938         BUILD_THREAD=no
1939 else
1940         BUILD_THREAD=yes
1941 fi
1942
1943 if test $ol_link_threads != no ; then
1944         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1,
1945                 [define to 1 if library is thread safe])
1946 fi
1947
1948 dnl ----------------------------------------------------------------
1949 dnl Tests for reentrant functions necessary to build -lldap_r
1950 AC_CHECK_FUNCS(         \
1951         ctime_r                 \
1952         gethostbyname_r gethostbyaddr_r \
1953 )
1954
1955 if test "$ac_cv_func_ctime_r" = no ; then
1956         ol_cv_func_ctime_r_nargs=0
1957 else
1958         OL_FUNC_CTIME_R_NARGS
1959 dnl     OL_FUNC_CTIME_R_TYPE
1960 fi
1961
1962 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1963         OL_FUNC_GETHOSTBYNAME_R_NARGS
1964 else
1965         ol_cv_func_gethostbyname_r_nargs=0
1966 fi
1967
1968 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1969         OL_FUNC_GETHOSTBYADDR_R_NARGS
1970 else
1971         ol_cv_func_gethostbyaddr_r_nargs=0
1972 fi
1973
1974 dnl ----------------------------------------------------------------
1975 ol_link_ldbm=no
1976
1977 case $ol_enable_ldbm_api in auto | berkeley | bcompat)
1978
1979         if test $ol_enable_ldbm_api = bcompat; then \
1980                 OL_BERKELEY_COMPAT_DB
1981         else
1982                 OL_BERKELEY_DB
1983         fi
1984
1985         if test $ol_cv_berkeley_db != no ; then
1986                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1987                         [define this if Berkeley DB is available])
1988
1989                 ol_link_ldbm=berkeley
1990                 ol_enable_ldbm_api=berkeley
1991
1992                 if test $ol_enable_ldbm_type = hash ; then
1993                         AC_DEFINE(LDBM_USE_DBHASH,1,
1994                                 [define this to use DBHASH w/ LDBM backend])
1995                 else
1996                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1997                                 [define this to use DBBTREE w/ LDBM backend])
1998                 fi
1999
2000                 dnl $ol_cv_lib_db should be yes or -ldb
2001                 dnl (it could be no, but that would be an error
2002                 if test $ol_cv_lib_db != yes ; then
2003                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
2004                 fi
2005         fi
2006         ;;
2007 esac
2008
2009 if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
2010         if test $ol_link_ldbm != berkeley ; then
2011                 AC_MSG_ERROR(BDB/HDB: BerkeleyDB not available)
2012         else
2013                 OL_BDB_COMPAT
2014
2015                 if test $ol_cv_bdb_compat != yes ; then
2016                         AC_MSG_ERROR([BDB/HDB: BerkeleyDB version incompatible])
2017                 fi
2018         fi
2019 fi
2020
2021 if test $ol_link_ldbm = no && test $ol_enable_ldbm_type = btree ; then
2022         AC_MSG_WARN([Could not find LDBM with BTREE support])
2023         ol_enable_ldbm_api=none
2024 fi
2025
2026 if test $ol_enable_ldbm_api = auto || test $ol_enable_ldbm_api = mdbm ; then
2027         OL_MDBM
2028
2029         if test $ol_cv_mdbm = yes ; then
2030                 ol_link_ldbm=mdbm
2031                 ol_enable_ldbm_api=mdbm
2032                 if test $ol_cv_lib_mdbm != yes ; then
2033                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
2034                 fi
2035         fi
2036 fi
2037
2038 if test $ol_enable_ldbm_api = auto || test $ol_enable_ldbm_api = gdbm ; then
2039         OL_GDBM
2040
2041         if test $ol_cv_gdbm = yes ; then
2042                 ol_link_ldbm=gdbm
2043                 ol_enable_ldbm_api=gdbm
2044
2045                 if test $ol_cv_lib_gdbm != yes ; then
2046                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
2047                 fi
2048         fi
2049 fi
2050
2051 if test $ol_enable_ldbm_api = ndbm ; then
2052         OL_NDBM
2053
2054         if test $ol_cv_ndbm = yes ; then
2055                 ol_link_ldbm=ndbm
2056                 ol_enable_ldbm_api=ndbm
2057
2058                 if test $ol_cv_lib_ndbm != yes ; then
2059                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
2060                 fi
2061         fi
2062 fi
2063
2064 if test $ol_link_ldbm = no && test $ol_enable_ldbm != no ; then
2065         AC_MSG_ERROR([could not find suitable LDBM backend])
2066 fi
2067
2068 if test $ol_enable_bdb = yes ||
2069    test $ol_enable_hdb = yes ||
2070    test $ol_enable_ldbm = yes ; then
2071         SLAPD_LIBS="$SLAPD_LIBS \$(LDBM_LIBS)"
2072 fi
2073
2074 dnl ----------------------------------------------------------------
2075
2076 if test $ol_enable_dynamic = yes && test $enable_shared = yes ; then
2077         BUILD_LIBS_DYNAMIC=shared
2078         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
2079         LTSTATIC=""
2080 else
2081         BUILD_LIBS_DYNAMIC=static
2082         LTSTATIC="-static"
2083 fi
2084 AC_SUBST(LTSTATIC)dnl
2085
2086 dnl ----------------------------------------------------------------
2087 if test $ol_enable_wrappers != no ; then
2088         AC_CHECK_HEADERS(tcpd.h,[
2089                 AC_MSG_CHECKING([for TCP wrappers library])
2090                 save_LIBS="$LIBS"
2091                 LIBS="$LIBS -lwrap"
2092                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2093 #include <tcpd.h>
2094 int allow_severity = 0;
2095 int deny_severity  = 0;
2096
2097 struct request_info *req;
2098                 ]], [[
2099 hosts_access(req)
2100                 ]])],[AC_MSG_RESULT([-lwrap])
2101                 have_wrappers=yes
2102                 LIBS="$save_LIBS"],[
2103                 dnl try with -lnsl
2104                 LIBS="$LIBS -lnsl"
2105                 AC_TRY_LINK([
2106 #include <tcpd.h>
2107 int allow_severity = 0;
2108 int deny_severity  = 0;
2109
2110 struct request_info *req;
2111                 ],[
2112 hosts_access(req)
2113                 ],[AC_MSG_RESULT([-lwrap -lnsl])
2114                 have_wrappers=yes
2115                 LIBS="$save_LIBS -lnsl"],[
2116                 AC_MSG_RESULT(no)
2117                 have_wrappers=no
2118                 LIBS=$save_LIBS])])],[have_wrappers=no])
2119
2120         if test $have_wrappers = yes ; then
2121                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
2122                 WRAP_LIBS="-lwrap"
2123         elif test $ol_enable_wrappers = yes ; then
2124                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options or disable])
2125         else
2126                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
2127                 WRAP_LIBS=""
2128         fi
2129 fi
2130
2131 dnl ----------------------------------------------------------------
2132 if test $ol_enable_syslog != no ; then
2133         AC_CHECK_FUNC(openlog)
2134         if test $ac_cv_func_openlog = no && test $ol_enable_syslog = yes; then
2135                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
2136         fi
2137         ol_enable_syslog=$ac_cv_func_openlog
2138 fi
2139
2140 dnl ----------------------------------------------------------------
2141 dnl SQL
2142 ol_link_sql=no
2143 if test $ol_enable_sql != no ; then
2144         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
2145                 AC_MSG_ERROR([could not locate SQL headers])
2146         ])
2147
2148         sql_LIBS="$LIBS"
2149         LIBS="$LTHREAD_LIBS"
2150
2151         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
2152         if test $have_iodbc = yes ; then
2153                 ol_link_sql="-liodbc"
2154         else
2155                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
2156                 if test $have_odbc = yes ; then
2157                         ol_link_sql="-lodbc"
2158                 fi
2159         fi
2160
2161         LIBS="$sql_LIBS"
2162
2163         if test $ol_link_sql != no ; then
2164                 SLAPD_SQL_LIBS="$ol_link_sql"
2165
2166         elif test $ol_enable_sql != auto ; then
2167                 AC_MSG_ERROR([could not locate suitable ODBC library])
2168         fi
2169 fi
2170
2171 dnl ----------------------------------------------------------------
2172 dnl International Components for Unicode
2173 OL_ICU
2174 if test "$ol_icu" = no ; then
2175         AC_MSG_WARN([ICU not available])
2176 else
2177         ICU_LIBS="$ol_icu"
2178 fi
2179 dnl ----------------------------------------------------------------
2180 dnl
2181 dnl Check for Cyrus SASL
2182 dnl
2183 WITH_SASL=no
2184 ol_link_sasl=no
2185 ol_link_spasswd=no
2186 if test $ol_with_cyrus_sasl != no ; then
2187         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
2188
2189         if test $ac_cv_header_sasl_sasl_h = yes ||
2190            test $ac_cv_header_sasl_h = yes; then
2191                 AC_CHECK_LIB(sasl2, sasl_client_init,
2192                         [ol_link_sasl="-lsasl2"],
2193                         [AC_CHECK_LIB(sasl, sasl_client_init,
2194                                 [ol_link_sasl="-lsasl"])])
2195         fi
2196
2197         if test $ol_link_sasl = no ; then
2198                 if test $ol_with_cyrus_sasl != auto ; then
2199                         AC_MSG_ERROR([Could not locate Cyrus SASL])
2200                 else
2201                         AC_MSG_WARN([Could not locate Cyrus SASL])
2202                         AC_MSG_WARN([SASL authentication not supported!])
2203                         if test $ol_link_tls = no ; then
2204                                 AC_MSG_WARN([Strong authentication not supported!])
2205                         fi
2206                 fi
2207         else
2208                 OL_SASL_COMPAT
2209                 if test $ol_cv_sasl_compat = no ; then
2210                         ol_link_sasl=no
2211                         AC_MSG_ERROR([Cyrus SASL library located but is incompatible])
2212                 fi
2213
2214                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
2215                 SASL_LIBS="$ol_link_sasl"
2216                 if test $ol_enable_spasswd != no ; then
2217                         ol_link_spasswd=yes
2218                 fi
2219
2220                 ac_save_LIBS="$LIBS"
2221                 LIBS="$LIBS $ol_link_sasl"
2222                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
2223                         [define if your SASL library has sasl_version()])])
2224                 LIBS="$ac_save_LIBS"
2225
2226                 WITH_SASL=yes
2227         fi
2228
2229 else
2230         AC_MSG_WARN([SASL authentication not supported!])
2231         if test $ol_link_tls = no ; then
2232                 AC_MSG_WARN([Strong authentication not supported!])
2233         fi
2234 fi
2235
2236 dnl ----------------------------------------------------------------
2237 dnl Check for entropy sources
2238 if test $cross_compiling != yes && test "$ac_cv_mingw32" != yes ; then
2239         dev=no
2240         if test -r /dev/urandom ; then
2241                 dev="/dev/urandom";
2242         elif test -r /idev/urandom ; then
2243                 dev="/idev/urandom";
2244         elif test -r /dev/srandom ; then
2245                 dev="/dev/srandom";
2246         elif test -r /dev/random ; then
2247                 dev="/dev/random";
2248         elif test -r /idev/random ; then
2249                 dev="/idev/random";
2250         fi
2251
2252         if test $dev != no ; then
2253                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2254         fi
2255 fi
2256
2257 dnl ----------------------------------------------------------------
2258 dnl
2259 dnl Check for fetch URL support
2260 dnl             should be extended to support other fetch URL APIs
2261 dnl
2262 ol_link_fetch=no
2263 if test $ol_with_fetch != no ; then
2264         OL_LIB_FETCH
2265
2266         if test $ol_cv_lib_fetch != no ; then
2267                 LUTIL_LIBS="$LUTIL_LIBS $ol_link_fetch"
2268                 ol_link_fetch=freebsd
2269
2270         elif test $ol_with_fetch != auto ; then
2271                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2272         fi
2273 fi
2274
2275 dnl ----------------------------------------------------------------
2276 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2277 if test $ol_enable_crypt != no ; then
2278         save_LIBS="$LIBS"
2279         LIBS="$TLS_LIBS $LIBS"
2280
2281         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2282                 LIBS="$save_LIBS"
2283                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2284                         have_crypt=yes], [have_crypt=no])])
2285
2286         LIBS="$save_LIBS"
2287
2288         if test $have_crypt = yes ; then
2289                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2290         else
2291                 AC_MSG_WARN([could not find crypt])
2292                 if test $ol_enable_crypt = yes ; then
2293                         AC_MSG_ERROR([could not find crypt, select appropriate options or disable])
2294                 fi
2295
2296                 AC_MSG_WARN([disabling crypt support])
2297                 ol_enable_crypt=no
2298         fi
2299 fi
2300
2301 dnl ----------------------------------------------------------------
2302 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2303 if test $ol_enable_proctitle != no ; then
2304         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2305                 AC_CHECK_LIB(util, setproctitle,
2306                         [have_setproctitle=yes
2307                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2308                         [have_setproctitle=no
2309                         AC_LIBOBJ(setproctitle)
2310                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2311
2312         if test $have_setproctitle = yes ; then
2313                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2314                         [define if setproctitle(3) is available])
2315         fi
2316 fi
2317
2318 dnl ----------------------------------------------------------------
2319 dnl Check for SLPv2 Compliant API Library
2320 if test $ol_enable_slp != no ; then
2321         AC_CHECK_HEADERS( slp.h )
2322
2323         if test $ac_cv_header_slp_h = yes ; then
2324                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2325                 if test $have_slp = yes ; then
2326                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2327                         SLAPD_SLP_LIBS=-lslp
2328                 fi
2329
2330         elif test $ol_enable_slp = yes ; then
2331                 AC_MSG_ERROR([SLP not found])
2332         fi
2333 fi
2334
2335 dnl ----------------------------------------------------------------
2336 dnl Check for multiple precision support
2337 if test "$ol_with_multiple_precision" != "no" ; then
2338         ol_have_bignum=no
2339         ol_have_gmp=no
2340
2341         AC_CHECK_HEADERS(openssl/bn.h bn.h)
2342         AC_CHECK_HEADERS(openssl/crypto.h crypto.h)
2343         AC_CHECK_HEADERS( gmp.h )
2344
2345         if test "$ol_with_tls" = "found" ; then
2346                 ol_have_bn_h=no
2347                 ol_have_crypto_h=no
2348
2349                 if test "$ac_cv_header_openssl_bn_h" = "yes" ||
2350                    test "$ac_cv_header_bn_h" = "yes" ; then
2351                         ol_have_bn_h=yes
2352                 fi
2353
2354                 if test "$ac_cv_header_openssl_crypto_h" = "yes" ||
2355                    test "$ac_cv_header_crypto_h" = "yes" ; then
2356                         ol_have_crypto_h=yes
2357                 fi
2358
2359                 if test "$ol_have_bn_h" = "yes" &&
2360                    test "$ol_have_crypto_h" = "yes" ; then
2361                         ol_have_bignum=yes
2362                 fi
2363         fi
2364
2365         if test $ac_cv_header_gmp_h = yes ; then
2366                 AC_CHECK_LIB(gmp, __gmpz_add_ui, [have_gmp=yes], [have_gmp=no])
2367                 if test $have_gmp = yes ; then
2368                         ol_have_gmp=yes
2369                 fi
2370         fi
2371
2372         AC_MSG_CHECKING([for multiple precision support])
2373
2374         ol_mp_support="none"
2375         case "$ol_with_multiple_precision" in
2376         auto)
2377                 dnl preferred sequence:
2378                 dnl - OpenSSL's BIGNUM (if libssl is already linked)
2379                 dnl - GNU's MP
2380                 dnl - unsigned long
2381                 if test "$ol_have_bignum" = "yes" ; then
2382                         ol_mp_support="bignum"
2383                 else
2384                         if test "$ol_have_gmp" = "yes" ; then
2385                                 ol_mp_support="gmp"
2386                         fi
2387                 fi
2388                 ;;
2389         bignum)
2390                 if test "$ol_have_bignum" != "yes" ; then
2391                         AC_MSG_ERROR([OpenSSL's BIGNUM not available])
2392                 fi
2393                 ol_mp_support="bignum"
2394                 ;;
2395         gmp)
2396                 if test "$ol_have_gmp" != "yes" ; then
2397                         AC_MSG_ERROR([GMP not available])
2398                 fi
2399                 ol_mp_support="gmp"
2400                 ;;
2401         yes)
2402                 if test "$ol_have_bignum" = "yes" ; then
2403                         ol_mp_support="bignum"
2404                 elif test "$ol_have_gmp" = "yes" ; then
2405                         ol_mp_support="gmp"
2406                 else
2407                         AC_MSG_ERROR([not available])
2408                 fi
2409                 ;;
2410         esac
2411
2412         case "$ol_mp_support" in
2413         bignum)
2414                 AC_DEFINE(HAVE_BIGNUM, 1,
2415                         [define if you have OpenSSL's BIGNUM])
2416                 ;;
2417         gmp)
2418                 AC_DEFINE(HAVE_GMP, 1, [define if you have -lgmp])
2419                 SLAPD_GMP_LIBS=-lgmp
2420                 ;;
2421         none)
2422                 ;;
2423         esac
2424
2425         AC_MSG_RESULT($ol_mp_support)
2426 fi
2427
2428 dnl ----------------------------------------------------------------
2429 dnl Checks for typedefs, structures, and compiler characteristics.
2430
2431 AC_CHECK_TYPE(mode_t, int)
2432 AC_CHECK_TYPE(off_t, long)
2433 AC_CHECK_TYPE(pid_t, int)
2434 AC_CHECK_TYPE(ssize_t, [signed int])
2435 AC_CHECK_TYPE(caddr_t,  [char *])
2436 AC_CHECK_TYPE(size_t, unsigned)
2437
2438 AC_CHECK_TYPES([long long])
2439 AC_CHECK_TYPES([ptrdiff_t])
2440
2441 AC_CHECK_TYPE([socklen_t],,
2442         [AC_DEFINE_UNQUOTED([socklen_t], [int],
2443                 [Define to `int' if <sys/socket.h> does not define.])],
2444         [$ac_includes_default
2445 #ifdef HAVE_SYS_SOCKET_H
2446 #include <sys/socket.h>
2447 #endif
2448         ])
2449
2450 AC_TYPE_SIGNAL
2451
2452 AC_CHECK_TYPE([sig_atomic_t],,
2453         [AC_DEFINE_UNQUOTED([sig_atomic_t], [int],
2454                 [Define to `int' if <signal.h> does not define.])],
2455         [$ac_includes_default
2456 #include <signal.h>
2457         ])
2458
2459 AC_TYPE_UID_T
2460
2461 AC_HEADER_TIME
2462 AC_STRUCT_TM
2463 AC_CHECK_MEMBERS([struct stat.st_blksize])
2464 AC_CHECK_MEMBERS([struct passwd.pw_gecos],,,[$ac_includes_default
2465 #include <pwd.h>])
2466 AC_CHECK_MEMBERS([struct passwd.pw_passwd],,,[$ac_includes_default
2467 #include <pwd.h>])
2468
2469 OL_C_UPPER_LOWER
2470 AC_C_CONST
2471 OL_C_VOLATILE
2472
2473 if test $cross_compiling = yes ; then
2474         AC_MSG_WARN([Crossing compiling... all bets are off!])
2475         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2476 else
2477         AC_C_BIGENDIAN
2478 fi
2479
2480 AC_CHECK_SIZEOF(short)
2481 AC_CHECK_SIZEOF(int)
2482 AC_CHECK_SIZEOF(long)
2483 AC_CHECK_SIZEOF(wchar_t)
2484
2485 if test "$ac_cv_sizeof_int" -lt 4 ; then
2486         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2487
2488         AC_DEFINE(LBER_INT_T,long,[define to 32-bit or greater integer type])
2489 else
2490         AC_DEFINE(LBER_INT_T,int,[define to 32-bit or greater integer type])
2491 fi
2492
2493 AC_DEFINE(LBER_LEN_T,long,[define to large integer type])
2494 AC_DEFINE(LBER_SOCKET_T,int,[define to socket descriptor type])
2495 AC_DEFINE(LBER_TAG_T,long,[define to large integer type])
2496
2497 dnl ----------------------------------------------------------------
2498 dnl Checks for library functions.
2499 AC_FUNC_MEMCMP
2500
2501 if test $ac_cv_func_memcmp_working = no ; then
2502         AC_DEFINE(NEED_MEMCMP_REPLACEMENT,1,
2503                 [define if memcmp is not 8-bit clean or is otherwise broken])
2504 fi
2505
2506 AC_FUNC_STRFTIME
2507
2508 OL_FUNC_INET_ATON
2509
2510 dnl Check for NT specific routines
2511 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2512
2513 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2514         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2515 ])
2516
2517 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2518         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2519 ])
2520
2521 AC_FUNC_VPRINTF
2522
2523 if test $ac_cv_func_vprintf = yes ; then
2524         dnl check for vsnprintf
2525         AC_CHECK_FUNCS(snprintf vsnprintf)
2526 fi
2527
2528 AC_CHECK_FUNCS(         \
2529         bcopy                   \
2530         closesocket             \
2531         chroot                  \
2532         endgrent                \
2533         endpwent                \
2534         fcntl                   \
2535         flock                   \
2536         fstat                   \
2537         getdtablesize   \
2538         getgrgid                \
2539         gethostname             \
2540         getpass                 \
2541         getpassphrase   \
2542         getpwuid                \
2543         getpwnam                \
2544         getspnam                \
2545         gettimeofday    \
2546         initgroups              \
2547         inet_ntoa_b             \
2548         lockf                   \
2549         memcpy                  \
2550         memmove                 \
2551         memrchr                 \
2552         mkstemp                 \
2553         mktemp                  \
2554         pipe                    \
2555         read                    \
2556         recv                    \
2557         recvfrom                \
2558         setpwfile               \
2559         setgid                  \
2560         setegid                 \
2561         setsid                  \
2562         setuid                  \
2563         seteuid                 \
2564         signal                  \
2565         strdup                  \
2566         strpbrk                 \
2567         strrchr                 \
2568         strsep                  \
2569         strstr                  \
2570         strtol                  \
2571         strtoul                 \
2572         strtoq                  \
2573         strtouq                 \
2574         strtoll                 \
2575         strspn                  \
2576         sysconf                 \
2577         usleep                  \
2578         waitpid                 \
2579         wait4                   \
2580         write                   \
2581         send                    \
2582         sendmsg                 \
2583         sendto                  \
2584 )
2585
2586 dnl We actually may need to replace more than this.
2587 AC_REPLACE_FUNCS(getopt getpeereid)
2588
2589 if test "$ac_cv_func_getopt" != yes; then
2590         LIBSRCS="$LIBSRCS getopt.c"
2591 fi
2592
2593 if test "$ac_cv_func_getpeereid" != yes; then
2594         AC_CHECK_FUNCS( getpeerucred )
2595         if test "$ac_cv_func_getpeerucred" != yes ; then
2596                 AC_CHECK_MEMBERS([struct msghdr.msg_accrightslen],,,
2597                         [$ac_includes_default
2598 #ifdef HAVE_SYS_SOCKET_H
2599 #include <sys/socket.h>
2600 #endif])
2601                 if test "$ac_cv_member_struct_msghdr_msg_accrightslen" != yes; then
2602                         AC_CHECK_MEMBERS([struct msghdr.msg_control],,,
2603                                 [$ac_includes_default
2604 #ifdef HAVE_SYS_SOCKET_H
2605 #include <sys/socket.h>
2606 #endif])
2607                 fi
2608         fi
2609         LIBSRCS="$LIBSRCS getpeereid.c"
2610 fi
2611
2612 if test "$ac_cv_func_snprintf" != yes ||
2613    test "$ac_cv_func_vsnprintf" != yes; then
2614         if test "$ac_cv_func_snprintf" != yes; then
2615                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2616         fi
2617         if test "$ac_cv_func_vsnprintf" != yes; then
2618                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2619         fi
2620 fi
2621
2622 dnl ----------------------------------------------------------------
2623 dnl Sort out defines
2624
2625 if test "$ol_enable_slapi" != no ; then
2626         dnl This check is done also if --enable-modules is used;
2627         dnl it is duplicated here, 'cause it'd be cached anyway
2628         AC_CHECK_HEADERS(ltdl.h)
2629
2630         if test $ac_cv_header_ltdl_h != yes ; then
2631                 AC_MSG_ERROR([could not locate <ltdl.h>])
2632         fi
2633         AC_CHECK_LIB(ltdl, lt_dlinit, [
2634                 SLAPI_LIBS=-lltdl
2635                 LIBSLAPI=libslapi.a
2636                 LIBSLAPITOOLS=../libslapi.a
2637                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
2638         ],[AC_MSG_ERROR([could not locate libtool -lltdl])])
2639
2640         AC_DEFINE(LDAP_SLAPI,1, [define this to add SLAPI code])
2641 fi
2642
2643 if test "$ol_enable_debug" != no ; then
2644         if test "$ol_enable_debug" = traditional; then
2645                 AC_DEFINE(OLD_DEBUG,1,
2646                         [define to use the original debug style])
2647         fi
2648         AC_DEFINE(LDAP_DEBUG,1,
2649                 [define this to add debugging code])
2650 fi
2651 if test "$ol_enable_syslog" = yes ; then
2652         AC_DEFINE(LDAP_SYSLOG,1,
2653                 [define this to add syslog code])
2654 fi
2655 if test "$ol_link_kbind" != no ; then
2656         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION,
2657                 [define to LDAP VENDOR VERSION])
2658 fi
2659 if test "$ol_enable_proctitle" != no ; then
2660         AC_DEFINE(LDAP_PROCTITLE,1,
2661                 [define this for LDAP process title support])
2662 fi
2663 if test "$ol_enable_referrals" != no ; then
2664         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION,
2665                 [define to LDAP VENDOR VERSION])
2666 fi
2667 if test "$ol_enable_local" != no; then
2668         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2669 fi
2670 if test "$ol_link_ipv6" != no; then
2671         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2672 fi
2673 if test "$ol_enable_cleartext" != no ; then
2674         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2675 fi
2676 if test "$ol_enable_crypt" != no ; then
2677         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2678 fi
2679 if test "$ol_link_spasswd" != no ; then
2680         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2681 fi
2682 if test "$ol_enable_multimaster" != no ; then
2683         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2684 fi
2685 if test "$ol_enable_rlookups" != no ; then
2686         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2687 fi
2688 if test "$ol_enable_aci" != no ; then
2689         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2690         WITH_ACI_ENABLED=yes
2691 else
2692         WITH_ACI_ENABLED=no
2693 fi
2694
2695 if test "$ol_link_modules" != no ; then
2696         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2697         BUILD_SLAPD=yes
2698         SLAPD_MODULES_LDFLAGS="-dlopen self"
2699 fi
2700
2701 AC_DEFINE(SLAPD_MOD_STATIC,1,[statically linked module])
2702 AC_DEFINE(SLAPD_MOD_DYNAMIC,2,[dynamically linked module])
2703
2704 if test "$ol_enable_bdb" != no ; then
2705         BUILD_SLAPD=yes
2706         BUILD_BDB=$ol_enable_bdb
2707         if test "$ol_enable_bdb" = mod ; then
2708                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2709                 MFLAG=SLAPD_MOD_DYNAMIC
2710         else
2711                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2712                 MFLAG=SLAPD_MOD_STATIC
2713         fi
2714         AC_DEFINE_UNQUOTED(SLAPD_BDB,$MFLAG,[define to support BDB backend])
2715 fi
2716
2717 if test "$ol_enable_dnssrv" != no ; then
2718         BUILD_SLAPD=yes
2719         BUILD_DNSSRV=$ol_enable_dnssrv
2720         if test "$ol_enable_dnssrv" = mod ; then
2721                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2722                 MFLAG=SLAPD_MOD_DYNAMIC
2723         else
2724                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2725                 MFLAG=SLAPD_MOD_STATIC
2726         fi
2727         AC_DEFINE_UNQUOTED(SLAPD_DNSSRV,$MFLAG,[define to support DNS SRV backend])
2728 fi
2729
2730 if test "$ol_enable_hdb" != no ; then
2731         BUILD_SLAPD=yes
2732         BUILD_HDB=$ol_enable_hdb
2733         if test "$ol_enable_hdb" = mod ; then
2734                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-hdb"
2735                 MFLAG=SLAPD_MOD_DYNAMIC
2736         else
2737                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-hdb"
2738                 MFLAG=SLAPD_MOD_STATIC
2739         fi
2740         AC_DEFINE_UNQUOTED(SLAPD_HDB,$MFLAG,[define to support HDB backend])
2741 fi
2742
2743 if test "$ol_enable_ldap" != no ; then
2744         BUILD_SLAPD=yes
2745         BUILD_LDAP=$ol_enable_ldap
2746         if test "$ol_enable_ldap" = mod ; then
2747                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2748                 MFLAG=SLAPD_MOD_DYNAMIC
2749         else
2750                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2751                 MFLAG=SLAPD_MOD_STATIC
2752         fi
2753         AC_DEFINE_UNQUOTED(SLAPD_LDAP,$MFLAG,[define to support LDAP backend])
2754 fi
2755
2756 if test "$ol_link_ldbm" != no && test $ol_enable_ldbm != no; then
2757         BUILD_SLAPD=yes
2758         BUILD_LDBM=$ol_enable_ldbm
2759         if test "$ol_enable_ldbm" = mod ; then
2760                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldbm"
2761                 MFLAG=SLAPD_MOD_DYNAMIC
2762         else
2763                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldbm"
2764                 MFLAG=SLAPD_MOD_STATIC
2765         fi
2766         AC_DEFINE_UNQUOTED(SLAPD_LDBM,$MFLAG,[define to support LDBM backend])
2767 fi
2768
2769 if test "$ol_enable_meta" != no ; then
2770         BUILD_SLAPD=yes
2771         BUILD_META=$ol_enable_meta
2772         BUILD_REWRITE=yes
2773         if test "$ol_enable_meta" = mod ; then
2774                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2775                 MFLAG=SLAPD_MOD_DYNAMIC
2776         else
2777                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2778                 MFLAG=SLAPD_MOD_STATIC
2779         fi
2780         AC_DEFINE_UNQUOTED(SLAPD_META,$MFLAG,[define to support LDAP Metadirectory backend])
2781 fi
2782
2783 if test "$ol_enable_monitor" != no ; then
2784         BUILD_SLAPD=yes
2785         BUILD_MONITOR=$ol_enable_monitor
2786         if test "$ol_enable_monitor" = mod ; then
2787                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2788                 MFLAG=SLAPD_MOD_DYNAMIC
2789         else
2790                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2791                 MFLAG=SLAPD_MOD_STATIC
2792         fi
2793         AC_DEFINE_UNQUOTED(SLAPD_MONITOR,$MFLAG,[define to support cn=Monitor backend])
2794 fi
2795
2796 if test "$ol_enable_null" != no ; then
2797         BUILD_SLAPD=yes
2798         BUILD_NULL=$ol_enable_null
2799         if test "$ol_enable_null" = mod ; then
2800                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2801                 MFLAG=SLAPD_MOD_DYNAMIC
2802         else
2803                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2804                 MFLAG=SLAPD_MOD_STATIC
2805         fi
2806         AC_DEFINE_UNQUOTED(SLAPD_NULL,$MFLAG,[define to support NULL backend])
2807 fi
2808
2809 if test "$ol_enable_passwd" != no ; then
2810         BUILD_SLAPD=yes
2811         BUILD_PASSWD=$ol_enable_passwd
2812         if test "$ol_enable_passwd" = mod ; then
2813                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2814                 MFLAG=SLAPD_MOD_DYNAMIC
2815         else
2816                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2817                 MFLAG=SLAPD_MOD_STATIC
2818         fi
2819         AC_DEFINE_UNQUOTED(SLAPD_PASSWD,$MFLAG,[define to support PASSWD backend])
2820 fi
2821
2822 if test "$ol_link_perl" != no ; then
2823         BUILD_SLAPD=yes
2824         BUILD_PERL=$ol_enable_perl
2825         if test "$ol_enable_perl" = mod ; then
2826                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2827                 MFLAG=SLAPD_MOD_DYNAMIC
2828         else
2829                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2830                 MFLAG=SLAPD_MOD_STATIC
2831         fi
2832         AC_DEFINE_UNQUOTED(SLAPD_PERL,$MFLAG,[define to support PERL backend])
2833 fi
2834
2835 if test "$ol_enable_relay" != no ; then
2836         BUILD_SLAPD=yes
2837         BUILD_RELAY=$ol_enable_relay
2838         if test "$ol_enable_relay" = mod ; then
2839                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-relay"
2840                 MFLAG=SLAPD_MOD_DYNAMIC
2841         else
2842                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-relay"
2843                 MFLAG=SLAPD_MOD_STATIC
2844         fi
2845         AC_DEFINE_UNQUOTED(SLAPD_RELAY,$MFLAG,[define to support relay backend])
2846 fi
2847
2848 if test "$ol_enable_shell" != no ; then
2849         if test "$ol_link_threads" != no ; then
2850                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2851         fi
2852         BUILD_SLAPD=yes
2853         BUILD_SHELL=$ol_enable_shell
2854         if test "$ol_enable_shell" = mod ; then
2855                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2856                 MFLAG=SLAPD_MOD_DYNAMIC
2857         else
2858                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2859                 MFLAG=SLAPD_MOD_STATIC
2860         fi
2861         AC_DEFINE_UNQUOTED(SLAPD_SHELL,$MFLAG,[define to support SHELL backend])
2862 fi
2863
2864 if test "$ol_link_sql" != no ; then
2865         BUILD_SLAPD=yes
2866         BUILD_SQL=$ol_enable_sql
2867         if test "$ol_enable_sql" = mod; then
2868                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2869                 MFLAG=SLAPD_MOD_DYNAMIC
2870         else
2871                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2872                 MFLAG=SLAPD_MOD_STATIC
2873         fi
2874         AC_DEFINE_UNQUOTED(SLAPD_SQL,$MFLAG,[define to support SQL backend])
2875 fi
2876
2877 if test "$ol_enable_accesslog" != no ; then
2878         BUILD_ACCESSLOG=$ol_enable_accesslog
2879         if test "$ol_enable_accesslog" = mod ; then
2880                 MFLAG=SLAPD_MOD_DYNAMIC
2881                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS accesslog.la"
2882         else
2883                 MFLAG=SLAPD_MOD_STATIC
2884                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS accesslog.o"
2885         fi
2886         AC_DEFINE_UNQUOTED(SLAPD_OVER_ACCESSLOG,$MFLAG,[define for In-Directory Access Logging overlay])
2887 fi
2888
2889 if test "$ol_enable_denyop" != no ; then
2890         BUILD_DENYOP=$ol_enable_denyop
2891         if test "$ol_enable_denyop" = mod ; then
2892                 MFLAG=SLAPD_MOD_DYNAMIC
2893                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS denyop.la"
2894         else
2895                 MFLAG=SLAPD_MOD_STATIC
2896                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS denyop.o"
2897         fi
2898         AC_DEFINE_UNQUOTED(SLAPD_OVER_DENYOP,$MFLAG,[define for Dynamic Group overlay])
2899 fi
2900
2901 if test "$ol_enable_dyngroup" != no ; then
2902         BUILD_DYNGROUP=$ol_enable_dyngroup
2903         if test "$ol_enable_dyngroup" = mod ; then
2904                 MFLAG=SLAPD_MOD_DYNAMIC
2905                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dyngroup.la"
2906         else
2907                 MFLAG=SLAPD_MOD_STATIC
2908                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dyngroup.o"
2909         fi
2910         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNGROUP,$MFLAG,[define for Dynamic Group overlay])
2911 fi
2912
2913 if test "$ol_enable_dynlist" != no ; then
2914         BUILD_DYNLIST=$ol_enable_dynlist
2915         if test "$ol_enable_dynlist" = mod ; then
2916                 MFLAG=SLAPD_MOD_DYNAMIC
2917                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dynlist.la"
2918         else
2919                 MFLAG=SLAPD_MOD_STATIC
2920                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dynlist.o"
2921         fi
2922         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNLIST,$MFLAG,[define for Dynamic List overlay])
2923 fi
2924
2925 if test "$ol_enable_lastmod" != no ; then
2926         BUILD_LASTMOD=$ol_enable_lastmod
2927         if test "$ol_enable_lastmod" = mod ; then
2928                 MFLAG=SLAPD_MOD_DYNAMIC
2929                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS lastmod.la"
2930         else
2931                 MFLAG=SLAPD_MOD_STATIC
2932                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS lastmod.o"
2933         fi
2934         AC_DEFINE_UNQUOTED(SLAPD_OVER_LASTMOD,$MFLAG,[define for Last Modification overlay])
2935 fi
2936
2937 if test "$ol_enable_ppolicy" != no ; then
2938         BUILD_PPOLICY=$ol_enable_ppolicy
2939         if test "$ol_enable_ppolicy" = mod ; then
2940                 MFLAG=SLAPD_MOD_DYNAMIC
2941                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS ppolicy.la"
2942         else
2943                 MFLAG=SLAPD_MOD_STATIC
2944                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS ppolicy.o"
2945         fi
2946         AC_DEFINE_UNQUOTED(SLAPD_OVER_PPOLICY,$MFLAG,[define for Password Policy overlay])
2947 fi
2948
2949 if test "$ol_enable_proxycache" != no ; then
2950         BUILD_PROXYCACHE=$ol_enable_proxycache
2951         if test "$ol_enable_proxycache" = mod ; then
2952                 MFLAG=SLAPD_MOD_DYNAMIC
2953                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS pcache.la"
2954         else
2955                 MFLAG=SLAPD_MOD_STATIC
2956                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS pcache.o"
2957         fi
2958         AC_DEFINE_UNQUOTED(SLAPD_OVER_PROXYCACHE,$MFLAG,[define for Proxy Cache overlay])
2959 fi
2960
2961 if test "$ol_enable_refint" != no ; then
2962         BUILD_REFINT=$ol_enable_refint
2963         if test "$ol_enable_refint" = mod ; then
2964                 MFLAG=SLAPD_MOD_DYNAMIC
2965                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS refint.la"
2966         else
2967                 MFLAG=SLAPD_MOD_STATIC
2968                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS refint.o"
2969         fi
2970         AC_DEFINE_UNQUOTED(SLAPD_OVER_REFINT,$MFLAG,[define for Referential Integrity overlay])
2971 fi
2972
2973 if test "$ol_enable_retcode" != no ; then
2974         BUILD_RETCODE=$ol_enable_retcode
2975         if test "$ol_enable_retcode" = mod ; then
2976                 MFLAG=SLAPD_MOD_DYNAMIC
2977                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS retcode.la"
2978         else
2979                 MFLAG=SLAPD_MOD_STATIC
2980                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS retcode.o"
2981         fi
2982         AC_DEFINE_UNQUOTED(SLAPD_OVER_RETCODE,$MFLAG,[define for Referential Integrity overlay])
2983 fi
2984
2985 if test "$ol_enable_rwm" != no ; then
2986         BUILD_REWRITE=yes
2987         BUILD_RWM=$ol_enable_rwm
2988         if test "$ol_enable_rwm" = mod ; then
2989                 MFLAG=SLAPD_MOD_DYNAMIC
2990                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS rwm.la"
2991         else
2992                 MFLAG=SLAPD_MOD_STATIC
2993                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS rwm_x.o"
2994         fi
2995         AC_DEFINE_UNQUOTED(SLAPD_OVER_RWM,$MFLAG,[define for Rewrite/Remap overlay])
2996 fi
2997
2998 if test "$ol_enable_syncprov" != no ; then
2999         BUILD_SYNCPROV=$ol_enable_syncprov
3000         if test "$ol_enable_syncprov" = mod ; then
3001                 MFLAG=SLAPD_MOD_DYNAMIC
3002                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS syncprov.la"
3003         else
3004                 MFLAG=SLAPD_MOD_STATIC
3005                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS syncprov.o"
3006         fi
3007         AC_DEFINE_UNQUOTED(SLAPD_OVER_SYNCPROV,$MFLAG,[define for Syncrepl Provider overlay])
3008 fi
3009
3010 if test "$ol_enable_translucent" != no ; then
3011         BUILD_TRANSLUCENT=$ol_enable_translucent
3012         if test "$ol_enable_translucent" = mod ; then
3013                 MFLAG=SLAPD_MOD_DYNAMIC
3014                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS translucent.la"
3015         else
3016                 MFLAG=SLAPD_MOD_STATIC
3017                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS translucent.o"
3018         fi
3019         AC_DEFINE_UNQUOTED(SLAPD_OVER_TRANSLUCENT,$MFLAG,[define for Translucent Proxy overlay])
3020 fi
3021
3022 if test "$ol_enable_unique" != no ; then
3023         BUILD_UNIQUE=$ol_enable_unique
3024         if test "$ol_enable_unique" = mod ; then
3025                 MFLAG=SLAPD_MOD_DYNAMIC
3026                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS unique.la"
3027         else
3028                 MFLAG=SLAPD_MOD_STATIC
3029                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS unique.o"
3030         fi
3031         AC_DEFINE_UNQUOTED(SLAPD_OVER_UNIQUE,$MFLAG,[define for Attribute Uniqueness overlay])
3032 fi
3033
3034 if test "$ol_enable_valsort" != no ; then
3035         BUILD_VALSORT=$ol_enable_valsort
3036         if test "$ol_enable_valsort" = mod ; then
3037                 MFLAG=SLAPD_MOD_DYNAMIC
3038                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS valsort.la"
3039         else
3040                 MFLAG=SLAPD_MOD_STATIC
3041                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS valsort.o"
3042         fi
3043         AC_DEFINE_UNQUOTED(SLAPD_OVER_VALSORT,$MFLAG,[define for Value Sorting overlay])
3044 fi
3045
3046 if test "$ol_enable_slurpd" != no &&
3047    test "$ol_link_threads" != no &&
3048    test $BUILD_SLAPD = yes ; then
3049         BUILD_SLURPD=yes
3050 fi
3051
3052 if test "$ol_enable_rewrite" != no ; then
3053         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
3054         BUILD_REWRITE=yes
3055 fi
3056
3057 if test "$ol_enable_slapi" != no ; then
3058         AC_DEFINE(ENABLE_SLAPI,1,[define to enable slapi library])
3059         BUILD_SLAPI=yes
3060         SLAPD_SLAPI_DEPEND=libslapi.a
3061 fi
3062
3063 dnl ----------------------------------------------------------------
3064
3065 dnl
3066 dnl For Windows build, we don't want to include -dlopen flags.
3067 dnl They hurt more than they help.
3068 dnl
3069
3070 if test "$ac_cv_mingw32" = yes ; then
3071         PLAT=NT
3072         SLAPD_MODULES_LDFLAGS=
3073 else
3074         PLAT=UNIX
3075 fi
3076
3077 AC_SUBST(LIBSRCS)
3078 AC_SUBST(PLAT)
3079 AC_SUBST(WITH_SASL)
3080 AC_SUBST(WITH_TLS)
3081 AC_SUBST(WITH_MODULES_ENABLED)
3082 AC_SUBST(WITH_ACI_ENABLED)
3083 AC_SUBST(BUILD_THREAD)
3084 AC_SUBST(BUILD_LIBS_DYNAMIC)
3085
3086 AC_SUBST(BUILD_SLAPD)
3087 dnl slapi
3088   AC_SUBST(BUILD_SLAPI)
3089   AC_SUBST(SLAPD_SLAPI_DEPEND)
3090 dnl backends
3091   AC_SUBST(BUILD_BDB)
3092   AC_SUBST(BUILD_DNSSRV)
3093   AC_SUBST(BUILD_HDB)
3094   AC_SUBST(BUILD_LDAP)
3095   AC_SUBST(BUILD_LDBM)
3096   AC_SUBST(BUILD_META)
3097   AC_SUBST(BUILD_MONITOR)
3098   AC_SUBST(BUILD_NULL)
3099   AC_SUBST(BUILD_PASSWD)
3100   AC_SUBST(BUILD_RELAY)
3101   AC_SUBST(BUILD_PERL)
3102   AC_SUBST(BUILD_SHELL)
3103   AC_SUBST(BUILD_SQL)
3104 dnl overlays
3105   AC_SUBST(BUILD_ACCESSLOG)
3106   AC_SUBST(BUILD_DENYOP)
3107   AC_SUBST(BUILD_DYNGROUP)
3108   AC_SUBST(BUILD_DYNLIST)
3109   AC_SUBST(BUILD_LASTMOD)
3110   AC_SUBST(BUILD_PPOLICY)
3111   AC_SUBST(BUILD_PROXYCACHE)
3112   AC_SUBST(BUILD_REFINT)
3113   AC_SUBST(BUILD_RETCODE)
3114   AC_SUBST(BUILD_RWM)
3115   AC_SUBST(BUILD_SYNCPROV)
3116   AC_SUBST(BUILD_TRANSLUCENT)
3117   AC_SUBST(BUILD_UNIQUE)
3118   AC_SUBST(BUILD_VALSORT)
3119 AC_SUBST(BUILD_SLURPD)
3120
3121 AC_SUBST(LDAP_LIBS)
3122 AC_SUBST(SLAPD_LIBS)
3123 AC_SUBST(SLURPD_LIBS)
3124 AC_SUBST(LDBM_LIBS)
3125 AC_SUBST(LTHREAD_LIBS)
3126 AC_SUBST(LUTIL_LIBS)
3127 AC_SUBST(WRAP_LIBS)
3128
3129 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
3130 AC_SUBST(SLAPD_MODULES_LDFLAGS)
3131
3132 AC_SUBST(SLAPD_NO_STATIC)
3133 AC_SUBST(SLAPD_STATIC_BACKENDS)
3134 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
3135 AC_SUBST(SLAPD_STATIC_OVERLAYS)
3136 AC_SUBST(SLAPD_DYNAMIC_OVERLAYS)
3137
3138 AC_SUBST(PERL_CPPFLAGS)
3139 AC_SUBST(SLAPD_PERL_LDFLAGS)
3140 AC_SUBST(MOD_PERL_LDFLAGS)
3141
3142 AC_SUBST(KRB4_LIBS)
3143 AC_SUBST(KRB5_LIBS)
3144 AC_SUBST(SASL_LIBS)
3145 AC_SUBST(TLS_LIBS)
3146 AC_SUBST(MODULES_LIBS)
3147 AC_SUBST(SLAPI_LIBS)
3148 AC_SUBST(LIBSLAPI)
3149 AC_SUBST(LIBSLAPITOOLS)
3150 AC_SUBST(AUTH_LIBS)
3151 AC_SUBST(ICU_LIBS)
3152
3153 AC_SUBST(SLAPD_SLP_LIBS)
3154 AC_SUBST(SLAPD_GMP_LIBS)
3155
3156 AC_SUBST(SLAPD_SQL_LDFLAGS)
3157 AC_SUBST(SLAPD_SQL_LIBS)
3158 AC_SUBST(SLAPD_SQL_INCLUDES)
3159
3160 dnl ----------------------------------------------------------------
3161 dnl final help output
3162 AC_ARG_WITH(xxinstall,[
3163 See INSTALL file for further details.])
3164
3165 dnl ----------------------------------------------------------------
3166 dnl final output
3167 dnl
3168
3169 AC_CONFIG_FILES([Makefile:build/top.mk:Makefile.in:build/dir.mk]
3170 [doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk]
3171 [doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk]
3172 [doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk]
3173 [doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk]
3174 [doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk]
3175 [doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk]
3176 [clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk]
3177 [clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk]
3178 [include/Makefile:build/top.mk:include/Makefile.in]
3179 [libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk]
3180 [libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk]
3181 [libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk]
3182 [libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk]
3183 [libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk]
3184 [libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk]
3185 [libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-static.mk]
3186 [servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk]
3187 [servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk]
3188 [servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk]
3189 [servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk]
3190 [servers/slapd/back-hdb/Makefile:build/top.mk:servers/slapd/back-hdb/Makefile.in:build/mod.mk]
3191 [servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk]
3192 [servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk]
3193 [servers/slapd/back-ldif/Makefile:build/top.mk:servers/slapd/back-ldif/Makefile.in:build/mod.mk]
3194 [servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk]
3195 [servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk]
3196 [servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk]
3197 [servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk]
3198 [servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk]
3199 [servers/slapd/back-relay/Makefile:build/top.mk:servers/slapd/back-relay/Makefile.in:build/mod.mk]
3200 [servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk]
3201 [servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk]
3202 [servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk]
3203 [servers/slapd/slapi/Makefile:build/top.mk:servers/slapd/slapi/Makefile.in:build/lib.mk:build/lib-shared.mk]
3204 [servers/slapd/overlays/Makefile:build/top.mk:servers/slapd/overlays/Makefile.in:build/lib.mk]
3205 [servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk]
3206 [tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk]
3207 [tests/run]
3208 [tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk])
3209
3210 AC_CONFIG_COMMANDS([default],[[
3211 chmod +x tests/run
3212 date > stamp-h
3213 BACKENDSC="servers/slapd/backends.c"
3214 echo "Making $BACKENDSC"
3215 rm -f $BACKENDSC
3216 cat > $BACKENDSC << ENDX
3217 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3218  *
3219  * Copyright 1998-2006 The OpenLDAP Foundation.
3220  * All rights reserved.
3221  *
3222  * Redistribution and use in source and binary forms, with or without
3223  * modification, are permitted only as authorized by the OpenLDAP
3224  * Public License.
3225  *
3226  * A copy of this license is available in the file LICENSE in the
3227  * top-level directory of the distribution or, alternatively, at
3228  * <http://www.OpenLDAP.org/license.html>.
3229  */
3230 /* This file is automatically generated by configure; please do not edit. */
3231
3232 #include "portable.h"
3233 #include "slap.h"
3234
3235 ENDX
3236 if test "${STATIC_BACKENDS}"; then
3237         for b in config ${STATIC_BACKENDS}; do
3238                 bb=`echo "${b}" | sed -e 's/back-//'`
3239                 cat >> $BACKENDSC << ENDX
3240 extern BI_init ${bb}_back_initialize;
3241 ENDX
3242         done
3243
3244         cat >> $BACKENDSC << ENDX
3245
3246 BackendInfo slap_binfo[] = {
3247 ENDX
3248
3249         for b in config ${STATIC_BACKENDS}; do
3250                 bb=`echo "${b}" | sed -e 's/back-//'`
3251                 echo "    Add ${bb} ..."
3252                 cat >> $BACKENDSC << ENDX
3253         { "${bb}", ${bb}_back_initialize },
3254 ENDX
3255         done
3256
3257         cat >> $BACKENDSC << ENDX
3258         { NULL, NULL },
3259 };
3260
3261 /* end of generated file */
3262 ENDX
3263 fi
3264 OVERLAYSC="servers/slapd/overlays/statover.c"
3265 echo "Making $OVERLAYSC"
3266 rm -f $OVERLAYSC
3267 cat > $OVERLAYSC << ENDX
3268 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3269  *
3270  * Copyright 1998-2006 The OpenLDAP Foundation.
3271  * All rights reserved.
3272  *
3273  * Redistribution and use in source and binary forms, with or without
3274  * modification, are permitted only as authorized by the OpenLDAP
3275  * Public License.
3276  *
3277  * A copy of this license is available in the file LICENSE in the
3278  * top-level directory of the distribution or, alternatively, at
3279  * <http://www.OpenLDAP.org/license.html>.
3280  */
3281 /* This file is automatically generated by configure; please do not edit. */
3282
3283 #include "portable.h"
3284 #include "slap.h"
3285
3286 ENDX
3287 if test "${STATIC_OVERLAYS}"; then
3288         for o in ${STATIC_OVERLAYS}; do
3289                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3290                 cat >> $OVERLAYSC << ENDX
3291 extern OV_init ${oo}_initialize;
3292 ENDX
3293         done
3294 fi
3295
3296 cat >> $OVERLAYSC << ENDX
3297
3298 OverlayInit slap_oinfo[] = {
3299 ENDX
3300
3301 if test "${STATIC_OVERLAYS}"; then
3302         for o in ${STATIC_OVERLAYS}; do
3303                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3304                 echo "    Add ${oo} ..."
3305                 cat >> $OVERLAYSC << ENDX
3306         { "${oo}", ${oo}_initialize },
3307 ENDX
3308         done
3309 fi
3310
3311         cat >> $OVERLAYSC << ENDX
3312         { NULL, NULL },
3313 };
3314
3315 /* end of generated file */
3316 ENDX
3317
3318 echo Please run \"make depend\" to build dependencies
3319 ]],[[
3320 STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS"
3321 STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS"
3322 ]])
3323 AC_OUTPUT