git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-1999 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Copying restrictions apply, see COPYRIGHT file."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35 AC_CONFIG_AUX_DIR(build)dnl
  36
  37 OL_VERSION=`cat $ac_aux_dir/version`
  38 if test -z "$OL_VERSION"; then
  39         AC_MSG_ERROR([could not determine version])
  40 fi
  41
  42 echo "Configuring OpenLDAP $OL_VERSION ..."
  43
  44 dnl Determine host platform
  45 dnl             we try not to use this for much
  46 AC_CANONICAL_SYSTEM
  47
  48 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  49 AC_SUBST(PACKAGE)
  50 AC_SUBST(VERSION)
  51 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  52 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  53
  54 dnl We use autoconf features new to 2.13.
  55 dnl aclocal.m4 should be built using aclocal from automake 1.4
  56 dnl libtool 1.3.3 should be installed.
  57 AC_PREREQ(2.13)dnl Required Autoconf version
  58
  59 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  60
  61 dnl ================================================================
  62 dnl Start Args
  63 AC_MSG_CHECKING(configure arguments)
  64 AC_PREFIX_DEFAULT(/usr/local)
  65
  66 top_builddir=`pwd`
  67 AC_SUBST(top_builddir)dnl
  68
  69 dnl ----------------------------------------------------------------
  70 dnl --with-subdir
  71 ldap_subdir="/openldap"
  72
  73 AC_ARG_WITH(subdir,
  74 [  --with-subdir=DIR change default subdirectory used for installs],
  75 [case "$withval" in
  76         no) ldap_subdir=""
  77                 ;;
  78         yes)
  79                 ;;
  80         /*|\\*)
  81                 ldap_subdir="$withval"
  82                 ;;
  83         *)
  84                 ldap_subdir="/$withval"
  85                 ;;
  86 esac
  87 ])dnl
  88
  89 AC_SUBST(ldap_subdir)dnl
  90
  91 dnl ----------------------------------------------------------------
  92 dnl General "enable" options
  93 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  94 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  95 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  96 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  97 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DX Referrals extension], no)dnl
  98 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  99 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
 100 OL_ARG_ENABLE(ldapi,[  --enable-ldapi   enable domain socket (PF_LOCAL) ldap], no)dnl
 101 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
 102         no, [yes no])dnl
 103
 104 dnl ----------------------------------------------------------------
 105 dnl General "with" options
 106 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
 107
 108 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl     with Cyrus SASL support],
 109         auto, [auto yes no] )
 110 OL_ARG_WITH(fetch,[  --with-fetch               with fetch URL support],
 111         auto, [auto yes no] )
 112 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
 113         auto, [auto k5 kth k4 afs yes no])
 114 OL_ARG_WITH(readline,[  --with-readline with readline support],
 115         auto, [auto yes no] )
 116 OL_ARG_WITH(threads,[  --with-threads   use threads],
 117         auto, [auto nt posix mach pth lwp yes no manual] )
 118 OL_ARG_WITH(tls,[  --with-tls           with TLS/SSL support],
 119         auto, [auto ssleay openssl yes no] )
 120 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
 121         auto, [auto yes no manual] )
 122
 123 dnl ----------------------------------------------------------------
 124 dnl Server options
 125 dnl ----------------------------------------------------------------
 126 dnl LDAPD OPTIONS
 127 AC_ARG_WITH(xxldapdoptions,[LDAPD (X.500-to-LDAP Gateway) Options:])
 128 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
 129
 130 dnl ----------------------------------------------------------------
 131 dnl SLAPD OPTIONS
 132 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 133 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 134 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 135 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 136 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 137 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 138 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 139 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 140 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 141 OL_ARG_ENABLE(aci,[    --enable-aci     enable per-object ACIs], no)dnl
 142 OL_ARG_ENABLE(discreteaci,[    --enable-discreteaci     enable discrete rights in ACIs], no)dnl
 143 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 144 OL_ARG_ENABLE(dynamic,[    --enable-dynamic     enable linking built binaries with dynamic libs], no)dnl
 145
 146 dnl SLAPD Backend options
 147 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 148 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 149         [static dynamic])
 150 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 151 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 152         [static dynamic])
 153 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 154 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 155         [auto db2 db mdbm gdbm ndbm manual])
 156 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 157         [static dynamic])
 158 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 159         [auto btree hash])
 160
 161 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 162 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 163         [static dynamic])
 164 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 165 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 166         [static dynamic])
 167 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 168 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 169         [static dynamic])
 170 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 171 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 172         [static dynamic])
 173
 174 dnl ----------------------------------------------------------------
 175 dnl SLURPD OPTIONS
 176 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 177 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 178
 179 dnl ----------------------------------------------------------------
 180 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 181 AC_ENABLE_STATIC
 182 dnl AC_DISABLE_SHARED
 183 AC_ENABLE_SHARED
 184
 185 dnl ----------------------------------------------------------------
 186
 187 dnl General "enable" options
 188 # validate options
 189 if test $ol_enable_dns = yes ; then
 190         if test $ol_enable_referrals = no ; then
 191                 AC_MSG_ERROR([DNS requires --enable-referrals])
 192         fi
 193         if test $ol_enable_referrals = auto ; then
 194                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 195                 ol_enable_referrals=yes
 196         fi
 197 fi
 198
 199 if test $ol_enable_slapd = no ; then
 200         dnl SLAPD was specificallly disabled
 201         if test $ol_enable_bdb2 = yes ; then
 202                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 203         fi
 204         if test $ol_enable_ldap = yes ; then
 205                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 206         fi
 207         if test $ol_enable_ldbm = yes ; then
 208                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 209         fi
 210         if test $ol_enable_passwd = yes ; then
 211                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 212         fi
 213         if test $ol_enable_perl = yes ; then
 214                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 215         fi
 216         if test $ol_enable_shell = yes ; then
 217                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 218         fi
 219         if test $ol_enable_tcl = yes ; then
 220                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 221         fi
 222         if test $ol_enable_modules = yes ; then
 223                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 224         fi
 225         if test $ol_enable_multimaster = yes ; then
 226                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 227         fi
 228         if test $ol_enable_wrappers = yes ; then
 229                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 230         fi
 231         if test $ol_enable_phonetic = yes ; then
 232                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 233         fi
 234         if test $ol_enable_quipu = yes ; then
 235                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 236         fi
 237         if test $ol_enable_rlookups = yes ; then
 238                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 239         fi
 240         if test $ol_enable_aci = yes ; then
 241                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 242         fi
 243         if test $ol_enable_discreteaci = yes ; then
 244                 AC_MSG_WARN([slapd disabled, ignoring --enable-discreteaci argument])
 245         fi
 246         if test $ol_with_ldbm_api != auto ; then
 247                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 248         fi
 249         if test $ol_with_ldbm_type != auto ; then
 250                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 251         fi
 252         if test $ol_with_bdb2_module != static ; then
 253                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 254         fi
 255         if test $ol_with_ldap_module != static ; then
 256                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 257         fi
 258         if test $ol_with_ldbm_module != static ; then
 259                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 260         fi
 261         if test $ol_with_passwd_module != static ; then
 262                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 263         fi
 264         if test $ol_with_perl_module != static ; then
 265                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 266         fi
 267         if test $ol_with_shell_module != static ; then
 268                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 269         fi
 270         if test $ol_with_tcl_module != static ; then
 271                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 272         fi
 273         if test $ol_enable_slurpd = yes ; then
 274                 AC_MSG_ERROR([slurpd requires slapd])
 275         fi
 276
 277         # force settings to no
 278         ol_enable_bdb2=no
 279         ol_enable_ldap=no
 280         ol_enable_ldbm=no
 281         ol_enable_passwd=no
 282         ol_enable_perl=no
 283         ol_enable_shell=no
 284         ol_enable_tcl=no
 285
 286         ol_enable_modules=no
 287         ol_enable_multimaster=no
 288         ol_enable_phonetic=no
 289         ol_enable_quipu=no
 290         ol_enable_rlookups=no
 291         ol_enable_aci=no
 292         ol_enable_discreteaci=no
 293         ol_enable_wrappers=no
 294         ol_enable_dynamic=no
 295
 296         ol_with_ldbm_api=no
 297         ol_with_ldbm_type=no
 298
 299         ol_with_bdb2_module=static
 300         ol_with_ldap_module=static
 301         ol_with_ldbm_module=static
 302         ol_with_passwd_module=static
 303         ol_with_perl_module=static
 304         ol_with_shell_module=static
 305         ol_with_tcl_module=static
 306
 307         ol_enable_slurpd=no
 308
 309 elif test $ol_enable_ldbm = no ; then
 310         dnl SLAPD without LDBM
 311
 312         if test $ol_with_ldbm_api != auto ; then
 313                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 314         fi
 315
 316         if test $ol_with_ldbm_type != auto ; then
 317                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 318         fi
 319
 320         if test $ol_with_ldbm_module != static ; then
 321                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 322         fi
 323
 324         if test $ol_enable_bdb2 = yes ; then
 325                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 326         fi
 327
 328         if test $ol_enable_modules != yes -a \
 329                 $ol_enable_ldap = no -a \
 330                 $ol_enable_passwd = no -a \
 331                 $ol_enable_perl = no -a \
 332                 $ol_enable_shell = no -a \
 333                 $ol_enable_tcl = no ; then
 334                 AC_MSG_ERROR([slapd requires a backend])
 335         fi
 336
 337         ol_with_ldbm_api=no
 338         ol_with_ldbm_type=no
 339         ol_with_ldbm_module=static
 340
 341 elif test $ol_enable_bdb2 = yes ; then
 342         dnl SLAPD with BDB2
 343
 344         if test $ol_with_ldbm_api != auto -a \
 345                 $ol_with_ldbm_api != db2 ; then
 346                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 347         fi
 348
 349         ol_with_ldbm_api=db2
 350
 351 else
 352         dnl SLAPD with LDBM
 353
 354         if test $ol_enable_bdb2 != no ; then
 355                 if test $ol_with_ldbm_api != auto -a \
 356                         $ol_with_ldbm_api != db2 ; then
 357                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 358                         ol_enable_bdb2=no
 359                 fi
 360         fi
 361
 362         if test $ol_with_ldbm_api = gdbm -a \
 363                 $ol_with_ldbm_type = btree ; then
 364                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 365         fi
 366         if test $ol_with_ldbm_api = mdbm -a \
 367                 $ol_with_ldbm_type = btree ; then
 368                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 369         fi
 370         if test $ol_with_ldbm_api = ndbm -a \
 371                 $ol_with_ldbm_type = btree ; then
 372                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 373         fi
 374 fi
 375
 376 if test $ol_enable_slurpd = yes ; then
 377         dnl SLURPD was specifically enabled
 378         if test $ol_with_threads = no ; then
 379                 AC_MSG_ERROR([slurpd requires threads])
 380         fi
 381 fi
 382
 383 AC_MSG_RESULT(done)
 384
 385 dnl ----------------------------------------------------------------
 386 dnl Initialize vars
 387 LDAP_LIBS=
 388 LDIF_LIBS=
 389 LDBM_LIBS=
 390 LTHREAD_LIBS=
 391 LUTIL_LIBS=
 392
 393 LDAPD_LIBS=
 394 SLAPD_LIBS=
 395 SLURPD_LIBS=
 396
 397 BUILD_LDAPD=no
 398 BUILD_SLAPD=no
 399 BUILD_SLURPD=no
 400
 401 BUILD_BDB2=no
 402 BUILD_LDAP=no
 403 BUILD_LDBM=no
 404 BUILD_PASSWD=no
 405 BUILD_PERL=no
 406 BUILD_QUIPU=no
 407 BUILD_SHELL=no
 408 BUILD_TCL=no
 409 BUILD_THREAD=no
 410
 411 BUILD_BDB2_DYNAMIC=static
 412 BUILD_LDAP_DYNAMIC=static
 413 BUILD_LDBM_DYNAMIC=static
 414 BUILD_PASSWD_DYNAMIC=static
 415 BUILD_PERL_DYNAMIC=static
 416 BUILD_SHELL_DYNAMIC=static
 417 BUILD_TCL_DYNAMIC=static
 418
 419 SLAPD_MODULES_LDFLAGS=
 420 SLAPD_MODULES_CPPFLAGS=
 421 SLAPD_MODULES_LIST=
 422
 423 SLAPD_PERL_LDFLAGS=
 424 MOD_PERL_LDFLAGS=
 425 PERL_CPPFLAGS=
 426
 427 MOD_TCL_LIB=
 428 KRB_LIBS=
 429 READLINE_LIBS=
 430 SASL_LIBS=
 431 TERMCAP_LIBS=
 432 TLS_LIBS=
 433 MODULES_LIBS=
 434
 435 dnl ================================================================
 436 dnl Checks for programs
 437
 438 dnl AC_PROG_INSTALL
 439
 440 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 441
 442 dnl ----------------------------------------------------------------
 443 dnl
 444 dnl Determine which C translator to use
 445 dnl
 446
 447 dnl AIX Thread requires we use cc_r or xlc_r.
 448 dnl But only do this IF AIX and CC is not set
 449 dnl and threads are auto|yes|posix.
 450 dnl
 451 dnl If we find cc_r|xlc_r, force pthreads and assume
 452 dnl             pthread_create is in $LIBS (ie: don't bring in
 453 dnl             any additional thread libraries)
 454 dnl If we do not find cc_r|xlc_r, disable threads
 455
 456 ol_aix_threads=no
 457 case "$target" in
 458 *-*-aix*) dnl all AIX is not a good idea.
 459         if test -z "$CC" ; then
 460                 case "$ol_with_threads" in
 461                 auto | yes |  posix) ol_aix_threads=yes ;;
 462                 esac
 463         fi
 464 ;;
 465 esac
 466
 467 if test $ol_aix_threads = yes ; then
 468         if test -z "${CC}" ; then
 469                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 470
 471                 if test "$CC" = cc ; then
 472                         dnl no CC! don't allow --with-threads
 473                         if test $ol_with_threads != auto ; then
 474                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 475                         else
 476                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 477                         fi
 478                         ol_with_threads=no
 479                 fi
 480         fi
 481
 482         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 483                 ol_with_threads=posix
 484                 ol_cv_pthread_create=yes
 485         fi
 486 fi
 487
 488 if test -z "${CC}"; then
 489         AC_CHECK_PROGS(CC,cc)
 490 fi
 491
 492 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 493 dnl (for now, let autoconf sort this out)
 494 dnl CFLAGS=${CFLAGS-""}
 495
 496 AC_LIBTOOL_WIN32_DLL
 497 AC_LIBTOOL_DLOPEN
 498 AC_PROG_LIBTOOL
 499
 500 AC_PROG_AWK
 501 OL_PROG_LN_H
 502 AC_PROG_LN_S
 503
 504 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 505         LN_S="$LN_H"
 506 fi
 507
 508 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 509         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 510 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 511 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 512
 513 dnl ----------------------------------------------------------------
 514 dnl Perl
 515 ol_link_perl=no
 516 if test $ol_enable_perl != no ; then
 517         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 518
 519         if test "no$PERLBIN" = "no" ; then
 520                 if test $ol_enable_perl = yes ; then
 521                         AC_MSG_ERROR([could not locate perl])
 522                 fi
 523
 524         else
 525                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 526                 if test x"$ol_with_perl_module" = "xstatic" ; then
 527                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 528                 else
 529                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 530                 fi
 531                 dnl should check perl version
 532                 ol_link_perl=yes
 533         fi
 534 fi
 535
 536 AC_PROG_CPP
 537
 538 dnl ----------------------------------------------------------------
 539 dnl Cross compiling checks
 540 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 541         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 542
 543 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 544         AC_MSG_WARN([programs compiled here do run here...])
 545         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 546
 547 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 548         AC_MSG_WARN([programs compiled here do not run here...])
 549         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 550 fi
 551
 552 dnl ----------------------------------------------------------------
 553 dnl Checks for UNIX Variants
 554 AC_AIX
 555 AC_ISC_POSIX
 556 AC_MINIX
 557
 558 dnl ----------------------------------------------------------------
 559 dnl Checks for system services
 560 AC_CYGWIN
 561 AC_MINGW32
 562 AC_EXEEXT
 563 AC_OBJEXT
 564
 565 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 566
 567 dnl ----------------------------------------------------------------
 568 dnl BeOS requires -lbe -lroot -lnet
 569 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 570
 571 dnl ----------------------------------------------------------------
 572 dnl OpenLDAP requires STDC features
 573 AM_PROG_CC_STDC
 574 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 575         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 576 fi
 577
 578 dnl ----------------------------------------------------------------
 579 dnl Check cc depend flags
 580 OL_MKDEPEND
 581 if test "${ol_cv_mkdep}" = no ; then
 582         # this will soon become an error
 583         AC_MSG_WARN([do not know how to generate dependencies])
 584 fi
 585
 586 dnl ----------------------------------------------------------------
 587 dnl Check for module support
 588 ol_link_modules=no
 589 if test $ol_enable_modules != no ; then
 590         AC_CHECK_HEADERS(ltdl.h)
 591
 592         if test $ac_cv_header_ltdl_h = no ; then
 593                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 594         fi
 595
 596         AC_CHECK_LIB(ltdl, lt_dlinit, [
 597             MODULES_LIBS=-lltdl
 598             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 599         ])
 600
 601         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 602                 AC_MSG_ERROR([could not locate libtool -lltdl])
 603         fi
 604         ol_link_modules=yes
 605 else
 606         ol_with_bdb2_module=static
 607         ol_with_ldap_module=static
 608         ol_with_ldbm_module=static
 609         ol_with_passwd_module=static
 610         ol_with_perl_module=static
 611         ol_with_shell_module=static
 612         ol_with_tcl_module=static
 613 fi
 614
 615 dnl ----------------------------------------------------------------
 616 dnl Checks for header files.
 617 OL_HEADER_STDC
 618
 619 if test $ol_cv_header_stdc != yes; then
 620         AC_MSG_WARN([could not locate Standard C compliant headers])
 621 fi
 622
 623 AC_HEADER_DIRENT
 624 AC_HEADER_SYS_WAIT
 625 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 626 if test $am_cv_sys_posix_termios = yes ; then
 627         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 628                 [define if you have POSIX termios])
 629 fi
 630
 631 AC_CHECK_HEADERS(       \
 632         arpa/inet.h             \
 633         arpa/nameser.h  \
 634         assert.h                \
 635         conio.h                 \
 636         crypt.h                 \
 637         direct.h                \
 638         errno.h                 \
 639         fcntl.h                 \
 640         filio.h                 \
 641         getopt.h                \
 642         grp.h                   \
 643         io.h                    \
 644         libutil.h               \
 645         limits.h                \
 646         locale.h                \
 647         netinet/tcp.h   \
 648         malloc.h                \
 649         memory.h                \
 650         psap.h                  \
 651         pwd.h                   \
 652         process.h               \
 653         resolv.h                \
 654         sgtty.h                 \
 655         shadow.h                \
 656         stddef.h                \
 657         string.h                \
 658         strings.h               \
 659         sysexits.h              \
 660         sys/file.h              \
 661         sys/filio.h             \
 662         sys/errno.h             \
 663         sys/ioctl.h             \
 664         sys/param.h             \
 665         sys/resource.h  \
 666         sys/select.h    \
 667         sys/socket.h    \
 668         sys/syslog.h    \
 669         sys/time.h              \
 670         sys/types.h             \
 671         syslog.h                \
 672         termios.h               \
 673         unistd.h                \
 674         winsock.h               \
 675 )
 676
 677
 678 dnl ----------------------------------------------------------------
 679 dnl Checks for libraries
 680
 681 dnl HP-UX requires -lV3
 682 AC_CHECK_LIB(V3, sigset)
 683
 684 dnl Gotta check for winsock manually
 685 if test $ac_cv_header_winsock_h = yes; then
 686         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 687         AC_TRY_LINK([#include <winsock.h>],[
 688                         socket(0,0,0);
 689                         select(0,NULL,NULL,NULL,NULL);
 690                         closesocket(0);
 691                         gethostname(NULL,0);
 692         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 693
 694         if test $ol_cv_winsock = yes ; then
 695                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 696                 ac_cv_func_socket=yes
 697                 ac_cv_func_select=yes
 698                 ac_cv_func_closesocket=yes
 699                 ac_cv_func_gethostname=yes
 700         fi
 701 fi
 702
 703 dnl Find socket()
 704 dnl Likely combinations:
 705 dnl             -lsocket [ -lnsl_s | -lnsl ]
 706 dnl             -linet
 707
 708 AC_CHECK_FUNC(socket, :, [
 709 dnl hopefully we won't include too many libraries
 710         AC_CHECK_LIB(socket, main)
 711         AC_CHECK_LIB(net, main)
 712         AC_CHECK_LIB(nsl_s, main)
 713         AC_CHECK_LIB(nsl, main)
 714         AC_CHECK_LIB(inet, socket)
 715         AC_CHECK_LIB(gen, main)
 716 ])
 717
 718 dnl require select
 719 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 720
 721 if test "${ac_cv_header_winsock_h}" != yes; then
 722     dnl Select arg types
 723     dnl (if this detection becomes permenent, it and the select() detection
 724     dnl should be done before the yielding select test)
 725     AC_FUNC_SELECT_ARGTYPES
 726 fi
 727
 728 dnl check to see if system call automatically restart
 729 dnl AC_SYS_RESTARTABLE_SYSCALLS
 730
 731 dnl ----------------------------------------------------------------
 732 dnl require POSIX regex
 733 AC_CHECK_HEADERS( regex.h )
 734 if test "$ac_cv_header_regex_h" != yes ; then
 735         AC_MSG_ERROR([POSIX regex.h required.])
 736 fi
 737 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 738
 739 OL_POSIX_REGEX
 740 if test "$ol_cv_c_posix_regex" = no ; then
 741         AC_MSG_ERROR([broken POSIX regex!])
 742 fi
 743
 744 dnl ----------------------------------------------------------------
 745 dnl Check for resolver routines
 746 AC_CHECK_FUNC(res_search,:)
 747 if test $ac_cv_func_res_search = no ; then
 748         AC_CHECK_LIB(bind, res_search)
 749         ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 750 fi
 751
 752 if test $ac_cv_func_res_search = no ; then
 753         AC_CHECK_LIB(bind, __res_search)
 754         ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 755 fi
 756
 757 if test $ac_cv_func_res_search = no ; then
 758         AC_CHECK_LIB(resolv, res_search)
 759         ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 760 fi
 761
 762 if test "$ac_cv_func_res_search" = yes ; then
 763         AC_DEFINE(HAVE_RES_SEARCH,1,
 764                 [define if you have res_search()])
 765 elif test $ol_enable_dns = yes ; then
 766         AC_MSG_ERROR([--enable-dns requires res_search])
 767 elif test $ol_enable_dns != no ; then
 768         AC_MSG_WARN([no res_search, disabling DNS support])
 769 fi
 770
 771
 772 dnl ----------------------------------------------------------------
 773 dnl ISODE tests
 774 ol_link_isode=no
 775 if test $ol_enable_ldapd != no ; then
 776         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 777
 778         dnl look for ISODE libraries
 779         AC_CHECK_LIB(xtpp, main, [
 780                 ol_link_isode=yes
 781                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 782                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 783                 ],:,[-lxtdsap -lxtisode -losi])
 784         AC_CHECK_LIB(dsap, main, [
 785                 ol_link_isode=yes
 786                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 787                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 788                 ],:,[-lisode])
 789         AC_CHECK_LIB(isode, main, [
 790                 ol_link_isode=yes
 791                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 792                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 793                 ],:)
 794 fi
 795
 796 if test $ol_link_isode != no; then
 797         AC_CHECK_LIB(pp, main, [
 798                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 799                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 800                 ],:)
 801
 802         AC_PATH_PROG(PEPSY, pepsy)
 803 fi
 804
 805 dnl ----------------------------------------------------------------
 806 dnl QUIPU
 807 if test $ol_enable_quipu != no ; then
 808         AC_CHECK_HEADERS(quipu/commonarg.h)
 809
 810         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 811                 BUILD_QUIPU=yes
 812         elif test $ol_enable_quipu = auto ; then
 813                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 814         else
 815                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 816         fi
 817 fi
 818
 819 dnl ----------------------------------------------------------------
 820 dnl Kerberos
 821 ol_link_kerberos=no
 822
 823 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 824         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 825
 826         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 827                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 828                         [-lkrb5 -ldes425 -lcrypto -lcom_err])
 829
 830                 if test $have_k5 = yes ; then
 831                         ol_with_kerberos=found
 832                         ol_link_kerberos=yes
 833
 834                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425 -lcrypto -lcom_err"
 835
 836                         LIBS="$KRB_LIBS $LIBS"
 837
 838                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 839                                 [ol_cv_var_des_debug], [
 840                                 dnl save the flags
 841                                 save_LIBS="$LIBS"
 842                                 LIBS="$KRB_LIBS $LIBS"
 843                                 AC_TRY_LINK([
 844 #include <kerberosIV/krb.h>
 845 #include <kerberosIV/des.h>
 846 extern int des_debug;
 847 ],[
 848 des_debug = 1;
 849 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 850                                 dnl restore the LIBS
 851                                 LIBS="$save_LIBS"
 852                         ])
 853
 854                         if test $ol_cv_var_des_debug = yes ; then
 855                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 856                                         [define if you have Kerberos des_debug])
 857                         fi
 858
 859                         LIBS="$save_LIBS"
 860                 fi
 861         fi
 862 fi
 863
 864 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 \
 865         -o $ol_with_kerberos = kth ; then
 866
 867         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 868
 869         if test $ac_cv_header_krb_h = yes ; then
 870                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 871
 872                 if test $have_k4 = yes ; then
 873                         ol_with_kerberos=found
 874                         ol_link_kerberos=yes
 875
 876                         KRB_LIBS="-lkrb -ldes"
 877
 878                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 879                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 880                                         [define if you have Kth Kerberos])
 881                         fi
 882                 fi
 883         fi
 884 fi
 885
 886 if test $ol_link_kerberos = yes ; then
 887         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 888
 889 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 890         AC_ERROR([Kerberos detection failed.])
 891 fi
 892
 893 dnl ----------------------------------------------------------------
 894 dnl TLS/SSL
 895 ol_link_tls=no
 896 if test $ol_with_tls != no ; then
 897
 898         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 899
 900         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 901                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 902                         [have_ssleay=yes
 903                         need_rsaref=no],
 904                         [have_ssleay=no],
 905                         [-lcrypto])
 906
 907                 if test $have_ssleay = no ; then
 908                         AC_CHECK_LIB(ssl, SSL_library_init,
 909                                 [have_ssleay=yes
 910                                 need_rsaref=no], [have_ssleay=no],
 911                                 [-lcrypto])
 912                 fi
 913
 914                 if test $have_ssleay = no ; then
 915                         AC_CHECK_LIB(ssl, ssl3_accept,
 916                                 [have_ssleay=yes
 917                                 need_rsaref=yes], [have_ssleay=no],
 918                                 [-lcrypto -lRSAglue -lrsaref])
 919                 fi
 920
 921                 if test $have_ssleay = yes ; then
 922                         ol_with_tls=found
 923                         ol_link_tls=yes
 924
 925                         AC_DEFINE(HAVE_SSLEAY, 1,
 926                                 [define if you have SSLeay or OpenSSL])
 927
 928                         if test $need_rsaref = yes; then
 929                                 AC_DEFINE(HAVE_RSAREF, 1,
 930                                         [define if you have RSAref])
 931
 932                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 933                         else
 934                                 TLS_LIBS="-lssl -lcrypto"
 935                         fi
 936                 fi
 937         fi
 938 fi
 939
 940 if test $ol_link_tls = yes ; then
 941         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 942 fi
 943
 944 dnl ----------------------------------------------------------------
 945 dnl Tests for reentrant functions necessary to build a
 946 dnl thread_safe -lldap.
 947 AC_CHECK_FUNCS(         \
 948         ctime_r                 \
 949         gethostbyname_r gethostbyaddr_r \
 950 )
 951
 952 if test "$ac_cv_func_ctime_r" = no ; then
 953         ol_cv_func_ctime_r_nargs=0
 954 else
 955         OL_FUNC_CTIME_R_NARGS
 956 dnl     OL_FUNC_CTIME_R_TYPE
 957 fi
 958
 959 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 960         OL_FUNC_GETHOSTBYNAME_R_NARGS
 961 else
 962         ol_cv_func_gethostbyname_r_nargs=0
 963 fi
 964
 965 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 966         OL_FUNC_GETHOSTBYADDR_R_NARGS
 967 else
 968         ol_cv_func_gethostbyaddr_r_nargs=0
 969 fi
 970
 971 if test "$ac_cv_func_ctime_r" = yes \
 972         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 973         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 974         -a "$ac_cv_func_gethostbyname_r" = yes \
 975         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 976         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 977         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 978         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 979         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 980         ; then
 981
 982         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 983 fi
 984
 985 dnl ----------------------------------------------------------------
 986 dnl Threads?
 987 ol_link_threads=no
 988
 989 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 990         -o $ol_with_threads = nt ; then
 991
 992         OL_NT_THREADS
 993
 994         if test "$ol_cv_nt_threads" = yes ; then
 995         ol_link_threads=nt
 996         ol_with_threads=found
 997         ol_with_yielding_select=yes
 998
 999                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1000                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1001         fi
1002
1003         if test $ol_with_threads = nt ; then
1004                 AC_MSG_ERROR([could not locate NT Threads])
1005         fi
1006 fi
1007
1008 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1009         -o $ol_with_threads = posix ; then
1010
1011         AC_CHECK_HEADERS(pthread.h)
1012
1013         if test $ac_cv_header_pthread_h = yes ; then
1014                 OL_POSIX_THREAD_VERSION
1015
1016                 if test $ol_cv_pthread_version = final ; then
1017                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1018                                 [define if pthreads API compatible with final spec])
1019                 elif test $ol_cv_pthread_version = draft4 ; then
1020                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1021                                 [define if pthreads API compatible with draft4 spec])
1022                 else
1023                         AC_MSG_ERROR([unknown pthread version])
1024                 fi
1025
1026                 # consider threads found
1027                 ol_with_threads=found
1028
1029                 OL_HEADER_LINUX_THREADS
1030                 OL_HEADER_GNU_PTH_PTHREAD_H
1031
1032                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1033                         AC_CHECK_HEADERS(sched.h)
1034                 fi
1035
1036                 dnl Now the hard part, how to link?
1037                 dnl
1038                 dnl currently supported checks:
1039                 dnl
1040                 dnl Check for no flags
1041                 dnl     pthread_create() in $LIBS
1042                 dnl
1043                 dnl Check special pthread (final) flags
1044                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1045                 dnl     pthread_create() with -kthread (FreeBSD)
1046                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1047                 dnl     pthread_create() with -pthreads (?)
1048                 dnl     pthread_create() with -mthreads (AIX)
1049                 dnl     pthread_create() with -thread (?)
1050                 dnl
1051                 dnl Check pthread (final) libraries
1052                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1053                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1054                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1055                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1056                 dnl     pthread_create() in -lpthread (many)
1057                 dnl     pthread_create() in -lc_r (FreeBSD)
1058                 dnl
1059                 dnl Check pthread (draft4) flags (depreciated)
1060                 dnl     pthread_create() with -threads (OSF/1)
1061                 dnl
1062                 dnl Check pthread (draft4) libraries (depreciated)
1063                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1064                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1065                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1066                 dnl     pthread_create() in -lpthreads (many)
1067                 dnl
1068
1069                 dnl pthread_create in $LIBS
1070                 AC_CACHE_CHECK([for pthread_create in default libraries],
1071                         ol_cv_pthread_create,[
1072                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1073                         [ol_cv_pthread_create=yes],
1074                         [ol_cv_pthread_create=no],
1075                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1076                                 [ol_cv_pthread_create=yes],
1077                                 [ol_cv_pthread_create=no])])])
1078
1079                 if test $ol_cv_pthread_create != no ; then
1080                         ol_link_threads=posix
1081                         ol_link_pthreads=""
1082                 fi
1083
1084 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1085                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1086                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1087                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1088                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1089                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1090
1091                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1092                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1093                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1094                         [ol_cv_pthread_lpthread_lmach_lexc])
1095 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1096 dnl                     [ol_cv_pthread_lpthread_lexc])
1097
1098                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1099                         [ol_cv_pthread_lib_lpthread_woff])
1100
1101                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1102                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1103
1104                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1105
1106                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1107                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1108                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1109                         [ol_cv_pthread_lpthreads_lmach_lexc])
1110                 OL_PTHREAD_TRY([-lpthreads -lexc],
1111                         [ol_cv_pthread_lpthreads_lexc])
1112
1113                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1114
1115                 if test $ol_link_threads != no ; then
1116                         AC_DEFINE(HAVE_PTHREADS,1,
1117                                 [define if you have POSIX Threads])
1118
1119                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1120
1121                         dnl save flags
1122                         save_CPPFLAGS="$CPPFLAGS"
1123                         save_LIBS="$LIBS"
1124                         LIBS="$LTHREAD_LIBS $LIBS"
1125
1126                         dnl All POSIX Thread (final) implementations should have
1127                         dnl sched_yield instead of pthread yield.
1128                         dnl check for both
1129                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1130
1131                         if test $ac_cv_func_sched_yield = no -a \
1132                                 $ac_cv_func_pthread_yield = no ; then
1133                                 dnl Digital UNIX has sched_yield() in -lrt
1134                                 AC_CHECK_LIB(rt, sched_yield,
1135                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1136                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1137                                                 [Define if you have the sched_yield function.])
1138                                         ac_cv_func_sched_yield=yes],
1139                                         [ac_cv_func_sched_yield=no])
1140                         fi
1141                         if test $ac_cv_func_sched_yield = no -a \
1142                                 $ac_cv_func_pthread_yield = no ; then
1143                                 dnl Solaris has sched_yield() stub in -lposix4
1144                                 dnl but we'll use thr_yield instead.
1145                                 AC_CHECK_FUNCS(thr_yield)
1146                         fi
1147                         if test $ac_cv_func_sched_yield = no -a \
1148                                 $ac_cv_func_pthread_yield = no -a \
1149                                 "$ac_cv_func_thr_yield" = no ; then
1150                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1151                         fi
1152
1153                         dnl Check functions for compatibility
1154                         AC_CHECK_FUNCS(pthread_kill)
1155
1156                         dnl Check for pthread_detach with <pthread.h> inclusion
1157                         dnl as it's symbol may have been mangled.
1158                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1159                                 [ol_cv_func_pthread_detach], [
1160                                 dnl save the flags
1161                                 AC_TRY_LINK([
1162 #include <pthread.h>
1163 #ifndef NULL
1164 #define NULL (void*)0
1165 #endif
1166 ],
1167                                         [pthread_detach(NULL);],
1168                                         [ol_cv_func_pthread_detach=yes],
1169                                         [ol_cv_func_pthread_detach=no])
1170                         ])
1171
1172                         if test $ol_cv_func_pthread_detach = no ; then
1173                                 AC_MSG_ERROR([could not locate pthread_detach()])
1174                         fi
1175
1176                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1177                                 [define if you have pthread_detach function])
1178
1179                         dnl Check for setconcurreny functions
1180                         AC_CHECK_FUNCS( \
1181                                 pthread_setconcurrency \
1182                                 pthread_getconcurrency \
1183                                 thr_setconcurrency \
1184                                 thr_getconcurrency \
1185                         )
1186
1187                         OL_SYS_LINUX_THREADS
1188                         OL_LINUX_THREADS
1189
1190                         if test $ol_cv_linux_threads = error; then
1191                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1192                         fi
1193
1194                         AC_CACHE_CHECK([if pthread_create() works],
1195                                 ol_cv_pthread_create_works,[
1196                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1197                                 [ol_cv_pthread_create_works=yes],
1198                                 [ol_cv_pthread_create_works=no],
1199                                 [dnl assume yes
1200                                 ol_cv_pthread_create_works=yes])])
1201
1202                         if test $ol_cv_pthread_create_works = no ; then
1203                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1204                         fi
1205
1206                         dnl Check if select causes an yield
1207                         if test $ol_with_yielding_select = auto ; then
1208                                 AC_CACHE_CHECK([if select yields when using pthreads],
1209                                         ol_cv_pthread_select_yields,[
1210                                 AC_TRY_RUN([
1211 #include <sys/types.h>
1212 #include <sys/time.h>
1213 #include <unistd.h>
1214 #include <pthread.h>
1215 #ifndef NULL
1216 #define NULL (void*) 0
1217 #endif
1218
1219 static int fildes[2];
1220
1221 static void *task(p)
1222         void *p;
1223 {
1224         int i;
1225         struct timeval tv;
1226
1227         fd_set rfds;
1228
1229         tv.tv_sec=10;
1230         tv.tv_usec=0;
1231
1232         FD_ZERO(&rfds);
1233         FD_SET(fildes[0], &rfds);
1234
1235         /* we're not interested in any fds */
1236         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1237
1238         if(i < 0) {
1239                 perror("select");
1240                 exit(10);
1241         }
1242
1243         exit(0); /* if we exit here, the select blocked the whole process */
1244 }
1245
1246 int main(argc, argv)
1247         int argc;
1248         char **argv;
1249 {
1250         pthread_t t;
1251
1252         /* create a pipe to select */
1253         if(pipe(&fildes[0])) {
1254                 perror("select");
1255                 exit(1);
1256         }
1257
1258 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1259         (void) pthread_setconcurrency(2);
1260 #else
1261 #ifdef HAVE_THR_SETCONCURRENCY
1262         /* Set Solaris LWP concurrency to 2 */
1263         thr_setconcurrency(2);
1264 #endif
1265 #endif
1266
1267 #if HAVE_PTHREADS_D4
1268         pthread_create(&t, pthread_attr_default, task, NULL);
1269 #else
1270         pthread_create(&t, NULL, task, NULL);
1271 #endif
1272
1273 #if HAVE_SCHED_YIELD
1274         sched_yield();  /* make sure task runs first */
1275 #else
1276 #ifdef HAVE_PTHREAD_YIELD
1277         pthread_yield();        /* make sure task runs first */
1278 #endif
1279 #endif
1280
1281         exit(2);
1282 }],
1283                                 [ol_cv_pthread_select_yields=no],
1284                                 [ol_cv_pthread_select_yields=yes],
1285                                 [ol_cv_pthread_select_yields=cross])])
1286
1287                                 if test $ol_cv_pthread_select_yields = cross ; then
1288                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1289                                 fi
1290
1291                                 if test $ol_cv_pthread_select_yields = yes ; then
1292                                         ol_with_yielding_select=yes
1293                                 fi
1294                         fi
1295
1296                         dnl restore flags
1297                         CPPFLAGS="$save_CPPFLAGS"
1298                         LIBS="$save_LIBS"
1299                 else
1300                         AC_MSG_ERROR([could not link with POSIX Threads])
1301                 fi
1302         fi
1303
1304         if test $ol_with_threads = posix ; then
1305                 AC_MSG_ERROR([could not locate POSIX Threads])
1306         fi
1307 fi
1308
1309 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1310         -o $ol_with_threads = mach ; then
1311
1312         dnl check for Mach CThreads
1313         AC_CHECK_HEADERS(mach/cthreads.h)
1314         if test $ac_cv_header_mach_cthreads_h = yes ; then
1315                 ol_with_threads=found
1316
1317                 dnl check for cthread support in current $LIBS
1318                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1319
1320                 if test $ol_link_threads = no ; then
1321                         dnl try -all_load
1322                         dnl this test needs work
1323                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1324                                 [ol_cv_cthread_all_load], [
1325                                 dnl save the flags
1326                                 save_LIBS="$LIBS"
1327                                 LIBS="-all_load $LIBS"
1328                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1329                                         cthread_fork((void *)0, (void *)0);
1330                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1331                                 dnl restore the LIBS
1332                                 LIBS="$save_LIBS"
1333                         ])
1334
1335                         if test $ol_cv_cthread_all_load = yes ; then
1336                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1337                                 ol_link_threads=mach
1338                         fi
1339                 fi
1340
1341                 if test $ol_link_threads != no ; then
1342                         : check for cthread specific functionality here
1343                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1344                                 [define if you have Mach Cthreads])
1345                 else
1346                         AC_MSG_ERROR([could not link with Mach CThreads])
1347                 fi
1348         fi
1349
1350         if test $ol_with_threads = mach ; then
1351                 AC_MSG_ERROR([could not locate Mach CThreads])
1352         fi
1353 fi
1354
1355 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1356         -o $ol_with_threads = pth ; then
1357
1358         AC_CHECK_HEADERS(pth.h)
1359
1360         if test $ac_cv_header_pth_h = yes ; then
1361                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1362
1363                 if test $have_pth = yes ; then
1364                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1365                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1366                         ol_link_threads=pth
1367
1368                         if test $ol_with_yielding_select = auto ; then
1369                                 ol_with_yielding_select=yes
1370                         fi
1371                 fi
1372         fi
1373 fi
1374
1375 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1376         -o $ol_with_threads = lwp ; then
1377
1378         dnl check for SunOS5 LWP
1379         AC_CHECK_HEADERS(thread.h synch.h)
1380         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1381                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1382
1383                 if test $have_thr = yes ; then
1384                         AC_DEFINE(HAVE_THR,1,
1385                                 [if you have Solaris LWP (thr) package])
1386                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1387                         ol_link_threads=thr
1388
1389                         if test $ol_with_yielding_select = auto ; then
1390                                 ol_with_yielding_select=yes
1391                         fi
1392
1393                         dnl Check for setconcurreny functions
1394                         AC_CHECK_FUNCS( \
1395                                 thr_setconcurrency \
1396                                 thr_getconcurrency \
1397                         )
1398                 fi
1399         fi
1400
1401         dnl check for SunOS4 LWP
1402         AC_CHECK_HEADERS(lwp/lwp.h)
1403         if test $ac_cv_header_lwp_lwp_h = yes ; then
1404                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1405
1406                 if test $have_lwp = yes ; then
1407                         AC_DEFINE(HAVE_LWP,1,
1408                                 [if you have SunOS LWP package])
1409                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1410                         ol_link_threads=lwp
1411
1412                         if test $ol_with_yielding_select = auto ; then
1413                                 ol_with_yielding_select=no
1414                         fi
1415                 fi
1416         fi
1417 fi
1418
1419 if test $ol_with_yielding_select = yes ; then
1420         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1421                 [define if select implicitly yields])
1422 fi
1423
1424 if test $ol_with_threads = manual ; then
1425         dnl User thinks he can manually configure threads.
1426         ol_link_threads=yes
1427
1428         AC_MSG_WARN([thread defines and link options must be set manually])
1429
1430         AC_CHECK_HEADERS(pthread.h sched.h)
1431         AC_CHECK_FUNCS(sched_yield pthread_yield)
1432         OL_HEADER_LINUX_THREADS
1433
1434         AC_CHECK_HEADERS(mach/cthreads.h)
1435         AC_CHECK_HEADERS(lwp/lwp.h)
1436         AC_CHECK_HEADERS(thread.h synch.h)
1437 fi
1438
1439 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1440         dnl needed to get reentrant/threadsafe versions
1441         dnl
1442         AC_DEFINE(REENTRANT,1)
1443         AC_DEFINE(_REENTRANT,1)
1444         AC_DEFINE(THREAD_SAFE,1)
1445         AC_DEFINE(_THREAD_SAFE,1)
1446         AC_DEFINE(THREADSAFE,1)
1447         AC_DEFINE(_THREADSAFE,1)
1448         AC_DEFINE(_SGI_MP_SOURCE,1)
1449
1450         dnl The errno declaration may dependent upon _REENTRANT.
1451         dnl If it does, we must link with thread support.
1452         AC_CACHE_CHECK([for thread specific errno],
1453                 [ol_cv_errno_thread_specific], [
1454                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1455                         [ol_cv_errno_thread_specific=yes],
1456                         [ol_cv_errno_thread_specific=no])
1457         ])
1458
1459         dnl The h_errno declaration may dependent upon _REENTRANT.
1460         dnl If it does, we must link with thread support.
1461         AC_CACHE_CHECK([for thread specific h_errno],
1462                 [ol_cv_h_errno_thread_specific], [
1463                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1464                         [ol_cv_h_errno_thread_specific=yes],
1465                         [ol_cv_h_errno_thread_specific=no])
1466         ])
1467
1468         if test $ol_cv_errno_thread_specific != yes \
1469                 -o $ol_cv_h_errno_thread_specific != yes ; then
1470                 LIBS="$LTHREAD_LIBS $LIBS"
1471                 LTHREAD_LIBS=""
1472         fi
1473
1474 dnl When in thread environment, use
1475 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1476 dnl                     || defined( HAVE_FUNC_R )
1477 dnl                     func_r(...);
1478 dnl             #else
1479 dnl             #       if defined( HAVE_THREADS )
1480 dnl                             /* lock */
1481 dnl             #       endif
1482 dnl                             func(...);
1483 dnl             #       if defined( HAVE_THREADS )
1484 dnl                             /* unlock */
1485 dnl             #       endif
1486 dnl             #endif
1487 dnl
1488 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1489 dnl             _POSIX_REENTRANT_FUNCTIONS
1490 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1491 dnl             _POSIX_THREADSAFE_FUNCTIONS
1492 dnl
1493 dnl             and is currently defined in lthread.h
1494 dnl
1495 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1496 dnl
1497 dnl libldap/*.c should only include <lthread.h> iff
1498 dnl LDAP_R_COMPILE is defined.  ie:
1499 dnl             #ifdef LDAP_R_COMPILE
1500 dnl             #       include LDAP_R_COMPILE
1501 dnl             #endif
1502 dnl
1503 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1504 dnl specifically for compiling the threadsafe version of
1505 dnl     the ldap library (-lldap_r).
1506 dnl
1507 dnl     dnl check for reentrant/threadsafe functions
1508 dnl     dnl
1509 dnl     dnl note: these should only be used when linking
1510 dnl     dnl       with $LTHREAD_LIBS
1511 dnl     dnl
1512 dnl     save_CPPFLAGS="$CPPFLAGS"
1513 dnl     save_LIBS="$LIBS"
1514 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1515 dnl     AC_CHECK_FUNCS( \
1516 dnl             gmtime_r \
1517 dnl             gethostbyaddr_r gethostbyname_r \
1518 dnl             feof_unlocked unlocked_feof \
1519 dnl             putc_unlocked unlocked_putc \
1520 dnl             flockfile ftrylockfile \
1521 dnl     )
1522 dnl     CPPFLAGS="$save_CPPFLAGS"
1523 dnl     LIBS="$save_LIBS"
1524 fi
1525
1526 if test $ol_link_threads = no ; then
1527         if test $ol_with_threads = yes ; then
1528                 AC_MSG_ERROR([no suitable thread support])
1529         fi
1530
1531         if test $ol_with_threads = auto ; then
1532                 AC_MSG_WARN([no suitable thread support, disabling threads])
1533                 ol_with_threads=no
1534         fi
1535
1536         AC_DEFINE(NO_THREADS,1,
1537                 [define if you have (or want) no threads])
1538         LTHREAD_LIBS=""
1539 fi
1540
1541 if test $ol_link_threads != no ; then
1542         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1543 fi
1544
1545 dnl ----------------------------------------------------------------
1546
1547 ol_link_ldbm=no
1548 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1549         OL_BERKELEY_DB2
1550
1551         if test $ol_cv_berkeley_db2 = yes ; then
1552                 ol_link_ldbm=db2
1553                 ol_with_ldbm_api=db2
1554
1555                 if test $ol_with_ldbm_type = hash ; then
1556                         AC_DEFINE(LDBM_USE_DBHASH,1,
1557                                 [define this to use DBHASH w/ LDBM backend])
1558                 else
1559                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1560                                 [define this to use DBBTREE w/ LDBM backend])
1561                 fi
1562
1563                 OL_BERKELEY_DB2_DB_THREAD
1564
1565                 dnl $ol_cv_lib_db2 should be yes or -ldb
1566                 dnl (it could be no, but that would be an error
1567                 if test $ol_cv_lib_db2 != yes ; then
1568                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1569                 fi
1570         fi
1571 fi
1572
1573 ol_link_bdb2=no
1574 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1575         if test $ol_cv_berkeley_db2_db_thread != no ; then
1576                 ol_link_bdb2=yes
1577         else
1578                 AC_MSG_WARN([Installed BerkeleyDB does not provide DB_THREAD support.])
1579         fi
1580 fi
1581
1582 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1583         OL_BERKELEY_DB
1584
1585         if test $ol_cv_berkeley_db = yes ; then
1586                 ol_link_ldbm=db
1587                 ol_with_ldbm_api=db
1588
1589                 if test $ol_with_ldbm_type = hash ; then
1590                         AC_DEFINE(LDBM_USE_DBHASH,1,
1591                                 [define this to use DBHASH w/ LDBM backend])
1592                 else
1593                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1594                                 [define this to use DBBTREE w/ LDBM backend])
1595                 fi
1596
1597                 dnl $ol_cv_lib_db should be yes or -ldb
1598                 dnl (it could be no, but that would be an error
1599                 if test $ol_cv_lib_db != yes ; then
1600                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1601                 fi
1602         fi
1603 fi
1604
1605 if test $ol_with_ldbm_api = manual ; then
1606         dnl User thinks he can manually configure LDBM api.
1607         ol_link_ldbm=yes
1608
1609         AC_MSG_WARN([LDBM defines and link options must be set manually])
1610
1611         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1612 fi
1613
1614 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1615         AC_MSG_WARN(Could not find LDBM with BTREE support)
1616         ol_with_ldbm_api=none
1617 fi
1618
1619 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1620         OL_MDBM
1621
1622         if test $ol_cv_mdbm = yes ; then
1623                 ol_link_ldbm=mdbm
1624                 ol_with_ldbm_api=mdbm
1625                 if test $ol_cv_lib_mdbm != yes ; then
1626                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1627                 fi
1628         fi
1629 fi
1630
1631 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1632         OL_GDBM
1633
1634         if test $ol_cv_gdbm = yes ; then
1635                 ol_link_ldbm=gdbm
1636                 ol_with_ldbm_api=gdbm
1637
1638                 if test $ol_cv_lib_gdbm != yes ; then
1639                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1640                 fi
1641         fi
1642 fi
1643
1644 if test $ol_with_ldbm_api = auto ; then
1645         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1646 elif test $ol_with_ldbm_api = ndbm ; then
1647         OL_NDBM
1648
1649         if test $ol_cv_ndbm = yes ; then
1650                 ol_link_ldbm=ndbm
1651                 ol_with_ldbm_api=ndbm
1652
1653                 if test $ol_cv_lib_ndbm != yes ; then
1654                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1655                 fi
1656         fi
1657 fi
1658
1659 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1660         AC_MSG_WARN(could not find suitable LDBM backend)
1661         if test $ol_enable_ldbm = yes ; then
1662                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1663         fi
1664
1665         AC_MSG_WARN(disabling LDBM)
1666         ol_enable_ldbm=no
1667 fi
1668
1669 dnl ----------------------------------------------------------------
1670 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1671         LINK_BINS_DYNAMIC="yes"
1672 else
1673         LINK_BINS_DYNAMIC="no"
1674 fi
1675
1676 dnl ----------------------------------------------------------------
1677 if test $ol_enable_wrappers != no ; then
1678         AC_CHECK_HEADERS(tcpd.h)
1679
1680         if test $ac_cv_header_tcpd_h != yes ; then
1681                 have_wrappers=no
1682         else
1683                 AC_TRY_COMPILE([
1684 int allow_severity = 0;
1685 int deny_severity  = 0;
1686                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1687         fi
1688
1689         if test $have_wrappers = yes ; then
1690                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1691                 WRAP_LIBS="-lwrap"
1692
1693                 dnl We add another check for -lnsl since some libwrap's
1694                 dnl need it, but it isn't always included from above
1695                 AC_CHECK_LIB(nsl, main)
1696         else
1697                 AC_MSG_WARN(could not find -lwrap)
1698                 if test $ol_enable_wrappers = yes ; then
1699                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1700                 fi
1701
1702                 AC_MSG_WARN(disabling wrappers support)
1703                 ol_enable_wrappers=no
1704                 WRAP_LIBS=""
1705         fi
1706 fi
1707
1708 dnl ----------------------------------------------------------------
1709 if test $ol_enable_syslog != no ; then
1710         AC_CHECK_FUNC(openlog)
1711         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1712                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1713         fi
1714         ol_enable_syslog=$ac_cv_func_openlog
1715 fi
1716
1717 dnl ----------------------------------------------------------------
1718 if test $ol_enable_dmalloc != no ; then
1719         AC_CHECK_HEADERS(dmalloc.h)
1720         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1721 fi
1722
1723 dnl ----------------------------------------------------------------
1724 dnl TCL
1725 if test $ol_enable_tcl != no ; then
1726         AC_CHECK_HEADERS(tcl.h)
1727
1728         if test $ac_cv_header_tcl_h != yes ; then
1729                 have_tcl=no
1730         else
1731                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1732                         AC_CHECK_LIB($lib,main,
1733                           [have_tcl=yes
1734                            if test x"$ol_with_tcl_module" = "xstatic" ; then
1735                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1736                            else
1737                                MOD_TCL_LIB="-l${lib}"
1738                            fi;break],[have_tcl=no])
1739                 done
1740         fi
1741
1742         if test $have_tcl != yes ; then
1743                 AC_MSG_WARN([could not find -ltcl])
1744                 if test $ol_enable_tcl = yes ; then
1745                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1746                 fi
1747
1748                 ol_enable_tcl=no
1749         fi
1750 fi
1751
1752 dnl ----------------------------------------------------------------
1753 dnl ud needs termcap (should insert check here)
1754 ol_link_termcap=no
1755 AC_CHECK_HEADERS(termcap.h ncurses.h)
1756
1757 if test $ol_link_termcap = no ; then
1758         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1759         if test $have_termcap = yes ; then
1760                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1761                 ol_link_termcap=yes
1762                 TERMCAP_LIBS=-ltermcap
1763         fi
1764 fi
1765
1766 if test $ol_link_termcap = no ; then
1767         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1768         if test $have_ncurses = yes ; then
1769                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1770                 ol_link_termcap=yes
1771                 TERMCAP_LIBS=-lncurses
1772         fi
1773 fi
1774
1775 if test $ol_link_termcap = no ; then
1776         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1777         TERMCAP_LIBS=
1778 fi
1779
1780 dnl ----------------------------------------------------------------
1781 dnl
1782 dnl Check for Cyrus SASL
1783 dnl
1784 ol_link_sasl=no
1785 if test $ol_with_cyrus_sasl != no ; then
1786         AC_CHECK_HEADER(sasl.h)
1787
1788         if test $ac_cv_header_sasl_h = yes ; then
1789                 AC_CHECK_LIB(sasl, sasl_client_init,
1790                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1791
1792                 if test $have_cyrus_sasl != no ; then
1793                         SASL_LIBS="-lsasl"
1794                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1795                         ol_link_sasl=yes
1796                 fi
1797         fi
1798
1799         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1800                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1801         fi
1802 fi
1803
1804 dnl ----------------------------------------------------------------
1805 dnl Check for entropy sources
1806 if test $cross_compiling != yes ; then
1807         dev=no
1808         if test -r /dev/urandom ; then
1809                 dev="/dev/urandom";
1810         elif test -r /idev/urandom ; then
1811                 dev="/idev/urandom";
1812         elif test -r /dev/srandom ; then
1813                 dev="/dev/srandom";
1814         elif test -r /dev/random ; then
1815                 dev="/dev/random";
1816         elif test -r /idev/random ; then
1817                 dev="/idev/random";
1818         fi
1819
1820         if test $dev != no ; then
1821                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1822         fi
1823 fi
1824
1825 dnl ----------------------------------------------------------------
1826 dnl
1827 dnl Check for fetch URL support
1828 dnl             should be extended to support other fetch URL APIs
1829 dnl
1830 ol_link_fetch=no
1831 if test $ol_with_fetch != no ; then
1832         OL_LIB_FETCH
1833
1834         if test $ol_cv_lib_fetch != no ; then
1835                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1836                 ol_link_fetch=freebsd
1837
1838         elif test $ol_with_fetch != auto ; then
1839                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1840         fi
1841 fi
1842
1843 dnl ----------------------------------------------------------------
1844 dnl
1845 dnl Check for GNU readline
1846 dnl
1847 ol_link_readline=no
1848 if test $ol_with_readline != no ; then
1849         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1850
1851         if test $ac_cv_header_readline_readline_h = yes ; then
1852                 save_LIBS="$LIBS"
1853                 LIBS="$TERMCAP_LIBS $LIBS"
1854                 AC_CHECK_LIB(readline, readline,
1855                         [have_readline=yes], [have_readline=no])
1856                 LIBS="$save_LIBS"
1857
1858                 if test $have_readline = yes ; then
1859                         ol_with_readline=found
1860                         ol_link_readline=yes
1861
1862                         READLINE_LIBS="-lreadline"
1863                 fi
1864         fi
1865 fi
1866
1867 if test $ol_link_readline = yes ; then
1868         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1869 fi
1870
1871
1872 dnl ----------------------------------------------------------------
1873 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1874 if test $ol_enable_crypt != no ; then
1875         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1876                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1877                         have_crypt=yes], [have_crypt=no])])
1878
1879         if test $have_crypt = yes ; then
1880                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1881         else
1882                 AC_MSG_WARN(could not find crypt)
1883                 if test $ol_enable_crypt = yes ; then
1884                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1885                 fi
1886
1887                 AC_MSG_WARN(disabling crypt support)
1888                 ol_enable_crypt=no
1889         fi
1890 fi
1891
1892 dnl ----------------------------------------------------------------
1893 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1894 if test $ol_enable_proctitle != no ; then
1895         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1896                 AC_CHECK_LIB(util, setproctitle,
1897                         [have_setproctitle=yes
1898                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1899                         [have_setproctitle=no
1900                         LIBOBJS="$LIBOBJS setproctitle.o"
1901                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1902
1903         if test $have_setproctitle = yes ; then
1904                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1905                         [define if setproctitle(3) is available])
1906         fi
1907 fi
1908
1909 dnl ----------------------------------------------------------------
1910 dnl Checks for typedefs, structures, and compiler characteristics.
1911 AC_TYPE_MODE_T
1912 AC_TYPE_OFF_T
1913 AC_TYPE_PID_T
1914 AM_TYPE_PTRDIFF_T
1915 AC_TYPE_SIGNAL
1916 AC_TYPE_SIZE_T
1917
1918 AC_CHECK_TYPE(ssize_t, [signed int])
1919 AC_CHECK_TYPE(caddr_t,  [char *])
1920
1921 OL_TYPE_SOCKLEN_T
1922 AC_STRUCT_ST_BLKSIZE
1923 AC_HEADER_TIME
1924 AC_STRUCT_TM
1925 AC_TYPE_UID_T
1926 OL_TYPE_SIG_ATOMIC_T
1927
1928 dnl AC_TYPE_GETGROUPS
1929
1930 OL_STRUCT_PASSWD_PW_GECOS
1931 OL_STRUCT_PASSWD_PW_PASSWD
1932
1933 OL_C_UPPER_LOWER
1934 AC_C_CONST
1935 OL_C_VOLATILE
1936
1937 if test $cross_compiling = yes ; then
1938         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1939 else
1940         AC_C_BIGENDIAN
1941 fi
1942
1943 AC_COMPILE_CHECK_SIZEOF(short)
1944 AC_COMPILE_CHECK_SIZEOF(int)
1945 AC_COMPILE_CHECK_SIZEOF(long)
1946
1947 if test "$ac_cv_sizeof_int" -lt 4 ; then
1948         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1949
1950         AC_DEFINE(LBER_INT_T,long)
1951 else
1952         AC_DEFINE(LBER_INT_T,int)
1953 fi
1954
1955 AC_DEFINE(LBER_LEN_T,long)
1956 AC_DEFINE(LBER_SOCKET_T,int)
1957 AC_DEFINE(LBER_TAG_T,long)
1958
1959 dnl ----------------------------------------------------------------
1960 dnl Checks for library functions.
1961 AC_FUNC_MEMCMP
1962 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1963 AC_FUNC_STRFTIME
1964 dnl AM_FUNC_STRTOD
1965
1966 OL_FUNC_INET_ATON
1967
1968 dnl Check for NT specific routines
1969 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
1970
1971 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
1972         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
1973 ])
1974
1975 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
1976         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
1977 ])
1978
1979 AC_FUNC_VPRINTF
1980
1981 if test $ac_cv_func_vprintf = yes ; then
1982         dnl check for vsnprintf
1983         AC_CHECK_FUNCS(vsnprintf vsprintf)
1984 fi
1985
1986 AC_CHECK_FUNCS(         \
1987         bcopy                   \
1988         closesocket             \
1989         endgrent                \
1990         endpwent                \
1991         flock                   \
1992         getdtablesize   \
1993         getgrgid                \
1994         gethostname             \
1995         getpass                 \
1996         getpwuid                \
1997         getpwnam                \
1998         getspnam                \
1999         gettimeofday    \
2000         initgroups              \
2001         lockf                   \
2002         memcpy                  \
2003         memmove                 \
2004         mkstemp                 \
2005         pipe                    \
2006         read                    \
2007         recv                    \
2008         recvfrom                \
2009         setpwfile               \
2010         setgid                  \
2011         setegid                 \
2012         setsid                  \
2013         setuid                  \
2014         seteuid                 \
2015         sigaction               \
2016         signal                  \
2017         sigset                  \
2018         snprintf                \
2019         strdup                  \
2020         strerror                \
2021         strpbrk                 \
2022         strrchr                 \
2023         strsep                  \
2024         strstr                  \
2025         strtol                  \
2026         strtoul                 \
2027         strspn                  \
2028         sysconf                 \
2029         waitpid                 \
2030         wait4                   \
2031         write                   \
2032         send                    \
2033         sendto                  \
2034 )
2035
2036 dnl We actually may need to replace more than this.
2037 AC_REPLACE_FUNCS(getopt tempnam)
2038
2039 if test "$ac_cv_func_getopt" != yes; then
2040     LIBSRCS="$LIBSRCS getopt.c"
2041 fi
2042
2043 if test "$ac_cv_func_tempnam" != yes; then
2044     LIBSRCS="$LIBSRCS tempnam.c"
2045 fi
2046
2047 dnl ----------------------------------------------------------------
2048 # Check Configuration
2049 OL_SYS_ERRLIST
2050
2051 dnl ----------------------------------------------------------------
2052 dnl Sort out defines
2053
2054 if test "$ol_enable_debug" != no ; then
2055         AC_DEFINE(LDAP_DEBUG,1,
2056                 [define this to add debugging code])
2057 fi
2058 if test "$ol_enable_syslog" = yes ; then
2059         AC_DEFINE(LDAP_SYSLOG,1,
2060                 [define this to add syslog code])
2061 fi
2062 if test "$ol_enable_libui" = yes ; then
2063         AC_DEFINE(LDAP_LIBUI,1,
2064                 [define this for LDAP User Interface support])
2065 fi
2066 if test "$ol_enable_cache" = no ; then
2067         AC_DEFINE(LDAP_NOCACHE,1,
2068                 [define this to remove -lldap cache support])
2069 fi
2070 if test "$ol_enable_dns" != no ; then
2071         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
2072 fi
2073 if test "$ol_enable_proctitle" != no ; then
2074         AC_DEFINE(LDAP_PROCTITLE,1,
2075                 [define this for LDAP process title support])
2076 fi
2077 if test "$ol_enable_referrals" != no ; then
2078         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2079 fi
2080 if test "$ol_enable_cldap" != no ; then
2081         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
2082 fi
2083 if test "$ol_enable_ldapi" != no; then
2084         AC_DEFINE(USE_PF_LOCAL,1,[define to support PF_LOCAL transport])
2085 fi
2086
2087 if test "$ol_enable_crypt" != no ; then
2088         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2089 fi
2090 if test "$ol_enable_cleartext" != no ; then
2091         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2092 fi
2093 if test "$ol_enable_multimaster" != no ; then
2094         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2095 fi
2096 if test "$ol_enable_phonetic" != no ; then
2097         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2098 fi
2099 if test "$ol_enable_rlookups" != no ; then
2100         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2101 fi
2102 if test "$ol_enable_aci" != no ; then
2103         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2104 fi
2105 if test "$ol_enable_discreteaci" != no ; then
2106         AC_DEFINE(SLAPD_ACI_DISCRETE_RIGHTS,1,[define to support discrete rights in ACIs])
2107 fi
2108
2109 if test "$ol_link_modules" != no ; then
2110         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2111         BUILD_SLAPD=yes
2112         SLAPD_MODULES_LDFLAGS="-dlopen self"
2113 fi
2114
2115 if test "$ol_link_bdb2" != no ; then
2116         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
2117         BUILD_SLAPD=yes
2118         BUILD_BDB2=yes
2119         if test "$ol_with_bdb2_module" != static ; then
2120                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
2121                         [define to support dynamic BDB2 backend])
2122                 BUILD_BDB2=mod
2123                 BUILD_BDB2_DYNAMIC=shared
2124                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
2125         fi
2126 fi
2127
2128 if test "$ol_enable_ldap" != no ; then
2129         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2130         BUILD_SLAPD=yes
2131         BUILD_LDAP=yes
2132         if test "$ol_with_ldap_module" != static ; then
2133                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2134                         [define to support dynamic LDAP backend])
2135                 BUILD_LDAP=mod
2136                 BUILD_LDAP_DYNAMIC=shared
2137                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2138         fi
2139 fi
2140
2141 if test "$ol_link_ldbm" != no ; then
2142         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2143         BUILD_SLAPD=yes
2144         BUILD_LDBM=yes
2145         if test "$ol_with_ldbm_module" != static ; then
2146                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2147                         [define to support dynamic LDBM backend])
2148                 BUILD_LDBM=mod
2149                 BUILD_LDBM_DYNAMIC=shared
2150                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2151         fi
2152 fi
2153
2154 if test "$ol_enable_passwd" != no ; then
2155         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2156         BUILD_SLAPD=yes
2157         BUILD_PASSWD=yes
2158         if test "$ol_with_passwd_module" != static ; then
2159                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2160                         [define to support dynamic PASSWD backend])
2161                 BUILD_PASSWD=mod
2162                 BUILD_PASSWD_DYNAMIC=shared
2163                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2164         fi
2165 fi
2166
2167 if test "$ol_link_perl" != no ; then
2168         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2169         BUILD_SLAPD=yes
2170         BUILD_PERL=yes
2171         if test "$ol_with_perl_module" != static ; then
2172                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2173                         [define to support dynamic PERL backend])
2174                 BUILD_PERL=mod
2175                 BUILD_PERL_DYNAMIC=shared
2176                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2177         fi
2178 fi
2179
2180 if test "$ol_enable_shell" != no ; then
2181         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2182         BUILD_SLAPD=yes
2183         BUILD_SHELL=yes
2184         if test "$ol_with_shell_module" != static ; then
2185                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2186                         [define to support dynamic SHELL backend])
2187                 BUILD_SHELL=mod
2188                 BUILD_SHELL_DYNAMIC=shared
2189                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2190         fi
2191 fi
2192
2193 if test "$ol_enable_tcl" != no ; then
2194         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2195         BUILD_SLAPD=yes
2196         BUILD_TCL=yes
2197         if test "$ol_with_tcl_module" != static; then
2198                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2199                         [define to support dynamic TCL backend])
2200                 BUILD_TCL=mod
2201                 BUILD_TCL_DYNAMIC=shared
2202                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2203         fi
2204 fi
2205
2206 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2207         $BUILD_SLAPD = yes ; then
2208         BUILD_SLURPD=yes
2209 fi
2210
2211 if test "$ol_link_isode" != no ; then
2212         BUILD_LDAPD=yes
2213 fi
2214
2215 dnl ----------------------------------------------------------------
2216
2217 if test "$LINK_BINS_DYNAMIC" = yes; then
2218     LIB_LINKAGE=DYN
2219     LT_LIB_LINKAGE=shared
2220 else
2221     LIB_LINKAGE=STAT
2222     LT_LIB_LINKAGE=static
2223 fi
2224
2225 if test "$ac_cv_mingw32" = yes ; then
2226     PLAT=NT
2227     DYN_EXT=dll
2228 else
2229     PLAT=UNIX
2230     DYN_EXT=so
2231 fi
2232
2233 AC_SUBST(LIBSRCS)
2234
2235 AC_SUBST(PLAT)
2236 AC_SUBST(LIB_LINKAGE)
2237 AC_SUBST(LT_LIB_LINKAGE)
2238 AC_SUBST(DYN_EXT)
2239
2240 AC_SUBST(BUILD_LDAPD)
2241 AC_SUBST(BUILD_SLAPD)
2242   AC_SUBST(BUILD_BDB2)
2243   AC_SUBST(BUILD_LDAP)
2244   AC_SUBST(BUILD_LDBM)
2245   AC_SUBST(BUILD_PASSWD)
2246   AC_SUBST(BUILD_PERL)
2247   AC_SUBST(BUILD_QUIPU)
2248   AC_SUBST(BUILD_SHELL)
2249   AC_SUBST(BUILD_TCL)
2250   AC_SUBST(BUILD_BDB2_DYNAMIC)
2251   AC_SUBST(BUILD_LDAP_DYNAMIC)
2252   AC_SUBST(BUILD_LDBM_DYNAMIC)
2253   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2254   AC_SUBST(BUILD_PERL_DYNAMIC)
2255   AC_SUBST(BUILD_SHELL_DYNAMIC)
2256   AC_SUBST(BUILD_TCL_DYNAMIC)
2257 AC_SUBST(BUILD_SLURPD)
2258
2259 AC_SUBST(LDAP_LIBS)
2260 AC_SUBST(LDAPD_LIBS)
2261 AC_SUBST(LDIF_LIBS)
2262 AC_SUBST(SLAPD_LIBS)
2263 AC_SUBST(SLURPD_LIBS)
2264 AC_SUBST(LDBM_LIBS)
2265 AC_SUBST(LTHREAD_LIBS)
2266 AC_SUBST(LUTIL_LIBS)
2267 AC_SUBST(WRAP_LIBS)
2268 AC_SUBST(MOD_TCL_LIB)
2269 AC_SUBST(LINK_BINS_DYNAMIC)
2270
2271 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2272 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2273 AC_SUBST(SLAPD_MODULES_LIST)
2274
2275 AC_SUBST(PERL_CPPFLAGS)
2276 AC_SUBST(SLAPD_PERL_LDFLAGS)
2277 AC_SUBST(MOD_PERL_LDFLAGS)
2278
2279 AC_SUBST(KRB_LIBS)
2280 AC_SUBST(READLINE_LIBS)
2281 AC_SUBST(SASL_LIBS)
2282 AC_SUBST(TERMCAP_LIBS)
2283 AC_SUBST(TLS_LIBS)
2284 AC_SUBST(MODULES_LIBS)
2285
2286 dnl ----------------------------------------------------------------
2287 dnl final output
2288 dnl
2289
2290 AC_OUTPUT( \
2291 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2292 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2293 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2294 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2295 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2296 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2297 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2298 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2299 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2300 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2301 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2302 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2303 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2304 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2305 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2306 include/Makefile:build/top.mk:include/Makefile.in \
2307 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2308 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2309 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2310 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2311 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2312 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2313 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2314 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2315 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2316 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2317 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2318 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2319 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2320 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2321 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2322 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2323 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2324 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2325 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2326 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2327 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2328 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2329 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2330 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2331 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2332 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2333 ,[
2334 date > stamp-h
2335 echo Please \"make depend\" to build dependencies
2336 ])