git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Restrictions apply, see COPYRIGHT and LICENSE files."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version.sh)dnl
  35
  36 # set unset (borrowed from autoconf 2.14a)
  37 if (unset FOO) >/dev/null 2>&1; then
  38   ol_unset=unset
  39 else
  40   ol_unset=false
  41 fi
  42 # unset CDPATH
  43 $ol_unset CDPATH || test "${CDPATH+set}" != set || CDPATH=: && export CDPATH
  44
  45 AC_CONFIG_AUX_DIR(build)dnl
  46
  47 eval `$ac_aux_dir/version.sh`
  48 if test -z "$OL_STRING"; then
  49         AC_MSG_ERROR([could not determine version])
  50 fi
  51
  52 echo "Configuring $OL_STRING ..."
  53
  54 dnl Determine host platform
  55 dnl             we try not to use this for much
  56 AC_CANONICAL_SYSTEM
  57
  58 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  59 AC_SUBST(PACKAGE)
  60 AC_SUBST(VERSION)
  61 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  62 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  63
  64 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  65 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  66 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  67 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  68
  69 OPENLDAP_LIBVERSION=$OL_API_LIB
  70 AC_SUBST(OPENLDAP_LIBVERSION)
  71
  72 dnl We use autoconf features new to 2.13.
  73 dnl aclocal.m4 should be built using aclocal from automake 1.4
  74 dnl libtool 1.3.3 should be installed.
  75 AC_PREREQ(2.13)dnl Required Autoconf version
  76
  77 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  78
  79 dnl ================================================================
  80 dnl Start Args
  81 AC_MSG_CHECKING(configure arguments)
  82 AC_PREFIX_DEFAULT(/usr/local)
  83
  84 top_builddir=`pwd`
  85 AC_SUBST(top_builddir)dnl
  86
  87 dnl ----------------------------------------------------------------
  88 dnl --with-subdir
  89 ldap_subdir="/openldap"
  90
  91 AC_ARG_WITH(subdir,
  92 [  --with-subdir=DIR change default subdirectory used for installs],
  93 [case "$withval" in
  94         no) ldap_subdir=""
  95                 ;;
  96         yes)
  97                 ;;
  98         /*|\\*)
  99                 ldap_subdir="$withval"
 100                 ;;
 101         *)
 102                 ldap_subdir="/$withval"
 103                 ;;
 104 esac
 105 ])dnl
 106
 107 AC_SUBST(ldap_subdir)dnl
 108
 109 dnl ----------------------------------------------------------------
 110 dnl General "enable" options
 111 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes)dnl
 112 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 113 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 114 OL_ARG_ENABLE(cache,[  --enable-cache     enable caching], yes)dnl
 115 OL_ARG_ENABLE(referrals,[  --enable-referrals     enable V2 Referrals extension], yes)dnl
 116 OL_ARG_ENABLE(kbind,[  --enable-kbind     enable V2 Kerberos IV bind], no)dnl
 117 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 118 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 119 OL_ARG_ENABLE(x_compile,[  --enable-x-compile     enable cross compiling],
 120         no, [yes no])dnl
 121
 122 dnl ----------------------------------------------------------------
 123 dnl General "with" options
 124 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc     enable debug malloc support], no)dnl
 125
 126 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 127         auto, [auto yes no] )
 128 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch URL support],
 129         auto, [auto yes no] )
 130 OL_ARG_WITH(kerberos,[  --with-kerberos   with support],
 131         auto, [auto k5 k5only k425 kth k4 afs yes no])
 132 OL_ARG_WITH(readline,[  --with-readline   with readline support],
 133         auto, [auto yes no] )
 134 OL_ARG_WITH(threads,[  --with-threads     with threads],
 135         auto, [auto nt posix mach pth lwp yes no manual] )
 136 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 137         auto, [auto ssleay openssl yes no] )
 138 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 139         auto, [auto yes no manual] )
 140
 141 dnl ----------------------------------------------------------------
 142 dnl Server options
 143 dnl ----------------------------------------------------------------
 144
 145 dnl ----------------------------------------------------------------
 146 dnl SLAPD OPTIONS
 147 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 148 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 149 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 150 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], auto)dnl
 151 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd       enable Kerberos password verification], no)dnl
 152 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 153 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 154 OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 155 OL_ARG_ENABLE(phonetic,[    --enable-phonetic     enable phonetic/soundex], no)dnl
 156 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups], auto)dnl
 157 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs], no)dnl
 158 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 159 OL_ARG_ENABLE(dynamic,[    --enable-dynamic       enable linking built binaries with dynamic libs], no)dnl
 160
 161 dnl SLAPD Backend options
 162 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend], no)dnl
 163 OL_ARG_WITH(dnssrv_module,[    --with-dnssrv-module  module type], static,
 164         [static dynamic])
 165 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend], no)dnl
 166 OL_ARG_WITH(ldap_module,[    --with-ldap-module   module type], static,
 167         [static dynamic])
 168 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend], yes)dnl
 169 OL_ARG_WITH(ldbm_api,[    --with-ldbm-api       with LDBM API], auto,
 170         [auto berkeley bcompat mdbm gdbm])
 171 OL_ARG_WITH(ldbm_module,[    --with-ldbm-module   module type], static,
 172         [static dynamic])
 173 OL_ARG_WITH(ldbm_type,[    --with-ldbm-type       use LDBM type], auto,
 174         [auto btree hash])
 175 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend], no)dnl
 176 OL_ARG_WITH(passwd_module,[    --with-passwd-module  module type], static,
 177         [static dynamic])
 178 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend], no)dnl
 179 OL_ARG_WITH(perl_module,[    --with-perl-module   module type], static,
 180         [static dynamic])
 181 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend], no)dnl
 182 OL_ARG_WITH(shell_module,[    --with-shell-module         module type], static,
 183         [static dynamic])
 184 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend], no)dnl
 185 OL_ARG_WITH(sql_module,[    --with-sql-module     module type], static,
 186         [static dynamic])
 187 OL_ARG_ENABLE(tcl,[    --enable-tcl       enable tcl backend], no)dnl
 188 OL_ARG_WITH(tcl_module,[    --with-tcl-module     module type], static,
 189         [static dynamic])
 190
 191 dnl ----------------------------------------------------------------
 192 dnl SLURPD OPTIONS
 193 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 194 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 195
 196 dnl ----------------------------------------------------------------
 197 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 198 AC_ENABLE_STATIC
 199 dnl AC_DISABLE_SHARED
 200 AC_ENABLE_SHARED
 201
 202 dnl ----------------------------------------------------------------
 203
 204 dnl General "enable" options
 205 # validate options
 206 if test $ol_enable_slapd = no ; then
 207         dnl SLAPD was specificallly disabled
 208         if test $ol_enable_dnssrv = yes ; then
 209                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 210         fi
 211         if test $ol_enable_ldap = yes ; then
 212                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 213         fi
 214         if test $ol_enable_ldbm = yes ; then
 215                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 216         fi
 217         if test $ol_enable_passwd = yes ; then
 218                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 219         fi
 220         if test $ol_enable_perl = yes ; then
 221                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 222         fi
 223         if test $ol_enable_shell = yes ; then
 224                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 225         fi
 226         if test $ol_enable_tcl = yes ; then
 227                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 228         fi
 229         if test $ol_enable_sql = yes ; then
 230                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 231         fi
 232         if test $ol_enable_modules = yes ; then
 233                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 234         fi
 235         if test $ol_enable_multimaster = yes ; then
 236                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 237         fi
 238         if test $ol_enable_wrappers = yes ; then
 239                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 240         fi
 241         if test $ol_enable_phonetic = yes ; then
 242                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 243         fi
 244         if test $ol_enable_rlookups = yes ; then
 245                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 246         fi
 247         if test $ol_enable_aci = yes ; then
 248                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 249         fi
 250         if test $ol_with_ldbm_api != auto ; then
 251                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 252         fi
 253         if test $ol_with_ldbm_type != auto ; then
 254                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 255         fi
 256         if test $ol_with_dnssrv_module != static ; then
 257                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 258         fi
 259         if test $ol_with_ldap_module != static ; then
 260                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 261         fi
 262         if test $ol_with_ldbm_module != static ; then
 263                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 264         fi
 265         if test $ol_with_passwd_module != static ; then
 266                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 267         fi
 268         if test $ol_with_perl_module != static ; then
 269                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 270         fi
 271         if test $ol_with_shell_module != static ; then
 272                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 273         fi
 274         if test $ol_with_tcl_module != static ; then
 275                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 276         fi
 277         if test $ol_with_sql_module != static ; then
 278                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 279         fi
 280         if test $ol_enable_slurpd = yes ; then
 281                 AC_MSG_ERROR([slurpd requires slapd])
 282         fi
 283
 284         # force settings to no
 285         ol_enable_dnssrv=no
 286         ol_enable_ldap=no
 287         ol_enable_ldbm=no
 288         ol_enable_passwd=no
 289         ol_enable_perl=no
 290         ol_enable_shell=no
 291         ol_enable_tcl=no
 292         ol_enable_sql=no
 293
 294         ol_enable_modules=no
 295         ol_enable_multimaster=no
 296         ol_enable_phonetic=no
 297         ol_enable_rlookups=no
 298         ol_enable_aci=no
 299         ol_enable_wrappers=no
 300         ol_enable_dynamic=no
 301
 302         ol_with_ldbm_api=no
 303         ol_with_ldbm_type=no
 304
 305         ol_with_dnssrv_module=static
 306         ol_with_ldap_module=static
 307         ol_with_ldbm_module=static
 308         ol_with_passwd_module=static
 309         ol_with_perl_module=static
 310         ol_with_shell_module=static
 311         ol_with_tcl_module=static
 312         ol_with_sql_module=static
 313
 314         ol_enable_slurpd=no
 315
 316 elif test $ol_enable_ldbm = no ; then
 317         dnl SLAPD without LDBM
 318
 319         if test $ol_with_ldbm_api != auto ; then
 320                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 321         fi
 322
 323         if test $ol_with_ldbm_type != auto ; then
 324                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 325         fi
 326
 327         if test $ol_with_ldbm_module != static ; then
 328                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 329         fi
 330
 331         if test $ol_enable_modules != yes -a \
 332                 $ol_enable_dnssrv = no -a \
 333                 $ol_enable_ldap = no -a \
 334                 $ol_enable_passwd = no -a \
 335                 $ol_enable_perl = no -a \
 336                 $ol_enable_shell = no -a \
 337                 $ol_enable_sql = no -a \
 338                 $ol_enable_tcl = no ; then
 339                 AC_MSG_ERROR([slapd requires a backend])
 340         fi
 341
 342         ol_with_ldbm_api=no
 343         ol_with_ldbm_type=no
 344         ol_with_ldbm_module=static
 345
 346 else
 347         dnl SLAPD with LDBM
 348         if test $ol_with_ldbm_api = gdbm -a \
 349                 $ol_with_ldbm_type = btree ; then
 350                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 351         fi
 352         if test $ol_with_ldbm_api = mdbm -a \
 353                 $ol_with_ldbm_type = btree ; then
 354                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 355         fi
 356         if test $ol_with_ldbm_api = ndbm -a \
 357                 $ol_with_ldbm_type = btree ; then
 358                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 359         fi
 360 fi
 361
 362 if test $ol_enable_slurpd = yes ; then
 363         dnl SLURPD was specifically enabled
 364         if test $ol_with_threads = no ; then
 365                 AC_MSG_ERROR([slurpd requires threads])
 366         fi
 367 fi
 368
 369 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 370         if test $ol_with_kerberos = no ; then
 371                 AC_MSG_ERROR([options require --with-kerberos])
 372         fi
 373         ol_with_kerberos=yes
 374 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 375         if test $ol_with_kerberos != no -a $ol_with_kerberos != auto ; then
 376                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 377         fi
 378         ol_with_kerberos=no
 379 fi
 380
 381 if test $ol_enable_spasswd = yes ; then
 382         if test $ol_with_cyrus_sasl = no ; then
 383                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 384         fi
 385         ol_link_spasswd=yes
 386 fi
 387
 388 AC_MSG_RESULT(done)
 389
 390 dnl ----------------------------------------------------------------
 391 dnl Initialize vars
 392 LDAP_LIBS=
 393 LDIF_LIBS=
 394 LDBM_LIBS=
 395 LTHREAD_LIBS=
 396 LUTIL_LIBS=
 397
 398 SLAPD_LIBS=
 399 SLURPD_LIBS=
 400
 401 BUILD_SLAPD=no
 402 BUILD_SLURPD=no
 403
 404 BUILD_THREAD=no
 405
 406 BUILD_DNSSRV=no
 407 BUILD_LDAP=no
 408 BUILD_LDBM=no
 409 BUILD_PASSWD=no
 410 BUILD_PERL=no
 411 BUILD_SHELL=no
 412 BUILD_SQL=no
 413 BUILD_TCL=no
 414
 415 BUILD_DNSSRV_DYNAMIC=static
 416 BUILD_LDAP_DYNAMIC=static
 417 BUILD_LDBM_DYNAMIC=static
 418 BUILD_PASSWD_DYNAMIC=static
 419 BUILD_PERL_DYNAMIC=static
 420 BUILD_SHELL_DYNAMIC=static
 421 BUILD_TCL_DYNAMIC=static
 422 BUILD_SQL_DYNAMIC=static
 423
 424 SLAPD_MODULES_LDFLAGS=
 425 SLAPD_MODULES_CPPFLAGS=
 426 SLAPD_MODULES_LIST=
 427
 428 SLAPD_PERL_LDFLAGS=
 429 MOD_PERL_LDFLAGS=
 430 PERL_CPPFLAGS=
 431
 432 SLAPD_SQL_LDFLAGS=
 433 SLAPD_SQL_LIBS=
 434 SLAPD_SQL_INCLUDES=
 435
 436 MOD_TCL_LIB=
 437 KRB4_LIBS=
 438 KRB5_LIBS=
 439 READLINE_LIBS=
 440 SASL_LIBS=
 441 TERMCAP_LIBS=
 442 TLS_LIBS=
 443 MODULES_LIBS=
 444 AUTH_LIBS=
 445
 446 dnl ================================================================
 447 dnl Checks for programs
 448
 449 dnl AC_PROG_INSTALL
 450
 451 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 452
 453 dnl ----------------------------------------------------------------
 454 dnl
 455 dnl Determine which C translator to use
 456 dnl
 457
 458 dnl AIX Thread requires we use cc_r or xlc_r.
 459 dnl But only do this IF AIX and CC is not set
 460 dnl and threads are auto|yes|posix.
 461 dnl
 462 dnl If we find cc_r|xlc_r, force pthreads and assume
 463 dnl             pthread_create is in $LIBS (ie: don't bring in
 464 dnl             any additional thread libraries)
 465 dnl If we do not find cc_r|xlc_r, disable threads
 466
 467 ol_aix_threads=no
 468 case "$target" in
 469 *-*-aix*) dnl all AIX is not a good idea.
 470         if test -z "$CC" ; then
 471                 case "$ol_with_threads" in
 472                 auto | yes |  posix) ol_aix_threads=yes ;;
 473                 esac
 474         fi
 475 ;;
 476 esac
 477
 478 if test $ol_aix_threads = yes ; then
 479         if test -z "${CC}" ; then
 480                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 481
 482                 if test "$CC" = cc ; then
 483                         dnl no CC! don't allow --with-threads
 484                         if test $ol_with_threads != auto ; then
 485                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 486                         else
 487                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 488                         fi
 489                         ol_with_threads=no
 490                 fi
 491         fi
 492
 493         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 494                 ol_with_threads=posix
 495                 ol_cv_pthread_create=yes
 496         fi
 497 fi
 498
 499 if test -z "${CC}"; then
 500         AC_CHECK_PROGS(CC,cc)
 501 fi
 502
 503 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 504 dnl (for now, let autoconf sort this out)
 505 dnl CFLAGS=${CFLAGS-""}
 506
 507 AC_LIBTOOL_WIN32_DLL
 508 AC_LIBTOOL_DLOPEN
 509 AC_PROG_LIBTOOL
 510
 511 AC_PROG_AWK
 512 OL_PROG_LN_H
 513 AC_PROG_LN_S
 514
 515 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 516         LN_S="$LN_H"
 517 fi
 518
 519 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 520         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 521 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 522 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 523
 524 dnl ----------------------------------------------------------------
 525 dnl Perl
 526 ol_link_perl=no
 527 if test $ol_enable_perl != no ; then
 528         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 529
 530         if test "no$PERLBIN" = "no" ; then
 531                 if test $ol_enable_perl = yes ; then
 532                         AC_MSG_ERROR([could not locate perl])
 533                 fi
 534
 535         else
 536                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 537                 if test x"$ol_with_perl_module" = "xstatic" ; then
 538                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 539                 else
 540                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 541                 fi
 542                 dnl should check perl version
 543                 ol_link_perl=yes
 544         fi
 545 fi
 546
 547 AC_PROG_CPP
 548
 549 dnl ----------------------------------------------------------------
 550 dnl Cross compiling checks
 551 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 552         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 553
 554 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 555         AC_MSG_WARN([programs compiled here do run here...])
 556         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 557
 558 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 559         AC_MSG_WARN([programs compiled here do not run here...])
 560         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 561 fi
 562
 563 dnl ----------------------------------------------------------------
 564 dnl Checks for UNIX Variants
 565 AC_AIX
 566 AC_ISC_POSIX
 567 AC_MINIX
 568
 569 dnl ----------------------------------------------------------------
 570 dnl Checks for system services
 571 AC_CYGWIN
 572 AC_MINGW32
 573 AC_EXEEXT
 574 AC_OBJEXT
 575
 576 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 577
 578 dnl ----------------------------------------------------------------
 579 dnl BeOS requires -lbe -lroot -lnet
 580 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 581
 582 dnl ----------------------------------------------------------------
 583 dnl OpenLDAP requires STDC features
 584 AM_PROG_CC_STDC
 585 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 586         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 587 fi
 588
 589 dnl ----------------------------------------------------------------
 590 dnl Check cc depend flags
 591 OL_MKDEPEND
 592 if test "${ol_cv_mkdep}" = no ; then
 593         # this will soon become an error
 594         AC_MSG_WARN([do not know how to generate dependencies])
 595 fi
 596
 597 dnl ----------------------------------------------------------------
 598 dnl Check for AIX security library
 599 AC_CHECK_LIB(s, afopen, [
 600         AUTH_LIBS=-ls
 601         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 602 ])
 603
 604
 605 dnl ----------------------------------------------------------------
 606 dnl PF_INET6 support requires getaddrinfo
 607 dnl PF_LOCAL may use getaddrinfo in available
 608 AC_CHECK_FUNCS( getaddrinfo )
 609
 610 if test $ac_cv_func_getaddrinfo = no ; then
 611         if test $ol_enable_ipv6 = yes ; then
 612                 AC_MSG_ERROR([IPv6 support requires getaddrinfo()])
 613         fi
 614         ol_enable_ipv6=no
 615 fi
 616
 617 if test $ol_enable_local != no ; then
 618         AC_CHECK_HEADERS( sys/un.h )
 619
 620         if test $ol_enable_local = auto ; then
 621                 ol_enable_local=$ac_cv_header_sys_un_h
 622         elif test $ac_cv_header_sys_un_h = no ; then
 623                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
 624         fi
 625 fi
 626
 627 dnl ----------------------------------------------------------------
 628 dnl Check for module support
 629 ol_link_modules=no
 630 if test $ol_enable_modules != no ; then
 631         AC_CHECK_HEADERS(ltdl.h)
 632
 633         if test $ac_cv_header_ltdl_h = no ; then
 634                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 635         fi
 636
 637         AC_CHECK_LIB(ltdl, lt_dlinit, [
 638             MODULES_LIBS=-lltdl
 639             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 640         ])
 641
 642         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 643                 AC_MSG_ERROR([could not locate libtool -lltdl])
 644         fi
 645         ol_link_modules=yes
 646 else
 647         ol_with_dnssrv_module=static
 648         ol_with_ldap_module=static
 649         ol_with_ldbm_module=static
 650         ol_with_passwd_module=static
 651         ol_with_perl_module=static
 652         ol_with_shell_module=static
 653         ol_with_tcl_module=static
 654         ol_with_sql_module=static
 655 fi
 656
 657 dnl ----------------------------------------------------------------
 658 dnl Checks for header files.
 659 OL_HEADER_STDC
 660
 661 if test $ol_cv_header_stdc != yes; then
 662         AC_MSG_WARN([could not locate Standard C compliant headers])
 663 fi
 664
 665 AC_HEADER_DIRENT
 666 AC_HEADER_SYS_WAIT
 667 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 668 if test $am_cv_sys_posix_termios = yes ; then
 669         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 670                 [define if you have POSIX termios])
 671 fi
 672
 673 AC_CHECK_HEADERS(       \
 674         arpa/inet.h             \
 675         arpa/nameser.h  \
 676         assert.h                \
 677         conio.h                 \
 678         crypt.h                 \
 679         direct.h                \
 680         errno.h                 \
 681         fcntl.h                 \
 682         filio.h                 \
 683         getopt.h                \
 684         grp.h                   \
 685         io.h                    \
 686         libutil.h               \
 687         limits.h                \
 688         locale.h                \
 689         netinet/tcp.h   \
 690         malloc.h                \
 691         memory.h                \
 692         psap.h                  \
 693         pwd.h                   \
 694         process.h               \
 695         resolv.h                \
 696         sgtty.h                 \
 697         shadow.h                \
 698         stddef.h                \
 699         string.h                \
 700         strings.h               \
 701         sysexits.h              \
 702         sys/file.h              \
 703         sys/filio.h             \
 704         sys/errno.h             \
 705         sys/ioctl.h             \
 706         sys/param.h             \
 707         sys/resource.h  \
 708         sys/select.h    \
 709         sys/socket.h    \
 710         sys/syslog.h    \
 711         sys/time.h              \
 712         sys/types.h             \
 713         syslog.h                \
 714         termios.h               \
 715         unistd.h                \
 716         winsock.h               \
 717 )
 718
 719
 720 dnl ----------------------------------------------------------------
 721 dnl Checks for libraries
 722
 723 dnl HP-UX requires -lV3
 724 AC_CHECK_LIB(V3, sigset)
 725
 726 dnl Gotta check for winsock manually
 727 if test $ac_cv_header_winsock_h = yes; then
 728         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 729         AC_TRY_LINK([#include <winsock.h>],[
 730                         socket(0,0,0);
 731                         select(0,NULL,NULL,NULL,NULL);
 732                         closesocket(0);
 733                         gethostname(NULL,0);
 734         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 735
 736         if test $ol_cv_winsock = yes ; then
 737                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 738                 ac_cv_func_socket=yes
 739                 ac_cv_func_select=yes
 740                 ac_cv_func_closesocket=yes
 741                 ac_cv_func_gethostname=yes
 742         fi
 743 fi
 744
 745 dnl Find socket()
 746 dnl Likely combinations:
 747 dnl             -lsocket [ -lnsl_s | -lnsl ]
 748 dnl             -linet
 749
 750 AC_CHECK_FUNC(socket, :, [
 751 dnl hopefully we won't include too many libraries
 752         AC_CHECK_LIB(socket, main)
 753         AC_CHECK_LIB(net, main)
 754         AC_CHECK_LIB(nsl_s, main)
 755         AC_CHECK_LIB(nsl, main)
 756         AC_CHECK_LIB(inet, socket)
 757         AC_CHECK_LIB(gen, main)
 758 ])
 759
 760 dnl require select
 761 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 762
 763 if test "${ac_cv_header_winsock_h}" != yes; then
 764     dnl Select arg types
 765     dnl (if this detection becomes permenent, it and the select() detection
 766     dnl should be done before the yielding select test)
 767     AC_FUNC_SELECT_ARGTYPES
 768 fi
 769
 770 dnl check to see if system call automatically restart
 771 dnl AC_SYS_RESTARTABLE_SYSCALLS
 772
 773 dnl ----------------------------------------------------------------
 774 dnl require POSIX regex
 775 AC_CHECK_HEADERS( regex.h )
 776 if test "$ac_cv_header_regex_h" != yes ; then
 777         AC_MSG_ERROR([POSIX regex.h required.])
 778 fi
 779 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 780
 781 OL_POSIX_REGEX
 782 if test "$ol_cv_c_posix_regex" = no ; then
 783         AC_MSG_ERROR([broken POSIX regex!])
 784 fi
 785
 786 dnl ----------------------------------------------------------------
 787 dnl Check for resolver routines
 788 ol_link_dnssrv=no
 789 AC_CHECK_FUNC(res_query,:)
 790 if test $ac_cv_func_res_query = no ; then
 791         AC_CHECK_LIB(bind, res_query)
 792         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 793 fi
 794
 795 if test $ac_cv_func_res_query = no ; then
 796         AC_CHECK_LIB(bind, __res_query)
 797         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 798 fi
 799
 800 if test $ac_cv_func_res_query = no ; then
 801         AC_CHECK_LIB(resolv, res_query)
 802         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 803 fi
 804
 805 if test "$ac_cv_func_res_query" = yes ; then
 806         AC_DEFINE(HAVE_RES_QUERY,1,
 807                 [define if you have res_query()])
 808
 809         if test $ol_enable_dnssrv != no ; then
 810                 ol_link_dnssrv=yes
 811         fi
 812 fi
 813
 814 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 815         AC_MSG_ERROR([DNSSRV requires res_query()])
 816 fi
 817
 818 dnl ----------------------------------------------------------------
 819 dnl Kerberos
 820 ol_link_kbind=no
 821 ol_link_kpasswd=no
 822 ol_link_krb5=no
 823 ol_link_krb4=no
 824
 825 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 826         -o $ol_with_kerberos = k5 -o $ol_with_kerberos = k5only \
 827         -o $ol_with_kerberos = k425 ; then
 828
 829         AC_CHECK_HEADERS(krb5.h)
 830
 831         if test $ac_cv_header_krb5_h = yes ; then
 832                 dnl lazy check for Heimdal Kerberos
 833                 AC_CHECK_HEADERS(heim_err.h)
 834                 if test $ac_cv_header_heim_err_h = yes ; then
 835                         krb5_impl=heimdal
 836                 else
 837                         krb5_impl=mit
 838                 fi
 839
 840                 if test $krb5_impl = mit; then
 841                         AC_CHECK_LIB(krb5, main,
 842                                 [have_krb5=yes
 843                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 844                                 [have_krb5=no],
 845                                 [-lcrypto -lcom_err])
 846
 847                 elif test $krb5_impl = heimdal; then
 848                         AC_CHECK_LIB(krb5, main,
 849                                 [have_krb5=yes
 850                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 851                                 [have_krb5=no],
 852                                 [-ldes -lasn1 -lroken -lcom_err])
 853
 854                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 855                                 [define if you have HEIMDAL Kerberos])
 856                 else
 857                         have_krb5=no
 858                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 859                 fi
 860
 861                 if test $have_krb5 = yes ; then
 862                         ol_link_krb5=yes
 863
 864                         AC_DEFINE(HAVE_KRB5, 1,
 865                                 [define if you have Kerberos V])
 866
 867                         if test $ol_enable_kpasswd != no ; then
 868                                 ol_link_kpasswd=yes;
 869                         fi
 870
 871                         if test $ol_with_kerberos = k5only ; then
 872                                 ol_with_kerberos=found
 873                         fi
 874
 875                 elif test $ol_with_kerberos != auto ; then
 876                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 877                 fi
 878
 879         fi
 880 fi
 881
 882 if test $ol_link_krb5 = yes -a \( $ol_with_kerberos = yes -o \
 883         $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 884
 885         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 886
 887         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 888                 if test $krb5_impl = mit; then
 889                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 890                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 891                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 892
 893                 elif test $krb5_impl = heimdal; then
 894                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 895                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 896                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 897
 898                 else
 899                         have_425=no
 900                         AC_MSG_WARN([Unrecongized Kerberos V Implementation])
 901                 fi
 902
 903                 if test $have_k425 = yes ; then
 904                         ol_with_kerberos=found
 905                         ol_link_krb4=yes
 906
 907                         AC_DEFINE(HAVE_KRB425, 1,
 908                                 [define if you have Kerberos V with IV support])
 909                         AC_DEFINE(HAVE_KRB4, 1,
 910                                 [define if you have Kerberos IV])
 911
 912                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 913                                 [ol_cv_var_des_debug], [
 914                                 dnl save the flags
 915                                 save_LIBS="$LIBS"
 916                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 917                                 AC_TRY_LINK([
 918 #include <kerberosIV/krb.h>
 919 #include <kerberosIV/des.h>
 920 extern int des_debug;
 921 ],[
 922 des_debug = 1;
 923 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 924                                 dnl restore the LIBS
 925                                 LIBS="$save_LIBS"
 926                         ])
 927
 928                         if test $ol_cv_var_des_debug = yes ; then
 929                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 930                                         [define if you have Kerberos des_debug])
 931                         fi
 932
 933                         LIBS="$save_LIBS"
 934                 fi
 935         fi
 936 fi
 937
 938 if test $ol_link_krb5 = yes ; then
 939         ol_with_kerberos=found
 940 fi
 941
 942 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 943         -o $ol_with_kerberos = k4 -o $ol_with_kerberos = kth ; then
 944
 945         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 946
 947         if test $ac_cv_header_krb_h = yes ; then
 948                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 949
 950                 if test $have_k4 = yes ; then
 951                         ol_with_kerberos=found
 952                         ol_link_krb4=yes
 953
 954                         AC_DEFINE(HAVE_KRB4, 1,
 955                                 [define if you have Kerberos IV])
 956
 957                         KRB4_LIBS="-lkrb -ldes"
 958
 959                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 960                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 961                                         [define if you have Kth Kerberos])
 962                         fi
 963                 fi
 964         fi
 965 fi
 966
 967 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 968         ol_link_kpasswd=yes
 969 fi
 970
 971 if test $ol_link_krb4 = yes -a $ol_enable_kbind != no ; then
 972         ol_link_kbind=yes
 973
 974 elif test $ol_enable_kbind = yes ; then
 975         AC_MSG_ERROR([Kerberos IV detection failed])
 976 fi
 977
 978 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 979         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 980
 981 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 982         AC_MSG_ERROR([Kerberos detection failed])
 983 fi
 984
 985 dnl ----------------------------------------------------------------
 986 dnl TLS/SSL
 987 ol_link_tls=no
 988 if test $ol_with_tls != no ; then
 989         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 990
 991         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 992                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 993                         [have_ssleay=yes
 994                         need_rsaref=no],
 995                         [have_ssleay=no],
 996                         [-lcrypto])
 997
 998                 if test $have_ssleay = no ; then
 999                         AC_CHECK_LIB(ssl, SSL_library_init,
1000                                 [have_ssleay=yes
1001                                 need_rsaref=no], [have_ssleay=no],
1002                                 [-lcrypto])
1003                 fi
1004
1005                 if test $have_ssleay = no ; then
1006                         AC_CHECK_LIB(ssl, ssl3_accept,
1007                                 [have_ssleay=yes
1008                                 need_rsaref=yes], [have_ssleay=no],
1009                                 [-lcrypto -lRSAglue -lrsaref])
1010                 fi
1011
1012                 if test $have_ssleay = yes ; then
1013                         ol_with_tls=found
1014                         ol_link_tls=yes
1015
1016                         AC_DEFINE(HAVE_SSLEAY, 1,
1017                                 [define if you have SSLeay or OpenSSL])
1018
1019                         if test $need_rsaref = yes; then
1020                                 AC_DEFINE(HAVE_RSAREF, 1,
1021                                         [define if you have RSAref])
1022
1023                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1024                         else
1025                                 TLS_LIBS="-lssl -lcrypto"
1026                         fi
1027                 fi
1028         fi
1029
1030 else
1031         AC_WARN([TLS privacy protection not supported!])
1032 fi
1033
1034 if test $ol_link_tls = yes ; then
1035         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1036
1037 elif test $ol_with_tls = auto ; then
1038         AC_WARN([Could not locate TLS/SSL package])
1039         AC_WARN([TLS privacy protection not supported!])
1040
1041 elif test $ol_with_tls != no ; then
1042         AC_ERROR([Could not locate TLS/SSL package])
1043 fi
1044
1045 dnl ----------------------------------------------------------------
1046 dnl Tests for reentrant functions necessary to build a
1047 dnl thread_safe -lldap.
1048 AC_CHECK_FUNCS(         \
1049         ctime_r                 \
1050         gethostbyname_r gethostbyaddr_r \
1051 )
1052
1053 if test "$ac_cv_func_ctime_r" = no ; then
1054         ol_cv_func_ctime_r_nargs=0
1055 else
1056         OL_FUNC_CTIME_R_NARGS
1057 dnl     OL_FUNC_CTIME_R_TYPE
1058 fi
1059
1060 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1061         OL_FUNC_GETHOSTBYNAME_R_NARGS
1062 else
1063         ol_cv_func_gethostbyname_r_nargs=0
1064 fi
1065
1066 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1067         OL_FUNC_GETHOSTBYADDR_R_NARGS
1068 else
1069         ol_cv_func_gethostbyaddr_r_nargs=0
1070 fi
1071
1072 if test "$ac_cv_func_ctime_r" = yes \
1073         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1074         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1075         -a "$ac_cv_func_gethostbyname_r" = yes \
1076         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1077         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1078         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1079         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1080         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1081         ; then
1082
1083         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1084 fi
1085
1086 dnl ----------------------------------------------------------------
1087 dnl Threads?
1088 ol_link_threads=no
1089
1090 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1091         -o $ol_with_threads = nt ; then
1092
1093         OL_NT_THREADS
1094
1095         if test "$ol_cv_nt_threads" = yes ; then
1096         ol_link_threads=nt
1097         ol_with_threads=found
1098         ol_with_yielding_select=yes
1099
1100                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1101                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1102         fi
1103
1104         if test $ol_with_threads = nt ; then
1105                 AC_MSG_ERROR([could not locate NT Threads])
1106         fi
1107 fi
1108
1109 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1110         -o $ol_with_threads = posix ; then
1111
1112         AC_CHECK_HEADERS(pthread.h)
1113
1114         if test $ac_cv_header_pthread_h = yes ; then
1115                 OL_POSIX_THREAD_VERSION
1116
1117                 if test $ol_cv_pthread_version = final ; then
1118                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1119                                 [define if pthreads API compatible with final spec])
1120                 elif test $ol_cv_pthread_version = draft4 ; then
1121                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1122                                 [define if pthreads API compatible with draft4 spec])
1123                 else
1124                         AC_MSG_ERROR([unknown pthread version])
1125                 fi
1126
1127                 # consider threads found
1128                 ol_with_threads=found
1129
1130                 OL_HEADER_LINUX_THREADS
1131                 OL_HEADER_GNU_PTH_PTHREAD_H
1132
1133                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1134                         AC_CHECK_HEADERS(sched.h)
1135                 fi
1136
1137                 dnl Now the hard part, how to link?
1138                 dnl
1139                 dnl currently supported checks:
1140                 dnl
1141                 dnl Check for no flags
1142                 dnl     pthread_create() in $LIBS
1143                 dnl
1144                 dnl Check special pthread (final) flags
1145                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1146                 dnl     pthread_create() with -kthread (FreeBSD)
1147                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1148                 dnl     pthread_create() with -pthreads (?)
1149                 dnl     pthread_create() with -mthreads (AIX)
1150                 dnl     pthread_create() with -thread (?)
1151                 dnl
1152                 dnl Check pthread (final) libraries
1153                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1154                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1155                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1156                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1157                 dnl     pthread_create() in -lpthread (many)
1158                 dnl     pthread_create() in -lc_r (FreeBSD)
1159                 dnl
1160                 dnl Check pthread (draft4) flags (depreciated)
1161                 dnl     pthread_create() with -threads (OSF/1)
1162                 dnl
1163                 dnl Check pthread (draft4) libraries (depreciated)
1164                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1165                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1166                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1167                 dnl     pthread_create() in -lpthreads (many)
1168                 dnl
1169
1170                 dnl pthread_create in $LIBS
1171                 AC_CACHE_CHECK([for pthread_create in default libraries],
1172                         ol_cv_pthread_create,[
1173                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1174                         [ol_cv_pthread_create=yes],
1175                         [ol_cv_pthread_create=no],
1176                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1177                                 [ol_cv_pthread_create=yes],
1178                                 [ol_cv_pthread_create=no])])])
1179
1180                 if test $ol_cv_pthread_create != no ; then
1181                         ol_link_threads=posix
1182                         ol_link_pthreads=""
1183                 fi
1184
1185 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1186                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1187                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1188                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1189                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1190                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1191
1192                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1193                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1194                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1195                         [ol_cv_pthread_lpthread_lmach_lexc])
1196 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1197 dnl                     [ol_cv_pthread_lpthread_lexc])
1198
1199                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1200                         [ol_cv_pthread_lib_lpthread_woff])
1201
1202                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1203                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1204
1205                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1206
1207                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1208                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1209                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1210                         [ol_cv_pthread_lpthreads_lmach_lexc])
1211                 OL_PTHREAD_TRY([-lpthreads -lexc],
1212                         [ol_cv_pthread_lpthreads_lexc])
1213
1214                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1215
1216                 if test $ol_link_threads != no ; then
1217                         AC_DEFINE(HAVE_PTHREADS,1,
1218                                 [define if you have POSIX Threads])
1219
1220                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1221
1222                         dnl save flags
1223                         save_CPPFLAGS="$CPPFLAGS"
1224                         save_LIBS="$LIBS"
1225                         LIBS="$LTHREAD_LIBS $LIBS"
1226
1227                         dnl All POSIX Thread (final) implementations should have
1228                         dnl sched_yield instead of pthread yield.
1229                         dnl check for both
1230                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1231
1232                         if test $ac_cv_func_sched_yield = no -a \
1233                                 $ac_cv_func_pthread_yield = no ; then
1234                                 dnl Digital UNIX has sched_yield() in -lrt
1235                                 AC_CHECK_LIB(rt, sched_yield,
1236                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1237                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1238                                                 [Define if you have the sched_yield function.])
1239                                         ac_cv_func_sched_yield=yes],
1240                                         [ac_cv_func_sched_yield=no])
1241                         fi
1242                         if test $ac_cv_func_sched_yield = no -a \
1243                                 $ac_cv_func_pthread_yield = no ; then
1244                                 dnl Solaris has sched_yield() stub in -lposix4
1245                                 dnl but we'll use thr_yield instead.
1246                                 AC_CHECK_FUNCS(thr_yield)
1247                         fi
1248                         if test $ac_cv_func_sched_yield = no -a \
1249                                 $ac_cv_func_pthread_yield = no -a \
1250                                 "$ac_cv_func_thr_yield" = no ; then
1251                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1252                         fi
1253
1254                         dnl Check functions for compatibility
1255                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1256
1257                         dnl Check for pthread_detach with <pthread.h> inclusion
1258                         dnl as it's symbol may have been mangled.
1259                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1260                                 [ol_cv_func_pthread_detach], [
1261                                 dnl save the flags
1262                                 AC_TRY_LINK([
1263 #include <pthread.h>
1264 #ifndef NULL
1265 #define NULL (void*)0
1266 #endif
1267 ],
1268                                         [pthread_detach(NULL);],
1269                                         [ol_cv_func_pthread_detach=yes],
1270                                         [ol_cv_func_pthread_detach=no])
1271                         ])
1272
1273                         if test $ol_cv_func_pthread_detach = no ; then
1274                                 AC_MSG_ERROR([could not locate pthread_detach()])
1275                         fi
1276
1277                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1278                                 [define if you have pthread_detach function])
1279
1280                         dnl Check for setconcurreny functions
1281                         AC_CHECK_FUNCS( \
1282                                 pthread_setconcurrency \
1283                                 pthread_getconcurrency \
1284                                 thr_setconcurrency \
1285                                 thr_getconcurrency \
1286                         )
1287
1288                         OL_SYS_LINUX_THREADS
1289                         OL_LINUX_THREADS
1290
1291                         if test $ol_cv_linux_threads = error; then
1292                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1293                         fi
1294
1295                         AC_CACHE_CHECK([if pthread_create() works],
1296                                 ol_cv_pthread_create_works,[
1297                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1298                                 [ol_cv_pthread_create_works=yes],
1299                                 [ol_cv_pthread_create_works=no],
1300                                 [dnl assume yes
1301                                 ol_cv_pthread_create_works=yes])])
1302
1303                         if test $ol_cv_pthread_create_works = no ; then
1304                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1305                         fi
1306
1307                         dnl Check if select causes an yield
1308                         if test $ol_with_yielding_select = auto ; then
1309                                 AC_CACHE_CHECK([if select yields when using pthreads],
1310                                         ol_cv_pthread_select_yields,[
1311                                 AC_TRY_RUN([
1312 #include <sys/types.h>
1313 #include <sys/time.h>
1314 #include <unistd.h>
1315 #include <pthread.h>
1316 #ifndef NULL
1317 #define NULL (void*) 0
1318 #endif
1319
1320 static int fildes[2];
1321
1322 static void *task(p)
1323         void *p;
1324 {
1325         int i;
1326         struct timeval tv;
1327
1328         fd_set rfds;
1329
1330         tv.tv_sec=10;
1331         tv.tv_usec=0;
1332
1333         FD_ZERO(&rfds);
1334         FD_SET(fildes[0], &rfds);
1335
1336         /* we're not interested in any fds */
1337         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1338
1339         if(i < 0) {
1340                 perror("select");
1341                 exit(10);
1342         }
1343
1344         exit(0); /* if we exit here, the select blocked the whole process */
1345 }
1346
1347 int main(argc, argv)
1348         int argc;
1349         char **argv;
1350 {
1351         pthread_t t;
1352
1353         /* create a pipe to select */
1354         if(pipe(&fildes[0])) {
1355                 perror("select");
1356                 exit(1);
1357         }
1358
1359 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1360         (void) pthread_setconcurrency(2);
1361 #else
1362 #ifdef HAVE_THR_SETCONCURRENCY
1363         /* Set Solaris LWP concurrency to 2 */
1364         thr_setconcurrency(2);
1365 #endif
1366 #endif
1367
1368 #if HAVE_PTHREADS_D4
1369         pthread_create(&t, pthread_attr_default, task, NULL);
1370 #else
1371         pthread_create(&t, NULL, task, NULL);
1372 #endif
1373
1374 #if HAVE_SCHED_YIELD
1375         sched_yield();  /* make sure task runs first */
1376 #else
1377 #ifdef HAVE_PTHREAD_YIELD
1378         pthread_yield();        /* make sure task runs first */
1379 #endif
1380 #endif
1381
1382         exit(2);
1383 }],
1384                                 [ol_cv_pthread_select_yields=no],
1385                                 [ol_cv_pthread_select_yields=yes],
1386                                 [ol_cv_pthread_select_yields=cross])])
1387
1388                                 if test $ol_cv_pthread_select_yields = cross ; then
1389                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1390                                 fi
1391
1392                                 if test $ol_cv_pthread_select_yields = yes ; then
1393                                         ol_with_yielding_select=yes
1394                                 fi
1395                         fi
1396
1397                         dnl restore flags
1398                         CPPFLAGS="$save_CPPFLAGS"
1399                         LIBS="$save_LIBS"
1400                 else
1401                         AC_MSG_ERROR([could not link with POSIX Threads])
1402                 fi
1403         fi
1404
1405         if test $ol_with_threads = posix ; then
1406                 AC_MSG_ERROR([could not locate POSIX Threads])
1407         fi
1408 fi
1409
1410 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1411         -o $ol_with_threads = mach ; then
1412
1413         dnl check for Mach CThreads
1414         AC_CHECK_HEADERS(mach/cthreads.h)
1415         if test $ac_cv_header_mach_cthreads_h = yes ; then
1416                 ol_with_threads=found
1417
1418                 dnl check for cthread support in current $LIBS
1419                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1420
1421                 if test $ol_link_threads = no ; then
1422                         dnl try -all_load
1423                         dnl this test needs work
1424                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1425                                 [ol_cv_cthread_all_load], [
1426                                 dnl save the flags
1427                                 save_LIBS="$LIBS"
1428                                 LIBS="-all_load $LIBS"
1429                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1430                                         cthread_fork((void *)0, (void *)0);
1431                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1432                                 dnl restore the LIBS
1433                                 LIBS="$save_LIBS"
1434                         ])
1435
1436                         if test $ol_cv_cthread_all_load = yes ; then
1437                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1438                                 ol_link_threads=mach
1439                         fi
1440                 fi
1441
1442                 if test $ol_link_threads != no ; then
1443                         : check for cthread specific functionality here
1444                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1445                                 [define if you have Mach Cthreads])
1446                 else
1447                         AC_MSG_ERROR([could not link with Mach CThreads])
1448                 fi
1449         fi
1450
1451         if test $ol_with_threads = mach ; then
1452                 AC_MSG_ERROR([could not locate Mach CThreads])
1453         fi
1454 fi
1455
1456 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1457         -o $ol_with_threads = pth ; then
1458
1459         AC_CHECK_HEADERS(pth.h)
1460
1461         if test $ac_cv_header_pth_h = yes ; then
1462                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1463
1464                 if test $have_pth = yes ; then
1465                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1466                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1467                         ol_link_threads=pth
1468
1469                         if test $ol_with_yielding_select = auto ; then
1470                                 ol_with_yielding_select=yes
1471                         fi
1472                 fi
1473         fi
1474 fi
1475
1476 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1477         -o $ol_with_threads = lwp ; then
1478
1479         dnl check for SunOS5 LWP
1480         AC_CHECK_HEADERS(thread.h synch.h)
1481         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1482                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1483
1484                 if test $have_thr = yes ; then
1485                         AC_DEFINE(HAVE_THR,1,
1486                                 [if you have Solaris LWP (thr) package])
1487                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1488                         ol_link_threads=thr
1489
1490                         if test $ol_with_yielding_select = auto ; then
1491                                 ol_with_yielding_select=yes
1492                         fi
1493
1494                         dnl Check for setconcurreny functions
1495                         AC_CHECK_FUNCS( \
1496                                 thr_setconcurrency \
1497                                 thr_getconcurrency \
1498                         )
1499                 fi
1500         fi
1501
1502         dnl check for SunOS4 LWP
1503         AC_CHECK_HEADERS(lwp/lwp.h)
1504         if test $ac_cv_header_lwp_lwp_h = yes ; then
1505                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1506
1507                 if test $have_lwp = yes ; then
1508                         AC_DEFINE(HAVE_LWP,1,
1509                                 [if you have SunOS LWP package])
1510                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1511                         ol_link_threads=lwp
1512
1513                         if test $ol_with_yielding_select = auto ; then
1514                                 ol_with_yielding_select=no
1515                         fi
1516                 fi
1517         fi
1518 fi
1519
1520 if test $ol_with_yielding_select = yes ; then
1521         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1522                 [define if select implicitly yields])
1523 fi
1524
1525 if test $ol_with_threads = manual ; then
1526         dnl User thinks he can manually configure threads.
1527         ol_link_threads=yes
1528
1529         AC_MSG_WARN([thread defines and link options must be set manually])
1530
1531         AC_CHECK_HEADERS(pthread.h sched.h)
1532         AC_CHECK_FUNCS(sched_yield pthread_yield)
1533         OL_HEADER_LINUX_THREADS
1534
1535         AC_CHECK_HEADERS(mach/cthreads.h)
1536         AC_CHECK_HEADERS(lwp/lwp.h)
1537         AC_CHECK_HEADERS(thread.h synch.h)
1538 fi
1539
1540 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1541         dnl needed to get reentrant/threadsafe versions
1542         dnl
1543         AC_DEFINE(REENTRANT,1)
1544         AC_DEFINE(_REENTRANT,1)
1545         AC_DEFINE(THREAD_SAFE,1)
1546         AC_DEFINE(_THREAD_SAFE,1)
1547         AC_DEFINE(THREADSAFE,1)
1548         AC_DEFINE(_THREADSAFE,1)
1549         AC_DEFINE(_SGI_MP_SOURCE,1)
1550
1551         dnl The errno declaration may dependent upon _REENTRANT.
1552         dnl If it does, we must link with thread support.
1553         AC_CACHE_CHECK([for thread specific errno],
1554                 [ol_cv_errno_thread_specific], [
1555                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1556                         [ol_cv_errno_thread_specific=yes],
1557                         [ol_cv_errno_thread_specific=no])
1558         ])
1559
1560         dnl The h_errno declaration may dependent upon _REENTRANT.
1561         dnl If it does, we must link with thread support.
1562         AC_CACHE_CHECK([for thread specific h_errno],
1563                 [ol_cv_h_errno_thread_specific], [
1564                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1565                         [ol_cv_h_errno_thread_specific=yes],
1566                         [ol_cv_h_errno_thread_specific=no])
1567         ])
1568
1569         if test $ol_cv_errno_thread_specific != yes \
1570                 -o $ol_cv_h_errno_thread_specific != yes ; then
1571                 LIBS="$LTHREAD_LIBS $LIBS"
1572                 LTHREAD_LIBS=""
1573         fi
1574
1575 dnl When in thread environment, use
1576 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1577 dnl                     || defined( HAVE_FUNC_R )
1578 dnl                     func_r(...);
1579 dnl             #else
1580 dnl             #       if defined( HAVE_THREADS )
1581 dnl                             /* lock */
1582 dnl             #       endif
1583 dnl                             func(...);
1584 dnl             #       if defined( HAVE_THREADS )
1585 dnl                             /* unlock */
1586 dnl             #       endif
1587 dnl             #endif
1588 dnl
1589 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1590 dnl             _POSIX_REENTRANT_FUNCTIONS
1591 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1592 dnl             _POSIX_THREADSAFE_FUNCTIONS
1593 dnl
1594 dnl             and is currently defined in lthread.h
1595 dnl
1596 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1597 dnl
1598 dnl libldap/*.c should only include <lthread.h> iff
1599 dnl LDAP_R_COMPILE is defined.  ie:
1600 dnl             #ifdef LDAP_R_COMPILE
1601 dnl             #       include LDAP_R_COMPILE
1602 dnl             #endif
1603 dnl
1604 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1605 dnl specifically for compiling the threadsafe version of
1606 dnl     the ldap library (-lldap_r).
1607 dnl
1608 dnl     dnl check for reentrant/threadsafe functions
1609 dnl     dnl
1610 dnl     dnl note: these should only be used when linking
1611 dnl     dnl       with $LTHREAD_LIBS
1612 dnl     dnl
1613 dnl     save_CPPFLAGS="$CPPFLAGS"
1614 dnl     save_LIBS="$LIBS"
1615 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1616 dnl     AC_CHECK_FUNCS( \
1617 dnl             gmtime_r \
1618 dnl             gethostbyaddr_r gethostbyname_r \
1619 dnl             feof_unlocked unlocked_feof \
1620 dnl             putc_unlocked unlocked_putc \
1621 dnl             flockfile ftrylockfile \
1622 dnl     )
1623 dnl     CPPFLAGS="$save_CPPFLAGS"
1624 dnl     LIBS="$save_LIBS"
1625 fi
1626
1627 if test $ol_link_threads = no ; then
1628         if test $ol_with_threads = yes ; then
1629                 AC_MSG_ERROR([no suitable thread support])
1630         fi
1631
1632         if test $ol_with_threads = auto ; then
1633                 AC_MSG_WARN([no suitable thread support, disabling threads])
1634                 ol_with_threads=no
1635         fi
1636
1637         AC_DEFINE(NO_THREADS,1,
1638                 [define if you have (or want) no threads])
1639         LTHREAD_LIBS=""
1640 fi
1641
1642 if test $ol_link_threads != no ; then
1643         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1644 fi
1645
1646 dnl ----------------------------------------------------------------
1647 ol_link_ldbm=no
1648
1649 if test $ol_with_ldbm_api = auto \
1650         -o $ol_with_ldbm_api = berkeley \
1651         -o $ol_with_ldbm_api = bcompat ; then
1652
1653         if test $ol_with_ldbm_api = bcompat; then \
1654                 OL_BERKELEY_COMPAT_DB
1655         else
1656                 OL_BERKELEY_DB
1657         fi
1658
1659         if test $ol_cv_berkeley_db != no ; then
1660                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1661                         [define this if Berkeley DB is available])
1662
1663                 ol_link_ldbm=berkeley
1664                 ol_with_ldbm_api=db
1665
1666                 if test $ol_with_ldbm_type = hash ; then
1667                         AC_DEFINE(LDBM_USE_DBHASH,1,
1668                                 [define this to use DBHASH w/ LDBM backend])
1669                 else
1670                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1671                                 [define this to use DBBTREE w/ LDBM backend])
1672                 fi
1673
1674                 dnl $ol_cv_lib_db should be yes or -ldb
1675                 dnl (it could be no, but that would be an error
1676                 if test $ol_cv_lib_db != yes ; then
1677                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1678                 fi
1679         fi
1680 fi
1681
1682 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1683         AC_MSG_WARN(Could not find LDBM with BTREE support)
1684         ol_with_ldbm_api=none
1685 fi
1686
1687 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1688         OL_MDBM
1689
1690         if test $ol_cv_mdbm = yes ; then
1691                 ol_link_ldbm=mdbm
1692                 ol_with_ldbm_api=mdbm
1693                 if test $ol_cv_lib_mdbm != yes ; then
1694                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1695                 fi
1696         fi
1697 fi
1698
1699 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1700         OL_GDBM
1701
1702         if test $ol_cv_gdbm = yes ; then
1703                 ol_link_ldbm=gdbm
1704                 ol_with_ldbm_api=gdbm
1705
1706                 if test $ol_cv_lib_gdbm != yes ; then
1707                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1708                 fi
1709         fi
1710 fi
1711
1712 if test $ol_with_ldbm_api = ndbm ; then
1713         OL_NDBM
1714
1715         if test $ol_cv_ndbm = yes ; then
1716                 ol_link_ldbm=ndbm
1717                 ol_with_ldbm_api=ndbm
1718
1719                 if test $ol_cv_lib_ndbm != yes ; then
1720                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1721                 fi
1722         fi
1723 fi
1724
1725 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1726         AC_MSG_WARN(could not find suitable LDBM backend)
1727         if test $ol_enable_ldbm = yes ; then
1728                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1729         fi
1730
1731         AC_MSG_WARN(disabling LDBM)
1732         ol_enable_ldbm=no
1733 fi
1734
1735 dnl ----------------------------------------------------------------
1736 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1737         LINK_BINS_DYNAMIC="yes"
1738 else
1739         LINK_BINS_DYNAMIC="no"
1740 fi
1741
1742 dnl ----------------------------------------------------------------
1743 if test $ol_enable_wrappers != no ; then
1744         AC_CHECK_HEADERS(tcpd.h)
1745
1746         if test $ac_cv_header_tcpd_h != yes ; then
1747                 have_wrappers=no
1748         else
1749                 AC_TRY_COMPILE([
1750 int allow_severity = 0;
1751 int deny_severity  = 0;
1752                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1753         fi
1754
1755         if test $have_wrappers = yes ; then
1756                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1757                 WRAP_LIBS="-lwrap"
1758
1759                 dnl We add another check for -lnsl since some libwrap's
1760                 dnl need it, but it isn't always included from above
1761                 AC_CHECK_LIB(nsl, main)
1762         else
1763                 AC_MSG_WARN(could not find -lwrap)
1764                 if test $ol_enable_wrappers = yes ; then
1765                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1766                 fi
1767
1768                 AC_MSG_WARN(disabling wrappers support)
1769                 ol_enable_wrappers=no
1770                 WRAP_LIBS=""
1771         fi
1772 fi
1773
1774 dnl ----------------------------------------------------------------
1775 if test $ol_enable_syslog != no ; then
1776         AC_CHECK_FUNC(openlog)
1777         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1778                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1779         fi
1780         ol_enable_syslog=$ac_cv_func_openlog
1781 fi
1782
1783 dnl ----------------------------------------------------------------
1784 dnl dmalloc support (deprecated in favor of -DCSRIMALLOC support)
1785 dnl if test $ol_enable_dmalloc != no ; then
1786 dnl     AC_CHECK_HEADERS(dmalloc.h)
1787 dnl     AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1788 dnl fi
1789
1790 dnl ----------------------------------------------------------------
1791 dnl SQL
1792 ol_link_sql=no
1793 if test $ol_enable_sql != no ; then
1794         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
1795         if test $have_iodbc = yes ; then
1796                 ol_link_sql="-liodbc"
1797         else
1798                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
1799                 if test $have_odbc = yes ; then
1800                         ol_link_sql="-lodbc"
1801                 fi
1802         fi
1803
1804         if test $ol_link_sql != no ; then
1805                 SLAPD_SQL_LIBS="$ol_link_sql"
1806
1807         elif test $ol_enable_sql != auto ; then
1808                 AC_MSG_ERROR([could not locate suitable ODBC library])
1809         fi
1810 fi
1811
1812 dnl ----------------------------------------------------------------
1813 dnl TCL
1814 if test $ol_enable_tcl != no ; then
1815         AC_CHECK_HEADERS(tcl.h)
1816
1817         if test $ac_cv_header_tcl_h != yes ; then
1818                 have_tcl=no
1819         else
1820                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1821                         AC_CHECK_LIB($lib,main,
1822                           [have_tcl=yes
1823                            if test x"$ol_with_tcl_module" = "xstatic" ; then
1824                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1825                            else
1826                                MOD_TCL_LIB="-l${lib}"
1827                            fi;break],[have_tcl=no])
1828                 done
1829         fi
1830
1831         if test $have_tcl != yes ; then
1832                 AC_MSG_WARN([could not find -ltcl])
1833                 if test $ol_enable_tcl = yes ; then
1834                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1835                 fi
1836
1837                 ol_enable_tcl=no
1838         fi
1839 fi
1840
1841 dnl ----------------------------------------------------------------
1842 dnl ud needs termcap (should insert check here)
1843 ol_link_termcap=no
1844 AC_CHECK_HEADERS(termcap.h ncurses.h)
1845
1846 if test $ol_link_termcap = no ; then
1847         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1848         if test $have_termcap = yes ; then
1849                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1850                 ol_link_termcap=yes
1851                 TERMCAP_LIBS=-ltermcap
1852         fi
1853 fi
1854
1855 if test $ol_link_termcap = no ; then
1856         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1857         if test $have_ncurses = yes ; then
1858                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1859                 ol_link_termcap=yes
1860                 TERMCAP_LIBS=-lncurses
1861         fi
1862 fi
1863
1864 if test $ol_link_termcap = no ; then
1865         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1866         TERMCAP_LIBS=
1867 fi
1868
1869 dnl ----------------------------------------------------------------
1870 dnl
1871 dnl Check for Cyrus SASL
1872 dnl
1873 ol_link_sasl=no
1874 ol_link_spasswd=no
1875 if test $ol_with_cyrus_sasl != no ; then
1876         AC_CHECK_HEADERS(sasl.h)
1877
1878         if test $ac_cv_header_sasl_h = yes ; then
1879                 AC_CHECK_LIB(sasl, sasl_client_init,
1880                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1881
1882                 if test $have_cyrus_sasl != no ; then
1883                         SASL_LIBS="-lsasl"
1884                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1885                         ol_link_sasl=yes
1886                 fi
1887         fi
1888
1889         if test $ol_link_sasl = no ; then
1890                 if test $ol_with_cyrus_sasl != auto ; then
1891                         AC_MSG_ERROR([Could not locate Cyrus SASL])
1892                 else
1893                         AC_MSG_WARN([Could not locate Cyrus SASL])
1894                         AC_MSG_WARN([SASL authentication not supported!])
1895                         if test $ol_link_tls = no ; then
1896                                 AC_MSG_WARN([Strong authentication not supported!])
1897                         fi
1898                 fi
1899         fi
1900 else
1901         AC_MSG_WARN([SASL authentication not supported!])
1902         if test $ol_link_tls = no ; then
1903                 AC_MSG_WARN([Strong authentication not supported!])
1904         fi
1905 fi
1906
1907 dnl ----------------------------------------------------------------
1908 dnl Check for entropy sources
1909 if test $cross_compiling != yes ; then
1910         dev=no
1911         if test -r /dev/urandom ; then
1912                 dev="/dev/urandom";
1913         elif test -r /idev/urandom ; then
1914                 dev="/idev/urandom";
1915         elif test -r /dev/srandom ; then
1916                 dev="/dev/srandom";
1917         elif test -r /dev/random ; then
1918                 dev="/dev/random";
1919         elif test -r /idev/random ; then
1920                 dev="/idev/random";
1921         fi
1922
1923         if test $dev != no ; then
1924                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1925         fi
1926 fi
1927
1928 dnl ----------------------------------------------------------------
1929 dnl
1930 dnl Check for fetch URL support
1931 dnl             should be extended to support other fetch URL APIs
1932 dnl
1933 ol_link_fetch=no
1934 if test $ol_with_fetch != no ; then
1935         OL_LIB_FETCH
1936
1937         if test $ol_cv_lib_fetch != no ; then
1938                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1939                 ol_link_fetch=freebsd
1940
1941         elif test $ol_with_fetch != auto ; then
1942                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1943         fi
1944 fi
1945
1946 dnl ----------------------------------------------------------------
1947 dnl
1948 dnl Check for GNU readline
1949 dnl
1950 ol_link_readline=no
1951 if test $ol_with_readline != no ; then
1952         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1953
1954         if test $ac_cv_header_readline_readline_h = yes ; then
1955                 save_LIBS="$LIBS"
1956                 LIBS="$TERMCAP_LIBS $LIBS"
1957                 AC_CHECK_LIB(readline, readline,
1958                         [have_readline=yes], [have_readline=no])
1959                 LIBS="$save_LIBS"
1960
1961                 if test $have_readline = yes ; then
1962                         ol_with_readline=found
1963                         ol_link_readline=yes
1964
1965                         READLINE_LIBS="-lreadline"
1966                 fi
1967         fi
1968 fi
1969
1970 if test $ol_link_readline = yes ; then
1971         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1972 fi
1973
1974
1975 dnl ----------------------------------------------------------------
1976 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1977 if test $ol_enable_crypt != no ; then
1978         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1979                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1980                         have_crypt=yes], [have_crypt=no])])
1981
1982         if test $have_crypt = yes ; then
1983                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1984         else
1985                 AC_MSG_WARN(could not find crypt)
1986                 if test $ol_enable_crypt = yes ; then
1987                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1988                 fi
1989
1990                 AC_MSG_WARN(disabling crypt support)
1991                 ol_enable_crypt=no
1992         fi
1993 fi
1994
1995 dnl ----------------------------------------------------------------
1996 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1997 if test $ol_enable_proctitle != no ; then
1998         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1999                 AC_CHECK_LIB(util, setproctitle,
2000                         [have_setproctitle=yes
2001                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2002                         [have_setproctitle=no
2003                         LIBOBJS="$LIBOBJS setproctitle.o"
2004                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2005
2006         if test $have_setproctitle = yes ; then
2007                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2008                         [define if setproctitle(3) is available])
2009         fi
2010 fi
2011
2012 dnl ----------------------------------------------------------------
2013 dnl Checks for typedefs, structures, and compiler characteristics.
2014 AC_TYPE_MODE_T
2015 AC_TYPE_OFF_T
2016 AC_TYPE_PID_T
2017 AM_TYPE_PTRDIFF_T
2018 AC_TYPE_SIGNAL
2019 AC_TYPE_SIZE_T
2020
2021 AC_CHECK_TYPE(ssize_t, [signed int])
2022 AC_CHECK_TYPE(caddr_t,  [char *])
2023
2024 OL_TYPE_SOCKLEN_T
2025 AC_STRUCT_ST_BLKSIZE
2026 AC_HEADER_TIME
2027 AC_STRUCT_TM
2028 AC_TYPE_UID_T
2029 OL_TYPE_SIG_ATOMIC_T
2030
2031 dnl AC_TYPE_GETGROUPS
2032
2033 OL_STRUCT_PASSWD_PW_GECOS
2034 OL_STRUCT_PASSWD_PW_PASSWD
2035
2036 OL_C_UPPER_LOWER
2037 AC_C_CONST
2038 OL_C_VOLATILE
2039
2040 if test $cross_compiling = yes ; then
2041         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2042 else
2043         AC_C_BIGENDIAN
2044 fi
2045
2046 AC_COMPILE_CHECK_SIZEOF(short)
2047 AC_COMPILE_CHECK_SIZEOF(int)
2048 AC_COMPILE_CHECK_SIZEOF(long)
2049
2050 if test "$ac_cv_sizeof_int" -lt 4 ; then
2051         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2052
2053         AC_DEFINE(LBER_INT_T,long)
2054 else
2055         AC_DEFINE(LBER_INT_T,int)
2056 fi
2057
2058 AC_DEFINE(LBER_LEN_T,long)
2059 AC_DEFINE(LBER_SOCKET_T,int)
2060 AC_DEFINE(LBER_TAG_T,long)
2061
2062 dnl ----------------------------------------------------------------
2063 dnl Checks for library functions.
2064 AC_FUNC_MEMCMP
2065 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
2066 AC_FUNC_STRFTIME
2067 dnl AM_FUNC_STRTOD
2068
2069 OL_FUNC_INET_ATON
2070
2071 dnl Check for NT specific routines
2072 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2073
2074 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2075         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2076 ])
2077
2078 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2079         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2080 ])
2081
2082 AC_FUNC_VPRINTF
2083
2084 if test $ac_cv_func_vprintf = yes ; then
2085         dnl check for vsnprintf
2086         AC_CHECK_FUNCS(vsnprintf vsprintf)
2087 fi
2088
2089 AC_CHECK_FUNCS(         \
2090         bcopy                   \
2091         closesocket             \
2092         chroot                  \
2093         endgrent                \
2094         endpwent                \
2095         flock                   \
2096         getdtablesize   \
2097         getgrgid                \
2098         gethostname             \
2099         getpass                 \
2100         getpassphrase   \
2101         getpwuid                \
2102         getpwnam                \
2103         getspnam                \
2104         gettimeofday    \
2105         initgroups              \
2106         lockf                   \
2107         memcpy                  \
2108         memmove                 \
2109         mkstemp                 \
2110         pipe                    \
2111         read                    \
2112         recv                    \
2113         recvfrom                \
2114         setpwfile               \
2115         setgid                  \
2116         setegid                 \
2117         setsid                  \
2118         setuid                  \
2119         seteuid                 \
2120         sigaction               \
2121         signal                  \
2122         sigset                  \
2123         snprintf                \
2124         strdup                  \
2125         strerror                \
2126         strpbrk                 \
2127         strrchr                 \
2128         strsep                  \
2129         strstr                  \
2130         strtol                  \
2131         strtoul                 \
2132         strspn                  \
2133         sysconf                 \
2134         waitpid                 \
2135         wait4                   \
2136         write                   \
2137         send                    \
2138         sendto                  \
2139 )
2140
2141 dnl We actually may need to replace more than this.
2142 AC_REPLACE_FUNCS(getopt tempnam)
2143
2144 if test "$ac_cv_func_getopt" != yes; then
2145     LIBSRCS="$LIBSRCS getopt.c"
2146 fi
2147
2148 if test "$ac_cv_func_tempnam" != yes; then
2149     LIBSRCS="$LIBSRCS tempnam.c"
2150 fi
2151
2152 dnl ----------------------------------------------------------------
2153 # Check Configuration
2154 OL_SYS_ERRLIST
2155
2156 dnl ----------------------------------------------------------------
2157 dnl Sort out defines
2158
2159 if test "$ol_enable_debug" != no ; then
2160         AC_DEFINE(LDAP_DEBUG,1,
2161                 [define this to add debugging code])
2162 fi
2163 if test "$ol_enable_syslog" = yes ; then
2164         AC_DEFINE(LDAP_SYSLOG,1,
2165                 [define this to add syslog code])
2166 fi
2167 if test "$ol_enable_cache" = no ; then
2168         AC_DEFINE(LDAP_NOCACHE,1,
2169                 [define this to remove -lldap cache support])
2170 fi
2171 if test "$ol_link_kbind" != no ; then
2172         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2173 fi
2174 if test "$ol_enable_proctitle" != no ; then
2175         AC_DEFINE(LDAP_PROCTITLE,1,
2176                 [define this for LDAP process title support])
2177 fi
2178 if test "$ol_enable_referrals" != no ; then
2179         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2180 fi
2181 if test "$ol_enable_local" != no; then
2182         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2183 fi
2184 if test "$ol_enable_ipv6" != no; then
2185         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2186 fi
2187 if test "$ol_enable_cleartext" != no ; then
2188         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2189 fi
2190 if test "$ol_enable_crypt" != no ; then
2191         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2192 fi
2193 if test "$ol_link_kpasswd" != no ; then
2194         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2195 fi
2196 if test "$ol_link_spasswd" != no ; then
2197         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2198 fi
2199 if test "$ol_enable_multimaster" != no ; then
2200         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2201 fi
2202 if test "$ol_enable_phonetic" != no ; then
2203         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2204 fi
2205 if test "$ol_enable_rlookups" != no ; then
2206         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2207 fi
2208 if test "$ol_enable_aci" != no ; then
2209         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2210 fi
2211
2212 if test "$ol_link_modules" != no ; then
2213         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2214         BUILD_SLAPD=yes
2215         SLAPD_MODULES_LDFLAGS="-dlopen self"
2216 fi
2217
2218 if test "$ol_link_dnssrv" != no ; then
2219         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2220         BUILD_SLAPD=yes
2221         BUILD_DNSSRV=yes
2222         if test "$ol_with_dnssrv_module" != static ; then
2223                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2224                         [define to support dynamic DNS SRV backend])
2225                 BUILD_DNSSRV=mod
2226                 BUILD_DNSSRV_DYNAMIC=shared
2227                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2228         fi
2229 fi
2230
2231 if test "$ol_enable_ldap" != no ; then
2232         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2233         BUILD_SLAPD=yes
2234         BUILD_LDAP=yes
2235         if test "$ol_with_ldap_module" != static ; then
2236                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2237                         [define to support dynamic LDAP backend])
2238                 BUILD_LDAP=mod
2239                 BUILD_LDAP_DYNAMIC=shared
2240                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2241         fi
2242 fi
2243
2244 if test "$ol_link_ldbm" != no ; then
2245         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2246         BUILD_SLAPD=yes
2247         BUILD_LDBM=yes
2248         if test "$ol_with_ldbm_module" != static ; then
2249                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2250                         [define to support dynamic LDBM backend])
2251                 BUILD_LDBM=mod
2252                 BUILD_LDBM_DYNAMIC=shared
2253                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2254         fi
2255 fi
2256
2257 if test "$ol_enable_passwd" != no ; then
2258         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2259         BUILD_SLAPD=yes
2260         BUILD_PASSWD=yes
2261         if test "$ol_with_passwd_module" != static ; then
2262                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2263                         [define to support dynamic PASSWD backend])
2264                 BUILD_PASSWD=mod
2265                 BUILD_PASSWD_DYNAMIC=shared
2266                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2267         fi
2268 fi
2269
2270 if test "$ol_link_perl" != no ; then
2271         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2272         BUILD_SLAPD=yes
2273         BUILD_PERL=yes
2274         if test "$ol_with_perl_module" != static ; then
2275                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2276                         [define to support dynamic PERL backend])
2277                 BUILD_PERL=mod
2278                 BUILD_PERL_DYNAMIC=shared
2279                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2280         fi
2281 fi
2282
2283 if test "$ol_enable_shell" != no ; then
2284         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2285         BUILD_SLAPD=yes
2286         BUILD_SHELL=yes
2287         if test "$ol_with_shell_module" != static ; then
2288                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2289                         [define to support dynamic SHELL backend])
2290                 BUILD_SHELL=mod
2291                 BUILD_SHELL_DYNAMIC=shared
2292                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2293         fi
2294 fi
2295
2296 if test "$ol_enable_tcl" != no ; then
2297         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2298         BUILD_SLAPD=yes
2299         BUILD_TCL=yes
2300         if test "$ol_with_tcl_module" != static; then
2301                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2302                         [define to support dynamic TCL backend])
2303                 BUILD_TCL=mod
2304                 BUILD_TCL_DYNAMIC=shared
2305                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2306         fi
2307 fi
2308
2309 if test "$ol_link_sql" != no ; then
2310         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2311         BUILD_SLAPD=yes
2312         BUILD_SQL=yes
2313         if test "$ol_with_sql_module" != static; then
2314                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2315                         [define to support dynamic SQL backend])
2316                 BUILD_SQL=mod
2317                 BUILD_SQL_DYNAMIC=shared
2318                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2319         fi
2320 fi
2321
2322 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2323         $BUILD_SLAPD = yes ; then
2324         BUILD_SLURPD=yes
2325 fi
2326
2327 dnl ----------------------------------------------------------------
2328
2329 if test "$LINK_BINS_DYNAMIC" = yes; then
2330     LIB_LINKAGE=DYN
2331     LT_LIB_LINKAGE=shared
2332 else
2333     LIB_LINKAGE=STAT
2334     LT_LIB_LINKAGE=static
2335 fi
2336
2337 if test "$ac_cv_mingw32" = yes ; then
2338     PLAT=NT
2339     DYN_EXT=dll
2340 else
2341     PLAT=UNIX
2342     DYN_EXT=so
2343 fi
2344
2345 AC_SUBST(LIBSRCS)
2346
2347 AC_SUBST(PLAT)
2348 AC_SUBST(LIB_LINKAGE)
2349 AC_SUBST(LT_LIB_LINKAGE)
2350 AC_SUBST(DYN_EXT)
2351
2352 AC_SUBST(BUILD_SLAPD)
2353   AC_SUBST(BUILD_DNSSRV)
2354   AC_SUBST(BUILD_LDAP)
2355   AC_SUBST(BUILD_LDBM)
2356   AC_SUBST(BUILD_PASSWD)
2357   AC_SUBST(BUILD_PERL)
2358   AC_SUBST(BUILD_SHELL)
2359   AC_SUBST(BUILD_SQL)
2360   AC_SUBST(BUILD_TCL)
2361   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2362   AC_SUBST(BUILD_LDAP_DYNAMIC)
2363   AC_SUBST(BUILD_LDBM_DYNAMIC)
2364   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2365   AC_SUBST(BUILD_PERL_DYNAMIC)
2366   AC_SUBST(BUILD_SHELL_DYNAMIC)
2367   AC_SUBST(BUILD_SQL_DYNAMIC)
2368   AC_SUBST(BUILD_TCL_DYNAMIC)
2369 AC_SUBST(BUILD_SLURPD)
2370
2371 AC_SUBST(LDAP_LIBS)
2372 AC_SUBST(LDIF_LIBS)
2373 AC_SUBST(SLAPD_LIBS)
2374 AC_SUBST(SLURPD_LIBS)
2375 AC_SUBST(LDBM_LIBS)
2376 AC_SUBST(LTHREAD_LIBS)
2377 AC_SUBST(LUTIL_LIBS)
2378 AC_SUBST(WRAP_LIBS)
2379 AC_SUBST(MOD_TCL_LIB)
2380 AC_SUBST(LINK_BINS_DYNAMIC)
2381
2382 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2383 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2384 AC_SUBST(SLAPD_MODULES_LIST)
2385
2386 AC_SUBST(PERL_CPPFLAGS)
2387 AC_SUBST(SLAPD_PERL_LDFLAGS)
2388 AC_SUBST(MOD_PERL_LDFLAGS)
2389
2390 AC_SUBST(KRB4_LIBS)
2391 AC_SUBST(KRB5_LIBS)
2392 AC_SUBST(READLINE_LIBS)
2393 AC_SUBST(SASL_LIBS)
2394 AC_SUBST(TERMCAP_LIBS)
2395 AC_SUBST(TLS_LIBS)
2396 AC_SUBST(MODULES_LIBS)
2397 AC_SUBST(AUTH_LIBS)
2398
2399 AC_SUBST(SLAPD_SQL_LDFLAGS)
2400 AC_SUBST(SLAPD_SQL_LIBS)
2401 AC_SUBST(SLAPD_SQL_INCLUDES)
2402
2403 dnl ----------------------------------------------------------------
2404 dnl final output
2405 dnl
2406
2407 AC_OUTPUT( \
2408 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2409 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2410 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2411 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2412 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2413 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2414 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2415 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2416 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2417 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2418 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2419 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2420 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2421 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2422 clients/maildap/Makefile:build/top.mk:clients/maildap/Makefile.in:build/rules.mk \
2423 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2424 include/Makefile:build/top.mk:include/Makefile.in \
2425 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2426 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2427 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2428 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2429 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2430 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2431 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2432 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2433 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2434 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2435 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2436 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2437 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2438 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2439 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2440 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2441 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2442 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2443 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2444 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2445 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2446 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2447 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2448 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2449 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2450 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2451 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2452 ,[
2453 date > stamp-h
2454 echo Please \"make depend\" to build dependencies
2455 ])