git.sur5r.net Git - openldap/blob - configure.in

   1 dnl $OpenLDAP$
   2 dnl This work is part of OpenLDAP Software <http://www.openldap.org/>.
   3 dnl
   4 dnl Copyright 1998-2008 The OpenLDAP Foundation.
   5 dnl All rights reserved.
   6 dnl
   7 dnl Redistribution and use in source and binary forms, with or without
   8 dnl modification, are permitted only as authorized by the OpenLDAP
   9 dnl Public License.
  10 dnl
  11 dnl A copy of this license is available in the file LICENSE in the
  12 dnl top-level directory of the distribution or, alternatively, at
  13 dnl <http://www.OpenLDAP.org/license.html>.
  14 dnl
  15 dnl ----------------------------------------------------------------
  16 dnl Disable config.cache!
  17 define([AC_CACHE_LOAD], )dnl
  18 define([AC_CACHE_SAVE], )dnl
  19 dnl ----------------------------------------------------------------
  20 dnl Disable libtool 1.5 support for languages we don't use
  21 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  22 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  23 define([AC_LIBTOOL_LANG_GCJ_CONFIG], [:])dnl
  24 dnl ================================================================
  25 dnl Configure.in for OpenLDAP
  26 AC_COPYRIGHT([[Copyright 1998-2008 The OpenLDAP Foundation. All rights reserved.
  27 Restrictions apply, see COPYRIGHT and LICENSE files.]])
  28 AC_REVISION([$OpenLDAP$])
  29 AC_INIT([OpenLDAP],,[http://www.openldap.org/its/])
  30 m4_define([AC_PACKAGE_BUGREPORT],[<http://www.openldap.org/its/>])
  31 AC_CONFIG_SRCDIR(build/version.sh)dnl
  32 dnl ----------------------------------------------------------------
  33 dnl OpenLDAP Autoconf Macros
  34 builtin(include, build/openldap.m4)dnl
  35 dnl ================================================================
  36
  37 AC_CONFIG_AUX_DIR(build)dnl
  38
  39 eval `$ac_aux_dir/version.sh`
  40 if test -z "$OL_STRING"; then
  41         AC_MSG_ERROR([could not determine version])
  42 fi
  43
  44 if test -f "$ac_aux_dir/shtool" && test ! -d $ac_aux_dir/shtool; then
  45         ac_cv_shtool="$ac_aux_dir/shtool"
  46 else
  47         AC_MSG_ERROR([no shtool found in $ac_aux_dir])
  48 fi
  49
  50 SHTOOL="$ac_cv_shtool"
  51 dnl AC_SUBST(SHTOOL)dnl
  52
  53 TB="" TN=""
  54 if test -t 1; then
  55         TB="`$SHTOOL echo -e '%B' 2>/dev/null`"
  56         TN="`$SHTOOL echo -e '%b' 2>/dev/null`"
  57 fi
  58
  59 OPENLDAP_CVS=""
  60 if test -d $ac_aux_dir/CVS; then
  61         OPENLDAP_CVS="(from CVS sources) "
  62 fi
  63
  64 echo "Configuring ${TB}${OL_STRING}${TN} ${OPENLDAP_CVS}..."
  65
  66 dnl Determine host platform
  67 dnl             we try not to use this for much
  68 AC_CANONICAL_TARGET([])
  69
  70 AM_INIT_AUTOMAKE([$OL_PACKAGE],[$OL_VERSION], [no defines])dnl
  71 AC_SUBST(PACKAGE)dnl
  72 AC_SUBST(VERSION)dnl
  73 AC_DEFINE_UNQUOTED(OPENLDAP_PACKAGE,"$PACKAGE",Package)
  74 AC_DEFINE_UNQUOTED(OPENLDAP_VERSION,"$VERSION",Version)
  75
  76 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION,$OL_API_INC,Version)
  77 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MAJOR,$OL_MAJOR,Major)
  78 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_MINOR,$OL_MINOR,Minor)
  79 AC_DEFINE_UNQUOTED(LDAP_VENDOR_VERSION_PATCH,$OL_PATCH,Patch)
  80
  81 OPENLDAP_LIBRELEASE=$OL_API_LIB_RELEASE
  82 AC_SUBST(OPENLDAP_LIBRELEASE)dnl
  83
  84 OPENLDAP_LIBVERSION=$OL_API_LIB_VERSION
  85 AC_SUBST(OPENLDAP_LIBVERSION)dnl
  86
  87 OPENLDAP_RELEASE_DATE="$OL_RELEASE_DATE"
  88 AC_SUBST(OPENLDAP_RELEASE_DATE)dnl
  89
  90 dnl We use autoconf features new to 2.59.  Later versions like won't work.
  91 dnl aclocal.m4 should be built using aclocal from automake 1.5
  92 dnl libtool 1.5 should be installed.
  93 AC_PREREQ(2.59)dnl Required Autoconf version
  94
  95 AH_TOP([
  96 /* begin of portable.h.pre */
  97 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
  98  *
  99  * Copyright 1998-2008 The OpenLDAP Foundation
 100  * All rights reserved.
 101  *
 102  * Redistribution and use in source and binary forms, with or without
 103  * modification, are permitted only as authorized by the OpenLDAP
 104  * Public License.
 105  *
 106  * A copy of this license is available in the file LICENSE in the
 107  * top-level directory of the distribution or, alternatively, at
 108  * <http://www.OpenLDAP.org/license.html>.
 109  */
 110
 111 #ifndef _LDAP_PORTABLE_H
 112 #define _LDAP_PORTABLE_H
 113
 114 /* define this if needed to get reentrant functions */
 115 #ifndef REENTRANT
 116 #undef REENTRANT
 117 #endif
 118 #ifndef _REENTRANT
 119 #undef _REENTRANT
 120 #endif
 121
 122 /* define this if needed to get threadsafe functions */
 123 #ifndef THREADSAFE
 124 #undef THREADSAFE
 125 #endif
 126 #ifndef _THREADSAFE
 127 #undef _THREADSAFE
 128 #endif
 129 #ifndef THREAD_SAFE
 130 #undef THREAD_SAFE
 131 #endif
 132 #ifndef _THREAD_SAFE
 133 #undef _THREAD_SAFE
 134 #endif
 135
 136 #ifndef _SGI_MP_SOURCE
 137 #undef _SGI_MP_SOURCE
 138 #endif
 139
 140 /* end of portable.h.pre */
 141 ])
 142 AH_BOTTOM([
 143 /* begin of portable.h.post */
 144
 145 #ifdef _WIN32
 146         /* don't suck in all of the win32 api */
 147 #       define WIN32_LEAN_AND_MEAN 1
 148 #endif
 149
 150 #ifndef LDAP_NEEDS_PROTOTYPES
 151 /* force LDAP_P to always include prototypes */
 152 #define LDAP_NEEDS_PROTOTYPES 1
 153 #endif
 154
 155 #ifndef LDAP_REL_ENG
 156 #if (LDAP_VENDOR_VERSION == 000000) && !defined(LDAP_DEVEL)
 157 #define LDAP_DEVEL
 158 #endif
 159 #if defined(LDAP_DEVEL) && !defined(LDAP_TEST)
 160 #define LDAP_TEST
 161 #endif
 162 #endif
 163
 164 #ifdef HAVE_STDDEF_H
 165 #       include <stddef.h>
 166 #endif
 167
 168 #ifdef HAVE_EBCDIC
 169 /* ASCII/EBCDIC converting replacements for stdio funcs
 170  * vsnprintf and snprintf are used too, but they are already
 171  * checked by the configure script
 172  */
 173 #define fputs ber_pvt_fputs
 174 #define fgets ber_pvt_fgets
 175 #define printf ber_pvt_printf
 176 #define fprintf ber_pvt_fprintf
 177 #define vfprintf ber_pvt_vfprintf
 178 #define vsprintf ber_pvt_vsprintf
 179 #endif
 180
 181 #include "ac/fdset.h"
 182
 183 #include "ldap_cdefs.h"
 184 #include "ldap_features.h"
 185
 186 #include "ac/assert.h"
 187 #include "ac/localize.h"
 188
 189 #endif /* _LDAP_PORTABLE_H */
 190 /* end of portable.h.post */
 191 ])
 192
 193 AC_CONFIG_HEADERS([include/portable.h:include/portable.hin])
 194 AC_CONFIG_HEADERS([include/ldap_features.h:include/ldap_features.hin])
 195 AC_CONFIG_HEADERS([include/lber_types.h:include/lber_types.hin])
 196
 197 dnl ================================================================
 198 dnl Start Args
 199 AC_MSG_CHECKING(configure arguments)
 200 AC_PREFIX_DEFAULT(/usr/local)
 201
 202 top_builddir=`pwd`
 203 AC_SUBST(top_builddir)dnl
 204
 205 dnl ----------------------------------------------------------------
 206 dnl --with-subdir
 207 ldap_subdir="/openldap"
 208
 209 AC_ARG_WITH(subdir,
 210 [  --with-subdir=DIR       change default subdirectory used for installs],
 211 [case "$withval" in
 212         no) ldap_subdir=""
 213                 ;;
 214         yes)
 215                 ;;
 216         /*|\\*)
 217                 ldap_subdir="$withval"
 218                 ;;
 219         *)
 220                 ldap_subdir="/$withval"
 221                 ;;
 222 esac
 223 ])dnl
 224
 225 AC_SUBST(ldap_subdir)dnl
 226
 227 dnl ----------------------------------------------------------------
 228 dnl General "enable" options
 229 dnl set default to traditional to enable the original debug style
 230 OL_ARG_ENABLE(debug,[  --enable-debug     enable debugging], yes, [no yes traditional])dnl
 231 OL_ARG_ENABLE(dynamic,[  --enable-dynamic         enable linking built binaries with dynamic libs], no)dnl
 232 OL_ARG_ENABLE(syslog,[  --enable-syslog   enable syslog support], auto)dnl
 233 OL_ARG_ENABLE(proctitle,[  --enable-proctitle     enable proctitle support], yes)dnl
 234 dnl OL_ARG_ENABLE(referrals,[  --enable-referrals         enable LDAPv2+ Referrals (experimental)], no)dnl
 235 ol_enable_referrals=${ol_enable_referrals-no}
 236 OL_ARG_ENABLE(ipv6,[  --enable-ipv6       enable IPv6 support], auto)dnl
 237 OL_ARG_ENABLE(local,[  --enable-local     enable AF_LOCAL (AF_UNIX) socket support], auto)dnl
 238
 239 dnl ----------------------------------------------------------------
 240 dnl General "with" options
 241 OL_ARG_WITH(cyrus_sasl,[  --with-cyrus-sasl       with Cyrus SASL support],
 242         auto, [auto yes no] )
 243 OL_ARG_WITH(fetch,[  --with-fetch                 with fetch(3) URL support],
 244         auto, [auto yes no] )
 245 OL_ARG_WITH(threads,[  --with-threads     with threads],
 246         auto, [auto nt posix mach pth lwp yes no manual] )
 247 OL_ARG_WITH(tls,[  --with-tls             with TLS/SSL support auto|openssl|gnutls],
 248         auto, [auto openssl gnutls yes no] )
 249 OL_ARG_WITH(yielding_select,
 250         [  --with-yielding-select  with implicitly yielding select],
 251         auto, [auto yes no manual] )
 252 OL_ARG_WITH(mp,
 253         [  --with-mp               with multiple precision statistics auto|longlong|long|bignum|gmp],
 254         auto, [auto longlong long bignum gmp yes no])
 255 OL_ARG_WITH(odbc,
 256         [  --with-odbc             with specific ODBC support iodbc|unixodbc|odbc32|auto],
 257         auto, [auto iodbc unixodbc odbc32] )
 258
 259 dnl ----------------------------------------------------------------
 260 dnl Server options
 261 dnl ----------------------------------------------------------------
 262
 263 dnl ----------------------------------------------------------------
 264 dnl SLAPD OPTIONS
 265 AC_ARG_ENABLE(xxslapdoptions,[
 266 SLAPD (Standalone LDAP Daemon) Options:])
 267 OL_ARG_ENABLE(slapd,[  --enable-slapd     enable building slapd], yes)dnl
 268 OL_ARG_ENABLE(dynacl,[    --enable-dynacl         enable run-time loadable ACL support (experimental)], no)dnl
 269 OL_ARG_ENABLE(aci,[    --enable-aci       enable per-object ACIs (experimental)], no, [no yes mod])dnl
 270 OL_ARG_ENABLE(cleartext,[    --enable-cleartext   enable cleartext passwords], yes)dnl
 271 OL_ARG_ENABLE(crypt,[    --enable-crypt   enable crypt(3) passwords], no)dnl
 272 OL_ARG_ENABLE(lmpasswd,[    --enable-lmpasswd     enable LAN Manager passwords], no)dnl
 273 OL_ARG_ENABLE(spasswd,[    --enable-spasswd       enable (Cyrus) SASL password verification], no)dnl
 274 OL_ARG_ENABLE(modules,[    --enable-modules       enable dynamic module support], no)dnl
 275 OL_ARG_ENABLE(rewrite,[    --enable-rewrite       enable DN rewriting in back-ldap and rwm overlay], auto)dnl
 276 OL_ARG_ENABLE(rlookups,[    --enable-rlookups     enable reverse lookups of client hostnames], no)dnl
 277 OL_ARG_ENABLE(slapi,[    --enable-slapi        enable SLAPI support (experimental)], no)dnl
 278 OL_ARG_ENABLE(slp,[    --enable-slp          enable SLPv2 support], no)dnl
 279 OL_ARG_ENABLE(wrappers,[    --enable-wrappers     enable tcp wrapper support], no)dnl
 280
 281 dnl ----------------------------------------------------------------
 282 dnl SLAPD Backend Options
 283 Backends="bdb \
 284         dnssrv \
 285         hdb \
 286         ldap \
 287         meta \
 288         monitor \
 289         ndb \
 290         null \
 291         passwd \
 292         perl \
 293         relay \
 294         shell \
 295         sock \
 296         sql"
 297
 298 AC_ARG_ENABLE(xxslapbackends,[
 299 SLAPD Backend Options:])
 300
 301 OL_ARG_ENABLE(backends,[    --enable-backends     enable all available backends],
 302         --, [no yes mod])dnl
 303 OL_ARG_ENABLE(bdb,[    --enable-bdb       enable Berkeley DB backend],
 304         yes, [no yes mod], ol_enable_backends)dnl
 305 OL_ARG_ENABLE(dnssrv,[    --enable-dnssrv         enable dnssrv backend],
 306         no, [no yes mod], ol_enable_backends)dnl
 307 OL_ARG_ENABLE(hdb,[    --enable-hdb       enable Hierarchical DB backend],
 308         yes, [no yes mod], ol_enable_backends)dnl
 309 OL_ARG_ENABLE(ldap,[    --enable-ldap     enable ldap backend],
 310         no, [no yes mod], ol_enable_backends)dnl
 311 OL_ARG_ENABLE(meta,[    --enable-meta     enable metadirectory backend],
 312         no, [no yes mod], ol_enable_backends)dnl
 313 OL_ARG_ENABLE(monitor,[    --enable-monitor       enable monitor backend],
 314         yes, [no yes mod], ol_enable_backends)dnl
 315 OL_ARG_ENABLE(ndb,[    --enable-ndb       enable MySQL NDB Cluster backend],
 316         no, [no yes mod], ol_enable_backends)dnl
 317 OL_ARG_ENABLE(null,[    --enable-null     enable null backend],
 318         no, [no yes mod], ol_enable_backends)dnl
 319 OL_ARG_ENABLE(passwd,[    --enable-passwd         enable passwd backend],
 320         no, [no yes mod], ol_enable_backends)dnl
 321 OL_ARG_ENABLE(perl,[    --enable-perl     enable perl backend],
 322         no, [no yes mod], ol_enable_backends)dnl
 323 OL_ARG_ENABLE(relay,[    --enable-relay           enable relay backend],
 324         yes, [no yes mod], ol_enable_backends)dnl
 325 OL_ARG_ENABLE(shell,[    --enable-shell   enable shell backend],
 326         no, [no yes mod], ol_enable_backends)dnl
 327 OL_ARG_ENABLE(sock,[    --enable-sock     enable sock backend],
 328         no, [no yes mod], ol_enable_backends)dnl
 329 OL_ARG_ENABLE(sql,[    --enable-sql       enable sql backend],
 330         no, [no yes mod], ol_enable_backends)dnl
 331
 332 dnl ----------------------------------------------------------------
 333 dnl SLAPD Overlay Options
 334 Overlays="accesslog \
 335         auditlog \
 336         constraint \
 337         dds \
 338         dyngroup \
 339         dynlist \
 340         memberof \
 341         ppolicy \
 342         proxycache \
 343         refint \
 344         retcode \
 345         rwm \
 346         seqmod \
 347         syncprov \
 348         translucent \
 349         unique \
 350         valsort"
 351
 352 AC_ARG_ENABLE(xxslapoverlays,[
 353 SLAPD Overlay Options:])
 354
 355 OL_ARG_ENABLE(overlays,[    --enable-overlays     enable all available overlays],
 356         --, [no yes mod])dnl
 357 OL_ARG_ENABLE(accesslog,[    --enable-accesslog   In-Directory Access Logging overlay],
 358         no, [no yes mod], ol_enable_overlays)
 359 OL_ARG_ENABLE(auditlog,[    --enable-auditlog     Audit Logging overlay],
 360         no, [no yes mod], ol_enable_overlays)
 361 OL_ARG_ENABLE(constraint,[    --enable-constraint         Attribute Constraint overlay],
 362         no, [no yes mod], ol_enable_overlays)
 363 OL_ARG_ENABLE(dds,[    --enable-dds       Dynamic Directory Services overlay],
 364         no, [no yes mod], ol_enable_overlays)
 365 OL_ARG_ENABLE(dyngroup,[    --enable-dyngroup     Dynamic Group overlay],
 366         no, [no yes mod], ol_enable_overlays)
 367 OL_ARG_ENABLE(dynlist,[    --enable-dynlist       Dynamic List overlay],
 368         no, [no yes mod], ol_enable_overlays)
 369 OL_ARG_ENABLE(memberof,[    --enable-memberof     Reverse Group Membership overlay],
 370         no, [no yes mod], ol_enable_overlays)
 371 OL_ARG_ENABLE(ppolicy,[    --enable-ppolicy       Password Policy overlay],
 372         no, [no yes mod], ol_enable_overlays)
 373 OL_ARG_ENABLE(proxycache,[    --enable-proxycache         Proxy Cache overlay],
 374         no, [no yes mod], ol_enable_overlays)
 375 OL_ARG_ENABLE(refint,[    --enable-refint         Referential Integrity overlay],
 376         no, [no yes mod], ol_enable_overlays)
 377 OL_ARG_ENABLE(retcode,[    --enable-retcode       Return Code testing overlay],
 378         no, [no yes mod], ol_enable_overlays)
 379 OL_ARG_ENABLE(rwm,[    --enable-rwm               Rewrite/Remap overlay],
 380         no, [no yes mod], ol_enable_overlays)
 381 OL_ARG_ENABLE(seqmod,[    --enable-seqmod         Sequential Modify overlay],
 382         yes, [no yes mod], ol_enable_overlays)
 383 OL_ARG_ENABLE(syncprov,[    --enable-syncprov     Syncrepl Provider overlay],
 384         yes, [no yes mod], ol_enable_overlays)
 385 OL_ARG_ENABLE(translucent,[    --enable-translucent  Translucent Proxy overlay],
 386         no, [no yes mod], ol_enable_overlays)
 387 OL_ARG_ENABLE(unique,[    --enable-unique       Attribute Uniqueness overlay],
 388         no, [no yes mod], ol_enable_overlays)
 389 OL_ARG_ENABLE(valsort,[    --enable-valsort      Value Sorting overlay],
 390         no, [no yes mod], ol_enable_overlays)
 391
 392 dnl ----------------------------------------------------------------
 393 AC_ARG_ENABLE(xxliboptions,[
 394 Library Generation & Linking Options])
 395 AC_ENABLE_STATIC
 396 AC_ENABLE_SHARED
 397
 398 dnl ----------------------------------------------------------------
 399
 400 # validate options
 401 if test $ol_enable_slapd = no ; then
 402         dnl SLAPD was specificallly disabled
 403         if test $ol_enable_slapi = yes ; then
 404                 AC_MSG_WARN([slapd disabled, ignoring --enable-slapi argument])
 405         fi
 406         case "$ol_enable_backends" in yes | mod)
 407                 AC_MSG_WARN([slapd disabled, ignoring --enable-backends argument])
 408         esac
 409         for i in $Backends; do
 410                 eval "ol_tmp=\$ol_enable_$i"
 411                 if test $ol_tmp != no ; then
 412                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 413                         eval "ol_enable_$i=no"
 414                 fi
 415         done
 416         if test $ol_enable_modules = yes ; then
 417                 AC_MSG_WARN([slapd disabled, ignoring --enable-modules argument])
 418         fi
 419         if test $ol_enable_wrappers = yes ; then
 420                 AC_MSG_WARN([slapd disabled, ignoring --enable-wrappers argument])
 421         fi
 422         if test $ol_enable_rlookups = yes ; then
 423                 AC_MSG_WARN([slapd disabled, ignoring --enable-rlookups argument])
 424         fi
 425         if test $ol_enable_dynacl = yes ; then
 426                 AC_MSG_WARN([slapd disabled, ignoring --enable-dynacl argument])
 427         fi
 428         if test $ol_enable_aci != no ; then
 429                 AC_MSG_WARN([slapd disabled, ignoring --enable-aci argument])
 430         fi
 431         if test $ol_enable_rewrite = yes ; then
 432                 AC_MSG_WARN([slapd disabled, ignoring --enable-rewrite argument])
 433         fi
 434         dnl overlays
 435         case "$ol_enable_overlays" in yes | mod)
 436                 AC_MSG_WARN([slapd disabled, ignoring --enable-overlays argument])
 437         esac
 438         for i in $Overlays; do
 439                 eval "ol_tmp=\$ol_enable_$i"
 440                 if test $ol_tmp != no ; then
 441                         AC_MSG_WARN([slapd disabled, ignoring --enable-$i argument])
 442                         eval "ol_enable_$i=no"
 443                 fi
 444         done
 445
 446         # force settings to no
 447         ol_enable_slapi=no
 448
 449         ol_enable_backends=
 450         ol_enable_overlays=
 451         ol_enable_modules=no
 452         ol_enable_rlookups=no
 453         ol_enable_dynacl=no
 454         ol_enable_aci=no
 455         ol_enable_wrappers=no
 456
 457         ol_enable_rewrite=no
 458
 459 elif test $ol_enable_modules != yes &&
 460         test $ol_enable_bdb = no &&
 461         test $ol_enable_dnssrv = no &&
 462         test $ol_enable_hdb = no &&
 463         test $ol_enable_ldap = no &&
 464         test $ol_enable_meta = no &&
 465         test $ol_enable_monitor = no &&
 466         test $ol_enable_ndb = no &&
 467         test $ol_enable_null = no &&
 468         test $ol_enable_passwd = no &&
 469         test $ol_enable_perl = no &&
 470         test $ol_enable_relay = no &&
 471         test $ol_enable_shell = no &&
 472         test $ol_enable_sock = no &&
 473         test $ol_enable_sql = no ; then
 474         dnl no slapd backend
 475
 476         if test $ol_enable_slapd = yes ; then
 477                 AC_MSG_ERROR([slapd requires a backend])
 478         else
 479                 AC_MSG_WARN([skipping slapd, no backend specified])
 480                 ol_enable_slapd=no
 481         fi
 482 fi
 483
 484 if test $ol_enable_meta/$ol_enable_ldap = yes/no ; then
 485         AC_MSG_ERROR([--enable-meta requires --enable-ldap])
 486 fi
 487
 488 if test $ol_enable_lmpasswd = yes ; then
 489         if test $ol_with_tls = no ; then
 490                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
 491         fi
 492 fi
 493
 494 if test $ol_enable_spasswd = yes ; then
 495         if test $ol_with_cyrus_sasl = no ; then
 496                 AC_MSG_ERROR([options require --with-cyrus-sasl])
 497         fi
 498         ol_with_cyrus_sasl=yes
 499 fi
 500
 501 AC_MSG_RESULT(done)
 502
 503 dnl ----------------------------------------------------------------
 504 dnl Initialize vars
 505 LDAP_LIBS=
 506 BDB_LIBS=
 507 SLAPD_NDB_LIBS=
 508 SLAPD_NDB_INCS=
 509 LTHREAD_LIBS=
 510 LUTIL_LIBS=
 511
 512 SLAPD_LIBS=
 513
 514 BUILD_SLAPD=no
 515
 516 BUILD_THREAD=no
 517
 518 BUILD_SLAPI=no
 519 SLAPD_SLAPI_DEPEND=
 520
 521 BUILD_BDB=no
 522 BUILD_DNSSRV=no
 523 BUILD_HDB=no
 524 BUILD_LDAP=no
 525 BUILD_META=no
 526 BUILD_MONITOR=no
 527 BUILD_NULL=no
 528 BUILD_PASSWD=no
 529 BUILD_PERL=no
 530 BUILD_RELAY=no
 531 BUILD_SHELL=no
 532 BUILD_SOCK=no
 533 BUILD_SQL=no
 534
 535 BUILD_ACCESSLOG=no
 536 BUILD_AUDITLOG=no
 537 BUILD_CONSTRAINT=no
 538 BUILD_DDS=no
 539 BUILD_DENYOP=no
 540 BUILD_DYNGROUP=no
 541 BUILD_DYNLIST=no
 542 BUILD_LASTMOD=no
 543 BUILD_MEMBEROF=no
 544 BUILD_PPOLICY=no
 545 BUILD_PROXYCACHE=no
 546 BUILD_REFINT=no
 547 BUILD_RETCODE=no
 548 BUILD_RWM=no
 549 BUILD_SEQMOD=no
 550 BUILD_SYNCPROV=no
 551 BUILD_TRANSLUCENT=no
 552 BUILD_UNIQUE=no
 553 BUILD_VALSORT=no
 554
 555 SLAPD_STATIC_OVERLAYS=
 556 SLAPD_DYNAMIC_OVERLAYS=
 557
 558 SLAPD_MODULES_LDFLAGS=
 559 SLAPD_MODULES_CPPFLAGS=
 560
 561 SLAPD_STATIC_BACKENDS=back-ldif
 562 SLAPD_DYNAMIC_BACKENDS=
 563
 564 SLAPD_PERL_LDFLAGS=
 565 MOD_PERL_LDFLAGS=
 566 PERL_CPPFLAGS=
 567
 568 SLAPD_SQL_LDFLAGS=
 569 SLAPD_SQL_LIBS=
 570 SLAPD_SQL_INCLUDES=
 571
 572 KRB4_LIBS=
 573 KRB5_LIBS=
 574 SASL_LIBS=
 575 TLS_LIBS=
 576 MODULES_LIBS=
 577 SLAPI_LIBS=
 578 LIBSLAPI=
 579 LIBSLAPITOOLS=
 580 AUTH_LIBS=
 581 ICU_LIBS=
 582
 583 SLAPD_SLP_LIBS=
 584 SLAPD_GMP_LIBS=
 585
 586 dnl ================================================================
 587 dnl Checks for programs
 588
 589 AC_DEFINE(HAVE_MKVERSION, 1, [define this if you have mkversion])
 590
 591 dnl ----------------------------------------------------------------
 592 dnl
 593 dnl Determine which C translator to use
 594 dnl
 595
 596 dnl AIX Thread requires we use cc_r or xlc_r.
 597 dnl But only do this IF AIX and CC is not set
 598 dnl and threads are auto|yes|posix.
 599 dnl
 600 dnl If we find cc_r|xlc_r, force pthreads and assume
 601 dnl             pthread_create is in $LIBS (ie: don't bring in
 602 dnl             any additional thread libraries)
 603 dnl If we do not find cc_r|xlc_r, disable threads
 604
 605 ol_aix_threads=no
 606 case "$target" in
 607 *-*-aix*) dnl all AIX is not a good idea.
 608         if test -z "$CC" ; then
 609                 case "$ol_with_threads" in
 610                 auto | yes |  posix) ol_aix_threads=yes ;;
 611                 esac
 612         fi
 613 ;;
 614 esac
 615
 616 if test $ol_aix_threads = yes ; then
 617         if test -z "${CC}" ; then
 618                 AC_CHECK_PROGS(CC,cc_r xlc_r cc)
 619
 620                 if test "$CC" = cc ; then
 621                         dnl no CC! don't allow --with-threads
 622                         if test $ol_with_threads != auto ; then
 623                                 AC_MSG_ERROR([--with-threads requires cc_r (or other suitable compiler) on AIX])
 624                         else
 625                                 AC_MSG_WARN([disabling threads, no cc_r on AIX])
 626                         fi
 627                         ol_with_threads=no
 628                 fi
 629         fi
 630
 631         case ${CC} in cc_r | xlc_r)
 632                 ol_with_threads=posix
 633                 ol_cv_pthread_create=yes
 634                 ;;
 635         esac
 636 fi
 637
 638 if test -z "${CC}"; then
 639         AC_CHECK_PROGS(CC,cc gcc,missing)
 640
 641         if test "${CC}" = "missing" ; then
 642                 AC_MSG_ERROR([Unable to locate cc(1) or suitable replacement.  Check PATH or set CC.])
 643         fi
 644 fi
 645
 646 if test -z "${AR}"; then
 647         AC_CHECK_PROGS(AR,ar gar,missing)
 648
 649         if test "${AR}" = "missing" ; then
 650                 AC_MSG_ERROR([Unable to locate ar(1) or suitable replacement.  Check PATH or set AR.])
 651         fi
 652 fi
 653
 654 AC_LIBTOOL_WIN32_DLL
 655 AC_LIBTOOL_DLOPEN
 656 AC_PROG_LIBTOOL
 657
 658 dnl ----------------------------------------------------------------
 659 dnl Perl
 660 ol_link_perl=no
 661 if test $ol_enable_perl != no ; then
 662         AC_PATH_PROG(PERLBIN, perl, /usr/bin/perl)
 663
 664         if test "no$PERLBIN" = "no" ; then
 665                 if test $ol_enable_perl = yes ; then
 666                         AC_MSG_ERROR([could not locate perl])
 667                 fi
 668
 669         else
 670                 PERL_CPPFLAGS="`$PERLBIN -MExtUtils::Embed -e ccopts`"
 671                 PERL_LDFLAGS="`$PERLBIN -MExtUtils::Embed -e ldopts|sed -e 's/ -lc / /' -e 's/ -lc$//'`"
 672
 673                 if test x"$ol_enable_perl" = "xyes" ; then
 674                         SLAPD_PERL_LDFLAGS="$PERL_LDFLAGS"
 675                 else
 676                         MOD_PERL_LDFLAGS="$PERL_LDFLAGS"
 677                 fi
 678                 dnl should check perl version
 679                 ol_link_perl=yes
 680         fi
 681 fi
 682
 683 AC_PROG_CPP
 684
 685 dnl ----------------------------------------------------------------
 686 dnl Checks for Windows NT
 687 case $host_os in
 688   *mingw32* ) ac_cv_mingw32=yes ;;
 689   *cygwin* ) ac_cv_cygwin=yes ;;
 690 esac
 691
 692 dnl ----------------------------------------------------------------
 693 dnl Checks for file extensions
 694 AC_EXEEXT
 695 AC_OBJEXT
 696 AC_DEFINE_UNQUOTED(EXEEXT, "${EXEEXT}", [defined to be the EXE extension])
 697
 698 dnl ----------------------------------------------------------------
 699 dnl BeOS requires -lbe -lroot -lnet
 700 AC_CHECK_LIB(be, be_app, [LIBS="$LIBS -lbe -lroot -lnet"], :, [-lroot -lnet])
 701
 702 dnl ----------------------------------------------------------------
 703 dnl OpenLDAP requires STDC features
 704 AC_PROG_CC
 705 if test "X${ac_cv_prog_cc_stdc}" = "Xno" ; then
 706         AC_MSG_ERROR([OpenLDAP requires compiler to support STDC constructs.])
 707 fi
 708
 709 dnl ----------------------------------------------------------------
 710 dnl Check cc depend flags
 711 OL_MKDEPEND
 712 if test "${ol_cv_mkdep}" = no ; then
 713         # this will soon become an error
 714         AC_MSG_WARN([do not know how to generate dependencies])
 715 fi
 716
 717 dnl ----------------------------------------------------------------
 718 dnl Check for AIX security library
 719 AC_CHECK_LIB(s, afopen, [
 720         AUTH_LIBS=-ls
 721         AC_DEFINE(HAVE_AIX_SECURITY,1,[define if you have AIX security lib])
 722 ])
 723
 724 dnl ----------------------------------------------------------------
 725 dnl Check for IBM OS/390
 726 case "$target" in
 727 *-ibm-openedition)
 728         ac_cv_func_getopt=no
 729         AC_DEFINE(BOTH_STRINGS_H,1,[define to use both <string.h> and <strings.h>])
 730         ;;
 731 esac
 732
 733 dnl ----------------------------------------------------------------
 734 dnl Check for module support
 735 ol_link_modules=no
 736 WITH_MODULES_ENABLED=no
 737 if test $ol_enable_modules != no ; then
 738         AC_CHECK_HEADERS(ltdl.h)
 739
 740         if test $ac_cv_header_ltdl_h = no ; then
 741                 AC_MSG_ERROR([could not locate libtool ltdl.h])
 742         fi
 743
 744         AC_CHECK_LIB(ltdl, lt_dlinit, [
 745                 MODULES_LIBS=-lltdl
 746                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
 747         ])
 748
 749         if test "$ac_cv_lib_ltdl_lt_dlinit" = no ; then
 750                 AC_MSG_ERROR([could not locate libtool -lltdl])
 751         fi
 752         ol_link_modules=yes
 753         WITH_MODULES_ENABLED=yes
 754
 755 else
 756         for i in $Backends; do
 757                 eval "ol_tmp=\$ol_enable_$i"
 758                 if test $ol_tmp = mod ; then
 759                         AC_MSG_WARN([building static $i backend])
 760                         eval "ol_enable_$i=yes"
 761                 fi
 762         done
 763         for i in $Overlays; do
 764                 eval "ol_tmp=\$ol_enable_$i"
 765                 if test $ol_tmp = mod ; then
 766                         AC_MSG_WARN([building static $i overlay])
 767                         eval "ol_enable_$i=yes"
 768                 fi
 769         done
 770 fi
 771
 772 dnl ----------------------------------------------------------------
 773 dnl Checks for header files.
 774 OL_HEADER_STDC
 775
 776 if test $ol_cv_header_stdc != yes; then
 777         AC_MSG_WARN([could not locate Standard C compliant headers])
 778 fi
 779
 780 AC_HEADER_DIRENT
 781 AC_HEADER_SYS_WAIT
 782 AC_HEADER_TIOCGWINSZ
 783
 784 AC_CHECK_HEADERS(       \
 785         arpa/inet.h             \
 786         arpa/nameser.h  \
 787         assert.h                \
 788         bits/types.h    \
 789         conio.h                 \
 790         crypt.h                 \
 791         direct.h                \
 792         errno.h                 \
 793         fcntl.h                 \
 794         filio.h                 \
 795         getopt.h                \
 796         grp.h                   \
 797         io.h                    \
 798         libutil.h               \
 799         limits.h                \
 800         locale.h                \
 801         malloc.h                \
 802         memory.h                \
 803         psap.h                  \
 804         pwd.h                   \
 805         process.h               \
 806         sgtty.h                 \
 807         shadow.h                \
 808         stddef.h                \
 809         string.h                \
 810         strings.h               \
 811         sysexits.h              \
 812         sys/file.h              \
 813         sys/filio.h             \
 814         sys/fstyp.h             \
 815         sys/errno.h             \
 816         sys/ioctl.h             \
 817         sys/param.h             \
 818         sys/privgrp.h   \
 819         sys/resource.h  \
 820         sys/select.h    \
 821         sys/socket.h    \
 822         sys/stat.h              \
 823         sys/syslog.h    \
 824         sys/time.h              \
 825         sys/types.h             \
 826         sys/uio.h               \
 827         sys/vmount.h    \
 828         syslog.h                \
 829         termios.h               \
 830         unistd.h                \
 831         utime.h                 \
 832 )
 833
 834 dnl Only check Winsock on MinGW
 835 if test "$ac_cv_mingw32" = yes ; then
 836         AC_CHECK_HEADERS( winsock.h winsock2.h )
 837 fi
 838
 839 AC_CHECK_HEADERS( resolv.h, [], [],
 840 [$ac_includes_default
 841 #include <netinet/in.h>
 842 ])
 843
 844 AC_CHECK_HEADERS( netinet/tcp.h, [], [],
 845 [$ac_includes_default
 846 #include <netinet/in.h>
 847 ])
 848
 849 AC_CHECK_HEADERS( sys/ucred.h, [], [],
 850 [$ac_includes_default
 851 #ifdef HAVE_SYS_PARAM_H
 852 #include <sys/param.h>
 853 #endif
 854 ])
 855
 856 dnl ----------------------------------------------------------------
 857 dnl Checks for libraries
 858
 859 AC_CHECK_FUNCS( sigaction sigset )
 860
 861 dnl HP-UX requires -lV3
 862 dnl this is not needed on newer versions of HP-UX
 863 if test $ac_cv_func_sigaction = no && test $ac_cv_func_sigaction = no ; then
 864         AC_CHECK_LIB(V3, sigset)
 865 fi
 866
 867 dnl The following is INTENTIONALLY scripted out because shell does not
 868 dnl support variable names with the '@' character, which is what
 869 dnl autoconf would try to generate if one merely used AC_SEARCH_LIBS
 870 if test "$ac_cv_header_winsock_h" = yes; then
 871 AC_CACHE_CHECK([for winsock], [ol_cv_winsock],
 872 save_LIBS="$LIBS"
 873 for curlib in ws2_32 wsock32; do
 874         LIBS="$LIBS -l$curlib"
 875         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <winsock.h>
 876                         ]], [[
 877                         socket(0,0,0);
 878                         select(0,NULL,NULL,NULL,NULL);
 879                         closesocket(0);
 880                         gethostname(NULL,0);
 881                         ]])],[ol_cv_winsock=yes],[ol_cv_winsock=no])
 882
 883         if test $ol_cv_winsock = yes; then
 884                 AC_DEFINE(HAVE_WINSOCK, 1, [define if you have winsock])
 885                 ac_cv_func_socket=yes
 886                 ac_cv_func_select=yes
 887                 ac_cv_func_closesocket=yes
 888                 ac_cv_func_gethostname=yes
 889                 if test $curlib = ws2_32; then
 890                         ol_cv_winsock=winsock2
 891                         AC_DEFINE(HAVE_WINSOCK2, 1,
 892                                   [define if you have winsock2])
 893                 fi
 894                 break
 895         fi
 896         LIBS="$save_LIBS"
 897 done)
 898 fi
 899
 900 dnl Find socket()
 901 dnl Likely combinations:
 902 dnl             -lsocket [ -lnsl_s | -lnsl ]
 903 dnl             -linet
 904
 905 AC_CHECK_FUNC(socket, :, [
 906 dnl hopefully we won't include too many libraries
 907         AC_CHECK_LIB(socket, main)
 908         AC_CHECK_LIB(net, main)
 909         AC_CHECK_LIB(nsl_s, main)
 910         AC_CHECK_LIB(nsl, main)
 911         AC_CHECK_LIB(inet, socket)
 912         AC_CHECK_LIB(gen, main)
 913 ])
 914
 915 dnl require select
 916 AC_CHECK_FUNC(select, :, AC_MSG_ERROR([select() required.]))
 917
 918 if test "${ac_cv_header_winsock_h}" != yes; then
 919         dnl Select arg types
 920         dnl (if this detection becomes permenent, it and the select() detection
 921         dnl should be done before the yielding select test)
 922         AC_FUNC_SELECT_ARGTYPES
 923 fi
 924
 925 dnl check to see if system call automatically restart
 926 dnl AC_SYS_RESTARTABLE_SYSCALLS
 927
 928 dnl ----------------------------------------------------------------
 929 AC_CHECK_FUNCS( poll )
 930 if test $ac_cv_func_poll = yes; then
 931 AC_CHECK_HEADERS( poll.h sys/poll.h )
 932 fi
 933
 934 dnl ----------------------------------------------------------------
 935 AC_CHECK_HEADERS( sys/epoll.h )
 936 if test "${ac_cv_header_sys_epoll_h}" = yes; then
 937         AC_MSG_CHECKING(for epoll system call)
 938         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 939 {
 940         int epfd = epoll_create(256);
 941         exit (epfd == -1 ? 1 : 0);
 942 }]])],[AC_MSG_RESULT(yes)
 943         AC_DEFINE(HAVE_EPOLL,1, [define if your system supports epoll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 944 fi
 945
 946 dnl ----------------------------------------------------------------
 947 AC_CHECK_HEADERS( sys/devpoll.h )
 948 dnl "/dev/poll" needs <sys/poll.h> as well...
 949 if test "${ac_cv_header_sys_devpoll_h}" = yes \
 950                 -a "${ac_cv_header_poll_h}" = yes ; \
 951 then
 952         AC_MSG_CHECKING(for /dev/poll)
 953         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv)
 954 {
 955         int devpollfd = open("/dev/poll", /* O_RDWR */ 2);
 956         exit (devpollfd == -1 ? 1 : 0);
 957 }]])],[AC_MSG_RESULT(yes)
 958         AC_DEFINE(HAVE_DEVPOLL,1, [define if your system supports /dev/poll])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 959 fi
 960
 961 dnl ----------------------------------------------------------------
 962 # strerror checks
 963 OL_STRERROR
 964
 965 dnl ----------------------------------------------------------------
 966 dnl require POSIX regex
 967 AC_CHECK_HEADERS( regex.h, [], [],
 968 [$ac_includes_default
 969 #ifdef HAVE_SYS_TYPES_H
 970 #include <sys/types.h>
 971 #endif
 972 ])
 973
 974 if test "$ac_cv_header_regex_h" != yes ; then
 975         AC_MSG_ERROR([POSIX regex.h required.])
 976 fi
 977 AC_SEARCH_LIBS(regfree, [regex gnuregex],
 978         :, AC_MSG_ERROR([POSIX regex required.]))
 979
 980 OL_POSIX_REGEX
 981 if test "$ol_cv_c_posix_regex" = no ; then
 982         AC_MSG_ERROR([broken POSIX regex!])
 983 fi
 984
 985 dnl ----------------------------------------------------------------
 986 dnl UUID Support
 987
 988 have_uuid=no
 989 AC_CHECK_HEADERS(sys/uuid.h)
 990 if test $ac_cv_header_sys_uuid_h = yes ; then
 991         save_LIBS="$LIBS"
 992         AC_SEARCH_LIBS([uuid_to_str], [uuid], [have_uuid=yes], :)
 993         LIBS="$save_LIBS"
 994
 995         if test have_uuid = yes ; then
 996                 AC_DEFINE(HAVE_UUID_TO_STR,1,
 997                         [define if you have uuid_to_str()])
 998
 999                 test "$ac_cv_search_uuid_to_str" = "none required" || \
1000                         SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_to_str"
1001         fi
1002 fi
1003
1004 dnl Look for uuid_generate
1005 if test $have_uuid = no ; then
1006         AC_CHECK_HEADERS(uuid/uuid.h)
1007         if test $ac_cv_header_uuid_uuid_h = yes ; then
1008                 save_LIBS="$LIBS"
1009                 AC_SEARCH_LIBS([uuid_generate], [uuid], [have_uuid=yes], :)
1010                 LIBS="$save_LIBS"
1011
1012                 if test have_uuid = yes ; then
1013                         AC_DEFINE(HAVE_UUID_GENERATE,1,
1014                                 [define if you have uuid_generate()])
1015
1016                         test "$ac_cv_search_uuid_generate" = "none required" || \
1017                                 SLAPD_LIBS="$SLAPD_LIBS $ac_cv_search_uuid_generate"
1018                 fi
1019         fi
1020 fi
1021
1022 dnl For windows, check for the need of RPCRT for UUID function support
1023 if test $have_uuid = no ; then
1024         AC_MSG_CHECKING(to see if -lrpcrt4 is needed for win32 UUID support)
1025         save_LIBS="$LIBS"
1026         LIBS="$LIBS -lrpcrt4"
1027         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1028                 int __stdcall UuidCreate(void *);
1029                 int __stdcall UuidToStringA(void *,void **);
1030                 ]], [[
1031                 UuidCreate(0);
1032                 UuidToStringA(0,0);
1033                 ]])],[need_rpcrt=yes],[need_rpcrt=no])
1034         if test $need_rpcrt = yes; then
1035                 SLAPD_LIBS="$SLAPD_LIBS -lrpcrt4"
1036         fi
1037         LIBS="$save_LIBS"
1038         AC_MSG_RESULT($need_rpcrt)
1039 fi
1040
1041 dnl ----------------------------------------------------------------
1042 dnl Check for resolver routines
1043 OL_RESOLVER_LINK
1044
1045 ol_link_dnssrv=no
1046 if test "$ol_cv_lib_resolver" != no ; then
1047         AC_DEFINE(HAVE_RES_QUERY,1,
1048                 [define if you have res_query()])
1049
1050         if test "$ol_enable_dnssrv" != no ; then
1051                 ol_link_dnssrv=yes
1052         fi
1053
1054         if test "$ol_cv_lib_resolver" != yes ; then
1055                 LIBS="$ol_cv_lib_resolver $LIBS"
1056         fi
1057 fi
1058
1059 if test "$ol_enable_dnssrv" = yes || test "$ol_enable_dnssrv" = mod ; then
1060         if test "$ol_link_dnssrv" = no ; then
1061                 AC_MSG_ERROR([DNSSRV requires res_query()])
1062         fi
1063 else
1064         ol_enable_dnssrv=no
1065 fi
1066
1067 AC_CHECK_FUNCS( hstrerror )
1068
1069 dnl ----------------------------------------------------------------
1070 dnl PF_INET6 support requires getaddrinfo and INET6_ADDRSTRLEN
1071 dnl PF_LOCAL may use getaddrinfo in available
1072 AC_CHECK_FUNCS( getaddrinfo getnameinfo gai_strerror inet_ntop )
1073
1074 ol_link_ipv6=no
1075 if test $ac_cv_func_getaddrinfo = no || test $ac_cv_func_inet_ntop = no ; then
1076         if test $ol_enable_ipv6 = yes ; then
1077                 AC_MSG_ERROR([IPv6 support requires getaddrinfo() and inet_ntop()])
1078         fi
1079 elif test $ol_enable_ipv6 != no ; then
1080         AC_CACHE_CHECK([INET6_ADDRSTRLEN],[ol_cv_inet6_addrstrlen],[
1081                 AC_EGREP_CPP(__has_inet6_addrstrlen__,[
1082 #                       include <netinet/in.h>
1083 #                       ifdef INET6_ADDRSTRLEN
1084                                 __has_inet6_addrstrlen__;
1085 #                       endif
1086                 ], [ol_cv_inet6_addrstrlen=yes], [ol_cv_inet6_addrstrlen=no])])
1087
1088
1089         AC_CACHE_CHECK([struct sockaddr_storage],ol_cv_struct_sockaddr_storage,[
1090                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1091 #include <sys/types.h>
1092 #include <sys/socket.h>
1093 ]], [[
1094                         struct sockaddr_storage ss;
1095 ]])],[ol_cv_struct_sockaddr_storage=yes],[ol_cv_struct_sockaddr_storage=no])])
1096
1097         if test $ol_cv_inet6_addrstrlen = yes &&
1098            test $ol_cv_struct_sockaddr_storage = yes ; then
1099                 ol_link_ipv6=yes
1100         elif test $ol_enable_ipv6 = yes &&
1101              test $ol_cv_inet6_addrstrlen = no ; then
1102                 AC_MSG_ERROR([IPv6 support requires INET6_ADDRSTRLEN])
1103         elif test $ol_enable_ipv6 = yes &&
1104              test $ol_cv_struct_sockaddr_storage = no ; then
1105                 AC_MSG_ERROR([IPv6 support requires struct sockaddr_storage])
1106         fi
1107 fi
1108
1109 if test $ol_enable_local != no ; then
1110         AC_CHECK_HEADERS( sys/un.h )
1111
1112         if test $ol_enable_local = auto ; then
1113                 ol_enable_local=$ac_cv_header_sys_un_h
1114         elif test $ac_cv_header_sys_un_h = no ; then
1115                 AC_MSG_ERROR([AF_LOCAL domain support requires sys/un.h])
1116         fi
1117 fi
1118
1119 dnl ----------------------------------------------------------------
1120 dnl TLS/SSL
1121
1122 if test $ol_with_tls = yes ; then
1123         ol_with_tls=auto
1124 fi
1125
1126 ol_link_tls=no
1127 if test $ol_with_tls = openssl || test $ol_with_tls = auto ; then
1128         AC_CHECK_HEADERS(openssl/ssl.h)
1129
1130         if test $ac_cv_header_openssl_ssl_h = yes ; then
1131                 AC_CHECK_LIB(ssl, SSL_library_init,
1132                         [have_openssl=yes
1133                         need_rsaref=no], [have_openssl=no],
1134                         [-lcrypto])
1135
1136                 if test $have_openssl = no ; then
1137                         AC_CHECK_LIB(ssl, ssl3_accept,
1138                                 [have_openssl=yes
1139                                 need_rsaref=yes], [have_openssl=no],
1140                                 [-lcrypto -lRSAglue -lrsaref])
1141                 fi
1142
1143                 if test $have_openssl = yes ; then
1144                         ol_with_tls=openssl
1145                         ol_link_tls=yes
1146
1147                         AC_DEFINE(HAVE_OPENSSL, 1,
1148                                 [define if you have OpenSSL])
1149
1150                         if test $need_rsaref = yes; then
1151                                 AC_DEFINE(HAVE_RSAREF, 1,
1152                                         [define if OpenSSL needs RSAref])
1153
1154                                 TLS_LIBS="-lssl -lcrypto -lRSAglue -lrsaref"
1155                         else
1156                                 TLS_LIBS="-lssl -lcrypto"
1157                         fi
1158
1159                         OL_SSL_COMPAT
1160                         if test $ol_cv_ssl_crl_compat = yes ; then
1161                                 AC_DEFINE(HAVE_OPENSSL_CRL, 1,
1162                                         [define if you have OpenSSL with CRL checking capability])
1163                         fi
1164                 fi
1165         fi
1166 fi
1167
1168 if test $ol_link_tls = no ; then
1169         if test $ol_with_tls = gnutls || test $ol_with_tls = auto ; then
1170                 AC_CHECK_HEADERS(gnutls/gnutls.h)
1171
1172                 if test $ac_cv_header_gnutls_gnutls_h = yes ; then
1173                         AC_CHECK_LIB(gnutls, gnutls_init,
1174                                 [have_gnutls=yes], [have_gnutls=no])
1175
1176                         if test $have_gnutls = yes ; then
1177                                 ol_with_tls=gnutls
1178                                 ol_link_tls=yes
1179
1180                                 TLS_LIBS="-lgnutls"
1181
1182                                 AC_DEFINE(HAVE_GNUTLS, 1,
1183                                         [define if you have GNUtls])
1184                         fi
1185                 fi
1186         fi
1187 fi
1188
1189 WITH_TLS=no
1190 if test $ol_link_tls = yes ; then
1191         AC_DEFINE(HAVE_TLS, 1, [define if you have TLS])
1192         WITH_TLS=yes
1193 elif test $ol_with_tls = auto ; then
1194         AC_MSG_WARN([Could not locate TLS/SSL package])
1195         AC_MSG_WARN([TLS data protection not supported!])
1196 elif test $ol_with_tls != no ; then
1197         AC_MSG_ERROR([Could not locate TLS/SSL package])
1198 else
1199         AC_MSG_WARN([TLS data protection not supported!])
1200 fi
1201
1202 dnl ----------------------------------------------------------------
1203 dnl LAN Manger password checking requires DES from OpenSSL
1204 if test $ol_enable_lmpasswd != no; then
1205         if test $ol_link_tls != yes ; then
1206                 AC_MSG_ERROR([LAN Manager passwords require OpenSSL])
1207         fi
1208
1209         AC_DEFINE(SLAPD_LMHASH, 1, [define to support LAN Manager passwords])
1210 fi
1211
1212 dnl ----------------------------------------------------------------
1213 dnl Threads?
1214 ol_link_threads=no
1215
1216 case $ol_with_threads in auto | yes | nt)
1217
1218         OL_NT_THREADS
1219
1220         if test "$ol_cv_nt_threads" = yes ; then
1221                 ol_link_threads=nt
1222                 ol_with_threads=found
1223                 ol_with_yielding_select=yes
1224
1225                 AC_DEFINE(HAVE_NT_SERVICE_MANAGER,1,[if you have NT Service Manager])
1226                 AC_DEFINE(HAVE_NT_EVENT_LOG,1,[if you have NT Event Log])
1227         fi
1228
1229         if test $ol_with_threads = nt ; then
1230                 AC_MSG_ERROR([could not locate NT Threads])
1231         fi
1232         ;;
1233 esac
1234
1235 case $ol_with_threads in auto | yes | posix)
1236
1237         AC_CHECK_HEADERS(pthread.h)
1238
1239         if test $ac_cv_header_pthread_h = yes ; then
1240                 OL_POSIX_THREAD_VERSION
1241
1242                 if test $ol_cv_pthread_version != 0 ; then
1243                         AC_DEFINE_UNQUOTED(HAVE_PTHREADS,$ol_cv_pthread_version,
1244                                 [define to pthreads API spec revision])
1245                 else
1246                         AC_MSG_ERROR([unknown pthread version])
1247                 fi
1248
1249                 # consider threads found
1250                 ol_with_threads=found
1251
1252                 OL_HEADER_LINUX_THREADS
1253                 OL_HEADER_GNU_PTH_PTHREAD_H
1254
1255                 if test $ol_cv_header_gnu_pth_pthread_h = no ; then
1256                         AC_CHECK_HEADERS(sched.h)
1257                 fi
1258
1259                 dnl Now the hard part, how to link?
1260                 dnl
1261                 dnl currently supported checks:
1262                 dnl
1263                 dnl Check for no flags
1264                 dnl     pthread_create() in $LIBS
1265                 dnl
1266                 dnl Check special pthread (final) flags
1267                 dnl     [skipped] pthread_create() with -mt (Solaris) [disabled]
1268                 dnl     pthread_create() with -kthread (FreeBSD)
1269                 dnl     pthread_create() with -pthread (FreeBSD/Digital Unix)
1270                 dnl     pthread_create() with -pthreads (?)
1271                 dnl     pthread_create() with -mthreads (AIX)
1272                 dnl     pthread_create() with -thread (?)
1273                 dnl
1274                 dnl Check pthread (final) libraries
1275                 dnl     pthread_mutex_unlock() in -lpthread -lmach -lexc -lc_r (OSF/1)
1276                 dnl     pthread_mutex_lock() in -lpthread -lmach -lexc (OSF/1)
1277                 dnl     [skipped] pthread_mutex_trylock() in -lpthread -lexc (OSF/1)
1278                 dnl     pthread_join() -Wl,-woff,85 -lpthread (IRIX)
1279                 dnl     pthread_create() in -lpthread (many)
1280                 dnl     pthread_create() in -lc_r (FreeBSD)
1281                 dnl
1282                 dnl Check pthread (draft4) flags (depreciated)
1283                 dnl     pthread_create() with -threads (OSF/1)
1284                 dnl
1285                 dnl Check pthread (draft4) libraries (depreciated)
1286                 dnl     pthread_mutex_unlock() in -lpthreads -lmach -lexc -lc_r (OSF/1)
1287                 dnl     pthread_mutex_lock() in -lpthreads -lmach -lexc (OSF/1)
1288                 dnl     pthread_mutex_trylock() in -lpthreads -lexc (OSF/1)
1289                 dnl     pthread_create() in -lpthreads (many)
1290                 dnl
1291
1292                 dnl pthread_create in $LIBS
1293                 AC_CACHE_CHECK([for pthread_create in default libraries],
1294                         ol_cv_pthread_create,[
1295                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1296                                 [ol_cv_pthread_create=yes],
1297                                 [ol_cv_pthread_create=no],
1298                                 [AC_TRY_LINK(OL_PTHREAD_TEST_INCLUDES,OL_PTHREAD_TEST_FUNCTION,
1299                                         [ol_cv_pthread_create=yes],
1300                                         [ol_cv_pthread_create=no])])])
1301
1302                 if test $ol_cv_pthread_create != no ; then
1303                         ol_link_threads=posix
1304                         ol_link_pthreads=""
1305                 fi
1306
1307 dnl             OL_PTHREAD_TRY([-mt],           [ol_cv_pthread_mt])
1308                 OL_PTHREAD_TRY([-kthread],      [ol_cv_pthread_kthread])
1309                 OL_PTHREAD_TRY([-pthread],      [ol_cv_pthread_pthread])
1310                 OL_PTHREAD_TRY([-pthreads],     [ol_cv_pthread_pthreads])
1311                 OL_PTHREAD_TRY([-mthreads],     [ol_cv_pthread_mthreads])
1312                 OL_PTHREAD_TRY([-thread],       [ol_cv_pthread_thread])
1313
1314                 OL_PTHREAD_TRY([-lpthread -lmach -lexc -lc_r],
1315                         [ol_cv_pthread_lpthread_lmach_lexc_lc_r])
1316                 OL_PTHREAD_TRY([-lpthread -lmach -lexc],
1317                         [ol_cv_pthread_lpthread_lmach_lexc])
1318 dnl             OL_PTHREAD_TRY([-lpthread -lexc],
1319 dnl                     [ol_cv_pthread_lpthread_lexc])
1320
1321                 OL_PTHREAD_TRY([-lpthread -Wl,-woff,85],
1322                         [ol_cv_pthread_lib_lpthread_woff])
1323
1324                 OL_PTHREAD_TRY([-lpthread],     [ol_cv_pthread_lpthread])
1325                 OL_PTHREAD_TRY([-lc_r],         [ol_cv_pthread_lc_r])
1326
1327                 OL_PTHREAD_TRY([-threads],      [ol_cv_pthread_threads])
1328
1329                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc -lc_r],
1330                         [ol_cv_pthread_lpthreads_lmach_lexc_lc_r])
1331                 OL_PTHREAD_TRY([-lpthreads -lmach -lexc],
1332                         [ol_cv_pthread_lpthreads_lmach_lexc])
1333                 OL_PTHREAD_TRY([-lpthreads -lexc],
1334                         [ol_cv_pthread_lpthreads_lexc])
1335
1336                 OL_PTHREAD_TRY([-lpthreads],[ol_cv_pthread_lib_lpthreads])
1337
1338                 if test $ol_link_threads != no ; then
1339                         LTHREAD_LIBS="$LTHREAD_LIBS $ol_link_pthreads"
1340
1341                         dnl save flags
1342                         save_CPPFLAGS="$CPPFLAGS"
1343                         save_LIBS="$LIBS"
1344                         LIBS="$LTHREAD_LIBS $LIBS"
1345
1346                         dnl All POSIX Thread (final) implementations should have
1347                         dnl sched_yield instead of pthread yield.
1348                         dnl check for both, and thr_yield for Solaris
1349                         AC_CHECK_FUNCS(sched_yield pthread_yield thr_yield)
1350
1351                         if test $ac_cv_func_sched_yield = no &&
1352                            test $ac_cv_func_pthread_yield = no &&
1353                            test $ac_cv_func_thr_yield = no ; then
1354                                 dnl Digital UNIX has sched_yield() in -lrt
1355                                 AC_CHECK_LIB(rt, sched_yield,
1356                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
1357                                         AC_DEFINE(HAVE_SCHED_YIELD,1,
1358                                                 [Define if you have the sched_yield function.])
1359                                         ac_cv_func_sched_yield=yes],
1360                                         [ac_cv_func_sched_yield=no])
1361                         fi
1362                         if test $ac_cv_func_sched_yield = no &&
1363                            test $ac_cv_func_pthread_yield = no &&
1364                            test "$ac_cv_func_thr_yield" = no ; then
1365                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
1366                         fi
1367
1368                         dnl Check functions for compatibility
1369                         AC_CHECK_FUNCS(pthread_kill)
1370
1371                         dnl Check for pthread_rwlock_destroy with <pthread.h>
1372                         dnl as pthread_rwlock_t may not be defined.
1373                         AC_CACHE_CHECK([for pthread_rwlock_destroy with <pthread.h>],
1374                                 [ol_cv_func_pthread_rwlock_destroy], [
1375                                 dnl save the flags
1376                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1377 #include <pthread.h>
1378 pthread_rwlock_t rwlock;
1379 ]], [[pthread_rwlock_destroy(&rwlock);]])],[ol_cv_func_pthread_rwlock_destroy=yes],[ol_cv_func_pthread_rwlock_destroy=no])
1380                         ])
1381                         if test $ol_cv_func_pthread_rwlock_destroy = yes ; then
1382                                 AC_DEFINE(HAVE_PTHREAD_RWLOCK_DESTROY,1,
1383                                         [define if you have pthread_rwlock_destroy function])
1384                         fi
1385
1386                         dnl Check for pthread_detach with <pthread.h> inclusion
1387                         dnl as it's symbol may have been mangled.
1388                         AC_CACHE_CHECK([for pthread_detach with <pthread.h>],
1389                                 [ol_cv_func_pthread_detach], [
1390                                 dnl save the flags
1391                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1392 #include <pthread.h>
1393 #ifndef NULL
1394 #define NULL (void*)0
1395 #endif
1396 ]], [[pthread_detach(NULL);]])],[ol_cv_func_pthread_detach=yes],[ol_cv_func_pthread_detach=no])
1397                         ])
1398
1399                         if test $ol_cv_func_pthread_detach = no ; then
1400                                 AC_MSG_ERROR([could not locate pthread_detach()])
1401                         fi
1402
1403                         AC_DEFINE(HAVE_PTHREAD_DETACH,1,
1404                                 [define if you have pthread_detach function])
1405
1406                         dnl Check for setconcurreny functions
1407                         AC_CHECK_FUNCS( \
1408                                 pthread_setconcurrency \
1409                                 pthread_getconcurrency \
1410                                 thr_setconcurrency \
1411                                 thr_getconcurrency \
1412                         )
1413
1414                         OL_SYS_LINUX_THREADS
1415                         OL_LINUX_THREADS
1416
1417                         if test $ol_cv_linux_threads = error; then
1418                                 AC_MSG_ERROR([LinuxThreads header/library mismatch]);
1419                         fi
1420
1421                         AC_CACHE_CHECK([if pthread_create() works],
1422                                 ol_cv_pthread_create_works,[
1423                         AC_RUN_IFELSE([OL_PTHREAD_TEST_PROGRAM],
1424                                 [ol_cv_pthread_create_works=yes],
1425                                 [ol_cv_pthread_create_works=no],
1426                                 [dnl assume yes
1427                                 ol_cv_pthread_create_works=yes])])
1428
1429                         if test $ol_cv_pthread_create_works = no ; then
1430                                 AC_MSG_ERROR([pthread_create is not usable, check environment settings])
1431                         fi
1432
1433                         ol_replace_broken_yield=no
1434 dnl                     case "$target" in
1435 dnl                     *-*-linux*)
1436 dnl                             AC_CHECK_FUNCS(nanosleep)
1437 dnl                             ol_replace_broken_yield=yes
1438 dnl                     ;;
1439 dnl                     esac
1440
1441                         if test $ol_replace_broken_yield = yes ; then
1442                                 AC_DEFINE([REPLACE_BROKEN_YIELD],1,
1443                                         [define if sched_yield yields the entire process])
1444                         fi
1445
1446                         dnl Check if select causes an yield
1447                         if test $ol_with_yielding_select = auto ; then
1448                                 AC_CACHE_CHECK([if select yields when using pthreads],
1449                                         ol_cv_pthread_select_yields,[
1450                                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1451 #include <sys/types.h>
1452 #include <sys/time.h>
1453 #include <unistd.h>
1454 #include <pthread.h>
1455 #ifndef NULL
1456 #define NULL (void*) 0
1457 #endif
1458
1459 static int fildes[2];
1460
1461 static void *task(p)
1462         void *p;
1463 {
1464         int i;
1465         struct timeval tv;
1466
1467         fd_set rfds;
1468
1469         tv.tv_sec=10;
1470         tv.tv_usec=0;
1471
1472         FD_ZERO(&rfds);
1473         FD_SET(fildes[0], &rfds);
1474
1475         /* we're not interested in any fds */
1476         i = select(FD_SETSIZE, &rfds, NULL, NULL, &tv);
1477
1478         if(i < 0) {
1479                 perror("select");
1480                 exit(10);
1481         }
1482
1483         exit(0); /* if we exit here, the select blocked the whole process */
1484 }
1485
1486 int main(argc, argv)
1487         int argc;
1488         char **argv;
1489 {
1490         pthread_t t;
1491
1492         /* create a pipe to select */
1493         if(pipe(&fildes[0])) {
1494                 perror("select");
1495                 exit(1);
1496         }
1497
1498 #ifdef HAVE_PTHREAD_SETCONCURRENCY
1499         (void) pthread_setconcurrency(2);
1500 #else
1501 #ifdef HAVE_THR_SETCONCURRENCY
1502         /* Set Solaris LWP concurrency to 2 */
1503         thr_setconcurrency(2);
1504 #endif
1505 #endif
1506
1507 #if HAVE_PTHREADS < 6
1508         pthread_create(&t, pthread_attr_default, task, NULL);
1509 #else
1510         pthread_create(&t, NULL, task, NULL);
1511 #endif
1512
1513         /* make sure task runs first */
1514 #ifdef HAVE_THR_YIELD
1515         thr_yield();
1516 #elif defined( HAVE_SCHED_YIELD )
1517         sched_yield();
1518 #elif defined( HAVE_PTHREAD_YIELD )
1519         pthread_yield();
1520 #endif
1521
1522         exit(2);
1523 }]])],[ol_cv_pthread_select_yields=no],[ol_cv_pthread_select_yields=yes],[ol_cv_pthread_select_yields=cross])])
1524
1525                                 if test $ol_cv_pthread_select_yields = cross ; then
1526                                         AC_MSG_ERROR([crossing compiling: use --with-yielding_select=yes|no|manual])
1527                                 fi
1528
1529                                 if test $ol_cv_pthread_select_yields = yes ; then
1530                                         ol_with_yielding_select=yes
1531                                 fi
1532                         fi
1533
1534                         dnl restore flags
1535                         CPPFLAGS="$save_CPPFLAGS"
1536                         LIBS="$save_LIBS"
1537                 else
1538                         AC_MSG_ERROR([could not locate usable POSIX Threads])
1539                 fi
1540         fi
1541
1542         if test $ol_with_threads = posix ; then
1543                 AC_MSG_ERROR([could not locate POSIX Threads])
1544         fi
1545         ;;
1546 esac
1547
1548 case $ol_with_threads in auto | yes | mach)
1549
1550         dnl check for Mach CThreads
1551         AC_CHECK_HEADERS(mach/cthreads.h cthreads.h)
1552         if test $ac_cv_header_mach_cthreads_h = yes ; then
1553                 ol_with_threads=found
1554
1555                 dnl check for cthreads support in current $LIBS
1556                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1557
1558                 if test $ol_link_threads = no ; then
1559                         dnl try -all_load
1560                         dnl this test needs work
1561                         AC_CACHE_CHECK([for cthread_fork with -all_load],
1562                                 [ol_cv_cthread_all_load], [
1563                                 dnl save the flags
1564                                 save_LIBS="$LIBS"
1565                                 LIBS="-all_load $LIBS"
1566                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <mach/cthreads.h>]], [[
1567                                         cthread_fork((void *)0, (void *)0);
1568                                         ]])],[ol_cv_cthread_all_load=yes],[ol_cv_cthread_all_load=no])
1569                                 dnl restore the LIBS
1570                                 LIBS="$save_LIBS"
1571                         ])
1572
1573                         if test $ol_cv_cthread_all_load = yes ; then
1574                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
1575                                 ol_link_threads=mach
1576                                 ol_with_threads=found
1577                         fi
1578                 fi
1579
1580         elif test $ac_cv_header_cthreads_h = yes ; then
1581                 dnl Hurd variant of Mach Cthreads
1582                 dnl uses <cthreads.h> and -lthreads
1583
1584                 ol_with_threads=found
1585
1586                 dnl save the flags
1587                 save_LIBS="$LIBS"
1588                 LIBS="$LIBS -lthreads"
1589                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
1590                 LIBS="$save_LIBS"
1591
1592                 if test $ol_link_threads = yes ; then
1593                         LTHREAD_LIBS="-lthreads"
1594                         ol_link_threads=mach
1595                         ol_with_threads=found
1596                 else
1597                         AC_MSG_ERROR([could not link with Mach CThreads])
1598                 fi
1599
1600         elif test $ol_with_threads = mach ; then
1601                 AC_MSG_ERROR([could not locate Mach CThreads])
1602         fi
1603
1604         if test $ol_link_threads = mach ; then
1605                 AC_DEFINE(HAVE_MACH_CTHREADS,1,
1606                         [define if you have Mach Cthreads])
1607         elif test $ol_with_threads = found ; then
1608                 AC_MSG_ERROR([could not link with Mach CThreads])
1609         fi
1610         ;;
1611 esac
1612
1613 case $ol_with_threads in auto | yes | pth)
1614
1615         AC_CHECK_HEADERS(pth.h)
1616
1617         if test $ac_cv_header_pth_h = yes ; then
1618                 AC_CHECK_LIB(pth, pth_version, [have_pth=yes], [have_pth=no])
1619
1620                 if test $have_pth = yes ; then
1621                         AC_DEFINE(HAVE_GNU_PTH,1,[if you have GNU Pth])
1622                         LTHREAD_LIBS="$LTHREAD_LIBS -lpth"
1623                         ol_link_threads=pth
1624                         ol_with_threads=found
1625
1626                         if test $ol_with_yielding_select = auto ; then
1627                                 ol_with_yielding_select=yes
1628                         fi
1629                 fi
1630         fi
1631         ;;
1632 esac
1633
1634 case $ol_with_threads in auto | yes | lwp)
1635
1636         dnl check for SunOS5 LWP
1637         AC_CHECK_HEADERS(thread.h synch.h)
1638         if test $ac_cv_header_thread_h = yes &&
1639            test $ac_cv_header_synch_h = yes ; then
1640                 AC_CHECK_LIB(thread, thr_create, [have_thr=yes], [have_thr=no])
1641
1642                 if test $have_thr = yes ; then
1643                         AC_DEFINE(HAVE_THR,1,
1644                                 [if you have Solaris LWP (thr) package])
1645                         LTHREAD_LIBS="$LTHREAD_LIBS -lthread"
1646                         ol_link_threads=thr
1647
1648                         if test $ol_with_yielding_select = auto ; then
1649                                 ol_with_yielding_select=yes
1650                         fi
1651
1652                         dnl Check for setconcurreny functions
1653                         AC_CHECK_FUNCS( \
1654                                 thr_setconcurrency \
1655                                 thr_getconcurrency \
1656                         )
1657                 fi
1658         fi
1659
1660         dnl check for SunOS4 LWP
1661         AC_CHECK_HEADERS(lwp/lwp.h)
1662         if test $ac_cv_header_lwp_lwp_h = yes ; then
1663                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
1664
1665                 if test $have_lwp = yes ; then
1666                         AC_DEFINE(HAVE_LWP,1,
1667                                 [if you have SunOS LWP package])
1668                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
1669                         ol_link_threads=lwp
1670
1671                         if test $ol_with_yielding_select = auto ; then
1672                                 ol_with_yielding_select=no
1673                         fi
1674                 fi
1675         fi
1676         ;;
1677 esac
1678
1679 if test $ol_with_yielding_select = yes ; then
1680         AC_DEFINE(HAVE_YIELDING_SELECT,1,
1681                 [define if select implicitly yields])
1682 fi
1683
1684 if test $ol_with_threads = manual ; then
1685         dnl User thinks he can manually configure threads.
1686         ol_link_threads=yes
1687
1688         AC_MSG_WARN([thread defines and link options must be set manually])
1689
1690         AC_CHECK_HEADERS(pthread.h sched.h)
1691         AC_CHECK_FUNCS(sched_yield pthread_yield)
1692         OL_HEADER_LINUX_THREADS
1693
1694         AC_CHECK_HEADERS(mach/cthreads.h)
1695         AC_CHECK_HEADERS(lwp/lwp.h)
1696         AC_CHECK_HEADERS(thread.h synch.h)
1697 fi
1698
1699 if test $ol_link_threads != no && test $ol_link_threads != nt ; then
1700         dnl needed to get reentrant/threadsafe versions
1701         dnl
1702         AC_DEFINE(REENTRANT,1)
1703         AC_DEFINE(_REENTRANT,1)
1704         AC_DEFINE(THREAD_SAFE,1)
1705         AC_DEFINE(_THREAD_SAFE,1)
1706         AC_DEFINE(THREADSAFE,1)
1707         AC_DEFINE(_THREADSAFE,1)
1708         AC_DEFINE(_SGI_MP_SOURCE,1)
1709
1710         dnl The errno declaration may dependent upon _REENTRANT.
1711         dnl If it does, we must link with thread support.
1712         AC_CACHE_CHECK([for thread specific errno],
1713                 [ol_cv_errno_thread_specific], [
1714                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[errno = 0;]])],[ol_cv_errno_thread_specific=yes],[ol_cv_errno_thread_specific=no])
1715         ])
1716
1717         dnl The h_errno declaration may dependent upon _REENTRANT.
1718         dnl If it does, we must link with thread support.
1719         AC_CACHE_CHECK([for thread specific h_errno],
1720                 [ol_cv_h_errno_thread_specific], [
1721                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[h_errno = 0;]])],[ol_cv_h_errno_thread_specific=yes],[ol_cv_h_errno_thread_specific=no])
1722         ])
1723
1724         if test $ol_cv_errno_thread_specific != yes ||
1725            test $ol_cv_h_errno_thread_specific != yes ; then
1726                 LIBS="$LTHREAD_LIBS $LIBS"
1727                 LTHREAD_LIBS=""
1728         fi
1729
1730 dnl When in thread environment, use
1731 dnl             #if defined( HAVE_REENTRANT_FUNCTIONS ) || defined( HAVE_FUNC_R )
1732 dnl                     func_r(...);
1733 dnl             #else
1734 dnl             #       if defined( HAVE_THREADS )
1735 dnl                             /* lock */
1736 dnl             #       endif
1737 dnl                             func(...);
1738 dnl             #       if defined( HAVE_THREADS )
1739 dnl                             /* unlock */
1740 dnl             #       endif
1741 dnl             #endif
1742 dnl
1743 dnl HAVE_REENTRANT_FUNCTIONS is derived from:
1744 dnl             _POSIX_REENTRANT_FUNCTIONS
1745 dnl             _POSIX_THREAD_SAFE_FUNCTIONS
1746 dnl             _POSIX_THREADSAFE_FUNCTIONS
1747 dnl
1748 dnl             and is currently defined in <ldap_pvt_thread.h>
1749 dnl
1750 dnl HAVE_THREADS is defined by <ldap_pvt_thread.h> iff -UNO_THREADS
1751 dnl
1752 dnl libldap/*.c should only include <ldap_pvt_thread.h> iff
1753 dnl LDAP_R_COMPILE is defined.  ie:
1754 dnl             #ifdef LDAP_R_COMPILE
1755 dnl             #       include <ldap_pvt_thread.h>
1756 dnl             #endif
1757 dnl
1758 dnl LDAP_R_COMPILE is defined by libldap_r/Makefile.in
1759 dnl specifically for compiling the threadsafe version of
1760 dnl     the ldap library (-lldap_r).
1761 dnl
1762 dnl     dnl check for reentrant/threadsafe functions
1763 dnl     dnl
1764 dnl     dnl note: these should only be used when linking
1765 dnl     dnl             with $LTHREAD_LIBS
1766 dnl     dnl
1767 dnl     save_CPPFLAGS="$CPPFLAGS"
1768 dnl     save_LIBS="$LIBS"
1769 dnl     LIBS="$LTHREAD_LIBS $LIBS"
1770 dnl     AC_CHECK_FUNCS( \
1771 dnl             gmtime_r \
1772 dnl             gethostbyaddr_r gethostbyname_r \
1773 dnl             feof_unlocked unlocked_feof \
1774 dnl             putc_unlocked unlocked_putc \
1775 dnl             flockfile ftrylockfile \
1776 dnl     )
1777 dnl     CPPFLAGS="$save_CPPFLAGS"
1778 dnl     LIBS="$save_LIBS"
1779 fi
1780
1781 if test $ol_link_threads = no ; then
1782         if test $ol_with_threads = yes ; then
1783                 AC_MSG_ERROR([no suitable thread support])
1784         fi
1785
1786         if test $ol_with_threads = auto ; then
1787                 AC_MSG_WARN([no suitable thread support, disabling threads])
1788                 ol_with_threads=no
1789         fi
1790
1791         AC_DEFINE(NO_THREADS,1,
1792                 [define if you have (or want) no threads])
1793         LTHREAD_LIBS=""
1794         BUILD_THREAD=no
1795 else
1796         BUILD_THREAD=yes
1797 fi
1798
1799 if test $ol_link_threads != no ; then
1800         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_THREAD_SAFE,1,
1801                 [define to 1 if library is thread safe])
1802 fi
1803
1804 dnl ----------------------------------------------------------------
1805 dnl Tests for reentrant functions necessary to build -lldap_r
1806 AC_CHECK_FUNCS(         \
1807         ctime_r                 \
1808         gethostbyname_r gethostbyaddr_r \
1809 )
1810
1811 if test "$ac_cv_func_ctime_r" = no ; then
1812         ol_cv_func_ctime_r_nargs=0
1813 else
1814         OL_FUNC_CTIME_R_NARGS
1815 dnl     OL_FUNC_CTIME_R_TYPE
1816 fi
1817
1818 if test "$ac_cv_func_gethostbyname_r" = yes ; then
1819         OL_FUNC_GETHOSTBYNAME_R_NARGS
1820 else
1821         ol_cv_func_gethostbyname_r_nargs=0
1822 fi
1823
1824 if test "$ac_cv_func_gethostbyaddr_r" = yes ; then
1825         OL_FUNC_GETHOSTBYADDR_R_NARGS
1826 else
1827         ol_cv_func_gethostbyaddr_r_nargs=0
1828 fi
1829
1830 dnl ----------------------------------------------------------------
1831 ol_link_bdb=no
1832
1833 if test $ol_enable_bdb/$ol_enable_hdb != no/no; then
1834         OL_BERKELEY_DB
1835
1836         if test $ol_cv_berkeley_db = no ; then
1837                 AC_MSG_ERROR(BDB/HDB: BerkeleyDB not available)
1838         fi
1839
1840         AC_DEFINE(HAVE_BERKELEY_DB,1,
1841                 [define this if Berkeley DB is available])
1842
1843         dnl $ol_cv_lib_db should be yes or -ldb
1844         dnl (it could be no, but that would be an error
1845         if test $ol_cv_lib_db != yes ; then
1846                 BDB_LIBS="$BDB_LIBS $ol_cv_lib_db"
1847         fi
1848
1849         OL_BDB_COMPAT
1850
1851         if test $ol_cv_bdb_compat != yes ; then
1852                 AC_MSG_ERROR([BDB/HDB: BerkeleyDB version incompatible])
1853         fi
1854
1855         SLAPD_LIBS="$SLAPD_LIBS \$(BDB_LIBS)"
1856
1857         ol_link_bdb=yes
1858 fi
1859
1860 dnl ----------------------------------------------------------------
1861
1862 if test $ol_enable_dynamic = yes && test $enable_shared = yes ; then
1863         BUILD_LIBS_DYNAMIC=shared
1864         AC_DEFINE(LDAP_LIBS_DYNAMIC, 1, [define if LDAP libs are dynamic])
1865         LTSTATIC=""
1866 else
1867         BUILD_LIBS_DYNAMIC=static
1868         LTSTATIC="-static"
1869 fi
1870 AC_SUBST(LTSTATIC)dnl
1871
1872 dnl ----------------------------------------------------------------
1873 if test $ol_enable_wrappers != no ; then
1874         AC_CHECK_HEADERS(tcpd.h,[
1875                 AC_MSG_CHECKING([for TCP wrappers library])
1876                 save_LIBS="$LIBS"
1877                 LIBS="$LIBS -lwrap"
1878                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1879 #include <tcpd.h>
1880 int allow_severity = 0;
1881 int deny_severity  = 0;
1882
1883 struct request_info *req;
1884                 ]], [[
1885 hosts_access(req)
1886                 ]])],[AC_MSG_RESULT([-lwrap])
1887                 have_wrappers=yes
1888                 LIBS="$save_LIBS"],[
1889                 dnl try with -lnsl
1890                 LIBS="$LIBS -lnsl"
1891                 AC_TRY_LINK([
1892 #include <tcpd.h>
1893 int allow_severity = 0;
1894 int deny_severity  = 0;
1895
1896 struct request_info *req;
1897                 ],[
1898 hosts_access(req)
1899                 ],[AC_MSG_RESULT([-lwrap -lnsl])
1900                 have_wrappers=yes
1901                 LIBS="$save_LIBS -lnsl"],[
1902                 AC_MSG_RESULT(no)
1903                 have_wrappers=no
1904                 LIBS=$save_LIBS])])],[have_wrappers=no])
1905
1906         if test $have_wrappers = yes ; then
1907                 AC_DEFINE(HAVE_TCPD,1, [define if you have -lwrap])
1908                 WRAP_LIBS="-lwrap"
1909         elif test $ol_enable_wrappers = yes ; then
1910                 AC_MSG_ERROR([could not find TCP wrappers, select apppropriate options or disable])
1911         else
1912                 AC_MSG_WARN([could not find TCP wrappers, support disabled])
1913                 WRAP_LIBS=""
1914         fi
1915 fi
1916
1917 dnl ----------------------------------------------------------------
1918 if test $ol_enable_syslog != no ; then
1919         AC_CHECK_FUNC(openlog)
1920         if test $ac_cv_func_openlog = no && test $ol_enable_syslog = yes; then
1921                 AC_MSG_ERROR(could not find syslog, select appropriate options or disable)
1922         fi
1923         ol_enable_syslog=$ac_cv_func_openlog
1924 fi
1925
1926 dnl ----------------------------------------------------------------
1927 dnl SQL
1928 ol_link_sql=no
1929 if test $ol_enable_sql != no ; then
1930         AC_CHECK_HEADERS(sql.h sqlext.h,[],[
1931                 AC_MSG_ERROR([could not locate SQL headers])
1932         ])
1933
1934         sql_LIBS="$LIBS"
1935         LIBS="$LTHREAD_LIBS"
1936
1937         if test $ol_with_odbc = auto ; then
1938                 ol_with_odbc="iodbc unixodbc odbc32"
1939         fi
1940
1941         for odbc in $ol_with_odbc ; do
1942                 if test $ol_link_sql = no ; then
1943                         case $odbc in
1944                         iodbc)
1945                                 AC_CHECK_LIB(iodbc, SQLDriverConnect, [have_iodbc=yes], [have_iodbc=no])
1946                                 if test $have_iodbc = yes ; then
1947                                         ol_link_sql="-liodbc"
1948                                 fi
1949                                 ;;
1950
1951                         unixodbc)
1952                                 AC_CHECK_LIB(odbc, SQLDriverConnect, [have_odbc=yes], [have_odbc=no])
1953                                 if test $have_odbc = yes ; then
1954                                         ol_link_sql="-lodbc"
1955                                 fi
1956                                 ;;
1957
1958                         odbc32)
1959                                 AC_CHECK_LIB(odbc32, SQLDriverConnect, [have_odbc32=yes], [have_odbc32=no])
1960                                 if test $have_odbc32 = yes ; then
1961                                         ol_link_sql="-lodbc32"
1962                                 fi
1963                                 ;;
1964
1965                         *)
1966                                 AC_MSG_ERROR([unknown ODBC library])
1967                                 ;;
1968                         esac
1969                 fi
1970         done
1971
1972         LIBS="$sql_LIBS"
1973
1974         if test $ol_link_sql != no ; then
1975                 SLAPD_SQL_LIBS="$ol_link_sql"
1976
1977         elif test $ol_enable_sql != auto ; then
1978                 AC_MSG_ERROR([could not locate suitable ODBC library])
1979         fi
1980 fi
1981
1982 dnl ----------------------------------------------------------------
1983 dnl MySQL NDBapi
1984 ol_link_ndb=no
1985 if test $ol_enable_ndb != no ; then
1986         AC_CHECK_PROG(MYSQL,mysql_config,yes)
1987         if test "$MYSQL" != yes ; then
1988                 AC_MSG_ERROR([could not locate mysql_config])
1989         fi
1990
1991         SQL_INC=`mysql_config --include`
1992         SLAPD_NDB_INCS="$SQL_INC $SQL_INC/storage/ndb $SQL_INC/storage/ndb/ndbapi"
1993
1994         SQL_LIB=`mysql_config --libs_r`
1995         SLAPD_NDB_LIBS="$SQL_LIB -lndbclient -lmysys -lmystrings -lstdc++"
1996
1997         if test "$ol_enable_ndb" = yes ; then
1998                 SLAPD_LIBS="$SLAPD_LIBS \$(SLAPD_NDB_LIBS)"
1999         fi
2000 fi
2001
2002 dnl ----------------------------------------------------------------
2003 dnl International Components for Unicode
2004 OL_ICU
2005 if test "$ol_icu" = no ; then
2006         AC_MSG_WARN([ICU not available])
2007 else
2008         ICU_LIBS="$ol_icu"
2009 fi
2010 dnl ----------------------------------------------------------------
2011 dnl
2012 dnl Check for Cyrus SASL
2013 dnl
2014 WITH_SASL=no
2015 ol_link_sasl=no
2016 ol_link_spasswd=no
2017 if test $ol_with_cyrus_sasl != no ; then
2018         AC_CHECK_HEADERS(sasl/sasl.h sasl.h)
2019
2020         if test $ac_cv_header_sasl_sasl_h = yes ||
2021            test $ac_cv_header_sasl_h = yes; then
2022                 AC_CHECK_LIB(sasl2, sasl_client_init,
2023                         [ol_link_sasl="-lsasl2"],
2024                         [AC_CHECK_LIB(sasl, sasl_client_init,
2025                                 [ol_link_sasl="-lsasl"])])
2026         fi
2027
2028         if test $ol_link_sasl = no ; then
2029                 if test $ol_with_cyrus_sasl != auto ; then
2030                         AC_MSG_ERROR([Could not locate Cyrus SASL])
2031                 else
2032                         AC_MSG_WARN([Could not locate Cyrus SASL])
2033                         AC_MSG_WARN([SASL authentication not supported!])
2034                         if test $ol_link_tls = no ; then
2035                                 AC_MSG_WARN([Strong authentication not supported!])
2036                         fi
2037                 fi
2038         else
2039                 OL_SASL_COMPAT
2040                 if test $ol_cv_sasl_compat = no ; then
2041                         ol_link_sasl=no
2042                         AC_MSG_ERROR([Cyrus SASL library located but is incompatible])
2043                 fi
2044
2045                 AC_DEFINE(HAVE_CYRUS_SASL,1,[define if you have Cyrus SASL])
2046                 SASL_LIBS="$ol_link_sasl"
2047                 if test $ol_enable_spasswd != no ; then
2048                         ol_link_spasswd=yes
2049                 fi
2050
2051                 ac_save_LIBS="$LIBS"
2052                 LIBS="$LIBS $ol_link_sasl"
2053                 AC_CHECK_FUNC(sasl_version, [AC_DEFINE(HAVE_SASL_VERSION,1,
2054                         [define if your SASL library has sasl_version()])])
2055                 LIBS="$ac_save_LIBS"
2056
2057                 WITH_SASL=yes
2058         fi
2059
2060 else
2061         AC_MSG_WARN([SASL authentication not supported!])
2062         if test $ol_link_tls = no ; then
2063                 AC_MSG_WARN([Strong authentication not supported!])
2064         fi
2065 fi
2066
2067 dnl ----------------------------------------------------------------
2068 dnl Check for entropy sources
2069 if test $cross_compiling != yes && test "$ac_cv_mingw32" != yes ; then
2070         dev=no
2071         if test -r /dev/urandom ; then
2072                 dev="/dev/urandom";
2073         elif test -r /idev/urandom ; then
2074                 dev="/idev/urandom";
2075         elif test -r /dev/srandom ; then
2076                 dev="/dev/srandom";
2077         elif test -r /dev/random ; then
2078                 dev="/dev/random";
2079         elif test -r /idev/random ; then
2080                 dev="/idev/random";
2081         fi
2082
2083         if test $dev != no ; then
2084                 AC_DEFINE_UNQUOTED(URANDOM_DEVICE,"$dev",[set to urandom device])
2085         fi
2086 fi
2087
2088 dnl ----------------------------------------------------------------
2089 dnl
2090 dnl Check for fetch URL support
2091 dnl             should be extended to support other fetch URL APIs
2092 dnl
2093 ol_link_fetch=no
2094 if test $ol_with_fetch != no ; then
2095         OL_LIB_FETCH
2096
2097         if test $ol_cv_lib_fetch != no ; then
2098                 LUTIL_LIBS="$LUTIL_LIBS $ol_link_fetch"
2099                 ol_link_fetch=freebsd
2100
2101         elif test $ol_with_fetch != auto ; then
2102                 AC_MSG_ERROR(no suitable API for --with-fetch=$ol_with_fetch)
2103         fi
2104 fi
2105
2106 dnl ----------------------------------------------------------------
2107 dnl FreeBSD (and others) have crypt(3) in -lcrypt
2108 if test $ol_enable_crypt != no ; then
2109         save_LIBS="$LIBS"
2110         LIBS="$TLS_LIBS $LIBS"
2111
2112         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
2113                 LIBS="$save_LIBS"
2114                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
2115                         have_crypt=yes], [have_crypt=no])])
2116
2117         LIBS="$save_LIBS"
2118
2119         if test $have_crypt = yes ; then
2120                 AC_DEFINE(HAVE_CRYPT,1, [define if crypt(3) is available])
2121         else
2122                 AC_MSG_WARN([could not find crypt])
2123                 if test $ol_enable_crypt = yes ; then
2124                         AC_MSG_ERROR([could not find crypt, select appropriate options or disable])
2125                 fi
2126
2127                 AC_MSG_WARN([disabling crypt support])
2128                 ol_enable_crypt=no
2129         fi
2130 fi
2131
2132 dnl ----------------------------------------------------------------
2133 dnl FreeBSD (and others) have setproctitle(3) in -lutil
2134 if test $ol_enable_proctitle != no ; then
2135         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
2136                 AC_CHECK_LIB(util, setproctitle,
2137                         [have_setproctitle=yes
2138                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
2139                         [have_setproctitle=no
2140                         AC_LIBOBJ(setproctitle)
2141                         LIBSRCS="$LIBSRCS setproctitle.c"])])
2142
2143         if test $have_setproctitle = yes ; then
2144                 AC_DEFINE(HAVE_SETPROCTITLE,1,
2145                         [define if setproctitle(3) is available])
2146         fi
2147 fi
2148
2149 dnl ----------------------------------------------------------------
2150 if test $ol_enable_slp != no ; then
2151         AC_CHECK_HEADERS( slp.h )
2152
2153         if test $ac_cv_header_slp_h = yes ; then
2154                 AC_CHECK_LIB(slp, SLPOpen, [have_slp=yes], [have_slp=no])
2155                 if test $have_slp = yes ; then
2156                         AC_DEFINE(HAVE_SLP, 1, [define if you have -lslp])
2157                         SLAPD_SLP_LIBS=-lslp
2158                 fi
2159
2160         elif test $ol_enable_slp = yes ; then
2161                 AC_MSG_ERROR([SLP not found])
2162         fi
2163 fi
2164
2165 dnl ----------------------------------------------------------------
2166 dnl Checks for typedefs, structures, and compiler characteristics.
2167
2168 AC_CHECK_TYPE(mode_t, int)
2169 AC_CHECK_TYPE(off_t, long)
2170 AC_CHECK_TYPE(pid_t, int)
2171 AC_CHECK_TYPE(ssize_t, [signed int])
2172 AC_CHECK_TYPE(caddr_t,  [char *])
2173 AC_CHECK_TYPE(size_t, unsigned)
2174
2175 AC_CHECK_TYPES([long long])
2176 AC_CHECK_TYPES([ptrdiff_t])
2177
2178
2179 AC_CHECK_TYPE([socklen_t],,, [$ac_includes_default
2180 #ifdef HAVE_SYS_SOCKET_H
2181 #include <sys/socket.h>
2182 #endif])
2183
2184 dnl socklen_t-like type in accept(), default socklen_t or int:
2185 dnl - The OS might define socklen_t without using it.  POSIX moved from
2186 dnl   int to size_t to socklen_t, hoping to stay at a 32-bit type, and
2187 dnl   HP-UX now has selectors for what to use.
2188 dnl - On Solaris 2.8 the prototype has void *len, but the default is OK.
2189 AC_MSG_CHECKING([the type of arg 3 to accept()])
2190 AC_CACHE_VAL(ol_cv_type_ber_socklen_t, [
2191         set socklen_t int unsigned "unsigned long" long size_t
2192         test "$ac_cv_type_socklen_t" = yes || shift
2193         ol_cv_type_ber_socklen_t=$1 guessing="guessing "
2194         for lentype in "$@" ; do for addrtype in "struct sockaddr" void ; do
2195                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([$ac_includes_default
2196 #ifdef HAVE_SYS_SOCKET_H
2197 #include <sys/socket.h>
2198 #endif
2199 extern int accept(int s, $addrtype *ap, $lentype *lp);
2200 ], [
2201 accept(0, (struct sockaddr *) 0, ($lentype *) 0);
2202 ])], [ol_cv_type_ber_socklen_t=$lentype guessing= ; break 2])
2203         done ; done])
2204 AC_MSG_RESULT([$guessing$ol_cv_type_ber_socklen_t *])
2205 AC_DEFINE_UNQUOTED(ber_socklen_t, $ol_cv_type_ber_socklen_t,
2206         [Define to the type of arg 3 for `accept'.])
2207
2208 dnl Modules should use ber_socklen_t, not socklen_t.  Define socklen_t
2209 dnl for the time being anyway, for backwards compatibility.
2210 if test "$ac_cv_type_socklen_t" != yes; then
2211         AC_DEFINE_UNQUOTED([socklen_t], [$ol_cv_type_ber_socklen_t],
2212                 [Define like ber_socklen_t if <sys/socket.h> does not define.])
2213 fi
2214
2215
2216 AC_TYPE_SIGNAL
2217
2218 AC_CHECK_TYPE([sig_atomic_t],,
2219         [AC_DEFINE_UNQUOTED([sig_atomic_t], [int],
2220                 [Define to `int' if <signal.h> does not define.])],
2221         [$ac_includes_default
2222 #include <signal.h>
2223         ])
2224
2225 AC_TYPE_UID_T
2226
2227 AC_HEADER_TIME
2228 AC_STRUCT_TM
2229 AC_CHECK_MEMBERS([struct stat.st_blksize])
2230 AC_CHECK_MEMBERS([struct passwd.pw_gecos],,,[$ac_includes_default
2231 #include <pwd.h>])
2232 AC_CHECK_MEMBERS([struct passwd.pw_passwd],,,[$ac_includes_default
2233 #include <pwd.h>])
2234
2235 OL_C_UPPER_LOWER
2236 AC_C_CONST
2237 OL_C_VOLATILE
2238
2239 if test $cross_compiling = yes ; then
2240         AC_MSG_WARN([Crossing compiling... all bets are off!])
2241         AC_DEFINE(CROSS_COMPILING, 1, [define if cross compiling])
2242 else
2243         AC_C_BIGENDIAN
2244 fi
2245
2246 AC_CHECK_SIZEOF(short)
2247 AC_CHECK_SIZEOF(int)
2248 AC_CHECK_SIZEOF(long)
2249 AC_CHECK_SIZEOF(long long)
2250 AC_CHECK_SIZEOF(wchar_t)
2251
2252 if test "$ac_cv_sizeof_int" -lt 4 ; then
2253         AC_MSG_WARN([OpenLDAP requires 'int' to be 32 bits or greater.])
2254
2255         AC_DEFINE(LBER_INT_T,long,[define to 32-bit or greater integer type])
2256 else
2257         AC_DEFINE(LBER_INT_T,int,[define to 32-bit or greater integer type])
2258 fi
2259
2260 AC_DEFINE(LBER_LEN_T,long,[define to large integer type])
2261 AC_DEFINE(LBER_SOCKET_T,int,[define to socket descriptor type])
2262 AC_DEFINE(LBER_TAG_T,long,[define to large integer type])
2263
2264 dnl ----------------------------------------------------------------
2265 dnl Check for multiple precision support
2266 if test $ol_with_mp = longlong || test $ol_with_mp = auto ; then
2267         if test $ac_cv_sizeof_long_long -gt 4 ; then
2268                 ol_with_mp=longlong
2269                 AC_DEFINE(USE_MP_LONG_LONG,1,[define to use 'long long' for MP])
2270         elif test $ol_with_mp = longlong ; then
2271                 AC_MSG_ERROR([long long unusable for multiple precision])
2272         fi
2273 fi
2274 if test $ol_with_mp = long || test $ol_with_mp = auto ; then
2275         if test $ac_cv_sizeof_long -gt 4 ; then
2276                 ol_with_mp=long
2277                 AC_DEFINE(USE_MP_LONG,1,[define to use 'long' for MP])
2278         elif test $ol_with_mp = long ; then
2279                 AC_MSG_ERROR([long unusable for multiple precision])
2280         fi
2281 fi
2282 if test $ol_with_mp = bignum || test $ol_with_mp = auto ; then
2283         AC_CHECK_HEADERS(openssl/bn.h)
2284         AC_CHECK_HEADERS(openssl/crypto.h)
2285         if test "$ac_cv_header_openssl_bn_h" = "yes" &&
2286                 test "$ac_cv_header_openssl_crypto_h" = "yes" &&
2287                 test "$ol_with_tls" = "found" ; then
2288                 ol_with_mp=bignum
2289                 AC_DEFINE(USE_MP_BIGNUM,1,[define to use OpenSSL BIGNUM for MP])
2290         elif test $ol_with_mp = bignum ; then
2291                 AC_MSG_ERROR([bignum not available])
2292         fi
2293 fi
2294 if test $ol_with_mp = gmp || test $ol_with_mp = auto ; then
2295         AC_CHECK_HEADERS(gmp.h)
2296         AC_CHECK_LIB(gmp, __gmpz_add_ui)
2297         if test $ac_cv_header_gmp_h = yes && test $ac_cv_lib_gmp___gmpz_add_ui = yes ; then
2298                 AC_DEFINE(USE_MP_GMP,1,[define to use GMP for MP])
2299                 ol_with_mp=gmp
2300         elif test $ol_with_mp = gmp ; then
2301                 AC_MSG_ERROR([gmp not available])
2302         fi
2303 fi
2304 if test $ol_with_mp = auto ; then
2305         ol_with_mp=no
2306 fi
2307
2308 dnl ----------------------------------------------------------------
2309 dnl Checks for library functions.
2310 AC_FUNC_MEMCMP
2311
2312 if test $ac_cv_func_memcmp_working = no ; then
2313         AC_DEFINE(NEED_MEMCMP_REPLACEMENT,1,
2314                 [define if memcmp is not 8-bit clean or is otherwise broken])
2315 fi
2316
2317 AC_FUNC_STRFTIME
2318
2319 OL_FUNC_INET_ATON
2320
2321 dnl Check for NT specific routines
2322 AC_CHECK_FUNC(_spawnlp, AC_DEFINE(HAVE_SPAWNLP,1,[if you have spawnlp()]))
2323
2324 AC_CHECK_FUNC(_snprintf, [ac_cv_func_snprintf=yes
2325         AC_DEFINE(snprintf, _snprintf, [define to snprintf routine])
2326 ])
2327
2328 AC_CHECK_FUNC(_vsnprintf, [ac_cv_func_vsnprintf=yes
2329         AC_DEFINE(vsnprintf, _vsnprintf, [define to vsnprintf routine])
2330 ])
2331
2332 AC_FUNC_VPRINTF
2333
2334 if test $ac_cv_func_vprintf = yes ; then
2335         dnl check for vsnprintf
2336         AC_CHECK_FUNCS(snprintf vsnprintf)
2337 fi
2338
2339 AC_CHECK_FUNCS(                 \
2340         bcopy                   \
2341         closesocket             \
2342         chroot                  \
2343         endgrent                \
2344         endpwent                \
2345         fcntl                   \
2346         flock                   \
2347         fstat                   \
2348         getdtablesize           \
2349         getgrgid                \
2350         gethostname             \
2351         getpass                 \
2352         getpassphrase           \
2353         getpwuid                \
2354         getpwnam                \
2355         getspnam                \
2356         gettimeofday            \
2357         initgroups              \
2358         inet_ntoa_b             \
2359         ioctl                   \
2360         lockf                   \
2361         memcpy                  \
2362         memmove                 \
2363         memrchr                 \
2364         mkstemp                 \
2365         mktemp                  \
2366         pipe                    \
2367         read                    \
2368         recv                    \
2369         recvfrom                \
2370         setpwfile               \
2371         setgid                  \
2372         setegid                 \
2373         setsid                  \
2374         setuid                  \
2375         seteuid                 \
2376         signal                  \
2377         strdup                  \
2378         strpbrk                 \
2379         strrchr                 \
2380         strsep                  \
2381         strstr                  \
2382         strtol                  \
2383         strtoul                 \
2384         strtoq                  \
2385         strtouq                 \
2386         strtoll                 \
2387         strspn                  \
2388         sysconf                 \
2389         waitpid                 \
2390         wait4                   \
2391         write                   \
2392         send                    \
2393         sendmsg                 \
2394         sendto                  \
2395 )
2396
2397 dnl We actually may need to replace more than this.
2398 AC_REPLACE_FUNCS(getopt getpeereid)
2399
2400 if test "$ac_cv_func_getopt" != yes; then
2401         LIBSRCS="$LIBSRCS getopt.c"
2402 fi
2403
2404 if test "$ac_cv_func_getpeereid" != yes; then
2405         AC_CHECK_FUNCS( getpeerucred )
2406         if test "$ac_cv_func_getpeerucred" != yes ; then
2407                 AC_CHECK_MEMBERS([struct msghdr.msg_accrightslen],,,
2408                         [$ac_includes_default
2409 #ifdef HAVE_SYS_SOCKET_H
2410 #include <sys/socket.h>
2411 #endif])
2412                 if test "$ac_cv_member_struct_msghdr_msg_accrightslen" != yes; then
2413                         AC_CHECK_MEMBERS([struct msghdr.msg_control],,,
2414                                 [$ac_includes_default
2415 #ifdef HAVE_SYS_SOCKET_H
2416 #include <sys/socket.h>
2417 #endif])
2418                 fi
2419                 AC_CHECK_MEMBERS([struct stat.st_fstype, struct stat.st_vfstype])
2420                 if test "$ac_cv_member_struct_stat_st_fstype" = yes; then
2421                         AC_COMPILE_IFELSE([struct stat st; char *ptr=st.st_fstype;],
2422                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_CHAR],1,[define to 1 if st_fstype is char *]),
2423                                 AC_DEFINE([HAVE_STRUCT_STAT_ST_FSTYPE_INT],1,[define to 1 if st_fstype is int]))
2424                 fi
2425         fi
2426         LIBSRCS="$LIBSRCS getpeereid.c"
2427 fi
2428
2429 if test "$ac_cv_func_snprintf" != yes ||
2430    test "$ac_cv_func_vsnprintf" != yes; then
2431         if test "$ac_cv_func_snprintf" != yes; then
2432                 AC_DEFINE(snprintf, ber_pvt_snprintf, [define to snprintf routine])
2433         fi
2434         if test "$ac_cv_func_vsnprintf" != yes; then
2435                 AC_DEFINE(vsnprintf, ber_pvt_vsnprintf, [define to snprintf routine])
2436         fi
2437 fi
2438
2439 dnl ----------------------------------------------------------------
2440 dnl Sort out defines
2441
2442 if test "$ol_enable_slapi" != no ; then
2443         dnl This check is done also if --enable-modules is used;
2444         dnl it is duplicated here, 'cause it'd be cached anyway
2445         AC_CHECK_HEADERS(ltdl.h)
2446
2447         if test $ac_cv_header_ltdl_h != yes ; then
2448                 AC_MSG_ERROR([could not locate <ltdl.h>])
2449         fi
2450         AC_CHECK_LIB(ltdl, lt_dlinit, [
2451                 SLAPI_LIBS=-lltdl
2452                 LIBSLAPI=libslapi.a
2453                 LIBSLAPITOOLS=../libslapi.a
2454                 AC_DEFINE(HAVE_LIBLTDL,1,[define if you have libtool -ltdl])
2455         ],[AC_MSG_ERROR([could not locate libtool -lltdl])])
2456
2457         AC_DEFINE(LDAP_SLAPI,1, [define this to add SLAPI code])
2458 fi
2459
2460 if test "$ol_enable_debug" != no ; then
2461         if test "$ol_enable_debug" = traditional; then
2462                 AC_DEFINE(OLD_DEBUG,1,
2463                         [define to use the original debug style])
2464         fi
2465         AC_DEFINE(LDAP_DEBUG,1,
2466                 [define this to add debugging code])
2467 fi
2468 if test "$ol_enable_syslog" = yes ; then
2469         AC_DEFINE(LDAP_SYSLOG,1,
2470                 [define this to add syslog code])
2471 fi
2472 if test "$ol_enable_proctitle" != no ; then
2473         AC_DEFINE(LDAP_PROCTITLE,1,
2474                 [define this for LDAP process title support])
2475 fi
2476 if test "$ol_enable_referrals" != no ; then
2477         AC_DEFINE(LDAP_API_FEATURE_X_OPENLDAP_V2_REFERRALS,LDAP_VENDOR_VERSION,
2478                 [define to LDAP VENDOR VERSION])
2479 fi
2480 if test "$ol_enable_local" != no; then
2481         AC_DEFINE(LDAP_PF_LOCAL,1,[define to support PF_LOCAL])
2482 fi
2483 if test "$ol_link_ipv6" != no; then
2484         AC_DEFINE(LDAP_PF_INET6,1,[define to support PF_INET6])
2485 fi
2486 if test "$ol_enable_cleartext" != no ; then
2487         AC_DEFINE(SLAPD_CLEARTEXT,1,[define to support cleartext passwords])
2488 fi
2489 if test "$ol_enable_crypt" != no ; then
2490         AC_DEFINE(SLAPD_CRYPT,1,[define to support crypt(3) passwords])
2491 fi
2492 if test "$ol_link_spasswd" != no ; then
2493         AC_DEFINE(SLAPD_SPASSWD,1,[define to support SASL passwords])
2494 fi
2495 if test "$ol_enable_rlookups" != no ; then
2496         AC_DEFINE(SLAPD_RLOOKUPS,1,[define to support reverse lookups])
2497 fi
2498 if test "$ol_enable_aci" != no ; then
2499         if test $ol_enable_dynacl = no ; then
2500                 ol_enable_dynacl=yes
2501                 AC_MSG_WARN([ACIs need dynacl])
2502         fi
2503         if test "$ol_enable_aci" = mod ; then
2504                 MFLAG=SLAPD_MOD_DYNAMIC
2505                 dnl remove this after moving servers/slapd/aci.c in contrib/slapd-modules/acl
2506                 AC_MSG_ERROR([ACI build as dynamic module not supported (yet)])
2507         else
2508                 MFLAG=SLAPD_MOD_STATIC
2509         fi
2510         WITH_ACI_ENABLED=$ol_enable_aci
2511         AC_DEFINE_UNQUOTED(SLAPD_ACI_ENABLED,$MFLAG,[define to support per-object ACIs])
2512 else
2513         WITH_ACI_ENABLED=no
2514 fi
2515 if test "$ol_enable_dynacl" != no ; then
2516         AC_DEFINE(SLAP_DYNACL,1,[define to support run-time loadable ACL])
2517 fi
2518
2519 if test "$ol_link_modules" != no ; then
2520         AC_DEFINE(SLAPD_MODULES,1,[define to support modules])
2521         BUILD_SLAPD=yes
2522         SLAPD_MODULES_LDFLAGS="-dlopen self"
2523 fi
2524
2525 AC_DEFINE(SLAPD_MOD_STATIC,1,[statically linked module])
2526 AC_DEFINE(SLAPD_MOD_DYNAMIC,2,[dynamically linked module])
2527
2528 dnl back-monitor goes first (well, after back-config)
2529 if test "$ol_enable_monitor" != no ; then
2530         BUILD_SLAPD=yes
2531         BUILD_MONITOR=$ol_enable_monitor
2532         if test "$ol_enable_monitor" = mod ; then
2533                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-monitor"
2534                 MFLAG=SLAPD_MOD_DYNAMIC
2535         else
2536                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-monitor"
2537                 MFLAG=SLAPD_MOD_STATIC
2538         fi
2539         AC_DEFINE_UNQUOTED(SLAPD_MONITOR,$MFLAG,[define to support cn=Monitor backend])
2540 fi
2541
2542 if test "$ol_enable_bdb" != no ; then
2543         BUILD_SLAPD=yes
2544         BUILD_BDB=$ol_enable_bdb
2545         if test "$ol_enable_bdb" = mod ; then
2546                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-bdb"
2547                 MFLAG=SLAPD_MOD_DYNAMIC
2548         else
2549                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-bdb"
2550                 MFLAG=SLAPD_MOD_STATIC
2551         fi
2552         AC_DEFINE_UNQUOTED(SLAPD_BDB,$MFLAG,[define to support BDB backend])
2553 fi
2554
2555 if test "$ol_enable_dnssrv" != no ; then
2556         BUILD_SLAPD=yes
2557         BUILD_DNSSRV=$ol_enable_dnssrv
2558         if test "$ol_enable_dnssrv" = mod ; then
2559                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-dnssrv"
2560                 MFLAG=SLAPD_MOD_DYNAMIC
2561         else
2562                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-dnssrv"
2563                 MFLAG=SLAPD_MOD_STATIC
2564         fi
2565         AC_DEFINE_UNQUOTED(SLAPD_DNSSRV,$MFLAG,[define to support DNS SRV backend])
2566 fi
2567
2568 if test "$ol_enable_hdb" != no ; then
2569         BUILD_SLAPD=yes
2570         BUILD_HDB=$ol_enable_hdb
2571         if test "$ol_enable_hdb" = mod ; then
2572                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-hdb"
2573                 MFLAG=SLAPD_MOD_DYNAMIC
2574         else
2575                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-hdb"
2576                 MFLAG=SLAPD_MOD_STATIC
2577         fi
2578         AC_DEFINE_UNQUOTED(SLAPD_HDB,$MFLAG,[define to support HDB backend])
2579 fi
2580
2581 if test "$ol_enable_ldap" != no ; then
2582         BUILD_SLAPD=yes
2583         BUILD_LDAP=$ol_enable_ldap
2584         if test "$ol_enable_ldap" = mod ; then
2585                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ldap"
2586                 MFLAG=SLAPD_MOD_DYNAMIC
2587         else
2588                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ldap"
2589                 MFLAG=SLAPD_MOD_STATIC
2590         fi
2591         AC_DEFINE_UNQUOTED(SLAPD_LDAP,$MFLAG,[define to support LDAP backend])
2592 fi
2593
2594 if test "$ol_enable_meta" != no ; then
2595         BUILD_SLAPD=yes
2596         BUILD_META=$ol_enable_meta
2597         BUILD_REWRITE=yes
2598         if test "$ol_enable_meta" = mod ; then
2599                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-meta"
2600                 MFLAG=SLAPD_MOD_DYNAMIC
2601         else
2602                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-meta"
2603                 MFLAG=SLAPD_MOD_STATIC
2604         fi
2605         AC_DEFINE_UNQUOTED(SLAPD_META,$MFLAG,[define to support LDAP Metadirectory backend])
2606 fi
2607
2608 if test "$ol_enable_ndb" != no ; then
2609         BUILD_SLAPD=yes
2610         BUILD_NDB=$ol_enable_ndb
2611         if test "$ol_enable_ndb" = mod ; then
2612                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-ndb"
2613                 MFLAG=SLAPD_MOD_DYNAMIC
2614         else
2615                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-ndb"
2616                 MFLAG=SLAPD_MOD_STATIC
2617         fi
2618         AC_DEFINE_UNQUOTED(SLAPD_NDB,$MFLAG,[define to support NDB backend])
2619 fi
2620
2621 if test "$ol_enable_null" != no ; then
2622         BUILD_SLAPD=yes
2623         BUILD_NULL=$ol_enable_null
2624         if test "$ol_enable_null" = mod ; then
2625                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-null"
2626                 MFLAG=SLAPD_MOD_DYNAMIC
2627         else
2628                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-null"
2629                 MFLAG=SLAPD_MOD_STATIC
2630         fi
2631         AC_DEFINE_UNQUOTED(SLAPD_NULL,$MFLAG,[define to support NULL backend])
2632 fi
2633
2634 if test "$ol_enable_passwd" != no ; then
2635         BUILD_SLAPD=yes
2636         BUILD_PASSWD=$ol_enable_passwd
2637         if test "$ol_enable_passwd" = mod ; then
2638                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-passwd"
2639                 MFLAG=SLAPD_MOD_DYNAMIC
2640         else
2641                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-passwd"
2642                 MFLAG=SLAPD_MOD_STATIC
2643         fi
2644         AC_DEFINE_UNQUOTED(SLAPD_PASSWD,$MFLAG,[define to support PASSWD backend])
2645 fi
2646
2647 if test "$ol_link_perl" != no ; then
2648         BUILD_SLAPD=yes
2649         BUILD_PERL=$ol_enable_perl
2650         if test "$ol_enable_perl" = mod ; then
2651                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-perl"
2652                 MFLAG=SLAPD_MOD_DYNAMIC
2653         else
2654                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-perl"
2655                 MFLAG=SLAPD_MOD_STATIC
2656         fi
2657         AC_DEFINE_UNQUOTED(SLAPD_PERL,$MFLAG,[define to support PERL backend])
2658 fi
2659
2660 if test "$ol_enable_relay" != no ; then
2661         BUILD_SLAPD=yes
2662         BUILD_RELAY=$ol_enable_relay
2663         if test "$ol_enable_relay" = mod ; then
2664                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-relay"
2665                 MFLAG=SLAPD_MOD_DYNAMIC
2666         else
2667                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-relay"
2668                 MFLAG=SLAPD_MOD_STATIC
2669         fi
2670         AC_DEFINE_UNQUOTED(SLAPD_RELAY,$MFLAG,[define to support relay backend])
2671 fi
2672
2673 if test "$ol_enable_shell" != no ; then
2674         if test "$ol_link_threads" != no ; then
2675                 AC_MSG_WARN([Use of --without-threads is recommended with back-shell])
2676         fi
2677         BUILD_SLAPD=yes
2678         BUILD_SHELL=$ol_enable_shell
2679         if test "$ol_enable_shell" = mod ; then
2680                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-shell"
2681                 MFLAG=SLAPD_MOD_DYNAMIC
2682         else
2683                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-shell"
2684                 MFLAG=SLAPD_MOD_STATIC
2685         fi
2686         AC_DEFINE_UNQUOTED(SLAPD_SHELL,$MFLAG,[define to support SHELL backend])
2687 fi
2688
2689 if test "$ol_enable_sock" != no ; then
2690         BUILD_SLAPD=yes
2691         BUILD_SOCK=$ol_enable_sock
2692         if test "$ol_enable_sock" = mod ; then
2693                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sock"
2694                 MFLAG=SLAPD_MOD_DYNAMIC
2695         else
2696                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sock"
2697                 MFLAG=SLAPD_MOD_STATIC
2698         fi
2699         AC_DEFINE_UNQUOTED(SLAPD_SOCK,$MFLAG,[define to support SOCK backend])
2700 fi
2701
2702 if test "$ol_link_sql" != no ; then
2703         BUILD_SLAPD=yes
2704         BUILD_SQL=$ol_enable_sql
2705         if test "$ol_enable_sql" = mod; then
2706                 SLAPD_DYNAMIC_BACKENDS="$SLAPD_DYNAMIC_BACKENDS back-sql"
2707                 MFLAG=SLAPD_MOD_DYNAMIC
2708         else
2709                 SLAPD_STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS back-sql"
2710                 MFLAG=SLAPD_MOD_STATIC
2711         fi
2712         AC_DEFINE_UNQUOTED(SLAPD_SQL,$MFLAG,[define to support SQL backend])
2713 fi
2714
2715 if test "$ol_enable_accesslog" != no ; then
2716         BUILD_ACCESSLOG=$ol_enable_accesslog
2717         if test "$ol_enable_accesslog" = mod ; then
2718                 MFLAG=SLAPD_MOD_DYNAMIC
2719                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS accesslog.la"
2720         else
2721                 MFLAG=SLAPD_MOD_STATIC
2722                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS accesslog.o"
2723         fi
2724         AC_DEFINE_UNQUOTED(SLAPD_OVER_ACCESSLOG,$MFLAG,[define for In-Directory Access Logging overlay])
2725 fi
2726
2727 if test "$ol_enable_auditlog" != no ; then
2728         BUILD_AUDITLOG=$ol_enable_auditlog
2729         if test "$ol_enable_auditlog" = mod ; then
2730                 MFLAG=SLAPD_MOD_DYNAMIC
2731                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS auditlog.la"
2732         else
2733                 MFLAG=SLAPD_MOD_STATIC
2734                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS auditlog.o"
2735         fi
2736         AC_DEFINE_UNQUOTED(SLAPD_OVER_AUDITLOG,$MFLAG,[define for Audit Logging overlay])
2737 fi
2738
2739 if test "$ol_enable_constraint" != no ; then
2740         BUILD_CONSTRAINT=$ol_enable_constraint
2741         if test "$ol_enable_constraint" = mod ; then
2742                 MFLAG=SLAPD_MOD_DYNAMIC
2743                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS constraint.la"
2744         else
2745                 MFLAG=SLAPD_MOD_STATIC
2746                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS constraint.o"
2747         fi
2748         AC_DEFINE_UNQUOTED(SLAPD_OVER_CONSTRAINT,$MFLAG,[define for Attribute Constraint overlay])
2749 fi
2750
2751 if test "$ol_enable_dds" != no ; then
2752         BUILD_DDS=$ol_enable_dds
2753         if test "$ol_enable_dds" = mod ; then
2754                 MFLAG=SLAPD_MOD_DYNAMIC
2755                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dds.la"
2756         else
2757                 MFLAG=SLAPD_MOD_STATIC
2758                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dds.o"
2759         fi
2760         AC_DEFINE_UNQUOTED(SLAPD_OVER_DDS,$MFLAG,[define for Dynamic Directory Services overlay])
2761 fi
2762
2763 if test "$ol_enable_dyngroup" != no ; then
2764         BUILD_DYNGROUP=$ol_enable_dyngroup
2765         if test "$ol_enable_dyngroup" = mod ; then
2766                 MFLAG=SLAPD_MOD_DYNAMIC
2767                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dyngroup.la"
2768         else
2769                 MFLAG=SLAPD_MOD_STATIC
2770                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dyngroup.o"
2771         fi
2772         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNGROUP,$MFLAG,[define for Dynamic Group overlay])
2773 fi
2774
2775 if test "$ol_enable_dynlist" != no ; then
2776         BUILD_DYNLIST=$ol_enable_dynlist
2777         if test "$ol_enable_dynlist" = mod ; then
2778                 MFLAG=SLAPD_MOD_DYNAMIC
2779                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS dynlist.la"
2780         else
2781                 MFLAG=SLAPD_MOD_STATIC
2782                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS dynlist.o"
2783         fi
2784         AC_DEFINE_UNQUOTED(SLAPD_OVER_DYNLIST,$MFLAG,[define for Dynamic List overlay])
2785 fi
2786
2787 if test "$ol_enable_memberof" != no ; then
2788         BUILD_MEMBEROF=$ol_enable_memberof
2789         if test "$ol_enable_memberof" = mod ; then
2790                 MFLAG=SLAPD_MOD_DYNAMIC
2791                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS memberof.la"
2792         else
2793                 MFLAG=SLAPD_MOD_STATIC
2794                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS memberof.o"
2795         fi
2796         AC_DEFINE_UNQUOTED(SLAPD_OVER_MEMBEROF,$MFLAG,[define for Reverse Group Membership overlay])
2797 fi
2798
2799 if test "$ol_enable_ppolicy" != no ; then
2800         BUILD_PPOLICY=$ol_enable_ppolicy
2801         if test "$ol_enable_ppolicy" = mod ; then
2802                 MFLAG=SLAPD_MOD_DYNAMIC
2803                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS ppolicy.la"
2804         else
2805                 MFLAG=SLAPD_MOD_STATIC
2806                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS ppolicy.o"
2807         fi
2808         AC_DEFINE_UNQUOTED(SLAPD_OVER_PPOLICY,$MFLAG,[define for Password Policy overlay])
2809 fi
2810
2811 if test "$ol_enable_proxycache" != no ; then
2812         BUILD_PROXYCACHE=$ol_enable_proxycache
2813         if test "$ol_enable_proxycache" = mod ; then
2814                 MFLAG=SLAPD_MOD_DYNAMIC
2815                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS pcache.la"
2816         else
2817                 MFLAG=SLAPD_MOD_STATIC
2818                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS pcache.o"
2819         fi
2820         AC_DEFINE_UNQUOTED(SLAPD_OVER_PROXYCACHE,$MFLAG,[define for Proxy Cache overlay])
2821 fi
2822
2823 if test "$ol_enable_refint" != no ; then
2824         BUILD_REFINT=$ol_enable_refint
2825         if test "$ol_enable_refint" = mod ; then
2826                 MFLAG=SLAPD_MOD_DYNAMIC
2827                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS refint.la"
2828         else
2829                 MFLAG=SLAPD_MOD_STATIC
2830                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS refint.o"
2831         fi
2832         AC_DEFINE_UNQUOTED(SLAPD_OVER_REFINT,$MFLAG,[define for Referential Integrity overlay])
2833 fi
2834
2835 if test "$ol_enable_retcode" != no ; then
2836         BUILD_RETCODE=$ol_enable_retcode
2837         if test "$ol_enable_retcode" = mod ; then
2838                 MFLAG=SLAPD_MOD_DYNAMIC
2839                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS retcode.la"
2840         else
2841                 MFLAG=SLAPD_MOD_STATIC
2842                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS retcode.o"
2843         fi
2844         AC_DEFINE_UNQUOTED(SLAPD_OVER_RETCODE,$MFLAG,[define for Referential Integrity overlay])
2845 fi
2846
2847 if test "$ol_enable_rwm" != no ; then
2848         BUILD_REWRITE=yes
2849         BUILD_RWM=$ol_enable_rwm
2850         if test "$ol_enable_rwm" = mod ; then
2851                 MFLAG=SLAPD_MOD_DYNAMIC
2852                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS rwm.la"
2853         else
2854                 MFLAG=SLAPD_MOD_STATIC
2855                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS rwm_x.o"
2856         fi
2857         AC_DEFINE_UNQUOTED(SLAPD_OVER_RWM,$MFLAG,[define for Rewrite/Remap overlay])
2858 fi
2859
2860 if test "$ol_enable_seqmod" != no ; then
2861         BUILD_SEQMOD=$ol_enable_seqmod
2862         if test "$ol_enable_seqmod" = mod ; then
2863                 MFLAG=SLAPD_MOD_DYNAMIC
2864                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS seqmod.la"
2865         else
2866                 MFLAG=SLAPD_MOD_STATIC
2867                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS seqmod.o"
2868         fi
2869         AC_DEFINE_UNQUOTED(SLAPD_OVER_SEQMOD,$MFLAG,[define for Sequential Modify overlay])
2870 fi
2871
2872 if test "$ol_enable_syncprov" != no ; then
2873         BUILD_SYNCPROV=$ol_enable_syncprov
2874         if test "$ol_enable_syncprov" = mod ; then
2875                 MFLAG=SLAPD_MOD_DYNAMIC
2876                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS syncprov.la"
2877         else
2878                 MFLAG=SLAPD_MOD_STATIC
2879                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS syncprov.o"
2880         fi
2881         AC_DEFINE_UNQUOTED(SLAPD_OVER_SYNCPROV,$MFLAG,[define for Syncrepl Provider overlay])
2882 fi
2883
2884 if test "$ol_enable_translucent" != no ; then
2885         BUILD_TRANSLUCENT=$ol_enable_translucent
2886         if test "$ol_enable_translucent" = mod ; then
2887                 MFLAG=SLAPD_MOD_DYNAMIC
2888                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS translucent.la"
2889         else
2890                 MFLAG=SLAPD_MOD_STATIC
2891                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS translucent.o"
2892         fi
2893         AC_DEFINE_UNQUOTED(SLAPD_OVER_TRANSLUCENT,$MFLAG,[define for Translucent Proxy overlay])
2894 fi
2895
2896 if test "$ol_enable_unique" != no ; then
2897         BUILD_UNIQUE=$ol_enable_unique
2898         if test "$ol_enable_unique" = mod ; then
2899                 MFLAG=SLAPD_MOD_DYNAMIC
2900                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS unique.la"
2901         else
2902                 MFLAG=SLAPD_MOD_STATIC
2903                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS unique.o"
2904         fi
2905         AC_DEFINE_UNQUOTED(SLAPD_OVER_UNIQUE,$MFLAG,[define for Attribute Uniqueness overlay])
2906 fi
2907
2908 if test "$ol_enable_valsort" != no ; then
2909         BUILD_VALSORT=$ol_enable_valsort
2910         if test "$ol_enable_valsort" = mod ; then
2911                 MFLAG=SLAPD_MOD_DYNAMIC
2912                 SLAPD_DYNAMIC_OVERLAYS="$SLAPD_DYNAMIC_OVERLAYS valsort.la"
2913         else
2914                 MFLAG=SLAPD_MOD_STATIC
2915                 SLAPD_STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS valsort.o"
2916         fi
2917         AC_DEFINE_UNQUOTED(SLAPD_OVER_VALSORT,$MFLAG,[define for Value Sorting overlay])
2918 fi
2919
2920 if test "$ol_enable_rewrite" != no ; then
2921         AC_DEFINE(ENABLE_REWRITE,1,[define to enable rewriting in back-ldap and back-meta])
2922         BUILD_REWRITE=yes
2923 fi
2924
2925 if test "$ol_enable_slapi" != no ; then
2926         AC_DEFINE(ENABLE_SLAPI,1,[define to enable slapi library])
2927         BUILD_SLAPI=yes
2928         SLAPD_SLAPI_DEPEND=libslapi.a
2929 fi
2930
2931 dnl ----------------------------------------------------------------
2932
2933 dnl
2934 dnl For Windows build, we don't want to include -dlopen flags.
2935 dnl They hurt more than they help.
2936 dnl
2937
2938 if test "$ac_cv_mingw32" = yes ; then
2939         PLAT=NT
2940         SLAPD_MODULES_LDFLAGS=
2941 else
2942         PLAT=UNIX
2943 fi
2944
2945 AC_SUBST(LIBSRCS)
2946 AC_SUBST(PLAT)
2947 AC_SUBST(WITH_SASL)
2948 AC_SUBST(WITH_TLS)
2949 AC_SUBST(WITH_MODULES_ENABLED)
2950 AC_SUBST(WITH_ACI_ENABLED)
2951 AC_SUBST(BUILD_THREAD)
2952 AC_SUBST(BUILD_LIBS_DYNAMIC)
2953
2954 AC_SUBST(BUILD_SLAPD)
2955 dnl slapi
2956   AC_SUBST(BUILD_SLAPI)
2957   AC_SUBST(SLAPD_SLAPI_DEPEND)
2958 dnl backends
2959   AC_SUBST(BUILD_BDB)
2960   AC_SUBST(BUILD_DNSSRV)
2961   AC_SUBST(BUILD_HDB)
2962   AC_SUBST(BUILD_LDAP)
2963   AC_SUBST(BUILD_META)
2964   AC_SUBST(BUILD_MONITOR)
2965   AC_SUBST(BUILD_NDB)
2966   AC_SUBST(BUILD_NULL)
2967   AC_SUBST(BUILD_PASSWD)
2968   AC_SUBST(BUILD_RELAY)
2969   AC_SUBST(BUILD_PERL)
2970   AC_SUBST(BUILD_SHELL)
2971   AC_SUBST(BUILD_SOCK)
2972   AC_SUBST(BUILD_SQL)
2973 dnl overlays
2974   AC_SUBST(BUILD_ACCESSLOG)
2975   AC_SUBST(BUILD_AUDITLOG)
2976   AC_SUBST(BUILD_CONSTRAINT)
2977   AC_SUBST(BUILD_DDS)
2978   AC_SUBST(BUILD_DENYOP)
2979   AC_SUBST(BUILD_DYNGROUP)
2980   AC_SUBST(BUILD_DYNLIST)
2981   AC_SUBST(BUILD_LASTMOD)
2982   AC_SUBST(BUILD_MEMBEROF)
2983   AC_SUBST(BUILD_PPOLICY)
2984   AC_SUBST(BUILD_PROXYCACHE)
2985   AC_SUBST(BUILD_REFINT)
2986   AC_SUBST(BUILD_RETCODE)
2987   AC_SUBST(BUILD_RWM)
2988   AC_SUBST(BUILD_SEQMOD)
2989   AC_SUBST(BUILD_SYNCPROV)
2990   AC_SUBST(BUILD_TRANSLUCENT)
2991   AC_SUBST(BUILD_UNIQUE)
2992   AC_SUBST(BUILD_VALSORT)
2993
2994 AC_SUBST(LDAP_LIBS)
2995 AC_SUBST(SLAPD_LIBS)
2996 AC_SUBST(BDB_LIBS)
2997 AC_SUBST(SLAPD_NDB_LIBS)
2998 AC_SUBST(SLAPD_NDB_INCS)
2999 AC_SUBST(LTHREAD_LIBS)
3000 AC_SUBST(LUTIL_LIBS)
3001 AC_SUBST(WRAP_LIBS)
3002
3003 AC_SUBST(SLAPD_MODULES_CPPFLAGS)
3004 AC_SUBST(SLAPD_MODULES_LDFLAGS)
3005
3006 AC_SUBST(SLAPD_NO_STATIC)
3007 AC_SUBST(SLAPD_STATIC_BACKENDS)
3008 AC_SUBST(SLAPD_DYNAMIC_BACKENDS)
3009 AC_SUBST(SLAPD_STATIC_OVERLAYS)
3010 AC_SUBST(SLAPD_DYNAMIC_OVERLAYS)
3011
3012 AC_SUBST(PERL_CPPFLAGS)
3013 AC_SUBST(SLAPD_PERL_LDFLAGS)
3014 AC_SUBST(MOD_PERL_LDFLAGS)
3015
3016 AC_SUBST(KRB4_LIBS)
3017 AC_SUBST(KRB5_LIBS)
3018 AC_SUBST(SASL_LIBS)
3019 AC_SUBST(TLS_LIBS)
3020 AC_SUBST(MODULES_LIBS)
3021 AC_SUBST(SLAPI_LIBS)
3022 AC_SUBST(LIBSLAPI)
3023 AC_SUBST(LIBSLAPITOOLS)
3024 AC_SUBST(AUTH_LIBS)
3025 AC_SUBST(ICU_LIBS)
3026
3027 AC_SUBST(SLAPD_SLP_LIBS)
3028 AC_SUBST(SLAPD_GMP_LIBS)
3029
3030 AC_SUBST(SLAPD_SQL_LDFLAGS)
3031 AC_SUBST(SLAPD_SQL_LIBS)
3032 AC_SUBST(SLAPD_SQL_INCLUDES)
3033
3034 dnl ----------------------------------------------------------------
3035 dnl final help output
3036 AC_ARG_WITH(xxinstall,[
3037 See INSTALL file for further details.])
3038
3039 dnl ----------------------------------------------------------------
3040 dnl final output
3041 dnl
3042
3043 AC_CONFIG_FILES([Makefile:build/top.mk:Makefile.in:build/dir.mk]
3044 [doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk]
3045 [doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk]
3046 [doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk]
3047 [doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk]
3048 [doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk]
3049 [doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk]
3050 [clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk]
3051 [clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk]
3052 [include/Makefile:build/top.mk:include/Makefile.in]
3053 [libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk]
3054 [libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk:build/lib-shared.mk]
3055 [libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk:build/lib-shared.mk]
3056 [libraries/libldap_r/Makefile:build/top.mk:libraries/libldap_r/Makefile.in:build/lib.mk:build/lib-shared.mk]
3057 [libraries/liblunicode/Makefile:build/top.mk:libraries/liblunicode/Makefile.in:build/lib.mk:build/lib-static.mk]
3058 [libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk:build/lib-static.mk]
3059 [libraries/librewrite/Makefile:build/top.mk:libraries/librewrite/Makefile.in:build/lib.mk:build/lib-static.mk]
3060 [servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk]
3061 [servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk]
3062 [servers/slapd/back-bdb/Makefile:build/top.mk:servers/slapd/back-bdb/Makefile.in:build/mod.mk]
3063 [servers/slapd/back-dnssrv/Makefile:build/top.mk:servers/slapd/back-dnssrv/Makefile.in:build/mod.mk]
3064 [servers/slapd/back-hdb/Makefile:build/top.mk:servers/slapd/back-hdb/Makefile.in:build/mod.mk]
3065 [servers/slapd/back-ldap/Makefile:build/top.mk:servers/slapd/back-ldap/Makefile.in:build/mod.mk]
3066 [servers/slapd/back-ldif/Makefile:build/top.mk:servers/slapd/back-ldif/Makefile.in:build/mod.mk]
3067 [servers/slapd/back-meta/Makefile:build/top.mk:servers/slapd/back-meta/Makefile.in:build/mod.mk]
3068 [servers/slapd/back-monitor/Makefile:build/top.mk:servers/slapd/back-monitor/Makefile.in:build/mod.mk]
3069 [servers/slapd/back-ndb/Makefile:build/top.mk:servers/slapd/back-ndb/Makefile.in:build/mod.mk]
3070 [servers/slapd/back-null/Makefile:build/top.mk:servers/slapd/back-null/Makefile.in:build/mod.mk]
3071 [servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/mod.mk]
3072 [servers/slapd/back-perl/Makefile:build/top.mk:servers/slapd/back-perl/Makefile.in:build/mod.mk]
3073 [servers/slapd/back-relay/Makefile:build/top.mk:servers/slapd/back-relay/Makefile.in:build/mod.mk]
3074 [servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/mod.mk]
3075 [servers/slapd/back-sock/Makefile:build/top.mk:servers/slapd/back-sock/Makefile.in:build/mod.mk]
3076 [servers/slapd/back-sql/Makefile:build/top.mk:servers/slapd/back-sql/Makefile.in:build/mod.mk]
3077 [servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk]
3078 [servers/slapd/slapi/Makefile:build/top.mk:servers/slapd/slapi/Makefile.in:build/lib.mk:build/lib-shared.mk]
3079 [servers/slapd/overlays/Makefile:build/top.mk:servers/slapd/overlays/Makefile.in:build/lib.mk]
3080 [tests/Makefile:build/top.mk:tests/Makefile.in:build/dir.mk]
3081 [tests/run]
3082 [tests/progs/Makefile:build/top.mk:tests/progs/Makefile.in:build/rules.mk])
3083
3084 AC_CONFIG_COMMANDS([default],[[
3085 chmod +x tests/run
3086 date > stamp-h
3087 BACKENDSC="servers/slapd/backends.c"
3088 echo "Making $BACKENDSC"
3089 rm -f $BACKENDSC
3090 cat > $BACKENDSC << ENDX
3091 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3092  *
3093  * Copyright 1998-2008 The OpenLDAP Foundation.
3094  * All rights reserved.
3095  *
3096  * Redistribution and use in source and binary forms, with or without
3097  * modification, are permitted only as authorized by the OpenLDAP
3098  * Public License.
3099  *
3100  * A copy of this license is available in the file LICENSE in the
3101  * top-level directory of the distribution or, alternatively, at
3102  * <http://www.OpenLDAP.org/license.html>.
3103  */
3104 /* This file is automatically generated by configure; please do not edit. */
3105
3106 #include "portable.h"
3107 #include "slap.h"
3108
3109 ENDX
3110 if test "${STATIC_BACKENDS}"; then
3111         for b in config ${STATIC_BACKENDS}; do
3112                 bb=`echo "${b}" | sed -e 's/back-//'`
3113                 cat >> $BACKENDSC << ENDX
3114 extern BI_init ${bb}_back_initialize;
3115 ENDX
3116         done
3117
3118         cat >> $BACKENDSC << ENDX
3119
3120 BackendInfo slap_binfo[] = {
3121 ENDX
3122
3123         for b in config ${STATIC_BACKENDS}; do
3124                 bb=`echo "${b}" | sed -e 's/back-//'`
3125                 echo "    Add ${bb} ..."
3126                 cat >> $BACKENDSC << ENDX
3127         { "${bb}", ${bb}_back_initialize },
3128 ENDX
3129         done
3130
3131         cat >> $BACKENDSC << ENDX
3132         { NULL, NULL },
3133 };
3134
3135 /* end of generated file */
3136 ENDX
3137 fi
3138 OVERLAYSC="servers/slapd/overlays/statover.c"
3139 echo "Making $OVERLAYSC"
3140 rm -f $OVERLAYSC
3141 cat > $OVERLAYSC << ENDX
3142 /* This work is part of OpenLDAP Software <http://www.openldap.org/>.
3143  *
3144  * Copyright 1998-2008 The OpenLDAP Foundation.
3145  * All rights reserved.
3146  *
3147  * Redistribution and use in source and binary forms, with or without
3148  * modification, are permitted only as authorized by the OpenLDAP
3149  * Public License.
3150  *
3151  * A copy of this license is available in the file LICENSE in the
3152  * top-level directory of the distribution or, alternatively, at
3153  * <http://www.OpenLDAP.org/license.html>.
3154  */
3155 /* This file is automatically generated by configure; please do not edit. */
3156
3157 #include "portable.h"
3158 #include "slap.h"
3159
3160 ENDX
3161 if test "${STATIC_OVERLAYS}"; then
3162         for o in ${STATIC_OVERLAYS}; do
3163                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3164                 cat >> $OVERLAYSC << ENDX
3165 extern OV_init ${oo}_initialize;
3166 ENDX
3167         done
3168 fi
3169
3170 cat >> $OVERLAYSC << ENDX
3171
3172 OverlayInit slap_oinfo[] = {
3173 ENDX
3174
3175 if test "${STATIC_OVERLAYS}"; then
3176         for o in ${STATIC_OVERLAYS}; do
3177                 oo=`echo "${o}" | sed -e 's/.o$//' -e 's/_x$//'`
3178                 echo "    Add ${oo} ..."
3179                 cat >> $OVERLAYSC << ENDX
3180         { "${oo}", ${oo}_initialize },
3181 ENDX
3182         done
3183 fi
3184
3185         cat >> $OVERLAYSC << ENDX
3186         { NULL, NULL },
3187 };
3188
3189 /* end of generated file */
3190 ENDX
3191
3192 if test "${ol_cv_mkdep}" = no; then
3193         echo '(Do not "make depend"; we do not know how to build dependencies)'
3194 else
3195         echo 'Please run "make depend" to build dependencies'
3196 fi
3197 ]],[[
3198 STATIC_BACKENDS="$SLAPD_STATIC_BACKENDS"
3199 STATIC_OVERLAYS="$SLAPD_STATIC_OVERLAYS"
3200 ]])
3201 AC_OUTPUT