git.sur5r.net Git - cc65/blob - libsrc/joystick/joy-kernel.s

   1 ;
   2 ; Ullrich von Bassewitz, 2002-12-20
   3 ;
   4 ; Common functions of the joystick API.
   5 ;
   6
   7         .export         joy_clear_ptr
   8
   9         .importzp       ptr1
  10         .interruptor    joy_irq         ; Export as IRQ handler
  11
  12         .include        "joy-kernel.inc"
  13         .include        "joy-error.inc"
  14
  15
  16 ;----------------------------------------------------------------------------
  17 ; Variables
  18
  19
  20 .bss
  21 _joy_drv:       .res    2               ; Pointer to driver
  22
  23 _joy_masks:     .res    .sizeof(JOY_HDR::MASKS)
  24
  25 ; Jump table for the driver functions.
  26 .data
  27 joy_vectors:
  28 joy_install:    jmp     $0000
  29 joy_uninstall:  jmp     $0000
  30 joy_count:      jmp     $0000
  31 joy_read:       jmp     $0000
  32 joy_irq:        .byte   $60, $00, $00   ; RTS plus two dummy bytes
  33
  34 ; Driver header signature
  35 .rodata
  36 joy_sig:        .byte   $6A, $6F, $79, JOY_API_VERSION  ; "joy", version
  37
  38
  39 ;----------------------------------------------------------------------------
  40 ; unsigned char __fastcall__ joy_install (void* driver);
  41 ; /* Install the driver once it is loaded */
  42
  43
  44 _joy_install:
  45         sta     _joy_drv
  46         sta     ptr1
  47         stx     _joy_drv+1
  48         stx     ptr1+1
  49
  50 ; Check the driver signature
  51
  52         ldy     #.sizeof(joy_sig)-1
  53 @L0:    lda     (ptr1),y
  54         cmp     joy_sig,y
  55         bne     inv_drv
  56         dey
  57         bpl     @L0
  58
  59 ; Copy the mask array
  60
  61         ldy     #JOY_HDR::MASKS + .sizeof(JOY_HDR::MASKS) - 1
  62         ldx     #.sizeof(JOY_HDR::MASKS)-1
  63 @L1:    lda     (ptr1),y
  64         sta     _joy_masks,x
  65         dey
  66         dex
  67         bpl     @L1
  68
  69 ; Copy the jump vectors
  70
  71         ldy     #JOY_HDR::JUMPTAB
  72         ldx     #0
  73 @L2:    inx                             ; Skip the JMP opcode
  74         jsr     copy                    ; Copy one byte
  75         jsr     copy                    ; Copy one byte
  76         cpy     #(JOY_HDR::JUMPTAB + .sizeof(JOY_HDR::JUMPTAB))
  77         bne     @L2
  78
  79         jsr     joy_install             ; Call driver install routine
  80
  81 ; Install the IRQ vector if the driver needs it. A/X contains the error code
  82 ; from joy_install, so don't use it.
  83
  84         ldy     joy_irq+2               ; Check high byte of IRQ vector
  85         beq     @L3                     ; Jump if vector invalid
  86         ldy     #$4C                    ; JMP opcode
  87         sty     joy_irq                 ; Activate IRQ routine
  88 @L3:    rts
  89
  90 ; Driver signature invalid
  91
  92 inv_drv:
  93         lda     #JOY_ERR_INV_DRIVER
  94         ldx     #0
  95         rts
  96
  97 ; Copy one byte from the jump vectors
  98
  99 copy:   lda     (ptr1),y
 100         iny
 101 set:    sta     joy_vectors,x
 102         inx
 103         rts
 104
 105 ;----------------------------------------------------------------------------
 106 ; unsigned char __fastcall__ joy_uninstall (void);
 107 ; /* Uninstall the currently loaded driver. Note: This call does not free
 108 ;  * allocated memory.
 109 ;  */
 110
 111 _joy_uninstall:
 112         lda     #$60                    ; RTS opcode
 113         sta     joy_irq                 ; Disable IRQ entry point
 114
 115         jsr     joy_uninstall           ; Call the driver routine
 116
 117 joy_clear_ptr:                          ; External entry point
 118         lda     #0
 119         sta     _joy_drv
 120         sta     _joy_drv+1              ; Clear the driver pointer
 121
 122         tax                             ; Return zero
 123         rts
 124