git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl
   3 dnl Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
   4 dnl
   5 dnl Redistribution and use in source and binary forms are permitted only
   6 dnl as authorized by the OpenLDAP Public License.  A copy of this
   7 dnl license is available at http://www.OpenLDAP.org/license.html or
   8 dnl in file LICENSE in the top-level directory of the distribution.
   9 dnl
  10 dnl ----------------------------------------------------------------
  11 dnl Redefine AC_INIT_BINSH to provide RCS IDs and copyright notice
  12 dnl at top of generated configure script.  Prints simple copyright.
  13 define([AC_INIT_BINSH],
  14 [[#! /bin/sh
  15 # $]OpenLDAP[$
  16 # from] translit([$OpenLDAP$], $")] [
  17
  18 # Copyright 1998-2000 The OpenLDAP Foundation.  All Rights Reserved.
  19 #
  20 # Redistribution and use in source and binary forms are permitted only
  21 # as authorized by the OpenLDAP Public License.  A copy of this
  22 # license is available at http://www.OpenLDAP.org/license.html or
  23 # in file LICENSE in the top-level directory of the distribution.
  24
  25 echo "Copyright 1998-2000 The OpenLDAP Foundation,  All Rights Reserved."
  26 echo "Restrictions apply, see COPYRIGHT and LICENSE files."
  27 ])dnl
  28 dnl ----------------------------------------------------------------
  29 dnl Disable config.cache!
  30 define([AC_CACHE_LOAD], )dnl
  31 define([AC_CACHE_SAVE], )dnl
  32 dnl ================================================================
  33 dnl Configure.in for OpenLDAP
  34 AC_INIT(build/version)dnl
  35
  36 # set unset (borrowed from autoconf 2.14a)
  37 if (unset FOO) >/dev/null 2>&1; then
  38   ol_unset=unset
  39 else
  40   ol_unset=false
  41 fi
  42 # unset CDPATH
  43 $ol_unset CDPATH || test "${CDPATH+set}" != set || CDPATH=: && export CDPATH
  44
  45 AC_CONFIG_AUX_DIR(build)dnl
  46
  47 OL_VERSION=`cat $ac_aux_dir/version`
  48 if test -z "$OL_VERSION"; then
  49         AC_MSG_ERROR([could not determine version])
  50 fi
  51
  52 echo "Configuring OpenLDAP $OL_VERSION ..."
  53
  54 dnl Determine host platform
  55 dnl             we try not to use this for much
  56 AC_CANONICAL_SYSTEM
  57
  58 AM_INIT_AUTOMAKE(OpenLDAP,[$OL_VERSION], [no defines])dnl
  59 AC_SUBST(PACKAGE)
  60 AC_SUBST(VERSION)
  61 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  62 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  63
  64 dnl We use autoconf features new to 2.13.
  65 dnl aclocal.m4 should be built using aclocal from automake 1.4
  66 dnl libtool 1.3.3 should be installed.
  67 AC_PREREQ(2.13)dnl Required Autoconf version
  68
  69 AC_CONFIG_HEADER(include/portable.h include/ldap_features.h include/lber_types.h)dnl
  70
  71 dnl ================================================================
  72 dnl Start Args
  73 AC_MSG_CHECKING(configure arguments)
  74 AC_PREFIX_DEFAULT(/usr/local)
  75
  76 top_builddir=`pwd`
  77 AC_SUBST(top_builddir)dnl
  78
  79 dnl ----------------------------------------------------------------
  80 dnl --with-subdir
  81 ldap_subdir="/openldap"
  82
  83 AC_ARG_WITH(subdir,
  84 [  --with-subdir=DIR change default subdirectory used for installs],
  85 [case "$withval" in
  86         no) ldap_subdir=""
  87                 ;;
  88         yes)
  89                 ;;
  90         /*|\\*)
  91                 ldap_subdir="$withval"
  92                 ;;
  93         *)
  94                 ldap_subdir="/$withval"
  95                 ;;
  96 esac
  97 ])dnl
  98
  99 AC_SUBST(ldap_subdir)dnl
 100
 101 dnl ----------------------------------------------------------------
 102 dnl General "enable" options
 103 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes)dnl
 104 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 105 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 106 OL_ARG_ENABLE(cache,[  --enable-cache     enable caching], yes)dnl
 107 OL_ARG_ENABLE(referrals,[  --enable-referrals     enable V2 Referrals extension], yes)dnl
 108 OL_ARG_ENABLE(kbind,[  --enable-kbind     enable V2 Kerberos IV bind], no)dnl
 109 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 110 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 111 OL_ARG_ENABLE(x_compile,[  --enable-x-compile     enable cross compiling],
 112         no, [yes no])dnl
 113
 114 dnl ----------------------------------------------------------------
 115 dnl General "with" options
 116 dnl OL_ARG_ENABLE(dmalloc,[  --enable-dmalloc     enable debug malloc support], no)dnl
 117
 118 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 119         auto, [auto yes no] )
 120 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch URL support],
 121         auto, [auto yes no] )
 122 OL_ARG_WITH(kerberos,[  --with-kerberos   with support],
 123         auto, [auto k5 k5only k425 kth k4 afs yes no])
 124 OL_ARG_WITH(readline,[  --with-readline   with readline support],
 125         auto, [auto yes no] )
 126 OL_ARG_WITH(threads,[  --with-threads     with threads],
 127         auto, [auto nt posix mach pth lwp yes no manual] )
 128 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support],
 129         auto, [auto ssleay openssl yes no] )
 130 OL_ARG_WITH(yielding_select,[  --with-yielding-select  with implicitly yielding select],
 131         auto, [auto yes no manual] )
 132
 133 dnl ----------------------------------------------------------------
 134 dnl Server options
 135 dnl ----------------------------------------------------------------
 136
 137 dnl ----------------------------------------------------------------
 138 dnl SLAPD OPTIONS
 139 AC_ARG_WITH(xxslapdoptions,[SLAPD (Standalone LDAP Daemon) Options:])
 140 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 141 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 142 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], auto)dnl
 143 OL_ARG_ENABLE(kpasswd,[    --enable-kpasswd       enable kerberos password verification], no)dnl
 144 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 145 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 146 OL_ARG_ENABLE(multimaster,[    --enable-multimaster  enable multimaster replication], no)dnl
 147 OL_ARG_ENABLE(phonetic,[    --enable-phonetic     enable phonetic/soundex], no)dnl
 148 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups], auto)dnl
 149 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs], no)dnl
 150 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 151 OL_ARG_ENABLE(dynamic,[    --enable-dynamic       enable linking built binaries with dynamic libs], no)dnl
 152
 153 dnl SLAPD Backend options
 154 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend], no)dnl
 155 OL_ARG_WITH(dnssrv_module,[    --with-dnssrv-module  module type], static,
 156         [static dynamic])
 157 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend], no)dnl
 158 OL_ARG_WITH(ldap_module,[    --with-ldap-module   module type], static,
 159         [static dynamic])
 160 OL_ARG_ENABLE(ldbm,[    --enable-ldbm     enable ldbm backend], yes)dnl
 161 OL_ARG_WITH(ldbm_api,[    --with-ldbm-api       with LDBM API], auto,
 162         [auto berkeley bcompat mdbm gdbm])
 163 OL_ARG_WITH(ldbm_module,[    --with-ldbm-module   module type], static,
 164         [static dynamic])
 165 OL_ARG_WITH(ldbm_type,[    --with-ldbm-type       use LDBM type], auto,
 166         [auto btree hash])
 167 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend], no)dnl
 168 OL_ARG_WITH(passwd_module,[    --with-passwd-module  module type], static,
 169         [static dynamic])
 170 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend], no)dnl
 171 OL_ARG_WITH(perl_module,[    --with-perl-module   module type], static,
 172         [static dynamic])
 173 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend], no)dnl
 174 OL_ARG_WITH(shell_module,[    --with-shell-module         module type], static,
 175         [static dynamic])
 176 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend], no)dnl
 177 OL_ARG_WITH(sql_module,[    --with-sql-module     module type], static,
 178         [static dynamic])
 179 OL_ARG_ENABLE(tcl,[    --enable-tcl       enable tcl backend], no)dnl
 180 OL_ARG_WITH(tcl_module,[    --with-tcl-module     module type], static,
 181         [static dynamic])
 182
 183 dnl ----------------------------------------------------------------
 184 dnl SLURPD OPTIONS
 185 AC_ARG_WITH(xxslurpdoptions,[SLURPD (Replication Daemon) Options:])
 186 OL_ARG_ENABLE(slurpd,[  --enable-slurpd   enable building slurpd], auto)dnl
 187
 188 dnl ----------------------------------------------------------------
 189 AC_ARG_WITH(xxliboptions,[Library Generation & Linking Options])
 190 AC_ENABLE_STATIC
 191 dnl AC_DISABLE_SHARED
 192 AC_ENABLE_SHARED
 193
 194 dnl ----------------------------------------------------------------
 195
 196 dnl General "enable" options
 197 # validate options
 198 if test $ol_enable_slapd = no ; then
 199         dnl SLAPD was specificallly disabled
 200         if test $ol_enable_dnssrv = yes ; then
 201                 AC_MSG_WARN([slapd disabled, ignoring --enable-dnssrv argument])
 202         fi
 203         if test $ol_enable_ldap = yes ; then
 204                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldap argument])
 205         fi
 206         if test $ol_enable_ldbm = yes ; then
 207                 AC_MSG_WARN([slapd disabled, ignoring --enable-ldbm argument])
 208         fi
 209         if test $ol_enable_passwd = yes ; then
 210                 AC_MSG_WARN([slapd disabled, ignoring --enable-passwd argument])
 211         fi
 212         if test $ol_enable_perl = yes ; then
 213                 AC_MSG_WARN([slapd disabled, ignoring --enable-perl argument])
 214         fi
 215         if test $ol_enable_shell = yes ; then
 216                 AC_MSG_WARN([slapd disabled, ignoring --enable-shell argument])
 217         fi
 218         if test $ol_enable_tcl = yes ; then
 219                 AC_MSG_WARN([slapd disabled, ignoring --enable-tcl argument])
 220         fi
 221         if test $ol_enable_sql = yes ; then
 222                 AC_MSG_WARN([slapd disabled, ignoring --enable-sql argument])
 223         fi
 224         if test $ol_enable_modules = yes ; then
 225                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 226         fi
 227         if test $ol_enable_multimaster = yes ; then
 228                 AC_MSG_WARN([slapd disabled, ignoring --enable-multimaster argument])
 229         fi
 230         if test $ol_enable_wrappers = yes ; then
 231                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 232         fi
 233         if test $ol_enable_phonetic = yes ; then
 234                 AC_MSG_WARN([slapd disabled, ignoring --enable-phonetic argument])
 235         fi
 236         if test $ol_enable_rlookups = yes ; then
 237                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 238         fi
 239         if test $ol_enable_aci = yes ; then
 240                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 241         fi
 242         if test $ol_with_ldbm_api != auto ; then
 243                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-api argument])
 244         fi
 245         if test $ol_with_ldbm_type != auto ; then
 246                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-type argument])
 247         fi
 248         if test $ol_with_dnssrv_module != static ; then
 249                 AC_MSG_WARN([slapd disabled, ignoring --with-dnssrv-module argument])
 250         fi
 251         if test $ol_with_ldap_module != static ; then
 252                 AC_MSG_WARN([slapd disabled, ignoring --with-ldap-module argument])
 253         fi
 254         if test $ol_with_ldbm_module != static ; then
 255                 AC_MSG_WARN([slapd disabled, ignoring --with-ldbm-module argument])
 256         fi
 257         if test $ol_with_passwd_module != static ; then
 258                 AC_MSG_WARN([slapd disabled, ignoring --with-passwd-module argument])
 259         fi
 260         if test $ol_with_perl_module != static ; then
 261                 AC_MSG_WARN([slapd disabled, ignoring --with-perl-module argument])
 262         fi
 263         if test $ol_with_shell_module != static ; then
 264                 AC_MSG_WARN([slapd disabled, ignoring --with-shell-module argument])
 265         fi
 266         if test $ol_with_tcl_module != static ; then
 267                 AC_MSG_WARN([slapd disabled, ignoring --with-tcl-module argument])
 268         fi
 269         if test $ol_with_sql_module != static ; then
 270                 AC_MSG_WARN([slapd disabled, ignoring --with-sql-module argument])
 271         fi
 272         if test $ol_enable_slurpd = yes ; then
 273                 AC_MSG_ERROR([slurpd requires slapd])
 274         fi
 275
 276         # force settings to no
 277         ol_enable_dnssrv=no
 278         ol_enable_ldap=no
 279         ol_enable_ldbm=no
 280         ol_enable_passwd=no
 281         ol_enable_perl=no
 282         ol_enable_shell=no
 283         ol_enable_tcl=no
 284         ol_enable_sql=no
 285
 286         ol_enable_modules=no
 287         ol_enable_multimaster=no
 288         ol_enable_phonetic=no
 289         ol_enable_rlookups=no
 290         ol_enable_aci=no
 291         ol_enable_wrappers=no
 292         ol_enable_dynamic=no
 293
 294         ol_with_ldbm_api=no
 295         ol_with_ldbm_type=no
 296
 297         ol_with_dnssrv_module=static
 298         ol_with_ldap_module=static
 299         ol_with_ldbm_module=static
 300         ol_with_passwd_module=static
 301         ol_with_perl_module=static
 302         ol_with_shell_module=static
 303         ol_with_tcl_module=static
 304         ol_with_sql_module=static
 305
 306         ol_enable_slurpd=no
 307
 308 elif test $ol_enable_ldbm = no ; then
 309         dnl SLAPD without LDBM
 310
 311         if test $ol_with_ldbm_api != auto ; then
 312                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-api argument])
 313         fi
 314
 315         if test $ol_with_ldbm_type != auto ; then
 316                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-type argument])
 317         fi
 318
 319         if test $ol_with_ldbm_module != static ; then
 320                 AC_MSG_WARN([LDBM disabled, ignoring --with-ldbm-module argument])
 321         fi
 322
 323         if test $ol_enable_modules != yes -a \
 324                 $ol_enable_dnssrv = no -a \
 325                 $ol_enable_ldap = no -a \
 326                 $ol_enable_passwd = no -a \
 327                 $ol_enable_perl = no -a \
 328                 $ol_enable_shell = no -a \
 329                 $ol_enable_sql = no -a \
 330                 $ol_enable_tcl = no ; then
 331                 AC_MSG_ERROR([slapd requires a backend])
 332         fi
 333
 334         ol_with_ldbm_api=no
 335         ol_with_ldbm_type=no
 336         ol_with_ldbm_module=static
 337
 338 else
 339         dnl SLAPD with LDBM
 340         if test $ol_with_ldbm_api = gdbm -a \
 341                 $ol_with_ldbm_type = btree ; then
 342                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 343         fi
 344         if test $ol_with_ldbm_api = mdbm -a \
 345                 $ol_with_ldbm_type = btree ; then
 346                 AC_MSG_ERROR([MDBM only supports LDBM type hash])
 347         fi
 348         if test $ol_with_ldbm_api = ndbm -a \
 349                 $ol_with_ldbm_type = btree ; then
 350                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 351         fi
 352 fi
 353
 354 if test $ol_enable_slurpd = yes ; then
 355         dnl SLURPD was specifically enabled
 356         if test $ol_with_threads = no ; then
 357                 AC_MSG_ERROR([slurpd requires threads])
 358         fi
 359 fi
 360
 361 if test $ol_enable_kbind = yes -o $ol_enable_kpasswd = yes ; then
 362         if test $ol_with_kerberos = no ; then
 363                 AC_MSG_ERROR([options require --with-kerberos])
 364         fi
 365         ol_with_kerberos=yes
 366 elif test $ol_enable_kbind = no -o $ol_enable_kpasswd = no ; then
 367         if test $ol_with_kerberos != no -a $ol_with_kerberos != auto ; then
 368                 AC_MSG_WARN([Kerberos detection enabled unnecessarily]);
 369         fi
 370         ol_with_kerberos=no
 371 fi
 372
 373 if test $ol_enable_spasswd = yes ; then
 374         if test $ol_with_cyrus_sasl = no ; then
 375                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 376         fi
 377         ol_link_spasswd=yes
 378 fi
 379
 380 AC_MSG_RESULT(done)
 381
 382 dnl ----------------------------------------------------------------
 383 dnl Initialize vars
 384 LDAP_LIBS=
 385 LDIF_LIBS=
 386 LDBM_LIBS=
 387 LTHREAD_LIBS=
 388 LUTIL_LIBS=
 389
 390 SLAPD_LIBS=
 391 SLURPD_LIBS=
 392
 393 BUILD_SLAPD=no
 394 BUILD_SLURPD=no
 395
 396 BUILD_THREAD=no
 397
 398 BUILD_DNSSRV=no
 399 BUILD_LDAP=no
 400 BUILD_LDBM=no
 401 BUILD_PASSWD=no
 402 BUILD_PERL=no
 403 BUILD_SHELL=no
 404 BUILD_SQL=no
 405 BUILD_TCL=no
 406
 407 BUILD_DNSSRV_DYNAMIC=static
 408 BUILD_LDAP_DYNAMIC=static
 409 BUILD_LDBM_DYNAMIC=static
 410 BUILD_PASSWD_DYNAMIC=static
 411 BUILD_PERL_DYNAMIC=static
 412 BUILD_SHELL_DYNAMIC=static
 413 BUILD_TCL_DYNAMIC=static
 414 BUILD_SQL_DYNAMIC=static
 415
 416 SLAPD_MODULES_LDFLAGS=
 417 SLAPD_MODULES_CPPFLAGS=
 418 SLAPD_MODULES_LIST=
 419
 420 SLAPD_PERL_LDFLAGS=
 421 MOD_PERL_LDFLAGS=
 422 PERL_CPPFLAGS=
 423
 424 SLAPD_SQL_LDFLAGS=
 425 SLAPD_SQL_LIBS=
 426 SLAPD_SQL_INCLUDES=
 427
 428 MOD_TCL_LIB=
 429 KRB4_LIBS=
 430 KRB5_LIBS=
 431 READLINE_LIBS=
 432 SASL_LIBS=
 433 TERMCAP_LIBS=
 434 TLS_LIBS=
 435 MODULES_LIBS=
 436 AUTH_LIBS=
 437
 438 dnl ================================================================
 439 dnl Checks for programs
 440
 441 dnl AC_PROG_INSTALL
 442
 443 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 444
 445 dnl ----------------------------------------------------------------
 446 dnl
 447 dnl Determine which C translator to use
 448 dnl
 449
 450 dnl AIX Thread requires we use cc_r or xlc_r.
 451 dnl But only do this IF AIX and CC is not set
 452 dnl and threads are auto|yes|posix.
 453 dnl
 454 dnl If we find cc_r|xlc_r, force pthreads and assume
 455 dnl             pthread_create is in $LIBS (ie: don't bring in
 456 dnl             any additional thread libraries)
 457 dnl If we do not find cc_r|xlc_r, disable threads
 458
 459 ol_aix_threads=no
 460 case "$target" in
 461 *-*-aix*) dnl all AIX is not a good idea.
 462         if test -z "$CC" ; then
 463                 case "$ol_with_threads" in
 464                 auto | yes |  posix) ol_aix_threads=yes ;;
 465                 esac
 466         fi
 467 ;;
 468 esac
 469
 470 if test $ol_aix_threads = yes ; then
 471         if test -z "${CC}" ; then
 472                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 473
 474                 if test "$CC" = cc ; then
 475                         dnl no CC! don't allow --with-threads
 476                         if test $ol_with_threads != auto ; then
 477                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 478                         else
 479                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 480                         fi
 481                         ol_with_threads=no
 482                 fi
 483         fi
 484
 485         if test "${CC}" = "cc_r" -o "${CC}" = "xlc_r" ; then
 486                 ol_with_threads=posix
 487                 ol_cv_pthread_create=yes
 488         fi
 489 fi
 490
 491 if test -z "${CC}"; then
 492         AC_CHECK_PROGS(CC,cc)
 493 fi
 494
 495 dnl The default CFLAGS is empty NOT whatever AC_PROG_CC sets.
 496 dnl (for now, let autoconf sort this out)
 497 dnl CFLAGS=${CFLAGS-""}
 498
 499 AC_LIBTOOL_WIN32_DLL
 500 AC_LIBTOOL_DLOPEN
 501 AC_PROG_LIBTOOL
 502
 503 AC_PROG_AWK
 504 OL_PROG_LN_H
 505 AC_PROG_LN_S
 506
 507 if test "$LN_H" = "cp" -a "$LN_S" = "ln"; then
 508         LN_S="$LN_H"
 509 fi
 510
 511 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 512         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 513 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 514 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 515
 516 dnl ----------------------------------------------------------------
 517 dnl Perl
 518 ol_link_perl=no
 519 if test $ol_enable_perl != no ; then
 520         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 521
 522         if test "no$PERLBIN" = "no" ; then
 523                 if test $ol_enable_perl = yes ; then
 524                         AC_MSG_ERROR([could not locate perl])
 525                 fi
 526
 527         else
 528                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 529                 if test x"$ol_with_perl_module" = "xstatic" ; then
 530                         SLAPD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 531                 else
 532                         MOD_PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e s/-lc//`"
 533                 fi
 534                 dnl should check perl version
 535                 ol_link_perl=yes
 536         fi
 537 fi
 538
 539 AC_PROG_CPP
 540
 541 dnl ----------------------------------------------------------------
 542 dnl Cross compiling checks
 543 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 544         AC_MSG_WARN([cross compiling....  some functionality will be removed.])
 545
 546 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 547         AC_MSG_WARN([programs compiled here do run here...])
 548         AC_MSG_ERROR([  if not cross compiling, use --disable-x-compile.])
 549
 550 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 551         AC_MSG_WARN([programs compiled here do not run here...])
 552         AC_MSG_ERROR([  if cross compiling,  add --enable-x-compile.])
 553 fi
 554
 555 dnl ----------------------------------------------------------------
 556 dnl Checks for UNIX Variants
 557 AC_AIX
 558 AC_ISC_POSIX
 559 AC_MINIX
 560
 561 dnl ----------------------------------------------------------------
 562 dnl Checks for system services
 563 AC_CYGWIN
 564 AC_MINGW32
 565 AC_EXEEXT
 566 AC_OBJEXT
 567
 568 AC_DEFINE_UNQUOTED( EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 569
 570 dnl ----------------------------------------------------------------
 571 dnl BeOS requires -lbe -lroot -lnet
 572 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 573
 574 dnl ----------------------------------------------------------------
 575 dnl OpenLDAP requires STDC features
 576 AM_PROG_CC_STDC
 577 if test "X${am_cv_prog_cc_stdc}" = "Xno" ; then
 578         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 579 fi
 580
 581 dnl ----------------------------------------------------------------
 582 dnl Check cc depend flags
 583 OL_MKDEPEND
 584 if test "${ol_cv_mkdep}" = no ; then
 585         # this will soon become an error
 586         AC_MSG_WARN([do not know how to generate dependencies])
 587 fi
 588
 589 dnl ----------------------------------------------------------------
 590 dnl Check for AIX security library
 591 AC_CHECK_LIB(s, afopen, [
 592         AUTH_LIBS=-ls
 593         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 594 ])
 595
 596
 597 dnl ----------------------------------------------------------------
 598 dnl PF_INET6 support requires getaddrinfo
 599 dnl PF_LOCAL may use getaddrinfo in available
 600 AC_CHECK_FUNCS( getaddrinfo )
 601
 602 if test $ac_cv_func_getaddrinfo = no ; then
 603         if test $ol_enable_ipv6 = yes ; then
 604                 AC_MSG_ERROR([IPv6 support requires getaddrinfo()])
 605         fi
 606         ol_enable_ipv6=no
 607 fi
 608
 609 if test $ol_enable_local != no ; then
 610         AC_CHECK_HEADERS( sys/un.h )
 611
 612         if test $ol_enable_local = auto ; then
 613                 ol_enable_local=$ac_cv_header_sys_un_h
 614         elif test $ac_cv_header_sys_un_h = no ; then
 615                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
 616         fi
 617 fi
 618
 619 dnl ----------------------------------------------------------------
 620 dnl Check for module support
 621 ol_link_modules=no
 622 if test $ol_enable_modules != no ; then
 623         AC_CHECK_HEADERS(ltdl.h)
 624
 625         if test $ac_cv_header_ltdl_h = no ; then
 626                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 627         fi
 628
 629         AC_CHECK_LIB(ltdl, lt_dlinit, [
 630             MODULES_LIBS=-lltdl
 631             AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 632         ])
 633
 634         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 635                 AC_MSG_ERROR([could not locate libtool -lltdl])
 636         fi
 637         ol_link_modules=yes
 638 else
 639         ol_with_dnssrv_module=static
 640         ol_with_ldap_module=static
 641         ol_with_ldbm_module=static
 642         ol_with_passwd_module=static
 643         ol_with_perl_module=static
 644         ol_with_shell_module=static
 645         ol_with_tcl_module=static
 646         ol_with_sql_module=static
 647 fi
 648
 649 dnl ----------------------------------------------------------------
 650 dnl Checks for header files.
 651 OL_HEADER_STDC
 652
 653 if test $ol_cv_header_stdc != yes; then
 654         AC_MSG_WARN([could not locate Standard C compliant headers])
 655 fi
 656
 657 AC_HEADER_DIRENT
 658 AC_HEADER_SYS_WAIT
 659 AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 660 if test $am_cv_sys_posix_termios = yes ; then
 661         AC_DEFINE(HAVE_POSIX_TERMIOS,1,
 662                 [define if you have POSIX termios])
 663 fi
 664
 665 AC_CHECK_HEADERS(       \
 666         arpa/inet.h             \
 667         arpa/nameser.h  \
 668         assert.h                \
 669         conio.h                 \
 670         crypt.h                 \
 671         direct.h                \
 672         errno.h                 \
 673         fcntl.h                 \
 674         filio.h                 \
 675         getopt.h                \
 676         grp.h                   \
 677         io.h                    \
 678         libutil.h               \
 679         limits.h                \
 680         locale.h                \
 681         netinet/tcp.h   \
 682         malloc.h                \
 683         memory.h                \
 684         psap.h                  \
 685         pwd.h                   \
 686         process.h               \
 687         resolv.h                \
 688         sgtty.h                 \
 689         shadow.h                \
 690         stddef.h                \
 691         string.h                \
 692         strings.h               \
 693         sysexits.h              \
 694         sys/file.h              \
 695         sys/filio.h             \
 696         sys/errno.h             \
 697         sys/ioctl.h             \
 698         sys/param.h             \
 699         sys/resource.h  \
 700         sys/select.h    \
 701         sys/socket.h    \
 702         sys/syslog.h    \
 703         sys/time.h              \
 704         sys/types.h             \
 705         syslog.h                \
 706         termios.h               \
 707         unistd.h                \
 708         winsock.h               \
 709 )
 710
 711
 712 dnl ----------------------------------------------------------------
 713 dnl Checks for libraries
 714
 715 dnl HP-UX requires -lV3
 716 AC_CHECK_LIB(V3, sigset)
 717
 718 dnl Gotta check for winsock manually
 719 if test $ac_cv_header_winsock_h = yes; then
 720         AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 721         AC_TRY_LINK([#include <winsock.h>],[
 722                         socket(0,0,0);
 723                         select(0,NULL,NULL,NULL,NULL);
 724                         closesocket(0);
 725                         gethostname(NULL,0);
 726         ],[ol_cv_winsock=yes],[ol_cv_winsock=no])])
 727
 728         if test $ol_cv_winsock = yes ; then
 729                 AC_DEFINE(HAVE_WINSOCK,1,[define if you have winsock])
 730                 ac_cv_func_socket=yes
 731                 ac_cv_func_select=yes
 732                 ac_cv_func_closesocket=yes
 733                 ac_cv_func_gethostname=yes
 734         fi
 735 fi
 736
 737 dnl Find socket()
 738 dnl Likely combinations:
 739 dnl             -lsocket [ -lnsl_s | -lnsl ]
 740 dnl             -linet
 741
 742 AC_CHECK_FUNC(socket, :, [
 743 dnl hopefully we won't include too many libraries
 744         AC_CHECK_LIB(socket, main)
 745         AC_CHECK_LIB(net, main)
 746         AC_CHECK_LIB(nsl_s, main)
 747         AC_CHECK_LIB(nsl, main)
 748         AC_CHECK_LIB(inet, socket)
 749         AC_CHECK_LIB(gen, main)
 750 ])
 751
 752 dnl require select
 753 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 754
 755 if test "${ac_cv_header_winsock_h}" != yes; then
 756     dnl Select arg types
 757     dnl (if this detection becomes permenent, it and the select() detection
 758     dnl should be done before the yielding select test)
 759     AC_FUNC_SELECT_ARGTYPES
 760 fi
 761
 762 dnl check to see if system call automatically restart
 763 dnl AC_SYS_RESTARTABLE_SYSCALLS
 764
 765 dnl ----------------------------------------------------------------
 766 dnl require POSIX regex
 767 AC_CHECK_HEADERS( regex.h )
 768 if test "$ac_cv_header_regex_h" != yes ; then
 769         AC_MSG_ERROR([POSIX regex.h required.])
 770 fi
 771 AC_CHECK_FUNC(regfree, :, AC_MSG_ERROR([POSIX regex required.]))
 772
 773 OL_POSIX_REGEX
 774 if test "$ol_cv_c_posix_regex" = no ; then
 775         AC_MSG_ERROR([broken POSIX regex!])
 776 fi
 777
 778 dnl ----------------------------------------------------------------
 779 dnl Check for resolver routines
 780 ol_link_dnssrv=no
 781 AC_CHECK_FUNC(res_query,:)
 782 if test $ac_cv_func_res_query = no ; then
 783         AC_CHECK_LIB(bind, res_query)
 784         ac_cv_func_res_query=$ac_cv_lib_bind_res_query
 785 fi
 786
 787 if test $ac_cv_func_res_query = no ; then
 788         AC_CHECK_LIB(bind, __res_query)
 789         ac_cv_func_res_query=$ac_cv_lib_bind___res_query
 790 fi
 791
 792 if test $ac_cv_func_res_query = no ; then
 793         AC_CHECK_LIB(resolv, res_query)
 794         ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
 795 fi
 796
 797 if test "$ac_cv_func_res_query" = yes ; then
 798         AC_DEFINE(HAVE_RES_QUERY,1,
 799                 [define if you have res_query()])
 800
 801         if test $ol_enable_dnssrv != no ; then
 802                 ol_link_dnssrv=yes
 803         fi
 804 fi
 805
 806 if test "$ol_enable_dnssrv" = yes -a "$ol_link_dnssrv" = no ; then
 807         AC_MSG_ERROR([DNSSRV requires res_query()])
 808 fi
 809
 810 dnl ----------------------------------------------------------------
 811 dnl Kerberos
 812 ol_link_kbind=no
 813 ol_link_kpasswd=no
 814 ol_link_krb5=no
 815 ol_link_krb4=no
 816
 817 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 818         -o $ol_with_kerberos = k5 -o $ol_with_kerberos = k5only \
 819         -o $ol_with_kerberos = k425 ; then
 820
 821         AC_CHECK_HEADERS(krb5.h)
 822
 823         if test $ac_cv_header_krb5_h = yes ; then
 824                 dnl lazy check for Heimdal Kerberos
 825                 AC_CHECK_HEADERS(heim_err.h)
 826                 if test $ac_cv_header_heim_err_h = yes ; then
 827                         krb5_impl=heimdal
 828                 else
 829                         krb5_impl=mit
 830                 fi
 831
 832                 if test $krb5_impl = mit; then
 833                         AC_CHECK_LIB(krb5, main,
 834                                 [have_krb5=yes
 835                                 KRB5_LIBS="-lkrb5 -lcrypto -lcom_err"],
 836                                 [have_krb5=no],
 837                                 [-lcrypto -lcom_err])
 838
 839                 elif test $krb5_impl = heimdal; then
 840                         AC_CHECK_LIB(krb5, main,
 841                                 [have_krb5=yes
 842                                 KRB5_LIBS="-lkrb5 -ldes -lasn1 -lroken -lcom_err"],
 843                                 [have_krb5=no],
 844                                 [-ldes -lasn1 -lroken -lcom_err])
 845
 846                         AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1,
 847                                 [define if you have HEIMDAL Kerberos])
 848                 else
 849                         have_krb5=no
 850                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 851                 fi
 852
 853                 if test $have_krb5 = yes ; then
 854                         ol_link_krb5=yes
 855
 856                         AC_DEFINE(HAVE_KRB5, 1,
 857                                 [define if you have Kerberos V])
 858
 859                         if test $ol_enable_kpasswd != no ; then
 860                                 ol_link_kpasswd=yes;
 861                         fi
 862
 863                         if test $ol_with_kerberos = k5only ; then
 864                                 ol_with_kerberos=found
 865                         fi
 866
 867                 elif test $ol_with_kerberos != auto ; then
 868                         AC_MSG_ERROR([Required Kerberos 5 support not available])
 869                 fi
 870
 871         fi
 872 fi
 873
 874 if test $ol_link_krb5 = yes -a \( $ol_with_kerberos = yes -o \
 875         $ol_with_kerberos = auto -o $ol_with_kerberos = k425 \) ; then
 876
 877         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 878
 879         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 880                 if test $krb5_impl = mit; then
 881                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 882                                 KRB4_LIBS="-lkrb4 -ldes425"], [have_k425=no],
 883                                 [-ldes425 -lkrb5 -lcrypto -lcom_err])
 884
 885                 elif test $krb5_impl = heimdal; then
 886                         AC_CHECK_LIB(krb4, main, [have_k425=yes
 887                                 KRB4_LIBS="-lkrb4"], [have_k425=no],
 888                                 [-lkrb5 -ldes -lasn1 -lroken -lcom_err])
 889
 890                 else
 891                         have_425=no
 892                         AC_MSG_WARN([Unrecongized Kerberos5 Implementation])
 893                 fi
 894
 895                 if test $have_k425 = yes ; then
 896                         ol_with_kerberos=found
 897                         ol_link_krb4=yes
 898
 899                         AC_DEFINE(HAVE_KRB425, 1,
 900                                 [define if you have Kerberos V with IV support])
 901                         AC_DEFINE(HAVE_KRB4, 1,
 902                                 [define if you have Kerberos IV])
 903
 904                         AC_CACHE_CHECK([for des_debug in Kerberos libraries],
 905                                 [ol_cv_var_des_debug], [
 906                                 dnl save the flags
 907                                 save_LIBS="$LIBS"
 908                                 LIBS="$KRB4_LIBS $KRB5_LIBS $LIBS"
 909                                 AC_TRY_LINK([
 910 #include <kerberosIV/krb.h>
 911 #include <kerberosIV/des.h>
 912 extern int des_debug;
 913 ],[
 914 des_debug = 1;
 915 ],                              ol_cv_var_des_debug=yes, ol_cv_var_des_debug=no)
 916                                 dnl restore the LIBS
 917                                 LIBS="$save_LIBS"
 918                         ])
 919
 920                         if test $ol_cv_var_des_debug = yes ; then
 921                                 AC_DEFINE(HAVE_DES_DEBUG,1,
 922                                         [define if you have Kerberos des_debug])
 923                         fi
 924
 925                         LIBS="$save_LIBS"
 926                 fi
 927         fi
 928 fi
 929
 930 if test $ol_link_krb5 = yes ; then
 931         ol_with_kerberos=found
 932 fi
 933
 934 if test $ol_with_kerberos = yes -o $ol_with_kerberos = auto \
 935         -o $ol_with_kerberos = k4 -o $ol_with_kerberos = kth ; then
 936
 937         AC_CHECK_HEADERS(krb.h des.h krb-archaeology.h )
 938
 939         if test $ac_cv_header_krb_h = yes ; then
 940                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 941
 942                 if test $have_k4 = yes ; then
 943                         ol_with_kerberos=found
 944                         ol_link_krb4=yes
 945
 946                         AC_DEFINE(HAVE_KRB4, 1,
 947                                 [define if you have Kerberos IV])
 948
 949                         KRB4_LIBS="-lkrb -ldes"
 950
 951                         if test $ac_cv_header_krb_archaeology_h = yes ; then
 952                                 AC_DEFINE(HAVE_KTH_KERBEROS, 1,
 953                                         [define if you have Kth Kerberos])
 954                         fi
 955                 fi
 956         fi
 957 fi
 958
 959 if test $ol_link_krb4 = yes -a $ol_enable_kpasswd != no ; then
 960         ol_link_kpasswd=yes
 961 fi
 962
 963 if test $ol_link_krb4 = yes -a $ol_enable_kbind != no ; then
 964         ol_link_kbind=yes
 965
 966 elif test $ol_enable_kbind = yes ; then
 967         AC_MSG_ERROR([Kerberos IV detection failed])
 968 fi
 969
 970 if test $ol_link_krb4 = yes -o $ol_link_krb5 = yes ; then
 971         AC_DEFINE(HAVE_KERBEROS, 1, [define if you have Kerberos])
 972
 973 elif test $ol_with_kerberos != auto -a $ol_with_kerberos != no ; then
 974         AC_MSG_ERROR([Kerberos detection failed])
 975 fi
 976
 977 dnl ----------------------------------------------------------------
 978 dnl TLS/SSL
 979 ol_link_tls=no
 980 if test $ol_with_tls != no ; then
 981         AC_CHECK_HEADERS(openssl/ssl.h ssl.h)
 982
 983         if test $ac_cv_header_openssl_ssl_h = yes -o $ac_cv_header_ssl_h = yes ; then
 984                 AC_CHECK_LIB(ssl, SSLeay_add_ssl_algorithms,
 985                         [have_ssleay=yes
 986                         need_rsaref=no],
 987                         [have_ssleay=no],
 988                         [-lcrypto])
 989
 990                 if test $have_ssleay = no ; then
 991                         AC_CHECK_LIB(ssl, SSL_library_init,
 992                                 [have_ssleay=yes
 993                                 need_rsaref=no], [have_ssleay=no],
 994                                 [-lcrypto])
 995                 fi
 996
 997                 if test $have_ssleay = no ; then
 998                         AC_CHECK_LIB(ssl, ssl3_accept,
 999                                 [have_ssleay=yes
1000                                 need_rsaref=yes], [have_ssleay=no],
1001                                 [-lcrypto -lRSAglue -lrsaref])
1002                 fi
1003
1004                 if test $have_ssleay = yes ; then
1005                         ol_with_tls=found
1006                         ol_link_tls=yes
1007
1008                         AC_DEFINE(HAVE_SSLEAY, 1,
1009                                 [define if you have SSLeay or OpenSSL])
1010
1011                         if test $need_rsaref = yes; then
1012                                 AC_DEFINE(HAVE_RSAREF, 1,
1013                                         [define if you have RSAref])
1014
1015                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1016                         else
1017                                 TLS_LIBS="-lssl -lcrypto"
1018                         fi
1019                 fi
1020         fi
1021
1022 else
1023         AC_WARN([TLS privacy protection not supported!])
1024 fi
1025
1026 if test $ol_link_tls = yes ; then
1027         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1028
1029 elif test $ol_with_tls = auto ; then
1030         AC_WARN([Could not locate TLS/SSL package])
1031         AC_WARN([TLS privacy protection not supported!])
1032
1033 elif test $ol_with_tls != no ; then
1034         AC_ERROR([Could not locate TLS/SSL package])
1035 fi
1036
1037 dnl ----------------------------------------------------------------
1038 dnl Tests for reentrant functions necessary to build a
1039 dnl thread_safe -lldap.
1040 AC_CHECK_FUNCS(         \
1041         ctime_r                 \
1042         gethostbyname_r gethostbyaddr_r \
1043 )
1044
1045 if test "$ac_cv_func_ctime_r" = no ; then
1046         ol_cv_func_ctime_r_nargs=0
1047 else
1048         OL_FUNC_CTIME_R_NARGS
1049 dnl     OL_FUNC_CTIME_R_TYPE
1050 fi
1051
1052 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1053         OL_FUNC_GETHOSTBYNAME_R_NARGS
1054 else
1055         ol_cv_func_gethostbyname_r_nargs=0
1056 fi
1057
1058 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1059         OL_FUNC_GETHOSTBYADDR_R_NARGS
1060 else
1061         ol_cv_func_gethostbyaddr_r_nargs=0
1062 fi
1063
1064 if test "$ac_cv_func_ctime_r" = yes \
1065         -a "$ol_cv_func_ctime_r_nargs" -ge 2 \
1066         -a "$ol_cv_func_ctime_r_nargs" -le 3 \
1067         -a "$ac_cv_func_gethostbyname_r" = yes \
1068         -a "$ol_cv_func_gethostbyname_r_nargs" -ge 5 \
1069         -a "$ol_cv_func_gethostbyname_r_nargs" -le 6 \
1070         -a "$ac_cv_func_gethostbyaddr_r" = yes \
1071         -a "$ol_cv_func_gethostbyaddr_r_nargs" -ge 5 \
1072         -a "$ol_cv_func_gethostbyaddr_r_nargs" -le 6 \
1073         ; then
1074
1075         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_REENTRANT,1)
1076 fi
1077
1078 dnl ----------------------------------------------------------------
1079 dnl Threads?
1080 ol_link_threads=no
1081
1082 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1083         -o $ol_with_threads = nt ; then
1084
1085         OL_NT_THREADS
1086
1087         if test "$ol_cv_nt_threads" = yes ; then
1088         ol_link_threads=nt
1089         ol_with_threads=found
1090         ol_with_yielding_select=yes
1091
1092                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1093                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1094         fi
1095
1096         if test $ol_with_threads = nt ; then
1097                 AC_MSG_ERROR([could not locate NT Threads])
1098         fi
1099 fi
1100
1101 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1102         -o $ol_with_threads = posix ; then
1103
1104         AC_CHECK_HEADERS(pthread.h)
1105
1106         if test $ac_cv_header_pthread_h = yes ; then
1107                 OL_POSIX_THREAD_VERSION
1108
1109                 if test $ol_cv_pthread_version = final ; then
1110                         AC_DEFINE(HAVE_PTHREADS_FINAL,1,
1111                                 [define if pthreads API compatible with final spec])
1112                 elif test $ol_cv_pthread_version = draft4 ; then
1113                         AC_DEFINE(HAVE_PTHREADS_D4,1,
1114                                 [define if pthreads API compatible with draft4 spec])
1115                 else
1116                         AC_MSG_ERROR([unknown pthread version])
1117                 fi
1118
1119                 # consider threads found
1120                 ol_with_threads=found
1121
1122                 OL_HEADER_LINUX_THREADS
1123                 OL_HEADER_GNU_PTH_PTHREAD_H
1124
1125                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1126                         AC_CHECK_HEADERS(sched.h)
1127                 fi
1128
1129                 dnl Now the hard part, how to link?
1130                 dnl
1131                 dnl currently supported checks:
1132                 dnl
1133                 dnl Check for no flags
1134                 dnl     pthread_create() in $LIBS
1135                 dnl
1136                 dnl Check special pthread (final) flags
1137                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1138                 dnl     pthread_create() with -kthread (FreeBSD)
1139                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1140                 dnl     pthread_create() with -pthreads (?)
1141                 dnl     pthread_create() with -mthreads (AIX)
1142                 dnl     pthread_create() with -thread (?)
1143                 dnl
1144                 dnl Check pthread (final) libraries
1145                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1146                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1147                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1148                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1149                 dnl     pthread_create() in -lpthread (many)
1150                 dnl     pthread_create() in -lc_r (FreeBSD)
1151                 dnl
1152                 dnl Check pthread (draft4) flags (depreciated)
1153                 dnl     pthread_create() with -threads (OSF/1)
1154                 dnl
1155                 dnl Check pthread (draft4) libraries (depreciated)
1156                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1157                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1158                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1159                 dnl     pthread_create() in -lpthreads (many)
1160                 dnl
1161
1162                 dnl pthread_create in $LIBS
1163                 AC_CACHE_CHECK([for pthread_create in default libraries],
1164                         ol_cv_pthread_create,[
1165                 AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1166                         [ol_cv_pthread_create=yes],
1167                         [ol_cv_pthread_create=no],
1168                         [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1169                                 [ol_cv_pthread_create=yes],
1170                                 [ol_cv_pthread_create=no])])])
1171
1172                 if test $ol_cv_pthread_create != no ; then
1173                         ol_link_threads=posix
1174                         ol_link_pthreads=""
1175                 fi
1176
1177 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1178                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1179                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1180                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1181                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1182                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1183
1184                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1185                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1186                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1187                         [ol_cv_pthread_lpthread_lmach_lexc])
1188 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1189 dnl                     [ol_cv_pthread_lpthread_lexc])
1190
1191                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1192                         [ol_cv_pthread_lib_lpthread_woff])
1193
1194                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1195                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1196
1197                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1198
1199                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1200                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1201                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1202                         [ol_cv_pthread_lpthreads_lmach_lexc])
1203                 OL_PTHREAD_TRY([-lpthreads -lexc],
1204                         [ol_cv_pthread_lpthreads_lexc])
1205
1206                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1207
1208                 if test $ol_link_threads != no ; then
1209                         AC_DEFINE(HAVE_PTHREADS,1,
1210                                 [define if you have POSIX Threads])
1211
1212                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1213
1214                         dnl save flags
1215                         save_CPPFLAGS="$CPPFLAGS"
1216                         save_LIBS="$LIBS"
1217                         LIBS="$LTHREAD_LIBS $LIBS"
1218
1219                         dnl All POSIX Thread (final) implementations should have
1220                         dnl sched_yield instead of pthread yield.
1221                         dnl check for both
1222                         AC_CHECK_FUNCS(sched_yield pthread_yield)
1223
1224                         if test $ac_cv_func_sched_yield = no -a \
1225                                 $ac_cv_func_pthread_yield = no ; then
1226                                 dnl Digital UNIX has sched_yield() in -lrt
1227                                 AC_CHECK_LIB(rt, sched_yield,
1228                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1229                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1230                                                 [Define if you have the sched_yield function.])
1231                                         ac_cv_func_sched_yield=yes],
1232                                         [ac_cv_func_sched_yield=no])
1233                         fi
1234                         if test $ac_cv_func_sched_yield = no -a \
1235                                 $ac_cv_func_pthread_yield = no ; then
1236                                 dnl Solaris has sched_yield() stub in -lposix4
1237                                 dnl but we'll use thr_yield instead.
1238                                 AC_CHECK_FUNCS(thr_yield)
1239                         fi
1240                         if test $ac_cv_func_sched_yield = no -a \
1241                                 $ac_cv_func_pthread_yield = no -a \
1242                                 "$ac_cv_func_thr_yield" = no ; then
1243                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1244                         fi
1245
1246                         dnl Check functions for compatibility
1247                         AC_CHECK_FUNCS(pthread_kill pthread_rwlock_destroy)
1248
1249                         dnl Check for pthread_detach with <pthread.h> inclusion
1250                         dnl as it's symbol may have been mangled.
1251                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1252                                 [ol_cv_func_pthread_detach], [
1253                                 dnl save the flags
1254                                 AC_TRY_LINK([
1255 #include <pthread.h>
1256 #ifndef NULL
1257 #define NULL (void*)0
1258 #endif
1259 ],
1260                                         [pthread_detach(NULL);],
1261                                         [ol_cv_func_pthread_detach=yes],
1262                                         [ol_cv_func_pthread_detach=no])
1263                         ])
1264
1265                         if test $ol_cv_func_pthread_detach = no ; then
1266                                 AC_MSG_ERROR([could not locate pthread_detach()])
1267                         fi
1268
1269                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1270                                 [define if you have pthread_detach function])
1271
1272                         dnl Check for setconcurreny functions
1273                         AC_CHECK_FUNCS( \
1274                                 pthread_setconcurrency \
1275                                 pthread_getconcurrency \
1276                                 thr_setconcurrency \
1277                                 thr_getconcurrency \
1278                         )
1279
1280                         OL_SYS_LINUX_THREADS
1281                         OL_LINUX_THREADS
1282
1283                         if test $ol_cv_linux_threads = error; then
1284                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1285                         fi
1286
1287                         AC_CACHE_CHECK([if pthread_create() works],
1288                                 ol_cv_pthread_create_works,[
1289                         AC_TRY_RUN(OL_PTHREAD_TEST_PROGRAM,
1290                                 [ol_cv_pthread_create_works=yes],
1291                                 [ol_cv_pthread_create_works=no],
1292                                 [dnl assume yes
1293                                 ol_cv_pthread_create_works=yes])])
1294
1295                         if test $ol_cv_pthread_create_works = no ; then
1296                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1297                         fi
1298
1299                         dnl Check if select causes an yield
1300                         if test $ol_with_yielding_select = auto ; then
1301                                 AC_CACHE_CHECK([if select yields when using pthreads],
1302                                         ol_cv_pthread_select_yields,[
1303                                 AC_TRY_RUN([
1304 #include <sys/types.h>
1305 #include <sys/time.h>
1306 #include <unistd.h>
1307 #include <pthread.h>
1308 #ifndef NULL
1309 #define NULL (void*) 0
1310 #endif
1311
1312 static int fildes[2];
1313
1314 static void *task(p)
1315         void *p;
1316 {
1317         int i;
1318         struct timeval tv;
1319
1320         fd_set rfds;
1321
1322         tv.tv_sec=10;
1323         tv.tv_usec=0;
1324
1325         FD_ZERO(&rfds);
1326         FD_SET(fildes[0], &rfds);
1327
1328         /* we're not interested in any fds */
1329         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1330
1331         if(i < 0) {
1332                 perror("select");
1333                 exit(10);
1334         }
1335
1336         exit(0); /* if we exit here, the select blocked the whole process */
1337 }
1338
1339 int main(argc, argv)
1340         int argc;
1341         char **argv;
1342 {
1343         pthread_t t;
1344
1345         /* create a pipe to select */
1346         if(pipe(&fildes[0])) {
1347                 perror("select");
1348                 exit(1);
1349         }
1350
1351 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1352         (void) pthread_setconcurrency(2);
1353 #else
1354 #ifdef HAVE_THR_SETCONCURRENCY
1355         /* Set Solaris LWP concurrency to 2 */
1356         thr_setconcurrency(2);
1357 #endif
1358 #endif
1359
1360 #if HAVE_PTHREADS_D4
1361         pthread_create(&t, pthread_attr_default, task, NULL);
1362 #else
1363         pthread_create(&t, NULL, task, NULL);
1364 #endif
1365
1366 #if HAVE_SCHED_YIELD
1367         sched_yield();  /* make sure task runs first */
1368 #else
1369 #ifdef HAVE_PTHREAD_YIELD
1370         pthread_yield();        /* make sure task runs first */
1371 #endif
1372 #endif
1373
1374         exit(2);
1375 }],
1376                                 [ol_cv_pthread_select_yields=no],
1377                                 [ol_cv_pthread_select_yields=yes],
1378                                 [ol_cv_pthread_select_yields=cross])])
1379
1380                                 if test $ol_cv_pthread_select_yields = cross ; then
1381                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1382                                 fi
1383
1384                                 if test $ol_cv_pthread_select_yields = yes ; then
1385                                         ol_with_yielding_select=yes
1386                                 fi
1387                         fi
1388
1389                         dnl restore flags
1390                         CPPFLAGS="$save_CPPFLAGS"
1391                         LIBS="$save_LIBS"
1392                 else
1393                         AC_MSG_ERROR([could not link with POSIX Threads])
1394                 fi
1395         fi
1396
1397         if test $ol_with_threads = posix ; then
1398                 AC_MSG_ERROR([could not locate POSIX Threads])
1399         fi
1400 fi
1401
1402 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1403         -o $ol_with_threads = mach ; then
1404
1405         dnl check for Mach CThreads
1406         AC_CHECK_HEADERS(mach/cthreads.h)
1407         if test $ac_cv_header_mach_cthreads_h = yes ; then
1408                 ol_with_threads=found
1409
1410                 dnl check for cthread support in current $LIBS
1411                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1412
1413                 if test $ol_link_threads = no ; then
1414                         dnl try -all_load
1415                         dnl this test needs work
1416                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1417                                 [ol_cv_cthread_all_load], [
1418                                 dnl save the flags
1419                                 save_LIBS="$LIBS"
1420                                 LIBS="-all_load $LIBS"
1421                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
1422                                         cthread_fork((void *)0, (void *)0);
1423                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
1424                                 dnl restore the LIBS
1425                                 LIBS="$save_LIBS"
1426                         ])
1427
1428                         if test $ol_cv_cthread_all_load = yes ; then
1429                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1430                                 ol_link_threads=mach
1431                         fi
1432                 fi
1433
1434                 if test $ol_link_threads != no ; then
1435                         : check for cthread specific functionality here
1436                         AC_DEFINE(HAVE_MACH_CTHREADS,1,
1437                                 [define if you have Mach Cthreads])
1438                 else
1439                         AC_MSG_ERROR([could not link with Mach CThreads])
1440                 fi
1441         fi
1442
1443         if test $ol_with_threads = mach ; then
1444                 AC_MSG_ERROR([could not locate Mach CThreads])
1445         fi
1446 fi
1447
1448 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1449         -o $ol_with_threads = pth ; then
1450
1451         AC_CHECK_HEADERS(pth.h)
1452
1453         if test $ac_cv_header_pth_h = yes ; then
1454                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1455
1456                 if test $have_pth = yes ; then
1457                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1458                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1459                         ol_link_threads=pth
1460
1461                         if test $ol_with_yielding_select = auto ; then
1462                                 ol_with_yielding_select=yes
1463                         fi
1464                 fi
1465         fi
1466 fi
1467
1468 if test $ol_with_threads = auto -o $ol_with_threads = yes \
1469         -o $ol_with_threads = lwp ; then
1470
1471         dnl check for SunOS5 LWP
1472         AC_CHECK_HEADERS(thread.h synch.h)
1473         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
1474                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1475
1476                 if test $have_thr = yes ; then
1477                         AC_DEFINE(HAVE_THR,1,
1478                                 [if you have Solaris LWP (thr) package])
1479                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1480                         ol_link_threads=thr
1481
1482                         if test $ol_with_yielding_select = auto ; then
1483                                 ol_with_yielding_select=yes
1484                         fi
1485
1486                         dnl Check for setconcurreny functions
1487                         AC_CHECK_FUNCS( \
1488                                 thr_setconcurrency \
1489                                 thr_getconcurrency \
1490                         )
1491                 fi
1492         fi
1493
1494         dnl check for SunOS4 LWP
1495         AC_CHECK_HEADERS(lwp/lwp.h)
1496         if test $ac_cv_header_lwp_lwp_h = yes ; then
1497                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1498
1499                 if test $have_lwp = yes ; then
1500                         AC_DEFINE(HAVE_LWP,1,
1501                                 [if you have SunOS LWP package])
1502                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1503                         ol_link_threads=lwp
1504
1505                         if test $ol_with_yielding_select = auto ; then
1506                                 ol_with_yielding_select=no
1507                         fi
1508                 fi
1509         fi
1510 fi
1511
1512 if test $ol_with_yielding_select = yes ; then
1513         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1514                 [define if select implicitly yields])
1515 fi
1516
1517 if test $ol_with_threads = manual ; then
1518         dnl User thinks he can manually configure threads.
1519         ol_link_threads=yes
1520
1521         AC_MSG_WARN([thread defines and link options must be set manually])
1522
1523         AC_CHECK_HEADERS(pthread.h sched.h)
1524         AC_CHECK_FUNCS(sched_yield pthread_yield)
1525         OL_HEADER_LINUX_THREADS
1526
1527         AC_CHECK_HEADERS(mach/cthreads.h)
1528         AC_CHECK_HEADERS(lwp/lwp.h)
1529         AC_CHECK_HEADERS(thread.h synch.h)
1530 fi
1531
1532 if test $ol_link_threads != no -a $ol_link_threads != nt ; then
1533         dnl needed to get reentrant/threadsafe versions
1534         dnl
1535         AC_DEFINE(REENTRANT,1)
1536         AC_DEFINE(_REENTRANT,1)
1537         AC_DEFINE(THREAD_SAFE,1)
1538         AC_DEFINE(_THREAD_SAFE,1)
1539         AC_DEFINE(THREADSAFE,1)
1540         AC_DEFINE(_THREADSAFE,1)
1541         AC_DEFINE(_SGI_MP_SOURCE,1)
1542
1543         dnl The errno declaration may dependent upon _REENTRANT.
1544         dnl If it does, we must link with thread support.
1545         AC_CACHE_CHECK([for thread specific errno],
1546                 [ol_cv_errno_thread_specific], [
1547                 AC_TRY_LINK([#include <errno.h>], [errno = 0;],
1548                         [ol_cv_errno_thread_specific=yes],
1549                         [ol_cv_errno_thread_specific=no])
1550         ])
1551
1552         dnl The h_errno declaration may dependent upon _REENTRANT.
1553         dnl If it does, we must link with thread support.
1554         AC_CACHE_CHECK([for thread specific h_errno],
1555                 [ol_cv_h_errno_thread_specific], [
1556                 AC_TRY_LINK([#include <netdb.h>], [h_errno = 0;],
1557                         [ol_cv_h_errno_thread_specific=yes],
1558                         [ol_cv_h_errno_thread_specific=no])
1559         ])
1560
1561         if test $ol_cv_errno_thread_specific != yes \
1562                 -o $ol_cv_h_errno_thread_specific != yes ; then
1563                 LIBS="$LTHREAD_LIBS $LIBS"
1564                 LTHREAD_LIBS=""
1565         fi
1566
1567 dnl When in thread environment, use
1568 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) \
1569 dnl                     || defined( HAVE_FUNC_R )
1570 dnl                     func_r(...);
1571 dnl             #else
1572 dnl             #       if defined( HAVE_THREADS )
1573 dnl                             /* lock */
1574 dnl             #       endif
1575 dnl                             func(...);
1576 dnl             #       if defined( HAVE_THREADS )
1577 dnl                             /* unlock */
1578 dnl             #       endif
1579 dnl             #endif
1580 dnl
1581 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1582 dnl             _POSIX_REENTRANT_FUNCTIONS
1583 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1584 dnl             _POSIX_THREADSAFE_FUNCTIONS
1585 dnl
1586 dnl             and is currently defined in lthread.h
1587 dnl
1588 dnl HAVE_THREADS is defined by lthread.h iff -UNO_THREADS
1589 dnl
1590 dnl libldap/*.c should only include <lthread.h> iff
1591 dnl LDAP_R_COMPILE is defined.  ie:
1592 dnl             #ifdef LDAP_R_COMPILE
1593 dnl             #       include LDAP_R_COMPILE
1594 dnl             #endif
1595 dnl
1596 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1597 dnl specifically for compiling the threadsafe version of
1598 dnl     the ldap library (-lldap_r).
1599 dnl
1600 dnl     dnl check for reentrant/threadsafe functions
1601 dnl     dnl
1602 dnl     dnl note: these should only be used when linking
1603 dnl     dnl       with $LTHREAD_LIBS
1604 dnl     dnl
1605 dnl     save_CPPFLAGS="$CPPFLAGS"
1606 dnl     save_LIBS="$LIBS"
1607 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1608 dnl     AC_CHECK_FUNCS( \
1609 dnl             gmtime_r \
1610 dnl             gethostbyaddr_r gethostbyname_r \
1611 dnl             feof_unlocked unlocked_feof \
1612 dnl             putc_unlocked unlocked_putc \
1613 dnl             flockfile ftrylockfile \
1614 dnl     )
1615 dnl     CPPFLAGS="$save_CPPFLAGS"
1616 dnl     LIBS="$save_LIBS"
1617 fi
1618
1619 if test $ol_link_threads = no ; then
1620         if test $ol_with_threads = yes ; then
1621                 AC_MSG_ERROR([no suitable thread support])
1622         fi
1623
1624         if test $ol_with_threads = auto ; then
1625                 AC_MSG_WARN([no suitable thread support, disabling threads])
1626                 ol_with_threads=no
1627         fi
1628
1629         AC_DEFINE(NO_THREADS,1,
1630                 [define if you have (or want) no threads])
1631         LTHREAD_LIBS=""
1632 fi
1633
1634 if test $ol_link_threads != no ; then
1635         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1)
1636 fi
1637
1638 dnl ----------------------------------------------------------------
1639 ol_link_ldbm=no
1640
1641 if test $ol_with_ldbm_api = auto \
1642         -o $ol_with_ldbm_api = berkeley \
1643         -o $ol_with_ldbm_api = bcompat ; then
1644
1645         if test $ol_with_ldbm_api = bcompat; then \
1646                 OL_BERKELEY_COMPAT_DB
1647         else
1648                 OL_BERKELEY_DB
1649         fi
1650
1651         if test $ol_cv_berkeley_db != no ; then
1652                 AC_DEFINE(HAVE_BERKELEY_DB,1,
1653                         [define this if Berkeley DB is available])
1654
1655                 ol_link_ldbm=berkeley
1656                 ol_with_ldbm_api=db
1657
1658                 if test $ol_with_ldbm_type = hash ; then
1659                         AC_DEFINE(LDBM_USE_DBHASH,1,
1660                                 [define this to use DBHASH w/ LDBM backend])
1661                 else
1662                         AC_DEFINE(LDBM_USE_DBBTREE,1,
1663                                 [define this to use DBBTREE w/ LDBM backend])
1664                 fi
1665
1666                 dnl $ol_cv_lib_db should be yes or -ldb
1667                 dnl (it could be no, but that would be an error
1668                 if test $ol_cv_lib_db != yes ; then
1669                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
1670                 fi
1671         fi
1672 fi
1673
1674 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
1675         AC_MSG_WARN(Could not find LDBM with BTREE support)
1676         ol_with_ldbm_api=none
1677 fi
1678
1679 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = mdbm ; then
1680         OL_MDBM
1681
1682         if test $ol_cv_mdbm = yes ; then
1683                 ol_link_ldbm=mdbm
1684                 ol_with_ldbm_api=mdbm
1685                 if test $ol_cv_lib_mdbm != yes ; then
1686                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_mdbm"
1687                 fi
1688         fi
1689 fi
1690
1691 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
1692         OL_GDBM
1693
1694         if test $ol_cv_gdbm = yes ; then
1695                 ol_link_ldbm=gdbm
1696                 ol_with_ldbm_api=gdbm
1697
1698                 if test $ol_cv_lib_gdbm != yes ; then
1699                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
1700                 fi
1701         fi
1702 fi
1703
1704 if test $ol_with_ldbm_api = ndbm ; then
1705         OL_NDBM
1706
1707         if test $ol_cv_ndbm = yes ; then
1708                 ol_link_ldbm=ndbm
1709                 ol_with_ldbm_api=ndbm
1710
1711                 if test $ol_cv_lib_ndbm != yes ; then
1712                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
1713                 fi
1714         fi
1715 fi
1716
1717 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
1718         AC_MSG_WARN(could not find suitable LDBM backend)
1719         if test $ol_enable_ldbm = yes ; then
1720                 AC_MSG_ERROR(select appropriate LDBM options or disable)
1721         fi
1722
1723         AC_MSG_WARN(disabling LDBM)
1724         ol_enable_ldbm=no
1725 fi
1726
1727 dnl ----------------------------------------------------------------
1728 if test $ol_enable_dynamic = yes -a $enable_shared = yes ; then
1729         LINK_BINS_DYNAMIC="yes"
1730 else
1731         LINK_BINS_DYNAMIC="no"
1732 fi
1733
1734 dnl ----------------------------------------------------------------
1735 if test $ol_enable_wrappers != no ; then
1736         AC_CHECK_HEADERS(tcpd.h)
1737
1738         if test $ac_cv_header_tcpd_h != yes ; then
1739                 have_wrappers=no
1740         else
1741                 AC_TRY_COMPILE([
1742 int allow_severity = 0;
1743 int deny_severity  = 0;
1744                 ],[hosts_access()],[have_wrappers=yes],[have_wrappers=no])
1745         fi
1746
1747         if test $have_wrappers = yes ; then
1748                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1749                 WRAP_LIBS="-lwrap"
1750
1751                 dnl We add another check for -lnsl since some libwrap's
1752                 dnl need it, but it isn't always included from above
1753                 AC_CHECK_LIB(nsl, main)
1754         else
1755                 AC_MSG_WARN(could not find -lwrap)
1756                 if test $ol_enable_wrappers = yes ; then
1757                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
1758                 fi
1759
1760                 AC_MSG_WARN(disabling wrappers support)
1761                 ol_enable_wrappers=no
1762                 WRAP_LIBS=""
1763         fi
1764 fi
1765
1766 dnl ----------------------------------------------------------------
1767 if test $ol_enable_syslog != no ; then
1768         AC_CHECK_FUNC(openlog)
1769         if test $ac_cv_func_openlog = no -a $ol_enable_syslog = yes; then
1770                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1771         fi
1772         ol_enable_syslog=$ac_cv_func_openlog
1773 fi
1774
1775 dnl ----------------------------------------------------------------
1776 dnl dmalloc support (deprecated in favor of -DCSRIMALLOC support)
1777 dnl if test $ol_enable_dmalloc != no ; then
1778 dnl     AC_CHECK_HEADERS(dmalloc.h)
1779 dnl     AC_CHECK_LIB(dmalloc, dmalloc_shutdown)
1780 dnl fi
1781
1782 dnl ----------------------------------------------------------------
1783 dnl SQL
1784 ol_link_sql=no
1785 if test $ol_enable_sql != no ; then
1786         AC_CHECK_LIB(iodbc,SQLDriverConnect,[have_iodbc=yes],[have_iodbc=no])
1787         if test $have_iodbc = yes ; then
1788                 ol_link_sql="-liodbc"
1789         else
1790                 AC_CHECK_LIB(odbc,SQLDriverConnect,[have_odbc=yes],[have_odbc=no])
1791                 if test $have_odbc = yes ; then
1792                         ol_link_sql="-lodbc"
1793                 fi
1794         fi
1795
1796         if test $ol_link_sql != no ; then
1797                 SLAPD_SQL_LIBS="$ol_link_sql"
1798
1799         elif test $ol_enable_sql != auto ; then
1800                 AC_MSG_ERROR([could not locate suitable ODBC library])
1801         fi
1802 fi
1803
1804 dnl ----------------------------------------------------------------
1805 dnl TCL
1806 if test $ol_enable_tcl != no ; then
1807         AC_CHECK_HEADERS(tcl.h)
1808
1809         if test $ac_cv_header_tcl_h != yes ; then
1810                 have_tcl=no
1811         else
1812                 for lib in tcl tcl7.6 tcl8.0 tcl8.2 ; do
1813                         AC_CHECK_LIB($lib,main,
1814                           [have_tcl=yes
1815                            if test x"$ol_with_tcl_module" = "xstatic" ; then
1816                                SLAPD_LIBS="$SLAPD_LIBS -l${lib}"
1817                            else
1818                                MOD_TCL_LIB="-l${lib}"
1819                            fi;break],[have_tcl=no])
1820                 done
1821         fi
1822
1823         if test $have_tcl != yes ; then
1824                 AC_MSG_WARN([could not find -ltcl])
1825                 if test $ol_enable_tcl = yes ; then
1826                         AC_MSG_ERROR([could not find tcl, select appropriate options or disable])
1827                 fi
1828
1829                 ol_enable_tcl=no
1830         fi
1831 fi
1832
1833 dnl ----------------------------------------------------------------
1834 dnl ud needs termcap (should insert check here)
1835 ol_link_termcap=no
1836 AC_CHECK_HEADERS(termcap.h ncurses.h)
1837
1838 if test $ol_link_termcap = no ; then
1839         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
1840         if test $have_termcap = yes ; then
1841                 AC_DEFINE(HAVE_TERMCAP, 1, [define if you have -ltermcap])
1842                 ol_link_termcap=yes
1843                 TERMCAP_LIBS=-ltermcap
1844         fi
1845 fi
1846
1847 if test $ol_link_termcap = no ; then
1848         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
1849         if test $have_ncurses = yes ; then
1850                 AC_DEFINE(HAVE_NCURSES, 1, [define if you have -lncurses])
1851                 ol_link_termcap=yes
1852                 TERMCAP_LIBS=-lncurses
1853         fi
1854 fi
1855
1856 if test $ol_link_termcap = no ; then
1857         AC_DEFINE(NO_TERMCAP,1, [define if you have no termcap support])
1858         TERMCAP_LIBS=
1859 fi
1860
1861 dnl ----------------------------------------------------------------
1862 dnl
1863 dnl Check for Cyrus SASL
1864 dnl
1865 ol_link_sasl=no
1866 ol_link_spasswd=no
1867 if test $ol_with_cyrus_sasl != no ; then
1868         AC_CHECK_HEADERS(sasl.h)
1869
1870         if test $ac_cv_header_sasl_h = yes ; then
1871                 AC_CHECK_LIB(sasl, sasl_client_init,
1872                         [have_cyrus_sasl=yes], [have_cyrus_sasl=no])
1873
1874                 if test $have_cyrus_sasl != no ; then
1875                         SASL_LIBS="-lsasl"
1876                         AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
1877                         ol_link_sasl=yes
1878                 fi
1879         fi
1880
1881         if test $ol_link_sasl = no ; then
1882                 if test $ol_with_cyrus_sasl != auto ; then
1883                         AC_MSG_ERROR([Could not locate Cyrus SASL])
1884                 else
1885                         AC_MSG_WARN([Could not locate Cyrus SASL])
1886                         AC_MSG_WARN([SASL authentication not supported!])
1887                         if test $ol_link_tls = no ; then
1888                                 AC_MSG_WARN([Strong authentication not supported!])
1889                         fi
1890                 fi
1891         fi
1892 else
1893         AC_MSG_WARN([SASL authentication not supported!])
1894         if test $ol_link_tls = no ; then
1895                 AC_MSG_WARN([Strong authentication not supported!])
1896         fi
1897 fi
1898
1899 dnl ----------------------------------------------------------------
1900 dnl Check for entropy sources
1901 if test $cross_compiling != yes ; then
1902         dev=no
1903         if test -r /dev/urandom ; then
1904                 dev="/dev/urandom";
1905         elif test -r /idev/urandom ; then
1906                 dev="/idev/urandom";
1907         elif test -r /dev/srandom ; then
1908                 dev="/dev/srandom";
1909         elif test -r /dev/random ; then
1910                 dev="/dev/random";
1911         elif test -r /idev/random ; then
1912                 dev="/idev/random";
1913         fi
1914
1915         if test $dev != no ; then
1916                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
1917         fi
1918 fi
1919
1920 dnl ----------------------------------------------------------------
1921 dnl
1922 dnl Check for fetch URL support
1923 dnl             should be extended to support other fetch URL APIs
1924 dnl
1925 ol_link_fetch=no
1926 if test $ol_with_fetch != no ; then
1927         OL_LIB_FETCH
1928
1929         if test $ol_cv_lib_fetch != no ; then
1930                 LDIF_LIBS="$LDIF_LIBS $ol_link_fetch"
1931                 ol_link_fetch=freebsd
1932
1933         elif test $ol_with_fetch != auto ; then
1934                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
1935         fi
1936 fi
1937
1938 dnl ----------------------------------------------------------------
1939 dnl
1940 dnl Check for GNU readline
1941 dnl
1942 ol_link_readline=no
1943 if test $ol_with_readline != no ; then
1944         AC_CHECK_HEADERS(readline/readline.h readline/history.h)
1945
1946         if test $ac_cv_header_readline_readline_h = yes ; then
1947                 save_LIBS="$LIBS"
1948                 LIBS="$TERMCAP_LIBS $LIBS"
1949                 AC_CHECK_LIB(readline, readline,
1950                         [have_readline=yes], [have_readline=no])
1951                 LIBS="$save_LIBS"
1952
1953                 if test $have_readline = yes ; then
1954                         ol_with_readline=found
1955                         ol_link_readline=yes
1956
1957                         READLINE_LIBS="-lreadline"
1958                 fi
1959         fi
1960 fi
1961
1962 if test $ol_link_readline = yes ; then
1963         AC_DEFINE(HAVE_READLINE, 1, [define if you have -lreadline])
1964 fi
1965
1966
1967 dnl ----------------------------------------------------------------
1968 dnl FreeBSD (and others) have crypt(3) in -lcrypt
1969 if test $ol_enable_crypt != no ; then
1970         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
1971                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
1972                         have_crypt=yes], [have_crypt=no])])
1973
1974         if test $have_crypt = yes ; then
1975                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
1976         else
1977                 AC_MSG_WARN(could not find crypt)
1978                 if test $ol_enable_crypt = yes ; then
1979                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
1980                 fi
1981
1982                 AC_MSG_WARN(disabling crypt support)
1983                 ol_enable_crypt=no
1984         fi
1985 fi
1986
1987 dnl ----------------------------------------------------------------
1988 dnl FreeBSD (and others) have setproctitle(3) in -lutil
1989 if test $ol_enable_proctitle != no ; then
1990         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
1991                 AC_CHECK_LIB(util, setproctitle,
1992                         [have_setproctitle=yes
1993                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
1994                         [have_setproctitle=no
1995                         LIBOBJS="$LIBOBJS setproctitle.o"
1996                         LIBSRCS="$LIBSRCS setproctitle.c"])])
1997
1998         if test $have_setproctitle = yes ; then
1999                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2000                         [define if setproctitle(3) is available])
2001         fi
2002 fi
2003
2004 dnl ----------------------------------------------------------------
2005 dnl Checks for typedefs, structures, and compiler characteristics.
2006 AC_TYPE_MODE_T
2007 AC_TYPE_OFF_T
2008 AC_TYPE_PID_T
2009 AM_TYPE_PTRDIFF_T
2010 AC_TYPE_SIGNAL
2011 AC_TYPE_SIZE_T
2012
2013 AC_CHECK_TYPE(ssize_t, [signed int])
2014 AC_CHECK_TYPE(caddr_t,  [char *])
2015
2016 OL_TYPE_SOCKLEN_T
2017 AC_STRUCT_ST_BLKSIZE
2018 AC_HEADER_TIME
2019 AC_STRUCT_TM
2020 AC_TYPE_UID_T
2021 OL_TYPE_SIG_ATOMIC_T
2022
2023 dnl AC_TYPE_GETGROUPS
2024
2025 OL_STRUCT_PASSWD_PW_GECOS
2026 OL_STRUCT_PASSWD_PW_PASSWD
2027
2028 OL_C_UPPER_LOWER
2029 AC_C_CONST
2030 OL_C_VOLATILE
2031
2032 if test $cross_compiling = yes ; then
2033         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2034 else
2035         AC_C_BIGENDIAN
2036 fi
2037
2038 AC_COMPILE_CHECK_SIZEOF(short)
2039 AC_COMPILE_CHECK_SIZEOF(int)
2040 AC_COMPILE_CHECK_SIZEOF(long)
2041
2042 if test "$ac_cv_sizeof_int" -lt 4 ; then
2043         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2044
2045         AC_DEFINE(LBER_INT_T,long)
2046 else
2047         AC_DEFINE(LBER_INT_T,int)
2048 fi
2049
2050 AC_DEFINE(LBER_LEN_T,long)
2051 AC_DEFINE(LBER_SOCKET_T,int)
2052 AC_DEFINE(LBER_TAG_T,long)
2053
2054 dnl ----------------------------------------------------------------
2055 dnl Checks for library functions.
2056 AC_FUNC_MEMCMP
2057 dnl AM_FUNC_MKTIME dnl checks for sys/time.h and unistd.h
2058 AC_FUNC_STRFTIME
2059 dnl AM_FUNC_STRTOD
2060
2061 OL_FUNC_INET_ATON
2062
2063 dnl Check for NT specific routines
2064 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2065
2066 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2067         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2068 ])
2069
2070 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2071         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2072 ])
2073
2074 AC_FUNC_VPRINTF
2075
2076 if test $ac_cv_func_vprintf = yes ; then
2077         dnl check for vsnprintf
2078         AC_CHECK_FUNCS(vsnprintf vsprintf)
2079 fi
2080
2081 AC_CHECK_FUNCS(         \
2082         bcopy                   \
2083         closesocket             \
2084         chroot                  \
2085         endgrent                \
2086         endpwent                \
2087         flock                   \
2088         getdtablesize   \
2089         getgrgid                \
2090         gethostname             \
2091         getpass                 \
2092         getpassphrase   \
2093         getpwuid                \
2094         getpwnam                \
2095         getspnam                \
2096         gettimeofday    \
2097         initgroups              \
2098         lockf                   \
2099         memcpy                  \
2100         memmove                 \
2101         mkstemp                 \
2102         pipe                    \
2103         read                    \
2104         recv                    \
2105         recvfrom                \
2106         setpwfile               \
2107         setgid                  \
2108         setegid                 \
2109         setsid                  \
2110         setuid                  \
2111         seteuid                 \
2112         sigaction               \
2113         signal                  \
2114         sigset                  \
2115         snprintf                \
2116         strdup                  \
2117         strerror                \
2118         strpbrk                 \
2119         strrchr                 \
2120         strsep                  \
2121         strstr                  \
2122         strtol                  \
2123         strtoul                 \
2124         strspn                  \
2125         sysconf                 \
2126         waitpid                 \
2127         wait4                   \
2128         write                   \
2129         send                    \
2130         sendto                  \
2131 )
2132
2133 dnl We actually may need to replace more than this.
2134 AC_REPLACE_FUNCS(getopt tempnam)
2135
2136 if test "$ac_cv_func_getopt" != yes; then
2137     LIBSRCS="$LIBSRCS getopt.c"
2138 fi
2139
2140 if test "$ac_cv_func_tempnam" != yes; then
2141     LIBSRCS="$LIBSRCS tempnam.c"
2142 fi
2143
2144 dnl ----------------------------------------------------------------
2145 # Check Configuration
2146 OL_SYS_ERRLIST
2147
2148 dnl ----------------------------------------------------------------
2149 dnl Sort out defines
2150
2151 if test "$ol_enable_debug" != no ; then
2152         AC_DEFINE(LDAP_DEBUG,1,
2153                 [define this to add debugging code])
2154 fi
2155 if test "$ol_enable_syslog" = yes ; then
2156         AC_DEFINE(LDAP_SYSLOG,1,
2157                 [define this to add syslog code])
2158 fi
2159 if test "$ol_enable_cache" = no ; then
2160         AC_DEFINE(LDAP_NOCACHE,1,
2161                 [define this to remove -lldap cache support])
2162 fi
2163 if test "$ol_link_kbind" != no ; then
2164         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_KBIND,LDAP_VENDOR_VERSION)
2165 fi
2166 if test "$ol_enable_proctitle" != no ; then
2167         AC_DEFINE(LDAP_PROCTITLE,1,
2168                 [define this for LDAP process title support])
2169 fi
2170 if test "$ol_enable_referrals" != no ; then
2171         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION)
2172 fi
2173 if test "$ol_enable_local" != no; then
2174         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2175 fi
2176 if test "$ol_enable_ipv6" != no; then
2177         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2178 fi
2179 if test "$ol_enable_cleartext" != no ; then
2180         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2181 fi
2182 if test "$ol_enable_crypt" != no ; then
2183         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2184 fi
2185 if test "$ol_link_kpasswd" != no ; then
2186         AC_DEFINE(SLAPD_KPASSWD,1,[define to support Kerberos passwords])
2187 fi
2188 if test "$ol_link_spasswd" != no ; then
2189         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2190 fi
2191 if test "$ol_enable_multimaster" != no ; then
2192         AC_DEFINE(SLAPD_MULTIMASTER,1,[define to support multimaster replication])
2193 fi
2194 if test "$ol_enable_phonetic" != no ; then
2195         AC_DEFINE(SLAPD_PHONETIC,1,[define to support phonetic])
2196 fi
2197 if test "$ol_enable_rlookups" != no ; then
2198         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2199 fi
2200 if test "$ol_enable_aci" != no ; then
2201         AC_DEFINE(SLAPD_ACI_ENABLED,1,[define to support per-object ACIs])
2202 fi
2203
2204 if test "$ol_link_modules" != no ; then
2205         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2206         BUILD_SLAPD=yes
2207         SLAPD_MODULES_LDFLAGS="-dlopen self"
2208 fi
2209
2210 if test "$ol_link_dnssrv" != no ; then
2211         AC_DEFINE(SLAPD_DNSSRV,1,[define to support DNS SRV backend])
2212         BUILD_SLAPD=yes
2213         BUILD_DNSSRV=yes
2214         if test "$ol_with_dnssrv_module" != static ; then
2215                 AC_DEFINE(SLAPD_DNSSRV_DYNAMIC,1,
2216                         [define to support dynamic DNS SRV backend])
2217                 BUILD_DNSSRV=mod
2218                 BUILD_DNSSRV_DYNAMIC=shared
2219                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-dnssrv/back_dnssrv.la"
2220         fi
2221 fi
2222
2223 if test "$ol_enable_ldap" != no ; then
2224         AC_DEFINE(SLAPD_LDAP,1,[define to support LDAP backend])
2225         BUILD_SLAPD=yes
2226         BUILD_LDAP=yes
2227         if test "$ol_with_ldap_module" != static ; then
2228                 AC_DEFINE(SLAPD_LDAP_DYNAMIC,1,
2229                         [define to support dynamic LDAP backend])
2230                 BUILD_LDAP=mod
2231                 BUILD_LDAP_DYNAMIC=shared
2232                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldap/back_ldap.la"
2233         fi
2234 fi
2235
2236 if test "$ol_link_ldbm" != no ; then
2237         AC_DEFINE(SLAPD_LDBM,1,[define to support LDBM backend])
2238         BUILD_SLAPD=yes
2239         BUILD_LDBM=yes
2240         if test "$ol_with_ldbm_module" != static ; then
2241                 AC_DEFINE(SLAPD_LDBM_DYNAMIC,1,
2242                         [define to support dynamic LDBM backend])
2243                 BUILD_LDBM=mod
2244                 BUILD_LDBM_DYNAMIC=shared
2245                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-ldbm/back_ldbm.la"
2246         fi
2247 fi
2248
2249 if test "$ol_enable_passwd" != no ; then
2250         AC_DEFINE(SLAPD_PASSWD,1,[define to support PASSWD backend])
2251         BUILD_SLAPD=yes
2252         BUILD_PASSWD=yes
2253         if test "$ol_with_passwd_module" != static ; then
2254                 AC_DEFINE(SLAPD_PASSWD_DYNAMIC,1,
2255                         [define to support dynamic PASSWD backend])
2256                 BUILD_PASSWD=mod
2257                 BUILD_PASSWD_DYNAMIC=shared
2258                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-passwd/back_passwd.la"
2259         fi
2260 fi
2261
2262 if test "$ol_link_perl" != no ; then
2263         AC_DEFINE(SLAPD_PERL,1,[define to support PERL backend])
2264         BUILD_SLAPD=yes
2265         BUILD_PERL=yes
2266         if test "$ol_with_perl_module" != static ; then
2267                 AC_DEFINE(SLAPD_PERL_DYNAMIC,1,
2268                         [define to support dynamic PERL backend])
2269                 BUILD_PERL=mod
2270                 BUILD_PERL_DYNAMIC=shared
2271                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-perl/back_perl.la"
2272         fi
2273 fi
2274
2275 if test "$ol_enable_shell" != no ; then
2276         AC_DEFINE(SLAPD_SHELL,1,[define to support SHELL backend])
2277         BUILD_SLAPD=yes
2278         BUILD_SHELL=yes
2279         if test "$ol_with_shell_module" != static ; then
2280                 AC_DEFINE(SLAPD_SHELL_DYNAMIC,1,
2281                         [define to support dynamic SHELL backend])
2282                 BUILD_SHELL=mod
2283                 BUILD_SHELL_DYNAMIC=shared
2284                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-shell/back_shell.la"
2285         fi
2286 fi
2287
2288 if test "$ol_enable_tcl" != no ; then
2289         AC_DEFINE(SLAPD_TCL,1,[define to support TCL backend])
2290         BUILD_SLAPD=yes
2291         BUILD_TCL=yes
2292         if test "$ol_with_tcl_module" != static; then
2293                 AC_DEFINE(SLAPD_TCL_DYNAMIC,1,
2294                         [define to support dynamic TCL backend])
2295                 BUILD_TCL=mod
2296                 BUILD_TCL_DYNAMIC=shared
2297                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-tcl/back_tcl.la"
2298         fi
2299 fi
2300
2301 if test "$ol_link_sql" != no ; then
2302         AC_DEFINE(SLAPD_SQL,1,[define to support SQL backend])
2303         BUILD_SLAPD=yes
2304         BUILD_SQL=yes
2305         if test "$ol_with_sql_module" != static; then
2306                 AC_DEFINE(SLAPD_SQL_DYNAMIC,1,
2307                         [define to support dynamic SQL backend])
2308                 BUILD_SQL=mod
2309                 BUILD_SQL_DYNAMIC=shared
2310                 SLAPD_MODULES_LIST="$SLAPD_MODULES_LIST -dlopen \$(SLAP_DIR)back-sql/back_sql.la"
2311         fi
2312 fi
2313
2314 if test "$ol_enable_slurpd" != no -a "$ol_link_threads" != no -a \
2315         $BUILD_SLAPD = yes ; then
2316         BUILD_SLURPD=yes
2317 fi
2318
2319 dnl ----------------------------------------------------------------
2320
2321 if test "$LINK_BINS_DYNAMIC" = yes; then
2322     LIB_LINKAGE=DYN
2323     LT_LIB_LINKAGE=shared
2324 else
2325     LIB_LINKAGE=STAT
2326     LT_LIB_LINKAGE=static
2327 fi
2328
2329 if test "$ac_cv_mingw32" = yes ; then
2330     PLAT=NT
2331     DYN_EXT=dll
2332 else
2333     PLAT=UNIX
2334     DYN_EXT=so
2335 fi
2336
2337 AC_SUBST(LIBSRCS)
2338
2339 AC_SUBST(PLAT)
2340 AC_SUBST(LIB_LINKAGE)
2341 AC_SUBST(LT_LIB_LINKAGE)
2342 AC_SUBST(DYN_EXT)
2343
2344 AC_SUBST(BUILD_SLAPD)
2345   AC_SUBST(BUILD_DNSSRV)
2346   AC_SUBST(BUILD_LDAP)
2347   AC_SUBST(BUILD_LDBM)
2348   AC_SUBST(BUILD_PASSWD)
2349   AC_SUBST(BUILD_PERL)
2350   AC_SUBST(BUILD_SHELL)
2351   AC_SUBST(BUILD_SQL)
2352   AC_SUBST(BUILD_TCL)
2353   AC_SUBST(BUILD_DNSSRV_DYNAMIC)
2354   AC_SUBST(BUILD_LDAP_DYNAMIC)
2355   AC_SUBST(BUILD_LDBM_DYNAMIC)
2356   AC_SUBST(BUILD_PASSWD_DYNAMIC)
2357   AC_SUBST(BUILD_PERL_DYNAMIC)
2358   AC_SUBST(BUILD_SHELL_DYNAMIC)
2359   AC_SUBST(BUILD_SQL_DYNAMIC)
2360   AC_SUBST(BUILD_TCL_DYNAMIC)
2361 AC_SUBST(BUILD_SLURPD)
2362
2363 AC_SUBST(LDAP_LIBS)
2364 AC_SUBST(LDIF_LIBS)
2365 AC_SUBST(SLAPD_LIBS)
2366 AC_SUBST(SLURPD_LIBS)
2367 AC_SUBST(LDBM_LIBS)
2368 AC_SUBST(LTHREAD_LIBS)
2369 AC_SUBST(LUTIL_LIBS)
2370 AC_SUBST(WRAP_LIBS)
2371 AC_SUBST(MOD_TCL_LIB)
2372 AC_SUBST(LINK_BINS_DYNAMIC)
2373
2374 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
2375 AC_SUBST(SLAPD_MODULES_LDFLAGS)
2376 AC_SUBST(SLAPD_MODULES_LIST)
2377
2378 AC_SUBST(PERL_CPPFLAGS)
2379 AC_SUBST(SLAPD_PERL_LDFLAGS)
2380 AC_SUBST(MOD_PERL_LDFLAGS)
2381
2382 AC_SUBST(KRB4_LIBS)
2383 AC_SUBST(KRB5_LIBS)
2384 AC_SUBST(READLINE_LIBS)
2385 AC_SUBST(SASL_LIBS)
2386 AC_SUBST(TERMCAP_LIBS)
2387 AC_SUBST(TLS_LIBS)
2388 AC_SUBST(MODULES_LIBS)
2389 AC_SUBST(AUTH_LIBS)
2390
2391 AC_SUBST(SLAPD_SQL_LDFLAGS)
2392 AC_SUBST(SLAPD_SQL_LIBS)
2393 AC_SUBST(SLAPD_SQL_INCLUDES)
2394
2395 dnl ----------------------------------------------------------------
2396 dnl final output
2397 dnl
2398
2399 AC_OUTPUT( \
2400 Makefile:build/top.mk:Makefile.in:build/dir.mk \
2401 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
2402 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
2403 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
2404 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
2405 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
2406 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
2407 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
2408 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
2409 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
2410 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
2411 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
2412 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
2413 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
2414 clients/maildap/Makefile:build/top.mk:clients/maildap/Makefile.in:build/rules.mk \
2415 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
2416 include/Makefile:build/top.mk:include/Makefile.in \
2417 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
2418 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk:build/lib-static.mk    \
2419 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2420 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk  \
2421 libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk      \
2422 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk:build/lib-static.mk  \
2423 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk:build/lib-static.mk  \
2424 libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk  \
2425 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk        \
2426 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
2427 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
2428 servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk \
2429 servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk \
2430 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/mod.mk \
2431 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk \
2432 servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk \
2433 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk \
2434 servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk \
2435 servers/slapd/back-tcl/Makefile:build/top.mk:servers/slapd/back-tcl/Makefile.in:build/mod.mk \
2436 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
2437 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
2438 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
2439 tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk \
2440 tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk \
2441 contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
2442 contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
2443 contrib/web_ldap/Makefile:build/top.mk:contrib/web_ldap/Makefile.in:build/rules.mk \
2444 ,[
2445 date > stamp-h
2446 echo Please \"make depend\" to build dependencies
2447 ])