git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  28 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  29 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  30 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  31 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  32 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  33 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  34         no, [yes no])dnl
  35
  36 dnl General "with" options
  37 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  38         auto, [auto k5 k4 afs yes no])
  39 OL_ARG_WITH(threads,[  --with-threads   use threads],
  40         auto, [auto posix mach lwp yes no manual] )
  41 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  42         auto, [auto yes no manual] )
  43
  44 dnl Server options
  45
  46 dnl LDAPD OPTIONS
  47 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  48
  49 dnl SLAPD OPTIONS
  50 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  51 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  52 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  53 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  54 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  55 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  56 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  57 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  58
  59 dnl SLAPD Backend options
  60 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  61 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  62         [auto db2 db gdbm ndbm manual])
  63 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  64         [auto btree hash])
  65
  66 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  67 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  68
  69 dnl SLURPD OPTIONS
  70 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  71
  72 # validate options
  73 if test $ol_enable_referrals = no ; then
  74         if test $ol_enable_dns = yes ; then
  75                 AC_MSG_WARN([dns disabled, ignoring --enable-dns argument])
  76         fi
  77         ol_enable_dns=no
  78 fi
  79
  80 if test $ol_enable_slapd = no ; then
  81         dnl SLAPD was specificallly disabled
  82         if test $ol_enable_ldbm = yes ; then
  83                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  84         fi
  85         if test $ol_enable_passwd = yes ; then
  86                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
  87         fi
  88         if test $ol_enable_shell = yes ; then
  89                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
  90         fi
  91         if test $ol_enable_aclgroups = yes ; then
  92                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
  93         fi
  94         if test $ol_enable_crypt = yes ; then
  95                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
  96         fi
  97         if test $ol_enable_md5 = yes ; then
  98                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
  99         fi
 100         if test $ol_enable_sha1 = yes ; then
 101                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
 102         fi
 103         if test $ol_enable_wrappers = yes ; then
 104                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 105         fi
 106         if test $ol_enable_phonetic = yes ; then
 107                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 108         fi
 109         if test $ol_enable_rlookups = yes ; then
 110                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 111         fi
 112         if test $ol_with_ldbm_api != auto ; then
 113                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 114         fi
 115         if test $ol_with_ldbm_type != auto ; then
 116                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 117         fi
 118         if test $ol_enable_slurpd = yes ; then
 119                 AC_MSG_ERROR([slurpd requires slapd])
 120         fi
 121
 122         # force settings to no
 123         ol_enable_ldbm=no
 124         ol_enable_shell=no
 125         ol_enable_passwd=no
 126         ol_enable_aclgroups=no
 127         ol_enable_crypt=no
 128         ol_enable_md5=no
 129         ol_enable_sha1=no
 130         ol_enable_wrappers=no
 131         ol_enable_phonetic=no
 132         ol_enable_rlookups=no
 133         ol_with_ldbm_api=no
 134         ol_with_ldbm_type=no
 135         ol_enable_slurpd=no
 136
 137 elif test $ol_enable_ldbm = no ; then
 138         dnl SLAPD without LDBM
 139
 140         if test $ol_with_ldbm_api != auto ; then
 141                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 142         fi
 143
 144         if test $ol_with_ldbm_type != auto ; then
 145                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 146         fi
 147
 148         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 149                 AC_MSG_ERROR([slapd requires a backend])
 150         fi
 151
 152         ol_with_ldbm_api=no
 153         ol_with_ldbm_type=no
 154
 155 else
 156         dnl SLAPD with LDBM
 157
 158         if test $ol_with_ldbm_api = gdbm -a \
 159                 $ol_with_ldbm_type = btree ; then
 160                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 161         fi
 162         if test $ol_with_ldbm_api = ndbm -a \
 163                 $ol_with_ldbm_type = btree ; then
 164                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 165         fi
 166 fi
 167
 168 if test $ol_enable_slurpd = yes ; then
 169         dnl SLURPD was specifically enabled
 170         if test $ol_with_threads = no ; then
 171                 AC_MSG_ERROR([slurpd requires threads])
 172         fi
 173 fi
 174
 175 AC_MSG_RESULT(done)
 176
 177 ## Initialize vars
 178 LDAP_LIBS=
 179 LDBM_LIBS=
 180 LTHREAD_LIBS=
 181 LUTIL_LIBS=
 182
 183 LDAPD_LIBS=
 184 SLAPD_LIBS=
 185 SLURPD_LIBS=
 186
 187 BUILD_LDAPD=no
 188 BUILD_SLAPD=no
 189 BUILD_SLURPD=no
 190
 191 BUILD_LDBM=no
 192 BUILD_PASSWD=no
 193 BUILD_SHELL=no
 194 BUILD_THREAD=no
 195
 196 KRB_LIBS=
 197 TERMCAP_LIBS=
 198
 199 dnl ----------------------------------------------------------------
 200 dnl Checks for programs
 201
 202 AC_PROG_LN_S
 203 AC_PROG_INSTALL
 204 AC_PROG_RANLIB
 205 AC_PROG_MAKE_SET
 206
 207 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 208         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 209 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 210 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 211
 212 dnl Checks the compiler and UNIX Variants
 213 AC_PROG_CC
 214
 215 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 216         AC_WARN([cross compiling....  some functionality will be removed.])
 217
 218 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 219         AC_WARN([programs compiled here do run here...])
 220         AC_ERROR([  if not cross compiling, use --disable-x-compile.])
 221
 222 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 223         AC_WARN([programs compiled here do not run here...])
 224         AC_ERROR([  if cross compiling,  add --enable-x-compile.])
 225 fi
 226
 227 dnl OpenLDAP requires STDC features
 228 dnl AC_PROG_GCC_TRADITIONAL
 229 AC_PROG_CPP
 230
 231
 232 AC_AIX
 233 AC_ISC_POSIX
 234 AC_MINIX
 235
 236 dnl Checks for libraries
 237
 238 dnl Find socket()
 239 dnl Likely combinations:
 240 dnl             -lsocket [ -lnsl_s | -lnsl ]
 241 dnl             -linet
 242
 243 AC_CHECK_FUNC(socket, :, [
 244 dnl
 245 dnl hopefully we won't include too many libraries
 246 dnl
 247         AC_CHECK_LIB(socket, main)
 248         AC_CHECK_LIB(net, main)
 249         AC_CHECK_LIB(nsl_s, main)
 250         AC_CHECK_LIB(nsl, main)
 251         AC_CHECK_LIB(inet, socket)
 252         AC_CHECK_LIB(gen, main)
 253 ])
 254
 255 dnl Check for resolv
 256 AC_CHECK_LIB(resolv, res_search)
 257
 258 dnl HP-UX requires -lV3
 259 AC_CHECK_LIB(V3, sigset)
 260
 261 # ISODE tests
 262 ol_link_isode=no
 263 if test $ol_enable_ldapd != no ; then
 264         dnl look for ISODE libraries
 265         AC_CHECK_LIB(xtpp, main, [
 266                 ol_link_isode=yes
 267                 AC_DEFINE(HAVE_XTPP,1)
 268                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 269                 ],:,[-lxtdsap -lxtisode -losi])
 270         AC_CHECK_LIB(dsap, main, [
 271                 ol_link_isode=yes
 272                 AC_DEFINE(HAVE_DSAP,1)
 273                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 274                 ],:,[-lisode])
 275         AC_CHECK_LIB(isode, main, [
 276                 ol_link_isode=yes
 277                 AC_DEFINE(HAVE_ISODE,1)
 278                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 279                 ],:)
 280 fi
 281
 282 if test $ol_link_isode != no; then
 283         AC_CHECK_LIB(pp, main, [
 284                 AC_DEFINE(HAVE_PP,1)
 285                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 286                 ],:)
 287
 288         AC_PATH_PROG(PEPSY, pepsy)
 289 fi
 290
 291 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 292         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 293
 294         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 295                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 296                         [-lkrb5 -ldes425])
 297
 298                 if test $have_k5 = yes ; then
 299                         ol_with_kerberos=found
 300                         ol_link_kerberos=yes
 301
 302                         AC_DEFINE(HAVE_KERBEROS)
 303
 304                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 305                 fi
 306         fi
 307 fi
 308 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 309         AC_CHECK_HEADERS(krb.h des.h)
 310
 311         if test $ac_cv_header_krb_h = yes ; then
 312                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 313
 314                 if test $have_k4 = yes ; then
 315                         ol_with_kerberos=found
 316                         ol_link_kerberos=yes
 317
 318                         AC_DEFINE(HAVE_KERBEROS)
 319
 320                         KRB_LIBS="-lkrb -ldes"
 321                 fi
 322         fi
 323 fi
 324
 325 ol_link_threads=no
 326 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 327         AC_CHECK_HEADERS(pthread.h sched.h)
 328
 329         if test $ac_cv_header_pthread_h = yes ; then
 330                 OL_POSIX_THREAD_VERSION
 331
 332                 if test $ol_cv_pthread_version = final ; then
 333                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 334                 elif test $ol_cv_pthread_version = draft4 ; then
 335                         AC_DEFINE(HAVE_PTHREADS_D4)
 336                 else
 337                         AC_MSG_ERROR([unknown pthread version])
 338                 fi
 339
 340                 # consider threads found
 341                 ol_with_threads=found
 342
 343                 OL_LINUX_THREADS
 344
 345                 if test $ol_cv_linux_threads = yes ; then
 346                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 347                 fi
 348
 349                 dnl Now the hard part, how to link
 350
 351                 dnl A few platforms have pthread support in standard libraries
 352                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 353
 354                 if test $ol_link_threads = no ; then
 355                         dnl try -pthread
 356                         AC_CACHE_CHECK([for pthread_create with -pthread],
 357                                 [ol_cv_pthread_flag], [
 358                                 dnl save the flags
 359                                 save_LIBS="$LIBS"
 360                                 LIBS="-pthread $LIBS"
 361                                 AC_TRY_LINK([char pthread();],[
 362                                         pthread_create();
 363                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 364                                 dnl restore the LIBS
 365                                 LIBS="$save_LIBS"
 366                         ])
 367
 368                         if test $ol_cv_pthread_flag = yes ; then
 369                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 370                                 ol_link_threads=posix
 371                         fi
 372                 fi
 373
 374                 if test $ol_link_threads = no ; then
 375                         dnl try -thread
 376                         AC_CACHE_CHECK([for pthread_create with -thread],
 377                                 [ol_cv_thread_flag], [
 378                                 dnl save the flags
 379                                 save_LIBS="$LIBS"
 380                                 LIBS="-thread $LIBS"
 381                                 AC_TRY_LINK([char pthread();],[
 382                                         pthread_create();
 383                                         ], ol_cv_thread_flag=yes, ol_cv_thread_flag=no)
 384                                 dnl restore the LIBS
 385                                 LIBS="$save_LIBS"
 386                         ])
 387
 388                         if test $ol_cv_thread_flag = yes ; then
 389                                 LTHREAD_LIBS="$LTHREAD_LIBS -thread"
 390                                 ol_link_threads=posix
 391                         fi
 392                 fi
 393
 394                 if test $ol_link_threads = no ; then
 395                         dnl try DEC Threads -lpthread -lexc
 396                         save_LIBS="$LIBS"
 397                         AC_CHECK_LIB(pthread, pthread_join, [
 398                                 ol_link_threads=posix
 399                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lexc"
 400                                 if test $ol_with_preemptive = auto ; then
 401                                         ol_with_preemptive=yes
 402                                 fi
 403                                 ],,[-lexc])
 404                         LIBS="$save_LIBS"
 405                 fi
 406
 407                 if test $ol_link_threads = no ; then
 408                         dnl try DEC Threads -lpthreads -lmach -lexc -lc_r
 409                         save_LIBS="$LIBS"
 410                         AC_CHECK_LIB(pthreads, pthread_join, [
 411                                 ol_link_threads=posix
 412                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthreads -lmach -lexc -lc_r"
 413                                 if test $ol_with_preemptive = auto ; then
 414                                         ol_with_preemptive=yes
 415                                 fi
 416                                 ],,[-lmach -lexc -lc_r])
 417                         LIBS="$save_LIBS"
 418                 fi
 419
 420                 if test $ol_link_threads = no ; then
 421                         dnl try -lpthread
 422                         save_LIBS="$LIBS"
 423                         AC_CHECK_LIB(pthread, pthread_create, [
 424                                 ol_link_threads=posix
 425                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 426                         LIBS="$save_LIBS"
 427                 fi
 428
 429                 if test $ol_link_threads = no ; then
 430                         dnl try -lc_r
 431                         save_LIBS="$LIBS"
 432                         AC_CHECK_LIB(c_r, pthread_create, [
 433                                 ol_link_threads=posix
 434                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 435                         LIBS="$save_LIBS"
 436                 fi
 437
 438                 if test $ol_link_threads != no ; then
 439                         AC_DEFINE(HAVE_PTHREADS)
 440
 441                         dnl save flags
 442                         save_CPPFLAGS="$CPPFLAGS"
 443                         save_LIBS="$LIBS"
 444                         LIBS="$LTHREAD_LIBS $LIBS"
 445
 446                         dnl All POSIX Thread (final) implementations should have
 447                         dnl sched_yield instead of pthread yield.
 448                         dnl check for both
 449                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 450
 451                         if test $ac_cv_func_sched_yield = no -a \
 452                                 $ac_cv_func_pthread_yield = no ; then
 453                                 dnl Digital UNIX has sched_yield() in -lrt
 454                                 AC_CHECK_LIB(rt, sched_yield,
 455                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 456                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 457                                         ac_cv_func_sched_yield=yes],
 458                                         [ac_cv_func_sched_yield=no])
 459                         fi
 460                         if test $ac_cv_func_sched_yield = no -a \
 461                                 $ac_cv_func_pthread_yield = no ; then
 462                                 dnl Solaris has sched_yield() in -lposix4
 463                                 AC_CHECK_LIB(posix4, sched_yield,
 464                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 465                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 466                                         ac_cv_func_sched_yield=yes],
 467                                         [ac_cv_func_sched_yield=no])
 468                         fi
 469                         if test $ac_cv_func_sched_yield = no -a \
 470                                 $ac_cv_func_pthread_yield = no ; then
 471                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 472                                 AC_MSG_ERROR([POSIX Threads are not usable])
 473                         fi
 474
 475                         dnl Check functions for compatibility
 476                         AC_CHECK_FUNCS(pthread_kill)
 477                         AC_CHECK_FUNCS( \
 478                                 pthread_attr_create pthread_attr_init \
 479                                 pthread_attr_destroy pthread_attr_delete \
 480                                 pthread_attr_setdetachstate pthread_attr_setdetach_np \
 481                         )
 482
 483                         dnl Check for setconcurreny functions
 484                         AC_CHECK_FUNCS( \
 485                                 pthread_setconcurrency \
 486                                 thr_setconcurrency \
 487                         )
 488
 489                         dnl Check PREEMPTIVE Implementation
 490                         if test $ol_with_preemptive = auto ; then
 491                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 492                                 AC_TRY_RUN([
 493 #include <sys/types.h>
 494 #include <sys/time.h>
 495 #include <unistd.h>
 496 #include <pthread.h>
 497 #ifndef NULL
 498 #define NULL 0
 499 #endif
 500
 501 int task(arg)
 502         int *arg;
 503 {
 504         int i;
 505         struct timeval tv;
 506
 507         tv.tv_sec=5;
 508         tv.tv_usec=0;
 509
 510         /* we're not interested in any fds */
 511         i = select(FD_SETSIZE, NULL, NULL, NULL, &tv);
 512
 513         if(i < 0) {
 514                 perror("select");
 515         }
 516
 517         exit(1); /* if we exit here, the select blocked the whole process */
 518 }
 519
 520 main(argc, argv)
 521 int argc; char **argv;
 522 {
 523         pthread_t t;
 524
 525 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 526         (void) pthread_setconcurrency(2);
 527 #else
 528 #ifdef HAVE_THR_SETCONCURRENCY
 529         /* Set Solaris LWP concurrency to 2 */
 530         thr_setconcurrency(2);
 531 #endif
 532 #endif
 533
 534         pthread_create(&t, NULL, (void *) task, NULL);
 535
 536 #if HAVE_SCHED_YIELD
 537         sched_yield();  /* make sure task runs first */
 538 #else
 539 #ifdef HAVE_PTHREAD_YIELD
 540         pthread_yield();        /* make sure task runs first */
 541 #endif
 542 #endif
 543         exit(0);
 544 }
 545                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 546                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 547                                 AC_MSG_RESULT($ol_pthread_preemptive)
 548
 549                                 if test $ol_pthread_preemptive = yes ; then
 550                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 551                                         ol_with_preemptive=yes
 552                                 fi
 553                         fi
 554
 555 dnl                     dnl check for reentrant/threadsafe functions
 556 dnl                     AC_CHECK_FUNCS( \
 557 dnl                             feof_unlocked \
 558 dnl                             unlocked_feof \
 559 dnl                             ftrylockfile \
 560 dnl                             flockfile \
 561 dnl                             putc_unlocked \
 562 dnl                             gmtime_r \
 563 dnl                             strtok_r \
 564 dnl                     )
 565
 566                         dnl restore flags
 567                         CPPFLAGS="$save_CPPFLAGS"
 568                         LIBS="$save_LIBS"
 569                 else
 570                         AC_MSG_ERROR([could not link with POSIX Threads])
 571                 fi
 572         fi
 573
 574         if test $ol_with_threads = posix ; then
 575                 AC_MSG_ERROR([could not locate POSIX Threads])
 576         fi
 577 fi
 578
 579 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 580         dnl check for Mach CThreads
 581         AC_CHECK_HEADERS(mach/cthreads.h)
 582         if test $ac_cv_header_mach_cthreads_h = yes ; then
 583                 ol_with_threads=found
 584
 585                 dnl A few platforms have cthread support in standard libraries
 586                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 587
 588                 if test $ol_link_threads = no ; then
 589                         dnl try -all_load
 590                         dnl this test needs work
 591                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 592                                 [ol_cv_cthread_all_load], [
 593                                 dnl save the flags
 594                                 save_LIBS="$LIBS"
 595                                 LIBS="-all_load $LIBS"
 596                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 597                                         cthread_fork((void *)0, (void *)0);
 598                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 599                                 dnl restore the LIBS
 600                                 LIBS="$save_LIBS"
 601                         ])
 602
 603                         if test $ol_cv_cthread_all_load = yes ; then
 604                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 605                                 ol_link_threads=mach
 606                         fi
 607                 fi
 608
 609                 if test $ol_link_threads != no ; then
 610                         : check for cthread specific functionality here
 611                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 612                 else
 613                         AC_MSG_ERROR([could not link with Mach CThreads])
 614                 fi
 615         fi
 616
 617         if test $ol_with_threads = mach ; then
 618                 AC_MSG_ERROR([could not locate Mach CThreads])
 619         fi
 620 fi
 621
 622 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 623         dnl check for SunOS5 LWP
 624         AC_CHECK_HEADERS(thread.h synch.h)
 625         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 626                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 627
 628                 if test $have_thr = yes ; then
 629                         AC_DEFINE(HAVE_THR)
 630                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 631                         ol_link_threads=thr
 632
 633                         if test $ol_with_preemptive = auto ; then
 634                                 ol_with_preemptive=yes
 635                         fi
 636                 fi
 637         fi
 638
 639         dnl check for SunOS4 LWP
 640         AC_CHECK_HEADERS(lwp/lwp.h)
 641         if test $ac_cv_header_lwp_lwp_h = yes ; then
 642                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 643
 644                 if test $have_lwp = yes ; then
 645                         AC_DEFINE(HAVE_LWP)
 646                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 647                         ol_link_threads=lwp
 648
 649                         if test $ol_with_preemptive = auto ; then
 650                                 ol_with_preemptive=no
 651                         fi
 652                 fi
 653         fi
 654 fi
 655
 656 if test $ol_with_preemptive = yes ; then
 657         AC_DEFINE(PREEMPTIVE_THREADS,1)
 658 fi
 659
 660 if test $ol_with_threads = manual ; then
 661         dnl User thinks he can manually configure threads.
 662         ol_link_threads=yes
 663
 664         AC_MSG_WARN([thread defines and link options must be set manually])
 665
 666         AC_CHECK_HEADERS(pthread.h sched.h)
 667         AC_CHECK_FUNCS(sched_yield pthread_yield)
 668         OL_LINUX_THREADS
 669
 670         AC_CHECK_HEADERS(mach/cthreads.h)
 671         AC_CHECK_HEADERS(lwp/lwp.h)
 672         AC_CHECK_HEADERS(thread.h synch.h)
 673 fi
 674
 675 if test $ol_with_threads != no ; then
 676         dnl needed to get reentrant/threadsafe versions
 677         dnl
 678         AC_DEFINE(_REENTRANT,1)
 679         AC_DEFINE(_THREAD_SAFE,1)
 680         AC_DEFINE(_THREADSAFE,1)
 681
 682         dnl this might cause the errno symbol to be
 683         dnl replaced with a function to get a thread specific errno.
 684         dnl check to see if everything needs to be compiled
 685         dnl with the thread libraries
 686         AC_CACHE_CHECK([for thread specific errno],
 687                 [ol_cv_errno_thread_specific], [
 688                 AC_TRY_LINK([
 689 #include <errno.h>
 690                         ], [
 691 int x = errno;
 692                         ],
 693                         [ol_cv_errno_thread_specific=yes],
 694                         [ol_cv_errno_thread_specific=no])
 695         ])
 696
 697         if test $ol_cv_errno_thread_specific != yes ; then
 698                 LIBS="$LTHREAD_LIBS $LIBS"
 699                 LTHREAD_LIBS=""
 700         fi
 701 fi
 702
 703 dnl ----------------------------------------------------------------
 704
 705 if test $ol_link_threads = no ; then
 706         if test $ol_with_threads = yes ; then
 707                 AC_MSG_ERROR([no suitable thread support])
 708         fi
 709
 710         if test $ol_with_threads = auto ; then
 711                 AC_MSG_WARN([no suitable thread support, disabling threads])
 712                 ol_with_threads=no
 713         fi
 714
 715         AC_DEFINE(NO_THREADS,1)
 716         AC_DEFINE(PREEMPTIVE_THREADS,1)
 717         LTHREAD_LIBS=""
 718 fi
 719
 720 ol_link_ldbm=no
 721 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 722         OL_BERKELEY_DB2
 723
 724         if test $ol_cv_berkeley_db2 = yes ; then
 725                 ol_link_ldbm=db2
 726                 ol_with_ldbm_api=db2
 727
 728                 if test $ol_with_ldbm_type = hash ; then
 729                         AC_DEFINE(LDBM_USE_DBHASH,1)
 730                 else
 731                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 732                 fi
 733
 734                 dnl $ol_cv_lib_db2 should be yes or -ldb
 735                 dnl (it could be no, but that would be an error
 736                 if test $ol_cv_lib_db2 != yes ; then
 737                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 738                 fi
 739         fi
 740 fi
 741
 742 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 743         OL_BERKELEY_DB
 744
 745         if test $ol_cv_berkeley_db = yes ; then
 746                 ol_link_ldbm=db
 747                 ol_with_ldbm_api=db
 748
 749                 if test $ol_with_ldbm_type = hash ; then
 750                         AC_DEFINE(LDBM_USE_DBHASH,1)
 751                 else
 752                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 753                 fi
 754
 755                 dnl $ol_cv_lib_db should be yes or -ldb
 756                 dnl (it could be no, but that would be an error
 757                 if test $ol_cv_lib_db != yes ; then
 758                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 759                 fi
 760         fi
 761 fi
 762
 763 if test $ol_with_ldbm_api = manual ; then
 764         dnl User thinks he can manually configure LDBM api.
 765         ol_link_ldbm=yes
 766
 767         AC_MSG_WARN([LDBM defines and link options must be set manually])
 768
 769         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 770 fi
 771
 772 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 773         AC_MSG_WARN(Could not find LDBM with BTREE support)
 774         ol_with_ldbm_api=none
 775 fi
 776
 777 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 778         OL_GDBM
 779
 780         if test $ol_cv_gdbm = yes ; then
 781                 ol_link_ldbm=gdbm
 782                 ol_with_ldbm_api=gdbm
 783
 784                 if test $ol_cv_lib_gdbm != yes ; then
 785                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 786                 fi
 787         fi
 788 fi
 789
 790 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 791         OL_NDBM
 792
 793         if test $ol_cv_ndbm = yes ; then
 794                 ol_link_ldbm=ndbm
 795                 ol_with_ldbm_api=ndbm
 796
 797                 if test $ol_with_ldbm_api = ndbm ; then
 798                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 799                 fi
 800
 801                 if test $ol_cv_lib_ndbm != yes ; then
 802                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 803                 fi
 804         fi
 805 fi
 806
 807 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 808         AC_MSG_WARN(could not find suitable LDBM backend)
 809         if test $ol_enable_ldbm = yes ; then
 810                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 811         fi
 812
 813         AC_MSG_WARN(disabling LDBM)
 814         ol_enable_ldbm=no
 815 fi
 816
 817 if test $ol_enable_wrappers = yes ; then
 818         AC_CHECK_LIB(wrap, hosts_access,
 819                 [have_wrappers=yes], [have_wrappers=no])
 820
 821         if test $have_wrappers = yes ; then
 822                 AC_DEFINE(HAVE_TCPD)
 823                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 824         else
 825                 AC_MSG_WARN(could not find -lwrap)
 826                 if test $ol_enable_wrappers = yes ; then
 827                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 828                 fi
 829
 830                 AC_MSG_WARN(disabling wrappers support)
 831                 ol_enable_wrappers=no
 832         fi
 833
 834 fi
 835
 836 # ud needs termcap (should insert check here)
 837 ol_link_termcap=no
 838 AC_CHECK_HEADERS(termcap.h ncurses.h)
 839
 840 if test $ol_link_termcap = no ; then
 841         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 842         if test $have_termcap = yes ; then
 843                 AC_DEFINE(HAVE_TERMCAP)
 844                 ol_link_termcap=yes
 845                 TERMCAP_LIBS=-ltermcap
 846         fi
 847 fi
 848
 849 if test $ol_link_termcap = no ; then
 850         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 851         if test $have_ncurses = yes ; then
 852                 AC_DEFINE(HAVE_NCURSES)
 853                 ol_link_termcap=yes
 854                 TERMCAP_LIBS=-lncurses
 855         fi
 856 fi
 857
 858 if test $ol_link_termcap = no ; then
 859         AC_DEFINE(NO_TERMCAP,1)
 860         TERMCAP_LIBS=
 861 fi
 862
 863 # FreeBSD (and others) have crypt(3) in -lcrypt
 864 if test $ol_enable_crypt != no ; then
 865         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 866                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 867                         have_crypt=yes], [have_crypt=no])])
 868
 869         if test $have_crypt = yes ; then
 870                 AC_DEFINE(HAVE_CRYPT,1)
 871         else
 872                 AC_MSG_WARN(could not find crypt)
 873                 if test $ol_enable_crypt = yes ; then
 874                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 875                 fi
 876
 877                 AC_MSG_WARN(disabling crypt support)
 878                 ol_enable_crypt=no
 879         fi
 880 fi
 881
 882 # FreeBSD (and others) have setproctitle(3) in -lutil
 883 if test $ol_enable_proctitle != no ; then
 884         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 885                 AC_CHECK_LIB(util, setproctitle,
 886                         [have_setproctitle=yes
 887                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 888                         [have_setproctitle=no
 889                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 890
 891         if test $have_setproctitle = yes ; then
 892                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 893         fi
 894 fi
 895
 896 dnl ----------------------------------------------------------------
 897 dnl Checks for header files.
 898 AC_HEADER_STDC
 899
 900 if test $ac_cv_header_stdc != yes; then
 901         AC_MSG_WARN([could not locate Standard C headers])
 902 fi
 903
 904 AC_HEADER_DIRENT
 905 AC_HEADER_SYS_WAIT
 906 AC_CHECK_HEADERS(       \
 907         crypt.h                 \
 908         errno.h                 \
 909         fcntl.h                 \
 910         filio.h                 \
 911         getopt.h                \
 912         libutil.h               \
 913         limits.h                \
 914         malloc.h                \
 915         memory.h                \
 916         regex.h                 \
 917         pwd.h                   \
 918         sgtty.h                 \
 919         stdarg.h                \
 920         stddef.h                \
 921         string.h                \
 922         strings.h               \
 923         sys/file.h              \
 924         sys/filio.h             \
 925         sys/errno.h             \
 926         sys/ioctl.h             \
 927         sys/param.h             \
 928         sys/resource.h  \
 929         sys/socket.h    \
 930         sys/syslog.h    \
 931         sys/time.h              \
 932         sys/types.h             \
 933         syslog.h                \
 934         termios.h               \
 935         unistd.h                \
 936 )
 937
 938 dnl ----------------------------------------------------------------
 939 dnl Checks for typedefs, structures, and compiler characteristics.
 940 AC_TYPE_GETGROUPS
 941 AC_TYPE_MODE_T
 942 AC_TYPE_OFF_T
 943 AC_TYPE_PID_T
 944 AC_TYPE_SIGNAL
 945 AC_TYPE_SIZE_T
 946 AC_TYPE_UID_T
 947 AC_STRUCT_ST_BLKSIZE
 948 AC_HEADER_TIME
 949 AC_STRUCT_TM
 950
 951 OL_C_UPPER_LOWER
 952 AC_C_CONST
 953
 954 if test $cross_compiling = yes ; then
 955         AC_DEFINE(CROSS_COMPILING, 1)
 956 else
 957         AC_C_BIGENDIAN
 958         AC_CHECK_SIZEOF(short)
 959         AC_CHECK_SIZEOF(int)
 960         AC_CHECK_SIZEOF(long)
 961 fi
 962
 963 dnl ----------------------------------------------------------------
 964 dnl Checks for library functions.
 965 AC_FUNC_MEMCMP
 966 AC_FUNC_STRFTIME
 967 AC_FUNC_VPRINTF
 968
 969 if test $ac_cv_func_vprintf = yes ; then
 970         dnl check for vsnprintf
 971         AC_CHECK_FUNCS(vsnprintf)
 972 fi
 973
 974 AC_FUNC_WAIT3
 975
 976 AC_CHECK_FUNCS(         \
 977         bcopy                   \
 978         flock                   \
 979         getdtablesize   \
 980         gethostname             \
 981         getpwuid                \
 982         gettimeofday    \
 983         lockf                   \
 984         memcpy                  \
 985         memmove                 \
 986         mkstemp                 \
 987         mktime                  \
 988         res_search              \
 989         select                  \
 990         setpwfile               \
 991         setsid                  \
 992         signal                  \
 993         sigset                  \
 994         snprintf                \
 995         socket                  \
 996         strerror                \
 997         strpbrk                 \
 998         strrchr                 \
 999         strsep                  \
1000         strstr                  \
1001         strtod                  \
1002         strtok                  \
1003         strtol                  \
1004         strtoul                 \
1005         sysconf                 \
1006         waitpid                 \
1007 )
1008
1009 dnl We actually may need to replace more than this.
1010 AC_REPLACE_FUNCS(getopt strdup tempnam)
1011
1012 dnl ----------------------------------------------------------------
1013 # Check Configuration
1014 OL_SYS_ERRLIST
1015
1016 dnl ----------------------------------------------------------------
1017 dnl Sort out defines
1018
1019 if test $ol_enable_debug != no ; then
1020         AC_DEFINE(LDAP_DEBUG,1)
1021 fi
1022 dnl     if test $ol_enable_syslog != no ; then
1023 dnl             AC_DEFINE(LDAP_SYSLOG,1)
1024 dnl     fi
1025 if test $ol_enable_libui = yes ; then
1026         AC_DEFINE(LDAP_LIBUI,1)
1027 fi
1028 if test $ol_enable_cache = no ; then
1029         AC_DEFINE(LDAP_NOCACHE,1)
1030 fi
1031 if test $ol_enable_dns != no ; then
1032         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION,1)
1033 fi
1034 if test $ol_enable_proctitle != no ; then
1035         AC_DEFINE(LDAP_PROCTITLE,1)
1036 fi
1037 if test $ol_enable_referrals != no ; then
1038         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION,1)
1039 fi
1040 if test $ol_enable_cldap != no ; then
1041         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1042 fi
1043
1044 if test $ol_enable_aclgroups != no ; then
1045         AC_DEFINE(SLAPD_ACLGROUPS,1)
1046 fi
1047 if test $ol_enable_crypt != no ; then
1048         AC_DEFINE(SLAPD_CRYPT,1)
1049 fi
1050 if test $ol_enable_md5 != no ; then
1051         AC_DEFINE(SLAPD_MD5,1)
1052 fi
1053 if test $ol_enable_sha1 != no ; then
1054         AC_DEFINE(SLAPD_SHA1,1)
1055 fi
1056 if test $ol_enable_phonetic != no ; then
1057         AC_DEFINE(SLAPD_PHONETIC,1)
1058 fi
1059 if test $ol_enable_rlookups != no ; then
1060         AC_DEFINE(SLAPD_RLOOKUPS,1)
1061 fi
1062
1063 if test $ol_link_ldbm != no ; then
1064         AC_DEFINE(SLAPD_LDBM,1)
1065         BUILD_SLAPD=yes
1066         BUILD_LDBM=yes
1067 fi
1068
1069 if test $ol_enable_passwd != no ; then
1070         AC_DEFINE(SLAPD_PASSWD,1)
1071         BUILD_SLAPD=yes
1072         BUILD_PASSWD=yes
1073 fi
1074
1075 if test $ol_enable_shell != no ; then
1076         AC_DEFINE(SLAPD_SHELL,1)
1077         BUILD_SLAPD=yes
1078         BUILD_SHELL=yes
1079 fi
1080
1081 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1082         $BUILD_SLAPD = yes ; then
1083         BUILD_SLURPD=yes
1084 fi
1085
1086 if test $ol_link_isode != no ; then
1087         BUILD_LDAPD=yes
1088 fi
1089
1090 dnl ----------------------------------------------------------------
1091
1092 AC_SUBST(BUILD_LDAPD)
1093 AC_SUBST(BUILD_SLAPD)
1094   AC_SUBST(BUILD_LDBM)
1095   AC_SUBST(BUILD_PASSWD)
1096   AC_SUBST(BUILD_SHELL)
1097 AC_SUBST(BUILD_SLURPD)
1098
1099
1100 AC_SUBST(LDAP_LIBS)
1101 AC_SUBST(LDAPD_LIBS)
1102 AC_SUBST(SLAPD_LIBS)
1103 AC_SUBST(SLURPD_LIBS)
1104 AC_SUBST(LDBM_LIBS)
1105 AC_SUBST(LTHREAD_LIBS)
1106 AC_SUBST(LUTIL_LIBS)
1107
1108 AC_SUBST(KRB_LIBS)
1109 AC_SUBST(TERMCAP_LIBS)
1110
1111 dnl ----------------------------------------------------------------
1112 dnl final output
1113 dnl
1114
1115 AC_OUTPUT( \
1116 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1117 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1118 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1119 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1120 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1121 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1122 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1123 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1124 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1125 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1126 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1127 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1128 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1129 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1130 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1131 include/Makefile:build/top.mk:include/Makefile.in \
1132 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1133 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
1134 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
1135 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
1136 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
1137 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
1138 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
1139 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
1140 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1141 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1142 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1143 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1144 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1145 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1146 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1147 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1148 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1149 tests/Makefile:build/top.mk:tests/Makefile.in \
1150 ,[
1151 date > stamp-h
1152 echo Please \"make depend\" to build dependencies
1153 ])