git.sur5r.net Git - openldap/blob - configure.in

   1 dnl
   2 dnl Copyright 1998,1999 The OpenLDAP Foundation.  All Rights Reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms are permitted only
   5 dnl as authorized by the OpenLDAP Public License.  A copy of this
   6 dnl license is available at http://www.OpenLDAP.org/license.html or
   7 dnl in file LICENSE in the top-level directory of the distribution.
   8 dnl
   9
  10 dnl Disable config.cache!
  11 define([AC_CACHE_LOAD], )dnl
  12 define([AC_CACHE_SAVE], )dnl
  13
  14 dnl Configure.in for OpenLDAP
  15 AC_INIT(build/version)dnl
  16 AC_CONFIG_AUX_DIR(build)dnl
  17
  18 OL_VERSION=`cat $ac_aux_dir/version`
  19 if test -z "$OL_VERSION"; then
  20         AC_MSG_ERROR([could not determine version])
  21 fi
  22
  23 dnl ----------------------------------------------------------------
  24 dnl Determine host platform
  25 dnl             we try not to use this for much
  26 AC_CANONICAL_SYSTEM
  27
  28 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  29 AC_SUBST(PACKAGE)
  30 AC_SUBST(VERSION)
  31 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  32 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  33
  34 dnl We use autoconf features new to 2.13.
  35 dnl aclocal.m4 should be built using aclocal from automake 1.4
  36 dnl libtool 1.3.3 should be installed.
  37 AC_PREREQ(2.13)dnl Required Autoconf version
  38
  39 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  40
  41 dnl ----------------------------------------------------------------
  42 dnl Start Args
  43 AC_MSG_CHECKING(configure arguments)
  44 AC_PREFIX_DEFAULT(/usr/local)
  45
  46 top_builddir=`pwd`
  47 AC_SUBST(top_builddir)dnl
  48
  49 ldap_subdir="/openldap"
  50
  51 AC_ARG_WITH(subdir,
  52 [  --with-subdir=DIR change default subdirectory used for installs],
  53 [case "$withval" in
  54         no) ldap_subdir=""
  55                 ;;
  56         yes)
  57                 ;;
  58         /*|\\*)
  59                 ldap_subdir="$withval"
  60                 ;;
  61         *)
  62                 ldap_subdir="/$withval"
  63                 ;;
  64 esac
  65 ])dnl
  66
  67 AC_SUBST(ldap_subdir)dnl
  68
  69 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  70 dnl ol_enable_syslog=no
  71 OL_ARG_ENABLE(syslog,[  --enable-syslog enable syslog support], auto)dnl
  72 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  73 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  74 OL_ARG_ENABLE(dns,[  --enable-dns               enable V2 DNS  extension], no)dnl
  75 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable V2 Referrals extension], yes)dnl
  76 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  77 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  78         no, [yes no])dnl
  79
  80 dnl General "with" options
  81 OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc       enable debug malloc support], no)dnl
  82
  83 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl  with Cyrus SASL support],
  84         auto, [auto yes no] )
  85 OL_ARG_WITH(fetch,[  --with-fetch  with fetch URL support],
  86         auto, [auto yes no] )
  87 OL_ARG_WITH(kerberos,[  --with-kerberos with Kerberos support],
  88         auto, [auto k5 k4 afs yes no])
  89 OL_ARG_WITH(readline,[  --with-readline  with readline support],
  90         auto, [auto yes no] )
  91 OL_ARG_WITH(threads,[  --with-threads   use threads],
  92         auto, [auto posix mach lwp yes no manual] )
  93 OL_ARG_WITH(tls,[  --with-tls  with TLS/SSL support],
  94         auto, [auto ssleay openssl yes no] )
  95 OL_ARG_WITH(yielding_select,[  --with-yielding-select   with implicitly yielding select],
  96         auto, [auto yes no manual] )
  97
  98 dnl Server options
  99
 100 dnl LDAPD OPTIONS
 101 AC_ARG_WITH(xxldapdoptions,[LDAPD Options:])
 102 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
 103
 104 dnl SLAPD OPTIONS
 105 AC_ARG_WITH(xxslapdoptions,[SLAPD Options:])
 106 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
 107 OL_ARG_ENABLE(cleartext,[    --enable-cleartext enable cleartext passwords], yes)dnl
 108 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
 109 OL_ARG_ENABLE(modules,[    --enable-modules     enable dynamic module support], no)dnl
 110 OL_ARG_ENABLE(multimaster,[    --enable-multimaster     enable multimaster replication], no)dnl
 111 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
 112 OL_ARG_ENABLE(quipu,[    --enable-quipu build quipu migration tools], no)dnl
 113 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
 114 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
 115
 116 dnl SLAPD Backend options
 117 OL_ARG_ENABLE(bdb2,[    --enable-bdb2   enable bdb2 backend], no)dnl
 118 OL_ARG_WITH(bdb2_module,[      --with-bdb2-module       module type], static,
 119         [static dynamic])
 120 OL_ARG_ENABLE(ldap,[    --enable-ldap   enable ldap backend], no)dnl
 121 OL_ARG_WITH(ldap_module,[      --with-ldap-module       module type], static,
 122         [static dynamic])
 123 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
 124 OL_ARG_WITH(ldbm_module,[      --with-ldbm-module       module type], static,
 125         [static dynamic])
 126 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
 127         [auto db2 db mdbm gdbm ndbm manual])
 128 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
 129         [auto btree hash])
 130
 131 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
 132 OL_ARG_WITH(passwd_module,[      --with-passwd-module   module type], static,
 133         [static dynamic])
 134 OL_ARG_ENABLE(perl,[    --enable-perl   enable perl backend], no)dnl
 135 OL_ARG_WITH(perl_module,[      --with-perl-module       module type], static,
 136         [static dynamic])
 137 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
 138 OL_ARG_WITH(shell_module,[      --with-shell-module     module type], static,
 139         [static dynamic])
 140 OL_ARG_ENABLE(tcl,[    --enable-tcl     enable tcl backend], no)dnl
 141 OL_ARG_WITH(tcl_module,[      --with-tcl-module module type], static,
 142         [static dynamic])
 143
 144 dnl SLURPD OPTIONS
 145 AC_ARG_WITH(xxslurpdoptions,[SLURPD Options:])
 146 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
 147
 148 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 149 AC_ENABLE_STATIC
 150 dnl AC_DISABLE_SHARED
 151 AC_ENABLE_SHARED
 152
 153 dnl General "enable" options
 154 # validate options
 155 if test $ol_enable_dns = yes ; then
 156         if test $ol_enable_referrals = no ; then
 157                 AC_MSG_ERROR([DNS requires --enable-referrals])
 158         fi
 159         if test $ol_enable_referrals = auto ; then
 160                 AC_MSG_WARN([DNS requires referrals, adding --enable-referrals])
 161                 ol_enable_referrals=yes
 162         fi
 163 fi
 164
 165 if test $ol_enable_slapd = no ; then
 166         dnl SLAPD was specificallly disabled
 167         if test $ol_enable_bdb2 = yes ; then
 168                 AC_MSG_WARN([slapd disabled, ignoring --enable-bdb2 argument])
 169         fi
 170         if test $ol_enable_ldap = yes ; then
 171                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 172         fi
 173         if test $ol_enable_ldbm = yes ; then
 174                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 175         fi
 176         if test $ol_enable_passwd = yes ; then
 177                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 178         fi
 179         if test $ol_enable_perl = yes ; then
 180                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 181         fi
 182         if test $ol_enable_shell = yes ; then
 183                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 184         fi
 185         if test $ol_enable_tcl = yes ; then
 186                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 187         fi
 188         if test $ol_enable_modules = yes ; then
 189                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 190         fi
 191         if test $ol_enable_multimaster = yes ; then
 192                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 193         fi
 194         if test $ol_enable_wrappers = yes ; then
 195                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 196         fi
 197         if test $ol_enable_phonetic = yes ; then
 198                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 199         fi
 200         if test $ol_enable_quipu = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-quipu argument])
 202         fi
 203         if test $ol_enable_rlookups = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 205         fi
 206         if test $ol_with_ldbm_api != auto ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 208         fi
 209         if test $ol_with_ldbm_type != auto ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 211         fi
 212         if test $ol_with_bdb2_module != static ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --with-bdb2-module argument])
 214         fi
 215         if test $ol_with_ldap_module != static ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 217         fi
 218         if test $ol_with_ldbm_module != static ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 220         fi
 221         if test $ol_with_passwd_module != static ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 223         fi
 224         if test $ol_with_perl_module != static ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 226         fi
 227         if test $ol_with_shell_module != static ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 229         fi
 230         if test $ol_with_tcl_module != static ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 232         fi
 233         if test $ol_enable_slurpd = yes ; then
 234                 AC_MSG_ERROR([slurpd requires slapd])
 235         fi
 236
 237         # force settings to no
 238         ol_enable_bdb2=no
 239         ol_enable_ldap=no
 240         ol_enable_ldbm=no
 241         ol_enable_passwd=no
 242         ol_enable_perl=no
 243         ol_enable_shell=no
 244         ol_enable_tcl=no
 245
 246         ol_enable_modules=no
 247         ol_enable_multimaster=no
 248         ol_enable_phonetic=no
 249         ol_enable_quipu=no
 250         ol_enable_rlookups=no
 251         ol_enable_wrappers=no
 252
 253         ol_with_ldbm_api=no
 254         ol_with_ldbm_type=no
 255
 256         ol_with_bdb2_module=static
 257         ol_with_ldap_module=static
 258         ol_with_ldbm_module=static
 259         ol_with_passwd_module=static
 260         ol_with_perl_module=static
 261         ol_with_shell_module=static
 262         ol_with_tcl_module=static
 263
 264         ol_enable_slurpd=no
 265
 266 elif test $ol_enable_ldbm = no ; then
 267         dnl SLAPD without LDBM
 268
 269         if test $ol_with_ldbm_api != auto ; then
 270                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 271         fi
 272
 273         if test $ol_with_ldbm_type != auto ; then
 274                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 275         fi
 276
 277         if test $ol_with_ldbm_module != static ; then
 278                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 279         fi
 280
 281         if test $ol_enable_bdb2 = yes ; then
 282                 AC_MSG_ERROR([BDB2 requires --enable-ldbm])
 283         fi
 284
 285         if test $ol_enable_modules != yes -a \
 286                 $ol_enable_ldap = no -a \
 287                 $ol_enable_passwd = no -a \
 288                 $ol_enable_perl = no -a \
 289                 $ol_enable_shell = no -a \
 290                 $ol_enable_tcl = no ; then
 291                 AC_MSG_ERROR([slapd requires a backend])
 292         fi
 293
 294         ol_with_ldbm_api=no
 295         ol_with_ldbm_type=no
 296         ol_with_ldbm_module=static
 297
 298 elif test $ol_enable_bdb2 = yes ; then
 299         dnl SLAPD with BDB2
 300
 301         if test $ol_with_ldbm_api != auto -a \
 302                 $ol_with_ldbm_api != db2 ; then
 303                 AC_MSG_ERROR([BDB2 requires LDBM API DB2])
 304         fi
 305
 306         ol_with_ldbm_api=db2
 307
 308 else
 309         dnl SLAPD with LDBM
 310
 311         if test $ol_enable_bdb2 != no ; then
 312                 if test $ol_with_ldbm_api != auto -a \
 313                         $ol_with_ldbm_api != db2 ; then
 314                         AC_MSG_WARN([BDB2 requires LDBM api db2 or auto])
 315                         ol_enable_bdb2=no
 316                 fi
 317         fi
 318
 319         if test $ol_with_ldbm_api = gdbm -a \
 320                 $ol_with_ldbm_type = btree ; then
 321                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 322         fi
 323         if test $ol_with_ldbm_api = mdbm -a \
 324                 $ol_with_ldbm_type = btree ; then
 325                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 326         fi
 327         if test $ol_with_ldbm_api = ndbm -a \
 328                 $ol_with_ldbm_type = btree ; then
 329                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 330         fi
 331 fi
 332
 333 if test $ol_enable_slurpd = yes ; then
 334         dnl SLURPD was specifically enabled
 335         if test $ol_with_threads = no ; then
 336                 AC_MSG_ERROR([slurpd requires threads])
 337         fi
 338 fi
 339
 340 AC_MSG_RESULT(done)
 341
 342 ## Initialize vars
 343 LDAP_LIBS=
 344 LDIF_LIBS=
 345 LDBM_LIBS=
 346 LTHREAD_LIBS=
 347 LUTIL_LIBS=
 348
 349 LDAPD_LIBS=
 350 SLAPD_LIBS=
 351 SLURPD_LIBS=
 352
 353 BUILD_LDAPD=no
 354 BUILD_SLAPD=no
 355 BUILD_SLURPD=no
 356
 357 BUILD_BDB2=no
 358 BUILD_LDAP=no
 359 BUILD_LDBM=no
 360 BUILD_PASSWD=no
 361 BUILD_PERL=no
 362 BUILD_QUIPU=no
 363 BUILD_SHELL=no
 364 BUILD_TCL=no
 365 BUILD_THREAD=no
 366
 367 BUILD_BDB2_DYNAMIC=static
 368 BUILD_LDAP_DYNAMIC=static
 369 BUILD_LDBM_DYNAMIC=static
 370 BUILD_PASSWD_DYNAMIC=static
 371 BUILD_PERL_DYNAMIC=static
 372 BUILD_SHELL_DYNAMIC=static
 373 BUILD_TCL_DYNAMIC=static
 374
 375 SLAPD_MODULES_LDFLAGS=
 376 SLAPD_MODULES_CPPFLAGS=
 377 SLAPD_MODULES_LIST=
 378
 379 SLAPD_PERL_LDFLAGS=
 380 SLAPD_PERL_CPPFLAGS=
 381
 382 KRB_LIBS=
 383 READLINE_LIBS=
 384 SASL_LIBS=
 385 TERMCAP_LIBS=
 386 TLS_LIBS=
 387 MODULES_LIBS=
 388
 389 dnl ----------------------------------------------------------------
 390 dnl Checks for programs
 391
 392 dnl AC_PROG_INSTALL
 393
 394 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 395
 396
 397 dnl
 398 dnl Determine which C translator to use
 399 dnl
 400
 401 dnl AIX Thread requires we use cc_r or xlc_r.
 402 dnl But only do this IF AIX and CC is not set
 403 dnl and threads are auto|yes|posix.
 404 dnl
 405 dnl If we find cc_r|xlc_r, force pthreads and assume
 406 dnl             pthread_create is in $LIBS (ie: don't bring in
 407 dnl             any additional thread libraries)
 408 dnl If we do not find cc_r|xlc_r, disable threads
 409
 410 ol_aix_threads=no
 411 case "$target" in
 412 *-*-aix*) dnl all AIX is not a good idea.
 413         if test -z "$CC" ; then
 414                 case "$ol_with_threads" in
 415                 auto | yes |  posix) ol_aix_threads=yes ;;
 416                 esac
 417         fi
 418 ;;
 419 esac
 420
 421 if test $ol_aix_threads = yes ; then
 422         if test -z "${CC}" ; then
 423                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 424
 425                 if test "$CC" = cc ; then
 426                         dnl no CC! don't allow --with-threads
 427                         if test $ol_with_threads != auto ; then
 428                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 429                         else
 430                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 431                         fi
 432                         ol_with_threads=no
 433                 fi
 434         fi
 435
 436         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 437                 ol_with_threads=posix
 438                 ol_cv_pthread_create=yes
 439         fi
 440 fi
 441
 442 if test -z "${CC}"; then
 443         AC_CHECK_PROGS(CC,cc)
 444 fi
 445
 446 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 447 dnl (for now, let autoconf sort this out)
 448 dnl CFLAGS=${CFLAGS-""}
 449
 450 AC_LIBTOOL_DLOPEN
 451 AC_PROG_LIBTOOL
 452 dnl AC_PROG_MAKE_SET
 453
 454 AC_PROG_AWK
 455 OL_PROG_LN_H
 456 AC_PROG_LN_S
 457
 458 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 459         LN_S="$LN_H"
 460 fi
 461
 462 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 463         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 464 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 465 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 466
 467 ol_link_perl=no
 468 if test $ol_enable_perl != no ; then
 469         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 470
 471         if test "no$PERLBIN" = "no" ; then
 472                 if test $ol_enable_perl = yes ; then
 473                         AC_MSG_ERROR([could not locate perl])
 474                 fi
 475
 476         else
 477                 SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 478                 SLAPD_PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 479
 480                 dnl should check perl version
 481                 ol_link_perl=yes
 482         fi
 483 fi
 484
 485 AC_PROG_CPP
 486
 487 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 488         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 489
 490 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 491         AC_MSG_WARN([programs compiled here do run here...])
 492         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 493
 494 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 495         AC_MSG_WARN([programs compiled here do not run here...])
 496         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 497 fi
 498
 499 dnl Checks for UNIX Variants
 500 AC_AIX
 501 AC_ISC_POSIX
 502 AC_MINIX
 503
 504 dnl Checks for system services
 505 AC_CYGWIN
 506 AC_MINGW32
 507 AC_EXEEXT
 508 AC_OBJEXT
 509
 510 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 511
 512 dnl BeOS requires -lbe -lroot -lnet
 513 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 514
 515 dnl OpenLDAP requires STDC features
 516 AM_PROG_CC_STDC
 517 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 518         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 519 fi
 520
 521 dnl Check cc depend flags
 522 OL_MKDEPEND
 523 if test "${ol_cv_mkdep}" = no ; then
 524         # this will soon become an error
 525         AC_MSG_WARN([do not know how to generate dependencies])
 526 fi
 527
 528 dnl
 529 dnl Check for module support
 530 dnl
 531 ol_link_modules=no
 532 if test $ol_enable_modules != no ; then
 533         AC_CHECK_HEADERS(ltdl.h)
 534
 535         if test $ac_cv_header_ltdl_h = no ; then
 536                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 537
 538         fi
 539
 540         AC_CHECK_LIB(ltdl, lt_dlinit)
 541         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 542                 AC_MSG_ERROR([could not locate libtool -lltdl])
 543         fi
 544         ol_link_modules=yes
 545 else
 546         ol_with_bdb2_module=static
 547         ol_with_ldap_module=static
 548         ol_with_ldbm_module=static
 549         ol_with_passwd_module=static
 550         ol_with_perl_module=static
 551         ol_with_shell_module=static
 552         ol_with_tcl_module=static
 553 fi
 554
 555 dnl ----------------------------------------------------------------
 556 dnl Checks for header files.
 557 OL_HEADER_STDC
 558
 559 if test $ol_cv_header_stdc != yes; then
 560         AC_MSG_WARN([could not locate Standard C compliant headers])
 561 fi
 562
 563 AC_HEADER_DIRENT
 564 AC_HEADER_SYS_WAIT
 565 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 566 if test $am_cv_sys_posix_termios = yes ; then
 567         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 568                 [define if you have POSIX termios])
 569 fi
 570
 571 AC_CHECK_HEADERS(       \
 572         arpa/inet.h             \
 573         arpa/nameser.h  \
 574         assert.h                \
 575         crypt.h                 \
 576         errno.h                 \
 577         fcntl.h                 \
 578         filio.h                 \
 579         getopt.h                \
 580         grp.h                   \
 581         libutil.h               \
 582         limits.h                \
 583         locale.h                \
 584         netinet/tcp.h   \
 585         malloc.h                \
 586         memory.h                \
 587         psap.h                  \
 588         pwd.h                   \
 589         resolv.h                \
 590         sgtty.h                 \
 591         shadow.h                \
 592         stdarg.h                \
 593         stddef.h                \
 594         string.h                \
 595         strings.h               \
 596         sysexits.h              \
 597         sys/file.h              \
 598         sys/filio.h             \
 599         sys/errno.h             \
 600         sys/ioctl.h             \
 601         sys/param.h             \
 602         sys/resource.h  \
 603         sys/select.h    \
 604         sys/socket.h    \
 605         sys/syslog.h    \
 606         sys/time.h              \
 607         sys/types.h             \
 608         syslog.h                \
 609         termios.h               \
 610         unistd.h                \
 611 )
 612
 613 dnl ----------------------------------------------------------------
 614 dnl Checks for libraries
 615
 616 dnl Find socket()
 617 dnl Likely combinations:
 618 dnl             -lsocket [ -lnsl_s | -lnsl ]
 619 dnl             -linet
 620
 621 AC_CHECK_FUNC(socket, :, [
 622 dnl
 623 dnl hopefully we won't include too many libraries
 624 dnl
 625         AC_CHECK_LIB(socket, main)
 626         AC_CHECK_LIB(net, main)
 627         AC_CHECK_LIB(net, socket)
 628         AC_CHECK_LIB(nsl_s, main)
 629         AC_CHECK_LIB(nsl, main)
 630         AC_CHECK_LIB(inet, socket)
 631         AC_CHECK_LIB(gen, main)
 632 ])
 633
 634 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 635
 636 dnl Select arg types
 637 dnl (if this detection becomes permenent, it and the select() detection
 638 dnl should be done before the yielding select test)
 639 AC_FUNC_SELECT_ARGTYPES
 640
 641
 642 AC_CHECK_HEADERS( regex.h )
 643 if test "$ac_cv_header_regex_h" != yes ; then
 644         AC_MSG_ERROR([POSIX regex.h required.])
 645 fi
 646 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 647
 648 OL_POSIX_REGEX
 649 if test "$ol_cv_c_posix_regex" = no ; then
 650         AC_MSG_ERROR([broken POSIX regex!])
 651 fi
 652
 653
 654 dnl HP-UX requires -lV3
 655 AC_CHECK_LIB(V3, sigset)
 656
 657
 658 # find res_search
 659 if test $ol_enable_dns != no ; then
 660         dnl Check for resolver routines
 661         AC_CHECK_FUNC(res_search,:)
 662         if test $ac_cv_func_res_search = no ; then
 663                 AC_CHECK_LIB(bind, res_search)
 664                 ac_cv_func_res_search=$ac_cv_lib_bind_res_search
 665         fi
 666         if test $ac_cv_func_res_search = no ; then
 667                 AC_CHECK_LIB(bind, __res_search)
 668                 ac_cv_func_res_search=$ac_cv_lib_bind___res_search
 669         fi
 670         if test $ac_cv_func_res_search = no ; then
 671                 AC_CHECK_LIB(resolv, res_search)
 672                 ac_cv_func_res_search=$ac_cv_lib_resolv_res_search
 673         fi
 674
 675         if test "$ac_cv_func_res_search" = yes ; then
 676                 AC_DEFINE(HAVE_RES_SEARCH,1,
 677                         [define if you have res_search()])
 678         elif test $ol_enable_dns = yes ; then
 679                 AC_MSG_ERROR([--enable-dns requires res_search])
 680         else
 681                 AC_MSG_WARN([no res_search, disabling DNS support])
 682         fi
 683 fi
 684
 685
 686 # ISODE tests
 687 ol_link_isode=no
 688 if test $ol_enable_ldapd != no ; then
 689         AC_MSG_WARN([ldapd is not supported and may suffer from bit rot.])
 690
 691         dnl look for ISODE libraries
 692         AC_CHECK_LIB(xtpp, main, [
 693                 ol_link_isode=yes
 694                 AC_DEFINE(HAVE_XTPP,1, [define if you have -lxttp])
 695                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lxtdsap -lxtisode -losi"
 696                 ],:,[-lxtdsap -lxtisode -losi])
 697         AC_CHECK_LIB(dsap, main, [
 698                 ol_link_isode=yes
 699                 AC_DEFINE(HAVE_DSAP,1, [define if you have -ldsap])
 700                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 701                 ],:,[-lisode])
 702         AC_CHECK_LIB(isode, main, [
 703                 ol_link_isode=yes
 704                 AC_DEFINE(HAVE_ISODE,1, [define if you have -lisode])
 705                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 706                 ],:)
 707 fi
 708
 709 if test $ol_link_isode != no; then
 710         AC_CHECK_LIB(pp, main, [
 711                 AC_DEFINE(HAVE_PP,1, [define if you have -lpp])
 712                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 713                 ],:)
 714
 715         AC_PATH_PROG(PEPSY, pepsy)
 716 fi
 717
 718 if test $ol_enable_quipu != no ; then
 719         AC_CHECK_HEADERS(quipu/commonarg.h)
 720
 721         if test $ac_cv_header_quipu_commonarg_h = yes ; then
 722                 BUILD_QUIPU=yes
 723         elif test $ol_enable_quipu = auto ; then
 724                 AC_MSG_WARN([no quipu for --enable-quipu=auto, disabling])
 725         else
 726                 AC_MSG_ERROR(no quipu for --enable-quipu=$ol_enable_quipu)
 727         fi
 728 fi
 729
 730 dnl
 731 dnl check for kerberos
 732 dnl
 733 ol_link_kerberos=no
 734
 735 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 736         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 737
 738         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 739                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 740                         [-lkrb5 -ldes425])
 741
 742                 if test $have_k5 = yes ; then
 743                         ol_with_kerberos=found
 744                         ol_link_kerberos=yes
 745
 746                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 747
 748                         LIBS="$KRB_LIBS $LIBS"
 749
 750                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 751                                 [ol_cv_var_des_debug], [
 752                                 dnl save the flags
 753                                 save_LIBS="$LIBS"
 754                                 LIBS="$KRB_LIBS $LIBS"
 755                                 AC_TRY_LINK([
 756 #include <kerberosIV/krb.h>
 757 #include <kerberosIV/des.h>
 758 extern int des_debug;
 759 ],[
 760 des_debug = 1;
 761 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 762                                 dnl restore the LIBS
 763                                 LIBS="$save_LIBS"
 764                         ])
 765
 766                         if test $ol_cv_var_des_debug = yes ; then
 767                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 768                                         [define if you have Kerberos des_debug])
 769                         fi
 770
 771                         LIBS="$save_LIBS"
 772                 fi
 773         fi
 774 fi
 775
 776 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 777         AC_CHECK_HEADERS(krb.h des.h)
 778
 779         if test $ac_cv_header_krb_h = yes ; then
 780                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 781
 782                 if test $have_k4 = yes ; then
 783                         ol_with_kerberos=found
 784                         ol_link_kerberos=yes
 785
 786                         KRB_LIBS="-lkrb -ldes"
 787                 fi
 788         fi
 789 fi
 790
 791 if test $ol_link_kerberos = yes ; then
 792         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 793 fi
 794
 795 dnl
 796 dnl Check for SSL/TLS
 797 dnl
 798 ol_link_tls=no
 799 if test $ol_with_tls != no ; then
 800
 801         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 802
 803         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 804                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 805                         [have_ssleay=yes
 806                         need_rsaref=no],
 807                         [have_ssleay=no],
 808                         [-lcrypto])
 809
 810                 if test $have_ssleay = no ; then
 811                         AC_CHECK_LIB(ssl, SSL_library_init,
 812                                 [have_ssleay=yes
 813                                 need_rsaref=no], [have_ssleay=no],
 814                                 [-lcrypto])
 815                 fi
 816
 817                 if test $have_ssleay = no ; then
 818                         AC_CHECK_LIB(ssl, ssl3_accept,
 819                                 [have_ssleay=yes
 820                                 need_rsaref=yes], [have_ssleay=no],
 821                                 [-lcrypto -lRSAglue -lrsaref])
 822                 fi
 823
 824                 if test $have_ssleay = yes ; then
 825                         ol_with_tls=found
 826                         ol_link_tls=yes
 827
 828                         AC_DEFINE(HAVE_SSLEAY, 1,
 829                                 [define if you have SSLeay or OpenSSL])
 830
 831                         if test $need_rsaref = yes; then
 832                                 AC_DEFINE(HAVE_RSAREF, 1,
 833                                         [define if you have RSAref])
 834
 835                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
 836                         else
 837                                 TLS_LIBS="-lssl -lcrypto"
 838                         fi
 839                 fi
 840         fi
 841 fi
 842
 843 if test $ol_link_tls = yes ; then
 844         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
 845 fi
 846
 847 dnl Tests for reentrant functions necessary to build a
 848 dnl thread_safe -lldap.
 849 AC_CHECK_FUNCS(         \
 850         ctime_r                 \
 851         gethostbyname_r gethostbyaddr_r \
 852 )
 853
 854 if test "$ac_cv_func_ctime_r" = no ; then
 855         ol_cv_func_ctime_r_nargs=0
 856 else
 857         OL_FUNC_CTIME_R_NARGS
 858 dnl     OL_FUNC_CTIME_R_TYPE
 859 fi
 860
 861 if test "$ac_cv_func_gethostbyname_r" = yes ; then
 862         OL_FUNC_GETHOSTBYNAME_R_NARGS
 863 else
 864         ol_cv_func_gethostbyname_r_nargs=0
 865 fi
 866
 867 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
 868         OL_FUNC_GETHOSTBYADDR_R_NARGS
 869 else
 870         ol_cv_func_gethostbyaddr_r_nargs=0
 871 fi
 872
 873 if test "$ac_cv_func_ctime_r" = yes \
 874         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
 875         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
 876         -a "$ac_cv_func_gethostbyname_r" = yes \
 877         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
 878         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
 879         -a "$ac_cv_func_gethostbyaddr_r" = yes \
 880         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
 881         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
 882         ; then
 883
 884         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
 885 fi
 886
 887 ol_link_threads=no
 888 if test $ol_with_threads = auto -o $ol_with_threads = yes \
 889         -o $ol_with_threads = posix ; then
 890
 891         AC_CHECK_HEADERS(pthread.h sched.h)
 892
 893         if test $ac_cv_header_pthread_h = yes ; then
 894                 OL_POSIX_THREAD_VERSION
 895
 896                 if test $ol_cv_pthread_version = final ; then
 897                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
 898                                 [define if pthreads API compatible with final spec])
 899                 elif test $ol_cv_pthread_version = draft4 ; then
 900                         AC_DEFINE(HAVE_PTHREADS_D4,1,
 901                                 [define if pthreads API compatible with draft4 spec])
 902                 else
 903                         AC_MSG_ERROR([unknown pthread version])
 904                 fi
 905
 906                 # consider threads found
 907                 ol_with_threads=found
 908
 909                 OL_HEADER_LINUX_THREADS
 910
 911                 dnl Now the hard part, how to link?
 912                 dnl
 913                 dnl currently supported checks:
 914                 dnl
 915                 dnl Check for no flags
 916                 dnl     pthread_create() in $LIBS
 917                 dnl
 918                 dnl Check special pthread (final) flags
 919                 dnl     pthread_create() with -mt (Solaris)
 920                 dnl     pthread_create() with -kthread (FreeBSD)
 921                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
 922                 dnl     pthread_create() with -pthreads (?)
 923                 dnl     pthread_create() with -mthreads (AIX)
 924                 dnl     pthread_create() with -thread (?)
 925                 dnl
 926                 dnl Check pthread (final) libraries
 927                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
 928                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
 929                 dnl     (skipped) pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
 930                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
 931                 dnl     pthread_create() in -lpthread (many)
 932                 dnl     pthread_create() in -lc_r (FreeBSD)
 933                 dnl
 934                 dnl Check pthread (draft4) flags (depreciated)
 935                 dnl     pthread_create() with -threads (OSF/1)
 936                 dnl
 937                 dnl Check pthread (draft4) libraries (depreciated)
 938                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
 939                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
 940                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
 941                 dnl     pthread_create() in -lpthreads (many)
 942                 dnl
 943
 944                 dnl pthread_create in $LIBS
 945                 AC_CACHE_CHECK([for pthread_create in default libraries],
 946                         ol_cv_pthread_create,[
 947                 AC_TRY_RUN([
 948 #include <pthread.h>
 949 #ifndef NULL
 950 #define NULL (void*)0
 951 #endif
 952
 953 static void *task(p)
 954         void *p;
 955 {
 956         return (void *) (p == NULL);
 957 }
 958
 959 int main(argc, argv)
 960         int argc;
 961         char **argv;
 962 {
 963         pthread_t t;
 964         int status;
 965
 966         /* make sure pthread_create() isn't just a stub */
 967 #if HAVE_PTHREADS_D4
 968         status = pthread_create(&t, pthread_attr_default, task, NULL);
 969 #else
 970         status = pthread_create(&t, NULL, task, NULL);
 971 #endif
 972
 973         if( status ) return status;
 974
 975         /* make sure pthread_detach() isn't just a stub */
 976 #if HAVE_PTHREADS_D4
 977         status = pthread_detach( &t );
 978 #else
 979         status = pthread_detach( t );
 980 #endif
 981
 982         return status;
 983 }
 984 ],
 985                         [ol_cv_pthread_create=yes],
 986                         [ol_cv_pthread_create=no],
 987                         [dnl assume yes
 988                         ol_cv_pthread_create=yes])])
 989
 990                 if test $ol_cv_pthread_create != no ; then
 991                         ol_link_threads=posix
 992                         ol_link_pthreads=""
 993                 fi
 994
 995                 OL_PTHREAD_TRY_LINK([-mt],              [ol_cv_pthread_mt])
 996                 OL_PTHREAD_TRY_LINK([-kthread], [ol_cv_pthread_kthread])
 997                 OL_PTHREAD_TRY_LINK([-pthread], [ol_cv_pthread_pthread])
 998                 OL_PTHREAD_TRY_LINK([-pthreads],[ol_cv_pthread_pthreads])
 999                 OL_PTHREAD_TRY_LINK([-mthreads],[ol_cv_pthread_mthreads])
1000                 OL_PTHREAD_TRY_LINK([-thread],  [ol_cv_pthread_thread])
1001
1002                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc -lc_r],
1003                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1004                 OL_PTHREAD_TRY_LINK([-lpthread -lmach -lexc],
1005                         [ol_cv_pthread_lpthread_lmach_lexc])
1006 dnl             OL_PTHREAD_TRY_LINK([-lpthread -lexc],
1007 dnl                     [ol_cv_pthread_lpthread_lexc])
1008
1009                 OL_PTHREAD_TRY_LINK([-lpthread -Wl,-woff,85],
1010                         [ol_cv_pthread_lib_lpthread_woff])
1011
1012                 OL_PTHREAD_TRY_LINK([-lpthread],[ol_cv_pthread_lpthread])
1013                 OL_PTHREAD_TRY_LINK([-lc_r],    [ol_cv_pthread_lc_r])
1014
1015                 OL_PTHREAD_TRY_LINK([-threads], [ol_cv_pthread_threads])
1016
1017                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc -lc_r],
1018                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1019                 OL_PTHREAD_TRY_LINK([-lpthreads -lmach -lexc],
1020                         [ol_cv_pthread_lpthreads_lmach_lexc])
1021                 OL_PTHREAD_TRY_LINK([-lpthreads -lexc],
1022                         [ol_cv_pthread_lpthreads_lexc])
1023
1024                 OL_PTHREAD_TRY_LINK([-lpthreads],       [ol_cv_pthread_lib_lpthreads])
1025
1026                 if test $ol_link_threads != no ; then
1027                         AC_DEFINE(HAVE_PTHREADS,1,
1028                                 [define if you have POSIX Threads])
1029
1030                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1031
1032                         dnl save flags
1033                         save_CPPFLAGS="$CPPFLAGS"
1034                         save_LIBS="$LIBS"
1035                         LIBS="$LTHREAD_LIBS $LIBS"
1036
1037                         dnl All POSIX Thread (final) implementations should have
1038                         dnl sched_yield instead of pthread yield.
1039                         dnl check for both
1040                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1041
1042                         if test $ac_cv_func_sched_yield = no -a \
1043                                 $ac_cv_func_pthread_yield = no ; then
1044                                 dnl Digital UNIX has sched_yield() in -lrt
1045                                 AC_CHECK_LIB(rt, sched_yield,
1046                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1047                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1048                                                 [Define if you have the sched_yield function.])
1049                                         ac_cv_func_sched_yield=yes],
1050                                         [ac_cv_func_sched_yield=no])
1051                         fi
1052                         if test $ac_cv_func_sched_yield = no -a \
1053                                 $ac_cv_func_pthread_yield = no ; then
1054                                 dnl Solaris has sched_yield() stub in -lposix4
1055                                 dnl but we'll use thr_yield instead.
1056                                 AC_CHECK_FUNCS(thr_yield)
1057                         fi
1058                         if test $ac_cv_func_sched_yield = no -a \
1059                                 $ac_cv_func_pthread_yield = no -a \
1060                                 "$ac_cv_func_thr_yield" = no ; then
1061                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1062                         fi
1063
1064                         dnl Check functions for compatibility
1065                         AC_CHECK_FUNCS(pthread_kill)
1066
1067                         dnl Check for pthread_detach with <pthread.h> inclusion
1068                         dnl as it's symbol may have been mangled.
1069                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1070                                 [ol_cv_func_pthread_detach], [
1071                                 dnl save the flags
1072                                 AC_TRY_LINK([
1073 #include <pthread.h>
1074 #ifndef NULL
1075 #define NULL (void*)0
1076 #endif
1077 ],
1078                                         [pthread_detach(NULL);],
1079                                         [ol_cv_func_pthread_detach=yes],
1080                                         [ol_cv_func_pthread_detach=no])
1081                         ])
1082
1083                         if test $ol_cv_func_pthread_detach = no ; then
1084                                 AC_MSG_ERROR([could not locate pthread_detach()])
1085                         fi
1086
1087                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1088                                 [define if you have pthread_detach function])
1089
1090                         dnl Check for setconcurreny functions
1091                         AC_CHECK_FUNCS( \
1092                                 pthread_setconcurrency \
1093                                 pthread_getconcurrency \
1094                                 thr_setconcurrency \
1095                                 thr_getconcurrency \
1096                         )
1097
1098                         OL_SYS_LINUX_THREADS
1099                         OL_LINUX_THREADS
1100
1101                         if test $ol_cv_linux_threads = error; then
1102                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1103                         fi
1104
1105                         AC_CACHE_CHECK([if pthread_create() works],
1106                                 ol_cv_pthread_create_works,[
1107                         AC_TRY_RUN([
1108 #include <pthread.h>
1109 #ifndef NULL
1110 #define NULL (void*)0
1111 #endif
1112
1113 static void *task(p)
1114         void *p;
1115 {
1116         return (void *) (p == NULL);
1117 }
1118
1119 int main(argc, argv)
1120         int argc;
1121         char **argv;
1122 {
1123         pthread_t t;
1124 #if HAVE_PTHREADS_D4
1125         exit(pthread_create(&t, pthread_attr_default, task, NULL));
1126 #else
1127         exit(pthread_create(&t, NULL, task, NULL));
1128 #endif
1129 }
1130 ],
1131                                 [ol_cv_pthread_create_works=yes],
1132                                 [ol_cv_pthread_create_works=no],
1133                                 [dnl assume yes
1134                                 ol_cv_pthread_create_works=yes])])
1135
1136                         if test $ol_cv_pthread_create_works = no ; then
1137                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1138                         fi
1139
1140                         dnl Check if select causes an yield
1141                         if test $ol_with_yielding_select = auto ; then
1142                                 AC_CACHE_CHECK([if select yields when using pthreads],
1143                                         ol_cv_pthread_select_yields,[
1144                                 AC_TRY_RUN([
1145 #include <sys/types.h>
1146 #include <sys/time.h>
1147 #include <unistd.h>
1148 #include <pthread.h>
1149 #ifndef NULL
1150 #define NULL (void*) 0
1151 #endif
1152
1153 static int fildes[2];
1154
1155 static void *task(p)
1156         void *p;
1157 {
1158         int i;
1159         struct timeval tv;
1160
1161         fd_set rfds;
1162
1163         tv.tv_sec=10;
1164         tv.tv_usec=0;
1165
1166         FD_ZERO(&rfds);
1167         FD_SET(fildes[0], &rfds);
1168
1169         /* we're not interested in any fds */
1170         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1171
1172         if(i < 0) {
1173                 perror("select");
1174                 exit(10);
1175         }
1176
1177         exit(0); /* if we exit here, the select blocked the whole process */
1178 }
1179
1180 int main(argc, argv)
1181         int argc;
1182         char **argv;
1183 {
1184         pthread_t t;
1185
1186         /* create a pipe to select */
1187         if(pipe(&fildes[0])) {
1188                 perror("select");
1189                 exit(1);
1190         }
1191
1192 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1193         (void) pthread_setconcurrency(2);
1194 #else
1195 #ifdef HAVE_THR_SETCONCURRENCY
1196         /* Set Solaris LWP concurrency to 2 */
1197         thr_setconcurrency(2);
1198 #endif
1199 #endif
1200
1201 #if HAVE_PTHREADS_D4
1202         pthread_create(&t, pthread_attr_default, task, NULL);
1203 #else
1204         pthread_create(&t, NULL, task, NULL);
1205 #endif
1206
1207 #if HAVE_SCHED_YIELD
1208         sched_yield();  /* make sure task runs first */
1209 #else
1210 #ifdef HAVE_PTHREAD_YIELD
1211         pthread_yield();        /* make sure task runs first */
1212 #endif
1213 #endif
1214
1215         exit(2);
1216 }],
1217                                 [ol_cv_pthread_select_yields=no],
1218                                 [ol_cv_pthread_select_yields=yes],
1219                                 [ol_cv_pthread_select_yields=cross])])
1220
1221                                 if test $ol_cv_pthread_select_yields = cross ; then
1222                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1223                                 fi
1224
1225                                 if test $ol_cv_pthread_select_yields = yes ; then
1226                                         ol_with_yielding_select=yes
1227                                 fi
1228                         fi
1229
1230                         dnl restore flags
1231                         CPPFLAGS="$save_CPPFLAGS"
1232                         LIBS="$save_LIBS"
1233                 else
1234                         AC_MSG_ERROR([could not link with POSIX Threads])
1235                 fi
1236         fi
1237
1238         if test $ol_with_threads = posix ; then
1239                 AC_MSG_ERROR([could not locate POSIX Threads])
1240         fi
1241 fi
1242
1243 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1244         -o $ol_with_threads = mach ; then
1245
1246         dnl check for Mach CThreads
1247         AC_CHECK_HEADERS(mach/cthreads.h)
1248         if test $ac_cv_header_mach_cthreads_h = yes ; then
1249                 ol_with_threads=found
1250
1251                 dnl check for cthread support in current $LIBS
1252                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1253
1254                 if test $ol_link_threads = no ; then
1255                         dnl try -all_load
1256                         dnl this test needs work
1257                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1258                                 [ol_cv_cthread_all_load], [
1259                                 dnl save the flags
1260                                 save_LIBS="$LIBS"
1261                                 LIBS="-all_load $LIBS"
1262                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1263                                         cthread_fork((void *)0, (void *)0);
1264                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1265                                 dnl restore the LIBS
1266                                 LIBS="$save_LIBS"
1267                         ])
1268
1269                         if test $ol_cv_cthread_all_load = yes ; then
1270                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1271                                 ol_link_threads=mach
1272                         fi
1273                 fi
1274
1275                 if test $ol_link_threads != no ; then
1276                         : check for cthread specific functionality here
1277                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1278                                 [define if you have Mach Cthreads])
1279                 else
1280                         AC_MSG_ERROR([could not link with Mach CThreads])
1281                 fi
1282         fi
1283
1284         if test $ol_with_threads = mach ; then
1285                 AC_MSG_ERROR([could not locate Mach CThreads])
1286         fi
1287 fi
1288
1289 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1290         -o $ol_with_threads = lwp ; then
1291
1292         dnl check for SunOS5 LWP
1293         AC_CHECK_HEADERS(thread.h synch.h)
1294         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1295                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1296
1297                 if test $have_thr = yes ; then
1298                         AC_DEFINE(HAVE_THR,1,
1299                                 [if you have Solaris LWP (thr) package])
1300                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1301                         ol_link_threads=thr
1302
1303                         if test $ol_with_yielding_select = auto ; then
1304                                 ol_with_yielding_select=yes
1305                         fi
1306
1307                         dnl Check for setconcurreny functions
1308                         AC_CHECK_FUNCS( \
1309                                 thr_setconcurrency \
1310                                 thr_getconcurrency \
1311                         )
1312                 fi
1313         fi
1314
1315         dnl check for SunOS4 LWP
1316         AC_CHECK_HEADERS(lwp/lwp.h)
1317         if test $ac_cv_header_lwp_lwp_h = yes ; then
1318                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1319
1320                 if test $have_lwp = yes ; then
1321                         AC_DEFINE(HAVE_LWP,1,
1322                                 [if you have SunOS LWP package])
1323                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1324                         ol_link_threads=lwp
1325
1326                         if test $ol_with_yielding_select = auto ; then
1327                                 ol_with_yielding_select=no
1328                         fi
1329                 fi
1330         fi
1331 fi
1332
1333 if test $ol_with_yielding_select = yes ; then
1334         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1335                 [define if select implicitly yields])
1336 fi
1337
1338 if test $ol_with_threads = manual ; then
1339         dnl User thinks he can manually configure threads.
1340         ol_link_threads=yes
1341
1342         AC_MSG_WARN([thread defines and link options must be set manually])
1343
1344         AC_CHECK_HEADERS(pthread.h sched.h)
1345         AC_CHECK_FUNCS(sched_yield pthread_yield)
1346         OL_HEADER_LINUX_THREADS
1347
1348         AC_CHECK_HEADERS(mach/cthreads.h)
1349         AC_CHECK_HEADERS(lwp/lwp.h)
1350         AC_CHECK_HEADERS(thread.h synch.h)
1351 fi
1352
1353 if test $ol_link_threads != no ; then
1354         dnl needed to get reentrant/threadsafe versions
1355         dnl
1356         AC_DEFINE(REENTRANT,1)
1357         AC_DEFINE(_REENTRANT,1)
1358         AC_DEFINE(THREAD_SAFE,1)
1359         AC_DEFINE(_THREAD_SAFE,1)
1360         AC_DEFINE(THREADSAFE,1)
1361         AC_DEFINE(_THREADSAFE,1)
1362         AC_DEFINE(_SGI_MP_SOURCE,1)
1363
1364         dnl The errno declaration may dependent upon _REENTRANT.
1365         dnl If it does, we must link with thread support.
1366         AC_CACHE_CHECK([for thread specific errno],
1367                 [ol_cv_errno_thread_specific], [
1368                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1369                         [ol_cv_errno_thread_specific=yes],
1370                         [ol_cv_errno_thread_specific=no])
1371         ])
1372
1373         dnl The h_errno declaration may dependent upon _REENTRANT.
1374         dnl If it does, we must link with thread support.
1375         AC_CACHE_CHECK([for thread specific h_errno],
1376                 [ol_cv_h_errno_thread_specific], [
1377                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1378                         [ol_cv_h_errno_thread_specific=yes],
1379                         [ol_cv_h_errno_thread_specific=no])
1380         ])
1381
1382         if test $ol_cv_errno_thread_specific != yes \
1383                 -o $ol_cv_h_errno_thread_specific != yes ; then
1384                 LIBS="$LTHREAD_LIBS $LIBS"
1385                 LTHREAD_LIBS=""
1386         fi
1387
1388 dnl When in thread environment, use
1389 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1390 dnl                     || defined( HAVE_FUNC_R )
1391 dnl                     func_r(...);
1392 dnl             #else
1393 dnl             #       if defined( HAVE_THREADS )
1394 dnl                             /* lock */
1395 dnl             #       endif
1396 dnl                             func(...);
1397 dnl             #       if defined( HAVE_THREADS )
1398 dnl                             /* unlock */
1399 dnl             #       endif
1400 dnl             #endif
1401 dnl
1402 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1403 dnl             _POSIX_REENTRANT_FUNCTIONS
1404 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1405 dnl             _POSIX_THREADSAFE_FUNCTIONS
1406 dnl
1407 dnl             and is currently defined in lthread.h
1408 dnl
1409 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1410 dnl
1411 dnl libldap/*.c should only include <lthread.h> iff
1412 dnl LDAP_R_COMPILE is defined.  ie:
1413 dnl             #ifdef LDAP_R_COMPILE
1414 dnl             #       include LDAP_R_COMPILE
1415 dnl             #endif
1416 dnl
1417 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1418 dnl specifically for compiling the threadsafe version of
1419 dnl     the ldap library (-lldap_r).
1420 dnl
1421 dnl     dnl check for reentrant/threadsafe functions
1422 dnl     dnl
1423 dnl     dnl note: these should only be used when linking
1424 dnl     dnl       with $LTHREAD_LIBS
1425 dnl     dnl
1426 dnl     save_CPPFLAGS="$CPPFLAGS"
1427 dnl     save_LIBS="$LIBS"
1428 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1429 dnl     AC_CHECK_FUNCS( \
1430 dnl             gmtime_r \
1431 dnl             gethostbyaddr_r gethostbyname_r \
1432 dnl             feof_unlocked unlocked_feof \
1433 dnl             putc_unlocked unlocked_putc \
1434 dnl             flockfile ftrylockfile \
1435 dnl     )
1436 dnl     CPPFLAGS="$save_CPPFLAGS"
1437 dnl     LIBS="$save_LIBS"
1438 fi
1439
1440 if test $ol_link_threads = no ; then
1441         if test $ol_with_threads = yes ; then
1442                 AC_MSG_ERROR([no suitable thread support])
1443         fi
1444
1445         if test $ol_with_threads = auto ; then
1446                 AC_MSG_WARN([no suitable thread support, disabling threads])
1447                 ol_with_threads=no
1448         fi
1449
1450         AC_DEFINE(NO_THREADS,1,
1451                 [define if you have (or want) no threads])
1452         LTHREAD_LIBS=""
1453 fi
1454
1455 if test $ol_link_threads != no ; then
1456         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1457 fi
1458
1459 dnl ----------------------------------------------------------------
1460
1461 ol_link_ldbm=no
1462 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
1463         OL_BERKELEY_DB2
1464
1465         if test $ol_cv_berkeley_db2 = yes ; then
1466                 ol_link_ldbm=db2
1467                 ol_with_ldbm_api=db2
1468
1469                 if test $ol_with_ldbm_type = hash ; then
1470                         AC_DEFINE(LDBM_USE_DBHASH,1,
1471                                 [define this to use DBHASH w/ LDBM backend])
1472                 else
1473                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1474                                 [define this to use DBBTREE w/ LDBM backend])
1475                 fi
1476
1477                 dnl $ol_cv_lib_db2 should be yes or -ldb
1478                 dnl (it could be no, but that would be an error
1479                 if test $ol_cv_lib_db2 != yes ; then
1480                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
1481                 fi
1482         fi
1483 fi
1484
1485 ol_link_bdb2=no
1486 if test $ol_link_ldbm = db2 -a $ol_enable_bdb2 != no ; then
1487         ol_link_bdb2=yes
1488 fi
1489
1490 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
1491         OL_BERKELEY_DB
1492
1493         if test $ol_cv_berkeley_db = yes ; then
1494                 ol_link_ldbm=db
1495                 ol_with_ldbm_api=db
1496
1497                 if test $ol_with_ldbm_type = hash ; then
1498                         AC_DEFINE(LDBM_USE_DBHASH,1,
1499                                 [define this to use DBHASH w/ LDBM backend])
1500                 else
1501                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1502                                 [define this to use DBBTREE w/ LDBM backend])
1503                 fi
1504
1505                 dnl $ol_cv_lib_db should be yes or -ldb
1506                 dnl (it could be no, but that would be an error
1507                 if test $ol_cv_lib_db != yes ; then
1508                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1509                 fi
1510         fi
1511 fi
1512
1513 if test $ol_with_ldbm_api = manual ; then
1514         dnl User thinks he can manually configure LDBM api.
1515         ol_link_ldbm=yes
1516
1517         AC_MSG_WARN([LDBM defines and link options must be set manually])
1518
1519         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
1520 fi
1521
1522 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1523         AC_MSG_WARN(Could not find LDBM with BTREE support)
1524         ol_with_ldbm_api=none
1525 fi
1526
1527 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1528         OL_MDBM
1529
1530         if test $ol_cv_mdbm = yes ; then
1531                 ol_link_ldbm=mdbm
1532                 ol_with_ldbm_api=mdbm
1533                 if test $ol_cv_lib_mdbm != yes ; then
1534                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1535                 fi
1536         fi
1537 fi
1538
1539 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1540         OL_GDBM
1541
1542         if test $ol_cv_gdbm = yes ; then
1543                 ol_link_ldbm=gdbm
1544                 ol_with_ldbm_api=gdbm
1545
1546                 if test $ol_cv_lib_gdbm != yes ; then
1547                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1548                 fi
1549         fi
1550 fi
1551
1552 if test $ol_with_ldbm_api = auto ; then
1553         AC_MSG_WARN([skipping automatic checking for NDBM, must be manually enabled.])
1554 elif test $ol_with_ldbm_api = ndbm ; then
1555         OL_NDBM
1556
1557         if test $ol_cv_ndbm = yes ; then
1558                 ol_link_ldbm=ndbm
1559                 ol_with_ldbm_api=ndbm
1560
1561                 if test $ol_cv_lib_ndbm != yes ; then
1562                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1563                 fi
1564         fi
1565 fi
1566
1567 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1568         AC_MSG_WARN(could not find suitable LDBM backend)
1569         if test $ol_enable_ldbm = yes ; then
1570                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1571         fi
1572
1573         AC_MSG_WARN(disabling LDBM)
1574         ol_enable_ldbm=no
1575 fi
1576
1577 if test $ol_enable_wrappers != no ; then
1578         AC_CHECK_HEADERS(tcpd.h)
1579
1580         if test $ac_cv_header_tcpd_h != yes ; then
1581                 have_wrappers=no
1582         else
1583                 AC_CHECK_LIB(wrap, main,
1584                         [have_wrappers=yes], [have_wrappers=no])
1585         fi
1586
1587         if test $have_wrappers = yes ; then
1588                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1589                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
1590
1591                 dnl We add another check for -lnsl since some libwrap's
1592                 dnl need it, but it isn't always included from above
1593                 AC_CHECK_LIB(nsl, main)
1594         else
1595                 AC_MSG_WARN(could not find -lwrap)
1596                 if test $ol_enable_wrappers = yes ; then
1597                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1598                 fi
1599
1600                 AC_MSG_WARN(disabling wrappers support)
1601                 ol_enable_wrappers=no
1602         fi
1603 fi
1604
1605 if test $ol_enable_syslog != no ; then
1606         AC_CHECK_FUNC(openlog)
1607         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1608                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1609         fi
1610         ol_enable_syslog=$ac_cv_func_openlog
1611 fi
1612
1613 if test $ol_enable_dmalloc != no ; then
1614         AC_CHECK_HEADERS(dmalloc.h)
1615         AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1616 fi
1617
1618 if test $ol_enable_tcl != no ; then
1619         AC_CHECK_HEADERS(tcl.h)
1620
1621         if test $ac_cv_header_tcl_h != yes ; then
1622                 have_tcl=no
1623         else
1624                 AC_CHECK_LIB(tcl,main,
1625                         [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl"],
1626                         [have_tcl=no])
1627
1628                 if test $have_tcl != yes; then
1629                         AC_CHECK_LIB(tcl7.6,main,
1630                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl7.6"],
1631                                 [have_tcl=no])
1632                 fi
1633
1634                 if test $have_tcl != yes; then
1635                         AC_CHECK_LIB(tcl8.0,main,
1636                                 [have_tcl=yes; SLAPD_LIBS="$SLAPD_LIBS -ltcl8.0"],
1637                                 [have_tcl=no])
1638                 fi
1639         fi
1640
1641         if test $have_tcl != yes ; then
1642                 AC_MSG_WARN([could not find -ltcl])
1643                 if test $ol_enable_tcl = yes ; then
1644                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1645                 fi
1646
1647                 ol_enable_tcl=no
1648         fi
1649 fi
1650
1651 # ud needs termcap (should insert check here)
1652 ol_link_termcap=no
1653 AC_CHECK_HEADERS(termcap.h ncurses.h)
1654
1655 if test $ol_link_termcap = no ; then
1656         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1657         if test $have_termcap = yes ; then
1658                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1659                 ol_link_termcap=yes
1660                 TERMCAP_LIBS=-ltermcap
1661         fi
1662 fi
1663
1664 if test $ol_link_termcap = no ; then
1665         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1666         if test $have_ncurses = yes ; then
1667                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1668                 ol_link_termcap=yes
1669                 TERMCAP_LIBS=-lncurses
1670         fi
1671 fi
1672
1673 if test $ol_link_termcap = no ; then
1674         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1675         TERMCAP_LIBS=
1676 fi
1677
1678 dnl
1679 dnl Check for fetch URL support
1680 dnl             should be extended to support other fetch URL APIs
1681 dnl
1682 ol_link_sasl=no
1683 if test $ol_with_cyrus_sasl != no ; then
1684         AC_CHECK_HEADER(sasl.h)
1685
1686         if test $ac_cv_header_sasl_h = yes ; then
1687                 AC_CHECK_LIB(sasl, sasl_client_init,
1688                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1689
1690                 if test $have_cyrus_sasl != no ; then
1691                         SASL_LIBS="-lsasl"
1692                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1693                         ol_link_sasl=yes
1694                 fi
1695         fi
1696
1697         if test $ol_link_sasl = no -a $ol_with_cyrus_sasl = yes ; then
1698                 AC_MSG_ERROR(no suitable API for --with-cyrus-sasl=$ol_with_cyrus_sasl)
1699         fi
1700 fi
1701
1702 dnl
1703 dnl Check for fetch URL support
1704 dnl             should be extended to support other fetch URL APIs
1705 dnl
1706 ol_link_fetch=no
1707 if test $ol_with_fetch != no ; then
1708         OL_LIB_FETCH
1709
1710         if test $ol_cv_lib_fetch != no ; then
1711                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1712                 ol_link_fetch=freebsd
1713
1714         elif test $ol_with_fetch != auto ; then
1715                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1716         fi
1717 fi
1718
1719 dnl
1720 dnl Check for GNU readline
1721 dnl
1722 ol_link_readline=no
1723 if test $ol_with_readline != no ; then
1724         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1725
1726         if test $ac_cv_header_readline_readline_h = yes ; then
1727                 save_LIBS="$LIBS"
1728                 LIBS="$TERMCAP_LIBS $LIBS"
1729                 AC_CHECK_LIB(readline, readline,
1730                         [have_readline=yes], [have_readline=no])
1731                 LIBS="$save_LIBS"
1732
1733                 if test $have_readline = yes ; then
1734                         ol_with_readline=found
1735                         ol_link_readline=yes
1736
1737                         READLINE_LIBS="-lreadline"
1738                 fi
1739         fi
1740 fi
1741
1742 if test $ol_link_readline = yes ; then
1743         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1744 fi
1745
1746
1747 # FreeBSD (and others) have crypt(3) in -lcrypt
1748 if test $ol_enable_crypt != no ; then
1749         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1750                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1751                         have_crypt=yes], [have_crypt=no])])
1752
1753         if test $have_crypt = yes ; then
1754                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1755         else
1756                 AC_MSG_WARN(could not find crypt)
1757                 if test $ol_enable_crypt = yes ; then
1758                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1759                 fi
1760
1761                 AC_MSG_WARN(disabling crypt support)
1762                 ol_enable_crypt=no
1763         fi
1764 fi
1765
1766 # FreeBSD (and others) have setproctitle(3) in -lutil
1767 if test $ol_enable_proctitle != no ; then
1768         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1769                 AC_CHECK_LIB(util, setproctitle,
1770                         [have_setproctitle=yes
1771                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1772                         [have_setproctitle=no
1773                         LIBOBJS="$LIBOBJS setproctitle.o"])])
1774
1775         if test $have_setproctitle = yes ; then
1776                 AC_DEFINE(HAVE_SETPROCTITLE,1,
1777                         [define if setproctitle(3) is available])
1778         fi
1779 fi
1780
1781 dnl ----------------------------------------------------------------
1782 dnl Checks for typedefs, structures, and compiler characteristics.
1783 AC_TYPE_GETGROUPS dnl requires AC_TYPE_UID_T
1784 AC_TYPE_MODE_T
1785 AC_TYPE_OFF_T
1786 AC_TYPE_PID_T
1787 AM_TYPE_PTRDIFF_T
1788 AC_TYPE_SIGNAL
1789 OL_TYPE_SIG_ATOMIC_T
1790 AC_TYPE_SIZE_T
1791 OL_TYPE_SOCKLEN_T
1792 AC_STRUCT_ST_BLKSIZE
1793 AC_HEADER_TIME
1794 AC_STRUCT_TM
1795 OL_STRUCT_PASSWD_PW_GECOS
1796 OL_STRUCT_PASSWD_PW_PASSWD
1797
1798 OL_C_UPPER_LOWER
1799 AC_C_CONST
1800 OL_C_VOLATILE
1801
1802 if test $cross_compiling = yes ; then
1803         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
1804
1805         AC_DEFINE(LBER_INT_T,long)
1806         AC_DEFINE(LBER_TAG_T,long)
1807         AC_DEFINE(LBER_SOCKET_T,int)
1808
1809 else
1810         AC_C_BIGENDIAN
1811         AC_CHECK_SIZEOF(short)
1812         AC_CHECK_SIZEOF(int)
1813         AC_CHECK_SIZEOF(long)
1814
1815         if test "$ac_cv_sizeof_int" -lt 4 ; then
1816                 AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
1817
1818                 AC_DEFINE(LBER_INT_T,long)
1819                 AC_DEFINE(LBER_TAG_T,long)
1820                 AC_DEFINE(LBER_SOCKET_T,int)
1821         else
1822                 AC_DEFINE(LBER_INT_T,int)
1823                 AC_DEFINE(LBER_TAG_T,long)
1824                 AC_DEFINE(LBER_SOCKET_T,int)
1825         fi
1826 fi
1827
1828 AC_DEFINE(LBER_LEN_T,long)
1829
1830 dnl ----------------------------------------------------------------
1831 dnl Checks for library functions.
1832 AC_FUNC_MEMCMP
1833 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
1834 AC_FUNC_STRFTIME
1835 dnl AM_FUNC_STRTOD
1836
1837 OL_FUNC_INET_ATON
1838
1839 dnl we should use vfork instead of fork in a number of places...
1840 dnl AC_FUNC_VFORK
1841 AC_FUNC_VPRINTF
1842
1843 if test $ac_cv_func_vprintf = yes ; then
1844         dnl check for vsnprintf
1845         AC_CHECK_FUNCS(vsnprintf vsprintf)
1846 fi
1847
1848 AC_CHECK_FUNCS(         \
1849         bcopy                   \
1850         closesocket             \
1851         endgrent                \
1852         endpwent                \
1853         flock                   \
1854         getdtablesize   \
1855         getgrgid                \
1856         gethostname             \
1857         getpass                 \
1858         getpwuid                \
1859         getpwnam                \
1860         getspnam                \
1861         gettimeofday    \
1862         initgroups              \
1863         lockf                   \
1864         memcpy                  \
1865         memmove                 \
1866         mkstemp                 \
1867         read                    \
1868         recv                    \
1869         recvfrom                \
1870         setpwfile               \
1871         setgid                  \
1872         setegid                 \
1873         setsid                  \
1874         setuid                  \
1875         seteuid                 \
1876         signal                  \
1877         sigset                  \
1878         snprintf                \
1879         strdup                  \
1880         strerror                \
1881         strpbrk                 \
1882         strrchr                 \
1883         strsep                  \
1884         strstr                  \
1885         strtol                  \
1886         strtoul                 \
1887         strspn                  \
1888         sysconf                 \
1889         waitpid                 \
1890         wait4                   \
1891         write                   \
1892         send                    \
1893         sendto                  \
1894 )
1895
1896 dnl We actually may need to replace more than this.
1897 AC_REPLACE_FUNCS(getopt tempnam)
1898
1899 dnl ----------------------------------------------------------------
1900 # Check Configuration
1901 OL_SYS_ERRLIST
1902
1903 dnl ----------------------------------------------------------------
1904 dnl Sort out defines
1905
1906 if test "$ol_enable_debug" != no ; then
1907         AC_DEFINE(LDAP_DEBUG,1,
1908                 [define this to add debugging code])
1909 fi
1910 if test "$ol_enable_syslog" = yes ; then
1911         AC_DEFINE(LDAP_SYSLOG,1,
1912                 [define this to add syslog code])
1913 fi
1914 if test "$ol_enable_libui" = yes ; then
1915         AC_DEFINE(LDAP_LIBUI,1,
1916                 [define this for LDAP User Interface support])
1917 fi
1918 if test "$ol_enable_cache" = no ; then
1919         AC_DEFINE(LDAP_NOCACHE,1,
1920                 [define this to remove -lldap cache support])
1921 fi
1922 if test "$ol_enable_dns" != no ; then
1923         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_DNS,LDAP_VENDOR_VERSION)
1924 fi
1925 if test "$ol_enable_proctitle" != no ; then
1926         AC_DEFINE(LDAP_PROCTITLE,1,
1927                 [define this for LDAP process title support])
1928 fi
1929 if test "$ol_enable_referrals" != no ; then
1930         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
1931 fi
1932 if test "$ol_enable_cldap" != no ; then
1933         AC_DEFINE(LDAP_CONNECTIONLESS,1,[define to support CLDAP])
1934 fi
1935
1936 if test "$ol_enable_crypt" != no ; then
1937         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
1938 fi
1939 if test "$ol_enable_cleartext" != no ; then
1940         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
1941 fi
1942 if test "$ol_enable_multimaster" != no ; then
1943         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
1944 fi
1945 if test "$ol_enable_phonetic" != no ; then
1946         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
1947 fi
1948 if test "$ol_enable_rlookups" != no ; then
1949         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
1950 fi
1951
1952 if test "$ol_link_modules" != no ; then
1953         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
1954         BUILD_SLAPD=yes
1955         MODULES_LIBS=-lltdl
1956         SLAPD_MODULES_LDFLAGS="-dlopen self"
1957 fi
1958
1959 if test "$ol_link_bdb2" != no ; then
1960         AC_DEFINE(SLAPD_BDB2,1,[define to support BDB2 backend])
1961         BUILD_SLAPD=yes
1962         BUILD_BDB2=yes
1963         if test "$ol_with_bdb2_module" != static ; then
1964                 AC_DEFINE(SLAPD_BDB2_DYNAMIC,1,
1965                         [define to support dynamic BDB2 backend])
1966                 BUILD_BDB2=mod
1967                 BUILD_BDB2_DYNAMIC=shared
1968                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-bdb2/back_bdb2.la"
1969         fi
1970 fi
1971
1972 if test "$ol_enable_ldap" != no ; then
1973         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
1974         BUILD_SLAPD=yes
1975         BUILD_LDAP=yes
1976         if test "$ol_with_ldap_module" != static ; then
1977                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
1978                         [define to support dynamic LDAP backend])
1979                 BUILD_LDAP=mod
1980                 BUILD_LDAP_DYNAMIC=shared
1981                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
1982         fi
1983 fi
1984
1985 if test "$ol_link_ldbm" != no ; then
1986         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
1987         BUILD_SLAPD=yes
1988         BUILD_LDBM=yes
1989         if test "$ol_with_ldbm_module" != static ; then
1990                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
1991                         [define to support dynamic LDBM backend])
1992                 BUILD_LDBM=mod
1993                 BUILD_LDBM_DYNAMIC=shared
1994                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
1995         fi
1996 fi
1997
1998 if test "$ol_enable_passwd" != no ; then
1999         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2000         BUILD_SLAPD=yes
2001         BUILD_PASSWD=yes
2002         if test "$ol_with_passwd_module" != static ; then
2003                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2004                         [define to support dynamic PASSWD backend])
2005                 BUILD_PASSWD=mod
2006                 BUILD_PASSWD_DYNAMIC=shared
2007                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2008         fi
2009 fi
2010
2011 if test "$ol_link_perl" != no ; then
2012         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2013         BUILD_SLAPD=yes
2014         BUILD_PERL=yes
2015         if test "$ol_with_perl_module" != static ; then
2016                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2017                         [define to support dynamic PERL backend])
2018                 BUILD_PERL=mod
2019                 BUILD_PERL_DYNAMIC=shared
2020                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2021         fi
2022 fi
2023
2024 if test "$ol_enable_shell" != no ; then
2025         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2026         BUILD_SLAPD=yes
2027         BUILD_SHELL=yes
2028         if test "$ol_with_shell_module" != static ; then
2029                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2030                         [define to support dynamic SHELL backend])
2031                 BUILD_SHELL=mod
2032                 BUILD_SHELL_DYNAMIC=shared
2033                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2034         fi
2035 fi
2036
2037 if test "$ol_enable_tcl" != no ; then
2038         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2039         BUILD_SLAPD=yes
2040         BUILD_TCL=yes
2041         if test "$ol_with_tcl_module" != static; then
2042                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2043                         [define to support dynamic TCL backend])
2044                 BUILD_TCL=mod
2045                 BUILD_TCL_DYNAMIC=shared
2046                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2047         fi
2048 fi
2049
2050 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2051         $BUILD_SLAPD = yes ; then
2052         BUILD_SLURPD=yes
2053 fi
2054
2055 if test "$ol_link_isode" != no ; then
2056         BUILD_LDAPD=yes
2057 fi
2058
2059 dnl ----------------------------------------------------------------
2060
2061 AC_SUBST(BUILD_LDAPD)
2062 AC_SUBST(BUILD_SLAPD)
2063   AC_SUBST(BUILD_BDB2)
2064   AC_SUBST(BUILD_LDAP)
2065   AC_SUBST(BUILD_LDBM)
2066   AC_SUBST(BUILD_PASSWD)
2067   AC_SUBST(BUILD_PERL)
2068   AC_SUBST(BUILD_QUIPU)
2069   AC_SUBST(BUILD_SHELL)
2070   AC_SUBST(BUILD_TCL)
2071   AC_SUBST(BUILD_BDB2_DYNAMIC)
2072   AC_SUBST(BUILD_LDAP_DYNAMIC)
2073   AC_SUBST(BUILD_LDBM_DYNAMIC)
2074   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2075   AC_SUBST(BUILD_PERL_DYNAMIC)
2076   AC_SUBST(BUILD_SHELL_DYNAMIC)
2077   AC_SUBST(BUILD_TCL_DYNAMIC)
2078 AC_SUBST(BUILD_SLURPD)
2079
2080 AC_SUBST(LDAP_LIBS)
2081 AC_SUBST(LDAPD_LIBS)
2082 AC_SUBST(LDIF_LIBS)
2083 AC_SUBST(SLAPD_LIBS)
2084 AC_SUBST(SLURPD_LIBS)
2085 AC_SUBST(LDBM_LIBS)
2086 AC_SUBST(LTHREAD_LIBS)
2087 AC_SUBST(LUTIL_LIBS)
2088
2089 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2090 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2091 AC_SUBST(SLAPD_MODULES_LIST)
2092
2093 AC_SUBST(SLAPD_PERL_CPPFLAGS)
2094 AC_SUBST(SLAPD_PERL_LDFLAGS)
2095
2096 AC_SUBST(KRB_LIBS)
2097 AC_SUBST(READLINE_LIBS)
2098 AC_SUBST(SASL_LIBS)
2099 AC_SUBST(TERMCAP_LIBS)
2100 AC_SUBST(TLS_LIBS)
2101 AC_SUBST(MODULES_LIBS)
2102
2103 dnl ----------------------------------------------------------------
2104 dnl final output
2105 dnl
2106
2107 AC_OUTPUT( \
2108 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2109 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2110 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2111 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2112 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2113 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2114 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2115 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2116 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2117 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2118 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2119 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2120 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2121 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2122 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2123 include/Makefile:build/top.mk:include/Makefile.in \
2124 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2125 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2126 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2127 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2128 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2129 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2130 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2131 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2132 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2133 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
2134 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2135 servers/slapd/back-bdb2/Makefile:build/top.mk:servers/slapd/back-bdb2/Makefile.in:build/mod.mk \
2136 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2137 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2138 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2139 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2140 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2141 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2142 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2143 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2144 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2145 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2146 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2147 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2148 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2149 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2150 ,[
2151 date > stamp-h
2152 echo Please \"make depend\" to build dependencies
2153 ])