git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Configure.in for OpenLDAP
  11 AC_INIT(include/ldap.h)dnl
  12 AC_CONFIG_AUX_DIR(build)dnl
  13 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel], [no ac_define])dnl
  14
  15 dnl We use autoconf features new to 2.13.
  16 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  17 AC_PREREQ(2.13)dnl Required Autoconf version
  18
  19 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  20
  21 dnl
  22 dnl Start Args
  23 AC_MSG_CHECKING(configure arguments)
  24 AC_PREFIX_DEFAULT(/usr/local)
  25
  26 top_builddir=`pwd`
  27 AC_SUBST(top_builddir)dnl
  28
  29 ldap_subdir="openldap"
  30
  31 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  32         if test "$withval" = "no"; then
  33                 ldap_subdir=""
  34         elif test "$withval" != "yes"; then
  35                 ldap_subdir="$withval"
  36         fi
  37 ])dnl
  38
  39 AC_SUBST(ldap_subdir)dnl
  40
  41 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  42 ol_enable_syslog=no
  43 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  44 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  45 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  46 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  47 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  48 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  49 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  50         no, [yes no])dnl
  51
  52 dnl General "with" options
  53 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  54
  55 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  56         auto, [auto k5 k4 afs yes no])
  57 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  58         auto, [auto yes no] )
  59 OL_ARG_WITH(threads,[  --with-threads   use threads],
  60         auto, [auto posix mach lwp yes no manual] )
  61 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  62         auto, [auto ssleay openssl yes no] )
  63 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  64         auto, [auto yes no manual] )
  65
  66 dnl Server options
  67
  68 dnl LDAPD OPTIONS
  69 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  70 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  71
  72 dnl SLAPD OPTIONS
  73 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  74 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  75 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  76 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  77 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  78 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  79 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  80 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  81
  82 dnl SLAPD Backend options
  83 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  84 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  85 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  86         [auto db2 db mdbm gdbm ndbm manual])
  87 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  88         [auto btree hash])
  89
  90 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  91 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
  92 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  93 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
  94
  95 dnl SLURPD OPTIONS
  96 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
  97 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  98
  99 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 100 AM_ENABLE_STATIC
 101 dnl AM_DISABLE_SHARED
 102 AM_ENABLE_SHARED
 103
 104 dnl General "enable" options
 105 # validate options
 106 if test $ol_enable_dns = yes ; then
 107         if test $ol_enable_referrals = no ; then
 108                 AC_MSG_ERROR([DNS requires --enable-referrals])
 109         fi
 110         if test $ol_enable_referrals = auto ; then
 111                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 112                 ol_enable_referrals=yes
 113         fi
 114 fi
 115
 116 if test $ol_enable_slapd = no ; then
 117         dnl SLAPD was specificallly disabled
 118         if test $ol_enable_bdb2 = yes ; then
 119                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 120         fi
 121         if test $ol_enable_ldbm = yes ; then
 122                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 123         fi
 124         if test $ol_enable_passwd = yes ; then
 125                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 126         fi
 127         if test $ol_enable_perl = yes ; then
 128                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 129         fi
 130         if test $ol_enable_shell = yes ; then
 131                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 132         fi
 133         if test $ol_enable_tcl = yes ; then
 134                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 135         fi
 136         if test $ol_enable_aclgroups = yes ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 138         fi
 139         if test $ol_enable_wrappers = yes ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 141         fi
 142         if test $ol_enable_phonetic = yes ; then
 143                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 144         fi
 145         if test $ol_enable_rlookups = yes ; then
 146                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 147         fi
 148         if test $ol_with_ldbm_api != auto ; then
 149                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 150         fi
 151         if test $ol_with_ldbm_type != auto ; then
 152                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 153         fi
 154         if test $ol_enable_slurpd = yes ; then
 155                 AC_MSG_ERROR([slurpd requires slapd])
 156         fi
 157
 158         # force settings to no
 159         ol_enable_bdb2=no
 160         ol_enable_ldbm=no
 161         ol_enable_passwd=no
 162         ol_enable_perl=no
 163         ol_enable_shell=no
 164         ol_enable_tcl=no
 165         ol_enable_aclgroups=no
 166         ol_enable_wrappers=no
 167         ol_enable_phonetic=no
 168         ol_enable_rlookups=no
 169         ol_with_ldbm_api=no
 170         ol_with_ldbm_type=no
 171         ol_enable_slurpd=no
 172
 173 elif test $ol_enable_ldbm = no ; then
 174         dnl SLAPD without LDBM
 175
 176         if test $ol_with_ldbm_api != auto ; then
 177                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 178         fi
 179
 180         if test $ol_with_ldbm_type != auto ; then
 181                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 182         fi
 183
 184         if test $ol_enable_bdb2 = yes ; then
 185                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 186         fi
 187
 188         if test $ol_enable_passwd = no -a \
 189                 $ol_enable_perl = no -a \
 190                 $ol_enable_shell = no -a \
 191                 $ol_enable_tcl = no ; then
 192                 AC_MSG_ERROR([slapd requires a backend])
 193         fi
 194
 195         ol_with_ldbm_api=no
 196         ol_with_ldbm_type=no
 197
 198 elif test $ol_enable_bdb2 = yes ; then
 199         dnl SLAPD with BDB2
 200
 201         if test $ol_with_ldbm_api != auto -a \
 202                 $ol_with_ldbm_api != db2 ; then
 203                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 204         fi
 205
 206         ol_with_ldbm_api=db2
 207
 208 else
 209         dnl SLAPD with LDBM
 210
 211         if test $ol_enable_bdb2 != no ; then
 212                 if test $ol_with_ldbm_api != auto -a \
 213                         $ol_with_ldbm_api != db2 ; then
 214                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 215                         ol_enable_bdb2=no
 216                 fi
 217         fi
 218
 219         if test $ol_with_ldbm_api = gdbm -a \
 220                 $ol_with_ldbm_type = btree ; then
 221                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 222         fi
 223         if test $ol_with_ldbm_api = mdbm -a \
 224                 $ol_with_ldbm_type = btree ; then
 225                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 226         fi
 227         if test $ol_with_ldbm_api = ndbm -a \
 228                 $ol_with_ldbm_type = btree ; then
 229                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 230         fi
 231 fi
 232
 233 if test $ol_enable_slurpd = yes ; then
 234         dnl SLURPD was specifically enabled
 235         if test $ol_with_threads = no ; then
 236                 AC_MSG_ERROR([slurpd requires threads])
 237         fi
 238 fi
 239
 240 AC_MSG_RESULT(done)
 241
 242 ## Initialize vars
 243 LDAP_LIBS=
 244 LDBM_LIBS=
 245 LTHREAD_LIBS=
 246 LUTIL_LIBS=
 247
 248 LDAPD_LIBS=
 249 SLAPD_LIBS=
 250 SLURPD_LIBS=
 251
 252 BUILD_LDAPD=no
 253 BUILD_SLAPD=no
 254 BUILD_SLURPD=no
 255
 256 BUILD_BDB2=no
 257 BUILD_LDBM=no
 258 BUILD_PASSWD=no
 259 BUILD_PERL=no
 260 BUILD_SHELL=no
 261 BUILD_TCL=no
 262 BUILD_THREAD=no
 263
 264 SLAPD_PERL_LDFLAGS=
 265 SLAPD_PERL_CPPFLAGS=
 266
 267 KRB_LIBS=
 268 READLINE_LIBS=
 269 TERMCAP_LIBS=
 270 TLS_LIBS=
 271
 272 dnl ----------------------------------------------------------------
 273 dnl Checks for programs
 274
 275 AC_PROG_INSTALL
 276
 277 dnl The default compiler is cc (NOT gcc)
 278 CC=${CC-"cc"}
 279 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 280 dnl CFLAGS=${CFLAGS-""}
 281
 282 AM_PROG_LIBTOOL
 283 dnl AC_PROG_MAKE_SET
 284
 285 AC_PROG_AWK
 286 OL_PROG_LN_H
 287 AC_PROG_LN_S
 288
 289 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 290         LN_S="$LN_H"
 291 fi
 292
 293 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 294         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 295 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 296 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 297
 298 if test $ol_enable_perl = yes ; then
 299         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 300
 301         if test "no$PERLBIN" = "no" ; then
 302                 ol_enable_perl=no
 303         fi
 304
 305         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 306         SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 307 fi
 308
 309 AC_PROG_CPP
 310
 311 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 312         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 313
 314 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 315         AC_MSG_WARN([programs compiled here do run here...])
 316         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 317
 318 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 319         AC_MSG_WARN([programs compiled here do not run here...])
 320         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 321 fi
 322
 323 dnl Checks for UNIX Variants
 324 AC_AIX
 325 AC_ISC_POSIX
 326 AC_MINIX
 327
 328 dnl BeOS requires -lbe -lroot
 329 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot"], :, [-lroot])
 330
 331 dnl Checks for system services
 332 AC_CYGWIN
 333 AC_MINGW32
 334 AC_EXEEXT
 335 AC_OBJEXT
 336
 337 dnl OpenLDAP requires STDC features
 338 AM_PROG_CC_STDC
 339 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 340         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 341 fi
 342
 343 dnl AM_C_PROTOTYPES
 344
 345 dnl Checks for libraries
 346
 347 dnl Find socket()
 348 dnl Likely combinations:
 349 dnl             -lsocket [ -lnsl_s | -lnsl ]
 350 dnl             -linet
 351
 352 AC_CHECK_FUNC(socket, :, [
 353 dnl
 354 dnl hopefully we won't include too many libraries
 355 dnl
 356         AC_CHECK_LIB(socket, main)
 357         AC_CHECK_LIB(net, main)
 358         AC_CHECK_LIB(nsl_s, main)
 359         AC_CHECK_LIB(nsl, main)
 360         AC_CHECK_LIB(inet, socket)
 361         AC_CHECK_LIB(gen, main)
 362 ])
 363
 364 dnl Check for resolver routines
 365 AC_CHECK_FUNCS(res_search)
 366 if test $ac_cv_func_res_search = "no" ; then
 367         AC_CHECK_LIB(bind, res_search)
 368         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 369                 AC_DEFINE(HAVE_RES_SEARCH,1)
 370         else
 371                 AC_CHECK_LIB(resolv, res_search)
 372                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 373                         AC_DEFINE(HAVE_RES_SEARCH,1)
 374                 fi
 375         fi
 376 fi
 377
 378 dnl HP-UX requires -lV3
 379 AC_CHECK_LIB(V3, sigset)
 380
 381 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 382
 383 dnl Select arg types
 384 dnl (if this detection becomes permenent, it and the select() detection
 385 dnl should be done before the yielding select test)
 386 AC_FUNC_SELECT_ARGTYPES
 387
 388 # ISODE tests
 389 ol_link_isode=no
 390 if test $ol_enable_ldapd != no ; then
 391         dnl look for ISODE libraries
 392         AC_CHECK_LIB(xtpp, main, [
 393                 ol_link_isode=yes
 394                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 395                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 396                 ],:,[-lxtdsap -lxtisode -losi])
 397         AC_CHECK_LIB(dsap, main, [
 398                 ol_link_isode=yes
 399                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 400                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 401                 ],:,[-lisode])
 402         AC_CHECK_LIB(isode, main, [
 403                 ol_link_isode=yes
 404                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 405                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 406                 ],:)
 407 fi
 408
 409 if test $ol_link_isode != no; then
 410         AC_CHECK_LIB(pp, main, [
 411                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 412                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 413                 ],:)
 414
 415         AC_PATH_PROG(PEPSY, pepsy)
 416 fi
 417
 418 dnl
 419 dnl check for kerberos
 420 dnl
 421 ol_link_kerberos=no
 422
 423 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 424         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 425
 426         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 427                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 428                         [-lkrb5 -ldes425])
 429
 430                 if test $have_k5 = yes ; then
 431                         ol_with_kerberos=found
 432                         ol_link_kerberos=yes
 433
 434                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 435
 436                         LIBS="$KRB_LIBS $LIBS"
 437
 438                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 439                                 [ol_cv_var_des_debug], [
 440                                 dnl save the flags
 441                                 save_LIBS="$LIBS"
 442                                 LIBS="$KRB_LIBS $LIBS"
 443                                 AC_TRY_LINK([
 444 #include <kerberosIV/krb.h>
 445 #include <kerberosIV/des.h>
 446 extern int des_debug;
 447 ],[
 448 des_debug = 1;
 449 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 450                                 dnl restore the LIBS
 451                                 LIBS="$save_LIBS"
 452                         ])
 453
 454                         if test $ol_cv_var_des_debug = yes ; then
 455                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 456                                         [define if you have Kerberos des_debug])
 457                         fi
 458
 459                         LIBS="$save_LIBS"
 460                 fi
 461         fi
 462 fi
 463
 464 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 465         AC_CHECK_HEADERS(krb.h des.h)
 466
 467         if test $ac_cv_header_krb_h = yes ; then
 468                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 469
 470                 if test $have_k4 = yes ; then
 471                         ol_with_kerberos=found
 472                         ol_link_kerberos=yes
 473
 474                         KRB_LIBS="-lkrb -ldes"
 475                 fi
 476         fi
 477 fi
 478
 479 if test $ol_link_kerberos = yes ; then
 480         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 481 fi
 482
 483 dnl
 484 dnl Check for SSL/TLS
 485 dnl
 486 ol_link_tls=no
 487 if test $ol_with_tls != no ; then
 488
 489         AC_CHECK_HEADERS(ssl.h)
 490
 491         if test $ac_cv_header_ssl_h = yes ; then
 492                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 493                         [have_ssleay=yes
 494                         need_rsaref=no],
 495                         [have_ssleay=no],
 496                         [-lcrypto])
 497
 498                 if test $have_ssleay = no ; then
 499                         AC_CHECK_LIB(ssl, ssl3_accept,
 500                                 [have_ssleay=yes
 501                                 need_rsaref=yes], [have_ssleay=no],
 502                                 [-lcrypto -lRSAglue -lrsaref])
 503                 fi
 504
 505                 if test $have_ssleay = yes ; then
 506                         ol_with_tls=found
 507                         ol_link_tls=yes
 508
 509                         AC_DEFINE(HAVE_SSLEAY, 1,
 510                                 [define if you have SSLeay or OpenSSL])
 511
 512                         if test $need_rsaref = yes; then
 513                                 AC_DEFINE(HAVE_RSAREF, 1,
 514                                         [define if you have RSAref])
 515
 516                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 517                         else
 518                                 TLS_LIBS="-lssl -lcrypto"
 519                         fi
 520                 fi
 521         fi
 522 fi
 523
 524 if test $ol_link_tls = yes ; then
 525         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 526 fi
 527
 528 dnl Tests for reentrant functions necessary to build a
 529 dnl thread_safe -lldap.
 530 AC_CHECK_FUNCS(         \
 531         ctime_r                 \
 532         gethostbyname_r gethostbyaddr_r \
 533 )
 534
 535 if test "$ac_cv_func_ctime_r" = no ; then
 536         ol_cv_func_ctime_r_nargs=0
 537 else
 538         OL_FUNC_CTIME_R_NARGS
 539 dnl     OL_FUNC_CTIME_R_TYPE
 540 fi
 541
 542 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 543         OL_FUNC_GETHOSTBYNAME_R_NARGS
 544 else
 545         ol_cv_func_gethostbyname_r_nargs=0
 546 fi
 547
 548 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 549         OL_FUNC_GETHOSTBYADDR_R_NARGS
 550 else
 551         ol_cv_func_gethostbyaddr_r_nargs=0
 552 fi
 553
 554 if test "$ac_cv_func_ctime_r" = yes \
 555         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 556         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 557         -a "$ac_cv_func_gethostbyname_r" = yes \
 558         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 559         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 560         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 561         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 562         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 563         ; then
 564
 565         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 566 fi
 567
 568 ol_link_threads=no
 569 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 570         -o $ol_with_threads = posix ; then
 571
 572         AC_CHECK_HEADERS(pthread.h sched.h)
 573
 574         if test $ac_cv_header_pthread_h = yes ; then
 575                 OL_POSIX_THREAD_VERSION
 576
 577                 if test $ol_cv_pthread_version = final ; then
 578                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 579                                 [define if pthreads API compatible with final spec])
 580                 elif test $ol_cv_pthread_version = draft4 ; then
 581                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 582                                 [define if pthreads API compatible with draft4 spec])
 583                 else
 584                         AC_MSG_ERROR([unknown pthread version])
 585                 fi
 586
 587                 # consider threads found
 588                 ol_with_threads=found
 589
 590                 OL_HEADER_LINUX_THREADS
 591
 592                 dnl Now the hard part, how to link?
 593                 dnl
 594                 dnl currently supported checks:
 595                 dnl
 596                 dnl Check for no flags
 597                 dnl     pthread_create() in $LIBS
 598                 dnl
 599                 dnl Check special pthread (final) flags
 600                 dnl     pthread_create() with -mt (Solaris)
 601                 dnl     pthread_create() with -kthread (FreeBSD)
 602                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 603                 dnl     pthread_create() with -pthreads (?)
 604                 dnl     pthread_create() with -thread (?)
 605                 dnl
 606                 dnl Check pthread (final) libraries
 607                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 608                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 609                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 610                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 611                 dnl     pthread_create() in -lpthread (many)
 612                 dnl     pthread_create() in -lc_r (FreeBSD)
 613                 dnl
 614                 dnl Check pthread (draft4) flags (depreciated)
 615                 dnl     pthread_create() with -threads (OSF/1)
 616                 dnl
 617                 dnl Check pthread (draft4) libraries (depreciated)
 618                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 619                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 620                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 621                 dnl     pthread_create() in -lpthreads (many)
 622                 dnl
 623
 624                 dnl pthread_create in $LIBS
 625                 AC_MSG_CHECKING([for pthread_create in default libraries])
 626                 AC_CACHE_VAL(ol_cv_pthread_create,[
 627                 AC_TRY_RUN([
 628 #include <pthread.h>
 629 #ifndef NULL
 630 #define NULL (void*)0
 631 #endif
 632
 633 static void *task(p)
 634         void *p;
 635 {
 636         return (void *) (p == NULL);
 637 }
 638
 639 int main(argc, argv)
 640         int argc;
 641         char **argv;
 642 {
 643         pthread_t t;
 644         int status;
 645
 646         /* make sure pthread_create() isn't just a stub */
 647 #if HAVE_PTHREADS_D4
 648         status = pthread_create(&t, pthread_attr_default, task, NULL);
 649 #else
 650         status = pthread_create(&t, NULL, task, NULL);
 651 #endif
 652
 653         if( status ) return status;
 654
 655         /* make sure pthread_detach() isn't just a stub */
 656 #if HAVE_PTHREADS_D4
 657         status = pthread_detach( &t );
 658 #else
 659         status = pthread_detach( t );
 660 #endif
 661
 662         if( status ) return status;
 663
 664         return status;
 665 }
 666 ],
 667                         [ol_cv_pthread_create=yes],
 668                         [ol_cv_pthread_create=no],
 669                         [dnl assume yes
 670                         ol_cv_pthread_create=yes])])
 671                 AC_MSG_RESULT($ol_cv_pthread_create)
 672
 673                 if test $ol_cv_pthread_create != no ; then
 674                         ol_link_threads=posix
 675                         ol_link_pthreads=""
 676                 fi
 677
 678                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 679                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 680                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 681                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 682                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 683
 684                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 685                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 686                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 687                         [ol_cv_pthread_lpthread_lmach_lexc])
 688 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 689 dnl                     [ol_cv_pthread_lpthread_lexc])
 690
 691                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 692                         [ol_cv_pthread_lib_lpthread_woff])
 693
 694                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 695                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 696
 697                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 698
 699                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 700                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 701                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 702                         [ol_cv_pthread_lpthreads_lmach_lexc])
 703                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 704                         [ol_cv_pthread_lpthreads_lexc])
 705
 706                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 707
 708                 if test $ol_link_threads != no ; then
 709                         AC_DEFINE(HAVE_PTHREADS,1,
 710                                 [define if you have POSIX Threads])
 711
 712                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 713
 714                         dnl save flags
 715                         save_CPPFLAGS="$CPPFLAGS"
 716                         save_LIBS="$LIBS"
 717                         LIBS="$LTHREAD_LIBS $LIBS"
 718
 719                         dnl All POSIX Thread (final) implementations should have
 720                         dnl sched_yield instead of pthread yield.
 721                         dnl check for both
 722                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 723
 724                         if test $ac_cv_func_sched_yield = no -a \
 725                                 $ac_cv_func_pthread_yield = no ; then
 726                                 dnl Digital UNIX has sched_yield() in -lrt
 727                                 AC_CHECK_LIB(rt, sched_yield,
 728                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 729                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 730                                         ac_cv_func_sched_yield=yes],
 731                                         [ac_cv_func_sched_yield=no])
 732                         fi
 733                         if test $ac_cv_func_sched_yield = no -a \
 734                                 $ac_cv_func_pthread_yield = no ; then
 735                                 dnl Solaris has sched_yield() in -lposix4
 736                                 dnl but we'll use thr_yield instead.
 737                                 AC_CHECK_FUNCS(thr_yield)
 738                         fi
 739                         if test $ac_cv_func_sched_yield = no -a \
 740                                 $ac_cv_func_pthread_yield = no -a \
 741                                 "$ac_cv_func_thr_yield" = no ; then
 742                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 743                         fi
 744
 745                         dnl Check functions for compatibility
 746                         AC_CHECK_FUNCS(pthread_kill)
 747
 748                         dnl Check for pthread_detach with <pthread.h> inclusion
 749                         dnl as it's symbol may have been mangled.
 750                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 751                                 [ol_cv_func_pthread_detach], [
 752                                 dnl save the flags
 753                                 AC_TRY_LINK([
 754 #include <pthread.h>
 755 #ifndef NULL
 756 #define NULL (void*)0
 757 #endif
 758 ],
 759                                         [pthread_detach(NULL);],
 760                                         [ol_cv_func_pthread_detach=yes],
 761                                         [ol_cv_func_pthread_detach=no])
 762                         ])
 763
 764                         if test $ol_cv_func_pthread_detach = no ; then
 765                                 AC_MSG_ERROR([could not locate pthread_detach()])
 766                         fi
 767
 768                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 769                                 [define if you have pthread_detach function])
 770
 771                         dnl Check for setconcurreny functions
 772                         AC_CHECK_FUNCS( \
 773                                 pthread_setconcurrency \
 774                                 pthread_getconcurrency \
 775                                 thr_setconcurrency \
 776                                 thr_getconcurrency \
 777                         )
 778
 779                         OL_SYS_LINUX_THREADS
 780                         OL_LINUX_THREADS
 781
 782                         if test $ol_cv_linux_threads = error; then
 783                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 784                         fi
 785
 786                         AC_MSG_CHECKING([if pthread_create() works])
 787                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 788                         AC_TRY_RUN([
 789 #include <pthread.h>
 790 #ifndef NULL
 791 #define NULL (void*)0
 792 #endif
 793
 794 static void *task(p)
 795         void *p;
 796 {
 797         return (void *) (p == NULL);
 798 }
 799
 800 int main(argc, argv)
 801         int argc;
 802         char **argv;
 803 {
 804         pthread_t t;
 805 #if HAVE_PTHREADS_D4
 806         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 807 #else
 808         exit(pthread_create(&t, NULL, task, NULL));
 809 #endif
 810 }
 811 ],
 812                                 [ol_cv_pthread_create_works=yes],
 813                                 [ol_cv_pthread_create_works=no],
 814                                 [dnl assume yes
 815                                 ol_cv_pthread_create_works=yes])])
 816                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 817
 818                         if test $ol_cv_pthread_create_works = no ; then
 819                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 820                         fi
 821
 822                         dnl Check if select causes an yield
 823                         if test $ol_with_yielding_select = auto ; then
 824                                 AC_MSG_CHECKING([if select yields when using pthreads])
 825                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 826                                 AC_TRY_RUN([
 827 #include <sys/types.h>
 828 #include <sys/time.h>
 829 #include <unistd.h>
 830 #include <pthread.h>
 831 #ifndef NULL
 832 #define NULL (void*) 0
 833 #endif
 834
 835 static int fildes[2];
 836
 837 static void *task(p)
 838         void *p;
 839 {
 840         int i;
 841         struct timeval tv;
 842
 843         fd_set rfds;
 844
 845         tv.tv_sec=10;
 846         tv.tv_usec=0;
 847
 848         FD_ZERO(&rfds);
 849         FD_SET(fildes[0], &rfds);
 850
 851         /* we're not interested in any fds */
 852         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 853
 854         if(i < 0) {
 855                 perror("select");
 856                 exit(10);
 857         }
 858
 859         exit(0); /* if we exit here, the select blocked the whole process */
 860 }
 861
 862 int main(argc, argv)
 863         int argc;
 864         char **argv;
 865 {
 866         pthread_t t;
 867
 868         /* create a pipe to select */
 869         if(pipe(&fildes[0])) {
 870                 perror("select");
 871                 exit(1);
 872         }
 873
 874 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 875         (void) pthread_setconcurrency(2);
 876 #else
 877 #ifdef HAVE_THR_SETCONCURRENCY
 878         /* Set Solaris LWP concurrency to 2 */
 879         thr_setconcurrency(2);
 880 #endif
 881 #endif
 882
 883 #if HAVE_PTHREADS_D4
 884         pthread_create(&t, pthread_attr_default, task, NULL);
 885 #else
 886         pthread_create(&t, NULL, task, NULL);
 887 #endif
 888
 889 #if HAVE_SCHED_YIELD
 890         sched_yield();  /* make sure task runs first */
 891 #else
 892 #ifdef HAVE_PTHREAD_YIELD
 893         pthread_yield();        /* make sure task runs first */
 894 #endif
 895 #endif
 896
 897         exit(2);
 898 }],
 899                                 [ol_cv_pthread_select_yields=no],
 900                                 [ol_cv_pthread_select_yields=yes], [
 901                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 902                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 903
 904                                 if test $ol_cv_pthread_select_yields = yes ; then
 905                                         ol_with_yielding_select=yes
 906                                 fi
 907                         fi
 908
 909                         dnl restore flags
 910                         CPPFLAGS="$save_CPPFLAGS"
 911                         LIBS="$save_LIBS"
 912                 else
 913                         AC_MSG_ERROR([could not link with POSIX Threads])
 914                 fi
 915         fi
 916
 917         if test $ol_with_threads = posix ; then
 918                 AC_MSG_ERROR([could not locate POSIX Threads])
 919         fi
 920 fi
 921
 922 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 923         -o $ol_with_threads = mach ; then
 924
 925         dnl check for Mach CThreads
 926         AC_CHECK_HEADERS(mach/cthreads.h)
 927         if test $ac_cv_header_mach_cthreads_h = yes ; then
 928                 ol_with_threads=found
 929
 930                 dnl check for cthread support in current $LIBS
 931                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 932
 933                 if test $ol_link_threads = no ; then
 934                         dnl try -all_load
 935                         dnl this test needs work
 936                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 937                                 [ol_cv_cthread_all_load], [
 938                                 dnl save the flags
 939                                 save_LIBS="$LIBS"
 940                                 LIBS="-all_load $LIBS"
 941                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 942                                         cthread_fork((void *)0, (void *)0);
 943                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 944                                 dnl restore the LIBS
 945                                 LIBS="$save_LIBS"
 946                         ])
 947
 948                         if test $ol_cv_cthread_all_load = yes ; then
 949                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 950                                 ol_link_threads=mach
 951                         fi
 952                 fi
 953
 954                 if test $ol_link_threads != no ; then
 955                         : check for cthread specific functionality here
 956                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
 957                                 [define if you have Mach Cthreads])
 958                 else
 959                         AC_MSG_ERROR([could not link with Mach CThreads])
 960                 fi
 961         fi
 962
 963         if test $ol_with_threads = mach ; then
 964                 AC_MSG_ERROR([could not locate Mach CThreads])
 965         fi
 966 fi
 967
 968 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 969         -o $ol_with_threads = lwp ; then
 970
 971         dnl check for SunOS5 LWP
 972         AC_CHECK_HEADERS(thread.h synch.h)
 973         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 974                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
 975
 976                 if test $have_thr = yes ; then
 977                         AC_DEFINE(HAVE_THR,1,
 978                                 [if you have Solaris LWP (thr) package])
 979                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
 980                         ol_link_threads=thr
 981
 982                         if test $ol_with_yielding_select = auto ; then
 983                                 ol_with_yielding_select=yes
 984                         fi
 985
 986                         dnl Check for setconcurreny functions
 987                         AC_CHECK_FUNCS( \
 988                                 thr_setconcurrency \
 989                                 thr_getconcurrency \
 990                         )
 991                 fi
 992         fi
 993
 994         dnl check for SunOS4 LWP
 995         AC_CHECK_HEADERS(lwp/lwp.h)
 996         if test $ac_cv_header_lwp_lwp_h = yes ; then
 997                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 998
 999                 if test $have_lwp = yes ; then
1000                         AC_DEFINE(HAVE_LWP,1,
1001                                 [if you have SunOS LWP package])
1002                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1003                         ol_link_threads=lwp
1004
1005                         if test $ol_with_yielding_select = auto ; then
1006                                 ol_with_yielding_select=no
1007                         fi
1008                 fi
1009         fi
1010 fi
1011
1012 if test $ol_with_yielding_select = yes ; then
1013         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1014                 [define if select implicitly yields])
1015 fi
1016
1017 if test $ol_with_threads = manual ; then
1018         dnl User thinks he can manually configure threads.
1019         ol_link_threads=yes
1020
1021         AC_MSG_WARN([thread defines and link options must be set manually])
1022
1023         AC_CHECK_HEADERS(pthread.h sched.h)
1024         AC_CHECK_FUNCS(sched_yield pthread_yield)
1025         OL_HEADER_LINUX_THREADS
1026
1027         AC_CHECK_HEADERS(mach/cthreads.h)
1028         AC_CHECK_HEADERS(lwp/lwp.h)
1029         AC_CHECK_HEADERS(thread.h synch.h)
1030 fi
1031
1032 if test $ol_link_threads != no ; then
1033         dnl needed to get reentrant/threadsafe versions
1034         dnl
1035         AC_DEFINE(REENTRANT,1)
1036         AC_DEFINE(_REENTRANT,1)
1037         AC_DEFINE(THREAD_SAFE,1)
1038         AC_DEFINE(_THREAD_SAFE,1)
1039         AC_DEFINE(THREADSAFE,1)
1040         AC_DEFINE(_THREADSAFE,1)
1041
1042         dnl The errno declaration may dependent upon _REENTRANT.
1043         dnl If it does, we must link with thread support.
1044         AC_CACHE_CHECK([for thread specific errno],
1045                 [ol_cv_errno_thread_specific], [
1046                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1047                         [ol_cv_errno_thread_specific=yes],
1048                         [ol_cv_errno_thread_specific=no])
1049         ])
1050
1051         if test $ol_cv_errno_thread_specific != yes ; then
1052                 LIBS="$LTHREAD_LIBS $LIBS"
1053                 LTHREAD_LIBS=""
1054         fi
1055
1056 dnl When in thread environment, use
1057 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1058 dnl                     || defined( HAVE_FUNC_R )
1059 dnl                     func_r(...);
1060 dnl             #else
1061 dnl             #       if defined( HAVE_THREADS )
1062 dnl                             /* lock */
1063 dnl             #       endif
1064 dnl                             func(...);
1065 dnl             #       if defined( HAVE_THREADS )
1066 dnl                             /* unlock */
1067 dnl             #       endif
1068 dnl             #endif
1069 dnl
1070 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1071 dnl             _POSIX_REENTRANT_FUNCTIONS
1072 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1073 dnl             _POSIX_THREADSAFE_FUNCTIONS
1074 dnl
1075 dnl             and is currently defined in lthread.h
1076 dnl
1077 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1078 dnl
1079 dnl libldap/*.c should only include <lthread.h> iff
1080 dnl LDAP_R_COMPILE is defined.  ie:
1081 dnl             #ifdef LDAP_R_COMPILE
1082 dnl             #       include LDAP_R_COMPILE
1083 dnl             #endif
1084 dnl
1085 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
1086 dnl specifically for compiling the threadsafe version of
1087 dnl     the ldap library (-lldap_r).
1088 dnl
1089 dnl     dnl check for reentrant/threadsafe functions
1090 dnl     dnl
1091 dnl     dnl note: these should only be used when linking
1092 dnl     dnl       with $LTHREAD_LIBS
1093 dnl     dnl
1094 dnl     save_CPPFLAGS="$CPPFLAGS"
1095 dnl     save_LIBS="$LIBS"
1096 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1097 dnl     AC_CHECK_FUNCS( \
1098 dnl             gmtime_r \
1099 dnl             gethostbyaddr_r gethostbyname_r \
1100 dnl             feof_unlocked unlocked_feof \
1101 dnl             putc_unlocked unlocked_putc \
1102 dnl             flockfile ftrylockfile \
1103 dnl     )
1104 dnl     CPPFLAGS="$save_CPPFLAGS"
1105 dnl     LIBS="$save_LIBS"
1106 fi
1107
1108 if test $ol_link_threads = no ; then
1109         if test $ol_with_threads = yes ; then
1110                 AC_MSG_ERROR([no suitable thread support])
1111         fi
1112
1113         if test $ol_with_threads = auto ; then
1114                 AC_MSG_WARN([no suitable thread support, disabling threads])
1115                 ol_with_threads=no
1116         fi
1117
1118         AC_DEFINE(NO_THREADS,1,
1119                 [define if you have (or want) no threads])
1120         LTHREAD_LIBS=""
1121 fi
1122
1123 if test $ol_link_threads != no ; then
1124         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1125 fi
1126
1127 dnl ----------------------------------------------------------------
1128
1129 ol_link_ldbm=no
1130 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1131         OL_BERKELEY_DB2
1132
1133         if test $ol_cv_berkeley_db2 = yes ; then
1134                 ol_link_ldbm=db2
1135                 ol_with_ldbm_api=db2
1136
1137                 if test $ol_with_ldbm_type = hash ; then
1138                         AC_DEFINE(LDBM_USE_DBHASH,1)
1139                 else
1140                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1141                 fi
1142
1143                 dnl $ol_cv_lib_db2 should be yes or -ldb
1144                 dnl (it could be no, but that would be an error
1145                 if test $ol_cv_lib_db2 != yes ; then
1146                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1147                 fi
1148         fi
1149 fi
1150
1151 ol_link_bdb2=no
1152 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1153         ol_link_bdb2=yes
1154 fi
1155
1156 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1157         OL_BERKELEY_DB
1158
1159         if test $ol_cv_berkeley_db = yes ; then
1160                 ol_link_ldbm=db
1161                 ol_with_ldbm_api=db
1162
1163                 if test $ol_with_ldbm_type = hash ; then
1164                         AC_DEFINE(LDBM_USE_DBHASH,1)
1165                 else
1166                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1167                 fi
1168
1169                 dnl $ol_cv_lib_db should be yes or -ldb
1170                 dnl (it could be no, but that would be an error
1171                 if test $ol_cv_lib_db != yes ; then
1172                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1173                 fi
1174         fi
1175 fi
1176
1177 if test $ol_with_ldbm_api = manual ; then
1178         dnl User thinks he can manually configure LDBM api.
1179         ol_link_ldbm=yes
1180
1181         AC_MSG_WARN([LDBM defines and link options must be set manually])
1182
1183         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1184 fi
1185
1186 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1187         AC_MSG_WARN(Could not find LDBM with BTREE support)
1188         ol_with_ldbm_api=none
1189 fi
1190
1191 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1192         OL_MDBM
1193
1194         if test $ol_cv_mdbm = yes ; then
1195                 ol_link_ldbm=mdbm
1196                 ol_with_ldbm_api=mdbm
1197                 if test $ol_cv_lib_mdbm != yes ; then
1198                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1199                 fi
1200         fi
1201 fi
1202
1203 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1204         OL_GDBM
1205
1206         if test $ol_cv_gdbm = yes ; then
1207                 ol_link_ldbm=gdbm
1208                 ol_with_ldbm_api=gdbm
1209
1210                 if test $ol_cv_lib_gdbm != yes ; then
1211                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1212                 fi
1213         fi
1214 fi
1215
1216 if test $ol_with_ldbm_api = auto ; then
1217         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1218 elif test $ol_with_ldbm_api = ndbm ; then
1219         OL_NDBM
1220
1221         if test $ol_cv_ndbm = yes ; then
1222                 ol_link_ldbm=ndbm
1223                 ol_with_ldbm_api=ndbm
1224
1225                 if test $ol_cv_lib_ndbm != yes ; then
1226                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1227                 fi
1228         fi
1229 fi
1230
1231 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1232         AC_MSG_WARN(could not find suitable LDBM backend)
1233         if test $ol_enable_ldbm = yes ; then
1234                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1235         fi
1236
1237         AC_MSG_WARN(disabling LDBM)
1238         ol_enable_ldbm=no
1239 fi
1240
1241 if test $ol_enable_wrappers != no ; then
1242         AC_CHECK_HEADERS(tcpd.h)
1243
1244         if test $ac_cv_header_tcpd_h != yes ; then
1245                 have_wrappers=no
1246         else
1247                 AC_CHECK_LIB(wrap, main,
1248                         [have_wrappers=yes], [have_wrappers=no])
1249         fi
1250
1251         if test $have_wrappers = yes ; then
1252                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1253                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1254         else
1255                 AC_MSG_WARN(could not find -lwrap)
1256                 if test $ol_enable_wrappers = yes ; then
1257                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1258                 fi
1259
1260                 AC_MSG_WARN(disabling wrappers support)
1261                 ol_enable_wrappers=no
1262         fi
1263 fi
1264
1265 if test $ol_enable_syslog != no ; then
1266         AC_CHECK_FUNC(openlog)
1267         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1268                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1269         fi
1270         ol_enable_syslog=$ac_cv_func_openlog
1271 fi
1272
1273 if test $ol_enable_dmalloc != no ; then
1274         AC_CHECK_HEADERS(dmalloc.h)
1275         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1276 fi
1277
1278 if test $ol_enable_tcl != no ; then
1279         AC_CHECK_HEADERS(tcl.h)
1280
1281         if test $ac_cv_header_tcl_h != yes ; then
1282                 have_tcl=no
1283         else
1284                 AC_CHECK_LIB(tcl,main,
1285                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1286                         [have_tcl=no])
1287
1288                 if test $have_tcl != yes; then
1289                         AC_CHECK_LIB(tcl7.6,main,
1290                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1291                                 [have_tcl=no])
1292                 fi
1293
1294                 if test $have_tcl != yes; then
1295                         AC_CHECK_LIB(tcl8.0,main,
1296                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1297                                 [have_tcl=no])
1298                 fi
1299         fi
1300
1301         if test $have_tcl != yes ; then
1302                 AC_MSG_WARN([could not find -ltcl])
1303                 if test $ol_enable_tcl = yes ; then
1304                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1305                 fi
1306
1307                 ol_enable_tcl=no
1308         fi
1309 fi
1310
1311 # ud needs termcap (should insert check here)
1312 ol_link_termcap=no
1313 AC_CHECK_HEADERS(termcap.h ncurses.h)
1314
1315 if test $ol_link_termcap = no ; then
1316         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1317         if test $have_termcap = yes ; then
1318                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1319                 ol_link_termcap=yes
1320                 TERMCAP_LIBS=-ltermcap
1321         fi
1322 fi
1323
1324 if test $ol_link_termcap = no ; then
1325         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1326         if test $have_ncurses = yes ; then
1327                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1328                 ol_link_termcap=yes
1329                 TERMCAP_LIBS=-lncurses
1330         fi
1331 fi
1332
1333 if test $ol_link_termcap = no ; then
1334         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1335         TERMCAP_LIBS=
1336 fi
1337
1338 dnl
1339 dnl Check for GNU readline
1340 dnl
1341 ol_link_readline=no
1342 if test $ol_with_readline != no ; then
1343         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1344
1345         if test $ac_cv_header_readline_readline_h = yes ; then
1346                 save_LIBS="$LIBS"
1347                 LIBS="$TERMCAP_LIBS $LIBS"
1348                 AC_CHECK_LIB(readline, readline,
1349                         [have_readline=yes], [have_readline=no])
1350                 LIBS="$save_LIBS"
1351
1352                 if test $have_readline = yes ; then
1353                         ol_with_readline=found
1354                         ol_link_readline=yes
1355
1356                         READLINE_LIBS="-lreadline"
1357                 fi
1358         fi
1359 fi
1360
1361 if test $ol_link_readline = yes ; then
1362         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1363 fi
1364
1365
1366 # FreeBSD (and others) have crypt(3) in -lcrypt
1367 if test $ol_enable_crypt != no ; then
1368         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1369                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1370                         have_crypt=yes], [have_crypt=no])])
1371
1372         if test $have_crypt = yes ; then
1373                 AC_DEFINE(HAVE_CRYPT,1)
1374         else
1375                 AC_MSG_WARN(could not find crypt)
1376                 if test $ol_enable_crypt = yes ; then
1377                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1378                 fi
1379
1380                 AC_MSG_WARN(disabling crypt support)
1381                 ol_enable_crypt=no
1382         fi
1383 fi
1384
1385 # FreeBSD (and others) have setproctitle(3) in -lutil
1386 if test $ol_enable_proctitle != no ; then
1387         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1388                 AC_CHECK_LIB(util, setproctitle,
1389                         [have_setproctitle=yes
1390                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1391                         [have_setproctitle=no
1392                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1393
1394         if test $have_setproctitle = yes ; then
1395                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1396         fi
1397 fi
1398
1399 dnl ----------------------------------------------------------------
1400 dnl Checks for header files.
1401 OL_HEADER_STDC
1402
1403 if test $ol_cv_header_stdc != yes; then
1404         AC_MSG_WARN([could not locate Standard C compliant headers])
1405 fi
1406
1407 AC_HEADER_DIRENT
1408 AC_HEADER_SYS_WAIT
1409 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1410 if test $am_cv_sys_posix_termios = yes ; then
1411         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1412                 [define if you have POSIX termios])
1413 fi
1414
1415 AC_CHECK_HEADERS(       \
1416         arpa/inet.h             \
1417         arpa/nameser.h  \
1418         assert.h                \
1419         crypt.h                 \
1420         errno.h                 \
1421         fcntl.h                 \
1422         filio.h                 \
1423         getopt.h                \
1424         grp.h                   \
1425         libutil.h               \
1426         limits.h                \
1427         locale.h                \
1428         malloc.h                \
1429         memory.h                \
1430         regex.h                 \
1431         psap.h                  \
1432         pwd.h                   \
1433         resolv.h                \
1434         sgtty.h                 \
1435         stdarg.h                \
1436         stddef.h                \
1437         string.h                \
1438         strings.h               \
1439         sysexits.h              \
1440         sys/file.h              \
1441         sys/filio.h             \
1442         sys/errno.h             \
1443         sys/ioctl.h             \
1444         sys/param.h             \
1445         sys/resource.h  \
1446         sys/socket.h    \
1447         sys/syslog.h    \
1448         sys/time.h              \
1449         sys/types.h             \
1450         syslog.h                \
1451         termios.h               \
1452         unistd.h                \
1453 )
1454
1455 dnl ----------------------------------------------------------------
1456 dnl Checks for typedefs, structures, and compiler characteristics.
1457 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1458 AC_TYPE_MODE_T
1459 AC_TYPE_OFF_T
1460 AC_TYPE_PID_T
1461 AM_TYPE_PTRDIFF_T
1462 AC_TYPE_SIGNAL
1463 OL_TYPE_SIG_ATOMIC_T
1464 AC_TYPE_SIZE_T
1465 AC_STRUCT_ST_BLKSIZE
1466 AC_HEADER_TIME
1467 AC_STRUCT_TM
1468 OL_STRUCT_PASSWD_PW_GECOS
1469
1470 OL_C_UPPER_LOWER
1471 AC_C_CONST
1472 OL_C_VOLATILE
1473
1474 if test $cross_compiling = yes ; then
1475         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1476 else
1477         AC_C_BIGENDIAN
1478         AC_CHECK_SIZEOF(short)
1479         AC_CHECK_SIZEOF(int)
1480         AC_CHECK_SIZEOF(long)
1481 fi
1482
1483 dnl ----------------------------------------------------------------
1484 dnl Checks for library functions.
1485 AC_FUNC_MEMCMP
1486 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1487 AC_FUNC_STRFTIME
1488 dnl AM_FUNC_STRTOD
1489 dnl AC_FUNC_VFORK
1490 AC_FUNC_VPRINTF
1491
1492 if test $ac_cv_func_vprintf = yes ; then
1493         dnl check for vsnprintf
1494         AC_CHECK_FUNCS(vsnprintf vsprintf)
1495 fi
1496
1497 AC_CHECK_FUNCS(         \
1498         bcopy                   \
1499         endgrent                \
1500         endpwent                \
1501         flock                   \
1502         getdtablesize           \
1503         getgrgid                \
1504         gethostname             \
1505         getpass                 \
1506         getpwuid                \
1507         gettimeofday            \
1508         lockf                   \
1509         memcpy                  \
1510         memmove                 \
1511         mkstemp                 \
1512         recv                    \
1513         recvfrom                \
1514         setpwfile               \
1515         setsid                  \
1516         signal                  \
1517         sigset                  \
1518         snprintf                \
1519         strdup                  \
1520         strerror                \
1521         strpbrk                 \
1522         strrchr                 \
1523         strsep                  \
1524         strstr                  \
1525         strtol                  \
1526         strtoul                 \
1527         strspn                  \
1528         sysconf                 \
1529         waitpid                 \
1530         wait4                   \
1531 )
1532
1533 dnl We actually may need to replace more than this.
1534 AC_REPLACE_FUNCS(getopt tempnam)
1535
1536 dnl ----------------------------------------------------------------
1537 # Check Configuration
1538 OL_SYS_ERRLIST
1539
1540 dnl ----------------------------------------------------------------
1541 dnl Check our declaration of strdup()
1542 OL_DECL_STRDUP
1543
1544 dnl ----------------------------------------------------------------
1545 dnl Sort out defines
1546
1547 if test "$ol_enable_debug" != no ; then
1548         AC_DEFINE(LDAP_DEBUG,1)
1549 fi
1550 if test "$ol_enable_syslog" = yes ; then
1551         AC_DEFINE(LDAP_SYSLOG,1)
1552 fi
1553 if test "$ol_enable_libui" = yes ; then
1554         AC_DEFINE(LDAP_LIBUI,1)
1555 fi
1556 if test "$ol_enable_cache" = no ; then
1557         AC_DEFINE(LDAP_NOCACHE,1)
1558 fi
1559 if test "$ol_enable_dns" != no ; then
1560         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1561 fi
1562 if test "$ol_enable_proctitle" != no ; then
1563         AC_DEFINE(LDAP_PROCTITLE,1)
1564 fi
1565 if test "$ol_enable_referrals" != no ; then
1566         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1567 fi
1568 if test "$ol_enable_cldap" != no ; then
1569         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1570 fi
1571
1572 if test "$ol_enable_aclgroups" != no ; then
1573         AC_DEFINE(SLAPD_ACLGROUPS,1)
1574 fi
1575 if test "$ol_enable_crypt" != no ; then
1576         AC_DEFINE(SLAPD_CRYPT,1)
1577 fi
1578 if test "$ol_enable_cleartext" != no ; then
1579         AC_DEFINE(SLAPD_CLEARTEXT,1)
1580 fi
1581 if test "$ol_enable_phonetic" != no ; then
1582         AC_DEFINE(SLAPD_PHONETIC,1)
1583 fi
1584 if test "$ol_enable_rlookups" != no ; then
1585         AC_DEFINE(SLAPD_RLOOKUPS,1)
1586 fi
1587
1588 if test "$ol_link_bdb2" != no ; then
1589         AC_DEFINE(SLAPD_BDB2,1)
1590         BUILD_SLAPD=yes
1591         BUILD_BDB2=yes
1592 fi
1593
1594 if test "$ol_link_ldbm" != no ; then
1595         AC_DEFINE(SLAPD_LDBM,1)
1596         BUILD_SLAPD=yes
1597         BUILD_LDBM=yes
1598 fi
1599
1600 if test "$ol_enable_passwd" != no ; then
1601         AC_DEFINE(SLAPD_PASSWD,1)
1602         BUILD_SLAPD=yes
1603         BUILD_PASSWD=yes
1604 fi
1605
1606 if test "$ol_enable_perl" != no ; then
1607         AC_DEFINE(SLAPD_PERL,1)
1608         BUILD_SLAPD=yes
1609         BUILD_PERL=yes
1610 fi
1611
1612 if test "$ol_enable_shell" != no ; then
1613         AC_DEFINE(SLAPD_SHELL,1)
1614         BUILD_SLAPD=yes
1615         BUILD_SHELL=yes
1616 fi
1617
1618 if test "$ol_enable_tcl" != no ; then
1619         AC_DEFINE(SLAPD_TCL,1)
1620         BUILD_SLAPD=yes
1621         BUILD_TCL=yes
1622 fi
1623
1624 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1625         $BUILD_SLAPD = yes ; then
1626         BUILD_SLURPD=yes
1627 fi
1628
1629 if test "$ol_link_isode" != no ; then
1630         BUILD_LDAPD=yes
1631 fi
1632
1633 dnl ----------------------------------------------------------------
1634
1635 AC_SUBST(BUILD_LDAPD)
1636 AC_SUBST(BUILD_SLAPD)
1637   AC_SUBST(BUILD_BDB2)
1638   AC_SUBST(BUILD_LDBM)
1639   AC_SUBST(BUILD_PASSWD)
1640   AC_SUBST(BUILD_PERL)
1641   AC_SUBST(BUILD_SHELL)
1642   AC_SUBST(BUILD_TCL)
1643 AC_SUBST(BUILD_SLURPD)
1644
1645 AC_SUBST(LDAP_LIBS)
1646 AC_SUBST(LDAPD_LIBS)
1647 AC_SUBST(SLAPD_LIBS)
1648 AC_SUBST(SLURPD_LIBS)
1649 AC_SUBST(LDBM_LIBS)
1650 AC_SUBST(LTHREAD_LIBS)
1651 AC_SUBST(LUTIL_LIBS)
1652
1653 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1654 AC_SUBST(SLAPD_PERL_LDFLAGS)
1655
1656 AC_SUBST(KRB_LIBS)
1657 AC_SUBST(READLINE_LIBS)
1658 AC_SUBST(TERMCAP_LIBS)
1659 AC_SUBST(TLS_LIBS)
1660
1661 dnl ----------------------------------------------------------------
1662 dnl final output
1663 dnl
1664
1665 AC_OUTPUT( \
1666 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1667 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1668 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1669 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1670 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1671 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1672 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1673 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1674 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1675 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1676 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1677 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1678 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1679 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1680 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1681 include/Makefile:build/top.mk:include/Makefile.in \
1682 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1683 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1684 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1685 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1686 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1687 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1688 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1689 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1690 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1691 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1692 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1693 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1694 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1695 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1696 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1697 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1698 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1699 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1700 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1701 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1702 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1703 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1704 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1705 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1706 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1707 ,[
1708 date > stamp-h
1709 echo Please \"make depend\" to build dependencies
1710 ])