git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  28 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  29 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  30 OL_ARG_ENABLE(dns,[  --enable--dns              enable V2 DNS  extension], no)dnl
  31 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  32 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  33 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  34         no, [yes no])dnl
  35
  36 dnl General "with" options
  37 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  38         auto, [auto k5 k4 afs yes no])
  39 OL_ARG_WITH(threads,[  --with-threads   use threads],
  40         auto, [auto posix mach lwp yes no manual] )
  41 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  42         auto, [auto yes no manual] )
  43
  44 dnl Server options
  45
  46 dnl LDAPD OPTIONS
  47 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  48
  49 dnl SLAPD OPTIONS
  50 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  51 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  52 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  53 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  54 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  55 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  56 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  57 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  58
  59 dnl SLAPD Backend options
  60 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  61 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  62         [auto db2 db gdbm ndbm manual])
  63 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  64         [auto btree hash])
  65
  66 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  67 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  68
  69 dnl SLURPD OPTIONS
  70 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  71
  72 if test $ol_enable_slapd = no ; then
  73         dnl SLAPD was specificallly disabled
  74         if test $ol_enable_ldbm = yes ; then
  75                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  76         fi
  77         if test $ol_enable_passwd = yes ; then
  78                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
  79         fi
  80         if test $ol_enable_shell = yes ; then
  81                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
  82         fi
  83         if test $ol_enable_aclgroups = yes ; then
  84                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
  85         fi
  86         if test $ol_enable_crypt = yes ; then
  87                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
  88         fi
  89         if test $ol_enable_md5 = yes ; then
  90                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
  91         fi
  92         if test $ol_enable_sha1 = yes ; then
  93                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
  94         fi
  95         if test $ol_enable_wrappers = yes ; then
  96                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
  97         fi
  98         if test $ol_enable_phonetic = yes ; then
  99                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 100         fi
 101         if test $ol_enable_rlookups = yes ; then
 102                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 103         fi
 104         if test $ol_with_ldbm_api != auto ; then
 105                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 106         fi
 107         if test $ol_with_ldbm_type != auto ; then
 108                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 109         fi
 110         if test $ol_enable_slurpd = yes ; then
 111                 AC_MSG_ERROR([slurpd requires slapd])
 112         fi
 113
 114         # force settings to no
 115         ol_enable_ldbm=no
 116         ol_enable_shell=no
 117         ol_enable_passwd=no
 118         ol_enable_aclgroups=no
 119         ol_enable_crypt=no
 120         ol_enable_md5=no
 121         ol_enable_sha1=no
 122         ol_enable_wrappers=no
 123         ol_enable_phonetic=no
 124         ol_enable_rlookups=no
 125         ol_with_ldbm_api=no
 126         ol_with_ldbm_type=no
 127         ol_enable_slurpd=no
 128
 129 elif test $ol_enable_ldbm = no ; then
 130         dnl SLAPD without LDBM
 131
 132         if test $ol_with_ldbm_api != auto ; then
 133                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 134         fi
 135
 136         if test $ol_with_ldbm_type != auto ; then
 137                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 138         fi
 139
 140         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 141                 AC_MSG_ERROR([slapd requires a backend])
 142         fi
 143
 144         ol_with_ldbm_api=no
 145         ol_with_ldbm_type=no
 146
 147 else
 148         dnl SLAPD with LDBM
 149
 150         if test $ol_with_ldbm_api = gdbm -a \
 151                 $ol_with_ldbm_type = btree ; then
 152                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 153         fi
 154         if test $ol_with_ldbm_api = ndbm -a \
 155                 $ol_with_ldbm_type = btree ; then
 156                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 157         fi
 158 fi
 159
 160 if test $ol_enable_slurpd = yes ; then
 161         dnl SLURPD was specifically enabled
 162         if test $ol_with_threads = no ; then
 163                 AC_MSG_ERROR([slurpd requires threads])
 164         fi
 165 fi
 166
 167 AC_MSG_RESULT(done)
 168
 169 ## Initialize vars
 170 LDAP_LIBS=
 171 LDBM_LIBS=
 172 LTHREAD_LIBS=
 173 LUTIL_LIBS=
 174
 175 LDAPD_LIBS=
 176 SLAPD_LIBS=
 177 SLURPD_LIBS=
 178
 179 BUILD_LDAPD=no
 180 BUILD_SLAPD=no
 181 BUILD_SLURPD=no
 182
 183 BUILD_LDBM=no
 184 BUILD_PASSWD=no
 185 BUILD_SHELL=no
 186 BUILD_THREAD=no
 187
 188 KRB_LIBS=
 189 TERMCAP_LIBS=
 190
 191 dnl ----------------------------------------------------------------
 192 dnl Checks for programs
 193
 194 AC_PROG_LN_S
 195 AC_PROG_INSTALL
 196 AC_PROG_RANLIB
 197 AC_PROG_MAKE_SET
 198
 199 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 200         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 201 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 202 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 203
 204 dnl Checks the compiler and UNIX Variants
 205 AC_PROG_CC
 206
 207 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 208         AC_WARN([cross compiling....  go for it])
 209
 210 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 211         AC_WARN([programs compiled here do run here...])
 212         AC_ERROR([  if not cross compiling, use --disable-x-compile.])
 213
 214 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 215         AC_WARN([programs compiled here do not run here...])
 216         AC_ERROR([  if cross compiling,  add --enable-x-compile.])
 217 fi
 218
 219 dnl OpenLDAP requires STDC features
 220 dnl AC_PROG_GCC_TRADITIONAL
 221 AC_PROG_CPP
 222
 223
 224 AC_AIX
 225 AC_ISC_POSIX
 226 AC_MINIX
 227
 228 dnl Checks for libraries
 229
 230 dnl Find socket()
 231 dnl Likely combinations:
 232 dnl             -lsocket [ -lnsl_s | -lnsl ]
 233 dnl             -linet
 234
 235 AC_CHECK_FUNC(socket, :, [
 236 dnl
 237 dnl hopefully we won't include too many libraries
 238 dnl
 239         AC_CHECK_LIB(socket, main)
 240         AC_CHECK_LIB(net, main)
 241         AC_CHECK_LIB(nsl_s, main)
 242         AC_CHECK_LIB(nsl, main)
 243         AC_CHECK_LIB(inet, socket)
 244         AC_CHECK_LIB(gen, main)
 245 ])
 246
 247 dnl Check for resolv
 248 AC_CHECK_LIB(resolv, res_search)
 249
 250 dnl HP-UX requires -lV3
 251 AC_CHECK_LIB(V3, sigset)
 252
 253 # ISODE tests
 254 ol_link_isode=no
 255 if test $ol_enable_ldapd != no ; then
 256         dnl look for ISODE libraries
 257         AC_CHECK_LIB(xtpp, main, [
 258                 ol_link_isode=yes
 259                 AC_DEFINE(HAVE_XTPP,1)
 260                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 261                 ],:,[-lxtdsap -lxtisode -losi])
 262         AC_CHECK_LIB(dsap, main, [
 263                 ol_link_isode=yes
 264                 AC_DEFINE(HAVE_DSAP,1)
 265                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 266                 ],:,[-lisode])
 267         AC_CHECK_LIB(isode, main, [
 268                 ol_link_isode=yes
 269                 AC_DEFINE(HAVE_ISODE,1)
 270                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 271                 ],:)
 272 fi
 273
 274 if test $ol_link_isode != no; then
 275         AC_CHECK_LIB(pp, main, [
 276                 AC_DEFINE(HAVE_PP,1)
 277                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 278                 ],:)
 279
 280         AC_PATH_PROG(PEPSY, pepsy)
 281 fi
 282
 283 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 284         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 285
 286         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 287                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 288                         [-lkrb5 -ldes425])
 289
 290                 if test $have_k5 = yes ; then
 291                         ol_with_kerberos=found
 292                         ol_link_kerberos=yes
 293
 294                         AC_DEFINE(HAVE_KERBEROS)
 295
 296                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 297                 fi
 298         fi
 299 fi
 300 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 301         AC_CHECK_HEADERS(krb.h des.h)
 302
 303         if test $ac_cv_header_krb_h = yes ; then
 304                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 305
 306                 if test $have_k4 = yes ; then
 307                         ol_with_kerberos=found
 308                         ol_link_kerberos=yes
 309
 310                         AC_DEFINE(HAVE_KERBEROS)
 311
 312                         KRB_LIBS="-lkrb -ldes"
 313                 fi
 314         fi
 315 fi
 316
 317
 318 ol_link_threads=no
 319 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 320         AC_CHECK_HEADERS(pthread.h sched.h)
 321
 322         if test $ac_cv_header_pthread_h = yes ; then
 323                 OL_POSIX_THREAD_VERSION
 324
 325                 if test $ol_cv_pthread_version = final ; then
 326                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 327                 elif test $ol_cv_pthread_version = draft4 ; then
 328                         AC_DEFINE(HAVE_PTHREADS_D4)
 329                 else
 330                         AC_MSG_ERROR([unknown pthread version])
 331                 fi
 332
 333                 # consider threads found
 334                 ol_with_threads=found
 335
 336                 OL_LINUX_THREADS
 337
 338                 if test $ol_cv_linux_threads = yes ; then
 339                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 340                 fi
 341
 342                 dnl Now the hard part, how to link
 343
 344                 dnl A few platforms have pthread support in standard libraries
 345                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 346
 347                 if test $ol_link_threads = no ; then
 348                         dnl try -pthread
 349                         AC_CACHE_CHECK([for pthread_create with -pthread],
 350                                 [ol_cv_pthread_flag], [
 351                                 dnl save the CPPFLAGS
 352                                 save_LIBS="$LIBS"
 353                                 LIBS="-pthread $LIBS"
 354                                 AC_TRY_LINK([#include <pthread.h>],[
 355                                         pthread_create((pthread_t*) 0,
 356                                                 (pthread_attr_t*) 0, 0, 0);
 357                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 358                                 dnl restore the LIBS
 359                                 LIBS="$save_LIBS"
 360                         ])
 361
 362                         if test $ol_cv_pthread_flag = yes ; then
 363                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 364                                 ol_link_threads=posix
 365                         fi
 366                 fi
 367
 368                 if test $ol_link_threads = no ; then
 369                         dnl try -lpthread
 370                         save_LIBS="$LIBS"
 371                         AC_CHECK_LIB(pthread, pthread_create, [
 372                                 ol_link_threads=posix
 373                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 374                         LIBS="$save_LIBS"
 375                 fi
 376
 377                 if test $ol_link_threads = no ; then
 378                         dnl try -lc_r
 379                         save_LIBS="$LIBS"
 380                         AC_CHECK_LIB(c_r, pthread_create, [
 381                                 ol_link_threads=posix
 382                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 383                         LIBS="$save_LIBS"
 384                 fi
 385
 386                 if test $ol_link_threads = no ; then
 387                         dnl try DEC Threads
 388                         save_LIBS="$LIBS"
 389                         AC_CHECK_LIB(pthread, pthread_create, [
 390                                 AC_DEFINE(HAVE_DCE)
 391                                 ol_link_threads=posix
 392                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc"
 393                                 if test $ol_with_preemptive = auto ; then
 394                                         ol_with_preemptive=yes
 395                                 fi
 396                                 ],,[-lmach -lexc -lc])
 397                         LIBS="$save_LIBS"
 398                 fi
 399
 400                 if test $ol_link_threads != no ; then
 401                         AC_DEFINE(HAVE_PTHREADS)
 402
 403                         dnl save DEFS/LIBS
 404                         save_CPPFLAGS="$CPPFLAGS"
 405                         save_LIBS="$LIBS"
 406                         LIBS="$LTHREAD_LIBS $LIBS"
 407
 408                         dnl All POSIX Thread (final) implementations should have
 409                         dnl sched_yield instead of pthread yield.
 410                         dnl check for both
 411                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 412
 413                         if test $ac_cv_func_sched_yield = no -a \
 414                                 $ac_cv_func_pthread_yield = no ; then
 415                                 dnl Digital UNIX has sched_yield() in -lrt
 416                                 AC_CHECK_LIB(rt, sched_yield,
 417                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 418                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 419                                         ac_cv_func_sched_yield=yes],
 420                                         [ac_cv_func_sched_yield=no])
 421                         fi
 422                         if test $ac_cv_func_sched_yield = no -a \
 423                                 $ac_cv_func_pthread_yield = no ; then
 424                                 dnl Solaris has sched_yield() in -lposix4
 425                                 AC_CHECK_LIB(posix4, sched_yield,
 426                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 427                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 428                                         ac_cv_func_sched_yield=yes],
 429                                         [ac_cv_func_sched_yield=no])
 430                         fi
 431                         if test $ac_cv_func_sched_yield = no -a \
 432                                 $ac_cv_func_pthread_yield = no ; then
 433                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 434                                 AC_MSG_ERROR([POSIX Threads are not usable])
 435                         fi
 436
 437                         dnl Check functions for compatibility
 438                         AC_CHECK_FUNCS(pthread_kill)
 439 dnl                     AC_CHECK_FUNCS( \
 440 dnl                             pthread_attr_create pthread_attr_init \
 441 dnl                             pthread_attr_destroy pthread_attr_delete \
 442 dnl                             pthread_attr_setdetachstate pthread_attr_setdetach_np \
 443 dnl                     )
 444
 445                         dnl Check for setconcurreny functions
 446                         AC_CHECK_FUNCS( \
 447                                 pthread_setconcurrency \
 448                                 thr_setconcurrency \
 449                         )
 450
 451                         dnl Check PREEMPTIVE Implementation
 452                         if test $ol_with_preemptive = auto ; then
 453                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 454                                 AC_TRY_RUN([
 455 #include <sys/types.h>
 456 #include <sys/time.h>
 457 #include <unistd.h>
 458 #include <pthread.h>
 459 #ifndef NULL
 460 #define NULL 0
 461 #endif
 462
 463 int task(arg)
 464         int *arg;
 465 {
 466         struct timeval tv;
 467
 468         tv.tv_sec=4;
 469         tv.tv_usec=0;
 470         select(0, NULL, NULL, NULL, &tv);
 471
 472         tv.tv_sec=6;
 473         tv.tv_usec=0;
 474         select(0, NULL, NULL, NULL, &tv);
 475
 476         exit(1); /* if we exit here, the select blocked the whole process */
 477 }
 478
 479 main(argc, argv)
 480 int argc; char **argv;
 481 {
 482         pthread_t t;
 483
 484 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 485         (void) pthread_setconcurrency(2);
 486 #elif HAVE_THR_SETCONCURRENCY
 487         /* Set Solaris LWP concurrency to 2 */
 488         thr_setconcurrency(2);
 489 #endif
 490
 491         pthread_create(&t, NULL, (void *) task, NULL);
 492
 493 #if HAVE_SCHED_YIELD
 494         sched_yield();  /* make sure task runs first */
 495 #else
 496 #if defined(HAVE_PTHREAD_YIELD)
 497         pthread_yield();        /* make sure task runs first */
 498 #endif
 499 #endif
 500         exit(0);
 501 }
 502                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 503                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 504                                 AC_MSG_RESULT($ol_pthread_preemptive)
 505
 506                                 if test $ol_pthread_preemptive = yes ; then
 507                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 508                                         ol_with_preemptive=yes
 509                                 fi
 510                         fi
 511
 512 dnl                     dnl check for reentrant/threadsafe functions
 513 dnl                     AC_CHECK_FUNCS( \
 514 dnl                             feof_unlocked \
 515 dnl                             unlocked_feof \
 516 dnl                             ftrylockfile \
 517 dnl                             flockfile \
 518 dnl                             putc_unlocked \
 519 dnl                             gmtime_r \
 520 dnl                             strtok_r \
 521 dnl                     )
 522
 523                         dnl restore DEFS/LIBS
 524                         CPPFLAGS="$save_CPPFLAGS"
 525                         LIBS="$save_LIBS"
 526                 else
 527                         AC_MSG_ERROR([could not link with POSIX Threads])
 528                 fi
 529         fi
 530
 531         if test $ol_with_threads = posix ; then
 532                 AC_MSG_ERROR([could not locate POSIX Threads])
 533         fi
 534 fi
 535
 536 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 537         dnl check for Mach CThreads
 538         AC_CHECK_HEADERS(mach/cthreads.h)
 539         if test $ac_cv_header_mach_cthreads_h = yes ; then
 540                 ol_with_threads=found
 541
 542                 dnl A few platforms have cthread support in standard libraries
 543                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 544
 545                 if test $ol_link_threads = no ; then
 546                         dnl try -all_load
 547                         dnl this test needs work
 548                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 549                                 [ol_cv_cthread_all_load], [
 550                                 dnl save the CPPFLAGS
 551                                 save_LIBS="$LIBS"
 552                                 LIBS="-all_load $LIBS"
 553                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 554                                         cthread_fork((void *)0, (void *)0);
 555                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 556                                 dnl restore the LIBS
 557                                 LIBS="$save_LIBS"
 558                         ])
 559
 560                         if test $ol_cv_cthread_all_load = yes ; then
 561                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 562                                 ol_link_threads=mach
 563                         fi
 564                 fi
 565
 566                 if test $ol_link_threads != no ; then
 567                         : check for cthread specific functionality here
 568                         AC_DEFINE(HAVE_MACH_CTHREADS,1)
 569                 else
 570                         AC_MSG_ERROR([could not link with Mach CThreads])
 571                 fi
 572         fi
 573
 574         if test $ol_with_threads = mach ; then
 575                 AC_MSG_ERROR([could not locate Mach CThreads])
 576         fi
 577 fi
 578
 579 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 580         dnl check for SunOS5 LWP
 581         AC_CHECK_HEADERS(thread.h synch.h)
 582         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 583                 AC_CHECK_LIB(thread, thr_create, [have_lwp=yes], [have_lwp=no])
 584
 585                 if test $have_lwp = yes ; then
 586                         AC_DEFINE(HAVE_THR)
 587                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 588
 589                         if test $ol_with_preemptive = auto ; then
 590                                 ol_with_preemptive=yes
 591                         fi
 592                 fi
 593         fi
 594
 595         dnl check for SunOS4 LWP
 596         AC_CHECK_HEADERS(lwp/lwp.h)
 597         if test $ac_cv_header_lwp_lwp_h = yes ; then
 598                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 599
 600                 if test $have_lwp = yes ; then
 601                         AC_DEFINE(HAVE_LWP)
 602                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 603
 604                         if test $ol_with_preemptive = auto ; then
 605                                 ol_with_preemptive=no
 606                         fi
 607                 fi
 608         fi
 609 fi
 610
 611 if test $ol_with_preemptive = yes ; then
 612         AC_DEFINE(PREEMPTIVE_THREADS,1)
 613 fi
 614
 615 if test $ol_with_threads = manual ; then
 616         dnl User thinks he can manually configure threads.
 617         ol_link_threads=yes
 618
 619         AC_MSG_WARN([thread defines and link options must be set manually])
 620
 621         AC_CHECK_HEADERS(pthread.h sched.h)
 622         AC_CHECK_FUNCS(sched_yield pthread_yield)
 623         OL_LINUX_THREADS
 624
 625         AC_CHECK_HEADERS(mach/cthreads.h)
 626         AC_CHECK_HEADERS(lwp/lwp.h)
 627         AC_CHECK_HEADERS(thread.h synch.h)
 628 fi
 629
 630 if test $ol_with_threads = yes ; then
 631         dnl needed to get reentrant/threadsafe versions
 632         dnl
 633         dnl hopefully this will not cause problems with
 634         dnl non-threaded apps
 635         dnl
 636         AC_DEFINE(_REENTRANT,1)
 637         AC_DEFINE(_THREAD_SAFE,1)
 638 fi
 639
 640 dnl ----------------------------------------------------------------
 641
 642 if test $ol_link_threads = no ; then
 643         if test $ol_with_threads = yes ; then
 644                 AC_MSG_ERROR([no suitable thread support])
 645         fi
 646
 647         if test $ol_with_threads = auto ; then
 648                 AC_MSG_WARN([no suitable thread support, disabling threads])
 649                 ol_with_threads=no
 650         fi
 651
 652         AC_DEFINE(NO_THREADS,1)
 653         AC_DEFINE(PREEMPTIVE_THREADS,1)
 654         LTHREAD_LIBS=""
 655 fi
 656
 657 ol_link_ldbm=no
 658 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 659         OL_BERKELEY_DB2
 660
 661         if test $ol_cv_berkeley_db2 = yes ; then
 662                 ol_link_ldbm=db2
 663                 ol_with_ldbm_api=db2
 664
 665                 if test $ol_with_ldbm_type = hash ; then
 666                         AC_DEFINE(LDBM_USE_DBHASH,1)
 667                 else
 668                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 669                 fi
 670
 671                 dnl $ol_cv_lib_db2 should be yes or -ldb
 672                 dnl (it could be no, but that would be an error
 673                 if test $ol_cv_lib_db2 != yes ; then
 674                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 675                 fi
 676         fi
 677 fi
 678
 679 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 680         OL_BERKELEY_DB
 681
 682         if test $ol_cv_berkeley_db = yes ; then
 683                 ol_link_ldbm=db
 684                 ol_with_ldbm_api=db
 685
 686                 if test $ol_with_ldbm_type = hash ; then
 687                         AC_DEFINE(LDBM_USE_DBHASH,1)
 688                 else
 689                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 690                 fi
 691
 692                 dnl $ol_cv_lib_db should be yes or -ldb
 693                 dnl (it could be no, but that would be an error
 694                 if test $ol_cv_lib_db != yes ; then
 695                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 696                 fi
 697         fi
 698 fi
 699
 700 if test $ol_with_ldbm_api = manual ; then
 701         dnl User thinks he can manually configure LDBM api.
 702         ol_link_ldbm=yes
 703
 704         AC_MSG_WARN([LDBM defines and link options must be set manually])
 705
 706         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 707 fi
 708
 709 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 710         AC_MSG_WARN(Could not find LDBM with BTREE support)
 711         ol_with_ldbm_api=none
 712 fi
 713
 714 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 715         OL_GDBM
 716
 717         if test $ol_cv_gdbm = yes ; then
 718                 ol_link_ldbm=gdbm
 719                 ol_with_ldbm_api=gdbm
 720
 721                 if test $ol_cv_lib_gdbm != yes ; then
 722                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 723                 fi
 724         fi
 725 fi
 726
 727 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 728         OL_NDBM
 729
 730         if test $ol_cv_ndbm = yes ; then
 731                 ol_link_ldbm=ndbm
 732                 ol_with_ldbm_api=ndbm
 733
 734                 if test $ol_with_ldbm_api = ndbm ; then
 735                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 736                 fi
 737
 738                 if test $ol_cv_lib_ndbm != yes ; then
 739                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 740                 fi
 741         fi
 742 fi
 743
 744 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 745         AC_MSG_WARN(could not find suitable LDBM backend)
 746         if test $ol_enable_ldbm = yes ; then
 747                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 748         fi
 749
 750         AC_MSG_WARN(disabling LDBM)
 751         ol_enable_ldbm=no
 752 fi
 753
 754 if test $ol_enable_wrappers = yes ; then
 755         AC_CHECK_LIB(wrap, hosts_access,
 756                 [have_wrappers=yes], [have_wrappers=no])
 757
 758         if test $have_wrappers = yes ; then
 759                 AC_DEFINE(HAVE_TCPD)
 760                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 761         else
 762                 AC_MSG_WARN(could not find -lwrap)
 763                 if test $ol_enable_wrappers = yes ; then
 764                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 765                 fi
 766
 767                 AC_MSG_WARN(disabling wrappers support)
 768                 ol_enable_wrappers=no
 769         fi
 770
 771 fi
 772
 773 # ud needs termcap (should insert check here)
 774 ol_link_termcap=no
 775 AC_CHECK_HEADERS(termcap.h ncurses.h)
 776
 777 if test $ol_link_termcap = no ; then
 778         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 779         if test $have_termcap = yes ; then
 780                 AC_DEFINE(HAVE_TERMCAP)
 781                 ol_link_termcap=yes
 782                 TERMCAP_LIBS=-ltermcap
 783         fi
 784 fi
 785
 786 if test $ol_link_termcap = no ; then
 787         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 788         if test $have_ncurses = yes ; then
 789                 AC_DEFINE(HAVE_NCURSES)
 790                 ol_link_termcap=yes
 791                 TERMCAP_LIBS=-lncurses
 792         fi
 793 fi
 794
 795 if test $ol_link_termcap = no ; then
 796         AC_DEFINE(NO_TERMCAP,1)
 797         TERMCAP_LIBS=
 798 fi
 799
 800 # FreeBSD (and others) have crypt(3) in -lcrypt
 801 if test $ol_enable_crypt != no ; then
 802         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 803                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 804                         have_crypt=yes], [have_crypt=no])])
 805
 806         if test $have_crypt = yes ; then
 807                 AC_DEFINE(HAVE_CRYPT,1)
 808         else
 809                 AC_MSG_WARN(could not find crypt)
 810                 if test $ol_enable_crypt = yes ; then
 811                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 812                 fi
 813
 814                 AC_MSG_WARN(disabling crypt support)
 815                 ol_enable_crypt=no
 816         fi
 817 fi
 818
 819 # FreeBSD (and others) have setproctitle(3) in -lutil
 820 if test $ol_enable_proctitle != no ; then
 821         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 822                 AC_CHECK_LIB(util, setproctitle,
 823                         [have_setproctitle=yes
 824                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 825                         [have_setproctitle=no
 826                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 827
 828         if test $have_setproctitle = yes ; then
 829                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 830         fi
 831 fi
 832
 833 dnl ----------------------------------------------------------------
 834 dnl Checks for header files.
 835 AC_HEADER_STDC
 836
 837 if test $ac_cv_header_stdc != yes; then
 838         AC_MSG_WARN([could not locate Standard C headers])
 839 fi
 840
 841 AC_HEADER_DIRENT
 842 AC_HEADER_SYS_WAIT
 843 AC_CHECK_HEADERS(       \
 844         stdarg.h                \
 845         stddef.h                \
 846         errno.h                 \
 847         fcntl.h                 \
 848         filio.h                 \
 849         getopt.h                \
 850         libutil.h               \
 851         limits.h                \
 852         malloc.h                \
 853         regex.h                 \
 854         sgtty.h                 \
 855         sys/file.h              \
 856         sys/filio.h             \
 857         sys/errno.h             \
 858         sys/ioctl.h             \
 859         sys/param.h             \
 860         sys/socket.h    \
 861         sys/syslog.h    \
 862         sys/time.h              \
 863         sys/types.h             \
 864         syslog.h                \
 865         termios.h               \
 866         unistd.h                \
 867 )
 868
 869 dnl ----------------------------------------------------------------
 870 dnl Checks for typedefs, structures, and compiler characteristics.
 871 AC_TYPE_GETGROUPS
 872 AC_TYPE_MODE_T
 873 AC_TYPE_OFF_T
 874 AC_TYPE_PID_T
 875 AC_TYPE_SIGNAL
 876 AC_TYPE_SIZE_T
 877 AC_TYPE_UID_T
 878 AC_STRUCT_ST_BLKSIZE
 879 AC_HEADER_TIME
 880 AC_STRUCT_TM
 881
 882 OL_C_UPPER_LOWER
 883 AC_C_CONST
 884
 885 dnl AC_CHECK_SIZEOF(short)
 886 dnl AC_CHECK_SIZEOF(int)
 887 dnl AC_CHECK_SIZEOF(long)
 888
 889 dnl ----------------------------------------------------------------
 890 dnl Checks for library functions.
 891 AC_FUNC_MEMCMP
 892 AC_FUNC_STRFTIME
 893 AC_FUNC_VPRINTF
 894
 895 if test $ac_cv_func_vprintf = yes ; then
 896         dnl check for vsnprintf
 897         AC_CHECK_FUNCS(vsnprintf)
 898 fi
 899
 900 AC_FUNC_WAIT3
 901
 902 AC_CHECK_FUNCS(         \
 903         bcopy                   \
 904         getopt                  \
 905         flock                   \
 906         gethostname             \
 907         gettimeofday    \
 908         getdtablesize   \
 909         lockf                   \
 910         memcpy                  \
 911         memmove                 \
 912         mkstemp                 \
 913         mktime                  \
 914         res_search              \
 915         select                  \
 916         setpwfile               \
 917         setsid                  \
 918         signal                  \
 919         sigset                  \
 920         snprintf                \
 921         socket                  \
 922         strerror                \
 923         strstr                  \
 924         strrchr                 \
 925         strsep                  \
 926         strtod                  \
 927         strtol                  \
 928         strtoul                 \
 929         sysconf                 \
 930         tempnam                 \
 931         waitpid                 \
 932 )
 933
 934 AC_REPLACE_FUNCS(getopt strdup tempnam)
 935
 936 dnl ----------------------------------------------------------------
 937 # Check Configuration
 938 OL_SYS_ERRLIST
 939
 940 dnl ----------------------------------------------------------------
 941 dnl Sort out defines
 942
 943 if test $ol_enable_debug != no ; then
 944         AC_DEFINE(LDAP_DEBUG,1)
 945 fi
 946 dnl     if test $ol_enable_syslog != no ; then
 947 dnl             AC_DEFINE(LDAP_SYSLOG,1)
 948 dnl     fi
 949 if test $ol_enable_libui = yes ; then
 950         AC_DEFINE(LDAP_LIBUI,1)
 951 fi
 952 if test $ol_enable_cache = no ; then
 953         AC_DEFINE(LDAP_NOCACHE,1)
 954 fi
 955 if test $ol_enable_dns != no ; then
 956         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_API_VENDOR_VERSION)
 957 fi
 958 if test $ol_enable_proctitle != no ; then
 959         AC_DEFINE(LDAP_PROCTITLE,1)
 960 fi
 961 if test $ol_enable_referrals != no ; then
 962         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_API_VENDOR_VERSION)
 963 fi
 964 if test $ol_enable_cldap != no ; then
 965         AC_DEFINE(LDAP_CONNECTIONLESS,1)
 966 fi
 967
 968 if test $ol_enable_aclgroups != no ; then
 969         AC_DEFINE(SLAPD_ACLGROUPS,1)
 970 fi
 971 if test $ol_enable_crypt != no ; then
 972         AC_DEFINE(SLAPD_CRYPT,1)
 973 fi
 974 if test $ol_enable_md5 != no ; then
 975         AC_DEFINE(SLAPD_MD5,1)
 976 fi
 977 if test $ol_enable_sha1 != no ; then
 978         AC_DEFINE(SLAPD_SHA1,1)
 979 fi
 980 if test $ol_enable_phonetic != no ; then
 981         AC_DEFINE(SLAPD_PHONETIC,1)
 982 fi
 983 if test $ol_enable_rlookups != no ; then
 984         AC_DEFINE(SLAPD_RLOOKUPS,1)
 985 fi
 986
 987 if test $ol_link_ldbm != no ; then
 988         AC_DEFINE(SLAPD_LDBM,1)
 989         BUILD_SLAPD=yes
 990         BUILD_LDBM=yes
 991 fi
 992
 993 if test $ol_enable_passwd != no ; then
 994         AC_DEFINE(SLAPD_PASSWD,1)
 995         BUILD_SLAPD=yes
 996         BUILD_PASSWD=yes
 997 fi
 998
 999 if test $ol_enable_shell != no ; then
1000         AC_DEFINE(SLAPD_SHELL,1)
1001         BUILD_SLAPD=yes
1002         BUILD_SHELL=yes
1003 fi
1004
1005 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1006         $BUILD_SLAPD = yes ; then
1007         BUILD_SLURPD=yes
1008 fi
1009
1010 if test $ol_link_isode != no ; then
1011         BUILD_LDAPD=yes
1012 fi
1013
1014 dnl ----------------------------------------------------------------
1015
1016 AC_SUBST(BUILD_LDAPD)
1017 AC_SUBST(BUILD_SLAPD)
1018   AC_SUBST(BUILD_LDBM)
1019   AC_SUBST(BUILD_PASSWD)
1020   AC_SUBST(BUILD_SHELL)
1021 AC_SUBST(BUILD_SLURPD)
1022
1023
1024 AC_SUBST(LDAP_LIBS)
1025 AC_SUBST(LDAPD_LIBS)
1026 AC_SUBST(SLAPD_LIBS)
1027 AC_SUBST(SLURPD_LIBS)
1028 AC_SUBST(LDBM_LIBS)
1029 AC_SUBST(LTHREAD_LIBS)
1030 AC_SUBST(LUTIL_LIBS)
1031
1032 AC_SUBST(KRB_LIBS)
1033 AC_SUBST(TERMCAP_LIBS)
1034
1035 dnl ----------------------------------------------------------------
1036 dnl final output
1037 dnl
1038
1039 AC_OUTPUT( \
1040 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1041 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1042 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1043 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1044 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1045 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1046 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1047 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1048 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1049 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1050 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1051 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1052 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1053 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1054 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1055 include/Makefile:build/top.mk:include/Makefile.in \
1056 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1057 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
1058 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
1059 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
1060 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
1061 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
1062 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
1063 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
1064 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1065 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1066 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1067 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1068 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1069 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1070 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1071 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1072 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1073 tests/Makefile:build/top.mk:tests/Makefile.in \
1074 ,[
1075 date > stamp-h
1076 echo Please \"make depend\" to build dependencies
1077 ])