git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8
   9 dnl Configure.in for OpenLDAP
  10 AC_INIT(include/ldap.h)dnl
  11 AC_CONFIG_AUX_DIR(build)dnl
  12 AM_INIT_AUTOMAKE(OpenLDAP,[1.1-beta], [no ac_define])dnl
  13
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_PREREQ(2.10)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  43 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  44 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  54         auto, [auto k5 k4 afs yes no])
  55 OL_ARG_WITH(threads,[  --with-threads   use threads],
  56         auto, [auto posix mach lwp yes no manual] )
  57 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  58         auto, [auto yes no manual] )
  59
  60 dnl Server options
  61
  62 dnl LDAPD OPTIONS
  63 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  64 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  65
  66 dnl SLAPD OPTIONS
  67 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  68 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  69 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  70 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  71 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  72 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  73 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  74 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  75
  76 dnl SLAPD Backend options
  77 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  78 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  79         [auto db2 db gdbm ndbm manual])
  80 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  81         [auto btree hash])
  82
  83 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  84 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  85
  86 dnl SLURPD OPTIONS
  87 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  88 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  89
  90 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
  91 AM_ENABLE_STATIC
  92 AM_DISABLE_SHARED
  93 dnl AM_ENABLE_SHARED
  94
  95 dnl General "enable" options
  96 # validate options
  97 if test $ol_enable_referrals = no ; then
  98         if test $ol_enable_dns = yes ; then
  99                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
 100         fi
 101         ol_enable_dns=no
 102 fi
 103
 104 if test $ol_enable_slapd = no ; then
 105         dnl SLAPD was specificallly disabled
 106         if test $ol_enable_ldbm = yes ; then
 107                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 108         fi
 109         if test $ol_enable_passwd = yes ; then
 110                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 111         fi
 112         if test $ol_enable_shell = yes ; then
 113                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 114         fi
 115         if test $ol_enable_aclgroups = yes ; then
 116                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 117         fi
 118         if test $ol_enable_wrappers = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 120         fi
 121         if test $ol_enable_phonetic = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 123         fi
 124         if test $ol_enable_rlookups = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 126         fi
 127         if test $ol_with_ldbm_api != auto ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 129         fi
 130         if test $ol_with_ldbm_type != auto ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 132         fi
 133         if test $ol_enable_slurpd = yes ; then
 134                 AC_MSG_ERROR([slurpd requires slapd])
 135         fi
 136
 137         # force settings to no
 138         ol_enable_ldbm=no
 139         ol_enable_shell=no
 140         ol_enable_passwd=no
 141         ol_enable_aclgroups=no
 142         ol_enable_wrappers=no
 143         ol_enable_phonetic=no
 144         ol_enable_rlookups=no
 145         ol_with_ldbm_api=no
 146         ol_with_ldbm_type=no
 147         ol_enable_slurpd=no
 148
 149 elif test $ol_enable_ldbm = no ; then
 150         dnl SLAPD without LDBM
 151
 152         if test $ol_with_ldbm_api != auto ; then
 153                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 154         fi
 155
 156         if test $ol_with_ldbm_type != auto ; then
 157                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 158         fi
 159
 160         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 161                 AC_MSG_ERROR([slapd requires a backend])
 162         fi
 163
 164         ol_with_ldbm_api=no
 165         ol_with_ldbm_type=no
 166
 167 else
 168         dnl SLAPD with LDBM
 169
 170         if test $ol_with_ldbm_api = gdbm -a \
 171                 $ol_with_ldbm_type = btree ; then
 172                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 173         fi
 174         if test $ol_with_ldbm_api = ndbm -a \
 175                 $ol_with_ldbm_type = btree ; then
 176                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 177         fi
 178 fi
 179
 180 if test $ol_enable_slurpd = yes ; then
 181         dnl SLURPD was specifically enabled
 182         if test $ol_with_threads = no ; then
 183                 AC_MSG_ERROR([slurpd requires threads])
 184         fi
 185 fi
 186
 187 AC_MSG_RESULT(done)
 188
 189 AC_CANONICAL_HOST
 190
 191 ## Initialize vars
 192 LDAP_LIBS=
 193 LDBM_LIBS=
 194 LTHREAD_LIBS=
 195 LUTIL_LIBS=
 196
 197 LDAPD_LIBS=
 198 SLAPD_LIBS=
 199 SLURPD_LIBS=
 200
 201 BUILD_LDAPD=no
 202 BUILD_SLAPD=no
 203 BUILD_SLURPD=no
 204
 205 BUILD_LDBM=no
 206 BUILD_PASSWD=no
 207 BUILD_SHELL=no
 208 BUILD_THREAD=no
 209
 210 KRB_LIBS=
 211 TERMCAP_LIBS=
 212
 213 dnl ----------------------------------------------------------------
 214 dnl Checks for programs
 215
 216 AC_PROG_INSTALL
 217 AM_PROG_LIBTOOL
 218 dnl AC_PROG_MAKE_SET
 219
 220 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 221         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 222 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 223 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 224
 225 dnl Checks the compiler and UNIX Variants
 226
 227 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 228         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 229
 230 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 231         AC_MSG_WARN([programs compiled here do run here...])
 232         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 233
 234 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 235         AC_MSG_WARN([programs compiled here do not run here...])
 236         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 237 fi
 238
 239 AC_PROG_CPP
 240
 241 AC_AIX
 242 AC_ISC_POSIX
 243 AC_MINIX
 244
 245 dnl OpenLDAP requires STDC features
 246 AM_PROG_CC_STDC
 247 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 248         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 249 fi
 250
 251 dnl AM_C_PROTOTYPES
 252
 253 dnl Checks for libraries
 254
 255 dnl Find socket()
 256 dnl Likely combinations:
 257 dnl             -lsocket [ -lnsl_s | -lnsl ]
 258 dnl             -linet
 259
 260 AC_CHECK_FUNC(socket, [have_socket=yes], [
 261 dnl
 262 dnl hopefully we won't include too many libraries
 263 dnl
 264         AC_CHECK_LIB(socket, main)
 265         AC_CHECK_LIB(net, main)
 266         AC_CHECK_LIB(nsl_s, main)
 267         AC_CHECK_LIB(nsl, main)
 268         AC_CHECK_LIB(inet, socket)
 269         AC_CHECK_LIB(gen, main)
 270 ])
 271
 272 dnl Check for resolv
 273 AC_CHECK_LIB(resolv, res_search)
 274
 275 dnl HP-UX requires -lV3
 276 AC_CHECK_LIB(V3, sigset)
 277
 278 # ISODE tests
 279 ol_link_isode=no
 280 if test $ol_enable_ldapd != no ; then
 281         dnl look for ISODE libraries
 282         AC_CHECK_LIB(xtpp, main, [
 283                 ol_link_isode=yes
 284                 AC_DEFINE(HAVE_XTPP,1)
 285                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 286                 ],:,[-lxtdsap -lxtisode -losi])
 287         AC_CHECK_LIB(dsap, main, [
 288                 ol_link_isode=yes
 289                 AC_DEFINE(HAVE_DSAP,1)
 290                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 291                 ],:,[-lisode])
 292         AC_CHECK_LIB(isode, main, [
 293                 ol_link_isode=yes
 294                 AC_DEFINE(HAVE_ISODE,1)
 295                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 296                 ],:)
 297 fi
 298
 299 if test $ol_link_isode != no; then
 300         AC_CHECK_LIB(pp, main, [
 301                 AC_DEFINE(HAVE_PP,1)
 302                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 303                 ],:)
 304
 305         AC_PATH_PROG(PEPSY, pepsy)
 306 fi
 307
 308 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 309         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 310
 311         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 312                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 313                         [-lkrb5 -ldes425])
 314
 315                 if test $have_k5 = yes ; then
 316                         ol_with_kerberos=found
 317                         ol_link_kerberos=yes
 318
 319                         AC_DEFINE(HAVE_KERBEROS)
 320
 321                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 322                 fi
 323         fi
 324 fi
 325 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 326         AC_CHECK_HEADERS(krb.h des.h)
 327
 328         if test $ac_cv_header_krb_h = yes ; then
 329                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 330
 331                 if test $have_k4 = yes ; then
 332                         ol_with_kerberos=found
 333                         ol_link_kerberos=yes
 334
 335                         AC_DEFINE(HAVE_KERBEROS)
 336                         KRB_LIBS="-lkrb -ldes"
 337
 338                         AC_CHECK_FUNCS(des_string_to_key)
 339                 fi
 340         fi
 341 fi
 342
 343 ol_link_threads=no
 344 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 345         -o $ol_with_threads = posix ; then
 346
 347         AC_CHECK_HEADERS(pthread.h sched.h)
 348
 349         if test $ac_cv_header_pthread_h = yes ; then
 350                 OL_POSIX_THREAD_VERSION
 351
 352                 if test $ol_cv_pthread_version = final ; then
 353                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 354                 elif test $ol_cv_pthread_version = draft4 ; then
 355                         AC_DEFINE(HAVE_PTHREADS_D4)
 356                 else
 357                         AC_MSG_ERROR([unknown pthread version])
 358                 fi
 359
 360                 # consider threads found
 361                 ol_with_threads=found
 362
 363                 OL_LINUX_THREADS
 364
 365                 if test $ol_cv_linux_threads = yes ; then
 366                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 367                 fi
 368
 369                 dnl Now the hard part, how to link
 370
 371                 dnl Check for pthread support in current $LIBS
 372                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 373
 374                 if test $ol_link_threads = no ; then
 375                         dnl try -pthread
 376                         AC_CACHE_CHECK([for pthread_create with -pthread],
 377                                 [ol_cv_pthread_flag], [
 378                                 dnl save the flags
 379                                 save_LIBS="$LIBS"
 380                                 LIBS="-pthread $LIBS"
 381                                 AC_TRY_LINK([char pthread();],[
 382                                         pthread_create();
 383                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 384                                 dnl restore the LIBS
 385                                 LIBS="$save_LIBS"
 386                         ])
 387
 388                         if test $ol_cv_pthread_flag = yes ; then
 389                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 390                                 ol_link_threads=posix
 391                         fi
 392                 fi
 393
 394                 if test $ol_link_threads = no ; then
 395                         dnl try -pthreads
 396                         AC_CACHE_CHECK([for pthread_create with -pthreads],
 397                                 [ol_cv_pthreads_flag], [
 398                                 dnl save the flags
 399                                 save_LIBS="$LIBS"
 400                                 LIBS="-pthreads $LIBS"
 401                                 AC_TRY_LINK([char pthread();],[
 402                                         pthread_create();
 403                                         ], ol_cv_pthreads_flag=yes, ol_cv_pthreads_flag=no)
 404                                 dnl restore the LIBS
 405                                 LIBS="$save_LIBS"
 406                         ])
 407
 408                         if test $ol_cv_pthreads_flag = yes ; then
 409                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
 410                                 ol_link_threads=posix
 411                         fi
 412                 fi
 413
 414                 if test $ol_link_threads = no ; then
 415                         dnl try -thread
 416                         AC_CACHE_CHECK([for pthread_create with -thread],
 417                                 [ol_cv_thread_flag], [
 418                                 dnl save the flags
 419                                 save_LIBS="$LIBS"
 420                                 LIBS="-thread $LIBS"
 421                                 AC_TRY_LINK([char pthread();],[
 422                                         pthread_create();
 423                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 424                                 dnl restore the LIBS
 425                                 LIBS="$save_LIBS"
 426                         ])
 427
 428                         if test $ol_cv_thread_flag = yes ; then
 429                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 430                                 ol_link_threads=posix
 431                         fi
 432                 fi
 433
 434                 if test $ol_link_threads = no ; then
 435                         dnl try DEC Threads -lpthread -lexc
 436                         save_LIBS="$LIBS"
 437                         AC_CHECK_LIB(pthread, pthread_join, [
 438                                 ol_link_threads=posix
 439                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 440                                 if test $ol_with_yielding_select = auto ; then
 441                                         ol_with_yielding_select=yes
 442                                 fi
 443                                 ],,[-lexc])
 444                         LIBS="$save_LIBS"
 445                 fi
 446
 447                 if test $ol_link_threads = no ; then
 448                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 449                         save_LIBS="$LIBS"
 450                         AC_CHECK_LIB(pthreads, pthread_join, [
 451                                 ol_link_threads=posix
 452                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 453                                 if test $ol_with_yielding_select = auto ; then
 454                                         ol_with_yielding_select=yes
 455                                 fi
 456                                 ],,[-lmach -lexc -lc_r])
 457                         LIBS="$save_LIBS"
 458                 fi
 459
 460                 if test $ol_link_threads = no ; then
 461                         dnl try -lpthread
 462                         save_LIBS="$LIBS"
 463                         AC_CHECK_LIB(pthread, pthread_create, [
 464                                 ol_link_threads=posix
 465                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 466                         LIBS="$save_LIBS"
 467                 fi
 468
 469                 if test $ol_link_threads = no ; then
 470                         dnl try -lc_r
 471                         save_LIBS="$LIBS"
 472                         AC_CHECK_LIB(c_r, pthread_create, [
 473                                 ol_link_threads=posix
 474                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 475                         LIBS="$save_LIBS"
 476                 fi
 477
 478                 if test $ol_link_threads != no ; then
 479                         AC_DEFINE(HAVE_PTHREADS)
 480
 481                         dnl save flags
 482                         save_CPPFLAGS="$CPPFLAGS"
 483                         save_LIBS="$LIBS"
 484                         LIBS="$LTHREAD_LIBS $LIBS"
 485
 486                         dnl All POSIX Thread (final) implementations should have
 487                         dnl sched_yield instead of pthread yield.
 488                         dnl check for both
 489                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 490
 491                         if test $ac_cv_func_sched_yield = no -a \
 492                                 $ac_cv_func_pthread_yield = no ; then
 493                                 dnl Digital UNIX has sched_yield() in -lrt
 494                                 AC_CHECK_LIB(rt, sched_yield,
 495                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 496                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 497                                         ac_cv_func_sched_yield=yes],
 498                                         [ac_cv_func_sched_yield=no])
 499                         fi
 500                         if test $ac_cv_func_sched_yield = no -a \
 501                                 $ac_cv_func_pthread_yield = no ; then
 502                                 dnl Solaris has sched_yield() in -lposix4
 503                                 AC_CHECK_LIB(posix4, sched_yield,
 504                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 505                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 506                                         ac_cv_func_sched_yield=yes],
 507                                         [ac_cv_func_sched_yield=no])
 508                         fi
 509                         if test $ac_cv_func_sched_yield = no -a \
 510                                 $ac_cv_func_pthread_yield = no ; then
 511                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 512                                 AC_MSG_ERROR([POSIX Threads are not usable])
 513                         fi
 514
 515                         dnl Check functions for compatibility
 516                         AC_CHECK_FUNCS(pthread_kill)
 517                         AC_CHECK_FUNCS( \
 518                                 pthread_attr_create pthread_attr_init \
 519                                 pthread_attr_destroy pthread_attr_delete \
 520                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 521                         )
 522
 523                         dnl Check for setconcurreny functions
 524                         AC_CHECK_FUNCS( \
 525                                 pthread_setconcurrency \
 526                                 thr_setconcurrency \
 527                         )
 528
 529                         AC_MSG_CHECKING([if pthread_create() works])
 530                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 531                         AC_TRY_RUN([
 532 #include <pthread.h>
 533 #ifndef NULL
 534 #define NULL (void*)0
 535 #endif
 536
 537 static void *task(p)
 538         void *p;
 539 {
 540         return (void *) (p == NULL);
 541 }
 542
 543 int main(argc, argv)
 544         int argc;
 545         char **argv;
 546 {
 547         pthread_t t;
 548         exit(pthread_create(&t, NULL, task, NULL));
 549 }
 550 ],
 551                                 [ol_cv_pthread_create_works=yes],
 552                                 [ol_cv_pthread_create_works=no],
 553                                 [dnl assume yes
 554                                 ol_cv_pthread_create_works=yes])])
 555                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 556
 557                         if test $ol_cv_pthread_create_works = no ; then
 558                                 AC_MSG_ERROR([pthread.h and pthread_create are not compatible])
 559                         fi
 560
 561                         dnl Check if select causes an yield
 562                         if test $ol_with_yielding_select = auto ; then
 563                                 AC_MSG_CHECKING([if select yields when using pthreads])
 564                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 565                                 AC_TRY_RUN([
 566 #include <sys/types.h>
 567 #include <sys/time.h>
 568 #include <unistd.h>
 569 #include <pthread.h>
 570 #ifndef NULL
 571 #define NULL (void*) 0
 572 #endif
 573
 574 static int fildes[2];
 575
 576 static void *task(p)
 577         void *p;
 578 {
 579         int i;
 580         struct timeval tv;
 581
 582         fd_set rfds;
 583
 584         tv.tv_sec=10;
 585         tv.tv_usec=0;
 586
 587         FD_ZERO(&rfds);
 588         FD_SET(fildes[0], &rfds);
 589
 590         /* we're not interested in any fds */
 591         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 592
 593         if(i < 0) {
 594                 perror("select");
 595                 exit(0);
 596         }
 597
 598         exit(1); /* if we exit here, the select blocked the whole process */
 599 }
 600
 601 int main(argc, argv)
 602         int argc;
 603         char **argv;
 604 {
 605         pthread_t t;
 606
 607         /* create a pipe to select */
 608         if(pipe(&fildes[0])) {
 609                 perror("select");
 610                 exit(0);
 611         }
 612
 613 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 614         (void) pthread_setconcurrency(2);
 615 #else
 616 #ifdef HAVE_THR_SETCONCURRENCY
 617         /* Set Solaris LWP concurrency to 2 */
 618         thr_setconcurrency(2);
 619 #endif
 620 #endif
 621
 622         pthread_create(&t, NULL, task, NULL);
 623
 624 #if HAVE_SCHED_YIELD
 625         sched_yield();  /* make sure task runs first */
 626 #else
 627 #ifdef HAVE_PTHREAD_YIELD
 628         pthread_yield();        /* make sure task runs first */
 629 #endif
 630 #endif
 631         exit(0);
 632 }],
 633                                 [ol_cv_pthread_select_yields=yes],
 634                                 [ol_cv_pthread_select_yields=no], [
 635                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 636                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 637
 638                                 if test $ol_cv_pthread_select_yields = yes ; then
 639                                         ol_with_yielding_select=yes
 640                                 fi
 641                         fi
 642
 643 dnl                     dnl check for reentrant/threadsafe functions
 644 dnl                     AC_CHECK_FUNCS( \
 645 dnl                             feof_unlocked \
 646 dnl                             unlocked_feof \
 647 dnl                             ftrylockfile \
 648 dnl                             flockfile \
 649 dnl                             putc_unlocked \
 650 dnl                             gmtime_r \
 651 dnl                             strtok_r \
 652 dnl                     )
 653
 654                         dnl restore flags
 655                         CPPFLAGS="$save_CPPFLAGS"
 656                         LIBS="$save_LIBS"
 657                 else
 658                         AC_MSG_ERROR([could not link with POSIX Threads])
 659                 fi
 660         fi
 661
 662         if test $ol_with_threads = posix ; then
 663                 AC_MSG_ERROR([could not locate POSIX Threads])
 664         fi
 665 fi
 666
 667 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 668         -o $ol_with_threads = mach ; then
 669
 670         dnl check for Mach CThreads
 671         AC_CHECK_HEADERS(mach/cthreads.h)
 672         if test $ac_cv_header_mach_cthreads_h = yes ; then
 673                 ol_with_threads=found
 674
 675                 dnl check for cthread support in current $LIBS
 676                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 677
 678                 if test $ol_link_threads = no ; then
 679                         dnl try -all_load
 680                         dnl this test needs work
 681                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 682                                 [ol_cv_cthread_all_load], [
 683                                 dnl save the flags
 684                                 save_LIBS="$LIBS"
 685                                 LIBS="-all_load $LIBS"
 686                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 687                                         cthread_fork((void *)0, (void *)0);
 688                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 689                                 dnl restore the LIBS
 690                                 LIBS="$save_LIBS"
 691                         ])
 692
 693                         if test $ol_cv_cthread_all_load = yes ; then
 694                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 695                                 ol_link_threads=mach
 696                         fi
 697                 fi
 698
 699                 if test $ol_link_threads != no ; then
 700                         : check for cthread specific functionality here
 701                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 702                 else
 703                         AC_MSG_ERROR([could not link with Mach CThreads])
 704                 fi
 705         fi
 706
 707         if test $ol_with_threads = mach ; then
 708                 AC_MSG_ERROR([could not locate Mach CThreads])
 709         fi
 710 fi
 711
 712 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 713         -o $ol_with_threads = lwp ; then
 714
 715         dnl check for SunOS5 LWP
 716         AC_CHECK_HEADERS(thread.h synch.h)
 717         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 718                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 719
 720                 if test $have_thr = yes ; then
 721                         AC_DEFINE(HAVE_THR)
 722                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 723                         ol_link_threads=thr
 724
 725                         if test $ol_with_yielding_select = auto ; then
 726                                 ol_with_yielding_select=yes
 727                         fi
 728                 fi
 729         fi
 730
 731         dnl check for SunOS4 LWP
 732         AC_CHECK_HEADERS(lwp/lwp.h)
 733         if test $ac_cv_header_lwp_lwp_h = yes ; then
 734                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 735
 736                 if test $have_lwp = yes ; then
 737                         AC_DEFINE(HAVE_LWP)
 738                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 739                         ol_link_threads=lwp
 740
 741                         if test $ol_with_yielding_select = auto ; then
 742                                 ol_with_yielding_select=no
 743                         fi
 744                 fi
 745         fi
 746 fi
 747
 748 if test $ol_with_yielding_select = yes ; then
 749         AC_DEFINE(HAVE_YIELDING_SELECT,1)
 750 fi
 751
 752 if test $ol_with_threads = manual ; then
 753         dnl User thinks he can manually configure threads.
 754         ol_link_threads=yes
 755
 756         AC_MSG_WARN([thread defines and link options must be set manually])
 757
 758         AC_CHECK_HEADERS(pthread.h sched.h)
 759         AC_CHECK_FUNCS(sched_yield pthread_yield)
 760         OL_LINUX_THREADS
 761
 762         AC_CHECK_HEADERS(mach/cthreads.h)
 763         AC_CHECK_HEADERS(lwp/lwp.h)
 764         AC_CHECK_HEADERS(thread.h synch.h)
 765 fi
 766
 767 if test $ol_link_threads != no ; then
 768         dnl needed to get reentrant/threadsafe versions
 769         dnl
 770         AC_DEFINE(REENTRANT,1)
 771         AC_DEFINE(_REENTRANT,1)
 772         AC_DEFINE(THREAD_SAFE,1)
 773         AC_DEFINE(_THREAD_SAFE,1)
 774         AC_DEFINE(THREADSAFE,1)
 775         AC_DEFINE(_THREADSAFE,1)
 776
 777         dnl this might cause the errno symbol to be
 778         dnl replaced with a function to get a thread specific errno.
 779         dnl check to see if everything needs to be compiled
 780         dnl with the thread libraries
 781         AC_CACHE_CHECK([for thread specific errno],
 782                 [ol_cv_errno_thread_specific], [
 783                 AC_TRY_LINK([
 784 #include <errno.h>
 785                         ], [
 786 int x = errno;
 787                         ],
 788                         [ol_cv_errno_thread_specific=yes],
 789                         [ol_cv_errno_thread_specific=no])
 790         ])
 791
 792         if test $ol_cv_errno_thread_specific != yes ; then
 793                 LIBS="$LTHREAD_LIBS $LIBS"
 794                 LTHREAD_LIBS=""
 795         fi
 796 fi
 797
 798 dnl ----------------------------------------------------------------
 799
 800 if test $ol_link_threads = no ; then
 801         if test $ol_with_threads = yes ; then
 802                 AC_MSG_ERROR([no suitable thread support])
 803         fi
 804
 805         if test $ol_with_threads = auto ; then
 806                 AC_MSG_WARN([no suitable thread support, disabling threads])
 807                 ol_with_threads=no
 808         fi
 809
 810         AC_DEFINE(NO_THREADS,1)
 811         LTHREAD_LIBS=""
 812 fi
 813
 814 ol_link_ldbm=no
 815 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 816         OL_BERKELEY_DB2
 817
 818         if test $ol_cv_berkeley_db2 = yes ; then
 819                 ol_link_ldbm=db2
 820                 ol_with_ldbm_api=db2
 821
 822                 if test $ol_with_ldbm_type = hash ; then
 823                         AC_DEFINE(LDBM_USE_DBHASH,1)
 824                 else
 825                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 826                 fi
 827
 828                 dnl $ol_cv_lib_db2 should be yes or -ldb
 829                 dnl (it could be no, but that would be an error
 830                 if test $ol_cv_lib_db2 != yes ; then
 831                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 832                 fi
 833         fi
 834 fi
 835
 836 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 837         OL_BERKELEY_DB
 838
 839         if test $ol_cv_berkeley_db = yes ; then
 840                 ol_link_ldbm=db
 841                 ol_with_ldbm_api=db
 842
 843                 if test $ol_with_ldbm_type = hash ; then
 844                         AC_DEFINE(LDBM_USE_DBHASH,1)
 845                 else
 846                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 847                 fi
 848
 849                 dnl $ol_cv_lib_db should be yes or -ldb
 850                 dnl (it could be no, but that would be an error
 851                 if test $ol_cv_lib_db != yes ; then
 852                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 853                 fi
 854         fi
 855 fi
 856
 857 if test $ol_with_ldbm_api = manual ; then
 858         dnl User thinks he can manually configure LDBM api.
 859         ol_link_ldbm=yes
 860
 861         AC_MSG_WARN([LDBM defines and link options must be set manually])
 862
 863         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 864 fi
 865
 866 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 867         AC_MSG_WARN(Could not find LDBM with BTREE support)
 868         ol_with_ldbm_api=none
 869 fi
 870
 871 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 872         OL_GDBM
 873
 874         if test $ol_cv_gdbm = yes ; then
 875                 ol_link_ldbm=gdbm
 876                 ol_with_ldbm_api=gdbm
 877
 878                 if test $ol_cv_lib_gdbm != yes ; then
 879                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 880                 fi
 881         fi
 882 fi
 883
 884 if test $ol_with_ldbm_api = auto ; then
 885         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
 886 elif test $ol_with_ldbm_api = ndbm ; then
 887         OL_NDBM
 888
 889         if test $ol_cv_ndbm = yes ; then
 890                 ol_link_ldbm=ndbm
 891                 ol_with_ldbm_api=ndbm
 892
 893                 if test $ol_cv_lib_ndbm != yes ; then
 894                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 895                 fi
 896         fi
 897 fi
 898
 899 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 900         AC_MSG_WARN(could not find suitable LDBM backend)
 901         if test $ol_enable_ldbm = yes ; then
 902                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 903         fi
 904
 905         AC_MSG_WARN(disabling LDBM)
 906         ol_enable_ldbm=no
 907 fi
 908
 909 if test $ol_enable_wrappers = yes ; then
 910         AC_CHECK_LIB(wrap, hosts_access,
 911                 [have_wrappers=yes], [have_wrappers=no])
 912
 913         if test $have_wrappers = yes ; then
 914                 AC_DEFINE(HAVE_TCPD)
 915                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 916         else
 917                 AC_MSG_WARN(could not find -lwrap)
 918                 if test $ol_enable_wrappers = yes ; then
 919                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 920                 fi
 921
 922                 AC_MSG_WARN(disabling wrappers support)
 923                 ol_enable_wrappers=no
 924         fi
 925
 926 fi
 927
 928 # ud needs termcap (should insert check here)
 929 ol_link_termcap=no
 930 AC_CHECK_HEADERS(termcap.h ncurses.h)
 931
 932 if test $ol_link_termcap = no ; then
 933         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 934         if test $have_termcap = yes ; then
 935                 AC_DEFINE(HAVE_TERMCAP)
 936                 ol_link_termcap=yes
 937                 TERMCAP_LIBS=-ltermcap
 938         fi
 939 fi
 940
 941 if test $ol_link_termcap = no ; then
 942         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 943         if test $have_ncurses = yes ; then
 944                 AC_DEFINE(HAVE_NCURSES)
 945                 ol_link_termcap=yes
 946                 TERMCAP_LIBS=-lncurses
 947         fi
 948 fi
 949
 950 if test $ol_link_termcap = no ; then
 951         AC_DEFINE(NO_TERMCAP,1)
 952         TERMCAP_LIBS=
 953 fi
 954
 955 # FreeBSD (and others) have crypt(3) in -lcrypt
 956 if test $ol_enable_crypt != no ; then
 957         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 958                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 959                         have_crypt=yes], [have_crypt=no])])
 960
 961         if test $have_crypt = yes ; then
 962                 AC_DEFINE(HAVE_CRYPT,1)
 963         else
 964                 AC_MSG_WARN(could not find crypt)
 965                 if test $ol_enable_crypt = yes ; then
 966                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 967                 fi
 968
 969                 AC_MSG_WARN(disabling crypt support)
 970                 ol_enable_crypt=no
 971         fi
 972 fi
 973
 974 # FreeBSD (and others) have setproctitle(3) in -lutil
 975 if test $ol_enable_proctitle != no ; then
 976         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 977                 AC_CHECK_LIB(util, setproctitle,
 978                         [have_setproctitle=yes
 979                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 980                         [have_setproctitle=no
 981                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 982
 983         if test $have_setproctitle = yes ; then
 984                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 985         fi
 986 fi
 987
 988 dnl ----------------------------------------------------------------
 989 dnl Checks for header files.
 990 AC_HEADER_STDC
 991
 992 if test $ac_cv_header_stdc != yes; then
 993         AC_MSG_WARN([could not Standard C compliant headers])
 994 fi
 995
 996 AC_HEADER_DIRENT
 997 AC_HEADER_SYS_WAIT
 998 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 999 if test $am_cv_sys_posix_termios = yes ; then
1000         AC_DEFINE(HAVE_POSIX_TERMIOS,1)
1001 fi
1002
1003 AC_CHECK_HEADERS(       \
1004         crypt.h                 \
1005         errno.h                 \
1006         fcntl.h                 \
1007         filio.h                 \
1008         getopt.h                \
1009         libutil.h               \
1010         limits.h                \
1011         malloc.h                \
1012         memory.h                \
1013         regex.h                 \
1014         psap.h                  \
1015         pwd.h                   \
1016         sgtty.h                 \
1017         stdarg.h                \
1018         stddef.h                \
1019         string.h                \
1020         strings.h               \
1021         sys/file.h              \
1022         sys/filio.h             \
1023         sys/errno.h             \
1024         sys/ioctl.h             \
1025         sys/param.h             \
1026         sys/resource.h  \
1027         sys/socket.h    \
1028         sys/syslog.h    \
1029         sys/time.h              \
1030         sys/types.h             \
1031         syslog.h                \
1032         termios.h               \
1033         unistd.h                \
1034 )
1035
1036 dnl ----------------------------------------------------------------
1037 dnl Checks for typedefs, structures, and compiler characteristics.
1038 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1039 AC_TYPE_MODE_T
1040 AC_TYPE_OFF_T
1041 AC_TYPE_PID_T
1042 AM_TYPE_PTRDIFF_T
1043 AC_TYPE_SIGNAL
1044 AC_TYPE_SIZE_T
1045 AC_STRUCT_ST_BLKSIZE
1046 AC_HEADER_TIME
1047 AC_STRUCT_TM
1048
1049 OL_C_UPPER_LOWER
1050 AC_C_CONST
1051
1052 if test $cross_compiling = yes ; then
1053         AC_DEFINE(CROSS_COMPILING, 1)
1054 else
1055         AC_C_BIGENDIAN
1056         AC_CHECK_SIZEOF(short)
1057         AC_CHECK_SIZEOF(int)
1058         AC_CHECK_SIZEOF(long)
1059 fi
1060
1061 dnl ----------------------------------------------------------------
1062 dnl Checks for library functions.
1063 AC_FUNC_MEMCMP
1064 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1065 AC_FUNC_STRFTIME
1066 dnl AM_FUNC_STRTOD
1067 AC_FUNC_VPRINTF
1068
1069 if test $ac_cv_func_vprintf = yes ; then
1070         dnl check for vsnprintf
1071         AC_CHECK_FUNCS(vsnprintf)
1072 fi
1073
1074 AC_FUNC_WAIT3
1075
1076 AC_CHECK_FUNCS(         \
1077         bcopy                   \
1078         flock                   \
1079         getdtablesize   \
1080         gethostname             \
1081         getpwuid                \
1082         gettimeofday    \
1083         lockf                   \
1084         memcpy                  \
1085         memmove                 \
1086         mkstemp                 \
1087         res_search              \
1088         select                  \
1089         setpwfile               \
1090         setsid                  \
1091         signal                  \
1092         sigset                  \
1093         snprintf                \
1094         socket                  \
1095         strerror                \
1096         strpbrk                 \
1097         strrchr                 \
1098         strsep                  \
1099         strstr                  \
1100         strtok                  \
1101         strtol                  \
1102         strtoul                 \
1103         sysconf                 \
1104         waitpid                 \
1105 )
1106
1107 dnl We actually may need to replace more than this.
1108 AC_REPLACE_FUNCS(getopt strdup tempnam)
1109
1110 dnl ----------------------------------------------------------------
1111 # Check Configuration
1112 OL_SYS_ERRLIST
1113
1114 dnl ----------------------------------------------------------------
1115 dnl Sort out defines
1116
1117 if test $ol_enable_debug != no ; then
1118         AC_DEFINE(LDAP_DEBUG,1)
1119 fi
1120 dnl     if test $ol_enable_syslog != no ; then
1121 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1122 dnl     fi
1123 if test $ol_enable_libui = yes ; then
1124         AC_DEFINE(LDAP_LIBUI,1)
1125 fi
1126 if test $ol_enable_cache = no ; then
1127         AC_DEFINE(LDAP_NOCACHE,1)
1128 fi
1129 if test $ol_enable_dns != no ; then
1130         AC_DEFINE(LDAP_DNS,1)
1131 fi
1132 if test $ol_enable_proctitle != no ; then
1133         AC_DEFINE(LDAP_PROCTITLE,1)
1134 fi
1135 if test $ol_enable_referrals != no ; then
1136         AC_DEFINE(LDAP_REFERRALS,1)
1137 fi
1138 if test $ol_enable_cldap != no ; then
1139         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1140 fi
1141
1142 if test $ol_enable_aclgroups != no ; then
1143         AC_DEFINE(SLAPD_ACLGROUPS,1)
1144 fi
1145 if test $ol_enable_crypt != no ; then
1146         AC_DEFINE(SLAPD_CRYPT,1)
1147 fi
1148 if test $ol_enable_cleartext != no ; then
1149         AC_DEFINE(SLAPD_CLEARTEXT,1)
1150 fi
1151 if test $ol_enable_phonetic != no ; then
1152         AC_DEFINE(SLAPD_PHONETIC,1)
1153 fi
1154 if test $ol_enable_rlookups != no ; then
1155         AC_DEFINE(SLAPD_RLOOKUPS,1)
1156 fi
1157
1158 if test $ol_link_ldbm != no ; then
1159         AC_DEFINE(SLAPD_LDBM,1)
1160         BUILD_SLAPD=yes
1161         BUILD_LDBM=yes
1162 fi
1163
1164 if test $ol_enable_passwd != no ; then
1165         AC_DEFINE(SLAPD_PASSWD,1)
1166         BUILD_SLAPD=yes
1167         BUILD_PASSWD=yes
1168 fi
1169
1170 if test $ol_enable_shell != no ; then
1171         AC_DEFINE(SLAPD_SHELL,1)
1172         BUILD_SLAPD=yes
1173         BUILD_SHELL=yes
1174 fi
1175
1176 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1177         $BUILD_SLAPD = yes ; then
1178         BUILD_SLURPD=yes
1179 fi
1180
1181 if test $ol_link_isode != no ; then
1182         BUILD_LDAPD=yes
1183 fi
1184
1185 dnl ----------------------------------------------------------------
1186
1187 AC_SUBST(BUILD_LDAPD)
1188 AC_SUBST(BUILD_SLAPD)
1189   AC_SUBST(BUILD_LDBM)
1190   AC_SUBST(BUILD_PASSWD)
1191   AC_SUBST(BUILD_SHELL)
1192 AC_SUBST(BUILD_SLURPD)
1193
1194
1195 AC_SUBST(LDAP_LIBS)
1196 AC_SUBST(LDAPD_LIBS)
1197 AC_SUBST(SLAPD_LIBS)
1198 AC_SUBST(SLURPD_LIBS)
1199 AC_SUBST(LDBM_LIBS)
1200 AC_SUBST(LTHREAD_LIBS)
1201 AC_SUBST(LUTIL_LIBS)
1202
1203 AC_SUBST(KRB_LIBS)
1204 AC_SUBST(TERMCAP_LIBS)
1205
1206 dnl ----------------------------------------------------------------
1207 dnl final output
1208 dnl
1209
1210 AC_OUTPUT( \
1211 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1212 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1213 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1214 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1215 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1216 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1217 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1218 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1219 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1220 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1221 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1222 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1223 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1224 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1225 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1226 include/Makefile:build/top.mk:include/Makefile.in \
1227 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1228 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1229 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1230 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1231 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1232 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1233 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk:build/lib-static.mk    \
1234 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1235 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1236 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1237 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1238 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1239 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1240 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1241 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1242 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1243 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1244 tests/Makefile:build/top.mk:tests/Makefile.in \
1245 ,[
1246 date > stamp-h
1247 echo Please \"make depend\" to build dependencies
1248 ])