git.sur5r.net Git - i3/i3/blob - src/cfgparse.l

   1 %{
   2 #include <stdio.h>
   3 #include "cfgparse.tab.h"
   4 #include <xcb/xcb.h>
   5
   6 #include "data.h"
   7 #include "config.h"
   8 %}
   9
  10 %Start BIND_COND
  11 %Start BIND_AWS_COND
  12 %Start BIND_A2WS_COND
  13 %Start ASSIGN_COND
  14 %Start COLOR_COND
  15 %Start SCREEN_COND
  16 %Start SCREEN_AWS_COND
  17
  18 %%
  19 <BIND_A2WS_COND>[^\n]+          { BEGIN(INITIAL); yylval.string = strdup(yytext); return STR; }
  20 ^#[^\n]*                        { return TOKCOMMENT; }
  21 [0-9]+                          { yylval.number = atoi(yytext); return NUMBER; }
  22 <COLOR_COND>[0-9a-fA-F]+        { yylval.string = strdup(yytext); return HEX; }
  23 bind                            { BEGIN(BIND_COND); return TOKBIND; }
  24 bindsym                         { BEGIN(BIND_COND); return TOKBINDSYM; }
  25 floating_modifier               { return TOKFLOATING_MODIFIER; }
  26 workspace                       { BEGIN(INITIAL); return TOKWORKSPACE; }
  27 screen                          { BEGIN(SCREEN_COND); return TOKSCREEN; }
  28 terminal                        { BEGIN(BIND_AWS_COND); return TOKTERMINAL; }
  29 font                            { BEGIN(BIND_AWS_COND); return TOKFONT; }
  30 assign                          { BEGIN(ASSIGN_COND); return TOKASSIGN; }
  31 set[^\n]*                       { return TOKCOMMENT; }
  32 ipc-socket                      { BEGIN(BIND_AWS_COND); return TOKIPCSOCKET; }
  33 exec                            { BEGIN(BIND_AWS_COND); return TOKEXEC; }
  34 client.focused                  { BEGIN(COLOR_COND); yylval.color = &config.client.focused; return TOKCOLOR; }
  35 client.focused_inactive         { BEGIN(COLOR_COND); yylval.color = &config.client.focused_inactive; return TOKCOLOR; }
  36 client.unfocused                { BEGIN(COLOR_COND); yylval.color = &config.client.unfocused; return TOKCOLOR; }
  37 client.urgent                   { BEGIN(COLOR_COND); yylval.color = &config.client.urgent; return TOKCOLOR; }
  38 bar.focused                     { BEGIN(COLOR_COND); yylval.color = &config.client.focused; return TOKCOLOR; }
  39 bar.unfocused                   { BEGIN(COLOR_COND); yylval.color = &config.client.unfocused; return TOKCOLOR; }
  40 bar.urgent                      { BEGIN(COLOR_COND); yylval.color = &config.client.urgent; return TOKCOLOR; }
  41 Mod1                            { yylval.number = BIND_MOD1; return MODIFIER; }
  42 Mod2                            { yylval.number = BIND_MOD2; return MODIFIER; }
  43 Mod3                            { yylval.number = BIND_MOD3; return MODIFIER; }
  44 Mod4                            { yylval.number = BIND_MOD4; return MODIFIER; }
  45 Mod5                            { yylval.number = BIND_MOD5; return MODIFIER; }
  46 control                         { return TOKCONTROL; }
  47 shift                           { return TOKSHIFT; }
  48 →                               { return TOKARROW; }
  49 \n                              /* ignore end of line */;
  50 <SCREEN_AWS_COND>x              { return (int)yytext[0]; }
  51 <BIND_COND>[ \t]+               { BEGIN(BIND_AWS_COND); return WHITESPACE; }
  52 <BIND_AWS_COND>[ \t]+           { BEGIN(BIND_A2WS_COND); return WHITESPACE; }
  53 <SCREEN_COND>[ \t]+             { BEGIN(SCREEN_AWS_COND); return WHITESPACE; }
  54 <SCREEN_AWS_COND>[ \t]+         { BEGIN(BIND_A2WS_COND); return WHITESPACE; }
  55 [ \t]+                          { return WHITESPACE; }
  56 \"[^\"]+\"                      {
  57                                   /* if ASSIGN_COND then */
  58                                   BEGIN(INITIAL);
  59                                   /* yylval will be the string, but without quotes */
  60                                   char *copy = strdup(yytext+1);
  61                                   copy[strlen(copy)-1] = '\0';
  62                                   yylval.string = copy;
  63                                   return QUOTEDSTRING;
  64                                 }
  65 <ASSIGN_COND>[^ \t]+            { BEGIN(INITIAL); yylval.string = strdup(yytext); return STR_NG; }
  66 [a-zA-Z]+                       { yylval.string = strdup(yytext); return WORD; }
  67 .                               { return (int)yytext[0]; }
  68 %%