git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8
   9 dnl Configure.in for OpenLDAP
  10 AC_INIT(include/ldap.h)dnl
  11 AC_CONFIG_AUX_DIR(build)dnl
  12 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  13
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_PREREQ(2.10)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  30 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  31 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  32 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  33 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  34 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  35 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  36 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  37 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  38         no, [yes no])dnl
  39
  40 dnl General "with" options
  41 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  42         auto, [auto k5 k4 afs yes no])
  43 OL_ARG_WITH(threads,[  --with-threads   use threads],
  44         auto, [auto posix mach lwp yes no manual] )
  45 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  46         auto, [auto yes no manual] )
  47
  48 dnl Server options
  49
  50 dnl LDAPD OPTIONS
  51 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  52 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  53
  54 dnl SLAPD OPTIONS
  55 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  56 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  57 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  58 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  59 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  60 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  61 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  62 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  63 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  64
  65 dnl SLAPD Backend options
  66 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  67 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  68         [auto db2 db gdbm ndbm manual])
  69 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  70         [auto btree hash])
  71
  72 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  73 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  74
  75 dnl SLURPD OPTIONS
  76 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  77 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  78
  79 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  80 AM_ENABLE_STATIC
  81 dnl AM_DISABLE_SHARED
  82 AM_ENABLE_SHARED
  83
  84 dnl General "enable" options
  85 # validate options
  86 if test $ol_enable_referrals = no ; then
  87         if test $ol_enable_dns = yes ; then
  88                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
  89         fi
  90         ol_enable_dns=no
  91 fi
  92
  93 if test $ol_enable_slapd = no ; then
  94         dnl SLAPD was specificallly disabled
  95         if test $ol_enable_ldbm = yes ; then
  96                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  97         fi
  98         if test $ol_enable_passwd = yes ; then
  99                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 100         fi
 101         if test $ol_enable_shell = yes ; then
 102                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 103         fi
 104         if test $ol_enable_aclgroups = yes ; then
 105                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 106         fi
 107         if test $ol_enable_crypt = yes ; then
 108                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
 109         fi
 110         if test $ol_enable_md5 = yes ; then
 111                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
 112         fi
 113         if test $ol_enable_sha1 = yes ; then
 114                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 115         fi
 116         if test $ol_enable_wrappers = yes ; then
 117                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 118         fi
 119         if test $ol_enable_phonetic = yes ; then
 120                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 121         fi
 122         if test $ol_enable_rlookups = yes ; then
 123                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 124         fi
 125         if test $ol_with_ldbm_api != auto ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 127         fi
 128         if test $ol_with_ldbm_type != auto ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 130         fi
 131         if test $ol_enable_slurpd = yes ; then
 132                 AC_MSG_ERROR([slurpd requires slapd])
 133         fi
 134
 135         # force settings to no
 136         ol_enable_ldbm=no
 137         ol_enable_shell=no
 138         ol_enable_passwd=no
 139         ol_enable_aclgroups=no
 140         ol_enable_crypt=no
 141         ol_enable_md5=no
 142         ol_enable_sha1=no
 143         ol_enable_wrappers=no
 144         ol_enable_phonetic=no
 145         ol_enable_rlookups=no
 146         ol_with_ldbm_api=no
 147         ol_with_ldbm_type=no
 148         ol_enable_slurpd=no
 149
 150 elif test $ol_enable_ldbm = no ; then
 151         dnl SLAPD without LDBM
 152
 153         if test $ol_with_ldbm_api != auto ; then
 154                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 155         fi
 156
 157         if test $ol_with_ldbm_type != auto ; then
 158                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 159         fi
 160
 161         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 162                 AC_MSG_ERROR([slapd requires a backend])
 163         fi
 164
 165         ol_with_ldbm_api=no
 166         ol_with_ldbm_type=no
 167
 168 else
 169         dnl SLAPD with LDBM
 170
 171         if test $ol_with_ldbm_api = gdbm -a \
 172                 $ol_with_ldbm_type = btree ; then
 173                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 174         fi
 175         if test $ol_with_ldbm_api = ndbm -a \
 176                 $ol_with_ldbm_type = btree ; then
 177                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 178         fi
 179 fi
 180
 181 if test $ol_enable_slurpd = yes ; then
 182         dnl SLURPD was specifically enabled
 183         if test $ol_with_threads = no ; then
 184                 AC_MSG_ERROR([slurpd requires threads])
 185         fi
 186 fi
 187
 188 AC_MSG_RESULT(done)
 189
 190 AC_CANONICAL_HOST
 191
 192 ## Initialize vars
 193 LDAP_LIBS=
 194 LDBM_LIBS=
 195 LTHREAD_LIBS=
 196 LUTIL_LIBS=
 197
 198 LDAPD_LIBS=
 199 SLAPD_LIBS=
 200 SLURPD_LIBS=
 201
 202 BUILD_LDAPD=no
 203 BUILD_SLAPD=no
 204 BUILD_SLURPD=no
 205
 206 BUILD_LDBM=no
 207 BUILD_PASSWD=no
 208 BUILD_SHELL=no
 209 BUILD_THREAD=no
 210
 211 KRB_LIBS=
 212 TERMCAP_LIBS=
 213
 214 dnl ----------------------------------------------------------------
 215 dnl Checks for programs
 216
 217 AC_PROG_INSTALL
 218 AM_PROG_LIBTOOL
 219 dnl AC_PROG_MAKE_SET
 220
 221 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 222         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 223 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 224 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 225
 226 dnl Checks the compiler and UNIX Variants
 227
 228 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 229         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 230
 231 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 232         AC_MSG_WARN([programs compiled here do run here...])
 233         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 234
 235 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 236         AC_MSG_WARN([programs compiled here do not run here...])
 237         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 238 fi
 239
 240 AC_PROG_CPP
 241
 242 AC_AIX
 243 AC_ISC_POSIX
 244 AC_MINIX
 245
 246 dnl OpenLDAP requires STDC features
 247 AM_PROG_CC_STDC
 248 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 249         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 250 fi
 251
 252 dnl AM_C_PROTOTYPES
 253
 254 dnl Checks for libraries
 255
 256 dnl Find socket()
 257 dnl Likely combinations:
 258 dnl             -lsocket [ -lnsl_s | -lnsl ]
 259 dnl             -linet
 260
 261 AC_CHECK_FUNC(socket, [have_socket=yes], [
 262 dnl
 263 dnl hopefully we won't include too many libraries
 264 dnl
 265         AC_CHECK_LIB(socket, main)
 266         AC_CHECK_LIB(net, main)
 267         AC_CHECK_LIB(nsl_s, main)
 268         AC_CHECK_LIB(nsl, main)
 269         AC_CHECK_LIB(inet, socket)
 270         AC_CHECK_LIB(gen, main)
 271 ])
 272
 273 dnl Check for resolv
 274 AC_CHECK_LIB(resolv, res_search)
 275
 276 dnl HP-UX requires -lV3
 277 AC_CHECK_LIB(V3, sigset)
 278
 279 # ISODE tests
 280 ol_link_isode=no
 281 if test $ol_enable_ldapd != no ; then
 282         dnl look for ISODE libraries
 283         AC_CHECK_LIB(xtpp, main, [
 284                 ol_link_isode=yes
 285                 AC_DEFINE(HAVE_XTPP,1)
 286                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 287                 ],:,[-lxtdsap -lxtisode -losi])
 288         AC_CHECK_LIB(dsap, main, [
 289                 ol_link_isode=yes
 290                 AC_DEFINE(HAVE_DSAP,1)
 291                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 292                 ],:,[-lisode])
 293         AC_CHECK_LIB(isode, main, [
 294                 ol_link_isode=yes
 295                 AC_DEFINE(HAVE_ISODE,1)
 296                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 297                 ],:)
 298 fi
 299
 300 if test $ol_link_isode != no; then
 301         AC_CHECK_LIB(pp, main, [
 302                 AC_DEFINE(HAVE_PP,1)
 303                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 304                 ],:)
 305
 306         AC_PATH_PROG(PEPSY, pepsy)
 307 fi
 308
 309 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 310         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 311
 312         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 313                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 314                         [-lkrb5 -ldes425])
 315
 316                 if test $have_k5 = yes ; then
 317                         ol_with_kerberos=found
 318                         ol_link_kerberos=yes
 319
 320                         AC_DEFINE(HAVE_KERBEROS)
 321
 322                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 323                 fi
 324         fi
 325 fi
 326 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 327         AC_CHECK_HEADERS(krb.h des.h)
 328
 329         if test $ac_cv_header_krb_h = yes ; then
 330                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 331
 332                 if test $have_k4 = yes ; then
 333                         ol_with_kerberos=found
 334                         ol_link_kerberos=yes
 335
 336                         AC_DEFINE(HAVE_KERBEROS)
 337
 338                         KRB_LIBS="-lkrb -ldes"
 339                 fi
 340         fi
 341 fi
 342
 343 ol_link_threads=no
 344 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 345         AC_CHECK_HEADERS(pthread.h sched.h)
 346
 347         if test $ac_cv_header_pthread_h = yes ; then
 348                 OL_POSIX_THREAD_VERSION
 349
 350                 if test $ol_cv_pthread_version = final ; then
 351                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 352                 elif test $ol_cv_pthread_version = draft4 ; then
 353                         AC_DEFINE(HAVE_PTHREADS_D4)
 354                 else
 355                         AC_MSG_ERROR([unknown pthread version])
 356                 fi
 357
 358                 # consider threads found
 359                 ol_with_threads=found
 360
 361                 OL_LINUX_THREADS
 362
 363                 if test $ol_cv_linux_threads = yes ; then
 364                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 365                 fi
 366
 367                 dnl Now the hard part, how to link
 368
 369                 dnl Check for pthread support in current $LIBS
 370                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 371
 372                 if test $ol_link_threads = no ; then
 373                         dnl try -pthread
 374                         AC_CACHE_CHECK([for pthread_create with -pthread],
 375                                 [ol_cv_pthread_flag], [
 376                                 dnl save the flags
 377                                 save_LIBS="$LIBS"
 378                                 LIBS="-pthread $LIBS"
 379                                 AC_TRY_LINK([char pthread();],[
 380                                         pthread_create();
 381                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 382                                 dnl restore the LIBS
 383                                 LIBS="$save_LIBS"
 384                         ])
 385
 386                         if test $ol_cv_pthread_flag = yes ; then
 387                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 388                                 ol_link_threads=posix
 389                         fi
 390                 fi
 391
 392                 if test $ol_link_threads = no ; then
 393                         dnl try -thread
 394                         AC_CACHE_CHECK([for pthread_create with -thread],
 395                                 [ol_cv_thread_flag], [
 396                                 dnl save the flags
 397                                 save_LIBS="$LIBS"
 398                                 LIBS="-thread $LIBS"
 399                                 AC_TRY_LINK([char pthread();],[
 400                                         pthread_create();
 401                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 402                                 dnl restore the LIBS
 403                                 LIBS="$save_LIBS"
 404                         ])
 405
 406                         if test $ol_cv_thread_flag = yes ; then
 407                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 408                                 ol_link_threads=posix
 409                         fi
 410                 fi
 411
 412                 if test $ol_link_threads = no ; then
 413                         dnl try DEC Threads -lpthread -lexc
 414                         save_LIBS="$LIBS"
 415                         AC_CHECK_LIB(pthread, pthread_join, [
 416                                 ol_link_threads=posix
 417                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 418                                 if test $ol_with_preemptive = auto ; then
 419                                         ol_with_preemptive=yes
 420                                 fi
 421                                 ],,[-lexc])
 422                         LIBS="$save_LIBS"
 423                 fi
 424
 425                 if test $ol_link_threads = no ; then
 426                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 427                         save_LIBS="$LIBS"
 428                         AC_CHECK_LIB(pthreads, pthread_join, [
 429                                 ol_link_threads=posix
 430                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 431                                 if test $ol_with_preemptive = auto ; then
 432                                         ol_with_preemptive=yes
 433                                 fi
 434                                 ],,[-lmach -lexc -lc_r])
 435                         LIBS="$save_LIBS"
 436                 fi
 437
 438                 if test $ol_link_threads = no ; then
 439                         dnl try -lpthread
 440                         save_LIBS="$LIBS"
 441                         AC_CHECK_LIB(pthread, pthread_create, [
 442                                 ol_link_threads=posix
 443                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 444                         LIBS="$save_LIBS"
 445                 fi
 446
 447                 if test $ol_link_threads = no ; then
 448                         dnl try -lc_r
 449                         save_LIBS="$LIBS"
 450                         AC_CHECK_LIB(c_r, pthread_create, [
 451                                 ol_link_threads=posix
 452                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 453                         LIBS="$save_LIBS"
 454                 fi
 455
 456                 if test $ol_link_threads != no ; then
 457                         AC_DEFINE(HAVE_PTHREADS)
 458
 459                         dnl save flags
 460                         save_CPPFLAGS="$CPPFLAGS"
 461                         save_LIBS="$LIBS"
 462                         LIBS="$LTHREAD_LIBS $LIBS"
 463
 464                         dnl All POSIX Thread (final) implementations should have
 465                         dnl sched_yield instead of pthread yield.
 466                         dnl check for both
 467                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 468
 469                         if test $ac_cv_func_sched_yield = no -a \
 470                                 $ac_cv_func_pthread_yield = no ; then
 471                                 dnl Digital UNIX has sched_yield() in -lrt
 472                                 AC_CHECK_LIB(rt, sched_yield,
 473                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 474                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 475                                         ac_cv_func_sched_yield=yes],
 476                                         [ac_cv_func_sched_yield=no])
 477                         fi
 478                         if test $ac_cv_func_sched_yield = no -a \
 479                                 $ac_cv_func_pthread_yield = no ; then
 480                                 dnl Solaris has sched_yield() in -lposix4
 481                                 AC_CHECK_LIB(posix4, sched_yield,
 482                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 483                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 484                                         ac_cv_func_sched_yield=yes],
 485                                         [ac_cv_func_sched_yield=no])
 486                         fi
 487                         if test $ac_cv_func_sched_yield = no -a \
 488                                 $ac_cv_func_pthread_yield = no ; then
 489                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 490                                 AC_MSG_ERROR([POSIX Threads are not usable])
 491                         fi
 492
 493                         dnl Check functions for compatibility
 494                         AC_CHECK_FUNCS(pthread_kill)
 495                         AC_CHECK_FUNCS( \
 496                                 pthread_attr_create pthread_attr_init \
 497                                 pthread_attr_destroy pthread_attr_delete \
 498                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 499                         )
 500
 501                         dnl Check for setconcurreny functions
 502                         AC_CHECK_FUNCS( \
 503                                 pthread_setconcurrency \
 504                                 thr_setconcurrency \
 505                         )
 506
 507                         dnl Check PREEMPTIVE Implementation
 508                         if test $ol_with_preemptive = auto ; then
 509                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 510                                 AC_TRY_RUN([
 511 #include <sys/types.h>
 512 #include <sys/time.h>
 513 #include <unistd.h>
 514 #include <pthread.h>
 515 #ifndef NULL
 516 #define NULL 0
 517 #endif
 518
 519 int task(arg)
 520         int *arg;
 521 {
 522         int i;
 523         struct timeval tv;
 524
 525         tv.tv_sec=5;
 526         tv.tv_usec=0;
 527
 528         /* we're not interested in any fds */
 529         i = select(FD_SETSIZE, NULL, NULL, NULL, &tv);
 530
 531         if(i < 0) {
 532                 perror("select");
 533         }
 534
 535         exit(1); /* if we exit here, the select blocked the whole process */
 536 }
 537
 538 main(argc, argv)
 539 int argc; char **argv;
 540 {
 541         pthread_t t;
 542
 543 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 544         (void) pthread_setconcurrency(2);
 545 #else
 546 #ifdef HAVE_THR_SETCONCURRENCY
 547         /* Set Solaris LWP concurrency to 2 */
 548         thr_setconcurrency(2);
 549 #endif
 550 #endif
 551
 552         pthread_create(&t, NULL, (void *) task, NULL);
 553
 554 #if HAVE_SCHED_YIELD
 555         sched_yield();  /* make sure task runs first */
 556 #else
 557 #ifdef HAVE_PTHREAD_YIELD
 558         pthread_yield();        /* make sure task runs first */
 559 #endif
 560 #endif
 561         exit(0);
 562 }
 563                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 564                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 565                                 AC_MSG_RESULT($ol_pthread_preemptive)
 566
 567                                 if test $ol_pthread_preemptive = yes ; then
 568                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 569                                         ol_with_preemptive=yes
 570                                 fi
 571                         fi
 572
 573 dnl                     dnl check for reentrant/threadsafe functions
 574 dnl                     AC_CHECK_FUNCS( \
 575 dnl                             feof_unlocked \
 576 dnl                             unlocked_feof \
 577 dnl                             ftrylockfile \
 578 dnl                             flockfile \
 579 dnl                             putc_unlocked \
 580 dnl                             gmtime_r \
 581 dnl                             strtok_r \
 582 dnl                     )
 583
 584                         dnl restore flags
 585                         CPPFLAGS="$save_CPPFLAGS"
 586                         LIBS="$save_LIBS"
 587                 else
 588                         AC_MSG_ERROR([could not link with POSIX Threads])
 589                 fi
 590         fi
 591
 592         if test $ol_with_threads = posix ; then
 593                 AC_MSG_ERROR([could not locate POSIX Threads])
 594         fi
 595 fi
 596
 597 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 598         dnl check for Mach CThreads
 599         AC_CHECK_HEADERS(mach/cthreads.h)
 600         if test $ac_cv_header_mach_cthreads_h = yes ; then
 601                 ol_with_threads=found
 602
 603                 dnl check for cthread support in current $LIBS
 604                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 605
 606                 if test $ol_link_threads = no ; then
 607                         dnl try -all_load
 608                         dnl this test needs work
 609                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 610                                 [ol_cv_cthread_all_load], [
 611                                 dnl save the flags
 612                                 save_LIBS="$LIBS"
 613                                 LIBS="-all_load $LIBS"
 614                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 615                                         cthread_fork((void *)0, (void *)0);
 616                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 617                                 dnl restore the LIBS
 618                                 LIBS="$save_LIBS"
 619                         ])
 620
 621                         if test $ol_cv_cthread_all_load = yes ; then
 622                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 623                                 ol_link_threads=mach
 624                         fi
 625                 fi
 626
 627                 if test $ol_link_threads != no ; then
 628                         : check for cthread specific functionality here
 629                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 630                 else
 631                         AC_MSG_ERROR([could not link with Mach CThreads])
 632                 fi
 633         fi
 634
 635         if test $ol_with_threads = mach ; then
 636                 AC_MSG_ERROR([could not locate Mach CThreads])
 637         fi
 638 fi
 639
 640 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 641         dnl check for SunOS5 LWP
 642         AC_CHECK_HEADERS(thread.h synch.h)
 643         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 644                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 645
 646                 if test $have_thr = yes ; then
 647                         AC_DEFINE(HAVE_THR)
 648                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 649                         ol_link_threads=thr
 650
 651                         if test $ol_with_preemptive = auto ; then
 652                                 ol_with_preemptive=yes
 653                         fi
 654                 fi
 655         fi
 656
 657         dnl check for SunOS4 LWP
 658         AC_CHECK_HEADERS(lwp/lwp.h)
 659         if test $ac_cv_header_lwp_lwp_h = yes ; then
 660                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 661
 662                 if test $have_lwp = yes ; then
 663                         AC_DEFINE(HAVE_LWP)
 664                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 665                         ol_link_threads=lwp
 666
 667                         if test $ol_with_preemptive = auto ; then
 668                                 ol_with_preemptive=no
 669                         fi
 670                 fi
 671         fi
 672 fi
 673
 674 if test $ol_with_preemptive = yes ; then
 675         AC_DEFINE(PREEMPTIVE_THREADS,1)
 676 fi
 677
 678 if test $ol_with_threads = manual ; then
 679         dnl User thinks he can manually configure threads.
 680         ol_link_threads=yes
 681
 682         AC_MSG_WARN([thread defines and link options must be set manually])
 683
 684         AC_CHECK_HEADERS(pthread.h sched.h)
 685         AC_CHECK_FUNCS(sched_yield pthread_yield)
 686         OL_LINUX_THREADS
 687
 688         AC_CHECK_HEADERS(mach/cthreads.h)
 689         AC_CHECK_HEADERS(lwp/lwp.h)
 690         AC_CHECK_HEADERS(thread.h synch.h)
 691 fi
 692
 693 if test $ol_with_threads != no ; then
 694         dnl needed to get reentrant/threadsafe versions
 695         dnl
 696         AC_DEFINE(_REENTRANT,1)
 697         AC_DEFINE(_THREAD_SAFE,1)
 698         AC_DEFINE(_THREADSAFE,1)
 699
 700         dnl this might cause the errno symbol to be
 701         dnl replaced with a function to get a thread specific errno.
 702         dnl check to see if everything needs to be compiled
 703         dnl with the thread libraries
 704         AC_CACHE_CHECK([for thread specific errno],
 705                 [ol_cv_errno_thread_specific], [
 706                 AC_TRY_LINK([
 707 #include <errno.h>
 708                         ], [
 709 int x = errno;
 710                         ],
 711                         [ol_cv_errno_thread_specific=yes],
 712                         [ol_cv_errno_thread_specific=no])
 713         ])
 714
 715         if test $ol_cv_errno_thread_specific != yes ; then
 716                 LIBS="$LTHREAD_LIBS $LIBS"
 717                 LTHREAD_LIBS=""
 718         fi
 719 fi
 720
 721 dnl ----------------------------------------------------------------
 722
 723 if test $ol_link_threads = no ; then
 724         if test $ol_with_threads = yes ; then
 725                 AC_MSG_ERROR([no suitable thread support])
 726         fi
 727
 728         if test $ol_with_threads = auto ; then
 729                 AC_MSG_WARN([no suitable thread support, disabling threads])
 730                 ol_with_threads=no
 731         fi
 732
 733         AC_DEFINE(NO_THREADS,1)
 734         AC_DEFINE(PREEMPTIVE_THREADS,1)
 735         LTHREAD_LIBS=""
 736 fi
 737
 738 ol_link_ldbm=no
 739 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 740         OL_BERKELEY_DB2
 741
 742         if test $ol_cv_berkeley_db2 = yes ; then
 743                 ol_link_ldbm=db2
 744                 ol_with_ldbm_api=db2
 745
 746                 if test $ol_with_ldbm_type = hash ; then
 747                         AC_DEFINE(LDBM_USE_DBHASH,1)
 748                 else
 749                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 750                 fi
 751
 752                 dnl $ol_cv_lib_db2 should be yes or -ldb
 753                 dnl (it could be no, but that would be an error
 754                 if test $ol_cv_lib_db2 != yes ; then
 755                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 756                 fi
 757         fi
 758 fi
 759
 760 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 761         OL_BERKELEY_DB
 762
 763         if test $ol_cv_berkeley_db = yes ; then
 764                 ol_link_ldbm=db
 765                 ol_with_ldbm_api=db
 766
 767                 if test $ol_with_ldbm_type = hash ; then
 768                         AC_DEFINE(LDBM_USE_DBHASH,1)
 769                 else
 770                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 771                 fi
 772
 773                 dnl $ol_cv_lib_db should be yes or -ldb
 774                 dnl (it could be no, but that would be an error
 775                 if test $ol_cv_lib_db != yes ; then
 776                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 777                 fi
 778         fi
 779 fi
 780
 781 if test $ol_with_ldbm_api = manual ; then
 782         dnl User thinks he can manually configure LDBM api.
 783         ol_link_ldbm=yes
 784
 785         AC_MSG_WARN([LDBM defines and link options must be set manually])
 786
 787         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 788 fi
 789
 790 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 791         AC_MSG_WARN(Could not find LDBM with BTREE support)
 792         ol_with_ldbm_api=none
 793 fi
 794
 795 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 796         OL_GDBM
 797
 798         if test $ol_cv_gdbm = yes ; then
 799                 ol_link_ldbm=gdbm
 800                 ol_with_ldbm_api=gdbm
 801
 802                 if test $ol_cv_lib_gdbm != yes ; then
 803                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 804                 fi
 805         fi
 806 fi
 807
 808 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 809         OL_NDBM
 810
 811         if test $ol_cv_ndbm = yes ; then
 812                 if test $ol_with_ldbm_api = auto ; then
 813                         AC_MSG_WARN([Attempting to use NDBM.  Functionality will be limited.])
 814                 fi
 815
 816                 ol_link_ldbm=ndbm
 817                 ol_with_ldbm_api=ndbm
 818
 819                 if test $ol_cv_lib_ndbm != yes ; then
 820                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 821                 fi
 822         fi
 823 fi
 824
 825 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 826         AC_MSG_WARN(could not find suitable LDBM backend)
 827         if test $ol_enable_ldbm = yes ; then
 828                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 829         fi
 830
 831         AC_MSG_WARN(disabling LDBM)
 832         ol_enable_ldbm=no
 833 fi
 834
 835 if test $ol_enable_wrappers = yes ; then
 836         AC_CHECK_LIB(wrap, hosts_access,
 837                 [have_wrappers=yes], [have_wrappers=no])
 838
 839         if test $have_wrappers = yes ; then
 840                 AC_DEFINE(HAVE_TCPD)
 841                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 842         else
 843                 AC_MSG_WARN(could not find -lwrap)
 844                 if test $ol_enable_wrappers = yes ; then
 845                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 846                 fi
 847
 848                 AC_MSG_WARN(disabling wrappers support)
 849                 ol_enable_wrappers=no
 850         fi
 851
 852 fi
 853
 854 # ud needs termcap (should insert check here)
 855 ol_link_termcap=no
 856 AC_CHECK_HEADERS(termcap.h ncurses.h)
 857
 858 if test $ol_link_termcap = no ; then
 859         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 860         if test $have_termcap = yes ; then
 861                 AC_DEFINE(HAVE_TERMCAP)
 862                 ol_link_termcap=yes
 863                 TERMCAP_LIBS=-ltermcap
 864         fi
 865 fi
 866
 867 if test $ol_link_termcap = no ; then
 868         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 869         if test $have_ncurses = yes ; then
 870                 AC_DEFINE(HAVE_NCURSES)
 871                 ol_link_termcap=yes
 872                 TERMCAP_LIBS=-lncurses
 873         fi
 874 fi
 875
 876 if test $ol_link_termcap = no ; then
 877         AC_DEFINE(NO_TERMCAP,1)
 878         TERMCAP_LIBS=
 879 fi
 880
 881 # FreeBSD (and others) have crypt(3) in -lcrypt
 882 if test $ol_enable_crypt != no ; then
 883         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 884                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 885                         have_crypt=yes], [have_crypt=no])])
 886
 887         if test $have_crypt = yes ; then
 888                 AC_DEFINE(HAVE_CRYPT,1)
 889         else
 890                 AC_MSG_WARN(could not find crypt)
 891                 if test $ol_enable_crypt = yes ; then
 892                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 893                 fi
 894
 895                 AC_MSG_WARN(disabling crypt support)
 896                 ol_enable_crypt=no
 897         fi
 898 fi
 899
 900 # FreeBSD (and others) have setproctitle(3) in -lutil
 901 if test $ol_enable_proctitle != no ; then
 902         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 903                 AC_CHECK_LIB(util, setproctitle,
 904                         [have_setproctitle=yes
 905                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 906                         [have_setproctitle=no
 907                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 908
 909         if test $have_setproctitle = yes ; then
 910                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 911         fi
 912 fi
 913
 914 dnl ----------------------------------------------------------------
 915 dnl Checks for header files.
 916 AC_HEADER_STDC
 917
 918 if test $ac_cv_header_stdc != yes; then
 919         AC_MSG_WARN([could not Standard C compliant headers])
 920 fi
 921
 922 AC_HEADER_DIRENT
 923 AC_HEADER_SYS_WAIT
 924 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 925 if test $am_cv_sys_posix_termios = yes ; then
 926         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
 927 fi
 928
 929 AC_CHECK_HEADERS(       \
 930         crypt.h                 \
 931         errno.h                 \
 932         fcntl.h                 \
 933         filio.h                 \
 934         getopt.h                \
 935         libutil.h               \
 936         limits.h                \
 937         malloc.h                \
 938         memory.h                \
 939         regex.h                 \
 940         psap.h                  \
 941         pwd.h                   \
 942         sgtty.h                 \
 943         stdarg.h                \
 944         stddef.h                \
 945         string.h                \
 946         strings.h               \
 947         sys/file.h              \
 948         sys/filio.h             \
 949         sys/errno.h             \
 950         sys/ioctl.h             \
 951         sys/param.h             \
 952         sys/resource.h  \
 953         sys/socket.h    \
 954         sys/syslog.h    \
 955         sys/types.h             \
 956         syslog.h                \
 957         termios.h               \
 958 )
 959
 960 dnl ----------------------------------------------------------------
 961 dnl Checks for typedefs, structures, and compiler characteristics.
 962 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
 963 AC_TYPE_MODE_T
 964 AC_TYPE_OFF_T
 965 AC_TYPE_PID_T
 966 AM_TYPE_PTRDIFF_T
 967 AC_TYPE_SIGNAL
 968 AC_TYPE_SIZE_T
 969 AC_STRUCT_ST_BLKSIZE
 970 AC_HEADER_TIME
 971 AC_STRUCT_TM
 972
 973 OL_C_UPPER_LOWER
 974 AC_C_CONST
 975
 976 if test $cross_compiling = yes ; then
 977         AC_DEFINE(CROSS_COMPILING, 1)
 978 else
 979         AC_C_BIGENDIAN
 980         AC_CHECK_SIZEOF(short)
 981         AC_CHECK_SIZEOF(int)
 982         AC_CHECK_SIZEOF(long)
 983 fi
 984
 985 dnl ----------------------------------------------------------------
 986 dnl Checks for library functions.
 987 AC_FUNC_MEMCMP
 988 AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
 989 AC_FUNC_STRFTIME
 990 AM_FUNC_STRTOD
 991 AC_FUNC_VPRINTF
 992
 993 if test $ac_cv_func_vprintf = yes ; then
 994         dnl check for vsnprintf
 995         AC_CHECK_FUNCS(vsnprintf)
 996 fi
 997
 998 AC_FUNC_WAIT3
 999
1000 AC_CHECK_FUNCS(         \
1001         bcopy                   \
1002         flock                   \
1003         getdtablesize   \
1004         gethostname             \
1005         getpwuid                \
1006         gettimeofday    \
1007         lockf                   \
1008         memcpy                  \
1009         memmove                 \
1010         mkstemp                 \
1011         res_search              \
1012         select                  \
1013         setpwfile               \
1014         setsid                  \
1015         signal                  \
1016         sigset                  \
1017         snprintf                \
1018         socket                  \
1019         strerror                \
1020         strpbrk                 \
1021         strrchr                 \
1022         strsep                  \
1023         strstr                  \
1024         strtok                  \
1025         strtol                  \
1026         strtoul                 \
1027         sysconf                 \
1028         waitpid                 \
1029 )
1030
1031 dnl We actually may need to replace more than this.
1032 AC_REPLACE_FUNCS(getopt strdup tempnam)
1033
1034 dnl ----------------------------------------------------------------
1035 # Check Configuration
1036 OL_SYS_ERRLIST
1037
1038 dnl ----------------------------------------------------------------
1039 dnl Sort out defines
1040
1041 if test $ol_enable_debug != no ; then
1042         AC_DEFINE(LDAP_DEBUG,1)
1043 fi
1044 dnl     if test $ol_enable_syslog != no ; then
1045 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1046 dnl     fi
1047 if test $ol_enable_libui = yes ; then
1048         AC_DEFINE(LDAP_LIBUI,1)
1049 fi
1050 if test $ol_enable_cache = no ; then
1051         AC_DEFINE(LDAP_NOCACHE,1)
1052 fi
1053 if test $ol_enable_dns != no ; then
1054         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION,1)
1055 fi
1056 if test $ol_enable_proctitle != no ; then
1057         AC_DEFINE(LDAP_PROCTITLE,1)
1058 fi
1059 if test $ol_enable_referrals != no ; then
1060         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION,1)
1061 fi
1062 if test $ol_enable_cldap != no ; then
1063         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1064 fi
1065
1066 if test $ol_enable_aclgroups != no ; then
1067         AC_DEFINE(SLAPD_ACLGROUPS,1)
1068 fi
1069 if test $ol_enable_crypt != no ; then
1070         AC_DEFINE(SLAPD_CRYPT,1)
1071 fi
1072 if test $ol_enable_md5 != no ; then
1073         AC_DEFINE(SLAPD_MD5,1)
1074 fi
1075 if test $ol_enable_sha1 != no ; then
1076         AC_DEFINE(SLAPD_SHA1,1)
1077 fi
1078 if test $ol_enable_phonetic != no ; then
1079         AC_DEFINE(SLAPD_PHONETIC,1)
1080 fi
1081 if test $ol_enable_rlookups != no ; then
1082         AC_DEFINE(SLAPD_RLOOKUPS,1)
1083 fi
1084
1085 if test $ol_link_ldbm != no ; then
1086         AC_DEFINE(SLAPD_LDBM,1)
1087         BUILD_SLAPD=yes
1088         BUILD_LDBM=yes
1089 fi
1090
1091 if test $ol_enable_passwd != no ; then
1092         AC_DEFINE(SLAPD_PASSWD,1)
1093         BUILD_SLAPD=yes
1094         BUILD_PASSWD=yes
1095 fi
1096
1097 if test $ol_enable_shell != no ; then
1098         AC_DEFINE(SLAPD_SHELL,1)
1099         BUILD_SLAPD=yes
1100         BUILD_SHELL=yes
1101 fi
1102
1103 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1104         $BUILD_SLAPD = yes ; then
1105         BUILD_SLURPD=yes
1106 fi
1107
1108 if test $ol_link_isode != no ; then
1109         BUILD_LDAPD=yes
1110 fi
1111
1112 dnl ----------------------------------------------------------------
1113
1114 AC_SUBST(BUILD_LDAPD)
1115 AC_SUBST(BUILD_SLAPD)
1116   AC_SUBST(BUILD_LDBM)
1117   AC_SUBST(BUILD_PASSWD)
1118   AC_SUBST(BUILD_SHELL)
1119 AC_SUBST(BUILD_SLURPD)
1120
1121
1122 AC_SUBST(LDAP_LIBS)
1123 AC_SUBST(LDAPD_LIBS)
1124 AC_SUBST(SLAPD_LIBS)
1125 AC_SUBST(SLURPD_LIBS)
1126 AC_SUBST(LDBM_LIBS)
1127 AC_SUBST(LTHREAD_LIBS)
1128 AC_SUBST(LUTIL_LIBS)
1129
1130 AC_SUBST(KRB_LIBS)
1131 AC_SUBST(TERMCAP_LIBS)
1132
1133 dnl ----------------------------------------------------------------
1134 dnl final output
1135 dnl
1136
1137 AC_OUTPUT( \
1138 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1139 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1140 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1141 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1142 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1143 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1144 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1145 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1146 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1147 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1148 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1149 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1150 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1151 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1152 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1153 include/Makefile:build/top.mk:include/Makefile.in \
1154 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1155 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1156 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1157 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1158 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1159 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1160 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1161 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1162 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1163 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1164 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1165 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1166 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1167 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1168 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1169 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1170 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1171 tests/Makefile:build/top.mk:tests/Makefile.in \
1172 ,[
1173 date > stamp-h
1174 echo Please \"make depend\" to build dependencies
1175 ])