git.sur5r.net Git - cc65/blob - libsrc/c128/joy/c128-stdjoy.s

   1 ;
   2 ; Standard joystick driver for the C128. May be used multiple times when linked
   3 ; to the statically application.
   4
   5 ;
   6 ; Ullrich von Bassewitz, 2002-12-21
   7 ;
   8
   9         .include        "zeropage.inc"
  10
  11         .include        "joy-kernel.inc"
  12         .include        "joy-error.inc"
  13         .include        "c128.inc"
  14
  15         .macpack        generic
  16
  17
  18 ; ------------------------------------------------------------------------
  19 ; Header. Includes jump table
  20
  21 .segment        "HEADER"
  22
  23 ; Driver signature
  24
  25         .byte   $6A, $6F, $79           ; "joy"
  26         .byte   JOY_API_VERSION         ; Driver API version number
  27
  28 ; Library reference
  29
  30         .addr   $0000
  31
  32 ; Button state masks (8 values)
  33
  34         .byte   $01                     ; JOY_UP
  35         .byte   $02                     ; JOY_DOWN
  36         .byte   $04                     ; JOY_LEFT
  37         .byte   $08                     ; JOY_RIGHT
  38         .byte   $10                     ; JOY_FIRE
  39         .byte   $00                     ; JOY_FIRE2 unavailable
  40         .byte   $00                     ; Future expansion
  41         .byte   $00                     ; Future expansion
  42
  43 ; Jump table.
  44
  45         .addr   INSTALL
  46         .addr   UNINSTALL
  47         .addr   COUNT
  48         .addr   READ
  49         .addr   0                       ; IRQ entry not used
  50
  51 ; ------------------------------------------------------------------------
  52 ; Constants
  53
  54 JOY_COUNT       = 2             ; Number of joysticks we support
  55
  56
  57 ; ------------------------------------------------------------------------
  58 ; Data.
  59
  60
  61 .code
  62
  63 ; ------------------------------------------------------------------------
  64 ; INSTALL routine. Is called after the driver is loaded into memory. If
  65 ; possible, check if the hardware is present and determine the amount of
  66 ; memory available.
  67 ; Must return an JOY_ERR_xx code in a/x.
  68 ;
  69
  70 INSTALL:
  71         lda     #<JOY_ERR_OK
  72         ldx     #>JOY_ERR_OK
  73 ;       rts                     ; Run into UNINSTALL instead
  74
  75 ; ------------------------------------------------------------------------
  76 ; UNINSTALL routine. Is called before the driver is removed from memory.
  77 ; Can do cleanup or whatever. Must not return anything.
  78 ;
  79
  80 UNINSTALL:
  81         rts
  82
  83
  84 ; ------------------------------------------------------------------------
  85 ; COUNT: Return the total number of available joysticks in a/x.
  86 ;
  87
  88 COUNT:
  89         lda     #<JOY_COUNT
  90         ldx     #>JOY_COUNT
  91         rts
  92
  93 ; ------------------------------------------------------------------------
  94 ; READ: Read a particular joystick passed in A.
  95 ;
  96
  97 READ:   tax                     ; Joystick number into X
  98         bne     joy2
  99
 100 ; Read joystick 1
 101
 102 joy1:   lda     #$7F
 103         sei
 104         sta     CIA1_PRA
 105         lda     CIA1_PRB
 106         cli
 107         and     #$1F
 108         eor     #$1F
 109         rts
 110
 111 ; Read joystick 2
 112
 113 joy2:   ldx     #0
 114         lda     #$E0
 115         ldy     #$FF
 116         sei
 117         sta     CIA1_DDRA
 118         lda     CIA1_PRA
 119         sty     CIA1_DDRA
 120         cli
 121         and     #$1F
 122         eor     #$1F
 123         rts
 124
 125