git.sur5r.net Git - i3/i3/blob - src/cmdparse.l

   1 /*
   2  * vim:ts=4:sw=4:expandtab
   3  *
   4  * i3 - an improved dynamic tiling window manager
   5  * © 2009-2010 Michael Stapelberg and contributors (see also: LICENSE)
   6  *
   7  * cmdparse.l: the lexer for commands you send to i3 (or bind on keys)
   8  *
   9  */
  10 %option nounput
  11 %option noinput
  12 %option noyy_top_state
  13 %option stack
  14
  15 %{
  16 #include <stdio.h>
  17 #include <string.h>
  18 #include "cmdparse.tab.h"
  19
  20 #include "config.h"
  21 #include "util.h"
  22
  23 int cmdyycolumn = 1;
  24
  25 #define YY_DECL int yylex (struct context *context)
  26
  27 #define YY_USER_ACTION { \
  28     context->first_column = cmdyycolumn; \
  29     context->last_column = cmdyycolumn+yyleng-1; \
  30     cmdyycolumn += yyleng; \
  31 }
  32
  33 %}
  34
  35 EOL (\r?\n)
  36
  37 /* handle everything up to \n as a string */
  38 %s WANT_STRING
  39 /* first expect a whitespace, then a string */
  40 %s WANT_WS_STRING
  41 /* handle a quoted string or everything up to the next whitespace */
  42 %s WANT_QSTRING
  43
  44 %x BUFFER_LINE
  45
  46 %%
  47
  48     {
  49         /* This is called when a new line is lexed. We only want the
  50          * first line to match to go into state BUFFER_LINE */
  51         if (context->line_number == 0) {
  52             context->line_number = 1;
  53             BEGIN(INITIAL);
  54             yy_push_state(BUFFER_LINE);
  55         }
  56     }
  57
  58 <BUFFER_LINE>^[^\r\n]*/{EOL}? {
  59     /* save whole line */
  60     context->line_copy = sstrdup(yytext);
  61
  62     yyless(0);
  63     yy_pop_state();
  64     yy_set_bol(true);
  65     cmdyycolumn = 1;
  66 }
  67
  68 <WANT_STRING>[^\n]+             { BEGIN(INITIAL); cmdyylval.string = sstrdup(yytext); return STR; }
  69 <WANT_WS_STRING>[ \t]*          { BEGIN(WANT_STRING); return WHITESPACE; }
  70 <WANT_QSTRING>\"[^\"]+\"        {
  71                                   BEGIN(INITIAL);
  72                                   /* strip quotes */
  73                                   char *copy = sstrdup(yytext+1);
  74                                   copy[strlen(copy)-1] = '\0';
  75                                   cmdyylval.string = copy;
  76                                   return STR;
  77                                 }
  78
  79 [ \t]*                          { return WHITESPACE; }
  80 attach                          { return TOK_ATTACH; }
  81 exec                            { BEGIN(WANT_WS_STRING); return TOK_EXEC; }
  82 exit                            { return TOK_EXIT; }
  83 reload                          { return TOK_RELOAD; }
  84 restart                         { return TOK_RESTART; }
  85 kill                            { return TOK_KILL; }
  86 fullscreen                      { return TOK_FULLSCREEN; }
  87 global                          { return TOK_GLOBAL; }
  88 layout                          { return TOK_LAYOUT; }
  89 default                         { return TOK_DEFAULT; }
  90 stacked                         { return TOK_STACKED; }
  91 stacking                        { return TOK_STACKED; }
  92 tabbed                          { return TOK_TABBED; }
  93 border                          { return TOK_BORDER; }
  94 none                            { return TOK_NONE; }
  95 1pixel                          { return TOK_1PIXEL; }
  96 mode                            { return TOK_MODE; }
  97 tiling                          { return TOK_TILING; }
  98 floating                        { return TOK_FLOATING; }
  99 toggle                          { return TOK_TOGGLE; }
 100 workspace                       { BEGIN(WANT_WS_STRING); return TOK_WORKSPACE; }
 101 focus                           { return TOK_FOCUS; }
 102 move                            { return TOK_MOVE; }
 103 open                            { return TOK_OPEN; }
 104 next                            { return TOK_NEXT; }
 105 prev                            { return TOK_PREV; }
 106 split                           { return TOK_SPLIT; }
 107 horizontal                      { return TOK_HORIZONTAL; }
 108 vertical                        { return TOK_VERTICAL; }
 109 level                           { return TOK_LEVEL; }
 110 up                              { return TOK_UP; }
 111 down                            { return TOK_DOWN; }
 112 before                          { return TOK_BEFORE; }
 113 after                           { return TOK_AFTER; }
 114 restore                         { BEGIN(WANT_WS_STRING); return TOK_RESTORE; }
 115 mark                            { BEGIN(WANT_WS_STRING); return TOK_MARK; }
 116
 117 class                           { BEGIN(WANT_QSTRING); return TOK_CLASS; }
 118 id                              { BEGIN(WANT_QSTRING); return TOK_ID; }
 119 con_id                          { BEGIN(WANT_QSTRING); return TOK_CON_ID; }
 120 con_mark                        { BEGIN(WANT_QSTRING); return TOK_MARK; }
 121
 122 .                               { return (int)yytext[0]; }
 123
 124 <<EOF>> {
 125     while (yy_start_stack_ptr > 0)
 126         yy_pop_state();
 127     yyterminate();
 128 }
 129
 130 %%