git.sur5r.net Git - glabels/blob - glabels2/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.52)
   4
   5 AC_INIT(glabels, 2.3.pre0svn, http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116)
   6 AC_CONFIG_SRCDIR(src/glabels.c)
   7 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   8
   9 AM_MAINTAINER_MODE
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AC_PROG_INTLTOOL([0.21])
  13 PKG_PROG_PKG_CONFIG
  14
  15 AM_PROG_LIBTOOL
  16
  17 AC_ISC_POSIX
  18 AC_PROG_CC
  19 AM_PROG_CC_STDC
  20 AC_HEADER_STDC
  21
  22 GNOME_COMPILE_WARNINGS
  23
  24 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
  25 AC_PATH_PROG(GTK_BUILDER_CONVERT, gtk-builder-convert)
  26
  27 GTK_DOC_CHECK(1.0)
  28
  29 dnl ---------------------------------------------------------------------------
  30 dnl - LIBGLABELS API versioning
  31 dnl ---------------------------------------------------------------------------
  32 dnl From the libtool manual:
  33 dnl 1. Start with version information of `0:0:0' for each libtool library.
  34 dnl 2. Update the version information only immediately before a public release.
  35 dnl    More frequent updates are unnecessary, and only guarantee that the current
  36 dnl    interface number gets larger faster.
  37 dnl 3. If the library source code has changed at all since the last update, then increment
  38 dnl    revision (`c:r:a' becomes `c:r+1:a').
  39 dnl 4. If any interfaces have been added, removed, or changed since the last update,
  40 dnl    increment current, and set revision to 0.
  41 dnl 5. If any interfaces have been added since the last public release, then increment age.
  42 dnl 6. If any interfaces have been removed since the last public release, then set age
  43 dnl    to 0.
  44 LIBGLABELS_C=5
  45 LIBGLABELS_R=1
  46 LIBGLABELS_A=0
  47
  48 LIBGLABELS_VERSION_INFO=${LIBGLABELS_C}:${LIBGLABELS_R}:${LIBGLABELS_A}
  49 AC_SUBST(LIBGLABELS_VERSION_INFO)
  50
  51
  52 dnl ---------------------------------------------------------------------------
  53 dnl - Library dependencies
  54 dnl ---------------------------------------------------------------------------
  55 GLIB_REQUIRED=2.18.0
  56 GTK_REQUIRED=2.14.0
  57 LIBXML_REQUIRED=2.7.0
  58 LIBEBOOK_REQUIRED=2.24.0
  59
  60 dnl Make above strings available for packaging files (e.g. rpm spec files)
  61 AC_SUBST(GLIB_REQUIRED)
  62 AC_SUBST(GTK_REQUIRED)
  63 AC_SUBST(LIBXML_REQUIRED)
  64 AC_SUBST(LIBEBOOK_REQUIRED)
  65
  66
  67 dnl ---------------------------------------------------------------------------
  68 dnl - Check for evolution data server
  69 dnl ---------------------------------------------------------------------------
  70 AC_ARG_WITH(libebook,
  71             [AC_HELP_STRING([--without-libebook],
  72                             [build without Evolution Data Server support])])
  73 have_libebook=no
  74 if test "x$with_libebook" != xno; then
  75         PKG_CHECK_MODULES(LIBEBOOK, libebook-1.2 >= $LIBEBOOK_REQUIRED,
  76                           [have_libebook=yes], [have_libebook=no])
  77 fi
  78
  79 if test "x$have_libebook" = "xyes"; then
  80         AC_DEFINE(HAVE_LIBEBOOK,1,[Define to 1 for EDS support])
  81         OPTIONAL_MODULES="$OPTIONAL_MODULES libebook-1.2 >= $LIBEBOOK_REQUIRED"
  82 fi
  83
  84
  85 dnl ---------------------------------------------------------------------------
  86 dnl - GLABELS prerequisites
  87 dnl ---------------------------------------------------------------------------
  88 PKG_CHECK_MODULES(GLABELS, \
  89 glib-2.0 >= $GLIB_REQUIRED \
  90 gtk+-2.0 >= $GTK_REQUIRED \
  91 libxml-2.0 >= $LIBXML_REQUIRED \
  92 $OPTIONAL_MODULES \
  93 )
  94
  95 AC_SUBST(GLABELS_CFLAGS)
  96 AC_SUBST(GLABELS_LIBS)
  97
  98
  99 dnl ---------------------------------------------------------------------------
 100 dnl - LIBGLABELS more modest prerequisites
 101 dnl ---------------------------------------------------------------------------
 102 PKG_CHECK_MODULES(LIBGLABELS, \
 103 glib-2.0 >= $GLIB_REQUIRED \
 104 libxml-2.0 >= $LIBXML_REQUIRED \
 105 )
 106
 107 AC_SUBST(LIBGLABELS_CFLAGS)
 108 AC_SUBST(LIBGLABELS_LIBS)
 109
 110
 111 dnl ---------------------------------------------------------------------------
 112 dnl - Enable deprecation testing
 113 dnl ---------------------------------------------------------------------------
 114 AC_ARG_ENABLE(deprecations,
 115               [AC_HELP_STRING([--enable-deprecations],
 116                               [warn about deprecated usages [default=no]])],,
 117               [enable_deprecations=no])
 118
 119 if test "x$enable_deprecations" = "xyes"; then
 120    DISABLE_DEPRECATED_CFLAGS="\
 121 -DG_DISABLE_DEPRECATED \
 122 -DGDK_DISABLE_DEPRECATED \
 123 -DGTK_DISABLE_DEPRECATED \
 124 -DGDK_PIXBUF_DISABLE_DEPRECATED \
 125 "
 126    AC_SUBST(DISABLE_DEPRECATED_CFLAGS)
 127 fi
 128
 129
 130 dnl ---------------------------------------------------------------------------
 131 dnl - Is freedesktop mime dbase available?
 132 dnl ---------------------------------------------------------------------------
 133 AC_PATH_PROG(UPDATE_MIME_DATABASE, update-mime-database, no)
 134 AM_CONDITIONAL(HAVE_NEW_MIME, test x$UPDATE_MIME_DATABASE != xno)
 135
 136 AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, update-desktop-database, no)
 137 AM_CONDITIONAL(HAVE_NEWER_MIME, test x$UPDATE_DESKTOP_DATABASE != xno)
 138
 139 AC_ARG_ENABLE(update-mimedb, AC_HELP_STRING([--disable-update-mimedb],
 140               [disable the update-mime-database after install [default=no]]),,
 141               enable_update_mimedb=yes)
 142 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
 143
 144 AC_ARG_ENABLE(update-desktopdb, AC_HELP_STRING([--disable-update-desktopdb],
 145               [disable the update-desktop-database after install [default=no]]),,
 146               enable_update_desktopdb=yes)
 147 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)
 148
 149
 150 dnl ---------------------------------------------------------------------------
 151 dnl - Supported languages
 152 dnl ---------------------------------------------------------------------------
 153 GETTEXT_PACKAGE=glabels
 154 AC_SUBST(GETTEXT_PACKAGE)
 155 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
 156
 157 dnl Add the languages here.
 158 ALL_LINGUAS="fr de ja pt_BR es ru zh_TW.Big5 pl cs it eo ko"
 159 AM_GLIB_GNU_GETTEXT
 160
 161
 162 dnl ---------------------------------------------------------------------------
 163 dnl - Makefiles, etc.
 164 dnl ---------------------------------------------------------------------------
 165 AC_OUTPUT([
 166 Makefile
 167 barcode-0.98/Makefile
 168 iec16022-0.2.1/Makefile
 169 libglabels/Makefile
 170 libglabels/libglabels.pc
 171 src/Makefile
 172 src/pixmaps/Makefile
 173 src/stock-pixmaps/Makefile
 174 data/Makefile
 175 data/templates/Makefile
 176 data/pixmaps/Makefile
 177 data/mime/Makefile
 178 data/builder/Makefile
 179 data/desktop/Makefile
 180 data/dtd/Makefile
 181 data/man/Makefile
 182 po/Makefile.in
 183 help/Makefile
 184 help/C/Makefile
 185 docs/Makefile
 186 docs/libglabels/Makefile
 187 glabels.spec
 188 ])
 189
 190
 191 dnl ---------------------------------------------------------------------------
 192 dnl - Print configuration information
 193 dnl ---------------------------------------------------------------------------
 194 echo "
 195 Configuration:
 196
 197         Package:                        ${PACKAGE}-${VERSION}:
 198         Installation prefix             ${prefix}
 199         Source code location:           ${srcdir}
 200         Compiler:                       ${CC}
 201         Evolution Data Server support:  ${have_libebook}
 202
 203 "
 204
 205 cat ${srcdir}/MESSAGE-OF-DOOM
 206