git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(build/version)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17
  18 OL_VERSION=`cat $ac_aux_dir/version`
  19 if test -z "$OL_VERSION"; then
  20         AC_MSG_ERROR([could not determine version])
  21 fi
  22
  23 dnl ----------------------------------------------------------------
  24 dnl Determine host platform
  25 dnl             we try not to use this for much
  26 AC_CANONICAL_SYSTEM
  27
  28 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  29 AC_SUBST(PACKAGE)
  30 AC_SUBST(VERSION)
  31 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  32 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  33
  34 dnl We use autoconf features new to 2.13.
  35 dnl aclocal.m4 should be built using aclocal from automake 1.4
  36 dnl libtool 1.3.3 should be installed.
  37 AC_PREREQ(2.13)dnl Required Autoconf version
  38
  39 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  40
  41 dnl ----------------------------------------------------------------
  42 dnl Start Args
  43 AC_MSG_CHECKING(configure arguments)
  44 AC_PREFIX_DEFAULT(/usr/local)
  45
  46 top_builddir=`pwd`
  47 AC_SUBST(top_builddir)dnl
  48
  49 ldap_subdir="openldap"
  50
  51 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  52         if test "$withval" = "no"; then
  53                 ldap_subdir=""
  54         elif test "$withval" != "yes"; then
  55                 ldap_subdir="$withval"
  56         fi
  57 ])dnl
  58
  59 AC_SUBST(ldap_subdir)dnl
  60
  61 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  62 dnl ol_enable_syslog=no
  63 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  64 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  65 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  66 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  67 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  68 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  69 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  70         no, [yes no])dnl
  71
  72 dnl General "with" options
  73 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  74
  75 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  76         auto, [auto k5 k4 afs yes no])
  77 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  78         auto, [auto yes no] )
  79 OL_ARG_WITH(threads,[  --with-threads   use threads],
  80         auto, [auto posix mach lwp yes no manual] )
  81 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  82         auto, [auto ssleay openssl yes no] )
  83 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  84         auto, [auto yes no manual] )
  85
  86 dnl Server options
  87
  88 dnl LDAPD OPTIONS
  89 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  90 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  91
  92 dnl SLAPD OPTIONS
  93 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  94 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  95 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  96 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  97 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
  98 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  99 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 100 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 101
 102 dnl SLAPD Backend options
 103 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 104 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 105         [static dynamic])
 106 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 107 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 108         [static dynamic])
 109 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 110 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 111         [static dynamic])
 112 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 113         [auto db2 db mdbm gdbm ndbm manual])
 114 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 115         [auto btree hash])
 116
 117 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 118 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 119         [static dynamic])
 120 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 121 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 122         [static dynamic])
 123 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 124 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 125         [static dynamic])
 126 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 127 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 128         [static dynamic])
 129
 130 dnl SLURPD OPTIONS
 131 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 132 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 133
 134 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 135 AC_ENABLE_STATIC
 136 dnl AC_DISABLE_SHARED
 137 AC_ENABLE_SHARED
 138
 139 dnl General "enable" options
 140 # validate options
 141 if test $ol_enable_dns = yes ; then
 142         if test $ol_enable_referrals = no ; then
 143                 AC_MSG_ERROR([DNS requires --enable-referrals])
 144         fi
 145         if test $ol_enable_referrals = auto ; then
 146                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 147                 ol_enable_referrals=yes
 148         fi
 149 fi
 150
 151 if test $ol_enable_slapd = no ; then
 152         dnl SLAPD was specificallly disabled
 153         if test $ol_enable_bdb2 = yes ; then
 154                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 155         fi
 156         if test $ol_enable_ldap = yes ; then
 157                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 158         fi
 159         if test $ol_enable_ldbm = yes ; then
 160                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 161         fi
 162         if test $ol_enable_passwd = yes ; then
 163                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 164         fi
 165         if test $ol_enable_perl = yes ; then
 166                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 167         fi
 168         if test $ol_enable_shell = yes ; then
 169                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 170         fi
 171         if test $ol_enable_tcl = yes ; then
 172                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 173         fi
 174         if test $ol_enable_modules = yes ; then
 175                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 176         fi
 177         if test $ol_enable_wrappers = yes ; then
 178                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 179         fi
 180         if test $ol_enable_phonetic = yes ; then
 181                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 182         fi
 183         if test $ol_enable_rlookups = yes ; then
 184                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 185         fi
 186         if test $ol_with_ldbm_api != auto ; then
 187                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 188         fi
 189         if test $ol_with_ldbm_type != auto ; then
 190                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 191         fi
 192         if test $ol_with_bdb2_module != static ; then
 193                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 194         fi
 195         if test $ol_with_ldap_module != static ; then
 196                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 197         fi
 198         if test $ol_with_ldbm_module != static ; then
 199                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 200         fi
 201         if test $ol_with_passwd_module != static ; then
 202                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 203         fi
 204         if test $ol_with_perl_module != static ; then
 205                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 206         fi
 207         if test $ol_with_shell_module != static ; then
 208                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 209         fi
 210         if test $ol_with_tcl_module != static ; then
 211                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 212         fi
 213         if test $ol_enable_slurpd = yes ; then
 214                 AC_MSG_ERROR([slurpd requires slapd])
 215         fi
 216
 217         # force settings to no
 218         ol_enable_bdb2=no
 219         ol_enable_ldap=no
 220         ol_enable_ldbm=no
 221         ol_enable_passwd=no
 222         ol_enable_perl=no
 223         ol_enable_shell=no
 224         ol_enable_tcl=no
 225
 226         ol_enable_modules=no
 227         ol_enable_phonetic=no
 228         ol_enable_rlookups=no
 229         ol_enable_wrappers=no
 230
 231         ol_with_ldbm_api=no
 232         ol_with_ldbm_type=no
 233
 234         ol_with_bdb2_module=static
 235         ol_with_ldap_module=static
 236         ol_with_ldbm_module=static
 237         ol_with_passwd_module=static
 238         ol_with_perl_module=static
 239         ol_with_shell_module=static
 240         ol_with_tcl_module=static
 241
 242         ol_enable_slurpd=no
 243
 244 elif test $ol_enable_ldbm = no ; then
 245         dnl SLAPD without LDBM
 246
 247         if test $ol_with_ldbm_api != auto ; then
 248                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 249         fi
 250
 251         if test $ol_with_ldbm_type != auto ; then
 252                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 253         fi
 254
 255         if test $ol_with_ldbm_module != static ; then
 256                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 257         fi
 258
 259         if test $ol_enable_bdb2 = yes ; then
 260                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 261         fi
 262
 263         if test $ol_enable_modules != yes -a \
 264                 $ol_enable_ldap = no -a \
 265                 $ol_enable_passwd = no -a \
 266                 $ol_enable_perl = no -a \
 267                 $ol_enable_shell = no -a \
 268                 $ol_enable_tcl = no ; then
 269                 AC_MSG_ERROR([slapd requires a backend])
 270         fi
 271
 272         ol_with_ldbm_api=no
 273         ol_with_ldbm_type=no
 274         ol_with_ldbm_module=static
 275
 276 elif test $ol_enable_bdb2 = yes ; then
 277         dnl SLAPD with BDB2
 278
 279         if test $ol_with_ldbm_api != auto -a \
 280                 $ol_with_ldbm_api != db2 ; then
 281                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 282         fi
 283
 284         ol_with_ldbm_api=db2
 285
 286 else
 287         dnl SLAPD with LDBM
 288
 289         if test $ol_enable_bdb2 != no ; then
 290                 if test $ol_with_ldbm_api != auto -a \
 291                         $ol_with_ldbm_api != db2 ; then
 292                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 293                         ol_enable_bdb2=no
 294                 fi
 295         fi
 296
 297         if test $ol_with_ldbm_api = gdbm -a \
 298                 $ol_with_ldbm_type = btree ; then
 299                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 300         fi
 301         if test $ol_with_ldbm_api = mdbm -a \
 302                 $ol_with_ldbm_type = btree ; then
 303                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 304         fi
 305         if test $ol_with_ldbm_api = ndbm -a \
 306                 $ol_with_ldbm_type = btree ; then
 307                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 308         fi
 309 fi
 310
 311 if test $ol_enable_slurpd = yes ; then
 312         dnl SLURPD was specifically enabled
 313         if test $ol_with_threads = no ; then
 314                 AC_MSG_ERROR([slurpd requires threads])
 315         fi
 316 fi
 317
 318 AC_MSG_RESULT(done)
 319
 320 ## Initialize vars
 321 LDAP_LIBS=
 322 LDBM_LIBS=
 323 LTHREAD_LIBS=
 324 LUTIL_LIBS=
 325
 326 LDAPD_LIBS=
 327 SLAPD_LIBS=
 328 SLURPD_LIBS=
 329
 330 BUILD_LDAPD=no
 331 BUILD_SLAPD=no
 332 BUILD_SLURPD=no
 333
 334 BUILD_BDB2=no
 335 BUILD_LDAP=no
 336 BUILD_LDBM=no
 337 BUILD_PASSWD=no
 338 BUILD_PERL=no
 339 BUILD_SHELL=no
 340 BUILD_TCL=no
 341 BUILD_THREAD=no
 342
 343 BUILD_BDB2_DYNAMIC=no
 344 BUILD_LDAP_DYNAMIC=no
 345 BUILD_LDBM_DYNAMIC=no
 346 BUILD_PASSWD_DYNAMIC=no
 347 BUILD_PERL_DYNAMIC=no
 348 BUILD_SHELL_DYNAMIC=no
 349 BUILD_TCL_DYNAMIC=no
 350
 351 SLAPD_MODULES_LDFLAGS=
 352 SLAPD_MODULES_CPPFLAGS=
 353
 354 SLAPD_PERL_LDFLAGS=
 355 SLAPD_PERL_CPPFLAGS=
 356
 357 KRB_LIBS=
 358 READLINE_LIBS=
 359 TERMCAP_LIBS=
 360 TLS_LIBS=
 361
 362 dnl ----------------------------------------------------------------
 363 dnl Checks for programs
 364
 365 dnl AC_PROG_INSTALL
 366
 367 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 368
 369
 370 dnl
 371 dnl Determine which C translator to use
 372 dnl
 373
 374 dnl AIX Thread requires we use cc_r or xlc_r.
 375 dnl But only do this IF AIX and CC is not set
 376 dnl and threads are auto|yes|posix.
 377 dnl
 378 dnl If we find cc_r|xlc_r, force pthreads and assume
 379 dnl             pthread_create is in $LIBS (ie: don't bring in
 380 dnl             any additional thread libraries)
 381 dnl If we do not find cc_r|xlc_r, disable threads
 382
 383 ol_aix_threads=no
 384 case "$target" in
 385 *-*-aix*) dnl all AIX is not a good idea.
 386         if test -z "$CC" ; then
 387                 case "$ol_with_threads" in
 388                 auto | yes |  posix) ol_aix_threads=yes ;;
 389                 esac
 390         fi
 391 ;;
 392 esac
 393
 394 if test $ol_aix_threads = yes ; then
 395         if test -z "${CC}" ; then
 396                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 397
 398                 if test "$CC" = cc ; then
 399                         dnl no CC! don't allow --with-threads
 400                         if test $ol_with_threads != auto ; then
 401                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 402                         else
 403                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 404                         fi
 405                         ol_with_threads=no
 406                 fi
 407         fi
 408
 409         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 410                 ol_with_threads=posix
 411                 ol_cv_pthread_create=yes
 412         fi
 413 fi
 414
 415 if test -z "${CC}"; then
 416         AC_CHECK_PROGS(CC,cc)
 417 fi
 418
 419 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 420 dnl (for now, let autoconf sort this out)
 421 dnl CFLAGS=${CFLAGS-""}
 422
 423 AC_PROG_LIBTOOL
 424 dnl AC_PROG_MAKE_SET
 425
 426 AC_PROG_AWK
 427 OL_PROG_LN_H
 428 AC_PROG_LN_S
 429
 430 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 431         LN_S="$LN_H"
 432 fi
 433
 434 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 435         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 436 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 437 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 438
 439 ol_link_perl=no
 440 if test $ol_enable_perl != no ; then
 441         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 442
 443         if test "no$PERLBIN" = "no" ; then
 444                 if test $ol_enable_perl = yes ; then
 445                         AC_MSG_ERROR([could not locate perl])
 446                 fi
 447
 448         else
 449                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 450                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 451
 452                 dnl should check perl version
 453                 ol_link_perl=yes
 454         fi
 455 fi
 456
 457 AC_PROG_CPP
 458
 459 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 460         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 461
 462 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 463         AC_MSG_WARN([programs compiled here do run here...])
 464         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 465
 466 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 467         AC_MSG_WARN([programs compiled here do not run here...])
 468         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 469 fi
 470
 471 dnl Checks for UNIX Variants
 472 AC_AIX
 473 AC_ISC_POSIX
 474 AC_MINIX
 475
 476 dnl Checks for system services
 477 AC_CYGWIN
 478 AC_MINGW32
 479 AC_EXEEXT
 480 AC_OBJEXT
 481
 482 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 483
 484 dnl BeOS requires -lbe -lroot -lnet
 485 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 486
 487 dnl OpenLDAP requires STDC features
 488 AM_PROG_CC_STDC
 489 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 490         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 491 fi
 492
 493 dnl Check cc depend flags
 494 OL_MKDEPEND
 495 if test "${ol_cv_mkdep}" = no ; then
 496         # this will soon become an error
 497         AC_MSG_WARN([do not know how to generate dependencies])
 498 fi
 499
 500 dnl
 501 dnl Check for module support
 502 dnl
 503 ol_link_modules=no
 504 if test $ol_enable_modules != no ; then
 505         AC_PATH_PROG(GLIBCONFIG, glib-config)
 506
 507         if test "no$GLIBCONFIG" = "no" ; then
 508                 if test $ol_enable_modules = yes ; then
 509                         AC_MSG_ERROR([could not locate glib-config])
 510                 fi
 511
 512         else
 513                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 514                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 515                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 516
 517                 dnl should check glib version
 518                 ol_link_modules=yes
 519         fi
 520 else
 521         ol_with_bdb2_module=static
 522         ol_with_ldap_module=static
 523         ol_with_ldbm_module=static
 524         ol_with_passwd_module=static
 525         ol_with_perl_module=static
 526         ol_with_shell_module=static
 527         ol_with_tcl_module=static
 528 fi
 529
 530 dnl ----------------------------------------------------------------
 531 dnl Checks for header files.
 532 OL_HEADER_STDC
 533
 534 if test $ol_cv_header_stdc != yes; then
 535         AC_MSG_WARN([could not locate Standard C compliant headers])
 536 fi
 537
 538 AC_HEADER_DIRENT
 539 AC_HEADER_SYS_WAIT
 540 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 541 if test $am_cv_sys_posix_termios = yes ; then
 542         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 543                 [define if you have POSIX termios])
 544 fi
 545
 546 AC_CHECK_HEADERS(       \
 547         arpa/inet.h             \
 548         arpa/nameser.h  \
 549         assert.h                \
 550         crypt.h                 \
 551         errno.h                 \
 552         fcntl.h                 \
 553         filio.h                 \
 554         getopt.h                \
 555         grp.h                   \
 556         libutil.h               \
 557         limits.h                \
 558         locale.h                \
 559         netinet/tcp.h   \
 560         malloc.h                \
 561         memory.h                \
 562         psap.h                  \
 563         pwd.h                   \
 564         resolv.h                \
 565         sgtty.h                 \
 566         shadow.h                \
 567         stdarg.h                \
 568         stddef.h                \
 569         string.h                \
 570         strings.h               \
 571         sysexits.h              \
 572         sys/file.h              \
 573         sys/filio.h             \
 574         sys/errno.h             \
 575         sys/ioctl.h             \
 576         sys/param.h             \
 577         sys/resource.h  \
 578         sys/select.h    \
 579         sys/socket.h    \
 580         sys/syslog.h    \
 581         sys/time.h              \
 582         sys/types.h             \
 583         syslog.h                \
 584         termios.h               \
 585         unistd.h                \
 586 )
 587
 588 dnl ----------------------------------------------------------------
 589 dnl Checks for libraries
 590
 591 dnl Find socket()
 592 dnl Likely combinations:
 593 dnl             -lsocket [ -lnsl_s | -lnsl ]
 594 dnl             -linet
 595
 596 AC_CHECK_FUNC(socket, :, [
 597 dnl
 598 dnl hopefully we won't include too many libraries
 599 dnl
 600         AC_CHECK_LIB(socket, main)
 601         AC_CHECK_LIB(net, main)
 602         AC_CHECK_LIB(net, socket)
 603         AC_CHECK_LIB(nsl_s, main)
 604         AC_CHECK_LIB(nsl, main)
 605         AC_CHECK_LIB(inet, socket)
 606         AC_CHECK_LIB(gen, main)
 607 ])
 608
 609 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 610
 611 dnl Select arg types
 612 dnl (if this detection becomes permenent, it and the select() detection
 613 dnl should be done before the yielding select test)
 614 AC_FUNC_SELECT_ARGTYPES
 615
 616
 617 AC_CHECK_HEADERS( regex.h )
 618 if test "$ac_cv_header_regex_h" != yes ; then
 619         AC_MSG_ERROR([POSIX regex.h required.])
 620 fi
 621 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 622
 623 OL_POSIX_REGEX
 624 if test "$ol_cv_c_posix_regex" = no ; then
 625         AC_MSG_ERROR([broken POSIX regex!])
 626 fi
 627
 628
 629 dnl HP-UX requires -lV3
 630 AC_CHECK_LIB(V3, sigset)
 631
 632
 633 # find res_search
 634 if test $ol_enable_dns != no ; then
 635         dnl Check for resolver routines
 636         AC_CHECK_FUNC(res_search,:)
 637         if test $ac_cv_func_res_search = no ; then
 638                 AC_CHECK_LIB(bind, res_search)
 639                 ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 640         fi
 641         if test $ac_cv_func_res_search = no ; then
 642                 AC_CHECK_LIB(resolv, res_search)
 643                 ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 644         fi
 645
 646         if test "$ac_cv_func_res_search" = yes ; then
 647                 AC_DEFINE(HAVE_RES_SEARCH,1,
 648                         [define if you have res_search()])
 649         elif test $ol_enable_dns = yes ; then
 650                 AC_MSG_ERROR([--enable-dns requires res_search])
 651         else
 652                 AC_MSG_WARN([no res_search, disabling DNS support])
 653         fi
 654 fi
 655
 656
 657 # ISODE tests
 658 ol_link_isode=no
 659 if test $ol_enable_ldapd != no ; then
 660         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 661
 662         dnl look for ISODE libraries
 663         AC_CHECK_LIB(xtpp, main, [
 664                 ol_link_isode=yes
 665                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 666                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 667                 ],:,[-lxtdsap -lxtisode -losi])
 668         AC_CHECK_LIB(dsap, main, [
 669                 ol_link_isode=yes
 670                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 671                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 672                 ],:,[-lisode])
 673         AC_CHECK_LIB(isode, main, [
 674                 ol_link_isode=yes
 675                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 676                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 677                 ],:)
 678 fi
 679
 680 if test $ol_link_isode != no; then
 681         AC_CHECK_LIB(pp, main, [
 682                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 683                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 684                 ],:)
 685
 686         AC_PATH_PROG(PEPSY, pepsy)
 687 fi
 688
 689 dnl
 690 dnl check for kerberos
 691 dnl
 692 ol_link_kerberos=no
 693
 694 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 695         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 696
 697         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 698                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 699                         [-lkrb5 -ldes425])
 700
 701                 if test $have_k5 = yes ; then
 702                         ol_with_kerberos=found
 703                         ol_link_kerberos=yes
 704
 705                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 706
 707                         LIBS="$KRB_LIBS $LIBS"
 708
 709                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 710                                 [ol_cv_var_des_debug], [
 711                                 dnl save the flags
 712                                 save_LIBS="$LIBS"
 713                                 LIBS="$KRB_LIBS $LIBS"
 714                                 AC_TRY_LINK([
 715 #include <kerberosIV/krb.h>
 716 #include <kerberosIV/des.h>
 717 extern int des_debug;
 718 ],[
 719 des_debug = 1;
 720 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 721                                 dnl restore the LIBS
 722                                 LIBS="$save_LIBS"
 723                         ])
 724
 725                         if test $ol_cv_var_des_debug = yes ; then
 726                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 727                                         [define if you have Kerberos des_debug])
 728                         fi
 729
 730                         LIBS="$save_LIBS"
 731                 fi
 732         fi
 733 fi
 734
 735 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 736         AC_CHECK_HEADERS(krb.h des.h)
 737
 738         if test $ac_cv_header_krb_h = yes ; then
 739                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 740
 741                 if test $have_k4 = yes ; then
 742                         ol_with_kerberos=found
 743                         ol_link_kerberos=yes
 744
 745                         KRB_LIBS="-lkrb -ldes"
 746                 fi
 747         fi
 748 fi
 749
 750 if test $ol_link_kerberos = yes ; then
 751         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 752 fi
 753
 754 dnl
 755 dnl Check for SSL/TLS
 756 dnl
 757 ol_link_tls=no
 758 if test $ol_with_tls != no ; then
 759
 760         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 761
 762         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 763                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 764                         [have_ssleay=yes
 765                         need_rsaref=no],
 766                         [have_ssleay=no],
 767                         [-lcrypto])
 768
 769                 if test $have_ssleay = no ; then
 770                         AC_CHECK_LIB(ssl, SSL_library_init,
 771                                 [have_ssleay=yes
 772                                 need_rsaref=no], [have_ssleay=no],
 773                                 [-lcrypto])
 774                 fi
 775
 776                 if test $have_ssleay = no ; then
 777                         AC_CHECK_LIB(ssl, ssl3_accept,
 778                                 [have_ssleay=yes
 779                                 need_rsaref=yes], [have_ssleay=no],
 780                                 [-lcrypto -lRSAglue -lrsaref])
 781                 fi
 782
 783                 if test $have_ssleay = yes ; then
 784                         ol_with_tls=found
 785                         ol_link_tls=yes
 786
 787                         AC_DEFINE(HAVE_SSLEAY, 1,
 788                                 [define if you have SSLeay or OpenSSL])
 789
 790                         if test $need_rsaref = yes; then
 791                                 AC_DEFINE(HAVE_RSAREF, 1,
 792                                         [define if you have RSAref])
 793
 794                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 795                         else
 796                                 TLS_LIBS="-lssl -lcrypto"
 797                         fi
 798                 fi
 799         fi
 800 fi
 801
 802 if test $ol_link_tls = yes ; then
 803         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 804 fi
 805
 806 dnl Tests for reentrant functions necessary to build a
 807 dnl thread_safe -lldap.
 808 AC_CHECK_FUNCS(         \
 809         ctime_r                 \
 810         gethostbyname_r gethostbyaddr_r \
 811 )
 812
 813 if test "$ac_cv_func_ctime_r" = no ; then
 814         ol_cv_func_ctime_r_nargs=0
 815 else
 816         OL_FUNC_CTIME_R_NARGS
 817 dnl     OL_FUNC_CTIME_R_TYPE
 818 fi
 819
 820 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 821         OL_FUNC_GETHOSTBYNAME_R_NARGS
 822 else
 823         ol_cv_func_gethostbyname_r_nargs=0
 824 fi
 825
 826 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 827         OL_FUNC_GETHOSTBYADDR_R_NARGS
 828 else
 829         ol_cv_func_gethostbyaddr_r_nargs=0
 830 fi
 831
 832 if test "$ac_cv_func_ctime_r" = yes \
 833         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 834         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 835         -a "$ac_cv_func_gethostbyname_r" = yes \
 836         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 837         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 838         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 839         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 840         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 841         ; then
 842
 843         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 844 fi
 845
 846 ol_link_threads=no
 847 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 848         -o $ol_with_threads = posix ; then
 849
 850         AC_CHECK_HEADERS(pthread.h sched.h)
 851
 852         if test $ac_cv_header_pthread_h = yes ; then
 853                 OL_POSIX_THREAD_VERSION
 854
 855                 if test $ol_cv_pthread_version = final ; then
 856                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 857                                 [define if pthreads API compatible with final spec])
 858                 elif test $ol_cv_pthread_version = draft4 ; then
 859                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 860                                 [define if pthreads API compatible with draft4 spec])
 861                 else
 862                         AC_MSG_ERROR([unknown pthread version])
 863                 fi
 864
 865                 # consider threads found
 866                 ol_with_threads=found
 867
 868                 OL_HEADER_LINUX_THREADS
 869
 870                 dnl Now the hard part, how to link?
 871                 dnl
 872                 dnl currently supported checks:
 873                 dnl
 874                 dnl Check for no flags
 875                 dnl     pthread_create() in $LIBS
 876                 dnl
 877                 dnl Check special pthread (final) flags
 878                 dnl     pthread_create() with -mt (Solaris)
 879                 dnl     pthread_create() with -kthread (FreeBSD)
 880                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 881                 dnl     pthread_create() with -pthreads (?)
 882                 dnl     pthread_create() with -mthreads (AIX)
 883                 dnl     pthread_create() with -thread (?)
 884                 dnl
 885                 dnl Check pthread (final) libraries
 886                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 887                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 888                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 889                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 890                 dnl     pthread_create() in -lpthread (many)
 891                 dnl     pthread_create() in -lc_r (FreeBSD)
 892                 dnl
 893                 dnl Check pthread (draft4) flags (depreciated)
 894                 dnl     pthread_create() with -threads (OSF/1)
 895                 dnl
 896                 dnl Check pthread (draft4) libraries (depreciated)
 897                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 898                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 899                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 900                 dnl     pthread_create() in -lpthreads (many)
 901                 dnl
 902
 903                 dnl pthread_create in $LIBS
 904                 AC_CACHE_CHECK([for pthread_create in default libraries],
 905                         ol_cv_pthread_create,[
 906                 AC_TRY_RUN([
 907 #include <pthread.h>
 908 #ifndef NULL
 909 #define NULL (void*)0
 910 #endif
 911
 912 static void *task(p)
 913         void *p;
 914 {
 915         return (void *) (p == NULL);
 916 }
 917
 918 int main(argc, argv)
 919         int argc;
 920         char **argv;
 921 {
 922         pthread_t t;
 923         int status;
 924
 925         /* make sure pthread_create() isn't just a stub */
 926 #if HAVE_PTHREADS_D4
 927         status = pthread_create(&t, pthread_attr_default, task, NULL);
 928 #else
 929         status = pthread_create(&t, NULL, task, NULL);
 930 #endif
 931
 932         if( status ) return status;
 933
 934         /* make sure pthread_detach() isn't just a stub */
 935 #if HAVE_PTHREADS_D4
 936         status = pthread_detach( &t );
 937 #else
 938         status = pthread_detach( t );
 939 #endif
 940
 941         return status;
 942 }
 943 ],
 944                         [ol_cv_pthread_create=yes],
 945                         [ol_cv_pthread_create=no],
 946                         [dnl assume yes
 947                         ol_cv_pthread_create=yes])])
 948
 949                 if test $ol_cv_pthread_create != no ; then
 950                         ol_link_threads=posix
 951                         ol_link_pthreads=""
 952                 fi
 953
 954                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 955                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 956                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 957                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 958                 OL_PTHREAD_TRY_LINK([-mthreads],[ol_cv_pthread_mthreads])
 959                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 960
 961                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 962                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 963                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 964                         [ol_cv_pthread_lpthread_lmach_lexc])
 965 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 966 dnl                     [ol_cv_pthread_lpthread_lexc])
 967
 968                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 969                         [ol_cv_pthread_lib_lpthread_woff])
 970
 971                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 972                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 973
 974                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 975
 976                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 977                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 978                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 979                         [ol_cv_pthread_lpthreads_lmach_lexc])
 980                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 981                         [ol_cv_pthread_lpthreads_lexc])
 982
 983                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 984
 985                 if test $ol_link_threads != no ; then
 986                         AC_DEFINE(HAVE_PTHREADS,1,
 987                                 [define if you have POSIX Threads])
 988
 989                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 990
 991                         dnl save flags
 992                         save_CPPFLAGS="$CPPFLAGS"
 993                         save_LIBS="$LIBS"
 994                         LIBS="$LTHREAD_LIBS $LIBS"
 995
 996                         dnl All POSIX Thread (final) implementations should have
 997                         dnl sched_yield instead of pthread yield.
 998                         dnl check for both
 999                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1000
1001                         if test $ac_cv_func_sched_yield = no -a \
1002                                 $ac_cv_func_pthread_yield = no ; then
1003                                 dnl Digital UNIX has sched_yield() in -lrt
1004                                 AC_CHECK_LIB(rt, sched_yield,
1005                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1006                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1007                                                 [Define if you have the sched_yield function.])
1008                                         ac_cv_func_sched_yield=yes],
1009                                         [ac_cv_func_sched_yield=no])
1010                         fi
1011                         if test $ac_cv_func_sched_yield = no -a \
1012                                 $ac_cv_func_pthread_yield = no ; then
1013                                 dnl Solaris has sched_yield() stub in -lposix4
1014                                 dnl but we'll use thr_yield instead.
1015                                 AC_CHECK_FUNCS(thr_yield)
1016                         fi
1017                         if test $ac_cv_func_sched_yield = no -a \
1018                                 $ac_cv_func_pthread_yield = no -a \
1019                                 "$ac_cv_func_thr_yield" = no ; then
1020                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1021                         fi
1022
1023                         dnl Check functions for compatibility
1024                         AC_CHECK_FUNCS(pthread_kill)
1025
1026                         dnl Check for pthread_detach with <pthread.h> inclusion
1027                         dnl as it's symbol may have been mangled.
1028                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1029                                 [ol_cv_func_pthread_detach], [
1030                                 dnl save the flags
1031                                 AC_TRY_LINK([
1032 #include <pthread.h>
1033 #ifndef NULL
1034 #define NULL (void*)0
1035 #endif
1036 ],
1037                                         [pthread_detach(NULL);],
1038                                         [ol_cv_func_pthread_detach=yes],
1039                                         [ol_cv_func_pthread_detach=no])
1040                         ])
1041
1042                         if test $ol_cv_func_pthread_detach = no ; then
1043                                 AC_MSG_ERROR([could not locate pthread_detach()])
1044                         fi
1045
1046                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1047                                 [define if you have pthread_detach function])
1048
1049                         dnl Check for setconcurreny functions
1050                         AC_CHECK_FUNCS( \
1051                                 pthread_setconcurrency \
1052                                 pthread_getconcurrency \
1053                                 thr_setconcurrency \
1054                                 thr_getconcurrency \
1055                         )
1056
1057                         OL_SYS_LINUX_THREADS
1058                         OL_LINUX_THREADS
1059
1060                         if test $ol_cv_linux_threads = error; then
1061                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1062                         fi
1063
1064                         AC_CACHE_CHECK([if pthread_create() works],
1065                                 ol_cv_pthread_create_works,[
1066                         AC_TRY_RUN([
1067 #include <pthread.h>
1068 #ifndef NULL
1069 #define NULL (void*)0
1070 #endif
1071
1072 static void *task(p)
1073         void *p;
1074 {
1075         return (void *) (p == NULL);
1076 }
1077
1078 int main(argc, argv)
1079         int argc;
1080         char **argv;
1081 {
1082         pthread_t t;
1083 #if HAVE_PTHREADS_D4
1084         exit(pthread_create(&t, pthread_attr_default, task, NULL));
1085 #else
1086         exit(pthread_create(&t, NULL, task, NULL));
1087 #endif
1088 }
1089 ],
1090                                 [ol_cv_pthread_create_works=yes],
1091                                 [ol_cv_pthread_create_works=no],
1092                                 [dnl assume yes
1093                                 ol_cv_pthread_create_works=yes])])
1094
1095                         if test $ol_cv_pthread_create_works = no ; then
1096                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1097                         fi
1098
1099                         dnl Check if select causes an yield
1100                         if test $ol_with_yielding_select = auto ; then
1101                                 AC_CACHE_CHECK([if select yields when using pthreads],
1102                                         ol_cv_pthread_select_yields,[
1103                                 AC_TRY_RUN([
1104 #include <sys/types.h>
1105 #include <sys/time.h>
1106 #include <unistd.h>
1107 #include <pthread.h>
1108 #ifndef NULL
1109 #define NULL (void*) 0
1110 #endif
1111
1112 static int fildes[2];
1113
1114 static void *task(p)
1115         void *p;
1116 {
1117         int i;
1118         struct timeval tv;
1119
1120         fd_set rfds;
1121
1122         tv.tv_sec=10;
1123         tv.tv_usec=0;
1124
1125         FD_ZERO(&rfds);
1126         FD_SET(fildes[0], &rfds);
1127
1128         /* we're not interested in any fds */
1129         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1130
1131         if(i < 0) {
1132                 perror("select");
1133                 exit(10);
1134         }
1135
1136         exit(0); /* if we exit here, the select blocked the whole process */
1137 }
1138
1139 int main(argc, argv)
1140         int argc;
1141         char **argv;
1142 {
1143         pthread_t t;
1144
1145         /* create a pipe to select */
1146         if(pipe(&fildes[0])) {
1147                 perror("select");
1148                 exit(1);
1149         }
1150
1151 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1152         (void) pthread_setconcurrency(2);
1153 #else
1154 #ifdef HAVE_THR_SETCONCURRENCY
1155         /* Set Solaris LWP concurrency to 2 */
1156         thr_setconcurrency(2);
1157 #endif
1158 #endif
1159
1160 #if HAVE_PTHREADS_D4
1161         pthread_create(&t, pthread_attr_default, task, NULL);
1162 #else
1163         pthread_create(&t, NULL, task, NULL);
1164 #endif
1165
1166 #if HAVE_SCHED_YIELD
1167         sched_yield();  /* make sure task runs first */
1168 #else
1169 #ifdef HAVE_PTHREAD_YIELD
1170         pthread_yield();        /* make sure task runs first */
1171 #endif
1172 #endif
1173
1174         exit(2);
1175 }],
1176                                 [ol_cv_pthread_select_yields=no],
1177                                 [ol_cv_pthread_select_yields=yes],
1178                                 [ol_cv_pthread_select_yields=cross])])
1179
1180                                 if test $ol_cv_pthread_select_yields = cross ; then
1181                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1182                                 fi
1183
1184                                 if test $ol_cv_pthread_select_yields = yes ; then
1185                                         ol_with_yielding_select=yes
1186                                 fi
1187                         fi
1188
1189                         dnl restore flags
1190                         CPPFLAGS="$save_CPPFLAGS"
1191                         LIBS="$save_LIBS"
1192                 else
1193                         AC_MSG_ERROR([could not link with POSIX Threads])
1194                 fi
1195         fi
1196
1197         if test $ol_with_threads = posix ; then
1198                 AC_MSG_ERROR([could not locate POSIX Threads])
1199         fi
1200 fi
1201
1202 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1203         -o $ol_with_threads = mach ; then
1204
1205         dnl check for Mach CThreads
1206         AC_CHECK_HEADERS(mach/cthreads.h)
1207         if test $ac_cv_header_mach_cthreads_h = yes ; then
1208                 ol_with_threads=found
1209
1210                 dnl check for cthread support in current $LIBS
1211                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1212
1213                 if test $ol_link_threads = no ; then
1214                         dnl try -all_load
1215                         dnl this test needs work
1216                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1217                                 [ol_cv_cthread_all_load], [
1218                                 dnl save the flags
1219                                 save_LIBS="$LIBS"
1220                                 LIBS="-all_load $LIBS"
1221                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1222                                         cthread_fork((void *)0, (void *)0);
1223                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1224                                 dnl restore the LIBS
1225                                 LIBS="$save_LIBS"
1226                         ])
1227
1228                         if test $ol_cv_cthread_all_load = yes ; then
1229                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1230                                 ol_link_threads=mach
1231                         fi
1232                 fi
1233
1234                 if test $ol_link_threads != no ; then
1235                         : check for cthread specific functionality here
1236                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1237                                 [define if you have Mach Cthreads])
1238                 else
1239                         AC_MSG_ERROR([could not link with Mach CThreads])
1240                 fi
1241         fi
1242
1243         if test $ol_with_threads = mach ; then
1244                 AC_MSG_ERROR([could not locate Mach CThreads])
1245         fi
1246 fi
1247
1248 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1249         -o $ol_with_threads = lwp ; then
1250
1251         dnl check for SunOS5 LWP
1252         AC_CHECK_HEADERS(thread.h synch.h)
1253         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1254                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1255
1256                 if test $have_thr = yes ; then
1257                         AC_DEFINE(HAVE_THR,1,
1258                                 [if you have Solaris LWP (thr) package])
1259                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1260                         ol_link_threads=thr
1261
1262                         if test $ol_with_yielding_select = auto ; then
1263                                 ol_with_yielding_select=yes
1264                         fi
1265
1266                         dnl Check for setconcurreny functions
1267                         AC_CHECK_FUNCS( \
1268                                 thr_setconcurrency \
1269                                 thr_getconcurrency \
1270                         )
1271                 fi
1272         fi
1273
1274         dnl check for SunOS4 LWP
1275         AC_CHECK_HEADERS(lwp/lwp.h)
1276         if test $ac_cv_header_lwp_lwp_h = yes ; then
1277                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1278
1279                 if test $have_lwp = yes ; then
1280                         AC_DEFINE(HAVE_LWP,1,
1281                                 [if you have SunOS LWP package])
1282                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1283                         ol_link_threads=lwp
1284
1285                         if test $ol_with_yielding_select = auto ; then
1286                                 ol_with_yielding_select=no
1287                         fi
1288                 fi
1289         fi
1290 fi
1291
1292 if test $ol_with_yielding_select = yes ; then
1293         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1294                 [define if select implicitly yields])
1295 fi
1296
1297 if test $ol_with_threads = manual ; then
1298         dnl User thinks he can manually configure threads.
1299         ol_link_threads=yes
1300
1301         AC_MSG_WARN([thread defines and link options must be set manually])
1302
1303         AC_CHECK_HEADERS(pthread.h sched.h)
1304         AC_CHECK_FUNCS(sched_yield pthread_yield)
1305         OL_HEADER_LINUX_THREADS
1306
1307         AC_CHECK_HEADERS(mach/cthreads.h)
1308         AC_CHECK_HEADERS(lwp/lwp.h)
1309         AC_CHECK_HEADERS(thread.h synch.h)
1310 fi
1311
1312 if test $ol_link_threads != no ; then
1313         dnl needed to get reentrant/threadsafe versions
1314         dnl
1315         AC_DEFINE(REENTRANT,1)
1316         AC_DEFINE(_REENTRANT,1)
1317         AC_DEFINE(THREAD_SAFE,1)
1318         AC_DEFINE(_THREAD_SAFE,1)
1319         AC_DEFINE(THREADSAFE,1)
1320         AC_DEFINE(_THREADSAFE,1)
1321         AC_DEFINE(_SGI_MP_SOURCE,1)
1322
1323         dnl The errno declaration may dependent upon _REENTRANT.
1324         dnl If it does, we must link with thread support.
1325         AC_CACHE_CHECK([for thread specific errno],
1326                 [ol_cv_errno_thread_specific], [
1327                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1328                         [ol_cv_errno_thread_specific=yes],
1329                         [ol_cv_errno_thread_specific=no])
1330         ])
1331
1332         dnl The h_errno declaration may dependent upon _REENTRANT.
1333         dnl If it does, we must link with thread support.
1334         AC_CACHE_CHECK([for thread specific h_errno],
1335                 [ol_cv_h_errno_thread_specific], [
1336                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1337                         [ol_cv_h_errno_thread_specific=yes],
1338                         [ol_cv_h_errno_thread_specific=no])
1339         ])
1340
1341         if test $ol_cv_errno_thread_specific != yes \
1342                 -o $ol_cv_h_errno_thread_specific != yes ; then
1343                 LIBS="$LTHREAD_LIBS $LIBS"
1344                 LTHREAD_LIBS=""
1345         fi
1346
1347 dnl When in thread environment, use
1348 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1349 dnl                     || defined( HAVE_FUNC_R )
1350 dnl                     func_r(...);
1351 dnl             #else
1352 dnl             #       if defined( HAVE_THREADS )
1353 dnl                             /* lock */
1354 dnl             #       endif
1355 dnl                             func(...);
1356 dnl             #       if defined( HAVE_THREADS )
1357 dnl                             /* unlock */
1358 dnl             #       endif
1359 dnl             #endif
1360 dnl
1361 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1362 dnl             _POSIX_REENTRANT_FUNCTIONS
1363 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1364 dnl             _POSIX_THREADSAFE_FUNCTIONS
1365 dnl
1366 dnl             and is currently defined in lthread.h
1367 dnl
1368 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1369 dnl
1370 dnl libldap/*.c should only include <lthread.h> iff
1371 dnl LDAP_R_COMPILE is defined.  ie:
1372 dnl             #ifdef LDAP_R_COMPILE
1373 dnl             #       include LDAP_R_COMPILE
1374 dnl             #endif
1375 dnl
1376 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1377 dnl specifically for compiling the threadsafe version of
1378 dnl     the ldap library (-lldap_r).
1379 dnl
1380 dnl     dnl check for reentrant/threadsafe functions
1381 dnl     dnl
1382 dnl     dnl note: these should only be used when linking
1383 dnl     dnl       with $LTHREAD_LIBS
1384 dnl     dnl
1385 dnl     save_CPPFLAGS="$CPPFLAGS"
1386 dnl     save_LIBS="$LIBS"
1387 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1388 dnl     AC_CHECK_FUNCS( \
1389 dnl             gmtime_r \
1390 dnl             gethostbyaddr_r gethostbyname_r \
1391 dnl             feof_unlocked unlocked_feof \
1392 dnl             putc_unlocked unlocked_putc \
1393 dnl             flockfile ftrylockfile \
1394 dnl     )
1395 dnl     CPPFLAGS="$save_CPPFLAGS"
1396 dnl     LIBS="$save_LIBS"
1397 fi
1398
1399 if test $ol_link_threads = no ; then
1400         if test $ol_with_threads = yes ; then
1401                 AC_MSG_ERROR([no suitable thread support])
1402         fi
1403
1404         if test $ol_with_threads = auto ; then
1405                 AC_MSG_WARN([no suitable thread support, disabling threads])
1406                 ol_with_threads=no
1407         fi
1408
1409         AC_DEFINE(NO_THREADS,1,
1410                 [define if you have (or want) no threads])
1411         LTHREAD_LIBS=""
1412 fi
1413
1414 if test $ol_link_threads != no ; then
1415         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1416 fi
1417
1418 dnl ----------------------------------------------------------------
1419
1420 ol_link_ldbm=no
1421 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1422         OL_BERKELEY_DB2
1423
1424         if test $ol_cv_berkeley_db2 = yes ; then
1425                 ol_link_ldbm=db2
1426                 ol_with_ldbm_api=db2
1427
1428                 if test $ol_with_ldbm_type = hash ; then
1429                         AC_DEFINE(LDBM_USE_DBHASH,1,
1430                                 [define this to use DBHASH w/ LDBM backend])
1431                 else
1432                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1433                                 [define this to use DBBTREE w/ LDBM backend])
1434                 fi
1435
1436                 dnl $ol_cv_lib_db2 should be yes or -ldb
1437                 dnl (it could be no, but that would be an error
1438                 if test $ol_cv_lib_db2 != yes ; then
1439                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1440                 fi
1441         fi
1442 fi
1443
1444 ol_link_bdb2=no
1445 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1446         ol_link_bdb2=yes
1447 fi
1448
1449 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1450         OL_BERKELEY_DB
1451
1452         if test $ol_cv_berkeley_db = yes ; then
1453                 ol_link_ldbm=db
1454                 ol_with_ldbm_api=db
1455
1456                 if test $ol_with_ldbm_type = hash ; then
1457                         AC_DEFINE(LDBM_USE_DBHASH,1,
1458                                 [define this to use DBHASH w/ LDBM backend])
1459                 else
1460                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1461                                 [define this to use DBBTREE w/ LDBM backend])
1462                 fi
1463
1464                 dnl $ol_cv_lib_db should be yes or -ldb
1465                 dnl (it could be no, but that would be an error
1466                 if test $ol_cv_lib_db != yes ; then
1467                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1468                 fi
1469         fi
1470 fi
1471
1472 if test $ol_with_ldbm_api = manual ; then
1473         dnl User thinks he can manually configure LDBM api.
1474         ol_link_ldbm=yes
1475
1476         AC_MSG_WARN([LDBM defines and link options must be set manually])
1477
1478         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1479 fi
1480
1481 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1482         AC_MSG_WARN(Could not find LDBM with BTREE support)
1483         ol_with_ldbm_api=none
1484 fi
1485
1486 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1487         OL_MDBM
1488
1489         if test $ol_cv_mdbm = yes ; then
1490                 ol_link_ldbm=mdbm
1491                 ol_with_ldbm_api=mdbm
1492                 if test $ol_cv_lib_mdbm != yes ; then
1493                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1494                 fi
1495         fi
1496 fi
1497
1498 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1499         OL_GDBM
1500
1501         if test $ol_cv_gdbm = yes ; then
1502                 ol_link_ldbm=gdbm
1503                 ol_with_ldbm_api=gdbm
1504
1505                 if test $ol_cv_lib_gdbm != yes ; then
1506                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1507                 fi
1508         fi
1509 fi
1510
1511 if test $ol_with_ldbm_api = auto ; then
1512         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1513 elif test $ol_with_ldbm_api = ndbm ; then
1514         OL_NDBM
1515
1516         if test $ol_cv_ndbm = yes ; then
1517                 ol_link_ldbm=ndbm
1518                 ol_with_ldbm_api=ndbm
1519
1520                 if test $ol_cv_lib_ndbm != yes ; then
1521                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1522                 fi
1523         fi
1524 fi
1525
1526 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1527         AC_MSG_WARN(could not find suitable LDBM backend)
1528         if test $ol_enable_ldbm = yes ; then
1529                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1530         fi
1531
1532         AC_MSG_WARN(disabling LDBM)
1533         ol_enable_ldbm=no
1534 fi
1535
1536 if test $ol_enable_wrappers != no ; then
1537         AC_CHECK_HEADERS(tcpd.h)
1538
1539         if test $ac_cv_header_tcpd_h != yes ; then
1540                 have_wrappers=no
1541         else
1542                 AC_CHECK_LIB(wrap, main,
1543                         [have_wrappers=yes], [have_wrappers=no])
1544         fi
1545
1546         if test $have_wrappers = yes ; then
1547                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1548                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1549
1550                 dnl We add another check for -lnsl since some libwrap's
1551                 dnl need it, but it isn't always included from above
1552                 AC_CHECK_LIB(nsl, main)
1553         else
1554                 AC_MSG_WARN(could not find -lwrap)
1555                 if test $ol_enable_wrappers = yes ; then
1556                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1557                 fi
1558
1559                 AC_MSG_WARN(disabling wrappers support)
1560                 ol_enable_wrappers=no
1561         fi
1562 fi
1563
1564 if test $ol_enable_syslog != no ; then
1565         AC_CHECK_FUNC(openlog)
1566         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1567                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1568         fi
1569         ol_enable_syslog=$ac_cv_func_openlog
1570 fi
1571
1572 if test $ol_enable_dmalloc != no ; then
1573         AC_CHECK_HEADERS(dmalloc.h)
1574         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1575 fi
1576
1577 if test $ol_enable_tcl != no ; then
1578         AC_CHECK_HEADERS(tcl.h)
1579
1580         if test $ac_cv_header_tcl_h != yes ; then
1581                 have_tcl=no
1582         else
1583                 AC_CHECK_LIB(tcl,main,
1584                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1585                         [have_tcl=no])
1586
1587                 if test $have_tcl != yes; then
1588                         AC_CHECK_LIB(tcl7.6,main,
1589                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1590                                 [have_tcl=no])
1591                 fi
1592
1593                 if test $have_tcl != yes; then
1594                         AC_CHECK_LIB(tcl8.0,main,
1595                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1596                                 [have_tcl=no])
1597                 fi
1598         fi
1599
1600         if test $have_tcl != yes ; then
1601                 AC_MSG_WARN([could not find -ltcl])
1602                 if test $ol_enable_tcl = yes ; then
1603                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1604                 fi
1605
1606                 ol_enable_tcl=no
1607         fi
1608 fi
1609
1610 # ud needs termcap (should insert check here)
1611 ol_link_termcap=no
1612 AC_CHECK_HEADERS(termcap.h ncurses.h)
1613
1614 if test $ol_link_termcap = no ; then
1615         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1616         if test $have_termcap = yes ; then
1617                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1618                 ol_link_termcap=yes
1619                 TERMCAP_LIBS=-ltermcap
1620         fi
1621 fi
1622
1623 if test $ol_link_termcap = no ; then
1624         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1625         if test $have_ncurses = yes ; then
1626                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1627                 ol_link_termcap=yes
1628                 TERMCAP_LIBS=-lncurses
1629         fi
1630 fi
1631
1632 if test $ol_link_termcap = no ; then
1633         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1634         TERMCAP_LIBS=
1635 fi
1636
1637 dnl
1638 dnl Check for GNU readline
1639 dnl
1640 ol_link_readline=no
1641 if test $ol_with_readline != no ; then
1642         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1643
1644         if test $ac_cv_header_readline_readline_h = yes ; then
1645                 save_LIBS="$LIBS"
1646                 LIBS="$TERMCAP_LIBS $LIBS"
1647                 AC_CHECK_LIB(readline, readline,
1648                         [have_readline=yes], [have_readline=no])
1649                 LIBS="$save_LIBS"
1650
1651                 if test $have_readline = yes ; then
1652                         ol_with_readline=found
1653                         ol_link_readline=yes
1654
1655                         READLINE_LIBS="-lreadline"
1656                 fi
1657         fi
1658 fi
1659
1660 if test $ol_link_readline = yes ; then
1661         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1662 fi
1663
1664
1665 # FreeBSD (and others) have crypt(3) in -lcrypt
1666 if test $ol_enable_crypt != no ; then
1667         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1668                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1669                         have_crypt=yes], [have_crypt=no])])
1670
1671         if test $have_crypt = yes ; then
1672                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1673         else
1674                 AC_MSG_WARN(could not find crypt)
1675                 if test $ol_enable_crypt = yes ; then
1676                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1677                 fi
1678
1679                 AC_MSG_WARN(disabling crypt support)
1680                 ol_enable_crypt=no
1681         fi
1682 fi
1683
1684 # FreeBSD (and others) have setproctitle(3) in -lutil
1685 if test $ol_enable_proctitle != no ; then
1686         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1687                 AC_CHECK_LIB(util, setproctitle,
1688                         [have_setproctitle=yes
1689                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1690                         [have_setproctitle=no
1691                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1692
1693         if test $have_setproctitle = yes ; then
1694                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1695                         [define if setproctitle(3) is available])
1696         fi
1697 fi
1698
1699 dnl ----------------------------------------------------------------
1700 dnl Checks for typedefs, structures, and compiler characteristics.
1701 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1702 AC_TYPE_MODE_T
1703 AC_TYPE_OFF_T
1704 AC_TYPE_PID_T
1705 AM_TYPE_PTRDIFF_T
1706 AC_TYPE_SIGNAL
1707 OL_TYPE_SIG_ATOMIC_T
1708 AC_TYPE_SIZE_T
1709 OL_TYPE_SOCKLEN_T
1710 AC_STRUCT_ST_BLKSIZE
1711 AC_HEADER_TIME
1712 AC_STRUCT_TM
1713 OL_STRUCT_PASSWD_PW_GECOS
1714 OL_STRUCT_PASSWD_PW_PASSWD
1715
1716 OL_C_UPPER_LOWER
1717 AC_C_CONST
1718 OL_C_VOLATILE
1719
1720 if test $cross_compiling = yes ; then
1721         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1722
1723         AC_DEFINE(LBER_INT_T,long)
1724         AC_DEFINE(LBER_TAG_T,long)
1725         AC_DEFINE(LBER_SOCKET_T,int)
1726
1727 else
1728         AC_C_BIGENDIAN
1729         AC_CHECK_SIZEOF(short)
1730         AC_CHECK_SIZEOF(int)
1731         AC_CHECK_SIZEOF(long)
1732
1733         if test "$ac_cv_sizeof_int" -lt 4 ; then
1734                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1735
1736                 AC_DEFINE(LBER_INT_T,long)
1737                 AC_DEFINE(LBER_TAG_T,long)
1738                 AC_DEFINE(LBER_SOCKET_T,int)
1739         else
1740                 AC_DEFINE(LBER_INT_T,int)
1741                 AC_DEFINE(LBER_TAG_T,long)
1742                 AC_DEFINE(LBER_SOCKET_T,int)
1743         fi
1744 fi
1745
1746 AC_DEFINE(LBER_LEN_T,long)
1747
1748 dnl ----------------------------------------------------------------
1749 dnl Checks for library functions.
1750 AC_FUNC_MEMCMP
1751 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1752 AC_FUNC_STRFTIME
1753 dnl AM_FUNC_STRTOD
1754
1755 dnl we should use vfork instead of fork in a number of places...
1756 dnl AC_FUNC_VFORK
1757 AC_FUNC_VPRINTF
1758
1759 if test $ac_cv_func_vprintf = yes ; then
1760         dnl check for vsnprintf
1761         AC_CHECK_FUNCS(vsnprintf vsprintf)
1762 fi
1763
1764 AC_CHECK_FUNCS(         \
1765         bcopy                   \
1766         closesocket             \
1767         endgrent                \
1768         endpwent                \
1769         flock                   \
1770         getdtablesize   \
1771         getgrgid                \
1772         gethostname             \
1773         getpass                 \
1774         getpwuid                \
1775         getpwnam                \
1776         getspnam                \
1777         gettimeofday    \
1778         initgroups              \
1779         lockf                   \
1780         memcpy                  \
1781         memmove                 \
1782         mkstemp                 \
1783         read                    \
1784         recv                    \
1785         recvfrom                \
1786         setpwfile               \
1787         setgid                  \
1788         setegid                 \
1789         setsid                  \
1790         setuid                  \
1791         seteuid                 \
1792         signal                  \
1793         sigset                  \
1794         snprintf                \
1795         strdup                  \
1796         strerror                \
1797         strpbrk                 \
1798         strrchr                 \
1799         strsep                  \
1800         strstr                  \
1801         strtol                  \
1802         strtoul                 \
1803         strspn                  \
1804         sysconf                 \
1805         waitpid                 \
1806         wait4                   \
1807         write                   \
1808         send                    \
1809         sendto                  \
1810 )
1811
1812 dnl We actually may need to replace more than this.
1813 AC_REPLACE_FUNCS(getopt tempnam)
1814
1815 dnl ----------------------------------------------------------------
1816 # Check Configuration
1817 OL_SYS_ERRLIST
1818
1819 dnl ----------------------------------------------------------------
1820 dnl Sort out defines
1821
1822 if test "$ol_enable_debug" != no ; then
1823         AC_DEFINE(LDAP_DEBUG,1,
1824                 [define this to add debugging code])
1825 fi
1826 if test "$ol_enable_syslog" = yes ; then
1827         AC_DEFINE(LDAP_SYSLOG,1,
1828                 [define this to add syslog code])
1829 fi
1830 if test "$ol_enable_libui" = yes ; then
1831         AC_DEFINE(LDAP_LIBUI,1,
1832                 [define this for LDAP User Interface support])
1833 fi
1834 if test "$ol_enable_cache" = no ; then
1835         AC_DEFINE(LDAP_NOCACHE,1,
1836                 [define this to remove -lldap cache support])
1837 fi
1838 if test "$ol_enable_dns" != no ; then
1839         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1840 fi
1841 if test "$ol_enable_proctitle" != no ; then
1842         AC_DEFINE(LDAP_PROCTITLE,1,
1843                 [define this for LDAP process title support])
1844 fi
1845 if test "$ol_enable_referrals" != no ; then
1846         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1847 fi
1848 if test "$ol_enable_cldap" != no ; then
1849         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
1850 fi
1851
1852 if test "$ol_enable_crypt" != no ; then
1853         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
1854 fi
1855 if test "$ol_enable_cleartext" != no ; then
1856         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
1857 fi
1858 if test "$ol_enable_phonetic" != no ; then
1859         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
1860 fi
1861 if test "$ol_enable_rlookups" != no ; then
1862         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
1863 fi
1864
1865 if test "$ol_link_modules" != no ; then
1866         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
1867         BUILD_SLAPD=yes
1868 fi
1869
1870 if test "$ol_link_bdb2" != no ; then
1871         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
1872         BUILD_SLAPD=yes
1873         BUILD_BDB2=yes
1874         if test "$ol_with_bdb2_module" != static ; then
1875                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
1876                         [define to support dynamic BDB2 backend])
1877                 BUILD_BDB2_DYNAMIC=yes
1878         fi
1879 fi
1880
1881 if test "$ol_enable_ldap" != no ; then
1882         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
1883         BUILD_SLAPD=yes
1884         BUILD_LDAP=yes
1885         if test "$ol_with_ldap_module" != static ; then
1886                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
1887                         [define to support dynamic LDAP backend])
1888                 BUILD_LDAP_DYNAMIC=yes
1889         fi
1890 fi
1891
1892 if test "$ol_link_ldbm" != no ; then
1893         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
1894         BUILD_SLAPD=yes
1895         BUILD_LDBM=yes
1896         if test "$ol_with_ldbm_module" != static ; then
1897                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
1898                         [define to support dynamic LDBM backend])
1899                 BUILD_LDBM_DYNAMIC=yes
1900         fi
1901 fi
1902
1903 if test "$ol_enable_passwd" != no ; then
1904         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
1905         BUILD_SLAPD=yes
1906         BUILD_PASSWD=yes
1907         if test "$ol_with_passwd_module" != static ; then
1908                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
1909                         [define to support dynamic PASSWD backend])
1910                 BUILD_PASSWD_DYNAMIC=yes
1911         fi
1912 fi
1913
1914 if test "$ol_link_perl" != no ; then
1915         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
1916         BUILD_SLAPD=yes
1917         BUILD_PERL=yes
1918         if test "$ol_with_perl_module" != static ; then
1919                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
1920                         [define to support dynamic PERL backend])
1921                 BUILD_PERL_DYNAMIC=yes
1922         fi
1923 fi
1924
1925 if test "$ol_enable_shell" != no ; then
1926         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
1927         BUILD_SLAPD=yes
1928         BUILD_SHELL=yes
1929         if test "$ol_with_shell_module" != static ; then
1930                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
1931                         [define to support dynamic SHELL backend])
1932                 BUILD_SHELL_DYNAMIC=yes
1933         fi
1934 fi
1935
1936 if test "$ol_enable_tcl" != no ; then
1937         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
1938         BUILD_SLAPD=yes
1939         BUILD_TCL=yes
1940         if test "$ol_with_tcl_module" != static; then
1941                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
1942                         [define to support dynamic TCL backend])
1943                 BUILD_TCL_DYNAMIC=yes
1944         fi
1945 fi
1946
1947 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1948         $BUILD_SLAPD = yes ; then
1949         BUILD_SLURPD=yes
1950 fi
1951
1952 if test "$ol_link_isode" != no ; then
1953         BUILD_LDAPD=yes
1954 fi
1955
1956 dnl ----------------------------------------------------------------
1957
1958 AC_SUBST(BUILD_LDAPD)
1959 AC_SUBST(BUILD_SLAPD)
1960   AC_SUBST(BUILD_BDB2)
1961   AC_SUBST(BUILD_LDAP)
1962   AC_SUBST(BUILD_LDBM)
1963   AC_SUBST(BUILD_PASSWD)
1964   AC_SUBST(BUILD_PERL)
1965   AC_SUBST(BUILD_SHELL)
1966   AC_SUBST(BUILD_TCL)
1967   AC_SUBST(BUILD_BDB2_DYNAMIC)
1968   AC_SUBST(BUILD_LDAP_DYNAMIC)
1969   AC_SUBST(BUILD_LDBM_DYNAMIC)
1970   AC_SUBST(BUILD_PASSWD_DYNAMIC)
1971   AC_SUBST(BUILD_PERL_DYNAMIC)
1972   AC_SUBST(BUILD_SHELL_DYNAMIC)
1973   AC_SUBST(BUILD_TCL_DYNAMIC)
1974 AC_SUBST(BUILD_SLURPD)
1975
1976 AC_SUBST(LDAP_LIBS)
1977 AC_SUBST(LDAPD_LIBS)
1978 AC_SUBST(SLAPD_LIBS)
1979 AC_SUBST(SLURPD_LIBS)
1980 AC_SUBST(LDBM_LIBS)
1981 AC_SUBST(LTHREAD_LIBS)
1982 AC_SUBST(LUTIL_LIBS)
1983
1984 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1985 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1986
1987 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1988 AC_SUBST(SLAPD_PERL_LDFLAGS)
1989
1990 AC_SUBST(KRB_LIBS)
1991 AC_SUBST(READLINE_LIBS)
1992 AC_SUBST(TERMCAP_LIBS)
1993 AC_SUBST(TLS_LIBS)
1994
1995 dnl ----------------------------------------------------------------
1996 dnl final output
1997 dnl
1998
1999 AC_OUTPUT( \
2000 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2001 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2002 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2003 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2004 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2005 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2006 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2007 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2008 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2009 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2010 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2011 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2012 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2013 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2014 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2015 include/Makefile:build/top.mk:include/Makefile.in \
2016 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2017 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2018 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2019 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2020 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2021 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2022 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2023 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2024 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2025 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2026 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2027 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
2028 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/srv.mk \
2029 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
2030 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
2031 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
2032 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
2033 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
2034 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2035 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2036 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2037 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2038 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2039 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2040 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2041 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2042 ,[
2043 date > stamp-h
2044 echo Please \"make depend\" to build dependencies
2045 ])