git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  28 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  29 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  30 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  31 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  32 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  33 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  34         no, [yes no])dnl
  35
  36 dnl General "with" options
  37 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  38         auto, [auto k5 k4 afs yes no])
  39 OL_ARG_WITH(threads,[  --with-threads   use threads],
  40         auto, [auto posix mach lwp yes no manual] )
  41 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  42         auto, [auto yes no manual] )
  43
  44 dnl Server options
  45
  46 dnl LDAPD OPTIONS
  47 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  48
  49 dnl SLAPD OPTIONS
  50 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  51 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  52 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  53 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  54 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  55 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  56 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  57 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  58
  59 dnl SLAPD Backend options
  60 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  61 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  62         [auto db2 db gdbm ndbm manual])
  63 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  64         [auto btree hash])
  65
  66 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  67 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  68
  69 dnl SLURPD OPTIONS
  70 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  71
  72 if test $ol_enable_slapd = no ; then
  73         dnl SLAPD was specificallly disabled
  74         if test $ol_enable_ldbm = yes ; then
  75                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  76         fi
  77         if test $ol_enable_passwd = yes ; then
  78                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
  79         fi
  80         if test $ol_enable_shell = yes ; then
  81                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
  82         fi
  83         if test $ol_enable_aclgroups = yes ; then
  84                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
  85         fi
  86         if test $ol_enable_crypt = yes ; then
  87                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
  88         fi
  89         if test $ol_enable_md5 = yes ; then
  90                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
  91         fi
  92         if test $ol_enable_sha1 = yes ; then
  93                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
  94         fi
  95         if test $ol_enable_wrappers = yes ; then
  96                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
  97         fi
  98         if test $ol_enable_phonetic = yes ; then
  99                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 100         fi
 101         if test $ol_enable_rlookups = yes ; then
 102                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 103         fi
 104         if test $ol_with_ldbm_api != auto ; then
 105                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 106         fi
 107         if test $ol_with_ldbm_type != auto ; then
 108                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 109         fi
 110         if test $ol_enable_slurpd = yes ; then
 111                 AC_MSG_ERROR([slurpd requires slapd])
 112         fi
 113
 114         # force settings to no
 115         ol_enable_ldbm=no
 116         ol_enable_shell=no
 117         ol_enable_passwd=no
 118         ol_enable_aclgroups=no
 119         ol_enable_crypt=no
 120         ol_enable_md5=no
 121         ol_enable_sha1=no
 122         ol_enable_wrappers=no
 123         ol_enable_phonetic=no
 124         ol_enable_rlookups=no
 125         ol_with_ldbm_api=no
 126         ol_with_ldbm_type=no
 127         ol_enable_slurpd=no
 128
 129 elif test $ol_enable_ldbm = no ; then
 130         dnl SLAPD without LDBM
 131
 132         if test $ol_with_ldbm_api != auto ; then
 133                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 134         fi
 135
 136         if test $ol_with_ldbm_type != auto ; then
 137                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 138         fi
 139
 140         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 141                 AC_MSG_ERROR([slapd requires a backend])
 142         fi
 143
 144         ol_with_ldbm_api=no
 145         ol_with_ldbm_type=no
 146
 147 else
 148         dnl SLAPD with LDBM
 149
 150         if test $ol_with_ldbm_api = gdbm -a \
 151                 $ol_with_ldbm_type = btree ; then
 152                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 153         fi
 154         if test $ol_with_ldbm_api = ndbm -a \
 155                 $ol_with_ldbm_type = btree ; then
 156                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 157         fi
 158 fi
 159
 160 if test $ol_enable_slurpd = yes ; then
 161         dnl SLURPD was specifically enabled
 162         if test $ol_with_threads = no ; then
 163                 AC_MSG_ERROR([slurpd requires threads])
 164         fi
 165 fi
 166
 167 AC_MSG_RESULT(done)
 168
 169 ## Initialize vars
 170 LDAP_LIBS=
 171 LDBM_LIBS=
 172 LTHREAD_LIBS=
 173 LUTIL_LIBS=
 174
 175 LDAPD_LIBS=
 176 SLAPD_LIBS=
 177 SLURPD_LIBS=
 178
 179 BUILD_LDAPD=no
 180 BUILD_SLAPD=no
 181 BUILD_SLURPD=no
 182
 183 BUILD_LDBM=no
 184 BUILD_PASSWD=no
 185 BUILD_SHELL=no
 186
 187 KRB_LIBS=
 188 TERMCAP_LIBS=
 189
 190 dnl ----------------------------------------------------------------
 191 dnl Checks for programs
 192
 193 AC_PROG_LN_S
 194 AC_PROG_INSTALL
 195 AC_PROG_RANLIB
 196 AC_PROG_MAKE_SET
 197
 198 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 199         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 200 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 201 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 202
 203 dnl Checks the compiler and UNIX Variants
 204 AC_PROG_CC
 205
 206 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 207         AC_WARN([cross compiling....  go for it])
 208
 209 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 210         AC_WARN([programs compiled here do run here...])
 211         AC_ERROR([  if not cross compiling, use --disable-x-compile.])
 212
 213 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 214         AC_WARN([programs compiled here do not run here...])
 215         AC_ERROR([  if cross compiling,  add --enable-x-compile.])
 216 fi
 217
 218 AC_PROG_GCC_TRADITIONAL
 219 AC_PROG_CPP
 220
 221
 222 AC_AIX
 223 AC_ISC_POSIX
 224 AC_MINIX
 225
 226 dnl Checks for libraries
 227
 228 dnl Find socket()
 229 dnl Likely combinations:
 230 dnl             -lsocket [ -lnsl_s | -lnsl ]
 231 dnl             -linet
 232
 233 AC_CHECK_FUNC(socket, :, [
 234 dnl
 235 dnl hopefully we won't include too many libraries
 236 dnl
 237         AC_CHECK_LIB(socket, main)
 238         AC_CHECK_LIB(net, main)
 239         AC_CHECK_LIB(nsl_s, main)
 240         AC_CHECK_LIB(nsl, main)
 241         AC_CHECK_LIB(inet, socket)
 242         AC_CHECK_LIB(gen, main)
 243 ])
 244
 245 dnl HP-UX requires -lV3
 246 AC_CHECK_LIB(V3, sigset)
 247
 248 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 249         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 250
 251         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 252                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 253                         [-lkrb5 -ldes425])
 254
 255                 if test $have_k5 = yes ; then
 256                         ol_with_kerberos=found
 257                         ol_link_kerberos=yes
 258
 259                         AC_DEFINE(HAVE_KERBEROS)
 260
 261                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 262                 fi
 263         fi
 264 fi
 265 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 266         AC_CHECK_HEADERS(krb.h des.h)
 267
 268         if test $ac_cv_header_krb_h = yes ; then
 269                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 270
 271                 if test $have_k4 = yes ; then
 272                         ol_with_kerberos=found
 273                         ol_link_kerberos=yes
 274
 275                         AC_DEFINE(HAVE_KERBEROS)
 276
 277                         KRB_LIBS="-lkrb -ldes"
 278                 fi
 279         fi
 280 fi
 281
 282
 283 ol_link_threads=no
 284 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 285         AC_CHECK_HEADERS(pthread.h sched.h)
 286
 287         if test $ac_cv_header_pthread_h = yes ; then
 288                 OL_POSIX_THREAD_VERSION
 289
 290                 if test $ol_cv_pthread_version = final ; then
 291                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 292                 elif test $ol_cv_pthread_version = draft4 ; then
 293                         AC_DEFINE(HAVE_PTHREADS_D4)
 294                 else
 295                         AC_MSG_ERROR([unknown pthread version])
 296                 fi
 297
 298                 # consider threads found
 299                 ol_with_threads=found
 300
 301                 OL_LINUX_THREADS
 302
 303                 if test $ol_cv_linux_threads = yes ; then
 304                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 305                 fi
 306
 307                 dnl Now the hard part, how to link
 308
 309                 dnl A few platforms have pthread support in standard libraries
 310                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 311
 312                 if test $ol_link_threads = no ; then
 313                         dnl try -pthread
 314                         AC_CACHE_CHECK([for pthread_create with -pthread],
 315                                 [ol_cv_pthread_flag], [
 316                                 dnl save the CPPFLAGS
 317                                 save_LIBS="$LIBS"
 318                                 LIBS="-pthread $LIBS"
 319                                 AC_TRY_LINK([#include <pthread.h>],[
 320                                         pthread_create((pthread_t*) 0,
 321                                                 (pthread_attr_t*) 0, 0, 0);
 322                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 323                                 dnl restore the LIBS
 324                                 LIBS="$save_LIBS"
 325                         ])
 326
 327                         if test $ol_cv_pthread_flag = yes ; then
 328                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 329                                 ol_link_threads=posix
 330                         fi
 331                 fi
 332
 333                 if test $ol_link_threads = no ; then
 334                         dnl try -lpthread
 335                         save_LIBS="$LIBS"
 336                         AC_CHECK_LIB(pthread, pthread_create, [
 337                                 ol_link_threads=posix
 338                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 339                         LIBS="$save_LIBS"
 340                 fi
 341
 342                 if test $ol_link_threads = no ; then
 343                         dnl try -lc_r
 344                         save_LIBS="$LIBS"
 345                         AC_CHECK_LIB(c_r, pthread_create, [
 346                                 ol_link_threads=posix
 347                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 348                         LIBS="$save_LIBS"
 349                 fi
 350
 351                 if test $ol_link_threads = no ; then
 352                         dnl try DEC Threads
 353                         save_LIBS="$LIBS"
 354                         AC_CHECK_LIB(pthread, pthread_create, [
 355                                 AC_DEFINE(HAVE_DCE)
 356                                 ol_link_threads=posix
 357                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc"
 358                                 if test $ol_with_preemptive = auto ; then
 359                                         ol_with_preemptive=yes
 360                                 fi
 361                                 ],,[-lmach -lexc -lc])
 362                         LIBS="$save_LIBS"
 363                 fi
 364
 365                 if test $ol_link_threads != no ; then
 366                         AC_DEFINE(HAVE_PTHREADS)
 367
 368                         dnl save DEFS/LIBS
 369                         save_CPPFLAGS="$CPPFLAGS"
 370                         save_LIBS="$LIBS"
 371                         LIBS="$LTHREAD_LIBS $LIBS"
 372
 373                         dnl All POSIX Thread (final) implementations should have
 374                         dnl sched_yield instead of pthread yield.
 375                         dnl check for both
 376                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 377
 378                         if test $ac_cv_func_sched_yield = no -a \
 379                                 $ac_cv_func_pthread_yield = no ; then
 380                                 dnl Digital UNIX has sched_yield() in -lrt
 381                                 AC_CHECK_LIB(rt, sched_yield,
 382                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 383                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 384                                         ac_cv_func_sched_yield=yes],
 385                                         [ac_cv_func_sched_yield=no])
 386                         fi
 387                         if test $ac_cv_func_sched_yield = no -a \
 388                                 $ac_cv_func_pthread_yield = no ; then
 389                                 dnl Solaris has sched_yield() in -lposix4
 390                                 AC_CHECK_LIB(posix4, sched_yield,
 391                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 392                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 393                                         ac_cv_func_sched_yield=yes],
 394                                         [ac_cv_func_sched_yield=no])
 395                         fi
 396                         if test $ac_cv_func_sched_yield = no -a \
 397                                 $ac_cv_func_pthread_yield = no ; then
 398                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 399                                 AC_MSG_ERROR([POSIX Threads are not usable])
 400                         fi
 401
 402                         dnl Check functions for compatibility
 403                         AC_CHECK_FUNCS(pthread_kill)
 404 dnl                     AC_CHECK_FUNCS( \
 405 dnl                             pthread_attr_create pthread_attr_init \
 406 dnl                             pthread_attr_destroy pthread_attr_delete \
 407 dnl                             pthread_attr_setdetachstate pthread_attr_setdetach_np \
 408 dnl                     )
 409
 410                         dnl Check for setconcurreny functions
 411                         AC_CHECK_FUNCS( \
 412                                 pthread_setconcurrency \
 413                                 thr_setconcurrency \
 414                         )
 415
 416                         dnl Check PREEMPTIVE Implementation
 417                         if test $ol_with_preemptive = auto ; then
 418                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 419                                 AC_TRY_RUN([
 420 #include <sys/types.h>
 421 #include <sys/time.h>
 422 #include <unistd.h>
 423 #include <pthread.h>
 424 #ifndef NULL
 425 #define NULL 0
 426 #endif
 427
 428 int task(arg)
 429         int *arg;
 430 {
 431         struct timeval tv;
 432
 433         tv.tv_sec=4;
 434         tv.tv_usec=0;
 435         select(0, NULL, NULL, NULL, &tv);
 436
 437         tv.tv_sec=6;
 438         tv.tv_usec=0;
 439         select(0, NULL, NULL, NULL, &tv);
 440
 441         exit(1); /* if we exit here, the select blocked the whole process */
 442 }
 443
 444 main(argc, argv)
 445 int argc; char **argv;
 446 {
 447         pthread_t t;
 448
 449 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 450         (void) pthread_setconcurrency(2);
 451 #elif HAVE_THR_SETCONCURRENCY
 452         /* Set Solaris LWP concurrency to 2 */
 453         thr_setconcurrency(2);
 454 #endif
 455
 456         pthread_create(&t, NULL, (void *) task, NULL);
 457
 458 #if HAVE_SCHED_YIELD
 459         sched_yield();  /* make sure task runs first */
 460 #else
 461 #if defined(HAVE_PTHREAD_YIELD)
 462         pthread_yield();        /* make sure task runs first */
 463 #endif
 464 #endif
 465         exit(0);
 466 }
 467                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 468                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 469                                 AC_MSG_RESULT($ol_pthread_preemptive)
 470
 471                                 if test $ol_pthread_preemptive = yes ; then
 472                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 473                                         ol_with_preemptive=yes
 474                                 fi
 475                         fi
 476
 477 dnl                     dnl check for reentrant/threadsafe functions
 478 dnl                     AC_CHECK_FUNCS( \
 479 dnl                             feof_unlocked \
 480 dnl                             unlocked_feof \
 481 dnl                             ftrylockfile \
 482 dnl                             flockfile \
 483 dnl                             putc_unlocked \
 484 dnl                             gmtime_r \
 485 dnl                             strtok_r \
 486 dnl                     )
 487
 488                         dnl restore DEFS/LIBS
 489                         CPPFLAGS="$save_CPPFLAGS"
 490                         LIBS="$save_LIBS"
 491                 else
 492                         AC_MSG_ERROR([could not link with POSIX Threads])
 493                 fi
 494         fi
 495
 496         if test $ol_with_threads = posix ; then
 497                 AC_MSG_ERROR([could not locate POSIX Threads])
 498         fi
 499 fi
 500
 501 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 502         dnl check for Mach CThreads
 503         AC_CHECK_HEADERS(mach/cthreads.h)
 504         if test $ac_cv_header_mach_cthreads_h = yes ; then
 505                 ol_with_threads=found
 506
 507                 dnl A few platforms have cthread support in standard libraries
 508                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 509
 510                 if test $ol_link_threads = no ; then
 511                         dnl try -all_load
 512                         dnl this test needs work
 513                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 514                                 [ol_cv_cthread_all_load], [
 515                                 dnl save the CPPFLAGS
 516                                 save_LIBS="$LIBS"
 517                                 LIBS="-all_load $LIBS"
 518                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 519                                         cthread_fork((void *)0, (void *)0);
 520                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 521                                 dnl restore the LIBS
 522                                 LIBS="$save_LIBS"
 523                         ])
 524
 525                         if test $ol_cv_cthread_all_load = yes ; then
 526                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 527                                 ol_link_threads=mach
 528                         fi
 529                 fi
 530
 531                 if test $ol_link_threads != no ; then
 532                         : check for cthread specific functionality here
 533                 else
 534                         AC_MSG_ERROR([could not link with Mach CThreads])
 535                 fi
 536         fi
 537
 538         if test $ol_with_threads = mach ; then
 539                 AC_MSG_ERROR([could not locate Mach CThreads])
 540         fi
 541 fi
 542
 543 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 544         dnl check for SunOS5 LWP
 545         AC_CHECK_HEADERS(thread.h synch.h)
 546         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 547                 AC_CHECK_LIB(thread, thr_create, [have_lwp=yes], [have_lwp=no])
 548
 549                 if test $have_lwp = yes ; then
 550                         AC_DEFINE(HAVE_THR)
 551                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 552
 553                         if test $ol_with_preemptive = auto ; then
 554                                 ol_with_preemptive=yes
 555                         fi
 556                 fi
 557         fi
 558
 559         dnl check for SunOS4 LWP
 560         AC_CHECK_HEADERS(lwp/lwp.h)
 561         if test $ac_cv_header_lwp_lwp_h = yes ; then
 562                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 563
 564                 if test $have_lwp = yes ; then
 565                         AC_DEFINE(HAVE_LWP)
 566                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 567
 568                         if test $ol_with_preemptive = auto ; then
 569                                 ol_with_preemptive=no
 570                         fi
 571                 fi
 572         fi
 573 fi
 574
 575 if test $ol_with_preemptive = yes ; then
 576         AC_DEFINE(PREEMPTIVE_THREADS,1)
 577 fi
 578
 579 if test $ol_with_threads = manual ; then
 580         dnl User thinks he can manually configure threads.
 581         ol_link_threads=yes
 582
 583         AC_MSG_WARN([thread defines and link options must be set manually])
 584
 585         AC_CHECK_HEADERS(pthread.h sched.h)
 586         AC_CHECK_FUNCS(sched_yield pthread_yield)
 587         OL_LINUX_THREADS
 588
 589         AC_CHECK_HEADERS(mach/cthreads.h)
 590         AC_CHECK_HEADERS(lwp/lwp.h)
 591         AC_CHECK_HEADERS(thread.h synch.h)
 592 fi
 593
 594 if test $ol_with_threads = yes ; then
 595         dnl needed to get reentrant/threadsafe versions
 596         dnl
 597         dnl hopefully this will not cause problems with
 598         dnl non-threaded apps
 599         dnl
 600         AC_DEFINE(_REENTRANT,1)
 601         AC_DEFINE(_THREAD_SAFE,1)
 602 fi
 603
 604 dnl ----------------------------------------------------------------
 605
 606 if test $ol_link_threads = no ; then
 607         if test $ol_with_threads = yes ; then
 608                 AC_MSG_ERROR([no suitable thread support])
 609         fi
 610
 611         if test $ol_with_threads = auto ; then
 612                 AC_MSG_WARN([no suitable thread support, disabling threads])
 613                 ol_with_threads=no
 614         fi
 615
 616         AC_DEFINE(NO_THREADS,1)
 617         AC_DEFINE(PREEMPTIVE_THREADS,1)
 618         LTHREAD_LIBS=""
 619 fi
 620
 621 ol_link_ldbm=no
 622 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 623         OL_BERKELEY_DB2
 624
 625         if test $ol_cv_berkeley_db2 = yes ; then
 626                 ol_link_ldbm=db2
 627                 ol_with_ldbm_api=db2
 628
 629                 if test $ol_with_ldbm_type = hash ; then
 630                         AC_DEFINE(LDBM_USE_DBHASH,1)
 631                 else
 632                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 633                 fi
 634
 635                 dnl $ol_cv_lib_db2 should be yes or -ldb
 636                 dnl (it could be no, but that would be an error
 637                 if test $ol_cv_lib_db2 != yes ; then
 638                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 639                 fi
 640         fi
 641 fi
 642
 643 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 644         OL_BERKELEY_DB
 645
 646         if test $ol_cv_berkeley_db = yes ; then
 647                 ol_link_ldbm=db
 648                 ol_with_ldbm_api=db
 649
 650                 if test $ol_with_ldbm_type = hash ; then
 651                         AC_DEFINE(LDBM_USE_DBHASH,1)
 652                 else
 653                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 654                 fi
 655
 656                 dnl $ol_cv_lib_db should be yes or -ldb
 657                 dnl (it could be no, but that would be an error
 658                 if test $ol_cv_lib_db != yes ; then
 659                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 660                 fi
 661         fi
 662 fi
 663
 664 if test $ol_with_ldbm_api = manual ; then
 665         dnl User thinks he can manually configure LDBM api.
 666         ol_link_ldbm=yes
 667
 668         AC_MSG_WARN([LDBM defines and link options must be set manually])
 669
 670         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 671 fi
 672
 673 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 674         AC_MSG_WARN(Could not find LDBM with BTREE support)
 675         ol_with_ldbm_api=none
 676 fi
 677
 678 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 679         OL_GDBM
 680
 681         if test $ol_cv_gdbm = yes ; then
 682                 ol_link_ldbm=gdbm
 683                 ol_with_ldbm_api=gdbm
 684
 685                 if test $ol_cv_lib_gdbm != yes ; then
 686                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 687                 fi
 688         fi
 689 fi
 690
 691 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 692         OL_NDBM
 693
 694         if test $ol_cv_ndbm = yes ; then
 695                 ol_link_ldbm=ndbm
 696                 ol_with_ldbm_api=ndbm
 697
 698                 if test $ol_with_ldbm_api = ndbm ; then
 699                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 700                 fi
 701
 702                 if test $ol_cv_lib_ndbm != yes ; then
 703                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 704                 fi
 705         fi
 706 fi
 707
 708 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 709         AC_MSG_WARN(could not find suitable LDBM backend)
 710         if test $ol_enable_ldbm = yes ; then
 711                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 712         fi
 713
 714         AC_MSG_WARN(disabling LDBM)
 715         ol_enable_ldbm=no
 716 fi
 717
 718 if test $ol_enable_wrappers = yes ; then
 719         AC_CHECK_LIB(wrap, hosts_access,
 720                 [have_wrappers=yes], [have_wrappers=no])
 721
 722         if test $have_wrappers = yes ; then
 723                 AC_DEFINE(HAVE_TCPD)
 724                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 725         else
 726                 AC_MSG_WARN(could not find -lwrap)
 727                 if test $ol_enable_wrappers = yes ; then
 728                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 729                 fi
 730
 731                 AC_MSG_WARN(disabling wrappers support)
 732                 ol_enable_wrappers=no
 733         fi
 734
 735 fi
 736
 737 # ud needs termcap (should insert check here)
 738 ol_link_termcap=no
 739 AC_CHECK_HEADERS(termcap.h ncurses.h)
 740
 741 if test $ol_link_termcap = no ; then
 742         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 743         if test $have_termcap = yes ; then
 744                 AC_DEFINE(HAVE_TERMCAP)
 745                 ol_link_termcap=yes
 746                 TERMCAP_LIBS=-ltermcap
 747         fi
 748 fi
 749
 750 if test $ol_link_termcap = no ; then
 751         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 752         if test $have_ncurses = yes ; then
 753                 AC_DEFINE(HAVE_NCURSES)
 754                 ol_link_termcap=yes
 755                 TERMCAP_LIBS=-lncurses
 756         fi
 757 fi
 758
 759 if test $ol_link_termcap = no ; then
 760         AC_DEFINE(NO_TERMCAP,1)
 761         TERMCAP_LIBS=
 762 fi
 763
 764 # FreeBSD (and others) have crypt(3) in -lcrypt
 765 if test $ol_enable_crypt != no ; then
 766         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 767                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 768                         have_crypt=yes], [have_crypt=no])])
 769
 770         if test $have_crypt = yes ; then
 771                 AC_DEFINE(HAVE_CRYPT,1)
 772         else
 773                 AC_MSG_WARN(could not find crypt)
 774                 if test $ol_enable_crypt = yes ; then
 775                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 776                 fi
 777
 778                 AC_MSG_WARN(disabling crypt support)
 779                 ol_enable_crypt=no
 780         fi
 781 fi
 782
 783 # FreeBSD (and others) have setproctitle(3) in -lutil
 784 if test $ol_enable_proctitle != no ; then
 785         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 786                 AC_CHECK_LIB(util, setproctitle,
 787                         [have_setproctitle=yes
 788                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 789                         [have_setproctitle=no
 790                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 791
 792         if test $have_setproctitle = yes ; then
 793                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 794         fi
 795 fi
 796
 797 dnl ----------------------------------------------------------------
 798 dnl Checks for header files.
 799 AC_HEADER_STDC
 800
 801 if test $ac_cv_header_stdc != yes; then
 802         AC_MSG_WARN([could not locate Standard C headers])
 803 fi
 804
 805 AC_HEADER_DIRENT
 806 AC_HEADER_SYS_WAIT
 807 AC_CHECK_HEADERS(       \
 808         stdarg.h                \
 809         stddef.h                \
 810         errno.h                 \
 811         fcntl.h                 \
 812         filio.h                 \
 813         getopt.h                \
 814         libutil.h               \
 815         limits.h                \
 816         malloc.h                \
 817         regex.h                 \
 818         sgtty.h                 \
 819         sys/file.h              \
 820         sys/filio.h             \
 821         sys/errno.h             \
 822         sys/ioctl.h             \
 823         sys/param.h             \
 824         sys/socket.h    \
 825         sys/syslog.h    \
 826         sys/time.h              \
 827         sys/types.h             \
 828         syslog.h                \
 829         termios.h               \
 830         unistd.h                \
 831 )
 832
 833 dnl ----------------------------------------------------------------
 834 dnl Checks for typedefs, structures, and compiler characteristics.
 835 AC_TYPE_GETGROUPS
 836 AC_TYPE_MODE_T
 837 AC_TYPE_OFF_T
 838 AC_TYPE_PID_T
 839 AC_TYPE_SIGNAL
 840 AC_TYPE_SIZE_T
 841 AC_TYPE_UID_T
 842 AC_STRUCT_ST_BLKSIZE
 843 AC_HEADER_TIME
 844 AC_STRUCT_TM
 845
 846 OL_C_UPPER_LOWER
 847 AC_C_CONST
 848
 849 dnl AC_CHECK_SIZEOF(short)
 850 dnl AC_CHECK_SIZEOF(int)
 851 dnl AC_CHECK_SIZEOF(long)
 852
 853 dnl ----------------------------------------------------------------
 854 dnl Checks for library functions.
 855 AC_FUNC_MEMCMP
 856 AC_FUNC_STRFTIME
 857 AC_FUNC_VPRINTF
 858
 859 if test $ac_cv_func_vprintf = yes ; then
 860         dnl check for vsnprintf
 861         AC_CHECK_FUNCS(vsnprintf)
 862 fi
 863
 864 AC_FUNC_WAIT3
 865
 866 AC_CHECK_FUNCS(         \
 867         bcopy                   \
 868         getopt                  \
 869         flock                   \
 870         gethostname             \
 871         gettimeofday    \
 872         getdtablesize   \
 873         lockf                   \
 874         memcpy                  \
 875         memmove                 \
 876         mkstemp                 \
 877         mktime                  \
 878         select                  \
 879         setpwfile               \
 880         setsid                  \
 881         signal                  \
 882         sigset                  \
 883         snprintf                \
 884         socket                  \
 885         strerror                \
 886         strstr                  \
 887         strrchr                 \
 888         strsep                  \
 889         strtod                  \
 890         strtol                  \
 891         strtoul                 \
 892         sysconf                 \
 893         tempnam                 \
 894         waitpid                 \
 895 )
 896
 897 AC_REPLACE_FUNCS(getopt strdup tempnam)
 898
 899 dnl ----------------------------------------------------------------
 900 # Check Configuration
 901 OL_SYS_ERRLIST
 902
 903 dnl ----------------------------------------------------------------
 904 dnl Sort out defines
 905
 906 if test $ol_enable_debug != no ; then
 907         AC_DEFINE(LDAP_DEBUG,1)
 908 fi
 909 dnl     if test $ol_enable_syslog != no ; then
 910 dnl             AC_DEFINE(LDAP_SYSLOG,1)
 911 dnl     fi
 912 if test $ol_enable_libui = yes ; then
 913         AC_DEFINE(LDAP_LIBUI,1)
 914 fi
 915 if test $ol_enable_cache = no ; then
 916         AC_DEFINE(LDAP_NOCACHE,1)
 917 fi
 918 if test $ol_enable_dns != no ; then
 919         AC_DEFINE(LDAP_DNS,1)
 920 fi
 921 if test $ol_enable_proctitle != no ; then
 922         AC_DEFINE(LDAP_PROCTITLE,1)
 923 fi
 924 if test $ol_enable_referrals != no ; then
 925         AC_DEFINE(LDAP_REFERRALS,1)
 926 fi
 927 if test $ol_enable_cldap != no ; then
 928         AC_DEFINE(LDAP_CONNECTIONLESS,1)
 929 fi
 930
 931 if test $ol_enable_aclgroups != no ; then
 932         AC_DEFINE(SLAPD_ACLGROUPS,1)
 933 fi
 934 if test $ol_enable_crypt != no ; then
 935         AC_DEFINE(SLAPD_CRYPT,1)
 936 fi
 937 if test $ol_enable_md5 != no ; then
 938         AC_DEFINE(SLAPD_MD5,1)
 939 fi
 940 if test $ol_enable_sha1 != no ; then
 941         AC_DEFINE(SLAPD_SHA1,1)
 942 fi
 943 if test $ol_enable_phonetic != no ; then
 944         AC_DEFINE(SLAPD_PHONETIC,1)
 945 fi
 946 if test $ol_enable_rlookups != no ; then
 947         AC_DEFINE(SLAPD_RLOOKUPS,1)
 948 fi
 949
 950 if test $ol_link_ldbm != no ; then
 951         AC_DEFINE(SLAPD_LDBM,1)
 952         BUILD_SLAPD=yes
 953         BUILD_LDBM=yes
 954 fi
 955
 956 if test $ol_enable_passwd != no ; then
 957         AC_DEFINE(SLAPD_PASSWD,1)
 958         BUILD_SLAPD=yes
 959         BUILD_PASSWD=yes
 960 fi
 961
 962 if test $ol_enable_shell != no ; then
 963         AC_DEFINE(SLAPD_SHELL,1)
 964         BUILD_SLAPD=yes
 965         BUILD_SHELL=yes
 966 fi
 967
 968 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
 969         $BUILD_SLAPD = yes ; then
 970         BUILD_SLURPD=yes
 971 fi
 972
 973 if test $ol_enable_ldapd != no ; then
 974         BUILD_LDAPD=yes
 975 fi
 976
 977 dnl ----------------------------------------------------------------
 978
 979 AC_SUBST(BUILD_LDAPD)
 980 AC_SUBST(BUILD_SLAPD)
 981   AC_SUBST(BUILD_LDBM)
 982   AC_SUBST(BUILD_PASSWD)
 983   AC_SUBST(BUILD_SHELL)
 984 AC_SUBST(BUILD_SLURPD)
 985
 986
 987 AC_SUBST(LDAP_LIBS)
 988 AC_SUBST(LDAPD_LIBS)
 989 AC_SUBST(SLAPD_LIBS)
 990 AC_SUBST(SLURPD_LIBS)
 991 AC_SUBST(LDBM_LIBS)
 992 AC_SUBST(LTHREAD_LIBS)
 993 AC_SUBST(LUTIL_LIBS)
 994
 995 AC_SUBST(KRB_LIBS)
 996 AC_SUBST(TERMCAP_LIBS)
 997
 998 dnl ----------------------------------------------------------------
 999 dnl final output
1000 dnl
1001
1002 dnl AC_OUTPUT( \
1003 dnl contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1004 dnl contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1005 dnl contrib/whois++/Makefile:build/top.mk:contrib/whois++/Makefile.in:build/rules.mk \
1006 dnl [date > stamp-h])
1007
1008 AC_OUTPUT( \
1009 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1010 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1011 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1012 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1013 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1014 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1015 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1016 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1017 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1018 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1019 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1020 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1021 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1022 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1023 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1024 include/Makefile:build/top.mk:include/Makefile.in \
1025 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1026 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
1027 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
1028 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
1029 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
1030 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
1031 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
1032 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
1033 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1034 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1035 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1036 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1037 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1038 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1039 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1040 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1041 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1042 tests/Makefile:build/top.mk:tests/Makefile.in \
1043 ,[
1044 date > stamp-h
1045 echo Please \"make depend\" to build dependencies
1046 ])