git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl This work is part of OpenLDAP Software <http://www.openldap.org/>.
   3 dnl
   4 dnl Copyright 1998-2006 The OpenLDAP Foundation.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted only as authorized by the OpenLDAP
   9 dnl Public License.
  10 dnl
  11 dnl A copy of this license is available in the file LICENSE in the
  12 dnl top-level directory of the distribution or, alternatively, at
  13 dnl <http://www.OpenLDAP.org/license.html>.
  14 dnl
  15 dnl ----------------------------------------------------------------
  16 dnl Disable config.cache!
  17 define([AC_CACHE_LOAD], )dnl
  18 define([AC_CACHE_SAVE], )dnl
  19 dnl ----------------------------------------------------------------
  20 dnl Disable libtool 1.5 support for languages we don't use
  21 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  22 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  23 define([AC_LIBTOOL_LANG_GCJ_CONFIG], [:])dnl
  24 dnl ================================================================
  25 dnl Configure.in for OpenLDAP
  26 AC_COPYRIGHT([[Copyright 1998-2006 The OpenLDAP Foundation. All rights reserved.
  27 Restrictions apply, see COPYRIGHT and LICENSE files.]])
  28 AC_REVISION([$OpenLDAP$])
  29 AC_INIT([OpenLDAP],,[http://www.openldap.org/its/])
  30 AC_CONFIG_SRCDIR(build/version.sh)dnl
  31 dnl ----------------------------------------------------------------
  32 dnl OpenLDAP Autoconf Macros
  33 builtin(include, build/openldap.m4)dnl
  34 dnl ================================================================
  35
  36 AC_CONFIG_AUX_DIR(build)dnl
  37
  38 eval `$ac_aux_dir/version.sh`
  39 if test -z "$OL_STRING"; then
  40         AC_MSG_ERROR([could not determine version])
  41 fi
  42
  43 if test -f "$ac_aux_dir/shtool" && test ! -d $ac_aux_dir/shtool; then
  44         ac_cv_shtool="$ac_aux_dir/shtool"
  45 else
  46         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  47 fi
  48
  49 SHTOOL="$ac_cv_shtool"
  50 dnl AC_SUBST(SHTOOL)dnl
  51
  52 TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  53 TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  54
  55 OPENLDAP_CVS=""
  56 if test -d $ac_aux_dir/CVS; then
  57         OPENLDAP_CVS="(from CVS sources) "
  58 fi
  59
  60 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_CVS}..."
  61
  62 dnl Determine host platform
  63 dnl             we try not to use this for much
  64 AC_CANONICAL_TARGET([])
  65
  66 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  67 AC_SUBST(PACKAGE)dnl
  68 AC_SUBST(VERSION)dnl
  69 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  70 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  71
  72 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  73 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  74 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  75 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  76
  77 OPENLDAP_LIBRELEASE=$OL_API_LIB_RELEASE
  78 AC_SUBST(OPENLDAP_LIBRELEASE)dnl
  79
  80 OPENLDAP_LIBVERSION=$OL_API_LIB_VERSION
  81 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  82
  83 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  84 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  85
  86 dnl We use autoconf features new to 2.59.  Later versions like won't work.
  87 dnl aclocal.m4 should be built using aclocal from automake 1.5
  88 dnl libtool 1.5 should be installed.
  89 AC_PREREQ(2.59)dnl Required Autoconf version
  90
  91 AH_TOP([
  92 /* begin of portable.h.pre */
  93 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
  94  *
  95  * Copyright 1998-2006 The OpenLDAP Foundation
  96  * All rights reserved.
  97  *
  98  * Redistribution and use in source and binary forms, with or without
  99  * modification, are permitted only as authorized by the OpenLDAP
 100  * Public License.
 101  *
 102  * A copy of this license is available in the file LICENSE in the
 103  * top-level directory of the distribution or, alternatively, at
 104  * <http://www.OpenLDAP.org/license.html>.
 105  */
 106
 107 #ifndef _LDAP_PORTABLE_H
 108 #define _LDAP_PORTABLE_H
 109
 110 /* define this if needed to get reentrant functions */
 111 #ifndef REENTRANT
 112 #undef REENTRANT
 113 #endif
 114 #ifndef _REENTRANT
 115 #undef _REENTRANT
 116 #endif
 117
 118 /* define this if needed to get threadsafe functions */
 119 #ifndef THREADSAFE
 120 #undef THREADSAFE
 121 #endif
 122 #ifndef _THREADSAFE
 123 #undef _THREADSAFE
 124 #endif
 125 #ifndef THREAD_SAFE
 126 #undef THREAD_SAFE
 127 #endif
 128 #ifndef _THREAD_SAFE
 129 #undef _THREAD_SAFE
 130 #endif
 131
 132 #ifndef _SGI_MP_SOURCE
 133 #undef _SGI_MP_SOURCE
 134 #endif
 135
 136 /* end of portable.h.pre */
 137 ])
 138 AH_BOTTOM([
 139 /* begin of portable.h.post */
 140
 141 #ifdef _WIN32
 142         /* don't suck in all of the win32 api */
 143 #       define WIN32_LEAN_AND_MEAN 1
 144 #endif
 145
 146 #ifndef LDAP_NEEDS_PROTOTYPES
 147 /* force LDAP_P to always include prototypes */
 148 #define LDAP_NEEDS_PROTOTYPES 1
 149 #endif
 150
 151 #ifndef LDAP_REL_ENG
 152 #if (LDAP_VENDOR_VERSION == 000000) && !defined(LDAP_DEVEL)
 153 #define LDAP_DEVEL
 154 #endif
 155 #if defined(LDAP_DEVEL) && !defined(LDAP_TEST)
 156 #define LDAP_TEST
 157 #endif
 158 #endif
 159
 160 #ifdef HAVE_STDDEF_H
 161 #       include <stddef.h>
 162 #endif
 163
 164 #ifdef HAVE_EBCDIC
 165 /* ASCII/EBCDIC converting replacements for stdio funcs
 166  * vsnprintf and snprintf are used too, but they are already
 167  * checked by the configure script
 168  */
 169 #define fputs ber_pvt_fputs
 170 #define fgets ber_pvt_fgets
 171 #define printf ber_pvt_printf
 172 #define fprintf ber_pvt_fprintf
 173 #define vfprintf ber_pvt_vfprintf
 174 #define vsprintf ber_pvt_vsprintf
 175 #endif
 176
 177 #include "ac/fdset.h"
 178
 179 #include "ldap_cdefs.h"
 180 #include "ldap_features.h"
 181
 182 #include "ac/assert.h"
 183 #include "ac/localize.h"
 184
 185 #endif /* _LDAP_PORTABLE_H */
 186 /* end of portable.h.post */
 187 ])
 188
 189 AC_CONFIG_HEADERS([include/portable.h:include/portable.hin])
 190 AC_CONFIG_HEADERS([include/ldap_features.h:include/ldap_features.hin])
 191 AC_CONFIG_HEADERS([include/lber_types.h:include/lber_types.hin])
 192
 193 dnl ================================================================
 194 dnl Start Args
 195 AC_MSG_CHECKING(configure arguments)
 196 AC_PREFIX_DEFAULT(/usr/local)
 197
 198 top_builddir=`pwd`
 199 AC_SUBST(top_builddir)dnl
 200
 201 dnl ----------------------------------------------------------------
 202 dnl --with-subdir
 203 ldap_subdir="/openldap"
 204
 205 AC_ARG_WITH(subdir,
 206 [  --with-subdir=DIR       change default subdirectory used for installs],
 207 [case "$withval" in
 208         no) ldap_subdir=""
 209                 ;;
 210         yes)
 211                 ;;
 212         /*|\\*)
 213                 ldap_subdir="$withval"
 214                 ;;
 215         *)
 216                 ldap_subdir="/$withval"
 217                 ;;
 218 esac
 219 ])dnl
 220
 221 AC_SUBST(ldap_subdir)dnl
 222
 223 dnl ----------------------------------------------------------------
 224 dnl General "enable" options
 225 dnl set default to traditional to enable the original debug style
 226 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes, [no yes traditional])dnl
 227 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 228 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 229 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 230 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 231 ol_enable_referrals=${ol_enable_referrals-no}
 232 dnl OL_ARG_ENABLE(kbind,[  --enable-kbind         enable LDAPv2+ Kerberos IV bind (deprecated)], no)dnl
 233 ol_enable_kbind=${ol_enable_kbind-no}
 234 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 235 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 236
 237 dnl ----------------------------------------------------------------
 238 dnl General "with" options
 239 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 240         auto, [auto yes no] )
 241 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 242         auto, [auto yes no] )
 243 dnl     OL_ARG_WITH(kerberos,[  --with-kerberos   with Kerberos support],
 244 dnl             auto, [auto k5 k5only k425 kth k4 afs yes no])
 245 ol_with_kerberos=${ol_with_kerberos-auto}
 246 OL_ARG_WITH(threads,[  --with-threads     with threads],
 247         auto, [auto nt posix mach pth lwp yes no manual] )
 248 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 249         auto, [auto openssl yes no] )
 250 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 251         auto, [auto yes no manual] )
 252 OL_ARG_WITH(multiple_precision,[  --with-multiple-precision
 253                           multiple precision support for statistics
 254                           auto|bignum|gmp],
 255         auto, [auto bignum gmp yes no] )
 256
 257 dnl ----------------------------------------------------------------
 258 dnl Server options
 259 dnl ----------------------------------------------------------------
 260
 261 dnl ----------------------------------------------------------------
 262 dnl SLAPD OPTIONS
 263 AC_ARG_ENABLE(xxslapdoptions,[
 264 SLAPD (Standalone LDAP Daemon) Options:])
 265 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 266 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no)dnl
 267 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 268 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 269 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 270 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 271 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 272 dnl OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 273 ol_enable_multimaster=${ol_enable_multimaster-no}
 274 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and rwm overlay], auto)dnl
 275 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 276 OL_ARG_ENABLE(slapi,[    --enable-slapi        enable SLAPI support (experimental)], no)dnl
 277 OL_ARG_ENABLE(slp,[    --enable-slp          enable SLPv2 support], no)dnl
 278 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 279
 280 dnl ----------------------------------------------------------------
 281 dnl SLAPD Backend Options
 282 Backends="bdb \
 283         dnssrv \
 284         hdb \
 285         ldap \
 286         ldbm \
 287         meta \
 288         monitor \
 289         null \
 290         passwd \
 291         perl \
 292         relay \
 293         shell \
 294         sql"
 295
 296 AC_ARG_ENABLE(xxslapbackends,[
 297 SLAPD Backend Options:])
 298
 299 OL_ARG_ENABLE(backends,[    --enable-backends     enable all available backends],
 300         --, [no yes mod])dnl
 301 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend],
 302         yes, [no yes mod], ol_enable_backends)dnl
 303 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend],
 304         no, [no yes mod], ol_enable_backends)dnl
 305 OL_ARG_ENABLE(hdb,[    --enable-hdb       enable Hierarchical DB backend],
 306         yes, [no yes mod], ol_enable_backends)dnl
 307 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend],
 308         no, [no yes mod], ol_enable_backends)dnl
 309 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend],
 310         no, [no yes mod], ol_enable_backends)dnl
 311 AC_ARG_WITH(ldbm_api,,[
 312         AC_MSG_WARN([Please use --enable-ldbm-api instead of --with-ldbm-api])
 313         enable_ldbm_api="$with_ldbm_api"])
 314 OL_ARG_ENABLE(ldbm_api,[      --enable-ldbm-api   use LDBM API],
 315         auto, [auto berkeley bcompat mdbm gdbm])
 316 AC_ARG_WITH(ldbm_type,,[
 317         AC_MSG_WARN([Please use --enable-ldbm-type instead of --with-ldbm-type])
 318         enable_ldbm_type="$with_ldbm_type"])
 319 OL_ARG_ENABLE(ldbm_type,[      --enable-ldbm-type  use LDBM type],
 320         auto, [auto btree hash])
 321 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend],
 322         no, [no yes mod], ol_enable_backends)dnl
 323 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend],
 324         yes, [no yes mod], ol_enable_backends)dnl
 325 OL_ARG_ENABLE(null,[    --enable-null     enable null backend],
 326         no, [no yes mod], ol_enable_backends)dnl
 327 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend],
 328         no, [no yes mod], ol_enable_backends)dnl
 329 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend],
 330         no, [no yes mod], ol_enable_backends)dnl
 331 OL_ARG_ENABLE(relay,[    --enable-relay           enable relay backend],
 332         yes, [no yes mod], ol_enable_backends)dnl
 333 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend],
 334         no, [no yes mod], ol_enable_backends)dnl
 335 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend],
 336         no, [no yes mod], ol_enable_backends)dnl
 337
 338 dnl ----------------------------------------------------------------
 339 dnl SLAPD Overlay Options
 340 Overlays="accesslog \
 341         denyop \
 342         dyngroup \
 343         dynlist \
 344         lastmod \
 345         ppolicy \
 346         proxycache \
 347         refint \
 348         retcode \
 349         rwm \
 350         syncprov \
 351         translucent \
 352         unique \
 353         valsort"
 354
 355 AC_ARG_ENABLE(xxslapoverlays,[
 356 SLAPD Overlay Options:])
 357
 358 OL_ARG_ENABLE(overlays,[    --enable-overlays     enable all available overlays],
 359         --, [no yes mod])dnl
 360 OL_ARG_ENABLE(accesslog,[    --enable-accesslog   In-Directory Access Logging overlay],
 361         no, [no yes mod], ol_enable_overlays)
 362 OL_ARG_ENABLE(denyop,[    --enable-denyop         Deny Operation overlay],
 363         no, [no yes mod], ol_enable_overlays)
 364 OL_ARG_ENABLE(dyngroup,[    --enable-dyngroup     Dynamic Group overlay],
 365         no, [no yes mod], ol_enable_overlays)
 366 OL_ARG_ENABLE(dynlist,[    --enable-dynlist       Dynamic List overlay],
 367         no, [no yes mod], ol_enable_overlays)
 368 OL_ARG_ENABLE(lastmod,[    --enable-lastmod       Last Modification overlay],
 369         no, [no yes mod], ol_enable_overlays)
 370 OL_ARG_ENABLE(ppolicy,[    --enable-ppolicy       Password Policy overlay],
 371         no, [no yes mod], ol_enable_overlays)
 372 OL_ARG_ENABLE(proxycache,[    --enable-proxycache         Proxy Cache overlay],
 373         no, [no yes mod], ol_enable_overlays)
 374 OL_ARG_ENABLE(refint,[    --enable-refint         Referential Integrity overlay],
 375         no, [no yes mod], ol_enable_overlays)
 376 OL_ARG_ENABLE(retcode,[    --enable-retcode       Return Code testing overlay],
 377         no, [no yes mod], ol_enable_overlays)
 378 OL_ARG_ENABLE(rwm,[    --enable-rwm               Rewrite/Remap overlay],
 379         no, [no yes mod], ol_enable_overlays)
 380 OL_ARG_ENABLE(syncprov,[    --enable-syncprov     Syncrepl Provider overlay],
 381         yes, [no yes mod], ol_enable_overlays)
 382 OL_ARG_ENABLE(translucent,[    --enable-translucent  Translucent Proxy overlay],
 383         no, [no yes mod], ol_enable_overlays)
 384 OL_ARG_ENABLE(unique,[    --enable-unique       Attribute Uniqueness overlay],
 385         no, [no yes mod], ol_enable_overlays)
 386 OL_ARG_ENABLE(valsort,[    --enable-valsort      Value Sorting overlay],
 387         no, [no yes mod], ol_enable_overlays)
 388
 389 dnl ----------------------------------------------------------------
 390 dnl SLURPD OPTIONS
 391 AC_ARG_ENABLE(xxslurpdoptions,[
 392 SLURPD (Replication Daemon) Options:])
 393 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 394
 395 dnl ----------------------------------------------------------------
 396 AC_ARG_ENABLE(xxliboptions,[
 397 Library Generation & Linking Options])
 398 AC_ENABLE_STATIC
 399 AC_ENABLE_SHARED
 400
 401 dnl ----------------------------------------------------------------
 402
 403 # validate options
 404 if test $ol_enable_slapd = no ; then
 405         dnl SLAPD was specificallly disabled
 406         if test $ol_enable_slapi = yes ; then
 407                 AC_MSG_WARN([slapd disabled, ignoring --enable-slapi argument])
 408         fi
 409         case "$ol_enable_backends" in yes | mod)
 410                 AC_MSG_WARN([slapd disabled, ignoring --enable-backends argument])
 411         esac
 412         for i in $Backends; do
 413                 eval "ol_tmp=\$ol_enable_$i"
 414                 if test $ol_tmp != no ; then
 415                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 416                         eval "ol_enable_$i=no"
 417                 fi
 418         done
 419         if test $ol_enable_modules = yes ; then
 420                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 421         fi
 422         if test $ol_enable_multimaster = yes ; then
 423                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 424         fi
 425         if test $ol_enable_wrappers = yes ; then
 426                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 427         fi
 428         if test $ol_enable_rlookups = yes ; then
 429                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 430         fi
 431         if test $ol_enable_aci = yes ; then
 432                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 433         fi
 434         if test $ol_enable_ldbm_api != auto ; then
 435                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm-api argument])
 436         fi
 437         if test $ol_enable_ldbm_type != auto ; then
 438                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm-type argument])
 439         fi
 440         if test $ol_enable_slurpd = yes ; then
 441                 AC_MSG_ERROR([slurpd requires slapd])
 442         fi
 443         if test $ol_enable_rewrite = yes ; then
 444                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 445         fi
 446         dnl overlays
 447         case "$ol_enable_overlays" in yes | mod)
 448                 AC_MSG_WARN([slapd disabled, ignoring --enable-overlays argument])
 449         esac
 450         for i in $Overlays; do
 451                 eval "ol_tmp=\$ol_enable_$i"
 452                 if test $ol_tmp != no ; then
 453                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 454                         eval "ol_enable_$i=no"
 455                 fi
 456         done
 457
 458         # force settings to no
 459         ol_enable_slapi=no
 460
 461         ol_enable_backends=
 462         ol_enable_overlays=
 463         ol_enable_modules=no
 464         ol_enable_multimaster=no
 465         ol_enable_rlookups=no
 466         ol_enable_aci=no
 467         ol_enable_wrappers=no
 468
 469         ol_enable_ldbm_api=no
 470         ol_enable_ldbm_type=no
 471
 472         ol_enable_slurpd=no
 473
 474         ol_enable_rewrite=no
 475
 476 elif test $ol_enable_ldbm = no ; then
 477         dnl SLAPD without LDBM
 478
 479         if test $ol_enable_ldbm_api != auto ; then
 480                 AC_MSG_WARN([LDBM disabled, ignoring --enable-ldbm-api argument])
 481         fi
 482
 483         if test $ol_enable_ldbm_type != auto ; then
 484                 AC_MSG_WARN([LDBM disabled, ignoring --enable-ldbm-type argument])
 485         fi
 486
 487         if test $ol_enable_modules != yes &&
 488            test $ol_enable_bdb = no &&
 489            test $ol_enable_dnssrv = no &&
 490            test $ol_enable_hdb = no &&
 491            test $ol_enable_ldap = no &&
 492            test $ol_enable_meta = no &&
 493            test $ol_enable_monitor = no &&
 494            test $ol_enable_null = no &&
 495            test $ol_enable_passwd = no &&
 496            test $ol_enable_perl = no &&
 497            test $ol_enable_relay = no &&
 498            test $ol_enable_shell = no &&
 499            test $ol_enable_sql = no ; then
 500
 501                 if test $ol_enable_slapd = yes ; then
 502                         AC_MSG_ERROR([slapd requires a backend])
 503                 else
 504                         AC_MSG_WARN([skipping slapd, no backend specified])
 505                         ol_enable_slapd=no
 506                 fi
 507         fi
 508
 509         ol_enable_ldbm_api=no
 510         ol_enable_ldbm_type=no
 511
 512         if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
 513                 ol_enable_ldbm_api=berkeley
 514         fi
 515
 516 else
 517         dnl SLAPD with LDBM
 518         if test $ol_enable_ldbm_api = gdbm &&
 519            test $ol_enable_ldbm_type = btree ; then
 520                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 521         fi
 522         if test $ol_enable_ldbm_api = mdbm &&
 523            test $ol_enable_ldbm_type = btree ; then
 524                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 525         fi
 526         if test $ol_enable_ldbm_api = ndbm &&
 527            test $ol_enable_ldbm_type = btree ; then
 528                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 529         fi
 530
 531         if test $ol_enable_bdb/$ol_enable_hdb != no/no ; then
 532                 if test $ol_enable_ldbm_api = auto ; then
 533                         ol_enable_ldbm_api=berkeley
 534                 elif test $ol_enable_ldbm_api != berkeley ; then
 535                         AC_MSG_ERROR([LDBM API not compatible with BDB/HDB])
 536                 fi
 537         fi
 538 fi
 539
 540 if test $ol_enable_meta/$ol_enable_ldap = yes/no ; then
 541         AC_MSG_ERROR([--enable-meta requires --enable-ldap])
 542 fi
 543
 544 if test $ol_enable_slurpd = yes ; then
 545         dnl SLURPD was specifically enabled
 546         if test $ol_with_threads = no ; then
 547                 AC_MSG_ERROR([slurpd requires threads])
 548         fi
 549 fi
 550
 551 if test $ol_enable_lmpasswd = yes ; then
 552         if test $ol_with_tls = no ; then
 553                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 554         fi
 555 fi
 556
 557 if test $ol_enable_kbind = yes ; then
 558         if test $ol_with_kerberos = no ; then
 559                 AC_MSG_ERROR([options require --with-kerberos])
 560         elif test $ol_with_kerberos = auto ; then
 561                 ol_with_kerberos=yes
 562         fi
 563
 564 elif test $ol_enable_kbind = no ; then
 565         if test $ol_with_kerberos = auto ; then
 566                 ol_with_kerberos=no
 567         elif test $ol_with_kerberos != no ; then
 568                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 569                 ol_with_kerberos=no
 570         fi
 571 fi
 572
 573 if test $ol_enable_spasswd = yes ; then
 574         if test $ol_with_cyrus_sasl = no ; then
 575                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 576         fi
 577         ol_with_cyrus_sasl=yes
 578 fi
 579
 580 AC_MSG_RESULT(done)
 581
 582 dnl ----------------------------------------------------------------
 583 dnl Initialize vars
 584 LDAP_LIBS=
 585 LDBM_LIBS=
 586 LTHREAD_LIBS=
 587 LUTIL_LIBS=
 588
 589 SLAPD_LIBS=
 590 SLURPD_LIBS=
 591
 592 BUILD_SLAPD=no
 593 BUILD_SLURPD=no
 594
 595 BUILD_THREAD=no
 596
 597 BUILD_SLAPI=no
 598 SLAPD_SLAPI_DEPEND=
 599
 600 BUILD_BDB=no
 601 BUILD_DNSSRV=no
 602 BUILD_HDB=no
 603 BUILD_LDAP=no
 604 BUILD_LDBM=no
 605 BUILD_META=no
 606 BUILD_MONITOR=no
 607 BUILD_NULL=no
 608 BUILD_PASSWD=no
 609 BUILD_PERL=no
 610 BUILD_RELAY=no
 611 BUILD_SHELL=no
 612 BUILD_SQL=no
 613
 614 BUILD_ACCESSLOG=no
 615 BUILD_DENYOP=no
 616 BUILD_DYNGROUP=no
 617 BUILD_DYNLIST=no
 618 BUILD_LASTMOD=no
 619 BUILD_PPOLICY=no
 620 BUILD_PROXYCACHE=no
 621 BUILD_REFINT=no
 622 BUILD_RETCODE=no
 623 BUILD_RWM=no
 624 BUILD_SYNCPROV=no
 625 BUILD_TRANSLUCENT=no
 626 BUILD_UNIQUE=no
 627 BUILD_VALSORT=no
 628
 629 SLAPD_STATIC_OVERLAYS=
 630 SLAPD_DYNAMIC_OVERLAYS=
 631
 632 SLAPD_MODULES_LDFLAGS=
 633 SLAPD_MODULES_CPPFLAGS=
 634
 635 SLAPD_STATIC_BACKENDS=back-ldif
 636 SLAPD_DYNAMIC_BACKENDS=
 637
 638 SLAPD_PERL_LDFLAGS=
 639 MOD_PERL_LDFLAGS=
 640 PERL_CPPFLAGS=
 641
 642 SLAPD_SQL_LDFLAGS=
 643 SLAPD_SQL_LIBS=
 644 SLAPD_SQL_INCLUDES=
 645
 646 KRB4_LIBS=
 647 KRB5_LIBS=
 648 SASL_LIBS=
 649 TLS_LIBS=
 650 MODULES_LIBS=
 651 SLAPI_LIBS=
 652 LIBSLAPI=
 653 LIBSLAPITOOLS=
 654 AUTH_LIBS=
 655 ICU_LIBS=
 656
 657 SLAPD_SLP_LIBS=
 658 SLAPD_GMP_LIBS=
 659
 660 dnl ================================================================
 661 dnl Checks for programs
 662
 663 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 664
 665 dnl ----------------------------------------------------------------
 666 dnl
 667 dnl Determine which C translator to use
 668 dnl
 669
 670 dnl AIX Thread requires we use cc_r or xlc_r.
 671 dnl But only do this IF AIX and CC is not set
 672 dnl and threads are auto|yes|posix.
 673 dnl
 674 dnl If we find cc_r|xlc_r, force pthreads and assume
 675 dnl             pthread_create is in $LIBS (ie: don't bring in
 676 dnl             any additional thread libraries)
 677 dnl If we do not find cc_r|xlc_r, disable threads
 678
 679 ol_aix_threads=no
 680 case "$target" in
 681 *-*-aix*) dnl all AIX is not a good idea.
 682         if test -z "$CC" ; then
 683                 case "$ol_with_threads" in
 684                 auto | yes |  posix) ol_aix_threads=yes ;;
 685                 esac
 686         fi
 687 ;;
 688 esac
 689
 690 if test $ol_aix_threads = yes ; then
 691         if test -z "${CC}" ; then
 692                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 693
 694                 if test "$CC" = cc ; then
 695                         dnl no CC! don't allow --with-threads
 696                         if test $ol_with_threads != auto ; then
 697                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 698                         else
 699                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 700                         fi
 701                         ol_with_threads=no
 702                 fi
 703         fi
 704
 705         case ${CC} in cc_r | xlc_r)
 706                 ol_with_threads=posix
 707                 ol_cv_pthread_create=yes
 708                 ;;
 709         esac
 710 fi
 711
 712 if test -z "${CC}"; then
 713         AC_CHECK_PROGS(CC,cc gcc,missing)
 714
 715         if test "${CC}" = "missing" ; then
 716                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 717         fi
 718 fi
 719
 720 if test -z "${AR}"; then
 721         AC_CHECK_PROGS(AR,ar gar,missing)
 722
 723         if test "${AR}" = "missing" ; then
 724                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 725         fi
 726 fi
 727
 728 AC_LIBTOOL_WIN32_DLL
 729 AC_LIBTOOL_DLOPEN
 730 AC_PROG_LIBTOOL
 731
 732 dnl ----------------------------------------------------------------
 733 dnl Perl
 734 ol_link_perl=no
 735 if test $ol_enable_perl != no ; then
 736         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 737
 738         if test "no$PERLBIN" = "no" ; then
 739                 if test $ol_enable_perl = yes ; then
 740                         AC_MSG_ERROR([could not locate perl])
 741                 fi
 742
 743         else
 744                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 745                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 746
 747                 if test x"$ol_enable_perl" = "xyes" ; then
 748                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 749                 else
 750                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 751                 fi
 752                 dnl should check perl version
 753                 ol_link_perl=yes
 754         fi
 755 fi
 756
 757 AC_PROG_CPP
 758
 759 dnl ----------------------------------------------------------------
 760 dnl Checks for Windows NT
 761 case $host_os in
 762   *mingw32* ) ac_cv_mingw32=yes ;;
 763   *cygwin* ) ac_cv_cygwin=yes ;;
 764 esac
 765
 766 dnl ----------------------------------------------------------------
 767 dnl Checks for file extensions
 768 AC_EXEEXT
 769 AC_OBJEXT
 770 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 771
 772 dnl ----------------------------------------------------------------
 773 dnl BeOS requires -lbe -lroot -lnet
 774 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 775
 776 dnl ----------------------------------------------------------------
 777 dnl OpenLDAP requires STDC features
 778 AC_PROG_CC
 779 if test "X${ac_cv_prog_cc_stdc}" = "Xno" ; then
 780         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 781 fi
 782
 783 dnl ----------------------------------------------------------------
 784 dnl Check cc depend flags
 785 OL_MKDEPEND
 786 if test "${ol_cv_mkdep}" = no ; then
 787         # this will soon become an error
 788         AC_MSG_WARN([do not know how to generate dependencies])
 789 fi
 790
 791 dnl ----------------------------------------------------------------
 792 dnl Check for AIX security library
 793 AC_CHECK_LIB(s, afopen, [
 794         AUTH_LIBS=-ls
 795         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 796 ])
 797
 798 dnl ----------------------------------------------------------------
 799 dnl Check for IBM OS/390
 800 case "$target" in
 801 *-ibm-openedition)
 802         ac_cv_func_getopt=no
 803         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 804         ;;
 805 esac
 806
 807 dnl ----------------------------------------------------------------
 808 dnl Check for module support
 809 ol_link_modules=no
 810 WITH_MODULES_ENABLED=no
 811 if test $ol_enable_modules != no ; then
 812         AC_CHECK_HEADERS(ltdl.h)
 813
 814         if test $ac_cv_header_ltdl_h = no ; then
 815                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 816         fi
 817
 818         AC_CHECK_LIB(ltdl, lt_dlinit, [
 819                 MODULES_LIBS=-lltdl
 820                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 821         ])
 822
 823         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 824                 AC_MSG_ERROR([could not locate libtool -lltdl])
 825         fi
 826         ol_link_modules=yes
 827         WITH_MODULES_ENABLED=yes
 828
 829 else
 830         for i in $Backends; do
 831                 eval "ol_tmp=\$ol_enable_$i"
 832                 if test $ol_tmp = mod ; then
 833                         AC_MSG_WARN([building static $i backend])
 834                         eval "ol_enable_$i=yes"
 835                 fi
 836         done
 837         for i in $Overlays; do
 838                 eval "ol_tmp=\$ol_enable_$i"
 839                 if test $ol_tmp = mod ; then
 840                         AC_MSG_WARN([building static $i overlay])
 841                         eval "ol_enable_$i=yes"
 842                 fi
 843         done
 844 fi
 845
 846 dnl ----------------------------------------------------------------
 847 dnl Checks for header files.
 848 OL_HEADER_STDC
 849
 850 if test $ol_cv_header_stdc != yes; then
 851         AC_MSG_WARN([could not locate Standard C compliant headers])
 852 fi
 853
 854 AC_HEADER_DIRENT
 855 AC_HEADER_SYS_WAIT
 856 AC_HEADER_TIOCGWINSZ
 857
 858 AC_CHECK_HEADERS(               \
 859         arpa/inet.h             \
 860         arpa/nameser.h          \
 861         assert.h                \
 862         bits/types.h            \
 863         conio.h                 \
 864         crypt.h                 \
 865         direct.h                \
 866         errno.h                 \
 867         fcntl.h                 \
 868         filio.h                 \
 869         getopt.h                \
 870         grp.h                   \
 871         io.h                    \
 872         libutil.h               \
 873         limits.h                \
 874         locale.h                \
 875         netinet/tcp.h           \
 876         malloc.h                \
 877         memory.h                \
 878         psap.h                  \
 879         pwd.h                   \
 880         process.h               \
 881         sgtty.h                 \
 882         shadow.h                \
 883         stddef.h                \
 884         string.h                \
 885         strings.h               \
 886         sysexits.h              \
 887         sys/file.h              \
 888         sys/filio.h             \
 889         sys/errno.h             \
 890         sys/ioctl.h             \
 891         sys/param.h             \
 892         sys/resource.h          \
 893         sys/select.h            \
 894         sys/socket.h            \
 895         sys/stat.h              \
 896         sys/syslog.h            \
 897         sys/time.h              \
 898         sys/types.h             \
 899         sys/uio.h               \
 900         syslog.h                \
 901         termios.h               \
 902         unistd.h                \
 903         utime.h                 \
 904         winsock.h               \
 905         winsock2.h              \
 906 )
 907
 908 AC_CHECK_HEADERS( resolv.h, [], [],
 909 [$ac_includes_default]
 910 #include <netinet/in.h>
 911 )
 912
 913 AC_CHECK_HEADERS(sys/ucred.h, [], [],
 914 [$ac_includes_default
 915 #ifdef HAVE_SYS_PARAM_H
 916 #include <sys/param.h>
 917 #endif
 918 ])
 919
 920 dnl ----------------------------------------------------------------
 921 dnl Checks for libraries
 922
 923 AC_CHECK_FUNCS( sigaction sigset )
 924
 925 dnl HP-UX requires -lV3
 926 dnl this is not needed on newer versions of HP-UX
 927 if test $ac_cv_func_sigaction = no && test $ac_cv_func_sigaction = no ; then
 928         AC_CHECK_LIB(V3, sigset)
 929 fi
 930
 931 dnl The following is INTENTIONALLY scripted out because shell does not
 932 dnl support variable names with the '@' character, which is what
 933 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 934 dnl
 935 dnl Skip Winsock tests on Cygwin
 936 if test "$ac_cv_cygwin" != yes && test "$ac_cv_header_winsock_h" = yes; then
 937 AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 938 save_LIBS="$LIBS"
 939 for curlib in ws2_32 wsock32; do
 940         LIBS="$LIBS -l$curlib"
 941         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <winsock.h>
 942                         ]], [[
 943                         socket(0,0,0);
 944                         select(0,NULL,NULL,NULL,NULL);
 945                         closesocket(0);
 946                         gethostname(NULL,0);
 947                         ]])],[ol_cv_winsock=yes],[ol_cv_winsock=no])
 948
 949         if test $ol_cv_winsock = yes; then
 950                 AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 951                 ac_cv_func_socket=yes
 952                 ac_cv_func_select=yes
 953                 ac_cv_func_closesocket=yes
 954                 ac_cv_func_gethostname=yes
 955                 if test $curlib = ws2_32; then
 956                         ol_cv_winsock=winsock2
 957                         AC_DEFINE(HAVE_WINSOCK2, 1,
 958                                   [define if you have winsock2])
 959                 fi
 960                 break
 961         fi
 962         LIBS="$save_LIBS"
 963 done)
 964 fi
 965
 966 dnl Find socket()
 967 dnl Likely combinations:
 968 dnl             -lsocket [ -lnsl_s | -lnsl ]
 969 dnl             -linet
 970
 971 AC_CHECK_FUNC(socket, :, [
 972 dnl hopefully we won't include too many libraries
 973         AC_CHECK_LIB(socket, main)
 974         AC_CHECK_LIB(net, main)
 975         AC_CHECK_LIB(nsl_s, main)
 976         AC_CHECK_LIB(nsl, main)
 977         AC_CHECK_LIB(inet, socket)
 978         AC_CHECK_LIB(gen, main)
 979 ])
 980
 981 dnl require select
 982 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 983
 984 if test "${ac_cv_header_winsock_h}" != yes; then
 985         dnl Select arg types
 986         dnl (if this detection becomes permenent, it and the select() detection
 987         dnl should be done before the yielding select test)
 988         AC_FUNC_SELECT_ARGTYPES
 989 fi
 990
 991 dnl check to see if system call automatically restart
 992 dnl AC_SYS_RESTARTABLE_SYSCALLS
 993
 994 dnl ----------------------------------------------------------------
 995 AC_CHECK_FUNCS( poll )
 996 AC_CHECK_HEADERS( poll.h )
 997
 998 dnl ----------------------------------------------------------------
 999 AC_CHECK_HEADERS( sys/epoll.h )
1000 if test "${ac_cv_header_sys_epoll_h}" = yes; then
1001 AC_MSG_CHECKING(for epoll system call)
1002 AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char *argv)
1003 {
1004         int epfd = epoll_create(256);
1005         exit (epfd == -1 ? 1 : 0);
1006 }]])],[AC_MSG_RESULT(yes)
1007 AC_DEFINE(HAVE_EPOLL,1, [define if your system supports epoll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1008 fi
1009
1010 dnl ----------------------------------------------------------------
1011 # strerror checks
1012 OL_STRERROR
1013
1014 dnl ----------------------------------------------------------------
1015 dnl require POSIX regex
1016 AC_CHECK_HEADERS( regex.h )
1017 if test "$ac_cv_header_regex_h" != yes ; then
1018         AC_MSG_ERROR([POSIX regex.h required.])
1019 fi
1020 AC_SEARCH_LIBS(regfree, [regex gnuregex],
1021         :, AC_MSG_ERROR([POSIX regex required.]))
1022
1023 OL_POSIX_REGEX
1024 if test "$ol_cv_c_posix_regex" = no ; then
1025         AC_MSG_ERROR([broken POSIX regex!])
1026 fi
1027
1028 dnl ----------------------------------------------------------------
1029 dnl UUID Support
1030
1031 have_uuid=no
1032 AC_CHECK_HEADERS(sys/uuid.h)
1033 if test $ac_cv_header_sys_uuid_h = yes ; then
1034         save_LIBS="$LIBS"
1035         AC_SEARCH_LIBS(uuid_to_str, uuid, [have_uuid=yes], :)
1036         LIBS="$save_LIBS"
1037
1038         if test have_uuid = yes ; then
1039                 AC_DEFINE(HAVE_UUID_TO_STR,1,
1040                         [define if you have uuid_to_str()])
1041
1042                 test "$ac_cv_search_uuid_to_str" = "none required" || \
1043                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
1044         fi
1045 fi
1046
1047 dnl For windows, check for the need of RPCRT for UUID function support
1048 if test $have_uuid = no ; then
1049         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
1050         save_LIBS="$LIBS"
1051         LIBS="$LIBS -lrpcrt4"
1052         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1053                 int __stdcall UuidCreate(void *);
1054                 int __stdcall UuidToStringA(void *,void **);
1055                 ]], [[
1056                 UuidCreate(0);
1057                 UuidToStringA(0,0);
1058                 ]])],[need_rpcrt=yes],[need_rpcrt=no])
1059         if test $need_rpcrt = yes; then
1060                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
1061         fi
1062         LIBS="$save_LIBS"
1063         AC_MSG_RESULT($need_rpcrt)
1064 fi
1065
1066 dnl ----------------------------------------------------------------
1067 dnl Check for resolver routines
1068 OL_RESOLVER_LINK
1069
1070 ol_link_dnssrv=no
1071 if test "$ol_cv_lib_resolver" != no ; then
1072         AC_DEFINE(HAVE_RES_QUERY,1,
1073                 [define if you have res_query()])
1074
1075         if test "$ol_enable_dnssrv" != no ; then
1076                 ol_link_dnssrv=yes
1077         fi
1078
1079         if test "$ol_cv_lib_resolver" != yes ; then
1080                 LIBS="$ol_cv_lib_resolver $LIBS"
1081         fi
1082 fi
1083
1084 if test "$ol_enable_dnssrv" = yes || test "$ol_enable_dnssrv" = mod ; then
1085         if test "$ol_link_dnssrv" = no ; then
1086                 AC_MSG_ERROR([DNSSRV requires res_query()])
1087         fi
1088 else
1089         ol_enable_dnssrv=no
1090 fi
1091
1092 AC_CHECK_FUNCS( hstrerror )
1093
1094 dnl ----------------------------------------------------------------
1095 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1096 dnl PF_LOCAL may use getaddrinfo in available
1097 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1098
1099 ol_link_ipv6=no
1100 if test $ac_cv_func_getaddrinfo = no || test $ac_cv_func_inet_ntop = no ; then
1101         if test $ol_enable_ipv6 = yes ; then
1102                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1103         fi
1104 elif test $ol_enable_ipv6 != no ; then
1105         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1106                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1107 #                       include <netinet/in.h>
1108 #                       ifdef INET6_ADDRSTRLEN
1109                                 __has_inet6_addrstrlen__;
1110 #                       endif
1111                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1112
1113
1114         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1115                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1116 #include <sys/types.h>
1117 #include <sys/socket.h>
1118 ]], [[
1119                         struct sockaddr_storage ss;
1120 ]])],[ol_cv_struct_sockaddr_storage=yes],[ol_cv_struct_sockaddr_storage=no])])
1121
1122         if test $ol_cv_inet6_addrstrlen = yes &&
1123            test $ol_cv_struct_sockaddr_storage = yes ; then
1124                 ol_link_ipv6=yes
1125         elif test $ol_enable_ipv6 = yes &&
1126              test $ol_cv_inet6_addrstrlen = no ; then
1127                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1128         elif test $ol_enable_ipv6 = yes &&
1129              test $ol_cv_struct_sockaddr_storage = no ; then
1130                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1131         fi
1132 fi
1133
1134 if test $ol_enable_local != no ; then
1135         AC_CHECK_HEADERS( sys/un.h )
1136
1137         if test $ol_enable_local = auto ; then
1138                 ol_enable_local=$ac_cv_header_sys_un_h
1139         elif test $ac_cv_header_sys_un_h = no ; then
1140                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1141         fi
1142 fi
1143
1144 dnl ----------------------------------------------------------------
1145 dnl Kerberos
1146 ol_link_kbind=no
1147 ol_link_krb5=no
1148 ol_link_krb4=no
1149
1150 case $ol_with_kerberos in yes | auto | k5 | k5only | k425)
1151
1152         AC_CHECK_HEADERS(krb5.h)
1153
1154         if test $ac_cv_header_krb5_h = yes ; then
1155                 dnl lazy check for Heimdal Kerberos
1156                 AC_CHECK_HEADERS(heim_err.h)
1157                 if test $ac_cv_header_heim_err_h = yes ; then
1158                         krb5_impl=heimdal
1159                 else
1160                         krb5_impl=mit
1161                 fi
1162
1163                 if test $krb5_impl = mit; then
1164                         AC_CHECK_LIB(k5crypto, main,
1165                                 [krb5crypto=k5crypto],
1166                                 [krb5crypto=crypto])
1167
1168                         AC_CHECK_LIB(krb5, main,
1169                                 [have_krb5=yes
1170                                 KRB5_LIBS="-lkrb5 -l$krb5crypto -lcom_err"],
1171                                 [have_krb5=no],
1172                                 [-l$krb5crypto -lcom_err])
1173
1174                 elif test $krb5_impl = heimdal; then
1175                         AC_CHECK_LIB(des, main,
1176                                 [krb5crypto=des],
1177                                 [krb5crypto=crypto])
1178
1179                         AC_CHECK_LIB(krb5, main,
1180                                 [have_krb5=yes
1181                                 KRB5_LIBS="-lkrb5 -l$krb5crypto -lasn1 -lroken -lcom_err"],
1182                                 [have_krb5=no],
1183                                 [-l$krb5crypto -lasn1 -lroken -lcom_err])
1184
1185                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
1186                                 [define if you have HEIMDAL Kerberos])
1187
1188                 else
1189                         have_krb5=no
1190                         AC_MSG_WARN([Unrecognized Kerberos5 Implementation])
1191                 fi
1192
1193                 if test $have_krb5 = yes ; then
1194                         ol_link_krb5=yes
1195
1196                         AC_DEFINE(HAVE_KRB5, 1,
1197                                 [define if you have Kerberos V])
1198
1199                         if test $ol_with_kerberos = k5only ; then
1200                                 ol_with_kerberos=found
1201                         fi
1202
1203                 elif test $ol_with_kerberos != auto ; then
1204                         AC_MSG_ERROR([Required Kerberos 5 support not available])
1205                 fi
1206
1207         fi
1208         ;;
1209 esac
1210
1211 if test $ol_link_krb5 = yes &&
1212    { test $ol_with_kerberos = yes ||
1213      test $ol_with_kerberos = auto ||
1214      test $ol_with_kerberos = k425; }; then
1215
1216         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
1217
1218         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
1219                 if test $krb5_impl = mit; then
1220                         AC_CHECK_LIB(krb4, main, [have_k425=yes
1221                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
1222                                 [-ldes425 -lkrb5 -l$krb5crypto -lcom_err])
1223
1224                 elif test $krb5_impl = heimdal; then
1225                         AC_CHECK_LIB(krb4, main, [have_k425=yes
1226                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
1227                                 [-lkrb5 -l$krb5crypto -lasn1 -lroken -lcom_err])
1228
1229                 else
1230                         have_425=no
1231                         AC_MSG_WARN([Unrecongized Kerberos V Implementation])
1232                 fi
1233
1234                 if test $have_k425 = yes ; then
1235                         ol_with_kerberos=found
1236                         ol_link_krb4=yes
1237
1238                         AC_DEFINE(HAVE_KRB425, 1,
1239                                 [define if you have Kerberos V with IV support])
1240                         AC_DEFINE(HAVE_KRB4, 1,
1241                                 [define if you have Kerberos IV])
1242
1243                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
1244                                 [ol_cv_var_des_debug], [
1245                                 dnl save the flags
1246                                 save_LIBS="$LIBS"
1247                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
1248                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1249 #include <kerberosIV/krb.h>
1250 #include <kerberosIV/des.h>
1251 extern int des_debug;
1252 ]], [[
1253 des_debug = 1;
1254 ]])],[ol_cv_var_des_debug=yes],[ol_cv_var_des_debug=no])
1255                                 dnl restore the LIBS
1256                                 LIBS="$save_LIBS"
1257                         ])
1258
1259                         if test $ol_cv_var_des_debug = yes ; then
1260                                 AC_DEFINE(HAVE_DES_DEBUG,1,
1261                                         [define if you have Kerberos des_debug])
1262                         fi
1263
1264                         LIBS="$save_LIBS"
1265                 fi
1266         fi
1267 fi
1268
1269 if test $ol_link_krb5 = yes ; then
1270         ol_with_kerberos=found
1271 fi
1272
1273 case $ol_with_kerberos in yes | auto | k4 | kth)
1274
1275         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
1276
1277         if test $ac_cv_header_krb_h = yes ; then
1278                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
1279
1280                 if test $have_k4 = yes ; then
1281                         ol_with_kerberos=found
1282                         ol_link_krb4=yes
1283
1284                         AC_DEFINE(HAVE_KRB4, 1,
1285                                 [define if you have Kerberos IV])
1286
1287                         KRB4_LIBS="-lkrb -ldes"
1288
1289                         if test $ac_cv_header_krb_archaeology_h = yes ; then
1290                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
1291                                         [define if you have Kth Kerberos])
1292                         fi
1293                 fi
1294         fi
1295         ;;
1296 esac
1297
1298 if test $ol_link_krb4 = yes && test $ol_enable_kbind != no ; then
1299         ol_link_kbind=yes
1300
1301 elif test $ol_enable_kbind = yes ; then
1302         AC_MSG_ERROR([Kerberos IV detection failed])
1303 fi
1304
1305 if test $ol_link_krb4 = yes || test $ol_link_krb5 = yes ; then
1306         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
1307
1308 elif test $ol_with_kerberos != auto && test $ol_with_kerberos != no ; then
1309         AC_MSG_ERROR([Kerberos detection failed])
1310 fi
1311
1312 dnl ----------------------------------------------------------------
1313 dnl TLS/SSL
1314
1315 ol_link_tls=no
1316 if test $ol_with_tls != no ; then
1317         AC_CHECK_HEADERS(openssl/ssl.h)
1318
1319         if test $ac_cv_header_openssl_ssl_h = yes ; then
1320                 AC_CHECK_LIB(ssl, SSL_library_init,
1321                         [have_openssl=yes
1322                         need_rsaref=no], [have_openssl=no],
1323                         [-lcrypto])
1324
1325                 if test $have_openssl = no ; then
1326                         AC_CHECK_LIB(ssl, ssl3_accept,
1327                                 [have_openssl=yes
1328                                 need_rsaref=yes], [have_openssl=no],
1329                                 [-lcrypto -lRSAglue -lrsaref])
1330                 fi
1331
1332                 if test $have_openssl = yes ; then
1333                         ol_with_tls=found
1334                         ol_link_tls=yes
1335
1336                         AC_DEFINE(HAVE_OPENSSL, 1,
1337                                 [define if you have OpenSSL])
1338
1339                         if test $need_rsaref = yes; then
1340                                 AC_DEFINE(HAVE_RSAREF, 1,
1341                                         [define if OpenSSL needs RSAref])
1342
1343                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1344                         else
1345                                 TLS_LIBS="-lssl -lcrypto"
1346                         fi
1347                 fi
1348                 OL_SSL_COMPAT
1349                 if test $ol_cv_ssl_crl_compat = no ; then
1350                         ol_link_ssl=no
1351                 else
1352                         AC_DEFINE(HAVE_OPENSSL_CRL, 1,
1353                                 [define if you have OpenSSL with CRL checking capability])
1354                 fi
1355         fi
1356
1357 else
1358         AC_MSG_WARN([TLS data protection not supported!])
1359 fi
1360
1361 WITH_TLS=no
1362 if test $ol_link_tls = yes ; then
1363         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1364         WITH_TLS=yes
1365
1366 elif test $ol_with_tls = auto ; then
1367         AC_MSG_WARN([Could not locate TLS/SSL package])
1368         AC_MSG_WARN([TLS data protection not supported!])
1369
1370 elif test $ol_with_tls != no ; then
1371         AC_MSG_ERROR([Could not locate TLS/SSL package])
1372 fi
1373
1374 dnl ----------------------------------------------------------------
1375 dnl LAN Manger password checking requires DES from OpenSSL
1376 if test $ol_enable_lmpasswd != no; then
1377         if test $ol_link_tls != yes ; then
1378                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
1379         fi
1380
1381         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1382 fi
1383
1384 dnl ----------------------------------------------------------------
1385 dnl Threads?
1386 ol_link_threads=no
1387
1388 case $ol_with_threads in auto | yes | nt)
1389
1390         OL_NT_THREADS
1391
1392         if test "$ol_cv_nt_threads" = yes ; then
1393                 ol_link_threads=nt
1394                 ol_with_threads=found
1395                 ol_with_yielding_select=yes
1396
1397                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1398                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1399         fi
1400
1401         if test $ol_with_threads = nt ; then
1402                 AC_MSG_ERROR([could not locate NT Threads])
1403         fi
1404         ;;
1405 esac
1406
1407 case $ol_with_threads in auto | yes | posix)
1408
1409         AC_CHECK_HEADERS(pthread.h)
1410
1411         if test $ac_cv_header_pthread_h = yes ; then
1412                 OL_POSIX_THREAD_VERSION
1413
1414                 if test $ol_cv_pthread_version != 0 ; then
1415                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1416                                 [define to pthreads API spec revision])
1417                 else
1418                         AC_MSG_ERROR([unknown pthread version])
1419                 fi
1420
1421                 # consider threads found
1422                 ol_with_threads=found
1423
1424                 OL_HEADER_LINUX_THREADS
1425                 OL_HEADER_GNU_PTH_PTHREAD_H
1426
1427                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1428                         AC_CHECK_HEADERS(sched.h)
1429                 fi
1430
1431                 dnl Now the hard part, how to link?
1432                 dnl
1433                 dnl currently supported checks:
1434                 dnl
1435                 dnl Check for no flags
1436                 dnl     pthread_create() in $LIBS
1437                 dnl
1438                 dnl Check special pthread (final) flags
1439                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1440                 dnl     pthread_create() with -kthread (FreeBSD)
1441                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1442                 dnl     pthread_create() with -pthreads (?)
1443                 dnl     pthread_create() with -mthreads (AIX)
1444                 dnl     pthread_create() with -thread (?)
1445                 dnl
1446                 dnl Check pthread (final) libraries
1447                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1448                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1449                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1450                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1451                 dnl     pthread_create() in -lpthread (many)
1452                 dnl     pthread_create() in -lc_r (FreeBSD)
1453                 dnl
1454                 dnl Check pthread (draft4) flags (depreciated)
1455                 dnl     pthread_create() with -threads (OSF/1)
1456                 dnl
1457                 dnl Check pthread (draft4) libraries (depreciated)
1458                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1459                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1460                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1461                 dnl     pthread_create() in -lpthreads (many)
1462                 dnl
1463
1464                 dnl pthread_create in $LIBS
1465                 AC_CACHE_CHECK([for pthread_create in default libraries],
1466                         ol_cv_pthread_create,[
1467                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1468                                 [ol_cv_pthread_create=yes],
1469                                 [ol_cv_pthread_create=no],
1470                                 [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1471                                         [ol_cv_pthread_create=yes],
1472                                         [ol_cv_pthread_create=no])])])
1473
1474                 if test $ol_cv_pthread_create != no ; then
1475                         ol_link_threads=posix
1476                         ol_link_pthreads=""
1477                 fi
1478
1479 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1480                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1481                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1482                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1483                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1484                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1485
1486                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1487                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1488                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1489                         [ol_cv_pthread_lpthread_lmach_lexc])
1490 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1491 dnl                     [ol_cv_pthread_lpthread_lexc])
1492
1493                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1494                         [ol_cv_pthread_lib_lpthread_woff])
1495
1496                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1497                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1498
1499                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1500
1501                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1502                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1503                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1504                         [ol_cv_pthread_lpthreads_lmach_lexc])
1505                 OL_PTHREAD_TRY([-lpthreads -lexc],
1506                         [ol_cv_pthread_lpthreads_lexc])
1507
1508                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1509
1510                 if test $ol_link_threads != no ; then
1511                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1512
1513                         dnl save flags
1514                         save_CPPFLAGS="$CPPFLAGS"
1515                         save_LIBS="$LIBS"
1516                         LIBS="$LTHREAD_LIBS $LIBS"
1517
1518                         dnl All POSIX Thread (final) implementations should have
1519                         dnl sched_yield instead of pthread yield.
1520                         dnl check for both, and thr_yield for Solaris
1521                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1522
1523                         if test $ac_cv_func_sched_yield = no &&
1524                            test $ac_cv_func_pthread_yield = no &&
1525                            test $ac_cv_func_thr_yield = no ; then
1526                                 dnl Digital UNIX has sched_yield() in -lrt
1527                                 AC_CHECK_LIB(rt, sched_yield,
1528                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1529                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1530                                                 [Define if you have the sched_yield function.])
1531                                         ac_cv_func_sched_yield=yes],
1532                                         [ac_cv_func_sched_yield=no])
1533                         fi
1534                         if test $ac_cv_func_sched_yield = no &&
1535                            test $ac_cv_func_pthread_yield = no &&
1536                            test "$ac_cv_func_thr_yield" = no ; then
1537                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1538                         fi
1539
1540                         dnl Check functions for compatibility
1541                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1542
1543                         dnl Check for pthread_detach with <pthread.h> inclusion
1544                         dnl as it's symbol may have been mangled.
1545                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1546                                 [ol_cv_func_pthread_detach], [
1547                                 dnl save the flags
1548                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1549 #include <pthread.h>
1550 #ifndef NULL
1551 #define NULL (void*)0
1552 #endif
1553 ]], [[pthread_detach(NULL);]])],[ol_cv_func_pthread_detach=yes],[ol_cv_func_pthread_detach=no])
1554                         ])
1555
1556                         if test $ol_cv_func_pthread_detach = no ; then
1557                                 AC_MSG_ERROR([could not locate pthread_detach()])
1558                         fi
1559
1560                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1561                                 [define if you have pthread_detach function])
1562
1563                         dnl Check for setconcurreny functions
1564                         AC_CHECK_FUNCS( \
1565                                 pthread_setconcurrency \
1566                                 pthread_getconcurrency \
1567                                 thr_setconcurrency \
1568                                 thr_getconcurrency \
1569                         )
1570
1571                         OL_SYS_LINUX_THREADS
1572                         OL_LINUX_THREADS
1573
1574                         if test $ol_cv_linux_threads = error; then
1575                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1576                         fi
1577
1578                         AC_CACHE_CHECK([if pthread_create() works],
1579                                 ol_cv_pthread_create_works,[
1580                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1581                                 [ol_cv_pthread_create_works=yes],
1582                                 [ol_cv_pthread_create_works=no],
1583                                 [dnl assume yes
1584                                 ol_cv_pthread_create_works=yes])])
1585
1586                         if test $ol_cv_pthread_create_works = no ; then
1587                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1588                         fi
1589
1590                         ol_replace_sched_yeild=no
1591                         case "$target" in
1592                         *-*-linux*)
1593                                 ol_replace_sched_yeild=yes
1594                         ;;
1595                         esac
1596
1597                         if test $ol_replace_sched_yeild = yes ; then
1598                                 AC_DEFINE([REPLACE_SCHED_YEILD],1,
1599                                         [define to replace sched_yeild(2)])
1600                         fi
1601
1602                         dnl Check if select causes an yield
1603                         if test $ol_with_yielding_select = auto ; then
1604                                 AC_CACHE_CHECK([if select yields when using pthreads],
1605                                         ol_cv_pthread_select_yields,[
1606                                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1607 #include <sys/types.h>
1608 #include <sys/time.h>
1609 #include <unistd.h>
1610 #include <pthread.h>
1611 #ifndef NULL
1612 #define NULL (void*) 0
1613 #endif
1614
1615 static int fildes[2];
1616
1617 static void *task(p)
1618         void *p;
1619 {
1620         int i;
1621         struct timeval tv;
1622
1623         fd_set rfds;
1624
1625         tv.tv_sec=10;
1626         tv.tv_usec=0;
1627
1628         FD_ZERO(&rfds);
1629         FD_SET(fildes[0], &rfds);
1630
1631         /* we're not interested in any fds */
1632         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1633
1634         if(i < 0) {
1635                 perror("select");
1636                 exit(10);
1637         }
1638
1639         exit(0); /* if we exit here, the select blocked the whole process */
1640 }
1641
1642 int main(argc, argv)
1643         int argc;
1644         char **argv;
1645 {
1646         pthread_t t;
1647
1648         /* create a pipe to select */
1649         if(pipe(&fildes[0])) {
1650                 perror("select");
1651                 exit(1);
1652         }
1653
1654 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1655         (void) pthread_setconcurrency(2);
1656 #else
1657 #ifdef HAVE_THR_SETCONCURRENCY
1658         /* Set Solaris LWP concurrency to 2 */
1659         thr_setconcurrency(2);
1660 #endif
1661 #endif
1662
1663 #if HAVE_PTHREADS < 6
1664         pthread_create(&t, pthread_attr_default, task, NULL);
1665 #else
1666         pthread_create(&t, NULL, task, NULL);
1667 #endif
1668
1669         /* make sure task runs first */
1670 #if HAVE_THR_YIELD
1671         thr_yield();
1672 #elif defined( HAVE_SCHED_YIELD )
1673         sched_yield();
1674 #elif defined( HAVE_PTHREAD_YIELD )
1675         pthread_yield();
1676 #endif
1677
1678         exit(2);
1679 }]])],[ol_cv_pthread_select_yields=no],[ol_cv_pthread_select_yields=yes],[ol_cv_pthread_select_yields=cross])])
1680
1681                                 if test $ol_cv_pthread_select_yields = cross ; then
1682                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1683                                 fi
1684
1685                                 if test $ol_cv_pthread_select_yields = yes ; then
1686                                         ol_with_yielding_select=yes
1687                                 fi
1688                         fi
1689
1690                         dnl restore flags
1691                         CPPFLAGS="$save_CPPFLAGS"
1692                         LIBS="$save_LIBS"
1693                 else
1694                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1695                 fi
1696         fi
1697
1698         if test $ol_with_threads = posix ; then
1699                 AC_MSG_ERROR([could not locate POSIX Threads])
1700         fi
1701         ;;
1702 esac
1703
1704 case $ol_with_threads in auto | yes | mach)
1705
1706         dnl check for Mach CThreads
1707         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1708         if test $ac_cv_header_mach_cthreads_h = yes ; then
1709                 ol_with_threads=found
1710
1711                 dnl check for cthreads support in current $LIBS
1712                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1713
1714                 if test $ol_link_threads = no ; then
1715                         dnl try -all_load
1716                         dnl this test needs work
1717                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1718                                 [ol_cv_cthread_all_load], [
1719                                 dnl save the flags
1720                                 save_LIBS="$LIBS"
1721                                 LIBS="-all_load $LIBS"
1722                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <mach/cthreads.h>]], [[
1723                                         cthread_fork((void *)0, (void *)0);
1724                                         ]])],[ol_cv_cthread_all_load=yes],[ol_cv_cthread_all_load=no])
1725                                 dnl restore the LIBS
1726                                 LIBS="$save_LIBS"
1727                         ])
1728
1729                         if test $ol_cv_cthread_all_load = yes ; then
1730                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1731                                 ol_link_threads=mach
1732                                 ol_with_threads=found
1733                         fi
1734                 fi
1735
1736         elif test $ac_cv_header_cthreads_h = yes ; then
1737                 dnl Hurd variant of Mach Cthreads
1738                 dnl uses <cthreads.h> and -lthreads
1739
1740                 ol_with_threads=found
1741
1742                 dnl save the flags
1743                 save_LIBS="$LIBS"
1744                 LIBS="$LIBS -lthreads"
1745                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1746                 LIBS="$save_LIBS"
1747
1748                 if test $ol_link_threads = yes ; then
1749                         LTHREAD_LIBS="-lthreads"
1750                         ol_link_threads=mach
1751                         ol_with_threads=found
1752                 else
1753                         AC_MSG_ERROR([could not link with Mach CThreads])
1754                 fi
1755
1756         elif test $ol_with_threads = mach ; then
1757                 AC_MSG_ERROR([could not locate Mach CThreads])
1758         fi
1759
1760         if test $ol_link_threads = mach ; then
1761                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1762                         [define if you have Mach Cthreads])
1763         elif test $ol_with_threads = found ; then
1764                 AC_MSG_ERROR([could not link with Mach CThreads])
1765         fi
1766         ;;
1767 esac
1768
1769 case $ol_with_threads in auto | yes | pth)
1770
1771         AC_CHECK_HEADERS(pth.h)
1772
1773         if test $ac_cv_header_pth_h = yes ; then
1774                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1775
1776                 if test $have_pth = yes ; then
1777                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1778                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1779                         ol_link_threads=pth
1780                         ol_with_threads=found
1781
1782                         if test $ol_with_yielding_select = auto ; then
1783                                 ol_with_yielding_select=yes
1784                         fi
1785                 fi
1786         fi
1787         ;;
1788 esac
1789
1790 case $ol_with_threads in auto | yes | lwp)
1791
1792         dnl check for SunOS5 LWP
1793         AC_CHECK_HEADERS(thread.h synch.h)
1794         if test $ac_cv_header_thread_h = yes &&
1795            test $ac_cv_header_synch_h = yes ; then
1796                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1797
1798                 if test $have_thr = yes ; then
1799                         AC_DEFINE(HAVE_THR,1,
1800                                 [if you have Solaris LWP (thr) package])
1801                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1802                         ol_link_threads=thr
1803
1804                         if test $ol_with_yielding_select = auto ; then
1805                                 ol_with_yielding_select=yes
1806                         fi
1807
1808                         dnl Check for setconcurreny functions
1809                         AC_CHECK_FUNCS( \
1810                                 thr_setconcurrency \
1811                                 thr_getconcurrency \
1812                         )
1813                 fi
1814         fi
1815
1816         dnl check for SunOS4 LWP
1817         AC_CHECK_HEADERS(lwp/lwp.h)
1818         if test $ac_cv_header_lwp_lwp_h = yes ; then
1819                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1820
1821                 if test $have_lwp = yes ; then
1822                         AC_DEFINE(HAVE_LWP,1,
1823                                 [if you have SunOS LWP package])
1824                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1825                         ol_link_threads=lwp
1826
1827                         if test $ol_with_yielding_select = auto ; then
1828                                 ol_with_yielding_select=no
1829                         fi
1830                 fi
1831         fi
1832         ;;
1833 esac
1834
1835 if test $ol_with_yielding_select = yes ; then
1836         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1837                 [define if select implicitly yields])
1838 fi
1839
1840 if test $ol_with_threads = manual ; then
1841         dnl User thinks he can manually configure threads.
1842         ol_link_threads=yes
1843
1844         AC_MSG_WARN([thread defines and link options must be set manually])
1845
1846         AC_CHECK_HEADERS(pthread.h sched.h)
1847         AC_CHECK_FUNCS(sched_yield pthread_yield)
1848         OL_HEADER_LINUX_THREADS
1849
1850         AC_CHECK_HEADERS(mach/cthreads.h)
1851         AC_CHECK_HEADERS(lwp/lwp.h)
1852         AC_CHECK_HEADERS(thread.h synch.h)
1853 fi
1854
1855 if test $ol_link_threads != no && test $ol_link_threads != nt ; then
1856         dnl needed to get reentrant/threadsafe versions
1857         dnl
1858         AC_DEFINE(REENTRANT,1)
1859         AC_DEFINE(_REENTRANT,1)
1860         AC_DEFINE(THREAD_SAFE,1)
1861         AC_DEFINE(_THREAD_SAFE,1)
1862         AC_DEFINE(THREADSAFE,1)
1863         AC_DEFINE(_THREADSAFE,1)
1864         AC_DEFINE(_SGI_MP_SOURCE,1)
1865
1866         dnl The errno declaration may dependent upon _REENTRANT.
1867         dnl If it does, we must link with thread support.
1868         AC_CACHE_CHECK([for thread specific errno],
1869                 [ol_cv_errno_thread_specific], [
1870                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[errno = 0;]])],[ol_cv_errno_thread_specific=yes],[ol_cv_errno_thread_specific=no])
1871         ])
1872
1873         dnl The h_errno declaration may dependent upon _REENTRANT.
1874         dnl If it does, we must link with thread support.
1875         AC_CACHE_CHECK([for thread specific h_errno],
1876                 [ol_cv_h_errno_thread_specific], [
1877                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[h_errno = 0;]])],[ol_cv_h_errno_thread_specific=yes],[ol_cv_h_errno_thread_specific=no])
1878         ])
1879
1880         if test $ol_cv_errno_thread_specific != yes ||
1881            test $ol_cv_h_errno_thread_specific != yes ; then
1882                 LIBS="$LTHREAD_LIBS $LIBS"
1883                 LTHREAD_LIBS=""
1884         fi
1885
1886 dnl When in thread environment, use
1887 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1888 dnl                     func_r(...);
1889 dnl             #else
1890 dnl             #       if defined( HAVE_THREADS )
1891 dnl                             /* lock */
1892 dnl             #       endif
1893 dnl                             func(...);
1894 dnl             #       if defined( HAVE_THREADS )
1895 dnl                             /* unlock */
1896 dnl             #       endif
1897 dnl             #endif
1898 dnl
1899 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1900 dnl             _POSIX_REENTRANT_FUNCTIONS
1901 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1902 dnl             _POSIX_THREADSAFE_FUNCTIONS
1903 dnl
1904 dnl             and is currently defined in <ldap_pvt_thread.h>
1905 dnl
1906 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1907 dnl
1908 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1909 dnl LDAP_R_COMPILE is defined.  ie:
1910 dnl             #ifdef LDAP_R_COMPILE
1911 dnl             #       include <ldap_pvt_thread.h>
1912 dnl             #endif
1913 dnl
1914 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1915 dnl specifically for compiling the threadsafe version of
1916 dnl     the ldap library (-lldap_r).
1917 dnl
1918 dnl     dnl check for reentrant/threadsafe functions
1919 dnl     dnl
1920 dnl     dnl note: these should only be used when linking
1921 dnl     dnl             with $LTHREAD_LIBS
1922 dnl     dnl
1923 dnl     save_CPPFLAGS="$CPPFLAGS"
1924 dnl     save_LIBS="$LIBS"
1925 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1926 dnl     AC_CHECK_FUNCS( \
1927 dnl             gmtime_r \
1928 dnl             gethostbyaddr_r gethostbyname_r \
1929 dnl             feof_unlocked unlocked_feof \
1930 dnl             putc_unlocked unlocked_putc \
1931 dnl             flockfile ftrylockfile \
1932 dnl     )
1933 dnl     CPPFLAGS="$save_CPPFLAGS"
1934 dnl     LIBS="$save_LIBS"
1935 fi
1936
1937 if test $ol_link_threads = no ; then
1938         if test $ol_with_threads = yes ; then
1939                 AC_MSG_ERROR([no suitable thread support])
1940         fi
1941
1942         if test $ol_with_threads = auto ; then
1943                 AC_MSG_WARN([no suitable thread support, disabling threads])
1944                 ol_with_threads=no
1945         fi
1946
1947         AC_DEFINE(NO_THREADS,1,
1948                 [define if you have (or want) no threads])
1949         LTHREAD_LIBS=""
1950         BUILD_THREAD=no
1951 else
1952         BUILD_THREAD=yes
1953 fi
1954
1955 if test $ol_link_threads != no ; then
1956         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1,
1957                 [define to 1 if library is thread safe])
1958 fi
1959
1960 dnl ----------------------------------------------------------------
1961 dnl Tests for reentrant functions necessary to build -lldap_r
1962 AC_CHECK_FUNCS(         \
1963         ctime_r                 \
1964         gethostbyname_r gethostbyaddr_r \
1965 )
1966
1967 if test "$ac_cv_func_ctime_r" = no ; then
1968         ol_cv_func_ctime_r_nargs=0
1969 else
1970         OL_FUNC_CTIME_R_NARGS
1971 dnl     OL_FUNC_CTIME_R_TYPE
1972 fi
1973
1974 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1975         OL_FUNC_GETHOSTBYNAME_R_NARGS
1976 else
1977         ol_cv_func_gethostbyname_r_nargs=0
1978 fi
1979
1980 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1981         OL_FUNC_GETHOSTBYADDR_R_NARGS
1982 else
1983         ol_cv_func_gethostbyaddr_r_nargs=0
1984 fi
1985
1986 dnl ----------------------------------------------------------------
1987 ol_link_ldbm=no
1988
1989 case $ol_enable_ldbm_api in auto | berkeley | bcompat)
1990
1991         if test $ol_enable_ldbm_api = bcompat; then \
1992                 OL_BERKELEY_COMPAT_DB
1993         else
1994                 OL_BERKELEY_DB
1995         fi
1996
1997         if test $ol_cv_berkeley_db != no ; then
1998                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1999                         [define this if Berkeley DB is available])
2000
2001                 ol_link_ldbm=berkeley
2002                 ol_enable_ldbm_api=berkeley
2003
2004                 if test $ol_enable_ldbm_type = hash ; then
2005                         AC_DEFINE(LDBM_USE_DBHASH,1,
2006                                 [define this to use DBHASH w/ LDBM backend])
2007                 else
2008                         AC_DEFINE(LDBM_USE_DBBTREE,1,
2009                                 [define this to use DBBTREE w/ LDBM backend])
2010                 fi
2011
2012                 dnl $ol_cv_lib_db should be yes or -ldb
2013                 dnl (it could be no, but that would be an error
2014                 if test $ol_cv_lib_db != yes ; then
2015                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
2016                 fi
2017         fi
2018         ;;
2019 esac
2020
2021 if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
2022         if test $ol_link_ldbm != berkeley ; then
2023                 AC_MSG_ERROR(BDB/HDB: BerkeleyDB not available)
2024         else
2025                 OL_BDB_COMPAT
2026
2027                 if test $ol_cv_bdb_compat != yes ; then
2028                         AC_MSG_ERROR([BDB/HDB: BerkeleyDB version incompatible])
2029                 fi
2030         fi
2031 fi
2032
2033 if test $ol_link_ldbm = no && test $ol_enable_ldbm_type = btree ; then
2034         AC_MSG_WARN([Could not find LDBM with BTREE support])
2035         ol_enable_ldbm_api=none
2036 fi
2037
2038 if test $ol_enable_ldbm_api = auto || test $ol_enable_ldbm_api = mdbm ; then
2039         OL_MDBM
2040
2041         if test $ol_cv_mdbm = yes ; then
2042                 ol_link_ldbm=mdbm
2043                 ol_enable_ldbm_api=mdbm
2044                 if test $ol_cv_lib_mdbm != yes ; then
2045                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
2046                 fi
2047         fi
2048 fi
2049
2050 if test $ol_enable_ldbm_api = auto || test $ol_enable_ldbm_api = gdbm ; then
2051         OL_GDBM
2052
2053         if test $ol_cv_gdbm = yes ; then
2054                 ol_link_ldbm=gdbm
2055                 ol_enable_ldbm_api=gdbm
2056
2057                 if test $ol_cv_lib_gdbm != yes ; then
2058                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
2059                 fi
2060         fi
2061 fi
2062
2063 if test $ol_enable_ldbm_api = ndbm ; then
2064         OL_NDBM
2065
2066         if test $ol_cv_ndbm = yes ; then
2067                 ol_link_ldbm=ndbm
2068                 ol_enable_ldbm_api=ndbm
2069
2070                 if test $ol_cv_lib_ndbm != yes ; then
2071                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
2072                 fi
2073         fi
2074 fi
2075
2076 if test $ol_link_ldbm = no && test $ol_enable_ldbm != no ; then
2077         AC_MSG_ERROR([could not find suitable LDBM backend])
2078 fi
2079
2080 if test $ol_enable_bdb = yes ||
2081    test $ol_enable_hdb = yes ||
2082    test $ol_enable_ldbm = yes ; then
2083         SLAPD_LIBS="$SLAPD_LIBS \$(LDBM_LIBS)"
2084 fi
2085
2086 dnl ----------------------------------------------------------------
2087
2088 if test $ol_enable_dynamic = yes && test $enable_shared = yes ; then
2089         BUILD_LIBS_DYNAMIC=shared
2090         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
2091         LTSTATIC=""
2092 else
2093         BUILD_LIBS_DYNAMIC=static
2094         LTSTATIC="-static"
2095 fi
2096 AC_SUBST(LTSTATIC)dnl
2097
2098 dnl ----------------------------------------------------------------
2099 if test $ol_enable_wrappers != no ; then
2100         AC_CHECK_HEADERS(tcpd.h,[
2101                 AC_MSG_CHECKING([for TCP wrappers library])
2102                 save_LIBS="$LIBS"
2103                 LIBS="$LIBS -lwrap"
2104                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2105 #include <tcpd.h>
2106 int allow_severity = 0;
2107 int deny_severity  = 0;
2108
2109 struct request_info *req;
2110                 ]], [[
2111 hosts_access(req)
2112                 ]])],[AC_MSG_RESULT([-lwrap])
2113                 have_wrappers=yes
2114                 LIBS="$save_LIBS"],[
2115                 dnl try with -lnsl
2116                 LIBS="$LIBS -lnsl"
2117                 AC_TRY_LINK([
2118 #include <tcpd.h>
2119 int allow_severity = 0;
2120 int deny_severity  = 0;
2121
2122 struct request_info *req;
2123                 ],[
2124 hosts_access(req)
2125                 ],[AC_MSG_RESULT([-lwrap -lnsl])
2126                 have_wrappers=yes
2127                 LIBS="$save_LIBS -lnsl"],[
2128                 AC_MSG_RESULT(no)
2129                 have_wrappers=no
2130                 LIBS=$save_LIBS])])],[have_wrappers=no])
2131
2132         if test $have_wrappers = yes ; then
2133                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
2134                 WRAP_LIBS="-lwrap"
2135         elif test $ol_enable_wrappers = yes ; then
2136                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options or disable])
2137         else
2138                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
2139                 WRAP_LIBS=""
2140         fi
2141 fi
2142
2143 dnl ----------------------------------------------------------------
2144 if test $ol_enable_syslog != no ; then
2145         AC_CHECK_FUNC(openlog)
2146         if test $ac_cv_func_openlog = no && test $ol_enable_syslog = yes; then
2147                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
2148         fi
2149         ol_enable_syslog=$ac_cv_func_openlog
2150 fi
2151
2152 dnl ----------------------------------------------------------------
2153 dnl SQL
2154 ol_link_sql=no
2155 if test $ol_enable_sql != no ; then
2156         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
2157                 AC_MSG_ERROR([could not locate SQL headers])
2158         ])
2159
2160         sql_LIBS="$LIBS"
2161         LIBS="$LTHREAD_LIBS"
2162
2163         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
2164         if test $have_iodbc = yes ; then
2165                 ol_link_sql="-liodbc"
2166         else
2167                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
2168                 if test $have_odbc = yes ; then
2169                         ol_link_sql="-lodbc"
2170                 fi
2171         fi
2172
2173         LIBS="$sql_LIBS"
2174
2175         if test $ol_link_sql != no ; then
2176                 SLAPD_SQL_LIBS="$ol_link_sql"
2177
2178         elif test $ol_enable_sql != auto ; then
2179                 AC_MSG_ERROR([could not locate suitable ODBC library])
2180         fi
2181 fi
2182
2183 dnl ----------------------------------------------------------------
2184 dnl International Components for Unicode
2185 OL_ICU
2186 if test "$ol_icu" = no ; then
2187         AC_MSG_WARN([ICU not available])
2188 else
2189         ICU_LIBS="$ol_icu"
2190 fi
2191 dnl ----------------------------------------------------------------
2192 dnl
2193 dnl Check for Cyrus SASL
2194 dnl
2195 WITH_SASL=no
2196 ol_link_sasl=no
2197 ol_link_spasswd=no
2198 if test $ol_with_cyrus_sasl != no ; then
2199         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
2200
2201         if test $ac_cv_header_sasl_sasl_h = yes ||
2202            test $ac_cv_header_sasl_h = yes; then
2203                 AC_CHECK_LIB(sasl2, sasl_client_init,
2204                         [ol_link_sasl="-lsasl2"],
2205                         [AC_CHECK_LIB(sasl, sasl_client_init,
2206                                 [ol_link_sasl="-lsasl"])])
2207         fi
2208
2209         if test $ol_link_sasl = no ; then
2210                 if test $ol_with_cyrus_sasl != auto ; then
2211                         AC_MSG_ERROR([Could not locate Cyrus SASL])
2212                 else
2213                         AC_MSG_WARN([Could not locate Cyrus SASL])
2214                         AC_MSG_WARN([SASL authentication not supported!])
2215                         if test $ol_link_tls = no ; then
2216                                 AC_MSG_WARN([Strong authentication not supported!])
2217                         fi
2218                 fi
2219         else
2220                 OL_SASL_COMPAT
2221                 if test $ol_cv_sasl_compat = no ; then
2222                         ol_link_sasl=no
2223                         AC_MSG_ERROR([Cyrus SASL library located but is incompatible])
2224                 fi
2225
2226                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
2227                 SASL_LIBS="$ol_link_sasl"
2228                 if test $ol_enable_spasswd != no ; then
2229                         ol_link_spasswd=yes
2230                 fi
2231
2232                 ac_save_LIBS="$LIBS"
2233                 LIBS="$LIBS $ol_link_sasl"
2234                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
2235                         [define if your SASL library has sasl_version()])])
2236                 LIBS="$ac_save_LIBS"
2237
2238                 WITH_SASL=yes
2239         fi
2240
2241 else
2242         AC_MSG_WARN([SASL authentication not supported!])
2243         if test $ol_link_tls = no ; then
2244                 AC_MSG_WARN([Strong authentication not supported!])
2245         fi
2246 fi
2247
2248 dnl ----------------------------------------------------------------
2249 dnl Check for entropy sources
2250 if test $cross_compiling != yes && test "$ac_cv_mingw32" != yes ; then
2251         dev=no
2252         if test -r /dev/urandom ; then
2253                 dev="/dev/urandom";
2254         elif test -r /idev/urandom ; then
2255                 dev="/idev/urandom";
2256         elif test -r /dev/srandom ; then
2257                 dev="/dev/srandom";
2258         elif test -r /dev/random ; then
2259                 dev="/dev/random";
2260         elif test -r /idev/random ; then
2261                 dev="/idev/random";
2262         fi
2263
2264         if test $dev != no ; then
2265                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2266         fi
2267 fi
2268
2269 dnl ----------------------------------------------------------------
2270 dnl
2271 dnl Check for fetch URL support
2272 dnl             should be extended to support other fetch URL APIs
2273 dnl
2274 ol_link_fetch=no
2275 if test $ol_with_fetch != no ; then
2276         OL_LIB_FETCH
2277
2278         if test $ol_cv_lib_fetch != no ; then
2279                 LUTIL_LIBS="$LUTIL_LIBS $ol_link_fetch"
2280                 ol_link_fetch=freebsd
2281
2282         elif test $ol_with_fetch != auto ; then
2283                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2284         fi
2285 fi
2286
2287 dnl ----------------------------------------------------------------
2288 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2289 if test $ol_enable_crypt != no ; then
2290         save_LIBS="$LIBS"
2291         LIBS="$TLS_LIBS $LIBS"
2292
2293         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2294                 LIBS="$save_LIBS"
2295                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2296                         have_crypt=yes], [have_crypt=no])])
2297
2298         LIBS="$save_LIBS"
2299
2300         if test $have_crypt = yes ; then
2301                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2302         else
2303                 AC_MSG_WARN([could not find crypt])
2304                 if test $ol_enable_crypt = yes ; then
2305                         AC_MSG_ERROR([could not find crypt, select appropriate options or disable])
2306                 fi
2307
2308                 AC_MSG_WARN([disabling crypt support])
2309                 ol_enable_crypt=no
2310         fi
2311 fi
2312
2313 dnl ----------------------------------------------------------------
2314 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2315 if test $ol_enable_proctitle != no ; then
2316         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2317                 AC_CHECK_LIB(util, setproctitle,
2318                         [have_setproctitle=yes
2319                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2320                         [have_setproctitle=no
2321                         AC_LIBOBJ(setproctitle)
2322                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2323
2324         if test $have_setproctitle = yes ; then
2325                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2326                         [define if setproctitle(3) is available])
2327         fi
2328 fi
2329
2330 dnl ----------------------------------------------------------------
2331 dnl Check for SLPv2 Compliant API Library
2332 if test $ol_enable_slp != no ; then
2333         AC_CHECK_HEADERS( slp.h )
2334
2335         if test $ac_cv_header_slp_h = yes ; then
2336                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2337                 if test $have_slp = yes ; then
2338                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2339                         SLAPD_SLP_LIBS=-lslp
2340                 fi
2341
2342         elif test $ol_enable_slp = yes ; then
2343                 AC_MSG_ERROR([SLP not found])
2344         fi
2345 fi
2346
2347 dnl ----------------------------------------------------------------
2348 dnl Check for multiple precision support
2349 if test "$ol_with_multiple_precision" != "no" ; then
2350         ol_have_bignum=no
2351         ol_have_gmp=no
2352
2353         AC_CHECK_HEADERS(openssl/bn.h bn.h)
2354         AC_CHECK_HEADERS(openssl/crypto.h crypto.h)
2355         AC_CHECK_HEADERS( gmp.h )
2356
2357         if test "$ol_with_tls" = "found" ; then
2358                 ol_have_bn_h=no
2359                 ol_have_crypto_h=no
2360
2361                 if test "$ac_cv_header_openssl_bn_h" = "yes" ||
2362                    test "$ac_cv_header_bn_h" = "yes" ; then
2363                         ol_have_bn_h=yes
2364                 fi
2365
2366                 if test "$ac_cv_header_openssl_crypto_h" = "yes" ||
2367                    test "$ac_cv_header_crypto_h" = "yes" ; then
2368                         ol_have_crypto_h=yes
2369                 fi
2370
2371                 if test "$ol_have_bn_h" = "yes" &&
2372                    test "$ol_have_crypto_h" = "yes" ; then
2373                         ol_have_bignum=yes
2374                 fi
2375         fi
2376
2377         if test $ac_cv_header_gmp_h = yes ; then
2378                 AC_CHECK_LIB(gmp, __gmpz_add_ui, [have_gmp=yes], [have_gmp=no])
2379                 if test $have_gmp = yes ; then
2380                         ol_have_gmp=yes
2381                 fi
2382         fi
2383
2384         AC_MSG_CHECKING([for multiple precision support])
2385
2386         ol_mp_support="none"
2387         case "$ol_with_multiple_precision" in
2388         auto)
2389                 dnl preferred sequence:
2390                 dnl - OpenSSL's BIGNUM (if libssl is already linked)
2391                 dnl - GNU's MP
2392                 dnl - unsigned long
2393                 if test "$ol_have_bignum" = "yes" ; then
2394                         ol_mp_support="bignum"
2395                 else
2396                         if test "$ol_have_gmp" = "yes" ; then
2397                                 ol_mp_support="gmp"
2398                         fi
2399                 fi
2400                 ;;
2401         bignum)
2402                 if test "$ol_have_bignum" != "yes" ; then
2403                         AC_MSG_ERROR([OpenSSL's BIGNUM not available])
2404                 fi
2405                 ol_mp_support="bignum"
2406                 ;;
2407         gmp)
2408                 if test "$ol_have_gmp" != "yes" ; then
2409                         AC_MSG_ERROR([GMP not available])
2410                 fi
2411                 ol_mp_support="gmp"
2412                 ;;
2413         yes)
2414                 if test "$ol_have_bignum" = "yes" ; then
2415                         ol_mp_support="bignum"
2416                 elif test "$ol_have_gmp" = "yes" ; then
2417                         ol_mp_support="gmp"
2418                 else
2419                         AC_MSG_ERROR([not available])
2420                 fi
2421                 ;;
2422         esac
2423
2424         case "$ol_mp_support" in
2425         bignum)
2426                 AC_DEFINE(HAVE_BIGNUM, 1,
2427                         [define if you have OpenSSL's BIGNUM])
2428                 ;;
2429         gmp)
2430                 AC_DEFINE(HAVE_GMP, 1, [define if you have -lgmp])
2431                 SLAPD_GMP_LIBS=-lgmp
2432                 ;;
2433         none)
2434                 ;;
2435         esac
2436
2437         AC_MSG_RESULT($ol_mp_support)
2438 fi
2439
2440 dnl ----------------------------------------------------------------
2441 dnl Checks for typedefs, structures, and compiler characteristics.
2442
2443 AC_CHECK_TYPE(mode_t, int)
2444 AC_CHECK_TYPE(off_t, long)
2445 AC_CHECK_TYPE(pid_t, int)
2446 AC_CHECK_TYPE(ssize_t, [signed int])
2447 AC_CHECK_TYPE(caddr_t,  [char *])
2448 AC_CHECK_TYPE(size_t, unsigned)
2449
2450 AC_CHECK_TYPES([long long])
2451 AC_CHECK_TYPES([ptrdiff_t])
2452
2453 AC_CHECK_TYPE([socklen_t],,
2454         [AC_DEFINE_UNQUOTED([socklen_t], [int],
2455                 [Define to `int' if <sys/socket.h> does not define.])],
2456         [$ac_includes_default
2457 #ifdef HAVE_SYS_SOCKET_H
2458 #include <sys/socket.h>
2459 #endif
2460         ])
2461
2462 AC_TYPE_SIGNAL
2463
2464 AC_CHECK_TYPE([sig_atomic_t],,
2465         [AC_DEFINE_UNQUOTED([sig_atomic_t], [int],
2466                 [Define to `int' if <signal.h> does not define.])],
2467         [$ac_includes_default
2468 #include <signal.h>
2469         ])
2470
2471 AC_TYPE_UID_T
2472
2473 AC_HEADER_TIME
2474 AC_STRUCT_TM
2475 AC_CHECK_MEMBERS([struct stat.st_blksize])
2476 AC_CHECK_MEMBERS([struct passwd.pw_gecos],,,[$ac_includes_default
2477 #include <pwd.h>])
2478 AC_CHECK_MEMBERS([struct passwd.pw_passwd],,,[$ac_includes_default
2479 #include <pwd.h>])
2480
2481 OL_C_UPPER_LOWER
2482 AC_C_CONST
2483 OL_C_VOLATILE
2484
2485 if test $cross_compiling = yes ; then
2486         AC_MSG_WARN([Crossing compiling... all bets are off!])
2487         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2488 else
2489         AC_C_BIGENDIAN
2490 fi
2491
2492 AC_CHECK_SIZEOF(short)
2493 AC_CHECK_SIZEOF(int)
2494 AC_CHECK_SIZEOF(long)
2495 AC_CHECK_SIZEOF(wchar_t)
2496
2497 if test "$ac_cv_sizeof_int" -lt 4 ; then
2498         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2499
2500         AC_DEFINE(LBER_INT_T,long,[define to 32-bit or greater integer type])
2501 else
2502         AC_DEFINE(LBER_INT_T,int,[define to 32-bit or greater integer type])
2503 fi
2504
2505 AC_DEFINE(LBER_LEN_T,long,[define to large integer type])
2506 AC_DEFINE(LBER_SOCKET_T,int,[define to socket descriptor type])
2507 AC_DEFINE(LBER_TAG_T,long,[define to large integer type])
2508
2509 dnl ----------------------------------------------------------------
2510 dnl Checks for library functions.
2511 AC_FUNC_MEMCMP
2512
2513 if test $ac_cv_func_memcmp_working = no ; then
2514         AC_DEFINE(NEED_MEMCMP_REPLACEMENT,1,
2515                 [define if memcmp is not 8-bit clean or is otherwise broken])
2516 fi
2517
2518 AC_FUNC_STRFTIME
2519
2520 OL_FUNC_INET_ATON
2521
2522 dnl Check for NT specific routines
2523 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2524
2525 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2526         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2527 ])
2528
2529 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2530         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2531 ])
2532
2533 AC_FUNC_VPRINTF
2534
2535 if test $ac_cv_func_vprintf = yes ; then
2536         dnl check for vsnprintf
2537         AC_CHECK_FUNCS(snprintf vsnprintf)
2538 fi
2539
2540 AC_CHECK_FUNCS(         \
2541         bcopy                   \
2542         closesocket             \
2543         chroot                  \
2544         endgrent                \
2545         endpwent                \
2546         fcntl                   \
2547         flock                   \
2548         fstat                   \
2549         getdtablesize   \
2550         getgrgid                \
2551         gethostname             \
2552         getpass                 \
2553         getpassphrase   \
2554         getpwuid                \
2555         getpwnam                \
2556         getspnam                \
2557         gettimeofday    \
2558         initgroups              \
2559         inet_ntoa_b             \
2560         lockf                   \
2561         memcpy                  \
2562         memmove                 \
2563         memrchr                 \
2564         mkstemp                 \
2565         mktemp                  \
2566         pipe                    \
2567         read                    \
2568         recv                    \
2569         recvfrom                \
2570         setpwfile               \
2571         setgid                  \
2572         setegid                 \
2573         setsid                  \
2574         setuid                  \
2575         seteuid                 \
2576         signal                  \
2577         strdup                  \
2578         strpbrk                 \
2579         strrchr                 \
2580         strsep                  \
2581         strstr                  \
2582         strtol                  \
2583         strtoul                 \
2584         strtoq                  \
2585         strtouq                 \
2586         strtoll                 \
2587         strspn                  \
2588         sysconf                 \
2589         usleep                  \
2590         waitpid                 \
2591         wait4                   \
2592         write                   \
2593         send                    \
2594         sendmsg                 \
2595         sendto                  \
2596 )
2597
2598 dnl We actually may need to replace more than this.
2599 AC_REPLACE_FUNCS(getopt getpeereid)
2600
2601 if test "$ac_cv_func_getopt" != yes; then
2602         LIBSRCS="$LIBSRCS getopt.c"
2603 fi
2604
2605 if test "$ac_cv_func_getpeereid" != yes; then
2606         AC_CHECK_FUNCS( getpeerucred )
2607         if test "$ac_cv_func_getpeerucred" != yes ; then
2608                 AC_CHECK_MEMBERS([struct msghdr.msg_accrightslen],,,
2609                         [$ac_includes_default
2610 #ifdef HAVE_SYS_SOCKET_H
2611 #include <sys/socket.h>
2612 #endif])
2613                 if test "$ac_cv_member_struct_msghdr_msg_accrightslen" != yes; then
2614                         AC_CHECK_MEMBERS([struct msghdr.msg_control],,,
2615                                 [$ac_includes_default
2616 #ifdef HAVE_SYS_SOCKET_H
2617 #include <sys/socket.h>
2618 #endif])
2619                 fi
2620         fi
2621         LIBSRCS="$LIBSRCS getpeereid.c"
2622 fi
2623
2624 if test "$ac_cv_func_snprintf" != yes ||
2625    test "$ac_cv_func_vsnprintf" != yes; then
2626         if test "$ac_cv_func_snprintf" != yes; then
2627                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2628         fi
2629         if test "$ac_cv_func_vsnprintf" != yes; then
2630                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2631         fi
2632 fi
2633
2634 dnl ----------------------------------------------------------------
2635 dnl Sort out defines
2636
2637 if test "$ol_enable_slapi" != no ; then
2638         dnl This check is done also if --enable-modules is used;
2639         dnl it is duplicated here, 'cause it'd be cached anyway
2640         AC_CHECK_HEADERS(ltdl.h)
2641
2642         if test $ac_cv_header_ltdl_h != yes ; then
2643                 AC_MSG_ERROR([could not locate <ltdl.h>])
2644         fi
2645         AC_CHECK_LIB(ltdl, lt_dlinit, [
2646                 SLAPI_LIBS=-lltdl
2647                 LIBSLAPI=libslapi.a
2648                 LIBSLAPITOOLS=../libslapi.a
2649                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
2650         ],[AC_MSG_ERROR([could not locate libtool -lltdl])])
2651
2652         AC_DEFINE(LDAP_SLAPI,1, [define this to add SLAPI code])
2653 fi
2654
2655 if test "$ol_enable_debug" != no ; then
2656         if test "$ol_enable_debug" = traditional; then
2657                 AC_DEFINE(OLD_DEBUG,1,
2658                         [define to use the original debug style])
2659         fi
2660         AC_DEFINE(LDAP_DEBUG,1,
2661                 [define this to add debugging code])
2662 fi
2663 if test "$ol_enable_syslog" = yes ; then
2664         AC_DEFINE(LDAP_SYSLOG,1,
2665                 [define this to add syslog code])
2666 fi
2667 if test "$ol_link_kbind" != no ; then
2668         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION,
2669                 [define to LDAP VENDOR VERSION])
2670 fi
2671 if test "$ol_enable_proctitle" != no ; then
2672         AC_DEFINE(LDAP_PROCTITLE,1,
2673                 [define this for LDAP process title support])
2674 fi
2675 if test "$ol_enable_referrals" != no ; then
2676         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION,
2677                 [define to LDAP VENDOR VERSION])
2678 fi
2679 if test "$ol_enable_local" != no; then
2680         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2681 fi
2682 if test "$ol_link_ipv6" != no; then
2683         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2684 fi
2685 if test "$ol_enable_cleartext" != no ; then
2686         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2687 fi
2688 if test "$ol_enable_crypt" != no ; then
2689         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2690 fi
2691 if test "$ol_link_spasswd" != no ; then
2692         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2693 fi
2694 if test "$ol_enable_multimaster" != no ; then
2695         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2696 fi
2697 if test "$ol_enable_rlookups" != no ; then
2698         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2699 fi
2700 if test "$ol_enable_aci" != no ; then
2701         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2702         WITH_ACI_ENABLED=yes
2703 else
2704         WITH_ACI_ENABLED=no
2705 fi
2706
2707 if test "$ol_link_modules" != no ; then
2708         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2709         BUILD_SLAPD=yes
2710         SLAPD_MODULES_LDFLAGS="-dlopen self"
2711 fi
2712
2713 AC_DEFINE(SLAPD_MOD_STATIC,1,[statically linked module])
2714 AC_DEFINE(SLAPD_MOD_DYNAMIC,2,[dynamically linked module])
2715
2716 if test "$ol_enable_bdb" != no ; then
2717         BUILD_SLAPD=yes
2718         BUILD_BDB=$ol_enable_bdb
2719         if test "$ol_enable_bdb" = mod ; then
2720                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2721                 MFLAG=SLAPD_MOD_DYNAMIC
2722         else
2723                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2724                 MFLAG=SLAPD_MOD_STATIC
2725         fi
2726         AC_DEFINE_UNQUOTED(SLAPD_BDB,$MFLAG,[define to support BDB backend])
2727 fi
2728
2729 if test "$ol_enable_dnssrv" != no ; then
2730         BUILD_SLAPD=yes
2731         BUILD_DNSSRV=$ol_enable_dnssrv
2732         if test "$ol_enable_dnssrv" = mod ; then
2733                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2734                 MFLAG=SLAPD_MOD_DYNAMIC
2735         else
2736                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2737                 MFLAG=SLAPD_MOD_STATIC
2738         fi
2739         AC_DEFINE_UNQUOTED(SLAPD_DNSSRV,$MFLAG,[define to support DNS SRV backend])
2740 fi
2741
2742 if test "$ol_enable_hdb" != no ; then
2743         BUILD_SLAPD=yes
2744         BUILD_HDB=$ol_enable_hdb
2745         if test "$ol_enable_hdb" = mod ; then
2746                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-hdb"
2747                 MFLAG=SLAPD_MOD_DYNAMIC
2748         else
2749                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-hdb"
2750                 MFLAG=SLAPD_MOD_STATIC
2751         fi
2752         AC_DEFINE_UNQUOTED(SLAPD_HDB,$MFLAG,[define to support HDB backend])
2753 fi
2754
2755 if test "$ol_enable_ldap" != no ; then
2756         BUILD_SLAPD=yes
2757         BUILD_LDAP=$ol_enable_ldap
2758         if test "$ol_enable_ldap" = mod ; then
2759                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2760                 MFLAG=SLAPD_MOD_DYNAMIC
2761         else
2762                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2763                 MFLAG=SLAPD_MOD_STATIC
2764         fi
2765         AC_DEFINE_UNQUOTED(SLAPD_LDAP,$MFLAG,[define to support LDAP backend])
2766 fi
2767
2768 if test "$ol_link_ldbm" != no && test $ol_enable_ldbm != no; then
2769         BUILD_SLAPD=yes
2770         BUILD_LDBM=$ol_enable_ldbm
2771         if test "$ol_enable_ldbm" = mod ; then
2772                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldbm"
2773                 MFLAG=SLAPD_MOD_DYNAMIC
2774         else
2775                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldbm"
2776                 MFLAG=SLAPD_MOD_STATIC
2777         fi
2778         AC_DEFINE_UNQUOTED(SLAPD_LDBM,$MFLAG,[define to support LDBM backend])
2779 fi
2780
2781 if test "$ol_enable_meta" != no ; then
2782         BUILD_SLAPD=yes
2783         BUILD_META=$ol_enable_meta
2784         BUILD_REWRITE=yes
2785         if test "$ol_enable_meta" = mod ; then
2786                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2787                 MFLAG=SLAPD_MOD_DYNAMIC
2788         else
2789                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2790                 MFLAG=SLAPD_MOD_STATIC
2791         fi
2792         AC_DEFINE_UNQUOTED(SLAPD_META,$MFLAG,[define to support LDAP Metadirectory backend])
2793 fi
2794
2795 if test "$ol_enable_monitor" != no ; then
2796         BUILD_SLAPD=yes
2797         BUILD_MONITOR=$ol_enable_monitor
2798         if test "$ol_enable_monitor" = mod ; then
2799                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2800                 MFLAG=SLAPD_MOD_DYNAMIC
2801         else
2802                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2803                 MFLAG=SLAPD_MOD_STATIC
2804         fi
2805         AC_DEFINE_UNQUOTED(SLAPD_MONITOR,$MFLAG,[define to support cn=Monitor backend])
2806 fi
2807
2808 if test "$ol_enable_null" != no ; then
2809         BUILD_SLAPD=yes
2810         BUILD_NULL=$ol_enable_null
2811         if test "$ol_enable_null" = mod ; then
2812                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2813                 MFLAG=SLAPD_MOD_DYNAMIC
2814         else
2815                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2816                 MFLAG=SLAPD_MOD_STATIC
2817         fi
2818         AC_DEFINE_UNQUOTED(SLAPD_NULL,$MFLAG,[define to support NULL backend])
2819 fi
2820
2821 if test "$ol_enable_passwd" != no ; then
2822         BUILD_SLAPD=yes
2823         BUILD_PASSWD=$ol_enable_passwd
2824         if test "$ol_enable_passwd" = mod ; then
2825                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2826                 MFLAG=SLAPD_MOD_DYNAMIC
2827         else
2828                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2829                 MFLAG=SLAPD_MOD_STATIC
2830         fi
2831         AC_DEFINE_UNQUOTED(SLAPD_PASSWD,$MFLAG,[define to support PASSWD backend])
2832 fi
2833
2834 if test "$ol_link_perl" != no ; then
2835         BUILD_SLAPD=yes
2836         BUILD_PERL=$ol_enable_perl
2837         if test "$ol_enable_perl" = mod ; then
2838                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2839                 MFLAG=SLAPD_MOD_DYNAMIC
2840         else
2841                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2842                 MFLAG=SLAPD_MOD_STATIC
2843         fi
2844         AC_DEFINE_UNQUOTED(SLAPD_PERL,$MFLAG,[define to support PERL backend])
2845 fi
2846
2847 if test "$ol_enable_relay" != no ; then
2848         BUILD_SLAPD=yes
2849         BUILD_RELAY=$ol_enable_relay
2850         if test "$ol_enable_relay" = mod ; then
2851                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-relay"
2852                 MFLAG=SLAPD_MOD_DYNAMIC
2853         else
2854                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-relay"
2855                 MFLAG=SLAPD_MOD_STATIC
2856         fi
2857         AC_DEFINE_UNQUOTED(SLAPD_RELAY,$MFLAG,[define to support relay backend])
2858 fi
2859
2860 if test "$ol_enable_shell" != no ; then
2861         if test "$ol_link_threads" != no ; then
2862                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2863         fi
2864         BUILD_SLAPD=yes
2865         BUILD_SHELL=$ol_enable_shell
2866         if test "$ol_enable_shell" = mod ; then
2867                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2868                 MFLAG=SLAPD_MOD_DYNAMIC
2869         else
2870                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2871                 MFLAG=SLAPD_MOD_STATIC
2872         fi
2873         AC_DEFINE_UNQUOTED(SLAPD_SHELL,$MFLAG,[define to support SHELL backend])
2874 fi
2875
2876 if test "$ol_link_sql" != no ; then
2877         BUILD_SLAPD=yes
2878         BUILD_SQL=$ol_enable_sql
2879         if test "$ol_enable_sql" = mod; then
2880                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2881                 MFLAG=SLAPD_MOD_DYNAMIC
2882         else
2883                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2884                 MFLAG=SLAPD_MOD_STATIC
2885         fi
2886         AC_DEFINE_UNQUOTED(SLAPD_SQL,$MFLAG,[define to support SQL backend])
2887 fi
2888
2889 if test "$ol_enable_accesslog" != no ; then
2890         BUILD_ACCESSLOG=$ol_enable_accesslog
2891         if test "$ol_enable_accesslog" = mod ; then
2892                 MFLAG=SLAPD_MOD_DYNAMIC
2893                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS accesslog.la"
2894         else
2895                 MFLAG=SLAPD_MOD_STATIC
2896                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS accesslog.o"
2897         fi
2898         AC_DEFINE_UNQUOTED(SLAPD_OVER_ACCESSLOG,$MFLAG,[define for In-Directory Access Logging overlay])
2899 fi
2900
2901 if test "$ol_enable_denyop" != no ; then
2902         BUILD_DENYOP=$ol_enable_denyop
2903         if test "$ol_enable_denyop" = mod ; then
2904                 MFLAG=SLAPD_MOD_DYNAMIC
2905                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS denyop.la"
2906         else
2907                 MFLAG=SLAPD_MOD_STATIC
2908                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS denyop.o"
2909         fi
2910         AC_DEFINE_UNQUOTED(SLAPD_OVER_DENYOP,$MFLAG,[define for Dynamic Group overlay])
2911 fi
2912
2913 if test "$ol_enable_dyngroup" != no ; then
2914         BUILD_DYNGROUP=$ol_enable_dyngroup
2915         if test "$ol_enable_dyngroup" = mod ; then
2916                 MFLAG=SLAPD_MOD_DYNAMIC
2917                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dyngroup.la"
2918         else
2919                 MFLAG=SLAPD_MOD_STATIC
2920                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dyngroup.o"
2921         fi
2922         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNGROUP,$MFLAG,[define for Dynamic Group overlay])
2923 fi
2924
2925 if test "$ol_enable_dynlist" != no ; then
2926         BUILD_DYNLIST=$ol_enable_dynlist
2927         if test "$ol_enable_dynlist" = mod ; then
2928                 MFLAG=SLAPD_MOD_DYNAMIC
2929                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dynlist.la"
2930         else
2931                 MFLAG=SLAPD_MOD_STATIC
2932                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dynlist.o"
2933         fi
2934         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNLIST,$MFLAG,[define for Dynamic List overlay])
2935 fi
2936
2937 if test "$ol_enable_lastmod" != no ; then
2938         BUILD_LASTMOD=$ol_enable_lastmod
2939         if test "$ol_enable_lastmod" = mod ; then
2940                 MFLAG=SLAPD_MOD_DYNAMIC
2941                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS lastmod.la"
2942         else
2943                 MFLAG=SLAPD_MOD_STATIC
2944                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS lastmod.o"
2945         fi
2946         AC_DEFINE_UNQUOTED(SLAPD_OVER_LASTMOD,$MFLAG,[define for Last Modification overlay])
2947 fi
2948
2949 if test "$ol_enable_ppolicy" != no ; then
2950         BUILD_PPOLICY=$ol_enable_ppolicy
2951         if test "$ol_enable_ppolicy" = mod ; then
2952                 MFLAG=SLAPD_MOD_DYNAMIC
2953                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS ppolicy.la"
2954         else
2955                 MFLAG=SLAPD_MOD_STATIC
2956                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS ppolicy.o"
2957         fi
2958         AC_DEFINE_UNQUOTED(SLAPD_OVER_PPOLICY,$MFLAG,[define for Password Policy overlay])
2959 fi
2960
2961 if test "$ol_enable_proxycache" != no ; then
2962         BUILD_PROXYCACHE=$ol_enable_proxycache
2963         if test "$ol_enable_proxycache" = mod ; then
2964                 MFLAG=SLAPD_MOD_DYNAMIC
2965                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS pcache.la"
2966         else
2967                 MFLAG=SLAPD_MOD_STATIC
2968                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS pcache.o"
2969         fi
2970         AC_DEFINE_UNQUOTED(SLAPD_OVER_PROXYCACHE,$MFLAG,[define for Proxy Cache overlay])
2971 fi
2972
2973 if test "$ol_enable_refint" != no ; then
2974         BUILD_REFINT=$ol_enable_refint
2975         if test "$ol_enable_refint" = mod ; then
2976                 MFLAG=SLAPD_MOD_DYNAMIC
2977                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS refint.la"
2978         else
2979                 MFLAG=SLAPD_MOD_STATIC
2980                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS refint.o"
2981         fi
2982         AC_DEFINE_UNQUOTED(SLAPD_OVER_REFINT,$MFLAG,[define for Referential Integrity overlay])
2983 fi
2984
2985 if test "$ol_enable_retcode" != no ; then
2986         BUILD_RETCODE=$ol_enable_retcode
2987         if test "$ol_enable_retcode" = mod ; then
2988                 MFLAG=SLAPD_MOD_DYNAMIC
2989                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS retcode.la"
2990         else
2991                 MFLAG=SLAPD_MOD_STATIC
2992                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS retcode.o"
2993         fi
2994         AC_DEFINE_UNQUOTED(SLAPD_OVER_RETCODE,$MFLAG,[define for Referential Integrity overlay])
2995 fi
2996
2997 if test "$ol_enable_rwm" != no ; then
2998         BUILD_REWRITE=yes
2999         BUILD_RWM=$ol_enable_rwm
3000         if test "$ol_enable_rwm" = mod ; then
3001                 MFLAG=SLAPD_MOD_DYNAMIC
3002                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS rwm.la"
3003         else
3004                 MFLAG=SLAPD_MOD_STATIC
3005                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS rwm_x.o"
3006         fi
3007         AC_DEFINE_UNQUOTED(SLAPD_OVER_RWM,$MFLAG,[define for Rewrite/Remap overlay])
3008 fi
3009
3010 if test "$ol_enable_syncprov" != no ; then
3011         BUILD_SYNCPROV=$ol_enable_syncprov
3012         if test "$ol_enable_syncprov" = mod ; then
3013                 MFLAG=SLAPD_MOD_DYNAMIC
3014                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS syncprov.la"
3015         else
3016                 MFLAG=SLAPD_MOD_STATIC
3017                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS syncprov.o"
3018         fi
3019         AC_DEFINE_UNQUOTED(SLAPD_OVER_SYNCPROV,$MFLAG,[define for Syncrepl Provider overlay])
3020 fi
3021
3022 if test "$ol_enable_translucent" != no ; then
3023         BUILD_TRANSLUCENT=$ol_enable_translucent
3024         if test "$ol_enable_translucent" = mod ; then
3025                 MFLAG=SLAPD_MOD_DYNAMIC
3026                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS translucent.la"
3027         else
3028                 MFLAG=SLAPD_MOD_STATIC
3029                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS translucent.o"
3030         fi
3031         AC_DEFINE_UNQUOTED(SLAPD_OVER_TRANSLUCENT,$MFLAG,[define for Translucent Proxy overlay])
3032 fi
3033
3034 if test "$ol_enable_unique" != no ; then
3035         BUILD_UNIQUE=$ol_enable_unique
3036         if test "$ol_enable_unique" = mod ; then
3037                 MFLAG=SLAPD_MOD_DYNAMIC
3038                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS unique.la"
3039         else
3040                 MFLAG=SLAPD_MOD_STATIC
3041                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS unique.o"
3042         fi
3043         AC_DEFINE_UNQUOTED(SLAPD_OVER_UNIQUE,$MFLAG,[define for Attribute Uniqueness overlay])
3044 fi
3045
3046 if test "$ol_enable_valsort" != no ; then
3047         BUILD_VALSORT=$ol_enable_valsort
3048         if test "$ol_enable_valsort" = mod ; then
3049                 MFLAG=SLAPD_MOD_DYNAMIC
3050                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS valsort.la"
3051         else
3052                 MFLAG=SLAPD_MOD_STATIC
3053                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS valsort.o"
3054         fi
3055         AC_DEFINE_UNQUOTED(SLAPD_OVER_VALSORT,$MFLAG,[define for Value Sorting overlay])
3056 fi
3057
3058 if test "$ol_enable_slurpd" != no &&
3059    test "$ol_link_threads" != no &&
3060    test $BUILD_SLAPD = yes ; then
3061         BUILD_SLURPD=yes
3062 fi
3063
3064 if test "$ol_enable_rewrite" != no ; then
3065         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
3066         BUILD_REWRITE=yes
3067 fi
3068
3069 if test "$ol_enable_slapi" != no ; then
3070         AC_DEFINE(ENABLE_SLAPI,1,[define to enable slapi library])
3071         BUILD_SLAPI=yes
3072         SLAPD_SLAPI_DEPEND=libslapi.a
3073 fi
3074
3075 dnl ----------------------------------------------------------------
3076
3077 dnl
3078 dnl For Windows build, we don't want to include -dlopen flags.
3079 dnl They hurt more than they help.
3080 dnl
3081
3082 if test "$ac_cv_mingw32" = yes ; then
3083         PLAT=NT
3084         SLAPD_MODULES_LDFLAGS=
3085 else
3086         PLAT=UNIX
3087 fi
3088
3089 AC_SUBST(LIBSRCS)
3090 AC_SUBST(PLAT)
3091 AC_SUBST(WITH_SASL)
3092 AC_SUBST(WITH_TLS)
3093 AC_SUBST(WITH_MODULES_ENABLED)
3094 AC_SUBST(WITH_ACI_ENABLED)
3095 AC_SUBST(BUILD_THREAD)
3096 AC_SUBST(BUILD_LIBS_DYNAMIC)
3097
3098 AC_SUBST(BUILD_SLAPD)
3099 dnl slapi
3100   AC_SUBST(BUILD_SLAPI)
3101   AC_SUBST(SLAPD_SLAPI_DEPEND)
3102 dnl backends
3103   AC_SUBST(BUILD_BDB)
3104   AC_SUBST(BUILD_DNSSRV)
3105   AC_SUBST(BUILD_HDB)
3106   AC_SUBST(BUILD_LDAP)
3107   AC_SUBST(BUILD_LDBM)
3108   AC_SUBST(BUILD_META)
3109   AC_SUBST(BUILD_MONITOR)
3110   AC_SUBST(BUILD_NULL)
3111   AC_SUBST(BUILD_PASSWD)
3112   AC_SUBST(BUILD_RELAY)
3113   AC_SUBST(BUILD_PERL)
3114   AC_SUBST(BUILD_SHELL)
3115   AC_SUBST(BUILD_SQL)
3116 dnl overlays
3117   AC_SUBST(BUILD_ACCESSLOG)
3118   AC_SUBST(BUILD_DENYOP)
3119   AC_SUBST(BUILD_DYNGROUP)
3120   AC_SUBST(BUILD_DYNLIST)
3121   AC_SUBST(BUILD_LASTMOD)
3122   AC_SUBST(BUILD_PPOLICY)
3123   AC_SUBST(BUILD_PROXYCACHE)
3124   AC_SUBST(BUILD_REFINT)
3125   AC_SUBST(BUILD_RETCODE)
3126   AC_SUBST(BUILD_RWM)
3127   AC_SUBST(BUILD_SYNCPROV)
3128   AC_SUBST(BUILD_TRANSLUCENT)
3129   AC_SUBST(BUILD_UNIQUE)
3130   AC_SUBST(BUILD_VALSORT)
3131 AC_SUBST(BUILD_SLURPD)
3132
3133 AC_SUBST(LDAP_LIBS)
3134 AC_SUBST(SLAPD_LIBS)
3135 AC_SUBST(SLURPD_LIBS)
3136 AC_SUBST(LDBM_LIBS)
3137 AC_SUBST(LTHREAD_LIBS)
3138 AC_SUBST(LUTIL_LIBS)
3139 AC_SUBST(WRAP_LIBS)
3140
3141 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
3142 AC_SUBST(SLAPD_MODULES_LDFLAGS)
3143
3144 AC_SUBST(SLAPD_NO_STATIC)
3145 AC_SUBST(SLAPD_STATIC_BACKENDS)
3146 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
3147 AC_SUBST(SLAPD_STATIC_OVERLAYS)
3148 AC_SUBST(SLAPD_DYNAMIC_OVERLAYS)
3149
3150 AC_SUBST(PERL_CPPFLAGS)
3151 AC_SUBST(SLAPD_PERL_LDFLAGS)
3152 AC_SUBST(MOD_PERL_LDFLAGS)
3153
3154 AC_SUBST(KRB4_LIBS)
3155 AC_SUBST(KRB5_LIBS)
3156 AC_SUBST(SASL_LIBS)
3157 AC_SUBST(TLS_LIBS)
3158 AC_SUBST(MODULES_LIBS)
3159 AC_SUBST(SLAPI_LIBS)
3160 AC_SUBST(LIBSLAPI)
3161 AC_SUBST(LIBSLAPITOOLS)
3162 AC_SUBST(AUTH_LIBS)
3163 AC_SUBST(ICU_LIBS)
3164
3165 AC_SUBST(SLAPD_SLP_LIBS)
3166 AC_SUBST(SLAPD_GMP_LIBS)
3167
3168 AC_SUBST(SLAPD_SQL_LDFLAGS)
3169 AC_SUBST(SLAPD_SQL_LIBS)
3170 AC_SUBST(SLAPD_SQL_INCLUDES)
3171
3172 dnl ----------------------------------------------------------------
3173 dnl final help output
3174 AC_ARG_WITH(xxinstall,[
3175 See INSTALL file for further details.])
3176
3177 dnl ----------------------------------------------------------------
3178 dnl final output
3179 dnl
3180
3181 AC_CONFIG_FILES([Makefile:build/top.mk:Makefile.in:build/dir.mk]
3182 [doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk]
3183 [doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk]
3184 [doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk]
3185 [doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk]
3186 [doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk]
3187 [doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk]
3188 [clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk]
3189 [clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk]
3190 [include/Makefile:build/top.mk:include/Makefile.in]
3191 [libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk]
3192 [libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk]
3193 [libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk]
3194 [libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk]
3195 [libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk]
3196 [libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk]
3197 [libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-static.mk]
3198 [servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk]
3199 [servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk]
3200 [servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk]
3201 [servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk]
3202 [servers/slapd/back-hdb/Makefile:build/top.mk:servers/slapd/back-hdb/Makefile.in:build/mod.mk]
3203 [servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk]
3204 [servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk]
3205 [servers/slapd/back-ldif/Makefile:build/top.mk:servers/slapd/back-ldif/Makefile.in:build/mod.mk]
3206 [servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk]
3207 [servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk]
3208 [servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk]
3209 [servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk]
3210 [servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk]
3211 [servers/slapd/back-relay/Makefile:build/top.mk:servers/slapd/back-relay/Makefile.in:build/mod.mk]
3212 [servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk]
3213 [servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk]
3214 [servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk]
3215 [servers/slapd/slapi/Makefile:build/top.mk:servers/slapd/slapi/Makefile.in:build/lib.mk:build/lib-shared.mk]
3216 [servers/slapd/overlays/Makefile:build/top.mk:servers/slapd/overlays/Makefile.in:build/lib.mk]
3217 [servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk]
3218 [tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk]
3219 [tests/run]
3220 [tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk])
3221
3222 AC_CONFIG_COMMANDS([default],[[
3223 chmod +x tests/run
3224 date > stamp-h
3225 BACKENDSC="servers/slapd/backends.c"
3226 echo "Making $BACKENDSC"
3227 rm -f $BACKENDSC
3228 cat > $BACKENDSC << ENDX
3229 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3230  *
3231  * Copyright 1998-2006 The OpenLDAP Foundation.
3232  * All rights reserved.
3233  *
3234  * Redistribution and use in source and binary forms, with or without
3235  * modification, are permitted only as authorized by the OpenLDAP
3236  * Public License.
3237  *
3238  * A copy of this license is available in the file LICENSE in the
3239  * top-level directory of the distribution or, alternatively, at
3240  * <http://www.OpenLDAP.org/license.html>.
3241  */
3242 /* This file is automatically generated by configure; please do not edit. */
3243
3244 #include "portable.h"
3245 #include "slap.h"
3246
3247 ENDX
3248 if test "${STATIC_BACKENDS}"; then
3249         for b in config ${STATIC_BACKENDS}; do
3250                 bb=`echo "${b}" | sed -e 's/back-//'`
3251                 cat >> $BACKENDSC << ENDX
3252 extern BI_init ${bb}_back_initialize;
3253 ENDX
3254         done
3255
3256         cat >> $BACKENDSC << ENDX
3257
3258 BackendInfo slap_binfo[] = {
3259 ENDX
3260
3261         for b in config ${STATIC_BACKENDS}; do
3262                 bb=`echo "${b}" | sed -e 's/back-//'`
3263                 echo "    Add ${bb} ..."
3264                 cat >> $BACKENDSC << ENDX
3265         { "${bb}", ${bb}_back_initialize },
3266 ENDX
3267         done
3268
3269         cat >> $BACKENDSC << ENDX
3270         { NULL, NULL },
3271 };
3272
3273 /* end of generated file */
3274 ENDX
3275 fi
3276 OVERLAYSC="servers/slapd/overlays/statover.c"
3277 echo "Making $OVERLAYSC"
3278 rm -f $OVERLAYSC
3279 cat > $OVERLAYSC << ENDX
3280 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3281  *
3282  * Copyright 1998-2006 The OpenLDAP Foundation.
3283  * All rights reserved.
3284  *
3285  * Redistribution and use in source and binary forms, with or without
3286  * modification, are permitted only as authorized by the OpenLDAP
3287  * Public License.
3288  *
3289  * A copy of this license is available in the file LICENSE in the
3290  * top-level directory of the distribution or, alternatively, at
3291  * <http://www.OpenLDAP.org/license.html>.
3292  */
3293 /* This file is automatically generated by configure; please do not edit. */
3294
3295 #include "portable.h"
3296 #include "slap.h"
3297
3298 ENDX
3299 if test "${STATIC_OVERLAYS}"; then
3300         for o in ${STATIC_OVERLAYS}; do
3301                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3302                 cat >> $OVERLAYSC << ENDX
3303 extern OV_init ${oo}_initialize;
3304 ENDX
3305         done
3306 fi
3307
3308 cat >> $OVERLAYSC << ENDX
3309
3310 OverlayInit slap_oinfo[] = {
3311 ENDX
3312
3313 if test "${STATIC_OVERLAYS}"; then
3314         for o in ${STATIC_OVERLAYS}; do
3315                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3316                 echo "    Add ${oo} ..."
3317                 cat >> $OVERLAYSC << ENDX
3318         { "${oo}", ${oo}_initialize },
3319 ENDX
3320         done
3321 fi
3322
3323         cat >> $OVERLAYSC << ENDX
3324         { NULL, NULL },
3325 };
3326
3327 /* end of generated file */
3328 ENDX
3329
3330 echo Please run \"make depend\" to build dependencies
3331 ]],[[
3332 STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS"
3333 STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS"
3334 ]])
3335 AC_OUTPUT