git.sur5r.net Git - glabels/blob - glabels2/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.52)
   4
   5 AC_INIT(glabels, 2.3.pre0svn, http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116)
   6 AC_CONFIG_SRCDIR(src/glabels.c)
   7 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   8
   9 AM_MAINTAINER_MODE
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AC_PROG_INTLTOOL([0.21])
  13 PKG_PROG_PKG_CONFIG
  14
  15 AM_PROG_LIBTOOL
  16
  17 AC_ISC_POSIX
  18 AC_PROG_CC
  19 AM_PROG_CC_STDC
  20 AC_HEADER_STDC
  21
  22 GNOME_COMPILE_WARNINGS
  23
  24 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
  25 AC_PATH_PROG(GTK_BUILDER_CONVERT, gtk-builder-convert)
  26
  27 GTK_DOC_CHECK(1.0)
  28
  29 dnl ---------------------------------------------------------------------------
  30 dnl - LIBGLABELS API versioning
  31 dnl ---------------------------------------------------------------------------
  32 dnl From the libtool manual:
  33 dnl 1. Start with version information of `0:0:0' for each libtool library.
  34 dnl 2. Update the version information only immediately before a public release.
  35 dnl    More frequent updates are unnecessary, and only guarantee that the current
  36 dnl    interface number gets larger faster.
  37 dnl 3. If the library source code has changed at all since the last update, then increment
  38 dnl    revision (`c:r:a' becomes `c:r+1:a').
  39 dnl 4. If any interfaces have been added, removed, or changed since the last update,
  40 dnl    increment current, and set revision to 0.
  41 dnl 5. If any interfaces have been added since the last public release, then increment age.
  42 dnl 6. If any interfaces have been removed since the last public release, then set age
  43 dnl    to 0.
  44 LIBGLABELS_C=5
  45 LIBGLABELS_R=1
  46 LIBGLABELS_A=0
  47
  48 LIBGLABELS_VERSION_INFO=${LIBGLABELS_C}:${LIBGLABELS_R}:${LIBGLABELS_A}
  49 AC_SUBST(LIBGLABELS_VERSION_INFO)
  50
  51
  52 dnl ---------------------------------------------------------------------------
  53 dnl - Library dependencies
  54 dnl ---------------------------------------------------------------------------
  55 GLIB_REQUIRED=2.12.0
  56 GTK_REQUIRED=2.10.0
  57 LIBGNOME_REQUIRED=2.16.0
  58 LIBGNOMEUI_REQUIRED=2.16.0
  59 LIBXML_REQUIRED=2.6.0
  60 LIBEBOOK_REQUIRED=1.8.0
  61
  62 dnl Make above strings available for packaging files (e.g. rpm spec files)
  63 AC_SUBST(GLIB_REQUIRED)
  64 AC_SUBST(GTK_REQUIRED)
  65 AC_SUBST(LIBGNOME_REQUIRED)
  66 AC_SUBST(LIBGNOMEUI_REQUIRED)
  67 AC_SUBST(LIBXML_REQUIRED)
  68 AC_SUBST(LIBEBOOK_REQUIRED)
  69
  70
  71 dnl ---------------------------------------------------------------------------
  72 dnl - Check for evolution data server
  73 dnl ---------------------------------------------------------------------------
  74 AC_ARG_WITH(libebook,
  75             [AC_HELP_STRING([--without-libebook],
  76                             [build without Evolution Data Server support])])
  77 have_libebook=no
  78 if test "x$with_libebook" != xno; then
  79         PKG_CHECK_MODULES(LIBEBOOK, libebook-1.2 >= $LIBEBOOK_REQUIRED,
  80                           [have_libebook=yes], [have_libebook=no])
  81 fi
  82
  83 if test "x$have_libebook" = "xyes"; then
  84         AC_DEFINE(HAVE_LIBEBOOK,1,[Define to 1 for EDS support])
  85         OPTIONAL_MODULES="$OPTIONAL_MODULES libebook-1.2 >= $LIBEBOOK_REQUIRED"
  86 fi
  87
  88
  89 dnl ---------------------------------------------------------------------------
  90 dnl - GLABELS prerequisites
  91 dnl ---------------------------------------------------------------------------
  92 PKG_CHECK_MODULES(GLABELS, \
  93 glib-2.0 >= $GLIB_REQUIRED \
  94 gtk+-2.0 >= $GTK_REQUIRED \
  95 libgnome-2.0 >= $LIBGNOME_REQUIRED \
  96 libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED \
  97 libxml-2.0 >= $LIBXML_REQUIRED \
  98 $OPTIONAL_MODULES \
  99 )
 100
 101 AC_SUBST(GLABELS_CFLAGS)
 102 AC_SUBST(GLABELS_LIBS)
 103
 104
 105 dnl ---------------------------------------------------------------------------
 106 dnl - LIBGLABELS more modest prerequisites
 107 dnl ---------------------------------------------------------------------------
 108 PKG_CHECK_MODULES(LIBGLABELS, \
 109 glib-2.0 >= $GLIB_REQUIRED \
 110 libxml-2.0 >= $LIBXML_REQUIRED \
 111 )
 112
 113 AC_SUBST(LIBGLABELS_CFLAGS)
 114 AC_SUBST(LIBGLABELS_LIBS)
 115
 116
 117 dnl ---------------------------------------------------------------------------
 118 dnl - Enable deprecation testing
 119 dnl ---------------------------------------------------------------------------
 120 AC_ARG_ENABLE(deprecations,
 121               [AC_HELP_STRING([--enable-deprecations],
 122                               [warn about deprecated usages [default=no]])],,
 123               [enable_deprecations=no])
 124
 125 if test "x$enable_deprecations" = "xyes"; then
 126    DISABLE_DEPRECATED_CFLAGS="\
 127 -DG_DISABLE_DEPRECATED \
 128 -DGDK_DISABLE_DEPRECATED \
 129 -DGTK_DISABLE_DEPRECATED \
 130 -DGDK_PIXBUF_DISABLE_DEPRECATED \
 131 -DGNOME_DISABLE_DEPRECATED \
 132 "
 133    AC_SUBST(DISABLE_DEPRECATED_CFLAGS)
 134 fi
 135
 136
 137 dnl ---------------------------------------------------------------------------
 138 dnl - Is freedesktop mime dbase available?
 139 dnl ---------------------------------------------------------------------------
 140 AC_PATH_PROG(UPDATE_MIME_DATABASE, update-mime-database, no)
 141 AM_CONDITIONAL(HAVE_NEW_MIME, test x$UPDATE_MIME_DATABASE != xno)
 142
 143 AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, update-desktop-database, no)
 144 AM_CONDITIONAL(HAVE_NEWER_MIME, test x$UPDATE_DESKTOP_DATABASE != xno)
 145
 146 AC_ARG_ENABLE(update-mimedb, AC_HELP_STRING([--disable-update-mimedb],
 147               [disable the update-mime-database after install [default=no]]),,
 148               enable_update_mimedb=yes)
 149 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
 150
 151 AC_ARG_ENABLE(update-desktopdb, AC_HELP_STRING([--disable-update-desktopdb],
 152               [disable the update-desktop-database after install [default=no]]),,
 153               enable_update_desktopdb=yes)
 154 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)
 155
 156
 157 dnl ---------------------------------------------------------------------------
 158 dnl - Supported languages
 159 dnl ---------------------------------------------------------------------------
 160 GETTEXT_PACKAGE=glabels
 161 AC_SUBST(GETTEXT_PACKAGE)
 162 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
 163
 164 dnl Add the languages here.
 165 ALL_LINGUAS="fr de ja pt_BR es ru zh_TW.Big5 pl cs it eo ko"
 166 AM_GLIB_GNU_GETTEXT
 167
 168
 169 dnl ---------------------------------------------------------------------------
 170 dnl - Makefiles, etc.
 171 dnl ---------------------------------------------------------------------------
 172 AC_OUTPUT([
 173 Makefile
 174 barcode-0.98/Makefile
 175 iec16022-0.2.1/Makefile
 176 libglabels/Makefile
 177 libglabels/libglabels.pc
 178 src/Makefile
 179 src/pixmaps/Makefile
 180 src/stock-pixmaps/Makefile
 181 data/Makefile
 182 data/templates/Makefile
 183 data/pixmaps/Makefile
 184 data/mime/Makefile
 185 data/builder/Makefile
 186 data/desktop/Makefile
 187 data/dtd/Makefile
 188 data/man/Makefile
 189 po/Makefile.in
 190 help/Makefile
 191 help/C/Makefile
 192 docs/Makefile
 193 docs/libglabels/Makefile
 194 glabels.spec
 195 ])
 196
 197
 198 dnl ---------------------------------------------------------------------------
 199 dnl - Print configuration information
 200 dnl ---------------------------------------------------------------------------
 201 echo "
 202 Configuration:
 203
 204         Package:                        ${PACKAGE}-${VERSION}:
 205         Installation prefix             ${prefix}
 206         Source code location:           ${srcdir}
 207         Compiler:                       ${CC}
 208         Evolution Data Server support:  ${have_libebook}
 209
 210 "
 211
 212 cat ${srcdir}/MESSAGE-OF-DOOM
 213