git.sur5r.net Git - minitube/blob - minitube.pro

   1 CONFIG += release
   2 TEMPLATE = app
   3 VERSION = 1.1
   4 DEFINES += APP_VERSION="$$VERSION"
   5 INCLUDEPATH += /usr/include/phonon
   6
   7 # TODO Saner string behaviour
   8 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
   9 TARGET = minitube
  10 QT += network \
  11     xml \
  12     phonon
  13 unix:!mac {
  14     QT += dbus
  15 }
  16 include(src/qtsingleapplication/qtsingleapplication.pri)
  17 HEADERS += src/MainWindow.h \
  18     src/SearchView.h \
  19     src/MediaView.h \
  20     src/AboutView.h \
  21     src/youtubesearch.h \
  22     src/video.h \
  23     src/youtubestreamreader.h \
  24     src/View.h \
  25     src/searchlineedit.h \
  26     src/urllineedit.h \
  27     src/spacer.h \
  28     src/constants.h \
  29     src/iconloader/qticonloader.h \
  30     src/faderwidget/FaderWidget.h \
  31     src/ListModel.h \
  32     src/playlist/PrettyItemDelegate.h \
  33     src/networkaccess.h \
  34     src/videomimedata.h \
  35     src/global.h \
  36     src/updatechecker.h \
  37     src/playlistwidget.h \
  38     src/searchparams.h \
  39     src/minisplitter.h \
  40     src/loadingwidget.h \
  41     src/videoareawidget.h \
  42     src/googlesuggest.h \
  43     src/videowidget.h \
  44     src/flickcharm.h \
  45     src/videodefinition.h \
  46     src/fontutils.h \
  47     src/thlibrary/thblackbar.h \
  48     src/gnomeglobalshortcutbackend.h \
  49     src/globalshortcuts.h \
  50     src/globalshortcutbackend.h
  51 SOURCES += src/main.cpp \
  52     src/MainWindow.cpp \
  53     src/SearchView.cpp \
  54     src/MediaView.cpp \
  55     src/AboutView.cpp \
  56     src/youtubesearch.cpp \
  57     src/youtubestreamreader.cpp \
  58     src/searchlineedit.cpp \
  59     src/urllineedit.cpp \
  60     src/spacer.cpp \
  61     src/video.cpp \
  62     src/iconloader/qticonloader.cpp \
  63     src/faderwidget/FaderWidget.cpp \
  64     src/ListModel.cpp \
  65     src/playlist/PrettyItemDelegate.cpp \
  66     src/videomimedata.cpp \
  67     src/updatechecker.cpp \
  68     src/networkaccess.cpp \
  69     src/playlistwidget.cpp \
  70     src/searchparams.cpp \
  71     src/minisplitter.cpp \
  72     src/loadingwidget.cpp \
  73     src/videoareawidget.cpp \
  74     src/googlesuggest.cpp \
  75     src/videowidget.cpp \
  76     src/flickcharm.cpp \
  77     src/videodefinition.cpp \
  78     src/constants.cpp \
  79     src/fontutils.cpp \
  80     src/thlibrary/thblackbar.cpp \
  81     src/gnomeglobalshortcutbackend.cpp \
  82     src/globalshortcuts.cpp \
  83     src/globalshortcutbackend.cpp
  84 RESOURCES += resources.qrc
  85 DESTDIR = build/target/
  86 OBJECTS_DIR = build/obj/
  87 MOC_DIR = build/moc/
  88 RCC_DIR = build/rcc/
  89
  90 # Tell Qt Linguist that we use UTF-8 strings in our sources
  91 CODECFORTR = UTF-8
  92 CODECFORSRC = UTF-8
  93 include(locale/locale.pri)
  94
  95 # deploy
  96 DISTFILES += CHANGES \
  97     COPYING
  98 unix {
  99     isEmpty(PREFIX):PREFIX = /usr
 100     BINDIR = $$PREFIX/bin
 101     INSTALLS += target
 102     target.path = $$BINDIR
 103     DATADIR = $$PREFIX/share
 104     PKGDATADIR = $$DATADIR/minitube
 105     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 106         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 107     INSTALLS += translations \
 108         desktop \
 109         iconsvg \
 110         icon16 \
 111         icon22 \
 112         icon32 \
 113         icon48 \
 114         icon64 \
 115         icon128 \
 116         icon256 \
 117         icon512
 118     translations.path = $$PKGDATADIR
 119     translations.files += $$DESTDIR/locale
 120     desktop.path = $$DATADIR/applications
 121     desktop.files += minitube.desktop
 122     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 123     iconsvg.files += data/minitube.svg
 124     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 125     icon16.files += data/16x16/minitube.png
 126     icon22.path = $$DATADIR/icons/hicolor/22x22/apps
 127     icon22.files += data/22x22/minitube.png
 128     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 129     icon32.files += data/32x32/minitube.png
 130     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 131     icon48.files += data/48x48/minitube.png
 132     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 133     icon64.files += data/64x64/minitube.png
 134     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 135     icon128.files += data/128x128/minitube.png
 136     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 137     icon256.files += data/256x256/minitube.png
 138     icon256.path = $$DATADIR/icons/hicolor/512x512/apps
 139     icon256.files += data/256x256/minitube.png
 140     icon512.path = $$DATADIR/icons/hicolor/512x512/apps
 141     icon512.files += data/512x512/minitube.png
 142 }
 143 mac|win32:include(local/local.pri)