git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Copying restrictions apply, see COPYRIGHT file."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35 AC_CONFIG_AUX_DIR(build)dnl
  36
  37 OL_VERSION=`cat $ac_aux_dir/version`
  38 if test -z "$OL_VERSION"; then
  39         AC_MSG_ERROR([could not determine version])
  40 fi
  41
  42 echo "Configuring OpenLDAP $OL_VERSION ..."
  43
  44 dnl Determine host platform
  45 dnl             we try not to use this for much
  46 AC_CANONICAL_SYSTEM
  47
  48 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  49 AC_SUBST(PACKAGE)
  50 AC_SUBST(VERSION)
  51 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  52 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  53
  54 dnl We use autoconf features new to 2.13.
  55 dnl aclocal.m4 should be built using aclocal from automake 1.4
  56 dnl libtool 1.3.3 should be installed.
  57 AC_PREREQ(2.13)dnl Required Autoconf version
  58
  59 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  60
  61 dnl ================================================================
  62 dnl Start Args
  63 AC_MSG_CHECKING(configure arguments)
  64 AC_PREFIX_DEFAULT(/usr/local)
  65
  66 top_builddir=`pwd`
  67 AC_SUBST(top_builddir)dnl
  68
  69 dnl ----------------------------------------------------------------
  70 dnl --with-subdir
  71 ldap_subdir="/openldap"
  72
  73 AC_ARG_WITH(subdir,
  74 [  --with-subdir=DIR change default subdirectory used for installs],
  75 [case "$withval" in
  76         no) ldap_subdir=""
  77                 ;;
  78         yes)
  79                 ;;
  80         /*|\\*)
  81                 ldap_subdir="$withval"
  82                 ;;
  83         *)
  84                 ldap_subdir="/$withval"
  85                 ;;
  86 esac
  87 ])dnl
  88
  89 AC_SUBST(ldap_subdir)dnl
  90
  91 dnl ----------------------------------------------------------------
  92 dnl General "enable" options
  93 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  94 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  95 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  96 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  97 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DX Referrals extension], no)dnl
  98 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  99 OL_ARG_ENABLE(kbind,[  --enable-kbind   enable V2 Kerberos IV bind], auto)dnl
 100 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
 101 OL_ARG_ENABLE(ldapi,[  --enable-ldapi   enable domain socket (PF_LOCAL) ldap], no)dnl
 102 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
 103         no, [yes no])dnl
 104
 105 dnl ----------------------------------------------------------------
 106 dnl General "with" options
 107 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
 108
 109 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
 110         auto, [auto yes no] )
 111 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
 112         auto, [auto yes no] )
 113 OL_ARG_WITH(kerberos,[  --with-kerberos with support],
 114         auto, [auto k5 k5only k425 kth k4 afs yes no])
 115 OL_ARG_WITH(readline,[  --with-readline with readline support],
 116         auto, [auto yes no] )
 117 OL_ARG_WITH(threads,[  --with-threads   use threads],
 118         auto, [auto nt posix mach pth lwp yes no manual] )
 119 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
 120         auto, [auto ssleay openssl yes no] )
 121 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
 122         auto, [auto yes no manual] )
 123
 124 dnl ----------------------------------------------------------------
 125 dnl Server options
 126 dnl ----------------------------------------------------------------
 127 dnl LDAPD OPTIONS
 128 AC_ARG_WITH(xxldapdoptions,[LDAPD (X.500-to-LDAP Gateway) Options:])
 129 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
 130
 131 dnl ----------------------------------------------------------------
 132 dnl SLAPD OPTIONS
 133 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 134 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 135 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 136 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 137 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd     enable kerberos password verification], no)dnl
 138 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 139 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 140 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 141 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 142 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 143 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 144 OL_ARG_ENABLE(discreteaci,[    --enable-discreteaci     enable discrete rights in ACIs], no)dnl
 145 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 146 OL_ARG_ENABLE(dynamic,[    --enable-dynamic     enable linking built binaries with dynamic libs], no)dnl
 147
 148 dnl SLAPD Backend options
 149 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 150 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 151         [static dynamic])
 152 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 153 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 154         [static dynamic])
 155 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 156 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 157         [auto db2 db mdbm gdbm ndbm manual])
 158 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 159         [static dynamic])
 160 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 161         [auto btree hash])
 162
 163 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 164 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 165         [static dynamic])
 166 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 167 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 168         [static dynamic])
 169 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 170 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 171         [static dynamic])
 172 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 173 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 174         [static dynamic])
 175
 176 dnl ----------------------------------------------------------------
 177 dnl SLURPD OPTIONS
 178 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 179 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 180
 181 dnl ----------------------------------------------------------------
 182 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 183 AC_ENABLE_STATIC
 184 dnl AC_DISABLE_SHARED
 185 AC_ENABLE_SHARED
 186
 187 dnl ----------------------------------------------------------------
 188
 189 dnl General "enable" options
 190 # validate options
 191 if test $ol_enable_dns = yes ; then
 192         if test $ol_enable_referrals = no ; then
 193                 AC_MSG_ERROR([DNS requires --enable-referrals])
 194         fi
 195         if test $ol_enable_referrals = auto ; then
 196                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 197                 ol_enable_referrals=yes
 198         fi
 199 fi
 200
 201 if test $ol_enable_slapd = no ; then
 202         dnl SLAPD was specificallly disabled
 203         if test $ol_enable_bdb2 = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 205         fi
 206         if test $ol_enable_ldap = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 208         fi
 209         if test $ol_enable_ldbm = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 211         fi
 212         if test $ol_enable_passwd = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 214         fi
 215         if test $ol_enable_perl = yes ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 217         fi
 218         if test $ol_enable_shell = yes ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 220         fi
 221         if test $ol_enable_tcl = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 223         fi
 224         if test $ol_enable_modules = yes ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 226         fi
 227         if test $ol_enable_multimaster = yes ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 229         fi
 230         if test $ol_enable_wrappers = yes ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 232         fi
 233         if test $ol_enable_phonetic = yes ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 235         fi
 236         if test $ol_enable_quipu = yes ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 238         fi
 239         if test $ol_enable_rlookups = yes ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 241         fi
 242         if test $ol_enable_aci = yes ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 244         fi
 245         if test $ol_enable_discreteaci = yes ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --enable-discreteaci argument])
 247         fi
 248         if test $ol_with_ldbm_api != auto ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 250         fi
 251         if test $ol_with_ldbm_type != auto ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 253         fi
 254         if test $ol_with_bdb2_module != static ; then
 255                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 256         fi
 257         if test $ol_with_ldap_module != static ; then
 258                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 259         fi
 260         if test $ol_with_ldbm_module != static ; then
 261                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 262         fi
 263         if test $ol_with_passwd_module != static ; then
 264                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 265         fi
 266         if test $ol_with_perl_module != static ; then
 267                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 268         fi
 269         if test $ol_with_shell_module != static ; then
 270                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 271         fi
 272         if test $ol_with_tcl_module != static ; then
 273                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 274         fi
 275         if test $ol_enable_slurpd = yes ; then
 276                 AC_MSG_ERROR([slurpd requires slapd])
 277         fi
 278
 279         # force settings to no
 280         ol_enable_bdb2=no
 281         ol_enable_ldap=no
 282         ol_enable_ldbm=no
 283         ol_enable_passwd=no
 284         ol_enable_perl=no
 285         ol_enable_shell=no
 286         ol_enable_tcl=no
 287
 288         ol_enable_modules=no
 289         ol_enable_multimaster=no
 290         ol_enable_phonetic=no
 291         ol_enable_quipu=no
 292         ol_enable_rlookups=no
 293         ol_enable_aci=no
 294         ol_enable_discreteaci=no
 295         ol_enable_wrappers=no
 296         ol_enable_dynamic=no
 297
 298         ol_with_ldbm_api=no
 299         ol_with_ldbm_type=no
 300
 301         ol_with_bdb2_module=static
 302         ol_with_ldap_module=static
 303         ol_with_ldbm_module=static
 304         ol_with_passwd_module=static
 305         ol_with_perl_module=static
 306         ol_with_shell_module=static
 307         ol_with_tcl_module=static
 308
 309         ol_enable_slurpd=no
 310
 311 elif test $ol_enable_ldbm = no ; then
 312         dnl SLAPD without LDBM
 313
 314         if test $ol_with_ldbm_api != auto ; then
 315                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 316         fi
 317
 318         if test $ol_with_ldbm_type != auto ; then
 319                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 320         fi
 321
 322         if test $ol_with_ldbm_module != static ; then
 323                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 324         fi
 325
 326         if test $ol_enable_bdb2 = yes ; then
 327                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 328         fi
 329
 330         if test $ol_enable_modules != yes -a \
 331                 $ol_enable_ldap = no -a \
 332                 $ol_enable_passwd = no -a \
 333                 $ol_enable_perl = no -a \
 334                 $ol_enable_shell = no -a \
 335                 $ol_enable_tcl = no ; then
 336                 AC_MSG_ERROR([slapd requires a backend])
 337         fi
 338
 339         ol_with_ldbm_api=no
 340         ol_with_ldbm_type=no
 341         ol_with_ldbm_module=static
 342
 343 elif test $ol_enable_bdb2 = yes ; then
 344         dnl SLAPD with BDB2
 345
 346         if test $ol_with_ldbm_api != auto -a \
 347                 $ol_with_ldbm_api != db2 ; then
 348                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 349         fi
 350
 351         ol_with_ldbm_api=db2
 352
 353 else
 354         dnl SLAPD with LDBM
 355
 356         if test $ol_enable_bdb2 != no ; then
 357                 if test $ol_with_ldbm_api != auto -a \
 358                         $ol_with_ldbm_api != db2 ; then
 359                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 360                         ol_enable_bdb2=no
 361                 fi
 362         fi
 363
 364         if test $ol_with_ldbm_api = gdbm -a \
 365                 $ol_with_ldbm_type = btree ; then
 366                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 367         fi
 368         if test $ol_with_ldbm_api = mdbm -a \
 369                 $ol_with_ldbm_type = btree ; then
 370                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 371         fi
 372         if test $ol_with_ldbm_api = ndbm -a \
 373                 $ol_with_ldbm_type = btree ; then
 374                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 375         fi
 376 fi
 377
 378 if test $ol_enable_slurpd = yes ; then
 379         dnl SLURPD was specifically enabled
 380         if test $ol_with_threads = no ; then
 381                 AC_MSG_ERROR([slurpd requires threads])
 382         fi
 383 fi
 384
 385 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 386         if test $ol_with_kerberos = no ; then
 387                 AC_MSG_ERROR([options require --with-kerberos])
 388         fi
 389 fi
 390
 391 AC_MSG_RESULT(done)
 392
 393 dnl ----------------------------------------------------------------
 394 dnl Initialize vars
 395 LDAP_LIBS=
 396 LDIF_LIBS=
 397 LDBM_LIBS=
 398 LTHREAD_LIBS=
 399 LUTIL_LIBS=
 400
 401 LDAPD_LIBS=
 402 SLAPD_LIBS=
 403 SLURPD_LIBS=
 404
 405 BUILD_LDAPD=no
 406 BUILD_SLAPD=no
 407 BUILD_SLURPD=no
 408
 409 BUILD_BDB2=no
 410 BUILD_LDAP=no
 411 BUILD_LDBM=no
 412 BUILD_PASSWD=no
 413 BUILD_PERL=no
 414 BUILD_QUIPU=no
 415 BUILD_SHELL=no
 416 BUILD_TCL=no
 417 BUILD_THREAD=no
 418
 419 BUILD_BDB2_DYNAMIC=static
 420 BUILD_LDAP_DYNAMIC=static
 421 BUILD_LDBM_DYNAMIC=static
 422 BUILD_PASSWD_DYNAMIC=static
 423 BUILD_PERL_DYNAMIC=static
 424 BUILD_SHELL_DYNAMIC=static
 425 BUILD_TCL_DYNAMIC=static
 426
 427 SLAPD_MODULES_LDFLAGS=
 428 SLAPD_MODULES_CPPFLAGS=
 429 SLAPD_MODULES_LIST=
 430
 431 SLAPD_PERL_LDFLAGS=
 432 MOD_PERL_LDFLAGS=
 433 PERL_CPPFLAGS=
 434
 435 MOD_TCL_LIB=
 436 KRB4_LIBS=
 437 KRB5_LIBS=
 438 READLINE_LIBS=
 439 SASL_LIBS=
 440 TERMCAP_LIBS=
 441 TLS_LIBS=
 442 MODULES_LIBS=
 443
 444 dnl ================================================================
 445 dnl Checks for programs
 446
 447 dnl AC_PROG_INSTALL
 448
 449 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 450
 451 dnl ----------------------------------------------------------------
 452 dnl
 453 dnl Determine which C translator to use
 454 dnl
 455
 456 dnl AIX Thread requires we use cc_r or xlc_r.
 457 dnl But only do this IF AIX and CC is not set
 458 dnl and threads are auto|yes|posix.
 459 dnl
 460 dnl If we find cc_r|xlc_r, force pthreads and assume
 461 dnl             pthread_create is in $LIBS (ie: don't bring in
 462 dnl             any additional thread libraries)
 463 dnl If we do not find cc_r|xlc_r, disable threads
 464
 465 ol_aix_threads=no
 466 case "$target" in
 467 *-*-aix*) dnl all AIX is not a good idea.
 468         if test -z "$CC" ; then
 469                 case "$ol_with_threads" in
 470                 auto | yes |  posix) ol_aix_threads=yes ;;
 471                 esac
 472         fi
 473 ;;
 474 esac
 475
 476 if test $ol_aix_threads = yes ; then
 477         if test -z "${CC}" ; then
 478                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 479
 480                 if test "$CC" = cc ; then
 481                         dnl no CC! don't allow --with-threads
 482                         if test $ol_with_threads != auto ; then
 483                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 484                         else
 485                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 486                         fi
 487                         ol_with_threads=no
 488                 fi
 489         fi
 490
 491         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 492                 ol_with_threads=posix
 493                 ol_cv_pthread_create=yes
 494         fi
 495 fi
 496
 497 if test -z "${CC}"; then
 498         AC_CHECK_PROGS(CC,cc)
 499 fi
 500
 501 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 502 dnl (for now, let autoconf sort this out)
 503 dnl CFLAGS=${CFLAGS-""}
 504
 505 AC_LIBTOOL_WIN32_DLL
 506 AC_LIBTOOL_DLOPEN
 507 AC_PROG_LIBTOOL
 508
 509 AC_PROG_AWK
 510 OL_PROG_LN_H
 511 AC_PROG_LN_S
 512
 513 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 514         LN_S="$LN_H"
 515 fi
 516
 517 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 518         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 519 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 520 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 521
 522 dnl ----------------------------------------------------------------
 523 dnl Perl
 524 ol_link_perl=no
 525 if test $ol_enable_perl != no ; then
 526         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 527
 528         if test "no$PERLBIN" = "no" ; then
 529                 if test $ol_enable_perl = yes ; then
 530                         AC_MSG_ERROR([could not locate perl])
 531                 fi
 532
 533         else
 534                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 535                 if test x"$ol_with_perl_module" = "xstatic" ; then
 536                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 537                 else
 538                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 539                 fi
 540                 dnl should check perl version
 541                 ol_link_perl=yes
 542         fi
 543 fi
 544
 545 AC_PROG_CPP
 546
 547 dnl ----------------------------------------------------------------
 548 dnl Cross compiling checks
 549 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 550         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 551
 552 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 553         AC_MSG_WARN([programs compiled here do run here...])
 554         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 555
 556 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 557         AC_MSG_WARN([programs compiled here do not run here...])
 558         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 559 fi
 560
 561 dnl ----------------------------------------------------------------
 562 dnl Checks for UNIX Variants
 563 AC_AIX
 564 AC_ISC_POSIX
 565 AC_MINIX
 566
 567 dnl ----------------------------------------------------------------
 568 dnl Checks for system services
 569 AC_CYGWIN
 570 AC_MINGW32
 571 AC_EXEEXT
 572 AC_OBJEXT
 573
 574 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 575
 576 dnl ----------------------------------------------------------------
 577 dnl BeOS requires -lbe -lroot -lnet
 578 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 579
 580 dnl ----------------------------------------------------------------
 581 dnl OpenLDAP requires STDC features
 582 AM_PROG_CC_STDC
 583 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 584         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 585 fi
 586
 587 dnl ----------------------------------------------------------------
 588 dnl Check cc depend flags
 589 OL_MKDEPEND
 590 if test "${ol_cv_mkdep}" = no ; then
 591         # this will soon become an error
 592         AC_MSG_WARN([do not know how to generate dependencies])
 593 fi
 594
 595 dnl ----------------------------------------------------------------
 596 dnl Check for module support
 597 ol_link_modules=no
 598 if test $ol_enable_modules != no ; then
 599         AC_CHECK_HEADERS(ltdl.h)
 600
 601         if test $ac_cv_header_ltdl_h = no ; then
 602                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 603         fi
 604
 605         AC_CHECK_LIB(ltdl, lt_dlinit, [
 606             MODULES_LIBS=-lltdl
 607             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 608         ])
 609
 610         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 611                 AC_MSG_ERROR([could not locate libtool -lltdl])
 612         fi
 613         ol_link_modules=yes
 614 else
 615         ol_with_bdb2_module=static
 616         ol_with_ldap_module=static
 617         ol_with_ldbm_module=static
 618         ol_with_passwd_module=static
 619         ol_with_perl_module=static
 620         ol_with_shell_module=static
 621         ol_with_tcl_module=static
 622 fi
 623
 624 dnl ----------------------------------------------------------------
 625 dnl Checks for header files.
 626 OL_HEADER_STDC
 627
 628 if test $ol_cv_header_stdc != yes; then
 629         AC_MSG_WARN([could not locate Standard C compliant headers])
 630 fi
 631
 632 AC_HEADER_DIRENT
 633 AC_HEADER_SYS_WAIT
 634 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 635 if test $am_cv_sys_posix_termios = yes ; then
 636         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 637                 [define if you have POSIX termios])
 638 fi
 639
 640 AC_CHECK_HEADERS(       \
 641         arpa/inet.h             \
 642         arpa/nameser.h  \
 643         assert.h                \
 644         conio.h                 \
 645         crypt.h                 \
 646         direct.h                \
 647         errno.h                 \
 648         fcntl.h                 \
 649         filio.h                 \
 650         getopt.h                \
 651         grp.h                   \
 652         io.h                    \
 653         libutil.h               \
 654         limits.h                \
 655         locale.h                \
 656         netinet/tcp.h   \
 657         malloc.h                \
 658         memory.h                \
 659         psap.h                  \
 660         pwd.h                   \
 661         process.h               \
 662         resolv.h                \
 663         sgtty.h                 \
 664         shadow.h                \
 665         stddef.h                \
 666         string.h                \
 667         strings.h               \
 668         sysexits.h              \
 669         sys/file.h              \
 670         sys/filio.h             \
 671         sys/errno.h             \
 672         sys/ioctl.h             \
 673         sys/param.h             \
 674         sys/resource.h  \
 675         sys/select.h    \
 676         sys/socket.h    \
 677         sys/syslog.h    \
 678         sys/time.h              \
 679         sys/types.h             \
 680         syslog.h                \
 681         termios.h               \
 682         unistd.h                \
 683         winsock.h               \
 684 )
 685
 686
 687 dnl ----------------------------------------------------------------
 688 dnl Checks for libraries
 689
 690 dnl HP-UX requires -lV3
 691 AC_CHECK_LIB(V3, sigset)
 692
 693 dnl Gotta check for winsock manually
 694 if test $ac_cv_header_winsock_h = yes; then
 695         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 696         AC_TRY_LINK([#include <winsock.h>],[
 697                         socket(0,0,0);
 698                         select(0,NULL,NULL,NULL,NULL);
 699                         closesocket(0);
 700                         gethostname(NULL,0);
 701         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 702
 703         if test $ol_cv_winsock = yes ; then
 704                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 705                 ac_cv_func_socket=yes
 706                 ac_cv_func_select=yes
 707                 ac_cv_func_closesocket=yes
 708                 ac_cv_func_gethostname=yes
 709         fi
 710 fi
 711
 712 dnl Find socket()
 713 dnl Likely combinations:
 714 dnl             -lsocket [ -lnsl_s | -lnsl ]
 715 dnl             -linet
 716
 717 AC_CHECK_FUNC(socket, :, [
 718 dnl hopefully we won't include too many libraries
 719         AC_CHECK_LIB(socket, main)
 720         AC_CHECK_LIB(net, main)
 721         AC_CHECK_LIB(nsl_s, main)
 722         AC_CHECK_LIB(nsl, main)
 723         AC_CHECK_LIB(inet, socket)
 724         AC_CHECK_LIB(gen, main)
 725 ])
 726
 727 dnl require select
 728 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 729
 730 if test "${ac_cv_header_winsock_h}" != yes; then
 731     dnl Select arg types
 732     dnl (if this detection becomes permenent, it and the select() detection
 733     dnl should be done before the yielding select test)
 734     AC_FUNC_SELECT_ARGTYPES
 735 fi
 736
 737 dnl check to see if system call automatically restart
 738 dnl AC_SYS_RESTARTABLE_SYSCALLS
 739
 740 dnl ----------------------------------------------------------------
 741 dnl require POSIX regex
 742 AC_CHECK_HEADERS( regex.h )
 743 if test "$ac_cv_header_regex_h" != yes ; then
 744         AC_MSG_ERROR([POSIX regex.h required.])
 745 fi
 746 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 747
 748 OL_POSIX_REGEX
 749 if test "$ol_cv_c_posix_regex" = no ; then
 750         AC_MSG_ERROR([broken POSIX regex!])
 751 fi
 752
 753 dnl ----------------------------------------------------------------
 754 dnl Check for resolver routines
 755 AC_CHECK_FUNC(res_search,:)
 756 if test $ac_cv_func_res_search = no ; then
 757         AC_CHECK_LIB(bind, res_search)
 758         ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 759 fi
 760
 761 if test $ac_cv_func_res_search = no ; then
 762         AC_CHECK_LIB(bind, __res_search)
 763         ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 764 fi
 765
 766 if test $ac_cv_func_res_search = no ; then
 767         AC_CHECK_LIB(resolv, res_search)
 768         ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 769 fi
 770
 771 if test "$ac_cv_func_res_search" = yes ; then
 772         AC_DEFINE(HAVE_RES_SEARCH,1,
 773                 [define if you have res_search()])
 774 elif test $ol_enable_dns = yes ; then
 775         AC_MSG_ERROR([--enable-dns requires res_search])
 776 elif test $ol_enable_dns != no ; then
 777         AC_MSG_WARN([no res_search, disabling DNS support])
 778 fi
 779
 780
 781 dnl ----------------------------------------------------------------
 782 dnl ISODE tests
 783 ol_link_isode=no
 784 if test $ol_enable_ldapd != no ; then
 785         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 786
 787         dnl look for ISODE libraries
 788         AC_CHECK_LIB(xtpp, main, [
 789                 ol_link_isode=yes
 790                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 791                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 792                 ],:,[-lxtdsap -lxtisode -losi])
 793         AC_CHECK_LIB(dsap, main, [
 794                 ol_link_isode=yes
 795                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 796                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 797                 ],:,[-lisode])
 798         AC_CHECK_LIB(isode, main, [
 799                 ol_link_isode=yes
 800                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 801                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 802                 ],:)
 803 fi
 804
 805 if test $ol_link_isode != no; then
 806         AC_CHECK_LIB(pp, main, [
 807                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 808                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 809                 ],:)
 810
 811         AC_PATH_PROG(PEPSY, pepsy)
 812 fi
 813
 814 dnl ----------------------------------------------------------------
 815 dnl QUIPU
 816 if test $ol_enable_quipu != no ; then
 817         AC_CHECK_HEADERS(quipu/commonarg.h)
 818
 819         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 820                 BUILD_QUIPU=yes
 821         elif test $ol_enable_quipu = auto ; then
 822                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 823         else
 824                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 825         fi
 826 fi
 827
 828 dnl ----------------------------------------------------------------
 829 dnl Kerberos
 830 ol_link_krb5=no
 831
 832 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 \
 833         -o $ol_with_kerberos = k5only -o $ol_with_kerberos = k425 ; then
 834
 835         AC_CHECK_HEADERS(krb5.h)
 836
 837         if test $ac_cv_header_krb5_h = yes ; then
 838                 dnl lazy check for Heimdal Kerberos
 839                 AC_CHECK_HEADERS(heim_err.h)
 840                 if test $ac_cv_header_heim_err_h = yes ; then
 841                         krb5_impl=heimdal
 842                 else
 843                         krb5_impl=mit
 844                 fi
 845
 846                 if test $krb5_impl = mit; then
 847                         AC_CHECK_LIB(krb5, main,
 848                                 [have_krb5=yes
 849                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 850                                 [have_krb5=no],
 851                                 [-lcrypto -lcom_err])
 852
 853                 elif test $krb5_impl = heimdal; then
 854                         AC_CHECK_LIB(krb5, main,
 855                                 [have_krb5=yes
 856                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 857                                 [have_krb5=no],
 858                                 [-ldes -lasn1 -lroken -lcom_err])
 859
 860                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 861                                 [define if you have HEIMDAL Kerberos])
 862                 else
 863                         have_krb5=no
 864                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 865                 fi
 866
 867                 if test $have_krb5 = yes ; then
 868                         ol_link_krb5=yes
 869
 870                         AC_DEFINE(HAVE_KRB5, 1,
 871                                 [define if you have Kerberos V])
 872
 873                         if test $ol_with_kerberos = k5only ; then
 874                                 ol_with_kerberos=found
 875                         fi
 876
 877                 elif test $ol_with_kerberos != auto ; then
 878                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 879                 fi
 880
 881         fi
 882 fi
 883
 884 ol_link_krb4=no
 885 if test $ol_link_krb5 = yes -a \
 886         \( $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 887
 888         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 889
 890         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 891                 if test $krb5_impl = mit; then
 892                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 893                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 894                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 895
 896                 elif test $krb5_impl = heimdal; then
 897                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 898                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 899                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 900
 901                 else
 902                         have_425=no
 903                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 904                 fi
 905
 906                 if test $have_k425 = yes ; then
 907                         ol_with_kerberos=found
 908                         ol_link_krb4=yes
 909
 910                         AC_DEFINE(HAVE_KRB425, 1,
 911                                 [define if you have Kerberos V with IV support])
 912                         AC_DEFINE(HAVE_KRB4, 1,
 913                                 [define if you have Kerberos IV])
 914
 915                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 916                                 [ol_cv_var_des_debug], [
 917                                 dnl save the flags
 918                                 save_LIBS="$LIBS"
 919                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 920                                 AC_TRY_LINK([
 921 #include <kerberosIV/krb.h>
 922 #include <kerberosIV/des.h>
 923 extern int des_debug;
 924 ],[
 925 des_debug = 1;
 926 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 927                                 dnl restore the LIBS
 928                                 LIBS="$save_LIBS"
 929                         ])
 930
 931                         if test $ol_cv_var_des_debug = yes ; then
 932                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 933                                         [define if you have Kerberos des_debug])
 934                         fi
 935
 936                         LIBS="$save_LIBS"
 937                 fi
 938         fi
 939 fi
 940
 941 if test $ol_link_krb5 = yes ; then
 942         ol_with_kerberos=found
 943 fi
 944
 945 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 \
 946         -o $ol_with_kerberos = kth ; then
 947
 948         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 949
 950         if test $ac_cv_header_krb_h = yes ; then
 951                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 952
 953                 if test $have_k4 = yes ; then
 954                         ol_with_kerberos=found
 955                         ol_link_krb4=yes
 956
 957                         AC_DEFINE(HAVE_KRB4, 1,
 958                                 [define if you have Kerberos IV])
 959
 960                         KRB4_LIBS="-lkrb -ldes"
 961
 962                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 963                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 964                                         [define if you have Kth Kerberos])
 965                         fi
 966                 fi
 967         fi
 968 fi
 969
 970 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 971         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 972
 973 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 974         AC_MSG_ERROR([Kerberos detection failed.])
 975 fi
 976
 977 dnl ----------------------------------------------------------------
 978 dnl TLS/SSL
 979 ol_link_tls=no
 980 if test $ol_with_tls != no ; then
 981
 982         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 983
 984         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 985                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 986                         [have_ssleay=yes
 987                         need_rsaref=no],
 988                         [have_ssleay=no],
 989                         [-lcrypto])
 990
 991                 if test $have_ssleay = no ; then
 992                         AC_CHECK_LIB(ssl, SSL_library_init,
 993                                 [have_ssleay=yes
 994                                 need_rsaref=no], [have_ssleay=no],
 995                                 [-lcrypto])
 996                 fi
 997
 998                 if test $have_ssleay = no ; then
 999                         AC_CHECK_LIB(ssl, ssl3_accept,
1000                                 [have_ssleay=yes
1001                                 need_rsaref=yes], [have_ssleay=no],
1002                                 [-lcrypto -lRSAglue -lrsaref])
1003                 fi
1004
1005                 if test $have_ssleay = yes ; then
1006                         ol_with_tls=found
1007                         ol_link_tls=yes
1008
1009                         AC_DEFINE(HAVE_SSLEAY, 1,
1010                                 [define if you have SSLeay or OpenSSL])
1011
1012                         if test $need_rsaref = yes; then
1013                                 AC_DEFINE(HAVE_RSAREF, 1,
1014                                         [define if you have RSAref])
1015
1016                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1017                         else
1018                                 TLS_LIBS="-lssl -lcrypto"
1019                         fi
1020                 fi
1021         fi
1022 fi
1023
1024 if test $ol_link_tls = yes ; then
1025         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1026 fi
1027
1028 dnl ----------------------------------------------------------------
1029 dnl Tests for reentrant functions necessary to build a
1030 dnl thread_safe -lldap.
1031 AC_CHECK_FUNCS(         \
1032         ctime_r                 \
1033         gethostbyname_r gethostbyaddr_r \
1034 )
1035
1036 if test "$ac_cv_func_ctime_r" = no ; then
1037         ol_cv_func_ctime_r_nargs=0
1038 else
1039         OL_FUNC_CTIME_R_NARGS
1040 dnl     OL_FUNC_CTIME_R_TYPE
1041 fi
1042
1043 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1044         OL_FUNC_GETHOSTBYNAME_R_NARGS
1045 else
1046         ol_cv_func_gethostbyname_r_nargs=0
1047 fi
1048
1049 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1050         OL_FUNC_GETHOSTBYADDR_R_NARGS
1051 else
1052         ol_cv_func_gethostbyaddr_r_nargs=0
1053 fi
1054
1055 if test "$ac_cv_func_ctime_r" = yes \
1056         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1057         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1058         -a "$ac_cv_func_gethostbyname_r" = yes \
1059         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1060         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1061         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1062         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1063         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1064         ; then
1065
1066         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1067 fi
1068
1069 dnl ----------------------------------------------------------------
1070 dnl Threads?
1071 ol_link_threads=no
1072
1073 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1074         -o $ol_with_threads = nt ; then
1075
1076         OL_NT_THREADS
1077
1078         if test "$ol_cv_nt_threads" = yes ; then
1079         ol_link_threads=nt
1080         ol_with_threads=found
1081         ol_with_yielding_select=yes
1082
1083                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1084                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1085         fi
1086
1087         if test $ol_with_threads = nt ; then
1088                 AC_MSG_ERROR([could not locate NT Threads])
1089         fi
1090 fi
1091
1092 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1093         -o $ol_with_threads = posix ; then
1094
1095         AC_CHECK_HEADERS(pthread.h)
1096
1097         if test $ac_cv_header_pthread_h = yes ; then
1098                 OL_POSIX_THREAD_VERSION
1099
1100                 if test $ol_cv_pthread_version = final ; then
1101                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1102                                 [define if pthreads API compatible with final spec])
1103                 elif test $ol_cv_pthread_version = draft4 ; then
1104                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1105                                 [define if pthreads API compatible with draft4 spec])
1106                 else
1107                         AC_MSG_ERROR([unknown pthread version])
1108                 fi
1109
1110                 # consider threads found
1111                 ol_with_threads=found
1112
1113                 OL_HEADER_LINUX_THREADS
1114                 OL_HEADER_GNU_PTH_PTHREAD_H
1115
1116                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1117                         AC_CHECK_HEADERS(sched.h)
1118                 fi
1119
1120                 dnl Now the hard part, how to link?
1121                 dnl
1122                 dnl currently supported checks:
1123                 dnl
1124                 dnl Check for no flags
1125                 dnl     pthread_create() in $LIBS
1126                 dnl
1127                 dnl Check special pthread (final) flags
1128                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1129                 dnl     pthread_create() with -kthread (FreeBSD)
1130                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1131                 dnl     pthread_create() with -pthreads (?)
1132                 dnl     pthread_create() with -mthreads (AIX)
1133                 dnl     pthread_create() with -thread (?)
1134                 dnl
1135                 dnl Check pthread (final) libraries
1136                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1137                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1138                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1139                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1140                 dnl     pthread_create() in -lpthread (many)
1141                 dnl     pthread_create() in -lc_r (FreeBSD)
1142                 dnl
1143                 dnl Check pthread (draft4) flags (depreciated)
1144                 dnl     pthread_create() with -threads (OSF/1)
1145                 dnl
1146                 dnl Check pthread (draft4) libraries (depreciated)
1147                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1148                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1149                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1150                 dnl     pthread_create() in -lpthreads (many)
1151                 dnl
1152
1153                 dnl pthread_create in $LIBS
1154                 AC_CACHE_CHECK([for pthread_create in default libraries],
1155                         ol_cv_pthread_create,[
1156                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1157                         [ol_cv_pthread_create=yes],
1158                         [ol_cv_pthread_create=no],
1159                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1160                                 [ol_cv_pthread_create=yes],
1161                                 [ol_cv_pthread_create=no])])])
1162
1163                 if test $ol_cv_pthread_create != no ; then
1164                         ol_link_threads=posix
1165                         ol_link_pthreads=""
1166                 fi
1167
1168 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1169                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1170                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1171                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1172                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1173                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1174
1175                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1176                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1177                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1178                         [ol_cv_pthread_lpthread_lmach_lexc])
1179 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1180 dnl                     [ol_cv_pthread_lpthread_lexc])
1181
1182                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1183                         [ol_cv_pthread_lib_lpthread_woff])
1184
1185                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1186                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1187
1188                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1189
1190                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1191                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1192                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1193                         [ol_cv_pthread_lpthreads_lmach_lexc])
1194                 OL_PTHREAD_TRY([-lpthreads -lexc],
1195                         [ol_cv_pthread_lpthreads_lexc])
1196
1197                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1198
1199                 if test $ol_link_threads != no ; then
1200                         AC_DEFINE(HAVE_PTHREADS,1,
1201                                 [define if you have POSIX Threads])
1202
1203                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1204
1205                         dnl save flags
1206                         save_CPPFLAGS="$CPPFLAGS"
1207                         save_LIBS="$LIBS"
1208                         LIBS="$LTHREAD_LIBS $LIBS"
1209
1210                         dnl All POSIX Thread (final) implementations should have
1211                         dnl sched_yield instead of pthread yield.
1212                         dnl check for both
1213                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1214
1215                         if test $ac_cv_func_sched_yield = no -a \
1216                                 $ac_cv_func_pthread_yield = no ; then
1217                                 dnl Digital UNIX has sched_yield() in -lrt
1218                                 AC_CHECK_LIB(rt, sched_yield,
1219                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1220                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1221                                                 [Define if you have the sched_yield function.])
1222                                         ac_cv_func_sched_yield=yes],
1223                                         [ac_cv_func_sched_yield=no])
1224                         fi
1225                         if test $ac_cv_func_sched_yield = no -a \
1226                                 $ac_cv_func_pthread_yield = no ; then
1227                                 dnl Solaris has sched_yield() stub in -lposix4
1228                                 dnl but we'll use thr_yield instead.
1229                                 AC_CHECK_FUNCS(thr_yield)
1230                         fi
1231                         if test $ac_cv_func_sched_yield = no -a \
1232                                 $ac_cv_func_pthread_yield = no -a \
1233                                 "$ac_cv_func_thr_yield" = no ; then
1234                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1235                         fi
1236
1237                         dnl Check functions for compatibility
1238                         AC_CHECK_FUNCS(pthread_kill)
1239
1240                         dnl Check for pthread_detach with <pthread.h> inclusion
1241                         dnl as it's symbol may have been mangled.
1242                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1243                                 [ol_cv_func_pthread_detach], [
1244                                 dnl save the flags
1245                                 AC_TRY_LINK([
1246 #include <pthread.h>
1247 #ifndef NULL
1248 #define NULL (void*)0
1249 #endif
1250 ],
1251                                         [pthread_detach(NULL);],
1252                                         [ol_cv_func_pthread_detach=yes],
1253                                         [ol_cv_func_pthread_detach=no])
1254                         ])
1255
1256                         if test $ol_cv_func_pthread_detach = no ; then
1257                                 AC_MSG_ERROR([could not locate pthread_detach()])
1258                         fi
1259
1260                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1261                                 [define if you have pthread_detach function])
1262
1263                         dnl Check for setconcurreny functions
1264                         AC_CHECK_FUNCS( \
1265                                 pthread_setconcurrency \
1266                                 pthread_getconcurrency \
1267                                 thr_setconcurrency \
1268                                 thr_getconcurrency \
1269                         )
1270
1271                         OL_SYS_LINUX_THREADS
1272                         OL_LINUX_THREADS
1273
1274                         if test $ol_cv_linux_threads = error; then
1275                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1276                         fi
1277
1278                         AC_CACHE_CHECK([if pthread_create() works],
1279                                 ol_cv_pthread_create_works,[
1280                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1281                                 [ol_cv_pthread_create_works=yes],
1282                                 [ol_cv_pthread_create_works=no],
1283                                 [dnl assume yes
1284                                 ol_cv_pthread_create_works=yes])])
1285
1286                         if test $ol_cv_pthread_create_works = no ; then
1287                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1288                         fi
1289
1290                         dnl Check if select causes an yield
1291                         if test $ol_with_yielding_select = auto ; then
1292                                 AC_CACHE_CHECK([if select yields when using pthreads],
1293                                         ol_cv_pthread_select_yields,[
1294                                 AC_TRY_RUN([
1295 #include <sys/types.h>
1296 #include <sys/time.h>
1297 #include <unistd.h>
1298 #include <pthread.h>
1299 #ifndef NULL
1300 #define NULL (void*) 0
1301 #endif
1302
1303 static int fildes[2];
1304
1305 static void *task(p)
1306         void *p;
1307 {
1308         int i;
1309         struct timeval tv;
1310
1311         fd_set rfds;
1312
1313         tv.tv_sec=10;
1314         tv.tv_usec=0;
1315
1316         FD_ZERO(&rfds);
1317         FD_SET(fildes[0], &rfds);
1318
1319         /* we're not interested in any fds */
1320         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1321
1322         if(i < 0) {
1323                 perror("select");
1324                 exit(10);
1325         }
1326
1327         exit(0); /* if we exit here, the select blocked the whole process */
1328 }
1329
1330 int main(argc, argv)
1331         int argc;
1332         char **argv;
1333 {
1334         pthread_t t;
1335
1336         /* create a pipe to select */
1337         if(pipe(&fildes[0])) {
1338                 perror("select");
1339                 exit(1);
1340         }
1341
1342 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1343         (void) pthread_setconcurrency(2);
1344 #else
1345 #ifdef HAVE_THR_SETCONCURRENCY
1346         /* Set Solaris LWP concurrency to 2 */
1347         thr_setconcurrency(2);
1348 #endif
1349 #endif
1350
1351 #if HAVE_PTHREADS_D4
1352         pthread_create(&t, pthread_attr_default, task, NULL);
1353 #else
1354         pthread_create(&t, NULL, task, NULL);
1355 #endif
1356
1357 #if HAVE_SCHED_YIELD
1358         sched_yield();  /* make sure task runs first */
1359 #else
1360 #ifdef HAVE_PTHREAD_YIELD
1361         pthread_yield();        /* make sure task runs first */
1362 #endif
1363 #endif
1364
1365         exit(2);
1366 }],
1367                                 [ol_cv_pthread_select_yields=no],
1368                                 [ol_cv_pthread_select_yields=yes],
1369                                 [ol_cv_pthread_select_yields=cross])])
1370
1371                                 if test $ol_cv_pthread_select_yields = cross ; then
1372                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1373                                 fi
1374
1375                                 if test $ol_cv_pthread_select_yields = yes ; then
1376                                         ol_with_yielding_select=yes
1377                                 fi
1378                         fi
1379
1380                         dnl restore flags
1381                         CPPFLAGS="$save_CPPFLAGS"
1382                         LIBS="$save_LIBS"
1383                 else
1384                         AC_MSG_ERROR([could not link with POSIX Threads])
1385                 fi
1386         fi
1387
1388         if test $ol_with_threads = posix ; then
1389                 AC_MSG_ERROR([could not locate POSIX Threads])
1390         fi
1391 fi
1392
1393 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1394         -o $ol_with_threads = mach ; then
1395
1396         dnl check for Mach CThreads
1397         AC_CHECK_HEADERS(mach/cthreads.h)
1398         if test $ac_cv_header_mach_cthreads_h = yes ; then
1399                 ol_with_threads=found
1400
1401                 dnl check for cthread support in current $LIBS
1402                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1403
1404                 if test $ol_link_threads = no ; then
1405                         dnl try -all_load
1406                         dnl this test needs work
1407                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1408                                 [ol_cv_cthread_all_load], [
1409                                 dnl save the flags
1410                                 save_LIBS="$LIBS"
1411                                 LIBS="-all_load $LIBS"
1412                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1413                                         cthread_fork((void *)0, (void *)0);
1414                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1415                                 dnl restore the LIBS
1416                                 LIBS="$save_LIBS"
1417                         ])
1418
1419                         if test $ol_cv_cthread_all_load = yes ; then
1420                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1421                                 ol_link_threads=mach
1422                         fi
1423                 fi
1424
1425                 if test $ol_link_threads != no ; then
1426                         : check for cthread specific functionality here
1427                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1428                                 [define if you have Mach Cthreads])
1429                 else
1430                         AC_MSG_ERROR([could not link with Mach CThreads])
1431                 fi
1432         fi
1433
1434         if test $ol_with_threads = mach ; then
1435                 AC_MSG_ERROR([could not locate Mach CThreads])
1436         fi
1437 fi
1438
1439 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1440         -o $ol_with_threads = pth ; then
1441
1442         AC_CHECK_HEADERS(pth.h)
1443
1444         if test $ac_cv_header_pth_h = yes ; then
1445                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1446
1447                 if test $have_pth = yes ; then
1448                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1449                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1450                         ol_link_threads=pth
1451
1452                         if test $ol_with_yielding_select = auto ; then
1453                                 ol_with_yielding_select=yes
1454                         fi
1455                 fi
1456         fi
1457 fi
1458
1459 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1460         -o $ol_with_threads = lwp ; then
1461
1462         dnl check for SunOS5 LWP
1463         AC_CHECK_HEADERS(thread.h synch.h)
1464         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1465                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1466
1467                 if test $have_thr = yes ; then
1468                         AC_DEFINE(HAVE_THR,1,
1469                                 [if you have Solaris LWP (thr) package])
1470                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1471                         ol_link_threads=thr
1472
1473                         if test $ol_with_yielding_select = auto ; then
1474                                 ol_with_yielding_select=yes
1475                         fi
1476
1477                         dnl Check for setconcurreny functions
1478                         AC_CHECK_FUNCS( \
1479                                 thr_setconcurrency \
1480                                 thr_getconcurrency \
1481                         )
1482                 fi
1483         fi
1484
1485         dnl check for SunOS4 LWP
1486         AC_CHECK_HEADERS(lwp/lwp.h)
1487         if test $ac_cv_header_lwp_lwp_h = yes ; then
1488                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1489
1490                 if test $have_lwp = yes ; then
1491                         AC_DEFINE(HAVE_LWP,1,
1492                                 [if you have SunOS LWP package])
1493                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1494                         ol_link_threads=lwp
1495
1496                         if test $ol_with_yielding_select = auto ; then
1497                                 ol_with_yielding_select=no
1498                         fi
1499                 fi
1500         fi
1501 fi
1502
1503 if test $ol_with_yielding_select = yes ; then
1504         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1505                 [define if select implicitly yields])
1506 fi
1507
1508 if test $ol_with_threads = manual ; then
1509         dnl User thinks he can manually configure threads.
1510         ol_link_threads=yes
1511
1512         AC_MSG_WARN([thread defines and link options must be set manually])
1513
1514         AC_CHECK_HEADERS(pthread.h sched.h)
1515         AC_CHECK_FUNCS(sched_yield pthread_yield)
1516         OL_HEADER_LINUX_THREADS
1517
1518         AC_CHECK_HEADERS(mach/cthreads.h)
1519         AC_CHECK_HEADERS(lwp/lwp.h)
1520         AC_CHECK_HEADERS(thread.h synch.h)
1521 fi
1522
1523 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1524         dnl needed to get reentrant/threadsafe versions
1525         dnl
1526         AC_DEFINE(REENTRANT,1)
1527         AC_DEFINE(_REENTRANT,1)
1528         AC_DEFINE(THREAD_SAFE,1)
1529         AC_DEFINE(_THREAD_SAFE,1)
1530         AC_DEFINE(THREADSAFE,1)
1531         AC_DEFINE(_THREADSAFE,1)
1532         AC_DEFINE(_SGI_MP_SOURCE,1)
1533
1534         dnl The errno declaration may dependent upon _REENTRANT.
1535         dnl If it does, we must link with thread support.
1536         AC_CACHE_CHECK([for thread specific errno],
1537                 [ol_cv_errno_thread_specific], [
1538                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1539                         [ol_cv_errno_thread_specific=yes],
1540                         [ol_cv_errno_thread_specific=no])
1541         ])
1542
1543         dnl The h_errno declaration may dependent upon _REENTRANT.
1544         dnl If it does, we must link with thread support.
1545         AC_CACHE_CHECK([for thread specific h_errno],
1546                 [ol_cv_h_errno_thread_specific], [
1547                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1548                         [ol_cv_h_errno_thread_specific=yes],
1549                         [ol_cv_h_errno_thread_specific=no])
1550         ])
1551
1552         if test $ol_cv_errno_thread_specific != yes \
1553                 -o $ol_cv_h_errno_thread_specific != yes ; then
1554                 LIBS="$LTHREAD_LIBS $LIBS"
1555                 LTHREAD_LIBS=""
1556         fi
1557
1558 dnl When in thread environment, use
1559 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1560 dnl                     || defined( HAVE_FUNC_R )
1561 dnl                     func_r(...);
1562 dnl             #else
1563 dnl             #       if defined( HAVE_THREADS )
1564 dnl                             /* lock */
1565 dnl             #       endif
1566 dnl                             func(...);
1567 dnl             #       if defined( HAVE_THREADS )
1568 dnl                             /* unlock */
1569 dnl             #       endif
1570 dnl             #endif
1571 dnl
1572 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1573 dnl             _POSIX_REENTRANT_FUNCTIONS
1574 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1575 dnl             _POSIX_THREADSAFE_FUNCTIONS
1576 dnl
1577 dnl             and is currently defined in lthread.h
1578 dnl
1579 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1580 dnl
1581 dnl libldap/*.c should only include <lthread.h> iff
1582 dnl LDAP_R_COMPILE is defined.  ie:
1583 dnl             #ifdef LDAP_R_COMPILE
1584 dnl             #       include LDAP_R_COMPILE
1585 dnl             #endif
1586 dnl
1587 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1588 dnl specifically for compiling the threadsafe version of
1589 dnl     the ldap library (-lldap_r).
1590 dnl
1591 dnl     dnl check for reentrant/threadsafe functions
1592 dnl     dnl
1593 dnl     dnl note: these should only be used when linking
1594 dnl     dnl       with $LTHREAD_LIBS
1595 dnl     dnl
1596 dnl     save_CPPFLAGS="$CPPFLAGS"
1597 dnl     save_LIBS="$LIBS"
1598 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1599 dnl     AC_CHECK_FUNCS( \
1600 dnl             gmtime_r \
1601 dnl             gethostbyaddr_r gethostbyname_r \
1602 dnl             feof_unlocked unlocked_feof \
1603 dnl             putc_unlocked unlocked_putc \
1604 dnl             flockfile ftrylockfile \
1605 dnl     )
1606 dnl     CPPFLAGS="$save_CPPFLAGS"
1607 dnl     LIBS="$save_LIBS"
1608 fi
1609
1610 if test $ol_link_threads = no ; then
1611         if test $ol_with_threads = yes ; then
1612                 AC_MSG_ERROR([no suitable thread support])
1613         fi
1614
1615         if test $ol_with_threads = auto ; then
1616                 AC_MSG_WARN([no suitable thread support, disabling threads])
1617                 ol_with_threads=no
1618         fi
1619
1620         AC_DEFINE(NO_THREADS,1,
1621                 [define if you have (or want) no threads])
1622         LTHREAD_LIBS=""
1623 fi
1624
1625 if test $ol_link_threads != no ; then
1626         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1627 fi
1628
1629 dnl ----------------------------------------------------------------
1630
1631 ol_link_ldbm=no
1632 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1633         OL_BERKELEY_DB2
1634
1635         if test $ol_cv_berkeley_db2 = yes ; then
1636                 ol_link_ldbm=db2
1637                 ol_with_ldbm_api=db2
1638
1639                 if test $ol_with_ldbm_type = hash ; then
1640                         AC_DEFINE(LDBM_USE_DBHASH,1,
1641                                 [define this to use DBHASH w/ LDBM backend])
1642                 else
1643                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1644                                 [define this to use DBBTREE w/ LDBM backend])
1645                 fi
1646
1647                 OL_BERKELEY_DB2_DB_THREAD
1648
1649                 dnl $ol_cv_lib_db2 should be yes or -ldb
1650                 dnl (it could be no, but that would be an error
1651                 if test $ol_cv_lib_db2 != yes ; then
1652                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1653                 fi
1654         fi
1655 fi
1656
1657 ol_link_bdb2=no
1658 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1659         if test $ol_cv_berkeley_db2_db_thread != no ; then
1660                 ol_link_bdb2=yes
1661         else
1662                 AC_MSG_WARN([Installed BerkeleyDB does not provide DB_THREAD support.])
1663         fi
1664 fi
1665
1666 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1667         OL_BERKELEY_DB
1668
1669         if test $ol_cv_berkeley_db = yes ; then
1670                 ol_link_ldbm=db
1671                 ol_with_ldbm_api=db
1672
1673                 if test $ol_with_ldbm_type = hash ; then
1674                         AC_DEFINE(LDBM_USE_DBHASH,1,
1675                                 [define this to use DBHASH w/ LDBM backend])
1676                 else
1677                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1678                                 [define this to use DBBTREE w/ LDBM backend])
1679                 fi
1680
1681                 dnl $ol_cv_lib_db should be yes or -ldb
1682                 dnl (it could be no, but that would be an error
1683                 if test $ol_cv_lib_db != yes ; then
1684                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1685                 fi
1686         fi
1687 fi
1688
1689 if test $ol_with_ldbm_api = manual ; then
1690         dnl User thinks he can manually configure LDBM api.
1691         ol_link_ldbm=yes
1692
1693         AC_MSG_WARN([LDBM defines and link options must be set manually])
1694
1695         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1696 fi
1697
1698 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1699         AC_MSG_WARN(Could not find LDBM with BTREE support)
1700         ol_with_ldbm_api=none
1701 fi
1702
1703 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1704         OL_MDBM
1705
1706         if test $ol_cv_mdbm = yes ; then
1707                 ol_link_ldbm=mdbm
1708                 ol_with_ldbm_api=mdbm
1709                 if test $ol_cv_lib_mdbm != yes ; then
1710                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1711                 fi
1712         fi
1713 fi
1714
1715 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1716         OL_GDBM
1717
1718         if test $ol_cv_gdbm = yes ; then
1719                 ol_link_ldbm=gdbm
1720                 ol_with_ldbm_api=gdbm
1721
1722                 if test $ol_cv_lib_gdbm != yes ; then
1723                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1724                 fi
1725         fi
1726 fi
1727
1728 if test $ol_with_ldbm_api = auto ; then
1729         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1730 elif test $ol_with_ldbm_api = ndbm ; then
1731         OL_NDBM
1732
1733         if test $ol_cv_ndbm = yes ; then
1734                 ol_link_ldbm=ndbm
1735                 ol_with_ldbm_api=ndbm
1736
1737                 if test $ol_cv_lib_ndbm != yes ; then
1738                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1739                 fi
1740         fi
1741 fi
1742
1743 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1744         AC_MSG_WARN(could not find suitable LDBM backend)
1745         if test $ol_enable_ldbm = yes ; then
1746                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1747         fi
1748
1749         AC_MSG_WARN(disabling LDBM)
1750         ol_enable_ldbm=no
1751 fi
1752
1753 dnl ----------------------------------------------------------------
1754 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1755         LINK_BINS_DYNAMIC="yes"
1756 else
1757         LINK_BINS_DYNAMIC="no"
1758 fi
1759
1760 dnl ----------------------------------------------------------------
1761 if test $ol_enable_wrappers != no ; then
1762         AC_CHECK_HEADERS(tcpd.h)
1763
1764         if test $ac_cv_header_tcpd_h != yes ; then
1765                 have_wrappers=no
1766         else
1767                 AC_TRY_COMPILE([
1768 int allow_severity = 0;
1769 int deny_severity  = 0;
1770                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1771         fi
1772
1773         if test $have_wrappers = yes ; then
1774                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1775                 WRAP_LIBS="-lwrap"
1776
1777                 dnl We add another check for -lnsl since some libwrap's
1778                 dnl need it, but it isn't always included from above
1779                 AC_CHECK_LIB(nsl, main)
1780         else
1781                 AC_MSG_WARN(could not find -lwrap)
1782                 if test $ol_enable_wrappers = yes ; then
1783                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1784                 fi
1785
1786                 AC_MSG_WARN(disabling wrappers support)
1787                 ol_enable_wrappers=no
1788                 WRAP_LIBS=""
1789         fi
1790 fi
1791
1792 dnl ----------------------------------------------------------------
1793 if test $ol_enable_syslog != no ; then
1794         AC_CHECK_FUNC(openlog)
1795         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1796                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1797         fi
1798         ol_enable_syslog=$ac_cv_func_openlog
1799 fi
1800
1801 dnl ----------------------------------------------------------------
1802 if test $ol_enable_dmalloc != no ; then
1803         AC_CHECK_HEADERS(dmalloc.h)
1804         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1805 fi
1806
1807 dnl ----------------------------------------------------------------
1808 dnl TCL
1809 if test $ol_enable_tcl != no ; then
1810         AC_CHECK_HEADERS(tcl.h)
1811
1812         if test $ac_cv_header_tcl_h != yes ; then
1813                 have_tcl=no
1814         else
1815                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1816                         AC_CHECK_LIB($lib,main,
1817                           [have_tcl=yes
1818                            if test x"$ol_with_tcl_module" = "xstatic" ; then
1819                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1820                            else
1821                                MOD_TCL_LIB="-l${lib}"
1822                            fi;break],[have_tcl=no])
1823                 done
1824         fi
1825
1826         if test $have_tcl != yes ; then
1827                 AC_MSG_WARN([could not find -ltcl])
1828                 if test $ol_enable_tcl = yes ; then
1829                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1830                 fi
1831
1832                 ol_enable_tcl=no
1833         fi
1834 fi
1835
1836 dnl ----------------------------------------------------------------
1837 dnl ud needs termcap (should insert check here)
1838 ol_link_termcap=no
1839 AC_CHECK_HEADERS(termcap.h ncurses.h)
1840
1841 if test $ol_link_termcap = no ; then
1842         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1843         if test $have_termcap = yes ; then
1844                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1845                 ol_link_termcap=yes
1846                 TERMCAP_LIBS=-ltermcap
1847         fi
1848 fi
1849
1850 if test $ol_link_termcap = no ; then
1851         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1852         if test $have_ncurses = yes ; then
1853                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1854                 ol_link_termcap=yes
1855                 TERMCAP_LIBS=-lncurses
1856         fi
1857 fi
1858
1859 if test $ol_link_termcap = no ; then
1860         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1861         TERMCAP_LIBS=
1862 fi
1863
1864 dnl ----------------------------------------------------------------
1865 dnl
1866 dnl Check for Cyrus SASL
1867 dnl
1868 ol_link_sasl=no
1869 if test $ol_with_cyrus_sasl != no ; then
1870         AC_CHECK_HEADER(sasl.h)
1871
1872         if test $ac_cv_header_sasl_h = yes ; then
1873                 AC_CHECK_LIB(sasl, sasl_client_init,
1874                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1875
1876                 if test $have_cyrus_sasl != no ; then
1877                         SASL_LIBS="-lsasl"
1878                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1879                         ol_link_sasl=yes
1880                 fi
1881         fi
1882
1883         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1884                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1885         fi
1886 fi
1887
1888 dnl ----------------------------------------------------------------
1889 dnl Check for entropy sources
1890 if test $cross_compiling != yes ; then
1891         dev=no
1892         if test -r /dev/urandom ; then
1893                 dev="/dev/urandom";
1894         elif test -r /idev/urandom ; then
1895                 dev="/idev/urandom";
1896         elif test -r /dev/srandom ; then
1897                 dev="/dev/srandom";
1898         elif test -r /dev/random ; then
1899                 dev="/dev/random";
1900         elif test -r /idev/random ; then
1901                 dev="/idev/random";
1902         fi
1903
1904         if test $dev != no ; then
1905                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1906         fi
1907 fi
1908
1909 dnl ----------------------------------------------------------------
1910 dnl
1911 dnl Check for fetch URL support
1912 dnl             should be extended to support other fetch URL APIs
1913 dnl
1914 ol_link_fetch=no
1915 if test $ol_with_fetch != no ; then
1916         OL_LIB_FETCH
1917
1918         if test $ol_cv_lib_fetch != no ; then
1919                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1920                 ol_link_fetch=freebsd
1921
1922         elif test $ol_with_fetch != auto ; then
1923                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1924         fi
1925 fi
1926
1927 dnl ----------------------------------------------------------------
1928 dnl
1929 dnl Check for GNU readline
1930 dnl
1931 ol_link_readline=no
1932 if test $ol_with_readline != no ; then
1933         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1934
1935         if test $ac_cv_header_readline_readline_h = yes ; then
1936                 save_LIBS="$LIBS"
1937                 LIBS="$TERMCAP_LIBS $LIBS"
1938                 AC_CHECK_LIB(readline, readline,
1939                         [have_readline=yes], [have_readline=no])
1940                 LIBS="$save_LIBS"
1941
1942                 if test $have_readline = yes ; then
1943                         ol_with_readline=found
1944                         ol_link_readline=yes
1945
1946                         READLINE_LIBS="-lreadline"
1947                 fi
1948         fi
1949 fi
1950
1951 if test $ol_link_readline = yes ; then
1952         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1953 fi
1954
1955
1956 dnl ----------------------------------------------------------------
1957 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1958 if test $ol_enable_crypt != no ; then
1959         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1960                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1961                         have_crypt=yes], [have_crypt=no])])
1962
1963         if test $have_crypt = yes ; then
1964                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1965         else
1966                 AC_MSG_WARN(could not find crypt)
1967                 if test $ol_enable_crypt = yes ; then
1968                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1969                 fi
1970
1971                 AC_MSG_WARN(disabling crypt support)
1972                 ol_enable_crypt=no
1973         fi
1974 fi
1975
1976 dnl ----------------------------------------------------------------
1977 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1978 if test $ol_enable_proctitle != no ; then
1979         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1980                 AC_CHECK_LIB(util, setproctitle,
1981                         [have_setproctitle=yes
1982                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1983                         [have_setproctitle=no
1984                         LIBOBJS="$LIBOBJS setproctitle.o"
1985                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1986
1987         if test $have_setproctitle = yes ; then
1988                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1989                         [define if setproctitle(3) is available])
1990         fi
1991 fi
1992
1993 dnl ----------------------------------------------------------------
1994 dnl Checks for typedefs, structures, and compiler characteristics.
1995 AC_TYPE_MODE_T
1996 AC_TYPE_OFF_T
1997 AC_TYPE_PID_T
1998 AM_TYPE_PTRDIFF_T
1999 AC_TYPE_SIGNAL
2000 AC_TYPE_SIZE_T
2001
2002 AC_CHECK_TYPE(ssize_t, [signed int])
2003 AC_CHECK_TYPE(caddr_t,  [char *])
2004
2005 OL_TYPE_SOCKLEN_T
2006 AC_STRUCT_ST_BLKSIZE
2007 AC_HEADER_TIME
2008 AC_STRUCT_TM
2009 AC_TYPE_UID_T
2010 OL_TYPE_SIG_ATOMIC_T
2011
2012 dnl AC_TYPE_GETGROUPS
2013
2014 OL_STRUCT_PASSWD_PW_GECOS
2015 OL_STRUCT_PASSWD_PW_PASSWD
2016
2017 OL_C_UPPER_LOWER
2018 AC_C_CONST
2019 OL_C_VOLATILE
2020
2021 if test $cross_compiling = yes ; then
2022         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2023 else
2024         AC_C_BIGENDIAN
2025 fi
2026
2027 AC_COMPILE_CHECK_SIZEOF(short)
2028 AC_COMPILE_CHECK_SIZEOF(int)
2029 AC_COMPILE_CHECK_SIZEOF(long)
2030
2031 if test "$ac_cv_sizeof_int" -lt 4 ; then
2032         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2033
2034         AC_DEFINE(LBER_INT_T,long)
2035 else
2036         AC_DEFINE(LBER_INT_T,int)
2037 fi
2038
2039 AC_DEFINE(LBER_LEN_T,long)
2040 AC_DEFINE(LBER_SOCKET_T,int)
2041 AC_DEFINE(LBER_TAG_T,long)
2042
2043 dnl ----------------------------------------------------------------
2044 dnl Checks for library functions.
2045 AC_FUNC_MEMCMP
2046 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
2047 AC_FUNC_STRFTIME
2048 dnl AM_FUNC_STRTOD
2049
2050 OL_FUNC_INET_ATON
2051
2052 dnl Check for NT specific routines
2053 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2054
2055 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2056         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2057 ])
2058
2059 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2060         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2061 ])
2062
2063 AC_FUNC_VPRINTF
2064
2065 if test $ac_cv_func_vprintf = yes ; then
2066         dnl check for vsnprintf
2067         AC_CHECK_FUNCS(vsnprintf vsprintf)
2068 fi
2069
2070 AC_CHECK_FUNCS(         \
2071         bcopy                   \
2072         closesocket             \
2073         endgrent                \
2074         endpwent                \
2075         flock                   \
2076         getdtablesize   \
2077         getgrgid                \
2078         gethostname             \
2079         getpass                 \
2080         getpwuid                \
2081         getpwnam                \
2082         getspnam                \
2083         gettimeofday    \
2084         initgroups              \
2085         lockf                   \
2086         memcpy                  \
2087         memmove                 \
2088         mkstemp                 \
2089         pipe                    \
2090         read                    \
2091         recv                    \
2092         recvfrom                \
2093         setpwfile               \
2094         setgid                  \
2095         setegid                 \
2096         setsid                  \
2097         setuid                  \
2098         seteuid                 \
2099         sigaction               \
2100         signal                  \
2101         sigset                  \
2102         snprintf                \
2103         strdup                  \
2104         strerror                \
2105         strpbrk                 \
2106         strrchr                 \
2107         strsep                  \
2108         strstr                  \
2109         strtol                  \
2110         strtoul                 \
2111         strspn                  \
2112         sysconf                 \
2113         waitpid                 \
2114         wait4                   \
2115         write                   \
2116         send                    \
2117         sendto                  \
2118 )
2119
2120 dnl We actually may need to replace more than this.
2121 AC_REPLACE_FUNCS(getopt tempnam)
2122
2123 if test "$ac_cv_func_getopt" != yes; then
2124     LIBSRCS="$LIBSRCS getopt.c"
2125 fi
2126
2127 if test "$ac_cv_func_tempnam" != yes; then
2128     LIBSRCS="$LIBSRCS tempnam.c"
2129 fi
2130
2131 dnl ----------------------------------------------------------------
2132 # Check Configuration
2133 OL_SYS_ERRLIST
2134
2135 dnl ----------------------------------------------------------------
2136 dnl Sort out defines
2137
2138 if test "$ol_enable_debug" != no ; then
2139         AC_DEFINE(LDAP_DEBUG,1,
2140                 [define this to add debugging code])
2141 fi
2142 if test "$ol_enable_syslog" = yes ; then
2143         AC_DEFINE(LDAP_SYSLOG,1,
2144                 [define this to add syslog code])
2145 fi
2146 if test "$ol_enable_libui" = yes ; then
2147         AC_DEFINE(LDAP_LIBUI,1,
2148                 [define this for LDAP User Interface support])
2149 fi
2150 if test "$ol_enable_cache" = no ; then
2151         AC_DEFINE(LDAP_NOCACHE,1,
2152                 [define this to remove -lldap cache support])
2153 fi
2154 if test "$ol_enable_kbind" != no ; then
2155         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2156 fi
2157 if test "$ol_enable_dns" != no ; then
2158         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
2159 fi
2160 if test "$ol_enable_proctitle" != no ; then
2161         AC_DEFINE(LDAP_PROCTITLE,1,
2162                 [define this for LDAP process title support])
2163 fi
2164 if test "$ol_enable_referrals" != no ; then
2165         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2166 fi
2167 if test "$ol_enable_cldap" != no ; then
2168         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
2169 fi
2170 if test "$ol_enable_ldapi" != no; then
2171         AC_DEFINE(USE_PF_LOCAL,1,[define to support PF_LOCAL transport])
2172 fi
2173
2174 if test "$ol_enable_cleartext" != no ; then
2175         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2176 fi
2177 if test "$ol_enable_crypt" != no ; then
2178         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2179 fi
2180 if test "$ol_enable_kpasswd" != no ; then
2181         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2182 fi
2183 if test "$ol_enable_multimaster" != no ; then
2184         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2185 fi
2186 if test "$ol_enable_phonetic" != no ; then
2187         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2188 fi
2189 if test "$ol_enable_rlookups" != no ; then
2190         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2191 fi
2192 if test "$ol_enable_aci" != no ; then
2193         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2194 fi
2195 if test "$ol_enable_discreteaci" != no ; then
2196         AC_DEFINE(SLAPD_ACI_DISCRETE_RIGHTS,1,[define to support discrete rights in ACIs])
2197 fi
2198
2199 if test "$ol_link_modules" != no ; then
2200         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2201         BUILD_SLAPD=yes
2202         SLAPD_MODULES_LDFLAGS="-dlopen self"
2203 fi
2204
2205 if test "$ol_link_bdb2" != no ; then
2206         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
2207         BUILD_SLAPD=yes
2208         BUILD_BDB2=yes
2209         if test "$ol_with_bdb2_module" != static ; then
2210                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
2211                         [define to support dynamic BDB2 backend])
2212                 BUILD_BDB2=mod
2213                 BUILD_BDB2_DYNAMIC=shared
2214                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
2215         fi
2216 fi
2217
2218 if test "$ol_enable_ldap" != no ; then
2219         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2220         BUILD_SLAPD=yes
2221         BUILD_LDAP=yes
2222         if test "$ol_with_ldap_module" != static ; then
2223                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2224                         [define to support dynamic LDAP backend])
2225                 BUILD_LDAP=mod
2226                 BUILD_LDAP_DYNAMIC=shared
2227                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2228         fi
2229 fi
2230
2231 if test "$ol_link_ldbm" != no ; then
2232         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2233         BUILD_SLAPD=yes
2234         BUILD_LDBM=yes
2235         if test "$ol_with_ldbm_module" != static ; then
2236                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2237                         [define to support dynamic LDBM backend])
2238                 BUILD_LDBM=mod
2239                 BUILD_LDBM_DYNAMIC=shared
2240                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2241         fi
2242 fi
2243
2244 if test "$ol_enable_passwd" != no ; then
2245         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2246         BUILD_SLAPD=yes
2247         BUILD_PASSWD=yes
2248         if test "$ol_with_passwd_module" != static ; then
2249                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2250                         [define to support dynamic PASSWD backend])
2251                 BUILD_PASSWD=mod
2252                 BUILD_PASSWD_DYNAMIC=shared
2253                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2254         fi
2255 fi
2256
2257 if test "$ol_link_perl" != no ; then
2258         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2259         BUILD_SLAPD=yes
2260         BUILD_PERL=yes
2261         if test "$ol_with_perl_module" != static ; then
2262                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2263                         [define to support dynamic PERL backend])
2264                 BUILD_PERL=mod
2265                 BUILD_PERL_DYNAMIC=shared
2266                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2267         fi
2268 fi
2269
2270 if test "$ol_enable_shell" != no ; then
2271         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2272         BUILD_SLAPD=yes
2273         BUILD_SHELL=yes
2274         if test "$ol_with_shell_module" != static ; then
2275                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2276                         [define to support dynamic SHELL backend])
2277                 BUILD_SHELL=mod
2278                 BUILD_SHELL_DYNAMIC=shared
2279                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2280         fi
2281 fi
2282
2283 if test "$ol_enable_tcl" != no ; then
2284         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2285         BUILD_SLAPD=yes
2286         BUILD_TCL=yes
2287         if test "$ol_with_tcl_module" != static; then
2288                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2289                         [define to support dynamic TCL backend])
2290                 BUILD_TCL=mod
2291                 BUILD_TCL_DYNAMIC=shared
2292                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2293         fi
2294 fi
2295
2296 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2297         $BUILD_SLAPD = yes ; then
2298         BUILD_SLURPD=yes
2299 fi
2300
2301 if test "$ol_link_isode" != no ; then
2302         BUILD_LDAPD=yes
2303 fi
2304
2305 dnl ----------------------------------------------------------------
2306
2307 if test "$LINK_BINS_DYNAMIC" = yes; then
2308     LIB_LINKAGE=DYN
2309     LT_LIB_LINKAGE=shared
2310 else
2311     LIB_LINKAGE=STAT
2312     LT_LIB_LINKAGE=static
2313 fi
2314
2315 if test "$ac_cv_mingw32" = yes ; then
2316     PLAT=NT
2317     DYN_EXT=dll
2318 else
2319     PLAT=UNIX
2320     DYN_EXT=so
2321 fi
2322
2323 AC_SUBST(LIBSRCS)
2324
2325 AC_SUBST(PLAT)
2326 AC_SUBST(LIB_LINKAGE)
2327 AC_SUBST(LT_LIB_LINKAGE)
2328 AC_SUBST(DYN_EXT)
2329
2330 AC_SUBST(BUILD_LDAPD)
2331 AC_SUBST(BUILD_SLAPD)
2332   AC_SUBST(BUILD_BDB2)
2333   AC_SUBST(BUILD_LDAP)
2334   AC_SUBST(BUILD_LDBM)
2335   AC_SUBST(BUILD_PASSWD)
2336   AC_SUBST(BUILD_PERL)
2337   AC_SUBST(BUILD_QUIPU)
2338   AC_SUBST(BUILD_SHELL)
2339   AC_SUBST(BUILD_TCL)
2340   AC_SUBST(BUILD_BDB2_DYNAMIC)
2341   AC_SUBST(BUILD_LDAP_DYNAMIC)
2342   AC_SUBST(BUILD_LDBM_DYNAMIC)
2343   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2344   AC_SUBST(BUILD_PERL_DYNAMIC)
2345   AC_SUBST(BUILD_SHELL_DYNAMIC)
2346   AC_SUBST(BUILD_TCL_DYNAMIC)
2347 AC_SUBST(BUILD_SLURPD)
2348
2349 AC_SUBST(LDAP_LIBS)
2350 AC_SUBST(LDAPD_LIBS)
2351 AC_SUBST(LDIF_LIBS)
2352 AC_SUBST(SLAPD_LIBS)
2353 AC_SUBST(SLURPD_LIBS)
2354 AC_SUBST(LDBM_LIBS)
2355 AC_SUBST(LTHREAD_LIBS)
2356 AC_SUBST(LUTIL_LIBS)
2357 AC_SUBST(WRAP_LIBS)
2358 AC_SUBST(MOD_TCL_LIB)
2359 AC_SUBST(LINK_BINS_DYNAMIC)
2360
2361 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2362 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2363 AC_SUBST(SLAPD_MODULES_LIST)
2364
2365 AC_SUBST(PERL_CPPFLAGS)
2366 AC_SUBST(SLAPD_PERL_LDFLAGS)
2367 AC_SUBST(MOD_PERL_LDFLAGS)
2368
2369 AC_SUBST(KRB4_LIBS)
2370 AC_SUBST(KRB5_LIBS)
2371 AC_SUBST(READLINE_LIBS)
2372 AC_SUBST(SASL_LIBS)
2373 AC_SUBST(TERMCAP_LIBS)
2374 AC_SUBST(TLS_LIBS)
2375 AC_SUBST(MODULES_LIBS)
2376
2377 dnl ----------------------------------------------------------------
2378 dnl final output
2379 dnl
2380
2381 AC_OUTPUT( \
2382 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2383 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2384 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2385 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2386 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2387 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2388 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2389 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2390 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2391 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2392 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2393 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2394 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2395 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2396 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2397 include/Makefile:build/top.mk:include/Makefile.in \
2398 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2399 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2400 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2401 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2402 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2403 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2404 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2405 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2406 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2407 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2408 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2409 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2410 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2411 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2412 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2413 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2414 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2415 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2416 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2417 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2418 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2419 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2420 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2421 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2422 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2423 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2424 ,[
2425 date > stamp-h
2426 echo Please \"make depend\" to build dependencies
2427 ])