git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(build/version)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17
  18 OL_VERSION=`cat $ac_aux_dir/version`
  19 if test -z "$OL_VERSION"; then
  20         AC_MSG_ERROR([could not determine version])
  21 fi
  22
  23 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  24 AC_SUBST(PACKAGE)
  25 AC_SUBST(VERSION)
  26 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  27 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  28
  29 dnl We use autoconf features new to 2.13.
  30 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  31 AC_PREREQ(2.13)dnl Required Autoconf version
  32
  33 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  34
  35 dnl
  36 dnl Start Args
  37 AC_MSG_CHECKING(configure arguments)
  38 AC_PREFIX_DEFAULT(/usr/local)
  39
  40 top_builddir=`pwd`
  41 AC_SUBST(top_builddir)dnl
  42
  43 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
  44
  45 ldap_subdir="openldap"
  46
  47 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  48         if test "$withval" = "no"; then
  49                 ldap_subdir=""
  50         elif test "$withval" != "yes"; then
  51                 ldap_subdir="$withval"
  52         fi
  53 ])dnl
  54
  55 AC_SUBST(ldap_subdir)dnl
  56
  57 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  58 dnl ol_enable_syslog=no
  59 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  60 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  61 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  62 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  63 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  64 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  65 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  66         no, [yes no])dnl
  67
  68 dnl General "with" options
  69 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  70
  71 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  72         auto, [auto k5 k4 afs yes no])
  73 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  74         auto, [auto yes no] )
  75 OL_ARG_WITH(threads,[  --with-threads   use threads],
  76         auto, [auto posix mach lwp yes no manual] )
  77 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  78         auto, [auto ssleay openssl yes no] )
  79 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  80         auto, [auto yes no manual] )
  81
  82 dnl Server options
  83
  84 dnl LDAPD OPTIONS
  85 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  86 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  87
  88 dnl SLAPD OPTIONS
  89 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  90 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  91 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  92 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  93 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  94 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
  95 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  96 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  97 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  98
  99 dnl SLAPD Backend options
 100 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 101 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 102 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 103 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 104         [auto db2 db mdbm gdbm ndbm manual])
 105 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 106         [auto btree hash])
 107
 108 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 109 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 110 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 111 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 112
 113 dnl SLURPD OPTIONS
 114 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 115 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 116
 117 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 118 AM_ENABLE_STATIC
 119 dnl AM_DISABLE_SHARED
 120 AM_ENABLE_SHARED
 121
 122 dnl General "enable" options
 123 # validate options
 124 if test $ol_enable_dns = yes ; then
 125         if test $ol_enable_referrals = no ; then
 126                 AC_MSG_ERROR([DNS requires --enable-referrals])
 127         fi
 128         if test $ol_enable_referrals = auto ; then
 129                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 130                 ol_enable_referrals=yes
 131         fi
 132 fi
 133
 134 if test $ol_enable_slapd = no ; then
 135         dnl SLAPD was specificallly disabled
 136         if test $ol_enable_bdb2 = yes ; then
 137                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 138         fi
 139         if test $ol_enable_ldap = yes ; then
 140                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 141         fi
 142         if test $ol_enable_ldbm = yes ; then
 143                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 144         fi
 145         if test $ol_enable_passwd = yes ; then
 146                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 147         fi
 148         if test $ol_enable_perl = yes ; then
 149                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 150         fi
 151         if test $ol_enable_shell = yes ; then
 152                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 153         fi
 154         if test $ol_enable_tcl = yes ; then
 155                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 156         fi
 157         if test $ol_enable_aclgroups = yes ; then
 158                 AC_MSG_WARN([slapd disabled, ignoring --enable-aclgroups argument])
 159         fi
 160         if test $ol_enable_modules = yes ; then
 161                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 162         fi
 163         if test $ol_enable_wrappers = yes ; then
 164                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 165         fi
 166         if test $ol_enable_phonetic = yes ; then
 167                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 168         fi
 169         if test $ol_enable_rlookups = yes ; then
 170                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 171         fi
 172         if test $ol_with_ldbm_api != auto ; then
 173                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 174         fi
 175         if test $ol_with_ldbm_type != auto ; then
 176                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 177         fi
 178         if test $ol_enable_slurpd = yes ; then
 179                 AC_MSG_ERROR([slurpd requires slapd])
 180         fi
 181
 182         # force settings to no
 183         ol_enable_bdb2=no
 184         ol_enable_ldap=no
 185         ol_enable_ldbm=no
 186         ol_enable_passwd=no
 187         ol_enable_perl=no
 188         ol_enable_shell=no
 189         ol_enable_tcl=no
 190
 191         ol_enable_aclgroups=no
 192         ol_enable_modules=no
 193         ol_enable_phonetic=no
 194         ol_enable_rlookups=no
 195         ol_enable_wrappers=no
 196
 197         ol_with_ldbm_api=no
 198         ol_with_ldbm_type=no
 199
 200         ol_enable_slurpd=no
 201
 202 elif test $ol_enable_ldbm = no ; then
 203         dnl SLAPD without LDBM
 204
 205         if test $ol_with_ldbm_api != auto ; then
 206                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 207         fi
 208
 209         if test $ol_with_ldbm_type != auto ; then
 210                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 211         fi
 212
 213         if test $ol_enable_bdb2 = yes ; then
 214                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 215         fi
 216
 217         if test $ol_enable_modules != yes -a \
 218                 $ol_enable_ldap = no -a \
 219                 $ol_enable_passwd = no -a \
 220                 $ol_enable_perl = no -a \
 221                 $ol_enable_shell = no -a \
 222                 $ol_enable_tcl = no ; then
 223                 AC_MSG_ERROR([slapd requires a backend])
 224         fi
 225
 226         ol_with_ldbm_api=no
 227         ol_with_ldbm_type=no
 228
 229 elif test $ol_enable_bdb2 = yes ; then
 230         dnl SLAPD with BDB2
 231
 232         if test $ol_with_ldbm_api != auto -a \
 233                 $ol_with_ldbm_api != db2 ; then
 234                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 235         fi
 236
 237         ol_with_ldbm_api=db2
 238
 239 else
 240         dnl SLAPD with LDBM
 241
 242         if test $ol_enable_bdb2 != no ; then
 243                 if test $ol_with_ldbm_api != auto -a \
 244                         $ol_with_ldbm_api != db2 ; then
 245                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 246                         ol_enable_bdb2=no
 247                 fi
 248         fi
 249
 250         if test $ol_with_ldbm_api = gdbm -a \
 251                 $ol_with_ldbm_type = btree ; then
 252                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 253         fi
 254         if test $ol_with_ldbm_api = mdbm -a \
 255                 $ol_with_ldbm_type = btree ; then
 256                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 257         fi
 258         if test $ol_with_ldbm_api = ndbm -a \
 259                 $ol_with_ldbm_type = btree ; then
 260                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 261         fi
 262 fi
 263
 264 if test $ol_enable_slurpd = yes ; then
 265         dnl SLURPD was specifically enabled
 266         if test $ol_with_threads = no ; then
 267                 AC_MSG_ERROR([slurpd requires threads])
 268         fi
 269 fi
 270
 271 AC_MSG_RESULT(done)
 272
 273 ## Initialize vars
 274 LDAP_LIBS=
 275 LDBM_LIBS=
 276 LTHREAD_LIBS=
 277 LUTIL_LIBS=
 278
 279 LDAPD_LIBS=
 280 SLAPD_LIBS=
 281 SLURPD_LIBS=
 282
 283 BUILD_LDAPD=no
 284 BUILD_SLAPD=no
 285 BUILD_SLURPD=no
 286
 287 BUILD_BDB2=no
 288 BUILD_LDAP=no
 289 BUILD_LDBM=no
 290 BUILD_PASSWD=no
 291 BUILD_PERL=no
 292 BUILD_SHELL=no
 293 BUILD_TCL=no
 294 BUILD_THREAD=no
 295
 296 SLAPD_MODULES_LDFLAGS=
 297 SLAPD_MODULES_CPPFLAGS=
 298
 299 SLAPD_PERL_LDFLAGS=
 300 SLAPD_PERL_CPPFLAGS=
 301
 302 KRB_LIBS=
 303 READLINE_LIBS=
 304 TERMCAP_LIBS=
 305 TLS_LIBS=
 306
 307 dnl ----------------------------------------------------------------
 308 dnl Checks for programs
 309
 310 dnl AC_PROG_INSTALL
 311
 312 dnl The default compiler is cc (NOT gcc)
 313 CC=${CC-"cc"}
 314 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 315 dnl CFLAGS=${CFLAGS-""}
 316
 317 AM_PROG_LIBTOOL
 318 dnl AC_PROG_MAKE_SET
 319
 320 AC_PROG_AWK
 321 OL_PROG_LN_H
 322 AC_PROG_LN_S
 323
 324 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 325         LN_S="$LN_H"
 326 fi
 327
 328 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 329         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 330 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 331 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 332
 333 ol_link_modules=no
 334 if test $ol_enable_modules != no ; then
 335         AC_PATH_PROG(GLIBCONFIG, glib-config)
 336
 337         if test "no$GLIBCONFIG" = "no" ; then
 338                 if test $ol_enable_modules = yes ; then
 339                         AC_MSG_ERROR([could not locate glib-config])
 340                 fi
 341
 342         else
 343                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 344                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 345                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 346
 347                 dnl should check glib version
 348                 ol_link_modules=yes
 349         fi
 350 fi
 351
 352 ol_link_perl=no
 353 if test $ol_enable_perl != no ; then
 354         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 355
 356         if test "no$PERLBIN" = "no" ; then
 357                 if test $ol_enable_perl = yes ; then
 358                         AC_MSG_ERROR([could not locate perl])
 359                 fi
 360
 361         else
 362                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 363                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 364
 365                 dnl should check perl version
 366                 ol_link_perl=yes
 367         fi
 368 fi
 369
 370 AC_PROG_CPP
 371
 372 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 373         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 374
 375 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 376         AC_MSG_WARN([programs compiled here do run here...])
 377         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 378
 379 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 380         AC_MSG_WARN([programs compiled here do not run here...])
 381         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 382 fi
 383
 384 dnl Checks for UNIX Variants
 385 AC_AIX
 386 AC_ISC_POSIX
 387 AC_MINIX
 388
 389 dnl BeOS requires -lbe -lroot -lnet
 390 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 391
 392 dnl Checks for system services
 393 AC_CYGWIN
 394 AC_MINGW32
 395 AC_EXEEXT
 396 AC_OBJEXT
 397
 398 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 399
 400 dnl OpenLDAP requires STDC features
 401 AM_PROG_CC_STDC
 402 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 403         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 404 fi
 405
 406 dnl AM_C_PROTOTYPES
 407
 408 dnl Checks for libraries
 409
 410 dnl Find socket()
 411 dnl Likely combinations:
 412 dnl             -lsocket [ -lnsl_s | -lnsl ]
 413 dnl             -linet
 414
 415 AC_CHECK_FUNC(socket, :, [
 416 dnl
 417 dnl hopefully we won't include too many libraries
 418 dnl
 419         AC_CHECK_LIB(socket, main)
 420         AC_CHECK_LIB(net, main)
 421         AC_CHECK_LIB(net, socket)
 422         AC_CHECK_LIB(nsl_s, main)
 423         AC_CHECK_LIB(nsl, main)
 424         AC_CHECK_LIB(inet, socket)
 425         AC_CHECK_LIB(gen, main)
 426 ])
 427
 428 dnl Check for resolver routines
 429 AC_CHECK_FUNCS(res_search)
 430 if test $ac_cv_func_res_search = "no" ; then
 431         AC_CHECK_LIB(bind, res_search)
 432         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 433                 AC_DEFINE(HAVE_RES_SEARCH,1)
 434         else
 435                 AC_CHECK_LIB(resolv, res_search)
 436                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 437                         AC_DEFINE(HAVE_RES_SEARCH,1)
 438                 fi
 439         fi
 440 fi
 441
 442 dnl HP-UX requires -lV3
 443 AC_CHECK_LIB(V3, sigset)
 444
 445 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 446
 447 dnl Select arg types
 448 dnl (if this detection becomes permenent, it and the select() detection
 449 dnl should be done before the yielding select test)
 450 AC_FUNC_SELECT_ARGTYPES
 451
 452 # ISODE tests
 453 ol_link_isode=no
 454 if test $ol_enable_ldapd != no ; then
 455         AC_MSG_WARN([ldapd support deprecated.  Manual intervention required.])
 456
 457         dnl look for ISODE libraries
 458         AC_CHECK_LIB(xtpp, main, [
 459                 ol_link_isode=yes
 460                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 461                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 462                 ],:,[-lxtdsap -lxtisode -losi])
 463         AC_CHECK_LIB(dsap, main, [
 464                 ol_link_isode=yes
 465                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 466                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 467                 ],:,[-lisode])
 468         AC_CHECK_LIB(isode, main, [
 469                 ol_link_isode=yes
 470                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 471                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 472                 ],:)
 473 fi
 474
 475 if test $ol_link_isode != no; then
 476         AC_CHECK_LIB(pp, main, [
 477                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 478                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 479                 ],:)
 480
 481         AC_PATH_PROG(PEPSY, pepsy)
 482 fi
 483
 484 dnl
 485 dnl check for kerberos
 486 dnl
 487 ol_link_kerberos=no
 488
 489 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 490         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 491
 492         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 493                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 494                         [-lkrb5 -ldes425])
 495
 496                 if test $have_k5 = yes ; then
 497                         ol_with_kerberos=found
 498                         ol_link_kerberos=yes
 499
 500                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 501
 502                         LIBS="$KRB_LIBS $LIBS"
 503
 504                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 505                                 [ol_cv_var_des_debug], [
 506                                 dnl save the flags
 507                                 save_LIBS="$LIBS"
 508                                 LIBS="$KRB_LIBS $LIBS"
 509                                 AC_TRY_LINK([
 510 #include <kerberosIV/krb.h>
 511 #include <kerberosIV/des.h>
 512 extern int des_debug;
 513 ],[
 514 des_debug = 1;
 515 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 516                                 dnl restore the LIBS
 517                                 LIBS="$save_LIBS"
 518                         ])
 519
 520                         if test $ol_cv_var_des_debug = yes ; then
 521                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 522                                         [define if you have Kerberos des_debug])
 523                         fi
 524
 525                         LIBS="$save_LIBS"
 526                 fi
 527         fi
 528 fi
 529
 530 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 531         AC_CHECK_HEADERS(krb.h des.h)
 532
 533         if test $ac_cv_header_krb_h = yes ; then
 534                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 535
 536                 if test $have_k4 = yes ; then
 537                         ol_with_kerberos=found
 538                         ol_link_kerberos=yes
 539
 540                         KRB_LIBS="-lkrb -ldes"
 541                 fi
 542         fi
 543 fi
 544
 545 if test $ol_link_kerberos = yes ; then
 546         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 547 fi
 548
 549 dnl
 550 dnl Check for SSL/TLS
 551 dnl
 552 ol_link_tls=no
 553 if test $ol_with_tls != no ; then
 554
 555         AC_CHECK_HEADERS(ssl.h)
 556
 557         if test $ac_cv_header_ssl_h = yes ; then
 558                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 559                         [have_ssleay=yes
 560                         need_rsaref=no],
 561                         [have_ssleay=no],
 562                         [-lcrypto])
 563
 564                 if test $have_ssleay = no ; then
 565                         AC_CHECK_LIB(ssl, ssl3_accept,
 566                                 [have_ssleay=yes
 567                                 need_rsaref=yes], [have_ssleay=no],
 568                                 [-lcrypto -lRSAglue -lrsaref])
 569                 fi
 570
 571                 if test $have_ssleay = yes ; then
 572                         ol_with_tls=found
 573                         ol_link_tls=yes
 574
 575                         AC_DEFINE(HAVE_SSLEAY, 1,
 576                                 [define if you have SSLeay or OpenSSL])
 577
 578                         if test $need_rsaref = yes; then
 579                                 AC_DEFINE(HAVE_RSAREF, 1,
 580                                         [define if you have RSAref])
 581
 582                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 583                         else
 584                                 TLS_LIBS="-lssl -lcrypto"
 585                         fi
 586                 fi
 587         fi
 588 fi
 589
 590 if test $ol_link_tls = yes ; then
 591         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 592 fi
 593
 594 dnl Tests for reentrant functions necessary to build a
 595 dnl thread_safe -lldap.
 596 AC_CHECK_FUNCS(         \
 597         ctime_r                 \
 598         gethostbyname_r gethostbyaddr_r \
 599 )
 600
 601 if test "$ac_cv_func_ctime_r" = no ; then
 602         ol_cv_func_ctime_r_nargs=0
 603 else
 604         OL_FUNC_CTIME_R_NARGS
 605 dnl     OL_FUNC_CTIME_R_TYPE
 606 fi
 607
 608 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 609         OL_FUNC_GETHOSTBYNAME_R_NARGS
 610 else
 611         ol_cv_func_gethostbyname_r_nargs=0
 612 fi
 613
 614 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 615         OL_FUNC_GETHOSTBYADDR_R_NARGS
 616 else
 617         ol_cv_func_gethostbyaddr_r_nargs=0
 618 fi
 619
 620 if test "$ac_cv_func_ctime_r" = yes \
 621         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 622         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 623         -a "$ac_cv_func_gethostbyname_r" = yes \
 624         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 625         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 626         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 627         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 628         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 629         ; then
 630
 631         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 632 fi
 633
 634 ol_link_threads=no
 635 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 636         -o $ol_with_threads = posix ; then
 637
 638         AC_CHECK_HEADERS(pthread.h sched.h)
 639
 640         if test $ac_cv_header_pthread_h = yes ; then
 641                 OL_POSIX_THREAD_VERSION
 642
 643                 if test $ol_cv_pthread_version = final ; then
 644                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 645                                 [define if pthreads API compatible with final spec])
 646                 elif test $ol_cv_pthread_version = draft4 ; then
 647                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 648                                 [define if pthreads API compatible with draft4 spec])
 649                 else
 650                         AC_MSG_ERROR([unknown pthread version])
 651                 fi
 652
 653                 # consider threads found
 654                 ol_with_threads=found
 655
 656                 OL_HEADER_LINUX_THREADS
 657
 658                 dnl Now the hard part, how to link?
 659                 dnl
 660                 dnl currently supported checks:
 661                 dnl
 662                 dnl Check for no flags
 663                 dnl     pthread_create() in $LIBS
 664                 dnl
 665                 dnl Check special pthread (final) flags
 666                 dnl     pthread_create() with -mt (Solaris)
 667                 dnl     pthread_create() with -kthread (FreeBSD)
 668                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 669                 dnl     pthread_create() with -pthreads (?)
 670                 dnl     pthread_create() with -thread (?)
 671                 dnl
 672                 dnl Check pthread (final) libraries
 673                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 674                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 675                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 676                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 677                 dnl     pthread_create() in -lpthread (many)
 678                 dnl     pthread_create() in -lc_r (FreeBSD)
 679                 dnl
 680                 dnl Check pthread (draft4) flags (depreciated)
 681                 dnl     pthread_create() with -threads (OSF/1)
 682                 dnl
 683                 dnl Check pthread (draft4) libraries (depreciated)
 684                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 685                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 686                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 687                 dnl     pthread_create() in -lpthreads (many)
 688                 dnl
 689
 690                 dnl pthread_create in $LIBS
 691                 AC_MSG_CHECKING([for pthread_create in default libraries])
 692                 AC_CACHE_VAL(ol_cv_pthread_create,[
 693                 AC_TRY_RUN([
 694 #include <pthread.h>
 695 #ifndef NULL
 696 #define NULL (void*)0
 697 #endif
 698
 699 static void *task(p)
 700         void *p;
 701 {
 702         return (void *) (p == NULL);
 703 }
 704
 705 int main(argc, argv)
 706         int argc;
 707         char **argv;
 708 {
 709         pthread_t t;
 710         int status;
 711
 712         /* make sure pthread_create() isn't just a stub */
 713 #if HAVE_PTHREADS_D4
 714         status = pthread_create(&t, pthread_attr_default, task, NULL);
 715 #else
 716         status = pthread_create(&t, NULL, task, NULL);
 717 #endif
 718
 719         if( status ) return status;
 720
 721         /* make sure pthread_detach() isn't just a stub */
 722 #if HAVE_PTHREADS_D4
 723         status = pthread_detach( &t );
 724 #else
 725         status = pthread_detach( t );
 726 #endif
 727
 728         if( status ) return status;
 729
 730         return status;
 731 }
 732 ],
 733                         [ol_cv_pthread_create=yes],
 734                         [ol_cv_pthread_create=no],
 735                         [dnl assume yes
 736                         ol_cv_pthread_create=yes])])
 737                 AC_MSG_RESULT($ol_cv_pthread_create)
 738
 739                 if test $ol_cv_pthread_create != no ; then
 740                         ol_link_threads=posix
 741                         ol_link_pthreads=""
 742                 fi
 743
 744                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 745                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 746                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 747                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 748                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 749
 750                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 751                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 752                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 753                         [ol_cv_pthread_lpthread_lmach_lexc])
 754 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 755 dnl                     [ol_cv_pthread_lpthread_lexc])
 756
 757                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 758                         [ol_cv_pthread_lib_lpthread_woff])
 759
 760                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 761                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 762
 763                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 764
 765                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 766                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 767                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 768                         [ol_cv_pthread_lpthreads_lmach_lexc])
 769                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 770                         [ol_cv_pthread_lpthreads_lexc])
 771
 772                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 773
 774                 if test $ol_link_threads != no ; then
 775                         AC_DEFINE(HAVE_PTHREADS,1,
 776                                 [define if you have POSIX Threads])
 777
 778                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 779
 780                         dnl save flags
 781                         save_CPPFLAGS="$CPPFLAGS"
 782                         save_LIBS="$LIBS"
 783                         LIBS="$LTHREAD_LIBS $LIBS"
 784
 785                         dnl All POSIX Thread (final) implementations should have
 786                         dnl sched_yield instead of pthread yield.
 787                         dnl check for both
 788                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 789
 790                         if test $ac_cv_func_sched_yield = no -a \
 791                                 $ac_cv_func_pthread_yield = no ; then
 792                                 dnl Digital UNIX has sched_yield() in -lrt
 793                                 AC_CHECK_LIB(rt, sched_yield,
 794                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 795                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 796                                         ac_cv_func_sched_yield=yes],
 797                                         [ac_cv_func_sched_yield=no])
 798                         fi
 799                         if test $ac_cv_func_sched_yield = no -a \
 800                                 $ac_cv_func_pthread_yield = no ; then
 801                                 dnl Solaris has sched_yield() stub in -lposix4
 802                                 dnl but we'll use thr_yield instead.
 803                                 AC_CHECK_FUNCS(thr_yield)
 804                         fi
 805                         if test $ac_cv_func_sched_yield = no -a \
 806                                 $ac_cv_func_pthread_yield = no -a \
 807                                 "$ac_cv_func_thr_yield" = no ; then
 808                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 809                         fi
 810
 811                         dnl Check functions for compatibility
 812                         AC_CHECK_FUNCS(pthread_kill)
 813
 814                         dnl Check for pthread_detach with <pthread.h> inclusion
 815                         dnl as it's symbol may have been mangled.
 816                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 817                                 [ol_cv_func_pthread_detach], [
 818                                 dnl save the flags
 819                                 AC_TRY_LINK([
 820 #include <pthread.h>
 821 #ifndef NULL
 822 #define NULL (void*)0
 823 #endif
 824 ],
 825                                         [pthread_detach(NULL);],
 826                                         [ol_cv_func_pthread_detach=yes],
 827                                         [ol_cv_func_pthread_detach=no])
 828                         ])
 829
 830                         if test $ol_cv_func_pthread_detach = no ; then
 831                                 AC_MSG_ERROR([could not locate pthread_detach()])
 832                         fi
 833
 834                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 835                                 [define if you have pthread_detach function])
 836
 837                         dnl Check for setconcurreny functions
 838                         AC_CHECK_FUNCS( \
 839                                 pthread_setconcurrency \
 840                                 pthread_getconcurrency \
 841                                 thr_setconcurrency \
 842                                 thr_getconcurrency \
 843                         )
 844
 845                         OL_SYS_LINUX_THREADS
 846                         OL_LINUX_THREADS
 847
 848                         if test $ol_cv_linux_threads = error; then
 849                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 850                         fi
 851
 852                         AC_MSG_CHECKING([if pthread_create() works])
 853                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 854                         AC_TRY_RUN([
 855 #include <pthread.h>
 856 #ifndef NULL
 857 #define NULL (void*)0
 858 #endif
 859
 860 static void *task(p)
 861         void *p;
 862 {
 863         return (void *) (p == NULL);
 864 }
 865
 866 int main(argc, argv)
 867         int argc;
 868         char **argv;
 869 {
 870         pthread_t t;
 871 #if HAVE_PTHREADS_D4
 872         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 873 #else
 874         exit(pthread_create(&t, NULL, task, NULL));
 875 #endif
 876 }
 877 ],
 878                                 [ol_cv_pthread_create_works=yes],
 879                                 [ol_cv_pthread_create_works=no],
 880                                 [dnl assume yes
 881                                 ol_cv_pthread_create_works=yes])])
 882                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 883
 884                         if test $ol_cv_pthread_create_works = no ; then
 885                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 886                         fi
 887
 888                         dnl Check if select causes an yield
 889                         if test $ol_with_yielding_select = auto ; then
 890                                 AC_MSG_CHECKING([if select yields when using pthreads])
 891                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 892                                 AC_TRY_RUN([
 893 #include <sys/types.h>
 894 #include <sys/time.h>
 895 #include <unistd.h>
 896 #include <pthread.h>
 897 #ifndef NULL
 898 #define NULL (void*) 0
 899 #endif
 900
 901 static int fildes[2];
 902
 903 static void *task(p)
 904         void *p;
 905 {
 906         int i;
 907         struct timeval tv;
 908
 909         fd_set rfds;
 910
 911         tv.tv_sec=10;
 912         tv.tv_usec=0;
 913
 914         FD_ZERO(&rfds);
 915         FD_SET(fildes[0], &rfds);
 916
 917         /* we're not interested in any fds */
 918         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 919
 920         if(i < 0) {
 921                 perror("select");
 922                 exit(10);
 923         }
 924
 925         exit(0); /* if we exit here, the select blocked the whole process */
 926 }
 927
 928 int main(argc, argv)
 929         int argc;
 930         char **argv;
 931 {
 932         pthread_t t;
 933
 934         /* create a pipe to select */
 935         if(pipe(&fildes[0])) {
 936                 perror("select");
 937                 exit(1);
 938         }
 939
 940 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 941         (void) pthread_setconcurrency(2);
 942 #else
 943 #ifdef HAVE_THR_SETCONCURRENCY
 944         /* Set Solaris LWP concurrency to 2 */
 945         thr_setconcurrency(2);
 946 #endif
 947 #endif
 948
 949 #if HAVE_PTHREADS_D4
 950         pthread_create(&t, pthread_attr_default, task, NULL);
 951 #else
 952         pthread_create(&t, NULL, task, NULL);
 953 #endif
 954
 955 #if HAVE_SCHED_YIELD
 956         sched_yield();  /* make sure task runs first */
 957 #else
 958 #ifdef HAVE_PTHREAD_YIELD
 959         pthread_yield();        /* make sure task runs first */
 960 #endif
 961 #endif
 962
 963         exit(2);
 964 }],
 965                                 [ol_cv_pthread_select_yields=no],
 966                                 [ol_cv_pthread_select_yields=yes], [
 967                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 968                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 969
 970                                 if test $ol_cv_pthread_select_yields = yes ; then
 971                                         ol_with_yielding_select=yes
 972                                 fi
 973                         fi
 974
 975                         dnl restore flags
 976                         CPPFLAGS="$save_CPPFLAGS"
 977                         LIBS="$save_LIBS"
 978                 else
 979                         AC_MSG_ERROR([could not link with POSIX Threads])
 980                 fi
 981         fi
 982
 983         if test $ol_with_threads = posix ; then
 984                 AC_MSG_ERROR([could not locate POSIX Threads])
 985         fi
 986 fi
 987
 988 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 989         -o $ol_with_threads = mach ; then
 990
 991         dnl check for Mach CThreads
 992         AC_CHECK_HEADERS(mach/cthreads.h)
 993         if test $ac_cv_header_mach_cthreads_h = yes ; then
 994                 ol_with_threads=found
 995
 996                 dnl check for cthread support in current $LIBS
 997                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 998
 999                 if test $ol_link_threads = no ; then
1000                         dnl try -all_load
1001                         dnl this test needs work
1002                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1003                                 [ol_cv_cthread_all_load], [
1004                                 dnl save the flags
1005                                 save_LIBS="$LIBS"
1006                                 LIBS="-all_load $LIBS"
1007                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1008                                         cthread_fork((void *)0, (void *)0);
1009                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1010                                 dnl restore the LIBS
1011                                 LIBS="$save_LIBS"
1012                         ])
1013
1014                         if test $ol_cv_cthread_all_load = yes ; then
1015                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1016                                 ol_link_threads=mach
1017                         fi
1018                 fi
1019
1020                 if test $ol_link_threads != no ; then
1021                         : check for cthread specific functionality here
1022                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1023                                 [define if you have Mach Cthreads])
1024                 else
1025                         AC_MSG_ERROR([could not link with Mach CThreads])
1026                 fi
1027         fi
1028
1029         if test $ol_with_threads = mach ; then
1030                 AC_MSG_ERROR([could not locate Mach CThreads])
1031         fi
1032 fi
1033
1034 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1035         -o $ol_with_threads = lwp ; then
1036
1037         dnl check for SunOS5 LWP
1038         AC_CHECK_HEADERS(thread.h synch.h)
1039         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1040                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1041
1042                 if test $have_thr = yes ; then
1043                         AC_DEFINE(HAVE_THR,1,
1044                                 [if you have Solaris LWP (thr) package])
1045                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1046                         ol_link_threads=thr
1047
1048                         if test $ol_with_yielding_select = auto ; then
1049                                 ol_with_yielding_select=yes
1050                         fi
1051
1052                         dnl Check for setconcurreny functions
1053                         AC_CHECK_FUNCS( \
1054                                 thr_setconcurrency \
1055                                 thr_getconcurrency \
1056                         )
1057                 fi
1058         fi
1059
1060         dnl check for SunOS4 LWP
1061         AC_CHECK_HEADERS(lwp/lwp.h)
1062         if test $ac_cv_header_lwp_lwp_h = yes ; then
1063                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1064
1065                 if test $have_lwp = yes ; then
1066                         AC_DEFINE(HAVE_LWP,1,
1067                                 [if you have SunOS LWP package])
1068                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1069                         ol_link_threads=lwp
1070
1071                         if test $ol_with_yielding_select = auto ; then
1072                                 ol_with_yielding_select=no
1073                         fi
1074                 fi
1075         fi
1076 fi
1077
1078 if test $ol_with_yielding_select = yes ; then
1079         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1080                 [define if select implicitly yields])
1081 fi
1082
1083 if test $ol_with_threads = manual ; then
1084         dnl User thinks he can manually configure threads.
1085         ol_link_threads=yes
1086
1087         AC_MSG_WARN([thread defines and link options must be set manually])
1088
1089         AC_CHECK_HEADERS(pthread.h sched.h)
1090         AC_CHECK_FUNCS(sched_yield pthread_yield)
1091         OL_HEADER_LINUX_THREADS
1092
1093         AC_CHECK_HEADERS(mach/cthreads.h)
1094         AC_CHECK_HEADERS(lwp/lwp.h)
1095         AC_CHECK_HEADERS(thread.h synch.h)
1096 fi
1097
1098 if test $ol_link_threads != no ; then
1099         dnl needed to get reentrant/threadsafe versions
1100         dnl
1101         AC_DEFINE(REENTRANT,1)
1102         AC_DEFINE(_REENTRANT,1)
1103         AC_DEFINE(THREAD_SAFE,1)
1104         AC_DEFINE(_THREAD_SAFE,1)
1105         AC_DEFINE(THREADSAFE,1)
1106         AC_DEFINE(_THREADSAFE,1)
1107
1108         dnl The errno declaration may dependent upon _REENTRANT.
1109         dnl If it does, we must link with thread support.
1110         AC_CACHE_CHECK([for thread specific errno],
1111                 [ol_cv_errno_thread_specific], [
1112                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1113                         [ol_cv_errno_thread_specific=yes],
1114                         [ol_cv_errno_thread_specific=no])
1115         ])
1116
1117         if test $ol_cv_errno_thread_specific != yes ; then
1118                 LIBS="$LTHREAD_LIBS $LIBS"
1119                 LTHREAD_LIBS=""
1120         fi
1121
1122 dnl When in thread environment, use
1123 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1124 dnl                     || defined( HAVE_FUNC_R )
1125 dnl                     func_r(...);
1126 dnl             #else
1127 dnl             #       if defined( HAVE_THREADS )
1128 dnl                             /* lock */
1129 dnl             #       endif
1130 dnl                             func(...);
1131 dnl             #       if defined( HAVE_THREADS )
1132 dnl                             /* unlock */
1133 dnl             #       endif
1134 dnl             #endif
1135 dnl
1136 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1137 dnl             _POSIX_REENTRANT_FUNCTIONS
1138 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1139 dnl             _POSIX_THREADSAFE_FUNCTIONS
1140 dnl
1141 dnl             and is currently defined in lthread.h
1142 dnl
1143 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1144 dnl
1145 dnl libldap/*.c should only include <lthread.h> iff
1146 dnl LDAP_R_COMPILE is defined.  ie:
1147 dnl             #ifdef LDAP_R_COMPILE
1148 dnl             #       include LDAP_R_COMPILE
1149 dnl             #endif
1150 dnl
1151 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1152 dnl specifically for compiling the threadsafe version of
1153 dnl     the ldap library (-lldap_r).
1154 dnl
1155 dnl     dnl check for reentrant/threadsafe functions
1156 dnl     dnl
1157 dnl     dnl note: these should only be used when linking
1158 dnl     dnl       with $LTHREAD_LIBS
1159 dnl     dnl
1160 dnl     save_CPPFLAGS="$CPPFLAGS"
1161 dnl     save_LIBS="$LIBS"
1162 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1163 dnl     AC_CHECK_FUNCS( \
1164 dnl             gmtime_r \
1165 dnl             gethostbyaddr_r gethostbyname_r \
1166 dnl             feof_unlocked unlocked_feof \
1167 dnl             putc_unlocked unlocked_putc \
1168 dnl             flockfile ftrylockfile \
1169 dnl     )
1170 dnl     CPPFLAGS="$save_CPPFLAGS"
1171 dnl     LIBS="$save_LIBS"
1172 fi
1173
1174 if test $ol_link_threads = no ; then
1175         if test $ol_with_threads = yes ; then
1176                 AC_MSG_ERROR([no suitable thread support])
1177         fi
1178
1179         if test $ol_with_threads = auto ; then
1180                 AC_MSG_WARN([no suitable thread support, disabling threads])
1181                 ol_with_threads=no
1182         fi
1183
1184         AC_DEFINE(NO_THREADS,1,
1185                 [define if you have (or want) no threads])
1186         LTHREAD_LIBS=""
1187 fi
1188
1189 if test $ol_link_threads != no ; then
1190         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1191 fi
1192
1193 dnl ----------------------------------------------------------------
1194
1195 ol_link_ldbm=no
1196 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1197         OL_BERKELEY_DB2
1198
1199         if test $ol_cv_berkeley_db2 = yes ; then
1200                 ol_link_ldbm=db2
1201                 ol_with_ldbm_api=db2
1202
1203                 if test $ol_with_ldbm_type = hash ; then
1204                         AC_DEFINE(LDBM_USE_DBHASH,1)
1205                 else
1206                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1207                 fi
1208
1209                 dnl $ol_cv_lib_db2 should be yes or -ldb
1210                 dnl (it could be no, but that would be an error
1211                 if test $ol_cv_lib_db2 != yes ; then
1212                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1213                 fi
1214         fi
1215 fi
1216
1217 ol_link_bdb2=no
1218 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1219         ol_link_bdb2=yes
1220 fi
1221
1222 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1223         OL_BERKELEY_DB
1224
1225         if test $ol_cv_berkeley_db = yes ; then
1226                 ol_link_ldbm=db
1227                 ol_with_ldbm_api=db
1228
1229                 if test $ol_with_ldbm_type = hash ; then
1230                         AC_DEFINE(LDBM_USE_DBHASH,1)
1231                 else
1232                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1233                 fi
1234
1235                 dnl $ol_cv_lib_db should be yes or -ldb
1236                 dnl (it could be no, but that would be an error
1237                 if test $ol_cv_lib_db != yes ; then
1238                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1239                 fi
1240         fi
1241 fi
1242
1243 if test $ol_with_ldbm_api = manual ; then
1244         dnl User thinks he can manually configure LDBM api.
1245         ol_link_ldbm=yes
1246
1247         AC_MSG_WARN([LDBM defines and link options must be set manually])
1248
1249         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1250 fi
1251
1252 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1253         AC_MSG_WARN(Could not find LDBM with BTREE support)
1254         ol_with_ldbm_api=none
1255 fi
1256
1257 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1258         OL_MDBM
1259
1260         if test $ol_cv_mdbm = yes ; then
1261                 ol_link_ldbm=mdbm
1262                 ol_with_ldbm_api=mdbm
1263                 if test $ol_cv_lib_mdbm != yes ; then
1264                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1265                 fi
1266         fi
1267 fi
1268
1269 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1270         OL_GDBM
1271
1272         if test $ol_cv_gdbm = yes ; then
1273                 ol_link_ldbm=gdbm
1274                 ol_with_ldbm_api=gdbm
1275
1276                 if test $ol_cv_lib_gdbm != yes ; then
1277                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1278                 fi
1279         fi
1280 fi
1281
1282 if test $ol_with_ldbm_api = auto ; then
1283         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1284 elif test $ol_with_ldbm_api = ndbm ; then
1285         OL_NDBM
1286
1287         if test $ol_cv_ndbm = yes ; then
1288                 ol_link_ldbm=ndbm
1289                 ol_with_ldbm_api=ndbm
1290
1291                 if test $ol_cv_lib_ndbm != yes ; then
1292                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1293                 fi
1294         fi
1295 fi
1296
1297 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1298         AC_MSG_WARN(could not find suitable LDBM backend)
1299         if test $ol_enable_ldbm = yes ; then
1300                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1301         fi
1302
1303         AC_MSG_WARN(disabling LDBM)
1304         ol_enable_ldbm=no
1305 fi
1306
1307 if test $ol_enable_wrappers != no ; then
1308         AC_CHECK_HEADERS(tcpd.h)
1309
1310         if test $ac_cv_header_tcpd_h != yes ; then
1311                 have_wrappers=no
1312         else
1313                 AC_CHECK_LIB(wrap, main,
1314                         [have_wrappers=yes], [have_wrappers=no])
1315         fi
1316
1317         if test $have_wrappers = yes ; then
1318                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1319                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1320
1321                 dnl We add another check for -lnsl since some libwrap's
1322                 dnl need it, but it isn't always included from above
1323                 AC_CHECK_LIB(nsl, main)
1324         else
1325                 AC_MSG_WARN(could not find -lwrap)
1326                 if test $ol_enable_wrappers = yes ; then
1327                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1328                 fi
1329
1330                 AC_MSG_WARN(disabling wrappers support)
1331                 ol_enable_wrappers=no
1332         fi
1333 fi
1334
1335 if test $ol_enable_syslog != no ; then
1336         AC_CHECK_FUNC(openlog)
1337         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1338                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1339         fi
1340         ol_enable_syslog=$ac_cv_func_openlog
1341 fi
1342
1343 if test $ol_enable_dmalloc != no ; then
1344         AC_CHECK_HEADERS(dmalloc.h)
1345         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1346 fi
1347
1348 if test $ol_enable_tcl != no ; then
1349         AC_CHECK_HEADERS(tcl.h)
1350
1351         if test $ac_cv_header_tcl_h != yes ; then
1352                 have_tcl=no
1353         else
1354                 AC_CHECK_LIB(tcl,main,
1355                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1356                         [have_tcl=no])
1357
1358                 if test $have_tcl != yes; then
1359                         AC_CHECK_LIB(tcl7.6,main,
1360                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1361                                 [have_tcl=no])
1362                 fi
1363
1364                 if test $have_tcl != yes; then
1365                         AC_CHECK_LIB(tcl8.0,main,
1366                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1367                                 [have_tcl=no])
1368                 fi
1369         fi
1370
1371         if test $have_tcl != yes ; then
1372                 AC_MSG_WARN([could not find -ltcl])
1373                 if test $ol_enable_tcl = yes ; then
1374                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1375                 fi
1376
1377                 ol_enable_tcl=no
1378         fi
1379 fi
1380
1381 # ud needs termcap (should insert check here)
1382 ol_link_termcap=no
1383 AC_CHECK_HEADERS(termcap.h ncurses.h)
1384
1385 if test $ol_link_termcap = no ; then
1386         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1387         if test $have_termcap = yes ; then
1388                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1389                 ol_link_termcap=yes
1390                 TERMCAP_LIBS=-ltermcap
1391         fi
1392 fi
1393
1394 if test $ol_link_termcap = no ; then
1395         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1396         if test $have_ncurses = yes ; then
1397                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1398                 ol_link_termcap=yes
1399                 TERMCAP_LIBS=-lncurses
1400         fi
1401 fi
1402
1403 if test $ol_link_termcap = no ; then
1404         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1405         TERMCAP_LIBS=
1406 fi
1407
1408 dnl
1409 dnl Check for GNU readline
1410 dnl
1411 ol_link_readline=no
1412 if test $ol_with_readline != no ; then
1413         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1414
1415         if test $ac_cv_header_readline_readline_h = yes ; then
1416                 save_LIBS="$LIBS"
1417                 LIBS="$TERMCAP_LIBS $LIBS"
1418                 AC_CHECK_LIB(readline, readline,
1419                         [have_readline=yes], [have_readline=no])
1420                 LIBS="$save_LIBS"
1421
1422                 if test $have_readline = yes ; then
1423                         ol_with_readline=found
1424                         ol_link_readline=yes
1425
1426                         READLINE_LIBS="-lreadline"
1427                 fi
1428         fi
1429 fi
1430
1431 if test $ol_link_readline = yes ; then
1432         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1433 fi
1434
1435
1436 # FreeBSD (and others) have crypt(3) in -lcrypt
1437 if test $ol_enable_crypt != no ; then
1438         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1439                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1440                         have_crypt=yes], [have_crypt=no])])
1441
1442         if test $have_crypt = yes ; then
1443                 AC_DEFINE(HAVE_CRYPT,1)
1444         else
1445                 AC_MSG_WARN(could not find crypt)
1446                 if test $ol_enable_crypt = yes ; then
1447                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1448                 fi
1449
1450                 AC_MSG_WARN(disabling crypt support)
1451                 ol_enable_crypt=no
1452         fi
1453 fi
1454
1455 # FreeBSD (and others) have setproctitle(3) in -lutil
1456 if test $ol_enable_proctitle != no ; then
1457         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1458                 AC_CHECK_LIB(util, setproctitle,
1459                         [have_setproctitle=yes
1460                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1461                         [have_setproctitle=no
1462                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1463
1464         if test $have_setproctitle = yes ; then
1465                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1466         fi
1467 fi
1468
1469 dnl ----------------------------------------------------------------
1470 dnl Checks for header files.
1471 OL_HEADER_STDC
1472
1473 if test $ol_cv_header_stdc != yes; then
1474         AC_MSG_WARN([could not locate Standard C compliant headers])
1475 fi
1476
1477 AC_HEADER_DIRENT
1478 AC_HEADER_SYS_WAIT
1479 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1480 if test $am_cv_sys_posix_termios = yes ; then
1481         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1482                 [define if you have POSIX termios])
1483 fi
1484
1485 AC_CHECK_HEADERS(       \
1486         arpa/inet.h             \
1487         arpa/nameser.h  \
1488         assert.h                \
1489         crypt.h                 \
1490         errno.h                 \
1491         fcntl.h                 \
1492         filio.h                 \
1493         getopt.h                \
1494         grp.h                   \
1495         libutil.h               \
1496         limits.h                \
1497         locale.h                \
1498         malloc.h                \
1499         memory.h                \
1500         regex.h                 \
1501         psap.h                  \
1502         pwd.h                   \
1503         resolv.h                \
1504         sgtty.h                 \
1505         stdarg.h                \
1506         stddef.h                \
1507         string.h                \
1508         strings.h               \
1509         sysexits.h              \
1510         sys/file.h              \
1511         sys/filio.h             \
1512         sys/errno.h             \
1513         sys/ioctl.h             \
1514         sys/param.h             \
1515         sys/resource.h  \
1516         sys/select.h    \
1517         sys/socket.h    \
1518         sys/syslog.h    \
1519         sys/time.h              \
1520         sys/types.h             \
1521         syslog.h                \
1522         termios.h               \
1523         unistd.h                \
1524 )
1525
1526 dnl ----------------------------------------------------------------
1527 dnl Checks for typedefs, structures, and compiler characteristics.
1528 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1529 AC_TYPE_MODE_T
1530 AC_TYPE_OFF_T
1531 AC_TYPE_PID_T
1532 AM_TYPE_PTRDIFF_T
1533 AC_TYPE_SIGNAL
1534 OL_TYPE_SIG_ATOMIC_T
1535 AC_TYPE_SIZE_T
1536 AC_STRUCT_ST_BLKSIZE
1537 AC_HEADER_TIME
1538 AC_STRUCT_TM
1539 OL_STRUCT_PASSWD_PW_GECOS
1540
1541 OL_C_UPPER_LOWER
1542 AC_C_CONST
1543 OL_C_VOLATILE
1544
1545 if test $cross_compiling = yes ; then
1546         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1547 else
1548         AC_C_BIGENDIAN
1549         AC_CHECK_SIZEOF(short)
1550         AC_CHECK_SIZEOF(int)
1551         AC_CHECK_SIZEOF(long)
1552 fi
1553
1554 dnl ----------------------------------------------------------------
1555 dnl Checks for library functions.
1556 AC_FUNC_MEMCMP
1557 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1558 AC_FUNC_STRFTIME
1559 dnl AM_FUNC_STRTOD
1560
1561 dnl we should use vfork instead of fork in a number of places...
1562 dnl AC_FUNC_VFORK
1563 AC_FUNC_VPRINTF
1564
1565 if test $ac_cv_func_vprintf = yes ; then
1566         dnl check for vsnprintf
1567         AC_CHECK_FUNCS(vsnprintf vsprintf)
1568 fi
1569
1570 AC_CHECK_FUNCS(         \
1571         bcopy                   \
1572         endgrent                \
1573         endpwent                \
1574         flock                   \
1575         getdtablesize   \
1576         getgrgid                \
1577         gethostname             \
1578         getpass                 \
1579         getpwuid                \
1580         gettimeofday    \
1581         initgroups              \
1582         lockf                   \
1583         memcpy                  \
1584         memmove                 \
1585         mkstemp                 \
1586         recv                    \
1587         recvfrom                \
1588         setpwfile               \
1589         setgid                  \
1590         setegid                 \
1591         setsid                  \
1592         setuid                  \
1593         seteuid                 \
1594         signal                  \
1595         sigset                  \
1596         snprintf                \
1597         strdup                  \
1598         strerror                \
1599         strpbrk                 \
1600         strrchr                 \
1601         strsep                  \
1602         strstr                  \
1603         strtol                  \
1604         strtoul                 \
1605         strspn                  \
1606         sysconf                 \
1607         waitpid                 \
1608         wait4                   \
1609 )
1610
1611 dnl We actually may need to replace more than this.
1612 AC_REPLACE_FUNCS(getopt tempnam)
1613
1614 dnl ----------------------------------------------------------------
1615 # Check Configuration
1616 OL_SYS_ERRLIST
1617
1618 dnl ----------------------------------------------------------------
1619 dnl Sort out defines
1620
1621 if test "$ol_enable_debug" != no ; then
1622         AC_DEFINE(LDAP_DEBUG,1)
1623 fi
1624 if test "$ol_enable_syslog" = yes ; then
1625         AC_DEFINE(LDAP_SYSLOG,1)
1626 fi
1627 if test "$ol_enable_libui" = yes ; then
1628         AC_DEFINE(LDAP_LIBUI,1)
1629 fi
1630 if test "$ol_enable_cache" = no ; then
1631         AC_DEFINE(LDAP_NOCACHE,1)
1632 fi
1633 if test "$ol_enable_dns" != no ; then
1634         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1635 fi
1636 if test "$ol_enable_proctitle" != no ; then
1637         AC_DEFINE(LDAP_PROCTITLE,1)
1638 fi
1639 if test "$ol_enable_referrals" != no ; then
1640         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1641 fi
1642 if test "$ol_enable_cldap" != no ; then
1643         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1644 fi
1645
1646 if test "$ol_enable_aclgroups" != no ; then
1647         AC_DEFINE(SLAPD_ACLGROUPS,1)
1648 fi
1649 if test "$ol_enable_crypt" != no ; then
1650         AC_DEFINE(SLAPD_CRYPT,1)
1651 fi
1652 if test "$ol_enable_cleartext" != no ; then
1653         AC_DEFINE(SLAPD_CLEARTEXT,1)
1654 fi
1655 if test "$ol_enable_phonetic" != no ; then
1656         AC_DEFINE(SLAPD_PHONETIC,1)
1657 fi
1658 if test "$ol_enable_rlookups" != no ; then
1659         AC_DEFINE(SLAPD_RLOOKUPS,1)
1660 fi
1661
1662 if test "$ol_link_modules" != no ; then
1663         AC_DEFINE(SLAPD_MODULES,1)
1664         BUILD_SLAPD=yes
1665 fi
1666
1667 if test "$ol_link_bdb2" != no ; then
1668         AC_DEFINE(SLAPD_BDB2,1)
1669         BUILD_SLAPD=yes
1670         BUILD_BDB2=yes
1671 fi
1672
1673 if test "$ol_enable_ldap" != no ; then
1674         AC_DEFINE(SLAPD_LDAP,1)
1675         BUILD_SLAPD=yes
1676         BUILD_LDAP=yes
1677 fi
1678
1679 if test "$ol_link_ldbm" != no ; then
1680         AC_DEFINE(SLAPD_LDBM,1)
1681         BUILD_SLAPD=yes
1682         BUILD_LDBM=yes
1683 fi
1684
1685 if test "$ol_enable_passwd" != no ; then
1686         AC_DEFINE(SLAPD_PASSWD,1)
1687         BUILD_SLAPD=yes
1688         BUILD_PASSWD=yes
1689 fi
1690
1691 if test "$ol_link_perl" != no ; then
1692         AC_DEFINE(SLAPD_PERL,1)
1693         BUILD_SLAPD=yes
1694         BUILD_PERL=yes
1695 fi
1696
1697 if test "$ol_enable_shell" != no ; then
1698         AC_DEFINE(SLAPD_SHELL,1)
1699         BUILD_SLAPD=yes
1700         BUILD_SHELL=yes
1701 fi
1702
1703 if test "$ol_enable_tcl" != no ; then
1704         AC_DEFINE(SLAPD_TCL,1)
1705         BUILD_SLAPD=yes
1706         BUILD_TCL=yes
1707 fi
1708
1709 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1710         $BUILD_SLAPD = yes ; then
1711         BUILD_SLURPD=yes
1712 fi
1713
1714 if test "$ol_link_isode" != no ; then
1715         BUILD_LDAPD=yes
1716 fi
1717
1718 dnl ----------------------------------------------------------------
1719
1720 AC_SUBST(BUILD_LDAPD)
1721 AC_SUBST(BUILD_SLAPD)
1722   AC_SUBST(BUILD_BDB2)
1723   AC_SUBST(BUILD_LDAP)
1724   AC_SUBST(BUILD_LDBM)
1725   AC_SUBST(BUILD_PASSWD)
1726   AC_SUBST(BUILD_PERL)
1727   AC_SUBST(BUILD_SHELL)
1728   AC_SUBST(BUILD_TCL)
1729 AC_SUBST(BUILD_SLURPD)
1730
1731 AC_SUBST(LDAP_LIBS)
1732 AC_SUBST(LDAPD_LIBS)
1733 AC_SUBST(SLAPD_LIBS)
1734 AC_SUBST(SLURPD_LIBS)
1735 AC_SUBST(LDBM_LIBS)
1736 AC_SUBST(LTHREAD_LIBS)
1737 AC_SUBST(LUTIL_LIBS)
1738
1739 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1740 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1741
1742 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1743 AC_SUBST(SLAPD_PERL_LDFLAGS)
1744
1745 AC_SUBST(KRB_LIBS)
1746 AC_SUBST(READLINE_LIBS)
1747 AC_SUBST(TERMCAP_LIBS)
1748 AC_SUBST(TLS_LIBS)
1749
1750 dnl ----------------------------------------------------------------
1751 dnl final output
1752 dnl
1753
1754 AC_OUTPUT( \
1755 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1756 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1757 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1758 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1759 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1760 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1761 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1762 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1763 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1764 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1765 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1766 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1767 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1768 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1769 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1770 include/Makefile:build/top.mk:include/Makefile.in \
1771 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1772 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1773 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1774 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1775 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1776 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1777 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1778 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1779 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1780 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1781 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1782 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1783 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/srv.mk \
1784 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1785 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1786 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1787 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1788 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1789 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1790 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1791 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1792 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1793 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1794 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1795 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1796 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1797 ,[
1798 date > stamp-h
1799 echo Please \"make depend\" to build dependencies
1800 ])