git.sur5r.net Git - openldap/blob - configure.in

   1 dnl Copyright 1998 The OpenLDAP Foundation.  All Rights Reserved.
   2 dnl
   3 dnl Redistribution and use in source and binary forms are permitted only
   4 dnl as authorized by the OpenLDAP Public License.  A copy of this
   5 dnl license is available at http://www.OpenLDAP.org/license.html or
   6 dnl in file LICENSE in the top-level directory of the distribution.
   7 dnl ----
   8 dnl Configure.in for OpenLDAP
   9 dnl
  10 AC_INIT(include/ldap.h)
  11 dnl
  12 dnl
  13 AC_PREREQ(2.10)dnl Required Autoconf version
  14 dnl Do not use AutoConf 2.12; it produces a configuration script
  15 dnl that causes an "internal 2K buffer" error on HPUX when run
  16 dnl with /bin/sh.  Autoconf 2.10 seems to be okay.
  17 AC_CONFIG_AUX_DIR(build)
  18 AC_CONFIG_HEADER(include/portable.h)dnl
  19 dnl
  20 dnl Start Args
  21 AC_MSG_CHECKING(configure arguments)
  22 AC_PREFIX_DEFAULT(/usr/local)
  23
  24 dnl General "enable" options
  25 OL_ARG_ENABLE(debug,[  --enable-debug   enable debugging], yes)dnl
  26 dnl OL_ARG_ENABLE(syslog,[  --enable-syslog     enable syslog support], auto)dnl
  27 OL_ARG_ENABLE(proctitle,[  --enable-proctitle   enable proctitle support], yes)dnl
  28 OL_ARG_ENABLE(libui,[  --enable-libui   enable library user interface], yes)dnl
  29 OL_ARG_ENABLE(cache,[  --enable-cache   enable caching], yes)dnl
  30 OL_ARG_ENABLE(dns,[  --enable-dns               enable dns support], no)dnl
  31 OL_ARG_ENABLE(referrals,[  --enable-referrals   enable referrals], yes)dnl
  32 OL_ARG_ENABLE(cldap,[  --enable-cldap   enable connectionless ldap], no)dnl
  33 OL_ARG_ENABLE(x_compile,[  --enable-x-compile   enable cross compiling],
  34         no, [yes no])dnl
  35
  36 dnl General "with" options
  37 OL_ARG_WITH(kerberos,[  --with-kerberos use Kerberos],
  38         auto, [auto k5 k4 afs yes no])
  39 OL_ARG_WITH(threads,[  --with-threads   use threads],
  40         auto, [auto posix mach lwp yes no manual] )
  41 OL_ARG_WITH(preemptive,[  --with-preemptive     thread implementation is preemptive],
  42         auto, [auto yes no manual] )
  43
  44 dnl Server options
  45
  46 dnl LDAPD OPTIONS
  47 OL_ARG_ENABLE(ldapd,[  --enable-ldapd   enable building ldapd], no)dnl
  48
  49 dnl SLAPD OPTIONS
  50 OL_ARG_ENABLE(slapd,[  --enable-slapd   enable building slapd], yes)dnl
  51 OL_ARG_ENABLE(aclgroups,[    --enable-aclgroups enable ACL group support], auto)dnl
  52 OL_ARG_ENABLE(crypt,[    --enable-crypt enable crypt(3) passwords], auto)dnl
  53 OL_ARG_ENABLE(md5,[    --enable-md5     enable MD5 passwords], auto)dnl
  54 OL_ARG_ENABLE(sha1,[    --enable-sha1   enable SHA1 passwords], auto)dnl
  55 OL_ARG_ENABLE(wrappers,[    --enable-wrappers   enable tcp wrapper support], no)dnl
  56 OL_ARG_ENABLE(phonetic,[    --enable-phonetic   enable phonetic/soundex], no)dnl
  57 OL_ARG_ENABLE(rlookups,[    --enable-rlookups   enable reverse lookups], auto)dnl
  58
  59 dnl SLAPD Backend options
  60 OL_ARG_ENABLE(ldbm,[    --enable-ldbm   enable ldbm backend], yes)dnl
  61 OL_ARG_WITH(ldbm_api,[      --with-ldbm-api     use LDBM API], auto,
  62         [auto db2 db gdbm ndbm manual])
  63 OL_ARG_WITH(ldbm_type,[      --with-ldbm-type   use LDBM type], auto,
  64         [auto btree hash])
  65
  66 OL_ARG_ENABLE(passwd,[    --enable-passwd       enable passwd backend], no)dnl
  67 OL_ARG_ENABLE(shell,[    --enable-shell enable shell backend], no)dnl
  68
  69 dnl SLURPD OPTIONS
  70 OL_ARG_ENABLE(slurpd,[  --enable-slurpd enable building slurpd], auto)dnl
  71
  72 if test $ol_enable_slapd = no ; then
  73         dnl SLAPD was specificallly disabled
  74         if test $ol_enable_ldbm = yes ; then
  75                 AC_MSG_WARN([slapd disabled, ignoring --enable_ldbm argument])
  76         fi
  77         if test $ol_enable_passwd = yes ; then
  78                 AC_MSG_WARN([slapd disabled, ignoring --enable_passwd argument])
  79         fi
  80         if test $ol_enable_shell = yes ; then
  81                 AC_MSG_WARN([slapd disabled, ignoring --enable_shell argument])
  82         fi
  83         if test $ol_enable_aclgroups = yes ; then
  84                 AC_MSG_WARN([slapd disabled, ignoring --enable_aclgroups argument])
  85         fi
  86         if test $ol_enable_crypt = yes ; then
  87                 AC_MSG_WARN([slapd disabled, ignoring --enable_crypt argument])
  88         fi
  89         if test $ol_enable_md5 = yes ; then
  90                 AC_MSG_WARN([slapd disabled, ignoring --enable_md5 argument])
  91         fi
  92         if test $ol_enable_sha1 = yes ; then
  93                 AC_MSG_WARN([slapd disabled, ignoring --enable_sha1 argument])
  94         fi
  95         if test $ol_enable_wrappers = yes ; then
  96                 AC_MSG_WARN([slapd disabled, ignoring --enable_wrappers argument])
  97         fi
  98         if test $ol_enable_phonetic = yes ; then
  99                 AC_MSG_WARN([slapd disabled, ignoring --enable_phonetic argument])
 100         fi
 101         if test $ol_enable_rlookups = yes ; then
 102                 AC_MSG_WARN([slapd disabled, ignoring --enable_rlookups argument])
 103         fi
 104         if test $ol_with_ldbm_api != auto ; then
 105                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_api argument])
 106         fi
 107         if test $ol_with_ldbm_type != auto ; then
 108                 AC_MSG_WARN([slapd disabled, ignoring --with_ldbm_type argument])
 109         fi
 110         if test $ol_enable_slurpd = yes ; then
 111                 AC_MSG_ERROR([slurpd requires slapd])
 112         fi
 113
 114         # force settings to no
 115         ol_enable_ldbm=no
 116         ol_enable_shell=no
 117         ol_enable_passwd=no
 118         ol_enable_aclgroups=no
 119         ol_enable_crypt=no
 120         ol_enable_md5=no
 121         ol_enable_sha1=no
 122         ol_enable_wrappers=no
 123         ol_enable_phonetic=no
 124         ol_enable_rlookups=no
 125         ol_with_ldbm_api=no
 126         ol_with_ldbm_type=no
 127         ol_enable_slurpd=no
 128
 129 elif test $ol_enable_ldbm = no ; then
 130         dnl SLAPD without LDBM
 131
 132         if test $ol_with_ldbm_api != auto ; then
 133                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_api argument])
 134         fi
 135
 136         if test $ol_with_ldbm_type != auto ; then
 137                 AC_MSG_WARN([LDBM disabled, ignoring --with_ldbm_type argument])
 138         fi
 139
 140         if test $ol_enable_passwd = no -a $ol_enable_shell = no ; then
 141                 AC_MSG_ERROR([slapd requires a backend])
 142         fi
 143
 144         ol_with_ldbm_api=no
 145         ol_with_ldbm_type=no
 146
 147 else
 148         dnl SLAPD with LDBM
 149
 150         if test $ol_with_ldbm_api = gdbm -a \
 151                 $ol_with_ldbm_type = btree ; then
 152                 AC_MSG_ERROR([GDBM only supports LDBM type hash])
 153         fi
 154         if test $ol_with_ldbm_api = ndbm -a \
 155                 $ol_with_ldbm_type = btree ; then
 156                 AC_MSG_ERROR([NDBM only supports LDBM type hash])
 157         fi
 158 fi
 159
 160 if test $ol_enable_slurpd = yes ; then
 161         dnl SLURPD was specifically enabled
 162         if test $ol_with_threads = no ; then
 163                 AC_MSG_ERROR([slurpd requires threads])
 164         fi
 165 fi
 166
 167 AC_MSG_RESULT(done)
 168
 169 ## Initialize vars
 170 LDAP_LIBS=
 171 LDBM_LIBS=
 172 LTHREAD_LIBS=
 173 LUTIL_LIBS=
 174
 175 LDAPD_LIBS=
 176 SLAPD_LIBS=
 177 SLURPD_LIBS=
 178
 179 BUILD_LDAPD=no
 180 BUILD_SLAPD=no
 181 BUILD_SLURPD=no
 182
 183 BUILD_LDBM=no
 184 BUILD_PASSWD=no
 185 BUILD_SHELL=no
 186
 187 KRB_LIBS=
 188 TERMCAP_LIBS=
 189
 190 dnl ----------------------------------------------------------------
 191 dnl Checks for programs
 192
 193 AC_PROG_LN_S
 194 AC_PROG_INSTALL
 195 AC_PROG_RANLIB
 196 AC_PROG_MAKE_SET
 197
 198 AC_PATH_PROG(SENDMAIL, sendmail, /usr/lib/sendmail,
 199         $PATH:/usr/libexec:/usr/lib:/usr/sbin:/usr/etc:/etc)
 200 AC_PATH_PROG(EDITOR, vi, /usr/ucb/vi, $PATH:/usr/ucb)
 201 AC_PATH_PROG(FINGER, finger, /usr/ucb/finger, $PATH:/usr/ucb)
 202
 203 dnl Checks the compiler and UNIX Variants
 204 AC_PROG_CC
 205
 206 if test $cross_compiling = yes -a $ol_enable_x_compile = yes; then
 207         AC_WARN([cross compiling....  go for it])
 208
 209 elif test $cross_compiling = no -a $ol_enable_x_compile = yes; then
 210         AC_WARN([programs compiled here do run here...])
 211         AC_ERROR([  if not cross compiling, use --disable-x-compile.])
 212
 213 elif test $cross_compiling = yes -a $ol_enable_x_compile = no; then
 214         AC_WARN([programs compiled here do not run here...])
 215         AC_ERROR([  if cross compiling,  add --enable-x-compile.])
 216 fi
 217
 218 dnl OpenLDAP requires STDC features
 219 dnl AC_PROG_GCC_TRADITIONAL
 220 AC_PROG_CPP
 221
 222
 223 AC_AIX
 224 AC_ISC_POSIX
 225 AC_MINIX
 226
 227 dnl Checks for libraries
 228
 229 dnl Find socket()
 230 dnl Likely combinations:
 231 dnl             -lsocket [ -lnsl_s | -lnsl ]
 232 dnl             -linet
 233
 234 AC_CHECK_FUNC(socket, :, [
 235 dnl
 236 dnl hopefully we won't include too many libraries
 237 dnl
 238         AC_CHECK_LIB(socket, main)
 239         AC_CHECK_LIB(net, main)
 240         AC_CHECK_LIB(nsl_s, main)
 241         AC_CHECK_LIB(nsl, main)
 242         AC_CHECK_LIB(inet, socket)
 243         AC_CHECK_LIB(gen, main)
 244 ])
 245
 246 dnl need to add check for -lresolv
 247
 248 dnl HP-UX requires -lV3
 249 AC_CHECK_LIB(V3, sigset)
 250
 251 # ISODE tests
 252 ol_link_isode=no
 253 if test $ol_enable_ldapd != no ; then
 254         dnl look for ISODE libraries
 255         AC_CHECK_LIB(xtpp, main, [
 256                 ol_link_isode=yes
 257                 AC_DEFINE(HAVE_XTPP,1)
 258                 LDAPD_LIBS="$LDAPD_LIBS -lxtpp -lresolv -lxtdsap -lxtisode -losi"
 259                 ],:,[-lresolv -lxtdsap -lxtisode -losi])
 260         AC_CHECK_LIB(dsap, main, [
 261                 ol_link_isode=yes
 262                 AC_DEFINE(HAVE_DSAP,1)
 263                 LDAPD_LIBS="$LDAPD_LIBS -ldsap"
 264                 ],:,[-lisode])
 265         AC_CHECK_LIB(isode, main, [
 266                 ol_link_isode=yes
 267                 AC_DEFINE(HAVE_ISODE,1)
 268                 LDAPD_LIBS="$LDAPD_LIBS -lisode"
 269                 ],:)
 270 fi
 271
 272 if test $ol_link_isode != no; then
 273         AC_CHECK_LIB(pp, main, [
 274                 AC_DEFINE(HAVE_PP,1)
 275                 LDAPD_LIBS="-lpp $LDAPD_LIBS"
 276                 ],:)
 277
 278         AC_PATH_PROG(PEPSY, pepsy)
 279 fi
 280
 281 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k5 ; then
 282         AC_CHECK_HEADERS(kerberosIV/krb.h kerberosIV/des.h)
 283
 284         if test $ac_cv_header_kerberosIV_krb_h = yes ; then
 285                 AC_CHECK_LIB(krb4, main, [have_k5=yes], [have_k5=no],
 286                         [-lkrb5 -ldes425])
 287
 288                 if test $have_k5 = yes ; then
 289                         ol_with_kerberos=found
 290                         ol_link_kerberos=yes
 291
 292                         AC_DEFINE(HAVE_KERBEROS)
 293
 294                         KRB_LIBS="-lkrb4 -lkrb5 -ldes425"
 295                 fi
 296         fi
 297 fi
 298 if test $ol_with_kerberos = auto -o $ol_with_kerberos = k4 ; then
 299         AC_CHECK_HEADERS(krb.h des.h)
 300
 301         if test $ac_cv_header_krb_h = yes ; then
 302                 AC_CHECK_LIB(krb, main, [have_k4=yes], [have_k4=no], [-ldes])
 303
 304                 if test $have_k4 = yes ; then
 305                         ol_with_kerberos=found
 306                         ol_link_kerberos=yes
 307
 308                         AC_DEFINE(HAVE_KERBEROS)
 309
 310                         KRB_LIBS="-lkrb -ldes"
 311                 fi
 312         fi
 313 fi
 314
 315
 316 ol_link_threads=no
 317 if test $ol_with_threads = auto -o $ol_with_threads = posix ; then
 318         AC_CHECK_HEADERS(pthread.h sched.h)
 319
 320         if test $ac_cv_header_pthread_h = yes ; then
 321                 OL_POSIX_THREAD_VERSION
 322
 323                 if test $ol_cv_pthread_version = final ; then
 324                         AC_DEFINE(HAVE_PTHREADS_FINAL)
 325                 elif test $ol_cv_pthread_version = draft4 ; then
 326                         AC_DEFINE(HAVE_PTHREADS_D4)
 327                 else
 328                         AC_MSG_ERROR([unknown pthread version])
 329                 fi
 330
 331                 # consider threads found
 332                 ol_with_threads=found
 333
 334                 OL_LINUX_THREADS
 335
 336                 if test $ol_cv_linux_threads = yes ; then
 337                         AC_DEFINE(HAVE_LINUX_THREADS,1)
 338                 fi
 339
 340                 dnl Now the hard part, how to link
 341
 342                 dnl A few platforms have pthread support in standard libraries
 343                 AC_CHECK_FUNC(pthread_create,[ol_link_threads=yes])
 344
 345                 if test $ol_link_threads = no ; then
 346                         dnl try -pthread
 347                         AC_CACHE_CHECK([for pthread_create with -pthread],
 348                                 [ol_cv_pthread_flag], [
 349                                 dnl save the CPPFLAGS
 350                                 save_LIBS="$LIBS"
 351                                 LIBS="-pthread $LIBS"
 352                                 AC_TRY_LINK([#include <pthread.h>],[
 353                                         pthread_create((pthread_t*) 0,
 354                                                 (pthread_attr_t*) 0, 0, 0);
 355                                         ], ol_cv_pthread_flag=yes, ol_cv_pthread_flag=no)
 356                                 dnl restore the LIBS
 357                                 LIBS="$save_LIBS"
 358                         ])
 359
 360                         if test $ol_cv_pthread_flag = yes ; then
 361                                 LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
 362                                 ol_link_threads=posix
 363                         fi
 364                 fi
 365
 366                 if test $ol_link_threads = no ; then
 367                         dnl try -lpthread
 368                         save_LIBS="$LIBS"
 369                         AC_CHECK_LIB(pthread, pthread_create, [
 370                                 ol_link_threads=posix
 371                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"])
 372                         LIBS="$save_LIBS"
 373                 fi
 374
 375                 if test $ol_link_threads = no ; then
 376                         dnl try -lc_r
 377                         save_LIBS="$LIBS"
 378                         AC_CHECK_LIB(c_r, pthread_create, [
 379                                 ol_link_threads=posix
 380                                 LTHREAD_LIBS="$LTHREAD_LIBS -lc_r"])
 381                         LIBS="$save_LIBS"
 382                 fi
 383
 384                 if test $ol_link_threads = no ; then
 385                         dnl try DEC Threads
 386                         save_LIBS="$LIBS"
 387                         AC_CHECK_LIB(pthread, pthread_create, [
 388                                 AC_DEFINE(HAVE_DCE)
 389                                 ol_link_threads=posix
 390                                 LTHREAD_LIBS="$LTHREAD_LIBS -lpthread -lmach -lexc -lc"
 391                                 if test $ol_with_preemptive = auto ; then
 392                                         ol_with_preemptive=yes
 393                                 fi
 394                                 ],,[-lmach -lexc -lc])
 395                         LIBS="$save_LIBS"
 396                 fi
 397
 398                 if test $ol_link_threads != no ; then
 399                         AC_DEFINE(HAVE_PTHREADS)
 400
 401                         dnl save DEFS/LIBS
 402                         save_CPPFLAGS="$CPPFLAGS"
 403                         save_LIBS="$LIBS"
 404                         LIBS="$LTHREAD_LIBS $LIBS"
 405
 406                         dnl All POSIX Thread (final) implementations should have
 407                         dnl sched_yield instead of pthread yield.
 408                         dnl check for both
 409                         AC_CHECK_FUNCS(sched_yield pthread_yield)
 410
 411                         if test $ac_cv_func_sched_yield = no -a \
 412                                 $ac_cv_func_pthread_yield = no ; then
 413                                 dnl Digital UNIX has sched_yield() in -lrt
 414                                 AC_CHECK_LIB(rt, sched_yield,
 415                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lrt"
 416                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 417                                         ac_cv_func_sched_yield=yes],
 418                                         [ac_cv_func_sched_yield=no])
 419                         fi
 420                         if test $ac_cv_func_sched_yield = no -a \
 421                                 $ac_cv_func_pthread_yield = no ; then
 422                                 dnl Solaris has sched_yield() in -lposix4
 423                                 AC_CHECK_LIB(posix4, sched_yield,
 424                                         [LTHREAD_LIBS="$LTHREAD_LIBS -lposix4"
 425                                         AC_DEFINE(HAVE_SCHED_YIELD,1)
 426                                         ac_cv_func_sched_yield=yes],
 427                                         [ac_cv_func_sched_yield=no])
 428                         fi
 429                         if test $ac_cv_func_sched_yield = no -a \
 430                                 $ac_cv_func_pthread_yield = no ; then
 431                                 AC_MSG_WARN([could not locate sched_yield() or pthread_yield()])
 432                                 AC_MSG_ERROR([POSIX Threads are not usable])
 433                         fi
 434
 435                         dnl Check functions for compatibility
 436                         AC_CHECK_FUNCS(pthread_kill)
 437 dnl                     AC_CHECK_FUNCS( \
 438 dnl                             pthread_attr_create pthread_attr_init \
 439 dnl                             pthread_attr_destroy pthread_attr_delete \
 440 dnl                             pthread_attr_setdetachstate pthread_attr_setdetach_np \
 441 dnl                     )
 442
 443                         dnl Check for setconcurreny functions
 444                         AC_CHECK_FUNCS( \
 445                                 pthread_setconcurrency \
 446                                 thr_setconcurrency \
 447                         )
 448
 449                         dnl Check PREEMPTIVE Implementation
 450                         if test $ol_with_preemptive = auto ; then
 451                                 AC_MSG_CHECKING([for preemptive Pthread implementation])
 452                                 AC_TRY_RUN([
 453 #include <sys/types.h>
 454 #include <sys/time.h>
 455 #include <unistd.h>
 456 #include <pthread.h>
 457 #ifndef NULL
 458 #define NULL 0
 459 #endif
 460
 461 int task(arg)
 462         int *arg;
 463 {
 464         struct timeval tv;
 465
 466         tv.tv_sec=4;
 467         tv.tv_usec=0;
 468         select(0, NULL, NULL, NULL, &tv);
 469
 470         tv.tv_sec=6;
 471         tv.tv_usec=0;
 472         select(0, NULL, NULL, NULL, &tv);
 473
 474         exit(1); /* if we exit here, the select blocked the whole process */
 475 }
 476
 477 main(argc, argv)
 478 int argc; char **argv;
 479 {
 480         pthread_t t;
 481
 482 #ifdef HAVE_PTHREAD_SETCONCURRENCY
 483         (void) pthread_setconcurrency(2);
 484 #elif HAVE_THR_SETCONCURRENCY
 485         /* Set Solaris LWP concurrency to 2 */
 486         thr_setconcurrency(2);
 487 #endif
 488
 489         pthread_create(&t, NULL, (void *) task, NULL);
 490
 491 #if HAVE_SCHED_YIELD
 492         sched_yield();  /* make sure task runs first */
 493 #else
 494 #if defined(HAVE_PTHREAD_YIELD)
 495         pthread_yield();        /* make sure task runs first */
 496 #endif
 497 #endif
 498         exit(0);
 499 }
 500                                 ], [ol_pthread_preemptive=yes], [ol_pthread_preemptive=no], [
 501                                 AC_MSG_ERROR([crossing compiling: use --with-preemptive=yes|no|manual])])
 502                                 AC_MSG_RESULT($ol_pthread_preemptive)
 503
 504                                 if test $ol_pthread_preemptive = yes ; then
 505                                         AC_DEFINE(HAVE_PREEMPTIVE_PTHREADS)
 506                                         ol_with_preemptive=yes
 507                                 fi
 508                         fi
 509
 510 dnl                     dnl check for reentrant/threadsafe functions
 511 dnl                     AC_CHECK_FUNCS( \
 512 dnl                             feof_unlocked \
 513 dnl                             unlocked_feof \
 514 dnl                             ftrylockfile \
 515 dnl                             flockfile \
 516 dnl                             putc_unlocked \
 517 dnl                             gmtime_r \
 518 dnl                             strtok_r \
 519 dnl                     )
 520
 521                         dnl restore DEFS/LIBS
 522                         CPPFLAGS="$save_CPPFLAGS"
 523                         LIBS="$save_LIBS"
 524                 else
 525                         AC_MSG_ERROR([could not link with POSIX Threads])
 526                 fi
 527         fi
 528
 529         if test $ol_with_threads = posix ; then
 530                 AC_MSG_ERROR([could not locate POSIX Threads])
 531         fi
 532 fi
 533
 534 if test $ol_with_threads = auto -o $ol_with_threads = mach ; then
 535         dnl check for Mach CThreads
 536         AC_CHECK_HEADERS(mach/cthreads.h)
 537         if test $ac_cv_header_mach_cthreads_h = yes ; then
 538                 ol_with_threads=found
 539
 540                 dnl A few platforms have cthread support in standard libraries
 541                 AC_CHECK_FUNC(cthread_fork,[ol_link_threads=yes])
 542
 543                 if test $ol_link_threads = no ; then
 544                         dnl try -all_load
 545                         dnl this test needs work
 546                         AC_CACHE_CHECK([for cthread_fork with -all_load],
 547                                 [ol_cv_cthread_all_load], [
 548                                 dnl save the CPPFLAGS
 549                                 save_LIBS="$LIBS"
 550                                 LIBS="-all_load $LIBS"
 551                                 AC_TRY_LINK([#include <mach/cthreads.h>],[
 552                                         cthread_fork((void *)0, (void *)0);
 553                                         ], ol_cv_cthread_all_load=yes, ol_cv_cthread_all_load=no)
 554                                 dnl restore the LIBS
 555                                 LIBS="$save_LIBS"
 556                         ])
 557
 558                         if test $ol_cv_cthread_all_load = yes ; then
 559                                 LTHREAD_LIBS="$LTHREAD_LIBS -all_load"
 560                                 ol_link_threads=mach
 561                         fi
 562                 fi
 563
 564                 if test $ol_link_threads != no ; then
 565                         : check for cthread specific functionality here
 566                 else
 567                         AC_MSG_ERROR([could not link with Mach CThreads])
 568                 fi
 569         fi
 570
 571         if test $ol_with_threads = mach ; then
 572                 AC_MSG_ERROR([could not locate Mach CThreads])
 573         fi
 574 fi
 575
 576 if test $ol_with_threads = auto -o $ol_with_threads = lwp ; then
 577         dnl check for SunOS5 LWP
 578         AC_CHECK_HEADERS(thread.h synch.h)
 579         if test $ac_cv_header_thread_h = yes -a $ac_cv_header_synch_h = yes ; then
 580                 AC_CHECK_LIB(thread, thr_create, [have_lwp=yes], [have_lwp=no])
 581
 582                 if test $have_lwp = yes ; then
 583                         AC_DEFINE(HAVE_THR)
 584                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 585
 586                         if test $ol_with_preemptive = auto ; then
 587                                 ol_with_preemptive=yes
 588                         fi
 589                 fi
 590         fi
 591
 592         dnl check for SunOS4 LWP
 593         AC_CHECK_HEADERS(lwp/lwp.h)
 594         if test $ac_cv_header_lwp_lwp_h = yes ; then
 595                 AC_CHECK_LIB(lwp, lwp_create, [have_lwp=yes], [have_lwp=no])
 596
 597                 if test $have_lwp = yes ; then
 598                         AC_DEFINE(HAVE_LWP)
 599                         LTHREAD_LIBS="$LTHREAD_LIBS -llwp"
 600
 601                         if test $ol_with_preemptive = auto ; then
 602                                 ol_with_preemptive=no
 603                         fi
 604                 fi
 605         fi
 606 fi
 607
 608 if test $ol_with_preemptive = yes ; then
 609         AC_DEFINE(PREEMPTIVE_THREADS,1)
 610 fi
 611
 612 if test $ol_with_threads = manual ; then
 613         dnl User thinks he can manually configure threads.
 614         ol_link_threads=yes
 615
 616         AC_MSG_WARN([thread defines and link options must be set manually])
 617
 618         AC_CHECK_HEADERS(pthread.h sched.h)
 619         AC_CHECK_FUNCS(sched_yield pthread_yield)
 620         OL_LINUX_THREADS
 621
 622         AC_CHECK_HEADERS(mach/cthreads.h)
 623         AC_CHECK_HEADERS(lwp/lwp.h)
 624         AC_CHECK_HEADERS(thread.h synch.h)
 625 fi
 626
 627 if test $ol_with_threads = yes ; then
 628         dnl needed to get reentrant/threadsafe versions
 629         dnl
 630         dnl hopefully this will not cause problems with
 631         dnl non-threaded apps
 632         dnl
 633         AC_DEFINE(_REENTRANT,1)
 634         AC_DEFINE(_THREAD_SAFE,1)
 635 fi
 636
 637 dnl ----------------------------------------------------------------
 638
 639 if test $ol_link_threads = no ; then
 640         if test $ol_with_threads = yes ; then
 641                 AC_MSG_ERROR([no suitable thread support])
 642         fi
 643
 644         if test $ol_with_threads = auto ; then
 645                 AC_MSG_WARN([no suitable thread support, disabling threads])
 646                 ol_with_threads=no
 647         fi
 648
 649         AC_DEFINE(NO_THREADS,1)
 650         AC_DEFINE(PREEMPTIVE_THREADS,1)
 651         LTHREAD_LIBS=""
 652 fi
 653
 654 ol_link_ldbm=no
 655 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db2 ; then
 656         OL_BERKELEY_DB2
 657
 658         if test $ol_cv_berkeley_db2 = yes ; then
 659                 ol_link_ldbm=db2
 660                 ol_with_ldbm_api=db2
 661
 662                 if test $ol_with_ldbm_type = hash ; then
 663                         AC_DEFINE(LDBM_USE_DBHASH,1)
 664                 else
 665                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 666                 fi
 667
 668                 dnl $ol_cv_lib_db2 should be yes or -ldb
 669                 dnl (it could be no, but that would be an error
 670                 if test $ol_cv_lib_db2 != yes ; then
 671                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db2"
 672                 fi
 673         fi
 674 fi
 675
 676 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = db ; then
 677         OL_BERKELEY_DB
 678
 679         if test $ol_cv_berkeley_db = yes ; then
 680                 ol_link_ldbm=db
 681                 ol_with_ldbm_api=db
 682
 683                 if test $ol_with_ldbm_type = hash ; then
 684                         AC_DEFINE(LDBM_USE_DBHASH,1)
 685                 else
 686                         AC_DEFINE(LDBM_USE_DBBTREE,1)
 687                 fi
 688
 689                 dnl $ol_cv_lib_db should be yes or -ldb
 690                 dnl (it could be no, but that would be an error
 691                 if test $ol_cv_lib_db != yes ; then
 692                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_db"
 693                 fi
 694         fi
 695 fi
 696
 697 if test $ol_with_ldbm_api = manual ; then
 698         dnl User thinks he can manually configure LDBM api.
 699         ol_link_ldbm=yes
 700
 701         AC_MSG_WARN([LDBM defines and link options must be set manually])
 702
 703         AC_CHECK_HEADERS(db.h db_185.h gdbm.h ndbm.h)
 704 fi
 705
 706 if test $ol_link_ldbm = no -a $ol_with_ldbm_type = btree ; then
 707         AC_MSG_WARN(Could not find LDBM with BTREE support)
 708         ol_with_ldbm_api=none
 709 fi
 710
 711 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = gdbm ; then
 712         OL_GDBM
 713
 714         if test $ol_cv_gdbm = yes ; then
 715                 ol_link_ldbm=gdbm
 716                 ol_with_ldbm_api=gdbm
 717
 718                 if test $ol_cv_lib_gdbm != yes ; then
 719                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_gdbm"
 720                 fi
 721         fi
 722 fi
 723
 724 if test $ol_with_ldbm_api = auto -o $ol_with_ldbm_api = ndbm ; then
 725         OL_NDBM
 726
 727         if test $ol_cv_ndbm = yes ; then
 728                 ol_link_ldbm=ndbm
 729                 ol_with_ldbm_api=ndbm
 730
 731                 if test $ol_with_ldbm_api = ndbm ; then
 732                         AC_WARN([Attempting to use NDBM.  Functionality will be limited.])
 733                 fi
 734
 735                 if test $ol_cv_lib_ndbm != yes ; then
 736                         LDBM_LIBS="$LDBM_LIBS $ol_cv_lib_ndbm"
 737                 fi
 738         fi
 739 fi
 740
 741 if test $ol_link_ldbm = no -a $ol_enable_ldbm != no ; then
 742         AC_MSG_WARN(could not find suitable LDBM backend)
 743         if test $ol_enable_ldbm = yes ; then
 744                 AC_MSG_ERROR(select appropriate LDBM options or disable)
 745         fi
 746
 747         AC_MSG_WARN(disabling LDBM)
 748         ol_enable_ldbm=no
 749 fi
 750
 751 if test $ol_enable_wrappers = yes ; then
 752         AC_CHECK_LIB(wrap, hosts_access,
 753                 [have_wrappers=yes], [have_wrappers=no])
 754
 755         if test $have_wrappers = yes ; then
 756                 AC_DEFINE(HAVE_TCPD)
 757                 SLAPD_LIBS="$SLAPD_LIBS -lwrap"
 758         else
 759                 AC_MSG_WARN(could not find -lwrap)
 760                 if test $ol_enable_wrappers = yes ; then
 761                         AC_MSG_ERROR(could not find wrappers, select appropriate options or disable)
 762                 fi
 763
 764                 AC_MSG_WARN(disabling wrappers support)
 765                 ol_enable_wrappers=no
 766         fi
 767
 768 fi
 769
 770 # ud needs termcap (should insert check here)
 771 ol_link_termcap=no
 772 AC_CHECK_HEADERS(termcap.h ncurses.h)
 773
 774 if test $ol_link_termcap = no ; then
 775         AC_CHECK_LIB(termcap, tputs, [have_termcap=yes], [have_termcap=no])
 776         if test $have_termcap = yes ; then
 777                 AC_DEFINE(HAVE_TERMCAP)
 778                 ol_link_termcap=yes
 779                 TERMCAP_LIBS=-ltermcap
 780         fi
 781 fi
 782
 783 if test $ol_link_termcap = no ; then
 784         AC_CHECK_LIB(ncurses, initscr, [have_ncurses=yes], [have_ncurses=no])
 785         if test $have_ncurses = yes ; then
 786                 AC_DEFINE(HAVE_NCURSES)
 787                 ol_link_termcap=yes
 788                 TERMCAP_LIBS=-lncurses
 789         fi
 790 fi
 791
 792 if test $ol_link_termcap = no ; then
 793         AC_DEFINE(NO_TERMCAP,1)
 794         TERMCAP_LIBS=
 795 fi
 796
 797 # FreeBSD (and others) have crypt(3) in -lcrypt
 798 if test $ol_enable_crypt != no ; then
 799         AC_CHECK_FUNC(crypt, [have_crypt=yes], [
 800                 AC_CHECK_LIB(crypt, crypt, [LUTIL_LIBS="$LUTIL_LIBS -lcrypt"
 801                         have_crypt=yes], [have_crypt=no])])
 802
 803         if test $have_crypt = yes ; then
 804                 AC_DEFINE(HAVE_CRYPT,1)
 805         else
 806                 AC_MSG_WARN(could not find crypt)
 807                 if test $ol_enable_crypt = yes ; then
 808                         AC_MSG_ERROR(could not find crypt, select appropriate options or disable)
 809                 fi
 810
 811                 AC_MSG_WARN(disabling crypt support)
 812                 ol_enable_crypt=no
 813         fi
 814 fi
 815
 816 # FreeBSD (and others) have setproctitle(3) in -lutil
 817 if test $ol_enable_proctitle != no ; then
 818         AC_CHECK_FUNC(setproctitle,     [have_setproctitle=yes], [
 819                 AC_CHECK_LIB(util, setproctitle,
 820                         [have_setproctitle=yes
 821                         LUTIL_LIBS="$LUTIL_LIBS -lutil"],
 822                         [have_setproctitle=no
 823                         LIBOBJS="$LIBOBJS setproctitle.o"])])
 824
 825         if test $have_setproctitle = yes ; then
 826                 AC_DEFINE(HAVE_SETPROCTITLE,1)
 827         fi
 828 fi
 829
 830 dnl ----------------------------------------------------------------
 831 dnl Checks for header files.
 832 AC_HEADER_STDC
 833
 834 if test $ac_cv_header_stdc != yes; then
 835         AC_MSG_WARN([could not locate Standard C headers])
 836 fi
 837
 838 AC_HEADER_DIRENT
 839 AC_HEADER_SYS_WAIT
 840 AC_CHECK_HEADERS(       \
 841         stdarg.h                \
 842         stddef.h                \
 843         errno.h                 \
 844         fcntl.h                 \
 845         filio.h                 \
 846         getopt.h                \
 847         libutil.h               \
 848         limits.h                \
 849         malloc.h                \
 850         regex.h                 \
 851         sgtty.h                 \
 852         sys/file.h              \
 853         sys/filio.h             \
 854         sys/errno.h             \
 855         sys/ioctl.h             \
 856         sys/param.h             \
 857         sys/socket.h    \
 858         sys/syslog.h    \
 859         sys/time.h              \
 860         sys/types.h             \
 861         syslog.h                \
 862         termios.h               \
 863         unistd.h                \
 864 )
 865
 866 dnl ----------------------------------------------------------------
 867 dnl Checks for typedefs, structures, and compiler characteristics.
 868 AC_TYPE_GETGROUPS
 869 AC_TYPE_MODE_T
 870 AC_TYPE_OFF_T
 871 AC_TYPE_PID_T
 872 AC_TYPE_SIGNAL
 873 AC_TYPE_SIZE_T
 874 AC_TYPE_UID_T
 875 AC_STRUCT_ST_BLKSIZE
 876 AC_HEADER_TIME
 877 AC_STRUCT_TM
 878
 879 OL_C_UPPER_LOWER
 880 AC_C_CONST
 881
 882 dnl AC_CHECK_SIZEOF(short)
 883 dnl AC_CHECK_SIZEOF(int)
 884 dnl AC_CHECK_SIZEOF(long)
 885
 886 dnl ----------------------------------------------------------------
 887 dnl Checks for library functions.
 888 AC_FUNC_MEMCMP
 889 AC_FUNC_STRFTIME
 890 AC_FUNC_VPRINTF
 891
 892 if test $ac_cv_func_vprintf = yes ; then
 893         dnl check for vsnprintf
 894         AC_CHECK_FUNCS(vsnprintf)
 895 fi
 896
 897 AC_FUNC_WAIT3
 898
 899 AC_CHECK_FUNCS(         \
 900         bcopy                   \
 901         getopt                  \
 902         flock                   \
 903         gethostname             \
 904         gettimeofday    \
 905         getdtablesize   \
 906         lockf                   \
 907         memcpy                  \
 908         memmove                 \
 909         mkstemp                 \
 910         mktime                  \
 911         select                  \
 912         setpwfile               \
 913         setsid                  \
 914         signal                  \
 915         sigset                  \
 916         snprintf                \
 917         socket                  \
 918         strerror                \
 919         strstr                  \
 920         strrchr                 \
 921         strsep                  \
 922         strtod                  \
 923         strtol                  \
 924         strtoul                 \
 925         sysconf                 \
 926         tempnam                 \
 927         waitpid                 \
 928 )
 929
 930 AC_REPLACE_FUNCS(getopt strdup tempnam)
 931
 932 dnl ----------------------------------------------------------------
 933 # Check Configuration
 934 OL_SYS_ERRLIST
 935
 936 dnl ----------------------------------------------------------------
 937 dnl Sort out defines
 938
 939 if test $ol_enable_debug != no ; then
 940         AC_DEFINE(LDAP_DEBUG,1)
 941 fi
 942 dnl     if test $ol_enable_syslog != no ; then
 943 dnl             AC_DEFINE(LDAP_SYSLOG,1)
 944 dnl     fi
 945 if test $ol_enable_libui = yes ; then
 946         AC_DEFINE(LDAP_LIBUI,1)
 947 fi
 948 if test $ol_enable_cache = no ; then
 949         AC_DEFINE(LDAP_NOCACHE,1)
 950 fi
 951 if test $ol_enable_dns != no ; then
 952         AC_DEFINE(LDAP_DNS,1)
 953 fi
 954 if test $ol_enable_proctitle != no ; then
 955         AC_DEFINE(LDAP_PROCTITLE,1)
 956 fi
 957 if test $ol_enable_referrals != no ; then
 958         AC_DEFINE(LDAP_REFERRALS,1)
 959 fi
 960 if test $ol_enable_cldap != no ; then
 961         AC_DEFINE(LDAP_CONNECTIONLESS,1)
 962 fi
 963
 964 if test $ol_enable_aclgroups != no ; then
 965         AC_DEFINE(SLAPD_ACLGROUPS,1)
 966 fi
 967 if test $ol_enable_crypt != no ; then
 968         AC_DEFINE(SLAPD_CRYPT,1)
 969 fi
 970 if test $ol_enable_md5 != no ; then
 971         AC_DEFINE(SLAPD_MD5,1)
 972 fi
 973 if test $ol_enable_sha1 != no ; then
 974         AC_DEFINE(SLAPD_SHA1,1)
 975 fi
 976 if test $ol_enable_phonetic != no ; then
 977         AC_DEFINE(SLAPD_PHONETIC,1)
 978 fi
 979 if test $ol_enable_rlookups != no ; then
 980         AC_DEFINE(SLAPD_RLOOKUPS,1)
 981 fi
 982
 983 if test $ol_link_ldbm != no ; then
 984         AC_DEFINE(SLAPD_LDBM,1)
 985         BUILD_SLAPD=yes
 986         BUILD_LDBM=yes
 987 fi
 988
 989 if test $ol_enable_passwd != no ; then
 990         AC_DEFINE(SLAPD_PASSWD,1)
 991         BUILD_SLAPD=yes
 992         BUILD_PASSWD=yes
 993 fi
 994
 995 if test $ol_enable_shell != no ; then
 996         AC_DEFINE(SLAPD_SHELL,1)
 997         BUILD_SLAPD=yes
 998         BUILD_SHELL=yes
 999 fi
1000
1001 if test $ol_enable_slurpd != no -a $ol_link_threads != no -a \
1002         $BUILD_SLAPD = yes ; then
1003         BUILD_SLURPD=yes
1004 fi
1005
1006 if test $ol_link_isode != no ; then
1007         BUILD_LDAPD=yes
1008 fi
1009
1010 dnl ----------------------------------------------------------------
1011
1012 AC_SUBST(BUILD_LDAPD)
1013 AC_SUBST(BUILD_SLAPD)
1014   AC_SUBST(BUILD_LDBM)
1015   AC_SUBST(BUILD_PASSWD)
1016   AC_SUBST(BUILD_SHELL)
1017 AC_SUBST(BUILD_SLURPD)
1018
1019
1020 AC_SUBST(LDAP_LIBS)
1021 AC_SUBST(LDAPD_LIBS)
1022 AC_SUBST(SLAPD_LIBS)
1023 AC_SUBST(SLURPD_LIBS)
1024 AC_SUBST(LDBM_LIBS)
1025 AC_SUBST(LTHREAD_LIBS)
1026 AC_SUBST(LUTIL_LIBS)
1027
1028 AC_SUBST(KRB_LIBS)
1029 AC_SUBST(TERMCAP_LIBS)
1030
1031 dnl ----------------------------------------------------------------
1032 dnl final output
1033 dnl
1034
1035 dnl AC_OUTPUT( \
1036 dnl contrib/Makefile:build/top.mk:contrib/Makefile.in:build/dir.mk \
1037 dnl contrib/saucer/Makefile:build/top.mk:contrib/saucer/Makefile.in:build/rules.mk \
1038 dnl contrib/whois++/Makefile:build/top.mk:contrib/whois++/Makefile.in:build/rules.mk \
1039 dnl [date > stamp-h])
1040
1041 AC_OUTPUT( \
1042 Makefile:build/top.mk:Makefile.in:build/dir.mk \
1043 doc/Makefile:build/top.mk:doc/Makefile.in:build/dir.mk \
1044 doc/man/Makefile:build/top.mk:doc/man/Makefile.in:build/dir.mk \
1045 doc/man/man1/Makefile:build/top.mk:doc/man/man1/Makefile.in:build/man.mk \
1046 doc/man/man3/Makefile:build/top.mk:doc/man/man3/Makefile.in:build/man.mk \
1047 doc/man/man5/Makefile:build/top.mk:doc/man/man5/Makefile.in:build/man.mk \
1048 doc/man/man8/Makefile:build/top.mk:doc/man/man8/Makefile.in:build/man.mk \
1049 clients/Makefile:build/top.mk:clients/Makefile.in:build/dir.mk \
1050 clients/finger/Makefile:build/top.mk:clients/finger/Makefile.in:build/rules.mk \
1051 clients/fax500/Makefile:build/top.mk:clients/fax500/Makefile.in:build/rules.mk \
1052 clients/gopher/Makefile:build/top.mk:clients/gopher/Makefile.in:build/rules.mk \
1053 clients/mail500/Makefile:build/top.mk:clients/mail500/Makefile.in:build/rules.mk \
1054 clients/rcpt500/Makefile:build/top.mk:clients/rcpt500/Makefile.in:build/rules.mk \
1055 clients/ud/Makefile:build/top.mk:clients/ud/Makefile.in:build/rules.mk \
1056 clients/tools/Makefile:build/top.mk:clients/tools/Makefile.in:build/rules.mk \
1057 include/Makefile:build/top.mk:include/Makefile.in \
1058 libraries/Makefile:build/top.mk:libraries/Makefile.in:build/dir.mk      \
1059 libraries/libavl/Makefile:build/top.mk:libraries/libavl/Makefile.in:build/lib.mk \
1060 libraries/liblber/Makefile:build/top.mk:libraries/liblber/Makefile.in:build/lib.mk \
1061 libraries/libldap/Makefile:build/top.mk:libraries/libldap/Makefile.in:build/lib.mk \
1062 libraries/libldbm/Makefile:build/top.mk:libraries/libldbm/Makefile.in:build/lib.mk \
1063 libraries/libldif/Makefile:build/top.mk:libraries/libldif/Makefile.in:build/lib.mk \
1064 libraries/liblthread/Makefile:build/top.mk:libraries/liblthread/Makefile.in:build/lib.mk \
1065 libraries/liblutil/Makefile:build/top.mk:libraries/liblutil/Makefile.in:build/lib.mk \
1066 servers/Makefile:build/top.mk:servers/Makefile.in:build/dir.mk \
1067 servers/ldapd/Makefile:build/top.mk:servers/ldapd/Makefile.in:build/srv.mk \
1068 servers/slapd/Makefile:build/top.mk:servers/slapd/Makefile.in:build/srv.mk \
1069 servers/slapd/back-ldbm/Makefile:build/top.mk:servers/slapd/back-ldbm/Makefile.in:build/srv.mk \
1070 servers/slapd/back-passwd/Makefile:build/top.mk:servers/slapd/back-passwd/Makefile.in:build/srv.mk \
1071 servers/slapd/back-shell/Makefile:build/top.mk:servers/slapd/back-shell/Makefile.in:build/srv.mk \
1072 servers/slapd/shell-backends/Makefile:build/top.mk:servers/slapd/shell-backends/Makefile.in:build/srv.mk \
1073 servers/slapd/tools/Makefile:build/top.mk:servers/slapd/tools/Makefile.in \
1074 servers/slurpd/Makefile:build/top.mk:servers/slurpd/Makefile.in:build/srv.mk \
1075 tests/Makefile:build/top.mk:tests/Makefile.in \
1076 ,[
1077 date > stamp-h
1078 echo Please \"make depend\" to build dependencies
1079 ])