git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Restrictions apply, see COPYRIGHT and LICENSE files."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version.sh)dnl
  35
  36 # set unset (borrowed from autoconf 2.14a)
  37 if (unset FOO) >/dev/null 2>&1; then
  38   ol_unset=unset
  39 else
  40   ol_unset=false
  41 fi
  42 # unset CDPATH
  43 $ol_unset CDPATH || test "${CDPATH+set}" != set || CDPATH=: && export CDPATH
  44
  45 AC_CONFIG_AUX_DIR(build)dnl
  46
  47 eval `$ac_aux_dir/version.sh`
  48 if test -z "$OL_STRING"; then
  49         AC_MSG_ERROR([could not determine version])
  50 fi
  51
  52 echo "Configuring $OL_STRING ..."
  53
  54 dnl Determine host platform
  55 dnl             we try not to use this for much
  56 AC_CANONICAL_SYSTEM
  57
  58 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  59 AC_SUBST(PACKAGE)
  60 AC_SUBST(VERSION)
  61 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  62 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  63
  64 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  65 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  66 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  67 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  68
  69 OPENLDAP_LIBVERSION=$OL_API_LIB
  70 AC_SUBST(OPENLDAP_LIBVERSION)
  71
  72 dnl We use autoconf features new to 2.13.
  73 dnl aclocal.m4 should be built using aclocal from automake 1.4
  74 dnl libtool 1.3.3 should be installed.
  75 AC_PREREQ(2.13)dnl Required Autoconf version
  76
  77 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  78
  79 dnl ================================================================
  80 dnl Start Args
  81 AC_MSG_CHECKING(configure arguments)
  82 AC_PREFIX_DEFAULT(/usr/local)
  83
  84 top_builddir=`pwd`
  85 AC_SUBST(top_builddir)dnl
  86
  87 dnl ----------------------------------------------------------------
  88 dnl --with-subdir
  89 ldap_subdir="/openldap"
  90
  91 AC_ARG_WITH(subdir,
  92 [  --with-subdir=DIR change default subdirectory used for installs],
  93 [case "$withval" in
  94         no) ldap_subdir=""
  95                 ;;
  96         yes)
  97                 ;;
  98         /*|\\*)
  99                 ldap_subdir="$withval"
 100                 ;;
 101         *)
 102                 ldap_subdir="/$withval"
 103                 ;;
 104 esac
 105 ])dnl
 106
 107 AC_SUBST(ldap_subdir)dnl
 108
 109 dnl ----------------------------------------------------------------
 110 dnl General "enable" options
 111 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes)dnl
 112 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 113 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 114 OL_ARG_ENABLE(cache,[  --enable-cache     enable caching], yes)dnl
 115 OL_ARG_ENABLE(referrals,[  --enable-referrals     enable V2 Referrals extension], yes)dnl
 116 OL_ARG_ENABLE(kbind,[  --enable-kbind     enable V2 Kerberos IV bind], no)dnl
 117 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 118 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 119 OL_ARG_ENABLE(x_compile,[  --enable-x-compile     enable cross compiling],
 120         no, [yes no])dnl
 121
 122 dnl ----------------------------------------------------------------
 123 dnl General "with" options
 124 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc     enable debug malloc support], no)dnl
 125
 126 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 127         auto, [auto yes no] )
 128 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch URL support],
 129         auto, [auto yes no] )
 130 OL_ARG_WITH(kerberos,[  --with-kerberos   with support],
 131         auto, [auto k5 k5only k425 kth k4 afs yes no])
 132 OL_ARG_WITH(readline,[  --with-readline   with readline support],
 133         auto, [auto yes no] )
 134 OL_ARG_WITH(threads,[  --with-threads     with threads],
 135         auto, [auto nt posix mach pth lwp yes no manual] )
 136 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 137         auto, [auto ssleay openssl yes no] )
 138 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 139         auto, [auto yes no manual] )
 140
 141 dnl ----------------------------------------------------------------
 142 dnl Server options
 143 dnl ----------------------------------------------------------------
 144
 145 dnl ----------------------------------------------------------------
 146 dnl SLAPD OPTIONS
 147 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 148 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 149 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 150 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], auto)dnl
 151 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd       enable Kerberos password verification], no)dnl
 152 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 153 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 154 OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 155 OL_ARG_ENABLE(phonetic,[    --enable-phonetic     enable phonetic/soundex], no)dnl
 156 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups], auto)dnl
 157 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs], no)dnl
 158 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 159 OL_ARG_ENABLE(dynamic,[    --enable-dynamic       enable linking built binaries with dynamic libs], no)dnl
 160
 161 dnl SLAPD Backend options
 162 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend], no)dnl
 163 OL_ARG_WITH(bdb_module,[    --with-bdb-module  module type], static,
 164         [static dynamic])
 165 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend], no)dnl
 166 OL_ARG_WITH(dnssrv_module,[    --with-dnssrv-module  module type], static,
 167         [static dynamic])
 168 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend], no)dnl
 169 OL_ARG_WITH(ldap_module,[    --with-ldap-module   module type], static,
 170         [static dynamic])
 171 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend], yes)dnl
 172 OL_ARG_WITH(ldbm_api,[    --with-ldbm-api       with LDBM API], auto,
 173         [auto berkeley bcompat mdbm gdbm])
 174 OL_ARG_WITH(ldbm_module,[    --with-ldbm-module   module type], static,
 175         [static dynamic])
 176 OL_ARG_WITH(ldbm_type,[    --with-ldbm-type       use LDBM type], auto,
 177         [auto btree hash])
 178 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend], no)dnl
 179 OL_ARG_WITH(passwd_module,[    --with-passwd-module  module type], static,
 180         [static dynamic])
 181 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend], no)dnl
 182 OL_ARG_WITH(perl_module,[    --with-perl-module   module type], static,
 183         [static dynamic])
 184 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend], no)dnl
 185 OL_ARG_WITH(shell_module,[    --with-shell-module         module type], static,
 186         [static dynamic])
 187 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend], no)dnl
 188 OL_ARG_WITH(sql_module,[    --with-sql-module     module type], static,
 189         [static dynamic])
 190 OL_ARG_ENABLE(tcl,[    --enable-tcl       enable tcl backend], no)dnl
 191 OL_ARG_WITH(tcl_module,[    --with-tcl-module     module type], static,
 192         [static dynamic])
 193
 194 dnl ----------------------------------------------------------------
 195 dnl SLURPD OPTIONS
 196 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 197 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 198
 199 dnl ----------------------------------------------------------------
 200 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 201 AC_ENABLE_STATIC
 202 dnl AC_DISABLE_SHARED
 203 AC_ENABLE_SHARED
 204
 205 dnl ----------------------------------------------------------------
 206
 207 dnl General "enable" options
 208 # validate options
 209 if test $ol_enable_slapd = no ; then
 210         dnl SLAPD was specificallly disabled
 211         if test $ol_enable_bdb = yes ; then
 212                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb argument])
 213         fi
 214         if test $ol_enable_dnssrv = yes ; then
 215                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 216         fi
 217         if test $ol_enable_ldap = yes ; then
 218                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 219         fi
 220         if test $ol_enable_ldbm = yes ; then
 221                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 222         fi
 223         if test $ol_enable_passwd = yes ; then
 224                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 225         fi
 226         if test $ol_enable_perl = yes ; then
 227                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 228         fi
 229         if test $ol_enable_shell = yes ; then
 230                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 231         fi
 232         if test $ol_enable_tcl = yes ; then
 233                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 234         fi
 235         if test $ol_enable_sql = yes ; then
 236                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 237         fi
 238         if test $ol_enable_modules = yes ; then
 239                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 240         fi
 241         if test $ol_enable_multimaster = yes ; then
 242                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 243         fi
 244         if test $ol_enable_wrappers = yes ; then
 245                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 246         fi
 247         if test $ol_enable_phonetic = yes ; then
 248                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 249         fi
 250         if test $ol_enable_rlookups = yes ; then
 251                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 252         fi
 253         if test $ol_enable_aci = yes ; then
 254                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 255         fi
 256         if test $ol_with_ldbm_api != auto ; then
 257                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 258         fi
 259         if test $ol_with_ldbm_type != auto ; then
 260                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 261         fi
 262         if test $ol_with_bdb_module != static ; then
 263                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb-module argument])
 264         fi
 265         if test $ol_with_dnssrv_module != static ; then
 266                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 267         fi
 268         if test $ol_with_ldap_module != static ; then
 269                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 270         fi
 271         if test $ol_with_ldbm_module != static ; then
 272                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 273         fi
 274         if test $ol_with_passwd_module != static ; then
 275                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 276         fi
 277         if test $ol_with_perl_module != static ; then
 278                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 279         fi
 280         if test $ol_with_shell_module != static ; then
 281                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 282         fi
 283         if test $ol_with_tcl_module != static ; then
 284                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 285         fi
 286         if test $ol_with_sql_module != static ; then
 287                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 288         fi
 289         if test $ol_enable_slurpd = yes ; then
 290                 AC_MSG_ERROR([slurpd requires slapd])
 291         fi
 292
 293         # force settings to no
 294         ol_enable_bdb=no
 295         ol_enable_dnssrv=no
 296         ol_enable_ldap=no
 297         ol_enable_ldbm=no
 298         ol_enable_passwd=no
 299         ol_enable_perl=no
 300         ol_enable_shell=no
 301         ol_enable_tcl=no
 302         ol_enable_sql=no
 303
 304         ol_enable_modules=no
 305         ol_enable_multimaster=no
 306         ol_enable_phonetic=no
 307         ol_enable_rlookups=no
 308         ol_enable_aci=no
 309         ol_enable_wrappers=no
 310         ol_enable_dynamic=no
 311
 312         ol_with_ldbm_api=no
 313         ol_with_ldbm_type=no
 314
 315         ol_with_bdb_module=static
 316         ol_with_dnssrv_module=static
 317         ol_with_ldap_module=static
 318         ol_with_ldbm_module=static
 319         ol_with_passwd_module=static
 320         ol_with_perl_module=static
 321         ol_with_shell_module=static
 322         ol_with_tcl_module=static
 323         ol_with_sql_module=static
 324
 325         ol_enable_slurpd=no
 326
 327 elif test $ol_enable_ldbm = no ; then
 328         dnl SLAPD without LDBM
 329
 330         if test $ol_with_ldbm_api != auto ; then
 331                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 332         fi
 333
 334         if test $ol_with_ldbm_type != auto ; then
 335                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 336         fi
 337
 338         if test $ol_with_ldbm_module != static ; then
 339                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 340         fi
 341
 342         if test $ol_enable_modules != yes -a \
 343                 $ol_enable_bdb = no -a \
 344                 $ol_enable_dnssrv = no -a \
 345                 $ol_enable_ldap = no -a \
 346                 $ol_enable_passwd = no -a \
 347                 $ol_enable_perl = no -a \
 348                 $ol_enable_shell = no -a \
 349                 $ol_enable_sql = no -a \
 350                 $ol_enable_tcl = no ; then
 351                 AC_MSG_ERROR([slapd requires a backend])
 352         fi
 353
 354         ol_with_ldbm_api=no
 355         ol_with_ldbm_type=no
 356         ol_with_ldbm_module=static
 357
 358 else
 359         dnl SLAPD with LDBM
 360         if test $ol_with_ldbm_api = gdbm -a \
 361                 $ol_with_ldbm_type = btree ; then
 362                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 363         fi
 364         if test $ol_with_ldbm_api = mdbm -a \
 365                 $ol_with_ldbm_type = btree ; then
 366                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 367         fi
 368         if test $ol_with_ldbm_api = ndbm -a \
 369                 $ol_with_ldbm_type = btree ; then
 370                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 371         fi
 372 fi
 373
 374 if test $ol_enable_slurpd = yes ; then
 375         dnl SLURPD was specifically enabled
 376         if test $ol_with_threads = no ; then
 377                 AC_MSG_ERROR([slurpd requires threads])
 378         fi
 379 fi
 380
 381 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 382         if test $ol_with_kerberos = no ; then
 383                 AC_MSG_ERROR([options require --with-kerberos])
 384         fi
 385         ol_with_kerberos=yes
 386 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 387         if test $ol_with_kerberos != no -a $ol_with_kerberos != auto ; then
 388                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 389         fi
 390         ol_with_kerberos=no
 391 fi
 392
 393 if test $ol_enable_spasswd = yes ; then
 394         if test $ol_with_cyrus_sasl = no ; then
 395                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 396         fi
 397         ol_link_spasswd=yes
 398 fi
 399
 400 AC_MSG_RESULT(done)
 401
 402 dnl ----------------------------------------------------------------
 403 dnl Initialize vars
 404 LDAP_LIBS=
 405 LDIF_LIBS=
 406 LDBM_LIBS=
 407 LTHREAD_LIBS=
 408 LUTIL_LIBS=
 409
 410 SLAPD_LIBS=
 411 SLURPD_LIBS=
 412
 413 BUILD_SLAPD=no
 414 BUILD_SLURPD=no
 415
 416 BUILD_THREAD=no
 417
 418 BUILD_BDB=no
 419 BUILD_DNSSRV=no
 420 BUILD_LDAP=no
 421 BUILD_LDBM=no
 422 BUILD_PASSWD=no
 423 BUILD_PERL=no
 424 BUILD_SHELL=no
 425 BUILD_SQL=no
 426 BUILD_TCL=no
 427
 428 BUILD_BDB_DYNAMIC=static
 429 BUILD_DNSSRV_DYNAMIC=static
 430 BUILD_LDAP_DYNAMIC=static
 431 BUILD_LDBM_DYNAMIC=static
 432 BUILD_PASSWD_DYNAMIC=static
 433 BUILD_PERL_DYNAMIC=static
 434 BUILD_SHELL_DYNAMIC=static
 435 BUILD_TCL_DYNAMIC=static
 436 BUILD_SQL_DYNAMIC=static
 437
 438 SLAPD_MODULES_LDFLAGS=
 439 SLAPD_MODULES_CPPFLAGS=
 440 SLAPD_MODULES_LIST=
 441
 442 SLAPD_PERL_LDFLAGS=
 443 MOD_PERL_LDFLAGS=
 444 PERL_CPPFLAGS=
 445
 446 SLAPD_SQL_LDFLAGS=
 447 SLAPD_SQL_LIBS=
 448 SLAPD_SQL_INCLUDES=
 449
 450 MOD_TCL_LIB=
 451 KRB4_LIBS=
 452 KRB5_LIBS=
 453 READLINE_LIBS=
 454 SASL_LIBS=
 455 TERMCAP_LIBS=
 456 TLS_LIBS=
 457 MODULES_LIBS=
 458 AUTH_LIBS=
 459
 460 dnl ================================================================
 461 dnl Checks for programs
 462
 463 dnl AC_PROG_INSTALL
 464
 465 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 466
 467 dnl ----------------------------------------------------------------
 468 dnl
 469 dnl Determine which C translator to use
 470 dnl
 471
 472 dnl AIX Thread requires we use cc_r or xlc_r.
 473 dnl But only do this IF AIX and CC is not set
 474 dnl and threads are auto|yes|posix.
 475 dnl
 476 dnl If we find cc_r|xlc_r, force pthreads and assume
 477 dnl             pthread_create is in $LIBS (ie: don't bring in
 478 dnl             any additional thread libraries)
 479 dnl If we do not find cc_r|xlc_r, disable threads
 480
 481 ol_aix_threads=no
 482 case "$target" in
 483 *-*-aix*) dnl all AIX is not a good idea.
 484         if test -z "$CC" ; then
 485                 case "$ol_with_threads" in
 486                 auto | yes |  posix) ol_aix_threads=yes ;;
 487                 esac
 488         fi
 489 ;;
 490 esac
 491
 492 if test $ol_aix_threads = yes ; then
 493         if test -z "${CC}" ; then
 494                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 495
 496                 if test "$CC" = cc ; then
 497                         dnl no CC! don't allow --with-threads
 498                         if test $ol_with_threads != auto ; then
 499                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 500                         else
 501                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 502                         fi
 503                         ol_with_threads=no
 504                 fi
 505         fi
 506
 507         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 508                 ol_with_threads=posix
 509                 ol_cv_pthread_create=yes
 510         fi
 511 fi
 512
 513 if test -z "${CC}"; then
 514         AC_CHECK_PROGS(CC,cc)
 515 fi
 516
 517 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 518 dnl (for now, let autoconf sort this out)
 519 dnl CFLAGS=${CFLAGS-""}
 520
 521 AC_LIBTOOL_WIN32_DLL
 522 AC_LIBTOOL_DLOPEN
 523 AC_PROG_LIBTOOL
 524
 525 AC_PROG_AWK
 526 OL_PROG_LN_H
 527 AC_PROG_LN_S
 528
 529 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 530         LN_S="$LN_H"
 531 fi
 532
 533 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 534         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 535 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 536 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 537
 538 dnl ----------------------------------------------------------------
 539 dnl Perl
 540 ol_link_perl=no
 541 if test $ol_enable_perl != no ; then
 542         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 543
 544         if test "no$PERLBIN" = "no" ; then
 545                 if test $ol_enable_perl = yes ; then
 546                         AC_MSG_ERROR([could not locate perl])
 547                 fi
 548
 549         else
 550                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 551                 if test x"$ol_with_perl_module" = "xstatic" ; then
 552                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 553                 else
 554                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 555                 fi
 556                 dnl should check perl version
 557                 ol_link_perl=yes
 558         fi
 559 fi
 560
 561 AC_PROG_CPP
 562
 563 dnl ----------------------------------------------------------------
 564 dnl Cross compiling checks
 565 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 566         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 567
 568 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 569         AC_MSG_WARN([programs compiled here do run here...])
 570         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 571
 572 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 573         AC_MSG_WARN([programs compiled here do not run here...])
 574         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 575 fi
 576
 577 dnl ----------------------------------------------------------------
 578 dnl Checks for UNIX Variants
 579 AC_AIX
 580 AC_ISC_POSIX
 581 AC_MINIX
 582
 583 dnl ----------------------------------------------------------------
 584 dnl Checks for system services
 585 AC_CYGWIN
 586 AC_MINGW32
 587 AC_EXEEXT
 588 AC_OBJEXT
 589
 590 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 591
 592 dnl ----------------------------------------------------------------
 593 dnl BeOS requires -lbe -lroot -lnet
 594 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 595
 596 dnl ----------------------------------------------------------------
 597 dnl OpenLDAP requires STDC features
 598 AM_PROG_CC_STDC
 599 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 600         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 601 fi
 602
 603 dnl ----------------------------------------------------------------
 604 dnl Check cc depend flags
 605 OL_MKDEPEND
 606 if test "${ol_cv_mkdep}" = no ; then
 607         # this will soon become an error
 608         AC_MSG_WARN([do not know how to generate dependencies])
 609 fi
 610
 611 dnl ----------------------------------------------------------------
 612 dnl Check for AIX security library
 613 AC_CHECK_LIB(s, afopen, [
 614         AUTH_LIBS=-ls
 615         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 616 ])
 617
 618
 619 dnl ----------------------------------------------------------------
 620 dnl PF_INET6 support requires getaddrinfo
 621 dnl PF_LOCAL may use getaddrinfo in available
 622 AC_CHECK_FUNCS( getaddrinfo )
 623
 624 if test $ac_cv_func_getaddrinfo = no ; then
 625         if test $ol_enable_ipv6 = yes ; then
 626                 AC_MSG_ERROR([IPv6 support requires getaddrinfo()])
 627         fi
 628         ol_enable_ipv6=no
 629 fi
 630
 631 if test $ol_enable_local != no ; then
 632         AC_CHECK_HEADERS( sys/un.h )
 633
 634         if test $ol_enable_local = auto ; then
 635                 ol_enable_local=$ac_cv_header_sys_un_h
 636         elif test $ac_cv_header_sys_un_h = no ; then
 637                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
 638         fi
 639 fi
 640
 641 dnl ----------------------------------------------------------------
 642 dnl Check for module support
 643 ol_link_modules=no
 644 if test $ol_enable_modules != no ; then
 645         AC_CHECK_HEADERS(ltdl.h)
 646
 647         if test $ac_cv_header_ltdl_h = no ; then
 648                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 649         fi
 650
 651         AC_CHECK_LIB(ltdl, lt_dlinit, [
 652             MODULES_LIBS=-lltdl
 653             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 654         ])
 655
 656         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 657                 AC_MSG_ERROR([could not locate libtool -lltdl])
 658         fi
 659         ol_link_modules=yes
 660 else
 661         ol_with_bdb_module=static
 662         ol_with_dnssrv_module=static
 663         ol_with_ldap_module=static
 664         ol_with_ldbm_module=static
 665         ol_with_passwd_module=static
 666         ol_with_perl_module=static
 667         ol_with_shell_module=static
 668         ol_with_tcl_module=static
 669         ol_with_sql_module=static
 670 fi
 671
 672 dnl ----------------------------------------------------------------
 673 dnl Checks for header files.
 674 OL_HEADER_STDC
 675
 676 if test $ol_cv_header_stdc != yes; then
 677         AC_MSG_WARN([could not locate Standard C compliant headers])
 678 fi
 679
 680 AC_HEADER_DIRENT
 681 AC_HEADER_SYS_WAIT
 682 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 683 if test $am_cv_sys_posix_termios = yes ; then
 684         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 685                 [define if you have POSIX termios])
 686 fi
 687
 688 AC_CHECK_HEADERS(       \
 689         arpa/inet.h             \
 690         arpa/nameser.h  \
 691         assert.h                \
 692         conio.h                 \
 693         crypt.h                 \
 694         direct.h                \
 695         errno.h                 \
 696         fcntl.h                 \
 697         filio.h                 \
 698         getopt.h                \
 699         grp.h                   \
 700         io.h                    \
 701         libutil.h               \
 702         limits.h                \
 703         locale.h                \
 704         netinet/tcp.h   \
 705         malloc.h                \
 706         memory.h                \
 707         psap.h                  \
 708         pwd.h                   \
 709         process.h               \
 710         resolv.h                \
 711         sgtty.h                 \
 712         shadow.h                \
 713         stddef.h                \
 714         string.h                \
 715         strings.h               \
 716         sysexits.h              \
 717         sys/file.h              \
 718         sys/filio.h             \
 719         sys/errno.h             \
 720         sys/ioctl.h             \
 721         sys/param.h             \
 722         sys/resource.h  \
 723         sys/select.h    \
 724         sys/socket.h    \
 725         sys/syslog.h    \
 726         sys/time.h              \
 727         sys/types.h             \
 728         syslog.h                \
 729         termios.h               \
 730         unistd.h                \
 731         winsock.h               \
 732 )
 733
 734
 735 dnl ----------------------------------------------------------------
 736 dnl Checks for libraries
 737
 738 dnl HP-UX requires -lV3
 739 AC_CHECK_LIB(V3, sigset)
 740
 741 dnl Gotta check for winsock manually
 742 if test $ac_cv_header_winsock_h = yes; then
 743         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 744         AC_TRY_LINK([#include <winsock.h>],[
 745                         socket(0,0,0);
 746                         select(0,NULL,NULL,NULL,NULL);
 747                         closesocket(0);
 748                         gethostname(NULL,0);
 749         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 750
 751         if test $ol_cv_winsock = yes ; then
 752                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 753                 ac_cv_func_socket=yes
 754                 ac_cv_func_select=yes
 755                 ac_cv_func_closesocket=yes
 756                 ac_cv_func_gethostname=yes
 757         fi
 758 fi
 759
 760 dnl Find socket()
 761 dnl Likely combinations:
 762 dnl             -lsocket [ -lnsl_s | -lnsl ]
 763 dnl             -linet
 764
 765 AC_CHECK_FUNC(socket, :, [
 766 dnl hopefully we won't include too many libraries
 767         AC_CHECK_LIB(socket, main)
 768         AC_CHECK_LIB(net, main)
 769         AC_CHECK_LIB(nsl_s, main)
 770         AC_CHECK_LIB(nsl, main)
 771         AC_CHECK_LIB(inet, socket)
 772         AC_CHECK_LIB(gen, main)
 773 ])
 774
 775 dnl require select
 776 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 777
 778 if test "${ac_cv_header_winsock_h}" != yes; then
 779     dnl Select arg types
 780     dnl (if this detection becomes permenent, it and the select() detection
 781     dnl should be done before the yielding select test)
 782     AC_FUNC_SELECT_ARGTYPES
 783 fi
 784
 785 dnl check to see if system call automatically restart
 786 dnl AC_SYS_RESTARTABLE_SYSCALLS
 787
 788 dnl ----------------------------------------------------------------
 789 dnl require POSIX regex
 790 AC_CHECK_HEADERS( regex.h )
 791 if test "$ac_cv_header_regex_h" != yes ; then
 792         AC_MSG_ERROR([POSIX regex.h required.])
 793 fi
 794 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 795
 796 OL_POSIX_REGEX
 797 if test "$ol_cv_c_posix_regex" = no ; then
 798         AC_MSG_ERROR([broken POSIX regex!])
 799 fi
 800
 801 dnl ----------------------------------------------------------------
 802 dnl Check for resolver routines
 803 ol_link_dnssrv=no
 804 AC_CHECK_FUNC(res_query,:)
 805 if test $ac_cv_func_res_query = no ; then
 806         AC_CHECK_LIB(bind, res_query)
 807         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 808 fi
 809
 810 if test $ac_cv_func_res_query = no ; then
 811         AC_CHECK_LIB(bind, __res_query)
 812         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 813 fi
 814
 815 if test $ac_cv_func_res_query = no ; then
 816         AC_CHECK_LIB(resolv, res_query)
 817         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 818 fi
 819
 820 if test "$ac_cv_func_res_query" = yes ; then
 821         AC_DEFINE(HAVE_RES_QUERY,1,
 822                 [define if you have res_query()])
 823
 824         if test $ol_enable_dnssrv != no ; then
 825                 ol_link_dnssrv=yes
 826         fi
 827 fi
 828
 829 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 830         AC_MSG_ERROR([DNSSRV requires res_query()])
 831 fi
 832
 833 dnl ----------------------------------------------------------------
 834 dnl Kerberos
 835 ol_link_kbind=no
 836 ol_link_kpasswd=no
 837 ol_link_krb5=no
 838 ol_link_krb4=no
 839
 840 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 841         -o $ol_with_kerberos = k5 -o $ol_with_kerberos = k5only \
 842         -o $ol_with_kerberos = k425 ; then
 843
 844         AC_CHECK_HEADERS(krb5.h)
 845
 846         if test $ac_cv_header_krb5_h = yes ; then
 847                 dnl lazy check for Heimdal Kerberos
 848                 AC_CHECK_HEADERS(heim_err.h)
 849                 if test $ac_cv_header_heim_err_h = yes ; then
 850                         krb5_impl=heimdal
 851                 else
 852                         krb5_impl=mit
 853                 fi
 854
 855                 if test $krb5_impl = mit; then
 856                         AC_CHECK_LIB(krb5, main,
 857                                 [have_krb5=yes
 858                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 859                                 [have_krb5=no],
 860                                 [-lcrypto -lcom_err])
 861
 862                 elif test $krb5_impl = heimdal; then
 863                         AC_CHECK_LIB(krb5, main,
 864                                 [have_krb5=yes
 865                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 866                                 [have_krb5=no],
 867                                 [-ldes -lasn1 -lroken -lcom_err])
 868
 869                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 870                                 [define if you have HEIMDAL Kerberos])
 871                 else
 872                         have_krb5=no
 873                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 874                 fi
 875
 876                 if test $have_krb5 = yes ; then
 877                         ol_link_krb5=yes
 878
 879                         AC_DEFINE(HAVE_KRB5, 1,
 880                                 [define if you have Kerberos V])
 881
 882                         if test $ol_enable_kpasswd != no ; then
 883                                 ol_link_kpasswd=yes;
 884                         fi
 885
 886                         if test $ol_with_kerberos = k5only ; then
 887                                 ol_with_kerberos=found
 888                         fi
 889
 890                 elif test $ol_with_kerberos != auto ; then
 891                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 892                 fi
 893
 894         fi
 895 fi
 896
 897 if test $ol_link_krb5 = yes -a \( $ol_with_kerberos = yes -o \
 898         $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 899
 900         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 901
 902         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 903                 if test $krb5_impl = mit; then
 904                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 905                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 906                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 907
 908                 elif test $krb5_impl = heimdal; then
 909                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 910                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 911                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 912
 913                 else
 914                         have_425=no
 915                         AC_MSG_WARN([Unrecongized Kerberos V Implementation])
 916                 fi
 917
 918                 if test $have_k425 = yes ; then
 919                         ol_with_kerberos=found
 920                         ol_link_krb4=yes
 921
 922                         AC_DEFINE(HAVE_KRB425, 1,
 923                                 [define if you have Kerberos V with IV support])
 924                         AC_DEFINE(HAVE_KRB4, 1,
 925                                 [define if you have Kerberos IV])
 926
 927                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 928                                 [ol_cv_var_des_debug], [
 929                                 dnl save the flags
 930                                 save_LIBS="$LIBS"
 931                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 932                                 AC_TRY_LINK([
 933 #include <kerberosIV/krb.h>
 934 #include <kerberosIV/des.h>
 935 extern int des_debug;
 936 ],[
 937 des_debug = 1;
 938 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 939                                 dnl restore the LIBS
 940                                 LIBS="$save_LIBS"
 941                         ])
 942
 943                         if test $ol_cv_var_des_debug = yes ; then
 944                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 945                                         [define if you have Kerberos des_debug])
 946                         fi
 947
 948                         LIBS="$save_LIBS"
 949                 fi
 950         fi
 951 fi
 952
 953 if test $ol_link_krb5 = yes ; then
 954         ol_with_kerberos=found
 955 fi
 956
 957 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 958         -o $ol_with_kerberos = k4 -o $ol_with_kerberos = kth ; then
 959
 960         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 961
 962         if test $ac_cv_header_krb_h = yes ; then
 963                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 964
 965                 if test $have_k4 = yes ; then
 966                         ol_with_kerberos=found
 967                         ol_link_krb4=yes
 968
 969                         AC_DEFINE(HAVE_KRB4, 1,
 970                                 [define if you have Kerberos IV])
 971
 972                         KRB4_LIBS="-lkrb -ldes"
 973
 974                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 975                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 976                                         [define if you have Kth Kerberos])
 977                         fi
 978                 fi
 979         fi
 980 fi
 981
 982 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 983         ol_link_kpasswd=yes
 984 fi
 985
 986 if test $ol_link_krb4 = yes -a $ol_enable_kbind != no ; then
 987         ol_link_kbind=yes
 988
 989 elif test $ol_enable_kbind = yes ; then
 990         AC_MSG_ERROR([Kerberos IV detection failed])
 991 fi
 992
 993 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 994         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 995
 996 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 997         AC_MSG_ERROR([Kerberos detection failed])
 998 fi
 999
1000 dnl ----------------------------------------------------------------
1001 dnl TLS/SSL
1002 ol_link_tls=no
1003 if test $ol_with_tls != no ; then
1004         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
1005
1006         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
1007                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
1008                         [have_ssleay=yes
1009                         need_rsaref=no],
1010                         [have_ssleay=no],
1011                         [-lcrypto])
1012
1013                 if test $have_ssleay = no ; then
1014                         AC_CHECK_LIB(ssl, SSL_library_init,
1015                                 [have_ssleay=yes
1016                                 need_rsaref=no], [have_ssleay=no],
1017                                 [-lcrypto])
1018                 fi
1019
1020                 if test $have_ssleay = no ; then
1021                         AC_CHECK_LIB(ssl, ssl3_accept,
1022                                 [have_ssleay=yes
1023                                 need_rsaref=yes], [have_ssleay=no],
1024                                 [-lcrypto -lRSAglue -lrsaref])
1025                 fi
1026
1027                 if test $have_ssleay = yes ; then
1028                         ol_with_tls=found
1029                         ol_link_tls=yes
1030
1031                         AC_DEFINE(HAVE_SSLEAY, 1,
1032                                 [define if you have SSLeay or OpenSSL])
1033
1034                         if test $need_rsaref = yes; then
1035                                 AC_DEFINE(HAVE_RSAREF, 1,
1036                                         [define if you have RSAref])
1037
1038                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1039                         else
1040                                 TLS_LIBS="-lssl -lcrypto"
1041                         fi
1042                 fi
1043         fi
1044
1045 else
1046         AC_WARN([TLS privacy protection not supported!])
1047 fi
1048
1049 if test $ol_link_tls = yes ; then
1050         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1051
1052 elif test $ol_with_tls = auto ; then
1053         AC_WARN([Could not locate TLS/SSL package])
1054         AC_WARN([TLS privacy protection not supported!])
1055
1056 elif test $ol_with_tls != no ; then
1057         AC_ERROR([Could not locate TLS/SSL package])
1058 fi
1059
1060 dnl ----------------------------------------------------------------
1061 dnl Tests for reentrant functions necessary to build a
1062 dnl thread_safe -lldap.
1063 AC_CHECK_FUNCS(         \
1064         ctime_r                 \
1065         gethostbyname_r gethostbyaddr_r \
1066 )
1067
1068 if test "$ac_cv_func_ctime_r" = no ; then
1069         ol_cv_func_ctime_r_nargs=0
1070 else
1071         OL_FUNC_CTIME_R_NARGS
1072 dnl     OL_FUNC_CTIME_R_TYPE
1073 fi
1074
1075 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1076         OL_FUNC_GETHOSTBYNAME_R_NARGS
1077 else
1078         ol_cv_func_gethostbyname_r_nargs=0
1079 fi
1080
1081 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1082         OL_FUNC_GETHOSTBYADDR_R_NARGS
1083 else
1084         ol_cv_func_gethostbyaddr_r_nargs=0
1085 fi
1086
1087 if test "$ac_cv_func_ctime_r" = yes \
1088         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1089         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1090         -a "$ac_cv_func_gethostbyname_r" = yes \
1091         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1092         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1093         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1094         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1095         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1096         ; then
1097
1098         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1099 fi
1100
1101 dnl ----------------------------------------------------------------
1102 dnl Threads?
1103 ol_link_threads=no
1104
1105 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1106         -o $ol_with_threads = nt ; then
1107
1108         OL_NT_THREADS
1109
1110         if test "$ol_cv_nt_threads" = yes ; then
1111         ol_link_threads=nt
1112         ol_with_threads=found
1113         ol_with_yielding_select=yes
1114
1115                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1116                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1117         fi
1118
1119         if test $ol_with_threads = nt ; then
1120                 AC_MSG_ERROR([could not locate NT Threads])
1121         fi
1122 fi
1123
1124 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1125         -o $ol_with_threads = posix ; then
1126
1127         AC_CHECK_HEADERS(pthread.h)
1128
1129         if test $ac_cv_header_pthread_h = yes ; then
1130                 OL_POSIX_THREAD_VERSION
1131
1132                 if test $ol_cv_pthread_version = final ; then
1133                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1134                                 [define if pthreads API compatible with final spec])
1135                 elif test $ol_cv_pthread_version = draft4 ; then
1136                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1137                                 [define if pthreads API compatible with draft4 spec])
1138                 else
1139                         AC_MSG_ERROR([unknown pthread version])
1140                 fi
1141
1142                 # consider threads found
1143                 ol_with_threads=found
1144
1145                 OL_HEADER_LINUX_THREADS
1146                 OL_HEADER_GNU_PTH_PTHREAD_H
1147
1148                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1149                         AC_CHECK_HEADERS(sched.h)
1150                 fi
1151
1152                 dnl Now the hard part, how to link?
1153                 dnl
1154                 dnl currently supported checks:
1155                 dnl
1156                 dnl Check for no flags
1157                 dnl     pthread_create() in $LIBS
1158                 dnl
1159                 dnl Check special pthread (final) flags
1160                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1161                 dnl     pthread_create() with -kthread (FreeBSD)
1162                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1163                 dnl     pthread_create() with -pthreads (?)
1164                 dnl     pthread_create() with -mthreads (AIX)
1165                 dnl     pthread_create() with -thread (?)
1166                 dnl
1167                 dnl Check pthread (final) libraries
1168                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1169                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1170                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1171                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1172                 dnl     pthread_create() in -lpthread (many)
1173                 dnl     pthread_create() in -lc_r (FreeBSD)
1174                 dnl
1175                 dnl Check pthread (draft4) flags (depreciated)
1176                 dnl     pthread_create() with -threads (OSF/1)
1177                 dnl
1178                 dnl Check pthread (draft4) libraries (depreciated)
1179                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1180                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1181                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1182                 dnl     pthread_create() in -lpthreads (many)
1183                 dnl
1184
1185                 dnl pthread_create in $LIBS
1186                 AC_CACHE_CHECK([for pthread_create in default libraries],
1187                         ol_cv_pthread_create,[
1188                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1189                         [ol_cv_pthread_create=yes],
1190                         [ol_cv_pthread_create=no],
1191                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1192                                 [ol_cv_pthread_create=yes],
1193                                 [ol_cv_pthread_create=no])])])
1194
1195                 if test $ol_cv_pthread_create != no ; then
1196                         ol_link_threads=posix
1197                         ol_link_pthreads=""
1198                 fi
1199
1200 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1201                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1202                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1203                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1204                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1205                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1206
1207                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1208                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1209                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1210                         [ol_cv_pthread_lpthread_lmach_lexc])
1211 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1212 dnl                     [ol_cv_pthread_lpthread_lexc])
1213
1214                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1215                         [ol_cv_pthread_lib_lpthread_woff])
1216
1217                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1218                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1219
1220                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1221
1222                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1223                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1224                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1225                         [ol_cv_pthread_lpthreads_lmach_lexc])
1226                 OL_PTHREAD_TRY([-lpthreads -lexc],
1227                         [ol_cv_pthread_lpthreads_lexc])
1228
1229                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1230
1231                 if test $ol_link_threads != no ; then
1232                         AC_DEFINE(HAVE_PTHREADS,1,
1233                                 [define if you have POSIX Threads])
1234
1235                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1236
1237                         dnl save flags
1238                         save_CPPFLAGS="$CPPFLAGS"
1239                         save_LIBS="$LIBS"
1240                         LIBS="$LTHREAD_LIBS $LIBS"
1241
1242                         dnl All POSIX Thread (final) implementations should have
1243                         dnl sched_yield instead of pthread yield.
1244                         dnl check for both
1245                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1246
1247                         if test $ac_cv_func_sched_yield = no -a \
1248                                 $ac_cv_func_pthread_yield = no ; then
1249                                 dnl Digital UNIX has sched_yield() in -lrt
1250                                 AC_CHECK_LIB(rt, sched_yield,
1251                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1252                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1253                                                 [Define if you have the sched_yield function.])
1254                                         ac_cv_func_sched_yield=yes],
1255                                         [ac_cv_func_sched_yield=no])
1256                         fi
1257                         if test $ac_cv_func_sched_yield = no -a \
1258                                 $ac_cv_func_pthread_yield = no ; then
1259                                 dnl Solaris has sched_yield() stub in -lposix4
1260                                 dnl but we'll use thr_yield instead.
1261                                 AC_CHECK_FUNCS(thr_yield)
1262                         fi
1263                         if test $ac_cv_func_sched_yield = no -a \
1264                                 $ac_cv_func_pthread_yield = no -a \
1265                                 "$ac_cv_func_thr_yield" = no ; then
1266                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1267                         fi
1268
1269                         dnl Check functions for compatibility
1270                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1271
1272                         dnl Check for pthread_detach with <pthread.h> inclusion
1273                         dnl as it's symbol may have been mangled.
1274                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1275                                 [ol_cv_func_pthread_detach], [
1276                                 dnl save the flags
1277                                 AC_TRY_LINK([
1278 #include <pthread.h>
1279 #ifndef NULL
1280 #define NULL (void*)0
1281 #endif
1282 ],
1283                                         [pthread_detach(NULL);],
1284                                         [ol_cv_func_pthread_detach=yes],
1285                                         [ol_cv_func_pthread_detach=no])
1286                         ])
1287
1288                         if test $ol_cv_func_pthread_detach = no ; then
1289                                 AC_MSG_ERROR([could not locate pthread_detach()])
1290                         fi
1291
1292                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1293                                 [define if you have pthread_detach function])
1294
1295                         dnl Check for setconcurreny functions
1296                         AC_CHECK_FUNCS( \
1297                                 pthread_setconcurrency \
1298                                 pthread_getconcurrency \
1299                                 thr_setconcurrency \
1300                                 thr_getconcurrency \
1301                         )
1302
1303                         OL_SYS_LINUX_THREADS
1304                         OL_LINUX_THREADS
1305
1306                         if test $ol_cv_linux_threads = error; then
1307                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1308                         fi
1309
1310                         AC_CACHE_CHECK([if pthread_create() works],
1311                                 ol_cv_pthread_create_works,[
1312                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1313                                 [ol_cv_pthread_create_works=yes],
1314                                 [ol_cv_pthread_create_works=no],
1315                                 [dnl assume yes
1316                                 ol_cv_pthread_create_works=yes])])
1317
1318                         if test $ol_cv_pthread_create_works = no ; then
1319                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1320                         fi
1321
1322                         dnl Check if select causes an yield
1323                         if test $ol_with_yielding_select = auto ; then
1324                                 AC_CACHE_CHECK([if select yields when using pthreads],
1325                                         ol_cv_pthread_select_yields,[
1326                                 AC_TRY_RUN([
1327 #include <sys/types.h>
1328 #include <sys/time.h>
1329 #include <unistd.h>
1330 #include <pthread.h>
1331 #ifndef NULL
1332 #define NULL (void*) 0
1333 #endif
1334
1335 static int fildes[2];
1336
1337 static void *task(p)
1338         void *p;
1339 {
1340         int i;
1341         struct timeval tv;
1342
1343         fd_set rfds;
1344
1345         tv.tv_sec=10;
1346         tv.tv_usec=0;
1347
1348         FD_ZERO(&rfds);
1349         FD_SET(fildes[0], &rfds);
1350
1351         /* we're not interested in any fds */
1352         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1353
1354         if(i < 0) {
1355                 perror("select");
1356                 exit(10);
1357         }
1358
1359         exit(0); /* if we exit here, the select blocked the whole process */
1360 }
1361
1362 int main(argc, argv)
1363         int argc;
1364         char **argv;
1365 {
1366         pthread_t t;
1367
1368         /* create a pipe to select */
1369         if(pipe(&fildes[0])) {
1370                 perror("select");
1371                 exit(1);
1372         }
1373
1374 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1375         (void) pthread_setconcurrency(2);
1376 #else
1377 #ifdef HAVE_THR_SETCONCURRENCY
1378         /* Set Solaris LWP concurrency to 2 */
1379         thr_setconcurrency(2);
1380 #endif
1381 #endif
1382
1383 #if HAVE_PTHREADS_D4
1384         pthread_create(&t, pthread_attr_default, task, NULL);
1385 #else
1386         pthread_create(&t, NULL, task, NULL);
1387 #endif
1388
1389 #if HAVE_SCHED_YIELD
1390         sched_yield();  /* make sure task runs first */
1391 #else
1392 #ifdef HAVE_PTHREAD_YIELD
1393         pthread_yield();        /* make sure task runs first */
1394 #endif
1395 #endif
1396
1397         exit(2);
1398 }],
1399                                 [ol_cv_pthread_select_yields=no],
1400                                 [ol_cv_pthread_select_yields=yes],
1401                                 [ol_cv_pthread_select_yields=cross])])
1402
1403                                 if test $ol_cv_pthread_select_yields = cross ; then
1404                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1405                                 fi
1406
1407                                 if test $ol_cv_pthread_select_yields = yes ; then
1408                                         ol_with_yielding_select=yes
1409                                 fi
1410                         fi
1411
1412                         dnl restore flags
1413                         CPPFLAGS="$save_CPPFLAGS"
1414                         LIBS="$save_LIBS"
1415                 else
1416                         AC_MSG_ERROR([could not link with POSIX Threads])
1417                 fi
1418         fi
1419
1420         if test $ol_with_threads = posix ; then
1421                 AC_MSG_ERROR([could not locate POSIX Threads])
1422         fi
1423 fi
1424
1425 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1426         -o $ol_with_threads = mach ; then
1427
1428         dnl check for Mach CThreads
1429         AC_CHECK_HEADERS(mach/cthreads.h)
1430         if test $ac_cv_header_mach_cthreads_h = yes ; then
1431                 ol_with_threads=found
1432
1433                 dnl check for cthread support in current $LIBS
1434                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1435
1436                 if test $ol_link_threads = no ; then
1437                         dnl try -all_load
1438                         dnl this test needs work
1439                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1440                                 [ol_cv_cthread_all_load], [
1441                                 dnl save the flags
1442                                 save_LIBS="$LIBS"
1443                                 LIBS="-all_load $LIBS"
1444                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1445                                         cthread_fork((void *)0, (void *)0);
1446                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1447                                 dnl restore the LIBS
1448                                 LIBS="$save_LIBS"
1449                         ])
1450
1451                         if test $ol_cv_cthread_all_load = yes ; then
1452                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1453                                 ol_link_threads=mach
1454                         fi
1455                 fi
1456
1457                 if test $ol_link_threads != no ; then
1458                         : check for cthread specific functionality here
1459                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1460                                 [define if you have Mach Cthreads])
1461                 else
1462                         AC_MSG_ERROR([could not link with Mach CThreads])
1463                 fi
1464         fi
1465
1466         if test $ol_with_threads = mach ; then
1467                 AC_MSG_ERROR([could not locate Mach CThreads])
1468         fi
1469 fi
1470
1471 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1472         -o $ol_with_threads = pth ; then
1473
1474         AC_CHECK_HEADERS(pth.h)
1475
1476         if test $ac_cv_header_pth_h = yes ; then
1477                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1478
1479                 if test $have_pth = yes ; then
1480                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1481                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1482                         ol_link_threads=pth
1483
1484                         if test $ol_with_yielding_select = auto ; then
1485                                 ol_with_yielding_select=yes
1486                         fi
1487                 fi
1488         fi
1489 fi
1490
1491 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1492         -o $ol_with_threads = lwp ; then
1493
1494         dnl check for SunOS5 LWP
1495         AC_CHECK_HEADERS(thread.h synch.h)
1496         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1497                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1498
1499                 if test $have_thr = yes ; then
1500                         AC_DEFINE(HAVE_THR,1,
1501                                 [if you have Solaris LWP (thr) package])
1502                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1503                         ol_link_threads=thr
1504
1505                         if test $ol_with_yielding_select = auto ; then
1506                                 ol_with_yielding_select=yes
1507                         fi
1508
1509                         dnl Check for setconcurreny functions
1510                         AC_CHECK_FUNCS( \
1511                                 thr_setconcurrency \
1512                                 thr_getconcurrency \
1513                         )
1514                 fi
1515         fi
1516
1517         dnl check for SunOS4 LWP
1518         AC_CHECK_HEADERS(lwp/lwp.h)
1519         if test $ac_cv_header_lwp_lwp_h = yes ; then
1520                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1521
1522                 if test $have_lwp = yes ; then
1523                         AC_DEFINE(HAVE_LWP,1,
1524                                 [if you have SunOS LWP package])
1525                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1526                         ol_link_threads=lwp
1527
1528                         if test $ol_with_yielding_select = auto ; then
1529                                 ol_with_yielding_select=no
1530                         fi
1531                 fi
1532         fi
1533 fi
1534
1535 if test $ol_with_yielding_select = yes ; then
1536         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1537                 [define if select implicitly yields])
1538 fi
1539
1540 if test $ol_with_threads = manual ; then
1541         dnl User thinks he can manually configure threads.
1542         ol_link_threads=yes
1543
1544         AC_MSG_WARN([thread defines and link options must be set manually])
1545
1546         AC_CHECK_HEADERS(pthread.h sched.h)
1547         AC_CHECK_FUNCS(sched_yield pthread_yield)
1548         OL_HEADER_LINUX_THREADS
1549
1550         AC_CHECK_HEADERS(mach/cthreads.h)
1551         AC_CHECK_HEADERS(lwp/lwp.h)
1552         AC_CHECK_HEADERS(thread.h synch.h)
1553 fi
1554
1555 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1556         dnl needed to get reentrant/threadsafe versions
1557         dnl
1558         AC_DEFINE(REENTRANT,1)
1559         AC_DEFINE(_REENTRANT,1)
1560         AC_DEFINE(THREAD_SAFE,1)
1561         AC_DEFINE(_THREAD_SAFE,1)
1562         AC_DEFINE(THREADSAFE,1)
1563         AC_DEFINE(_THREADSAFE,1)
1564         AC_DEFINE(_SGI_MP_SOURCE,1)
1565
1566         dnl The errno declaration may dependent upon _REENTRANT.
1567         dnl If it does, we must link with thread support.
1568         AC_CACHE_CHECK([for thread specific errno],
1569                 [ol_cv_errno_thread_specific], [
1570                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1571                         [ol_cv_errno_thread_specific=yes],
1572                         [ol_cv_errno_thread_specific=no])
1573         ])
1574
1575         dnl The h_errno declaration may dependent upon _REENTRANT.
1576         dnl If it does, we must link with thread support.
1577         AC_CACHE_CHECK([for thread specific h_errno],
1578                 [ol_cv_h_errno_thread_specific], [
1579                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1580                         [ol_cv_h_errno_thread_specific=yes],
1581                         [ol_cv_h_errno_thread_specific=no])
1582         ])
1583
1584         if test $ol_cv_errno_thread_specific != yes \
1585                 -o $ol_cv_h_errno_thread_specific != yes ; then
1586                 LIBS="$LTHREAD_LIBS $LIBS"
1587                 LTHREAD_LIBS=""
1588         fi
1589
1590 dnl When in thread environment, use
1591 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1592 dnl                     || defined( HAVE_FUNC_R )
1593 dnl                     func_r(...);
1594 dnl             #else
1595 dnl             #       if defined( HAVE_THREADS )
1596 dnl                             /* lock */
1597 dnl             #       endif
1598 dnl                             func(...);
1599 dnl             #       if defined( HAVE_THREADS )
1600 dnl                             /* unlock */
1601 dnl             #       endif
1602 dnl             #endif
1603 dnl
1604 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1605 dnl             _POSIX_REENTRANT_FUNCTIONS
1606 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1607 dnl             _POSIX_THREADSAFE_FUNCTIONS
1608 dnl
1609 dnl             and is currently defined in lthread.h
1610 dnl
1611 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1612 dnl
1613 dnl libldap/*.c should only include <lthread.h> iff
1614 dnl LDAP_R_COMPILE is defined.  ie:
1615 dnl             #ifdef LDAP_R_COMPILE
1616 dnl             #       include LDAP_R_COMPILE
1617 dnl             #endif
1618 dnl
1619 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1620 dnl specifically for compiling the threadsafe version of
1621 dnl     the ldap library (-lldap_r).
1622 dnl
1623 dnl     dnl check for reentrant/threadsafe functions
1624 dnl     dnl
1625 dnl     dnl note: these should only be used when linking
1626 dnl     dnl       with $LTHREAD_LIBS
1627 dnl     dnl
1628 dnl     save_CPPFLAGS="$CPPFLAGS"
1629 dnl     save_LIBS="$LIBS"
1630 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1631 dnl     AC_CHECK_FUNCS( \
1632 dnl             gmtime_r \
1633 dnl             gethostbyaddr_r gethostbyname_r \
1634 dnl             feof_unlocked unlocked_feof \
1635 dnl             putc_unlocked unlocked_putc \
1636 dnl             flockfile ftrylockfile \
1637 dnl     )
1638 dnl     CPPFLAGS="$save_CPPFLAGS"
1639 dnl     LIBS="$save_LIBS"
1640 fi
1641
1642 if test $ol_link_threads = no ; then
1643         if test $ol_with_threads = yes ; then
1644                 AC_MSG_ERROR([no suitable thread support])
1645         fi
1646
1647         if test $ol_with_threads = auto ; then
1648                 AC_MSG_WARN([no suitable thread support, disabling threads])
1649                 ol_with_threads=no
1650         fi
1651
1652         AC_DEFINE(NO_THREADS,1,
1653                 [define if you have (or want) no threads])
1654         LTHREAD_LIBS=""
1655 fi
1656
1657 if test $ol_link_threads != no ; then
1658         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1659 fi
1660
1661 dnl ----------------------------------------------------------------
1662 ol_link_ldbm=no
1663
1664 if test $ol_with_ldbm_api = auto \
1665         -o $ol_with_ldbm_api = berkeley \
1666         -o $ol_with_ldbm_api = bcompat ; then
1667
1668         if test $ol_with_ldbm_api = bcompat; then \
1669                 OL_BERKELEY_COMPAT_DB
1670         else
1671                 OL_BERKELEY_DB
1672         fi
1673
1674         if test $ol_cv_berkeley_db != no ; then
1675                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1676                         [define this if Berkeley DB is available])
1677
1678                 ol_link_ldbm=berkeley
1679                 ol_with_ldbm_api=db
1680
1681                 if test $ol_with_ldbm_type = hash ; then
1682                         AC_DEFINE(LDBM_USE_DBHASH,1,
1683                                 [define this to use DBHASH w/ LDBM backend])
1684                 else
1685                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1686                                 [define this to use DBBTREE w/ LDBM backend])
1687                 fi
1688
1689                 dnl $ol_cv_lib_db should be yes or -ldb
1690                 dnl (it could be no, but that would be an error
1691                 if test $ol_cv_lib_db != yes ; then
1692                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1693                 fi
1694         fi
1695 fi
1696
1697 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1698         AC_MSG_WARN(Could not find LDBM with BTREE support)
1699         ol_with_ldbm_api=none
1700 fi
1701
1702 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1703         OL_MDBM
1704
1705         if test $ol_cv_mdbm = yes ; then
1706                 ol_link_ldbm=mdbm
1707                 ol_with_ldbm_api=mdbm
1708                 if test $ol_cv_lib_mdbm != yes ; then
1709                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1710                 fi
1711         fi
1712 fi
1713
1714 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1715         OL_GDBM
1716
1717         if test $ol_cv_gdbm = yes ; then
1718                 ol_link_ldbm=gdbm
1719                 ol_with_ldbm_api=gdbm
1720
1721                 if test $ol_cv_lib_gdbm != yes ; then
1722                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1723                 fi
1724         fi
1725 fi
1726
1727 if test $ol_with_ldbm_api = ndbm ; then
1728         OL_NDBM
1729
1730         if test $ol_cv_ndbm = yes ; then
1731                 ol_link_ldbm=ndbm
1732                 ol_with_ldbm_api=ndbm
1733
1734                 if test $ol_cv_lib_ndbm != yes ; then
1735                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1736                 fi
1737         fi
1738 fi
1739
1740 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1741         AC_MSG_WARN(could not find suitable LDBM backend)
1742         if test $ol_enable_ldbm = yes ; then
1743                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1744         fi
1745
1746         AC_MSG_WARN(disabling LDBM)
1747         ol_enable_ldbm=no
1748 fi
1749
1750 dnl ----------------------------------------------------------------
1751 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1752         LINK_BINS_DYNAMIC="yes"
1753 else
1754         LINK_BINS_DYNAMIC="no"
1755 fi
1756
1757 dnl ----------------------------------------------------------------
1758 if test $ol_enable_wrappers != no ; then
1759         AC_CHECK_HEADERS(tcpd.h)
1760
1761         if test $ac_cv_header_tcpd_h != yes ; then
1762                 have_wrappers=no
1763         else
1764                 AC_TRY_COMPILE([
1765 int allow_severity = 0;
1766 int deny_severity  = 0;
1767                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1768         fi
1769
1770         if test $have_wrappers = yes ; then
1771                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1772                 WRAP_LIBS="-lwrap"
1773
1774                 dnl We add another check for -lnsl since some libwrap's
1775                 dnl need it, but it isn't always included from above
1776                 AC_CHECK_LIB(nsl, main)
1777         else
1778                 AC_MSG_WARN(could not find -lwrap)
1779                 if test $ol_enable_wrappers = yes ; then
1780                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1781                 fi
1782
1783                 AC_MSG_WARN(disabling wrappers support)
1784                 ol_enable_wrappers=no
1785                 WRAP_LIBS=""
1786         fi
1787 fi
1788
1789 dnl ----------------------------------------------------------------
1790 if test $ol_enable_syslog != no ; then
1791         AC_CHECK_FUNC(openlog)
1792         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1793                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1794         fi
1795         ol_enable_syslog=$ac_cv_func_openlog
1796 fi
1797
1798 dnl ----------------------------------------------------------------
1799 dnl dmalloc support (deprecated in favor of -DCSRIMALLOC support)
1800 dnl if test $ol_enable_dmalloc != no ; then
1801 dnl     AC_CHECK_HEADERS(dmalloc.h)
1802 dnl     AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1803 dnl fi
1804
1805 dnl ----------------------------------------------------------------
1806 dnl SQL
1807 ol_link_sql=no
1808 if test $ol_enable_sql != no ; then
1809         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
1810         if test $have_iodbc = yes ; then
1811                 ol_link_sql="-liodbc"
1812         else
1813                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
1814                 if test $have_odbc = yes ; then
1815                         ol_link_sql="-lodbc"
1816                 fi
1817         fi
1818
1819         if test $ol_link_sql != no ; then
1820                 SLAPD_SQL_LIBS="$ol_link_sql"
1821
1822         elif test $ol_enable_sql != auto ; then
1823                 AC_MSG_ERROR([could not locate suitable ODBC library])
1824         fi
1825 fi
1826
1827 dnl ----------------------------------------------------------------
1828 dnl TCL
1829 if test $ol_enable_tcl != no ; then
1830         AC_CHECK_HEADERS(tcl.h)
1831
1832         if test $ac_cv_header_tcl_h != yes ; then
1833                 have_tcl=no
1834         else
1835                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1836                         AC_CHECK_LIB($lib,main,
1837                           [have_tcl=yes
1838                            if test x"$ol_with_tcl_module" = "xstatic" ; then
1839                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1840                            else
1841                                MOD_TCL_LIB="-l${lib}"
1842                            fi;break],[have_tcl=no])
1843                 done
1844         fi
1845
1846         if test $have_tcl != yes ; then
1847                 AC_MSG_WARN([could not find -ltcl])
1848                 if test $ol_enable_tcl = yes ; then
1849                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1850                 fi
1851
1852                 ol_enable_tcl=no
1853         fi
1854 fi
1855
1856 dnl ----------------------------------------------------------------
1857 dnl ud needs termcap (should insert check here)
1858 ol_link_termcap=no
1859 AC_CHECK_HEADERS(termcap.h ncurses.h)
1860
1861 if test $ol_link_termcap = no ; then
1862         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1863         if test $have_termcap = yes ; then
1864                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1865                 ol_link_termcap=yes
1866                 TERMCAP_LIBS=-ltermcap
1867         fi
1868 fi
1869
1870 if test $ol_link_termcap = no ; then
1871         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1872         if test $have_ncurses = yes ; then
1873                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1874                 ol_link_termcap=yes
1875                 TERMCAP_LIBS=-lncurses
1876         fi
1877 fi
1878
1879 if test $ol_link_termcap = no ; then
1880         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1881         TERMCAP_LIBS=
1882 fi
1883
1884 dnl ----------------------------------------------------------------
1885 dnl
1886 dnl Check for Cyrus SASL
1887 dnl
1888 ol_link_sasl=no
1889 ol_link_spasswd=no
1890 if test $ol_with_cyrus_sasl != no ; then
1891         AC_CHECK_HEADERS(sasl.h)
1892
1893         if test $ac_cv_header_sasl_h = yes ; then
1894                 AC_CHECK_LIB(sasl, sasl_client_init,
1895                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1896
1897                 if test $have_cyrus_sasl != no ; then
1898                         SASL_LIBS="-lsasl"
1899                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1900                         ol_link_sasl=yes
1901                 fi
1902         fi
1903
1904         if test $ol_link_sasl = no ; then
1905                 if test $ol_with_cyrus_sasl != auto ; then
1906                         AC_MSG_ERROR([Could not locate Cyrus SASL])
1907                 else
1908                         AC_MSG_WARN([Could not locate Cyrus SASL])
1909                         AC_MSG_WARN([SASL authentication not supported!])
1910                         if test $ol_link_tls = no ; then
1911                                 AC_MSG_WARN([Strong authentication not supported!])
1912                         fi
1913                 fi
1914         fi
1915 else
1916         AC_MSG_WARN([SASL authentication not supported!])
1917         if test $ol_link_tls = no ; then
1918                 AC_MSG_WARN([Strong authentication not supported!])
1919         fi
1920 fi
1921
1922 dnl ----------------------------------------------------------------
1923 dnl Check for entropy sources
1924 if test $cross_compiling != yes ; then
1925         dev=no
1926         if test -r /dev/urandom ; then
1927                 dev="/dev/urandom";
1928         elif test -r /idev/urandom ; then
1929                 dev="/idev/urandom";
1930         elif test -r /dev/srandom ; then
1931                 dev="/dev/srandom";
1932         elif test -r /dev/random ; then
1933                 dev="/dev/random";
1934         elif test -r /idev/random ; then
1935                 dev="/idev/random";
1936         fi
1937
1938         if test $dev != no ; then
1939                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1940         fi
1941 fi
1942
1943 dnl ----------------------------------------------------------------
1944 dnl
1945 dnl Check for fetch URL support
1946 dnl             should be extended to support other fetch URL APIs
1947 dnl
1948 ol_link_fetch=no
1949 if test $ol_with_fetch != no ; then
1950         OL_LIB_FETCH
1951
1952         if test $ol_cv_lib_fetch != no ; then
1953                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1954                 ol_link_fetch=freebsd
1955
1956         elif test $ol_with_fetch != auto ; then
1957                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1958         fi
1959 fi
1960
1961 dnl ----------------------------------------------------------------
1962 dnl
1963 dnl Check for GNU readline
1964 dnl
1965 ol_link_readline=no
1966 if test $ol_with_readline != no ; then
1967         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1968
1969         if test $ac_cv_header_readline_readline_h = yes ; then
1970                 save_LIBS="$LIBS"
1971                 LIBS="$TERMCAP_LIBS $LIBS"
1972                 AC_CHECK_LIB(readline, readline,
1973                         [have_readline=yes], [have_readline=no])
1974                 LIBS="$save_LIBS"
1975
1976                 if test $have_readline = yes ; then
1977                         ol_with_readline=found
1978                         ol_link_readline=yes
1979
1980                         READLINE_LIBS="-lreadline"
1981                 fi
1982         fi
1983 fi
1984
1985 if test $ol_link_readline = yes ; then
1986         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1987 fi
1988
1989
1990 dnl ----------------------------------------------------------------
1991 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1992 if test $ol_enable_crypt != no ; then
1993         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1994                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1995                         have_crypt=yes], [have_crypt=no])])
1996
1997         if test $have_crypt = yes ; then
1998                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1999         else
2000                 AC_MSG_WARN(could not find crypt)
2001                 if test $ol_enable_crypt = yes ; then
2002                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
2003                 fi
2004
2005                 AC_MSG_WARN(disabling crypt support)
2006                 ol_enable_crypt=no
2007         fi
2008 fi
2009
2010 dnl ----------------------------------------------------------------
2011 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2012 if test $ol_enable_proctitle != no ; then
2013         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2014                 AC_CHECK_LIB(util, setproctitle,
2015                         [have_setproctitle=yes
2016                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2017                         [have_setproctitle=no
2018                         LIBOBJS="$LIBOBJS setproctitle.o"
2019                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2020
2021         if test $have_setproctitle = yes ; then
2022                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2023                         [define if setproctitle(3) is available])
2024         fi
2025 fi
2026
2027 dnl ----------------------------------------------------------------
2028 dnl Checks for typedefs, structures, and compiler characteristics.
2029 AC_TYPE_MODE_T
2030 AC_TYPE_OFF_T
2031 AC_TYPE_PID_T
2032 AM_TYPE_PTRDIFF_T
2033 AC_TYPE_SIGNAL
2034 AC_TYPE_SIZE_T
2035
2036 AC_CHECK_TYPE(ssize_t, [signed int])
2037 AC_CHECK_TYPE(caddr_t,  [char *])
2038
2039 OL_TYPE_SOCKLEN_T
2040 AC_STRUCT_ST_BLKSIZE
2041 AC_HEADER_TIME
2042 AC_STRUCT_TM
2043 AC_TYPE_UID_T
2044 OL_TYPE_SIG_ATOMIC_T
2045
2046 dnl AC_TYPE_GETGROUPS
2047
2048 OL_STRUCT_PASSWD_PW_GECOS
2049 OL_STRUCT_PASSWD_PW_PASSWD
2050
2051 OL_C_UPPER_LOWER
2052 AC_C_CONST
2053 OL_C_VOLATILE
2054
2055 if test $cross_compiling = yes ; then
2056         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2057 else
2058         AC_C_BIGENDIAN
2059 fi
2060
2061 AC_COMPILE_CHECK_SIZEOF(short)
2062 AC_COMPILE_CHECK_SIZEOF(int)
2063 AC_COMPILE_CHECK_SIZEOF(long)
2064
2065 if test "$ac_cv_sizeof_int" -lt 4 ; then
2066         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2067
2068         AC_DEFINE(LBER_INT_T,long)
2069 else
2070         AC_DEFINE(LBER_INT_T,int)
2071 fi
2072
2073 AC_DEFINE(LBER_LEN_T,long)
2074 AC_DEFINE(LBER_SOCKET_T,int)
2075 AC_DEFINE(LBER_TAG_T,long)
2076
2077 dnl ----------------------------------------------------------------
2078 dnl Checks for library functions.
2079 AC_FUNC_MEMCMP
2080 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
2081 AC_FUNC_STRFTIME
2082 dnl AM_FUNC_STRTOD
2083
2084 OL_FUNC_INET_ATON
2085
2086 dnl Check for NT specific routines
2087 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2088
2089 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2090         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2091 ])
2092
2093 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2094         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2095 ])
2096
2097 AC_FUNC_VPRINTF
2098
2099 if test $ac_cv_func_vprintf = yes ; then
2100         dnl check for vsnprintf
2101         AC_CHECK_FUNCS(vsnprintf vsprintf)
2102 fi
2103
2104 AC_CHECK_FUNCS(         \
2105         bcopy                   \
2106         closesocket             \
2107         chroot                  \
2108         endgrent                \
2109         endpwent                \
2110         flock                   \
2111         getdtablesize   \
2112         getgrgid                \
2113         gethostname             \
2114         getpass                 \
2115         getpassphrase   \
2116         getpwuid                \
2117         getpwnam                \
2118         getspnam                \
2119         gettimeofday    \
2120         initgroups              \
2121         lockf                   \
2122         memcpy                  \
2123         memmove                 \
2124         mkstemp                 \
2125         pipe                    \
2126         read                    \
2127         recv                    \
2128         recvfrom                \
2129         setpwfile               \
2130         setgid                  \
2131         setegid                 \
2132         setsid                  \
2133         setuid                  \
2134         seteuid                 \
2135         sigaction               \
2136         signal                  \
2137         sigset                  \
2138         snprintf                \
2139         strdup                  \
2140         strerror                \
2141         strpbrk                 \
2142         strrchr                 \
2143         strsep                  \
2144         strstr                  \
2145         strtol                  \
2146         strtoul                 \
2147         strspn                  \
2148         sysconf                 \
2149         waitpid                 \
2150         wait4                   \
2151         write                   \
2152         send                    \
2153         sendto                  \
2154 )
2155
2156 dnl We actually may need to replace more than this.
2157 AC_REPLACE_FUNCS(getopt tempnam)
2158
2159 if test "$ac_cv_func_getopt" != yes; then
2160     LIBSRCS="$LIBSRCS getopt.c"
2161 fi
2162
2163 if test "$ac_cv_func_tempnam" != yes; then
2164     LIBSRCS="$LIBSRCS tempnam.c"
2165 fi
2166
2167 dnl ----------------------------------------------------------------
2168 # Check Configuration
2169 OL_SYS_ERRLIST
2170
2171 dnl ----------------------------------------------------------------
2172 dnl Sort out defines
2173
2174 if test "$ol_enable_debug" != no ; then
2175         AC_DEFINE(LDAP_DEBUG,1,
2176                 [define this to add debugging code])
2177 fi
2178 if test "$ol_enable_syslog" = yes ; then
2179         AC_DEFINE(LDAP_SYSLOG,1,
2180                 [define this to add syslog code])
2181 fi
2182 if test "$ol_enable_cache" = no ; then
2183         AC_DEFINE(LDAP_NOCACHE,1,
2184                 [define this to remove -lldap cache support])
2185 fi
2186 if test "$ol_link_kbind" != no ; then
2187         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2188 fi
2189 if test "$ol_enable_proctitle" != no ; then
2190         AC_DEFINE(LDAP_PROCTITLE,1,
2191                 [define this for LDAP process title support])
2192 fi
2193 if test "$ol_enable_referrals" != no ; then
2194         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2195 fi
2196 if test "$ol_enable_local" != no; then
2197         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2198 fi
2199 if test "$ol_enable_ipv6" != no; then
2200         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2201 fi
2202 if test "$ol_enable_cleartext" != no ; then
2203         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2204 fi
2205 if test "$ol_enable_crypt" != no ; then
2206         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2207 fi
2208 if test "$ol_link_kpasswd" != no ; then
2209         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2210 fi
2211 if test "$ol_link_spasswd" != no ; then
2212         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2213 fi
2214 if test "$ol_enable_multimaster" != no ; then
2215         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2216 fi
2217 if test "$ol_enable_phonetic" != no ; then
2218         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2219 fi
2220 if test "$ol_enable_rlookups" != no ; then
2221         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2222 fi
2223 if test "$ol_enable_aci" != no ; then
2224         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2225 fi
2226
2227 if test "$ol_link_modules" != no ; then
2228         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2229         BUILD_SLAPD=yes
2230         SLAPD_MODULES_LDFLAGS="-dlopen self"
2231 fi
2232
2233 if test "$ol_enable_bdb" != no ; then
2234         AC_DEFINE(SLAPD_BDB,1,[define to support BDB backend])
2235         BUILD_SLAPD=yes
2236         BUILD_BDB=yes
2237         if test "$ol_with_bdb_module" != static ; then
2238                 AC_DEFINE(SLAPD_BDB_DYNAMIC,1,
2239                         [define to support dynamic BDB backend])
2240                 BUILD_BDB=mod
2241                 BUILD_BDB_DYNAMIC=shared
2242                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb/back_bdb.la"
2243         fi
2244 fi
2245
2246 if test "$ol_link_dnssrv" != no ; then
2247         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2248         BUILD_SLAPD=yes
2249         BUILD_DNSSRV=yes
2250         if test "$ol_with_dnssrv_module" != static ; then
2251                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2252                         [define to support dynamic DNS SRV backend])
2253                 BUILD_DNSSRV=mod
2254                 BUILD_DNSSRV_DYNAMIC=shared
2255                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2256         fi
2257 fi
2258
2259 if test "$ol_enable_ldap" != no ; then
2260         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2261         BUILD_SLAPD=yes
2262         BUILD_LDAP=yes
2263         if test "$ol_with_ldap_module" != static ; then
2264                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2265                         [define to support dynamic LDAP backend])
2266                 BUILD_LDAP=mod
2267                 BUILD_LDAP_DYNAMIC=shared
2268                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2269         fi
2270 fi
2271
2272 if test "$ol_link_ldbm" != no ; then
2273         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2274         BUILD_SLAPD=yes
2275         BUILD_LDBM=yes
2276         if test "$ol_with_ldbm_module" != static ; then
2277                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2278                         [define to support dynamic LDBM backend])
2279                 BUILD_LDBM=mod
2280                 BUILD_LDBM_DYNAMIC=shared
2281                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2282         fi
2283 fi
2284
2285 if test "$ol_enable_passwd" != no ; then
2286         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2287         BUILD_SLAPD=yes
2288         BUILD_PASSWD=yes
2289         if test "$ol_with_passwd_module" != static ; then
2290                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2291                         [define to support dynamic PASSWD backend])
2292                 BUILD_PASSWD=mod
2293                 BUILD_PASSWD_DYNAMIC=shared
2294                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2295         fi
2296 fi
2297
2298 if test "$ol_link_perl" != no ; then
2299         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2300         BUILD_SLAPD=yes
2301         BUILD_PERL=yes
2302         if test "$ol_with_perl_module" != static ; then
2303                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2304                         [define to support dynamic PERL backend])
2305                 BUILD_PERL=mod
2306                 BUILD_PERL_DYNAMIC=shared
2307                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2308         fi
2309 fi
2310
2311 if test "$ol_enable_shell" != no ; then
2312         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2313         BUILD_SLAPD=yes
2314         BUILD_SHELL=yes
2315         if test "$ol_with_shell_module" != static ; then
2316                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2317                         [define to support dynamic SHELL backend])
2318                 BUILD_SHELL=mod
2319                 BUILD_SHELL_DYNAMIC=shared
2320                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2321         fi
2322 fi
2323
2324 if test "$ol_enable_tcl" != no ; then
2325         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2326         BUILD_SLAPD=yes
2327         BUILD_TCL=yes
2328         if test "$ol_with_tcl_module" != static; then
2329                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2330                         [define to support dynamic TCL backend])
2331                 BUILD_TCL=mod
2332                 BUILD_TCL_DYNAMIC=shared
2333                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2334         fi
2335 fi
2336
2337 if test "$ol_link_sql" != no ; then
2338         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2339         BUILD_SLAPD=yes
2340         BUILD_SQL=yes
2341         if test "$ol_with_sql_module" != static; then
2342                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2343                         [define to support dynamic SQL backend])
2344                 BUILD_SQL=mod
2345                 BUILD_SQL_DYNAMIC=shared
2346                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2347         fi
2348 fi
2349
2350 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2351         $BUILD_SLAPD = yes ; then
2352         BUILD_SLURPD=yes
2353 fi
2354
2355 dnl ----------------------------------------------------------------
2356
2357 if test "$LINK_BINS_DYNAMIC" = yes; then
2358     LIB_LINKAGE=DYN
2359     LT_LIB_LINKAGE=shared
2360 else
2361     LIB_LINKAGE=STAT
2362     LT_LIB_LINKAGE=static
2363 fi
2364
2365 if test "$ac_cv_mingw32" = yes ; then
2366     PLAT=NT
2367     DYN_EXT=dll
2368 else
2369     PLAT=UNIX
2370     DYN_EXT=so
2371 fi
2372
2373 AC_SUBST(LIBSRCS)
2374
2375 AC_SUBST(PLAT)
2376 AC_SUBST(LIB_LINKAGE)
2377 AC_SUBST(LT_LIB_LINKAGE)
2378 AC_SUBST(DYN_EXT)
2379
2380 AC_SUBST(BUILD_SLAPD)
2381   AC_SUBST(BUILD_BDB)
2382   AC_SUBST(BUILD_DNSSRV)
2383   AC_SUBST(BUILD_LDAP)
2384   AC_SUBST(BUILD_LDBM)
2385   AC_SUBST(BUILD_PASSWD)
2386   AC_SUBST(BUILD_PERL)
2387   AC_SUBST(BUILD_SHELL)
2388   AC_SUBST(BUILD_SQL)
2389   AC_SUBST(BUILD_TCL)
2390   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2391   AC_SUBST(BUILD_LDAP_DYNAMIC)
2392   AC_SUBST(BUILD_LDBM_DYNAMIC)
2393   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2394   AC_SUBST(BUILD_PERL_DYNAMIC)
2395   AC_SUBST(BUILD_SHELL_DYNAMIC)
2396   AC_SUBST(BUILD_SQL_DYNAMIC)
2397   AC_SUBST(BUILD_TCL_DYNAMIC)
2398 AC_SUBST(BUILD_SLURPD)
2399
2400 AC_SUBST(LDAP_LIBS)
2401 AC_SUBST(LDIF_LIBS)
2402 AC_SUBST(SLAPD_LIBS)
2403 AC_SUBST(SLURPD_LIBS)
2404 AC_SUBST(LDBM_LIBS)
2405 AC_SUBST(LTHREAD_LIBS)
2406 AC_SUBST(LUTIL_LIBS)
2407 AC_SUBST(WRAP_LIBS)
2408 AC_SUBST(MOD_TCL_LIB)
2409 AC_SUBST(LINK_BINS_DYNAMIC)
2410
2411 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2412 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2413 AC_SUBST(SLAPD_MODULES_LIST)
2414
2415 AC_SUBST(PERL_CPPFLAGS)
2416 AC_SUBST(SLAPD_PERL_LDFLAGS)
2417 AC_SUBST(MOD_PERL_LDFLAGS)
2418
2419 AC_SUBST(KRB4_LIBS)
2420 AC_SUBST(KRB5_LIBS)
2421 AC_SUBST(READLINE_LIBS)
2422 AC_SUBST(SASL_LIBS)
2423 AC_SUBST(TERMCAP_LIBS)
2424 AC_SUBST(TLS_LIBS)
2425 AC_SUBST(MODULES_LIBS)
2426 AC_SUBST(AUTH_LIBS)
2427
2428 AC_SUBST(SLAPD_SQL_LDFLAGS)
2429 AC_SUBST(SLAPD_SQL_LIBS)
2430 AC_SUBST(SLAPD_SQL_INCLUDES)
2431
2432 dnl ----------------------------------------------------------------
2433 dnl final output
2434 dnl
2435
2436 AC_OUTPUT( \
2437 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2438 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2439 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2440 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2441 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2442 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2443 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2444 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2445 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2446 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2447 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2448 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2449 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2450 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2451 clients/maildap/Makefile:build/top.mk:clients/maildap/Makefile.in:build/rules.mk \
2452 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2453 include/Makefile:build/top.mk:include/Makefile.in \
2454 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2455 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2456 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2457 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2458 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2459 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2460 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2461 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2462 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2463 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2464 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2465 servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk \
2466 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2467 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2468 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2469 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2470 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2471 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2472 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2473 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2474 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2475 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2476 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2477 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2478 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2479 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2480 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2481 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2482 ,[
2483 date > stamp-h
2484 echo Please \"make depend\" to build dependencies
2485 ])