git.sur5r.net Git - cc65/blob - libsrc/geos-common/drivers/fio_module.s

   1 ;
   2 ; Low level file I/O routines, ONLY for module loading OR sth similar
   3 ;
   4 ; Maciej 'YTM/Elysium' Witkowiak <ytm@elysium.pl>
   5 ; 25.12.2002
   6 ;
   7 ; only ONE opened file at a time, only O_RDONLY flag
   8
   9 ; int open (const char* name, int flags, ...);  /* May take a mode argument */
  10 ; int __fastcall__ close (int fd);
  11 ; int __fastcall__ read (int fd, void* buf, unsigned count);
  12
  13 FILEDES         = 3             ; first free to use file descriptor
  14
  15             .importzp ptr1, ptr2, ptr3, tmp1
  16             .import addysp, popax, poptr1
  17             .import __oserror
  18             .import _FindFile, _ReadByte
  19             .export _open, _close, _read
  20
  21             .include "geossym.inc"
  22             .include "const.inc"
  23             .include "errno.inc"
  24             .include "fcntl.inc"
  25
  26 _open:
  27         cpy #4                  ; correct # of arguments (bytes)?
  28         beq @parmok             ; parameter count ok
  29         tya                     ; parm count < 4 shouldn't be needed to be...
  30         sec                     ; ...checked (it generates a c compiler warning)
  31         sbc #4
  32         tay
  33         jsr addysp              ; fix stack, throw away unused parameters
  34
  35 ; Parameters ok. Pop the flags and save them into tmp3
  36
  37 @parmok:
  38         jsr popax               ; Get flags
  39         sta tmp1
  40         jsr popptr1             ; Get name
  41
  42         lda filedesc            ; is there a file already open?
  43         bne @alreadyopen
  44
  45         lda tmp1                ; check open mode
  46         and #(O_RDWR | O_CREAT)
  47         cmp #O_RDONLY           ; only O_RDONLY is valid
  48         bne @badmode
  49
  50         lda ptr1
  51         ldx ptr1+1
  52         jsr _FindFile           ; try to find the file
  53         tax
  54         bne @oserror
  55
  56         lda dirEntryBuf + OFF_DE_TR_SC ; tr&se for ReadByte (r1)
  57         sta f_track
  58         lda dirEntryBuf + OFF_DE_TR_SC + 1
  59         sta f_sector
  60         lda #<diskBlkBuf        ; buffer for ReadByte (r4)
  61         sta f_buffer
  62         lda #>diskBlkBuf
  63         sta f_buffer+1
  64         ldx #0                  ; offset for ReadByte (r5)
  65         stx f_offset
  66         stx f_offset+1
  67         lda #0                  ; clear errors
  68         sta __oserror
  69         jsr __seterrno
  70         lda #FILEDES            ; return fd
  71         sta filedesc
  72         rts
  73 @badmode:
  74         lda #EINVAL             ; invalid parameters - invalid open mode
  75         .byte $2c               ; skip
  76 @alreadyopen:
  77         lda #EMFILE             ; too many opened files (there can be only one)
  78         jmp __directerrno       ; set errno, clear oserror, return -1
  79 @oserror:
  80         jmp __mappederrno       ; set platform error code, return -1
  81
  82 _close:
  83         lda #0
  84         sta __oserror
  85         jsr __seterrno          ; clear errors
  86         lda #0                  ; clear fd
  87         sta filedesc
  88         tax
  89         rts
  90
  91 _read:
  92     ; a/x - number of bytes
  93     ; popax - buffer ptr
  94     ; popax - fd, must be == to the above one
  95     ; return -1+__oserror or number of bytes read
  96
  97         eor #$ff
  98         sta ptr1
  99         txa
 100         eor #$ff
 101         sta ptr1+1              ; -(# of bytes to read)-1
 102         jsr popax
 103         sta ptr2
 104         stx ptr2+1              ; buffer ptr
 105         jsr popax
 106         cmp #FILEDES            ; lo-byte == FILEDES
 107         bne @filenotopen
 108         txa                     ; hi-byte == 0
 109         beq @fileok             ; fd must be == FILEDES
 110
 111 @filenotopen:
 112         lda #EBADF
 113         jmp __directerrno       ; Sets _errno, clears _oserror, returns -1
 114
 115 @fileok:
 116         lda #0
 117         sta ptr3
 118         sta ptr3+1              ; put 0 into ptr3 (number of bytes read)
 119         sta __oserror           ; clear error flags
 120         jsr __seterrno
 121
 122         lda f_track             ; restore stuff for ReadByte
 123         ldx f_sector
 124         sta r1L
 125         stx r1H
 126         lda f_buffer
 127         ldx f_buffer+1
 128         sta r4L
 129         stx r4H
 130         lda f_offset
 131         ldx f_offset+1
 132         sta r5L
 133         stx r5H
 134
 135         clc
 136         bcc @L3                 ; branch always
 137
 138 @L0:    jsr _ReadByte
 139         ldy #0                  ; store the byte
 140         sta (ptr2),y
 141         inc ptr2                ; increment target address
 142         bne @L1
 143         inc ptr2+1
 144
 145 @L1:    inc ptr3                ; increment byte count
 146         bne @L2
 147         inc ptr3+1
 148
 149 @L2:    lda __oserror           ; was there error ?
 150         beq @L3
 151         cmp #BFR_OVERFLOW       ; EOF?
 152         beq @done               ; yes, we're done
 153         jmp __mappederrno       ; no, we're screwed
 154
 155 @L3:    inc ptr1                ; decrement the count
 156         bne @L0
 157         inc ptr1+1
 158         bne @L0
 159
 160 @done:
 161         lda r1L                 ; preserve data for ReadByte
 162         ldx r1H
 163         sta f_track
 164         stx f_sector
 165         lda r4L
 166         ldx r4H
 167         sta f_buffer
 168         stx f_buffer+1
 169         lda r5L
 170         ldx r5H
 171         sta f_offset
 172         stx f_offset+1
 173
 174         lda ptr3                ; return byte count
 175         ldx ptr3+1
 176         rts
 177
 178 .bss
 179
 180 filedesc:
 181         .res 1                  ; file open flag - 0 (no file opened) or 1
 182 f_track:
 183         .res 1                  ; values preserved for ReadByte
 184 f_sector:
 185         .res 1
 186 f_offset:
 187         .res 2
 188 f_buffer:
 189         .res 2