git.sur5r.net Git - i3/i3/blob - src/cfgparse.l

   1 %option nounput
   2 %option noinput
   3 %option noyy_top_state
   4 %option stack
   5
   6 %{
   7 /*
   8  * vim:ts=8:expandtab
   9  *
  10  */
  11 #include <stdio.h>
  12 #include <string.h>
  13 #include <stdint.h>
  14 #include "cfgparse.tab.h"
  15 #include <xcb/xcb.h>
  16
  17 #include "data.h"
  18 #include "config.h"
  19 #include "log.h"
  20 #include "util.h"
  21
  22 int yycolumn = 1;
  23
  24 #define YY_DECL int yylex (struct context *context)
  25
  26 #define YY_USER_ACTION { \
  27         context->first_column = yycolumn; \
  28         context->last_column = yycolumn+yyleng-1; \
  29         yycolumn += yyleng; \
  30 }
  31
  32 %}
  33
  34 EOL     (\r?\n)
  35
  36 %s BIND_COND
  37 %s BINDSYM_COND
  38 %s BIND_AWS_COND
  39 %s BINDSYM_AWS_COND
  40 %s BIND_A2WS_COND
  41 %s ASSIGN_COND
  42 %s COLOR_COND
  43 %s OUTPUT_COND
  44 %s OUTPUT_AWS_COND
  45 %x BUFFER_LINE
  46
  47 %%
  48
  49         {
  50                 /* This is called when a new line is lexed. We only want the
  51                  * first line to match to go into state BUFFER_LINE */
  52                 if (context->line_number == 0) {
  53                         context->line_number = 1;
  54                         BEGIN(INITIAL);
  55                         yy_push_state(BUFFER_LINE);
  56                 }
  57         }
  58
  59 <BUFFER_LINE>^[^\r\n]*/{EOL}? {
  60         /* save whole line */
  61         context->line_copy = strdup(yytext);
  62
  63         yyless(0);
  64         yy_pop_state();
  65         yy_set_bol(true);
  66         yycolumn = 1;
  67 }
  68
  69
  70 <BIND_A2WS_COND>[^\n]+          { BEGIN(INITIAL); yylval.string = strdup(yytext); return STR; }
  71 <OUTPUT_AWS_COND>[a-zA-Z0-9_-]+ { yylval.string = strdup(yytext); return OUTPUT; }
  72 ^[ \t]*#[^\n]*                  { return TOKCOMMENT; }
  73 <COLOR_COND>[0-9a-fA-F]+        { yylval.string = strdup(yytext); return HEX; }
  74 [0-9]+                          { yylval.number = atoi(yytext); return NUMBER; }
  75 mode                            { return TOKMODE; }
  76 bind                            { BEGIN(BIND_COND); return TOKBIND; }
  77 bindsym                         { BEGIN(BINDSYM_COND); return TOKBINDSYM; }
  78 floating_modifier               { BEGIN(INITIAL); return TOKFLOATING_MODIFIER; }
  79 workspace                       { BEGIN(INITIAL); return TOKWORKSPACE; }
  80 output                          { BEGIN(OUTPUT_COND); return TOKOUTPUT; }
  81 screen                          {
  82                                   /* for compatibility until v3.φ */
  83                                   ELOG("Assignments to screens are DEPRECATED and will not work. " \
  84                                        "Please replace them with assignments to outputs.\n");
  85                                   BEGIN(OUTPUT_COND);
  86                                   return TOKOUTPUT;
  87                                 }
  88 terminal                        { BEGIN(BIND_AWS_COND); return TOKTERMINAL; }
  89 font                            { BEGIN(BIND_AWS_COND); return TOKFONT; }
  90 assign                          { BEGIN(ASSIGN_COND); return TOKASSIGN; }
  91 set[^\n]*                       { return TOKCOMMENT; }
  92 ipc-socket                      { BEGIN(BIND_AWS_COND); return TOKIPCSOCKET; }
  93 ipc_socket                      { BEGIN(BIND_AWS_COND); return TOKIPCSOCKET; }
  94 restart_state                   { BEGIN(BIND_AWS_COND); return TOKRESTARTSTATE; }
  95 default_orientation             { return TOK_ORIENTATION; }
  96 horizontal                      { return TOK_HORIZ; }
  97 vertical                        { return TOK_VERT; }
  98 auto                            { return TOK_AUTO; }
  99 workspace_layout                { return TOK_WORKSPACE_LAYOUT; }
 100 new_window                      { return TOKNEWWINDOW; }
 101 normal                          { return TOK_NORMAL; }
 102 none                            { return TOK_NONE; }
 103 1pixel                          { return TOK_1PIXEL; }
 104 focus_follows_mouse             { return TOKFOCUSFOLLOWSMOUSE; }
 105 workspace_bar                   { return TOKWORKSPACEBAR; }
 106 popup_during_fullscreen         { return TOK_POPUP_DURING_FULLSCREEN; }
 107 ignore                          { return TOK_IGNORE; }
 108 leave_fullscreen                { return TOK_LEAVE_FULLSCREEN; }
 109 default                         { /* yylval.number = MODE_DEFAULT; */return TOK_DEFAULT; }
 110 stacking                        { /* yylval.number = MODE_STACK; */return TOK_STACKING; }
 111 stacked                         { return TOK_STACKING; }
 112 tabbed                          { /* yylval.number = MODE_TABBED; */return TOK_TABBED; }
 113 stack-limit                     { return TOKSTACKLIMIT; }
 114 cols                            { /* yylval.number = STACK_LIMIT_COLS; */return TOKSTACKLIMIT; }
 115 rows                            { /* yylval.number = STACK_LIMIT_ROWS; */return TOKSTACKLIMIT; }
 116 exec                            { BEGIN(BIND_AWS_COND); return TOKEXEC; }
 117 client.background               { BEGIN(COLOR_COND); yylval.single_color = &config.client.background; return TOKSINGLECOLOR; }
 118 client.focused                  { BEGIN(COLOR_COND); yylval.color = &config.client.focused; return TOKCOLOR; }
 119 client.focused_inactive         { BEGIN(COLOR_COND); yylval.color = &config.client.focused_inactive; return TOKCOLOR; }
 120 client.unfocused                { BEGIN(COLOR_COND); yylval.color = &config.client.unfocused; return TOKCOLOR; }
 121 client.urgent                   { BEGIN(COLOR_COND); yylval.color = &config.client.urgent; return TOKCOLOR; }
 122 bar.focused                     { BEGIN(COLOR_COND); yylval.color = &config.bar.focused; return TOKCOLOR; }
 123 bar.unfocused                   { BEGIN(COLOR_COND); yylval.color = &config.bar.unfocused; return TOKCOLOR; }
 124 bar.urgent                      { BEGIN(COLOR_COND); yylval.color = &config.bar.urgent; return TOKCOLOR; }
 125 Mod1                            { yylval.number = BIND_MOD1; return MODIFIER; }
 126 Mod2                            { yylval.number = BIND_MOD2; return MODIFIER; }
 127 Mod3                            { yylval.number = BIND_MOD3; return MODIFIER; }
 128 Mod4                            { yylval.number = BIND_MOD4; return MODIFIER; }
 129 Mod5                            { yylval.number = BIND_MOD5; return MODIFIER; }
 130 Mode_switch                     { yylval.number = BIND_MODE_SWITCH; return MODIFIER; }
 131 control                         { return TOKCONTROL; }
 132 ctrl                            { return TOKCONTROL; }
 133 shift                           { return TOKSHIFT; }
 134 →                               { return TOKARROW; }
 135 {EOL}                           {
 136                                   FREE(context->line_copy);
 137                                   context->line_number++;
 138                                   BEGIN(INITIAL);
 139                                   yy_push_state(BUFFER_LINE);
 140                                 }
 141 <BIND_COND>[ \t]+               { BEGIN(BIND_AWS_COND); return WHITESPACE; }
 142 <BINDSYM_COND>[ \t]+            { BEGIN(BINDSYM_AWS_COND); return WHITESPACE; }
 143 <BIND_AWS_COND>[ \t]+           { BEGIN(BIND_A2WS_COND); return WHITESPACE; }
 144 <BINDSYM_AWS_COND>[ \t]+        { BEGIN(BIND_A2WS_COND); return WHITESPACE; }
 145 <OUTPUT_COND>[ \t]+             { BEGIN(OUTPUT_AWS_COND); return WHITESPACE; }
 146 <OUTPUT_AWS_COND>[ \t]+         { BEGIN(BIND_A2WS_COND); return WHITESPACE; }
 147 [ \t]+                          { return WHITESPACE; }
 148 \"[^\"]+\"                      {
 149                                   /* if ASSIGN_COND then */
 150                                   BEGIN(INITIAL);
 151                                   /* yylval will be the string, but without quotes */
 152                                   char *copy = strdup(yytext+1);
 153                                   copy[strlen(copy)-1] = '\0';
 154                                   yylval.string = copy;
 155                                   return QUOTEDSTRING;
 156                                 }
 157 <ASSIGN_COND>[^ \t]+            { BEGIN(INITIAL); yylval.string = strdup(yytext); return STR_NG; }
 158 <BINDSYM_AWS_COND>[a-zA-Z0-9_]+ { yylval.string = strdup(yytext); return WORD; }
 159 [a-zA-Z]+                       { yylval.string = strdup(yytext); return WORD; }
 160 .                               { return (int)yytext[0]; }
 161
 162 <<EOF>> {
 163         while (yy_start_stack_ptr > 0)
 164                 yy_pop_state();
 165         yyterminate();
 166 }
 167
 168 %%