git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(include/ldap.h)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17 AM_INIT_AUTOMAKE(OpenLDAP,[2.0-devel])dnl
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20
  21 dnl We use autoconf features new to 2.13.
  22 dnl     aclocal.m4 should be built using aclocal from automake 1.4
  23 AC_PREREQ(2.13)dnl Required Autoconf version
  24
  25 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h)dnl
  26
  27 dnl
  28 dnl Start Args
  29 AC_MSG_CHECKING(configure arguments)
  30 AC_PREFIX_DEFAULT(/usr/local)
  31
  32 top_builddir=`pwd`
  33 AC_SUBST(top_builddir)dnl
  34
  35 ldap_subdir="openldap"
  36
  37 AC_ARG_WITH(subdir, [  --with-subdir=DIR change default subdirectory used for installs], [
  38         if test "$withval" = "no"; then
  39                 ldap_subdir=""
  40         elif test "$withval" != "yes"; then
  41                 ldap_subdir="$withval"
  42         fi
  43 ])dnl
  44
  45 AC_SUBST(ldap_subdir)dnl
  46
  47 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  48 dnl ol_enable_syslog=no
  49 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  50 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  51 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  52 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  53 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  54 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  55 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  56         no, [yes no])dnl
  57
  58 dnl General "with" options
  59 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  60
  61 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  62         auto, [auto k5 k4 afs yes no])
  63 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  64         auto, [auto yes no] )
  65 OL_ARG_WITH(threads,[  --with-threads   use threads],
  66         auto, [auto posix mach lwp yes no manual] )
  67 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  68         auto, [auto ssleay openssl yes no] )
  69 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  70         auto, [auto yes no manual] )
  71
  72 dnl Server options
  73
  74 dnl LDAPD OPTIONS
  75 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
  76 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  77
  78 dnl SLAPD OPTIONS
  79 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
  80 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  81 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  82 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
  83 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  84 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
  85 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  86 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  87 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  88
  89 dnl SLAPD Backend options
  90 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
  91 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  92 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  93         [auto db2 db mdbm gdbm ndbm manual])
  94 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  95         [auto btree hash])
  96
  97 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  98 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
  99 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 100 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 101
 102 dnl SLURPD OPTIONS
 103 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 104 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 105
 106 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 107 AM_ENABLE_STATIC
 108 dnl AM_DISABLE_SHARED
 109 AM_ENABLE_SHARED
 110
 111 dnl General "enable" options
 112 # validate options
 113 if test $ol_enable_dns = yes ; then
 114         if test $ol_enable_referrals = no ; then
 115                 AC_MSG_ERROR([DNS requires --enable-referrals])
 116         fi
 117         if test $ol_enable_referrals = auto ; then
 118                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 119                 ol_enable_referrals=yes
 120         fi
 121 fi
 122
 123 if test $ol_enable_slapd = no ; then
 124         dnl SLAPD was specificallly disabled
 125         if test $ol_enable_bdb2 = yes ; then
 126                 AC_MSG_WARN([slapd disabled, ignoring --enable_bdb2 argument])
 127         fi
 128         if test $ol_enable_ldbm = yes ; then
 129                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
 130         fi
 131         if test $ol_enable_passwd = yes ; then
 132                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
 133         fi
 134         if test $ol_enable_perl = yes ; then
 135                 AC_MSG_WARN([slapd disabled, ignoring --enable_perl argument])
 136         fi
 137         if test $ol_enable_shell = yes ; then
 138                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
 139         fi
 140         if test $ol_enable_tcl = yes ; then
 141                 AC_MSG_WARN([slapd disabled, ignoring --enable_tcl argument])
 142         fi
 143         if test $ol_enable_aclgroups = yes ; then
 144                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
 145         fi
 146         if test $ol_enable_modules = yes ; then
 147                 AC_MSG_WARN([slapd disabled, ignoring --enable_modules argument])
 148         fi
 149         if test $ol_enable_wrappers = yes ; then
 150                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
 151         fi
 152         if test $ol_enable_phonetic = yes ; then
 153                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 154         fi
 155         if test $ol_enable_rlookups = yes ; then
 156                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 157         fi
 158         if test $ol_with_ldbm_api != auto ; then
 159                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 160         fi
 161         if test $ol_with_ldbm_type != auto ; then
 162                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 163         fi
 164         if test $ol_enable_slurpd = yes ; then
 165                 AC_MSG_ERROR([slurpd requires slapd])
 166         fi
 167
 168         # force settings to no
 169         ol_enable_bdb2=no
 170         ol_enable_ldbm=no
 171         ol_enable_passwd=no
 172         ol_enable_perl=no
 173         ol_enable_shell=no
 174         ol_enable_tcl=no
 175
 176         ol_enable_aclgroups=no
 177         ol_enable_modules=no
 178         ol_enable_phonetic=no
 179         ol_enable_rlookups=no
 180         ol_enable_wrappers=no
 181
 182         ol_with_ldbm_api=no
 183         ol_with_ldbm_type=no
 184
 185         ol_enable_slurpd=no
 186
 187 elif test $ol_enable_ldbm = no ; then
 188         dnl SLAPD without LDBM
 189
 190         if test $ol_with_ldbm_api != auto ; then
 191                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 192         fi
 193
 194         if test $ol_with_ldbm_type != auto ; then
 195                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 196         fi
 197
 198         if test $ol_enable_bdb2 = yes ; then
 199                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 200         fi
 201
 202         if test $ol_enable_modules != yes -a \
 203                 $ol_enable_passwd = no -a \
 204                 $ol_enable_perl = no -a \
 205                 $ol_enable_shell = no -a \
 206                 $ol_enable_tcl = no ; then
 207                 AC_MSG_ERROR([slapd requires a backend])
 208         fi
 209
 210         ol_with_ldbm_api=no
 211         ol_with_ldbm_type=no
 212
 213 elif test $ol_enable_bdb2 = yes ; then
 214         dnl SLAPD with BDB2
 215
 216         if test $ol_with_ldbm_api != auto -a \
 217                 $ol_with_ldbm_api != db2 ; then
 218                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 219         fi
 220
 221         ol_with_ldbm_api=db2
 222
 223 else
 224         dnl SLAPD with LDBM
 225
 226         if test $ol_enable_bdb2 != no ; then
 227                 if test $ol_with_ldbm_api != auto -a \
 228                         $ol_with_ldbm_api != db2 ; then
 229                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 230                         ol_enable_bdb2=no
 231                 fi
 232         fi
 233
 234         if test $ol_with_ldbm_api = gdbm -a \
 235                 $ol_with_ldbm_type = btree ; then
 236                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 237         fi
 238         if test $ol_with_ldbm_api = mdbm -a \
 239                 $ol_with_ldbm_type = btree ; then
 240                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 241         fi
 242         if test $ol_with_ldbm_api = ndbm -a \
 243                 $ol_with_ldbm_type = btree ; then
 244                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 245         fi
 246 fi
 247
 248 if test $ol_enable_slurpd = yes ; then
 249         dnl SLURPD was specifically enabled
 250         if test $ol_with_threads = no ; then
 251                 AC_MSG_ERROR([slurpd requires threads])
 252         fi
 253 fi
 254
 255 AC_MSG_RESULT(done)
 256
 257 ## Initialize vars
 258 LDAP_LIBS=
 259 LDBM_LIBS=
 260 LTHREAD_LIBS=
 261 LUTIL_LIBS=
 262
 263 LDAPD_LIBS=
 264 SLAPD_LIBS=
 265 SLURPD_LIBS=
 266
 267 BUILD_LDAPD=no
 268 BUILD_SLAPD=no
 269 BUILD_SLURPD=no
 270
 271 BUILD_BDB2=no
 272 BUILD_LDBM=no
 273 BUILD_PASSWD=no
 274 BUILD_PERL=no
 275 BUILD_SHELL=no
 276 BUILD_TCL=no
 277 BUILD_THREAD=no
 278
 279 SLAPD_MODULES_LDFLAGS=
 280 SLAPD_MODULES_CPPFLAGS=
 281
 282 SLAPD_PERL_LDFLAGS=
 283 SLAPD_PERL_CPPFLAGS=
 284
 285 KRB_LIBS=
 286 READLINE_LIBS=
 287 TERMCAP_LIBS=
 288 TLS_LIBS=
 289
 290 dnl ----------------------------------------------------------------
 291 dnl Checks for programs
 292
 293 AC_PROG_INSTALL
 294
 295 dnl The default compiler is cc (NOT gcc)
 296 CC=${CC-"cc"}
 297 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 298 dnl CFLAGS=${CFLAGS-""}
 299
 300 AM_PROG_LIBTOOL
 301 dnl AC_PROG_MAKE_SET
 302
 303 AC_PROG_AWK
 304 OL_PROG_LN_H
 305 AC_PROG_LN_S
 306
 307 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 308         LN_S="$LN_H"
 309 fi
 310
 311 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 312         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 313 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 314 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 315
 316 ol_link_modules=no
 317 if test $ol_enable_modules != no ; then
 318         AC_PATH_PROG(GLIBCONFIG, glib-config)
 319
 320         if test "no$GLIBCONFIG" = "no" ; then
 321                 if test $ol_enable_modules = yes ; then
 322                         AC_MSG_ERROR([could not locate glib-config])
 323                 fi
 324
 325         else
 326                 SLAPD_MODULES_VERSION="`$GLIBCONFIG --version gmodule`"
 327                 SLAPD_MODULES_CPPFLAGS="`$GLIBCONFIG --cflags gmodule`"
 328                 SLAPD_MODULES_LDFLAGS="`$GLIBCONFIG --libs gmodule`"
 329
 330                 dnl should check glib version
 331                 ol_link_modules=yes
 332         fi
 333 fi
 334
 335 ol_link_perl=no
 336 if test $ol_enable_perl != no ; then
 337         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 338
 339         if test "no$PERLBIN" = "no" ; then
 340                 if test $ol_enable_perl = yes ; then
 341                         AC_MSG_ERROR([could not locate perl])
 342                 fi
 343
 344         else
 345                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 346                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 347
 348                 dnl should check perl version
 349                 ol_link_perl=yes
 350         fi
 351 fi
 352
 353 AC_PROG_CPP
 354
 355 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 356         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 357
 358 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 359         AC_MSG_WARN([programs compiled here do run here...])
 360         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 361
 362 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 363         AC_MSG_WARN([programs compiled here do not run here...])
 364         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 365 fi
 366
 367 dnl Checks for UNIX Variants
 368 AC_AIX
 369 AC_ISC_POSIX
 370 AC_MINIX
 371
 372 dnl BeOS requires -lbe -lroot
 373 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot"], :, [-lroot])
 374
 375 dnl Checks for system services
 376 AC_CYGWIN
 377 AC_MINGW32
 378 AC_EXEEXT
 379 AC_OBJEXT
 380
 381 dnl OpenLDAP requires STDC features
 382 AM_PROG_CC_STDC
 383 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 384         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC prototypes.])
 385 fi
 386
 387 dnl AM_C_PROTOTYPES
 388
 389 dnl Checks for libraries
 390
 391 dnl Find socket()
 392 dnl Likely combinations:
 393 dnl             -lsocket [ -lnsl_s | -lnsl ]
 394 dnl             -linet
 395
 396 AC_CHECK_FUNC(socket, :, [
 397 dnl
 398 dnl hopefully we won't include too many libraries
 399 dnl
 400         AC_CHECK_LIB(socket, main)
 401         AC_CHECK_LIB(net, main)
 402         AC_CHECK_LIB(nsl_s, main)
 403         AC_CHECK_LIB(nsl, main)
 404         AC_CHECK_LIB(inet, socket)
 405         AC_CHECK_LIB(gen, main)
 406 ])
 407
 408 dnl Check for resolver routines
 409 AC_CHECK_FUNCS(res_search)
 410 if test $ac_cv_func_res_search = "no" ; then
 411         AC_CHECK_LIB(bind, res_search)
 412         if test "$ac_cv_lib_bind_res_search" = "yes" ; then
 413                 AC_DEFINE(HAVE_RES_SEARCH,1)
 414         else
 415                 AC_CHECK_LIB(resolv, res_search)
 416                 if test "$ac_cv_lib_resolv_res_search" = "yes" ; then
 417                         AC_DEFINE(HAVE_RES_SEARCH,1)
 418                 fi
 419         fi
 420 fi
 421
 422 dnl HP-UX requires -lV3
 423 AC_CHECK_LIB(V3, sigset)
 424
 425 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 426
 427 dnl Select arg types
 428 dnl (if this detection becomes permenent, it and the select() detection
 429 dnl should be done before the yielding select test)
 430 AC_FUNC_SELECT_ARGTYPES
 431
 432 # ISODE tests
 433 ol_link_isode=no
 434 if test $ol_enable_ldapd != no ; then
 435         dnl look for ISODE libraries
 436         AC_CHECK_LIB(xtpp, main, [
 437                 ol_link_isode=yes
 438                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 439                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 440                 ],:,[-lxtdsap -lxtisode -losi])
 441         AC_CHECK_LIB(dsap, main, [
 442                 ol_link_isode=yes
 443                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 444                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 445                 ],:,[-lisode])
 446         AC_CHECK_LIB(isode, main, [
 447                 ol_link_isode=yes
 448                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 449                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 450                 ],:)
 451 fi
 452
 453 if test $ol_link_isode != no; then
 454         AC_CHECK_LIB(pp, main, [
 455                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 456                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 457                 ],:)
 458
 459         AC_PATH_PROG(PEPSY, pepsy)
 460 fi
 461
 462 dnl
 463 dnl check for kerberos
 464 dnl
 465 ol_link_kerberos=no
 466
 467 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 468         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 469
 470         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 471                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 472                         [-lkrb5 -ldes425])
 473
 474                 if test $have_k5 = yes ; then
 475                         ol_with_kerberos=found
 476                         ol_link_kerberos=yes
 477
 478                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 479
 480                         LIBS="$KRB_LIBS $LIBS"
 481
 482                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 483                                 [ol_cv_var_des_debug], [
 484                                 dnl save the flags
 485                                 save_LIBS="$LIBS"
 486                                 LIBS="$KRB_LIBS $LIBS"
 487                                 AC_TRY_LINK([
 488 #include <kerberosIV/krb.h>
 489 #include <kerberosIV/des.h>
 490 extern int des_debug;
 491 ],[
 492 des_debug = 1;
 493 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 494                                 dnl restore the LIBS
 495                                 LIBS="$save_LIBS"
 496                         ])
 497
 498                         if test $ol_cv_var_des_debug = yes ; then
 499                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 500                                         [define if you have Kerberos des_debug])
 501                         fi
 502
 503                         LIBS="$save_LIBS"
 504                 fi
 505         fi
 506 fi
 507
 508 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 509         AC_CHECK_HEADERS(krb.h des.h)
 510
 511         if test $ac_cv_header_krb_h = yes ; then
 512                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 513
 514                 if test $have_k4 = yes ; then
 515                         ol_with_kerberos=found
 516                         ol_link_kerberos=yes
 517
 518                         KRB_LIBS="-lkrb -ldes"
 519                 fi
 520         fi
 521 fi
 522
 523 if test $ol_link_kerberos = yes ; then
 524         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 525 fi
 526
 527 dnl
 528 dnl Check for SSL/TLS
 529 dnl
 530 ol_link_tls=no
 531 if test $ol_with_tls != no ; then
 532
 533         AC_CHECK_HEADERS(ssl.h)
 534
 535         if test $ac_cv_header_ssl_h = yes ; then
 536                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 537                         [have_ssleay=yes
 538                         need_rsaref=no],
 539                         [have_ssleay=no],
 540                         [-lcrypto])
 541
 542                 if test $have_ssleay = no ; then
 543                         AC_CHECK_LIB(ssl, ssl3_accept,
 544                                 [have_ssleay=yes
 545                                 need_rsaref=yes], [have_ssleay=no],
 546                                 [-lcrypto -lRSAglue -lrsaref])
 547                 fi
 548
 549                 if test $have_ssleay = yes ; then
 550                         ol_with_tls=found
 551                         ol_link_tls=yes
 552
 553                         AC_DEFINE(HAVE_SSLEAY, 1,
 554                                 [define if you have SSLeay or OpenSSL])
 555
 556                         if test $need_rsaref = yes; then
 557                                 AC_DEFINE(HAVE_RSAREF, 1,
 558                                         [define if you have RSAref])
 559
 560                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 561                         else
 562                                 TLS_LIBS="-lssl -lcrypto"
 563                         fi
 564                 fi
 565         fi
 566 fi
 567
 568 if test $ol_link_tls = yes ; then
 569         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 570 fi
 571
 572 dnl Tests for reentrant functions necessary to build a
 573 dnl thread_safe -lldap.
 574 AC_CHECK_FUNCS(         \
 575         ctime_r                 \
 576         gethostbyname_r gethostbyaddr_r \
 577 )
 578
 579 if test "$ac_cv_func_ctime_r" = no ; then
 580         ol_cv_func_ctime_r_nargs=0
 581 else
 582         OL_FUNC_CTIME_R_NARGS
 583 dnl     OL_FUNC_CTIME_R_TYPE
 584 fi
 585
 586 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 587         OL_FUNC_GETHOSTBYNAME_R_NARGS
 588 else
 589         ol_cv_func_gethostbyname_r_nargs=0
 590 fi
 591
 592 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 593         OL_FUNC_GETHOSTBYADDR_R_NARGS
 594 else
 595         ol_cv_func_gethostbyaddr_r_nargs=0
 596 fi
 597
 598 if test "$ac_cv_func_ctime_r" = yes \
 599         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 600         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 601         -a "$ac_cv_func_gethostbyname_r" = yes \
 602         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 603         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 604         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 605         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 606         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 607         ; then
 608
 609         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 610 fi
 611
 612 ol_link_threads=no
 613 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 614         -o $ol_with_threads = posix ; then
 615
 616         AC_CHECK_HEADERS(pthread.h sched.h)
 617
 618         if test $ac_cv_header_pthread_h = yes ; then
 619                 OL_POSIX_THREAD_VERSION
 620
 621                 if test $ol_cv_pthread_version = final ; then
 622                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 623                                 [define if pthreads API compatible with final spec])
 624                 elif test $ol_cv_pthread_version = draft4 ; then
 625                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 626                                 [define if pthreads API compatible with draft4 spec])
 627                 else
 628                         AC_MSG_ERROR([unknown pthread version])
 629                 fi
 630
 631                 # consider threads found
 632                 ol_with_threads=found
 633
 634                 OL_HEADER_LINUX_THREADS
 635
 636                 dnl Now the hard part, how to link?
 637                 dnl
 638                 dnl currently supported checks:
 639                 dnl
 640                 dnl Check for no flags
 641                 dnl     pthread_create() in $LIBS
 642                 dnl
 643                 dnl Check special pthread (final) flags
 644                 dnl     pthread_create() with -mt (Solaris)
 645                 dnl     pthread_create() with -kthread (FreeBSD)
 646                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 647                 dnl     pthread_create() with -pthreads (?)
 648                 dnl     pthread_create() with -thread (?)
 649                 dnl
 650                 dnl Check pthread (final) libraries
 651                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 652                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 653                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 654                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 655                 dnl     pthread_create() in -lpthread (many)
 656                 dnl     pthread_create() in -lc_r (FreeBSD)
 657                 dnl
 658                 dnl Check pthread (draft4) flags (depreciated)
 659                 dnl     pthread_create() with -threads (OSF/1)
 660                 dnl
 661                 dnl Check pthread (draft4) libraries (depreciated)
 662                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 663                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 664                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 665                 dnl     pthread_create() in -lpthreads (many)
 666                 dnl
 667
 668                 dnl pthread_create in $LIBS
 669                 AC_MSG_CHECKING([for pthread_create in default libraries])
 670                 AC_CACHE_VAL(ol_cv_pthread_create,[
 671                 AC_TRY_RUN([
 672 #include <pthread.h>
 673 #ifndef NULL
 674 #define NULL (void*)0
 675 #endif
 676
 677 static void *task(p)
 678         void *p;
 679 {
 680         return (void *) (p == NULL);
 681 }
 682
 683 int main(argc, argv)
 684         int argc;
 685         char **argv;
 686 {
 687         pthread_t t;
 688         int status;
 689
 690         /* make sure pthread_create() isn't just a stub */
 691 #if HAVE_PTHREADS_D4
 692         status = pthread_create(&t, pthread_attr_default, task, NULL);
 693 #else
 694         status = pthread_create(&t, NULL, task, NULL);
 695 #endif
 696
 697         if( status ) return status;
 698
 699         /* make sure pthread_detach() isn't just a stub */
 700 #if HAVE_PTHREADS_D4
 701         status = pthread_detach( &t );
 702 #else
 703         status = pthread_detach( t );
 704 #endif
 705
 706         if( status ) return status;
 707
 708         return status;
 709 }
 710 ],
 711                         [ol_cv_pthread_create=yes],
 712                         [ol_cv_pthread_create=no],
 713                         [dnl assume yes
 714                         ol_cv_pthread_create=yes])])
 715                 AC_MSG_RESULT($ol_cv_pthread_create)
 716
 717                 if test $ol_cv_pthread_create != no ; then
 718                         ol_link_threads=posix
 719                         ol_link_pthreads=""
 720                 fi
 721
 722                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 723                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 724                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 725                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 726                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
 727
 728                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
 729                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
 730                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
 731                         [ol_cv_pthread_lpthread_lmach_lexc])
 732 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
 733 dnl                     [ol_cv_pthread_lpthread_lexc])
 734
 735                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
 736                         [ol_cv_pthread_lib_lpthread_woff])
 737
 738                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
 739                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
 740
 741                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
 742
 743                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
 744                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
 745                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
 746                         [ol_cv_pthread_lpthreads_lmach_lexc])
 747                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
 748                         [ol_cv_pthread_lpthreads_lexc])
 749
 750                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
 751
 752                 if test $ol_link_threads != no ; then
 753                         AC_DEFINE(HAVE_PTHREADS,1,
 754                                 [define if you have POSIX Threads])
 755
 756                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
 757
 758                         dnl save flags
 759                         save_CPPFLAGS="$CPPFLAGS"
 760                         save_LIBS="$LIBS"
 761                         LIBS="$LTHREAD_LIBS $LIBS"
 762
 763                         dnl All POSIX Thread (final) implementations should have
 764                         dnl sched_yield instead of pthread yield.
 765                         dnl check for both
 766                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 767
 768                         if test $ac_cv_func_sched_yield = no -a \
 769                                 $ac_cv_func_pthread_yield = no ; then
 770                                 dnl Digital UNIX has sched_yield() in -lrt
 771                                 AC_CHECK_LIB(rt, sched_yield,
 772                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 773                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 774                                         ac_cv_func_sched_yield=yes],
 775                                         [ac_cv_func_sched_yield=no])
 776                         fi
 777                         if test $ac_cv_func_sched_yield = no -a \
 778                                 $ac_cv_func_pthread_yield = no ; then
 779                                 dnl Solaris has sched_yield() stub in -lposix4
 780                                 dnl but we'll use thr_yield instead.
 781                                 AC_CHECK_FUNCS(thr_yield)
 782                         fi
 783                         if test $ac_cv_func_sched_yield = no -a \
 784                                 $ac_cv_func_pthread_yield = no -a \
 785                                 "$ac_cv_func_thr_yield" = no ; then
 786                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 787                         fi
 788
 789                         dnl Check functions for compatibility
 790                         AC_CHECK_FUNCS(pthread_kill)
 791
 792                         dnl Check for pthread_detach with <pthread.h> inclusion
 793                         dnl as it's symbol may have been mangled.
 794                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
 795                                 [ol_cv_func_pthread_detach], [
 796                                 dnl save the flags
 797                                 AC_TRY_LINK([
 798 #include <pthread.h>
 799 #ifndef NULL
 800 #define NULL (void*)0
 801 #endif
 802 ],
 803                                         [pthread_detach(NULL);],
 804                                         [ol_cv_func_pthread_detach=yes],
 805                                         [ol_cv_func_pthread_detach=no])
 806                         ])
 807
 808                         if test $ol_cv_func_pthread_detach = no ; then
 809                                 AC_MSG_ERROR([could not locate pthread_detach()])
 810                         fi
 811
 812                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
 813                                 [define if you have pthread_detach function])
 814
 815                         dnl Check for setconcurreny functions
 816                         AC_CHECK_FUNCS( \
 817                                 pthread_setconcurrency \
 818                                 pthread_getconcurrency \
 819                                 thr_setconcurrency \
 820                                 thr_getconcurrency \
 821                         )
 822
 823                         OL_SYS_LINUX_THREADS
 824                         OL_LINUX_THREADS
 825
 826                         if test $ol_cv_linux_threads = error; then
 827                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
 828                         fi
 829
 830                         AC_MSG_CHECKING([if pthread_create() works])
 831                         AC_CACHE_VAL(ol_cv_pthread_create_works,[
 832                         AC_TRY_RUN([
 833 #include <pthread.h>
 834 #ifndef NULL
 835 #define NULL (void*)0
 836 #endif
 837
 838 static void *task(p)
 839         void *p;
 840 {
 841         return (void *) (p == NULL);
 842 }
 843
 844 int main(argc, argv)
 845         int argc;
 846         char **argv;
 847 {
 848         pthread_t t;
 849 #if HAVE_PTHREADS_D4
 850         exit(pthread_create(&t, pthread_attr_default, task, NULL));
 851 #else
 852         exit(pthread_create(&t, NULL, task, NULL));
 853 #endif
 854 }
 855 ],
 856                                 [ol_cv_pthread_create_works=yes],
 857                                 [ol_cv_pthread_create_works=no],
 858                                 [dnl assume yes
 859                                 ol_cv_pthread_create_works=yes])])
 860                         AC_MSG_RESULT($ol_cv_pthread_create_works)
 861
 862                         if test $ol_cv_pthread_create_works = no ; then
 863                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
 864                         fi
 865
 866                         dnl Check if select causes an yield
 867                         if test $ol_with_yielding_select = auto ; then
 868                                 AC_MSG_CHECKING([if select yields when using pthreads])
 869                                 AC_CACHE_VAL(ol_cv_pthread_select_yields,[
 870                                 AC_TRY_RUN([
 871 #include <sys/types.h>
 872 #include <sys/time.h>
 873 #include <unistd.h>
 874 #include <pthread.h>
 875 #ifndef NULL
 876 #define NULL (void*) 0
 877 #endif
 878
 879 static int fildes[2];
 880
 881 static void *task(p)
 882         void *p;
 883 {
 884         int i;
 885         struct timeval tv;
 886
 887         fd_set rfds;
 888
 889         tv.tv_sec=10;
 890         tv.tv_usec=0;
 891
 892         FD_ZERO(&rfds);
 893         FD_SET(fildes[0], &rfds);
 894
 895         /* we're not interested in any fds */
 896         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
 897
 898         if(i < 0) {
 899                 perror("select");
 900                 exit(10);
 901         }
 902
 903         exit(0); /* if we exit here, the select blocked the whole process */
 904 }
 905
 906 int main(argc, argv)
 907         int argc;
 908         char **argv;
 909 {
 910         pthread_t t;
 911
 912         /* create a pipe to select */
 913         if(pipe(&fildes[0])) {
 914                 perror("select");
 915                 exit(1);
 916         }
 917
 918 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 919         (void) pthread_setconcurrency(2);
 920 #else
 921 #ifdef HAVE_THR_SETCONCURRENCY
 922         /* Set Solaris LWP concurrency to 2 */
 923         thr_setconcurrency(2);
 924 #endif
 925 #endif
 926
 927 #if HAVE_PTHREADS_D4
 928         pthread_create(&t, pthread_attr_default, task, NULL);
 929 #else
 930         pthread_create(&t, NULL, task, NULL);
 931 #endif
 932
 933 #if HAVE_SCHED_YIELD
 934         sched_yield();  /* make sure task runs first */
 935 #else
 936 #ifdef HAVE_PTHREAD_YIELD
 937         pthread_yield();        /* make sure task runs first */
 938 #endif
 939 #endif
 940
 941         exit(2);
 942 }],
 943                                 [ol_cv_pthread_select_yields=no],
 944                                 [ol_cv_pthread_select_yields=yes], [
 945                                 AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])])])
 946                                 AC_MSG_RESULT($ol_cv_pthread_select_yields)
 947
 948                                 if test $ol_cv_pthread_select_yields = yes ; then
 949                                         ol_with_yielding_select=yes
 950                                 fi
 951                         fi
 952
 953                         dnl restore flags
 954                         CPPFLAGS="$save_CPPFLAGS"
 955                         LIBS="$save_LIBS"
 956                 else
 957                         AC_MSG_ERROR([could not link with POSIX Threads])
 958                 fi
 959         fi
 960
 961         if test $ol_with_threads = posix ; then
 962                 AC_MSG_ERROR([could not locate POSIX Threads])
 963         fi
 964 fi
 965
 966 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 967         -o $ol_with_threads = mach ; then
 968
 969         dnl check for Mach CThreads
 970         AC_CHECK_HEADERS(mach/cthreads.h)
 971         if test $ac_cv_header_mach_cthreads_h = yes ; then
 972                 ol_with_threads=found
 973
 974                 dnl check for cthread support in current $LIBS
 975                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 976
 977                 if test $ol_link_threads = no ; then
 978                         dnl try -all_load
 979                         dnl this test needs work
 980                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 981                                 [ol_cv_cthread_all_load], [
 982                                 dnl save the flags
 983                                 save_LIBS="$LIBS"
 984                                 LIBS="-all_load $LIBS"
 985                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 986                                         cthread_fork((void *)0, (void *)0);
 987                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 988                                 dnl restore the LIBS
 989                                 LIBS="$save_LIBS"
 990                         ])
 991
 992                         if test $ol_cv_cthread_all_load = yes ; then
 993                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 994                                 ol_link_threads=mach
 995                         fi
 996                 fi
 997
 998                 if test $ol_link_threads != no ; then
 999                         : check for cthread specific functionality here
1000                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1001                                 [define if you have Mach Cthreads])
1002                 else
1003                         AC_MSG_ERROR([could not link with Mach CThreads])
1004                 fi
1005         fi
1006
1007         if test $ol_with_threads = mach ; then
1008                 AC_MSG_ERROR([could not locate Mach CThreads])
1009         fi
1010 fi
1011
1012 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1013         -o $ol_with_threads = lwp ; then
1014
1015         dnl check for SunOS5 LWP
1016         AC_CHECK_HEADERS(thread.h synch.h)
1017         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1018                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1019
1020                 if test $have_thr = yes ; then
1021                         AC_DEFINE(HAVE_THR,1,
1022                                 [if you have Solaris LWP (thr) package])
1023                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1024                         ol_link_threads=thr
1025
1026                         if test $ol_with_yielding_select = auto ; then
1027                                 ol_with_yielding_select=yes
1028                         fi
1029
1030                         dnl Check for setconcurreny functions
1031                         AC_CHECK_FUNCS( \
1032                                 thr_setconcurrency \
1033                                 thr_getconcurrency \
1034                         )
1035                 fi
1036         fi
1037
1038         dnl check for SunOS4 LWP
1039         AC_CHECK_HEADERS(lwp/lwp.h)
1040         if test $ac_cv_header_lwp_lwp_h = yes ; then
1041                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1042
1043                 if test $have_lwp = yes ; then
1044                         AC_DEFINE(HAVE_LWP,1,
1045                                 [if you have SunOS LWP package])
1046                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1047                         ol_link_threads=lwp
1048
1049                         if test $ol_with_yielding_select = auto ; then
1050                                 ol_with_yielding_select=no
1051                         fi
1052                 fi
1053         fi
1054 fi
1055
1056 if test $ol_with_yielding_select = yes ; then
1057         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1058                 [define if select implicitly yields])
1059 fi
1060
1061 if test $ol_with_threads = manual ; then
1062         dnl User thinks he can manually configure threads.
1063         ol_link_threads=yes
1064
1065         AC_MSG_WARN([thread defines and link options must be set manually])
1066
1067         AC_CHECK_HEADERS(pthread.h sched.h)
1068         AC_CHECK_FUNCS(sched_yield pthread_yield)
1069         OL_HEADER_LINUX_THREADS
1070
1071         AC_CHECK_HEADERS(mach/cthreads.h)
1072         AC_CHECK_HEADERS(lwp/lwp.h)
1073         AC_CHECK_HEADERS(thread.h synch.h)
1074 fi
1075
1076 if test $ol_link_threads != no ; then
1077         dnl needed to get reentrant/threadsafe versions
1078         dnl
1079         AC_DEFINE(REENTRANT,1)
1080         AC_DEFINE(_REENTRANT,1)
1081         AC_DEFINE(THREAD_SAFE,1)
1082         AC_DEFINE(_THREAD_SAFE,1)
1083         AC_DEFINE(THREADSAFE,1)
1084         AC_DEFINE(_THREADSAFE,1)
1085
1086         dnl The errno declaration may dependent upon _REENTRANT.
1087         dnl If it does, we must link with thread support.
1088         AC_CACHE_CHECK([for thread specific errno],
1089                 [ol_cv_errno_thread_specific], [
1090                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1091                         [ol_cv_errno_thread_specific=yes],
1092                         [ol_cv_errno_thread_specific=no])
1093         ])
1094
1095         if test $ol_cv_errno_thread_specific != yes ; then
1096                 LIBS="$LTHREAD_LIBS $LIBS"
1097                 LTHREAD_LIBS=""
1098         fi
1099
1100 dnl When in thread environment, use
1101 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1102 dnl                     || defined( HAVE_FUNC_R )
1103 dnl                     func_r(...);
1104 dnl             #else
1105 dnl             #       if defined( HAVE_THREADS )
1106 dnl                             /* lock */
1107 dnl             #       endif
1108 dnl                             func(...);
1109 dnl             #       if defined( HAVE_THREADS )
1110 dnl                             /* unlock */
1111 dnl             #       endif
1112 dnl             #endif
1113 dnl
1114 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1115 dnl             _POSIX_REENTRANT_FUNCTIONS
1116 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1117 dnl             _POSIX_THREADSAFE_FUNCTIONS
1118 dnl
1119 dnl             and is currently defined in lthread.h
1120 dnl
1121 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1122 dnl
1123 dnl libldap/*.c should only include <lthread.h> iff
1124 dnl LDAP_R_COMPILE is defined.  ie:
1125 dnl             #ifdef LDAP_R_COMPILE
1126 dnl             #       include LDAP_R_COMPILE
1127 dnl             #endif
1128 dnl
1129 dnl LDAP_R_COMIPLE is defined by libldap_r/Makefile.in
1130 dnl specifically for compiling the threadsafe version of
1131 dnl     the ldap library (-lldap_r).
1132 dnl
1133 dnl     dnl check for reentrant/threadsafe functions
1134 dnl     dnl
1135 dnl     dnl note: these should only be used when linking
1136 dnl     dnl       with $LTHREAD_LIBS
1137 dnl     dnl
1138 dnl     save_CPPFLAGS="$CPPFLAGS"
1139 dnl     save_LIBS="$LIBS"
1140 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1141 dnl     AC_CHECK_FUNCS( \
1142 dnl             gmtime_r \
1143 dnl             gethostbyaddr_r gethostbyname_r \
1144 dnl             feof_unlocked unlocked_feof \
1145 dnl             putc_unlocked unlocked_putc \
1146 dnl             flockfile ftrylockfile \
1147 dnl     )
1148 dnl     CPPFLAGS="$save_CPPFLAGS"
1149 dnl     LIBS="$save_LIBS"
1150 fi
1151
1152 if test $ol_link_threads = no ; then
1153         if test $ol_with_threads = yes ; then
1154                 AC_MSG_ERROR([no suitable thread support])
1155         fi
1156
1157         if test $ol_with_threads = auto ; then
1158                 AC_MSG_WARN([no suitable thread support, disabling threads])
1159                 ol_with_threads=no
1160         fi
1161
1162         AC_DEFINE(NO_THREADS,1,
1163                 [define if you have (or want) no threads])
1164         LTHREAD_LIBS=""
1165 fi
1166
1167 if test $ol_link_threads != no ; then
1168         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1169 fi
1170
1171 dnl ----------------------------------------------------------------
1172
1173 ol_link_ldbm=no
1174 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1175         OL_BERKELEY_DB2
1176
1177         if test $ol_cv_berkeley_db2 = yes ; then
1178                 ol_link_ldbm=db2
1179                 ol_with_ldbm_api=db2
1180
1181                 if test $ol_with_ldbm_type = hash ; then
1182                         AC_DEFINE(LDBM_USE_DBHASH,1)
1183                 else
1184                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1185                 fi
1186
1187                 dnl $ol_cv_lib_db2 should be yes or -ldb
1188                 dnl (it could be no, but that would be an error
1189                 if test $ol_cv_lib_db2 != yes ; then
1190                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1191                 fi
1192         fi
1193 fi
1194
1195 ol_link_bdb2=no
1196 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1197         ol_link_bdb2=yes
1198 fi
1199
1200 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1201         OL_BERKELEY_DB
1202
1203         if test $ol_cv_berkeley_db = yes ; then
1204                 ol_link_ldbm=db
1205                 ol_with_ldbm_api=db
1206
1207                 if test $ol_with_ldbm_type = hash ; then
1208                         AC_DEFINE(LDBM_USE_DBHASH,1)
1209                 else
1210                         AC_DEFINE(LDBM_USE_DBBTREE,1)
1211                 fi
1212
1213                 dnl $ol_cv_lib_db should be yes or -ldb
1214                 dnl (it could be no, but that would be an error
1215                 if test $ol_cv_lib_db != yes ; then
1216                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1217                 fi
1218         fi
1219 fi
1220
1221 if test $ol_with_ldbm_api = manual ; then
1222         dnl User thinks he can manually configure LDBM api.
1223         ol_link_ldbm=yes
1224
1225         AC_MSG_WARN([LDBM defines and link options must be set manually])
1226
1227         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1228 fi
1229
1230 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1231         AC_MSG_WARN(Could not find LDBM with BTREE support)
1232         ol_with_ldbm_api=none
1233 fi
1234
1235 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1236         OL_MDBM
1237
1238         if test $ol_cv_mdbm = yes ; then
1239                 ol_link_ldbm=mdbm
1240                 ol_with_ldbm_api=mdbm
1241                 if test $ol_cv_lib_mdbm != yes ; then
1242                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1243                 fi
1244         fi
1245 fi
1246
1247 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1248         OL_GDBM
1249
1250         if test $ol_cv_gdbm = yes ; then
1251                 ol_link_ldbm=gdbm
1252                 ol_with_ldbm_api=gdbm
1253
1254                 if test $ol_cv_lib_gdbm != yes ; then
1255                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1256                 fi
1257         fi
1258 fi
1259
1260 if test $ol_with_ldbm_api = auto ; then
1261         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1262 elif test $ol_with_ldbm_api = ndbm ; then
1263         OL_NDBM
1264
1265         if test $ol_cv_ndbm = yes ; then
1266                 ol_link_ldbm=ndbm
1267                 ol_with_ldbm_api=ndbm
1268
1269                 if test $ol_cv_lib_ndbm != yes ; then
1270                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1271                 fi
1272         fi
1273 fi
1274
1275 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1276         AC_MSG_WARN(could not find suitable LDBM backend)
1277         if test $ol_enable_ldbm = yes ; then
1278                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1279         fi
1280
1281         AC_MSG_WARN(disabling LDBM)
1282         ol_enable_ldbm=no
1283 fi
1284
1285 if test $ol_enable_wrappers != no ; then
1286         AC_CHECK_HEADERS(tcpd.h)
1287
1288         if test $ac_cv_header_tcpd_h != yes ; then
1289                 have_wrappers=no
1290         else
1291                 AC_CHECK_LIB(wrap, main,
1292                         [have_wrappers=yes], [have_wrappers=no])
1293         fi
1294
1295         if test $have_wrappers = yes ; then
1296                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1297                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1298         else
1299                 AC_MSG_WARN(could not find -lwrap)
1300                 if test $ol_enable_wrappers = yes ; then
1301                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1302                 fi
1303
1304                 AC_MSG_WARN(disabling wrappers support)
1305                 ol_enable_wrappers=no
1306         fi
1307 fi
1308
1309 if test $ol_enable_syslog != no ; then
1310         AC_CHECK_FUNC(openlog)
1311         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1312                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1313         fi
1314         ol_enable_syslog=$ac_cv_func_openlog
1315 fi
1316
1317 if test $ol_enable_dmalloc != no ; then
1318         AC_CHECK_HEADERS(dmalloc.h)
1319         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1320 fi
1321
1322 if test $ol_enable_tcl != no ; then
1323         AC_CHECK_HEADERS(tcl.h)
1324
1325         if test $ac_cv_header_tcl_h != yes ; then
1326                 have_tcl=no
1327         else
1328                 AC_CHECK_LIB(tcl,main,
1329                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1330                         [have_tcl=no])
1331
1332                 if test $have_tcl != yes; then
1333                         AC_CHECK_LIB(tcl7.6,main,
1334                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1335                                 [have_tcl=no])
1336                 fi
1337
1338                 if test $have_tcl != yes; then
1339                         AC_CHECK_LIB(tcl8.0,main,
1340                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1341                                 [have_tcl=no])
1342                 fi
1343         fi
1344
1345         if test $have_tcl != yes ; then
1346                 AC_MSG_WARN([could not find -ltcl])
1347                 if test $ol_enable_tcl = yes ; then
1348                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1349                 fi
1350
1351                 ol_enable_tcl=no
1352         fi
1353 fi
1354
1355 # ud needs termcap (should insert check here)
1356 ol_link_termcap=no
1357 AC_CHECK_HEADERS(termcap.h ncurses.h)
1358
1359 if test $ol_link_termcap = no ; then
1360         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1361         if test $have_termcap = yes ; then
1362                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1363                 ol_link_termcap=yes
1364                 TERMCAP_LIBS=-ltermcap
1365         fi
1366 fi
1367
1368 if test $ol_link_termcap = no ; then
1369         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1370         if test $have_ncurses = yes ; then
1371                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1372                 ol_link_termcap=yes
1373                 TERMCAP_LIBS=-lncurses
1374         fi
1375 fi
1376
1377 if test $ol_link_termcap = no ; then
1378         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1379         TERMCAP_LIBS=
1380 fi
1381
1382 dnl
1383 dnl Check for GNU readline
1384 dnl
1385 ol_link_readline=no
1386 if test $ol_with_readline != no ; then
1387         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1388
1389         if test $ac_cv_header_readline_readline_h = yes ; then
1390                 save_LIBS="$LIBS"
1391                 LIBS="$TERMCAP_LIBS $LIBS"
1392                 AC_CHECK_LIB(readline, readline,
1393                         [have_readline=yes], [have_readline=no])
1394                 LIBS="$save_LIBS"
1395
1396                 if test $have_readline = yes ; then
1397                         ol_with_readline=found
1398                         ol_link_readline=yes
1399
1400                         READLINE_LIBS="-lreadline"
1401                 fi
1402         fi
1403 fi
1404
1405 if test $ol_link_readline = yes ; then
1406         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1407 fi
1408
1409
1410 # FreeBSD (and others) have crypt(3) in -lcrypt
1411 if test $ol_enable_crypt != no ; then
1412         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1413                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1414                         have_crypt=yes], [have_crypt=no])])
1415
1416         if test $have_crypt = yes ; then
1417                 AC_DEFINE(HAVE_CRYPT,1)
1418         else
1419                 AC_MSG_WARN(could not find crypt)
1420                 if test $ol_enable_crypt = yes ; then
1421                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1422                 fi
1423
1424                 AC_MSG_WARN(disabling crypt support)
1425                 ol_enable_crypt=no
1426         fi
1427 fi
1428
1429 # FreeBSD (and others) have setproctitle(3) in -lutil
1430 if test $ol_enable_proctitle != no ; then
1431         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1432                 AC_CHECK_LIB(util, setproctitle,
1433                         [have_setproctitle=yes
1434                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1435                         [have_setproctitle=no
1436                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1437
1438         if test $have_setproctitle = yes ; then
1439                 AC_DEFINE(HAVE_SETPROCTITLE,1)
1440         fi
1441 fi
1442
1443 dnl ----------------------------------------------------------------
1444 dnl Checks for header files.
1445 OL_HEADER_STDC
1446
1447 if test $ol_cv_header_stdc != yes; then
1448         AC_MSG_WARN([could not locate Standard C compliant headers])
1449 fi
1450
1451 AC_HEADER_DIRENT
1452 AC_HEADER_SYS_WAIT
1453 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
1454 if test $am_cv_sys_posix_termios = yes ; then
1455         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
1456                 [define if you have POSIX termios])
1457 fi
1458
1459 AC_CHECK_HEADERS(       \
1460         arpa/inet.h             \
1461         arpa/nameser.h  \
1462         assert.h                \
1463         crypt.h                 \
1464         errno.h                 \
1465         fcntl.h                 \
1466         filio.h                 \
1467         getopt.h                \
1468         grp.h                   \
1469         libutil.h               \
1470         limits.h                \
1471         locale.h                \
1472         malloc.h                \
1473         memory.h                \
1474         regex.h                 \
1475         psap.h                  \
1476         pwd.h                   \
1477         resolv.h                \
1478         sgtty.h                 \
1479         stdarg.h                \
1480         stddef.h                \
1481         string.h                \
1482         strings.h               \
1483         sysexits.h              \
1484         sys/file.h              \
1485         sys/filio.h             \
1486         sys/errno.h             \
1487         sys/ioctl.h             \
1488         sys/param.h             \
1489         sys/resource.h  \
1490         sys/socket.h    \
1491         sys/syslog.h    \
1492         sys/time.h              \
1493         sys/types.h             \
1494         syslog.h                \
1495         termios.h               \
1496         unistd.h                \
1497 )
1498
1499 dnl ----------------------------------------------------------------
1500 dnl Checks for typedefs, structures, and compiler characteristics.
1501 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1502 AC_TYPE_MODE_T
1503 AC_TYPE_OFF_T
1504 AC_TYPE_PID_T
1505 AM_TYPE_PTRDIFF_T
1506 AC_TYPE_SIGNAL
1507 OL_TYPE_SIG_ATOMIC_T
1508 AC_TYPE_SIZE_T
1509 AC_STRUCT_ST_BLKSIZE
1510 AC_HEADER_TIME
1511 AC_STRUCT_TM
1512 OL_STRUCT_PASSWD_PW_GECOS
1513
1514 OL_C_UPPER_LOWER
1515 AC_C_CONST
1516 OL_C_VOLATILE
1517
1518 if test $cross_compiling = yes ; then
1519         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1520 else
1521         AC_C_BIGENDIAN
1522         AC_CHECK_SIZEOF(short)
1523         AC_CHECK_SIZEOF(int)
1524         AC_CHECK_SIZEOF(long)
1525 fi
1526
1527 dnl ----------------------------------------------------------------
1528 dnl Checks for library functions.
1529 AC_FUNC_MEMCMP
1530 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1531 AC_FUNC_STRFTIME
1532 dnl AM_FUNC_STRTOD
1533
1534 dnl we should use vfork instead of fork in a number of places...
1535 dnl AC_FUNC_VFORK
1536 AC_FUNC_VPRINTF
1537
1538 if test $ac_cv_func_vprintf = yes ; then
1539         dnl check for vsnprintf
1540         AC_CHECK_FUNCS(vsnprintf vsprintf)
1541 fi
1542
1543 AC_CHECK_FUNCS(         \
1544         bcopy                   \
1545         endgrent                \
1546         endpwent                \
1547         flock                   \
1548         getdtablesize   \
1549         getgrgid                \
1550         gethostname             \
1551         getpass                 \
1552         getpwuid                \
1553         gettimeofday    \
1554         initgroups              \
1555         lockf                   \
1556         memcpy                  \
1557         memmove                 \
1558         mkstemp                 \
1559         recv                    \
1560         recvfrom                \
1561         setpwfile               \
1562         setgid                  \
1563         setegid                 \
1564         setsid                  \
1565         setuid                  \
1566         seteuid                 \
1567         signal                  \
1568         sigset                  \
1569         snprintf                \
1570         strdup                  \
1571         strerror                \
1572         strpbrk                 \
1573         strrchr                 \
1574         strsep                  \
1575         strstr                  \
1576         strtol                  \
1577         strtoul                 \
1578         strspn                  \
1579         sysconf                 \
1580         waitpid                 \
1581         wait4                   \
1582 )
1583
1584 dnl We actually may need to replace more than this.
1585 AC_REPLACE_FUNCS(getopt tempnam)
1586
1587 dnl ----------------------------------------------------------------
1588 # Check Configuration
1589 OL_SYS_ERRLIST
1590
1591 dnl ----------------------------------------------------------------
1592 dnl Check our declaration of strdup()
1593 OL_DECL_STRDUP
1594
1595 dnl ----------------------------------------------------------------
1596 dnl Sort out defines
1597
1598 if test "$ol_enable_debug" != no ; then
1599         AC_DEFINE(LDAP_DEBUG,1)
1600 fi
1601 if test "$ol_enable_syslog" = yes ; then
1602         AC_DEFINE(LDAP_SYSLOG,1)
1603 fi
1604 if test "$ol_enable_libui" = yes ; then
1605         AC_DEFINE(LDAP_LIBUI,1)
1606 fi
1607 if test "$ol_enable_cache" = no ; then
1608         AC_DEFINE(LDAP_NOCACHE,1)
1609 fi
1610 if test "$ol_enable_dns" != no ; then
1611         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1612 fi
1613 if test "$ol_enable_proctitle" != no ; then
1614         AC_DEFINE(LDAP_PROCTITLE,1)
1615 fi
1616 if test "$ol_enable_referrals" != no ; then
1617         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1618 fi
1619 if test "$ol_enable_cldap" != no ; then
1620         AC_DEFINE(LDAP_CONNECTIONLESS,1)
1621 fi
1622
1623 if test "$ol_enable_aclgroups" != no ; then
1624         AC_DEFINE(SLAPD_ACLGROUPS,1)
1625 fi
1626 if test "$ol_enable_crypt" != no ; then
1627         AC_DEFINE(SLAPD_CRYPT,1)
1628 fi
1629 if test "$ol_enable_cleartext" != no ; then
1630         AC_DEFINE(SLAPD_CLEARTEXT,1)
1631 fi
1632 if test "$ol_enable_phonetic" != no ; then
1633         AC_DEFINE(SLAPD_PHONETIC,1)
1634 fi
1635 if test "$ol_enable_rlookups" != no ; then
1636         AC_DEFINE(SLAPD_RLOOKUPS,1)
1637 fi
1638
1639 if test "$ol_link_modules" != no ; then
1640         AC_DEFINE(SLAPD_MODULES,1)
1641         BUILD_SLAPD=yes
1642 fi
1643
1644 if test "$ol_link_bdb2" != no ; then
1645         AC_DEFINE(SLAPD_BDB2,1)
1646         BUILD_SLAPD=yes
1647         BUILD_BDB2=yes
1648 fi
1649
1650 if test "$ol_link_ldbm" != no ; then
1651         AC_DEFINE(SLAPD_LDBM,1)
1652         BUILD_SLAPD=yes
1653         BUILD_LDBM=yes
1654 fi
1655
1656 if test "$ol_enable_passwd" != no ; then
1657         AC_DEFINE(SLAPD_PASSWD,1)
1658         BUILD_SLAPD=yes
1659         BUILD_PASSWD=yes
1660 fi
1661
1662 if test "$ol_link_perl" != no ; then
1663         AC_DEFINE(SLAPD_PERL,1)
1664         BUILD_SLAPD=yes
1665         BUILD_PERL=yes
1666 fi
1667
1668 if test "$ol_enable_shell" != no ; then
1669         AC_DEFINE(SLAPD_SHELL,1)
1670         BUILD_SLAPD=yes
1671         BUILD_SHELL=yes
1672 fi
1673
1674 if test "$ol_enable_tcl" != no ; then
1675         AC_DEFINE(SLAPD_TCL,1)
1676         BUILD_SLAPD=yes
1677         BUILD_TCL=yes
1678 fi
1679
1680 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
1681         $BUILD_SLAPD = yes ; then
1682         BUILD_SLURPD=yes
1683 fi
1684
1685 if test "$ol_link_isode" != no ; then
1686         BUILD_LDAPD=yes
1687 fi
1688
1689 dnl ----------------------------------------------------------------
1690
1691 AC_SUBST(BUILD_LDAPD)
1692 AC_SUBST(BUILD_SLAPD)
1693   AC_SUBST(BUILD_BDB2)
1694   AC_SUBST(BUILD_LDBM)
1695   AC_SUBST(BUILD_PASSWD)
1696   AC_SUBST(BUILD_PERL)
1697   AC_SUBST(BUILD_SHELL)
1698   AC_SUBST(BUILD_TCL)
1699 AC_SUBST(BUILD_SLURPD)
1700
1701 AC_SUBST(LDAP_LIBS)
1702 AC_SUBST(LDAPD_LIBS)
1703 AC_SUBST(SLAPD_LIBS)
1704 AC_SUBST(SLURPD_LIBS)
1705 AC_SUBST(LDBM_LIBS)
1706 AC_SUBST(LTHREAD_LIBS)
1707 AC_SUBST(LUTIL_LIBS)
1708
1709 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
1710 AC_SUBST(SLAPD_MODULES_LDFLAGS)
1711
1712 AC_SUBST(SLAPD_PERL_CPPFLAGS)
1713 AC_SUBST(SLAPD_PERL_LDFLAGS)
1714
1715 AC_SUBST(KRB_LIBS)
1716 AC_SUBST(READLINE_LIBS)
1717 AC_SUBST(TERMCAP_LIBS)
1718 AC_SUBST(TLS_LIBS)
1719
1720 dnl ----------------------------------------------------------------
1721 dnl final output
1722 dnl
1723
1724 AC_OUTPUT( \
1725 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1726 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1727 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1728 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1729 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1730 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1731 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1732 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1733 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1734 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1735 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1736 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1737 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1738 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1739 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1740 include/Makefile:build/top.mk:include/Makefile.in \
1741 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1742 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
1743 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1744 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
1745 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
1746 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
1747 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
1748 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
1749 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1750 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1751 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1752 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/srv.mk \
1753 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1754 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1755 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/srv.mk \
1756 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1757 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/srv.mk \
1758 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1759 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1760 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1761 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
1762 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
1763 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1764 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1765 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
1766 ,[
1767 date > stamp-h
1768 echo Please \"make depend\" to build dependencies
1769 ])