git.sur5r.net Git - u-boot/blob - cpu/mc9328/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <gj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27
  28 #include <config.h>
  29 #include <version.h>
  30
  31
  32 /*
  33  *************************************************************************
  34  *
  35  * Jump vector table as in table 3.1 in [1]
  36  *
  37  *************************************************************************
  38  */
  39
  40
  41 .globl _start
  42 _start: b       reset
  43         ldr     pc, _undefined_instruction
  44         ldr     pc, _software_interrupt
  45         ldr     pc, _prefetch_abort
  46         ldr     pc, _data_abort
  47         ldr     pc, _not_used
  48         ldr     pc, _irq
  49         ldr     pc, _fiq
  50
  51 _undefined_instruction: .word undefined_instruction
  52 _software_interrupt:    .word software_interrupt
  53 _prefetch_abort:        .word prefetch_abort
  54 _data_abort:            .word data_abort
  55 _not_used:              .word not_used
  56 _irq:                   .word irq
  57 _fiq:                   .word fiq
  58
  59         .balignl 16,0xdeadbeef
  60
  61
  62 /*
  63  *************************************************************************
  64  *
  65  * Startup Code (reset vector)
  66  *
  67  * do important init only if we don't start from memory!
  68  * relocate armboot to ram
  69  * setup stack
  70  * jump to second stage
  71  *
  72  *************************************************************************
  73  */
  74
  75 _TEXT_BASE:
  76         .word   TEXT_BASE
  77
  78 .globl _armboot_start
  79 _armboot_start:
  80         .word _start
  81
  82 /*
  83  * These are defined in the board-specific linker script.
  84  */
  85 .globl _bss_start
  86 _bss_start:
  87         .word __bss_start
  88
  89 .globl _bss_end
  90 _bss_end:
  91         .word _end
  92
  93 #ifdef CONFIG_USE_IRQ
  94 /* IRQ stack memory (calculated at run-time) */
  95 .globl IRQ_STACK_START
  96 IRQ_STACK_START:
  97         .word   0x0badc0de
  98
  99 /* IRQ stack memory (calculated at run-time) */
 100 .globl FIQ_STACK_START
 101 FIQ_STACK_START:
 102         .word 0x0badc0de
 103 #endif
 104
 105
 106 /*
 107  * the actual reset code
 108  */
 109
 110 reset:
 111         /*
 112          * set the cpu to SVC32 mode
 113          */
 114         mrs     r0,cpsr
 115         bic     r0,r0,#0x1f
 116         orr     r0,r0,#0xd3
 117         msr     cpsr,r0
 118
 119         /*
 120          * we do sys-critical inits only at reboot,
 121          * not when booting from ram!
 122          */
 123 #ifdef CONFIG_INIT_CRITICAL
 124         bl      cpu_init_crit
 125 #endif
 126
 127 relocate:                               /* relocate U-Boot to RAM           */
 128         adr     r0, _start              /* r0 <- current position of code   */
 129         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 130         cmp     r0, r1                  /* don't reloc during debug         */
 131         beq     stack_setup
 132
 133         ldr     r2, _armboot_start
 134         ldr     r3, _bss_start
 135         sub     r2, r3, r2              /* r2 <- size of armboot            */
 136         add     r2, r0, r2              /* r2 <- source end address         */
 137
 138 copy_loop:
 139         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 140         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 141         cmp     r0, r2                  /* until source end addreee [r2]    */
 142         ble     copy_loop
 143
 144         /* Set up the stack                                                 */
 145 stack_setup:
 146         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 147         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 148         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 149 #ifdef CONFIG_USE_IRQ
 150         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 151 #endif
 152         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 153
 154 clear_bss:
 155         ldr     r0, _bss_start          /* find start of bss segment        */
 156         ldr     r1, _bss_end            /* stop here                        */
 157         mov     r2, #0x00000000         /* clear                            */
 158
 159 clbss_l:str     r2, [r0]                /* clear loop...                    */
 160         add     r0, r0, #4
 161         cmp     r0, r1
 162         bne     clbss_l
 163
 164         ldr     pc, _start_armboot
 165
 166 _start_armboot: .word start_armboot
 167
 168
 169 /*
 170  *************************************************************************
 171  *
 172  * CPU_init_critical registers
 173  *
 174  * setup important registers
 175  * setup memory timing
 176  *
 177  *************************************************************************
 178  */
 179
 180
 181 cpu_init_crit:
 182         /*
 183          * flush v4 I/D caches
 184          */
 185         mov     r0, #0
 186         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 187         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 188
 189         /*
 190          * disable MMU stuff and caches
 191          */
 192         mrc     p15, 0, r0, c1, c0, 0
 193         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 194         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 195         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 196         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 197         mcr     p15, 0, r0, c1, c0, 0
 198
 199
 200         /*
 201          * before relocating, we have to setup RAM timing
 202          * because memory timing is board-dependend, you will
 203          * find a memsetup.S in your board directory.
 204          */
 205         mov     ip, lr
 206         bl      memsetup
 207         mov     lr, ip
 208
 209         mov     pc, lr
 210
 211
 212 /*
 213  *************************************************************************
 214  *
 215  * Interrupt handling
 216  *
 217  *************************************************************************
 218  */
 219
 220 @
 221 @ IRQ stack frame.
 222 @
 223 #define S_FRAME_SIZE    72
 224
 225 #define S_OLD_R0        68
 226 #define S_PSR           64
 227 #define S_PC            60
 228 #define S_LR            56
 229 #define S_SP            52
 230
 231 #define S_IP            48
 232 #define S_FP            44
 233 #define S_R10           40
 234 #define S_R9            36
 235 #define S_R8            32
 236 #define S_R7            28
 237 #define S_R6            24
 238 #define S_R5            20
 239 #define S_R4            16
 240 #define S_R3            12
 241 #define S_R2            8
 242 #define S_R1            4
 243 #define S_R0            0
 244
 245 #define MODE_SVC 0x13
 246 #define I_BIT    0x80
 247
 248 /*
 249  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 250  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 251  */
 252
 253         .macro  bad_save_user_regs
 254         sub     sp, sp, #S_FRAME_SIZE
 255         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 256         ldr     r2, _armboot_start
 257         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 258         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 259         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 260         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 261
 262         add     r5, sp, #S_SP
 263         mov     r1, lr
 264         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 265         mov     r0, sp
 266         .endm
 267
 268         .macro  irq_save_user_regs
 269         sub     sp, sp, #S_FRAME_SIZE
 270         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 271         add     r8, sp, #S_PC
 272         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 273         str     lr, [r8, #0]                    @ Save calling PC
 274         mrs     r6, spsr
 275         str     r6, [r8, #4]                    @ Save CPSR
 276         str     r0, [r8, #8]                    @ Save OLD_R0
 277         mov     r0, sp
 278         .endm
 279
 280         .macro  irq_restore_user_regs
 281         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 282         mov     r0, r0
 283         ldr     lr, [sp, #S_PC]                 @ Get PC
 284         add     sp, sp, #S_FRAME_SIZE
 285         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 286         .endm
 287
 288         .macro get_bad_stack
 289         ldr     r13, _armboot_start             @ setup our mode stack
 290         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 291         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 292
 293         str     lr, [r13]                       @ save caller lr / spsr
 294         mrs     lr, spsr
 295         str     lr, [r13, #4]
 296
 297         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 298         @ msr   spsr_c, r13
 299         msr     spsr, r13
 300         mov     lr, pc
 301         movs    pc, lr
 302         .endm
 303
 304         .macro get_irq_stack                    @ setup IRQ stack
 305         ldr     sp, IRQ_STACK_START
 306         .endm
 307
 308         .macro get_fiq_stack                    @ setup FIQ stack
 309         ldr     sp, FIQ_STACK_START
 310         .endm
 311
 312 /*
 313  * exception handlers
 314  */
 315         .align  5
 316 undefined_instruction:
 317         get_bad_stack
 318         bad_save_user_regs
 319         bl      do_undefined_instruction
 320
 321         .align  5
 322 software_interrupt:
 323         get_bad_stack
 324         bad_save_user_regs
 325         bl      do_software_interrupt
 326
 327         .align  5
 328 prefetch_abort:
 329         get_bad_stack
 330         bad_save_user_regs
 331         bl      do_prefetch_abort
 332
 333         .align  5
 334 data_abort:
 335         get_bad_stack
 336         bad_save_user_regs
 337         bl      do_data_abort
 338
 339         .align  5
 340 not_used:
 341         get_bad_stack
 342         bad_save_user_regs
 343         bl      do_not_used
 344
 345 #ifdef CONFIG_USE_IRQ
 346
 347         .align  5
 348 irq:
 349         get_irq_stack
 350         irq_save_user_regs
 351         bl      do_irq
 352         irq_restore_user_regs
 353
 354         .align  5
 355 fiq:
 356         get_fiq_stack
 357         /* someone ought to write a more effiction fiq_save_user_regs */
 358         irq_save_user_regs
 359         bl      do_fiq
 360         irq_restore_user_regs
 361
 362 #else
 363
 364         .align  5
 365 irq:
 366         get_bad_stack
 367         bad_save_user_regs
 368         bl      do_irq
 369
 370         .align  5
 371 fiq:
 372         get_bad_stack
 373         bad_save_user_regs
 374         bl      do_fiq
 375
 376 #endif
 377
 378         .align  5
 379 .globl reset_cpu
 380 reset_cpu:
 381         mov     ip, #0
 382         mcr     p15, 0, ip, c7, c7, 0           @ invalidate cache
 383         mcr     p15, 0, ip, c8, c7, 0           @ flush TLB (v4)
 384         mrc     p15, 0, ip, c1, c0, 0           @ get ctrl register
 385         bic     ip, ip, #0x000f                 @ ............wcam
 386         bic     ip, ip, #0x2100                 @ ..v....s........
 387         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 388         mov     pc, r0